git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_AUX_DIR(tools)
   7
   8 # We want these before the checks, so the checks can modify their values.
   9 test -z "$CFLAGS" && CFLAGS="-g -O2" AC_SUBST(CFLAGS)
  10 test -z "$LDFLAGS" && LDFLAGS=-g AC_SUBST(LDFLAGS)
  11 test -z "$LDLIBS" && LDLIBS=-lm AC_SUBST(LDLIBS)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_WITH(library,
  16 [  --with-library          build Wine as a library instead of an emulator],
  17 [AC_DEFINE(WINELIB) MAIN_TARGET="libwine.a"],[MAIN_TARGET="wine"])
  18 AC_SUBST(MAIN_TARGET)
  19
  20 AC_ARG_WITH(ipc,
  21 [  --with-ipc              use inter-process communication for DDE],
  22 [AC_DEFINE(CONFIG_IPC)])
  23
  24 AC_ARG_WITH(malloc-debug,
  25 [  --with-malloc-debug     enable malloc() debugging],
  26 [AC_DEFINE(MALLOC_DEBUGGING)])
  27
  28 dnl **** Check for some programs and libraries ****
  29
  30 AC_PROG_MAKE_SET
  31 AC_PROG_CC
  32 AC_PROG_CPP
  33 AC_PATH_XTRA
  34 AC_PROG_YACC
  35 AC_PROG_LEX
  36 AC_PROG_RANLIB
  37 AC_PROG_INSTALL
  38 dnl Check for -li386 for NetBSD
  39 AC_CHECK_LIB(i386,i386_set_ldt,LDLIBS="$LDLIBS -li386")
  40
  41 dnl **** Check for gcc strength-reduce bug ****
  42
  43 if test "x${GCC}" = "xyes"
  44 then
  45   CFLAGS="$CFLAGS -Wall"
  46   AC_C_CROSS
  47   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
  48                   AC_TRY_RUN([
  49 int main(void) {
  50   static int Array[3];
  51   unsigned int B = 3;
  52   int i;
  53   for(i=0; i<B; i++) Array[i] = i - 3;
  54   exit( Array[1] != -2 );
  55 }],
  56     ac_cv_c_gcc_strength_bug="no",
  57     ac_cv_c_gcc_strength_bug="yes",
  58     ac_cv_c_gcc_strength_bug="yes") )
  59   if test "$ac_cv_c_gcc_strength_bug" = "yes"
  60   then
  61     CFLAGS="$CFLAGS -fno-strength-reduce"
  62   fi
  63 fi
  64
  65 dnl **** Check for functions and header files ****
  66
  67 AC_CHECK_FUNCS(tcgetattr usleep)
  68 AC_CHECK_HEADERS(stdlib.h)
  69 AC_HEADER_STAT()
  70 AC_C_CONST()
  71 AC_TYPE_SIZE_T()
  72
  73 dnl **** Generate output files ****
  74
  75 MAKE_RULES=Make.rules
  76 AC_SUBST_FILE(MAKE_RULES)
  77
  78 AC_OUTPUT([
  79 Make.rules
  80 Makefile
  81 controls/Makefile
  82 debugger/Makefile
  83 debugger/readline/Makefile
  84 files/Makefile
  85 if1632/Makefile
  86 ipc/Makefile
  87 library/Makefile
  88 libtest/Makefile
  89 loader/Makefile
  90 memory/Makefile
  91 misc/Makefile
  92 miscemu/Makefile
  93 multimedia/Makefile
  94 objects/Makefile
  95 rc/Makefile
  96 resources/Makefile
  97 tools/Makefile
  98 win32/Makefile
  99 windows/Makefile ])
 100
 101 echo
 102 echo "Configure finished.  Do 'make depend; make' to compile Wine."
 103 echo
 104
 105 dnl Local Variables:
 106 dnl comment-start: "dnl "
 107 dnl comment-end: ""
 108 dnl comment-start-skip: "\\bdnl\\b\\s *"
 109 dnl compile-command: "autoconf"
 110 dnl End: