git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(dll,
  19 [  --disable-dll           build static libraries instead of DLLs],
  20 [if test "$enableval" = "no"; then LIBEXT="a"; fi])
  21
  22 AC_ARG_ENABLE(debug,
  23 [  --disable-debug         compile out all debugging messages],
  24 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  25
  26 AC_ARG_ENABLE(opengl,
  27 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe],
  28 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  29
  30 AC_ARG_ENABLE(trace,
  31 [  --disable-trace         compile out TRACE messages],
  32 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  33
  34 AC_ARG_WITH(curses,
  35 [  --without-curses        do not use curses],
  36 [if test "$withval" = "no"; then CURSES="no"; fi])
  37
  38 AC_ARG_WITH(reentrant-x,
  39 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  40
  41 AC_SUBST(OPTIONS)
  42
  43 if test "$DEBUG_MSGS" = "no"
  44 then
  45     AC_DEFINE(NO_DEBUG_MSGS)
  46     AC_DEFINE(NO_TRACE_MSGS)
  47 else
  48     if test "$TRACE_MSGS" = "no"
  49     then
  50         AC_DEFINE(NO_TRACE_MSGS)
  51     fi
  52 fi
  53
  54 dnl **** Check for some programs ****
  55
  56 AC_PROG_MAKE_SET
  57 AC_PROG_CC
  58 AC_PROG_CPP
  59 AC_PATH_XTRA
  60 AC_PROG_YACC
  61 AC_PROG_LEX
  62 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  63 if test "$XLEX" = "none"
  64 then
  65         echo "*** Error: No suitable lex found. ***"
  66         echo "    Please install the 'flex' package."
  67         exit 1
  68 fi
  69 AC_DECL_YYTEXT
  70 AC_PROG_RANLIB
  71 AC_PROG_INSTALL
  72 AC_PROG_LN_S
  73 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  74 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  75
  76 dnl Check for lint
  77 AC_CHECK_PROGS(LINT, lclint lint)
  78 if test "$LINT" = "lint"
  79 then
  80   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  81   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  82 fi
  83 AC_SUBST(LINT)
  84 AC_SUBST(LINTFLAGS)
  85
  86 dnl **** Check for some libraries ****
  87
  88 dnl Check for -lm for BeOS
  89 AC_CHECK_LIB(m,sqrt)
  90 dnl Check for -li386 for NetBSD and OpenBSD
  91 AC_CHECK_LIB(i386,i386_set_ldt)
  92 dnl Check for -lossaudio for NetBSD
  93 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  94 dnl Check for -lw for Solaris
  95 AC_CHECK_LIB(w,iswalnum)
  96 dnl Check for -lnsl for Solaris
  97 AC_CHECK_FUNCS(gethostbyname,, AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", AC_CHECK_LIB(socket, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", , -lnsl), -lsocket))
  98 dnl Check for -lsocket for Solaris
  99 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 100 dnl Check for -lxpg4 for FreeBSD
 101 AC_CHECK_LIB(xpg4,setrunelocale)
 102 dnl Check for -lmmap for OS/2
 103 AC_CHECK_LIB(mmap,mmap)
 104 dnl Check for openpty
 105 AC_CHECK_FUNCS(openpty,,
 106         AC_CHECK_LIB(util,openpty,
 107                 AC_DEFINE(HAVE_OPENPTY)
 108                 LIBS="$LIBS -lutil"
 109         ))
 110
 111 AC_CHECK_HEADERS(dlfcn.h,
 112         AC_CHECK_FUNCS(dlopen,
 113                 AC_DEFINE(HAVE_DL_API),
 114                 AC_CHECK_LIB(dl,dlopen,
 115                         AC_DEFINE(HAVE_DL_API)
 116                         LIBS="$LIBS -ldl",
 117                         LIBEXT="a"
 118                 )
 119         ),
 120         LIBEXT="a"
 121 )
 122 AC_SUBST(XLIB)
 123 AC_SUBST(X_DLLS)
 124 X_DLLS=""
 125 AC_SUBST(XFILES)
 126 XFILES=""
 127 AC_SUBST(OPENGLFILES)
 128 OPENGLFILES=""
 129 AC_SUBST(OPENGL32_DLL)
 130 OPENGL32_DLL=""
 131 AC_SUBST(DGA_SRCS)
 132 DGA_SRCS=""
 133 AC_SUBST(DGA2_SRCS)
 134 DGA2_SRCS=""
 135 AC_SUBST(MESA_SRCS)
 136 MESA_SRCS=""
 137 if test "$have_x" = "yes"
 138 then
 139     XLIB="-lXext -lX11"
 140     ac_save_CPPFLAGS="$CPPFLAGS"
 141     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 142
 143     dnl *** Check for -lXpm
 144     AC_CHECK_HEADERS(X11/xpm.h,
 145       [ dnl *** If X11/xpm.h exists...
 146         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 147           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 148           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 149         )
 150       ],
 151       [ dnl *** If X11/xpm.h does not exist...
 152         dnl NOTE: autoconf does not allow commas inside the third
 153         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 154         dnl       magic it does.
 155         echo "Redhat            :       xpm xpm-devel"
 156         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 157         echo "SuSE              :       xpm"
 158         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 159         echo
 160         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 161         echo "the directory /contrib/libraries."
 162         echo
 163         exit 1
 164       ]
 165     )
 166
 167     dnl *** All three of the following tests require X11/Xlib.h
 168     AC_CHECK_HEADERS(X11/Xlib.h,
 169       [
 170         dnl *** Check for X Shm extension
 171         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 172             [ dnl *** If X11/extensions/XShm.h exists...
 173               AC_CHECK_LIB(Xext, XShmQueryExtension,
 174               AC_DEFINE(HAVE_LIBXXSHM),,
 175               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 176             ],
 177             AC_MSG_WARN([Xshm extension not found!!])
 178         )
 179
 180         dnl *** Check for X shape extension
 181         AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/shape.h,
 182             [ dnl *** If X11/extensions/shape.h exists...
 183               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 184               AC_DEFINE(HAVE_LIBXSHAPE),,
 185               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 186             ],
 187             AC_MSG_WARN([XShape extension found!!])
 188         )
 189
 190         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 191         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 192             [ dnl *** If X11/extensions/xf86dga.h exists, check
 193               dnl *** for XDGAQueryExtension()...
 194               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 195                 [ dnl *** If found...
 196                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 197                   AC_DEFINE(HAVE_LIBXXF86DGA)
 198                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 199                   DGA_SRCS='$(DGA_SRCS)'
 200                   DGA2_SRCS='$(DGA2_SRCS)'
 201                ],
 202                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 203                   dnl *** instead (DGA 2.0 not found)...
 204                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 205                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 206                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 207                       DGA_SRCS='$(DGA_SRCS)'
 208                     ],,
 209                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 210                   )
 211                 ],
 212                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 213               )
 214             ],
 215             AC_MSG_WARN([DGA extension not found!!])
 216         )
 217
 218         dnl *** Check for XFree86 VMODE extension
 219         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 220             [ dnl *** If X11/extensions/xf86vmode.h exists...
 221                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 222                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 223                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 224                   ],,
 225                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 226                 )
 227             ],
 228             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 229         )
 230       ]
 231     ) dnl *** End of X11/Xlib.h check
 232
 233     dnl Check for the presence of OpenGL
 234     if test $OPENGL = "yes" -o $OPENGL = "normal"
 235     then
 236         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 237         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes" -a "$ac_cv_header_GL_glext_h" = "yes"
 238         then
 239             dnl Check for some problems due to old Mesa versions
 240             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 241               AC_TRY_COMPILE(
 242                 [#include <GL/gl.h>],
 243                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 244                 [wine_cv_opengl_version_OK="yes"],
 245                 [wine_cv_opengl_version_OK="no"]
 246               )
 247             )
 248
 249             dnl Check for the thread-safety of the OpenGL library
 250             AC_CACHE_CHECK("for thread-safe OpenGL version",
 251                            wine_cv_opengl_version_threadsafe,
 252               [saved_libs=$LIBS
 253                LIBS="$X_LIBS -lGL"
 254                AC_TRY_LINK([],[pthread_getspecific();],
 255                               [wine_cv_opengl_version_threadsafe="yes"],
 256                               [wine_cv_opengl_version_threadsafe="no"])
 257                LIBS=$saved_libs]
 258             )
 259
 260             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 261             then
 262                 dnl Check for the presense of the library
 263                 AC_CHECK_LIB(GL,glXCreateContext,
 264                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 265                              MESA_SRCS='$(MESA_SRCS)'
 266                              ,,
 267                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 268
 269                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 270                 then
 271                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 272
 273                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 274                         then
 275                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 276                                   AC_TRY_COMPILE([#include <GL/gl.h>
 277                                                   #include <GL/glext.h>],
 278                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 279                                                  [AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 280                                                   wine_cv_extension_prototypes="yes"],
 281                                                  [wine_cv_extension_prototypes="no"]
 282                                   )
 283                                 )
 284
 285                                 AC_DEFINE(HAVE_OPENGL)
 286                                 OPENGL32_DLL=opengl32
 287                                 OPENGLFILES='$(OPENGLFILES)'
 288                         fi
 289                 fi
 290              fi
 291          fi
 292     fi
 293
 294     CPPFLAGS="$ac_save_CPPFLAGS"
 295     X_DLLS='$(X_DLLS)'
 296     XFILES='$(XFILES)'
 297 else
 298     XLIB=""
 299     X_CFLAGS=""
 300     X_LIBS=""
 301 fi
 302
 303 dnl **** Check which curses lib to use ***
 304 if test "$CURSES" = "yes"
 305 then
 306     AC_CHECK_HEADERS(ncurses.h)
 307     if test "$ac_cv_header_ncurses_h" = "yes"
 308     then
 309         AC_CHECK_LIB(ncurses,waddch)
 310     fi
 311     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 312     then
 313         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 314         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 315     else
 316         AC_CHECK_HEADERS(curses.h)
 317         if test "$ac_cv_header_curses_h" = "yes"
 318         then
 319             AC_CHECK_LIB(curses,waddch)
 320             if test "$ac_cv_lib_curses_waddch" = "yes"
 321             then
 322                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 323                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 324             fi
 325         fi
 326     fi
 327 fi
 328
 329 dnl **** Check for IPX (currently Linux only) ****
 330 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 331  AC_TRY_COMPILE(
 332    [#include <sys/socket.h>
 333     #include <netipx/ipx.h>],
 334    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 335    [ac_cv_c_ipx_gnu="yes"],
 336    [ac_cv_c_ipx_gnu="no"])
 337  )
 338 if test "$ac_cv_c_ipx_gnu" = "yes"
 339 then
 340     AC_DEFINE(HAVE_IPX_GNU)
 341 fi
 342
 343 if test "$ac_cv_c_ipx_gnu" = "no"
 344 then
 345  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 346   AC_TRY_COMPILE(
 347     [#include <sys/socket.h>
 348      #include <asm/types.h>
 349      #include <linux/ipx.h>],
 350     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 351     [ac_cv_c_ipx_linux="yes"],
 352     [ac_cv_c_ipx_linux="no"])
 353   )
 354   if test "$ac_cv_c_ipx_linux" = "yes"
 355   then
 356       AC_DEFINE(HAVE_IPX_LINUX)
 357   fi
 358 fi
 359
 360 dnl **** Check for Open Sound System ****
 361 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 362
 363 AC_CACHE_CHECK("for Open Sound System",
 364         ac_cv_c_opensoundsystem,
 365         AC_TRY_COMPILE([
 366         #if defined(HAVE_SYS_SOUNDCARD_H)
 367                 #include <sys/soundcard.h>
 368         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 369                 #include <machine/soundcard.h>
 370         #elif defined(HAVE_SOUNDCARD_H)
 371                 #include <soundcard.h>
 372         #endif
 373         ],[
 374
 375 /* check for one of the Open Sound System specific SNDCTL_ defines */
 376 #if !defined(SNDCTL_DSP_STEREO)
 377 #error No open sound system
 378 #endif
 379 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 380
 381 if test "$ac_cv_c_opensoundsystem" = "yes"
 382 then
 383     AC_DEFINE(HAVE_OSS)
 384 fi
 385
 386 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 387         ac_cv_c_opensoundsystem_midi,
 388         AC_TRY_COMPILE([
 389         #if defined(HAVE_SYS_SOUNDCARD_H)
 390                 #include <sys/soundcard.h>
 391         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 392                 #include <machine/soundcard.h>
 393         #elif defined(HAVE_SOUNDCARD_H)
 394                 #include <soundcard.h>
 395         #endif
 396         ],[
 397
 398 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 399 #if !defined(SNDCTL_SEQ_SYNC)
 400 #error No open sound system MIDI interface
 401 #endif
 402 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 403
 404 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 405 then
 406     AC_DEFINE(HAVE_OSS_MIDI)
 407 fi
 408
 409 dnl **** If ln -s doesn't work, use cp instead ****
 410 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 411
 412 dnl **** Check for gcc strength-reduce bug ****
 413
 414 if test "x${GCC}" = "xyes"
 415 then
 416   CFLAGS="$CFLAGS -Wall"
 417   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 418                   AC_TRY_RUN([
 419 int main(void) {
 420   static int Array[[3]];
 421   unsigned int B = 3;
 422   int i;
 423   for(i=0; i<B; i++) Array[[i]] = i - 3;
 424   exit( Array[[1]] != -2 );
 425 }],
 426     ac_cv_c_gcc_strength_bug="no",
 427     ac_cv_c_gcc_strength_bug="yes",
 428     ac_cv_c_gcc_strength_bug="yes") )
 429   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 430   then
 431     CFLAGS="$CFLAGS -fno-strength-reduce"
 432   fi
 433 fi
 434
 435 dnl **** Check for underscore on external symbols ****
 436
 437 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 438                ac_cv_c_extern_prefix,
 439 [saved_libs=$LIBS
 440 LIBS="conftest_asm.s $LIBS"
 441 cat > conftest_asm.s <<EOF
 442         .globl _ac_test
 443 _ac_test:
 444         .long 0
 445 EOF
 446 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 447             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 448 LIBS=$saved_libs])
 449 if test "$ac_cv_c_extern_prefix" = "yes"
 450 then
 451   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 452 fi
 453
 454 dnl **** Check for .string in assembler ****
 455
 456 AC_CACHE_CHECK("whether assembler accepts .string",
 457                ac_cv_c_asm_string,
 458 [saved_libs=$LIBS
 459 LIBS="conftest_asm.s $LIBS"
 460 cat > conftest_asm.s <<EOF
 461         .string "test"
 462 EOF
 463 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 464 LIBS=$saved_libs])
 465 if test "$ac_cv_c_asm_string" = "yes"
 466 then
 467   AC_DEFINE(HAVE_ASM_STRING)
 468 fi
 469
 470 dnl **** Check for working dll ****
 471
 472 LDSHARED=""
 473 if test "$LIBEXT" = "so"
 474 then
 475   AC_CACHE_CHECK("whether we can build a Linux dll",
 476                  ac_cv_c_dll_linux,
 477   [saved_cflags=$CFLAGS
 478   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 479   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 480   CFLAGS=$saved_cflags
 481   ])
 482   if test "$ac_cv_c_dll_linux" = "yes"
 483   then
 484     LDSHARED="\$(CC) -shared -Wl,-soname,\$(SONAME),-rpath,\$(libdir)"
 485   else
 486     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 487                  ac_cv_c_dll_unixware,
 488     [saved_cflags=$CFLAGS
 489     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0"
 490     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 491     CFLAGS=$saved_cflags
 492     ])
 493     if test "$ac_cv_c_dll_unixware" = "yes"
 494     then
 495       LDSHARED="\$(CC) -Wl,-G,-h,\$(libdir)/\$(SONAME)"
 496     else
 497       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 498                    ac_cv_c_dll_netbsd,
 499       [saved_cflags=$CFLAGS
 500       CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 501       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 502       CFLAGS=$saved_cflags
 503       ])
 504       if test "$ac_cv_c_dll_netbsd" = "yes"
 505       then
 506         LDSHARED="ld -Bshareable -Bforcearchive"
 507       fi
 508     fi
 509   fi
 510   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 511   then
 512     LIBEXT="a"
 513   fi
 514 fi
 515
 516 DLLFLAGS=""
 517
 518 if test "$LIBEXT" = "so"; then
 519     DLLFLAGS="-fPIC"
 520     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) -L\$(TOPOBJDIR) -lwine -lwine_unicode"
 521 else
 522     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) -L\$(TOPOBJDIR) -lwine -lwine_unicode \$(X_LIBS) \$(XLIB)"
 523     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 524                    ac_cv_c_whole_archive,
 525             [saved_cflags=$CFLAGS
 526             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 527             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 528             CFLAGS=$saved_cflags
 529             ])
 530     if test "$ac_cv_c_whole_archive" = "yes"
 531     then
 532         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 533     else
 534         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 535                        ac_cv_c_allextract,
 536                 [saved_cflags=$CFLAGS
 537                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 538                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 539                 CFLAGS=$saved_cflags
 540                 ])
 541         if test "$ac_cv_c_allextract" = "yes"
 542         then
 543             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 544         fi
 545     fi
 546 fi
 547
 548 AC_SUBST(DLL_LINK)
 549 AC_SUBST(DLLFLAGS)
 550 AC_SUBST(LDSHARED)
 551 AC_SUBST(LIBEXT)
 552
 553 dnl **** Check for reentrant libc ****
 554 dnl
 555 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 556 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 557
 558 wine_cv_libc_reentrant=no
 559 dnl
 560 dnl Linux style errno location
 561 dnl
 562 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 563   [AC_TRY_RUN([int myerrno = 0;
 564 char buf[256];
 565 int *__errno_location(){return &myerrno;}
 566 main(){connect(0,buf,255); exit(!myerrno);}],
 567   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 568   wine_cv_libc_r__errno_location=yes )
 569 ])
 570 if test "$wine_cv_libc_r__errno_location" = "yes"
 571 then
 572     AC_DEFINE(HAVE__ERRNO_LOCATION)
 573     wine_cv_libc_reentrant=__errno_location
 574 fi
 575 dnl
 576 dnl FreeBSD style errno location
 577 dnl
 578 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 579   [AC_TRY_RUN([int myerrno = 0;
 580 char buf[256];
 581 int *__error(){return &myerrno;}
 582 main(){connect(0,buf,255); exit(!myerrno);}],
 583     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 584     wine_cv_libc_r__error=yes )
 585 ])
 586 if test "$wine_cv_libc_r__error" = "yes"
 587 then
 588     AC_DEFINE(HAVE__ERROR)
 589     wine_cv_libc_reentrant=__error
 590 fi
 591 dnl
 592 dnl Solaris style errno location
 593 dnl
 594 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 595   [AC_TRY_RUN([int myerrno = 0;
 596 char buf[256];
 597 int *___errno(){return &myerrno;}
 598 main(){connect(0,buf,255); exit(!myerrno);}],
 599     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 600     wine_cv_libc_r___errno=yes )
 601 ])
 602 if test "$wine_cv_libc_r___errno" = "yes"
 603 then
 604     AC_DEFINE(HAVE___ERRNO)
 605     wine_cv_libc_reentrant=___errno
 606 fi
 607 dnl
 608 dnl UnixWare style errno location
 609 dnl
 610 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 611   [AC_TRY_RUN([int myerrno = 0;
 612 char buf[256];
 613 int *__thr_errno(){return &myerrno;}
 614 main(){connect(0,buf,255); exit(!myerrno);}],
 615     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 616     wine_cv_libc_r__thr_errno=yes )
 617 ])
 618 if test "$wine_cv_libc_r__thr_errno" = "yes"
 619 then
 620     AC_DEFINE(HAVE__THR_ERRNO)
 621     wine_cv_libc_reentrant=__thr_errno
 622 fi
 623 if test "$wine_cv_libc_reentrant" = "no"
 624 then
 625   AC_DEFINE(NO_REENTRANT_LIBC)
 626 fi
 627
 628 dnl **** Check for reentrant X libraries ****
 629 dnl
 630 dnl This may fail to determine whether X libraries are reentrant if
 631 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 632 dnl is possible with the --without-reentrant-x option.
 633
 634 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 635 then
 636 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 637   [ if test "x$with_reentrant_x" = "xno"
 638     then
 639         wine_cv_x_reentrant=no
 640     else
 641         libX11_check=none
 642         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 643             if test -r $dir/libX11.so; then
 644                 libX11_check="-D $dir/libX11.so"
 645                 break 1
 646             fi
 647             if test -r $dir/libX11.a; then
 648                 libX11_check="$dir/libX11.a"
 649                 break 1
 650             fi
 651         done
 652         if test "$libX11_check" != "none"; then
 653             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 654             then
 655                 wine_cv_x_reentrant=yes
 656             else
 657                 wine_cv_x_reentrant=no
 658             fi
 659         else
 660             wine_cv_x_reentrant=unknown
 661         fi
 662     fi ] )
 663 else
 664     wine_cv_x_reentrant=no
 665 fi
 666 if test "$wine_cv_x_reentrant" = "no"
 667 then
 668   AC_DEFINE(NO_REENTRANT_X11)
 669 fi
 670
 671 dnl **** Check for endianness ****
 672
 673 AC_C_BIGENDIAN
 674
 675 dnl **** Check for functions ****
 676
 677 AC_FUNC_ALLOCA()
 678 AC_CHECK_FUNCS(\
 679         __libc_fork \
 680         _lwp_create \
 681         clone \
 682         getnetbyaddr \
 683         getnetbyname \
 684         getpagesize \
 685         getprotobyname \
 686         getprotobynumber \
 687         getservbyport \
 688         getsockopt \
 689         inet_network \
 690         memmove \
 691         rfork \
 692         select \
 693         sendmsg \
 694         settimeofday \
 695         sigaltstack \
 696         statfs \
 697         strcasecmp \
 698         strerror \
 699         strncasecmp \
 700         tcgetattr \
 701         timegm \
 702         usleep \
 703         vfscanf \
 704         wait4 \
 705         waitpid \
 706 )
 707
 708 dnl **** Check for header files ****
 709
 710 AC_CHECK_HEADERS(\
 711         a.out.h \
 712         a_out.h \
 713         arpa/inet.h \
 714         arpa/nameser.h \
 715         elf.h \
 716         float.h \
 717         libio.h \
 718         libutil.h \
 719         link.h \
 720         linux/cdrom.h \
 721         linux/joystick.h \
 722         linux/ucdrom.h \
 723         net/if.h \
 724         netinet/in.h \
 725         netinet/tcp.h \
 726         pty.h \
 727         resolv.h \
 728         sched.h \
 729         socket.h \
 730         strings.h \
 731         sys/cdio.h \
 732         sys/errno.h \
 733         sys/file.h \
 734         sys/filio.h \
 735         sys/ipc.h \
 736         sys/lwp.h \
 737         sys/mman.h \
 738         sys/modem.h \
 739         sys/mount.h \
 740         sys/msg.h \
 741         sys/param.h \
 742         sys/reg.h \
 743         sys/signal.h \
 744         sys/shm.h \
 745         sys/socket.h \
 746         sys/sockio.h \
 747         sys/statfs.h \
 748         sys/strtio.h \
 749         sys/syscall.h \
 750         sys/wait.h \
 751         sys/v86.h \
 752         sys/v86intr.h \
 753         sys/vfs.h \
 754         sys/vm86.h \
 755         syscall.h \
 756         ucontext.h \
 757         wctype.h \
 758 )
 759 AC_HEADER_STAT()
 760
 761 dnl **** Check for types ****
 762
 763 AC_C_CONST()
 764 AC_C_INLINE()
 765 AC_TYPE_SIZE_T()
 766 AC_CHECK_SIZEOF(long long,0)
 767
 768 if test "$ac_cv_header_linux_joystick_h" = "yes"
 769 then
 770    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 771         wine_cv_linux_joystick_22_api,
 772         AC_TRY_COMPILE([
 773         #include <sys/ioctl.h>
 774         #include <linux/joystick.h>
 775
 776         struct js_event blub;
 777         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 778         #error "no 2.2 header"
 779         #endif
 780         ],/*empty*/,
 781         wine_cv_linux_joystick_22_api=yes,
 782         wine_cv_linux_joystick_22_api=no,
 783         wine_cv_linux_joystick_22_api=no
 784         )
 785    )
 786    if test "$wine_cv_linux_joystick_22_api" = "yes"
 787    then
 788       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 789    fi
 790 fi
 791
 792 dnl **** statfs checks ****
 793
 794 if test "$ac_cv_header_sys_vfs_h" = "yes"
 795 then
 796     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 797                     wine_cv_sys_vfs_has_statfs,
 798         AC_TRY_COMPILE([
 799         #include <sys/types.h>
 800         #ifdef HAVE_SYS_PARAM_H
 801         # include <sys/param.h>
 802         #endif
 803         #include <sys/vfs.h>
 804         ],[
 805                 struct statfs stfs;
 806
 807                 memset(&stfs,0,sizeof(stfs));
 808         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 809         )
 810     )
 811     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 812     then
 813       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 814     fi
 815 fi
 816
 817 if test "$ac_cv_header_sys_statfs_h" = "yes"
 818 then
 819     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 820                     wine_cv_sys_statfs_has_statfs,
 821         AC_TRY_COMPILE([
 822         #include <sys/types.h>
 823         #ifdef HAVE_SYS_PARAM_H
 824         # include <sys/param.h>
 825         #endif
 826         #include <sys/statfs.h>
 827         ],[
 828                 struct statfs stfs;
 829         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 830         )
 831     )
 832     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 833     then
 834       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 835     fi
 836 fi
 837
 838 if test "$ac_cv_header_sys_mount_h" = "yes"
 839 then
 840     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 841                     wine_cv_sys_mount_has_statfs,
 842         AC_TRY_COMPILE([
 843         #include <sys/types.h>
 844         #ifdef HAVE_SYS_PARAM_H
 845         # include <sys/param.h>
 846         #endif
 847         #include <sys/mount.h>
 848         ],[
 849                 struct statfs stfs;
 850         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 851         )
 852     )
 853     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 854     then
 855       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 856     fi
 857 fi
 858
 859 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 860
 861 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 862   [ if test "x$statfs_bfree" = "xno"
 863     then
 864         wine_cv_statfs_bfree=no
 865     else
 866         AC_TRY_COMPILE([
 867         #include <sys/types.h>
 868         #ifdef HAVE_SYS_PARAM_H
 869         # include <sys/param.h>
 870         #endif
 871         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 872         # include <sys/mount.h>
 873         #else
 874         # ifdef STATFS_DEFINED_BY_SYS_VFS
 875         #  include <sys/vfs.h>
 876         # else
 877         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 878         #   include <sys/statfs.h>
 879         #  endif
 880         # endif
 881         #endif
 882         ],[
 883                 struct statfs stfs;
 884
 885                 stfs.f_bfree++;
 886         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 887         )
 888     fi ] )
 889 if test "$wine_cv_statfs_bfree" = "yes"
 890 then
 891   AC_DEFINE(STATFS_HAS_BFREE)
 892 fi
 893
 894 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 895   [ if test "x$statfs_bavail" = "xno"
 896     then
 897         wine_cv_statfs_bavail=no
 898     else
 899         AC_TRY_COMPILE([
 900         #include <sys/types.h>
 901         #ifdef HAVE_SYS_PARAM_H
 902         # include <sys/param.h>
 903         #endif
 904         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 905         # include <sys/mount.h>
 906         #else
 907         # ifdef STATFS_DEFINED_BY_SYS_VFS
 908         #  include <sys/vfs.h>
 909         # else
 910         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 911         #   include <sys/statfs.h>
 912         #  endif
 913         # endif
 914         #endif
 915         ],[
 916                 struct statfs stfs;
 917
 918                 stfs.f_bavail++;
 919         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 920         )
 921     fi ] )
 922 if test "$wine_cv_statfs_bavail" = "yes"
 923 then
 924   AC_DEFINE(STATFS_HAS_BAVAIL)
 925 fi
 926
 927 dnl *** check for file descriptor passing with msg_accrights
 928
 929 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 930  AC_TRY_COMPILE([#include <sys/types.h>
 931 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 932                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 933 if test "$ac_cv_c_msg_accrights" = "yes"
 934 then
 935     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 936 fi
 937
 938 dnl *** Check for the sun_len member in struct sockaddr_un
 939
 940 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
 941  AC_TRY_COMPILE([#include <sys/types.h>
 942 #include <sys/socket.h>
 943 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
 944                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
 945 if test "$ac_cv_c_sun_len" = "yes"
 946 then
 947     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
 948 fi
 949
 950 dnl *** check for the need to define __i386__
 951
 952 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
 953  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
 954 yes
 955 #endif],
 956  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
 957 if test "$ac_cv_cpp_def_i386" = "yes"
 958 then
 959     CFLAGS="$CFLAGS -D__i386__"
 960     LINTFLAGS="$LINTFLAGS -D__i386__"
 961 fi
 962
 963 dnl $GCC is set by autoconf
 964 GCC_NO_BUILTIN=""
 965 if test "$GCC" = "yes"
 966 then
 967     GCC_NO_BUILTIN="-fno-builtin"
 968 fi
 969 AC_SUBST(GCC_NO_BUILTIN)
 970
 971 dnl **** Generate output files ****
 972
 973 AC_OUTPUT_COMMANDS([
 974 extra_subdirs="\
 975 dlls/ddraw/d3ddevice \
 976 dlls/ddraw/dclipper \
 977 dlls/ddraw/ddraw \
 978 dlls/ddraw/direct3d \
 979 dlls/ddraw/dpalette \
 980 dlls/ddraw/dsurface \
 981 "
 982 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
 983
 984 MAKE_RULES=Make.rules
 985 AC_SUBST_FILE(MAKE_RULES)
 986
 987 MAKE_DLL_RULES=dlls/Makedll.rules
 988 AC_SUBST_FILE(MAKE_DLL_RULES)
 989
 990 AC_OUTPUT([
 991 Make.rules
 992 Makefile
 993 console/Makefile
 994 controls/Makefile
 995 debugger/Makefile
 996 dlls/Makedll.rules
 997 dlls/Makefile
 998 dlls/advapi32/Makefile
 999 dlls/avifil32/Makefile
1000 dlls/comctl32/Makefile
1001 dlls/commdlg/Makefile
1002 dlls/crtdll/Makefile
1003 dlls/dciman32/Makefile
1004 dlls/ddraw/Makefile
1005 dlls/dinput/Makefile
1006 dlls/dplay/Makefile
1007 dlls/dplayx/Makefile
1008 dlls/dsound/Makefile
1009 dlls/gdi/Makefile
1010 dlls/icmp/Makefile
1011 dlls/imagehlp/Makefile
1012 dlls/imm32/Makefile
1013 dlls/kernel/Makefile
1014 dlls/lzexpand/Makefile
1015 dlls/mpr/Makefile
1016 dlls/msacm/Makefile
1017 dlls/msnet32/Makefile
1018 dlls/msvideo/Makefile
1019 dlls/ntdll/Makefile
1020 dlls/odbc32/Makefile
1021 dlls/ole32/Makefile
1022 dlls/oleaut32/Makefile
1023 dlls/olecli/Makefile
1024 dlls/oledlg/Makefile
1025 dlls/olepro32/Makefile
1026 dlls/olesvr/Makefile
1027 dlls/opengl32/Makefile
1028 dlls/psapi/Makefile
1029 dlls/rasapi32/Makefile
1030 dlls/richedit/Makefile
1031 dlls/rpcrt4/Makefile
1032 dlls/serialui/Makefile
1033 dlls/setupapi/Makefile
1034 dlls/shell32/Makefile
1035 dlls/shfolder/Makefile
1036 dlls/shlwapi/Makefile
1037 dlls/tapi32/Makefile
1038 dlls/ttydrv/Makefile
1039 dlls/ttydrv/Makefile
1040 dlls/urlmon/Makefile
1041 dlls/user/Makefile
1042 dlls/version/Makefile
1043 dlls/win32s/Makefile
1044 dlls/winaspi/Makefile
1045 dlls/wineps/Makefile
1046 dlls/wininet/Makefile
1047 dlls/winmm/Makefile
1048 dlls/winmm/joystick/Makefile
1049 dlls/winmm/mcianim/Makefile
1050 dlls/winmm/mciavi/Makefile
1051 dlls/winmm/mcicda/Makefile
1052 dlls/winmm/mciseq/Makefile
1053 dlls/winmm/mciwave/Makefile
1054 dlls/winmm/midimap/Makefile
1055 dlls/winmm/wavemap/Makefile
1056 dlls/winmm/wineoss/Makefile
1057 dlls/winsock/Makefile
1058 dlls/winspool/Makefile
1059 dlls/wow32/Makefile
1060 dlls/wsock32/Makefile
1061 dlls/x11drv/Makefile
1062 documentation/Makefile
1063 documentation/wine.conf.man
1064 documentation/wine.man
1065 files/Makefile
1066 graphics/Makefile
1067 graphics/enhmetafiledrv/Makefile
1068 graphics/metafiledrv/Makefile
1069 graphics/ttydrv/Makefile
1070 graphics/win16drv/Makefile
1071 graphics/x11drv/Makefile
1072 if1632/Makefile
1073 include/Makefile
1074 library/Makefile
1075 libtest/Makefile
1076 loader/Makefile
1077 loader/ne/Makefile
1078 loader/dos/Makefile
1079 memory/Makefile
1080 misc/Makefile
1081 miscemu/Makefile
1082 msdos/Makefile
1083 objects/Makefile
1084 ole/Makefile
1085 programs/Makefile
1086 programs/clock/Makefile
1087 programs/cmdlgtst/Makefile
1088 programs/control/Makefile
1089 programs/avitools/Makefile
1090 programs/osversioncheck/Makefile
1091 programs/notepad/Makefile
1092 programs/progman/Makefile
1093 programs/regtest/Makefile
1094 programs/regapi/Makefile
1095 programs/view/Makefile
1096 programs/wcmd/Makefile
1097 programs/winemine/Makefile
1098 programs/winhelp/Makefile
1099 programs/winver/Makefile
1100 relay32/Makefile
1101 resources/Makefile
1102 scheduler/Makefile
1103 server/Makefile
1104 tools/Makefile
1105 tools/cvdump/Makefile
1106 tools/winebuild/Makefile
1107 tools/wrc/Makefile
1108 tools/wmc/Makefile
1109 tsx11/Makefile
1110 unicode/Makefile
1111 win32/Makefile
1112 windows/Makefile
1113 windows/ttydrv/Makefile
1114 windows/x11drv/Makefile ])
1115
1116 if test "$have_x" = "no"
1117 then
1118   echo
1119   echo "*** Warning: X development files not found. Wine will be built without"
1120   echo "*** X support, which currently does not work, and would probably not be"
1121   echo "*** what you want anyway. You will need to install devel packages of"
1122   echo "*** Xlib/Xfree86 and Xpm at the very least."
1123 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1124 then
1125   echo
1126   echo "*** Warning: Xpm development files not found. Wine will be built without"
1127   echo "*** Xpm support, which currently does not work. You will need to install"
1128   echo "*** devel packages of Xpm."
1129 fi
1130
1131 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1132 then
1133   echo
1134   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1135   echo "*** terminal resize support. Consider upgrading ncurses."
1136 fi
1137
1138 if test "$wine_cv_libc_reentrant" = "no"
1139 then
1140   echo
1141   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1142   echo "*** thread support. Consider upgrading libc to a more recent"
1143   echo "*** reentrant version of libc."
1144 fi
1145
1146 if test "$wine_cv_opengl_version_OK" = "no"
1147 then
1148   echo
1149   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1150   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1151 fi
1152
1153 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1154 then
1155   echo
1156   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1157   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1158   echo "*** A fix for glibc 2.1.3 that seem to work is included in this version of Wine,"
1159   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1160 fi
1161
1162 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1163 then
1164   echo
1165   echo "*** Warning: you explicitely linked in a thread-safe OpenGL version. If you"
1166   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1167   echo "*** support before reporting bugs."
1168 fi
1169
1170
1171 echo
1172 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1173 echo
1174
1175 dnl Local Variables:
1176 dnl comment-start: "dnl "
1177 dnl comment-end: ""
1178 dnl comment-start-skip: "\\bdnl\\b\\s *"
1179 dnl compile-command: "autoconf"
1180 dnl End: