git.oblomov.eu Git - wine/blob - dlls/vbscript/parser.y

   1 /*
   2  * Copyright 2011 Jacek Caban for CodeWeavers
   3  *
   4  * This library is free software; you can redistribute it and/or
   5  * modify it under the terms of the GNU Lesser General Public
   6  * License as published by the Free Software Foundation; either
   7  * version 2.1 of the License, or (at your option) any later version.
   8  *
   9  * This library is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * Lesser General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU Lesser General Public
  15  * License along with this library; if not, write to the Free Software
  16  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  17  */
  18
  19 %{
  20
  21 #include "vbscript.h"
  22 #include "parse.h"
  23
  24 #include "wine/debug.h"
  25
  26 WINE_DEFAULT_DEBUG_CHANNEL(vbscript);
  27
  28
  29 #define YYLEX_PARAM ctx
  30 #define YYPARSE_PARAM ctx
  31
  32 static int parser_error(const char*);
  33
  34  static void parse_complete(parser_ctx_t*,BOOL);
  35
  36 static void source_add_statement(parser_ctx_t*,statement_t*);
  37
  38 static void *new_expression(parser_ctx_t*,expression_type_t,size_t);
  39 static expression_t *new_bool_expression(parser_ctx_t*,VARIANT_BOOL);
  40 static expression_t *new_string_expression(parser_ctx_t*,const WCHAR*);
  41 static expression_t *new_long_expression(parser_ctx_t*,expression_type_t,LONG);
  42 static expression_t *new_double_expression(parser_ctx_t*,double);
  43 static expression_t *new_unary_expression(parser_ctx_t*,expression_type_t,expression_t*);
  44 static expression_t *new_binary_expression(parser_ctx_t*,expression_type_t,expression_t*,expression_t*);
  45
  46 static member_expression_t *new_member_expression(parser_ctx_t*,expression_t*,const WCHAR*);
  47
  48 static statement_t *new_call_statement(parser_ctx_t*,member_expression_t*);
  49 static statement_t *new_assign_statement(parser_ctx_t*,member_expression_t*,expression_t*);
  50 static statement_t *new_dim_statement(parser_ctx_t*,dim_decl_t*);
  51  static statement_t *new_if_statement(parser_ctx_t*,expression_t*,statement_t*,elseif_decl_t*,statement_t*);
  52
  53 static dim_decl_t *new_dim_decl(parser_ctx_t*,const WCHAR*,dim_decl_t*);
  54 static elseif_decl_t *new_elseif_decl(parser_ctx_t*,expression_t*,statement_t*);
  55
  56 #define CHECK_ERROR if(((parser_ctx_t*)ctx)->hres != S_OK) YYABORT
  57
  58 %}
  59
  60 %pure_parser
  61 %start Program
  62
  63 %union {
  64     const WCHAR *string;
  65     statement_t *statement;
  66     expression_t *expression;
  67     member_expression_t *member;
  68     elseif_decl_t *elseif;
  69     dim_decl_t *dim_decl;
  70     LONG lng;
  71     BOOL bool;
  72     double dbl;
  73 }
  74
  75 %token tEOF tNL tREM tEMPTYBRACKETS
  76 %token tTRUE tFALSE
  77 %token tNOT tAND tOR tXOR tEQV tIMP tNEQ
  78 %token tIS tLTEQ tGTEQ tMOD
  79 %token tCALL tDIM tSUB tFUNCTION tPROPERTY tGET tLET
  80 %token tIF tELSE tELSEIF tEND tTHEN tEXIT
  81 %token tWHILE tWEND tDO tLOOP tUNTIL
  82 %token tBYREF tBYVAL
  83 %token tOPTION tEXPLICIT
  84 %token tSTOP
  85 %token tNOTHING tEMPTY tNULL
  86 %token tCLASS tSET tNEW tPUBLIC tPRIVATE tDEFAULT tME
  87 %token tERROR tNEXT tON tRESUME tGOTO
  88 %token <string> tIdentifier tString
  89 %token <lng> tLong tShort
  90 %token <dbl> tDouble
  91
  92 %type <statement> Statement StatementNl StatementsNl IfStatement Else_opt
  93 %type <expression> Expression LiteralExpression PrimaryExpression EqualityExpression CallExpression
  94 %type <expression> ConcatExpression AdditiveExpression ModExpression IntdivExpression MultiplicativeExpression
  95 %type <expression> NotExpression UnaryExpression
  96 %type <member> MemberExpression
  97 %type <expression> Arguments_opt ArgumentList_opt ArgumentList
  98 %type <bool> OptionExplicit_opt
  99 %type <elseif> ElseIfs_opt ElseIfs ElseIf
 100 %type <dim_decl> DimDeclList
 101
 102 %%
 103
 104 Program
 105     : OptionExplicit_opt SourceElements tEOF    { parse_complete(ctx, $1); }
 106
 107 OptionExplicit_opt
 108     : /* empty */                { $$ = FALSE; }
 109     | tOPTION tEXPLICIT tNL      { $$ = TRUE; }
 110
 111 SourceElements
 112     : /* empty */
 113     | SourceElements StatementNl    { source_add_statement(ctx, $2); }
 114
 115 StatementsNl
 116     : StatementNl                           { $$ = $1; }
 117     | StatementNl StatementsNl              { $1->next = $2; $$ = $1; }
 118
 119 StatementNl
 120     : Statement tNL                 { $$ = $1; }
 121
 122 Statement
 123     : MemberExpression ArgumentList_opt     { $1->args = $2; $$ = new_call_statement(ctx, $1); CHECK_ERROR; }
 124     | tCALL MemberExpression Arguments_opt  { $2->args = $3; $$ = new_call_statement(ctx, $2); CHECK_ERROR; }
 125     | MemberExpression Arguments_opt '=' Expression
 126                                             { $1->args = $2; $$ = new_assign_statement(ctx, $1, $4); CHECK_ERROR; }
 127     | tDIM DimDeclList                      { $$ = new_dim_statement(ctx, $2); CHECK_ERROR; }
 128     | IfStatement                           { $$ = $1; }
 129
 130 MemberExpression
 131     : tIdentifier                           { $$ = new_member_expression(ctx, NULL, $1); CHECK_ERROR; }
 132     | CallExpression '.' tIdentifier        { $$ = new_member_expression(ctx, $1, $3); CHECK_ERROR; }
 133
 134 DimDeclList /* FIXME: Support arrays */
 135     : tIdentifier                           { $$ = new_dim_decl(ctx, $1, NULL); CHECK_ERROR; }
 136     | tIdentifier ',' DimDeclList           { $$ = new_dim_decl(ctx, $1, $3); CHECK_ERROR; }
 137
 138 IfStatement
 139     : tIF Expression tTHEN tNL StatementsNl ElseIfs_opt Else_opt tEND tIF
 140                                             { $$ = new_if_statement(ctx, $2, $5, $6, $7); CHECK_ERROR; }
 141     /* FIXME: short if statement */
 142
 143 ElseIfs_opt
 144     : /* empty */                           { $$ = NULL; }
 145     | ElseIfs                               { $$ = $1; }
 146
 147 ElseIfs
 148     : ElseIf                                { $$ = $1; }
 149     | ElseIf ElseIfs                        { $1->next = $2; $$ = $1; }
 150
 151 ElseIf
 152     : tELSEIF Expression tTHEN tNL StatementsNl
 153                                             { $$ = new_elseif_decl(ctx, $2, $5); }
 154
 155 Else_opt
 156     : /* empty */                           { $$ = NULL; }
 157     | tELSE tNL StatementsNl                { $$ = $3; }
 158
 159 Arguments_opt
 160     : EmptyBrackets_opt             { $$ = NULL; }
 161     | '(' ArgumentList ')'          { $$ = $2; }
 162
 163 ArgumentList_opt
 164     : EmptyBrackets_opt             { $$ = NULL; }
 165     | ArgumentList                  { $$ = $1; }
 166
 167 ArgumentList
 168     : Expression                    { $$ = $1; }
 169     | Expression ',' ArgumentList   { $1->next = $3; $$ = $1; }
 170
 171 EmptyBrackets_opt
 172     : /* empty */
 173     | tEMPTYBRACKETS
 174
 175 Expression
 176     : NotExpression                 { $$ = $1; }
 177
 178 NotExpression
 179     : EqualityExpression            { $$ = $1; }
 180     | tNOT NotExpression            { $$ = new_unary_expression(ctx, EXPR_NOT, $2); CHECK_ERROR; }
 181
 182 EqualityExpression
 183     : ConcatExpression                          { $$ = $1; }
 184     | EqualityExpression '=' ConcatExpression   { $$ = new_binary_expression(ctx, EXPR_EQUAL, $1, $3); CHECK_ERROR; }
 185     | EqualityExpression tNEQ ConcatExpression  { $$ = new_binary_expression(ctx, EXPR_NEQUAL, $1, $3); CHECK_ERROR; }
 186
 187 ConcatExpression
 188     : AdditiveExpression                        { $$ = $1; }
 189     | ConcatExpression '&' AdditiveExpression   { $$ = new_binary_expression(ctx, EXPR_CONCAT, $1, $3); CHECK_ERROR; }
 190
 191 AdditiveExpression
 192     : ModExpression                             { $$ = $1; }
 193     | AdditiveExpression '+' ModExpression      { $$ = new_binary_expression(ctx, EXPR_ADD, $1, $3); CHECK_ERROR; }
 194     | AdditiveExpression '-' ModExpression      { $$ = new_binary_expression(ctx, EXPR_SUB, $1, $3); CHECK_ERROR; }
 195
 196 ModExpression
 197     : IntdivExpression                          { $$ = $1; }
 198     | ModExpression tMOD IntdivExpression       { $$ = new_binary_expression(ctx, EXPR_MOD, $1, $3); CHECK_ERROR; }
 199
 200 IntdivExpression
 201     : MultiplicativeExpression                  { $$ = $1; }
 202     | IntdivExpression '\\' MultiplicativeExpression
 203                                                 { $$ = new_binary_expression(ctx, EXPR_IDIV, $1, $3); CHECK_ERROR; }
 204
 205 MultiplicativeExpression
 206     : UnaryExpression /* FIXME */   { $$ = $1; }
 207
 208 UnaryExpression
 209     : LiteralExpression             { $$ = $1; }
 210     | CallExpression                { $$ = $1; }
 211     | '-' UnaryExpression           { $$ = new_unary_expression(ctx, EXPR_NEG, $2); CHECK_ERROR; }
 212
 213 CallExpression
 214     : PrimaryExpression                 { $$ = $1; }
 215     | MemberExpression Arguments_opt    { $1->args = $2; $$ = &$1->expr; }
 216
 217 LiteralExpression
 218     : tTRUE                         { $$ = new_bool_expression(ctx, VARIANT_TRUE); CHECK_ERROR; }
 219     | tFALSE                        { $$ = new_bool_expression(ctx, VARIANT_FALSE); CHECK_ERROR; }
 220     | tString                       { $$ = new_string_expression(ctx, $1); CHECK_ERROR; }
 221     | tShort                        { $$ = new_long_expression(ctx, EXPR_USHORT, $1); CHECK_ERROR; }
 222     | '0'                           { $$ = new_long_expression(ctx, EXPR_USHORT, 0); CHECK_ERROR; }
 223     | tLong                         { $$ = new_long_expression(ctx, EXPR_ULONG, $1); CHECK_ERROR; }
 224     | tDouble                       { $$ = new_double_expression(ctx, $1); CHECK_ERROR; }
 225     | tEMPTY                        { $$ = new_expression(ctx, EXPR_EMPTY, 0); CHECK_ERROR; }
 226     | tNULL                         { $$ = new_expression(ctx, EXPR_NULL, 0); CHECK_ERROR; }
 227
 228 PrimaryExpression
 229     : '(' Expression ')'            { $$ = $2; }
 230
 231 %%
 232
 233 static int parser_error(const char *str)
 234 {
 235     return 0;
 236 }
 237
 238 static void source_add_statement(parser_ctx_t *ctx, statement_t *stat)
 239 {
 240     if(ctx->stats) {
 241         ctx->stats_tail->next = stat;
 242         ctx->stats_tail = stat;
 243     }else {
 244         ctx->stats = ctx->stats_tail = stat;
 245     }
 246 }
 247
 248 static void parse_complete(parser_ctx_t *ctx, BOOL option_explicit)
 249 {
 250     ctx->parse_complete = TRUE;
 251     ctx->option_explicit = option_explicit;
 252 }
 253
 254 static void *new_expression(parser_ctx_t *ctx, expression_type_t type, size_t size)
 255 {
 256     expression_t *expr;
 257
 258     expr = parser_alloc(ctx, size ? size : sizeof(*expr));
 259     if(expr) {
 260         expr->type = type;
 261         expr->next = NULL;
 262     }
 263
 264     return expr;
 265 }
 266
 267 static expression_t *new_bool_expression(parser_ctx_t *ctx, VARIANT_BOOL value)
 268 {
 269     bool_expression_t *expr;
 270
 271     expr = new_expression(ctx, EXPR_BOOL, sizeof(*expr));
 272     if(!expr)
 273         return NULL;
 274
 275     expr->value = value;
 276     return &expr->expr;
 277 }
 278
 279 static expression_t *new_string_expression(parser_ctx_t *ctx, const WCHAR *value)
 280 {
 281     string_expression_t *expr;
 282
 283     expr = new_expression(ctx, EXPR_STRING, sizeof(*expr));
 284     if(!expr)
 285         return NULL;
 286
 287     expr->value = value;
 288     return &expr->expr;
 289 }
 290
 291 static expression_t *new_long_expression(parser_ctx_t *ctx, expression_type_t type, LONG value)
 292 {
 293     int_expression_t *expr;
 294
 295     expr = new_expression(ctx, type, sizeof(*expr));
 296     if(!expr)
 297         return NULL;
 298
 299     expr->value = value;
 300     return &expr->expr;
 301 }
 302
 303 static expression_t *new_double_expression(parser_ctx_t *ctx, double value)
 304 {
 305     double_expression_t *expr;
 306
 307     expr = new_expression(ctx, EXPR_DOUBLE, sizeof(*expr));
 308     if(!expr)
 309         return NULL;
 310
 311     expr->value = value;
 312     return &expr->expr;
 313 }
 314
 315 static expression_t *new_unary_expression(parser_ctx_t *ctx, expression_type_t type, expression_t *subexpr)
 316 {
 317     unary_expression_t *expr;
 318
 319     expr = new_expression(ctx, type, sizeof(*expr));
 320     if(!expr)
 321         return NULL;
 322
 323     expr->subexpr = subexpr;
 324     return &expr->expr;
 325 }
 326
 327 static expression_t *new_binary_expression(parser_ctx_t *ctx, expression_type_t type, expression_t *left, expression_t *right)
 328 {
 329     binary_expression_t *expr;
 330
 331     expr = new_expression(ctx, type, sizeof(*expr));
 332     if(!expr)
 333         return NULL;
 334
 335     expr->left = left;
 336     expr->right = right;
 337     return &expr->expr;
 338 }
 339
 340 static member_expression_t *new_member_expression(parser_ctx_t *ctx, expression_t *obj_expr, const WCHAR *identifier)
 341 {
 342     member_expression_t *expr;
 343
 344     expr = new_expression(ctx, EXPR_MEMBER, sizeof(*expr));
 345     if(!expr)
 346         return NULL;
 347
 348     expr->obj_expr = obj_expr;
 349     expr->identifier = identifier;
 350     expr->args = NULL;
 351     return expr;
 352 }
 353
 354 static void *new_statement(parser_ctx_t *ctx, statement_type_t type, unsigned size)
 355 {
 356     statement_t *stat;
 357
 358     stat = parser_alloc(ctx, size);
 359     if(stat) {
 360         stat->type = type;
 361         stat->next = NULL;
 362     }
 363
 364     return stat;
 365 }
 366
 367 static statement_t *new_call_statement(parser_ctx_t *ctx, member_expression_t *expr)
 368 {
 369     call_statement_t *stat;
 370
 371     stat = new_statement(ctx, STAT_CALL, sizeof(*stat));
 372     if(!stat)
 373         return NULL;
 374
 375     stat->expr = expr;
 376     return &stat->stat;
 377 }
 378
 379 static statement_t *new_assign_statement(parser_ctx_t *ctx, member_expression_t *left, expression_t *right)
 380 {
 381     assign_statement_t *stat;
 382
 383     stat = new_statement(ctx, STAT_ASSIGN, sizeof(*stat));
 384     if(!stat)
 385         return NULL;
 386
 387     stat->member_expr = left;
 388     stat->value_expr = right;
 389     return &stat->stat;
 390 }
 391
 392 static dim_decl_t *new_dim_decl(parser_ctx_t *ctx, const WCHAR *name, dim_decl_t *next)
 393 {
 394     dim_decl_t *decl;
 395
 396     decl = parser_alloc(ctx, sizeof(*decl));
 397     if(!decl)
 398         return NULL;
 399
 400     decl->name = name;
 401     decl->next = next;
 402     return decl;
 403 }
 404
 405 static statement_t *new_dim_statement(parser_ctx_t *ctx, dim_decl_t *decls)
 406 {
 407     dim_statement_t *stat;
 408
 409     stat = new_statement(ctx, STAT_DIM, sizeof(*stat));
 410     if(!stat)
 411         return NULL;
 412
 413     stat->dim_decls = decls;
 414     return &stat->stat;
 415 }
 416
 417 static elseif_decl_t *new_elseif_decl(parser_ctx_t *ctx, expression_t *expr, statement_t *stat)
 418 {
 419     elseif_decl_t *decl;
 420
 421     decl = parser_alloc(ctx, sizeof(*decl));
 422     if(!decl)
 423         return NULL;
 424
 425     decl->expr = expr;
 426     decl->stat = stat;
 427     decl->next = NULL;
 428     return decl;
 429 }
 430
 431 static statement_t *new_if_statement(parser_ctx_t *ctx, expression_t *expr, statement_t *if_stat, elseif_decl_t *elseif_decl,
 432         statement_t *else_stat)
 433 {
 434     if_statement_t *stat;
 435
 436     stat = new_statement(ctx, STAT_IF, sizeof(*stat));
 437     if(!stat)
 438         return NULL;
 439
 440     stat->expr = expr;
 441     stat->if_stat = if_stat;
 442     stat->elseifs = elseif_decl;
 443     stat->else_stat = else_stat;
 444     return &stat->stat;
 445 }
 446
 447 void *parser_alloc(parser_ctx_t *ctx, size_t size)
 448 {
 449     void *ret;
 450
 451     ret = vbsheap_alloc(&ctx->heap, size);
 452     if(!ret)
 453         ctx->hres = E_OUTOFMEMORY;
 454     return ret;
 455 }
 456
 457 HRESULT parse_script(parser_ctx_t *ctx, const WCHAR *code)
 458 {
 459     ctx->code = ctx->ptr = code;
 460     ctx->end = ctx->code + strlenW(ctx->code);
 461
 462     vbsheap_init(&ctx->heap);
 463
 464     ctx->parse_complete = FALSE;
 465     ctx->hres = S_OK;
 466
 467     ctx->last_token = tNL;
 468     ctx->last_nl = 0;
 469     ctx->stats = ctx->stats_tail = NULL;
 470     ctx->option_explicit = FALSE;
 471
 472     parser_parse(ctx);
 473
 474     if(FAILED(ctx->hres))
 475         return ctx->hres;
 476     if(!ctx->parse_complete) {
 477         FIXME("parser failed on parsing %s\n", debugstr_w(ctx->ptr));
 478         return E_FAIL;
 479     }
 480
 481     return S_OK;
 482 }
 483
 484 void parser_release(parser_ctx_t *ctx)
 485 {
 486     vbsheap_free(&ctx->heap);
 487 }