git.oblomov.eu Git - wine/blob - tools/winemaker

   1 #!/usr/bin/perl -w
   2 use strict;
   3
   4 # Copyright 2000-2004 Francois Gouget for CodeWeavers
   5 # Copyright 2004 Dimitrie O. Paun
   6 # Copyright 2009 André Hentschel
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22
  23 my $version="0.7.4";
  24
  25 use Cwd;
  26 use File::Basename;
  27 use File::Copy;
  28
  29
  30
  31 #####
  32 #
  33 # Options
  34 #
  35 #####
  36
  37 # The following constants define what we do with the case of filenames
  38
  39 ##
  40 # Never rename a file to lowercase
  41 my $OPT_LOWER_NONE=0;
  42
  43 ##
  44 # Rename all files to lowercase
  45 my $OPT_LOWER_ALL=1;
  46
  47 ##
  48 # Rename only files that are all uppercase to lowercase
  49 my $OPT_LOWER_UPPERCASE=2;
  50
  51
  52 # The following constants define whether to ask questions or not
  53
  54 ##
  55 # No (synonym of never)
  56 my $OPT_ASK_NO=0;
  57
  58 ##
  59 # Yes (always)
  60 my $OPT_ASK_YES=1;
  61
  62 ##
  63 # Skip the questions till the end of this scope
  64 my $OPT_ASK_SKIP=-1;
  65
  66
  67 # The following constants define the architecture
  68
  69 ##
  70 # Default Architecture will be choosen
  71 my $OPT_ARCH_DEFAULT=0;
  72
  73 ##
  74 # 32-Bit Target
  75 my $OPT_ARCH_32=32;
  76
  77 ##
  78 # 64-Bit Target
  79 my $OPT_ARCH_64=64;
  80
  81
  82 # General options
  83
  84 ##
  85 # This is the directory in which winemaker will operate.
  86 my $opt_work_dir;
  87
  88 ##
  89 # This is the file in which winemaker will operate if a project file is specified.
  90 my $opt_work_file;
  91
  92 ##
  93 # Make a backup of the files
  94 my $opt_backup;
  95
  96 ##
  97 # Defines which files to rename
  98 my $opt_lower;
  99
 100 ##
 101 # If we don't find the file referenced by an include, lower it
 102 my $opt_lower_include;
 103
 104 ##
 105 # If true then winemaker should not attempt to fix the source.  This is
 106 # useful if the source is known to be already in a suitable form and is
 107 # readonly
 108 my $opt_no_source_fix;
 109
 110 # Options for the 'Source' method
 111
 112 ##
 113 # Specifies that we have only one target so that all sources relate
 114 # to this target. By default this variable is left undefined which
 115 # means winemaker should try to find out by itself what the targets
 116 # are. If not undefined then this contains the name of the default
 117 # target (without the extension).
 118 my $opt_single_target;
 119
 120 ##
 121 # If '$opt_single_target' has been specified then this is the type of
 122 # that target. Otherwise it specifies whether the default target type
 123 # is guiexe or cuiexe.
 124 my $opt_target_type;
 125
 126 ##
 127 # Contains the default set of flags to be used when creating a new target.
 128 my $opt_flags;
 129
 130 ##
 131 # Contains 32 for 32-Bit-Targets and 64 for 64-Bit-Targets
 132 my $opt_arch;
 133
 134 ##
 135 # If true then winemaker should ask questions to the user as it goes
 136 # along.
 137 my $opt_is_interactive;
 138 my $opt_ask_project_options;
 139 my $opt_ask_target_options;
 140
 141 ##
 142 # If false then winemaker should not generate the makefiles.
 143 my $opt_no_generated_files;
 144
 145 ##
 146 # Specifies not to print the banner if set.
 147 my $opt_no_banner;
 148
 149
 150
 151 #####
 152 #
 153 # Target modelization
 154 #
 155 #####
 156
 157 # The description of a target is stored in an array. The constants
 158 # below identify what is stored at each index of the array.
 159
 160 ##
 161 # This is the name of the target.
 162 my $T_NAME=0;
 163
 164 ##
 165 # Defines the type of target we want to build. See the TT_xxx
 166 # constants below
 167 my $T_TYPE=1;
 168
 169 ##
 170 # This is a bitfield containing flags refining the way the target
 171 # should be handled. See the TF_xxx constants below
 172 my $T_FLAGS=2;
 173
 174 ##
 175 # This is a reference to an array containing the list of the
 176 # resp. C, C++, RC, other (.h, .hxx, etc.) source files.
 177 my $T_SOURCES_C=3;
 178 my $T_SOURCES_CXX=4;
 179 my $T_SOURCES_RC=5;
 180 my $T_SOURCES_MISC=6;
 181
 182 ##
 183 # This is a reference to an array containing the list of
 184 # C compiler options
 185 my $T_CEXTRA=7;
 186
 187 ##
 188 # This is a reference to an array containing the list of
 189 # C++ compiler options
 190 my $T_CXXEXTRA=8;
 191
 192 ##
 193 # This is a reference to an array containing the list of
 194 # RC compiler options
 195 my $T_RCEXTRA=9;
 196
 197 ##
 198 # This is a reference to an array containing the list of macro
 199 # definitions
 200 my $T_DEFINES=10;
 201
 202 ##
 203 # This is a reference to an array containing the list of directory
 204 # names that constitute the include path
 205 my $T_INCLUDE_PATH=11;
 206
 207 ##
 208 # Flags for the linker
 209 my $T_LDFLAGS=12;
 210
 211 ##
 212 # Same as T_INCLUDE_PATH but for the dll search path
 213 my $T_DLL_PATH=13;
 214
 215 ##
 216 # The list of Windows dlls to import
 217 my $T_DLLS=14;
 218
 219 ##
 220 # Same as T_INCLUDE_PATH but for the library search path
 221 my $T_LIBRARY_PATH=15;
 222
 223 ##
 224 # The list of Unix libraries to link with
 225 my $T_LIBRARIES=16;
 226
 227 ##
 228 # The list of dependencies between targets
 229 my $T_DEPENDS=17;
 230
 231
 232 # The following constants define the recognized types of target
 233
 234 ##
 235 # This is not a real target. This type of target is used to collect
 236 # the sources that don't seem to belong to any other target. Thus no
 237 # real target is generated for them, we just put the sources of the
 238 # fake target in the global source list.
 239 my $TT_SETTINGS=0;
 240
 241 ##
 242 # For executables in the windows subsystem
 243 my $TT_GUIEXE=1;
 244
 245 ##
 246 # For executables in the console subsystem
 247 my $TT_CUIEXE=2;
 248
 249 ##
 250 # For dynamically linked libraries
 251 my $TT_DLL=3;
 252
 253
 254 # The following constants further refine how the target should be handled
 255
 256 ##
 257 # This target is an MFC-based target
 258 my $TF_MFC=4;
 259
 260 ##
 261 # User has specified --nomfc option for this target or globally
 262 my $TF_NOMFC=8;
 263
 264 ##
 265 # --nodlls option: Do not use standard DLL set
 266 my $TF_NODLLS=16;
 267
 268 ##
 269 # --nomsvcrt option: Do not link with msvcrt
 270 my $TF_NOMSVCRT=32;
 271
 272 ##
 273 # Initialize a target:
 274 # - set the target type to TT_SETTINGS, i.e. no real target will
 275 #   be generated.
 276 sub target_init($)
 277 {
 278   my $target=$_[0];
 279
 280   @$target[$T_TYPE]=$TT_SETTINGS;
 281   # leaving $T_INIT undefined
 282   @$target[$T_FLAGS]=$opt_flags;
 283   @$target[$T_SOURCES_C]=[];
 284   @$target[$T_SOURCES_CXX]=[];
 285   @$target[$T_SOURCES_RC]=[];
 286   @$target[$T_SOURCES_MISC]=[];
 287   @$target[$T_CEXTRA]=[];
 288   @$target[$T_CXXEXTRA]=[];
 289   @$target[$T_RCEXTRA]=[];
 290   @$target[$T_DEFINES]=[];
 291   @$target[$T_INCLUDE_PATH]=[];
 292   @$target[$T_LDFLAGS]=[];
 293   @$target[$T_DLL_PATH]=[];
 294   @$target[$T_DLLS]=[];
 295   @$target[$T_LIBRARY_PATH]=[];
 296   @$target[$T_LIBRARIES]=[];
 297 }
 298
 299
 300
 301 #####
 302 #
 303 # Project modelization
 304 #
 305 #####
 306
 307 # First we have the notion of project. A project is described by an
 308 # array (since we don't have structs in perl). The constants below
 309 # identify what is stored at each index of the array.
 310
 311 ##
 312 # This is the path in which this project is located. In other
 313 # words, this is the path to  the Makefile.
 314 my $P_PATH=0;
 315
 316 ##
 317 # This index contains a reference to an array containing the project-wide
 318 # settings. The structure of that arrray is actually identical to that of
 319 # a regular target since it can also contain extra sources.
 320 my $P_SETTINGS=1;
 321
 322 ##
 323 # This index contains a reference to an array of targets for this
 324 # project. Each target describes how an executable or library is to
 325 # be built. For each target this description takes the same form as
 326 # that of the project: an array. So this entry is an array of arrays.
 327 my $P_TARGETS=2;
 328
 329 ##
 330 # Initialize a project:
 331 # - set the project's path
 332 # - initialize the target list
 333 # - create a default target (will be removed later if unnecessary)
 334 sub project_init($$$)
 335 {
 336   my ($project, $path, $global_settings)=@_;
 337
 338   my $project_settings=[];
 339   target_init($project_settings);
 340   @$project_settings[$T_DEFINES]=[@{@$global_settings[$T_DEFINES]}];
 341   @$project_settings[$T_INCLUDE_PATH]=[@{@$global_settings[$T_INCLUDE_PATH]}];
 342   @$project_settings[$T_DLL_PATH]=[@{@$global_settings[$T_DLL_PATH]}];
 343   @$project_settings[$T_DLLS]=[@{@$global_settings[$T_DLLS]}];
 344   @$project_settings[$T_LIBRARY_PATH]=[@{@$global_settings[$T_LIBRARY_PATH]}];
 345   @$project_settings[$T_LIBRARIES]=[@{@$global_settings[$T_LIBRARIES]}];
 346
 347   @$project[$P_PATH]=$path;
 348   @$project[$P_SETTINGS]=$project_settings;
 349   @$project[$P_TARGETS]=[];
 350 }
 351
 352
 353
 354 #####
 355 #
 356 # Global variables
 357 #
 358 #####
 359
 360 my %warnings;
 361
 362 my %templates;
 363
 364 ##
 365 # This maps a directory name to a reference to an array listing
 366 # its contents (files and directories)
 367 my %directories;
 368
 369 ##
 370 # Contains the list of all projects. This list tells us what are
 371 # the subprojects of the main Makefile and where we have to generate
 372 # Makefiles.
 373 my @projects=();
 374
 375 ##
 376 # This is the main project, i.e. the one in the "." directory.
 377 # It may well be empty in which case the main Makefile will only
 378 # call out subprojects.
 379 my @main_project;
 380
 381 ##
 382 # Contains the defaults for the include path, etc.
 383 # We store the defaults as if this were a target except that we only
 384 # exploit the defines, include path, library path, library list and misc
 385 # sources fields.
 386 my @global_settings;
 387
 388
 389
 390 #####
 391 #
 392 # Utility functions
 393 #
 394 #####
 395
 396 ##
 397 # Cleans up a name to make it an acceptable Makefile
 398 # variable name.
 399 sub canonize($)
 400 {
 401   my $name=$_[0];
 402
 403   $name =~ tr/a-zA-Z0-9_/_/c;
 404   return $name;
 405 }
 406
 407 ##
 408 # Returns true is the specified pathname is absolute.
 409 # Note: pathnames that start with a variable '$' or
 410 # '~' are considered absolute.
 411 sub is_absolute($)
 412 {
 413   my $path=$_[0];
 414
 415   return ($path =~ /^[\/~\$]/);
 416 }
 417
 418 ##
 419 # Retrieves the contents of the specified directory.
 420 # We either get it from the directories hashtable which acts as a
 421 # cache, or use opendir, readdir, closedir and store the result
 422 # in the hashtable.
 423 sub get_directory_contents($)
 424 {
 425   my $dirname=$_[0];
 426   my $directory;
 427
 428   #print "getting the contents of $dirname\n";
 429
 430   # check for a cached version
 431   $dirname =~ s+/$++;
 432   if ($dirname eq "") {
 433     $dirname=cwd;
 434   }
 435   $directory=$directories{$dirname};
 436   if (defined $directory) {
 437     #print "->@$directory\n";
 438     return $directory;
 439   }
 440
 441   # Read this directory
 442   if (opendir(DIRECTORY, "$dirname")) {
 443     my @files=readdir DIRECTORY;
 444     closedir(DIRECTORY);
 445     $directory=\@files;
 446   } else {
 447     # Return an empty list
 448     #print "error: cannot open $dirname\n";
 449     my @files;
 450     $directory=\@files;
 451   }
 452   #print "->@$directory\n";
 453   $directories{$dirname}=$directory;
 454   return $directory;
 455 }
 456
 457 ##
 458 # Removes a directory from the cache.
 459 # This is needed if one of its files or subdirectory has been renamed.
 460 sub clear_directory_cache($)
 461 {
 462     my ($dirname)=@_;
 463     delete $directories{$dirname};
 464 }
 465
 466
 467 #####
 468 #
 469 # 'Source'-based Project analysis
 470 #
 471 #####
 472
 473 ##
 474 # Allows the user to specify makefile and target specific options
 475 # - target: the structure in which to store the results
 476 # - options: the string containing the options
 477 sub source_set_options($$)
 478 {
 479   my $target=$_[0];
 480   my $options=$_[1];
 481
 482   #FIXME: we must deal with escaping of stuff and all
 483   foreach my $option (split / /,$options) {
 484     if (@$target[$T_TYPE] == $TT_SETTINGS and $option =~ /^-D/) {
 485       push @{@$target[$T_DEFINES]},$option;
 486     } elsif (@$target[$T_TYPE] == $TT_SETTINGS and $option =~ /^-I/) {
 487       push @{@$target[$T_INCLUDE_PATH]},$option;
 488     } elsif ($option =~ /^-P/) {
 489       push @{@$target[$T_DLL_PATH]},"-L$'";
 490     } elsif ($option =~ /^-i/) {
 491       push @{@$target[$T_DLLS]},"$'";
 492     } elsif ($option =~ /^-L/) {
 493       push @{@$target[$T_LIBRARY_PATH]},$option;
 494     } elsif ($option =~ /^-l/) {
 495       push @{@$target[$T_LIBRARIES]},"$'";
 496     } elsif ($option =~ /^--mfc/) {
 497       @$target[$T_FLAGS]|=$TF_MFC;
 498       @$target[$T_FLAGS]&=~$TF_NOMFC;
 499     } elsif ($option =~ /^--nomfc/) {
 500       @$target[$T_FLAGS]&=~$TF_MFC;
 501       @$target[$T_FLAGS]|=$TF_NOMFC;
 502     } elsif ($option =~ /^--nodlls/) {
 503       @$target[$T_FLAGS]|=$TF_NODLLS;
 504     } elsif ($option =~ /^--nomsvcrt/) {
 505       @$target[$T_FLAGS]|=$TF_NOMSVCRT;
 506     } else {
 507       print STDERR "error: unknown option \"$option\"\n";
 508       return 0;
 509     }
 510   }
 511   return 1;
 512 }
 513
 514 ##
 515 # Scans the specified project file to:
 516 # - get a list of targets for this project
 517 # - get some settings
 518 # - get the list of source files
 519 sub source_scan_project_file($$$);
 520 sub source_scan_project_file($$$)
 521 {
 522     # a reference to the parent's project
 523     my $parent_project=$_[0];
 524     # 0 if it is a single project, 1 if it is part of a workspace
 525     my $is_sub_project=$_[1];
 526     # the name of the project file, with complete path, or without if in
 527     # the same directory
 528     my $filename=$_[2];
 529
 530     # reference to the project for this file. May not be used
 531     my $project;
 532     # list of sources found in the current file
 533     my @sources_c=();
 534     my @sources_cxx=();
 535     my @sources_rc=();
 536     my @sources_misc=();
 537     # some more settings
 538     my $path=dirname($filename);
 539     my $prj_target_cflags;
 540     my $prj_target_defines;
 541     my $prj_target_ldflags;
 542     my $prj_target_libs;
 543     my $prj_name;
 544     my $found_cfg=0;
 545     my $prj_cfg;
 546     my $prj_target_type=$TT_GUIEXE;
 547     my @prj_target_options;
 548
 549     if (!($path=~/\/$/)) {
 550         $path.="/";
 551     }
 552
 553     if (defined $opt_single_target or $is_sub_project == 0) {
 554         # Either there is a single target and thus a single project,
 555         # or we are a single project-file for which a project
 556         # already exists
 557         $project=$parent_project;
 558     } else {
 559         $project=[];
 560         project_init($project, $path, \@global_settings);
 561     }
 562     my $project_settings=@$project[$P_SETTINGS];
 563
 564     if ($filename =~ /.dsp$/i) {
 565         # First find out what this project file contains:
 566         # collect all sources, find targets and settings
 567         if (!open(FILEI,$filename)) {
 568             print STDERR "error: unable to open $filename for reading:\n";
 569             print STDERR "       $!\n";
 570             return;
 571         }
 572         my $sfilet;
 573         while (<FILEI>) {
 574             # Remove any trailing CtrlZ, which isn't strictly in the file
 575             if (/\x1A/) {
 576                 s/\x1A//;
 577                 last if (/^$/)
 578             }
 579
 580             # Remove any trailing CrLf
 581             s/\r\n$/\n/;
 582             if (!/\n$/) {
 583                 # Make sure all lines are '\n' terminated
 584                 $_ .= "\n";
 585             }
 586
 587             if (/^\# Microsoft Developer Studio Project File - Name=\"([^\"]+)/) {
 588                 $prj_name="$1";
 589                 $prj_name=~s/\s+/_/g;
 590                 #print $prj_name;
 591                 next;
 592             } elsif (/^# TARGTYPE/) {
 593                 if (/[[:space:]]0x0101$/) {
 594                     # Application
 595                     $prj_target_type=$TT_GUIEXE;
 596                 }elsif (/[[:space:]]0x0102$/) {
 597                     # Dynamic-Link Library
 598                     $prj_target_type=$TT_DLL;
 599                 }elsif (/[[:space:]]0x0103$/) {
 600                     # Console Application
 601                     $prj_target_type=$TT_CUIEXE;
 602                 }elsif (/[[:space:]]0x0104$/) {
 603                     # Static Library
 604                 }
 605                 next;
 606             } elsif (/^# ADD CPP(.*)/ && $found_cfg==1) {
 607                 $prj_target_cflags=$1;
 608                 @prj_target_options=split(" /", $prj_target_cflags);
 609                 $prj_target_cflags="";
 610                 foreach ( @prj_target_options ) {
 611                     if ($_ eq "") {
 612                         # empty
 613                     } elsif (/nologo/) {
 614                         # Suppress Startup Banner and Information Messages
 615                     } elsif (/^W0$/) {
 616                         # Turns off all warning messages
 617                         $prj_target_cflags.="-w ";
 618                     } elsif (/^W[123]$/) {
 619                         # Warning Level
 620                         $prj_target_cflags.="-W ";
 621                     } elsif (/^W4$/) {
 622                         # Warning Level
 623                         $prj_target_cflags.="-Wall ";
 624                     } elsif (/^WX$/) {
 625                         # Warnings As Errors
 626                         $prj_target_cflags.="-Werror ";
 627                     } elsif (/^Gm$/) {
 628                         # Enable Minimal Rebuild
 629                     } elsif (/^GX$/) {
 630                         # Enable Exception Handling
 631                         $prj_target_cflags.="-fexceptions ";
 632                     } elsif (/^Z[d7iI]$/) {
 633                         # Debug Info
 634                         $prj_target_cflags.="-g ";
 635                     } elsif (/^Od$/) {
 636                         # Disable Optimizations
 637                         $prj_target_cflags.="-O0 ";
 638                     } elsif (/^O1$/) {
 639                         # Minimize Size
 640                         $prj_target_cflags.="-Os ";
 641                     } elsif (/^O2$/) {
 642                         # Maximize Speed
 643                         $prj_target_cflags.="-O2 ";
 644                     } elsif (/^Ob0$/) {
 645                         # Disables inline Expansion
 646                         $prj_target_cflags.="-fno-inline ";
 647                     } elsif (/^Ob1$/) {
 648                         #In-line Function Expansion
 649                         $prj_target_cflags.="-finline-functions ";
 650                     } elsif (/^Ob2$/) {
 651                         # auto In-line Function Expansion
 652                         $prj_target_cflags.="-finline-functions ";
 653                     } elsif (/^Ox$/) {
 654                         # Use maximum optimization
 655                         $prj_target_cflags.="-O3 ";
 656                     } elsif (/^Oy$/) {
 657                         # Frame-Pointer Omission
 658                         $prj_target_cflags.="-fomit-frame-pointer ";
 659                     } elsif (/^Oy-$/) {
 660                         # Frame-Pointer Omission
 661                         $prj_target_cflags.="-fno-omit-frame-pointer ";
 662                     } elsif (/^GZ$/) {
 663                         # Catch Release-Build Errors in Debug Build
 664                     } elsif (/^M[DLT]d?$/) {
 665                         # Use Multithreaded Run-Time Library
 666                     } elsif (/^D\s*\"(.*)\"/) {
 667                         # Preprocessor Definitions
 668                         $prj_target_defines.="-D".$1." ";
 669                     } elsif (/^I\s*\"(.*)\"/) {
 670                         # Additional Include Directories
 671                         $sfilet=$1;
 672                         $sfilet=~s/\\/\//g;
 673                         push @{@$project_settings[$T_INCLUDE_PATH]},"-I".$sfilet." ";
 674                     } elsif (/^U\s*\"(.*)\"/) {
 675                         # Undefines a previously defined symbol
 676                         $prj_target_cflags.="-U".$1." ";
 677                     } elsif (/^Fp/) {
 678                         # Name .PCH File
 679                     } elsif (/^F[Rr]/) {
 680                         # Create .SBR File
 681                     } elsif (/^YX$/) {
 682                         # Automatic Use of Precompiled Headers
 683                     } elsif (/^FD$/) {
 684                         # Generate File Dependencies
 685                     } elsif (/^c$/) {
 686                         # Compile Without Linking
 687                         # this option is always present and is already specified in the suffix rules
 688                     } elsif (/^GB$/) {
 689                         # Blend Optimization
 690                         $prj_target_cflags.="-mcpu=pentiumpro -D_M_IX86=500 ";
 691                     } elsif (/^G6$/) {
 692                         # Pentium Pro Optimization
 693                         $prj_target_cflags.="-march=pentiumpro -D_M_IX86=600 ";
 694                     } elsif (/^G5$/) {
 695                         # Pentium Optimization
 696                         $prj_target_cflags.="-mcpu=pentium -D_M_IX86=500 ";
 697                     } elsif (/^G3$/) {
 698                         # 80386 Optimization
 699                         $prj_target_cflags.="-mcpu=i386 -D_M_IX86=300 ";
 700                     } elsif (/^G4$/) {
 701                         # 80486 Optimization
 702                         $prj_target_cflags.="-mcpu=i486 -D_M_IX86=400 ";
 703                     } elsif (/^Yc/) {
 704                         # Create Precompiled Header
 705                     } elsif (/^Yu/) {
 706                         # Use Precompiled Header
 707                     } elsif (/^Za$/) {
 708                         # Disable Language Extensions
 709                         $prj_target_cflags.="-ansi ";
 710                     } elsif (/^Ze$/) {
 711                         # Enable Microsoft Extensions
 712                     } elsif (/^Zm[[:digit:]]+$/) {
 713                         # Specify Memory Allocation Limit
 714                     } elsif (/^Zp1?$/) {
 715                         # Packs structures on 1-byte boundaries
 716                         $prj_target_cflags.="-fpack-struct ";
 717                     } elsif (/^Zp(2|4|8|16)$/) {
 718                         # Struct Member Alignment
 719                         $prj_target_cflags.="-fpack-struct=".$1;
 720                     } else {
 721                         print "C compiler option $_ not implemented\n";
 722                     }
 723                 }
 724
 725                 #print "\nOptions: $prj_target_cflags\n";
 726                 next;
 727             } elsif (/^# ADD LINK32(.*)/ && $found_cfg==1) {
 728                 $prj_target_ldflags=$1;
 729                 @prj_target_options=split(" /", $prj_target_ldflags);
 730                 $prj_target_ldflags="";
 731                 $prj_target_libs=$prj_target_options[0];
 732                 $prj_target_libs=~s/\\/\//g;
 733                 $prj_target_libs=~s/\.lib//g;
 734                 $prj_target_libs=~s/\s+/ -l/g;
 735                 shift (@prj_target_options);
 736                 foreach ( @prj_target_options ) {
 737                     if ($_ eq "") {
 738                         # empty
 739                     } elsif (/^base:(.*)/) {
 740                         # Base Address
 741                         $prj_target_ldflags.="--image-base ".$1." ";
 742                     } elsif (/^debug$/) {
 743                         # Generate Debug Info
 744                     } elsif (/^dll$/) {
 745                         # Build a DLL
 746                         $prj_target_type=$TT_DLL;
 747                     } elsif (/^incremental:[[:alpha:]]+$/) {
 748                         # Link Incrmentally
 749                     } elsif (/^implib:/) {
 750                         # Name import library
 751                     } elsif (/^libpath:\"(.*)\"/) {
 752                         # Additional Libpath
 753                         push @{@$project_settings[$T_DLL_PATH]},"-L$1";
 754                     } elsif (/^machine:[[:alnum:]]+$/) {
 755                         # Specify Target Platform
 756                     } elsif (/^map/) {
 757                         # Generate Mapfile
 758                         if (/^map:(.*)/) {
 759                             $prj_target_ldflags.="-Map ".$1." ";
 760                         } else {
 761                             $prj_target_ldflags.="-Map ".$prj_name.".map ";
 762                         }
 763                     } elsif (/^nologo$/) {
 764                         # Suppress Startup Banner and Information Messages
 765                     } elsif (/^out:/) {
 766                         # Output File Name
 767                         # may use it as Target?
 768                     } elsif (/^pdbtype:/) {
 769                         # Program Database Storage
 770                     } elsif (/^subsystem:/) {
 771                         # Specify Subsystem
 772                     } elsif (/^version:[[:digit:].]+$/) {
 773                         # Version Information
 774                     } else {
 775                         print "Linker option $_ not implemented\n";
 776                     }
 777                 }
 778                 next;
 779             } elsif (/^LIB32=/ && $found_cfg==1) {
 780                 #$libflag = 1;
 781                 next;
 782             } elsif (/^SOURCE=(.*)$/) {
 783                 my @components=split /[\/\\]+/, $1;
 784                 $sfilet=search_from($path, \@components);
 785                 if ($sfilet =~ /\.c$/i and $sfilet !~ /\.(dbg|spec)\.c$/) {
 786                     push @sources_c,$sfilet;
 787                 } elsif ($sfilet =~ /\.(cpp|cxx)$/i) {
 788                     if ($sfilet =~ /^stdafx.cpp$/i && !(@$project_settings[$T_FLAGS] & $TF_NOMFC)) {
 789                         push @sources_misc,$sfilet;
 790                         @$project_settings[$T_FLAGS]|=$TF_MFC;
 791                     } else {
 792                         push @sources_cxx,$sfilet;
 793                     }
 794                 } elsif ($sfilet =~ /\.rc$/i) {
 795                     push @sources_rc,$sfilet;
 796                 } elsif ($sfilet =~ /\.(h|hxx|hpp|inl|rc2|dlg)$/i) {
 797                     push @sources_misc,$sfilet;
 798                     if ($sfilet =~ /^stdafx.h$/i && !(@$project_settings[$T_FLAGS] & $TF_NOMFC)) {
 799                         @$project_settings[$T_FLAGS]|=$TF_MFC;
 800                     }
 801                 }
 802                 next;
 803
 804             } elsif (/^# (Begin|End) Source File/) {
 805                 # Source-Files already handled
 806                 next;
 807             } elsif (/^# (Begin|End) Group/) {
 808                 # Groups are ignored
 809                 next;
 810             } elsif (/^# (Begin|End) Custom Build/) {
 811                 # Custom Builds are ignored
 812                 next;
 813             } elsif (/^# ADD LIB32 /) {
 814                 #"ARFLAGS=rus"
 815                 next;
 816             } elsif (/^# Begin Target$/) {
 817                 # Targets are ignored
 818                 next;
 819             } elsif (/^# End Target$/) {
 820                 # Targets are ignored
 821                 next;
 822             } elsif (/^!/) {
 823                 if ($found_cfg == 1) {
 824                     $found_cfg=0;
 825                 }
 826                 if (/if (.*)\(CFG\)" == "(.*)"/i) {
 827                     if ($2 eq $prj_cfg) {
 828                         $found_cfg=1;
 829                     }
 830                 }
 831                 next;
 832             } elsif (/^CFG=(.*)/i) {
 833                 $prj_cfg=$1;
 834                 next;
 835             }
 836                 else { # Line recognized
 837                 # print "|\n";
 838             }
 839         }
 840         close(FILEI);
 841
 842         push @{@$project_settings[$T_LIBRARIES]},$prj_target_libs;
 843         push @{@$project_settings[$T_CEXTRA]},$prj_target_cflags;
 844         push @{@$project_settings[$T_CXXEXTRA]},$prj_target_cflags;
 845         push @{@$project_settings[$T_DEFINES]},$prj_target_defines;
 846         push @{@$project_settings[$T_LDFLAGS]},$prj_target_ldflags;
 847     } elsif ($filename =~ /.vcproj$/i) {
 848         # Import XML::LibXML, you need the libxml package (deb: libxml-libxml-perl, rpm: perl-libxml-perl)
 849         require XML::LibXML;
 850
 851         my $xmlparser = XML::LibXML->new();
 852         my $project_xml = $xmlparser->parse_file($filename);
 853         my $sfilet;
 854         my $configt;
 855
 856         foreach my $vc_project ($project_xml->findnodes('/VisualStudioProject')) {
 857             foreach my $vc_project_attr ($vc_project->attributes) {
 858                 if ($vc_project_attr->getName eq "Name") {
 859                     $prj_name=$vc_project_attr->getValue;
 860                     $prj_name=~s/\s+/_/g;
 861                     last;
 862                 }
 863             }
 864         }
 865
 866         for (my $flevel = 0; $flevel <= 5; $flevel++) {
 867             foreach my $vc_file ($project_xml->findnodes('/VisualStudioProject/Files/'.('Filter/' x $flevel).'File')) {
 868                 foreach my $vc_file_attr ($vc_file->attributes) {
 869                     if ($vc_file_attr->getName eq "RelativePath") {
 870                         $sfilet = $vc_file_attr->getValue;
 871                         $sfilet=~s/\\\\/\\/g; #remove double backslash
 872                         $sfilet=~s/^\.\\//; #remove starting 'this directory'
 873                         $sfilet=~s/\\/\//g; #make slashes out of backslashes
 874                         if ($sfilet =~ /\.c$/i and $sfilet !~ /\.(dbg|spec)\.c$/) {
 875                             push @sources_c,$sfilet;
 876                         } elsif ($sfilet =~ /\.(cpp|cxx)$/i) {
 877                             if ($sfilet =~ /^stdafx.cpp$/i && !(@$project_settings[$T_FLAGS] & $TF_NOMFC)) {
 878                                 push @sources_misc,$sfilet;
 879                                 @$project_settings[$T_FLAGS]|=$TF_MFC;
 880                             } else {
 881                                 push @sources_cxx,$sfilet;
 882                             }
 883                         } elsif ($sfilet =~ /\.rc$/i) {
 884                             push @sources_rc,$sfilet;
 885                         } elsif ($sfilet =~ /\.(h|hxx|hpp|inl|rc2|dlg)$/i) {
 886                             push @sources_misc,$sfilet;
 887                             if ($sfilet =~ /^stdafx.h$/i && !(@$project_settings[$T_FLAGS] & $TF_NOMFC)) {
 888                                 @$project_settings[$T_FLAGS]|=$TF_MFC;
 889                             }
 890                         }
 891                     }
 892                 }
 893             }
 894         }
 895
 896         my @vc_configurations = $project_xml->findnodes('/VisualStudioProject/Configurations/Configuration');
 897         my $vc_configuration = $vc_configurations[0];
 898         foreach my $vc_configuration_attr ($vc_configuration->attributes) {
 899             if ($vc_configuration_attr->getName eq "ConfigurationType") {
 900                 if ($vc_configuration_attr->getValue==1) {
 901                     $prj_target_type=$TT_GUIEXE; # Application
 902                 } elsif ($vc_configuration_attr->getValue==2) {
 903                     $prj_target_type=$TT_DLL; # Dynamic-Link Library
 904                 }
 905             }
 906         }
 907
 908         foreach my $vc_configuration_tools ($vc_configuration->findnodes('Tool')) {
 909             my @find_tool = $vc_configuration_tools->attributes;
 910             if ($find_tool[0]->getValue eq "VCCLCompilerTool") {
 911                 foreach my $vc_compiler_tool ($vc_configuration_tools->attributes) {
 912                     if ($vc_compiler_tool->getName eq "Optimization") {$prj_target_cflags.="-O".$vc_compiler_tool->getValue." ";}
 913                     if ($vc_compiler_tool->getName eq "WarningLevel") {
 914                         if ($vc_compiler_tool->getValue==0) {
 915                             $prj_target_cflags.="-w ";
 916                         } elsif ($vc_compiler_tool->getValue<4) {
 917                             $prj_target_cflags.="-W ";
 918                         } elsif ($vc_compiler_tool->getValue==4) {
 919                             $prj_target_cflags.="-Wall ";
 920                         } elsif ($vc_compiler_tool->getValue eq "X") {
 921                             $prj_target_cflags.="-Werror ";
 922                         }
 923                     }
 924                     if ($vc_compiler_tool->getName eq "PreprocessorDefinitions") {
 925                         $configt=$vc_compiler_tool->getValue;
 926                         $configt=~s/;/ -D/g;
 927                         $prj_target_defines.="-D".$configt." ";
 928                     }
 929                     if ($vc_compiler_tool->getName eq "AdditionalIncludeDirectories") {
 930                         $configt=$vc_compiler_tool->getValue;
 931                         $configt=~s/\\/\//g;
 932                         $configt=~s/;/ -I/g;
 933                         push @{@$project_settings[$T_INCLUDE_PATH]},"-I".$configt;
 934                     }
 935                 }
 936             }
 937             if ($find_tool[0]->getValue eq "VCLinkerTool") {
 938                 foreach my $vc_linker_tool ($vc_configuration_tools->attributes) {
 939                     if ($vc_linker_tool->getName eq "AdditionalDependencies") {
 940                         $prj_target_libs=" ".$vc_linker_tool->getValue;
 941                         $prj_target_libs=~s/\\/\//g;
 942                         $prj_target_libs=~s/\.lib//g;
 943                         $prj_target_libs=~s/\s+/ -l/g;
 944                     }
 945                 }
 946             }
 947         }
 948
 949         push @{@$project_settings[$T_LIBRARIES]},$prj_target_libs;
 950         push @{@$project_settings[$T_CEXTRA]},$prj_target_cflags;
 951         push @{@$project_settings[$T_CXXEXTRA]},$prj_target_cflags;
 952         push @{@$project_settings[$T_DEFINES]},$prj_target_defines;
 953     }
 954
 955     # Add this project to the project list, except for
 956     # the main project which is already in the list.
 957     if ($is_sub_project == 1) {
 958         push @projects,$project;
 959     }
 960
 961     # Ask for project-wide options
 962     if ($opt_ask_project_options == $OPT_ASK_YES) {
 963         my $flag_desc="";
 964         if ((@$project_settings[$T_FLAGS] & $TF_MFC)!=0) {
 965             $flag_desc="mfc";
 966         }
 967         print "* Type any project-wide options (-D/-I/-P/-i/-L/-l/--mfc),\n";
 968         if (defined $flag_desc) {
 969             print "* (currently $flag_desc)\n";
 970         }
 971         print "* or 'skip' to skip the target specific options,\n";
 972         print "* or 'never' to not be asked this question again:\n";
 973         while (1) {
 974             my $options=<STDIN>;
 975             chomp $options;
 976             if ($options eq "skip") {
 977                 $opt_ask_target_options=$OPT_ASK_SKIP;
 978                 last;
 979             } elsif ($options eq "never") {
 980                 $opt_ask_project_options=$OPT_ASK_NO;
 981                 last;
 982             } elsif (source_set_options($project_settings,$options)) {
 983                 last;
 984             }
 985             print "Please re-enter the options:\n";
 986         }
 987     }
 988
 989     my @local_dlls=();
 990     my @local_depends=();
 991     my @exe_list=();
 992
 993     # Create the target...
 994     my $target=[];
 995     target_init($target);
 996
 997     if ($prj_target_type!=$TT_DLL) {
 998         $prj_name=lc($prj_name.".exe");
 999         @$target[$T_TYPE]=$opt_target_type;
1000         push @exe_list,$target;
1001         push @{@$target[$T_LDFLAGS]},(@$target[$T_TYPE] == $TT_CUIEXE ? "-mconsole" : "-mwindows");
1002     } else {
1003         $prj_name=lc($prj_name.".dll");
1004         @$target[$T_TYPE]=$TT_DLL;
1005         push @local_depends,"$prj_name.so";
1006         push @local_dlls,$prj_name;
1007         my $canon=canonize($prj_name);
1008         push @{@$target[$T_LDFLAGS]},("-shared","\$(${canon}_MODULE:%=%.spec)");
1009     }
1010
1011     @$target[$T_NAME]=$prj_name;
1012     @$target[$T_FLAGS]|=@$project_settings[$T_FLAGS];
1013
1014     # This is the default link list of Visual Studio
1015     my @std_imports=qw(odbc32 ole32 oleaut32 winspool odbccp32);
1016     my @std_libraries=qw(uuid);
1017     if ((@$target[$T_FLAGS] & $TF_NODLLS) == 0) {
1018         @$target[$T_DLLS]=\@std_imports;
1019         @$target[$T_LIBRARIES]=\@std_libraries;
1020     } else {
1021         @$target[$T_DLLS]=[];
1022         @$target[$T_LIBRARIES]=[];
1023     }
1024     if ((@$target[$T_FLAGS] & $TF_NOMSVCRT) == 0) {
1025         push @{@$target[$T_LDFLAGS]},"-mno-cygwin";
1026         if ($opt_arch != $OPT_ARCH_DEFAULT) {
1027             push @{@$target[$T_LDFLAGS]},"-m$opt_arch";
1028         }
1029     }
1030     push @{@$project[$P_TARGETS]},$target;
1031
1032     # Ask for target-specific options
1033     if ($opt_ask_target_options == $OPT_ASK_YES) {
1034         my $flag_desc="";
1035         if ((@$target[$T_FLAGS] & $TF_MFC)!=0) {
1036             $flag_desc=" (mfc";
1037         }
1038         if ($flag_desc ne "") {
1039             $flag_desc.=")";
1040         }
1041         print "* Specify any link option (-P/-i/-L/-l/--mfc) specific to the target\n";
1042         print "* \"$prj_name\"$flag_desc or 'never' to not be asked this question again:\n";
1043         while (1) {
1044         my $options=<STDIN>;
1045         chomp $options;
1046         if ($options eq "never") {
1047             $opt_ask_target_options=$OPT_ASK_NO;
1048             last;
1049         } elsif (source_set_options($target,$options)) {
1050             last;
1051         }
1052         print "Please re-enter the options:\n";
1053         }
1054     }
1055     if (@$target[$T_FLAGS] & $TF_MFC) {
1056         @$project_settings[$T_FLAGS]|=$TF_MFC;
1057         push @{@$target[$T_DLL_PATH]},"\$(MFC_LIBRARY_PATH)";
1058         push @{@$target[$T_DLLS]},"mfc.dll";
1059         # FIXME: Link with the MFC in the Unix sense, until we
1060         # start exporting the functions properly.
1061         push @{@$target[$T_LIBRARY_PATH]},"\$(MFC_LIBRARY_PATH)";
1062         push @{@$target[$T_LIBRARIES]},"mfc";
1063     }
1064
1065     # Match sources...
1066     push @{@$target[$T_SOURCES_C]},@{@$project_settings[$T_SOURCES_C]},@sources_c;
1067     @$project_settings[$T_SOURCES_C]=[];
1068     @sources_c=();
1069     push @{@$target[$T_SOURCES_CXX]},@{@$project_settings[$T_SOURCES_CXX]},@sources_cxx;
1070     @$project_settings[$T_SOURCES_CXX]=[];
1071     @sources_cxx=();
1072     push @{@$target[$T_SOURCES_RC]},@{@$project_settings[$T_SOURCES_RC]},@sources_rc;
1073     @$project_settings[$T_SOURCES_RC]=[];
1074     @sources_rc=();
1075     push @{@$target[$T_SOURCES_MISC]},@{@$project_settings[$T_SOURCES_MISC]},@sources_misc;
1076     @$project_settings[$T_SOURCES_MISC]=[];
1077     @sources_misc=();
1078
1079     @$target[$T_SOURCES_C]=[sort @{@$target[$T_SOURCES_C]}];
1080     @$target[$T_SOURCES_CXX]=[sort @{@$target[$T_SOURCES_CXX]}];
1081     @$target[$T_SOURCES_RC]=[sort @{@$target[$T_SOURCES_RC]}];
1082     @$target[$T_SOURCES_MISC]=[sort @{@$target[$T_SOURCES_MISC]}];
1083
1084     if ($opt_ask_target_options == $OPT_ASK_SKIP) {
1085         $opt_ask_target_options=$OPT_ASK_YES;
1086     }
1087
1088     if ((@$project_settings[$T_FLAGS] & $TF_NOMSVCRT) == 0) {
1089         push @{@$project_settings[$T_CEXTRA]},"-mno-cygwin";
1090         push @{@$project_settings[$T_CXXEXTRA]},"-mno-cygwin";
1091         if ($opt_arch != $OPT_ARCH_DEFAULT) {
1092             push @{@$project_settings[$T_CEXTRA]},"-m$opt_arch";
1093             push @{@$project_settings[$T_CXXEXTRA]},"-m$opt_arch";
1094         }
1095     }
1096
1097     if (@$project_settings[$T_FLAGS] & $TF_MFC) {
1098         push @{@$project_settings[$T_INCLUDE_PATH]},"\$(MFC_INCLUDE_PATH)";
1099     }
1100     # The sources that did not match, if any, go to the extra
1101     # source list of the project settings
1102     foreach my $source (@sources_c) {
1103         if ($source ne "") {
1104             push @{@$project_settings[$T_SOURCES_C]},$source;
1105         }
1106     }
1107     @$project_settings[$T_SOURCES_C]=[sort @{@$project_settings[$T_SOURCES_C]}];
1108     foreach my $source (@sources_cxx) {
1109         if ($source ne "") {
1110             push @{@$project_settings[$T_SOURCES_CXX]},$source;
1111         }
1112     }
1113     @$project_settings[$T_SOURCES_CXX]=[sort @{@$project_settings[$T_SOURCES_CXX]}];
1114     foreach my $source (@sources_rc) {
1115         if ($source ne "") {
1116             push @{@$project_settings[$T_SOURCES_RC]},$source;
1117         }
1118     }
1119     @$project_settings[$T_SOURCES_RC]=[sort @{@$project_settings[$T_SOURCES_RC]}];
1120     foreach my $source (@sources_misc) {
1121         if ($source ne "") {
1122             push @{@$project_settings[$T_SOURCES_MISC]},$source;
1123         }
1124     }
1125     @$project_settings[$T_SOURCES_MISC]=[sort @{@$project_settings[$T_SOURCES_MISC]}];
1126 }
1127
1128 ##
1129 # Scans the specified workspace file to find the project files
1130 sub source_scan_workspace_file($);
1131 sub source_scan_workspace_file($)
1132 {
1133     my $filename=$_[0];
1134     my $path=dirname($filename);
1135     my @components;
1136
1137     if (! -e $filename) {
1138         return;
1139     }
1140
1141     if (!open(FILEIWS,$filename)) {
1142         print STDERR "error: unable to open $filename for reading:\n";
1143         print STDERR "       $!\n";
1144         return;
1145     }
1146
1147     my $prj_name;
1148     my $prj_path;
1149
1150     if ($filename =~ /.dsw$/i) {
1151         while (<FILEIWS>) {
1152             # Remove any trailing CrLf
1153             s/\r\n$/\n/;
1154
1155             # catch a project definition
1156             if (/^Project:\s\"(.*)\"=(.*)\s-/) {
1157                 $prj_name=$1;
1158                 $prj_path=$2;
1159                 @components=split /[\/\\]+/, $prj_path;
1160                 $prj_path=search_from($path, \@components);
1161                 print "Name: $prj_name\nPath: $prj_path\n";
1162                 source_scan_project_file(\@main_project,1,$prj_path);
1163                 next;
1164             } elsif (/^#/) {
1165                 # ignore Comments
1166             } elsif (/^Global:/) {
1167                 # ignore the Global section
1168             } elsif (/\w:/) {
1169                 print STDERR "unknown section $_\n";
1170             } elsif (/^Microsoft(.*)Studio(.*)File,\sFormat Version\s(.*)/) {
1171                 print "\nFileversion: $3\n";
1172             }
1173         }
1174         close(FILEIWS);
1175     } elsif ($filename =~ /.sln$/i) {
1176         while (<FILEIWS>) {
1177             # Remove any trailing CrLf
1178             s/\r\n$/\n/;
1179
1180             # catch a project definition
1181             if (/^Project(.*)=\s*"(.*)",\s*"(.*)",\s*"(.*)"/) {
1182                 $prj_name=$2;
1183                 $prj_path=$3;
1184                 @components=split /[\/\\]+/, $3;
1185                 $prj_path=search_from($path, \@components);
1186                 print "Name: $prj_name\nPath: $prj_path\n";
1187                 source_scan_project_file(\@main_project,1,$prj_path);
1188                 next;
1189             } elsif (/^Microsoft(.*)Studio(.*)File,\sFormat Version\s(.*)/) {
1190                 print "\nFileversion: $3\n";
1191             }
1192         }
1193         close(FILEIWS);
1194     }
1195
1196     @projects=sort { @$a[$P_PATH] cmp @$b[$P_PATH] } @projects;
1197 }
1198
1199 ##
1200 # Scans the specified directory to:
1201 # - see if we should create a Makefile in this directory. We normally do
1202 #   so if we find a project file and sources
1203 # - get a list of targets for this directory
1204 # - get the list of source files
1205 sub source_scan_directory($$$$);
1206 sub source_scan_directory($$$$)
1207 {
1208   # a reference to the parent's project
1209   my $parent_project=$_[0];
1210   # the full relative path to the current directory, including a
1211   # trailing '/', or an empty string if this is the top level directory
1212   my $path=$_[1];
1213   # the name of this directory, including a trailing '/', or an empty
1214   # string if this is the top level directory
1215   my $dirname=$_[2];
1216   # if set then no targets will be looked for and the sources will all
1217   # end up in the parent_project's 'misc' bucket
1218   my $no_target=$_[3];
1219
1220   # reference to the project for this directory. May not be used
1221   my $project;
1222   # list of targets found in the 'current' directory
1223   my %targets;
1224   # list of sources found in the current directory
1225   my @sources_c=();
1226   my @sources_cxx=();
1227   my @sources_rc=();
1228   my @sources_misc=();
1229   # true if this directory contains a Windows project
1230   my $has_win_project=0;
1231   # true if this directory contains headers
1232   my $has_headers=0;
1233   # If we don't find any executable/library then we might make up targets
1234   # from the list of .dsp/.mak files we find since they usually have the
1235   # same name as their target.
1236   my @prj_files=();
1237   my @mak_files=();
1238
1239   if (defined $opt_single_target or $dirname eq "") {
1240     # Either there is a single target and thus a single project,
1241     # or we are in the top level directory for which a project
1242     # already exists
1243     $project=$parent_project;
1244   } else {
1245     $project=[];
1246     project_init($project, $path, \@global_settings);
1247   }
1248   my $project_settings=@$project[$P_SETTINGS];
1249
1250   # First find out what this directory contains:
1251   # collect all sources, targets and subdirectories
1252   my $directory=get_directory_contents($path);
1253   foreach my $dentry (@$directory) {
1254     if ($dentry =~ /^\./) {
1255       next;
1256     }
1257     my $fullentry="$path$dentry";
1258     if (-d "$fullentry") {
1259       if ($dentry =~ /^(Release|Debug)/i) {
1260         # These directories are often used to store the object files and the
1261         # resulting executable/library. They should not contain anything else.
1262         my @candidates=grep /\.(exe|dll)$/i, @{get_directory_contents("$fullentry")};
1263         foreach my $candidate (@candidates) {
1264           $targets{$candidate}=1;
1265         }
1266       } elsif ($dentry =~ /^include/i) {
1267         # This directory must contain headers we're going to need
1268         push @{@$project_settings[$T_INCLUDE_PATH]},"-I$dentry";
1269         source_scan_directory($project,"$fullentry/","$dentry/",1);
1270       } else {
1271         # Recursively scan this directory. Any source file that cannot be
1272         # attributed to a project in one of the subdirectories will be
1273         # attributed to this project.
1274         source_scan_directory($project,"$fullentry/","$dentry/",$no_target);
1275       }
1276     } elsif (-f "$fullentry") {
1277       if ($dentry =~ /\.(exe|dll)$/i) {
1278         $targets{$dentry}=1;
1279       } elsif ($dentry =~ /\.c$/i and $dentry !~ /\.(dbg|spec)\.c$/) {
1280         push @sources_c,"$dentry";
1281       } elsif ($dentry =~ /\.(cpp|cxx)$/i) {
1282         if ($dentry =~ /^stdafx.cpp$/i && !(@$project_settings[$T_FLAGS] & $TF_NOMFC)) {
1283           push @sources_misc,"$dentry";
1284           @$project_settings[$T_FLAGS]|=$TF_MFC;
1285         } else {
1286           push @sources_cxx,"$dentry";
1287         }
1288       } elsif ($dentry =~ /\.rc$/i) {
1289         push @sources_rc,"$dentry";
1290       } elsif ($dentry =~ /\.(h|hxx|hpp|inl|rc2|dlg)$/i) {
1291         $has_headers=1;
1292         push @sources_misc,"$dentry";
1293         if ($dentry =~ /^stdafx.h$/i && !(@$project_settings[$T_FLAGS] & $TF_NOMFC)) {
1294           @$project_settings[$T_FLAGS]|=$TF_MFC;
1295         }
1296       } elsif ($dentry =~ /\.(dsp|vcproj)$/i) {
1297         push @prj_files,"$dentry";
1298         $has_win_project=1;
1299       } elsif ($dentry =~ /\.mak$/i) {
1300         push @mak_files,"$dentry";
1301         $has_win_project=1;
1302       } elsif ($dentry =~ /^makefile/i) {
1303         $has_win_project=1;
1304       }
1305     }
1306   }
1307
1308   if ($has_headers) {
1309     push @{@$project_settings[$T_INCLUDE_PATH]},"-I.";
1310   }
1311   # If we have a single target then all we have to do is assign
1312   # all the sources to it and we're done
1313   # FIXME: does this play well with the --interactive mode?
1314   if ($opt_single_target) {
1315     my $target=@{@$project[$P_TARGETS]}[0];
1316     push @{@$target[$T_SOURCES_C]},map "$path$_",@sources_c;
1317     push @{@$target[$T_SOURCES_CXX]},map "$path$_",@sources_cxx;
1318     push @{@$target[$T_SOURCES_RC]},map "$path$_",@sources_rc;
1319     push @{@$target[$T_SOURCES_MISC]},map "$path$_",@sources_misc;
1320     return;
1321   }
1322   if ($no_target) {
1323     my $parent_settings=@$parent_project[$P_SETTINGS];
1324     push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@sources_c;
1325     push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@sources_cxx;
1326     push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@sources_rc;
1327     push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@sources_misc;
1328     push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@{@$project_settings[$T_SOURCES_MISC]};
1329     return;
1330   }
1331
1332   my $source_count=@sources_c+@sources_cxx+@sources_rc+
1333                    @{@$project_settings[$T_SOURCES_C]}+
1334                    @{@$project_settings[$T_SOURCES_CXX]}+
1335                    @{@$project_settings[$T_SOURCES_RC]};
1336   if ($source_count == 0) {
1337     # A project without real sources is not a project, get out!
1338     if ($project!=$parent_project) {
1339       my $parent_settings=@$parent_project[$P_SETTINGS];
1340       push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@sources_misc;
1341       push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@{@$project_settings[$T_SOURCES_MISC]};
1342     }
1343     return;
1344   }
1345   #print "targets=",%targets,"\n";
1346   #print "target_count=$target_count\n";
1347   #print "has_win_project=$has_win_project\n";
1348   #print "dirname=$dirname\n";
1349
1350   my $target_count;
1351   if (($has_win_project != 0) or ($dirname eq "")) {
1352     # Deal with cases where we could not find any executable/library, and
1353     # thus have no target, although we did find some sort of windows project.
1354     $target_count=keys %targets;
1355     if ($target_count == 0) {
1356       # Try to come up with a target list based on .dsp/.mak files
1357       my $prj_list;
1358       if (@prj_files > 0) {
1359         print "Projectfile found! You might want to try using it directly.\n";
1360         $prj_list=\@prj_files;
1361       } else {
1362         $prj_list=\@mak_files;
1363       }
1364       foreach my $filename (@$prj_list) {
1365         $filename =~ s/\.(dsp|vcproj|mak)$//i;
1366         if ($opt_target_type == $TT_DLL) {
1367           $filename = "$filename.dll";
1368         }
1369         $targets{$filename}=1;
1370       }
1371       $target_count=keys %targets;
1372       if ($target_count == 0) {
1373         # Still nothing, try the name of the directory
1374         my $name;
1375         if ($dirname eq "") {
1376           # Bad luck, this is the top level directory!
1377           $name=(split /\//, cwd)[-1];
1378         } else {
1379           $name=$dirname;
1380           # Remove the trailing '/'. Also eliminate whatever is after the last
1381           # '.' as it is likely to be meaningless (.orig, .new, ...)
1382           $name =~ s+(/|\.[^.]*)$++;
1383           if ($name eq "src") {
1384             # 'src' is probably a subdirectory of the real project directory.
1385             # Try again with the parent (if any).
1386             my $parent=$path;
1387             if ($parent =~ s+([^/]*)/[^/]*/$+$1+) {
1388               $name=$parent;
1389             } else {
1390               $name=(split /\//, cwd)[-1];
1391             }
1392           }
1393         }
1394         $name =~ s+(/|\.[^.]*)$++;
1395         if ($opt_target_type == $TT_DLL) {
1396           $name = canonize($name).".dll";
1397         } else {
1398           $name = canonize($name).".exe";
1399         }
1400         $targets{$name}=1;
1401       }
1402     }
1403
1404     # Ask confirmation to the user if he wishes so
1405     if ($opt_is_interactive == $OPT_ASK_YES) {
1406       my $target_list=join " ",keys %targets;
1407       print "\n*** In ",($path?$path:"./"),"\n";
1408       print "* winemaker found the following list of (potential) targets\n";
1409       print "*   $target_list\n";
1410       print "* Type enter to use it as is, your own comma-separated list of\n";
1411       print "* targets, 'none' to assign the source files to a parent directory,\n";
1412       print "* or 'ignore' to ignore everything in this directory tree.\n";
1413       print "* Target list:\n";
1414       $target_list=<STDIN>;
1415       chomp $target_list;
1416       if ($target_list eq "") {
1417         # Keep the target list as is, i.e. do nothing
1418       } elsif ($target_list eq "none") {
1419         # Empty the target list
1420         undef %targets;
1421       } elsif ($target_list eq "ignore") {
1422         # Ignore this subtree altogether
1423         return;
1424       } else {
1425         undef %targets;
1426         foreach my $target (split /,/,$target_list) {
1427           $target =~ s+^\s*++;
1428           $target =~ s+\s*$++;
1429           $targets{$target}=1;
1430         }
1431       }
1432     }
1433   }
1434
1435   # If we have no project at this level, then transfer all
1436   # the sources to the parent project
1437   $target_count=keys %targets;
1438   if ($target_count == 0) {
1439     if ($project!=$parent_project) {
1440       my $parent_settings=@$parent_project[$P_SETTINGS];
1441       push @{@$parent_settings[$T_SOURCES_C]},map "$dirname$_",@sources_c;
1442       push @{@$parent_settings[$T_SOURCES_CXX]},map "$dirname$_",@sources_cxx;
1443       push @{@$parent_settings[$T_SOURCES_RC]},map "$dirname$_",@sources_rc;
1444       push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@sources_misc;
1445       push @{@$parent_settings[$T_SOURCES_MISC]},map "$dirname$_",@{@$project_settings[$T_SOURCES_MISC]};
1446     }
1447     return;
1448   }
1449
1450   # Otherwise add this project to the project list, except for
1451   # the main project which is already in the list.
1452   if ($dirname ne "") {
1453     push @projects,$project;
1454   }
1455
1456   # Ask for project-wide options
1457   if ($opt_ask_project_options == $OPT_ASK_YES) {
1458     my $flag_desc="";
1459     if ((@$project_settings[$T_FLAGS] & $TF_MFC)!=0) {
1460       $flag_desc="mfc";
1461     }
1462     print "* Type any project-wide options (-D/-I/-P/-i/-L/-l/--mfc),\n";
1463     if (defined $flag_desc) {
1464       print "* (currently $flag_desc)\n";
1465     }
1466     print "* or 'skip' to skip the target specific options,\n";
1467     print "* or 'never' to not be asked this question again:\n";
1468     while (1) {
1469       my $options=<STDIN>;
1470       chomp $options;
1471       if ($options eq "skip") {
1472         $opt_ask_target_options=$OPT_ASK_SKIP;
1473         last;
1474       } elsif ($options eq "never") {
1475         $opt_ask_project_options=$OPT_ASK_NO;
1476         last;
1477       } elsif (source_set_options($project_settings,$options)) {
1478         last;
1479       }
1480       print "Please re-enter the options:\n";
1481     }
1482   }
1483
1484   # - Create the targets
1485   # - Check if we have both libraries and programs
1486   # - Match each target with source files (sort in reverse
1487   #   alphabetical order to get the longest matches first)
1488   my @local_dlls=();
1489   my @local_depends=();
1490   my @exe_list=();
1491   foreach my $target_name (map (lc, (sort { $b cmp $a } keys %targets))) {
1492     # Create the target...
1493     my $target=[];
1494     target_init($target);
1495     @$target[$T_NAME]=$target_name;
1496     @$target[$T_FLAGS]|=@$project_settings[$T_FLAGS];
1497     if ($target_name =~ /\.dll$/) {
1498       @$target[$T_TYPE]=$TT_DLL;
1499       push @local_depends,"$target_name.so";
1500       push @local_dlls,$target_name;
1501       my $canon=canonize($target_name);
1502       push @{@$target[$T_LDFLAGS]},("-shared","\$(${canon}_MODULE:%=%.spec)");
1503     } else {
1504       @$target[$T_TYPE]=$opt_target_type;
1505       push @exe_list,$target;
1506       push @{@$target[$T_LDFLAGS]},(@$target[$T_TYPE] == $TT_CUIEXE ? "-mconsole" : "-mwindows");
1507     }
1508     my $basename=$target_name;
1509     $basename=~ s/\.(dll|exe)$//i;
1510     # This is the default link list of Visual Studio
1511     my @std_imports=qw(odbc32 ole32 oleaut32 winspool odbccp32);
1512     my @std_libraries=qw(uuid);
1513     if ((@$target[$T_FLAGS] & $TF_NODLLS) == 0) {
1514       @$target[$T_DLLS]=\@std_imports;
1515       @$target[$T_LIBRARIES]=\@std_libraries;
1516     } else {
1517       @$target[$T_DLLS]=[];
1518       @$target[$T_LIBRARIES]=[];
1519     }
1520     if ((@$target[$T_FLAGS] & $TF_NOMSVCRT) == 0) {
1521       push @{@$target[$T_LDFLAGS]},"-mno-cygwin";
1522       if ($opt_arch != $OPT_ARCH_DEFAULT) {
1523         push @{@$target[$T_LDFLAGS]},"-m$opt_arch";
1524       }
1525     }
1526     push @{@$project[$P_TARGETS]},$target;
1527
1528     # Ask for target-specific options
1529     if ($opt_ask_target_options == $OPT_ASK_YES) {
1530       my $flag_desc="";
1531       if ((@$target[$T_FLAGS] & $TF_MFC)!=0) {
1532         $flag_desc=" (mfc";
1533       }
1534       if ($flag_desc ne "") {
1535         $flag_desc.=")";
1536       }
1537       print "* Specify any link option (-P/-i/-L/-l/--mfc) specific to the target\n";
1538       print "* \"$target_name\"$flag_desc or 'never' to not be asked this question again:\n";
1539       while (1) {
1540         my $options=<STDIN>;
1541         chomp $options;
1542         if ($options eq "never") {
1543           $opt_ask_target_options=$OPT_ASK_NO;
1544           last;
1545         } elsif (source_set_options($target,$options)) {
1546           last;
1547         }
1548         print "Please re-enter the options:\n";
1549       }
1550     }
1551     if (@$target[$T_FLAGS] & $TF_MFC) {
1552       @$project_settings[$T_FLAGS]|=$TF_MFC;
1553       push @{@$target[$T_DLL_PATH]},"\$(MFC_LIBRARY_PATH)";
1554       push @{@$target[$T_DLLS]},"mfc.dll";
1555       # FIXME: Link with the MFC in the Unix sense, until we
1556       # start exporting the functions properly.
1557       push @{@$target[$T_LIBRARY_PATH]},"\$(MFC_LIBRARY_PATH)";
1558       push @{@$target[$T_LIBRARIES]},"mfc";
1559     }
1560
1561     # Match sources...
1562     if ($target_count == 1) {
1563       push @{@$target[$T_SOURCES_C]},@{@$project_settings[$T_SOURCES_C]},@sources_c;
1564       @$project_settings[$T_SOURCES_C]=[];
1565       @sources_c=();
1566
1567       push @{@$target[$T_SOURCES_CXX]},@{@$project_settings[$T_SOURCES_CXX]},@sources_cxx;
1568       @$project_settings[$T_SOURCES_CXX]=[];
1569       @sources_cxx=();
1570
1571       push @{@$target[$T_SOURCES_RC]},@{@$project_settings[$T_SOURCES_RC]},@sources_rc;
1572       @$project_settings[$T_SOURCES_RC]=[];
1573       @sources_rc=();
1574
1575       push @{@$target[$T_SOURCES_MISC]},@{@$project_settings[$T_SOURCES_MISC]},@sources_misc;
1576       # No need for sorting these sources
1577       @$project_settings[$T_SOURCES_MISC]=[];
1578       @sources_misc=();
1579     } else {
1580       foreach my $source (@sources_c) {
1581         if ($source =~ /^$basename/i) {
1582           push @{@$target[$T_SOURCES_C]},$source;
1583           $source="";
1584         }
1585       }
1586       foreach my $source (@sources_cxx) {
1587         if ($source =~ /^$basename/i) {
1588           push @{@$target[$T_SOURCES_CXX]},$source;
1589           $source="";
1590         }
1591       }
1592       foreach my $source (@sources_rc) {
1593         if ($source =~ /^$basename/i) {
1594           push @{@$target[$T_SOURCES_RC]},$source;
1595           $source="";
1596         }
1597       }
1598       foreach my $source (@sources_misc) {
1599         if ($source =~ /^$basename/i) {
1600           push @{@$target[$T_SOURCES_MISC]},$source;
1601           $source="";
1602         }
1603       }
1604     }
1605     @$target[$T_SOURCES_C]=[sort @{@$target[$T_SOURCES_C]}];
1606     @$target[$T_SOURCES_CXX]=[sort @{@$target[$T_SOURCES_CXX]}];
1607     @$target[$T_SOURCES_RC]=[sort @{@$target[$T_SOURCES_RC]}];
1608     @$target[$T_SOURCES_MISC]=[sort @{@$target[$T_SOURCES_MISC]}];
1609   }
1610   if ($opt_ask_target_options == $OPT_ASK_SKIP) {
1611     $opt_ask_target_options=$OPT_ASK_YES;
1612   }
1613
1614   if ((@$project_settings[$T_FLAGS] & $TF_NOMSVCRT) == 0) {
1615     push @{@$project_settings[$T_CEXTRA]},"-mno-cygwin";
1616     push @{@$project_settings[$T_CXXEXTRA]},"-mno-cygwin";
1617       if ($opt_arch != $OPT_ARCH_DEFAULT) {
1618         push @{@$project_settings[$T_CEXTRA]},"-m$opt_arch";
1619         push @{@$project_settings[$T_CXXEXTRA]},"-m$opt_arch";
1620       }
1621   }
1622
1623   if (@$project_settings[$T_FLAGS] & $TF_MFC) {
1624     push @{@$project_settings[$T_INCLUDE_PATH]},"\$(MFC_INCLUDE_PATH)";
1625   }
1626   # The sources that did not match, if any, go to the extra
1627   # source list of the project settings
1628   foreach my $source (@sources_c) {
1629     if ($source ne "") {
1630       push @{@$project_settings[$T_SOURCES_C]},$source;
1631     }
1632   }
1633   @$project_settings[$T_SOURCES_C]=[sort @{@$project_settings[$T_SOURCES_C]}];
1634   foreach my $source (@sources_cxx) {
1635     if ($source ne "") {
1636       push @{@$project_settings[$T_SOURCES_CXX]},$source;
1637     }
1638   }
1639   @$project_settings[$T_SOURCES_CXX]=[sort @{@$project_settings[$T_SOURCES_CXX]}];
1640   foreach my $source (@sources_rc) {
1641     if ($source ne "") {
1642       push @{@$project_settings[$T_SOURCES_RC]},$source;
1643     }
1644   }
1645   @$project_settings[$T_SOURCES_RC]=[sort @{@$project_settings[$T_SOURCES_RC]}];
1646   foreach my $source (@sources_misc) {
1647     if ($source ne "") {
1648       push @{@$project_settings[$T_SOURCES_MISC]},$source;
1649     }
1650   }
1651   @$project_settings[$T_SOURCES_MISC]=[sort @{@$project_settings[$T_SOURCES_MISC]}];
1652
1653   # Finally if we are building both libraries and programs in
1654   # this directory, then the programs should be linked with all
1655   # the libraries
1656   if (@local_dlls > 0 and @exe_list > 0) {
1657     foreach my $target (@exe_list) {
1658       push @{@$target[$T_DLL_PATH]},"-L.";
1659       push @{@$target[$T_DLLS]},@local_dlls;
1660     }
1661   }
1662 }
1663
1664 ##
1665 # Scan the source directories in search of things to build
1666 sub source_scan()
1667 {
1668   # If there's a single target then this is going to be the default target
1669   if (defined $opt_single_target) {
1670     # Create the main target
1671     my $main_target=[];
1672     target_init($main_target);
1673     @$main_target[$T_NAME]=$opt_single_target;
1674     @$main_target[$T_TYPE]=$opt_target_type;
1675
1676     # Add it to the list
1677     push @{$main_project[$P_TARGETS]},$main_target;
1678   }
1679
1680   # The main directory is always going to be there
1681   push @projects,\@main_project;
1682
1683     if (defined $opt_work_dir) {
1684         # Now scan the directory tree looking for source files and, maybe, targets
1685         print "Scanning the source directories...\n";
1686         source_scan_directory(\@main_project,"","",0);
1687         @projects=sort { @$a[$P_PATH] cmp @$b[$P_PATH] } @projects;
1688     } elsif (defined $opt_work_file) {
1689         if ($opt_work_file =~ /.dsp$/i or $opt_work_file =~ /.vcproj$/i) {
1690             source_scan_project_file(\@main_project,0,$opt_work_file);
1691         } elsif ($opt_work_file =~ /.dsw$/i or $opt_work_file =~ /.sln$/i) {
1692             source_scan_workspace_file($opt_work_file);
1693         }
1694     }
1695 }
1696
1697 #####
1698 #
1699 # Source search
1700 #
1701 #####
1702
1703 ##
1704 # Performs a directory traversal and renames the files so that:
1705 # - they have the case desired by the user
1706 # - their extension is of the appropriate case
1707 # - they don't contain annoying characters like ' ', '$', '#', ...
1708 # But only perform these changes for source files and directories.
1709 sub fix_file_and_directory_names($);
1710 sub fix_file_and_directory_names($)
1711 {
1712   my $dirname=$_[0];
1713
1714   my $directory=get_directory_contents($dirname);
1715   foreach my $dentry (@$directory)
1716   {
1717       if ($dentry =~ /^\./ or $dentry eq "CVS") {
1718           next;
1719       }
1720       # Set $warn to 1 if the user should be warned of the renaming
1721       my $warn;
1722       my $new_name=$dentry;
1723
1724       if (-f "$dirname/$dentry")
1725       {
1726           # Don't rename Winemaker's makefiles
1727           next if ($dentry eq "Makefile" and
1728                    `head -n 1 "$dirname/$dentry"` =~ /Generated by Winemaker/);
1729
1730           # Leave non-source files alone
1731           next if ($new_name !~ /(^makefile|\.(c|cpp|h|rc))$/i);
1732
1733           # Only all lowercase extensions are supported (because of
1734           # rules like '.c.o:'.
1735           $new_name =~ s/\.C$/.c/;
1736           $new_name =~ s/\.cpp$/.cpp/i;
1737           $warn=1 if ($new_name =~ s/\.cxx$/.cpp/i);
1738           $new_name =~ s/\.rc$/.rc/i;
1739           # And this last one is to avoid confusion then running make
1740           $warn=1 if ($new_name =~ s/^makefile$/makefile.win/i);
1741       }
1742
1743       # Adjust the case to the user's preferences
1744       if (($opt_lower == $OPT_LOWER_ALL and $dentry =~ /[A-Z]/) or
1745           ($opt_lower == $OPT_LOWER_UPPERCASE and $dentry !~ /[a-z]/)
1746          ) {
1747           $new_name=lc $new_name;
1748       }
1749
1750       # autoconf and make don't support these characters well
1751       $new_name =~ s/[ \$]/_/g;
1752
1753       # And finally, perform the renaming
1754       if ($new_name ne $dentry)
1755       {
1756           if ($warn) {
1757               print STDERR "warning: in \"$dirname\", renaming \"$dentry\" to \"$new_name\"\n";
1758           }
1759           if (!rename("$dirname/$dentry","$dirname/$new_name")) {
1760               print STDERR "error: in \"$dirname\", unable to rename \"$dentry\" to \"$new_name\"\n";
1761               print STDERR "       $!\n";
1762               $new_name=$dentry;
1763           }
1764           else
1765           {
1766               clear_directory_cache($dirname);
1767           }
1768       }
1769       if (-d "$dirname/$new_name") {
1770           fix_file_and_directory_names("$dirname/$new_name");
1771       }
1772   }
1773 }
1774
1775
1776
1777 #####
1778 #
1779 # Source fixup
1780 #
1781 #####
1782
1783 ##
1784 # Try to find a file for the specified filename. The attempt is
1785 # case-insensitive which is why it's not trivial. If a match is
1786 # found then we return the pathname with the correct case.
1787 sub search_from($$)
1788 {
1789   my $dirname=$_[0];
1790   my $path=$_[1];
1791   my $real_path="";
1792
1793   if ($dirname eq "" or $dirname eq "." or $dirname eq "./") {
1794     $dirname=cwd;
1795   } elsif ($dirname !~ m+^/+) {
1796     $dirname=cwd . "/" . $dirname;
1797   }
1798   if ($dirname !~ m+/$+) {
1799     $dirname.="/";
1800   }
1801
1802   foreach my $component (@$path) {
1803     $component=~s/^\"//;
1804     $component=~s/\"$//;
1805     #print "    looking for $component in \"$dirname\"\n";
1806     if ($component eq ".") {
1807       # Pass it as is
1808       $real_path.="./";
1809     } elsif ($component eq "..") {
1810       # Go up one level
1811       $dirname=dirname($dirname) . "/";
1812       $real_path.="../";
1813     } else {
1814       # The file/directory may have been renamed before. Also try to
1815       # match the renamed file.
1816       my $renamed=$component;
1817       $renamed =~ s/[ \$]/_/g;
1818       if ($renamed eq $component) {
1819         undef $renamed;
1820       }
1821
1822       my $directory=get_directory_contents $dirname;
1823       my $found;
1824       foreach my $dentry (@$directory) {
1825         if ($dentry =~ /^\Q$component\E$/i or
1826             (defined $renamed and $dentry =~ /^$renamed$/i)
1827            ) {
1828           $dirname.="$dentry/";
1829           $real_path.="$dentry/";
1830           $found=1;
1831           last;
1832         }
1833       }
1834       if (!defined $found) {
1835         # Give up
1836         #print "    could not find $component in $dirname\n";
1837         return;
1838       }
1839     }
1840   }
1841   $real_path=~ s+/$++;
1842   #print "    -> found $real_path\n";
1843   return $real_path;
1844 }
1845
1846 ##
1847 # Performs a case-insensitive search for the specified file in the
1848 # include path.
1849 # $line is the line number that should be referenced when an error occurs
1850 # $filename is the file we are looking for
1851 # $dirname is the directory of the file containing the '#include' directive
1852 #    if '"' was used, it is an empty string otherwise
1853 # $project and $target specify part of the include path
1854 sub get_real_include_name($$$$$)
1855 {
1856   my $line=$_[0];
1857   my $filename=$_[1];
1858   my $dirname=$_[2];
1859   my $project=$_[3];
1860   my $target=$_[4];
1861
1862   if ($filename =~ /^([a-zA-Z]:)?[\/]/ or $filename =~ /^[a-zA-Z]:[\/]?/) {
1863     # This is not a relative path, we cannot make any check
1864     my $warning="path:$filename";
1865     if (!defined $warnings{$warning}) {
1866       $warnings{$warning}="1";
1867       print STDERR "warning: cannot check the case of absolute pathnames:\n";
1868       print STDERR "$line:   $filename\n";
1869     }
1870   } else {
1871     # Here's how we proceed:
1872     # - split the filename we look for into its components
1873     # - then for each directory in the include path
1874     #   - trace the directory components starting from that directory
1875     #   - if we fail to find a match at any point then continue with
1876     #     the next directory in the include path
1877     #   - otherwise, rejoice, our quest is over.
1878     my @file_components=split /[\/\\]+/, $filename;
1879     #print "  Searching for $filename from @$project[$P_PATH]\n";
1880
1881     my $real_filename;
1882     if ($dirname ne "") {
1883       # This is an 'include ""' -> look in dirname first.
1884       #print "    in $dirname (include \"\")\n";
1885       $real_filename=search_from($dirname,\@file_components);
1886       if (defined $real_filename) {
1887         return $real_filename;
1888       }
1889     }
1890     my $project_settings=@$project[$P_SETTINGS];
1891     foreach my $include (@{@$target[$T_INCLUDE_PATH]}, @{@$project_settings[$T_INCLUDE_PATH]}) {
1892       my $dirname=$include;
1893       $dirname=~ s+^-I++;
1894       $dirname=~ s+\s$++;
1895       if (!is_absolute($dirname)) {
1896         $dirname="@$project[$P_PATH]$dirname";
1897       } else {
1898         $dirname=~ s+^\$\(TOPSRCDIR\)/++;
1899         $dirname=~ s+^\$\(SRCDIR\)/+@$project[$P_PATH]+;
1900       }
1901       #print "    in $dirname\n";
1902       $real_filename=search_from("$dirname",\@file_components);
1903       if (defined $real_filename) {
1904         return $real_filename;
1905       }
1906     }
1907     my $dotdotpath=@$project[$P_PATH];
1908     $dotdotpath =~ s/[^\/]+/../g;
1909     foreach my $include (@{$global_settings[$T_INCLUDE_PATH]}) {
1910       my $dirname=$include;
1911       $dirname=~ s+^-I++;
1912       $dirname=~ s+^\$\(TOPSRCDIR\)\/++;
1913       $dirname=~ s+^\$\(SRCDIR\)\/+@$project[$P_PATH]+;
1914       #print "    in $dirname  (global setting)\n";
1915       $real_filename=search_from("$dirname",\@file_components);
1916       if (defined $real_filename) {
1917         return $real_filename;
1918       }
1919     }
1920   }
1921   $filename =~ s+\\\\+/+g; # in include ""
1922   $filename =~ s+\\+/+g; # in include <> !
1923   if ($opt_lower_include) {
1924     return lc "$filename";
1925   }
1926   return $filename;
1927 }
1928
1929 sub print_pack($$$)
1930 {
1931   my $indent=$_[0];
1932   my $size=$_[1];
1933   my $trailer=$_[2];
1934
1935   if ($size =~ /^(1|2|4|8)$/) {
1936     print FILEO "$indent#include <pshpack$size.h>$trailer";
1937   } else {
1938     print FILEO "$indent/* winemaker:warning: Unknown size \"$size\". Defaulting to 4 */\n";
1939     print FILEO "$indent#include <pshpack4.h>$trailer";
1940   }
1941 }
1942
1943 ##
1944 # 'Parses' a source file and fixes constructs that would not work with
1945 # Winelib. The parsing is rather simple and not all non-portable features
1946 # are corrected. The most important feature that is corrected is the case
1947 # and path separator of '#include' directives. This requires that each
1948 # source file be associated to a project & target so that the proper
1949 # include path is used.
1950 # Also note that the include path is relative to the directory in which the
1951 # compiler is run, i.e. that of the project, not to that of the file.
1952 sub fix_file($$$)
1953 {
1954   my $filename=$_[0];
1955   my $project=$_[1];
1956   my $target=$_[2];
1957   $filename="@$project[$P_PATH]$filename";
1958   if (! -e $filename) {
1959     return;
1960   }
1961
1962   my $is_rc=($filename =~ /\.(rc2?|dlg)$/i);
1963   my $dirname=dirname($filename);
1964   my $is_mfc=0;
1965   if (defined $target and (@$target[$T_FLAGS] & $TF_MFC)) {
1966     $is_mfc=1;
1967   }
1968
1969   print "  $filename\n";
1970   #FIXME:assuming that because there is a .bak file, this is what we want is
1971   #probably flawed. Or is it???
1972   if (! -e "$filename.bak") {
1973     if (!copy("$filename","$filename.bak")) {
1974       print STDERR "error: unable to make a backup of $filename:\n";
1975       print STDERR "       $!\n";
1976       return;
1977     }
1978   }
1979   if (!open(FILEI,"$filename.bak")) {
1980     print STDERR "error: unable to open $filename.bak for reading:\n";
1981     print STDERR "       $!\n";
1982     return;
1983   }
1984   if (!open(FILEO,">$filename")) {
1985     print STDERR "error: unable to open $filename for writing:\n";
1986     print STDERR "       $!\n";
1987     return;
1988   }
1989   my $line=0;
1990   my $modified=0;
1991   my $rc_block_depth=0;
1992   my $rc_textinclude_state=0;
1993   my @pack_stack;
1994   while (<FILEI>) {
1995     # Remove any trailing CtrlZ, which isn't strictly in the file
1996     if (/\x1A/) {
1997       s/\x1A//;
1998       last if (/^$/)
1999     }
2000     $line++;
2001     s/\r\n$/\n/;
2002     if (!/\n$/) {
2003       # Make sure all files are '\n' terminated
2004       $_ .= "\n";
2005     }
2006     if ($is_rc and !$is_mfc and /^(\s*)(\#\s*include\s*)\"afxres\.h\"/) {
2007       # VC6 automatically includes 'afxres.h', an MFC specific header, in
2008       # the RC files it generates (even in non-MFC projects). So we replace
2009       # it with 'winresrc.h' its very close standard cousin so that non MFC
2010       # projects can compile in Wine without the MFC sources.
2011       my $warning="mfc:afxres.h";
2012       if (!defined $warnings{$warning}) {
2013         $warnings{$warning}="1";
2014         print STDERR "warning: In non-MFC projects, winemaker replaces the MFC specific header 'afxres.h' with 'winresrc.h'\n";
2015         print STDERR "warning: the above warning is issued only once\n";
2016       }
2017       print FILEO "$1/* winemaker: $2\"afxres.h\" */\n";
2018       print FILEO "$1/* winemaker:warning: 'afxres.h' is an MFC specific header. Replacing it with 'winresrc.h' */\n";
2019       print FILEO "$1$2\"winresrc.h\"$'";
2020       $modified=1;
2021
2022     } elsif (/^(\s*\#\s*include\s*)([\"<])([^\"]+)([\">])/) {
2023       my $from_file=($2 eq "<"?"":$dirname);
2024       my $real_include_name=get_real_include_name($line,$3,$from_file,$project,$target);
2025       print FILEO "$1$2$real_include_name$4$'";
2026       $modified|=($real_include_name ne $3);
2027
2028     } elsif (s/^(\s*)(\#\s*pragma\s+pack\s*\(\s*)//) {
2029       # Pragma pack handling
2030       #
2031       # pack_stack is an array of references describing the stack of
2032       # pack directives currently in effect. Each directive if described
2033       # by a reference to an array containing:
2034       # - "push" for pack(push,...) directives, "" otherwise
2035       # - the directive's identifier at index 1
2036       # - the directive's alignment value at index 2
2037       #
2038       # Don't believe a word of what the documentation says: it's all wrong.
2039       # The code below is based on the actual behavior of Visual C/C++ 6.
2040       my $pack_indent=$1;
2041       my $pack_header=$2;
2042       if (/^(\))/) {
2043         # pragma pack()
2044         # Pushes the default stack alignment
2045         print FILEO "$pack_indent/* winemaker: $pack_header$1 */\n";
2046         print FILEO "$pack_indent/* winemaker:warning: Using 4 as the default alignment */\n";
2047         print_pack($pack_indent,4,$');
2048         push @pack_stack, [ "", "", 4 ];
2049
2050       } elsif (/^(pop\s*(,\s*\d+\s*)?\))/) {
2051         # pragma pack(pop)
2052         # pragma pack(pop,n)
2053         # Goes up the stack until it finds a pack(push,...), and pops it
2054         # Ignores any pack(n) entry
2055         # Issues a warning if the pack is of the form pack(push,label)
2056         print FILEO "$pack_indent/* winemaker: $pack_header$1 */\n";
2057         my $pack_comment=$';
2058         $pack_comment =~ s/^\s*//;
2059         if ($pack_comment ne "") {
2060           print FILEO "$pack_indent$pack_comment";
2061         }
2062         while (1) {
2063           my $alignment=pop @pack_stack;
2064           if (!defined $alignment) {
2065             print FILEO "$pack_indent/* winemaker:warning: No pack(push,...) found. All the stack has been popped */\n";
2066             last;
2067           }
2068           if (@$alignment[1]) {
2069             print FILEO "$pack_indent/* winemaker:warning: Anonymous pop of pack(push,@$alignment[1]) (@$alignment[2]) */\n";
2070           }
2071           print FILEO "$pack_indent#include <poppack.h>\n";
2072           if (@$alignment[0]) {
2073             last;
2074           }
2075         }
2076
2077       } elsif (/^(pop\s*,\s*(\w+)\s*(,\s*\d+\s*)?\))/) {
2078         # pragma pack(pop,label[,n])
2079         # Goes up the stack until finding a pack(push,...) and pops it.
2080         # 'n', if specified, is ignored.
2081         # Ignores any pack(n) entry
2082         # Issues a warning if the label of the pack does not match,
2083         # or if it is in fact a pack(push,n)
2084         my $label=$2;
2085         print FILEO "$pack_indent/* winemaker: $pack_header$1 */\n";
2086         my $pack_comment=$';
2087         $pack_comment =~ s/^\s*//;
2088         if ($pack_comment ne "") {
2089           print FILEO "$pack_indent$pack_comment";
2090         }
2091         while (1) {
2092           my $alignment=pop @pack_stack;
2093           if (!defined $alignment) {
2094             print FILEO "$pack_indent/* winemaker:warning: No pack(push,$label) found. All the stack has been popped */\n";
2095             last;
2096           }
2097           if (@$alignment[1] and @$alignment[1] ne $label) {
2098             print FILEO "$pack_indent/* winemaker:warning: Push/pop mismatch: \"@$alignment[1]\" (@$alignment[2]) != \"$label\" */\n";
2099           }
2100           print FILEO "$pack_indent#include <poppack.h>\n";
2101           if (@$alignment[0]) {
2102             last;
2103           }
2104         }
2105
2106       } elsif (/^(push\s*\))/) {
2107         # pragma pack(push)
2108         # Push the current alignment
2109         print FILEO "$pack_indent/* winemaker: $pack_header$1 */\n";
2110         if (@pack_stack > 0) {
2111           my $alignment=$pack_stack[$#pack_stack];
2112           print_pack($pack_indent,@$alignment[2],$');
2113           push @pack_stack, [ "push", "", @$alignment[2] ];
2114         } else {
2115           print FILEO "$pack_indent/* winemaker:warning: Using 4 as the default alignment */\n";
2116           print_pack($pack_indent,4,$');
2117           push @pack_stack, [ "push", "", 4 ];
2118         }
2119
2120       } elsif (/^((push\s*,\s*)?(\d+)\s*\))/) {
2121         # pragma pack([push,]n)
2122         # Push new alignment n
2123         print FILEO "$pack_indent/* winemaker: $pack_header$1 */\n";
2124         print_pack($pack_indent,$3,"$'");
2125         push @pack_stack, [ ($2 ? "push" : ""), "", $3 ];
2126
2127       } elsif (/^((\w+)\s*\))/) {
2128         # pragma pack(label)
2129         # label must in fact be a macro that resolves to an integer
2130         # Then behaves like 'pragma pack(n)'
2131         print FILEO "$pack_indent/* winemaker: $pack_header$1 */\n";
2132         print FILEO "$pack_indent/* winemaker:warning: Assuming $2 == 4 */\n";
2133         print_pack($pack_indent,4,$');
2134         push @pack_stack, [ "", "", 4 ];
2135
2136       } elsif (/^(push\s*,\s*(\w+)\s*(,\s*(\d+)\s*)?\))/) {
2137         # pragma pack(push,label[,n])
2138         # Pushes a new label on the stack. It is possible to push the same
2139         # label multiple times. If 'n' is omitted then the alignment is
2140         # unchanged. Otherwise it becomes 'n'.
2141         print FILEO "$pack_indent/* winemaker: $pack_header$1 */\n";
2142         my $size;
2143         if (defined $4) {
2144           $size=$4;
2145         } elsif (@pack_stack > 0) {
2146           my $alignment=$pack_stack[$#pack_stack];
2147           $size=@$alignment[2];
2148         } else {
2149           print FILEO "$pack_indent/* winemaker:warning: Using 4 as the default alignment */\n";
2150           $size=4;
2151         }
2152         print_pack($pack_indent,$size,$');
2153         push @pack_stack, [ "push", $2, $size ];
2154
2155       } else {
2156         # pragma pack(???               -> What's that?
2157         print FILEO "$pack_indent/* winemaker:warning: Unknown type of pragma pack directive */\n";
2158         print FILEO "$pack_indent$pack_header$_";
2159
2160       }
2161       $modified=1;
2162
2163     } elsif ($is_rc) {
2164       if ($rc_block_depth == 0 and /^(\w+\s+(BITMAP|CURSOR|FONT|FONTDIR|ICON|MESSAGETABLE|TEXT|RTF)\s+((DISCARDABLE|FIXED|IMPURE|LOADONCALL|MOVEABLE|PRELOAD|PURE)\s+)*)([\"<]?)([^\">\r\n]+)([\">]?)/) {
2165         my $from_file=($5 eq "<"?"":$dirname);
2166         my $real_include_name=get_real_include_name($line,$6,$from_file,$project,$target);
2167         print FILEO "$1$5$real_include_name$7$'";
2168         $modified|=($real_include_name ne $6);
2169
2170       } elsif (/^(\s*RCINCLUDE\s*)([\"<]?)([^\">\r\n]+)([\">]?)/) {
2171         my $from_file=($2 eq "<"?"":$dirname);
2172         my $real_include_name=get_real_include_name($line,$3,$from_file,$project,$target);
2173         print FILEO "$1$2$real_include_name$4$'";
2174         $modified|=($real_include_name ne $3);
2175
2176       } elsif ($is_rc and !$is_mfc and $rc_block_depth == 0 and /^\s*\d+\s+TEXTINCLUDE\s*/) {
2177         $rc_textinclude_state=1;
2178         print FILEO;
2179
2180       } elsif ($rc_textinclude_state == 3 and /^(\s*\"\#\s*include\s*\"\")afxres\.h(\"\"\\r\\n\")/) {
2181         print FILEO "$1winresrc.h$2$'";
2182         $modified=1;
2183
2184       } elsif (/^\s*BEGIN(\W.*)?$/) {
2185         $rc_textinclude_state|=2;
2186         $rc_block_depth++;
2187         print FILEO;
2188
2189       } elsif (/^\s*END(\W.*)?$/) {
2190         $rc_textinclude_state=0;
2191         if ($rc_block_depth>0) {
2192           $rc_block_depth--;
2193         }
2194         print FILEO;
2195
2196       } else {
2197         print FILEO;
2198       }
2199
2200     } else {
2201       print FILEO;
2202     }
2203   }
2204
2205   close(FILEI);
2206   close(FILEO);
2207   if ($opt_backup == 0 or $modified == 0) {
2208     if (!unlink("$filename.bak")) {
2209       print STDERR "error: unable to delete $filename.bak:\n";
2210       print STDERR "       $!\n";
2211     }
2212   }
2213 }
2214
2215 ##
2216 # Analyzes each source file in turn to find and correct issues
2217 # that would cause it not to compile.
2218 sub fix_source()
2219 {
2220   print "Fixing the source files...\n";
2221   foreach my $project (@projects) {
2222     foreach my $target (@$project[$P_SETTINGS],@{@$project[$P_TARGETS]}) {
2223       foreach my $source (@{@$target[$T_SOURCES_C]}, @{@$target[$T_SOURCES_CXX]}, @{@$target[$T_SOURCES_RC]}, @{@$target[$T_SOURCES_MISC]}) {
2224         fix_file($source,$project,$target);
2225       }
2226     }
2227   }
2228 }
2229
2230
2231
2232 #####
2233 #
2234 # File generation
2235 #
2236 #####
2237
2238 ##
2239 # A convenience function to generate all the lists (defines,
2240 # C sources, C++ source, etc.) in the Makefile
2241 sub generate_list($$$;$)
2242 {
2243   my $name=$_[0];
2244   my $last=$_[1];
2245   my $list=$_[2];
2246   my $data=$_[3];
2247   my $first=$name;
2248
2249   if ($name) {
2250     printf FILEO "%-22s=",$name;
2251   }
2252   if (defined $list) {
2253     foreach my $item (@$list) {
2254       my $value;
2255       if (defined $data) {
2256         $value=&$data($item);
2257       } else {
2258         if (defined $item) {
2259           $value=$item;
2260         } else {
2261           $value="";
2262         }
2263       }
2264       if ($value ne "") {
2265         if ($first) {
2266           print FILEO " $value";
2267           $first=0;
2268         } else {
2269           print FILEO " \\\n\t\t\t$value";
2270         }
2271       }
2272     }
2273   }
2274   if ($last) {
2275     print FILEO "\n";
2276   }
2277 }
2278
2279 ##
2280 # Generates a project's Makefile and all the target files
2281 sub generate_project_files($)
2282 {
2283   my $project=$_[0];
2284   my $project_settings=@$project[$P_SETTINGS];
2285   my @dll_list=();
2286   my @exe_list=();
2287
2288   # Then sort the targets and separate the libraries from the programs
2289   foreach my $target (sort { @$a[$T_NAME] cmp @$b[$T_NAME] } @{@$project[$P_TARGETS]}) {
2290     if (@$target[$T_TYPE] == $TT_DLL) {
2291       push @dll_list,$target;
2292     } else {
2293       push @exe_list,$target;
2294     }
2295   }
2296   @$project[$P_TARGETS]=[];
2297   push @{@$project[$P_TARGETS]}, @dll_list;
2298   push @{@$project[$P_TARGETS]}, @exe_list;
2299
2300   if (!open(FILEO,">@$project[$P_PATH]Makefile")) {
2301     print STDERR "error: could not open \"@$project[$P_PATH]/Makefile\" for writing\n";
2302     print STDERR "       $!\n";
2303     return;
2304   }
2305
2306   print FILEO "### Generated by Winemaker $version\n";
2307   print FILEO "\n\n";
2308
2309   generate_list("SRCDIR",1,[ "." ]);
2310   if (@$project[$P_PATH] eq "") {
2311     # This is the main project. It is also responsible for recursively
2312     # calling the other projects
2313     generate_list("SUBDIRS",1,\@projects,sub
2314                   {
2315                     if ($_[0] != \@main_project) {
2316                       my $subdir=@{$_[0]}[$P_PATH];
2317                       $subdir =~ s+/$++;
2318                       return $subdir;
2319                     }
2320                     # Eliminating the main project by returning undefined!
2321                   });
2322   }
2323   if (@{@$project[$P_TARGETS]} > 0) {
2324     generate_list("DLLS",1,\@dll_list,sub
2325                   {
2326                     return @{$_[0]}[$T_NAME];
2327                   });
2328     generate_list("EXES",1,\@exe_list,sub
2329                   {
2330                     return "@{$_[0]}[$T_NAME]";
2331                   });
2332     print FILEO "\n\n\n";
2333
2334     print FILEO "### Common settings\n\n";
2335     # Make it so that the project-wide settings override the global settings
2336     generate_list("CEXTRA",1,@$project_settings[$T_CEXTRA]);
2337     generate_list("CXXEXTRA",1,@$project_settings[$T_CXXEXTRA]);
2338     generate_list("RCEXTRA",1,@$project_settings[$T_RCEXTRA]);
2339     generate_list("DEFINES",1,@$project_settings[$T_DEFINES]);
2340     generate_list("INCLUDE_PATH",1,@$project_settings[$T_INCLUDE_PATH]);
2341     generate_list("DLL_PATH",1,@$project_settings[$T_DLL_PATH]);
2342     generate_list("DLL_IMPORTS",1,@$project_settings[$T_DLLS]);
2343     generate_list("LIBRARY_PATH",1,@$project_settings[$T_LIBRARY_PATH]);
2344     generate_list("LIBRARIES",1,@$project_settings[$T_LIBRARIES]);
2345     print FILEO "\n\n";
2346
2347     my $extra_source_count=@{@$project_settings[$T_SOURCES_C]}+
2348                            @{@$project_settings[$T_SOURCES_CXX]}+
2349                            @{@$project_settings[$T_SOURCES_RC]};
2350     my $no_extra=($extra_source_count == 0);
2351     if (!$no_extra) {
2352       print FILEO "### Extra source lists\n\n";
2353       generate_list("EXTRA_C_SRCS",1,@$project_settings[$T_SOURCES_C]);
2354       generate_list("EXTRA_CXX_SRCS",1,@$project_settings[$T_SOURCES_CXX]);
2355       generate_list("EXTRA_RC_SRCS",1,@$project_settings[$T_SOURCES_RC]);
2356       print FILEO "\n";
2357       generate_list("EXTRA_OBJS",1,["\$(EXTRA_C_SRCS:.c=.o)","\$(EXTRA_CXX_SRCS:.cpp=.o)"]);
2358       print FILEO "\n\n\n";
2359     }
2360
2361     # Iterate over all the targets...
2362     foreach my $target (@{@$project[$P_TARGETS]}) {
2363       print FILEO "### @$target[$T_NAME] sources and settings\n\n";
2364       my $canon=canonize("@$target[$T_NAME]");
2365       $canon =~ s+_so$++;
2366
2367       generate_list("${canon}_MODULE",1,[@$target[$T_NAME]]);
2368       generate_list("${canon}_C_SRCS",1,@$target[$T_SOURCES_C]);
2369       generate_list("${canon}_CXX_SRCS",1,@$target[$T_SOURCES_CXX]);
2370       generate_list("${canon}_RC_SRCS",1,@$target[$T_SOURCES_RC]);
2371       generate_list("${canon}_LDFLAGS",1,@$target[$T_LDFLAGS]);
2372       generate_list("${canon}_DLL_PATH",1,@$target[$T_DLL_PATH]);
2373       generate_list("${canon}_DLLS",1,@$target[$T_DLLS]);
2374       generate_list("${canon}_LIBRARY_PATH",1,@$target[$T_LIBRARY_PATH]);
2375       generate_list("${canon}_LIBRARIES",1,@$target[$T_LIBRARIES]);
2376       print FILEO "\n";
2377       generate_list("${canon}_OBJS",1,["\$(${canon}_C_SRCS:.c=.o)","\$(${canon}_CXX_SRCS:.cpp=.o)","\$(${canon}_RC_SRCS:.rc=.res)"]);
2378       print FILEO "\n\n\n";
2379     }
2380     print FILEO "### Global source lists\n\n";
2381     generate_list("C_SRCS",$no_extra,@$project[$P_TARGETS],sub
2382                   {
2383                     my $canon=canonize(@{$_[0]}[$T_NAME]);
2384                     $canon =~ s+_so$++;
2385                     return "\$(${canon}_C_SRCS)";
2386                   });
2387     if (!$no_extra) {
2388       generate_list("",1,[ "\$(EXTRA_C_SRCS)" ]);
2389     }
2390     generate_list("CXX_SRCS",$no_extra,@$project[$P_TARGETS],sub
2391                   {
2392                     my $canon=canonize(@{$_[0]}[$T_NAME]);
2393                     $canon =~ s+_so$++;
2394                     return "\$(${canon}_CXX_SRCS)";
2395                   });
2396     if (!$no_extra) {
2397       generate_list("",1,[ "\$(EXTRA_CXX_SRCS)" ]);
2398     }
2399     generate_list("RC_SRCS",$no_extra,@$project[$P_TARGETS],sub
2400                   {
2401                     my $canon=canonize(@{$_[0]}[$T_NAME]);
2402                     $canon =~ s+_so$++;
2403                     return "\$(${canon}_RC_SRCS)";
2404                   });
2405     if (!$no_extra) {
2406       generate_list("",1,[ "\$(EXTRA_RC_SRCS)" ]);
2407     }
2408   }
2409   print FILEO "\n\n";
2410   print FILEO "### Tools\n\n";
2411   print FILEO "CC = winegcc\n";
2412   print FILEO "CXX = wineg++\n";
2413   print FILEO "RC = wrc\n";
2414   print FILEO "\n\n";
2415
2416   print FILEO "### Generic targets\n\n";
2417   print FILEO "all:";
2418   if (@$project[$P_PATH] eq "") {
2419     print FILEO " \$(SUBDIRS)";
2420   }
2421   if (@{@$project[$P_TARGETS]} > 0) {
2422     print FILEO " \$(DLLS:%=%.so) \$(EXES:%=%.so)";
2423   }
2424   print FILEO "\n\n";
2425   print FILEO "### Build rules\n";
2426   print FILEO "\n";
2427   print FILEO ".PHONY: all clean dummy\n";
2428   print FILEO "\n";
2429   print FILEO "\$(SUBDIRS): dummy\n";
2430   print FILEO "\t\@cd \$\@ && \$(MAKE)\n";
2431   print FILEO "\n";
2432   print FILEO "# Implicit rules\n";
2433   print FILEO "\n";
2434   print FILEO ".SUFFIXES: .cpp .rc .res\n";
2435   print FILEO "DEFINCL = \$(INCLUDE_PATH) \$(DEFINES) \$(OPTIONS)\n";
2436   print FILEO "\n";
2437   print FILEO ".c.o:\n";
2438   print FILEO "\t\$(CC) -c \$(CFLAGS) \$(CEXTRA) \$(DEFINCL) -o \$\@ \$<\n";
2439   print FILEO "\n";
2440   print FILEO ".cpp.o:\n";
2441   print FILEO "\t\$(CXX) -c \$(CXXFLAGS) \$(CXXEXTRA) \$(DEFINCL) -o \$\@ \$<\n";
2442   print FILEO "\n";
2443   print FILEO ".cxx.o:\n";
2444   print FILEO "\t\$(CXX) -c \$(CXXFLAGS) \$(CXXEXTRA) \$(DEFINCL) -o \$\@ \$<\n";
2445   print FILEO "\n";
2446   print FILEO ".rc.res:\n";
2447   print FILEO "\t\$(RC) \$(RCFLAGS) \$(RCEXTRA) \$(DEFINCL) -fo\$@ \$<\n";
2448   print FILEO "\n";
2449   print FILEO "# Rules for cleaning\n";
2450   print FILEO "\n";
2451   print FILEO "CLEAN_FILES     = y.tab.c y.tab.h lex.yy.c core *.orig *.rej \\\n";
2452   print FILEO "                  \\\\\\#*\\\\\\# *~ *% .\\\\\\#*\n";
2453   print FILEO "\n";
2454   print FILEO "clean:: \$(SUBDIRS:%=%/__clean__) \$(EXTRASUBDIRS:%=%/__clean__)\n";
2455   print FILEO "\t\$(RM) \$(CLEAN_FILES) \$(RC_SRCS:.rc=.res) \$(C_SRCS:.c=.o) \$(CXX_SRCS:.cpp=.o)\n";
2456   print FILEO "\t\$(RM) \$(DLLS:%=%.so) \$(EXES:%=%.so) \$(EXES:%.exe=%)\n";
2457   print FILEO "\n";
2458   print FILEO "\$(SUBDIRS:%=%/__clean__): dummy\n";
2459   print FILEO "\tcd `dirname \$\@` && \$(MAKE) clean\n";
2460   print FILEO "\n";
2461   print FILEO "\$(EXTRASUBDIRS:%=%/__clean__): dummy\n";
2462   print FILEO "\t-cd `dirname \$\@` && \$(RM) \$(CLEAN_FILES)\n";
2463   print FILEO "\n";
2464
2465   if (@{@$project[$P_TARGETS]} > 0) {
2466     print FILEO "### Target specific build rules\n";
2467     print FILEO "DEFLIB = \$(LIBRARY_PATH) \$(LIBRARIES) \$(DLL_PATH) \$(DLL_IMPORTS:%=-l%)\n\n";
2468     foreach my $target (@{@$project[$P_TARGETS]}) {
2469       my $canon=canonize("@$target[$T_NAME]");
2470       $canon =~ s/_so$//;
2471
2472       print FILEO "\$(${canon}_MODULE).so: \$(${canon}_OBJS)\n";
2473       if (@{@$target[$T_SOURCES_CXX]} > 0 or @{@$project_settings[$T_SOURCES_CXX]} > 0) {
2474         print FILEO "\t\$(CXX)";
2475       } else {
2476         print FILEO "\t\$(CC)";
2477       }
2478       print FILEO " \$(${canon}_LDFLAGS) -o \$\@ \$(${canon}_OBJS) \$(${canon}_LIBRARY_PATH) \$(DEFLIB) \$(${canon}_DLLS:%=-l%) \$(${canon}_LIBRARIES:%=-l%)\n";
2479       print FILEO "\n\n";
2480     }
2481   }
2482   close(FILEO);
2483
2484 }
2485
2486
2487 ##
2488 # This is where we finally generate files. In fact this method does not
2489 # do anything itself but calls the methods that do the actual work.
2490 sub generate()
2491 {
2492   print "Generating project files...\n";
2493
2494   foreach my $project (@projects) {
2495     my $path=@$project[$P_PATH];
2496     if ($path eq "") {
2497       $path=".";
2498     } else {
2499       $path =~ s+/$++;
2500     }
2501     print "  $path\n";
2502     generate_project_files($project);
2503   }
2504 }
2505
2506
2507
2508 #####
2509 #
2510 # Option defaults
2511 #
2512 #####
2513
2514 $opt_backup=1;
2515 $opt_lower=$OPT_LOWER_UPPERCASE;
2516 $opt_lower_include=1;
2517
2518 $opt_work_dir=undef;
2519 $opt_single_target=undef;
2520 $opt_target_type=$TT_GUIEXE;
2521 $opt_flags=0;
2522 $opt_arch=$OPT_ARCH_DEFAULT;
2523 $opt_is_interactive=$OPT_ASK_NO;
2524 $opt_ask_project_options=$OPT_ASK_NO;
2525 $opt_ask_target_options=$OPT_ASK_NO;
2526 $opt_no_generated_files=0;
2527 $opt_no_source_fix=0;
2528 $opt_no_banner=0;
2529
2530
2531
2532 #####
2533 #
2534 # Main
2535 #
2536 #####
2537
2538 sub print_banner()
2539 {
2540   print "Winemaker $version\n";
2541   print "Copyright 2000 Francois Gouget <fgouget\@codeweavers.com> for CodeWeavers\n";
2542   print "Copyright 2004 Dimitrie O. Paun\n";
2543   print "Copyright 2009 André Hentschel\n";
2544 }
2545
2546 sub usage()
2547 {
2548   print_banner();
2549   print STDERR "Usage: winemaker [--nobanner] [--backup|--nobackup] [--nosource-fix]\n";
2550   print STDERR "                 [--lower-none|--lower-all|--lower-uppercase]\n";
2551   print STDERR "                 [--lower-include|--nolower-include] [--mfc|--nomfc]\n";
2552   print STDERR "                 [--guiexe|--windows|--cuiexe|--console|--dll]\n";
2553   print STDERR "                 [-Dmacro[=defn]] [-Idir] [-Pdir] [-idll] [-Ldir] [-llibrary]\n";
2554   print STDERR "                 [--nodlls] [--nomsvcrt] [--interactive] [--single-target name]\n";
2555   print STDERR "                 [--generated-files|--nogenerated-files]\n";
2556   print STDERR "                 [--wine32]\n";
2557   print STDERR "                 work_directory|project_file|workspace_file\n";
2558   print STDERR "\nWinemaker is designed to recursively convert all the Windows sources found in\n";
2559   print STDERR "the specified directory or project-file, so that they can be compiled with Winelib.\n";
2560   print STDERR "During this process it will modify and rename some of the corresponding files.\n";
2561   print STDERR "\tPlease read the manual page before use.\n";
2562   exit (2);
2563 }
2564
2565 target_init(\@global_settings);
2566
2567 while (@ARGV>0) {
2568   my $arg=shift @ARGV;
2569   # General options
2570   if ($arg eq "--nobanner") {
2571     $opt_no_banner=1;
2572   } elsif ($arg eq "--backup") {
2573     $opt_backup=1;
2574   } elsif ($arg eq "--nobackup") {
2575     $opt_backup=0;
2576   } elsif ($arg eq "--single-target") {
2577     $opt_single_target=shift @ARGV;
2578   } elsif ($arg eq "--lower-none") {
2579     $opt_lower=$OPT_LOWER_NONE;
2580   } elsif ($arg eq "--lower-all") {
2581     $opt_lower=$OPT_LOWER_ALL;
2582   } elsif ($arg eq "--lower-uppercase") {
2583     $opt_lower=$OPT_LOWER_UPPERCASE;
2584   } elsif ($arg eq "--lower-include") {
2585     $opt_lower_include=1;
2586   } elsif ($arg eq "--nolower-include") {
2587     $opt_lower_include=0;
2588   } elsif ($arg eq "--nosource-fix") {
2589     $opt_no_source_fix=1;
2590   } elsif ($arg eq "--generated-files") {
2591     $opt_no_generated_files=0;
2592   } elsif ($arg eq "--nogenerated-files") {
2593     $opt_no_generated_files=1;
2594   } elsif ($arg eq "--wine32") {
2595     $opt_arch=$OPT_ARCH_32;
2596   } elsif ($arg =~ /^-D/) {
2597     push @{$global_settings[$T_DEFINES]},$arg;
2598   } elsif ($arg =~ /^-I/) {
2599     push @{$global_settings[$T_INCLUDE_PATH]},$arg;
2600   } elsif ($arg =~ /^-P/) {
2601     push @{$global_settings[$T_DLL_PATH]},"-L$'";
2602   } elsif ($arg =~ /^-i/) {
2603     push @{$global_settings[$T_DLLS]},$';
2604   } elsif ($arg =~ /^-L/) {
2605     push @{$global_settings[$T_LIBRARY_PATH]},$arg;
2606   } elsif ($arg =~ /^-l/) {
2607     push @{$global_settings[$T_LIBRARIES]},$';
2608
2609   # 'Source'-based method options
2610   } elsif ($arg eq "--dll") {
2611     $opt_target_type=$TT_DLL;
2612   } elsif ($arg eq "--guiexe" or $arg eq "--windows") {
2613     $opt_target_type=$TT_GUIEXE;
2614   } elsif ($arg eq "--cuiexe" or $arg eq "--console") {
2615     $opt_target_type=$TT_CUIEXE;
2616   } elsif ($arg eq "--interactive") {
2617     $opt_is_interactive=$OPT_ASK_YES;
2618     $opt_ask_project_options=$OPT_ASK_YES;
2619     $opt_ask_target_options=$OPT_ASK_YES;
2620   } elsif ($arg eq "--mfc") {
2621     $opt_flags|=$TF_MFC;
2622   } elsif ($arg eq "--nomfc") {
2623     $opt_flags&=~$TF_MFC;
2624     $opt_flags|=$TF_NOMFC;
2625   } elsif ($arg eq "--nodlls") {
2626     $opt_flags|=$TF_NODLLS;
2627   } elsif ($arg eq "--nomsvcrt") {
2628     $opt_flags|=$TF_NOMSVCRT;
2629
2630   # Catch errors
2631   } else {
2632     if ($arg ne "--help" and $arg ne "-h" and $arg ne "-?") {
2633         if (!defined $opt_work_dir and !defined $opt_work_file) {
2634             if (-f $arg) {
2635                 $opt_work_file=$arg;
2636             }
2637             else {
2638                 $opt_work_dir=$arg;
2639             }
2640         } else {
2641             print STDERR "error: the work directory, \"$arg\", has already been specified (was \"$opt_work_dir\")\n";
2642             usage();
2643         }
2644     } else {
2645         usage();
2646     }
2647   }
2648 }
2649
2650 if (!defined $opt_work_dir and !defined $opt_work_file) {
2651   print STDERR "error: you must specify the directory or project file containing the sources to be converted\n";
2652   usage();
2653 } elsif (defined $opt_work_dir and !chdir $opt_work_dir) {
2654   print STDERR "error: could not chdir to the work directory\n";
2655   print STDERR "       $!\n";
2656   usage();
2657 }
2658
2659 if ($opt_no_banner == 0) {
2660   print_banner();
2661 }
2662
2663 project_init(\@main_project, "", \@global_settings);
2664
2665 # Fix the file and directory names
2666 fix_file_and_directory_names(".");
2667
2668 # Scan the sources to identify the projects and targets
2669 source_scan();
2670
2671 # Fix the source files
2672 if (! $opt_no_source_fix) {
2673   fix_source();
2674 }
2675
2676 # Generate the Makefile and the spec file
2677 if (! $opt_no_generated_files) {
2678   generate();
2679 }