git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  47
  48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  49   [if test -z "$with_wine_tools"; then
  50      if test "$cross_compiling" = "yes"; then
  51        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  52      else
  53        wine_cv_toolsdir="\$(TOPOBJDIR)"
  54      fi
  55    elif test -d "$with_wine_tools/tools/winebuild"; then
  56      case $with_wine_tools in
  57        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  58        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  59      esac
  60    else
  61      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  62    fi])
  63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  64
  65 AC_PATH_XTRA
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  71 if test "$XLEX" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  74 fi
  75
  76 dnl Check for bison
  77 AC_CHECK_PROGS(BISON,bison,none)
  78 if test "$BISON" = "none"
  79 then
  80   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  81 fi
  82
  83 AC_CHECK_TOOLS(AS,[gas as],as)
  84 AC_CHECK_TOOL(LD,ld,ld)
  85 AC_CHECK_TOOL(AR,ar,ar)
  86 AC_PROG_RANLIB
  87 AC_CHECK_TOOL(STRIP,strip,strip)
  88 AC_CHECK_TOOL(WINDRES,windres,false)
  89 AC_PROG_LN_S
  90 WINE_PROG_LN
  91 AC_PROG_EGREP
  92 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  93 AC_PROG_INSTALL
  94 dnl Prepend src dir to install path dir if it's a relative path
  95 case "$INSTALL" in
  96   [[\\/$]]* | ?:[[\\/]]* ) ;;
  97   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  98 esac
  99
 100 dnl Check for lint
 101 AC_CHECK_PROGS(LINT, lclint lint)
 102 if test "$LINT" = "lint"
 103 then
 104   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 105   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 106 fi
 107 AC_SUBST(LINT)
 108 AC_SUBST(LINTFLAGS)
 109
 110 dnl Check for various programs
 111 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 112 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 113 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 114 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 115 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 116
 117 dnl **** Check for some libraries ****
 118
 119 dnl Check for -li386 for NetBSD and OpenBSD
 120 AC_CHECK_LIB(i386,i386_set_ldt)
 121 dnl Check for -lossaudio for NetBSD
 122 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 123 dnl Check for -lw for Solaris
 124 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 125 dnl Check for -lnsl for Solaris
 126 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 127 dnl Check for -lsocket for Solaris
 128 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 129 dnl Check for -lresolv for Solaris
 130 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 131 dnl Check for -lxpg4 for FreeBSD
 132 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 133 dnl Check for -lpoll for Mac OS X/Darwin
 134 AC_CHECK_LIB(poll,poll)
 135 dnl Check for -lresolv for Mac OS X/Darwin
 136 AC_CHECK_LIB(resolv,res_9_init)
 137 dnl Check for -lpthread
 138 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 139
 140 AC_SUBST(XLIB)
 141 AC_SUBST(XFILES)
 142 XFILES=""
 143 AC_SUBST(OPENGLFILES)
 144 OPENGLFILES=""
 145 AC_SUBST(GLU32FILES)
 146 GLU32FILES=""
 147 AC_SUBST(OPENGL_LIBS)
 148 OPENGL_LIBS=""
 149 if test "$have_x" = "yes"
 150 then
 151     XLIB="-lXext -lX11"
 152     ac_save_CPPFLAGS="$CPPFLAGS"
 153     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 154
 155     dnl *** All of the following tests require X11/Xlib.h
 156     AC_CHECK_HEADERS(X11/Xlib.h,
 157       [
 158         AC_CHECK_HEADERS([X11/XKBlib.h \
 159                           X11/Xutil.h \
 160                           X11/extensions/shape.h \
 161                           X11/extensions/XInput.h \
 162                           X11/extensions/XShm.h \
 163                           X11/extensions/Xrandr.h \
 164                           X11/extensions/Xrender.h \
 165                           X11/extensions/Xvlib.h \
 166                           X11/extensions/xf86dga.h \
 167                           X11/extensions/xf86vmode.h],,,
 168                          [#include <X11/Xlib.h>
 169                           #ifdef HAVE_X11_XUTIL_H
 170                           # include <X11/Xutil.h>
 171                           #endif])
 172
 173         dnl *** Check for X keyboard extension
 174         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 175         then
 176               AC_CHECK_LIB(X11, XkbQueryExtension,
 177               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 178               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 179         fi
 180
 181         dnl *** Check for X Shm extension
 182         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 183         then
 184               AC_CHECK_LIB(Xext, XShmQueryExtension,
 185               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 186               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 187         fi
 188
 189         dnl *** Check for X shape extension
 190         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 191         then
 192               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 193               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 194               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 195         fi
 196
 197         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 198         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 199         then
 200               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 201                 [ dnl *** If found...
 202                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 203                             [Define if you have the Xxf86dga library version 2])
 204                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 205                ],
 206                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 207                   dnl *** instead (DGA 2.0 not found)...
 208                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 209                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 210                                 [Define if you have the Xxf86dga library version 1])
 211                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 212                     ],,
 213                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 214                   )
 215                 ],
 216                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 217         fi
 218
 219         dnl *** Check for XFree86 VMODE extension
 220         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 221         then
 222                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 223                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 224                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 225                   ],,
 226                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 227         fi
 228
 229         dnl *** Check for X RandR extension
 230         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 231         then
 232                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 233 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 234                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 235         fi
 236
 237         dnl *** Check for XVideo extension supporting XvImages
 238         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 239         then
 240                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 241                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 242                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 243                   ],,
 244                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 245         fi
 246       ]
 247     ) dnl *** End of X11/Xlib.h check
 248
 249     dnl Check for the presence of OpenGL
 250     if test "x$with_opengl" != "xno"
 251     then
 252         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 253         then
 254             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 255 This prevents linking to OpenGL. Delete the file and restart configure.])
 256         fi
 257
 258         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 259         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 260         then
 261             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 262             dnl Check for some problems due to old Mesa versions
 263             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 264               AC_TRY_COMPILE(
 265                 [#include <GL/gl.h>],
 266                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 267                 [wine_cv_opengl_version_OK="yes"],
 268                 [wine_cv_opengl_version_OK="no"]
 269               )
 270             )
 271
 272             if test "$wine_cv_opengl_version_OK" = "yes"
 273             then
 274                 dnl Check for the presence of the library
 275                 AC_CHECK_LIB(GL,glXCreateContext,
 276                              OPENGL_LIBS="-lGL"
 277                              ,,
 278                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 279
 280                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 281                 then
 282                         OPENGLFILES='$(OPENGLFILES)'
 283                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 284
 285                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 286                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 287                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 288                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 289
 290                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 291                         then
 292                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 293                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 294                                                   #ifdef HAVE_GL_GLEXT_H
 295                                                   # include <GL/glext.h>
 296                                                   #endif
 297                                                   ],
 298                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 299                                                  [wine_cv_extension_prototypes="yes"],
 300                                                  [wine_cv_extension_prototypes="no"]
 301                                   )]
 302                                 )
 303                                 if test "$wine_cv_extension_prototypes" = "yes"
 304                                 then
 305                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 306                                               [Define if the OpenGL headers define extension typedefs])
 307                                 fi
 308                         fi
 309
 310                 fi
 311                 dnl Check for GLU32 library.
 312                 AC_CHECK_LIB(GLU,gluLookAt,
 313                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 314                              GLU32FILES='$(GLU32FILES)']
 315                              ,,
 316                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 317                 )
 318              fi
 319
 320              dnl Check for glut32 library.
 321              AC_CHECK_LIB(glut,glutMainLoop,
 322                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 323                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 324                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 325          fi
 326     fi
 327
 328     dnl **** Check for NAS ****
 329     AC_SUBST(NASLIBS,"")
 330     AC_CHECK_HEADERS(audio/audiolib.h,
 331          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 332           AC_CHECK_LIB(audio,AuCreateFlow,
 333                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 334                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 335                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 336
 337     CPPFLAGS="$ac_save_CPPFLAGS"
 338     XFILES='$(XFILES)'
 339 else
 340     XLIB=""
 341     X_CFLAGS=""
 342     X_LIBS=""
 343 fi
 344
 345 dnl **** Check which curses lib to use ***
 346 CURSESLIBS=""
 347 if test "x$with_curses" != "xno"
 348 then
 349     AC_CHECK_HEADERS(ncurses.h,
 350         [AC_CHECK_LIB(ncurses,waddch,
 351             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 352              CURSESLIBS="-lncurses"],
 353              [AC_CHECK_HEADERS(curses.h,
 354                  [AC_CHECK_LIB(curses,waddch,
 355                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 356                       CURSESLIBS="-lcurses"])])])])
 357     saved_libs="$LIBS"
 358     LIBS="$CURSESLIBS $LIBS"
 359     AC_CHECK_FUNCS(getbkgd resizeterm)
 360     LIBS="$saved_libs"
 361 fi
 362 AC_SUBST(CURSESLIBS)
 363
 364 dnl **** Check for SANE ****
 365 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 366 if test "$sane_devel" = "no"
 367 then
 368     SANELIBS=""
 369     SANEINCL=""
 370 else
 371     SANELIBS="`$sane_devel --libs`"
 372     SANEINCL="`$sane_devel --cflags`"
 373     ac_save_CPPFLAGS="$CPPFLAGS"
 374     ac_save_LIBS="$LIBS"
 375     CPPFLAGS="$CPPFLAGS $SANEINCL"
 376     LIBS="$LIBS $SANELIBS"
 377     AC_CHECK_HEADER(sane/sane.h,
 378                     [AC_CHECK_LIB(sane,sane_open,
 379                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 380                                   [SANELIBS=""
 381                                   SANEINCL=""])],
 382                     [SANELIBS=""
 383                     SANEINCL=""])
 384     LIBS="$ac_save_LIBS"
 385     CPPFLAGS="$ac_save_CPPFLAGS"
 386 fi
 387 AC_SUBST(SANELIBS)
 388 AC_SUBST(SANEINCL)
 389
 390 dnl **** Check for the ICU library ****
 391 AC_CHECK_HEADERS(unicode/ubidi.h)
 392 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 393 then
 394     saved_libs="$LIBS"
 395     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 396     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 397     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 398     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 399     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 400     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 401                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 402                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 403                  AC_MSG_RESULT(yes)],
 404                 [AC_MSG_RESULT(no)])
 405     LIBS="$saved_libs"
 406 fi
 407
 408 dnl **** Check for FreeType 2 ****
 409 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 410 if test "$ft_lib" = "no"
 411 then
 412     FREETYPELIBS=""
 413     FREETYPEINCL=""
 414     wine_cv_msg_freetype=no
 415 else
 416     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 417     if test "$ft_devel" = "no"
 418     then
 419         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 420         if test "$ft_devel2" = "freetype2-config"
 421         then
 422                 ft_devel=$ft_devel2
 423         fi
 424     fi
 425     if test "$ft_devel" = "no"
 426     then
 427         FREETYPELIBS=""
 428         FREETYPEINCL=""
 429         wine_cv_msg_freetype=yes
 430     else
 431         FREETYPELIBS=`$ft_devel --libs`
 432         FREETYPEINCL=`$ft_devel --cflags`
 433         ac_save_CPPFLAGS="$CPPFLAGS"
 434         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 435         AC_CHECK_HEADERS(ft2build.h \
 436                          freetype/freetype.h \
 437                          freetype/ftglyph.h \
 438                          freetype/tttables.h \
 439                          freetype/ftnames.h \
 440                          freetype/ftsnames.h \
 441                          freetype/ttnameid.h \
 442                          freetype/ftoutln.h \
 443                          freetype/ftwinfnt.h \
 444                          freetype/internal/sfnt.h,,,
 445                          [#if HAVE_FT2BUILD_H
 446                           #include <ft2build.h>
 447                           #endif])
 448         AC_TRY_CPP([#include <ft2build.h>
 449                     #include <freetype/fttrigon.h>],
 450                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 451           [Define if you have the <freetype/fttrigon.h> header file.])
 452                     wine_cv_fttrigon=yes],
 453                     wine_cv_fttrigon=no)
 454         CPPFLAGS="$ac_save_CPPFLAGS"
 455         dnl Check that we have at least freetype/freetype.h
 456         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 457         then
 458             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 459             wine_cv_msg_freetype=no
 460         else
 461             FREETYPELIBS=""
 462             FREETYPEINCL=""
 463             wine_cv_msg_freetype=yes
 464         fi
 465     fi
 466 fi
 467 AC_SUBST(FREETYPELIBS)
 468 AC_SUBST(FREETYPEINCL)
 469
 470 dnl Only build the fonts dir if we have both freetype and fontforge
 471 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 472 then
 473   AC_SUBST(FONTSSUBDIRS,"fonts")
 474 fi
 475
 476 dnl **** Check for parport (currently Linux only) ****
 477 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 478  AC_TRY_COMPILE(
 479    [#include <linux/ppdev.h>],
 480    [ioctl (1,PPCLAIM,0)],
 481    [ac_cv_c_ppdev="yes"],
 482    [ac_cv_c_ppdev="no"])
 483  )
 484 if test "$ac_cv_c_ppdev" = "yes"
 485 then
 486     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 487 fi
 488
 489 dnl **** Check for va_copy ****
 490 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 491  AC_TRY_LINK(
 492    [#include <stdarg.h>],
 493    [va_list ap1, ap2;
 494     va_copy(ap1,ap2);
 495    ],
 496    [ac_cv_c_va_copy="yes"],
 497    [ac_cv_c_va_copy="no"])
 498  )
 499 if test "$ac_cv_c_va_copy" = "yes"
 500 then
 501     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 502 fi
 503 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 504  AC_TRY_LINK(
 505    [#include <stdarg.h>],
 506    [va_list ap1, ap2;
 507     __va_copy(ap1,ap2);
 508    ],
 509    [ac_cv_c___va_copy="yes"],
 510    [ac_cv_c___va_copy="no"])
 511  )
 512 if test "$ac_cv_c___va_copy" = "yes"
 513 then
 514     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 515 fi
 516
 517 dnl **** Check for sigsetjmp ****
 518 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 519  AC_TRY_LINK(
 520    [#include <setjmp.h>],
 521    [sigjmp_buf buf;
 522     sigsetjmp( buf, 1 );
 523     siglongjmp( buf, 1 );],
 524    [ac_cv_c_sigsetjmp="yes"],
 525    [ac_cv_c_sigsetjmp="no"])
 526  )
 527 if test "$ac_cv_c_sigsetjmp" = "yes"
 528 then
 529     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 530 fi
 531
 532 dnl **** Check for pthread_rwlock_t ****
 533 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 534 #include <pthread.h>])
 535
 536 dnl **** Check for pthread functions ****
 537 ac_save_LIBS="$LIBS"
 538 LIBS="$LIBS $LIBPTHREAD"
 539 AC_CHECK_FUNCS(\
 540         pthread_getattr_np \
 541         pthread_get_stackaddr_np \
 542         pthread_get_stacksize_np \
 543 )
 544 LIBS="$ac_save_LIBS"
 545
 546 dnl **** Check for Open Sound System ****
 547 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 548
 549 AC_CACHE_CHECK([for Open Sound System],
 550         ac_cv_c_opensoundsystem,
 551         AC_TRY_COMPILE([
 552         #if defined(HAVE_SYS_SOUNDCARD_H)
 553                 #include <sys/soundcard.h>
 554         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 555                 #include <machine/soundcard.h>
 556         #elif defined(HAVE_SOUNDCARD_H)
 557                 #include <soundcard.h>
 558         #endif
 559         ],[
 560
 561 /* check for one of the Open Sound System specific SNDCTL_ defines */
 562 #if !defined(SNDCTL_DSP_STEREO)
 563 #error No open sound system
 564 #endif
 565 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 566
 567 if test "$ac_cv_c_opensoundsystem" = "yes"
 568 then
 569     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 570 fi
 571
 572 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 573         ac_cv_c_opensoundsystem_midi,
 574         AC_TRY_COMPILE([
 575         #if defined(HAVE_SYS_SOUNDCARD_H)
 576                 #include <sys/soundcard.h>
 577         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 578                 #include <machine/soundcard.h>
 579         #elif defined(HAVE_SOUNDCARD_H)
 580                 #include <soundcard.h>
 581         #endif
 582         ],[
 583
 584 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 585 #if !defined(SNDCTL_SEQ_SYNC)
 586 #error No open sound system MIDI interface
 587 #endif
 588 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 589
 590 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 591 then
 592     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 593 fi
 594
 595 dnl **** Check for aRts Sound Server ****
 596 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 597 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 598 then
 599     ARTSC_CFLAGS=""
 600     for i in `$ARTSCCONFIG --cflags`
 601     do
 602       case "$i" in
 603         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 604       esac
 605     done
 606     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 607     save_CFLAGS="$CFLAGS"
 608     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 609     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 610         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 611          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 612          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 613     CFLAGS="$save_CFLAGS"
 614 fi
 615
 616 dnl **** Check for ALSA ****
 617 AC_SUBST(ALSALIBS,"")
 618 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 619 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 620 then
 621     AC_CHECK_LIB(asound,snd_pcm_open,
 622         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 623         ALSALIBS="-lasound")
 624 fi
 625
 626 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 627
 628 AC_SUBST(AUDIOIOLIBS,"")
 629 AC_CHECK_HEADERS(libaudioio.h,
 630     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 631                   [AUDIOIOLIBS="-laudioio"
 632                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 633
 634 dnl **** Check for lcms ****
 635
 636 AC_CHECK_HEADERS(lcms.h,
 637     [AC_CHECK_LIB(lcms,cmsOpenProfileFromFile,
 638         [AC_DEFINE(HAVE_LCMS,1,[Define if you have lcms libs and headers])
 639          AC_SUBST(LCMSLIBS,"-llcms")
 640     ])
 641 ])
 642
 643 dnl **** Check for capi4linux ****
 644
 645 AC_CHECK_HEADERS(capi20.h,[
 646         AC_CHECK_HEADERS(linux/capi.h,[
 647                 AC_CHECK_LIB(capi20,capi20_register,[
 648                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 649                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 650                 ])
 651         ])
 652 ])
 653
 654 dnl **** Check for broken glibc mmap64 ****
 655
 656 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 657         AC_TRY_RUN([
 658                 #define _FILE_OFFSET_BITS 64
 659                 #include <stdio.h>
 660                 #include <unistd.h>
 661                 #include <fcntl.h>
 662                 #include <sys/mman.h>
 663                 #include <errno.h>
 664
 665                 int main(int argc,char **argv) {
 666                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 667                         if (fd == -1) exit(1);
 668
 669                         unlink("conftest.map");
 670
 671                         write(fd,"test",4);
 672
 673                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 674                             (errno == EINVAL)
 675                         ) {
 676                                 exit(1);
 677                         }
 678                         close(fd);
 679                         fprintf(stderr,"success!\n");
 680                         exit(0);
 681                 }
 682
 683         ],
 684     ac_cv_mmap64_works="yes",
 685     ac_cv_mmap64_works="no",
 686     ac_cv_mmap64_works="no") )
 687
 688 if test "$ac_cv_mmap64_works" = "yes"
 689 then
 690     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 691 fi
 692
 693 dnl **** Check for gcc specific options ****
 694
 695 AC_SUBST(EXTRACFLAGS,"")
 696 if test "x${GCC}" = "xyes"
 697 then
 698   EXTRACFLAGS="-Wall -pipe"
 699
 700   dnl Check for strength-reduce bug
 701   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 702                   AC_TRY_RUN([
 703 int     L[[4]] = {0,1,2,3};
 704 int main(void) {
 705   static int Array[[3]];
 706   unsigned int B = 3;
 707   int i;
 708   for(i=0; i<B; i++) Array[[i]] = i - 3;
 709   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 710   L[[i]] = 4;
 711
 712   exit( Array[[1]] != -2 || L[[2]] != 3);
 713 }],
 714     ac_cv_c_gcc_strength_bug="no",
 715     ac_cv_c_gcc_strength_bug="yes",
 716     ac_cv_c_gcc_strength_bug="yes") )
 717   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 718   then
 719     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 720   fi
 721
 722   dnl Check for -fshort-wchar
 723   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 724       [WINE_TRY_CFLAGS([-fshort-wchar],
 725                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 726   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 727   then
 728       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 729   fi
 730
 731   dnl Check for -mpreferred-stack-boundary
 732   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 733       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 734                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 735   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 736   then
 737     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 738   fi
 739
 740   dnl Check for -fno-strict-aliasing
 741   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 742       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 743                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 744   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 745   then
 746     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 747   fi
 748
 749   dnl Check for -gstabs+ option
 750   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 751       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 752   if test "$ac_cv_c_gcc_gstabs" = "yes"
 753   then
 754     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 755   fi
 756
 757   dnl Check for noisy string.h
 758   saved_CFLAGS="$CFLAGS"
 759   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 760   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 761       AC_TRY_COMPILE([#include <string.h>],[],
 762                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 763   CFLAGS="$saved_CFLAGS"
 764   if test "$ac_cv_c_string_h_warnings" = "no"
 765   then
 766     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 767   fi
 768 fi
 769
 770 dnl **** Check how to define a function in assembly code ****
 771
 772 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 773   WINE_TRY_ASM_LINK(
 774       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 775       ac_cv_asm_func_def=".def",
 776     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 777       ac_cv_asm_func_def=".type @function",
 778     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 779       ac_cv_asm_func_def=".type 2",
 780       ac_cv_asm_func_def="unknown")])]))
 781
 782 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 783 case "$ac_cv_asm_func_def" in
 784   ".def")
 785      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 786   ".type @function")
 787      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 788   ".type 2")
 789      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 790   *)
 791      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 792 esac
 793
 794 dnl **** Check for underscore on external symbols ****
 795
 796 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 797     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 798                       [extern int ac_test;],
 799                       [if (ac_test) return 1],
 800                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 801
 802 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 803 if test "$ac_cv_c_extern_prefix" = "yes"
 804 then
 805   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 806 else
 807   AC_DEFINE([__ASM_NAME(name)], [name])
 808 fi
 809
 810 dnl **** Check how to do strings in assembler ****
 811
 812 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 813     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 814       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 815         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 816           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 817
 818 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 819                    [Define to the assembler keyword used to specify an ASCII string])
 820
 821 dnl **** Check for .short in assembler ****
 822
 823 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 824     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 825       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 826         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 827
 828 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 829                    [Define to the assembler keyword used to specify a word value])
 830
 831 dnl **** Check for .size in assembler ****
 832
 833 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 834     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 835                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 836
 837 if test "$ac_cv_c_asm_size" = "yes"
 838 then
 839   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 840 fi
 841
 842 dnl **** Check for working dll ****
 843
 844 AC_SUBST(DLLEXT,"")
 845 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 846 AC_SUBST(DLLIBS,"")
 847 AC_SUBST(LDSHARED,"")
 848 AC_SUBST(LDDLLFLAGS,"")
 849 AC_SUBST(LIBEXT,"so")
 850 AC_SUBST(IMPLIBEXT,"def")
 851
 852 case $host_os in
 853   cygwin*|mingw32*)
 854     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 855     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 856     if test "$DLLWRAP" = "false"; then
 857       LIBEXT="a"
 858     else
 859       dnl FIXME - check whether dllwrap works correctly...
 860       LIBEXT="dll"
 861     fi
 862     IMPLIBEXT="a"
 863     dnl We can't build 16-bit NE dlls
 864     WIN16_FILES=""
 865     WIN16_INSTALL=""
 866     ;;
 867   *)
 868     AC_CHECK_HEADERS(dlfcn.h,
 869         [AC_CHECK_FUNCS(dlopen,,
 870             [AC_CHECK_LIB(dl,dlopen,
 871                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 872                           DLLIBS="-ldl"],
 873                          [LIBEXT="a"])])],
 874         [LIBEXT="a"])
 875
 876     if test "$LIBEXT" = "so"
 877     then
 878       DLLFLAGS="$DLLFLAGS -fPIC"
 879       DLLEXT=".so"
 880       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 881           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 882                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 883       if test "$ac_cv_c_dll_gnuelf" = "yes"
 884       then
 885         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 886         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 887         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 888           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 889                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 890         if test "$ac_cv_c_dll_zdefs" = "yes"
 891         then
 892           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 893         fi
 894
 895         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 896           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 897                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 898         if test "$ac_cv_c_dll_init_fini" = "yes"
 899         then
 900           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 901         fi
 902
 903         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 904           [echo '{ global: *; };' >conftest.map
 905            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 906                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 907            rm -f conftest.map])
 908         if test "$ac_cv_c_ld_version_scripts" = "yes"
 909         then
 910           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 911         fi
 912
 913         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 914           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 915                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 916         if test "$ac_cv_c_export_dynamic" = "yes"
 917         then
 918           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 919         fi
 920
 921         case $host_cpu in
 922           *i[[3456789]]86*)
 923             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 924               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 925                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 926             if test "$ac_cv_ld_reloc_exec" = "yes"
 927             then
 928               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 929             fi
 930             ;;
 931         esac
 932
 933       else
 934         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 935             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 936                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 937         if test "$ac_cv_c_dll_unixware" = "yes"
 938         then
 939           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 940           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 941
 942         else
 943           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 944             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 945           if test "$ac_cv_c_dll_macho" = "yes"
 946           then
 947             LIBEXT="dylib"
 948             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 949             LDSHARED="\$(CC) -dynamiclib"
 950             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 951             STRIP="$STRIP -u -r"
 952             dnl Relocate wine executable
 953             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 954             dnl Relocate libwine.dyld too
 955             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 956             dnl declare needed frameworks
 957             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 958             AC_SUBST(IOKITLIB,"-framework IOKit")
 959             dnl using IOKit imply we use CoreFoundation too
 960             IOKITLIB = "$IOKITLIB $COREFOUNDATIONLIB"
 961           fi
 962         fi
 963       fi
 964     fi
 965
 966     dnl Check for cross compiler to build test programs
 967     AC_SUBST(CROSSTEST,"")
 968     if test "$cross_compiling" = "no"
 969     then
 970       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 971       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 972       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 973       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 974     fi
 975     ;;
 976 esac
 977
 978 if test "$LIBEXT" = "a"; then
 979   AC_MSG_ERROR(
 980 [could not find a way to build shared libraries.
 981 It is currently not possible to build Wine without shared library
 982 (.so) support to allow transparent switch between .so and .dll files.
 983 If you are using Linux, you will need a newer binutils.]
 984 )
 985 fi
 986
 987 case $build_os in
 988   cygwin*|mingw32*)
 989     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 990   darwin*|macosx*)
 991     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 992   *)
 993     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 994 esac
 995
 996 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
 997 case $host_os in
 998   mingw32*)
 999     AC_SUBST(CRTLIBS,"-lmsvcrt")
1000     AC_SUBST(SOCKETLIBS,"-lws2_32")
1001     ;;
1002 esac
1003
1004 case $host_os in
1005   linux*)
1006     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
1007     AC_SUBST(MAIN_BINARY,"wine-glibc")
1008     ;;
1009   darwin*)
1010     AC_SUBST(WINE_BINARIES,"wine-pthread")
1011     AC_SUBST(MAIN_BINARY,"wine-pthread")
1012     ;;
1013   *)
1014     AC_SUBST(WINE_BINARIES,"wine-kthread")
1015     AC_SUBST(MAIN_BINARY,"wine-kthread")
1016     ;;
1017 esac
1018
1019 dnl **** Get the soname for libraries that we load dynamically ****
1020
1021 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1022 then
1023   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1024   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1025   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1026   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1027   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1028   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1029   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1030   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1031   WINE_GET_SONAME(cups,cupsGetDefault)
1032   WINE_GET_SONAME(jack,jack_client_new)
1033   WINE_GET_SONAME(fontconfig,FcInit)
1034   WINE_GET_SONAME(ssl,SSL_library_init)
1035   WINE_GET_SONAME(crypto,BIO_new_socket)
1036   WINE_GET_SONAME(ncurses,waddch)
1037   WINE_GET_SONAME(curses,waddch)
1038   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1039   WINE_GET_SONAME(ungif,DGifOpen)
1040   WINE_GET_SONAME(gif,DGifOpen)
1041 fi
1042
1043
1044 dnl **** Check for functions ****
1045
1046 AC_FUNC_ALLOCA()
1047 AC_CHECK_FUNCS(\
1048         _lwp_create \
1049         _lwp_self \
1050         _pclose \
1051         _popen \
1052         _snprintf \
1053         _spawnvp \
1054         _stricmp \
1055         _strnicmp \
1056         _vsnprintf \
1057         chsize \
1058         clone \
1059         finite \
1060         fpclass \
1061         fstatfs \
1062         fstatvfs \
1063         ftruncate \
1064         ftruncate64 \
1065         futimes \
1066         getnetbyaddr \
1067         getnetbyname \
1068         getopt_long \
1069         getpagesize \
1070         getprotobyname \
1071         getprotobynumber \
1072         getpwuid \
1073         getservbyport \
1074         gettid \
1075         gettimeofday \
1076         inet_network \
1077         lseek64 \
1078         lstat \
1079         memmove \
1080         mmap \
1081         pclose \
1082         popen \
1083         pread \
1084         pwrite \
1085         readlink \
1086         rfork \
1087         select \
1088         sendmsg \
1089         settimeofday \
1090         sigaltstack \
1091         snprintf \
1092         spawnvp \
1093         statfs \
1094         statvfs \
1095         strcasecmp \
1096         strerror \
1097         strncasecmp \
1098         tcgetattr \
1099         timegm \
1100         usleep \
1101         vfscanf \
1102         vsnprintf \
1103         wait4 \
1104         waitpid \
1105 )
1106
1107 dnl **** Check for header files ****
1108
1109 AC_CHECK_HEADERS(\
1110         arpa/inet.h \
1111         arpa/nameser.h \
1112         cups/cups.h \
1113         direct.h \
1114         elf.h \
1115         float.h \
1116         fontconfig/fontconfig.h \
1117         getopt.h \
1118         gif_lib.h \
1119         ieeefp.h \
1120         io.h \
1121         jack/jack.h \
1122         jpeglib.h \
1123         libio.h \
1124         libutil.h \
1125         link.h \
1126         linux/cdrom.h \
1127         linux/compiler.h \
1128         linux/hdreg.h \
1129         linux/input.h \
1130         linux/ioctl.h \
1131         linux/joystick.h \
1132         linux/major.h \
1133         linux/param.h \
1134         linux/serial.h \
1135         linux/ucdrom.h \
1136         machine/cpu.h \
1137         mntent.h \
1138         netdb.h \
1139         netinet/in.h \
1140         netinet/in_systm.h \
1141         netinet/tcp.h \
1142         netinet/tcp_fsm.h \
1143         openssl/ssl.h \
1144         process.h \
1145         pthread.h \
1146         pty.h \
1147         pwd.h \
1148         regex.h \
1149         sched.h \
1150         scsi/sg.h \
1151         scsi/scsi.h \
1152         scsi/scsi_ioctl.h \
1153         socket.h \
1154         stdint.h \
1155         strings.h \
1156         sys/cdio.h \
1157         sys/elf32.h \
1158         sys/errno.h \
1159         sys/exec_elf.h \
1160         sys/file.h \
1161         sys/filio.h \
1162         sys/inttypes.h \
1163         sys/ioctl.h \
1164         sys/ipc.h \
1165         sys/link.h \
1166         sys/lwp.h \
1167         sys/mman.h \
1168         sys/modem.h \
1169         sys/msg.h \
1170         sys/param.h \
1171         sys/poll.h \
1172         sys/ptrace.h \
1173         sys/reg.h \
1174         sys/scsiio.h \
1175         sys/shm.h \
1176         sys/signal.h \
1177         sys/socket.h \
1178         sys/sockio.h \
1179         sys/statfs.h \
1180         sys/statvfs.h \
1181         sys/strtio.h \
1182         sys/syscall.h \
1183         sys/sysctl.h \
1184         sys/time.h \
1185         sys/times.h \
1186         sys/uio.h \
1187         sys/un.h \
1188         sys/v86.h \
1189         sys/v86intr.h \
1190         sys/vfs.h \
1191         sys/vm86.h \
1192         sys/wait.h \
1193         syscall.h \
1194         termios.h \
1195         unistd.h \
1196         utime.h \
1197         valgrind/memcheck.h
1198 )
1199 AC_HEADER_STAT()
1200
1201 dnl **** Checks for headers that depend on other ones ****
1202
1203 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1204     [#include <sys/types.h>
1205      #if HAVE_SYS_PARAM_H
1206      # include <sys/param.h>
1207      #endif])
1208
1209 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1210     [#include <sys/types.h>
1211      #if HAVE_SYS_SOCKET_H
1212      # include <sys/socket.h>
1213      #endif])
1214
1215 AC_CHECK_HEADERS([resolv.h],,,
1216     [#include <sys/types.h>
1217      #if HAVE_SYS_SOCKET_H
1218      # include <sys/socket.h>
1219      #endif
1220      #if HAVE_NETINET_IN_H
1221      # include <netinet/in.h>
1222      #endif
1223      #if HAVE_ARPA_NAMESER_H
1224      # include <arpa/nameser.h>
1225      #endif])
1226
1227 AC_CHECK_HEADERS(netinet/ip.h,,,
1228     [#include <sys/types.h>
1229      #if HAVE_SYS_SOCKET_H
1230      # include <sys/socket.h>
1231      #endif
1232      #if HAVE_NETINET_IN_SYSTM_H
1233      # include <netinet/in_systm.h>
1234      #endif])
1235
1236 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1237
1238 dnl **** Check for IPX headers (currently Linux only) ****
1239
1240 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1241  AC_TRY_COMPILE(
1242    [#include <sys/types.h>
1243     #ifdef HAVE_SYS_SOCKET_H
1244     # include <sys/socket.h>
1245     #endif
1246     #include <netipx/ipx.h>],
1247    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1248    [ac_cv_c_ipx_gnu="yes"],
1249    [ac_cv_c_ipx_gnu="no"])
1250  )
1251 if test "$ac_cv_c_ipx_gnu" = "yes"
1252 then
1253     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1254 fi
1255
1256 if test "$ac_cv_c_ipx_gnu" = "no"
1257 then
1258  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1259   AC_TRY_COMPILE(
1260     [#include <sys/types.h>
1261      #ifdef HAVE_SYS_SOCKET_H
1262      # include <sys/socket.h>
1263      #endif
1264      #include <asm/types.h>
1265      #include <linux/ipx.h>],
1266     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1267     [ac_cv_c_ipx_linux="yes"],
1268     [ac_cv_c_ipx_linux="no"])
1269   )
1270   if test "$ac_cv_c_ipx_linux" = "yes"
1271   then
1272       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1273   fi
1274 fi
1275
1276 dnl **** Check for types ****
1277
1278 AC_C_CONST
1279 AC_C_INLINE
1280 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1281
1282 AC_CACHE_CHECK([whether linux/input.h is for real],
1283         wine_cv_linux_input_h,
1284         AC_TRY_COMPILE([
1285             #include <linux/input.h>
1286         ] , [
1287             int foo = EVIOCGBIT(EV_ABS,42);
1288             int bar = BTN_PINKIE;
1289             int fortytwo = 42;
1290         ],
1291         wine_cv_linux_input_h=yes,
1292         wine_cv_linux_input_h=no,
1293         no
1294         )
1295     )
1296     if test "$wine_cv_linux_input_h" = "yes"
1297     then
1298         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1299                   [Define if we have linux/input.h AND it contains the INPUT event API])
1300     fi
1301
1302
1303 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1304         wine_cv_linux_gethostbyname_r_6,
1305         AC_TRY_LINK([
1306 #include <netdb.h>
1307         ], [
1308     char *name=NULL;
1309     struct hostent he;
1310     struct hostent *result;
1311     char *buf=NULL;
1312     int bufsize=0;
1313     int res,errnr;
1314     char *addr=NULL;
1315     int addrlen=0;
1316     int addrtype=0;
1317     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1318     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1319     ],
1320         wine_cv_linux_gethostbyname_r_6=yes,
1321         wine_cv_linux_gethostbyname_r_6=no
1322         )
1323    )
1324    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1325    then
1326       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1327                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1328    fi
1329
1330 if test "$ac_cv_header_linux_joystick_h" = "yes"
1331 then
1332    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1333         wine_cv_linux_joystick_22_api,
1334         AC_TRY_COMPILE([
1335         #include <sys/ioctl.h>
1336         #include <linux/joystick.h>
1337
1338         struct js_event blub;
1339         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1340         #error "no 2.2 header"
1341         #endif
1342         ],/*empty*/,
1343         wine_cv_linux_joystick_22_api=yes,
1344         wine_cv_linux_joystick_22_api=no,
1345         wine_cv_linux_joystick_22_api=no
1346         )
1347    )
1348    if test "$wine_cv_linux_joystick_22_api" = "yes"
1349    then
1350       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1351                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1352    fi
1353 fi
1354
1355 dnl **** statfs checks ****
1356
1357 if test "$ac_cv_header_sys_vfs_h" = "yes"
1358 then
1359     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1360                     wine_cv_sys_vfs_has_statfs,
1361         AC_TRY_COMPILE([
1362         #include <sys/types.h>
1363         #ifdef HAVE_SYS_PARAM_H
1364         # include <sys/param.h>
1365         #endif
1366         #include <sys/vfs.h>
1367         ],[
1368                 struct statfs stfs;
1369
1370                 memset(&stfs,0,sizeof(stfs));
1371         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1372         )
1373     )
1374     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1375     then
1376       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1377                 [Define if the struct statfs is defined by <sys/vfs.h>])
1378     fi
1379 fi
1380
1381 if test "$ac_cv_header_sys_statfs_h" = "yes"
1382 then
1383     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1384                     wine_cv_sys_statfs_has_statfs,
1385         AC_TRY_COMPILE([
1386         #include <sys/types.h>
1387         #ifdef HAVE_SYS_PARAM_H
1388         # include <sys/param.h>
1389         #endif
1390         #include <sys/statfs.h>
1391         ],[
1392                 struct statfs stfs;
1393         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1394         )
1395     )
1396     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1397     then
1398       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1399                 [Define if the struct statfs is defined by <sys/statfs.h>])
1400     fi
1401 fi
1402
1403 if test "$ac_cv_header_sys_mount_h" = "yes"
1404 then
1405     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1406                     wine_cv_sys_mount_has_statfs,
1407         AC_TRY_COMPILE([
1408         #include <sys/types.h>
1409         #ifdef HAVE_SYS_PARAM_H
1410         # include <sys/param.h>
1411         #endif
1412         #include <sys/mount.h>
1413         ],[
1414                 struct statfs stfs;
1415         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1416         )
1417     )
1418     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1419     then
1420       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1421                 [Define if the struct statfs is defined by <sys/mount.h>])
1422     fi
1423 fi
1424
1425 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1426
1427 dnl Check for statfs members
1428 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1429 [#include <sys/types.h>
1430 #ifdef HAVE_SYS_PARAM_H
1431 # include <sys/param.h>
1432 #endif
1433 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1434 # include <sys/mount.h>
1435 #else
1436 # ifdef STATFS_DEFINED_BY_SYS_VFS
1437 #  include <sys/vfs.h>
1438 # else
1439 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1440 #   include <sys/statfs.h>
1441 #  endif
1442 # endif
1443 #endif])
1444
1445 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1446 [#ifdef HAVE_SYS_STATVFS_H
1447 #include <sys/statvfs.h>
1448 #endif])
1449
1450 dnl Check for socket structure members
1451 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1452 [#include <sys/types.h>
1453 #ifdef HAVE_SYS_SOCKET_H
1454 # include <sys/socket.h>
1455 #endif
1456 #ifdef HAVE_SYS_UN_H
1457 # include <sys/un.h>
1458 #endif])
1459
1460 dnl Check for siginfo_t members
1461 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1462
1463 dnl Check for struct option
1464 AC_CHECK_MEMBERS([struct option.name],,,
1465 [#ifdef HAVE_GETOPT_H
1466 #include <getopt.h>
1467 #endif])
1468
1469 dnl Check for stat.st_blocks
1470 AC_CHECK_MEMBERS([struct stat.st_blocks])
1471
1472 dnl *** check for the need to define platform-specific symbols
1473
1474 case $host_cpu in
1475   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1476   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1477   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1478   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1479 esac
1480
1481 case $host_vendor in
1482   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1483 esac
1484
1485 dnl **** Generate output files ****
1486
1487 AH_TOP([#define __WINE_CONFIG_H])
1488
1489 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1490 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1491 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1492 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1493 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1494 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1495 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1496 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1497 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1498 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1499 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1500 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1501 WINE_CONFIG_EXTRA_DIR(include/wine)
1502 WINE_CONFIG_EXTRA_DIR(misc)
1503 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1504 WINE_CONFIG_EXTRA_DIR(windows)
1505
1506 MAKE_RULES=Make.rules
1507 AC_SUBST_FILE(MAKE_RULES)
1508
1509 MAKE_DLL_RULES=dlls/Makedll.rules
1510 AC_SUBST_FILE(MAKE_DLL_RULES)
1511
1512 MAKE_TEST_RULES=dlls/Maketest.rules
1513 AC_SUBST_FILE(MAKE_TEST_RULES)
1514
1515 MAKE_LIB_RULES=libs/Makelib.rules
1516 AC_SUBST_FILE(MAKE_LIB_RULES)
1517
1518 MAKE_PROG_RULES=programs/Makeprog.rules
1519 AC_SUBST_FILE(MAKE_PROG_RULES)
1520
1521 AC_CONFIG_FILES([
1522 Make.rules
1523 dlls/Makedll.rules
1524 dlls/Maketest.rules
1525 libs/Makelib.rules
1526 programs/Makeprog.rules
1527 Makefile
1528 dlls/Makefile
1529 dlls/advapi32/Makefile
1530 dlls/advapi32/tests/Makefile
1531 dlls/amstream/Makefile
1532 dlls/atl/Makefile
1533 dlls/avicap32/Makefile
1534 dlls/avifil32/Makefile
1535 dlls/cabinet/Makefile
1536 dlls/capi2032/Makefile
1537 dlls/cards/Makefile
1538 dlls/cfgmgr32/Makefile
1539 dlls/comcat/Makefile
1540 dlls/comctl32/Makefile
1541 dlls/comctl32/tests/Makefile
1542 dlls/commdlg/Makefile
1543 dlls/crtdll/Makefile
1544 dlls/crypt32/Makefile
1545 dlls/ctl3d/Makefile
1546 dlls/d3d8/Makefile
1547 dlls/d3d9/Makefile
1548 dlls/d3dim/Makefile
1549 dlls/d3drm/Makefile
1550 dlls/d3dx8/Makefile
1551 dlls/d3dxof/Makefile
1552 dlls/dbghelp/Makefile
1553 dlls/dciman32/Makefile
1554 dlls/ddraw/Makefile
1555 dlls/ddraw/tests/Makefile
1556 dlls/devenum/Makefile
1557 dlls/dinput/Makefile
1558 dlls/dinput8/Makefile
1559 dlls/dmband/Makefile
1560 dlls/dmcompos/Makefile
1561 dlls/dmime/Makefile
1562 dlls/dmloader/Makefile
1563 dlls/dmscript/Makefile
1564 dlls/dmstyle/Makefile
1565 dlls/dmsynth/Makefile
1566 dlls/dmusic/Makefile
1567 dlls/dmusic32/Makefile
1568 dlls/dplay/Makefile
1569 dlls/dplayx/Makefile
1570 dlls/dpnet/Makefile
1571 dlls/dpnhpast/Makefile
1572 dlls/dsound/Makefile
1573 dlls/dsound/tests/Makefile
1574 dlls/dswave/Makefile
1575 dlls/dxdiagn/Makefile
1576 dlls/dxerr8/Makefile
1577 dlls/dxerr9/Makefile
1578 dlls/dxguid/Makefile
1579 dlls/gdi/Makefile
1580 dlls/gdi/tests/Makefile
1581 dlls/glu32/Makefile
1582 dlls/glut32/Makefile
1583 dlls/hhctrl.ocx/Makefile
1584 dlls/iccvid/Makefile
1585 dlls/icmp/Makefile
1586 dlls/ifsmgr.vxd/Makefile
1587 dlls/imagehlp/Makefile
1588 dlls/imm32/Makefile
1589 dlls/iphlpapi/Makefile
1590 dlls/iphlpapi/tests/Makefile
1591 dlls/itss/Makefile
1592 dlls/kernel/Makefile
1593 dlls/kernel/tests/Makefile
1594 dlls/lzexpand/Makefile
1595 dlls/mapi32/Makefile
1596 dlls/mapi32/tests/Makefile
1597 dlls/mlang/Makefile
1598 dlls/mlang/tests/Makefile
1599 dlls/mmdevldr.vxd/Makefile
1600 dlls/monodebg.vxd/Makefile
1601 dlls/mpr/Makefile
1602 dlls/msacm/Makefile
1603 dlls/msacm/imaadp32/Makefile
1604 dlls/msacm/msadp32/Makefile
1605 dlls/msacm/msg711/Makefile
1606 dlls/msacm/winemp3/Makefile
1607 dlls/msacm/tests/Makefile
1608 dlls/mscms/Makefile
1609 dlls/msdmo/Makefile
1610 dlls/mshtml/Makefile
1611 dlls/msi/Makefile
1612 dlls/msimg32/Makefile
1613 dlls/msisys/Makefile
1614 dlls/msnet32/Makefile
1615 dlls/msrle32/Makefile
1616 dlls/msvcrt/Makefile
1617 dlls/msvcrt/tests/Makefile
1618 dlls/msvcrt20/Makefile
1619 dlls/msvcrt40/Makefile
1620 dlls/msvcrtd/Makefile
1621 dlls/msvcrtd/tests/Makefile
1622 dlls/msvidc32/Makefile
1623 dlls/msvideo/Makefile
1624 dlls/mswsock/Makefile
1625 dlls/netapi32/Makefile
1626 dlls/netapi32/tests/Makefile
1627 dlls/newdev/Makefile
1628 dlls/ntdll/Makefile
1629 dlls/ntdll/tests/Makefile
1630 dlls/odbc32/Makefile
1631 dlls/ole32/Makefile
1632 dlls/ole32/tests/Makefile
1633 dlls/oleacc/Makefile
1634 dlls/oleaut32/Makefile
1635 dlls/oleaut32/tests/Makefile
1636 dlls/olecli/Makefile
1637 dlls/oledlg/Makefile
1638 dlls/olepro32/Makefile
1639 dlls/olesvr/Makefile
1640 dlls/opengl32/Makefile
1641 dlls/psapi/Makefile
1642 dlls/psapi/tests/Makefile
1643 dlls/qcap/Makefile
1644 dlls/quartz/Makefile
1645 dlls/quartz/tests/Makefile
1646 dlls/rasapi32/Makefile
1647 dlls/richedit/Makefile
1648 dlls/rpcrt4/Makefile
1649 dlls/rpcrt4/tests/Makefile
1650 dlls/rsabase/Makefile
1651 dlls/rsabase/tests/Makefile
1652 dlls/secur32/Makefile
1653 dlls/serialui/Makefile
1654 dlls/setupapi/Makefile
1655 dlls/shdocvw/Makefile
1656 dlls/shell32/Makefile
1657 dlls/shell32/tests/Makefile
1658 dlls/shfolder/Makefile
1659 dlls/shlwapi/Makefile
1660 dlls/shlwapi/tests/Makefile
1661 dlls/snmpapi/Makefile
1662 dlls/sti/Makefile
1663 dlls/strmiids/Makefile
1664 dlls/tapi32/Makefile
1665 dlls/ttydrv/Makefile
1666 dlls/twain/Makefile
1667 dlls/unicows/Makefile
1668 dlls/url/Makefile
1669 dlls/urlmon/Makefile
1670 dlls/urlmon/tests/Makefile
1671 dlls/user/Makefile
1672 dlls/user/tests/Makefile
1673 dlls/uuid/Makefile
1674 dlls/uxtheme/Makefile
1675 dlls/vdhcp.vxd/Makefile
1676 dlls/vdmdbg/Makefile
1677 dlls/version/Makefile
1678 dlls/version/tests/Makefile
1679 dlls/vmm.vxd/Makefile
1680 dlls/vnbt.vxd/Makefile
1681 dlls/vnetbios.vxd/Makefile
1682 dlls/vtdapi.vxd/Makefile
1683 dlls/vwin32.vxd/Makefile
1684 dlls/win32s/Makefile
1685 dlls/winaspi/Makefile
1686 dlls/wined3d/Makefile
1687 dlls/winedos/Makefile
1688 dlls/wineps/Makefile
1689 dlls/wininet/Makefile
1690 dlls/wininet/tests/Makefile
1691 dlls/winmm/Makefile
1692 dlls/winmm/joystick/Makefile
1693 dlls/winmm/mcianim/Makefile
1694 dlls/winmm/mciavi/Makefile
1695 dlls/winmm/mcicda/Makefile
1696 dlls/winmm/mciseq/Makefile
1697 dlls/winmm/mciwave/Makefile
1698 dlls/winmm/midimap/Makefile
1699 dlls/winmm/tests/Makefile
1700 dlls/winmm/wavemap/Makefile
1701 dlls/winmm/winealsa/Makefile
1702 dlls/winmm/winearts/Makefile
1703 dlls/winmm/wineaudioio/Makefile
1704 dlls/winmm/winejack/Makefile
1705 dlls/winmm/winenas/Makefile
1706 dlls/winmm/wineoss/Makefile
1707 dlls/winnls/Makefile
1708 dlls/winsock/Makefile
1709 dlls/winsock/tests/Makefile
1710 dlls/winspool/Makefile
1711 dlls/winspool/tests/Makefile
1712 dlls/wintab32/Makefile
1713 dlls/wintrust/Makefile
1714 dlls/wow32/Makefile
1715 dlls/wsock32/Makefile
1716 dlls/x11drv/Makefile
1717 documentation/Makefile
1718 fonts/Makefile
1719 include/Makefile
1720 libs/Makefile
1721 libs/port/Makefile
1722 libs/unicode/Makefile
1723 libs/wine/Makefile
1724 libs/wpp/Makefile
1725 loader/Makefile
1726 programs/Makefile
1727 programs/avitools/Makefile
1728 programs/clock/Makefile
1729 programs/cmdlgtst/Makefile
1730 programs/control/Makefile
1731 programs/expand/Makefile
1732 programs/msiexec/Makefile
1733 programs/notepad/Makefile
1734 programs/progman/Makefile
1735 programs/regedit/Makefile
1736 programs/regsvr32/Makefile
1737 programs/rpcss/Makefile
1738 programs/rundll32/Makefile
1739 programs/start/Makefile
1740 programs/taskmgr/Makefile
1741 programs/uninstaller/Makefile
1742 programs/view/Makefile
1743 programs/wcmd/Makefile
1744 programs/wineboot/Makefile
1745 programs/winebrowser/Makefile
1746 programs/winecfg/Makefile
1747 programs/wineconsole/Makefile
1748 programs/winedbg/Makefile
1749 programs/winefile/Makefile
1750 programs/winemenubuilder/Makefile
1751 programs/winemine/Makefile
1752 programs/winepath/Makefile
1753 programs/winetest/Makefile
1754 programs/winevdm/Makefile
1755 programs/winhelp/Makefile
1756 programs/winver/Makefile
1757 server/Makefile
1758 tools/Makefile
1759 tools/widl/Makefile
1760 tools/winapi/Makefile
1761 tools/winebuild/Makefile
1762 tools/winedump/Makefile
1763 tools/winegcc/Makefile
1764 tools/wmc/Makefile
1765 tools/wrc/Makefile])
1766
1767 AC_OUTPUT
1768
1769 if test "$have_x" = "no"
1770 then
1771   echo
1772   echo "*** Warning: X development files not found. Wine will be built without"
1773   echo "*** X support, which currently does not work, and would probably not be"
1774   echo "*** what you want anyway. You will need to install devel packages of"
1775   echo "*** Xlib/Xfree86 at the very least."
1776 fi
1777
1778 if test "$wine_cv_opengl_version_OK" = "no"
1779 then
1780   echo
1781   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1782   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1783 fi
1784
1785 if test "$wine_cv_msg_freetype" = "yes"
1786 then
1787   echo
1788   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1789   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1790   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1791   echo "*** enable Wine to use TrueType fonts."
1792 fi
1793
1794 echo
1795 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1796 echo
1797
1798 dnl Local Variables:
1799 dnl comment-start: "dnl "
1800 dnl comment-end: ""
1801 dnl comment-start-skip: "\\bdnl\\b\\s *"
1802 dnl compile-command: "autoconf"
1803 dnl End: