git.oblomov.eu Git - wine/blob - programs/winedbg/dbg.y

   1 %{
   2 /*
   3  * Parser for command lines in the Wine debugger
   4  *
   5  * Copyright 1993 Eric Youngdale
   6  * Copyright 1995 Morten Welinder
   7  * Copyright 2000 Eric Pouech
   8  *
   9  * This library is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public
  11  * License as published by the Free Software Foundation; either
  12  * version 2.1 of the License, or (at your option) any later version.
  13  *
  14  * This library is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with this library; if not, write to the Free Software
  21  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  22  */
  23
  24 #include "config.h"
  25 #include "wine/port.h"
  26
  27 #include <stdio.h>
  28 #include <stdlib.h>
  29 #include <string.h>
  30 #ifdef HAVE_UNISTD_H
  31 # include <unistd.h>
  32 #endif
  33
  34 #include "debugger.h"
  35 #include "wine/exception.h"
  36 #include "expr.h"
  37
  38 int dbg_lex(void);
  39 static int dbg_error(const char*);
  40
  41 %}
  42
  43 %union
  44 {
  45     struct dbg_lvalue   lvalue;
  46     char*               string;
  47     int                 integer;
  48     IMAGEHLP_LINE       listing;
  49     struct expr*        expression;
  50     struct type_expr_t  type;
  51 }
  52
  53 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tALL tINFO tUP tDOWN
  54 %token tENABLE tDISABLE tBREAK tHBREAK tWATCH tDELETE tSET tPRINT tEXAM
  55 %token tABORT tECHO
  56 %token tCLASS tMAPS tSTACK tSEGMENTS tSYMBOL tREGS tALLREGS tWND tQUEUE tLOCAL tEXCEPTION
  57 %token tPROCESS tTHREAD tEOL tEOF
  58 %token tFRAME tSHARE tMODULE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
  59 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS tSOURCE
  60 %token <string> tPATH tIDENTIFIER tSTRING tDEBUGSTR tINTVAR
  61 %token <integer> tNUM tFORMAT
  62 %token tSYMBOLFILE tRUN tATTACH tDETACH tMAINTENANCE tTYPE tMINIDUMP
  63 %token tNOPROCESS
  64
  65 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
  66 %token tSTRUCT tUNION tENUM
  67
  68 /* %left ',' */
  69 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
  70          OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
  71          OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
  72 /* %left OP_COND */ /* ... ? ... : ... */
  73 %left OP_LOR
  74 %left OP_LAND
  75 %left '|'
  76 %left '^'
  77 %left '&'
  78 %left OP_EQ OP_NE
  79 %left '<' '>' OP_LE OP_GE
  80 %left OP_SHL OP_SHR
  81 %left '+' '-'
  82 %left '*' '/' '%'
  83 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
  84 %left '.' '[' OP_DRF OP_SCOPE
  85 %nonassoc ':'
  86
  87 %type <expression> expr lvalue
  88 %type <lvalue> expr_lvalue lvalue_addr
  89 %type <integer> expr_rvalue
  90 %type <string> pathname identifier cpp_identifier
  91 %type <listing> list_arg
  92 %type <type> type_expr
  93
  94 %%
  95
  96 input:
  97       line
  98     | input line
  99     ;
 100
 101 line:
 102       command tEOL              { expr_free_all(); }
 103     | tEOL
 104     | tEOF                      { return 1; }
 105     | error tEOL                { yyerrok; expr_free_all(); }
 106     ;
 107
 108 command:
 109       tQUIT                     { return 1; }
 110     | tHELP                     { print_help(); }
 111     | tHELP tINFO               { info_help(); }
 112     | tPASS                     { dbg_wait_next_exception(DBG_EXCEPTION_NOT_HANDLED, 0, 0); }
 113     | tCONT                     { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_cont); }
 114     | tCONT tNUM                { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_cont); }
 115     | tSTEP                     { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_step_into_line); }
 116     | tSTEP tNUM                { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_into_line); }
 117     | tNEXT                     { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_step_over_line); }
 118     | tNEXT tNUM                { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_over_line); }
 119     | tSTEPI                    { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_step_into_insn); }
 120     | tSTEPI tNUM               { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_into_insn); }
 121     | tNEXTI                    { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_step_over_insn); }
 122     | tNEXTI tNUM               { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_over_insn); }
 123     | tFINISH                   { dbg_wait_next_exception(DBG_CONTINUE, 0,  dbg_exec_finish); }
 124     | tABORT                    { abort(); }
 125     | tBACKTRACE                { stack_backtrace(dbg_curr_tid); }
 126     | tBACKTRACE tNUM           { stack_backtrace($2); }
 127     | tBACKTRACE tALL           { stack_backtrace(-1); }
 128     | tUP                       { stack_set_frame(dbg_curr_thread->curr_frame + 1);  }
 129     | tUP tNUM                  { stack_set_frame(dbg_curr_thread->curr_frame + $2); }
 130     | tDOWN                     { stack_set_frame(dbg_curr_thread->curr_frame - 1);  }
 131     | tDOWN tNUM                { stack_set_frame(dbg_curr_thread->curr_frame - $2); }
 132     | tFRAME tNUM               { stack_set_frame($2); }
 133     | tSHOW tDIR                { source_show_path(); }
 134     | tDIR pathname             { source_add_path($2); }
 135     | tDIR                      { source_nuke_path(); }
 136     | tCOND tNUM                { break_add_condition($2, NULL); }
 137     | tCOND tNUM expr           { break_add_condition($2, $3); }
 138     | tSOURCE pathname          { parser($2); }
 139     | tSYMBOLFILE pathname      { symbol_read_symtable($2, 0); }
 140     | tSYMBOLFILE pathname expr_rvalue { symbol_read_symtable($2, $3); }
 141     | tWHATIS expr_lvalue       { dbg_printf("type = "); types_print_type(&$2.type, FALSE); dbg_printf("\n"); }
 142     | tATTACH tNUM              { dbg_attach_debuggee($2, FALSE); dbg_active_wait_for_first_exception(); }
 143     | tDETACH                   { dbg_curr_process->process_io->close_process(dbg_curr_process, FALSE); }
 144     | tMINIDUMP pathname        { minidump_write($2, (dbg_curr_thread && dbg_curr_thread->in_exception) ? &dbg_curr_thread->excpt_record : NULL);}
 145     | tECHO tSTRING             { dbg_printf("%s\n", $2); }
 146     | run_command
 147     | list_command
 148     | disassemble_command
 149     | set_command
 150     | x_command
 151     | print_command
 152     | break_command
 153     | watch_command
 154     | display_command
 155     | info_command
 156     | maintenance_command
 157     | noprocess_state
 158     ;
 159
 160 pathname:
 161       identifier                { $$ = $1; }
 162     | tSTRING                   { $$ = $1; }
 163     | tPATH                     { $$ = $1; }
 164     ;
 165
 166 cpp_identifier:
 167       tIDENTIFIER               { $$ = $1; }
 168     | identifier OP_SCOPE tIDENTIFIER { $$ = lexeme_alloc_size(strlen($1) + 2 + strlen($3) + 1);
 169                                        sprintf($$, "%s::%s", $1, $3); }
 170     ;
 171
 172 identifier:
 173       cpp_identifier            { $$ = $1; }
 174     | tIDENTIFIER '!' cpp_identifier { $$ = lexeme_alloc_size(strlen($1) + 1 + strlen($3) + 1);
 175                                        sprintf($$, "%s!%s", $1, $3); }
 176     ;
 177
 178 list_arg:
 179       tNUM                      { $$.FileName = NULL; $$.LineNumber = $1; }
 180     | pathname ':' tNUM         { $$.FileName = $1; $$.LineNumber = $3; }
 181     | identifier                { symbol_get_line(NULL, $1, &$$); }
 182     | pathname ':' identifier   { symbol_get_line($3, $1, &$$); }
 183     | '*' expr_lvalue           { DWORD disp; $$.SizeOfStruct = sizeof($$);
 184                                   SymGetLineFromAddr(dbg_curr_process->handle, (unsigned long)memory_to_linear_addr(& $2.addr), &disp, & $$); }
 185     ;
 186
 187 run_command:
 188       tRUN                      { dbg_run_debuggee(NULL); }
 189     | tRUN tSTRING              { dbg_run_debuggee($2); }
 190     ;
 191
 192 list_command:
 193       tLIST                     { source_list(NULL, NULL, 10); }
 194     | tLIST '-'                 { source_list(NULL,  NULL, -10); }
 195     | tLIST list_arg            { source_list(& $2, NULL, 10); }
 196     | tLIST ',' list_arg        { source_list(NULL, & $3, -10); }
 197     | tLIST list_arg ',' list_arg      { source_list(& $2, & $4, 0); }
 198     ;
 199
 200 disassemble_command:
 201       tDISASSEMBLE              { memory_disassemble(NULL, NULL, 10); }
 202     | tDISASSEMBLE expr_lvalue  { memory_disassemble(&$2, NULL, 10); }
 203     | tDISASSEMBLE expr_lvalue ',' expr_lvalue { memory_disassemble(&$2, &$4, 0); }
 204     ;
 205
 206 set_command:
 207       tSET lvalue_addr '=' expr_rvalue { memory_write_value(&$2, sizeof(int), &$4); }
 208     | tSET '+' tIDENTIFIER      { info_wine_dbg_channel(TRUE, NULL, $3); }
 209     | tSET '-' tIDENTIFIER      { info_wine_dbg_channel(FALSE, NULL, $3); }
 210     | tSET tIDENTIFIER '+' tIDENTIFIER { info_wine_dbg_channel(TRUE, $2, $4); }
 211     | tSET tIDENTIFIER '-' tIDENTIFIER { info_wine_dbg_channel(FALSE, $2, $4); }
 212     ;
 213
 214 x_command:
 215       tEXAM expr_lvalue         { memory_examine(&$2, 1, 'x'); }
 216     | tEXAM tFORMAT expr_lvalue { memory_examine(&$3, $2 >> 8, $2 & 0xff); }
 217     ;
 218
 219 print_command:
 220       tPRINT expr_lvalue         { print_value(&$2, 0, 0); }
 221     | tPRINT tFORMAT expr_lvalue { if (($2 >> 8) == 1) print_value(&$3, $2 & 0xff, 0); else dbg_printf("Count is meaningless in print command\n"); }
 222     ;
 223
 224 break_command:
 225       tBREAK '*' expr_lvalue    { break_add_break_from_lvalue(&$3, TRUE); }
 226     | tBREAK identifier         { break_add_break_from_id($2, -1, TRUE); }
 227     | tBREAK identifier ':' tNUM { break_add_break_from_id($2, $4, TRUE); }
 228     | tBREAK tNUM               { break_add_break_from_lineno($2, TRUE); }
 229     | tBREAK                    { break_add_break_from_lineno(-1, TRUE); }
 230     | tHBREAK '*' expr_lvalue   { break_add_break_from_lvalue(&$3, FALSE); }
 231     | tHBREAK identifier        { break_add_break_from_id($2, -1, FALSE); }
 232     | tHBREAK identifier ':' tNUM { break_add_break_from_id($2, $4, FALSE); }
 233     | tHBREAK tNUM              { break_add_break_from_lineno($2, FALSE); }
 234     | tHBREAK                   { break_add_break_from_lineno(-1, FALSE); }
 235     | tENABLE tNUM              { break_enable_xpoint($2, TRUE); }
 236     | tENABLE tBREAK tNUM       { break_enable_xpoint($3, TRUE); }
 237     | tDISABLE tNUM             { break_enable_xpoint($2, FALSE); }
 238     | tDISABLE tBREAK tNUM      { break_enable_xpoint($3, FALSE); }
 239     | tDELETE tNUM              { break_delete_xpoint($2); }
 240     | tDELETE tBREAK tNUM       { break_delete_xpoint($3); }
 241     ;
 242
 243 watch_command:
 244       tWATCH '*' expr_lvalue    { break_add_watch_from_lvalue(&$3); }
 245     | tWATCH identifier         { break_add_watch_from_id($2); }
 246     ;
 247
 248 display_command:
 249       tDISPLAY                  { display_print(); }
 250     | tDISPLAY expr             { display_add($2, 1, 0); }
 251     | tDISPLAY tFORMAT expr     { display_add($3, $2 >> 8, $2 & 0xff); }
 252     | tENABLE tDISPLAY tNUM     { display_enable($3, TRUE); }
 253     | tDISABLE tDISPLAY tNUM    { display_enable($3, FALSE); }
 254     | tDELETE tDISPLAY tNUM     { display_delete($3); }
 255     | tDELETE tDISPLAY          { display_delete(-1); }
 256     | tUNDISPLAY tNUM           { display_delete($2); }
 257     | tUNDISPLAY                { display_delete(-1); }
 258     ;
 259
 260 info_command:
 261       tINFO tBREAK              { break_info(); }
 262     | tINFO tSHARE              { info_win32_module(0); }
 263     | tINFO tSHARE expr_rvalue  { info_win32_module($3); }
 264     | tINFO tREGS               { be_cpu->print_context(dbg_curr_thread->handle, &dbg_context, 0); }
 265     | tINFO tALLREGS            { be_cpu->print_context(dbg_curr_thread->handle, &dbg_context, 1); }
 266     | tINFO tSEGMENTS expr_rvalue { info_win32_segments($3 >> 3, 1); }
 267     | tINFO tSEGMENTS           { info_win32_segments(0, -1); }
 268     | tINFO tSTACK              { stack_info(); }
 269     | tINFO tSYMBOL tSTRING     { symbol_info($3); }
 270     | tINFO tLOCAL              { symbol_info_locals(); }
 271     | tINFO tDISPLAY            { display_info(); }
 272     | tINFO tCLASS              { info_win32_class(NULL, NULL); }
 273     | tINFO tCLASS tSTRING      { info_win32_class(NULL, $3); }
 274     | tINFO tWND                { info_win32_window(NULL, FALSE); }
 275     | tINFO tWND expr_rvalue    { info_win32_window((HWND)$3, FALSE); }
 276     | tINFO '*' tWND            { info_win32_window(NULL, TRUE); }
 277     | tINFO '*' tWND expr_rvalue { info_win32_window((HWND)$4, TRUE); }
 278     | tINFO tPROCESS            { info_win32_processes(); }
 279     | tINFO tTHREAD             { info_win32_threads(); }
 280     | tINFO tEXCEPTION          { info_win32_exceptions(dbg_curr_tid); }
 281     | tINFO tEXCEPTION expr_rvalue { info_win32_exceptions($3); }
 282     | tINFO tMAPS               { info_win32_virtual(dbg_curr_pid); }
 283     | tINFO tMAPS expr_rvalue   { info_win32_virtual($3); }
 284     ;
 285
 286 maintenance_command:
 287       tMAINTENANCE tTYPE        { print_types(); }
 288     | tMAINTENANCE tMODULE tSTRING { tgt_module_load($3, FALSE); }
 289     | tMAINTENANCE '*' tMODULE tSTRING { tgt_module_load($4, TRUE); }
 290     ;
 291
 292 noprocess_state:
 293       tNOPROCESS                 {} /* <CR> shall not barf anything */
 294     | tNOPROCESS tBACKTRACE tALL { stack_backtrace(-1); } /* can backtrace all threads with no attached process */
 295     | tNOPROCESS tSTRING         { dbg_printf("No process loaded, cannot execute '%s'\n", $2); }
 296     ;
 297
 298 type_expr:
 299       tCHAR                     { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_char; }
 300     | tINT                      { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_int; }
 301     | tLONG tINT                { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_long_int; }
 302     | tLONG                     { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_long_int; }
 303     | tUNSIGNED tINT            { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_int; }
 304     | tUNSIGNED                 { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_int; }
 305     | tLONG tUNSIGNED tINT      { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_long_int; }
 306     | tLONG tUNSIGNED           { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_long_int; }
 307     | tSHORT tINT               { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_short_int; }
 308     | tSHORT                    { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_short_int; }
 309     | tSHORT tUNSIGNED tINT     { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_short_int; }
 310     | tSHORT tUNSIGNED          { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_short_int; }
 311     | tSIGNED tCHAR             { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_char_int; }
 312     | tUNSIGNED tCHAR           { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_char_int; }
 313     | tLONG tLONG tUNSIGNED tINT{ $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_longlong_int; }
 314     | tLONG tLONG tUNSIGNED     { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_longlong_int; }
 315     | tLONG tLONG tINT          { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_longlong_int; }
 316     | tLONG tLONG               { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_longlong_int; }
 317     | tFLOAT                    { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_short_real; }
 318     | tDOUBLE                   { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_real; }
 319     | tLONG tDOUBLE             { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_long_real; }
 320     | type_expr '*'             { $$ = $1; $$.deref_count++; }
 321     | tCLASS identifier         { $$.type = type_expr_udt_class; $$.deref_count = 0; $$.u.name = $2; }
 322     | tSTRUCT identifier        { $$.type = type_expr_udt_struct; $$.deref_count = 0; $$.u.name = $2; }
 323     | tUNION identifier         { $$.type = type_expr_udt_union; $$.deref_count = 0; $$.u.name = $2; }
 324     | tENUM identifier          { $$.type = type_expr_enumeration; $$.deref_count = 0; $$.u.name = $2; }
 325     ;
 326
 327 expr_lvalue:
 328       expr                      { $$ = expr_eval($1); }
 329     ;
 330
 331 expr_rvalue:
 332       expr_lvalue               { $$ = types_extract_as_integer(&$1); }
 333     ;
 334
 335 /*
 336  * The expr rule builds an expression tree.  When we are done, we call
 337  * EvalExpr to evaluate the value of the expression.  The advantage of
 338  * the two-step approach is that it is possible to save expressions for
 339  * use in 'display' commands, and in conditional watchpoints.
 340  */
 341 expr:
 342       tNUM                      { $$ = expr_alloc_sconstant($1); }
 343     | tSTRING                   { $$ = expr_alloc_string($1); }
 344     | tINTVAR                   { $$ = expr_alloc_internal_var($1); }
 345     | identifier                { $$ = expr_alloc_symbol($1); }
 346     | expr OP_DRF tIDENTIFIER   { $$ = expr_alloc_pstruct($1, $3); }
 347     | expr '.' tIDENTIFIER      { $$ = expr_alloc_struct($1, $3); }
 348     | identifier '(' ')'        { $$ = expr_alloc_func_call($1, 0); }
 349     | identifier '(' expr ')'   { $$ = expr_alloc_func_call($1, 1, $3); }
 350     | identifier '(' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 2, $3, $5); }
 351     | identifier '(' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 3, $3, $5, $7); }
 352     | identifier '(' expr ',' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 4, $3, $5, $7, $9); }
 353     | identifier '(' expr ',' expr ',' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 5, $3, $5, $7, $9, $11); }
 354     | expr '[' expr ']'          { $$ = expr_alloc_binary_op(EXP_OP_ARR, $1, $3); }
 355     | expr ':' expr              { $$ = expr_alloc_binary_op(EXP_OP_SEG, $1, $3); }
 356     | expr OP_LOR expr           { $$ = expr_alloc_binary_op(EXP_OP_LOR, $1, $3); }
 357     | expr OP_LAND expr          { $$ = expr_alloc_binary_op(EXP_OP_LAND, $1, $3); }
 358     | expr '|' expr              { $$ = expr_alloc_binary_op(EXP_OP_OR, $1, $3); }
 359     | expr '&' expr              { $$ = expr_alloc_binary_op(EXP_OP_AND, $1, $3); }
 360     | expr '^' expr              { $$ = expr_alloc_binary_op(EXP_OP_XOR, $1, $3); }
 361     | expr OP_EQ expr            { $$ = expr_alloc_binary_op(EXP_OP_EQ, $1, $3); }
 362     | expr '>' expr              { $$ = expr_alloc_binary_op(EXP_OP_GT, $1, $3); }
 363     | expr '<' expr              { $$ = expr_alloc_binary_op(EXP_OP_LT, $1, $3); }
 364     | expr OP_GE expr            { $$ = expr_alloc_binary_op(EXP_OP_GE, $1, $3); }
 365     | expr OP_LE expr            { $$ = expr_alloc_binary_op(EXP_OP_LE, $1, $3); }
 366     | expr OP_NE expr            { $$ = expr_alloc_binary_op(EXP_OP_NE, $1, $3); }
 367     | expr OP_SHL expr           { $$ = expr_alloc_binary_op(EXP_OP_SHL, $1, $3); }
 368     | expr OP_SHR expr           { $$ = expr_alloc_binary_op(EXP_OP_SHR, $1, $3); }
 369     | expr '+' expr              { $$ = expr_alloc_binary_op(EXP_OP_ADD, $1, $3); }
 370     | expr '-' expr              { $$ = expr_alloc_binary_op(EXP_OP_SUB, $1, $3); }
 371     | expr '*' expr              { $$ = expr_alloc_binary_op(EXP_OP_MUL, $1, $3); }
 372     | expr '/' expr              { $$ = expr_alloc_binary_op(EXP_OP_DIV, $1, $3); }
 373     | expr '%' expr              { $$ = expr_alloc_binary_op(EXP_OP_REM, $1, $3); }
 374     | '-' expr %prec OP_SIGN     { $$ = expr_alloc_unary_op(EXP_OP_NEG, $2); }
 375     | '+' expr %prec OP_SIGN     { $$ = $2; }
 376     | '!' expr                   { $$ = expr_alloc_unary_op(EXP_OP_NOT, $2); }
 377     | '~' expr                   { $$ = expr_alloc_unary_op(EXP_OP_LNOT, $2); }
 378     | '(' expr ')'               { $$ = $2; }
 379     | '*' expr %prec OP_DEREF    { $$ = expr_alloc_unary_op(EXP_OP_DEREF, $2); }
 380     | '&' expr %prec OP_DEREF    { $$ = expr_alloc_unary_op(EXP_OP_ADDR, $2); }
 381     | '(' type_expr ')' expr %prec OP_DEREF { $$ = expr_alloc_typecast(&$2, $4); }
 382     ;
 383
 384 /*
 385  * The lvalue rule builds an expression tree.  This is a limited form
 386  * of expression that is suitable to be used as an lvalue.
 387  */
 388 lvalue_addr:
 389       lvalue                     { $$ = expr_eval($1); }
 390     ;
 391
 392 lvalue:
 393       tNUM                       { $$ = expr_alloc_sconstant($1); }
 394     | tINTVAR                    { $$ = expr_alloc_internal_var($1); }
 395     | identifier                 { $$ = expr_alloc_symbol($1); }
 396     | lvalue OP_DRF tIDENTIFIER  { $$ = expr_alloc_pstruct($1, $3); }
 397     | lvalue '.' tIDENTIFIER     { $$ = expr_alloc_struct($1, $3); }
 398     | lvalue '[' expr ']'        { $$ = expr_alloc_binary_op(EXP_OP_ARR, $1, $3); }
 399     | '*' expr                   { $$ = expr_alloc_unary_op(EXP_OP_FORCE_DEREF, $2); }
 400     ;
 401
 402 %%
 403
 404 static WINE_EXCEPTION_FILTER(wine_dbg_cmd)
 405 {
 406     switch (GetExceptionCode())
 407     {
 408     case DEBUG_STATUS_INTERNAL_ERROR:
 409         dbg_printf("\nWineDbg internal error\n");
 410         break;
 411     case DEBUG_STATUS_NO_SYMBOL:
 412         dbg_printf("\nUndefined symbol\n");
 413         break;
 414     case DEBUG_STATUS_DIV_BY_ZERO:
 415         dbg_printf("\nDivision by zero\n");
 416         break;
 417     case DEBUG_STATUS_BAD_TYPE:
 418         dbg_printf("\nNo type or type mismatch\n");
 419         break;
 420     case DEBUG_STATUS_NO_FIELD:
 421         dbg_printf("\nNo such field in structure or union\n");
 422         break;
 423     case DEBUG_STATUS_CANT_DEREF:
 424         dbg_printf("\nDereference failed (not a pointer, or out of array bounds)\n");
 425         break;
 426     case DEBUG_STATUS_ABORT:
 427         break;
 428     case DEBUG_STATUS_NOT_AN_INTEGER:
 429         dbg_printf("\nNeeding an integral value\n");
 430         break;
 431     case CONTROL_C_EXIT:
 432         /* this is generally sent by a ctrl-c when we run winedbg outside of wineconsole */
 433         /* stop the debuggee, and continue debugger execution, we will be reentered by the
 434          * debug events generated by stopping
 435          */
 436         dbg_interrupt_debuggee();
 437         return EXCEPTION_CONTINUE_EXECUTION;
 438     default:
 439         dbg_printf("\nException %x\n", GetExceptionCode());
 440         break;
 441     }
 442
 443     return EXCEPTION_EXECUTE_HANDLER;
 444 }
 445
 446 static HANDLE dbg_parser_input;
 447 static HANDLE dbg_parser_output;
 448
 449 int      input_fetch_entire_line(const char* pfx, char** line)
 450 {
 451     char        ch;
 452     DWORD       nread;
 453     size_t      len, alloc;
 454
 455     /* as of today, console handles can be file handles... so better use file APIs rather than
 456      * console's
 457      */
 458     WriteFile(dbg_parser_output, pfx, strlen(pfx), &nread, NULL);
 459
 460     if (*line)
 461     {
 462         alloc = HeapSize(GetProcessHeap(), 0, *line);
 463         assert(alloc);
 464     }
 465     else
 466     {
 467         *line = HeapAlloc(GetProcessHeap(), 0, alloc = 16);
 468         assert(*line);
 469     }
 470
 471     len = 0;
 472     do
 473     {
 474         if (!ReadFile(dbg_parser_input, &ch, 1, &nread, NULL) || nread == 0)
 475             return -1;
 476
 477         if (len + 2 > alloc)
 478         {
 479             while (len + 2 > alloc) alloc *= 2;
 480             *line = dbg_heap_realloc(*line, alloc);
 481         }
 482         (*line)[len++] = ch;
 483     }
 484     while (ch != '\n');
 485     (*line)[len] = '\0';
 486
 487     return len;
 488 }
 489
 490 int input_read_line(const char* pfx, char* buf, int size)
 491 {
 492     char*       line = NULL;
 493
 494     int len = input_fetch_entire_line(pfx, &line);
 495     if (len < 0) return 0;
 496     /* remove trailing \n */
 497     if (len > 0 && line[len - 1] == '\n') len--;
 498     len = min(size - 1, len);
 499     memcpy(buf, line, len);
 500     buf[len] = '\0';
 501     HeapFree(GetProcessHeap(), 0, line);
 502     return 1;
 503 }
 504
 505 /***********************************************************************
 506  *           parser_handle
 507  *
 508  * Debugger command line parser
 509  */
 510 void    parser_handle(HANDLE input)
 511 {
 512     BOOL                ret_ok;
 513     HANDLE              in_copy  = dbg_parser_input;
 514     HANDLE              out_copy = dbg_parser_output;
 515
 516     ret_ok = FALSE;
 517
 518     if (input != INVALID_HANDLE_VALUE)
 519     {
 520         dbg_parser_output = INVALID_HANDLE_VALUE;
 521         dbg_parser_input  = input;
 522     }
 523     else
 524     {
 525         dbg_parser_output = GetStdHandle(STD_OUTPUT_HANDLE);
 526         dbg_parser_input  = GetStdHandle(STD_INPUT_HANDLE);
 527     }
 528
 529     do
 530     {
 531        __TRY
 532        {
 533           ret_ok = TRUE;
 534           dbg_parse();
 535        }
 536        __EXCEPT(wine_dbg_cmd)
 537        {
 538           ret_ok = FALSE;
 539        }
 540        __ENDTRY;
 541        lexeme_flush();
 542     } while (!ret_ok);
 543
 544     dbg_parser_input  = in_copy;
 545     dbg_parser_output = out_copy;
 546 }
 547
 548 void parser(const char* filename)
 549 {
 550     HANDLE h = CreateFile(filename, GENERIC_READ, FILE_SHARE_READ, NULL, OPEN_EXISTING, 0L, 0);
 551     if (h != INVALID_HANDLE_VALUE)
 552     {
 553         parser_handle(h);
 554         CloseHandle(h);
 555     }
 556 }
 557
 558 int dbg_error(const char* s)
 559 {
 560     dbg_printf("%s\n", s);
 561     return 0;
 562 }
 563
 564 HANDLE parser_generate_command_file(const char* pmt, ...)
 565 {
 566     HANDLE      hFile;
 567     char        path[MAX_PATH], file[MAX_PATH];
 568     DWORD       w;
 569     const char* p;
 570
 571     GetTempPath(sizeof(path), path);
 572     GetTempFileName(path, "WD", 0, file);
 573     hFile = CreateFileA(file, GENERIC_READ|GENERIC_WRITE|DELETE, FILE_SHARE_DELETE,
 574                         NULL, CREATE_ALWAYS, FILE_ATTRIBUTE_NORMAL | FILE_FLAG_DELETE_ON_CLOSE, 0);
 575     if (hFile != INVALID_HANDLE_VALUE)
 576     {
 577         va_list ap;
 578
 579         WriteFile(hFile, pmt, strlen(pmt), &w, 0);
 580         va_start(ap, pmt);
 581         while ((p = va_arg(ap, const char*)) != NULL)
 582         {
 583             WriteFile(hFile, "\n", 1, &w, 0);
 584             WriteFile(hFile, p, strlen(p), &w, 0);
 585         }
 586         va_end(ap);
 587         WriteFile(hFile, "\nquit\n", 6, &w, 0);
 588         SetFilePointer(hFile, 0, NULL, FILE_BEGIN);
 589     }
 590     return hFile;
 591 }