git.oblomov.eu Git - wine/blob - aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_GET_SONAME(LIBRARY, FUNCTION, [OTHER_LIBRARIES])
  34 dnl
  35 AC_DEFUN([WINE_GET_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 AC_CACHE_CHECK([for -l$1 soname], ac_Lib,
  39 [ac_get_soname_save_LIBS=$LIBS
  40 LIBS="-l$1 $3 $LIBS"
  41   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  42   [case "$LIBEXT" in
  43     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep lib$1\\.[[0-9A-Za-z.]]*dylib | sed -e "s/^.*\/\(lib$1\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  44     so) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep lib$1\\.so | sed -e "s/^.*\(lib$1\.so[[^   ]]*\).*$/\1/"';2,$d'`]) ;;
  45   esac
  46   if test "x$ac_Lib" = "x"
  47   then
  48      AS_VAR_SET(ac_Lib,"lib$1.$LIBEXT")
  49   fi],
  50   [AS_VAR_SET(ac_Lib,"lib$1.$LIBEXT")])
  51   LIBS=$ac_get_soname_save_LIBS])
  52 AS_VAR_SET_IF(ac_Lib,[AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  53                         [Define to the soname of the lib$1 library.])])dnl
  54 AS_VAR_POPDEF([ac_Lib])])
  55
  56 dnl **** Link C code with an assembly file ****
  57 dnl
  58 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  59 dnl
  60 AC_DEFUN([WINE_TRY_ASM_LINK],
  61 [AC_TRY_LINK([void ac_asm(void) { asm([$1]); }
  62 [$2]],[$3],[$4],[$5])])
  63
  64 dnl **** Check if we can link an empty program with special CFLAGS ****
  65 dnl
  66 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  67 dnl
  68 AC_DEFUN([WINE_TRY_CFLAGS],
  69 [ac_wine_try_cflags_saved=$CFLAGS
  70 CFLAGS="$CFLAGS $1"
  71 AC_TRY_LINK([],[],[$2],[$3])
  72 CFLAGS=$ac_wine_try_cflags_saved])
  73
  74 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  75 dnl
  76 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  77 dnl
  78 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  79 [ac_wine_try_cflags_saved=$CFLAGS
  80 CFLAGS="$CFLAGS $1"
  81 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  82 CFLAGS=$ac_wine_try_cflags_saved])
  83
  84 dnl **** Check whether we need to define a symbol on the compiler command line ****
  85 dnl
  86 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  87 dnl
  88 AC_DEFUN([WINE_CHECK_DEFINE],
  89 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
  90 AC_CACHE_CHECK([whether we need to define $1],ac_var,
  91     AC_EGREP_CPP(yes,[#ifndef $1
  92 yes
  93 #endif],
  94     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
  95 AS_IF([test AS_VAR_GET(ac_var) = yes],
  96       [CFLAGS="$CFLAGS -D$1"
  97   LINTFLAGS="$LINTFLAGS -D$1"])dnl
  98 AS_VAR_POPDEF([ac_var])])
  99
 100 dnl **** Check for functions with some extra libraries ****
 101 dnl
 102 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 103 dnl
 104 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 105 [ac_wine_check_funcs_save_LIBS="$LIBS"
 106 LIBS="$LIBS $2"
 107 AC_CHECK_FUNCS([$1],[$3],[$4])
 108 LIBS="$ac_wine_check_funcs_save_LIBS"])
 109
 110 dnl **** Check for ln ****
 111 dnl
 112 dnl Usage: WINE_PROG_LN
 113 dnl
 114 AC_DEFUN([WINE_PROG_LN],
 115 [AC_MSG_CHECKING([whether ln works])
 116 rm -f conf$$ conf$$.file
 117 echo >conf$$.file
 118 if ln conf$$.file conf$$ 2>/dev/null; then
 119   AC_SUBST(LN,ln)
 120   AC_MSG_RESULT([yes])
 121 else
 122   AC_SUBST(LN,["cp -p"])
 123   AC_MSG_RESULT([no, using $LN])
 124 fi
 125 rm -f conf$$ conf$$.file])
 126
 127 dnl **** Create nonexistent directories from config.status ****
 128 dnl
 129 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 130 dnl
 131 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 132 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])])