git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  47
  48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  49   [if test -z "$with_wine_tools"; then
  50      if test "$cross_compiling" = "yes"; then
  51        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  52      else
  53        wine_cv_toolsdir="\$(TOPOBJDIR)"
  54      fi
  55    elif test -d "$with_wine_tools/tools/winebuild"; then
  56      case $with_wine_tools in
  57        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  58        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  59      esac
  60    else
  61      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  62    fi])
  63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  64
  65 AC_PATH_XTRA
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  71 if test "$XLEX" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  74 fi
  75
  76 dnl Check for bison
  77 AC_CHECK_PROGS(BISON,bison,none)
  78 if test "$BISON" = "none"
  79 then
  80   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  81 fi
  82
  83 AC_CHECK_TOOLS(AS,[gas as],as)
  84 AC_CHECK_TOOL(LD,ld,ld)
  85 AC_CHECK_TOOL(AR,ar,ar)
  86 AC_PROG_RANLIB
  87 AC_CHECK_TOOL(STRIP,strip,strip)
  88 AC_CHECK_TOOL(WINDRES,windres,false)
  89 AC_PROG_LN_S
  90 WINE_PROG_LN
  91 AC_PROG_EGREP
  92 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  93 AC_PROG_INSTALL
  94 dnl Prepend src dir to install path dir if it's a relative path
  95 case "$INSTALL" in
  96   [[\\/$]]* | ?:[[\\/]]* ) ;;
  97   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  98 esac
  99
 100 dnl Check for lint
 101 AC_CHECK_PROGS(LINT, lclint lint)
 102 if test "$LINT" = "lint"
 103 then
 104   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 105   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 106 fi
 107 AC_SUBST(LINT)
 108 AC_SUBST(LINTFLAGS)
 109
 110 dnl Check for various programs
 111 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 112 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 113 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 114 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 115 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 116
 117 dnl **** Check for some libraries ****
 118
 119 dnl Check for -li386 for NetBSD and OpenBSD
 120 AC_CHECK_LIB(i386,i386_set_ldt)
 121 dnl Check for -lossaudio for NetBSD
 122 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 123 dnl Check for -lw for Solaris
 124 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 125 dnl Check for -lnsl for Solaris
 126 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 127 dnl Check for -lsocket for Solaris
 128 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 129 dnl Check for -lresolv for Solaris
 130 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 131 dnl Check for -lxpg4 for FreeBSD
 132 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 133 dnl Check for -lpoll for Mac OS X/Darwin
 134 AC_CHECK_LIB(poll,poll)
 135 dnl Check for -lresolv for Mac OS X/Darwin
 136 AC_CHECK_LIB(resolv,res_9_init)
 137 dnl Check for -lpthread
 138 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 139
 140 AC_SUBST(XLIB)
 141 AC_SUBST(XFILES)
 142 XFILES=""
 143 AC_SUBST(OPENGLFILES)
 144 OPENGLFILES=""
 145 AC_SUBST(GLU32FILES)
 146 GLU32FILES=""
 147 AC_SUBST(OPENGL_LIBS)
 148 OPENGL_LIBS=""
 149 if test "$have_x" = "yes"
 150 then
 151     XLIB="-lXext -lX11"
 152     ac_save_CPPFLAGS="$CPPFLAGS"
 153     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 154
 155     dnl *** All of the following tests require X11/Xlib.h
 156     AC_CHECK_HEADERS(X11/Xlib.h,
 157       [
 158         AC_CHECK_HEADERS([X11/XKBlib.h \
 159                           X11/Xutil.h \
 160                           X11/extensions/shape.h \
 161                           X11/extensions/XInput.h \
 162                           X11/extensions/XShm.h \
 163                           X11/extensions/Xrandr.h \
 164                           X11/extensions/Xrender.h \
 165                           X11/extensions/Xvlib.h \
 166                           X11/extensions/xf86dga.h \
 167                           X11/extensions/xf86vmode.h],,,
 168                          [#include <X11/Xlib.h>
 169                           #ifdef HAVE_X11_XUTIL_H
 170                           # include <X11/Xutil.h>
 171                           #endif])
 172
 173         dnl *** Check for X keyboard extension
 174         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 175         then
 176               AC_CHECK_LIB(X11, XkbQueryExtension,
 177               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 178               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 179         fi
 180
 181         dnl *** Check for X Shm extension
 182         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 183         then
 184               AC_CHECK_LIB(Xext, XShmQueryExtension,
 185               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 186               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 187         fi
 188
 189         dnl *** Check for X shape extension
 190         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 191         then
 192               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 193               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 194               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 195         fi
 196
 197         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 198         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 199         then
 200               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 201                 [ dnl *** If found...
 202                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 203                             [Define if you have the Xxf86dga library version 2])
 204                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 205                ],
 206                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 207                   dnl *** instead (DGA 2.0 not found)...
 208                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 209                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 210                                 [Define if you have the Xxf86dga library version 1])
 211                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 212                     ],,
 213                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 214                   )
 215                 ],
 216                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 217         fi
 218
 219         dnl *** Check for XFree86 VMODE extension
 220         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 221         then
 222                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 223                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 224                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 225                   ],,
 226                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 227         fi
 228
 229         dnl *** Check for X RandR extension
 230         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 231         then
 232                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 233 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 234                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 235         fi
 236
 237         dnl *** Check for XVideo extension supporting XvImages
 238         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 239         then
 240                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 241                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 242                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 243                   ],,
 244                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 245         fi
 246       ]
 247     ) dnl *** End of X11/Xlib.h check
 248
 249     dnl Check for the presence of OpenGL
 250     if test "x$with_opengl" != "xno"
 251     then
 252         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 253         then
 254             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 255 This prevents linking to OpenGL. Delete the file and restart configure.])
 256         fi
 257
 258         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 259         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 260         then
 261             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 262             dnl Check for some problems due to old Mesa versions
 263             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 264               AC_TRY_COMPILE(
 265                 [#include <GL/gl.h>],
 266                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 267                 [wine_cv_opengl_version_OK="yes"],
 268                 [wine_cv_opengl_version_OK="no"]
 269               )
 270             )
 271
 272             if test "$wine_cv_opengl_version_OK" = "yes"
 273             then
 274                 dnl Check for the presence of the library
 275                 AC_CHECK_LIB(GL,glXCreateContext,
 276                              OPENGL_LIBS="-lGL"
 277                              ,,
 278                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 279
 280                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 281                 then
 282                         OPENGLFILES='$(OPENGLFILES)'
 283                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 284
 285                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 286                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 287                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 288                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 289
 290                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 291                         then
 292                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 293                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 294                                                   #ifdef HAVE_GL_GLEXT_H
 295                                                   # include <GL/glext.h>
 296                                                   #endif
 297                                                   ],
 298                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 299                                                  [wine_cv_extension_prototypes="yes"],
 300                                                  [wine_cv_extension_prototypes="no"]
 301                                   )]
 302                                 )
 303                                 if test "$wine_cv_extension_prototypes" = "yes"
 304                                 then
 305                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 306                                               [Define if the OpenGL headers define extension typedefs])
 307                                 fi
 308                         fi
 309
 310                 fi
 311                 dnl Check for GLU32 library.
 312                 AC_CHECK_LIB(GLU,gluLookAt,
 313                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 314                              GLU32FILES='$(GLU32FILES)']
 315                              ,,
 316                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 317                 )
 318              fi
 319
 320              dnl Check for glut32 library.
 321              AC_CHECK_LIB(glut,glutMainLoop,
 322                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 323                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 324                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 325          fi
 326     fi
 327
 328     dnl **** Check for NAS ****
 329     AC_SUBST(NASLIBS,"")
 330     AC_CHECK_HEADERS(audio/audiolib.h,
 331          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 332           AC_CHECK_LIB(audio,AuCreateFlow,
 333                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 334                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 335                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 336
 337     CPPFLAGS="$ac_save_CPPFLAGS"
 338     XFILES='$(XFILES)'
 339 else
 340     XLIB=""
 341     X_CFLAGS=""
 342     X_LIBS=""
 343 fi
 344
 345 dnl **** Check which curses lib to use ***
 346 CURSESLIBS=""
 347 if test "x$with_curses" != "xno"
 348 then
 349     AC_CHECK_HEADERS(ncurses.h,
 350         [AC_CHECK_LIB(ncurses,waddch,
 351             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 352              CURSESLIBS="-lncurses"],
 353              [AC_CHECK_HEADERS(curses.h,
 354                  [AC_CHECK_LIB(curses,waddch,
 355                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 356                       CURSESLIBS="-lcurses"])])])])
 357     saved_libs="$LIBS"
 358     LIBS="$CURSESLIBS $LIBS"
 359     AC_CHECK_FUNCS(getbkgd resizeterm)
 360     LIBS="$saved_libs"
 361 fi
 362 AC_SUBST(CURSESLIBS)
 363
 364 dnl **** Check for SANE ****
 365 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 366 if test "$sane_devel" = "no"
 367 then
 368     SANELIBS=""
 369     SANEINCL=""
 370 else
 371     SANELIBS="`$sane_devel --libs`"
 372     SANEINCL="`$sane_devel --cflags`"
 373     ac_save_CPPFLAGS="$CPPFLAGS"
 374     ac_save_LIBS="$LIBS"
 375     CPPFLAGS="$CPPFLAGS $SANEINCL"
 376     LIBS="$LIBS $SANELIBS"
 377     AC_CHECK_HEADER(sane/sane.h,
 378                     [AC_CHECK_LIB(sane,sane_open,
 379                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 380                                   [SANELIBS=""
 381                                   SANEINCL=""])],
 382                     [SANELIBS=""
 383                     SANEINCL=""])
 384     LIBS="$ac_save_LIBS"
 385     CPPFLAGS="$ac_save_CPPFLAGS"
 386 fi
 387 AC_SUBST(SANELIBS)
 388 AC_SUBST(SANEINCL)
 389
 390 dnl **** Check for the ICU library ****
 391 AC_CHECK_HEADERS(unicode/ubidi.h)
 392 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 393 then
 394     saved_libs="$LIBS"
 395     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 396     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 397     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 398     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 399     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 400     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 401                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 402                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 403                  AC_MSG_RESULT(yes)],
 404                 [AC_MSG_RESULT(no)])
 405     LIBS="$saved_libs"
 406 fi
 407
 408 dnl **** Check for FreeType 2 ****
 409 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 410 if test "$ft_lib" = "no"
 411 then
 412     FREETYPELIBS=""
 413     FREETYPEINCL=""
 414     wine_cv_msg_freetype=no
 415 else
 416     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 417     if test "$ft_devel" = "no"
 418     then
 419         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 420         if test "$ft_devel2" = "freetype2-config"
 421         then
 422                 ft_devel=$ft_devel2
 423         fi
 424     fi
 425     if test "$ft_devel" = "no"
 426     then
 427         FREETYPELIBS=""
 428         FREETYPEINCL=""
 429         wine_cv_msg_freetype=yes
 430     else
 431         FREETYPELIBS=`$ft_devel --libs`
 432         FREETYPEINCL=`$ft_devel --cflags`
 433         ac_save_CPPFLAGS="$CPPFLAGS"
 434         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 435         AC_CHECK_HEADERS(ft2build.h \
 436                          freetype/freetype.h \
 437                          freetype/ftglyph.h \
 438                          freetype/tttables.h \
 439                          freetype/ftnames.h \
 440                          freetype/ftsnames.h \
 441                          freetype/ttnameid.h \
 442                          freetype/ftoutln.h \
 443                          freetype/ftwinfnt.h \
 444                          freetype/internal/sfnt.h,,,
 445                          [#if HAVE_FT2BUILD_H
 446                           #include <ft2build.h>
 447                           #endif])
 448         AC_TRY_CPP([#include <ft2build.h>
 449                     #include <freetype/fttrigon.h>],
 450                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 451           [Define if you have the <freetype/fttrigon.h> header file.])
 452                     wine_cv_fttrigon=yes],
 453                     wine_cv_fttrigon=no)
 454         CPPFLAGS="$ac_save_CPPFLAGS"
 455         dnl Check that we have at least freetype/freetype.h
 456         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 457         then
 458             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 459             wine_cv_msg_freetype=no
 460         else
 461             FREETYPELIBS=""
 462             FREETYPEINCL=""
 463             wine_cv_msg_freetype=yes
 464         fi
 465     fi
 466 fi
 467 AC_SUBST(FREETYPELIBS)
 468 AC_SUBST(FREETYPEINCL)
 469
 470 dnl Only build the fonts dir if we have both freetype and fontforge
 471 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 472 then
 473   AC_SUBST(FONTSSUBDIRS,"fonts")
 474 fi
 475
 476 dnl **** Check for parport (currently Linux only) ****
 477 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 478  AC_TRY_COMPILE(
 479    [#include <linux/ppdev.h>],
 480    [ioctl (1,PPCLAIM,0)],
 481    [ac_cv_c_ppdev="yes"],
 482    [ac_cv_c_ppdev="no"])
 483  )
 484 if test "$ac_cv_c_ppdev" = "yes"
 485 then
 486     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 487 fi
 488
 489 dnl **** Check for va_copy ****
 490 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 491  AC_TRY_LINK(
 492    [#include <stdarg.h>],
 493    [va_list ap1, ap2;
 494     va_copy(ap1,ap2);
 495    ],
 496    [ac_cv_c_va_copy="yes"],
 497    [ac_cv_c_va_copy="no"])
 498  )
 499 if test "$ac_cv_c_va_copy" = "yes"
 500 then
 501     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 502 fi
 503 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 504  AC_TRY_LINK(
 505    [#include <stdarg.h>],
 506    [va_list ap1, ap2;
 507     __va_copy(ap1,ap2);
 508    ],
 509    [ac_cv_c___va_copy="yes"],
 510    [ac_cv_c___va_copy="no"])
 511  )
 512 if test "$ac_cv_c___va_copy" = "yes"
 513 then
 514     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 515 fi
 516
 517 dnl **** Check for sigsetjmp ****
 518 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 519  AC_TRY_LINK(
 520    [#include <setjmp.h>],
 521    [sigjmp_buf buf;
 522     sigsetjmp( buf, 1 );
 523     siglongjmp( buf, 1 );],
 524    [ac_cv_c_sigsetjmp="yes"],
 525    [ac_cv_c_sigsetjmp="no"])
 526  )
 527 if test "$ac_cv_c_sigsetjmp" = "yes"
 528 then
 529     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 530 fi
 531
 532 dnl **** Check for pthread_rwlock_t ****
 533 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 534 #include <pthread.h>])
 535
 536 dnl **** Check for pthread functions ****
 537 ac_save_LIBS="$LIBS"
 538 LIBS="$LIBS $LIBPTHREAD"
 539 AC_CHECK_FUNCS(\
 540         pthread_getattr_np \
 541         pthread_get_stackaddr_np \
 542         pthread_get_stacksize_np \
 543 )
 544 LIBS="$ac_save_LIBS"
 545
 546 dnl **** Check for Open Sound System ****
 547 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 548
 549 AC_CACHE_CHECK([for Open Sound System],
 550         ac_cv_c_opensoundsystem,
 551         AC_TRY_COMPILE([
 552         #if defined(HAVE_SYS_SOUNDCARD_H)
 553                 #include <sys/soundcard.h>
 554         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 555                 #include <machine/soundcard.h>
 556         #elif defined(HAVE_SOUNDCARD_H)
 557                 #include <soundcard.h>
 558         #endif
 559         ],[
 560
 561 /* check for one of the Open Sound System specific SNDCTL_ defines */
 562 #if !defined(SNDCTL_DSP_STEREO)
 563 #error No open sound system
 564 #endif
 565 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 566
 567 if test "$ac_cv_c_opensoundsystem" = "yes"
 568 then
 569     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 570 fi
 571
 572 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 573         ac_cv_c_opensoundsystem_midi,
 574         AC_TRY_COMPILE([
 575         #if defined(HAVE_SYS_SOUNDCARD_H)
 576                 #include <sys/soundcard.h>
 577         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 578                 #include <machine/soundcard.h>
 579         #elif defined(HAVE_SOUNDCARD_H)
 580                 #include <soundcard.h>
 581         #endif
 582         ],[
 583
 584 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 585 #if !defined(SNDCTL_SEQ_SYNC)
 586 #error No open sound system MIDI interface
 587 #endif
 588 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 589
 590 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 591 then
 592     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 593 fi
 594
 595 dnl **** Check for aRts Sound Server ****
 596 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 597 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 598 then
 599     ARTSC_CFLAGS=""
 600     for i in `$ARTSCCONFIG --cflags`
 601     do
 602       case "$i" in
 603         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 604       esac
 605     done
 606     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 607     save_CFLAGS="$CFLAGS"
 608     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 609     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 610         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 611          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 612          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 613     CFLAGS="$save_CFLAGS"
 614 fi
 615
 616 dnl **** Check for ALSA ****
 617 AC_SUBST(ALSALIBS,"")
 618 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 619 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 620 then
 621     AC_CHECK_LIB(asound,snd_pcm_open,
 622         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 623         ALSALIBS="-lasound")
 624 fi
 625
 626 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 627
 628 AC_SUBST(AUDIOIOLIBS,"")
 629 AC_CHECK_HEADERS(libaudioio.h,
 630     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 631                   [AUDIOIOLIBS="-laudioio"
 632                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 633
 634 dnl **** Check for lcms ****
 635
 636 AC_CHECK_HEADERS(lcms.h,
 637     [AC_CHECK_LIB(lcms,cmsOpenProfileFromFile,
 638         [AC_DEFINE(HAVE_LCMS,1,[Define if you have lcms libs and headers])
 639          AC_SUBST(LCMSLIBS,"-llcms")
 640     ])
 641 ])
 642
 643 dnl **** Check for capi4linux ****
 644
 645 AC_CHECK_HEADERS(capi20.h,[
 646         AC_CHECK_HEADERS(linux/capi.h,[
 647                 AC_CHECK_LIB(capi20,capi20_register,[
 648                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 649                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 650                 ])
 651         ])
 652 ])
 653
 654 dnl **** Check for broken glibc mmap64 ****
 655
 656 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 657         AC_TRY_RUN([
 658                 #define _FILE_OFFSET_BITS 64
 659                 #include <stdio.h>
 660                 #include <unistd.h>
 661                 #include <fcntl.h>
 662                 #include <sys/mman.h>
 663                 #include <errno.h>
 664
 665                 int main(int argc,char **argv) {
 666                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 667                         if (fd == -1) exit(1);
 668
 669                         unlink("conftest.map");
 670
 671                         write(fd,"test",4);
 672
 673                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 674                             (errno == EINVAL)
 675                         ) {
 676                                 exit(1);
 677                         }
 678                         close(fd);
 679                         fprintf(stderr,"success!\n");
 680                         exit(0);
 681                 }
 682
 683         ],
 684     ac_cv_mmap64_works="yes",
 685     ac_cv_mmap64_works="no",
 686     ac_cv_mmap64_works="no") )
 687
 688 if test "$ac_cv_mmap64_works" = "yes"
 689 then
 690     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 691 fi
 692
 693 dnl **** Check for gcc specific options ****
 694
 695 AC_SUBST(EXTRACFLAGS,"")
 696 if test "x${GCC}" = "xyes"
 697 then
 698   EXTRACFLAGS="-Wall -pipe"
 699
 700   dnl Check for strength-reduce bug
 701   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 702                   AC_TRY_RUN([
 703 int     L[[4]] = {0,1,2,3};
 704 int main(void) {
 705   static int Array[[3]];
 706   unsigned int B = 3;
 707   int i;
 708   for(i=0; i<B; i++) Array[[i]] = i - 3;
 709   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 710   L[[i]] = 4;
 711
 712   exit( Array[[1]] != -2 || L[[2]] != 3);
 713 }],
 714     ac_cv_c_gcc_strength_bug="no",
 715     ac_cv_c_gcc_strength_bug="yes",
 716     ac_cv_c_gcc_strength_bug="yes") )
 717   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 718   then
 719     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 720   fi
 721
 722   dnl Check for -fshort-wchar
 723   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 724       [WINE_TRY_CFLAGS([-fshort-wchar],
 725                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 726   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 727   then
 728       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 729   fi
 730
 731   dnl Check for -mpreferred-stack-boundary
 732   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 733       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 734                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 735   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 736   then
 737     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 738   fi
 739
 740   dnl Check for -fno-strict-aliasing
 741   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 742       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 743                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 744   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 745   then
 746     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 747   fi
 748
 749   dnl Check for -gstabs+ option
 750   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 751       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 752   if test "$ac_cv_c_gcc_gstabs" = "yes"
 753   then
 754     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 755   fi
 756
 757   dnl Check for noisy string.h
 758   saved_CFLAGS="$CFLAGS"
 759   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 760   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 761       AC_TRY_COMPILE([#include <string.h>],[],
 762                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 763   CFLAGS="$saved_CFLAGS"
 764   if test "$ac_cv_c_string_h_warnings" = "no"
 765   then
 766     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 767   fi
 768 fi
 769
 770 dnl **** Check how to define a function in assembly code ****
 771
 772 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 773   WINE_TRY_ASM_LINK(
 774       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 775       ac_cv_asm_func_def=".def",
 776     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 777       ac_cv_asm_func_def=".type @function",
 778     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 779       ac_cv_asm_func_def=".type 2",
 780       ac_cv_asm_func_def="unknown")])]))
 781
 782 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 783 case "$ac_cv_asm_func_def" in
 784   ".def")
 785      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 786   ".type @function")
 787      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 788   ".type 2")
 789      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 790   *)
 791      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 792 esac
 793
 794 dnl **** Check for underscore on external symbols ****
 795
 796 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 797     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 798                       [extern int ac_test;],
 799                       [if (ac_test) return 1],
 800                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 801
 802 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 803 if test "$ac_cv_c_extern_prefix" = "yes"
 804 then
 805   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 806 else
 807   AC_DEFINE([__ASM_NAME(name)], [name])
 808 fi
 809
 810 dnl **** Check how to do strings in assembler ****
 811
 812 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 813     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 814       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 815         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 816           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 817
 818 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 819                    [Define to the assembler keyword used to specify an ASCII string])
 820
 821 dnl **** Check for .short in assembler ****
 822
 823 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 824     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 825       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 826         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 827
 828 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 829                    [Define to the assembler keyword used to specify a word value])
 830
 831 dnl **** Check for .size in assembler ****
 832
 833 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 834     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 835                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 836
 837 if test "$ac_cv_c_asm_size" = "yes"
 838 then
 839   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 840 fi
 841
 842 dnl **** Check for working dll ****
 843
 844 AC_SUBST(DLLEXT,"")
 845 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 846 AC_SUBST(DLLIBS,"")
 847 AC_SUBST(LDSHARED,"")
 848 AC_SUBST(LDDLLFLAGS,"")
 849 AC_SUBST(LIBEXT,"so")
 850 AC_SUBST(IMPLIBEXT,"def")
 851
 852 case $host_os in
 853   cygwin*|mingw32*)
 854     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 855     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 856     if test "$DLLWRAP" = "false"; then
 857       LIBEXT="a"
 858     else
 859       dnl FIXME - check whether dllwrap works correctly...
 860       LIBEXT="dll"
 861     fi
 862     IMPLIBEXT="a"
 863     dnl We can't build 16-bit NE dlls
 864     WIN16_FILES=""
 865     WIN16_INSTALL=""
 866     ;;
 867   *)
 868     AC_CHECK_HEADERS(dlfcn.h,
 869         [AC_CHECK_FUNCS(dlopen,,
 870             [AC_CHECK_LIB(dl,dlopen,
 871                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 872                           DLLIBS="-ldl"],
 873                          [LIBEXT="a"])])],
 874         [LIBEXT="a"])
 875
 876     if test "$LIBEXT" = "so"
 877     then
 878       DLLFLAGS="$DLLFLAGS -fPIC"
 879       DLLEXT=".so"
 880       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 881           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 882                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 883       if test "$ac_cv_c_dll_gnuelf" = "yes"
 884       then
 885         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 886         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 887         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 888           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 889                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 890         if test "$ac_cv_c_dll_zdefs" = "yes"
 891         then
 892           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 893         fi
 894
 895         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 896           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 897                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 898         if test "$ac_cv_c_dll_init_fini" = "yes"
 899         then
 900           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 901         fi
 902
 903         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 904           [echo '{ global: *; };' >conftest.map
 905            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 906                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 907            rm -f conftest.map])
 908         if test "$ac_cv_c_ld_version_scripts" = "yes"
 909         then
 910           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 911         fi
 912
 913         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 914           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 915                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 916         if test "$ac_cv_c_export_dynamic" = "yes"
 917         then
 918           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 919         fi
 920
 921         case $host_cpu in
 922           *i[[3456789]]86*)
 923             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 924               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 925                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 926             if test "$ac_cv_ld_reloc_exec" = "yes"
 927             then
 928               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 929             fi
 930             ;;
 931         esac
 932
 933       else
 934         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 935             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 936                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 937         if test "$ac_cv_c_dll_unixware" = "yes"
 938         then
 939           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 940           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 941
 942         else
 943           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 944             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 945           if test "$ac_cv_c_dll_macho" = "yes"
 946           then
 947             LIBEXT="dylib"
 948             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 949             LDSHARED="\$(CC) -dynamiclib"
 950             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 951             STRIP="$STRIP -u -r"
 952             dnl Relocate wine executable
 953             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 954             dnl Relocate libwine.dyld too
 955             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 956             dnl declare needed frameworks
 957             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 958             AC_SUBST(IOKITLIB,"-framework IOKit")
 959             dnl using IOKit imply we use CoreFoundation too
 960             IOKITLIB = "$IOKITLIB $COREFOUNDATIONLIB"
 961           else
 962             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 963               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 964             if test "$ac_cv_c_dll_hpux" = "yes"
 965             then
 966               LIBEXT="sl"
 967               LDDLLFLAGS="-shared"
 968               LDSHARED="\$(CC) -shared"
 969             fi
 970           fi
 971         fi
 972       fi
 973     fi
 974
 975     dnl Check for cross compiler to build test programs
 976     AC_SUBST(CROSSTEST,"")
 977     if test "$cross_compiling" = "no"
 978     then
 979       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 980       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 981       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 982       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 983     fi
 984     ;;
 985 esac
 986
 987 if test "$LIBEXT" = "a"; then
 988   AC_MSG_ERROR(
 989 [could not find a way to build shared libraries.
 990 It is currently not possible to build Wine without shared library
 991 (.so) support to allow transparent switch between .so and .dll files.
 992 If you are using Linux, you will need a newer binutils.]
 993 )
 994 fi
 995
 996 case $build_os in
 997   cygwin*|mingw32*)
 998     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 999   darwin*|macosx*)
1000     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1001   *)
1002     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1003 esac
1004
1005 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1006 case $host_os in
1007   mingw32*)
1008     AC_SUBST(CRTLIBS,"-lmsvcrt")
1009     AC_SUBST(SOCKETLIBS,"-lws2_32")
1010     ;;
1011 esac
1012
1013 case $host_os in
1014   linux*)
1015     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
1016     AC_SUBST(MAIN_BINARY,"wine-glibc")
1017     ;;
1018   darwin*)
1019     AC_SUBST(WINE_BINARIES,"wine-pthread")
1020     AC_SUBST(MAIN_BINARY,"wine-pthread")
1021     ;;
1022   *)
1023     AC_SUBST(WINE_BINARIES,"wine-kthread")
1024     AC_SUBST(MAIN_BINARY,"wine-kthread")
1025     ;;
1026 esac
1027
1028 dnl **** Get the soname for libraries that we load dynamically ****
1029
1030 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1031 then
1032   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1033   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1034   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1035   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1036   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1037   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1038   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1039   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1040   WINE_GET_SONAME(cups,cupsGetDefault)
1041   WINE_GET_SONAME(jack,jack_client_new)
1042   WINE_GET_SONAME(fontconfig,FcInit)
1043   WINE_GET_SONAME(ssl,SSL_library_init)
1044   WINE_GET_SONAME(crypto,BIO_new_socket)
1045   WINE_GET_SONAME(ncurses,waddch)
1046   WINE_GET_SONAME(curses,waddch)
1047   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1048   WINE_GET_SONAME(ungif,DGifOpen)
1049   WINE_GET_SONAME(gif,DGifOpen)
1050 fi
1051
1052
1053 dnl **** Check for functions ****
1054
1055 AC_FUNC_ALLOCA()
1056 AC_CHECK_FUNCS(\
1057         _lwp_create \
1058         _lwp_self \
1059         _pclose \
1060         _popen \
1061         _snprintf \
1062         _spawnvp \
1063         _stricmp \
1064         _strnicmp \
1065         _vsnprintf \
1066         chsize \
1067         clone \
1068         finite \
1069         fpclass \
1070         fstatfs \
1071         fstatvfs \
1072         ftruncate \
1073         ftruncate64 \
1074         futimes \
1075         getnetbyaddr \
1076         getnetbyname \
1077         getopt_long \
1078         getpagesize \
1079         getprotobyname \
1080         getprotobynumber \
1081         getpwuid \
1082         getservbyport \
1083         gettid \
1084         gettimeofday \
1085         inet_network \
1086         lseek64 \
1087         lstat \
1088         memmove \
1089         mmap \
1090         pclose \
1091         popen \
1092         pread \
1093         pwrite \
1094         readlink \
1095         rfork \
1096         select \
1097         sendmsg \
1098         settimeofday \
1099         sigaltstack \
1100         snprintf \
1101         spawnvp \
1102         statfs \
1103         statvfs \
1104         strcasecmp \
1105         strerror \
1106         strncasecmp \
1107         tcgetattr \
1108         timegm \
1109         usleep \
1110         vfscanf \
1111         vsnprintf \
1112         wait4 \
1113         waitpid \
1114 )
1115
1116 dnl **** Check for header files ****
1117
1118 AC_CHECK_HEADERS(\
1119         arpa/inet.h \
1120         arpa/nameser.h \
1121         cups/cups.h \
1122         direct.h \
1123         elf.h \
1124         float.h \
1125         fontconfig/fontconfig.h \
1126         getopt.h \
1127         gif_lib.h \
1128         ieeefp.h \
1129         io.h \
1130         jack/jack.h \
1131         jpeglib.h \
1132         libio.h \
1133         libutil.h \
1134         link.h \
1135         linux/cdrom.h \
1136         linux/compiler.h \
1137         linux/hdreg.h \
1138         linux/input.h \
1139         linux/ioctl.h \
1140         linux/joystick.h \
1141         linux/major.h \
1142         linux/param.h \
1143         linux/serial.h \
1144         linux/ucdrom.h \
1145         machine/cpu.h \
1146         mntent.h \
1147         netdb.h \
1148         netinet/in.h \
1149         netinet/in_systm.h \
1150         netinet/tcp.h \
1151         netinet/tcp_fsm.h \
1152         openssl/ssl.h \
1153         process.h \
1154         pthread.h \
1155         pty.h \
1156         pwd.h \
1157         regex.h \
1158         sched.h \
1159         scsi/sg.h \
1160         scsi/scsi.h \
1161         scsi/scsi_ioctl.h \
1162         socket.h \
1163         stdint.h \
1164         strings.h \
1165         sys/cdio.h \
1166         sys/elf32.h \
1167         sys/errno.h \
1168         sys/exec_elf.h \
1169         sys/file.h \
1170         sys/filio.h \
1171         sys/inttypes.h \
1172         sys/ioctl.h \
1173         sys/ipc.h \
1174         sys/link.h \
1175         sys/lwp.h \
1176         sys/mman.h \
1177         sys/modem.h \
1178         sys/msg.h \
1179         sys/param.h \
1180         sys/poll.h \
1181         sys/ptrace.h \
1182         sys/reg.h \
1183         sys/scsiio.h \
1184         sys/shm.h \
1185         sys/signal.h \
1186         sys/socket.h \
1187         sys/sockio.h \
1188         sys/statfs.h \
1189         sys/statvfs.h \
1190         sys/strtio.h \
1191         sys/syscall.h \
1192         sys/sysctl.h \
1193         sys/time.h \
1194         sys/times.h \
1195         sys/uio.h \
1196         sys/un.h \
1197         sys/v86.h \
1198         sys/v86intr.h \
1199         sys/vfs.h \
1200         sys/vm86.h \
1201         sys/wait.h \
1202         syscall.h \
1203         termios.h \
1204         unistd.h \
1205         utime.h \
1206         valgrind/memcheck.h
1207 )
1208 AC_HEADER_STAT()
1209
1210 dnl **** Checks for headers that depend on other ones ****
1211
1212 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1213     [#include <sys/types.h>
1214      #if HAVE_SYS_PARAM_H
1215      # include <sys/param.h>
1216      #endif])
1217
1218 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1219     [#include <sys/types.h>
1220      #if HAVE_SYS_SOCKET_H
1221      # include <sys/socket.h>
1222      #endif])
1223
1224 AC_CHECK_HEADERS([resolv.h],,,
1225     [#include <sys/types.h>
1226      #if HAVE_SYS_SOCKET_H
1227      # include <sys/socket.h>
1228      #endif
1229      #if HAVE_NETINET_IN_H
1230      # include <netinet/in.h>
1231      #endif
1232      #if HAVE_ARPA_NAMESER_H
1233      # include <arpa/nameser.h>
1234      #endif])
1235
1236 AC_CHECK_HEADERS(netinet/ip.h,,,
1237     [#include <sys/types.h>
1238      #if HAVE_SYS_SOCKET_H
1239      # include <sys/socket.h>
1240      #endif
1241      #if HAVE_NETINET_IN_SYSTM_H
1242      # include <netinet/in_systm.h>
1243      #endif])
1244
1245 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1246
1247 dnl **** Check for IPX headers (currently Linux only) ****
1248
1249 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1250  AC_TRY_COMPILE(
1251    [#include <sys/types.h>
1252     #ifdef HAVE_SYS_SOCKET_H
1253     # include <sys/socket.h>
1254     #endif
1255     #include <netipx/ipx.h>],
1256    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1257    [ac_cv_c_ipx_gnu="yes"],
1258    [ac_cv_c_ipx_gnu="no"])
1259  )
1260 if test "$ac_cv_c_ipx_gnu" = "yes"
1261 then
1262     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1263 fi
1264
1265 if test "$ac_cv_c_ipx_gnu" = "no"
1266 then
1267  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1268   AC_TRY_COMPILE(
1269     [#include <sys/types.h>
1270      #ifdef HAVE_SYS_SOCKET_H
1271      # include <sys/socket.h>
1272      #endif
1273      #include <asm/types.h>
1274      #include <linux/ipx.h>],
1275     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1276     [ac_cv_c_ipx_linux="yes"],
1277     [ac_cv_c_ipx_linux="no"])
1278   )
1279   if test "$ac_cv_c_ipx_linux" = "yes"
1280   then
1281       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1282   fi
1283 fi
1284
1285 dnl **** Check for types ****
1286
1287 AC_C_CONST
1288 AC_C_INLINE
1289 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1290
1291 AC_CACHE_CHECK([whether linux/input.h is for real],
1292         wine_cv_linux_input_h,
1293         AC_TRY_COMPILE([
1294             #include <linux/input.h>
1295         ] , [
1296             int foo = EVIOCGBIT(EV_ABS,42);
1297             int bar = BTN_PINKIE;
1298             int fortytwo = 42;
1299         ],
1300         wine_cv_linux_input_h=yes,
1301         wine_cv_linux_input_h=no,
1302         no
1303         )
1304     )
1305     if test "$wine_cv_linux_input_h" = "yes"
1306     then
1307         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1308                   [Define if we have linux/input.h AND it contains the INPUT event API])
1309     fi
1310
1311
1312 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1313         wine_cv_linux_gethostbyname_r_6,
1314         AC_TRY_LINK([
1315 #include <netdb.h>
1316         ], [
1317     char *name=NULL;
1318     struct hostent he;
1319     struct hostent *result;
1320     char *buf=NULL;
1321     int bufsize=0;
1322     int res,errnr;
1323     char *addr=NULL;
1324     int addrlen=0;
1325     int addrtype=0;
1326     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1327     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1328     ],
1329         wine_cv_linux_gethostbyname_r_6=yes,
1330         wine_cv_linux_gethostbyname_r_6=no
1331         )
1332    )
1333    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1334    then
1335       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1336                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1337    fi
1338
1339 if test "$ac_cv_header_linux_joystick_h" = "yes"
1340 then
1341    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1342         wine_cv_linux_joystick_22_api,
1343         AC_TRY_COMPILE([
1344         #include <sys/ioctl.h>
1345         #include <linux/joystick.h>
1346
1347         struct js_event blub;
1348         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1349         #error "no 2.2 header"
1350         #endif
1351         ],/*empty*/,
1352         wine_cv_linux_joystick_22_api=yes,
1353         wine_cv_linux_joystick_22_api=no,
1354         wine_cv_linux_joystick_22_api=no
1355         )
1356    )
1357    if test "$wine_cv_linux_joystick_22_api" = "yes"
1358    then
1359       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1360                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1361    fi
1362 fi
1363
1364 dnl **** statfs checks ****
1365
1366 if test "$ac_cv_header_sys_vfs_h" = "yes"
1367 then
1368     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1369                     wine_cv_sys_vfs_has_statfs,
1370         AC_TRY_COMPILE([
1371         #include <sys/types.h>
1372         #ifdef HAVE_SYS_PARAM_H
1373         # include <sys/param.h>
1374         #endif
1375         #include <sys/vfs.h>
1376         ],[
1377                 struct statfs stfs;
1378
1379                 memset(&stfs,0,sizeof(stfs));
1380         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1381         )
1382     )
1383     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1384     then
1385       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1386                 [Define if the struct statfs is defined by <sys/vfs.h>])
1387     fi
1388 fi
1389
1390 if test "$ac_cv_header_sys_statfs_h" = "yes"
1391 then
1392     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1393                     wine_cv_sys_statfs_has_statfs,
1394         AC_TRY_COMPILE([
1395         #include <sys/types.h>
1396         #ifdef HAVE_SYS_PARAM_H
1397         # include <sys/param.h>
1398         #endif
1399         #include <sys/statfs.h>
1400         ],[
1401                 struct statfs stfs;
1402         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1403         )
1404     )
1405     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1406     then
1407       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1408                 [Define if the struct statfs is defined by <sys/statfs.h>])
1409     fi
1410 fi
1411
1412 if test "$ac_cv_header_sys_mount_h" = "yes"
1413 then
1414     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1415                     wine_cv_sys_mount_has_statfs,
1416         AC_TRY_COMPILE([
1417         #include <sys/types.h>
1418         #ifdef HAVE_SYS_PARAM_H
1419         # include <sys/param.h>
1420         #endif
1421         #include <sys/mount.h>
1422         ],[
1423                 struct statfs stfs;
1424         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1425         )
1426     )
1427     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1428     then
1429       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1430                 [Define if the struct statfs is defined by <sys/mount.h>])
1431     fi
1432 fi
1433
1434 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1435
1436 dnl Check for statfs members
1437 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1438 [#include <sys/types.h>
1439 #ifdef HAVE_SYS_PARAM_H
1440 # include <sys/param.h>
1441 #endif
1442 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1443 # include <sys/mount.h>
1444 #else
1445 # ifdef STATFS_DEFINED_BY_SYS_VFS
1446 #  include <sys/vfs.h>
1447 # else
1448 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1449 #   include <sys/statfs.h>
1450 #  endif
1451 # endif
1452 #endif])
1453
1454 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1455 [#ifdef HAVE_SYS_STATVFS_H
1456 #include <sys/statvfs.h>
1457 #endif])
1458
1459 dnl Check for socket structure members
1460 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1461 [#include <sys/types.h>
1462 #ifdef HAVE_SYS_SOCKET_H
1463 # include <sys/socket.h>
1464 #endif
1465 #ifdef HAVE_SYS_UN_H
1466 # include <sys/un.h>
1467 #endif])
1468
1469 dnl Check for siginfo_t members
1470 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1471
1472 dnl Check for struct option
1473 AC_CHECK_MEMBERS([struct option.name],,,
1474 [#ifdef HAVE_GETOPT_H
1475 #include <getopt.h>
1476 #endif])
1477
1478 dnl Check for stat.st_blocks
1479 AC_CHECK_MEMBERS([struct stat.st_blocks])
1480
1481 dnl *** check for the need to define platform-specific symbols
1482
1483 case $host_cpu in
1484   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1485   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1486   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1487   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1488 esac
1489
1490 case $host_vendor in
1491   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1492 esac
1493
1494 dnl **** Generate output files ****
1495
1496 AH_TOP([#define __WINE_CONFIG_H])
1497
1498 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1499 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1500 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1501 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1502 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1503 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1504 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1505 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1506 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1507 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1508 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1509 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1510 WINE_CONFIG_EXTRA_DIR(include/wine)
1511 WINE_CONFIG_EXTRA_DIR(misc)
1512 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1513 WINE_CONFIG_EXTRA_DIR(windows)
1514
1515 MAKE_RULES=Make.rules
1516 AC_SUBST_FILE(MAKE_RULES)
1517
1518 MAKE_DLL_RULES=dlls/Makedll.rules
1519 AC_SUBST_FILE(MAKE_DLL_RULES)
1520
1521 MAKE_TEST_RULES=dlls/Maketest.rules
1522 AC_SUBST_FILE(MAKE_TEST_RULES)
1523
1524 MAKE_LIB_RULES=libs/Makelib.rules
1525 AC_SUBST_FILE(MAKE_LIB_RULES)
1526
1527 MAKE_PROG_RULES=programs/Makeprog.rules
1528 AC_SUBST_FILE(MAKE_PROG_RULES)
1529
1530 AC_CONFIG_FILES([
1531 Make.rules
1532 dlls/Makedll.rules
1533 dlls/Maketest.rules
1534 libs/Makelib.rules
1535 programs/Makeprog.rules
1536 Makefile
1537 dlls/Makefile
1538 dlls/advapi32/Makefile
1539 dlls/advapi32/tests/Makefile
1540 dlls/amstream/Makefile
1541 dlls/atl/Makefile
1542 dlls/avicap32/Makefile
1543 dlls/avifil32/Makefile
1544 dlls/cabinet/Makefile
1545 dlls/capi2032/Makefile
1546 dlls/cards/Makefile
1547 dlls/cfgmgr32/Makefile
1548 dlls/comcat/Makefile
1549 dlls/comctl32/Makefile
1550 dlls/comctl32/tests/Makefile
1551 dlls/commdlg/Makefile
1552 dlls/crtdll/Makefile
1553 dlls/crypt32/Makefile
1554 dlls/ctl3d/Makefile
1555 dlls/d3d8/Makefile
1556 dlls/d3d9/Makefile
1557 dlls/d3dim/Makefile
1558 dlls/d3drm/Makefile
1559 dlls/d3dx8/Makefile
1560 dlls/d3dxof/Makefile
1561 dlls/dbghelp/Makefile
1562 dlls/dciman32/Makefile
1563 dlls/ddraw/Makefile
1564 dlls/ddraw/tests/Makefile
1565 dlls/devenum/Makefile
1566 dlls/dinput/Makefile
1567 dlls/dinput8/Makefile
1568 dlls/dmband/Makefile
1569 dlls/dmcompos/Makefile
1570 dlls/dmime/Makefile
1571 dlls/dmloader/Makefile
1572 dlls/dmscript/Makefile
1573 dlls/dmstyle/Makefile
1574 dlls/dmsynth/Makefile
1575 dlls/dmusic/Makefile
1576 dlls/dmusic32/Makefile
1577 dlls/dplay/Makefile
1578 dlls/dplayx/Makefile
1579 dlls/dpnet/Makefile
1580 dlls/dpnhpast/Makefile
1581 dlls/dsound/Makefile
1582 dlls/dsound/tests/Makefile
1583 dlls/dswave/Makefile
1584 dlls/dxdiagn/Makefile
1585 dlls/dxerr8/Makefile
1586 dlls/dxerr9/Makefile
1587 dlls/dxguid/Makefile
1588 dlls/gdi/Makefile
1589 dlls/gdi/tests/Makefile
1590 dlls/glu32/Makefile
1591 dlls/glut32/Makefile
1592 dlls/hhctrl.ocx/Makefile
1593 dlls/iccvid/Makefile
1594 dlls/icmp/Makefile
1595 dlls/ifsmgr.vxd/Makefile
1596 dlls/imagehlp/Makefile
1597 dlls/imm32/Makefile
1598 dlls/iphlpapi/Makefile
1599 dlls/iphlpapi/tests/Makefile
1600 dlls/itss/Makefile
1601 dlls/kernel/Makefile
1602 dlls/kernel/tests/Makefile
1603 dlls/lzexpand/Makefile
1604 dlls/mapi32/Makefile
1605 dlls/mapi32/tests/Makefile
1606 dlls/mlang/Makefile
1607 dlls/mlang/tests/Makefile
1608 dlls/mmdevldr.vxd/Makefile
1609 dlls/monodebg.vxd/Makefile
1610 dlls/mpr/Makefile
1611 dlls/msacm/Makefile
1612 dlls/msacm/imaadp32/Makefile
1613 dlls/msacm/msadp32/Makefile
1614 dlls/msacm/msg711/Makefile
1615 dlls/msacm/winemp3/Makefile
1616 dlls/msacm/tests/Makefile
1617 dlls/mscms/Makefile
1618 dlls/msdmo/Makefile
1619 dlls/mshtml/Makefile
1620 dlls/msi/Makefile
1621 dlls/msimg32/Makefile
1622 dlls/msisys/Makefile
1623 dlls/msnet32/Makefile
1624 dlls/msrle32/Makefile
1625 dlls/msvcrt/Makefile
1626 dlls/msvcrt/tests/Makefile
1627 dlls/msvcrt20/Makefile
1628 dlls/msvcrt40/Makefile
1629 dlls/msvcrtd/Makefile
1630 dlls/msvcrtd/tests/Makefile
1631 dlls/msvidc32/Makefile
1632 dlls/msvideo/Makefile
1633 dlls/mswsock/Makefile
1634 dlls/netapi32/Makefile
1635 dlls/netapi32/tests/Makefile
1636 dlls/newdev/Makefile
1637 dlls/ntdll/Makefile
1638 dlls/ntdll/tests/Makefile
1639 dlls/odbc32/Makefile
1640 dlls/ole32/Makefile
1641 dlls/ole32/tests/Makefile
1642 dlls/oleacc/Makefile
1643 dlls/oleaut32/Makefile
1644 dlls/oleaut32/tests/Makefile
1645 dlls/olecli/Makefile
1646 dlls/oledlg/Makefile
1647 dlls/olepro32/Makefile
1648 dlls/olesvr/Makefile
1649 dlls/opengl32/Makefile
1650 dlls/psapi/Makefile
1651 dlls/psapi/tests/Makefile
1652 dlls/qcap/Makefile
1653 dlls/quartz/Makefile
1654 dlls/quartz/tests/Makefile
1655 dlls/rasapi32/Makefile
1656 dlls/richedit/Makefile
1657 dlls/rpcrt4/Makefile
1658 dlls/rpcrt4/tests/Makefile
1659 dlls/rsabase/Makefile
1660 dlls/rsabase/tests/Makefile
1661 dlls/secur32/Makefile
1662 dlls/serialui/Makefile
1663 dlls/setupapi/Makefile
1664 dlls/shdocvw/Makefile
1665 dlls/shell32/Makefile
1666 dlls/shell32/tests/Makefile
1667 dlls/shfolder/Makefile
1668 dlls/shlwapi/Makefile
1669 dlls/shlwapi/tests/Makefile
1670 dlls/snmpapi/Makefile
1671 dlls/sti/Makefile
1672 dlls/strmiids/Makefile
1673 dlls/tapi32/Makefile
1674 dlls/ttydrv/Makefile
1675 dlls/twain/Makefile
1676 dlls/unicows/Makefile
1677 dlls/url/Makefile
1678 dlls/urlmon/Makefile
1679 dlls/urlmon/tests/Makefile
1680 dlls/user/Makefile
1681 dlls/user/tests/Makefile
1682 dlls/uuid/Makefile
1683 dlls/uxtheme/Makefile
1684 dlls/vdhcp.vxd/Makefile
1685 dlls/vdmdbg/Makefile
1686 dlls/version/Makefile
1687 dlls/version/tests/Makefile
1688 dlls/vmm.vxd/Makefile
1689 dlls/vnbt.vxd/Makefile
1690 dlls/vnetbios.vxd/Makefile
1691 dlls/vtdapi.vxd/Makefile
1692 dlls/vwin32.vxd/Makefile
1693 dlls/win32s/Makefile
1694 dlls/winaspi/Makefile
1695 dlls/wined3d/Makefile
1696 dlls/winedos/Makefile
1697 dlls/wineps/Makefile
1698 dlls/wininet/Makefile
1699 dlls/wininet/tests/Makefile
1700 dlls/winmm/Makefile
1701 dlls/winmm/joystick/Makefile
1702 dlls/winmm/mcianim/Makefile
1703 dlls/winmm/mciavi/Makefile
1704 dlls/winmm/mcicda/Makefile
1705 dlls/winmm/mciseq/Makefile
1706 dlls/winmm/mciwave/Makefile
1707 dlls/winmm/midimap/Makefile
1708 dlls/winmm/tests/Makefile
1709 dlls/winmm/wavemap/Makefile
1710 dlls/winmm/winealsa/Makefile
1711 dlls/winmm/winearts/Makefile
1712 dlls/winmm/wineaudioio/Makefile
1713 dlls/winmm/winejack/Makefile
1714 dlls/winmm/winenas/Makefile
1715 dlls/winmm/wineoss/Makefile
1716 dlls/winnls/Makefile
1717 dlls/winsock/Makefile
1718 dlls/winsock/tests/Makefile
1719 dlls/winspool/Makefile
1720 dlls/winspool/tests/Makefile
1721 dlls/wintab32/Makefile
1722 dlls/wintrust/Makefile
1723 dlls/wow32/Makefile
1724 dlls/wsock32/Makefile
1725 dlls/x11drv/Makefile
1726 documentation/Makefile
1727 fonts/Makefile
1728 include/Makefile
1729 libs/Makefile
1730 libs/port/Makefile
1731 libs/unicode/Makefile
1732 libs/wine/Makefile
1733 libs/wpp/Makefile
1734 loader/Makefile
1735 programs/Makefile
1736 programs/avitools/Makefile
1737 programs/clock/Makefile
1738 programs/cmdlgtst/Makefile
1739 programs/control/Makefile
1740 programs/expand/Makefile
1741 programs/msiexec/Makefile
1742 programs/notepad/Makefile
1743 programs/progman/Makefile
1744 programs/regedit/Makefile
1745 programs/regsvr32/Makefile
1746 programs/rpcss/Makefile
1747 programs/rundll32/Makefile
1748 programs/start/Makefile
1749 programs/taskmgr/Makefile
1750 programs/uninstaller/Makefile
1751 programs/view/Makefile
1752 programs/wcmd/Makefile
1753 programs/wineboot/Makefile
1754 programs/winebrowser/Makefile
1755 programs/winecfg/Makefile
1756 programs/wineconsole/Makefile
1757 programs/winedbg/Makefile
1758 programs/winefile/Makefile
1759 programs/winemenubuilder/Makefile
1760 programs/winemine/Makefile
1761 programs/winepath/Makefile
1762 programs/winetest/Makefile
1763 programs/winevdm/Makefile
1764 programs/winhelp/Makefile
1765 programs/winver/Makefile
1766 server/Makefile
1767 tools/Makefile
1768 tools/widl/Makefile
1769 tools/winapi/Makefile
1770 tools/winebuild/Makefile
1771 tools/winedump/Makefile
1772 tools/winegcc/Makefile
1773 tools/wmc/Makefile
1774 tools/wrc/Makefile])
1775
1776 AC_OUTPUT
1777
1778 if test "$have_x" = "no"
1779 then
1780   echo
1781   echo "*** Warning: X development files not found. Wine will be built without"
1782   echo "*** X support, which currently does not work, and would probably not be"
1783   echo "*** what you want anyway. You will need to install devel packages of"
1784   echo "*** Xlib/Xfree86 at the very least."
1785 fi
1786
1787 if test "$wine_cv_opengl_version_OK" = "no"
1788 then
1789   echo
1790   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1791   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1792 fi
1793
1794 if test "$wine_cv_msg_freetype" = "yes"
1795 then
1796   echo
1797   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1798   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1799   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1800   echo "*** enable Wine to use TrueType fonts."
1801 fi
1802
1803 echo
1804 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1805 echo
1806
1807 dnl Local Variables:
1808 dnl comment-start: "dnl "
1809 dnl comment-end: ""
1810 dnl comment-start-skip: "\\bdnl\\b\\s *"
1811 dnl compile-command: "autoconf"
1812 dnl End: