git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "proxy.h"
  41 #include "typelib.h"
  42
  43 #if defined(YYBYACC)
  44         /* Berkeley yacc (byacc) doesn't seem to know about these */
  45         /* Some *BSD supplied versions do define these though */
  46 # ifndef YYEMPTY
  47 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  48 # endif
  49 # ifndef YYLEX
  50 #  define YYLEX         yylex()
  51 # endif
  52
  53 #elif defined(YYBISON)
  54         /* Bison was used for original development */
  55         /* #define YYEMPTY -2 */
  56         /* #define YYLEX   yylex() */
  57
  58 #else
  59         /* No yacc we know yet */
  60 # if !defined(YYEMPTY) || !defined(YYLEX)
  61 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  62 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  63 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  64   /* #else we just take a chance that it works... */
  65 # endif
  66 #endif
  67
  68 static attr_t *make_attr(enum attr_type type);
  69 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  70 static attr_t *make_attrp(enum attr_type type, void *val);
  71 static expr_t *make_expr(enum expr_type type);
  72 static expr_t *make_exprl(enum expr_type type, long val);
  73 static expr_t *make_exprs(enum expr_type type, char *val);
  74 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  75 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  76 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  77 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  78 static type_t *make_type(unsigned char type, type_t *ref);
  79 static typeref_t *make_tref(char *name, type_t *ref);
  80 static typeref_t *uniq_tref(typeref_t *ref);
  81 static type_t *type_ref(typeref_t *ref);
  82 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  83 static ifref_t *make_ifref(type_t *iface);
  84 static var_t *make_var(char *name);
  85 static func_t *make_func(var_t *def, var_t *args);
  86 static class_t *make_class(char *name);
  87
  88 static type_t *reg_type(type_t *type, char *name, int t);
  89 static type_t *reg_types(type_t *type, var_t *names, int t);
  90 static type_t *find_type(char *name, int t);
  91 static type_t *find_type2(char *name, int t);
  92 static type_t *get_type(unsigned char type, char *name, int t);
  93 static type_t *get_typev(unsigned char type, var_t *name, int t);
  94 static int get_struct_type(var_t *fields);
  95
  96 static var_t *reg_const(var_t *var);
  97 static var_t *find_const(char *name, int f);
  98
  99 #define tsENUM   1
 100 #define tsSTRUCT 2
 101 #define tsUNION  3
 102
 103 static type_t std_bool = { "boolean" };
 104 static type_t std_int = { "int" };
 105 static type_t std_int64 = { "__int64" };
 106 static type_t std_uhyper = { "MIDL_uhyper" };
 107
 108 %}
 109 %union {
 110         attr_t *attr;
 111         expr_t *expr;
 112         type_t *type;
 113         typeref_t *tref;
 114         var_t *var;
 115         func_t *func;
 116         ifref_t *ifref;
 117         class_t *clas;
 118         char *str;
 119         UUID *uuid;
 120         unsigned int num;
 121 }
 122
 123 %token <str> aIDENTIFIER
 124 %token <str> aKNOWNTYPE
 125 %token <num> aNUM aHEXNUM
 126 %token <str> aSTRING
 127 %token <uuid> aUUID
 128 %token aEOF
 129 %token SHL SHR
 130 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
 131 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 132 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 133 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 134 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 135 %token tDEFAULT
 136 %token tDEFAULTVALUE
 137 %token tDISPINTERFACE
 138 %token tDLLNAME tDOUBLE tDUAL
 139 %token tENDPOINT
 140 %token tENTRY tENUM tERRORSTATUST
 141 %token tEXPLICITHANDLE tEXTERN
 142 %token tFLOAT
 143 %token tHANDLE
 144 %token tHANDLET
 145 %token tHELPCONTEXT tHELPFILE
 146 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 147 %token tHIDDEN
 148 %token tHYPER tID tIDEMPOTENT
 149 %token tIIDIS
 150 %token tIMPLICITHANDLE
 151 %token tIMPORT tIMPORTLIB
 152 %token tIN tINCLUDE tINLINE
 153 %token tINPUTSYNC
 154 %token tINT tINT64
 155 %token tINTERFACE
 156 %token tLENGTHIS tLIBRARY
 157 %token tLOCAL
 158 %token tLONG
 159 %token tMETHODS
 160 %token tMODULE
 161 %token tNONCREATABLE
 162 %token tOBJECT tODL tOLEAUTOMATION
 163 %token tOPTIONAL
 164 %token tOUT
 165 %token tPOINTERDEFAULT
 166 %token tPROPERTIES
 167 %token tPROPGET tPROPPUT tPROPPUTREF
 168 %token tPUBLIC
 169 %token tREADONLY tREF
 170 %token tRESTRICTED
 171 %token tRETVAL
 172 %token tSHORT
 173 %token tSIGNED
 174 %token tSIZEIS tSIZEOF
 175 %token tSOURCE
 176 %token tSTDCALL
 177 %token tSTRING tSTRUCT
 178 %token tSWITCH tSWITCHIS tSWITCHTYPE
 179 %token tTRANSMITAS
 180 %token tTYPEDEF
 181 %token tUNION
 182 %token tUNIQUE
 183 %token tUNSIGNED
 184 %token tUUID
 185 %token tV1ENUM
 186 %token tVARARG
 187 %token tVERSION
 188 %token tVOID
 189 %token tWCHAR tWIREMARSHAL
 190
 191 /* used in attr_t */
 192 %token tPOINTERTYPE
 193
 194 %type <attr> m_attributes attributes attrib_list attribute
 195 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 196 %type <expr> array array_list
 197 %type <type> inherit interface interfacehdr interfacedef interfacedec
 198 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 199 %type <type> module modulehdr moduledef
 200 %type <type> base_type int_std
 201 %type <type> enumdef structdef typedef uniondef
 202 %type <ifref> gbl_statements coclass_ints coclass_int
 203 %type <tref> type
 204 %type <var> m_args no_args args arg
 205 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 206 %type <var> m_ident t_ident ident p_ident pident pident_list
 207 %type <var> dispint_props
 208 %type <func> funcdef int_statements
 209 %type <func> dispint_meths
 210 %type <clas> coclass coclasshdr coclassdef
 211 %type <num> pointer_type version
 212 %type <str> libraryhdr
 213
 214 %left ','
 215 %right COND
 216 %left '|'
 217 %left '&'
 218 %left '-' '+'
 219 %left '*' '/'
 220 %left SHL SHR
 221 %right '~'
 222 %right CAST
 223 %right PPTR
 224 %right NEG
 225
 226 %%
 227
 228 input:   gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 229         ;
 230
 231 gbl_statements:                                 { $$ = NULL; }
 232         | gbl_statements interfacedec           { $$ = $1; }
 233         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 234         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 235         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 236         | gbl_statements librarydef             { $$ = $1; }
 237         | gbl_statements statement              { $$ = $1; }
 238         ;
 239
 240 imp_statements:                                 {}
 241         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 242         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 243         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 244         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 245         | imp_statements statement              {}
 246         ;
 247
 248 int_statements:                                 { $$ = NULL; }
 249         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 250         | int_statements statement              { $$ = $1; }
 251         ;
 252
 253 statement: ';'                                  {}
 254         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 255         | cppquote                              {}
 256         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 257         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 258         | import                                {}
 259         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 260         | typedef ';'                           {}
 261         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 262         ;
 263
 264 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 265         ;
 266 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 267                                                   if (!do_import($2)) yychar = aEOF; }
 268         ;
 269 import:   import_start imp_statements aEOF      {}
 270         ;
 271
 272 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 273         ;
 274 library_start: attributes libraryhdr '{'        { start_typelib($2, $1); }
 275         ;
 276 librarydef: library_start imp_statements '}'    { end_typelib(); }
 277         ;
 278
 279 m_args:                                         { $$ = NULL; }
 280         | args
 281         ;
 282
 283 no_args:  tVOID                                 { $$ = NULL; }
 284         ;
 285
 286 args:     arg
 287         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 288         | no_args
 289         ;
 290
 291 /* split into two rules to get bison to resolve a tVOID conflict */
 292 arg:      attributes type pident array          { $$ = $3;
 293                                                   set_type($$, $2, $4);
 294                                                   $$->attrs = $1;
 295                                                 }
 296         | type pident array                     { $$ = $2;
 297                                                   set_type($$, $1, $3);
 298                                                 }
 299         | attributes type pident '(' m_args ')' { $$ = $3;
 300                                                   $$->ptr_level--;
 301                                                   set_type($$, $2, NULL);
 302                                                   $$->attrs = $1;
 303                                                   $$->args = $5;
 304                                                 }
 305         | type pident '(' m_args ')'            { $$ = $2;
 306                                                   $$->ptr_level--;
 307                                                   set_type($$, $1, NULL);
 308                                                   $$->args = $4;
 309                                                 }
 310         ;
 311
 312 array:                                          { $$ = NULL; }
 313         | '[' array_list ']'                    { $$ = $2; }
 314         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 315         ;
 316
 317 array_list: m_expr /* size of first dimension is optional */
 318         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 319         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 320         ;
 321
 322 m_attributes:                                   { $$ = NULL; }
 323         | attributes
 324         ;
 325
 326 attributes:
 327           '[' attrib_list ']'                   { $$ = $2; }
 328         ;
 329
 330 attrib_list: attribute
 331         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 332         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 333         ;
 334
 335 attribute:
 336           tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 337         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 338         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 339         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 340         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 341         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 342         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 343         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 344         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 345         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 346         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 347         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 348         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 349         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 350         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 351         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 352         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 353         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 354         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 355         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 356         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 357         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 358         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 359         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 360         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 361         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 362         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 363         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 364         | tIN                                   { $$ = make_attr(ATTR_IN); }
 365         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 366         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 367         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 368         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 369         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 370         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 371         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 372         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 373         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 374         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 375         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 376         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 377         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 378         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 379         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 380         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 381         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 382         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 383         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 384         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 385         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 386         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 387         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 388         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 389         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 390         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 391         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 392         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 393         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 394         ;
 395
 396 callconv:
 397         | tSTDCALL
 398         ;
 399
 400 cases:                                          { $$ = NULL; }
 401         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 402                                                   else { $$ = $1; }
 403                                                 }
 404         ;
 405
 406 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 407                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 408                                                   LINK(a, $$->attrs); $$->attrs = a;
 409                                                 }
 410         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 411                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 412                                                   LINK(a, $$->attrs); $$->attrs = a;
 413                                                 }
 414         ;
 415
 416 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 417                                                   set_type($$, $2, NULL);
 418                                                   $$->eval = $5;
 419                                                   $$->lval = $5->cval;
 420                                                 }
 421         ;
 422
 423 enums:                                          { $$ = NULL; }
 424         | enum_list ','                         { $$ = $1; }
 425         | enum_list
 426         ;
 427
 428 enum_list: enum
 429         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 430                                                   if ($1 && !$3->eval)
 431                                                     $3->lval = $1->lval + 1;
 432                                                 }
 433         ;
 434
 435 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 436                                                   $$->eval = $3;
 437                                                   $$->lval = $3->cval;
 438                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 439                                                 }
 440         | ident                                 { $$ = reg_const($1);
 441                                                   $$->lval = 0; /* default for first enum entry */
 442                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 443                                                 }
 444         ;
 445
 446 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 447                                                   $$->fields = $4;
 448                                                   $$->defined = TRUE;
 449                                                   if(in_typelib)
 450                                                       add_enum($$);
 451                                                 }
 452         ;
 453
 454 m_exprs:  m_expr
 455         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 456         ;
 457
 458 /*
 459 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 460         | expr_list
 461         ;
 462
 463 expr_list: expr
 464         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 465         ;
 466 */
 467
 468 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 469         | expr
 470         ;
 471
 472 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 473         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 474         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 475         | expr '?' expr ':' expr %prec COND     { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 476         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 477         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 478         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 479         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 480         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 481         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 482         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 483         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 484         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 485         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 486         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 487         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 488         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 489         | '(' expr ')'                          { $$ = $2; }
 490         ;
 491
 492 expr_list_const: expr_const
 493         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 494         ;
 495
 496 expr_const: expr                                { $$ = $1;
 497                                                   if (!$$->is_const)
 498                                                       yyerror("expression is not constant\n");
 499                                                 }
 500         ;
 501
 502 externdef: tEXTERN tCONST type ident            { $$ = $4;
 503                                                   set_type($$, $3, NULL);
 504                                                 }
 505         ;
 506
 507 fields:                                         { $$ = NULL; }
 508         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 509                                                   else { $$ = $1; }
 510                                                 }
 511         ;
 512
 513 field:    s_field ';'                           { $$ = $1; }
 514         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 515         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 516         | ';'                                   { $$ = NULL; }
 517         ;
 518
 519 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 520         ;
 521
 522 funcdef:
 523           m_attributes type callconv pident
 524           '(' m_args ')'                        { set_type($4, $2, NULL);
 525                                                   $4->attrs = $1;
 526                                                   $$ = make_func($4, $6);
 527                                                   if (is_attr($4->attrs, ATTR_IN)) {
 528                                                     yyerror("Inapplicable attribute");
 529                                                   }
 530                                                 }
 531         ;
 532
 533 m_ident:                                        { $$ = NULL; }
 534         | ident
 535         ;
 536
 537 t_ident:                                        { $$ = NULL; }
 538         | aIDENTIFIER                           { $$ = make_var($1); }
 539         | aKNOWNTYPE                            { $$ = make_var($1); }
 540         ;
 541
 542 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 543 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 544         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 545         | tID                                   { $$ = make_var($<str>1); }
 546         | tRETVAL                               { $$ = make_var($<str>1); }
 547         | tVERSION                              { $$ = make_var($<str>1); }
 548         ;
 549
 550 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 551         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 552         | int_std
 553         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 554         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 555                                                   switch ($$->type) {
 556                                                   case RPC_FC_CHAR:  $$->type = RPC_FC_BYTE; $$->sign = 0; break;
 557                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 558                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 559                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 560                                                   case RPC_FC_HYPER:
 561                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 562                                                     break;
 563                                                   default: break;
 564                                                   }
 565                                                 }
 566         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 567         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 568         | tBOOLEAN                              { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
 569         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 570         | tHANDLET                              { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
 571         ;
 572
 573 m_int:
 574         | tINT
 575         ;
 576
 577 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 578         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 579         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 580         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 581         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 582         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 583         ;
 584
 585 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 586         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 587         ;
 588
 589 coclasshdr: attributes coclass                  { $$ = $2;
 590                                                   $$->attrs = $1;
 591                                                   if (!parse_only && do_header) write_coclass($$);
 592                                                 }
 593         ;
 594
 595 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 596                                                   $$->ifaces = $3;
 597                                                 }
 598         ;
 599
 600 coclass_ints:                                   { $$ = NULL; }
 601         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 602         ;
 603
 604 coclass_int:
 605           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 606         ;
 607
 608 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 609         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 610         ;
 611
 612 dispinterfacehdr: attributes dispinterface      { $$ = $2;
 613                                                   if ($$->defined) yyerror("multiple definition error\n");
 614                                                   $$->attrs = $1;
 615                                                   $$->attrs = make_attr(ATTR_DISPINTERFACE);
 616                                                   LINK($$->attrs, $1);
 617                                                   $$->ref = find_type("IDispatch", 0);
 618                                                   if (!$$->ref) yyerror("IDispatch is undefined\n");
 619                                                   $$->defined = TRUE;
 620                                                   if (!parse_only && do_header) write_forward($$);
 621                                                 }
 622         ;
 623
 624 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 625         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 626         ;
 627
 628 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 629         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 630         ;
 631
 632 dispinterfacedef: dispinterfacehdr '{'
 633           dispint_props
 634           dispint_meths
 635           '}'                                   { $$ = $1;
 636                                                   $$->fields = $3;
 637                                                   $$->funcs = $4;
 638                                                   if (!parse_only && do_header) write_dispinterface($$);
 639                                                 }
 640 /* FIXME: not sure how to handle this yet
 641         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 642                                                   if (!parse_only && do_header) write_interface($$);
 643                                                 }
 644 */
 645         ;
 646
 647 inherit:                                        { $$ = NULL; }
 648         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 649         ;
 650
 651 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 652         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 653         ;
 654
 655 interfacehdr: attributes interface              { $$ = $2;
 656                                                   if ($$->defined) yyerror("multiple definition error\n");
 657                                                   $$->attrs = $1;
 658                                                   $$->defined = TRUE;
 659                                                   if (!parse_only && do_header) write_forward($$);
 660                                                 }
 661         ;
 662
 663 interfacedef: interfacehdr inherit
 664           '{' int_statements '}'                { $$ = $1;
 665                                                   $$->ref = $2;
 666                                                   $$->funcs = $4;
 667                                                   if (!parse_only && do_header) write_interface($$);
 668                                                 }
 669 /* MIDL is able to import the definition of a base class from inside the
 670  * definition of a derived class, I'll try to support it with this rule */
 671         | interfacehdr ':' aIDENTIFIER
 672           '{' import int_statements '}'         { $$ = $1;
 673                                                   $$->ref = find_type2($3, 0);
 674                                                   if (!$$->ref) yyerror("base class %s not found in import\n", $3);
 675                                                   $$->funcs = $6;
 676                                                   if (!parse_only && do_header) write_interface($$);
 677                                                 }
 678         | dispinterfacedef                      { $$ = $1; }
 679         ;
 680
 681 interfacedec:
 682           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 683         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 684         ;
 685
 686 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 687         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 688         ;
 689
 690 modulehdr: attributes module                    { $$ = $2;
 691                                                   $$->attrs = $1;
 692                                                 }
 693         ;
 694
 695 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 696                                                   $$->funcs = $3;
 697                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 698                                                 }
 699         ;
 700
 701 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 702         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 703         ;
 704
 705 pident:   ident
 706         | p_ident
 707         | '(' pident ')'                        { $$ = $2; }
 708         ;
 709
 710 pident_list:
 711           pident
 712         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 713         ;
 714
 715 pointer_type:
 716           tREF                                  { $$ = RPC_FC_RP; }
 717         | tUNIQUE                               { $$ = RPC_FC_UP; }
 718         ;
 719
 720 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 721                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 722                                                   $$->type = get_struct_type( $4 );
 723                                                   $$->fields = $4;
 724                                                   $$->defined = TRUE;
 725                                                   if(in_typelib)
 726                                                       add_struct($$);
 727                                                 }
 728         ;
 729
 730 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 731         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 732         | base_type                             { $$ = make_tref(NULL, $1); }
 733         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 734         | enumdef                               { $$ = make_tref(NULL, $1); }
 735         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 736         | structdef                             { $$ = make_tref(NULL, $1); }
 737         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 738         | uniondef                              { $$ = make_tref(NULL, $1); }
 739         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 740         ;
 741
 742 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 743                                                   $4->tname = tref->name;
 744                                                   tref->name = NULL;
 745                                                   $$ = type_ref(tref);
 746                                                   $$->attrs = $2;
 747                                                   if (!parse_only && do_header) write_typedef($$, $4);
 748                                                   if (in_typelib && $$->attrs)
 749                                                       add_typedef($$, $4);
 750                                                   reg_types($$, $4, 0);
 751                                                 }
 752         ;
 753
 754 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 755                                                   $$->fields = $4;
 756                                                   $$->defined = TRUE;
 757                                                 }
 758         | tUNION t_ident
 759           tSWITCH '(' s_field ')'
 760           m_ident '{' cases '}'                 { var_t *u = $7;
 761                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 762                                                   if (!u) u = make_var("tagged_union");
 763                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 764                                                   u->type->fields = $9;
 765                                                   u->type->defined = TRUE;
 766                                                   LINK(u, $5); $$->fields = u;
 767                                                   $$->defined = TRUE;
 768                                                 }
 769         ;
 770
 771 version:
 772           aNUM                                  { $$ = MAKELONG($1, 0); }
 773         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 774         ;
 775
 776 %%
 777
 778 static attr_t *make_attr(enum attr_type type)
 779 {
 780   attr_t *a = xmalloc(sizeof(attr_t));
 781   a->type = type;
 782   a->u.ival = 0;
 783   INIT_LINK(a);
 784   return a;
 785 }
 786
 787 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 788 {
 789   attr_t *a = xmalloc(sizeof(attr_t));
 790   a->type = type;
 791   a->u.ival = val;
 792   INIT_LINK(a);
 793   return a;
 794 }
 795
 796 static attr_t *make_attrp(enum attr_type type, void *val)
 797 {
 798   attr_t *a = xmalloc(sizeof(attr_t));
 799   a->type = type;
 800   a->u.pval = val;
 801   INIT_LINK(a);
 802   return a;
 803 }
 804
 805 static expr_t *make_expr(enum expr_type type)
 806 {
 807   expr_t *e = xmalloc(sizeof(expr_t));
 808   e->type = type;
 809   e->ref = NULL;
 810   e->u.lval = 0;
 811   e->is_const = FALSE;
 812   INIT_LINK(e);
 813   return e;
 814 }
 815
 816 static expr_t *make_exprl(enum expr_type type, long val)
 817 {
 818   expr_t *e = xmalloc(sizeof(expr_t));
 819   e->type = type;
 820   e->ref = NULL;
 821   e->u.lval = val;
 822   e->is_const = FALSE;
 823   INIT_LINK(e);
 824   /* check for numeric constant */
 825   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 826     e->is_const = TRUE;
 827     e->cval = val;
 828   }
 829   return e;
 830 }
 831
 832 static expr_t *make_exprs(enum expr_type type, char *val)
 833 {
 834   expr_t *e;
 835   e = xmalloc(sizeof(expr_t));
 836   e->type = type;
 837   e->ref = NULL;
 838   e->u.sval = val;
 839   e->is_const = FALSE;
 840   INIT_LINK(e);
 841   /* check for predefined constants */
 842   if (type == EXPR_IDENTIFIER) {
 843     var_t *c = find_const(val, 0);
 844     if (c) {
 845       e->u.sval = c->name;
 846       free(val);
 847       e->is_const = TRUE;
 848       e->cval = c->lval;
 849     }
 850   }
 851   return e;
 852 }
 853
 854 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 855 {
 856   expr_t *e;
 857   e = xmalloc(sizeof(expr_t));
 858   e->type = type;
 859   e->ref = expr;
 860   e->u.tref = tref;
 861   e->is_const = FALSE;
 862   INIT_LINK(e);
 863   /* check for cast of constant expression */
 864   if (type == EXPR_CAST && expr->is_const) {
 865     e->is_const = TRUE;
 866     e->cval = expr->cval;
 867   }
 868   return e;
 869 }
 870
 871 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 872 {
 873   expr_t *e;
 874   e = xmalloc(sizeof(expr_t));
 875   e->type = type;
 876   e->ref = expr;
 877   e->u.lval = 0;
 878   e->is_const = FALSE;
 879   INIT_LINK(e);
 880   /* check for compile-time optimization */
 881   if (expr->is_const) {
 882     e->is_const = TRUE;
 883     switch (type) {
 884     case EXPR_NEG:
 885       e->cval = -expr->cval;
 886       break;
 887     case EXPR_NOT:
 888       e->cval = ~expr->cval;
 889       break;
 890     default:
 891       e->is_const = FALSE;
 892       break;
 893     }
 894   }
 895   return e;
 896 }
 897
 898 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 899 {
 900   expr_t *e;
 901   e = xmalloc(sizeof(expr_t));
 902   e->type = type;
 903   e->ref = expr1;
 904   e->u.ext = expr2;
 905   e->is_const = FALSE;
 906   INIT_LINK(e);
 907   /* check for compile-time optimization */
 908   if (expr1->is_const && expr2->is_const) {
 909     e->is_const = TRUE;
 910     switch (type) {
 911     case EXPR_ADD:
 912       e->cval = expr1->cval + expr2->cval;
 913       break;
 914     case EXPR_SUB:
 915       e->cval = expr1->cval - expr2->cval;
 916       break;
 917     case EXPR_MUL:
 918       e->cval = expr1->cval * expr2->cval;
 919       break;
 920     case EXPR_DIV:
 921       e->cval = expr1->cval / expr2->cval;
 922       break;
 923     case EXPR_OR:
 924       e->cval = expr1->cval | expr2->cval;
 925       break;
 926     case EXPR_AND:
 927       e->cval = expr1->cval & expr2->cval;
 928       break;
 929     case EXPR_SHL:
 930       e->cval = expr1->cval << expr2->cval;
 931       break;
 932     case EXPR_SHR:
 933       e->cval = expr1->cval >> expr2->cval;
 934       break;
 935     default:
 936       e->is_const = FALSE;
 937       break;
 938     }
 939   }
 940   return e;
 941 }
 942
 943 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
 944 {
 945   expr_t *e;
 946   e = xmalloc(sizeof(expr_t));
 947   e->type = type;
 948   e->ref = expr1;
 949   e->u.ext = expr2;
 950   e->ext2 = expr3;
 951   e->is_const = FALSE;
 952   INIT_LINK(e);
 953   /* check for compile-time optimization */
 954   if (expr1->is_const && expr2->is_const && expr3->is_const) {
 955     e->is_const = TRUE;
 956     switch (type) {
 957     case EXPR_COND:
 958       e->cval = expr1->cval ? expr2->cval : expr3->cval;
 959       break;
 960     default:
 961       e->is_const = FALSE;
 962       break;
 963     }
 964   }
 965   return e;
 966 }
 967
 968 static type_t *make_type(unsigned char type, type_t *ref)
 969 {
 970   type_t *t = xmalloc(sizeof(type_t));
 971   t->name = NULL;
 972   t->type = type;
 973   t->ref = ref;
 974   t->rname = NULL;
 975   t->attrs = NULL;
 976   t->funcs = NULL;
 977   t->fields = NULL;
 978   t->ignore = parse_only;
 979   t->is_const = FALSE;
 980   t->sign = 0;
 981   t->defined = FALSE;
 982   t->written = FALSE;
 983   t->typelib_idx = -1;
 984   INIT_LINK(t);
 985   return t;
 986 }
 987
 988 static typeref_t *make_tref(char *name, type_t *ref)
 989 {
 990   typeref_t *t = xmalloc(sizeof(typeref_t));
 991   t->name = name;
 992   t->ref = ref;
 993   t->uniq = ref ? 0 : 1;
 994   return t;
 995 }
 996
 997 static typeref_t *uniq_tref(typeref_t *ref)
 998 {
 999   typeref_t *t = ref;
1000   type_t *tp;
1001   if (t->uniq) return t;
1002   tp = make_type(0, t->ref);
1003   tp->name = t->name;
1004   t->name = NULL;
1005   t->ref = tp;
1006   t->uniq = 1;
1007   return t;
1008 }
1009
1010 static type_t *type_ref(typeref_t *ref)
1011 {
1012   type_t *t = ref->ref;
1013   if (ref->name) free(ref->name);
1014   free(ref);
1015   return t;
1016 }
1017
1018 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1019 {
1020   v->type = ref->ref;
1021   v->tname = ref->name;
1022   ref->name = NULL;
1023   free(ref);
1024   v->array = arr;
1025 }
1026
1027 static ifref_t *make_ifref(type_t *iface)
1028 {
1029   ifref_t *l = xmalloc(sizeof(ifref_t));
1030   l->iface = iface;
1031   l->attrs = NULL;
1032   INIT_LINK(l);
1033   return l;
1034 }
1035
1036 static var_t *make_var(char *name)
1037 {
1038   var_t *v = xmalloc(sizeof(var_t));
1039   v->name = name;
1040   v->ptr_level = 0;
1041   v->type = NULL;
1042   v->tname = NULL;
1043   v->attrs = NULL;
1044   v->array = NULL;
1045   v->eval = NULL;
1046   v->lval = 0;
1047   INIT_LINK(v);
1048   return v;
1049 }
1050
1051 static func_t *make_func(var_t *def, var_t *args)
1052 {
1053   func_t *f = xmalloc(sizeof(func_t));
1054   f->def = def;
1055   f->args = args;
1056   f->ignore = parse_only;
1057   f->idx = -1;
1058   INIT_LINK(f);
1059   return f;
1060 }
1061
1062 static class_t *make_class(char *name)
1063 {
1064   class_t *c = xmalloc(sizeof(class_t));
1065   c->name = name;
1066   c->attrs = NULL;
1067   c->ifaces = NULL;
1068   INIT_LINK(c);
1069   return c;
1070 }
1071
1072 #define HASHMAX 64
1073
1074 static int hash_ident(const char *name)
1075 {
1076   const char *p = name;
1077   int sum = 0;
1078   /* a simple sum hash is probably good enough */
1079   while (*p) {
1080     sum += *p;
1081     p++;
1082   }
1083   return sum & (HASHMAX-1);
1084 }
1085
1086 /***** type repository *****/
1087
1088 struct rtype {
1089   char *name;
1090   type_t *type;
1091   int t;
1092   struct rtype *next;
1093 };
1094
1095 struct rtype *type_hash[HASHMAX];
1096
1097 static type_t *reg_type(type_t *type, char *name, int t)
1098 {
1099   struct rtype *nt;
1100   int hash;
1101   if (!name) {
1102     yyerror("registering named type without name\n");
1103     return type;
1104   }
1105   hash = hash_ident(name);
1106   nt = xmalloc(sizeof(struct rtype));
1107   nt->name = name;
1108   nt->type = type;
1109   nt->t = t;
1110   nt->next = type_hash[hash];
1111   type_hash[hash] = nt;
1112   return type;
1113 }
1114
1115 /* determine pointer type from attrs */
1116 static unsigned char get_pointer_type( type_t *type )
1117 {
1118   int t;
1119   if (is_attr( type->attrs, ATTR_STRING ))
1120   {
1121     type_t *t = type;
1122     while( t->type == 0 && t->ref )
1123       t = t->ref;
1124     switch( t->type )
1125     {
1126     case RPC_FC_CHAR:
1127       return RPC_FC_C_CSTRING;
1128     case RPC_FC_WCHAR:
1129       return RPC_FC_C_WSTRING;
1130     }
1131   }
1132   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1133   if (t) return t;
1134   return RPC_FC_FP;
1135 }
1136
1137 static type_t *reg_types(type_t *type, var_t *names, int t)
1138 {
1139   type_t *ptr = type;
1140   int ptrc = 0;
1141
1142   while (names) {
1143     var_t *next = NEXT_LINK(names);
1144     if (names->name) {
1145       type_t *cur = ptr;
1146       int cptr = names->ptr_level;
1147       if (cptr > ptrc) {
1148         while (cptr > ptrc) {
1149           int t = get_pointer_type( cur );
1150           cur = ptr = make_type(t, cur);
1151           ptrc++;
1152         }
1153       } else {
1154         while (cptr < ptrc) {
1155           cur = cur->ref;
1156           cptr++;
1157         }
1158       }
1159       reg_type(cur, names->name, t);
1160     }
1161     free(names);
1162     names = next;
1163   }
1164   return type;
1165 }
1166
1167 static type_t *find_type(char *name, int t)
1168 {
1169   struct rtype *cur = type_hash[hash_ident(name)];
1170   while (cur && (cur->t != t || strcmp(cur->name, name)))
1171     cur = cur->next;
1172   if (!cur) {
1173     yyerror("type %s not found\n", name);
1174     return NULL;
1175   }
1176   return cur->type;
1177 }
1178
1179 static type_t *find_type2(char *name, int t)
1180 {
1181   type_t *tp = find_type(name, t);
1182   free(name);
1183   return tp;
1184 }
1185
1186 int is_type(const char *name)
1187 {
1188   struct rtype *cur = type_hash[hash_ident(name)];
1189   while (cur && (cur->t || strcmp(cur->name, name)))
1190     cur = cur->next;
1191   if (cur) return TRUE;
1192   return FALSE;
1193 }
1194
1195 static type_t *get_type(unsigned char type, char *name, int t)
1196 {
1197   struct rtype *cur = NULL;
1198   type_t *tp;
1199   if (name) {
1200     cur = type_hash[hash_ident(name)];
1201     while (cur && (cur->t != t || strcmp(cur->name, name)))
1202       cur = cur->next;
1203   }
1204   if (cur) {
1205     free(name);
1206     return cur->type;
1207   }
1208   tp = make_type(type, NULL);
1209   tp->name = name;
1210   if (!name) return tp;
1211   return reg_type(tp, name, t);
1212 }
1213
1214 static type_t *get_typev(unsigned char type, var_t *name, int t)
1215 {
1216   char *sname = NULL;
1217   if (name) {
1218     sname = name->name;
1219     free(name);
1220   }
1221   return get_type(type, sname, t);
1222 }
1223
1224 static int get_struct_type(var_t *field)
1225 {
1226   int has_pointer = 0;
1227   int has_conformant_array = 0;
1228   int has_conformant_string = 0;
1229
1230   while (field)
1231   {
1232     type_t *t = field->type;
1233
1234     /* get the base type */
1235     while( (t->type == 0) && t->ref )
1236       t = t->ref;
1237
1238     switch (t->type)
1239     {
1240     /*
1241      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1242      *  Simple types don't effect the type of struct.
1243      *  A struct containing a simple struct is still a simple struct.
1244      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1245      */
1246     case 0: /* void pointer */
1247     case RPC_FC_BYTE:
1248     case RPC_FC_CHAR:
1249     case RPC_FC_SMALL:
1250     case RPC_FC_USMALL:
1251     case RPC_FC_WCHAR:
1252     case RPC_FC_SHORT:
1253     case RPC_FC_USHORT:
1254     case RPC_FC_LONG:
1255     case RPC_FC_ULONG:
1256     case RPC_FC_INT3264:
1257     case RPC_FC_UINT3264:
1258     case RPC_FC_HYPER:
1259     case RPC_FC_FLOAT:
1260     case RPC_FC_DOUBLE:
1261     case RPC_FC_STRUCT:
1262     case RPC_FC_ENUM16:
1263     case RPC_FC_ENUM32:
1264       break;
1265
1266     case RPC_FC_UP:
1267     case RPC_FC_FP:
1268       has_pointer = 1;
1269       break;
1270     case RPC_FC_CARRAY:
1271       has_conformant_array = 1;
1272       break;
1273     case RPC_FC_C_CSTRING:
1274     case RPC_FC_C_WSTRING:
1275       has_conformant_string = 1;
1276       break;
1277
1278     /*
1279      * Propagate member attributes
1280      *  a struct should be at least as complex as its member
1281      */
1282     case RPC_FC_CVSTRUCT:
1283       has_conformant_string = 1;
1284       has_pointer = 1;
1285       break;
1286
1287     case RPC_FC_CPSTRUCT:
1288       has_conformant_array = 1;
1289       has_pointer = 1;
1290       break;
1291
1292     case RPC_FC_CSTRUCT:
1293       has_conformant_array = 1;
1294       break;
1295
1296     case RPC_FC_PSTRUCT:
1297       has_pointer = 1;
1298       break;
1299
1300     default:
1301       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1302               field->name, t->type);
1303       /* fallthru - treat it as complex */
1304
1305     /* as soon as we see one of these these members, it's bogus... */
1306     case RPC_FC_IP:
1307     case RPC_FC_ENCAPSULATED_UNION:
1308     case RPC_FC_NON_ENCAPSULATED_UNION:
1309     case RPC_FC_TRANSMIT_AS:
1310     case RPC_FC_REPRESENT_AS:
1311     case RPC_FC_PAD:
1312     case RPC_FC_EMBEDDED_COMPLEX:
1313     case RPC_FC_BOGUS_STRUCT:
1314       return RPC_FC_BOGUS_STRUCT;
1315     }
1316     field = NEXT_LINK(field);
1317   }
1318
1319   if( has_conformant_string && has_pointer )
1320     return RPC_FC_CVSTRUCT;
1321   if( has_conformant_array && has_pointer )
1322     return RPC_FC_CPSTRUCT;
1323   if( has_conformant_array )
1324     return RPC_FC_CSTRUCT;
1325   if( has_pointer )
1326     return RPC_FC_PSTRUCT;
1327   return RPC_FC_STRUCT;
1328 }
1329
1330 /***** constant repository *****/
1331
1332 struct rconst {
1333   char *name;
1334   var_t *var;
1335   struct rconst *next;
1336 };
1337
1338 struct rconst *const_hash[HASHMAX];
1339
1340 static var_t *reg_const(var_t *var)
1341 {
1342   struct rconst *nc;
1343   int hash;
1344   if (!var->name) {
1345     yyerror("registering constant without name\n");
1346     return var;
1347   }
1348   hash = hash_ident(var->name);
1349   nc = xmalloc(sizeof(struct rconst));
1350   nc->name = var->name;
1351   nc->var = var;
1352   nc->next = const_hash[hash];
1353   const_hash[hash] = nc;
1354   return var;
1355 }
1356
1357 static var_t *find_const(char *name, int f)
1358 {
1359   struct rconst *cur = const_hash[hash_ident(name)];
1360   while (cur && strcmp(cur->name, name))
1361     cur = cur->next;
1362   if (!cur) {
1363     if (f) yyerror("constant %s not found\n", name);
1364     return NULL;
1365   }
1366   return cur->var;
1367 }