git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "proxy.h"
  41 #include "typelib.h"
  42
  43 #if defined(YYBYACC)
  44         /* Berkeley yacc (byacc) doesn't seem to know about these */
  45         /* Some *BSD supplied versions do define these though */
  46 # ifndef YYEMPTY
  47 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  48 # endif
  49 # ifndef YYLEX
  50 #  define YYLEX         yylex()
  51 # endif
  52
  53 #elif defined(YYBISON)
  54         /* Bison was used for original development */
  55         /* #define YYEMPTY -2 */
  56         /* #define YYLEX   yylex() */
  57
  58 #else
  59         /* No yacc we know yet */
  60 # if !defined(YYEMPTY) || !defined(YYLEX)
  61 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  62 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  63 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  64   /* #else we just take a chance that it works... */
  65 # endif
  66 #endif
  67
  68 static attr_t *make_attr(enum attr_type type);
  69 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  70 static attr_t *make_attrp(enum attr_type type, void *val);
  71 static expr_t *make_expr(enum expr_type type);
  72 static expr_t *make_exprl(enum expr_type type, long val);
  73 static expr_t *make_exprs(enum expr_type type, char *val);
  74 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  75 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  76 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  77 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  78 static type_t *make_type(unsigned char type, type_t *ref);
  79 static typeref_t *make_tref(char *name, type_t *ref);
  80 static typeref_t *uniq_tref(typeref_t *ref);
  81 static type_t *type_ref(typeref_t *ref);
  82 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  83 static ifref_t *make_ifref(type_t *iface);
  84 static var_t *make_var(char *name);
  85 static func_t *make_func(var_t *def, var_t *args);
  86 static class_t *make_class(char *name);
  87
  88 static type_t *reg_type(type_t *type, char *name, int t);
  89 static type_t *reg_types(type_t *type, var_t *names, int t);
  90 static type_t *find_type(char *name, int t);
  91 static type_t *find_type2(char *name, int t);
  92 static type_t *get_type(unsigned char type, char *name, int t);
  93 static type_t *get_typev(unsigned char type, var_t *name, int t);
  94 static int get_struct_type(var_t *fields);
  95
  96 static var_t *reg_const(var_t *var);
  97 static var_t *find_const(char *name, int f);
  98
  99 #define tsENUM   1
 100 #define tsSTRUCT 2
 101 #define tsUNION  3
 102
 103 static type_t std_bool = { "boolean" };
 104 static type_t std_int = { "int" };
 105 static type_t std_int64 = { "__int64" };
 106 static type_t std_uhyper = { "MIDL_uhyper" };
 107
 108 %}
 109 %union {
 110         attr_t *attr;
 111         expr_t *expr;
 112         type_t *type;
 113         typeref_t *tref;
 114         var_t *var;
 115         func_t *func;
 116         ifref_t *ifref;
 117         class_t *clas;
 118         char *str;
 119         UUID *uuid;
 120         unsigned int num;
 121 }
 122
 123 %token <str> aIDENTIFIER
 124 %token <str> aKNOWNTYPE
 125 %token <num> aNUM aHEXNUM
 126 %token <str> aSTRING
 127 %token <uuid> aUUID
 128 %token aEOF
 129 %token SHL SHR
 130 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
 131 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 132 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 133 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 134 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 135 %token tDEFAULT
 136 %token tDEFAULTVALUE
 137 %token tDISPINTERFACE
 138 %token tDLLNAME tDOUBLE tDUAL
 139 %token tENDPOINT
 140 %token tENTRY tENUM tERRORSTATUST
 141 %token tEXTERN
 142 %token tFLOAT
 143 %token tHANDLE
 144 %token tHANDLET
 145 %token tHELPSTRING
 146 %token tHIDDEN
 147 %token tHYPER tID tIDEMPOTENT
 148 %token tIIDIS
 149 %token tIMPORT tIMPORTLIB
 150 %token tIN tINCLUDE tINLINE
 151 %token tINPUTSYNC
 152 %token tINT tINT64
 153 %token tINTERFACE
 154 %token tLENGTHIS tLIBRARY
 155 %token tLOCAL
 156 %token tLONG
 157 %token tMETHODS
 158 %token tMODULE
 159 %token tOBJECT tODL tOLEAUTOMATION
 160 %token tOPTIONAL
 161 %token tOUT
 162 %token tPOINTERDEFAULT
 163 %token tPROPERTIES
 164 %token tPROPGET tPROPPUT
 165 %token tPUBLIC
 166 %token tREADONLY tREF
 167 %token tRESTRICTED
 168 %token tRETVAL
 169 %token tSHORT
 170 %token tSIGNED
 171 %token tSIZEIS tSIZEOF
 172 %token tSOURCE
 173 %token tSTDCALL
 174 %token tSTRING tSTRUCT
 175 %token tSWITCH tSWITCHIS tSWITCHTYPE
 176 %token tTRANSMITAS
 177 %token tTYPEDEF
 178 %token tUNION
 179 %token tUNIQUE
 180 %token tUNSIGNED
 181 %token tUUID
 182 %token tV1ENUM
 183 %token tVARARG
 184 %token tVERSION
 185 %token tVOID
 186 %token tWCHAR tWIREMARSHAL
 187
 188 /* used in attr_t */
 189 %token tPOINTERTYPE
 190
 191 %type <attr> m_attributes attributes attrib_list attribute
 192 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 193 %type <expr> array array_list
 194 %type <type> inherit interface interfacehdr interfacedef interfacedec
 195 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 196 %type <type> module modulehdr moduledef
 197 %type <type> base_type int_std
 198 %type <type> enumdef structdef typedef uniondef
 199 %type <ifref> gbl_statements coclass_ints coclass_int
 200 %type <tref> type
 201 %type <var> m_args no_args args arg
 202 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 203 %type <var> m_ident t_ident ident p_ident pident pident_list
 204 %type <var> dispint_props
 205 %type <func> funcdef int_statements
 206 %type <func> dispint_meths
 207 %type <clas> coclass coclasshdr coclassdef
 208 %type <num> pointer_type version
 209 %type <str> libraryhdr
 210
 211 %left ','
 212 %right COND
 213 %left '|'
 214 %left '&'
 215 %left '-' '+'
 216 %left '*' '/'
 217 %left SHL SHR
 218 %right '~'
 219 %right CAST
 220 %right PPTR
 221 %right NEG
 222
 223 %%
 224
 225 input:    gbl_statements                        { write_proxies($1); }
 226         ;
 227
 228 gbl_statements:                                 { $$ = NULL; }
 229         | gbl_statements interfacedec           { $$ = $1; }
 230         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 231         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 232         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 233         | gbl_statements librarydef             { $$ = $1; }
 234         | gbl_statements statement              { $$ = $1; }
 235         ;
 236
 237 imp_statements:                                 {}
 238         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 239         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 240         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 241         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 242         | imp_statements statement              {}
 243         ;
 244
 245 int_statements:                                 { $$ = NULL; }
 246         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 247         | int_statements statement              { $$ = $1; }
 248         ;
 249
 250 statement: ';'                                  {}
 251         | constdef ';'                          { if (!parse_only) { write_constdef($1); } }
 252         | cppquote                              {}
 253         | enumdef ';'                           { if (!parse_only) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 254         | externdef ';'                         { if (!parse_only) { write_externdef($1); } }
 255         | import                                {}
 256         | structdef ';'                         { if (!parse_only) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 257         | typedef ';'                           {}
 258         | uniondef ';'                          { if (!parse_only) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 259         ;
 260
 261 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only) fprintf(header, "%s\n", $3); }
 262         ;
 263 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 264                                                   if (!do_import($2)) yychar = aEOF; }
 265         ;
 266 import:   import_start imp_statements aEOF      {}
 267         ;
 268
 269 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 270         ;
 271 library_start: attributes libraryhdr '{'        { start_typelib($2, $1); }
 272         ;
 273 librarydef: library_start imp_statements '}'    { end_typelib(); }
 274         ;
 275
 276 m_args:                                         { $$ = NULL; }
 277         | args
 278         ;
 279
 280 no_args:  tVOID                                 { $$ = NULL; }
 281         ;
 282
 283 args:     arg
 284         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 285         | no_args
 286         ;
 287
 288 /* split into two rules to get bison to resolve a tVOID conflict */
 289 arg:      attributes type pident array          { $$ = $3;
 290                                                   set_type($$, $2, $4);
 291                                                   $$->attrs = $1;
 292                                                   if (!is_attr($$->attrs, ATTR_OUT) &&
 293                                                       !is_attr($$->attrs, ATTR_IN)) {
 294                                                     attr_t *a = make_attr(ATTR_IN);
 295                                                     LINK(a, $$->attrs); $$->attrs = a;
 296                                                   }
 297                                                 }
 298         | type pident array                     { $$ = $2;
 299                                                   set_type($$, $1, $3);
 300                                                   $$->attrs = make_attr(ATTR_IN);
 301                                                 }
 302         | attributes type pident '(' m_args ')' { $$ = $3;
 303                                                   $$->ptr_level--;
 304                                                   set_type($$, $2, NULL);
 305                                                   $$->attrs = $1;
 306                                                   $$->args = $5;
 307                                                   if (!is_attr($$->attrs, ATTR_OUT) &&
 308                                                       !is_attr($$->attrs, ATTR_IN)) {
 309                                                     attr_t *a = make_attr(ATTR_IN);
 310                                                     LINK(a, $$->attrs); $$->attrs = a;
 311                                                   }
 312                                                 }
 313         | type pident '(' m_args ')'            { $$ = $2;
 314                                                   $$->ptr_level--;
 315                                                   set_type($$, $1, NULL);
 316                                                   $$->attrs = make_attr(ATTR_IN);
 317                                                   $$->args = $4;
 318                                                 }
 319         ;
 320
 321 array:                                          { $$ = NULL; }
 322         | '[' array_list ']'                    { $$ = $2; }
 323         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 324         ;
 325
 326 array_list: m_expr /* size of first dimension is optional */
 327         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 328         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 329         ;
 330
 331 m_attributes:                                   { $$ = NULL; }
 332         | attributes
 333         ;
 334
 335 attributes:
 336           '[' attrib_list ']'                   { $$ = $2; }
 337         ;
 338
 339 attrib_list: attribute
 340         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 341         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 342         ;
 343
 344 attribute:
 345           tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 346         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 347         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 348         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 349         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 350         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 351         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 352         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 353         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE, $3); }
 354         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE, $3); }
 355         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 356         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 357         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 358         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 359         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 360         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 361         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 362         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 363         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 364         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 365         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 366         | tIN                                   { $$ = make_attr(ATTR_IN); }
 367         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 368         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 369         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 370         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 371         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 372         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 373         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 374         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 375         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 376         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 377         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 378         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 379         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 380         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 381         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 382         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 383         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 384         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 385         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 386         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 387         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 388         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 389         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 390         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 391         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 392         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 393         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 394         ;
 395
 396 callconv:
 397         | tSTDCALL
 398         ;
 399
 400 cases:                                          { $$ = NULL; }
 401         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 402                                                   else { $$ = $1; }
 403                                                 }
 404         ;
 405
 406 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 407                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 408                                                   LINK(a, $$->attrs); $$->attrs = a;
 409                                                 }
 410         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 411                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 412                                                   LINK(a, $$->attrs); $$->attrs = a;
 413                                                 }
 414         ;
 415
 416 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 417                                                   set_type($$, $2, NULL);
 418                                                   $$->eval = $5;
 419                                                   $$->lval = $5->cval;
 420                                                 }
 421         ;
 422
 423 enums:                                          { $$ = NULL; }
 424         | enum_list ','                         { $$ = $1; }
 425         | enum_list
 426         ;
 427
 428 enum_list: enum
 429         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 430                                                   if ($1 && !$3->eval)
 431                                                     $3->lval = $1->lval + 1;
 432                                                 }
 433         ;
 434
 435 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 436                                                   $$->eval = $3;
 437                                                   $$->lval = $3->cval;
 438                                                 }
 439         | ident                                 { $$ = reg_const($1);
 440                                                   $$->lval = 0; /* default for first enum entry */
 441                                                 }
 442         ;
 443
 444 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 445                                                   $$->fields = $4;
 446                                                   $$->defined = TRUE;
 447                                                 }
 448         ;
 449
 450 m_exprs:  m_expr
 451         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 452         ;
 453
 454 /*
 455 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 456         | expr_list
 457         ;
 458
 459 expr_list: expr
 460         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 461         ;
 462 */
 463
 464 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 465         | expr
 466         ;
 467
 468 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 469         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 470         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 471         | expr '?' expr ':' expr %prec COND     { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 472         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 473         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 474         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 475         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 476         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 477         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 478         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 479         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 480         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 481         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 482         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 483         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 484         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 485         | '(' expr ')'                          { $$ = $2; }
 486         ;
 487
 488 expr_list_const: expr_const
 489         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 490         ;
 491
 492 expr_const: expr                                { $$ = $1;
 493                                                   if (!$$->is_const) yyerror("expression is not constant\n");
 494                                                 }
 495         ;
 496
 497 externdef: tEXTERN tCONST type ident            { $$ = $4;
 498                                                   set_type($$, $3, NULL);
 499                                                 }
 500         ;
 501
 502 fields:                                         { $$ = NULL; }
 503         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 504                                                   else { $$ = $1; }
 505                                                 }
 506         ;
 507
 508 field:    s_field ';'                           { $$ = $1; }
 509         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 510         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 511         | ';'                                   { $$ = NULL; }
 512         ;
 513
 514 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 515         ;
 516
 517 funcdef:
 518           m_attributes type callconv pident
 519           '(' m_args ')'                        { set_type($4, $2, NULL);
 520                                                   $4->attrs = $1;
 521                                                   $$ = make_func($4, $6);
 522                                                   if (is_attr($4->attrs, ATTR_IN)) {
 523                                                     yyerror("Inapplicable attribute");
 524                                                   }
 525                                                   if (!is_attr($4->attrs, ATTR_OUT)) {
 526                                                     attr_t *a = make_attr(ATTR_OUT);
 527                                                     LINK(a, $4->attrs); $4->attrs = a;
 528                                                   }
 529                                                 }
 530         ;
 531
 532 m_ident:                                        { $$ = NULL; }
 533         | ident
 534         ;
 535
 536 t_ident:                                        { $$ = NULL; }
 537         | aIDENTIFIER                           { $$ = make_var($1); }
 538         | aKNOWNTYPE                            { $$ = make_var($1); }
 539         ;
 540
 541 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 542 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 543         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 544         | tID                                   { $$ = make_var($<str>1); }
 545         | tRETVAL                               { $$ = make_var($<str>1); }
 546         | tVERSION                              { $$ = make_var($<str>1); }
 547         ;
 548
 549 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 550         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 551         | int_std
 552         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 553         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 554                                                   switch ($$->type) {
 555                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 556                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 557                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 558                                                   case RPC_FC_HYPER:
 559                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 560                                                     break;
 561                                                   default: break;
 562                                                   }
 563                                                 }
 564         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 565         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 566         | tBOOLEAN                              { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
 567         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 568         | tHANDLET                              { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
 569         ;
 570
 571 m_int:
 572         | tINT
 573         ;
 574
 575 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 576         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 577         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 578         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 579         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 580         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 581         ;
 582
 583 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 584         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 585         ;
 586
 587 coclasshdr: attributes coclass                  { $$ = $2;
 588                                                   $$->attrs = $1;
 589                                                   if (!parse_only) write_coclass($$);
 590                                                 }
 591         ;
 592
 593 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 594                                                   $$->ifaces = $3;
 595                                                 }
 596         ;
 597
 598 coclass_ints:                                   { $$ = NULL; }
 599         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 600         ;
 601
 602 coclass_int:
 603           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 604         ;
 605
 606 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 607         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 608         ;
 609
 610 dispinterfacehdr: attributes dispinterface      { $$ = $2;
 611                                                   if ($$->defined) yyerror("multiple definition error\n");
 612                                                   $$->attrs = $1;
 613                                                   $$->attrs = make_attr(ATTR_DISPINTERFACE);
 614                                                   LINK($$->attrs, $1);
 615                                                   $$->ref = find_type("IDispatch", 0);
 616                                                   if (!$$->ref) yyerror("IDispatch is undefined\n");
 617                                                   $$->defined = TRUE;
 618                                                   if (!parse_only) write_forward($$);
 619                                                 }
 620         ;
 621
 622 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 623         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 624         ;
 625
 626 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 627         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 628         ;
 629
 630 dispinterfacedef: dispinterfacehdr '{'
 631           dispint_props
 632           dispint_meths
 633           '}'                                   { $$ = $1;
 634                                                   $$->fields = $3;
 635                                                   $$->funcs = $4;
 636                                                   if (!parse_only) write_dispinterface($$);
 637                                                 }
 638 /* FIXME: not sure how to handle this yet
 639         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 640                                                   if (!parse_only) write_interface($$);
 641                                                 }
 642 */
 643         ;
 644
 645 inherit:                                        { $$ = NULL; }
 646         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 647         ;
 648
 649 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 650         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 651         ;
 652
 653 interfacehdr: attributes interface              { $$ = $2;
 654                                                   if ($$->defined) yyerror("multiple definition error\n");
 655                                                   $$->attrs = $1;
 656                                                   $$->defined = TRUE;
 657                                                   if (!parse_only) write_forward($$);
 658                                                 }
 659         ;
 660
 661 interfacedef: interfacehdr inherit
 662           '{' int_statements '}'                { $$ = $1;
 663                                                   $$->ref = $2;
 664                                                   $$->funcs = $4;
 665                                                   if (!parse_only) write_interface($$);
 666                                                 }
 667 /* MIDL is able to import the definition of a base class from inside the
 668  * definition of a derived class, I'll try to support it with this rule */
 669         | interfacehdr ':' aIDENTIFIER
 670           '{' import int_statements '}'         { $$ = $1;
 671                                                   $$->ref = find_type2($3, 0);
 672                                                   if (!$$->ref) yyerror("base class %s not found in import\n", $3);
 673                                                   $$->funcs = $6;
 674                                                   if (!parse_only) write_interface($$);
 675                                                 }
 676         | dispinterfacedef                      { $$ = $1; }
 677         ;
 678
 679 interfacedec:
 680           interface ';'                         { $$ = $1; if (!parse_only) write_forward($$); }
 681         | dispinterface ';'                     { $$ = $1; if (!parse_only) write_forward($$); }
 682         ;
 683
 684 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 685         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 686         ;
 687
 688 modulehdr: attributes module                    { $$ = $2;
 689                                                   $$->attrs = $1;
 690                                                 }
 691         ;
 692
 693 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 694                                                   $$->funcs = $3;
 695                                                   /* FIXME: if (!parse_only) write_module($$); */
 696                                                 }
 697         ;
 698
 699 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 700         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 701         ;
 702
 703 pident:   ident
 704         | p_ident
 705         | '(' pident ')'                        { $$ = $2; }
 706         ;
 707
 708 pident_list:
 709           pident
 710         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 711         ;
 712
 713 pointer_type:
 714           tREF                                  { $$ = RPC_FC_RP; }
 715         | tUNIQUE                               { $$ = RPC_FC_UP; }
 716         ;
 717
 718 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 719                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 720                                                   $$->type = get_struct_type( $4 );
 721                                                   $$->fields = $4;
 722                                                   $$->defined = TRUE;
 723                                                   if(in_typelib)
 724                                                       add_struct($$);
 725                                                 }
 726         ;
 727
 728 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 729         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 730         | base_type                             { $$ = make_tref(NULL, $1); }
 731         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 732         | enumdef                               { $$ = make_tref(NULL, $1); }
 733         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 734         | structdef                             { $$ = make_tref(NULL, $1); }
 735         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 736         | uniondef                              { $$ = make_tref(NULL, $1); }
 737         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 738         ;
 739
 740 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 741                                                   $4->tname = tref->name;
 742                                                   tref->name = NULL;
 743                                                   $$ = type_ref(tref);
 744                                                   $$->attrs = $2;
 745                                                   if (!parse_only) write_typedef($$, $4);
 746                                                   reg_types($$, $4, 0);
 747                                                 }
 748         ;
 749
 750 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 751                                                   $$->fields = $4;
 752                                                   $$->defined = TRUE;
 753                                                 }
 754         | tUNION t_ident
 755           tSWITCH '(' s_field ')'
 756           m_ident '{' cases '}'                 { var_t *u = $7;
 757                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 758                                                   if (!u) u = make_var("tagged_union");
 759                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 760                                                   u->type->fields = $9;
 761                                                   u->type->defined = TRUE;
 762                                                   LINK(u, $5); $$->fields = u;
 763                                                   $$->defined = TRUE;
 764                                                 }
 765         ;
 766
 767 version:
 768           aNUM                                  { $$ = MAKELONG($1, 0); }
 769         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 770         ;
 771
 772 %%
 773
 774 static attr_t *make_attr(enum attr_type type)
 775 {
 776   attr_t *a = xmalloc(sizeof(attr_t));
 777   a->type = type;
 778   a->u.ival = 0;
 779   INIT_LINK(a);
 780   return a;
 781 }
 782
 783 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 784 {
 785   attr_t *a = xmalloc(sizeof(attr_t));
 786   a->type = type;
 787   a->u.ival = val;
 788   INIT_LINK(a);
 789   return a;
 790 }
 791
 792 static attr_t *make_attrp(enum attr_type type, void *val)
 793 {
 794   attr_t *a = xmalloc(sizeof(attr_t));
 795   a->type = type;
 796   a->u.pval = val;
 797   INIT_LINK(a);
 798   return a;
 799 }
 800
 801 static expr_t *make_expr(enum expr_type type)
 802 {
 803   expr_t *e = xmalloc(sizeof(expr_t));
 804   e->type = type;
 805   e->ref = NULL;
 806   e->u.lval = 0;
 807   e->is_const = FALSE;
 808   INIT_LINK(e);
 809   return e;
 810 }
 811
 812 static expr_t *make_exprl(enum expr_type type, long val)
 813 {
 814   expr_t *e = xmalloc(sizeof(expr_t));
 815   e->type = type;
 816   e->ref = NULL;
 817   e->u.lval = val;
 818   e->is_const = FALSE;
 819   INIT_LINK(e);
 820   /* check for numeric constant */
 821   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 822     e->is_const = TRUE;
 823     e->cval = val;
 824   }
 825   return e;
 826 }
 827
 828 static expr_t *make_exprs(enum expr_type type, char *val)
 829 {
 830   expr_t *e;
 831   e = xmalloc(sizeof(expr_t));
 832   e->type = type;
 833   e->ref = NULL;
 834   e->u.sval = val;
 835   e->is_const = FALSE;
 836   INIT_LINK(e);
 837   /* check for predefined constants */
 838   if (type == EXPR_IDENTIFIER) {
 839     var_t *c = find_const(val, 0);
 840     if (c) {
 841       e->u.sval = c->name;
 842       free(val);
 843       e->is_const = TRUE;
 844       e->cval = c->lval;
 845     }
 846   }
 847   return e;
 848 }
 849
 850 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 851 {
 852   expr_t *e;
 853   e = xmalloc(sizeof(expr_t));
 854   e->type = type;
 855   e->ref = expr;
 856   e->u.tref = tref;
 857   e->is_const = FALSE;
 858   INIT_LINK(e);
 859   /* check for cast of constant expression */
 860   if (type == EXPR_CAST && expr->is_const) {
 861     e->is_const = TRUE;
 862     e->cval = expr->cval;
 863   }
 864   return e;
 865 }
 866
 867 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 868 {
 869   expr_t *e;
 870   e = xmalloc(sizeof(expr_t));
 871   e->type = type;
 872   e->ref = expr;
 873   e->u.lval = 0;
 874   e->is_const = FALSE;
 875   INIT_LINK(e);
 876   /* check for compile-time optimization */
 877   if (expr->is_const) {
 878     e->is_const = TRUE;
 879     switch (type) {
 880     case EXPR_NEG:
 881       e->cval = -expr->cval;
 882       break;
 883     case EXPR_NOT:
 884       e->cval = ~expr->cval;
 885       break;
 886     default:
 887       e->is_const = FALSE;
 888       break;
 889     }
 890   }
 891   return e;
 892 }
 893
 894 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 895 {
 896   expr_t *e;
 897   e = xmalloc(sizeof(expr_t));
 898   e->type = type;
 899   e->ref = expr1;
 900   e->u.ext = expr2;
 901   e->is_const = FALSE;
 902   INIT_LINK(e);
 903   /* check for compile-time optimization */
 904   if (expr1->is_const && expr2->is_const) {
 905     e->is_const = TRUE;
 906     switch (type) {
 907     case EXPR_ADD:
 908       e->cval = expr1->cval + expr2->cval;
 909       break;
 910     case EXPR_SUB:
 911       e->cval = expr1->cval - expr2->cval;
 912       break;
 913     case EXPR_MUL:
 914       e->cval = expr1->cval * expr2->cval;
 915       break;
 916     case EXPR_DIV:
 917       e->cval = expr1->cval / expr2->cval;
 918       break;
 919     case EXPR_OR:
 920       e->cval = expr1->cval | expr2->cval;
 921       break;
 922     case EXPR_AND:
 923       e->cval = expr1->cval & expr2->cval;
 924       break;
 925     case EXPR_SHL:
 926       e->cval = expr1->cval << expr2->cval;
 927       break;
 928     case EXPR_SHR:
 929       e->cval = expr1->cval >> expr2->cval;
 930       break;
 931     default:
 932       e->is_const = FALSE;
 933       break;
 934     }
 935   }
 936   return e;
 937 }
 938
 939 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
 940 {
 941   expr_t *e;
 942   e = xmalloc(sizeof(expr_t));
 943   e->type = type;
 944   e->ref = expr1;
 945   e->u.ext = expr2;
 946   e->ext2 = expr3;
 947   e->is_const = FALSE;
 948   INIT_LINK(e);
 949   /* check for compile-time optimization */
 950   if (expr1->is_const && expr2->is_const && expr3->is_const) {
 951     e->is_const = TRUE;
 952     switch (type) {
 953     case EXPR_COND:
 954       e->cval = expr1->cval ? expr2->cval : expr3->cval;
 955       break;
 956     default:
 957       e->is_const = FALSE;
 958       break;
 959     }
 960   }
 961   return e;
 962 }
 963
 964 static type_t *make_type(unsigned char type, type_t *ref)
 965 {
 966   type_t *t = xmalloc(sizeof(type_t));
 967   t->name = NULL;
 968   t->type = type;
 969   t->ref = ref;
 970   t->rname = NULL;
 971   t->attrs = NULL;
 972   t->funcs = NULL;
 973   t->fields = NULL;
 974   t->ignore = parse_only;
 975   t->is_const = FALSE;
 976   t->sign = 0;
 977   t->defined = FALSE;
 978   t->written = FALSE;
 979   t->typelib_idx = -1;
 980   INIT_LINK(t);
 981   return t;
 982 }
 983
 984 static typeref_t *make_tref(char *name, type_t *ref)
 985 {
 986   typeref_t *t = xmalloc(sizeof(typeref_t));
 987   t->name = name;
 988   t->ref = ref;
 989   t->uniq = ref ? 0 : 1;
 990   return t;
 991 }
 992
 993 static typeref_t *uniq_tref(typeref_t *ref)
 994 {
 995   typeref_t *t = ref;
 996   type_t *tp;
 997   if (t->uniq) return t;
 998   tp = make_type(0, t->ref);
 999   tp->name = t->name;
1000   t->name = NULL;
1001   t->ref = tp;
1002   t->uniq = 1;
1003   return t;
1004 }
1005
1006 static type_t *type_ref(typeref_t *ref)
1007 {
1008   type_t *t = ref->ref;
1009   if (ref->name) free(ref->name);
1010   free(ref);
1011   return t;
1012 }
1013
1014 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1015 {
1016   v->type = ref->ref;
1017   v->tname = ref->name;
1018   ref->name = NULL;
1019   free(ref);
1020   v->array = arr;
1021 }
1022
1023 static ifref_t *make_ifref(type_t *iface)
1024 {
1025   ifref_t *l = xmalloc(sizeof(ifref_t));
1026   l->iface = iface;
1027   l->attrs = NULL;
1028   INIT_LINK(l);
1029   return l;
1030 }
1031
1032 static var_t *make_var(char *name)
1033 {
1034   var_t *v = xmalloc(sizeof(var_t));
1035   v->name = name;
1036   v->ptr_level = 0;
1037   v->type = NULL;
1038   v->tname = NULL;
1039   v->attrs = NULL;
1040   v->array = NULL;
1041   v->eval = NULL;
1042   v->lval = 0;
1043   INIT_LINK(v);
1044   return v;
1045 }
1046
1047 static func_t *make_func(var_t *def, var_t *args)
1048 {
1049   func_t *f = xmalloc(sizeof(func_t));
1050   f->def = def;
1051   f->args = args;
1052   f->ignore = parse_only;
1053   f->idx = -1;
1054   INIT_LINK(f);
1055   return f;
1056 }
1057
1058 static class_t *make_class(char *name)
1059 {
1060   class_t *c = xmalloc(sizeof(class_t));
1061   c->name = name;
1062   c->attrs = NULL;
1063   c->ifaces = NULL;
1064   INIT_LINK(c);
1065   return c;
1066 }
1067
1068 #define HASHMAX 64
1069
1070 static int hash_ident(const char *name)
1071 {
1072   const char *p = name;
1073   int sum = 0;
1074   /* a simple sum hash is probably good enough */
1075   while (*p) {
1076     sum += *p;
1077     p++;
1078   }
1079   return sum & (HASHMAX-1);
1080 }
1081
1082 /***** type repository *****/
1083
1084 struct rtype {
1085   char *name;
1086   type_t *type;
1087   int t;
1088   struct rtype *next;
1089 };
1090
1091 struct rtype *type_hash[HASHMAX];
1092
1093 static type_t *reg_type(type_t *type, char *name, int t)
1094 {
1095   struct rtype *nt;
1096   int hash;
1097   if (!name) {
1098     yyerror("registering named type without name\n");
1099     return type;
1100   }
1101   hash = hash_ident(name);
1102   nt = xmalloc(sizeof(struct rtype));
1103   nt->name = name;
1104   nt->type = type;
1105   nt->t = t;
1106   nt->next = type_hash[hash];
1107   type_hash[hash] = nt;
1108   return type;
1109 }
1110
1111 /* determine pointer type from attrs */
1112 static unsigned char get_pointer_type( type_t *type )
1113 {
1114   int t;
1115   if (is_attr( type->attrs, ATTR_STRING ))
1116   {
1117     type_t *t = type;
1118     while( t->type == 0 && t->ref )
1119       t = t->ref;
1120     switch( t->type )
1121     {
1122     case RPC_FC_CHAR:
1123       return RPC_FC_C_CSTRING;
1124     case RPC_FC_WCHAR:
1125       return RPC_FC_C_WSTRING;
1126     }
1127   }
1128   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1129   if (t) return t;
1130   return RPC_FC_FP;
1131 }
1132
1133 static type_t *reg_types(type_t *type, var_t *names, int t)
1134 {
1135   type_t *ptr = type;
1136   int ptrc = 0;
1137
1138   while (names) {
1139     var_t *next = NEXT_LINK(names);
1140     if (names->name) {
1141       type_t *cur = ptr;
1142       int cptr = names->ptr_level;
1143       if (cptr > ptrc) {
1144         while (cptr > ptrc) {
1145           int t = get_pointer_type( cur );
1146           cur = ptr = make_type(t, cur);
1147           ptrc++;
1148         }
1149       } else {
1150         while (cptr < ptrc) {
1151           cur = cur->ref;
1152           cptr++;
1153         }
1154       }
1155       reg_type(cur, names->name, t);
1156     }
1157     free(names);
1158     names = next;
1159   }
1160   return type;
1161 }
1162
1163 static type_t *find_type(char *name, int t)
1164 {
1165   struct rtype *cur = type_hash[hash_ident(name)];
1166   while (cur && (cur->t != t || strcmp(cur->name, name)))
1167     cur = cur->next;
1168   if (!cur) {
1169     yyerror("type %s not found\n", name);
1170     return NULL;
1171   }
1172   return cur->type;
1173 }
1174
1175 static type_t *find_type2(char *name, int t)
1176 {
1177   type_t *tp = find_type(name, t);
1178   free(name);
1179   return tp;
1180 }
1181
1182 int is_type(const char *name)
1183 {
1184   struct rtype *cur = type_hash[hash_ident(name)];
1185   while (cur && (cur->t || strcmp(cur->name, name)))
1186     cur = cur->next;
1187   if (cur) return TRUE;
1188   return FALSE;
1189 }
1190
1191 static type_t *get_type(unsigned char type, char *name, int t)
1192 {
1193   struct rtype *cur = NULL;
1194   type_t *tp;
1195   if (name) {
1196     cur = type_hash[hash_ident(name)];
1197     while (cur && (cur->t != t || strcmp(cur->name, name)))
1198       cur = cur->next;
1199   }
1200   if (cur) {
1201     free(name);
1202     return cur->type;
1203   }
1204   tp = make_type(type, NULL);
1205   tp->name = name;
1206   if (!name) return tp;
1207   return reg_type(tp, name, t);
1208 }
1209
1210 static type_t *get_typev(unsigned char type, var_t *name, int t)
1211 {
1212   char *sname = NULL;
1213   if (name) {
1214     sname = name->name;
1215     free(name);
1216   }
1217   return get_type(type, sname, t);
1218 }
1219
1220 static int get_struct_type(var_t *field)
1221 {
1222   int has_pointer = 0;
1223   int has_conformant_array = 0;
1224   int has_conformant_string = 0;
1225
1226   while (field)
1227   {
1228     type_t *t = field->type;
1229
1230     /* get the base type */
1231     while( (t->type == 0) && t->ref )
1232       t = t->ref;
1233
1234     switch (t->type)
1235     {
1236     /*
1237      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1238      *  Simple types don't effect the type of struct.
1239      *  A struct containing a simple struct is still a simple struct.
1240      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1241      */
1242     case 0: /* void pointer */
1243     case RPC_FC_BYTE:
1244     case RPC_FC_CHAR:
1245     case RPC_FC_SMALL:
1246     case RPC_FC_USMALL:
1247     case RPC_FC_WCHAR:
1248     case RPC_FC_SHORT:
1249     case RPC_FC_USHORT:
1250     case RPC_FC_LONG:
1251     case RPC_FC_ULONG:
1252     case RPC_FC_INT3264:
1253     case RPC_FC_UINT3264:
1254     case RPC_FC_HYPER:
1255     case RPC_FC_FLOAT:
1256     case RPC_FC_DOUBLE:
1257     case RPC_FC_STRUCT:
1258     case RPC_FC_ENUM16:
1259     case RPC_FC_ENUM32:
1260       break;
1261
1262     case RPC_FC_UP:
1263     case RPC_FC_FP:
1264       has_pointer = 1;
1265       break;
1266     case RPC_FC_CARRAY:
1267       has_conformant_array = 1;
1268       break;
1269     case RPC_FC_C_CSTRING:
1270     case RPC_FC_C_WSTRING:
1271       has_conformant_string = 1;
1272       break;
1273
1274     /*
1275      * Propagate member attributes
1276      *  a struct should be at least as complex as its member
1277      */
1278     case RPC_FC_CVSTRUCT:
1279       has_conformant_string = 1;
1280       has_pointer = 1;
1281       break;
1282
1283     case RPC_FC_CPSTRUCT:
1284       has_conformant_array = 1;
1285       has_pointer = 1;
1286       break;
1287
1288     case RPC_FC_CSTRUCT:
1289       has_conformant_array = 1;
1290       break;
1291
1292     case RPC_FC_PSTRUCT:
1293       has_pointer = 1;
1294       break;
1295
1296     default:
1297       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1298               field->name, t->type);
1299       /* fallthru - treat it as complex */
1300
1301     /* as soon as we see one of these these members, it's bogus... */
1302     case RPC_FC_IP:
1303     case RPC_FC_ENCAPSULATED_UNION:
1304     case RPC_FC_NON_ENCAPSULATED_UNION:
1305     case RPC_FC_TRANSMIT_AS:
1306     case RPC_FC_REPRESENT_AS:
1307     case RPC_FC_PAD:
1308     case RPC_FC_EMBEDDED_COMPLEX:
1309     case RPC_FC_BOGUS_STRUCT:
1310       return RPC_FC_BOGUS_STRUCT;
1311     }
1312     field = NEXT_LINK(field);
1313   }
1314
1315   if( has_conformant_string && has_pointer )
1316     return RPC_FC_CVSTRUCT;
1317   if( has_conformant_array && has_pointer )
1318     return RPC_FC_CPSTRUCT;
1319   if( has_conformant_array )
1320     return RPC_FC_CSTRUCT;
1321   if( has_pointer )
1322     return RPC_FC_PSTRUCT;
1323   return RPC_FC_STRUCT;
1324 }
1325
1326 /***** constant repository *****/
1327
1328 struct rconst {
1329   char *name;
1330   var_t *var;
1331   struct rconst *next;
1332 };
1333
1334 struct rconst *const_hash[HASHMAX];
1335
1336 static var_t *reg_const(var_t *var)
1337 {
1338   struct rconst *nc;
1339   int hash;
1340   if (!var->name) {
1341     yyerror("registering constant without name\n");
1342     return var;
1343   }
1344   hash = hash_ident(var->name);
1345   nc = xmalloc(sizeof(struct rconst));
1346   nc->name = var->name;
1347   nc->var = var;
1348   nc->next = const_hash[hash];
1349   const_hash[hash] = nc;
1350   return var;
1351 }
1352
1353 static var_t *find_const(char *name, int f)
1354 {
1355   struct rconst *cur = const_hash[hash_ident(name)];
1356   while (cur && strcmp(cur->name, name))
1357     cur = cur->next;
1358   if (!cur) {
1359     if (f) yyerror("constant %s not found\n", name);
1360     return NULL;
1361   }
1362   return cur->var;
1363 }