git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$LD" || LD="ld -m elf_i386"
  28       test -n "$AS" || AS="as --32"
  29       host_cpu="i386"
  30     fi
  31     ;;
  32 esac
  33
  34 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  35 case $host_cpu in
  36   *i[[3456789]]86*)
  37     if test "x$enable_win16" != "xno"
  38     then
  39       enable_win16="yes"
  40     fi
  41     ;;
  42 esac
  43
  44 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  45 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  46 if test "x$enable_win16" != "xyes"
  47 then
  48   WIN16_FILES=""
  49   WIN16_INSTALL=""
  50 fi
  51
  52 dnl check for out of tree build with unclean source tree
  53 case "$srcdir" in
  54  .) ;;
  55  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  56       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  57 You need to run 'make distclean' in the source tree first.])
  58     fi ;;
  59 esac
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  67 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  68
  69 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  70   [if test -z "$with_wine_tools"; then
  71      if test "$cross_compiling" = "yes"; then
  72        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  73      else
  74        wine_cv_toolsdir="\$(TOPOBJDIR)"
  75      fi
  76    elif test -d "$with_wine_tools/tools/winebuild"; then
  77      case $with_wine_tools in
  78        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  79        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  80      esac
  81    else
  82      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  83    fi])
  84 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  85
  86 AC_PATH_XTRA
  87
  88 dnl Check for flex
  89 AC_CHECK_PROGS(FLEX,flex,none)
  90 if test "$FLEX" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  93 fi
  94
  95 dnl Check for bison
  96 AC_CHECK_PROGS(BISON,bison,none)
  97 if test "$BISON" = "none"
  98 then
  99   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 100 fi
 101
 102 AC_CHECK_TOOLS(AS,[gas as],as)
 103 AC_CHECK_TOOL(LD,ld,ld)
 104 AC_CHECK_TOOL(AR,ar,ar)
 105 AC_PROG_RANLIB
 106 AC_CHECK_TOOL(STRIP,strip,strip)
 107 AC_CHECK_TOOL(WINDRES,windres,false)
 108 AC_PROG_LN_S
 109 WINE_PROG_LN
 110 AC_PROG_EGREP
 111 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 112 AC_PROG_INSTALL
 113 dnl Prepend src dir to install path dir if it's a relative path
 114 case "$INSTALL" in
 115   [[\\/$]]* | ?:[[\\/]]* ) ;;
 116   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 117 esac
 118
 119 dnl Check for lint
 120 AC_CHECK_PROGS(LINT, lclint lint)
 121 if test "$LINT" = "lint"
 122 then
 123   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 124   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 125 fi
 126 AC_SUBST(LINT)
 127 AC_SUBST(LINTFLAGS)
 128
 129 dnl Check for various programs
 130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 131 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 132
 133 case $host_cpu in
 134   *i[[3456789]]86*)
 135     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 136     ;;
 137 esac
 138
 139 dnl **** Check for some libraries ****
 140
 141 dnl Check for -li386 for NetBSD and OpenBSD
 142 AC_CHECK_LIB(i386,i386_set_ldt)
 143 dnl Check for -lossaudio for NetBSD
 144 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpthread
 148 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 149
 150 AC_SUBST(XLIB,"")
 151 AC_SUBST(XFILES,"")
 152 AC_SUBST(OPENGLFILES,"")
 153 AC_SUBST(GLU32FILES,"")
 154 AC_SUBST(OPENGL_LIBS,"")
 155 AC_SUBST(QUARTZFILES,"")
 156
 157 dnl **** Check for header files ****
 158
 159 AC_CHECK_HEADERS(\
 160         AudioUnit/AudioUnit.h \
 161         Carbon/Carbon.h \
 162         CoreAudio/CoreAudio.h \
 163         DiskArbitration/DiskArbitration.h \
 164         IOKit/IOKitLib.h \
 165         alsa/asoundlib.h \
 166         arpa/inet.h \
 167         arpa/nameser.h \
 168         asm/types.h \
 169         capi20.h \
 170         cups/cups.h \
 171         curses.h \
 172         direct.h \
 173         dlfcn.h \
 174         elf.h \
 175         float.h \
 176         fontconfig/fontconfig.h \
 177         getopt.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/mach.h \
 199         mach/machine.h \
 200         machine/cpu.h \
 201         machine/limits.h \
 202         machine/soundcard.h \
 203         mntent.h \
 204         ncurses.h \
 205         netdb.h \
 206         netinet/in.h \
 207         netinet/in_systm.h \
 208         netinet/tcp.h \
 209         netinet/tcp_fsm.h \
 210         openssl/err.h \
 211         openssl/ssl.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/sockio.h \
 252         sys/soundcard.h \
 253         sys/statvfs.h \
 254         sys/strtio.h \
 255         sys/syscall.h \
 256         sys/sysctl.h \
 257         sys/time.h \
 258         sys/times.h \
 259         sys/uio.h \
 260         sys/un.h \
 261         sys/vm86.h \
 262         sys/wait.h \
 263         syscall.h \
 264         termios.h \
 265         unicode/ubidi.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285
 286 AC_CHECK_HEADERS([linux/ipx.h],,,
 287     [#include <sys/types.h>
 288      #ifdef HAVE_ASM_TYPES_H
 289      # include <asm/types.h>
 290      #endif
 291      #if HAVE_SYS_SOCKET_H
 292      # include <sys/socket.h>
 293      #endif])
 294
 295 AC_CHECK_HEADERS([resolv.h],,,
 296     [#include <sys/types.h>
 297      #if HAVE_SYS_SOCKET_H
 298      # include <sys/socket.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #if HAVE_ARPA_NAMESER_H
 304      # include <arpa/nameser.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 308
 309 AC_CHECK_HEADERS([pthread_np.h],,,
 310 [#ifdef HAVE_PTHREAD_H
 311 #include <pthread.h>
 312 #endif])
 313
 314 AC_CHECK_HEADERS([linux/videodev.h],,,
 315 [#ifdef HAVE_SYS_TIME_H
 316 #include <sys/time.h>
 317 #endif
 318 #include <sys/types.h>
 319 #ifdef HAVE_ASM_TYPES_H
 320 #include <asm/types.h>
 321 #endif])
 322
 323 dnl Check for broken kernel header that doesn't define __user
 324 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 325
 326 dnl **** Check for working dll ****
 327
 328 AC_SUBST(DLLEXT,"")
 329 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 330 AC_SUBST(LDSHARED,"")
 331 AC_SUBST(LDDLLFLAGS,"")
 332 AC_SUBST(LIBEXT,"so")
 333 AC_SUBST(IMPLIBEXT,"def")
 334 AC_SUBST(LDRPATH_INSTALL,"")
 335 AC_SUBST(LDRPATH_LOCAL,"")
 336 WINE_PATH_LDD
 337
 338 case $host_os in
 339   cygwin*|mingw32*)
 340     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 341     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 342     AC_CHECK_TOOL(MINGWAR,ar,false)
 343     if test "$DLLWRAP" = "false"; then
 344       LIBEXT="a"
 345     else
 346       dnl FIXME - check whether dllwrap works correctly...
 347       LIBEXT="dll"
 348     fi
 349     IMPLIBEXT="a"
 350     dnl We can't build 16-bit NE dlls
 351     WIN16_FILES=""
 352     WIN16_INSTALL=""
 353     ;;
 354   darwin*|macosx*)
 355     DLLEXT=".so"
 356     LIBEXT="dylib"
 357     DLLFLAGS="$DLLFLAGS -fPIC"
 358     LDDLLFLAGS="-bundle -multiply_defined suppress"
 359     LIBWINE_LDFLAGS="-multiply_defined suppress"
 360     LDSHARED="\$(CC) -dynamiclib"
 361     STRIP="$STRIP -x"
 362     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 363     dnl declare needed frameworks
 364     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 365     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 366     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 367     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 368     then
 369         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 370         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 371     fi
 372     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 373     then
 374         dnl CoreServices needed by AudioUnit
 375         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 376     fi
 377     case $host_cpu in
 378       *powerpc*)
 379         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 380         ;;
 381     esac
 382     dnl Enable quartz driver on Mac OS X
 383     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 384     then
 385         AC_SUBST(CARBONLIB,"-framework Carbon")
 386         QUARTZFILES='$(QUARTZFILES)'
 387     fi
 388     ;;
 389   *)
 390     DLLFLAGS="$DLLFLAGS -fPIC"
 391     DLLEXT=".so"
 392     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 393         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 394                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 395     if test "$ac_cv_c_dll_gnuelf" = "yes"
 396     then
 397       LDSHARED="\$(CC) -shared"
 398       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 399       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 400                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 401                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 402                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 403
 404       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 405
 406       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 407                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 408
 409       echo '{ global: *; };' >conftest.map
 410       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 411                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 412       rm -f conftest.map
 413
 414       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 415                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 416
 417       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 418                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 419                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 420           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 421                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 422                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 423
 424       case $host_cpu in
 425         *i[[3456789]]86* | x86_64)
 426           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 427                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 428           ;;
 429       esac
 430
 431     else
 432       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 433           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 434                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 435       if test "$ac_cv_c_dll_unixware" = "yes"
 436       then
 437         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 438         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 439
 440       else
 441         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 442           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 443         if test "$ac_cv_c_dll_hpux" = "yes"
 444         then
 445           LIBEXT="sl"
 446           DLLEXT=".sl"
 447           LDDLLFLAGS="-shared -fPIC"
 448           LDSHARED="\$(CC) -shared"
 449         fi
 450       fi
 451     fi
 452
 453     dnl Check for cross compiler to build test programs
 454     AC_SUBST(CROSSTEST,"")
 455     if test "$cross_compiling" = "no"
 456     then
 457       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 458       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 459       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 460       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 461       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 462     fi
 463     ;;
 464 esac
 465
 466 if test "$LIBEXT" = "a"; then
 467   AC_MSG_ERROR(
 468 [could not find a way to build shared libraries.
 469 It is currently not possible to build Wine without shared library
 470 (.so) support to allow transparent switch between .so and .dll files.
 471 If you are using Linux, you will need a newer binutils.]
 472 )
 473 fi
 474
 475 dnl **** Check for X11 ****
 476
 477 if test "$have_x" = "yes"
 478 then
 479     XLIB="-lXext -lX11"
 480     ac_save_CPPFLAGS="$CPPFLAGS"
 481     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 482
 483     dnl *** All of the following tests require X11/Xlib.h
 484     AC_CHECK_HEADERS([X11/Xlib.h \
 485                       X11/XKBlib.h \
 486                       X11/Xutil.h \
 487                       X11/Xcursor/Xcursor.h \
 488                       X11/extensions/shape.h \
 489                       X11/extensions/XInput.h \
 490                       X11/extensions/XShm.h \
 491                       X11/extensions/Xinerama.h \
 492                       X11/extensions/Xrandr.h \
 493                       X11/extensions/Xrender.h \
 494                       X11/extensions/xf86vmode.h],,,
 495 [#ifdef HAVE_X11_XLIB_H
 496 # include <X11/Xlib.h>
 497 #endif
 498 #ifdef HAVE_X11_XUTIL_H
 499 # include <X11/Xutil.h>
 500 #endif])
 501
 502         dnl *** Check for X keyboard extension
 503         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 504         then
 505               AC_CHECK_LIB(X11, XkbQueryExtension,
 506               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 507               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 508         fi
 509
 510         dnl *** Check for X Shm extension
 511         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 512         then
 513               AC_CHECK_LIB(Xext, XShmQueryExtension,
 514               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 515               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 516         fi
 517
 518         dnl *** Check for X shape extension
 519         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 520         then
 521               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 522               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 523               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 524         fi
 525
 526         dnl *** Check for XFree86 VMODE extension
 527         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 528         then
 529                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 530                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 531                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 532                   ],,
 533                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 534         fi
 535
 536         dnl *** Check for X RandR extension
 537         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 538         then
 539                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 540 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 541                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])],[])
 542         fi
 543
 544         dnl *** Check for Transform functions in Xrender
 545         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 546         then
 547               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 548                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 549                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 550                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 551         fi
 552
 553         dnl *** Check for Xinerama extension
 554         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 555         then
 556                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 557 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 558                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])],[])
 559         fi
 560
 561     dnl *** End of X11/Xlib.h check
 562
 563     dnl Check for the presence of OpenGL
 564     if test "x$with_opengl" != "xno"
 565     then
 566         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 567 [#ifdef HAVE_GL_GLX_H
 568 # include <GL/glx.h>
 569 #endif])
 570         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 571         then
 572             dnl Check for some problems due to old Mesa versions
 573             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 574               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 575                 [wine_cv_opengl_header_version_OK="yes"],
 576                 [wine_cv_opengl_header_version_OK="no"]))
 577
 578             if test "$wine_cv_opengl_header_version_OK" = "yes"
 579             then
 580                 dnl Check for the presence of the library
 581                 AC_CHECK_LIB(GL,glXCreateContext,
 582                              [OPENGL_LIBS="-lGL"
 583                              OPENGLFILES='$(OPENGLFILES)'
 584                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 585                              ,,
 586                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 587
 588                 dnl Check for GLU32 library.
 589                 AC_CHECK_LIB(GLU,gluLookAt,
 590                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 591                              GLU32FILES='$(GLU32FILES)']
 592                              ,,
 593                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 594                 )
 595              fi
 596          else
 597              wine_cv_opengl_headers_found="no"
 598          fi
 599     fi
 600     dnl **** Check for NAS ****
 601     AC_SUBST(NASLIBS,"")
 602     AC_CHECK_HEADERS(audio/audiolib.h,
 603          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 604           AC_CHECK_LIB(audio,AuCreateFlow,
 605                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 606                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 607                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 608                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 609                           [$X_LIBS])
 610                        ],,
 611                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 612
 613     CPPFLAGS="$ac_save_CPPFLAGS"
 614     XFILES='$(XFILES)'
 615 else
 616     XLIB=""
 617     X_CFLAGS=""
 618     X_LIBS=""
 619 fi
 620
 621 dnl **** Check for libxml2 ****
 622
 623 AC_SUBST(XML2LIBS,"")
 624 AC_SUBST(XML2INCL,"")
 625 AC_SUBST(XSLTLIBS,"")
 626 AC_SUBST(XSLTINCL,"")
 627 ac_save_CPPFLAGS="$CPPFLAGS"
 628 if test "$PKG_CONFIG" != "false"
 629 then
 630     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 631     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 632 else
 633     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 634     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 635 fi
 636 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 637 AC_CHECK_HEADERS(libxml/parser.h,
 638         [AC_CHECK_LIB(xml2, xmlParseMemory,
 639             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 640              XML2LIBS="$ac_xml_libs"
 641              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 642          AC_CHECK_LIB(xml2, xmlReadMemory,
 643             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 644          AC_CHECK_LIB(xml2, xmlNewDocPI,
 645             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 646     ])
 647 CPPFLAGS="$ac_save_CPPFLAGS"
 648 if test "$PKG_CONFIG" != "false"
 649 then
 650     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 651     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 652 else
 653     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 654     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 655 fi
 656 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 657 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 658         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 659             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 660              XSLTLIBS="$ac_xslt_libs"
 661              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 662         ],,
 663 [#ifdef HAVE_LIBXSLT_PATTERN_H
 664 # include <libxslt/pattern.h>
 665 #endif])
 666 CPPFLAGS="$ac_save_CPPFLAGS"
 667
 668 dnl **** Check for libhal ****
 669 AC_SUBST(HALINCL,"")
 670 if test "$PKG_CONFIG" != "false"
 671 then
 672     ac_save_CPPFLAGS="$CPPFLAGS"
 673     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 674     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 675     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 676     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 677     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 678     then
 679         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 680           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 681             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 682     fi
 683     CPPFLAGS="$ac_save_CPPFLAGS"
 684 fi
 685
 686 dnl **** Check which curses lib to use ***
 687 CURSESLIBS=""
 688 if test "$ac_cv_header_ncurses_h" = "yes"
 689 then
 690     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 691 elif test "$ac_cv_header_curses_h" = "yes"
 692 then
 693     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 694 fi
 695 ac_save_LIBS="$LIBS"
 696 LIBS="$LIBS $CURSESLIBS"
 697 AC_CHECK_FUNCS(mousemask)
 698 LIBS="$ac_save_LIBS"
 699
 700 dnl **** Check for SANE ****
 701 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 702 if test "$sane_devel" != "no"
 703 then
 704     ac_sane_incl="`$sane_devel --cflags`"
 705     ac_save_CPPFLAGS="$CPPFLAGS"
 706     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 707     AC_CHECK_HEADER(sane/sane.h,
 708         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 709     CPPFLAGS="$ac_save_CPPFLAGS"
 710 fi
 711
 712 dnl **** Check for libgphoto2 ****
 713 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 714 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 715 AC_SUBST(GPHOTO2LIBS,"")
 716 AC_SUBST(GPHOTO2INCL,"")
 717 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 718 then
 719     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 720     GPHOTO2LIBS=""
 721     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 722     do
 723       case "$i" in
 724         -L/usr/lib|-L/usr/lib64) ;;
 725         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 726       esac
 727     done
 728     ac_save_CPPFLAGS="$CPPFLAGS"
 729     ac_save_LIBS="$LIBS"
 730     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 731     LIBS="$LIBS $GPHOTO2LIBS"
 732     AC_CHECK_HEADER(gphoto2-camera.h,
 733                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 734                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 735                                   [GPHOTO2LIBS=""
 736                                   GPHOTO2INCL=""])],
 737                     [GPHOTO2LIBS=""
 738                     GPHOTO2INCL=""])
 739     LIBS="$ac_save_LIBS"
 740     CPPFLAGS="$ac_save_CPPFLAGS"
 741 fi
 742
 743 dnl **** Check for the ICU library ****
 744 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 745 then
 746     saved_libs="$LIBS"
 747     icu_libs="-lsicuuc -lsicudata -lstdc++ -lgcc_s"
 748     if test -n "$ICU_LIB_DIR"
 749     then
 750         icu_libs="-L$ICU_LIB_DIR $icu_libs"
 751     fi
 752     AC_MSG_CHECKING(whether can link with ICU libraries)
 753     LIBS="$saved_libs $icu_libs"
 754     AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <unicode/ubidi.h>]],[[ubidi_open()]])],
 755                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 756                  AC_SUBST(ICULIBS,"$icu_libs")
 757                  AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 758     LIBS="$saved_libs"
 759 fi
 760
 761 dnl **** Check for resolver library ***
 762 AC_SUBST(RESOLVLIBS,"")
 763 if test "$ac_cv_header_resolv_h" = "yes"
 764 then
 765     AC_CHECK_LIB(resolv, res_query,
 766         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 767          RESOLVLIBS="-lresolv"])
 768 fi
 769
 770 dnl **** Check for LittleCMS ***
 771 AC_SUBST(LCMSLIBS,"")
 772 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 773 then
 774     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 775         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 776          LCMSLIBS="-llcms"])
 777 fi
 778
 779 dnl **** Check for OpenLDAP ***
 780 AC_SUBST(LDAPLIBS,"")
 781 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 782 then
 783     AC_CHECK_LIB(ldap_r, ldap_initialize,
 784         [AC_CHECK_LIB(lber, ber_init,
 785             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 786              LDAPLIBS="-lldap_r -llber"],,
 787              [$LIBPTHREAD])],,
 788              [$LIBPTHREAD])
 789     WINE_CHECK_LIB_FUNCS(\
 790         ldap_count_references \
 791         ldap_first_reference \
 792         ldap_next_reference \
 793         ldap_parse_reference,
 794         [$LDAPLIBS $LIBPTHREAD])
 795 fi
 796
 797 dnl **** Check for FreeType 2 ****
 798 AC_SUBST(FREETYPELIBS,"")
 799 AC_SUBST(FREETYPEINCL,"")
 800 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 801 if test "$ft_devel" = "no"
 802 then
 803     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 804     if test "$ft_devel2" = "freetype2-config"
 805     then
 806         ft_devel=$ft_devel2
 807     fi
 808 fi
 809
 810 if test "$ft_devel" = "no"
 811 then
 812     wine_cv_msg_freetype=yes
 813 else
 814     FREETYPELIBS=`$ft_devel --libs`
 815     FREETYPEINCL=`$ft_devel --cflags`
 816     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 817     if test "$ft_lib" = "no"
 818     then
 819         wine_cv_msg_freetype=yes
 820         FREETYPELIBS=""
 821         FREETYPEINCL=""
 822     else
 823         ac_save_CPPFLAGS="$CPPFLAGS"
 824         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 825         AC_CHECK_HEADERS(ft2build.h \
 826                          freetype/freetype.h \
 827                          freetype/ftglyph.h \
 828                          freetype/tttables.h \
 829                          freetype/ftnames.h \
 830                          freetype/ftsnames.h \
 831                          freetype/ttnameid.h \
 832                          freetype/ftoutln.h \
 833                          freetype/ftwinfnt.h \
 834                          freetype/ftmodapi.h \
 835                          freetype/internal/sfnt.h,,,
 836                          [#if HAVE_FT2BUILD_H
 837                           #include <ft2build.h>
 838                           #endif])
 839         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 840                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 841           [Define if you have the <freetype/fttrigon.h> header file.])
 842                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 843         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 844         ac_save_CFLAGS="$CFLAGS"
 845         CFLAGS="$CFLAGS $FREETYPELIBS"
 846         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 847         CFLAGS="$ac_save_CFLAGS"
 848         CPPFLAGS="$ac_save_CPPFLAGS"
 849         dnl Check that we have at least freetype/freetype.h
 850         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 851         then
 852             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 853             wine_cv_msg_freetype=no
 854         else
 855             FREETYPELIBS=""
 856             FREETYPEINCL=""
 857             wine_cv_msg_freetype=yes
 858         fi
 859     fi
 860 fi
 861
 862 dnl Only build the fonts dir if we have both freetype and fontforge
 863 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 864 then
 865   AC_SUBST(FONTSSUBDIRS,"fonts")
 866 fi
 867
 868 dnl **** Check for parport (currently Linux only) ****
 869 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 870  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 871     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 872 if test "$ac_cv_c_ppdev" = "yes"
 873 then
 874     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 875 fi
 876
 877 dnl **** Check for va_copy ****
 878 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 879  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 880     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 881  )
 882 if test "$ac_cv_c_va_copy" = "yes"
 883 then
 884     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 885 fi
 886 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 887  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 888     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 889  )
 890 if test "$ac_cv_c___va_copy" = "yes"
 891 then
 892     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 893 fi
 894
 895 dnl **** Check for sigsetjmp ****
 896 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 897  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 898     sigsetjmp( buf, 1 );
 899     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 900  )
 901 if test "$ac_cv_c_sigsetjmp" = "yes"
 902 then
 903     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 904 fi
 905
 906 dnl **** Check for pthread_rwlock_t ****
 907 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 908 #include <pthread.h>])
 909
 910 dnl **** Check for pthread functions ****
 911 WINE_CHECK_LIB_FUNCS(\
 912         pthread_attr_get_np \
 913         pthread_getattr_np \
 914         pthread_get_stackaddr_np \
 915         pthread_get_stacksize_np,
 916         [$LIBPTHREAD])
 917
 918 dnl **** Check for EsounD ****
 919 AC_PATH_PROG(ESDCONFIG, esd-config)
 920 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 921 then
 922     ESD_CFLAGS=""
 923     for i in `$ESDCONFIG --cflags`
 924     do
 925       case "$i" in
 926         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 927       esac
 928     done
 929     ESD_LIBS=`$ESDCONFIG --libs`
 930     save_CFLAGS="$CFLAGS"
 931     CFLAGS="$CFLAGS $ESD_CFLAGS"
 932     AC_CHECK_LIB(esd,esd_open_sound,
 933         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 934          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 935          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 936     CFLAGS="$save_CFLAGS"
 937 fi
 938
 939 dnl **** Check for ALSA 1.x ****
 940 AC_SUBST(ALSALIBS,"")
 941 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 942 then
 943     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 944         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
 945 #include <alsa/asoundlib.h>
 946 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 947 #include <sys/asoundlib.h>
 948 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
 949                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 950                          ALSALIBS="-lasound"],[])])
 951 fi
 952
 953 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 954
 955 AC_SUBST(AUDIOIOLIBS,"")
 956 if test "$ac_cv_header_libaudioio_h" = "yes"
 957 then
 958     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 959                   [AUDIOIOLIBS="-laudioio"
 960                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 961 fi
 962
 963 dnl **** Check for capi4linux ****
 964
 965 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 966 then
 967     WINE_CHECK_SONAME(capi20,capi20_register)
 968 fi
 969
 970 dnl **** Check for cups ****
 971 if test "$ac_cv_header_cups_cups_h" = "yes"
 972 then
 973     WINE_CHECK_SONAME(cups,cupsGetDefault)
 974 fi
 975
 976 dnl **** Check for jack ****
 977 if test "$ac_cv_header_jack_jack_h" = "yes"
 978 then
 979     WINE_CHECK_SONAME(jack,jack_client_new)
 980 fi
 981
 982 dnl **** Check for gcc specific options ****
 983
 984 AC_SUBST(EXTRACFLAGS,"")
 985 if test "x${GCC}" = "xyes"
 986 then
 987   EXTRACFLAGS="-Wall -pipe"
 988
 989   dnl Check for strength-reduce bug
 990   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 991                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
 992 [[static int Array[[3]];
 993   unsigned int B = 3;
 994   int i;
 995   for(i=0; i<B; i++) Array[[i]] = i - 3;
 996   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 997   L[[i]] = 4;
 998   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
 999     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1000   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1001   then
1002     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1003   fi
1004
1005   dnl Check for some compiler flags
1006
1007   WINE_TRY_CFLAGS([-fshort-wchar],
1008                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1009                              [Specifies the compiler flag that forces a short wchar_t])])
1010   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1011   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1012   WINE_TRY_CFLAGS([-Wwrite-strings])
1013
1014   dnl Check for noisy string.h
1015   saved_CFLAGS="$CFLAGS"
1016   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1017   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1018       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1019   CFLAGS="$saved_CFLAGS"
1020   if test "$ac_cv_c_string_h_warnings" = "no"
1021   then
1022     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1023   fi
1024
1025   AC_SUBST(BUILTINFLAG,"")
1026   saved_CFLAGS="$CFLAGS"
1027   CFLAGS="$CFLAGS -Werror"
1028   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1029       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1030   CFLAGS="$saved_CFLAGS"
1031   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1032   then
1033     BUILTINFLAG="-fno-builtin"
1034   fi
1035 fi
1036
1037 dnl **** Check how to define a function in assembly code ****
1038
1039 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1040   WINE_TRY_ASM_LINK(
1041       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1042       ac_cv_asm_func_def=".def",
1043     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1044       ac_cv_asm_func_def=".type @function",
1045     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1046       ac_cv_asm_func_def=".type 2",
1047       ac_cv_asm_func_def="unknown")])]))
1048
1049 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1050 case "$ac_cv_asm_func_def" in
1051   ".def")
1052      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1053   ".type @function")
1054      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1055   ".type 2")
1056      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1057   *)
1058      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1059 esac
1060
1061 dnl **** Check for underscore on external symbols ****
1062
1063 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1064     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1065                       [extern int ac_test;],
1066                       [if (ac_test) return 1],
1067                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1068
1069 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1070 if test "$ac_cv_c_extern_prefix" = "yes"
1071 then
1072   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1073 else
1074   AC_DEFINE([__ASM_NAME(name)], [name])
1075 fi
1076
1077 dnl **** Platform-specific checks ****
1078
1079 AC_SUBST(LDPATH,"")
1080 case $build_os in
1081   cygwin*|mingw32*)
1082     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1083     ;;
1084   darwin*|macosx*)
1085     ;;
1086   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1087     if test -z "$LDRPATH_LOCAL"
1088     then
1089       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1090     fi
1091     ;;
1092   *)
1093     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1094     ;;
1095 esac
1096
1097 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1098 case $host_os in
1099   mingw32*)
1100     AC_SUBST(CRTLIBS,"-lmsvcrt")
1101     AC_SUBST(SOCKETLIBS,"-lws2_32")
1102     ;;
1103 esac
1104
1105 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1106 case $host_cpu in
1107   *i[[3456789]]86*)
1108     case $host_os in
1109       linux* | k*bsd*-gnu)
1110         AC_SUBST(MAIN_BINARY,"wine-glibc")
1111         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1112     esac
1113     ;;
1114 esac
1115
1116 dnl **** Get the soname for libraries that we load dynamically ****
1117
1118 AC_DEFINE_UNQUOTED(SONAME_EXT,[".$LIBEXT"],[Define to the file extension of shared libraries.])
1119
1120 WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
1121 WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1122 WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1123 WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1124 WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1125 WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1126 WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1127 WINE_CHECK_SONAME(freetype,FT_Init_FreeType,,,[$X_LIBS])
1128 WINE_CHECK_SONAME(GL,glXQueryExtension,,,[$X_LIBS $X_EXTRA_LIBS])
1129 WINE_CHECK_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1130 WINE_CHECK_SONAME(fontconfig,FcInit)
1131 WINE_CHECK_SONAME(ssl,SSL_library_init)
1132 WINE_CHECK_SONAME(crypto,BIO_new_socket)
1133 WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1134
1135
1136 dnl **** Check for functions ****
1137
1138 AC_CHECK_FUNCS(\
1139         _pclose \
1140         _popen \
1141         _snprintf \
1142         _spawnvp \
1143         _stricmp \
1144         _strnicmp \
1145         _vsnprintf \
1146         asctime_r \
1147         chsize \
1148         clone \
1149         dlopen \
1150         epoll_create \
1151         ffs \
1152         finite \
1153         fork \
1154         fpclass \
1155         fstatfs \
1156         fstatvfs \
1157         ftruncate \
1158         futimes \
1159         futimesat \
1160         getdirentries \
1161         getopt_long \
1162         getpagesize \
1163         getpwuid \
1164         gettid \
1165         gettimeofday \
1166         getuid \
1167         inet_pton \
1168         kqueue \
1169         lstat \
1170         memmove \
1171         mmap \
1172         pclose \
1173         poll \
1174         popen \
1175         prctl \
1176         pread \
1177         pwrite \
1178         readlink \
1179         rfork \
1180         sched_yield \
1181         select \
1182         setrlimit \
1183         settimeofday \
1184         sigaltstack \
1185         sigprocmask \
1186         snprintf \
1187         spawnvp \
1188         statfs \
1189         statvfs \
1190         strcasecmp \
1191         strerror \
1192         strncasecmp \
1193         strtold \
1194         tcgetattr \
1195         timegm \
1196         usleep \
1197         vsnprintf \
1198         wait4 \
1199         waitpid \
1200 )
1201
1202 dnl Check for -ldl
1203 if test "$ac_cv_func_dlopen" = no
1204 then
1205     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1206 fi
1207 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1208
1209 dnl Check for -lpoll for Mac OS X/Darwin
1210 if test "$ac_cv_func_poll" = no
1211 then
1212     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1213 fi
1214
1215 dnl Check for -lnsl for Solaris
1216 AC_SEARCH_LIBS(gethostbyname, nsl)
1217
1218 dnl Check for -lsocket for Solaris
1219 AC_SEARCH_LIBS(connect, socket)
1220
1221 dnl Check for -lresolv for Solaris
1222 AC_SEARCH_LIBS(inet_aton, resolv)
1223
1224 dnl **** Check for functions which may rely on -lsocket on Solaris.
1225 AC_CHECK_FUNCS(\
1226         getaddrinfo \
1227         getnameinfo \
1228         getnetbyname \
1229         getprotobyname \
1230         getprotobynumber \
1231         getservbyport \
1232         inet_network \
1233         sendmsg \
1234 )
1235
1236 dnl **** Check for types ****
1237
1238 AC_C_CONST
1239 AC_C_INLINE
1240 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1241 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1242 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1243
1244 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1245 [#ifdef HAVE_LINUX_INPUT_H
1246 #include <linux/input.h>
1247 #endif])
1248
1249 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1250                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1251 if test "$wine_cv_have_sigaddset" = "yes"
1252 then
1253   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1254 fi
1255
1256
1257 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1258         wine_cv_linux_gethostbyname_r_6,
1259         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1260     char *name=NULL;
1261     struct hostent he;
1262     struct hostent *result;
1263     char *buf=NULL;
1264     int bufsize=0;
1265     int res,errnr;
1266     char *addr=NULL;
1267     int addrlen=0;
1268     int addrtype=0;
1269     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1270     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1271     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1272         ])
1273    )
1274    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1275    then
1276       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1277                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1278    fi
1279
1280 if test "$ac_cv_header_linux_joystick_h" = "yes"
1281 then
1282    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1283         wine_cv_linux_joystick_22_api,
1284         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1285         #include <sys/ioctl.h>
1286         #include <sys/types.h>
1287         #include <linux/joystick.h>
1288
1289         struct js_event blub;
1290         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1291         #error "no 2.2 header"
1292         #endif
1293         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1294    )
1295    if test "$wine_cv_linux_joystick_22_api" = "yes"
1296    then
1297       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1298                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1299    fi
1300 fi
1301
1302 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1303
1304 dnl Check for statfs members
1305 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1306 [#include <sys/types.h>
1307 #ifdef HAVE_SYS_PARAM_H
1308 # include <sys/param.h>
1309 #endif
1310 #ifdef HAVE_SYS_MOUNT_H
1311 # include <sys/mount.h>
1312 #endif
1313 #ifdef HAVE_SYS_VFS_H
1314 # include <sys/vfs.h>
1315 #endif
1316 #ifdef HAVE_SYS_STATFS_H
1317 # include <sys/statfs.h>
1318 #endif])
1319
1320 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1321 [#ifdef HAVE_SYS_STATVFS_H
1322 #include <sys/statvfs.h>
1323 #endif])
1324
1325 dnl Check for socket structure members
1326 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1327 [#include <sys/types.h>
1328 #ifdef HAVE_SYS_SOCKET_H
1329 # include <sys/socket.h>
1330 #endif
1331 #ifdef HAVE_SYS_UN_H
1332 # include <sys/un.h>
1333 #endif])
1334
1335 dnl Check for scsireq_t and sg_io_hdr_t members
1336 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1337 [#include <sys/types.h>
1338 #ifdef HAVE_SCSI_SG_H
1339 #include <scsi/sg.h>
1340 #endif])
1341
1342 dnl Check for siginfo_t members
1343 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1344
1345 dnl Check for struct mtget members
1346 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1347 [#include <sys/types.h>
1348 #ifdef HAVE_SYS_MTIO_H
1349 #include <sys/mtio.h>
1350 #endif])
1351
1352 dnl Check for struct option
1353 AC_CHECK_MEMBERS([struct option.name],,,
1354 [#ifdef HAVE_GETOPT_H
1355 #include <getopt.h>
1356 #endif])
1357
1358 dnl Check for stat.st_blocks
1359 AC_CHECK_MEMBERS([struct stat.st_blocks])
1360
1361 dnl Check for sin6_scope_id
1362 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1363 [#ifdef HAVE_SYS_TYPES_H
1364 #include <sys/types.h>
1365 #endif
1366 #ifdef HAVE_NETINET_IN_H
1367 #include <netinet/in.h>
1368 #endif])
1369
1370 dnl Check for ns_msg ptr member
1371 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1372 [#ifdef HAVE_SYS_TYPES_H
1373 #include <sys/types.h>
1374 #endif
1375 #ifdef HAVE_NETINET_IN_H
1376 # include <netinet/in.h>
1377 #endif
1378 #ifdef HAVE_ARPA_NAMESER_H
1379 # include <arpa/nameser.h>
1380 #endif])
1381
1382 dnl Check for the external timezone variables timezone and daylight
1383 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1384                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1385 if test "$ac_cv_have_timezone" = "yes"
1386 then
1387     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1388 fi
1389 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1390                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1391 if test "$ac_cv_have_daylight" = "yes"
1392 then
1393     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1394 fi
1395
1396 dnl *** check for the need to define platform-specific symbols
1397
1398 case $host_cpu in
1399   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1400   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1401   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1402   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1403   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1404 esac
1405
1406 case $host_vendor in
1407   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1408 esac
1409
1410 dnl **** Generate output files ****
1411
1412 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1413 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1414 ["### Dependencies:\\
1415 \\
1416 .INIT: Makefile\\
1417 .BEGIN: Makefile\\
1418 Makefile: dummy\\
1419         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1420 \\
1421 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1422 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1423 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1424 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1425 ["### Dependencies:
1426
1427 .INIT: Makefile
1428 .BEGIN: Makefile
1429 Makefile: dummy
1430         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1431
1432 \$(OBJS): \$(IDL_GEN_HEADERS)
1433 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1434 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1435 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1436
1437 AH_TOP([#define __WINE_CONFIG_H])
1438
1439 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1440
1441 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1442 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1443 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1444 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1445 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1446 WINE_CONFIG_EXTRA_DIR(include/wine)
1447
1448 MAKE_RULES=Make.rules
1449 AC_SUBST_FILE(MAKE_RULES)
1450
1451 MAKE_DLL_RULES=dlls/Makedll.rules
1452 AC_SUBST_FILE(MAKE_DLL_RULES)
1453
1454 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1455 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1456
1457 MAKE_TEST_RULES=dlls/Maketest.rules
1458 AC_SUBST_FILE(MAKE_TEST_RULES)
1459
1460 MAKE_PROG_RULES=programs/Makeprog.rules
1461 AC_SUBST_FILE(MAKE_PROG_RULES)
1462
1463 AC_CONFIG_FILES([Make.rules])
1464 AC_CONFIG_FILES([dlls/Makedll.rules])
1465 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1466 AC_CONFIG_FILES([dlls/Maketest.rules])
1467 AC_CONFIG_FILES([programs/Makeprog.rules])
1468 AC_CONFIG_FILES([Makefile])
1469 AC_CONFIG_FILES([dlls/Makefile])
1470 AC_CONFIG_FILES([dlls/acledit/Makefile])
1471 AC_CONFIG_FILES([dlls/activeds/Makefile])
1472 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1473 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1474 AC_CONFIG_FILES([dlls/advpack/Makefile])
1475 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1476 AC_CONFIG_FILES([dlls/amstream/Makefile])
1477 AC_CONFIG_FILES([dlls/atl/Makefile])
1478 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1479 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1480 AC_CONFIG_FILES([dlls/browseui/Makefile])
1481 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1482 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1483 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1484 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1485 AC_CONFIG_FILES([dlls/cards/Makefile])
1486 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1487 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1488 AC_CONFIG_FILES([dlls/comcat/Makefile])
1489 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1490 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1491 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1492 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1493 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1494 AC_CONFIG_FILES([dlls/compstui/Makefile])
1495 AC_CONFIG_FILES([dlls/credui/Makefile])
1496 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1497 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1498 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1499 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1500 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1501 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1502 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1503 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1504 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1505 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1506 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1507 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1508 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1509 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1510 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1511 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1512 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1513 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1514 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1515 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1516 AC_CONFIG_FILES([dlls/devenum/Makefile])
1517 AC_CONFIG_FILES([dlls/dinput/Makefile])
1518 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1519 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1520 AC_CONFIG_FILES([dlls/dmband/Makefile])
1521 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1522 AC_CONFIG_FILES([dlls/dmime/Makefile])
1523 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1524 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1525 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1526 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1527 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1528 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1529 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1530 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1531 AC_CONFIG_FILES([dlls/dplay/Makefile])
1532 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1533 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1534 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1535 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1536 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1537 AC_CONFIG_FILES([dlls/dsound/Makefile])
1538 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1539 AC_CONFIG_FILES([dlls/dswave/Makefile])
1540 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1541 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1542 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1543 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1544 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1545 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1546 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1547 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1548 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1549 AC_CONFIG_FILES([dlls/glu32/Makefile])
1550 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1551 AC_CONFIG_FILES([dlls/hal/Makefile])
1552 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1553 AC_CONFIG_FILES([dlls/hid/Makefile])
1554 AC_CONFIG_FILES([dlls/hlink/Makefile])
1555 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1556 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1557 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1558 AC_CONFIG_FILES([dlls/icmp/Makefile])
1559 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1560 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1561 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1562 AC_CONFIG_FILES([dlls/imm32/Makefile])
1563 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1564 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1565 AC_CONFIG_FILES([dlls/inseng/Makefile])
1566 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1567 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1568 AC_CONFIG_FILES([dlls/itss/Makefile])
1569 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1570 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1571 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1572 AC_CONFIG_FILES([dlls/localspl/Makefile])
1573 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1574 AC_CONFIG_FILES([dlls/localui/Makefile])
1575 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1576 AC_CONFIG_FILES([dlls/lz32/Makefile])
1577 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1578 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1579 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1580 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1581 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1582 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1583 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1584 AC_CONFIG_FILES([dlls/midimap/Makefile])
1585 AC_CONFIG_FILES([dlls/mlang/Makefile])
1586 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1587 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1588 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1589 AC_CONFIG_FILES([dlls/mpr/Makefile])
1590 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1591 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1592 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1593 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1594 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1595 AC_CONFIG_FILES([dlls/mscms/Makefile])
1596 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1597 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1598 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1599 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1600 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1601 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1602 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1603 AC_CONFIG_FILES([dlls/msi/Makefile])
1604 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1605 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1606 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1607 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1608 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1609 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1610 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1611 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1612 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1613 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1614 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1615 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1616 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1617 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1618 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1619 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1620 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1621 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1622 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1623 AC_CONFIG_FILES([dlls/newdev/Makefile])
1624 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1625 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1626 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1627 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1628 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1629 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1630 AC_CONFIG_FILES([dlls/objsel/Makefile])
1631 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1632 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1633 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1634 AC_CONFIG_FILES([dlls/ole32/Makefile])
1635 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1636 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1637 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1638 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1639 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1640 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1641 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1642 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1643 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1644 AC_CONFIG_FILES([dlls/pdh/Makefile])
1645 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1646 AC_CONFIG_FILES([dlls/printui/Makefile])
1647 AC_CONFIG_FILES([dlls/psapi/Makefile])
1648 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1649 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1650 AC_CONFIG_FILES([dlls/qcap/Makefile])
1651 AC_CONFIG_FILES([dlls/quartz/Makefile])
1652 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1653 AC_CONFIG_FILES([dlls/query/Makefile])
1654 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1655 AC_CONFIG_FILES([dlls/resutils/Makefile])
1656 AC_CONFIG_FILES([dlls/riched20/Makefile])
1657 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1658 AC_CONFIG_FILES([dlls/riched32/Makefile])
1659 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1660 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1661 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1662 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1663 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1664 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1665 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1666 AC_CONFIG_FILES([dlls/schannel/Makefile])
1667 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1668 AC_CONFIG_FILES([dlls/secur32/Makefile])
1669 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1670 AC_CONFIG_FILES([dlls/security/Makefile])
1671 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1672 AC_CONFIG_FILES([dlls/serialui/Makefile])
1673 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1674 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1675 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1676 AC_CONFIG_FILES([dlls/sfc/Makefile])
1677 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1678 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1679 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1680 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1681 AC_CONFIG_FILES([dlls/shell32/Makefile])
1682 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1684 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1685 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1686 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1687 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1688 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1689 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1690 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1691 AC_CONFIG_FILES([dlls/sti/Makefile])
1692 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1693 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1694 AC_CONFIG_FILES([dlls/sxs/Makefile])
1695 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1696 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1697 AC_CONFIG_FILES([dlls/unicows/Makefile])
1698 AC_CONFIG_FILES([dlls/url/Makefile])
1699 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1700 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1701 AC_CONFIG_FILES([dlls/user32/Makefile])
1702 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1703 AC_CONFIG_FILES([dlls/userenv/Makefile])
1704 AC_CONFIG_FILES([dlls/usp10/Makefile])
1705 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1706 AC_CONFIG_FILES([dlls/uuid/Makefile])
1707 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1708 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1710 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1711 AC_CONFIG_FILES([dlls/version/Makefile])
1712 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1713 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1714 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1715 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1716 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1717 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1718 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1719 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1720 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1721 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1722 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1723 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1724 AC_CONFIG_FILES([dlls/winedos/Makefile])
1725 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1726 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1727 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1728 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1729 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1730 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1731 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1732 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1733 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1734 AC_CONFIG_FILES([dlls/wing32/Makefile])
1735 AC_CONFIG_FILES([dlls/wininet/Makefile])
1736 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1737 AC_CONFIG_FILES([dlls/winmm/Makefile])
1738 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1740 AC_CONFIG_FILES([dlls/winscard/Makefile])
1741 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1742 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1743 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1744 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1745 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1746 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1747 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1748 AC_CONFIG_FILES([dlls/wow32/Makefile])
1749 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1750 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1751 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1752 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1753 AC_CONFIG_FILES([documentation/Makefile])
1754 AC_CONFIG_FILES([fonts/Makefile])
1755 AC_CONFIG_FILES([include/Makefile])
1756 AC_CONFIG_FILES([libs/Makefile])
1757 AC_CONFIG_FILES([libs/port/Makefile])
1758 AC_CONFIG_FILES([libs/wine/Makefile])
1759 AC_CONFIG_FILES([libs/wpp/Makefile])
1760 AC_CONFIG_FILES([loader/Makefile])
1761 AC_CONFIG_FILES([programs/Makefile])
1762 AC_CONFIG_FILES([programs/clock/Makefile])
1763 AC_CONFIG_FILES([programs/cmd/Makefile])
1764 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1765 AC_CONFIG_FILES([programs/control/Makefile])
1766 AC_CONFIG_FILES([programs/eject/Makefile])
1767 AC_CONFIG_FILES([programs/expand/Makefile])
1768 AC_CONFIG_FILES([programs/explorer/Makefile])
1769 AC_CONFIG_FILES([programs/hh/Makefile])
1770 AC_CONFIG_FILES([programs/icinfo/Makefile])
1771 AC_CONFIG_FILES([programs/iexplore/Makefile])
1772 AC_CONFIG_FILES([programs/msiexec/Makefile])
1773 AC_CONFIG_FILES([programs/net/Makefile])
1774 AC_CONFIG_FILES([programs/notepad/Makefile])
1775 AC_CONFIG_FILES([programs/oleview/Makefile])
1776 AC_CONFIG_FILES([programs/progman/Makefile])
1777 AC_CONFIG_FILES([programs/regedit/Makefile])
1778 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1779 AC_CONFIG_FILES([programs/rpcss/Makefile])
1780 AC_CONFIG_FILES([programs/rundll32/Makefile])
1781 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1782 AC_CONFIG_FILES([programs/start/Makefile])
1783 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1784 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1785 AC_CONFIG_FILES([programs/view/Makefile])
1786 AC_CONFIG_FILES([programs/wineboot/Makefile])
1787 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1788 AC_CONFIG_FILES([programs/winecfg/Makefile])
1789 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1790 AC_CONFIG_FILES([programs/winedbg/Makefile])
1791 AC_CONFIG_FILES([programs/winedevice/Makefile])
1792 AC_CONFIG_FILES([programs/winefile/Makefile])
1793 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1794 AC_CONFIG_FILES([programs/winemine/Makefile])
1795 AC_CONFIG_FILES([programs/winepath/Makefile])
1796 AC_CONFIG_FILES([programs/winetest/Makefile])
1797 AC_CONFIG_FILES([programs/winevdm/Makefile])
1798 AC_CONFIG_FILES([programs/winhelp/Makefile])
1799 AC_CONFIG_FILES([programs/winver/Makefile])
1800 AC_CONFIG_FILES([programs/wordpad/Makefile])
1801 AC_CONFIG_FILES([programs/xcopy/Makefile])
1802 AC_CONFIG_FILES([server/Makefile])
1803 AC_CONFIG_FILES([tools/Makefile])
1804 AC_CONFIG_FILES([tools/widl/Makefile])
1805 AC_CONFIG_FILES([tools/winebuild/Makefile])
1806 AC_CONFIG_FILES([tools/winedump/Makefile])
1807 AC_CONFIG_FILES([tools/winegcc/Makefile])
1808 AC_CONFIG_FILES([tools/wmc/Makefile])
1809 AC_CONFIG_FILES([tools/wrc/Makefile])
1810
1811 AC_OUTPUT
1812
1813 dnl **** Display messages about additional packages ***
1814
1815 if test "$no_create" = "yes"
1816 then
1817   exit 0
1818 fi
1819
1820 if test "$verbose" = "yes"
1821 then
1822   dnl **** libcapi20-dev devel package ***
1823   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1824   then
1825     echo >&2
1826     AC_MSG_NOTICE([libcapi20 development files not found.])
1827     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1828   fi
1829
1830   dnl **** libcupsys-dev devel package ***
1831   if test "$ac_cv_header_cups_cups_h" != "yes"
1832   then
1833     echo >&2
1834     AC_MSG_NOTICE([libcups development files not found.])
1835     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1836   fi
1837
1838   dnl **** libcurses devel package: see libncurses ***
1839   dnl **** libdbus-1 devel package ***
1840   dnl **** libdbus-1-dev is required for libhal-dev ***
1841
1842   dnl **** libgphoto2 devel package ***
1843   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1844   then
1845     echo >&2
1846     AC_MSG_NOTICE([libgphoto2 development files not found.])
1847     if test "$ac_cv_header_sane_sane_h" = "yes"
1848     then
1849       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1850     else
1851       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1852     fi
1853   fi
1854
1855   dnl **** libhal devel package ***
1856   dnl **** libhal-dev depends on libdbus-1-dev ***
1857   if test "$ac_cv_header_hal_libhal_h" != "yes"
1858   then
1859     echo >&2
1860     AC_MSG_NOTICE([libhal development files not found.])
1861     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1862   fi
1863
1864   dnl **** libicu devel package ****
1865   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1866   then
1867     echo >&2
1868     AC_MSG_NOTICE([libicu development files not found.])
1869     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1870   fi
1871
1872   dnl **** liblcms devel package ****
1873   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1874   then
1875     echo >&2
1876     AC_MSG_NOTICE([liblcms development files not found.])
1877     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1878   fi
1879
1880   dnl **** libldap devel package ****
1881   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1882   then
1883     echo >&2
1884     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1885     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1886   fi
1887
1888   dnl **** libncurses / libcurses devel package ***
1889   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1890   then
1891     echo >&2
1892     AC_MSG_NOTICE([lib(n)curses development files not found.])
1893     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1894   fi
1895
1896   dnl **** libsane devel package ***
1897   if test "$ac_cv_header_sane_sane_h" != "yes"
1898   then
1899     echo >&2
1900     AC_MSG_NOTICE([libsane development files not found.])
1901     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1902   fi
1903
1904   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1905   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1906   if test "$have_x" = "yes"
1907   then
1908     dnl **** libX11 - extension: Xext ***
1909     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1910     then
1911       echo >&2
1912       AC_MSG_NOTICE([libxext development files not found.])
1913       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1914     fi
1915
1916     dnl **** libX11 - extension: Xrandr ***
1917     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1918     then
1919       echo >&2
1920       AC_MSG_NOTICE([libXrandr development files not found.])
1921       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1922     fi
1923
1924     dnl **** libX11 - extension: Xrender ***
1925     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1926     then
1927       echo >&2
1928       AC_MSG_NOTICE([libXrender development files not found.])
1929       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1930     fi
1931
1932     dnl **** libX11 - extension: Xxf86vm ***
1933     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1934     then
1935       echo >&2
1936       AC_MSG_NOTICE([libXxf86vm development files not found.])
1937       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1938     fi
1939   fi
1940
1941   dnl **** libxml2 devel package ***
1942   if test "$ac_cv_header_libxml_parser_h" != "yes"
1943   then
1944     echo >&2
1945     AC_MSG_NOTICE([libxml2 development files not found.])
1946     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1947   fi
1948
1949   dnl **** libxslt devel package ***
1950   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1951   then
1952     echo >&2
1953     AC_MSG_NOTICE([libxslt development files not found.])
1954     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1955   fi
1956 fi
1957
1958
1959 dnl **** Display warnings about important packages ***
1960 if test "$have_x" = "no"
1961 then
1962   echo >&2
1963   AC_MSG_WARN([X development files not found. Wine will be built without])
1964   AC_MSG_WARN([X support, which currently does not work, and probably])
1965   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1966   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1967 fi
1968
1969 if test -z "$OPENGLFILES"
1970 then
1971   echo >&2
1972   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
1973   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
1974   if test "$wine_cv_opengl_headers_found" = "no"
1975   then
1976     AC_MSG_WARN([No OpenGL development headers were found])
1977   fi
1978   if test "$wine_cv_opengl_header_version_OK" = "no"
1979   then
1980     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1981   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
1982   then
1983      if test -f /usr/X11R6/lib/libGL.a
1984      then
1985         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
1986 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
1987      else
1988         AC_MSG_WARN([No OpenGL library found on this system.])
1989      fi
1990   fi
1991 fi
1992
1993 if test "$wine_cv_msg_freetype" = "yes"
1994 then
1995   echo >&2
1996   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
1997   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
1998   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
1999   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
2000 fi
2001
2002 if test -z "$FONTSSUBDIRS"
2003 then
2004   echo >&2
2005   if test "$FONTFORGE" = "false"
2006   then
2007     AC_MSG_WARN([FontForge is missing.])
2008   else
2009     AC_MSG_WARN([FreeType is missing.])
2010   fi
2011   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2012 fi
2013
2014 if test -z "$ALSALIBS" -a \
2015         -z "$AUDIOIOLIBS" -a \
2016         -z "$NASLIBS" -a \
2017         -z "$ESD_LIBS" -a \
2018         -z "$ac_cv_lib_soname_jack" -a \
2019         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2020         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2021         "$ac_cv_header_soundcard_h" != "yes"
2022 then
2023   echo >&2
2024   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2025   AC_MSG_WARN([The currently supported sound systems are:])
2026   AC_MSG_WARN([ALSA, EsounD, AudioIO, Jack, NAS and OSS])
2027 fi
2028
2029 echo
2030 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2031 echo
2032
2033 dnl Local Variables:
2034 dnl comment-start: "dnl "
2035 dnl comment-end: ""
2036 dnl comment-start-skip: "\\bdnl\\b\\s *"
2037 dnl compile-command: "autoreconf --warnings=all"
2038 dnl End: