git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  20 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  21
  22 AC_CANONICAL_HOST
  23 case $host in
  24   x86_64*linux*)
  25     if test "x$enable_win64" != "xyes"
  26     then
  27       test -n "$CC" || CC="gcc -m32"
  28       test -n "$LD" || LD="ld -m elf_i386"
  29       test -n "$AS" || AS="as --32"
  30       host_cpu="i386"
  31     fi
  32     ;;
  33 esac
  34
  35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  36 case $host_cpu in
  37   *i[[3456789]]86*)
  38     if test "x$enable_win16" != "xno"
  39     then
  40       enable_win16="yes"
  41     fi
  42     ;;
  43 esac
  44
  45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  47 if test "x$enable_win16" != "xyes"
  48 then
  49   WIN16_FILES=""
  50   WIN16_INSTALL=""
  51 fi
  52
  53 dnl **** Check for some programs ****
  54
  55 AC_PROG_MAKE_SET
  56 AC_PROG_CC
  57 AC_PROG_CXX
  58 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  59 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  60
  61 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  62   [if test -z "$with_wine_tools"; then
  63      if test "$cross_compiling" = "yes"; then
  64        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  65      else
  66        wine_cv_toolsdir="\$(TOPOBJDIR)"
  67      fi
  68    elif test -d "$with_wine_tools/tools/winebuild"; then
  69      case $with_wine_tools in
  70        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  71        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  72      esac
  73    else
  74      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  75    fi])
  76 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  77
  78 AC_PATH_XTRA
  79 AC_PROG_LEX
  80
  81 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  82 dnl **** without one present.
  83 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  84 if test "$XLEX" = "none"
  85 then
  86   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  87 fi
  88
  89 dnl Check for bison
  90 AC_CHECK_PROGS(BISON,bison,none)
  91 if test "$BISON" = "none"
  92 then
  93   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  94 fi
  95
  96 AC_CHECK_TOOLS(AS,[gas as],as)
  97 AC_CHECK_TOOL(LD,ld,ld)
  98 AC_CHECK_TOOL(AR,ar,ar)
  99 AC_PROG_RANLIB
 100 AC_CHECK_TOOL(STRIP,strip,strip)
 101 AC_CHECK_TOOL(WINDRES,windres,false)
 102 AC_PROG_LN_S
 103 WINE_PROG_LN
 104 AC_PROG_EGREP
 105 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 106 AC_PROG_INSTALL
 107 dnl Prepend src dir to install path dir if it's a relative path
 108 case "$INSTALL" in
 109   [[\\/$]]* | ?:[[\\/]]* ) ;;
 110   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 111 esac
 112
 113 dnl Check for lint
 114 AC_CHECK_PROGS(LINT, lclint lint)
 115 if test "$LINT" = "lint"
 116 then
 117   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 118   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 119 fi
 120 AC_SUBST(LINT)
 121 AC_SUBST(LINTFLAGS)
 122
 123 dnl Check for various programs
 124 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 125 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 126
 127 case $host_cpu in
 128   *i[[3456789]]86*)
 129     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 130     ;;
 131 esac
 132
 133 dnl **** Check for some libraries ****
 134
 135 dnl Check for -li386 for NetBSD and OpenBSD
 136 AC_CHECK_LIB(i386,i386_set_ldt)
 137 dnl Check for -lossaudio for NetBSD
 138 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 139 dnl Check for -lnsl for Solaris
 140 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 141 dnl Check for -lsocket for Solaris
 142 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 143 dnl Check for -lresolv for Solaris
 144 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpoll for Mac OS X/Darwin
 148 AC_CHECK_LIB(poll,poll)
 149 dnl Check for -lpthread
 150 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 151
 152 AC_SUBST(XLIB,"")
 153 AC_SUBST(XFILES,"")
 154 AC_SUBST(OPENGLFILES,"")
 155 AC_SUBST(GLU32FILES,"")
 156 AC_SUBST(OPENGL_LIBS,"")
 157
 158 dnl **** Check for header files ****
 159
 160 AC_CHECK_HEADERS(\
 161         AudioUnit/AudioUnit.h \
 162         CoreAudio/CoreAudio.h \
 163         IOKit/IOKitLib.h \
 164         alsa/asoundlib.h \
 165         arpa/inet.h \
 166         arpa/nameser.h \
 167         asm/types.h \
 168         capi20.h \
 169         cups/cups.h \
 170         curses.h \
 171         direct.h \
 172         dlfcn.h \
 173         elf.h \
 174         float.h \
 175         fontconfig/fontconfig.h \
 176         getopt.h \
 177         gif_lib.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/machine.h \
 199         machine/cpu.h \
 200         machine/limits.h \
 201         machine/soundcard.h \
 202         mntent.h \
 203         ncurses.h \
 204         netdb.h \
 205         netinet/in.h \
 206         netinet/in_systm.h \
 207         netinet/tcp.h \
 208         netinet/tcp_fsm.h \
 209         openssl/err.h \
 210         openssl/ssl.h \
 211         poll.h \
 212         process.h \
 213         pthread.h \
 214         pthread_np.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/sockio.h \
 252         sys/soundcard.h \
 253         sys/statvfs.h \
 254         sys/strtio.h \
 255         sys/syscall.h \
 256         sys/sysctl.h \
 257         sys/time.h \
 258         sys/times.h \
 259         sys/uio.h \
 260         sys/un.h \
 261         sys/vm86.h \
 262         sys/wait.h \
 263         syscall.h \
 264         termios.h \
 265         unicode/ubidi.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285
 286 AC_CHECK_HEADERS([linux/ipx.h],,,
 287     [#include <sys/types.h>
 288      #ifdef HAVE_ASM_TYPES_H
 289      # include <asm/types.h>
 290      #endif
 291      #if HAVE_SYS_SOCKET_H
 292      # include <sys/socket.h>
 293      #endif])
 294
 295 AC_CHECK_HEADERS([resolv.h],,,
 296     [#include <sys/types.h>
 297      #if HAVE_SYS_SOCKET_H
 298      # include <sys/socket.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #if HAVE_ARPA_NAMESER_H
 304      # include <arpa/nameser.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 308
 309 AC_CHECK_HEADERS([linux/videodev.h],,,
 310 [#ifdef HAVE_SYS_TIME_H
 311 #include <sys/time.h>
 312 #endif
 313 #include <sys/types.h>
 314 #ifdef HAVE_ASM_TYPES_H
 315 #include <asm/types.h>
 316 #endif])
 317
 318 dnl Check for broken kernel header that doesn't define __user
 319 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 320
 321 dnl **** Check for X11 ****
 322
 323 if test "$have_x" = "yes"
 324 then
 325     XLIB="-lXext -lX11"
 326     ac_save_CPPFLAGS="$CPPFLAGS"
 327     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 328
 329     dnl *** All of the following tests require X11/Xlib.h
 330     AC_CHECK_HEADERS([X11/Xlib.h \
 331                       X11/XKBlib.h \
 332                       X11/Xutil.h \
 333                       X11/extensions/shape.h \
 334                       X11/extensions/XInput.h \
 335                       X11/extensions/XShm.h \
 336                       X11/extensions/Xrandr.h \
 337                       X11/extensions/Xrender.h \
 338                       X11/extensions/xf86vmode.h],,,
 339 [#ifdef HAVE_X11_XLIB_H
 340 # include <X11/Xlib.h>
 341 #endif
 342 #ifdef HAVE_X11_XUTIL_H
 343 # include <X11/Xutil.h>
 344 #endif])
 345
 346         dnl *** Check for X keyboard extension
 347         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 348         then
 349               AC_CHECK_LIB(X11, XkbQueryExtension,
 350               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 351               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 352         fi
 353
 354         dnl *** Check for X Shm extension
 355         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 356         then
 357               AC_CHECK_LIB(Xext, XShmQueryExtension,
 358               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 359               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 360         fi
 361
 362         dnl *** Check for X shape extension
 363         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 364         then
 365               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 366               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 367               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 368         fi
 369
 370         dnl *** Check for XFree86 VMODE extension
 371         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 372         then
 373                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 374                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 375                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 376                   ],,
 377                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 378         fi
 379
 380         dnl *** Check for X RandR extension
 381         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 382         then
 383                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 384 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 385                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 386         fi
 387
 388         dnl *** Check for Transform functions in Xrender
 389         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 390         then
 391               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 392                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 393                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 394                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 395         fi
 396     dnl *** End of X11/Xlib.h check
 397
 398     dnl Check for the presence of OpenGL
 399     if test "x$with_opengl" != "xno"
 400     then
 401         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 402 [#ifdef HAVE_GL_GLX_H
 403 # include <GL/glx.h>
 404 #endif])
 405         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 406         then
 407             dnl Check for some problems due to old Mesa versions
 408             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 409               AC_TRY_COMPILE(
 410                 [#include <GL/gl.h>],
 411                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 412                 [wine_cv_opengl_version_OK="yes"],
 413                 [wine_cv_opengl_version_OK="no"]
 414               )
 415             )
 416
 417             if test "$wine_cv_opengl_version_OK" = "yes"
 418             then
 419                 dnl Check for the presence of the library
 420                 AC_CHECK_LIB(GL,glXCreateContext,
 421                              OPENGL_LIBS="-lGL"
 422                              ,,
 423                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 424
 425                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 426                 then
 427                         OPENGLFILES='$(OPENGLFILES)'
 428                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 429                 else
 430                     if test -f /usr/X11R6/lib/libGL.a
 431                     then
 432                        AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 433 This prevents linking to OpenGL. Delete the file and restart configure.])
 434                     fi
 435                 fi
 436
 437                 dnl Check for GLU32 library.
 438                 AC_CHECK_LIB(GLU,gluLookAt,
 439                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 440                              GLU32FILES='$(GLU32FILES)']
 441                              ,,
 442                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 443                 )
 444              fi
 445
 446              dnl Check for glut32 library.
 447              AC_CHECK_LIB(glut,glutMainLoop,
 448                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 449                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 450                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 451          fi
 452     fi
 453
 454     dnl **** Check for NAS ****
 455     AC_SUBST(NASLIBS,"")
 456     AC_CHECK_HEADERS(audio/audiolib.h,
 457          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 458           AC_CHECK_LIB(audio,AuCreateFlow,
 459                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 460                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 461                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 462
 463     CPPFLAGS="$ac_save_CPPFLAGS"
 464     XFILES='$(XFILES)'
 465 else
 466     XLIB=""
 467     X_CFLAGS=""
 468     X_LIBS=""
 469 fi
 470
 471 dnl **** Check for libxml2 ****
 472
 473 AC_SUBST(XML2LIBS,"")
 474 AC_SUBST(XML2INCL,"")
 475 AC_SUBST(XSLTLIBS,"")
 476 AC_SUBST(XSLTINCL,"")
 477 if test "$PKG_CONFIG" != "false"
 478 then
 479     ac_save_CPPFLAGS="$CPPFLAGS"
 480     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 481     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 482     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 483     AC_CHECK_HEADERS(libxml/parser.h,
 484         [AC_CHECK_LIB(xml2, xmlParseMemory,
 485             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 486              XML2LIBS="$ac_xml_libs"
 487              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 488          AC_CHECK_LIB(xml2, xmlReadMemory,
 489             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 490         ])
 491     CPPFLAGS="$ac_save_CPPFLAGS"
 492     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 493     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 494     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 495     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 496         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 497             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 498              XSLTLIBS="$ac_xslt_libs"
 499              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 500         ],,
 501 [#ifdef HAVE_LIBXSLT_PATTERN_H
 502 # include <libxslt/pattern.h>
 503 #endif])
 504     CPPFLAGS="$ac_save_CPPFLAGS"
 505 fi
 506
 507 dnl **** Check for libhal ****
 508 AC_SUBST(HALINCL,"")
 509 if test "$PKG_CONFIG" != "false"
 510 then
 511     ac_save_CPPFLAGS="$CPPFLAGS"
 512     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 513     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 514     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 515     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 516     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 517     then
 518         AC_CHECK_LIB(hal, libhal_ctx_new,
 519           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 520             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 521              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 522     fi
 523     CPPFLAGS="$ac_save_CPPFLAGS"
 524 fi
 525
 526 dnl **** Check which curses lib to use ***
 527 CURSESLIBS=""
 528 if test "x$with_curses" != "xno"
 529 then
 530     if test "$ac_cv_header_ncurses_h" = "yes"
 531     then
 532         AC_CHECK_LIB(ncurses,waddch,
 533             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 534              CURSESLIBS="-lncurses"])
 535     elif test "$ac_cv_header_curses_h" = "yes"
 536     then
 537         AC_CHECK_LIB(curses,waddch,
 538             [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 539              CURSESLIBS="-lcurses"])
 540     fi
 541     ac_save_LIBS="$LIBS"
 542     LIBS="$LIBS $CURSESLIBS"
 543     AC_CHECK_FUNCS(mousemask)
 544     LIBS="$ac_save_LIBS"
 545 fi
 546 AC_SUBST(CURSESLIBS)
 547
 548 dnl **** Check for SANE ****
 549 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 550 AC_SUBST(SANELIBS,"")
 551 AC_SUBST(SANEINCL,"")
 552 if test "$sane_devel" != "no"
 553 then
 554     SANELIBS="`$sane_devel --libs`"
 555     SANEINCL="`$sane_devel --cflags`"
 556     ac_save_CPPFLAGS="$CPPFLAGS"
 557     ac_save_LIBS="$LIBS"
 558     CPPFLAGS="$CPPFLAGS $SANEINCL"
 559     LIBS="$LIBS $SANELIBS"
 560     AC_CHECK_HEADER(sane/sane.h,
 561                     [AC_CHECK_LIB(sane,sane_open,
 562                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 563                                   [SANELIBS=""
 564                                   SANEINCL=""])],
 565                     [SANELIBS=""
 566                     SANEINCL=""])
 567     LIBS="$ac_save_LIBS"
 568     CPPFLAGS="$ac_save_CPPFLAGS"
 569 fi
 570
 571 dnl **** Check for libgphoto2 ****
 572 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 573 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 574 AC_SUBST(GPHOTO2LIBS,"")
 575 AC_SUBST(GPHOTO2INCL,"")
 576 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 577 then
 578     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 579     GPHOTO2LIBS=""
 580     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 581     do
 582       case "$i" in
 583         -L/usr/lib|-L/usr/lib64) ;;
 584         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 585       esac
 586     done
 587     ac_save_CPPFLAGS="$CPPFLAGS"
 588     ac_save_LIBS="$LIBS"
 589     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 590     LIBS="$LIBS $GPHOTO2LIBS"
 591     AC_CHECK_HEADER(gphoto2-camera.h,
 592                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 593                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 594                                   [GPHOTO2LIBS=""
 595                                   GPHOTO2INCL=""])],
 596                     [GPHOTO2LIBS=""
 597                     GPHOTO2INCL=""])
 598     LIBS="$ac_save_LIBS"
 599     CPPFLAGS="$ac_save_CPPFLAGS"
 600 fi
 601
 602 dnl **** Check for the ICU library ****
 603 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 604 then
 605     saved_libs="$LIBS"
 606     for i in ${ICU_LIB_DIR-/usr/lib}/libsicu ${ICU_LIB_DIR-/usr/lib}/libicu
 607     do
 608         TEST_ICUUC_LIB="${ICUUC_LIB-${i}uc.a}"
 609         TEST_ICUDATA_LIB="${ICUDATA_LIB-${i}data.a}"
 610         AC_MSG_CHECKING(whether can link with ICU libraries $TEST_ICUUC_LIB and $TEST_ICUDATA_LIB)
 611         LIBS="$saved_libs $TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s"
 612         AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 613                     [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 614                      AC_SUBST(ICULIBS,"$TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s")
 615                      AC_MSG_RESULT(yes)],
 616                     [AC_MSG_RESULT(no)])
 617     done
 618     LIBS="$saved_libs"
 619 fi
 620
 621 dnl **** Check for resolver library ***
 622 AC_SUBST(RESOLVLIBS,"")
 623 if test "$ac_cv_header_resolv_h" = "yes"
 624 then
 625     AC_CHECK_LIB(resolv, res_query,
 626         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 627          RESOLVLIBS="-lresolv"])
 628 fi
 629
 630 dnl **** Check for LittleCMS ***
 631 AC_SUBST(LCMSLIBS,"")
 632 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 633 then
 634     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 635         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 636          LCMSLIBS="-llcms"])
 637 fi
 638
 639 dnl **** Check for OpenLDAP ***
 640 AC_SUBST(LDAPLIBS,"")
 641 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 642 then
 643     AC_CHECK_LIB(ldap_r, ldap_initialize,
 644         [AC_CHECK_LIB(lber, ber_init,
 645             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 646              LDAPLIBS="-lldap_r -llber"],,
 647              [$LIBPTHREAD])],,
 648              [$LIBPTHREAD])
 649     WINE_CHECK_LIB_FUNCS(\
 650         ldap_count_references \
 651         ldap_first_reference \
 652         ldap_next_reference \
 653         ldap_parse_reference,
 654         [$LDAPLIBS $LIBPTHREAD])
 655 fi
 656
 657 dnl **** Check for FreeType 2 ****
 658 AC_SUBST(FREETYPELIBS,"")
 659 AC_SUBST(FREETYPEINCL,"")
 660 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 661 if test "$ft_devel" = "no"
 662 then
 663     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 664     if test "$ft_devel2" = "freetype2-config"
 665     then
 666         ft_devel=$ft_devel2
 667     fi
 668 fi
 669
 670 if test "$ft_devel" = "no"
 671 then
 672     wine_cv_msg_freetype=yes
 673 else
 674     FREETYPELIBS=`$ft_devel --libs`
 675     FREETYPEINCL=`$ft_devel --cflags`
 676     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 677     if test "$ft_lib" = "no"
 678     then
 679         wine_cv_msg_freetype=yes
 680         FREETYPELIBS=""
 681         FREETYPEINCL=""
 682     else
 683         ac_save_CPPFLAGS="$CPPFLAGS"
 684         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 685         AC_CHECK_HEADERS(ft2build.h \
 686                          freetype/freetype.h \
 687                          freetype/ftglyph.h \
 688                          freetype/tttables.h \
 689                          freetype/ftnames.h \
 690                          freetype/ftsnames.h \
 691                          freetype/ttnameid.h \
 692                          freetype/ftoutln.h \
 693                          freetype/ftwinfnt.h \
 694                          freetype/ftmodapi.h \
 695                          freetype/internal/sfnt.h,,,
 696                          [#if HAVE_FT2BUILD_H
 697                           #include <ft2build.h>
 698                           #endif])
 699         AC_TRY_CPP([#include <ft2build.h>
 700                     #include <freetype/fttrigon.h>],
 701                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 702           [Define if you have the <freetype/fttrigon.h> header file.])
 703                     wine_cv_fttrigon=yes],
 704                     wine_cv_fttrigon=no)
 705         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 706         ac_save_CFLAGS="$CFLAGS"
 707         CFLAGS="$CFLAGS $FREETYPELIBS"
 708         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 709         CFLAGS="$ac_save_CFLAGS"
 710         CPPFLAGS="$ac_save_CPPFLAGS"
 711         dnl Check that we have at least freetype/freetype.h
 712         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 713         then
 714             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 715             wine_cv_msg_freetype=no
 716         else
 717             FREETYPELIBS=""
 718             FREETYPEINCL=""
 719             wine_cv_msg_freetype=yes
 720         fi
 721     fi
 722 fi
 723
 724 dnl Only build the fonts dir if we have both freetype and fontforge
 725 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 726 then
 727   AC_SUBST(FONTSSUBDIRS,"fonts")
 728 fi
 729
 730 dnl **** Check for parport (currently Linux only) ****
 731 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 732  AC_TRY_COMPILE(
 733    [#include <linux/ppdev.h>],
 734    [ioctl (1,PPCLAIM,0)],
 735    [ac_cv_c_ppdev="yes"],
 736    [ac_cv_c_ppdev="no"])
 737  )
 738 if test "$ac_cv_c_ppdev" = "yes"
 739 then
 740     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 741 fi
 742
 743 dnl **** Check for va_copy ****
 744 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 745  AC_TRY_LINK(
 746    [#include <stdarg.h>],
 747    [va_list ap1, ap2;
 748     va_copy(ap1,ap2);
 749    ],
 750    [ac_cv_c_va_copy="yes"],
 751    [ac_cv_c_va_copy="no"])
 752  )
 753 if test "$ac_cv_c_va_copy" = "yes"
 754 then
 755     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 756 fi
 757 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 758  AC_TRY_LINK(
 759    [#include <stdarg.h>],
 760    [va_list ap1, ap2;
 761     __va_copy(ap1,ap2);
 762    ],
 763    [ac_cv_c___va_copy="yes"],
 764    [ac_cv_c___va_copy="no"])
 765  )
 766 if test "$ac_cv_c___va_copy" = "yes"
 767 then
 768     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 769 fi
 770
 771 dnl **** Check for sigsetjmp ****
 772 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 773  AC_TRY_LINK(
 774    [#include <setjmp.h>],
 775    [sigjmp_buf buf;
 776     sigsetjmp( buf, 1 );
 777     siglongjmp( buf, 1 );],
 778    [ac_cv_c_sigsetjmp="yes"],
 779    [ac_cv_c_sigsetjmp="no"])
 780  )
 781 if test "$ac_cv_c_sigsetjmp" = "yes"
 782 then
 783     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 784 fi
 785
 786 dnl **** Check for pthread_rwlock_t ****
 787 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 788 #include <pthread.h>])
 789
 790 dnl **** Check for pthread functions ****
 791 WINE_CHECK_LIB_FUNCS(\
 792         pthread_attr_get_np \
 793         pthread_getattr_np \
 794         pthread_get_stackaddr_np \
 795         pthread_get_stacksize_np,
 796         [$LIBPTHREAD])
 797
 798 dnl **** Check for aRts Sound Server ****
 799 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 800 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 801 then
 802     ARTSC_CFLAGS=""
 803     for i in `$ARTSCCONFIG --cflags`
 804     do
 805       case "$i" in
 806         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 807       esac
 808     done
 809     ARTSC_LIBS=""
 810     for i in `$ARTSCCONFIG --libs`
 811     do
 812       case "$i" in
 813         -L/usr/lib|-L/usr/lib64) ;;
 814         -L*|-l*) ARTSC_LIBS="$ARTSC_LIBS $i";;
 815       esac
 816     done
 817     save_CFLAGS="$CFLAGS"
 818     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 819     AC_CHECK_LIB(artsc,arts_init,
 820         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 821             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 822             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 823             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 824             $ARTSC_LIBS)
 825     CFLAGS="$save_CFLAGS"
 826 fi
 827
 828 dnl **** Check for EsounD ****
 829 AC_PATH_PROG(ESDCONFIG, esd-config)
 830 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 831 then
 832     ESD_CFLAGS=""
 833     for i in `$ESDCONFIG --cflags`
 834     do
 835       case "$i" in
 836         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 837       esac
 838     done
 839     ESD_LIBS=`$ESDCONFIG --libs`
 840     save_CFLAGS="$CFLAGS"
 841     CFLAGS="$CFLAGS $ESD_CFLAGS"
 842     AC_CHECK_LIB(esd,esd_open_sound,
 843         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 844          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 845          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 846     CFLAGS="$save_CFLAGS"
 847 fi
 848
 849 dnl **** Check for ALSA 1.x ****
 850 AC_SUBST(ALSALIBS,"")
 851 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 852 then
 853     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 854         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 855 #include <alsa/asoundlib.h>
 856 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 857 #include <sys/asoundlib.h>
 858 #endif],
 859                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 860                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 861                          ALSALIBS="-lasound"])])
 862 fi
 863
 864 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 865
 866 AC_SUBST(AUDIOIOLIBS,"")
 867 if test "$ac_cv_header_libaudioio_h" = "yes"
 868 then
 869     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 870                   [AUDIOIOLIBS="-laudioio"
 871                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 872 fi
 873
 874 dnl **** Check for capi4linux ****
 875
 876 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 877 then
 878     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 879 fi
 880
 881 dnl **** Check for gif header usability ****
 882
 883 if test "$ac_cv_header_gif_lib_h" = "yes"
 884 then
 885     AC_TRY_COMPILE([#include <gif_lib.h>],[static typeof(DGifOpen) * func;],
 886         AC_DEFINE(HAVE_GIF, 1, [Define if you have usable GIF headers]))
 887 fi
 888
 889 dnl **** Check for gcc specific options ****
 890
 891 AC_SUBST(EXTRACFLAGS,"")
 892 if test "x${GCC}" = "xyes"
 893 then
 894   EXTRACFLAGS="-Wall -pipe"
 895
 896   dnl Check for strength-reduce bug
 897   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 898                   AC_TRY_RUN([
 899 int     L[[4]] = {0,1,2,3};
 900 int main(void) {
 901   static int Array[[3]];
 902   unsigned int B = 3;
 903   int i;
 904   for(i=0; i<B; i++) Array[[i]] = i - 3;
 905   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 906   L[[i]] = 4;
 907
 908   exit( Array[[1]] != -2 || L[[2]] != 3);
 909 }],
 910     ac_cv_c_gcc_strength_bug="no",
 911     ac_cv_c_gcc_strength_bug="yes",
 912     ac_cv_c_gcc_strength_bug="yes") )
 913   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 914   then
 915     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 916   fi
 917
 918   dnl Check for -fshort-wchar
 919   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 920       [WINE_TRY_CFLAGS([-fshort-wchar],
 921                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 922   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 923   then
 924       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 925   fi
 926
 927   dnl Check for -fno-strict-aliasing
 928   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 929       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 930                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 931   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 932   then
 933     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 934   fi
 935
 936   dnl Check for -gstabs+ option
 937   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 938       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 939   if test "$ac_cv_c_gcc_gstabs" = "yes"
 940   then
 941     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 942   fi
 943
 944   dnl Check for -Wdeclaration-after-statement option
 945   AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
 946       [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
 947   if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
 948   then
 949     EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
 950   fi
 951
 952   dnl Check for noisy string.h
 953   saved_CFLAGS="$CFLAGS"
 954   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 955   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 956       AC_TRY_COMPILE([#include <string.h>],[],
 957                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 958   CFLAGS="$saved_CFLAGS"
 959   if test "$ac_cv_c_string_h_warnings" = "no"
 960   then
 961     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 962   fi
 963
 964   AC_SUBST(BUILTINFLAG,"")
 965   saved_CFLAGS="$CFLAGS"
 966   CFLAGS="$CFLAGS -Werror"
 967   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 968       AC_TRY_COMPILE([],
 969                      [int iswlower(unsigned short);],
 970                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 971   CFLAGS="$saved_CFLAGS"
 972   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 973   then
 974     BUILTINFLAG="-fno-builtin"
 975   fi
 976 fi
 977
 978 dnl **** Check how to define a function in assembly code ****
 979
 980 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 981   WINE_TRY_ASM_LINK(
 982       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 983       ac_cv_asm_func_def=".def",
 984     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 985       ac_cv_asm_func_def=".type @function",
 986     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 987       ac_cv_asm_func_def=".type 2",
 988       ac_cv_asm_func_def="unknown")])]))
 989
 990 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 991 case "$ac_cv_asm_func_def" in
 992   ".def")
 993      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 994   ".type @function")
 995      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 996   ".type 2")
 997      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 998   *)
 999      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1000 esac
1001
1002 dnl **** Check for underscore on external symbols ****
1003
1004 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1005     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1006                       [extern int ac_test;],
1007                       [if (ac_test) return 1],
1008                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1009
1010 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1011 if test "$ac_cv_c_extern_prefix" = "yes"
1012 then
1013   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1014 else
1015   AC_DEFINE([__ASM_NAME(name)], [name])
1016 fi
1017
1018 dnl **** Check for working dll ****
1019
1020 AC_SUBST(DLLEXT,"")
1021 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
1022 AC_SUBST(DLLIBS,"")
1023 AC_SUBST(LDSHARED,"")
1024 AC_SUBST(LDDLLFLAGS,"")
1025 AC_SUBST(LIBEXT,"so")
1026 AC_SUBST(IMPLIBEXT,"def")
1027
1028 case $host_os in
1029   cygwin*|mingw32*)
1030     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
1031     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
1032     if test "$DLLWRAP" = "false"; then
1033       LIBEXT="a"
1034     else
1035       dnl FIXME - check whether dllwrap works correctly...
1036       LIBEXT="dll"
1037     fi
1038     IMPLIBEXT="a"
1039     dnl We can't build 16-bit NE dlls
1040     WIN16_FILES=""
1041     WIN16_INSTALL=""
1042     ;;
1043   *)
1044     if test "$ac_cv_header_dlfcn_h" = "yes"
1045     then
1046         AC_CHECK_FUNCS(dlopen,,
1047             [AC_CHECK_LIB(dl,dlopen,
1048                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
1049                           DLLIBS="-ldl"],
1050                          [LIBEXT="a"])])
1051         WINE_CHECK_LIB_FUNCS(dladdr,[$DLLIBS])
1052     else
1053         LIBEXT="a"
1054     fi
1055
1056     if test "$LIBEXT" = "so"
1057     then
1058       DLLFLAGS="$DLLFLAGS -fPIC"
1059       DLLEXT=".so"
1060       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1061           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
1062                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1063       if test "$ac_cv_c_dll_gnuelf" = "yes"
1064       then
1065         LDSHARED="\$(CC) -shared"
1066         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1067         AC_CACHE_CHECK([whether the linker accepts soname], ac_cv_c_sonames,
1068           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
1069                            ac_cv_c_sonames="yes",ac_cv_c_sonames="no")])
1070         if test "$ac_cv_c_sonames" = "yes"
1071         then
1072           LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
1073         else
1074           AC_CACHE_CHECK([check to see if -h soname is an alternate], ac_cv_c_h_sonames,
1075             [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
1076                              ac_cv_c_h_sonames="yes",ac_cv_c_h_sonames="no")])
1077           if test "$ac_cv_c_h_sonames" = "yes"
1078           then
1079             LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"
1080           fi
1081         fi
1082
1083         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
1084           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
1085                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
1086         if test "$ac_cv_c_dll_zdefs" = "yes"
1087         then
1088           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
1089         fi
1090
1091         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
1092           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1093                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
1094         if test "$ac_cv_c_dll_init_fini" = "yes"
1095         then
1096           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
1097         fi
1098
1099         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
1100           [echo '{ global: *; };' >conftest.map
1101            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1102                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
1103            rm -f conftest.map])
1104         if test "$ac_cv_c_ld_version_scripts" = "yes"
1105         then
1106           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
1107         fi
1108
1109         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
1110           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1111                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
1112         if test "$ac_cv_c_export_dynamic" = "yes"
1113         then
1114           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
1115         fi
1116
1117         AC_CACHE_CHECK([whether the linker accepts --rpath], ac_cv_ld_rpath,
1118           [WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1119                            ac_cv_ld_rpath="yes",ac_cv_ld_rpath="no")])
1120         if test "$ac_cv_ld_rpath" = "yes"
1121         then
1122           AC_SUBST(LDEXERPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1123           AC_SUBST(LDDLLRPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(dlldir) \$(libdir)\`"])
1124         fi
1125
1126         case $host_cpu in
1127           *i[[3456789]]86* | x86_64)
1128             AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1129               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1130                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1131             if test "$ac_cv_ld_reloc_exec" = "yes"
1132             then
1133               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1134             fi
1135             ;;
1136         esac
1137
1138       else
1139         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1140             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1141                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1142         if test "$ac_cv_c_dll_unixware" = "yes"
1143         then
1144           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1145           LDDLLFLAGS="-Wl,-G,-B,symbolic"
1146
1147         else
1148           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1149             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1150           if test "$ac_cv_c_dll_macho" = "yes"
1151           then
1152             LIBEXT="dylib"
1153             LDDLLFLAGS="-bundle"
1154             LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME) \$(SOVERSION:%=-compatibility_version %)"
1155             STRIP="$STRIP -u -r"
1156             dnl declare needed frameworks
1157             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1158             AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1159             AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
1160             if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
1161             then
1162                 dnl CoreServices needed by AudioUnit
1163                 AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices")
1164             fi
1165             case $host_cpu in
1166               *powerpc*)
1167                 CFLAGS="$CFLAGS -ffixed-r13"
1168                 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1169                 ;;
1170             esac
1171
1172           else
1173             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1174               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1175             if test "$ac_cv_c_dll_hpux" = "yes"
1176             then
1177               LIBEXT="sl"
1178               DLLEXT=".sl"
1179               LDDLLFLAGS="-shared -fPIC"
1180               LDSHARED="\$(CC) -shared"
1181             fi
1182           fi
1183         fi
1184       fi
1185     fi
1186
1187     dnl Check for cross compiler to build test programs
1188     AC_SUBST(CROSSTEST,"")
1189     if test "$cross_compiling" = "no"
1190     then
1191       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1192       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1193       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1194       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1195     fi
1196     ;;
1197 esac
1198
1199 if test "$LIBEXT" = "a"; then
1200   AC_MSG_ERROR(
1201 [could not find a way to build shared libraries.
1202 It is currently not possible to build Wine without shared library
1203 (.so) support to allow transparent switch between .so and .dll files.
1204 If you are using Linux, you will need a newer binutils.]
1205 )
1206 fi
1207
1208 case $build_os in
1209   cygwin*|mingw32*)
1210     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\"") ;;
1211   darwin*|macosx*)
1212     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$DYLD_LIBRARY_PATH\"") ;;
1213   *)
1214     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\"") ;;
1215 esac
1216
1217 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1218 case $host_os in
1219   mingw32*)
1220     AC_SUBST(CRTLIBS,"-lmsvcrt")
1221     AC_SUBST(SOCKETLIBS,"-lws2_32")
1222     ;;
1223 esac
1224
1225 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1226 case $host_cpu in
1227   *i[[3456789]]86*)
1228     case $host_os in
1229       linux* | k*bsd*-gnu)
1230         AC_SUBST(MAIN_BINARY,"wine-glibc")
1231         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1232     esac
1233     ;;
1234 esac
1235
1236 dnl **** Get the soname for libraries that we load dynamically ****
1237
1238 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1239 then
1240   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1241   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1242   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1243   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1244   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1245   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1246   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1247   WINE_GET_SONAME(dbus-1,dbus_error_init)
1248   WINE_GET_SONAME(hal,libhal_ctx_new)
1249   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1250   WINE_GET_SONAME(cups,cupsGetDefault)
1251   WINE_GET_SONAME(jack,jack_client_new)
1252   WINE_GET_SONAME(fontconfig,FcInit)
1253   WINE_GET_SONAME(ssl,SSL_library_init)
1254   WINE_GET_SONAME(crypto,BIO_new_socket)
1255   WINE_GET_SONAME(ncurses,waddch)
1256   WINE_GET_SONAME(curses,waddch)
1257   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1258   WINE_GET_SONAME(ungif,DGifOpen)
1259   WINE_GET_SONAME(gif,DGifOpen)
1260   WINE_GET_SONAME(capi20,capi20_isinstalled)
1261 fi
1262
1263
1264 dnl **** Check for functions ****
1265
1266 AC_CHECK_FUNCS(\
1267         _lwp_create \
1268         _lwp_self \
1269         _pclose \
1270         _popen \
1271         _snprintf \
1272         _spawnvp \
1273         _stricmp \
1274         _strnicmp \
1275         _vsnprintf \
1276         asctime_r \
1277         chsize \
1278         clone \
1279         epoll_create \
1280         ffs \
1281         finite \
1282         fork \
1283         fpclass \
1284         fstatfs \
1285         fstatvfs \
1286         ftruncate \
1287         futimes \
1288         futimesat \
1289         getaddrinfo \
1290         getnameinfo \
1291         getnetbyname \
1292         getopt_long \
1293         getpagesize \
1294         getprotobyname \
1295         getprotobynumber \
1296         getpwuid \
1297         getservbyport \
1298         gettid \
1299         gettimeofday \
1300         getuid \
1301         inet_network \
1302         kqueue \
1303         lstat \
1304         memmove \
1305         mmap \
1306         pclose \
1307         popen \
1308         prctl \
1309         pread \
1310         pwrite \
1311         readlink \
1312         rfork \
1313         sched_yield \
1314         select \
1315         sendmsg \
1316         setrlimit \
1317         settimeofday \
1318         sigaltstack \
1319         sigprocmask \
1320         snprintf \
1321         spawnvp \
1322         statfs \
1323         statvfs \
1324         strcasecmp \
1325         strerror \
1326         strncasecmp \
1327         tcgetattr \
1328         timegm \
1329         usleep \
1330         vsnprintf \
1331         wait4 \
1332         waitpid \
1333 )
1334
1335
1336 dnl **** Check for types ****
1337
1338 AC_C_CONST
1339 AC_C_INLINE
1340 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1341 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1342 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1343
1344 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1345 [#ifdef HAVE_LINUX_INPUT_H
1346 #include <linux/input.h>
1347 #endif])
1348
1349 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1350                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1351                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1352 if test "$wine_cv_have_sigaddset" = "yes"
1353 then
1354   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1355 fi
1356
1357
1358 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1359         wine_cv_linux_gethostbyname_r_6,
1360         AC_TRY_LINK([
1361 #include <netdb.h>
1362         ], [
1363     char *name=NULL;
1364     struct hostent he;
1365     struct hostent *result;
1366     char *buf=NULL;
1367     int bufsize=0;
1368     int res,errnr;
1369     char *addr=NULL;
1370     int addrlen=0;
1371     int addrtype=0;
1372     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1373     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1374     ],
1375         wine_cv_linux_gethostbyname_r_6=yes,
1376         wine_cv_linux_gethostbyname_r_6=no
1377         )
1378    )
1379    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1380    then
1381       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1382                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1383    fi
1384
1385 if test "$ac_cv_header_linux_joystick_h" = "yes"
1386 then
1387    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1388         wine_cv_linux_joystick_22_api,
1389         AC_TRY_COMPILE([
1390         #include <sys/ioctl.h>
1391         #include <linux/joystick.h>
1392
1393         struct js_event blub;
1394         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1395         #error "no 2.2 header"
1396         #endif
1397         ],/*empty*/,
1398         wine_cv_linux_joystick_22_api=yes,
1399         wine_cv_linux_joystick_22_api=no,
1400         wine_cv_linux_joystick_22_api=no
1401         )
1402    )
1403    if test "$wine_cv_linux_joystick_22_api" = "yes"
1404    then
1405       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1406                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1407    fi
1408 fi
1409
1410 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1411
1412 dnl Check for statfs members
1413 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1414 [#include <sys/types.h>
1415 #ifdef HAVE_SYS_PARAM_H
1416 # include <sys/param.h>
1417 #endif
1418 #ifdef HAVE_SYS_MOUNT_H
1419 # include <sys/mount.h>
1420 #endif
1421 #ifdef HAVE_SYS_VFS_H
1422 # include <sys/vfs.h>
1423 #endif
1424 #ifdef HAVE_SYS_STATFS_H
1425 # include <sys/statfs.h>
1426 #endif])
1427
1428 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1429 [#ifdef HAVE_SYS_STATVFS_H
1430 #include <sys/statvfs.h>
1431 #endif])
1432
1433 dnl Check for socket structure members
1434 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1435 [#include <sys/types.h>
1436 #ifdef HAVE_SYS_SOCKET_H
1437 # include <sys/socket.h>
1438 #endif
1439 #ifdef HAVE_SYS_UN_H
1440 # include <sys/un.h>
1441 #endif])
1442
1443 dnl Check for scsireq_t and sg_io_hdr_t members
1444 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1445 [#include <sys/types.h>
1446 #ifdef HAVE_SCSI_SG_H
1447 #include <scsi/sg.h>
1448 #endif])
1449
1450 dnl Check for siginfo_t members
1451 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1452
1453 dnl Check for struct mtget members
1454 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1455 [#include <sys/types.h>
1456 #ifdef HAVE_SYS_MTIO_H
1457 #include <sys/mtio.h>
1458 #endif])
1459
1460 dnl Check for struct option
1461 AC_CHECK_MEMBERS([struct option.name],,,
1462 [#ifdef HAVE_GETOPT_H
1463 #include <getopt.h>
1464 #endif])
1465
1466 dnl Check for stat.st_blocks
1467 AC_CHECK_MEMBERS([struct stat.st_blocks])
1468
1469 dnl Check for sin6_scope_id
1470 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1471 [#ifdef HAVE_SYS_TYPES_H
1472 #include <sys/types.h>
1473 #endif
1474 #ifdef HAVE_NETINET_IN_H
1475 #include <netinet/in.h>
1476 #endif])
1477
1478 dnl Check for ns_msg ptr member
1479 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1480 [#ifdef HAVE_SYS_TYPES_H
1481 #include <sys/types.h>
1482 #endif
1483 #ifdef HAVE_NETINET_IN_H
1484 # include <netinet/in.h>
1485 #endif
1486 #ifdef HAVE_ARPA_NAMESER_H
1487 # include <arpa/nameser.h>
1488 #endif])
1489
1490 dnl Check for the external timezone variables timezone and daylight
1491 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1492                AC_TRY_LINK([#include <time.h>],[timezone;],
1493                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1494 if test "$ac_cv_have_timezone" = "yes"
1495 then
1496     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1497 fi
1498 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1499                AC_TRY_LINK([#include <time.h>],[daylight;],
1500                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1501 if test "$ac_cv_have_daylight" = "yes"
1502 then
1503     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1504 fi
1505
1506 dnl *** check for the need to define platform-specific symbols
1507
1508 case $host_cpu in
1509   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1510   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__])
1511                     WINE_CHECK_DEFINE([_WIN64]) ;;
1512   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1513   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1514   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1515 esac
1516
1517 case $host_vendor in
1518   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1519 esac
1520
1521 dnl **** Generate output files ****
1522
1523 AH_TOP([#define __WINE_CONFIG_H])
1524
1525 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1526 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1527 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1528 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1529 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1530 WINE_CONFIG_EXTRA_DIR(include/wine)
1531
1532 MAKE_RULES=Make.rules
1533 AC_SUBST_FILE(MAKE_RULES)
1534
1535 MAKE_DLL_RULES=dlls/Makedll.rules
1536 AC_SUBST_FILE(MAKE_DLL_RULES)
1537
1538 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1539 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1540
1541 MAKE_TEST_RULES=dlls/Maketest.rules
1542 AC_SUBST_FILE(MAKE_TEST_RULES)
1543
1544 MAKE_PROG_RULES=programs/Makeprog.rules
1545 AC_SUBST_FILE(MAKE_PROG_RULES)
1546
1547 AC_CONFIG_FILES([
1548 Make.rules
1549 dlls/Makedll.rules
1550 dlls/Makeimplib.rules
1551 dlls/Maketest.rules
1552 programs/Makeprog.rules
1553 Makefile
1554 dlls/Makefile
1555 dlls/activeds/Makefile
1556 dlls/advapi32/Makefile
1557 dlls/advapi32/tests/Makefile
1558 dlls/advpack/Makefile
1559 dlls/advpack/tests/Makefile
1560 dlls/amstream/Makefile
1561 dlls/atl/Makefile
1562 dlls/avicap32/Makefile
1563 dlls/avifil32/Makefile
1564 dlls/cabinet/Makefile
1565 dlls/cabinet/tests/Makefile
1566 dlls/capi2032/Makefile
1567 dlls/cards/Makefile
1568 dlls/cfgmgr32/Makefile
1569 dlls/comcat/Makefile
1570 dlls/comcat/tests/Makefile
1571 dlls/comctl32/Makefile
1572 dlls/comctl32/tests/Makefile
1573 dlls/comdlg32/Makefile
1574 dlls/comdlg32/tests/Makefile
1575 dlls/compstui/Makefile
1576 dlls/crtdll/Makefile
1577 dlls/crypt32/Makefile
1578 dlls/crypt32/tests/Makefile
1579 dlls/cryptdll/Makefile
1580 dlls/cryptnet/Makefile
1581 dlls/ctl3d32/Makefile
1582 dlls/d3d8/Makefile
1583 dlls/d3d8/tests/Makefile
1584 dlls/d3d9/Makefile
1585 dlls/d3d9/tests/Makefile
1586 dlls/d3dim/Makefile
1587 dlls/d3drm/Makefile
1588 dlls/d3dx8/Makefile
1589 dlls/d3dxof/Makefile
1590 dlls/dbghelp/Makefile
1591 dlls/dciman32/Makefile
1592 dlls/ddraw/Makefile
1593 dlls/ddraw/tests/Makefile
1594 dlls/devenum/Makefile
1595 dlls/dinput/Makefile
1596 dlls/dinput/tests/Makefile
1597 dlls/dinput8/Makefile
1598 dlls/dmband/Makefile
1599 dlls/dmcompos/Makefile
1600 dlls/dmime/Makefile
1601 dlls/dmloader/Makefile
1602 dlls/dmscript/Makefile
1603 dlls/dmstyle/Makefile
1604 dlls/dmsynth/Makefile
1605 dlls/dmusic/Makefile
1606 dlls/dmusic32/Makefile
1607 dlls/dnsapi/Makefile
1608 dlls/dnsapi/tests/Makefile
1609 dlls/dplay/Makefile
1610 dlls/dplayx/Makefile
1611 dlls/dpnet/Makefile
1612 dlls/dpnhpast/Makefile
1613 dlls/dsound/Makefile
1614 dlls/dsound/tests/Makefile
1615 dlls/dswave/Makefile
1616 dlls/dxdiagn/Makefile
1617 dlls/dxerr8/Makefile
1618 dlls/dxerr9/Makefile
1619 dlls/dxguid/Makefile
1620 dlls/gdi/Makefile
1621 dlls/gdi/tests/Makefile
1622 dlls/glu32/Makefile
1623 dlls/glut32/Makefile
1624 dlls/gphoto2.ds/Makefile
1625 dlls/hhctrl.ocx/Makefile
1626 dlls/hid/Makefile
1627 dlls/hlink/Makefile
1628 dlls/hlink/tests/Makefile
1629 dlls/iccvid/Makefile
1630 dlls/icmp/Makefile
1631 dlls/ifsmgr.vxd/Makefile
1632 dlls/imaadp32.acm/Makefile
1633 dlls/imagehlp/Makefile
1634 dlls/imm32/Makefile
1635 dlls/infosoft/Makefile
1636 dlls/inseng/Makefile
1637 dlls/iphlpapi/Makefile
1638 dlls/iphlpapi/tests/Makefile
1639 dlls/itss/Makefile
1640 dlls/kernel/Makefile
1641 dlls/kernel/tests/Makefile
1642 dlls/lz32/Makefile
1643 dlls/lz32/tests/Makefile
1644 dlls/mapi32/Makefile
1645 dlls/mapi32/tests/Makefile
1646 dlls/mciavi32/Makefile
1647 dlls/mcicda/Makefile
1648 dlls/mciseq/Makefile
1649 dlls/mciwave/Makefile
1650 dlls/midimap/Makefile
1651 dlls/mlang/Makefile
1652 dlls/mlang/tests/Makefile
1653 dlls/mmdevldr.vxd/Makefile
1654 dlls/monodebg.vxd/Makefile
1655 dlls/mpr/Makefile
1656 dlls/mprapi/Makefile
1657 dlls/msacm32.drv/Makefile
1658 dlls/msacm32/Makefile
1659 dlls/msacm32/tests/Makefile
1660 dlls/msadp32.acm/Makefile
1661 dlls/mscms/Makefile
1662 dlls/mscms/tests/Makefile
1663 dlls/msdmo/Makefile
1664 dlls/msftedit/Makefile
1665 dlls/msg711.acm/Makefile
1666 dlls/mshtml/Makefile
1667 dlls/mshtml/tests/Makefile
1668 dlls/msi/Makefile
1669 dlls/msi/tests/Makefile
1670 dlls/msimg32/Makefile
1671 dlls/msisys.ocx/Makefile
1672 dlls/msnet32/Makefile
1673 dlls/msrle32/Makefile
1674 dlls/msvcrt/Makefile
1675 dlls/msvcrt/tests/Makefile
1676 dlls/msvcrt20/Makefile
1677 dlls/msvcrt40/Makefile
1678 dlls/msvcrtd/Makefile
1679 dlls/msvcrtd/tests/Makefile
1680 dlls/msvfw32/Makefile
1681 dlls/msvidc32/Makefile
1682 dlls/mswsock/Makefile
1683 dlls/msxml3/Makefile
1684 dlls/msxml3/tests/Makefile
1685 dlls/netapi32/Makefile
1686 dlls/netapi32/tests/Makefile
1687 dlls/newdev/Makefile
1688 dlls/ntdll/Makefile
1689 dlls/ntdll/tests/Makefile
1690 dlls/ntdsapi/Makefile
1691 dlls/objsel/Makefile
1692 dlls/odbc32/Makefile
1693 dlls/odbccp32/Makefile
1694 dlls/ole32/Makefile
1695 dlls/ole32/tests/Makefile
1696 dlls/oleacc/Makefile
1697 dlls/oleaut32/Makefile
1698 dlls/oleaut32/tests/Makefile
1699 dlls/olecli32/Makefile
1700 dlls/oledlg/Makefile
1701 dlls/olepro32/Makefile
1702 dlls/olesvr32/Makefile
1703 dlls/opengl32/Makefile
1704 dlls/powrprof/Makefile
1705 dlls/psapi/Makefile
1706 dlls/psapi/tests/Makefile
1707 dlls/pstorec/Makefile
1708 dlls/qcap/Makefile
1709 dlls/quartz/Makefile
1710 dlls/quartz/tests/Makefile
1711 dlls/query/Makefile
1712 dlls/rasapi32/Makefile
1713 dlls/riched20/Makefile
1714 dlls/riched20/tests/Makefile
1715 dlls/riched32/Makefile
1716 dlls/rpcrt4/Makefile
1717 dlls/rpcrt4/tests/Makefile
1718 dlls/rsabase/Makefile
1719 dlls/rsabase/tests/Makefile
1720 dlls/rsaenh/Makefile
1721 dlls/rsaenh/tests/Makefile
1722 dlls/sane.ds/Makefile
1723 dlls/secur32/Makefile
1724 dlls/secur32/tests/Makefile
1725 dlls/security/Makefile
1726 dlls/sensapi/Makefile
1727 dlls/serialui/Makefile
1728 dlls/setupapi/Makefile
1729 dlls/setupapi/tests/Makefile
1730 dlls/sfc/Makefile
1731 dlls/shdocvw/Makefile
1732 dlls/shdocvw/tests/Makefile
1733 dlls/shell32/Makefile
1734 dlls/shell32/tests/Makefile
1735 dlls/shfolder/Makefile
1736 dlls/shlwapi/Makefile
1737 dlls/shlwapi/tests/Makefile
1738 dlls/snmpapi/Makefile
1739 dlls/spoolss/Makefile
1740 dlls/stdole2.tlb/Makefile
1741 dlls/stdole32.tlb/Makefile
1742 dlls/sti/Makefile
1743 dlls/strmiids/Makefile
1744 dlls/tapi32/Makefile
1745 dlls/twain_32/Makefile
1746 dlls/unicows/Makefile
1747 dlls/url/Makefile
1748 dlls/urlmon/Makefile
1749 dlls/urlmon/tests/Makefile
1750 dlls/user/Makefile
1751 dlls/user/tests/Makefile
1752 dlls/userenv/Makefile
1753 dlls/usp10/Makefile
1754 dlls/usp10/tests/Makefile
1755 dlls/uuid/Makefile
1756 dlls/uxtheme/Makefile
1757 dlls/uxtheme/tests/Makefile
1758 dlls/vdhcp.vxd/Makefile
1759 dlls/vdmdbg/Makefile
1760 dlls/version/Makefile
1761 dlls/version/tests/Makefile
1762 dlls/vmm.vxd/Makefile
1763 dlls/vnbt.vxd/Makefile
1764 dlls/vnetbios.vxd/Makefile
1765 dlls/vtdapi.vxd/Makefile
1766 dlls/vwin32.vxd/Makefile
1767 dlls/w32skrnl/Makefile
1768 dlls/winecrt0/Makefile
1769 dlls/wined3d/Makefile
1770 dlls/winedos/Makefile
1771 dlls/winemp3.acm/Makefile
1772 dlls/wineps.drv/Makefile
1773 dlls/winex11.drv/Makefile
1774 dlls/wininet/Makefile
1775 dlls/wininet/tests/Makefile
1776 dlls/winmm/Makefile
1777 dlls/winmm/joystick/Makefile
1778 dlls/winmm/tests/Makefile
1779 dlls/winmm/winealsa/Makefile
1780 dlls/winmm/winearts/Makefile
1781 dlls/winmm/wineaudioio/Makefile
1782 dlls/winmm/winecoreaudio/Makefile
1783 dlls/winmm/wineesd/Makefile
1784 dlls/winmm/winejack/Makefile
1785 dlls/winmm/winenas/Makefile
1786 dlls/winmm/wineoss/Makefile
1787 dlls/winnls32/Makefile
1788 dlls/winspool.drv/Makefile
1789 dlls/winspool.drv/tests/Makefile
1790 dlls/wintab32/Makefile
1791 dlls/wintrust/Makefile
1792 dlls/wldap32/Makefile
1793 dlls/wnaspi32/Makefile
1794 dlls/wow32/Makefile
1795 dlls/ws2_32/Makefile
1796 dlls/ws2_32/tests/Makefile
1797 dlls/wsock32/Makefile
1798 dlls/wtsapi32/Makefile
1799 documentation/Makefile
1800 fonts/Makefile
1801 include/Makefile
1802 libs/Makefile
1803 libs/port/Makefile
1804 libs/wine/Makefile
1805 libs/wpp/Makefile
1806 loader/Makefile
1807 programs/Makefile
1808 programs/clock/Makefile
1809 programs/cmdlgtst/Makefile
1810 programs/control/Makefile
1811 programs/eject/Makefile
1812 programs/expand/Makefile
1813 programs/explorer/Makefile
1814 programs/hh/Makefile
1815 programs/icinfo/Makefile
1816 programs/iexplore/Makefile
1817 programs/msiexec/Makefile
1818 programs/notepad/Makefile
1819 programs/oleview/Makefile
1820 programs/progman/Makefile
1821 programs/regedit/Makefile
1822 programs/regsvr32/Makefile
1823 programs/rpcss/Makefile
1824 programs/rundll32/Makefile
1825 programs/start/Makefile
1826 programs/taskmgr/Makefile
1827 programs/uninstaller/Makefile
1828 programs/view/Makefile
1829 programs/wcmd/Makefile
1830 programs/wineboot/Makefile
1831 programs/winebrowser/Makefile
1832 programs/winecfg/Makefile
1833 programs/wineconsole/Makefile
1834 programs/winedbg/Makefile
1835 programs/winefile/Makefile
1836 programs/winemenubuilder/Makefile
1837 programs/winemine/Makefile
1838 programs/winepath/Makefile
1839 programs/winetest/Makefile
1840 programs/winevdm/Makefile
1841 programs/winhelp/Makefile
1842 programs/winver/Makefile
1843 programs/wordpad/Makefile
1844 server/Makefile
1845 tools/Makefile
1846 tools/widl/Makefile
1847 tools/winapi/Makefile
1848 tools/winebuild/Makefile
1849 tools/winedump/Makefile
1850 tools/winegcc/Makefile
1851 tools/wmc/Makefile
1852 tools/wrc/Makefile])
1853
1854 AC_OUTPUT
1855
1856 if test "$have_x" = "no"
1857 then
1858   echo >&2
1859   AC_MSG_WARN([X development files not found. Wine will be built without])
1860   AC_MSG_WARN([X support, which currently does not work, and probably])
1861   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1862   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1863 fi
1864
1865 if test "$wine_cv_opengl_version_OK" = "no"
1866 then
1867   echo >&2
1868   AC_MSG_WARN([Old Mesa headers detected. Wine will be built without Direct3D])
1869   AC_MSG_WARN([support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1870 fi
1871
1872 if test "$wine_cv_msg_freetype" = "yes"
1873 then
1874   echo >&2
1875   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
1876   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
1877   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
1878   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
1879 fi
1880
1881 if test -z "$FONTSSUBDIRS"
1882 then
1883   echo >&2
1884   if test "$FONTFORGE" = "false"
1885   then
1886     AC_MSG_WARN([FontForge is missing.])
1887   else
1888     AC_MSG_WARN([FreeType is missing.])
1889   fi
1890   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
1891 fi
1892
1893 if test -z "$ALSALIBS" -a \
1894         -z "$ARTSC_LIBS" -a \
1895         -z "$AUDIOIOLIBS" -a \
1896         -z "$NASLIBS" -a \
1897         -z "$ESD_LIBS" -a \
1898         -z "$ac_cv_lib_soname_jack" -a \
1899         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1900         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1901         "$ac_cv_header_soundcard_h" != "yes"
1902 then
1903   echo >&2
1904   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
1905   AC_MSG_WARN([The currently supported sound systems are:])
1906   AC_MSG_WARN([ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS])
1907 fi
1908
1909 echo
1910 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1911 echo
1912
1913 dnl Local Variables:
1914 dnl comment-start: "dnl "
1915 dnl comment-end: ""
1916 dnl comment-start-skip: "\\bdnl\\b\\s *"
1917 dnl compile-command: "autoconf && autoheader"
1918 dnl End: