git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "proxy.h"
  41 #include "typelib.h"
  42
  43 #if defined(YYBYACC)
  44         /* Berkeley yacc (byacc) doesn't seem to know about these */
  45         /* Some *BSD supplied versions do define these though */
  46 # ifndef YYEMPTY
  47 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  48 # endif
  49 # ifndef YYLEX
  50 #  define YYLEX         yylex()
  51 # endif
  52
  53 #elif defined(YYBISON)
  54         /* Bison was used for original development */
  55         /* #define YYEMPTY -2 */
  56         /* #define YYLEX   yylex() */
  57
  58 #else
  59         /* No yacc we know yet */
  60 # if !defined(YYEMPTY) || !defined(YYLEX)
  61 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  62 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  63 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  64   /* #else we just take a chance that it works... */
  65 # endif
  66 #endif
  67
  68 static attr_t *make_attr(enum attr_type type);
  69 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  70 static attr_t *make_attrp(enum attr_type type, void *val);
  71 static expr_t *make_expr(enum expr_type type);
  72 static expr_t *make_exprl(enum expr_type type, long val);
  73 static expr_t *make_exprs(enum expr_type type, char *val);
  74 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  75 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  76 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  77 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  78 static type_t *make_type(unsigned char type, type_t *ref);
  79 static typeref_t *make_tref(char *name, type_t *ref);
  80 static typeref_t *uniq_tref(typeref_t *ref);
  81 static type_t *type_ref(typeref_t *ref);
  82 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  83 static ifref_t *make_ifref(type_t *iface);
  84 static var_t *make_var(char *name);
  85 static func_t *make_func(var_t *def, var_t *args);
  86 static class_t *make_class(char *name);
  87
  88 static type_t *reg_type(type_t *type, char *name, int t);
  89 static type_t *reg_types(type_t *type, var_t *names, int t);
  90 static type_t *find_type(char *name, int t);
  91 static type_t *find_type2(char *name, int t);
  92 static type_t *get_type(unsigned char type, char *name, int t);
  93 static type_t *get_typev(unsigned char type, var_t *name, int t);
  94 static int get_struct_type(var_t *fields);
  95
  96 static var_t *reg_const(var_t *var);
  97 static var_t *find_const(char *name, int f);
  98
  99 #define tsENUM   1
 100 #define tsSTRUCT 2
 101 #define tsUNION  3
 102
 103 static type_t std_bool = { "boolean" };
 104 static type_t std_int = { "int" };
 105 static type_t std_int64 = { "__int64" };
 106 static type_t std_uhyper = { "MIDL_uhyper" };
 107
 108 %}
 109 %union {
 110         attr_t *attr;
 111         expr_t *expr;
 112         type_t *type;
 113         typeref_t *tref;
 114         var_t *var;
 115         func_t *func;
 116         ifref_t *ifref;
 117         class_t *clas;
 118         char *str;
 119         UUID *uuid;
 120         unsigned int num;
 121 }
 122
 123 %token <str> aIDENTIFIER
 124 %token <str> aKNOWNTYPE
 125 %token <num> aNUM aHEXNUM
 126 %token <str> aSTRING
 127 %token <uuid> aUUID
 128 %token aEOF
 129 %token SHL SHR
 130 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
 131 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 132 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 133 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 134 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 135 %token tDEFAULT
 136 %token tDEFAULTVALUE
 137 %token tDISPINTERFACE
 138 %token tDLLNAME tDOUBLE tDUAL
 139 %token tENDPOINT
 140 %token tENTRY tENUM tERRORSTATUST
 141 %token tEXTERN
 142 %token tFLOAT
 143 %token tHANDLE
 144 %token tHANDLET
 145 %token tHELPCONTEXT tHELPFILE
 146 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 147 %token tHIDDEN
 148 %token tHYPER tID tIDEMPOTENT
 149 %token tIIDIS
 150 %token tIMPORT tIMPORTLIB
 151 %token tIN tINCLUDE tINLINE
 152 %token tINPUTSYNC
 153 %token tINT tINT64
 154 %token tINTERFACE
 155 %token tLENGTHIS tLIBRARY
 156 %token tLOCAL
 157 %token tLONG
 158 %token tMETHODS
 159 %token tMODULE
 160 %token tOBJECT tODL tOLEAUTOMATION
 161 %token tOPTIONAL
 162 %token tOUT
 163 %token tPOINTERDEFAULT
 164 %token tPROPERTIES
 165 %token tPROPGET tPROPPUT tPROPPUTREF
 166 %token tPUBLIC
 167 %token tREADONLY tREF
 168 %token tRESTRICTED
 169 %token tRETVAL
 170 %token tSHORT
 171 %token tSIGNED
 172 %token tSIZEIS tSIZEOF
 173 %token tSOURCE
 174 %token tSTDCALL
 175 %token tSTRING tSTRUCT
 176 %token tSWITCH tSWITCHIS tSWITCHTYPE
 177 %token tTRANSMITAS
 178 %token tTYPEDEF
 179 %token tUNION
 180 %token tUNIQUE
 181 %token tUNSIGNED
 182 %token tUUID
 183 %token tV1ENUM
 184 %token tVARARG
 185 %token tVERSION
 186 %token tVOID
 187 %token tWCHAR tWIREMARSHAL
 188
 189 /* used in attr_t */
 190 %token tPOINTERTYPE
 191
 192 %type <attr> m_attributes attributes attrib_list attribute
 193 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 194 %type <expr> array array_list
 195 %type <type> inherit interface interfacehdr interfacedef interfacedec
 196 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 197 %type <type> module modulehdr moduledef
 198 %type <type> base_type int_std
 199 %type <type> enumdef structdef typedef uniondef
 200 %type <ifref> gbl_statements coclass_ints coclass_int
 201 %type <tref> type
 202 %type <var> m_args no_args args arg
 203 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 204 %type <var> m_ident t_ident ident p_ident pident pident_list
 205 %type <var> dispint_props
 206 %type <func> funcdef int_statements
 207 %type <func> dispint_meths
 208 %type <clas> coclass coclasshdr coclassdef
 209 %type <num> pointer_type version
 210 %type <str> libraryhdr
 211
 212 %left ','
 213 %right COND
 214 %left '|'
 215 %left '&'
 216 %left '-' '+'
 217 %left '*' '/'
 218 %left SHL SHR
 219 %right '~'
 220 %right CAST
 221 %right PPTR
 222 %right NEG
 223
 224 %%
 225
 226 input:    gbl_statements                        { write_proxies($1); }
 227         ;
 228
 229 gbl_statements:                                 { $$ = NULL; }
 230         | gbl_statements interfacedec           { $$ = $1; }
 231         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 232         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 233         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 234         | gbl_statements librarydef             { $$ = $1; }
 235         | gbl_statements statement              { $$ = $1; }
 236         ;
 237
 238 imp_statements:                                 {}
 239         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 240         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 241         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 242         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 243         | imp_statements statement              {}
 244         ;
 245
 246 int_statements:                                 { $$ = NULL; }
 247         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 248         | int_statements statement              { $$ = $1; }
 249         ;
 250
 251 statement: ';'                                  {}
 252         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 253         | cppquote                              {}
 254         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 255         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 256         | import                                {}
 257         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 258         | typedef ';'                           {}
 259         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 260         ;
 261
 262 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 263         ;
 264 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 265                                                   if (!do_import($2)) yychar = aEOF; }
 266         ;
 267 import:   import_start imp_statements aEOF      {}
 268         ;
 269
 270 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 271         ;
 272 library_start: attributes libraryhdr '{'        { start_typelib($2, $1); }
 273         ;
 274 librarydef: library_start imp_statements '}'    { end_typelib(); }
 275         ;
 276
 277 m_args:                                         { $$ = NULL; }
 278         | args
 279         ;
 280
 281 no_args:  tVOID                                 { $$ = NULL; }
 282         ;
 283
 284 args:     arg
 285         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 286         | no_args
 287         ;
 288
 289 /* split into two rules to get bison to resolve a tVOID conflict */
 290 arg:      attributes type pident array          { $$ = $3;
 291                                                   set_type($$, $2, $4);
 292                                                   $$->attrs = $1;
 293                                                 }
 294         | type pident array                     { $$ = $2;
 295                                                   set_type($$, $1, $3);
 296                                                 }
 297         | attributes type pident '(' m_args ')' { $$ = $3;
 298                                                   $$->ptr_level--;
 299                                                   set_type($$, $2, NULL);
 300                                                   $$->attrs = $1;
 301                                                   $$->args = $5;
 302                                                 }
 303         | type pident '(' m_args ')'            { $$ = $2;
 304                                                   $$->ptr_level--;
 305                                                   set_type($$, $1, NULL);
 306                                                   $$->args = $4;
 307                                                 }
 308         ;
 309
 310 array:                                          { $$ = NULL; }
 311         | '[' array_list ']'                    { $$ = $2; }
 312         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 313         ;
 314
 315 array_list: m_expr /* size of first dimension is optional */
 316         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 317         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 318         ;
 319
 320 m_attributes:                                   { $$ = NULL; }
 321         | attributes
 322         ;
 323
 324 attributes:
 325           '[' attrib_list ']'                   { $$ = $2; }
 326         ;
 327
 328 attrib_list: attribute
 329         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 330         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 331         ;
 332
 333 attribute:
 334           tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 335         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 336         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 337         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 338         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 339         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 340         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 341         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 342         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 343         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 344         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 345         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 346         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 347         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 348         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 349         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 350         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 351         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 352         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 353         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 354         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 355         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 356         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 357         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 358         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 359         | tIN                                   { $$ = make_attr(ATTR_IN); }
 360         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 361         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 362         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 363         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 364         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 365         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 366         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 367         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 368         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 369         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 370         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 371         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 372         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 373         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 374         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 375         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 376         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 377         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 378         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 379         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 380         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 381         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 382         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 383         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 384         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 385         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 386         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 387         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 388         ;
 389
 390 callconv:
 391         | tSTDCALL
 392         ;
 393
 394 cases:                                          { $$ = NULL; }
 395         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 396                                                   else { $$ = $1; }
 397                                                 }
 398         ;
 399
 400 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 401                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 402                                                   LINK(a, $$->attrs); $$->attrs = a;
 403                                                 }
 404         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 405                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 406                                                   LINK(a, $$->attrs); $$->attrs = a;
 407                                                 }
 408         ;
 409
 410 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 411                                                   set_type($$, $2, NULL);
 412                                                   $$->eval = $5;
 413                                                   $$->lval = $5->cval;
 414                                                 }
 415         ;
 416
 417 enums:                                          { $$ = NULL; }
 418         | enum_list ','                         { $$ = $1; }
 419         | enum_list
 420         ;
 421
 422 enum_list: enum
 423         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 424                                                   if ($1 && !$3->eval)
 425                                                     $3->lval = $1->lval + 1;
 426                                                 }
 427         ;
 428
 429 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 430                                                   $$->eval = $3;
 431                                                   $$->lval = $3->cval;
 432                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 433                                                 }
 434         | ident                                 { $$ = reg_const($1);
 435                                                   $$->lval = 0; /* default for first enum entry */
 436                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 437                                                 }
 438         ;
 439
 440 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 441                                                   $$->fields = $4;
 442                                                   $$->defined = TRUE;
 443                                                   if(in_typelib)
 444                                                       add_enum($$);
 445                                                 }
 446         ;
 447
 448 m_exprs:  m_expr
 449         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 450         ;
 451
 452 /*
 453 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 454         | expr_list
 455         ;
 456
 457 expr_list: expr
 458         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 459         ;
 460 */
 461
 462 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 463         | expr
 464         ;
 465
 466 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 467         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 468         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 469         | expr '?' expr ':' expr %prec COND     { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 470         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 471         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 472         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 473         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 474         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 475         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 476         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 477         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 478         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 479         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 480         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 481         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 482         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 483         | '(' expr ')'                          { $$ = $2; }
 484         ;
 485
 486 expr_list_const: expr_const
 487         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 488         ;
 489
 490 expr_const: expr                                { $$ = $1;
 491                                                   if (!$$->is_const) yyerror("expression is not constant\n");
 492                                                 }
 493         ;
 494
 495 externdef: tEXTERN tCONST type ident            { $$ = $4;
 496                                                   set_type($$, $3, NULL);
 497                                                 }
 498         ;
 499
 500 fields:                                         { $$ = NULL; }
 501         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 502                                                   else { $$ = $1; }
 503                                                 }
 504         ;
 505
 506 field:    s_field ';'                           { $$ = $1; }
 507         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 508         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 509         | ';'                                   { $$ = NULL; }
 510         ;
 511
 512 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 513         ;
 514
 515 funcdef:
 516           m_attributes type callconv pident
 517           '(' m_args ')'                        { set_type($4, $2, NULL);
 518                                                   $4->attrs = $1;
 519                                                   $$ = make_func($4, $6);
 520                                                   if (is_attr($4->attrs, ATTR_IN)) {
 521                                                     yyerror("Inapplicable attribute");
 522                                                   }
 523                                                 }
 524         ;
 525
 526 m_ident:                                        { $$ = NULL; }
 527         | ident
 528         ;
 529
 530 t_ident:                                        { $$ = NULL; }
 531         | aIDENTIFIER                           { $$ = make_var($1); }
 532         | aKNOWNTYPE                            { $$ = make_var($1); }
 533         ;
 534
 535 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 536 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 537         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 538         | tID                                   { $$ = make_var($<str>1); }
 539         | tRETVAL                               { $$ = make_var($<str>1); }
 540         | tVERSION                              { $$ = make_var($<str>1); }
 541         ;
 542
 543 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 544         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 545         | int_std
 546         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 547         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 548                                                   switch ($$->type) {
 549                                                   case RPC_FC_CHAR:  $$->type = RPC_FC_BYTE; $$->sign = 0; break;
 550                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 551                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 552                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 553                                                   case RPC_FC_HYPER:
 554                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 555                                                     break;
 556                                                   default: break;
 557                                                   }
 558                                                 }
 559         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 560         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 561         | tBOOLEAN                              { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
 562         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 563         | tHANDLET                              { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
 564         ;
 565
 566 m_int:
 567         | tINT
 568         ;
 569
 570 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 571         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 572         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 573         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 574         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 575         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 576         ;
 577
 578 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 579         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 580         ;
 581
 582 coclasshdr: attributes coclass                  { $$ = $2;
 583                                                   $$->attrs = $1;
 584                                                   if (!parse_only && do_header) write_coclass($$);
 585                                                 }
 586         ;
 587
 588 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 589                                                   $$->ifaces = $3;
 590                                                 }
 591         ;
 592
 593 coclass_ints:                                   { $$ = NULL; }
 594         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 595         ;
 596
 597 coclass_int:
 598           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 599         ;
 600
 601 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 602         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 603         ;
 604
 605 dispinterfacehdr: attributes dispinterface      { $$ = $2;
 606                                                   if ($$->defined) yyerror("multiple definition error\n");
 607                                                   $$->attrs = $1;
 608                                                   $$->attrs = make_attr(ATTR_DISPINTERFACE);
 609                                                   LINK($$->attrs, $1);
 610                                                   $$->ref = find_type("IDispatch", 0);
 611                                                   if (!$$->ref) yyerror("IDispatch is undefined\n");
 612                                                   $$->defined = TRUE;
 613                                                   if (!parse_only && do_header) write_forward($$);
 614                                                 }
 615         ;
 616
 617 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 618         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 619         ;
 620
 621 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 622         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 623         ;
 624
 625 dispinterfacedef: dispinterfacehdr '{'
 626           dispint_props
 627           dispint_meths
 628           '}'                                   { $$ = $1;
 629                                                   $$->fields = $3;
 630                                                   $$->funcs = $4;
 631                                                   if (!parse_only && do_header) write_dispinterface($$);
 632                                                 }
 633 /* FIXME: not sure how to handle this yet
 634         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 635                                                   if (!parse_only && do_header) write_interface($$);
 636                                                 }
 637 */
 638         ;
 639
 640 inherit:                                        { $$ = NULL; }
 641         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 642         ;
 643
 644 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 645         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 646         ;
 647
 648 interfacehdr: attributes interface              { $$ = $2;
 649                                                   if ($$->defined) yyerror("multiple definition error\n");
 650                                                   $$->attrs = $1;
 651                                                   $$->defined = TRUE;
 652                                                   if (!parse_only && do_header) write_forward($$);
 653                                                 }
 654         ;
 655
 656 interfacedef: interfacehdr inherit
 657           '{' int_statements '}'                { $$ = $1;
 658                                                   $$->ref = $2;
 659                                                   $$->funcs = $4;
 660                                                   if (!parse_only && do_header) write_interface($$);
 661                                                 }
 662 /* MIDL is able to import the definition of a base class from inside the
 663  * definition of a derived class, I'll try to support it with this rule */
 664         | interfacehdr ':' aIDENTIFIER
 665           '{' import int_statements '}'         { $$ = $1;
 666                                                   $$->ref = find_type2($3, 0);
 667                                                   if (!$$->ref) yyerror("base class %s not found in import\n", $3);
 668                                                   $$->funcs = $6;
 669                                                   if (!parse_only && do_header) write_interface($$);
 670                                                 }
 671         | dispinterfacedef                      { $$ = $1; }
 672         ;
 673
 674 interfacedec:
 675           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 676         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 677         ;
 678
 679 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 680         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 681         ;
 682
 683 modulehdr: attributes module                    { $$ = $2;
 684                                                   $$->attrs = $1;
 685                                                 }
 686         ;
 687
 688 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 689                                                   $$->funcs = $3;
 690                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 691                                                 }
 692         ;
 693
 694 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 695         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 696         ;
 697
 698 pident:   ident
 699         | p_ident
 700         | '(' pident ')'                        { $$ = $2; }
 701         ;
 702
 703 pident_list:
 704           pident
 705         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 706         ;
 707
 708 pointer_type:
 709           tREF                                  { $$ = RPC_FC_RP; }
 710         | tUNIQUE                               { $$ = RPC_FC_UP; }
 711         ;
 712
 713 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 714                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 715                                                   $$->type = get_struct_type( $4 );
 716                                                   $$->fields = $4;
 717                                                   $$->defined = TRUE;
 718                                                   if(in_typelib)
 719                                                       add_struct($$);
 720                                                 }
 721         ;
 722
 723 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 724         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 725         | base_type                             { $$ = make_tref(NULL, $1); }
 726         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 727         | enumdef                               { $$ = make_tref(NULL, $1); }
 728         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 729         | structdef                             { $$ = make_tref(NULL, $1); }
 730         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 731         | uniondef                              { $$ = make_tref(NULL, $1); }
 732         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 733         ;
 734
 735 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 736                                                   $4->tname = tref->name;
 737                                                   tref->name = NULL;
 738                                                   $$ = type_ref(tref);
 739                                                   $$->attrs = $2;
 740                                                   if (!parse_only && do_header) write_typedef($$, $4);
 741                                                   reg_types($$, $4, 0);
 742                                                 }
 743         ;
 744
 745 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 746                                                   $$->fields = $4;
 747                                                   $$->defined = TRUE;
 748                                                 }
 749         | tUNION t_ident
 750           tSWITCH '(' s_field ')'
 751           m_ident '{' cases '}'                 { var_t *u = $7;
 752                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 753                                                   if (!u) u = make_var("tagged_union");
 754                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 755                                                   u->type->fields = $9;
 756                                                   u->type->defined = TRUE;
 757                                                   LINK(u, $5); $$->fields = u;
 758                                                   $$->defined = TRUE;
 759                                                 }
 760         ;
 761
 762 version:
 763           aNUM                                  { $$ = MAKELONG($1, 0); }
 764         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 765         ;
 766
 767 %%
 768
 769 static attr_t *make_attr(enum attr_type type)
 770 {
 771   attr_t *a = xmalloc(sizeof(attr_t));
 772   a->type = type;
 773   a->u.ival = 0;
 774   INIT_LINK(a);
 775   return a;
 776 }
 777
 778 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 779 {
 780   attr_t *a = xmalloc(sizeof(attr_t));
 781   a->type = type;
 782   a->u.ival = val;
 783   INIT_LINK(a);
 784   return a;
 785 }
 786
 787 static attr_t *make_attrp(enum attr_type type, void *val)
 788 {
 789   attr_t *a = xmalloc(sizeof(attr_t));
 790   a->type = type;
 791   a->u.pval = val;
 792   INIT_LINK(a);
 793   return a;
 794 }
 795
 796 static expr_t *make_expr(enum expr_type type)
 797 {
 798   expr_t *e = xmalloc(sizeof(expr_t));
 799   e->type = type;
 800   e->ref = NULL;
 801   e->u.lval = 0;
 802   e->is_const = FALSE;
 803   INIT_LINK(e);
 804   return e;
 805 }
 806
 807 static expr_t *make_exprl(enum expr_type type, long val)
 808 {
 809   expr_t *e = xmalloc(sizeof(expr_t));
 810   e->type = type;
 811   e->ref = NULL;
 812   e->u.lval = val;
 813   e->is_const = FALSE;
 814   INIT_LINK(e);
 815   /* check for numeric constant */
 816   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 817     e->is_const = TRUE;
 818     e->cval = val;
 819   }
 820   return e;
 821 }
 822
 823 static expr_t *make_exprs(enum expr_type type, char *val)
 824 {
 825   expr_t *e;
 826   e = xmalloc(sizeof(expr_t));
 827   e->type = type;
 828   e->ref = NULL;
 829   e->u.sval = val;
 830   e->is_const = FALSE;
 831   INIT_LINK(e);
 832   /* check for predefined constants */
 833   if (type == EXPR_IDENTIFIER) {
 834     var_t *c = find_const(val, 0);
 835     if (c) {
 836       e->u.sval = c->name;
 837       free(val);
 838       e->is_const = TRUE;
 839       e->cval = c->lval;
 840     }
 841   }
 842   return e;
 843 }
 844
 845 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 846 {
 847   expr_t *e;
 848   e = xmalloc(sizeof(expr_t));
 849   e->type = type;
 850   e->ref = expr;
 851   e->u.tref = tref;
 852   e->is_const = FALSE;
 853   INIT_LINK(e);
 854   /* check for cast of constant expression */
 855   if (type == EXPR_CAST && expr->is_const) {
 856     e->is_const = TRUE;
 857     e->cval = expr->cval;
 858   }
 859   return e;
 860 }
 861
 862 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 863 {
 864   expr_t *e;
 865   e = xmalloc(sizeof(expr_t));
 866   e->type = type;
 867   e->ref = expr;
 868   e->u.lval = 0;
 869   e->is_const = FALSE;
 870   INIT_LINK(e);
 871   /* check for compile-time optimization */
 872   if (expr->is_const) {
 873     e->is_const = TRUE;
 874     switch (type) {
 875     case EXPR_NEG:
 876       e->cval = -expr->cval;
 877       break;
 878     case EXPR_NOT:
 879       e->cval = ~expr->cval;
 880       break;
 881     default:
 882       e->is_const = FALSE;
 883       break;
 884     }
 885   }
 886   return e;
 887 }
 888
 889 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 890 {
 891   expr_t *e;
 892   e = xmalloc(sizeof(expr_t));
 893   e->type = type;
 894   e->ref = expr1;
 895   e->u.ext = expr2;
 896   e->is_const = FALSE;
 897   INIT_LINK(e);
 898   /* check for compile-time optimization */
 899   if (expr1->is_const && expr2->is_const) {
 900     e->is_const = TRUE;
 901     switch (type) {
 902     case EXPR_ADD:
 903       e->cval = expr1->cval + expr2->cval;
 904       break;
 905     case EXPR_SUB:
 906       e->cval = expr1->cval - expr2->cval;
 907       break;
 908     case EXPR_MUL:
 909       e->cval = expr1->cval * expr2->cval;
 910       break;
 911     case EXPR_DIV:
 912       e->cval = expr1->cval / expr2->cval;
 913       break;
 914     case EXPR_OR:
 915       e->cval = expr1->cval | expr2->cval;
 916       break;
 917     case EXPR_AND:
 918       e->cval = expr1->cval & expr2->cval;
 919       break;
 920     case EXPR_SHL:
 921       e->cval = expr1->cval << expr2->cval;
 922       break;
 923     case EXPR_SHR:
 924       e->cval = expr1->cval >> expr2->cval;
 925       break;
 926     default:
 927       e->is_const = FALSE;
 928       break;
 929     }
 930   }
 931   return e;
 932 }
 933
 934 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
 935 {
 936   expr_t *e;
 937   e = xmalloc(sizeof(expr_t));
 938   e->type = type;
 939   e->ref = expr1;
 940   e->u.ext = expr2;
 941   e->ext2 = expr3;
 942   e->is_const = FALSE;
 943   INIT_LINK(e);
 944   /* check for compile-time optimization */
 945   if (expr1->is_const && expr2->is_const && expr3->is_const) {
 946     e->is_const = TRUE;
 947     switch (type) {
 948     case EXPR_COND:
 949       e->cval = expr1->cval ? expr2->cval : expr3->cval;
 950       break;
 951     default:
 952       e->is_const = FALSE;
 953       break;
 954     }
 955   }
 956   return e;
 957 }
 958
 959 static type_t *make_type(unsigned char type, type_t *ref)
 960 {
 961   type_t *t = xmalloc(sizeof(type_t));
 962   t->name = NULL;
 963   t->type = type;
 964   t->ref = ref;
 965   t->rname = NULL;
 966   t->attrs = NULL;
 967   t->funcs = NULL;
 968   t->fields = NULL;
 969   t->ignore = parse_only;
 970   t->is_const = FALSE;
 971   t->sign = 0;
 972   t->defined = FALSE;
 973   t->written = FALSE;
 974   t->typelib_idx = -1;
 975   INIT_LINK(t);
 976   return t;
 977 }
 978
 979 static typeref_t *make_tref(char *name, type_t *ref)
 980 {
 981   typeref_t *t = xmalloc(sizeof(typeref_t));
 982   t->name = name;
 983   t->ref = ref;
 984   t->uniq = ref ? 0 : 1;
 985   return t;
 986 }
 987
 988 static typeref_t *uniq_tref(typeref_t *ref)
 989 {
 990   typeref_t *t = ref;
 991   type_t *tp;
 992   if (t->uniq) return t;
 993   tp = make_type(0, t->ref);
 994   tp->name = t->name;
 995   t->name = NULL;
 996   t->ref = tp;
 997   t->uniq = 1;
 998   return t;
 999 }
1000
1001 static type_t *type_ref(typeref_t *ref)
1002 {
1003   type_t *t = ref->ref;
1004   if (ref->name) free(ref->name);
1005   free(ref);
1006   return t;
1007 }
1008
1009 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1010 {
1011   v->type = ref->ref;
1012   v->tname = ref->name;
1013   ref->name = NULL;
1014   free(ref);
1015   v->array = arr;
1016 }
1017
1018 static ifref_t *make_ifref(type_t *iface)
1019 {
1020   ifref_t *l = xmalloc(sizeof(ifref_t));
1021   l->iface = iface;
1022   l->attrs = NULL;
1023   INIT_LINK(l);
1024   return l;
1025 }
1026
1027 static var_t *make_var(char *name)
1028 {
1029   var_t *v = xmalloc(sizeof(var_t));
1030   v->name = name;
1031   v->ptr_level = 0;
1032   v->type = NULL;
1033   v->tname = NULL;
1034   v->attrs = NULL;
1035   v->array = NULL;
1036   v->eval = NULL;
1037   v->lval = 0;
1038   INIT_LINK(v);
1039   return v;
1040 }
1041
1042 static func_t *make_func(var_t *def, var_t *args)
1043 {
1044   func_t *f = xmalloc(sizeof(func_t));
1045   f->def = def;
1046   f->args = args;
1047   f->ignore = parse_only;
1048   f->idx = -1;
1049   INIT_LINK(f);
1050   return f;
1051 }
1052
1053 static class_t *make_class(char *name)
1054 {
1055   class_t *c = xmalloc(sizeof(class_t));
1056   c->name = name;
1057   c->attrs = NULL;
1058   c->ifaces = NULL;
1059   INIT_LINK(c);
1060   return c;
1061 }
1062
1063 #define HASHMAX 64
1064
1065 static int hash_ident(const char *name)
1066 {
1067   const char *p = name;
1068   int sum = 0;
1069   /* a simple sum hash is probably good enough */
1070   while (*p) {
1071     sum += *p;
1072     p++;
1073   }
1074   return sum & (HASHMAX-1);
1075 }
1076
1077 /***** type repository *****/
1078
1079 struct rtype {
1080   char *name;
1081   type_t *type;
1082   int t;
1083   struct rtype *next;
1084 };
1085
1086 struct rtype *type_hash[HASHMAX];
1087
1088 static type_t *reg_type(type_t *type, char *name, int t)
1089 {
1090   struct rtype *nt;
1091   int hash;
1092   if (!name) {
1093     yyerror("registering named type without name\n");
1094     return type;
1095   }
1096   hash = hash_ident(name);
1097   nt = xmalloc(sizeof(struct rtype));
1098   nt->name = name;
1099   nt->type = type;
1100   nt->t = t;
1101   nt->next = type_hash[hash];
1102   type_hash[hash] = nt;
1103   return type;
1104 }
1105
1106 /* determine pointer type from attrs */
1107 static unsigned char get_pointer_type( type_t *type )
1108 {
1109   int t;
1110   if (is_attr( type->attrs, ATTR_STRING ))
1111   {
1112     type_t *t = type;
1113     while( t->type == 0 && t->ref )
1114       t = t->ref;
1115     switch( t->type )
1116     {
1117     case RPC_FC_CHAR:
1118       return RPC_FC_C_CSTRING;
1119     case RPC_FC_WCHAR:
1120       return RPC_FC_C_WSTRING;
1121     }
1122   }
1123   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1124   if (t) return t;
1125   return RPC_FC_FP;
1126 }
1127
1128 static type_t *reg_types(type_t *type, var_t *names, int t)
1129 {
1130   type_t *ptr = type;
1131   int ptrc = 0;
1132
1133   while (names) {
1134     var_t *next = NEXT_LINK(names);
1135     if (names->name) {
1136       type_t *cur = ptr;
1137       int cptr = names->ptr_level;
1138       if (cptr > ptrc) {
1139         while (cptr > ptrc) {
1140           int t = get_pointer_type( cur );
1141           cur = ptr = make_type(t, cur);
1142           ptrc++;
1143         }
1144       } else {
1145         while (cptr < ptrc) {
1146           cur = cur->ref;
1147           cptr++;
1148         }
1149       }
1150       reg_type(cur, names->name, t);
1151     }
1152     free(names);
1153     names = next;
1154   }
1155   return type;
1156 }
1157
1158 static type_t *find_type(char *name, int t)
1159 {
1160   struct rtype *cur = type_hash[hash_ident(name)];
1161   while (cur && (cur->t != t || strcmp(cur->name, name)))
1162     cur = cur->next;
1163   if (!cur) {
1164     yyerror("type %s not found\n", name);
1165     return NULL;
1166   }
1167   return cur->type;
1168 }
1169
1170 static type_t *find_type2(char *name, int t)
1171 {
1172   type_t *tp = find_type(name, t);
1173   free(name);
1174   return tp;
1175 }
1176
1177 int is_type(const char *name)
1178 {
1179   struct rtype *cur = type_hash[hash_ident(name)];
1180   while (cur && (cur->t || strcmp(cur->name, name)))
1181     cur = cur->next;
1182   if (cur) return TRUE;
1183   return FALSE;
1184 }
1185
1186 static type_t *get_type(unsigned char type, char *name, int t)
1187 {
1188   struct rtype *cur = NULL;
1189   type_t *tp;
1190   if (name) {
1191     cur = type_hash[hash_ident(name)];
1192     while (cur && (cur->t != t || strcmp(cur->name, name)))
1193       cur = cur->next;
1194   }
1195   if (cur) {
1196     free(name);
1197     return cur->type;
1198   }
1199   tp = make_type(type, NULL);
1200   tp->name = name;
1201   if (!name) return tp;
1202   return reg_type(tp, name, t);
1203 }
1204
1205 static type_t *get_typev(unsigned char type, var_t *name, int t)
1206 {
1207   char *sname = NULL;
1208   if (name) {
1209     sname = name->name;
1210     free(name);
1211   }
1212   return get_type(type, sname, t);
1213 }
1214
1215 static int get_struct_type(var_t *field)
1216 {
1217   int has_pointer = 0;
1218   int has_conformant_array = 0;
1219   int has_conformant_string = 0;
1220
1221   while (field)
1222   {
1223     type_t *t = field->type;
1224
1225     /* get the base type */
1226     while( (t->type == 0) && t->ref )
1227       t = t->ref;
1228
1229     switch (t->type)
1230     {
1231     /*
1232      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1233      *  Simple types don't effect the type of struct.
1234      *  A struct containing a simple struct is still a simple struct.
1235      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1236      */
1237     case 0: /* void pointer */
1238     case RPC_FC_BYTE:
1239     case RPC_FC_CHAR:
1240     case RPC_FC_SMALL:
1241     case RPC_FC_USMALL:
1242     case RPC_FC_WCHAR:
1243     case RPC_FC_SHORT:
1244     case RPC_FC_USHORT:
1245     case RPC_FC_LONG:
1246     case RPC_FC_ULONG:
1247     case RPC_FC_INT3264:
1248     case RPC_FC_UINT3264:
1249     case RPC_FC_HYPER:
1250     case RPC_FC_FLOAT:
1251     case RPC_FC_DOUBLE:
1252     case RPC_FC_STRUCT:
1253     case RPC_FC_ENUM16:
1254     case RPC_FC_ENUM32:
1255       break;
1256
1257     case RPC_FC_UP:
1258     case RPC_FC_FP:
1259       has_pointer = 1;
1260       break;
1261     case RPC_FC_CARRAY:
1262       has_conformant_array = 1;
1263       break;
1264     case RPC_FC_C_CSTRING:
1265     case RPC_FC_C_WSTRING:
1266       has_conformant_string = 1;
1267       break;
1268
1269     /*
1270      * Propagate member attributes
1271      *  a struct should be at least as complex as its member
1272      */
1273     case RPC_FC_CVSTRUCT:
1274       has_conformant_string = 1;
1275       has_pointer = 1;
1276       break;
1277
1278     case RPC_FC_CPSTRUCT:
1279       has_conformant_array = 1;
1280       has_pointer = 1;
1281       break;
1282
1283     case RPC_FC_CSTRUCT:
1284       has_conformant_array = 1;
1285       break;
1286
1287     case RPC_FC_PSTRUCT:
1288       has_pointer = 1;
1289       break;
1290
1291     default:
1292       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1293               field->name, t->type);
1294       /* fallthru - treat it as complex */
1295
1296     /* as soon as we see one of these these members, it's bogus... */
1297     case RPC_FC_IP:
1298     case RPC_FC_ENCAPSULATED_UNION:
1299     case RPC_FC_NON_ENCAPSULATED_UNION:
1300     case RPC_FC_TRANSMIT_AS:
1301     case RPC_FC_REPRESENT_AS:
1302     case RPC_FC_PAD:
1303     case RPC_FC_EMBEDDED_COMPLEX:
1304     case RPC_FC_BOGUS_STRUCT:
1305       return RPC_FC_BOGUS_STRUCT;
1306     }
1307     field = NEXT_LINK(field);
1308   }
1309
1310   if( has_conformant_string && has_pointer )
1311     return RPC_FC_CVSTRUCT;
1312   if( has_conformant_array && has_pointer )
1313     return RPC_FC_CPSTRUCT;
1314   if( has_conformant_array )
1315     return RPC_FC_CSTRUCT;
1316   if( has_pointer )
1317     return RPC_FC_PSTRUCT;
1318   return RPC_FC_STRUCT;
1319 }
1320
1321 /***** constant repository *****/
1322
1323 struct rconst {
1324   char *name;
1325   var_t *var;
1326   struct rconst *next;
1327 };
1328
1329 struct rconst *const_hash[HASHMAX];
1330
1331 static var_t *reg_const(var_t *var)
1332 {
1333   struct rconst *nc;
1334   int hash;
1335   if (!var->name) {
1336     yyerror("registering constant without name\n");
1337     return var;
1338   }
1339   hash = hash_ident(var->name);
1340   nc = xmalloc(sizeof(struct rconst));
1341   nc->name = var->name;
1342   nc->var = var;
1343   nc->next = const_hash[hash];
1344   const_hash[hash] = nc;
1345   return var;
1346 }
1347
1348 static var_t *find_const(char *name, int f)
1349 {
1350   struct rconst *cur = const_hash[hash_ident(name)];
1351   while (cur && strcmp(cur->name, name))
1352     cur = cur->next;
1353   if (!cur) {
1354     if (f) yyerror("constant %s not found\n", name);
1355     return NULL;
1356   }
1357   return cur->var;
1358 }