git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(dll,
  19 [  --disable-dll           build static libraries instead of DLLs],
  20 [if test "$enableval" = "no"; then LIBEXT="a"; fi])
  21
  22 AC_ARG_ENABLE(debug,
  23 [  --disable-debug         compile out all debugging messages],
  24 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  25
  26 AC_ARG_ENABLE(opengl,
  27 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe],
  28 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  29
  30 AC_ARG_ENABLE(trace,
  31 [  --disable-trace         compile out TRACE messages],
  32 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  33
  34 AC_ARG_WITH(curses,
  35 [  --without-curses        do not use curses],
  36 [if test "$withval" = "no"; then CURSES="no"; fi])
  37
  38 AC_ARG_WITH(reentrant-x,
  39 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  40
  41 AC_SUBST(OPTIONS)
  42
  43 if test "$DEBUG_MSGS" = "no"
  44 then
  45     AC_DEFINE(NO_DEBUG_MSGS)
  46     AC_DEFINE(NO_TRACE_MSGS)
  47 else
  48     if test "$TRACE_MSGS" = "no"
  49     then
  50         AC_DEFINE(NO_TRACE_MSGS)
  51     fi
  52 fi
  53
  54 dnl **** Check for some programs ****
  55
  56 AC_PROG_MAKE_SET
  57 AC_PROG_CC
  58 AC_PROG_CPP
  59 AC_PATH_XTRA
  60 AC_PROG_YACC
  61 AC_PROG_LEX
  62 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  63 if test "$XLEX" = "none"
  64 then
  65         echo "*** Error: No suitable lex found. ***"
  66         echo "    Please install the 'flex' package."
  67         exit 1
  68 fi
  69 AC_DECL_YYTEXT
  70 AC_PROG_RANLIB
  71 AC_PROG_INSTALL
  72 AC_PROG_LN_S
  73 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  74 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  75
  76 dnl Check for lint
  77 AC_CHECK_PROGS(LINT, lclint lint)
  78 if test "$LINT" = "lint"
  79 then
  80   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  81   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  82 fi
  83 AC_SUBST(LINT)
  84 AC_SUBST(LINTFLAGS)
  85
  86 dnl **** Check for some libraries ****
  87
  88 dnl Check for -lm for BeOS
  89 AC_CHECK_LIB(m,sqrt)
  90 dnl Check for -li386 for NetBSD and OpenBSD
  91 AC_CHECK_LIB(i386,i386_set_ldt)
  92 dnl Check for -lossaudio for NetBSD
  93 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  94 dnl Check for -lw for Solaris
  95 AC_CHECK_LIB(w,iswalnum)
  96 dnl Check for -lnsl for Solaris
  97 AC_CHECK_FUNCS(gethostbyname,, AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", AC_CHECK_LIB(socket, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", , -lnsl), -lsocket))
  98 dnl Check for -lsocket for Solaris
  99 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 100 dnl Check for -lxpg4 for FreeBSD
 101 AC_CHECK_LIB(xpg4,setrunelocale)
 102 dnl Check for -lmmap for OS/2
 103 AC_CHECK_LIB(mmap,mmap)
 104 dnl Check for openpty
 105 AC_CHECK_FUNCS(openpty,,
 106         AC_CHECK_LIB(util,openpty,
 107                 AC_DEFINE(HAVE_OPENPTY)
 108                 LIBS="$LIBS -lutil"
 109         ))
 110
 111 AC_CHECK_HEADERS(dlfcn.h,
 112         AC_CHECK_FUNCS(dlopen,
 113                 AC_DEFINE(HAVE_DL_API),
 114                 AC_CHECK_LIB(dl,dlopen,
 115                         AC_DEFINE(HAVE_DL_API)
 116                         LIBS="$LIBS -ldl",
 117                         LIBEXT="a"
 118                 )
 119         ),
 120         LIBEXT="a"
 121 )
 122 AC_SUBST(XLIB)
 123 AC_SUBST(X_DLLS)
 124 X_DLLS=""
 125 AC_SUBST(XFILES)
 126 XFILES=""
 127 AC_SUBST(OPENGLFILES)
 128 OPENGLFILES=""
 129 AC_SUBST(OPENGL32_DLL)
 130 OPENGL32_DLL=""
 131 AC_SUBST(DGA_SRCS)
 132 DGA_SRCS=""
 133 AC_SUBST(DGA2_SRCS)
 134 DGA2_SRCS=""
 135 AC_SUBST(MESA_SRCS)
 136 MESA_SRCS=""
 137 if test "$have_x" = "yes"
 138 then
 139     XLIB="-lXext -lX11"
 140     ac_save_CPPFLAGS="$CPPFLAGS"
 141     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 142
 143     dnl *** Check for -lXpm
 144     AC_CHECK_HEADERS(X11/xpm.h,
 145       [ dnl *** If X11/xpm.h exists...
 146         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 147           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 148           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 149         )
 150       ],
 151       [ dnl *** If X11/xpm.h does not exist...
 152         dnl NOTE: autoconf does not allow commas inside the third
 153         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 154         dnl       magic it does.
 155         echo "Redhat            :       xpm xpm-devel"
 156         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 157         echo "SuSE              :       xpm"
 158         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 159         echo
 160         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 161         echo "the directory /contrib/libraries."
 162         echo
 163         exit 1
 164       ]
 165     )
 166
 167     dnl *** All three of the following tests require X11/Xlib.h
 168     AC_CHECK_HEADERS(X11/Xlib.h,
 169       [
 170         dnl *** Check for X Shm extension
 171         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 172             [ dnl *** If X11/extensions/XShm.h exists...
 173               AC_CHECK_LIB(Xext, XShmQueryExtension,
 174               AC_DEFINE(HAVE_LIBXXSHM),,
 175               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 176             ],
 177             AC_MSG_WARN([Xshm extension not found!!])
 178         )
 179
 180         dnl *** Check for X shape extension
 181         AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/shape.h,
 182             [ dnl *** If X11/extensions/shape.h exists...
 183               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 184               AC_DEFINE(HAVE_LIBXSHAPE),,
 185               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 186             ],
 187             AC_MSG_WARN([XShape extension found!!])
 188         )
 189
 190         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 191         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 192             [ dnl *** If X11/extensions/xf86dga.h exists, check
 193               dnl *** for XDGAQueryExtension()...
 194               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 195                 [ dnl *** If found...
 196                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 197                   AC_DEFINE(HAVE_LIBXXF86DGA)
 198                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 199                   DGA_SRCS='$(DGA_SRCS)'
 200                   DGA2_SRCS='$(DGA2_SRCS)'
 201                ],
 202                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 203                   dnl *** instead (DGA 2.0 not found)...
 204                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 205                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 206                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 207                       DGA_SRCS='$(DGA_SRCS)'
 208                     ],,
 209                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 210                   )
 211                 ],
 212                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 213               )
 214             ],
 215             AC_MSG_WARN([DGA extension not found!!])
 216         )
 217
 218         dnl *** Check for XFree86 VMODE extension
 219         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 220             [ dnl *** If X11/extensions/xf86vmode.h exists...
 221                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 222                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 223                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 224                   ],,
 225                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 226                 )
 227             ],
 228             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 229         )
 230
 231         dnl *** Check for XVideo extension supporting XvImages
 232         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 233             [ dnl *** If X11/extensions/Xvlib.h exists...
 234                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 235                   [ AC_DEFINE(HAVE_XVIDEO)
 236                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 237                   ],,
 238                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 239                 )
 240             ],
 241             AC_MSG_WARN([XVideo extension not found !!])
 242         )
 243
 244       ]
 245     ) dnl *** End of X11/Xlib.h check
 246
 247     dnl Check for the presence of OpenGL
 248     if test $OPENGL = "yes" -o $OPENGL = "normal"
 249     then
 250         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 251         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 252         then
 253             dnl Check for some problems due to old Mesa versions
 254             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 255               AC_TRY_COMPILE(
 256                 [#include <GL/gl.h>],
 257                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 258                 [wine_cv_opengl_version_OK="yes"],
 259                 [wine_cv_opengl_version_OK="no"]
 260               )
 261             )
 262
 263             dnl Check for the thread-safety of the OpenGL library
 264             AC_CACHE_CHECK("for thread-safe OpenGL version",
 265                            wine_cv_opengl_version_threadsafe,
 266               [saved_libs=$LIBS
 267                LIBS="$X_LIBS -lGL"
 268                AC_TRY_LINK([],[pthread_getspecific();],
 269                               [wine_cv_opengl_version_threadsafe="yes"],
 270                               [wine_cv_opengl_version_threadsafe="no"])
 271                LIBS=$saved_libs]
 272             )
 273
 274             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 275             then
 276                 dnl Check for the presence of the library
 277                 AC_CHECK_LIB(GL,glXCreateContext,
 278                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 279                              MESA_SRCS='$(MESA_SRCS)'
 280                              ,,
 281                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 282
 283                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 284                 then
 285
 286                         OPENGLFILES='$(OPENGLFILES)'
 287                         AC_DEFINE(HAVE_OPENGL)
 288
 289                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 290
 291                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 292                         then
 293                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 294                                   AC_TRY_COMPILE([#include <GL/gl.h>
 295                                                   #ifdef HAVE_GL_GLEXT_H
 296                                                   # include <GL/glext.h>
 297                                                   #endif
 298                                                   ],
 299                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 300                                                  [wine_cv_extension_prototypes="yes"],
 301                                                  [wine_cv_extension_prototypes="no"]
 302                                   )
 303                                 )
 304                                 if test $wine_cv_extension_prototypes = "yes"
 305                                 then
 306                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 307                                 fi
 308
 309                                 OPENGL32_DLL=opengl32
 310                         fi
 311                 fi
 312              fi
 313          fi
 314     fi
 315
 316     CPPFLAGS="$ac_save_CPPFLAGS"
 317     X_DLLS='$(X_DLLS)'
 318     XFILES='$(XFILES)'
 319 else
 320     XLIB=""
 321     X_CFLAGS=""
 322     X_LIBS=""
 323 fi
 324
 325 dnl **** Check which curses lib to use ***
 326 if test "$CURSES" = "yes"
 327 then
 328     AC_CHECK_HEADERS(ncurses.h)
 329     if test "$ac_cv_header_ncurses_h" = "yes"
 330     then
 331         AC_CHECK_LIB(ncurses,waddch)
 332     fi
 333     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 334     then
 335         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 336         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 337     else
 338         AC_CHECK_HEADERS(curses.h)
 339         if test "$ac_cv_header_curses_h" = "yes"
 340         then
 341             AC_CHECK_LIB(curses,waddch)
 342             if test "$ac_cv_lib_curses_waddch" = "yes"
 343             then
 344                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 345                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 346             fi
 347         fi
 348     fi
 349 fi
 350
 351 dnl **** Check for IPX (currently Linux only) ****
 352 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 353  AC_TRY_COMPILE(
 354    [#include <sys/socket.h>
 355     #include <netipx/ipx.h>],
 356    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 357    [ac_cv_c_ipx_gnu="yes"],
 358    [ac_cv_c_ipx_gnu="no"])
 359  )
 360 if test "$ac_cv_c_ipx_gnu" = "yes"
 361 then
 362     AC_DEFINE(HAVE_IPX_GNU)
 363 fi
 364
 365 if test "$ac_cv_c_ipx_gnu" = "no"
 366 then
 367  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 368   AC_TRY_COMPILE(
 369     [#include <sys/socket.h>
 370      #include <asm/types.h>
 371      #include <linux/ipx.h>],
 372     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 373     [ac_cv_c_ipx_linux="yes"],
 374     [ac_cv_c_ipx_linux="no"])
 375   )
 376   if test "$ac_cv_c_ipx_linux" = "yes"
 377   then
 378       AC_DEFINE(HAVE_IPX_LINUX)
 379   fi
 380 fi
 381
 382 dnl **** Check for Open Sound System ****
 383 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 384
 385 AC_CACHE_CHECK("for Open Sound System",
 386         ac_cv_c_opensoundsystem,
 387         AC_TRY_COMPILE([
 388         #if defined(HAVE_SYS_SOUNDCARD_H)
 389                 #include <sys/soundcard.h>
 390         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 391                 #include <machine/soundcard.h>
 392         #elif defined(HAVE_SOUNDCARD_H)
 393                 #include <soundcard.h>
 394         #endif
 395         ],[
 396
 397 /* check for one of the Open Sound System specific SNDCTL_ defines */
 398 #if !defined(SNDCTL_DSP_STEREO)
 399 #error No open sound system
 400 #endif
 401 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 402
 403 if test "$ac_cv_c_opensoundsystem" = "yes"
 404 then
 405     AC_DEFINE(HAVE_OSS)
 406 fi
 407
 408 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 409         ac_cv_c_opensoundsystem_midi,
 410         AC_TRY_COMPILE([
 411         #if defined(HAVE_SYS_SOUNDCARD_H)
 412                 #include <sys/soundcard.h>
 413         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 414                 #include <machine/soundcard.h>
 415         #elif defined(HAVE_SOUNDCARD_H)
 416                 #include <soundcard.h>
 417         #endif
 418         ],[
 419
 420 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 421 #if !defined(SNDCTL_SEQ_SYNC)
 422 #error No open sound system MIDI interface
 423 #endif
 424 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 425
 426 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 427 then
 428     AC_DEFINE(HAVE_OSS_MIDI)
 429 fi
 430
 431 dnl **** If ln -s doesn't work, use cp instead ****
 432 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 433
 434 dnl **** Check for gcc strength-reduce bug ****
 435
 436 if test "x${GCC}" = "xyes"
 437 then
 438   CFLAGS="$CFLAGS -Wall"
 439   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 440                   AC_TRY_RUN([
 441 int main(void) {
 442   static int Array[[3]];
 443   unsigned int B = 3;
 444   int i;
 445   for(i=0; i<B; i++) Array[[i]] = i - 3;
 446   exit( Array[[1]] != -2 );
 447 }],
 448     ac_cv_c_gcc_strength_bug="no",
 449     ac_cv_c_gcc_strength_bug="yes",
 450     ac_cv_c_gcc_strength_bug="yes") )
 451   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 452   then
 453     CFLAGS="$CFLAGS -fno-strength-reduce"
 454   fi
 455 fi
 456
 457 dnl **** Check for underscore on external symbols ****
 458
 459 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 460                ac_cv_c_extern_prefix,
 461 [saved_libs=$LIBS
 462 LIBS="conftest_asm.s $LIBS"
 463 cat > conftest_asm.s <<EOF
 464         .globl _ac_test
 465 _ac_test:
 466         .long 0
 467 EOF
 468 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 469             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 470 LIBS=$saved_libs])
 471 if test "$ac_cv_c_extern_prefix" = "yes"
 472 then
 473   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 474 fi
 475
 476 dnl **** Check for .string in assembler ****
 477
 478 AC_CACHE_CHECK("whether assembler accepts .string",
 479                ac_cv_c_asm_string,
 480 [saved_libs=$LIBS
 481 LIBS="conftest_asm.s $LIBS"
 482 cat > conftest_asm.s <<EOF
 483         .string "test"
 484 EOF
 485 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 486 LIBS=$saved_libs])
 487 if test "$ac_cv_c_asm_string" = "yes"
 488 then
 489   AC_DEFINE(HAVE_ASM_STRING)
 490 fi
 491
 492 dnl **** Check for working dll ****
 493
 494 LDSHARED=""
 495 LDDLLFLAGS=""
 496 if test "$LIBEXT" = "so"
 497 then
 498   AC_CACHE_CHECK("whether we can build a Linux dll",
 499                  ac_cv_c_dll_linux,
 500   [saved_cflags=$CFLAGS
 501   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 502   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 503   CFLAGS=$saved_cflags
 504   ])
 505   if test "$ac_cv_c_dll_linux" = "yes"
 506   then
 507     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 508     LDDLLFLAGS="-Wl,-Bsymbolic"
 509   else
 510     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 511                  ac_cv_c_dll_unixware,
 512     [saved_cflags=$CFLAGS
 513     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 514     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 515     CFLAGS=$saved_cflags
 516     ])
 517     if test "$ac_cv_c_dll_unixware" = "yes"
 518     then
 519       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,h,\$(libdir)/%)"
 520       LDDLLFLAGS="-Wl,-B,symbolic"
 521     else
 522       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 523                    ac_cv_c_dll_netbsd,
 524       [saved_cflags=$CFLAGS
 525       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 526       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 527       CFLAGS=$saved_cflags
 528       ])
 529       if test "$ac_cv_c_dll_netbsd" = "yes"
 530       then
 531         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 532         LDDLLFLAGS="" #FIXME
 533       fi
 534     fi
 535   fi
 536   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 537   then
 538     LIBEXT="a"
 539   fi
 540 fi
 541
 542 DLLFLAGS=""
 543
 544 if test "$LIBEXT" = "so"; then
 545     DLLFLAGS="-fPIC"
 546     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) -L\$(TOPOBJDIR) -lwine -lwine_unicode"
 547 else
 548     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) -L\$(TOPOBJDIR) -lwine -lwine_unicode \$(X_LIBS) \$(XLIB)"
 549     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 550                    ac_cv_c_whole_archive,
 551             [saved_cflags=$CFLAGS
 552             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 553             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 554             CFLAGS=$saved_cflags
 555             ])
 556     if test "$ac_cv_c_whole_archive" = "yes"
 557     then
 558         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 559     else
 560         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 561                        ac_cv_c_allextract,
 562                 [saved_cflags=$CFLAGS
 563                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 564                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 565                 CFLAGS=$saved_cflags
 566                 ])
 567         if test "$ac_cv_c_allextract" = "yes"
 568         then
 569             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 570         fi
 571     fi
 572 fi
 573
 574 AC_SUBST(DLL_LINK)
 575 AC_SUBST(DLLFLAGS)
 576 AC_SUBST(LDSHARED)
 577 AC_SUBST(LDDLLFLAGS)
 578 AC_SUBST(LIBEXT)
 579
 580 dnl **** Check for reentrant libc ****
 581 dnl
 582 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 583 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 584
 585 wine_cv_libc_reentrant=no
 586 dnl
 587 dnl Linux style errno location
 588 dnl
 589 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 590   [AC_TRY_RUN([int myerrno = 0;
 591 char buf[256];
 592 int *__errno_location(){return &myerrno;}
 593 main(){connect(0,buf,255); exit(!myerrno);}],
 594   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 595   wine_cv_libc_r__errno_location=yes )
 596 ])
 597 if test "$wine_cv_libc_r__errno_location" = "yes"
 598 then
 599     AC_DEFINE(HAVE__ERRNO_LOCATION)
 600     wine_cv_libc_reentrant=__errno_location
 601 fi
 602 dnl
 603 dnl FreeBSD style errno location
 604 dnl
 605 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 606   [AC_TRY_RUN([int myerrno = 0;
 607 char buf[256];
 608 int *__error(){return &myerrno;}
 609 main(){connect(0,buf,255); exit(!myerrno);}],
 610     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 611     wine_cv_libc_r__error=yes )
 612 ])
 613 if test "$wine_cv_libc_r__error" = "yes"
 614 then
 615     AC_DEFINE(HAVE__ERROR)
 616     wine_cv_libc_reentrant=__error
 617 fi
 618 dnl
 619 dnl Solaris style errno location
 620 dnl
 621 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 622   [AC_TRY_RUN([int myerrno = 0;
 623 char buf[256];
 624 int *___errno(){return &myerrno;}
 625 main(){connect(0,buf,255); exit(!myerrno);}],
 626     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 627     wine_cv_libc_r___errno=yes )
 628 ])
 629 if test "$wine_cv_libc_r___errno" = "yes"
 630 then
 631     AC_DEFINE(HAVE___ERRNO)
 632     wine_cv_libc_reentrant=___errno
 633 fi
 634 dnl
 635 dnl UnixWare style errno location
 636 dnl
 637 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 638   [AC_TRY_RUN([int myerrno = 0;
 639 char buf[256];
 640 int *__thr_errno(){return &myerrno;}
 641 main(){connect(0,buf,255); exit(!myerrno);}],
 642     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 643     wine_cv_libc_r__thr_errno=yes )
 644 ])
 645 if test "$wine_cv_libc_r__thr_errno" = "yes"
 646 then
 647     AC_DEFINE(HAVE__THR_ERRNO)
 648     wine_cv_libc_reentrant=__thr_errno
 649 fi
 650 if test "$wine_cv_libc_reentrant" = "no"
 651 then
 652   AC_DEFINE(NO_REENTRANT_LIBC)
 653 fi
 654
 655 dnl **** Check for reentrant X libraries ****
 656 dnl
 657 dnl This may fail to determine whether X libraries are reentrant if
 658 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 659 dnl is possible with the --without-reentrant-x option.
 660
 661 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 662 then
 663 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 664   [ if test "x$with_reentrant_x" = "xno"
 665     then
 666         wine_cv_x_reentrant=no
 667     else
 668         libX11_check=none
 669         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 670             if test -r $dir/libX11.so; then
 671                 libX11_check="-D $dir/libX11.so"
 672                 break 1
 673             fi
 674             if test -r $dir/libX11.a; then
 675                 libX11_check="$dir/libX11.a"
 676                 break 1
 677             fi
 678         done
 679         if test "$libX11_check" != "none"; then
 680             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 681             then
 682                 wine_cv_x_reentrant=yes
 683             else
 684                 wine_cv_x_reentrant=no
 685             fi
 686         else
 687             wine_cv_x_reentrant=unknown
 688         fi
 689     fi ] )
 690 else
 691     wine_cv_x_reentrant=no
 692 fi
 693 if test "$wine_cv_x_reentrant" = "no"
 694 then
 695   AC_DEFINE(NO_REENTRANT_X11)
 696 fi
 697
 698 dnl **** Check for endianness ****
 699
 700 AC_C_BIGENDIAN
 701
 702 dnl **** Check for functions ****
 703
 704 AC_FUNC_ALLOCA()
 705 AC_CHECK_FUNCS(\
 706         __libc_fork \
 707         _lwp_create \
 708         clone \
 709         getnetbyaddr \
 710         getnetbyname \
 711         getpagesize \
 712         getprotobyname \
 713         getprotobynumber \
 714         getservbyport \
 715         getsockopt \
 716         inet_network \
 717         memmove \
 718         rfork \
 719         select \
 720         sendmsg \
 721         settimeofday \
 722         sigaltstack \
 723         statfs \
 724         strcasecmp \
 725         strerror \
 726         strncasecmp \
 727         tcgetattr \
 728         timegm \
 729         usleep \
 730         vfscanf \
 731         wait4 \
 732         waitpid \
 733 )
 734
 735 dnl **** Check for header files ****
 736
 737 AC_CHECK_HEADERS(\
 738         a.out.h \
 739         a_out.h \
 740         arpa/inet.h \
 741         arpa/nameser.h \
 742         elf.h \
 743         float.h \
 744         libio.h \
 745         libutil.h \
 746         link.h \
 747         linux/cdrom.h \
 748         linux/joystick.h \
 749         linux/ucdrom.h \
 750         net/if.h \
 751         netinet/in.h \
 752         netinet/tcp.h \
 753         pty.h \
 754         resolv.h \
 755         sched.h \
 756         socket.h \
 757         strings.h \
 758         sys/cdio.h \
 759         sys/errno.h \
 760         sys/file.h \
 761         sys/filio.h \
 762         sys/ipc.h \
 763         sys/lwp.h \
 764         sys/mman.h \
 765         sys/modem.h \
 766         sys/mount.h \
 767         sys/msg.h \
 768         sys/param.h \
 769         sys/reg.h \
 770         sys/signal.h \
 771         sys/shm.h \
 772         sys/socket.h \
 773         sys/sockio.h \
 774         sys/statfs.h \
 775         sys/strtio.h \
 776         sys/syscall.h \
 777         sys/wait.h \
 778         sys/v86.h \
 779         sys/v86intr.h \
 780         sys/vfs.h \
 781         sys/vm86.h \
 782         syscall.h \
 783         ucontext.h
 784 )
 785 AC_HEADER_STAT()
 786
 787 dnl **** Check for types ****
 788
 789 AC_C_CONST()
 790 AC_C_INLINE()
 791 AC_TYPE_SIZE_T()
 792 AC_CHECK_SIZEOF(long long,0)
 793
 794
 795 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 796         wine_cv_linux_gethostbyname_r_6,
 797         AC_TRY_COMPILE([
 798 #include <netdb.h>
 799         ], [
 800     char *name=NULL;
 801     struct hostent he;
 802     struct hostent *result;
 803     char *buf=NULL;
 804     int bufsize=0;
 805     int res,errnr;
 806     char *addr=NULL;
 807     int addrlen=0;
 808     int addrtype=0;
 809     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 810     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 811     ],
 812         wine_cv_linux_gethostbyname_r_6=yes,
 813         wine_cv_linux_gethostbyname_r_6=no
 814         )
 815    )
 816    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 817    then
 818       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 819    fi
 820
 821 if test "$ac_cv_header_linux_joystick_h" = "yes"
 822 then
 823    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 824         wine_cv_linux_joystick_22_api,
 825         AC_TRY_COMPILE([
 826         #include <sys/ioctl.h>
 827         #include <linux/joystick.h>
 828
 829         struct js_event blub;
 830         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 831         #error "no 2.2 header"
 832         #endif
 833         ],/*empty*/,
 834         wine_cv_linux_joystick_22_api=yes,
 835         wine_cv_linux_joystick_22_api=no,
 836         wine_cv_linux_joystick_22_api=no
 837         )
 838    )
 839    if test "$wine_cv_linux_joystick_22_api" = "yes"
 840    then
 841       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 842    fi
 843 fi
 844
 845 dnl **** statfs checks ****
 846
 847 if test "$ac_cv_header_sys_vfs_h" = "yes"
 848 then
 849     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 850                     wine_cv_sys_vfs_has_statfs,
 851         AC_TRY_COMPILE([
 852         #include <sys/types.h>
 853         #ifdef HAVE_SYS_PARAM_H
 854         # include <sys/param.h>
 855         #endif
 856         #include <sys/vfs.h>
 857         ],[
 858                 struct statfs stfs;
 859
 860                 memset(&stfs,0,sizeof(stfs));
 861         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 862         )
 863     )
 864     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 865     then
 866       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 867     fi
 868 fi
 869
 870 if test "$ac_cv_header_sys_statfs_h" = "yes"
 871 then
 872     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 873                     wine_cv_sys_statfs_has_statfs,
 874         AC_TRY_COMPILE([
 875         #include <sys/types.h>
 876         #ifdef HAVE_SYS_PARAM_H
 877         # include <sys/param.h>
 878         #endif
 879         #include <sys/statfs.h>
 880         ],[
 881                 struct statfs stfs;
 882         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 883         )
 884     )
 885     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 886     then
 887       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 888     fi
 889 fi
 890
 891 if test "$ac_cv_header_sys_mount_h" = "yes"
 892 then
 893     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 894                     wine_cv_sys_mount_has_statfs,
 895         AC_TRY_COMPILE([
 896         #include <sys/types.h>
 897         #ifdef HAVE_SYS_PARAM_H
 898         # include <sys/param.h>
 899         #endif
 900         #include <sys/mount.h>
 901         ],[
 902                 struct statfs stfs;
 903         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 904         )
 905     )
 906     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 907     then
 908       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 909     fi
 910 fi
 911
 912 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 913
 914 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 915   [ if test "x$statfs_bfree" = "xno"
 916     then
 917         wine_cv_statfs_bfree=no
 918     else
 919         AC_TRY_COMPILE([
 920         #include <sys/types.h>
 921         #ifdef HAVE_SYS_PARAM_H
 922         # include <sys/param.h>
 923         #endif
 924         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 925         # include <sys/mount.h>
 926         #else
 927         # ifdef STATFS_DEFINED_BY_SYS_VFS
 928         #  include <sys/vfs.h>
 929         # else
 930         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 931         #   include <sys/statfs.h>
 932         #  endif
 933         # endif
 934         #endif
 935         ],[
 936                 struct statfs stfs;
 937
 938                 stfs.f_bfree++;
 939         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 940         )
 941     fi ] )
 942 if test "$wine_cv_statfs_bfree" = "yes"
 943 then
 944   AC_DEFINE(STATFS_HAS_BFREE)
 945 fi
 946
 947 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 948   [ if test "x$statfs_bavail" = "xno"
 949     then
 950         wine_cv_statfs_bavail=no
 951     else
 952         AC_TRY_COMPILE([
 953         #include <sys/types.h>
 954         #ifdef HAVE_SYS_PARAM_H
 955         # include <sys/param.h>
 956         #endif
 957         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 958         # include <sys/mount.h>
 959         #else
 960         # ifdef STATFS_DEFINED_BY_SYS_VFS
 961         #  include <sys/vfs.h>
 962         # else
 963         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 964         #   include <sys/statfs.h>
 965         #  endif
 966         # endif
 967         #endif
 968         ],[
 969                 struct statfs stfs;
 970
 971                 stfs.f_bavail++;
 972         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 973         )
 974     fi ] )
 975 if test "$wine_cv_statfs_bavail" = "yes"
 976 then
 977   AC_DEFINE(STATFS_HAS_BAVAIL)
 978 fi
 979
 980 dnl *** check for file descriptor passing with msg_accrights
 981
 982 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 983  AC_TRY_COMPILE([#include <sys/types.h>
 984 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 985                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 986 if test "$ac_cv_c_msg_accrights" = "yes"
 987 then
 988     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 989 fi
 990
 991 dnl *** Check for the sun_len member in struct sockaddr_un
 992
 993 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
 994  AC_TRY_COMPILE([#include <sys/types.h>
 995 #include <sys/socket.h>
 996 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
 997                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
 998 if test "$ac_cv_c_sun_len" = "yes"
 999 then
1000     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1001 fi
1002
1003 dnl *** check for the need to define __i386__
1004
1005 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1006  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1007 yes
1008 #endif],
1009  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1010 if test "$ac_cv_cpp_def_i386" = "yes"
1011 then
1012     CFLAGS="$CFLAGS -D__i386__"
1013     LINTFLAGS="$LINTFLAGS -D__i386__"
1014 fi
1015
1016 dnl $GCC is set by autoconf
1017 GCC_NO_BUILTIN=""
1018 if test "$GCC" = "yes"
1019 then
1020     GCC_NO_BUILTIN="-fno-builtin"
1021 fi
1022 AC_SUBST(GCC_NO_BUILTIN)
1023
1024 dnl **** Generate output files ****
1025
1026 AC_OUTPUT_COMMANDS([
1027 extra_subdirs="\
1028 dlls/ddraw/d3ddevice \
1029 dlls/ddraw/dclipper \
1030 dlls/ddraw/ddraw \
1031 dlls/ddraw/direct3d \
1032 dlls/ddraw/dpalette \
1033 dlls/ddraw/dsurface \
1034 dlls/dinput/joystick \
1035 dlls/dinput/keyboard \
1036 dlls/dinput/mouse \
1037 dlls/kernel/messages \
1038 dlls/user/resources \
1039 "
1040 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1041
1042 MAKE_RULES=Make.rules
1043 AC_SUBST_FILE(MAKE_RULES)
1044
1045 MAKE_DLL_RULES=dlls/Makedll.rules
1046 AC_SUBST_FILE(MAKE_DLL_RULES)
1047
1048 AC_OUTPUT([
1049 Make.rules
1050 Makefile
1051 console/Makefile
1052 controls/Makefile
1053 debugger/Makefile
1054 dlls/Makedll.rules
1055 dlls/Makefile
1056 dlls/advapi32/Makefile
1057 dlls/avifil32/Makefile
1058 dlls/comctl32/Makefile
1059 dlls/commdlg/Makefile
1060 dlls/crtdll/Makefile
1061 dlls/dciman32/Makefile
1062 dlls/ddraw/Makefile
1063 dlls/dinput/Makefile
1064 dlls/dplay/Makefile
1065 dlls/dplayx/Makefile
1066 dlls/dsound/Makefile
1067 dlls/gdi/Makefile
1068 dlls/icmp/Makefile
1069 dlls/imagehlp/Makefile
1070 dlls/imm32/Makefile
1071 dlls/kernel/Makefile
1072 dlls/lzexpand/Makefile
1073 dlls/mpr/Makefile
1074 dlls/msacm/Makefile
1075 dlls/msnet32/Makefile
1076 dlls/msvideo/Makefile
1077 dlls/ntdll/Makefile
1078 dlls/odbc32/Makefile
1079 dlls/ole32/Makefile
1080 dlls/oleaut32/Makefile
1081 dlls/olecli/Makefile
1082 dlls/oledlg/Makefile
1083 dlls/olepro32/Makefile
1084 dlls/olesvr/Makefile
1085 dlls/opengl32/Makefile
1086 dlls/psapi/Makefile
1087 dlls/rasapi32/Makefile
1088 dlls/richedit/Makefile
1089 dlls/rpcrt4/Makefile
1090 dlls/serialui/Makefile
1091 dlls/setupapi/Makefile
1092 dlls/shell32/Makefile
1093 dlls/shfolder/Makefile
1094 dlls/shlwapi/Makefile
1095 dlls/tapi32/Makefile
1096 dlls/ttydrv/Makefile
1097 dlls/urlmon/Makefile
1098 dlls/user/Makefile
1099 dlls/version/Makefile
1100 dlls/win32s/Makefile
1101 dlls/winaspi/Makefile
1102 dlls/wineps/Makefile
1103 dlls/wininet/Makefile
1104 dlls/winmm/Makefile
1105 dlls/winmm/joystick/Makefile
1106 dlls/winmm/mcianim/Makefile
1107 dlls/winmm/mciavi/Makefile
1108 dlls/winmm/mcicda/Makefile
1109 dlls/winmm/mciseq/Makefile
1110 dlls/winmm/mciwave/Makefile
1111 dlls/winmm/midimap/Makefile
1112 dlls/winmm/wavemap/Makefile
1113 dlls/winmm/wineoss/Makefile
1114 dlls/winsock/Makefile
1115 dlls/winspool/Makefile
1116 dlls/wow32/Makefile
1117 dlls/wsock32/Makefile
1118 dlls/x11drv/Makefile
1119 documentation/Makefile
1120 documentation/wine.conf.man
1121 documentation/wine.man
1122 files/Makefile
1123 graphics/Makefile
1124 graphics/enhmetafiledrv/Makefile
1125 graphics/metafiledrv/Makefile
1126 graphics/win16drv/Makefile
1127 graphics/x11drv/Makefile
1128 if1632/Makefile
1129 include/Makefile
1130 library/Makefile
1131 libtest/Makefile
1132 loader/Makefile
1133 loader/dos/Makefile
1134 loader/ne/Makefile
1135 memory/Makefile
1136 misc/Makefile
1137 miscemu/Makefile
1138 msdos/Makefile
1139 objects/Makefile
1140 ole/Makefile
1141 programs/Makefile
1142 programs/avitools/Makefile
1143 programs/clock/Makefile
1144 programs/cmdlgtst/Makefile
1145 programs/control/Makefile
1146 programs/notepad/Makefile
1147 programs/osversioncheck/Makefile
1148 programs/progman/Makefile
1149 programs/regapi/Makefile
1150 programs/regtest/Makefile
1151 programs/uninstaller/Makefile
1152 programs/view/Makefile
1153 programs/wcmd/Makefile
1154 programs/winemine/Makefile
1155 programs/winhelp/Makefile
1156 programs/winver/Makefile
1157 relay32/Makefile
1158 scheduler/Makefile
1159 server/Makefile
1160 tools/Makefile
1161 tools/cvdump/Makefile
1162 tools/winebuild/Makefile
1163 tools/winelauncher
1164 tools/wmc/Makefile
1165 tools/wrc/Makefile
1166 tsx11/Makefile
1167 unicode/Makefile
1168 win32/Makefile
1169 windows/Makefile
1170 windows/x11drv/Makefile ])
1171
1172 if test "$have_x" = "no"
1173 then
1174   echo
1175   echo "*** Warning: X development files not found. Wine will be built without"
1176   echo "*** X support, which currently does not work, and would probably not be"
1177   echo "*** what you want anyway. You will need to install devel packages of"
1178   echo "*** Xlib/Xfree86 and Xpm at the very least."
1179 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1180 then
1181   echo
1182   echo "*** Warning: Xpm development files not found. Wine will be built without"
1183   echo "*** Xpm support, which currently does not work. You will need to install"
1184   echo "*** devel packages of Xpm."
1185 fi
1186
1187 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1188 then
1189   echo
1190   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1191   echo "*** terminal resize support. Consider upgrading ncurses."
1192 fi
1193
1194 if test "$wine_cv_libc_reentrant" = "no"
1195 then
1196   echo
1197   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1198   echo "*** thread support. Consider upgrading libc to a more recent"
1199   echo "*** reentrant version of libc."
1200 fi
1201
1202 if test "$wine_cv_opengl_version_OK" = "no"
1203 then
1204   echo
1205   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1206   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1207 fi
1208
1209 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1210 then
1211   echo
1212   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1213   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1214   echo "*** A fix for glibc 2.1.3 that seem to work is included in this version of Wine,"
1215   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1216 fi
1217
1218 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1219 then
1220   echo
1221   echo "*** Warning: you explicitely linked in a thread-safe OpenGL version. If you"
1222   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1223   echo "*** support before reporting bugs."
1224 fi
1225
1226
1227 echo
1228 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1229 echo
1230
1231 dnl Local Variables:
1232 dnl comment-start: "dnl "
1233 dnl comment-end: ""
1234 dnl comment-start-skip: "\\bdnl\\b\\s *"
1235 dnl compile-command: "autoconf"
1236 dnl End: