git.oblomov.eu Git - wine/blob - tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of include/wine/server.h.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (                     # size align format
  26     "int"           => [  4,   4,  "%d" ],
  27     "short int"     => [  2,   2,  "%d" ],
  28     "char"          => [  1,   1,  "%c" ],
  29     "unsigned char" => [  1,   1,  "%02x" ],
  30     "unsigned short"=> [  2,   2,  "%04x" ],
  31     "unsigned int"  => [  4,   4,  "%08x" ],
  32     "data_size_t"   => [  4,   4,  "%u" ],
  33     "obj_handle_t"  => [  4,   4,  "%04x" ],
  34     "atom_t"        => [  4,   4,  "%04x" ],
  35     "user_handle_t" => [  4,   4,  "%08x" ],
  36     "process_id_t"  => [  4,   4,  "%04x" ],
  37     "thread_id_t"   => [  4,   4,  "%04x" ],
  38     "client_ptr_t"  => [  8,   8,  "&dump_uint64" ],
  39     "mod_handle_t"  => [  8,   8,  "&dump_uint64" ],
  40     "lparam_t"      => [  8,   8,  "&dump_uint64" ],
  41     "apc_param_t"   => [  8,   8,  "&dump_uint64" ],
  42     "file_pos_t"    => [  8,   8,  "&dump_uint64" ],
  43     "mem_size_t"    => [  8,   8,  "&dump_uint64" ],
  44     "affinity_t"    => [  8,   8,  "&dump_uint64" ],
  45     "timeout_t"     => [  8,   8,  "&dump_timeout" ],
  46     "rectangle_t"   => [  16,  4,  "&dump_rectangle" ],
  47     "char_info_t"   => [  4,   2,  "&dump_char_info" ],
  48     "apc_call_t"    => [  40,  8,  "&dump_apc_call" ],
  49     "apc_result_t"  => [  40,  8,  "&dump_apc_result" ],
  50     "async_data_t"  => [  40,  8,  "&dump_async_data" ],
  51     "luid_t"        => [  8,   4,  "&dump_luid" ],
  52     "ioctl_code_t"  => [  4,   4,  "&dump_ioctl_code" ],
  53     "cpu_type_t"    => [  4,   4,  "&dump_cpu_type" ],
  54 );
  55
  56 my @requests = ();
  57 my %replies = ();
  58 my @asserts = ();
  59
  60 my @trace_lines = ();
  61
  62 my $max_req_size = 64;
  63
  64 my $warnings = scalar(@ARGV) && $ARGV[0] eq "-w";
  65
  66 ### Generate a dumping function
  67
  68 sub DO_DUMP_FUNC($$@)
  69 {
  70     my $name = shift;
  71     my $req = shift;
  72     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  73     while ($#_ >= 0)
  74     {
  75         my $type = shift;
  76         my $var = shift;
  77         next if $var =~ /^__pad/;
  78         if (defined($formats{$type}))
  79         {
  80             my $fmt = ${$formats{$type}}[2];
  81             if ($fmt =~ /^&(.*)/)
  82             {
  83                 my $func = $1;
  84                 push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  85                 push @trace_lines, "    $func( &req->$var );\n";
  86                 push @trace_lines, "    fprintf( stderr, \",\" );\n" if ($#_ > 0);
  87             }
  88             elsif ($fmt =~ /^(%.*)\s+\((.*)\)/)
  89             {
  90                 my ($format, $cast) = ($1, $2);
  91                 push @trace_lines, "    fprintf( stderr, \" $var=$format";
  92                 push @trace_lines, "," if ($#_ > 0);
  93                 push @trace_lines, "\", ($cast)req->$var );\n";
  94             }
  95             else
  96             {
  97                 push @trace_lines, "    fprintf( stderr, \" $var=$fmt";
  98                 push @trace_lines, "," if ($#_ > 0);
  99                 push @trace_lines, "\", req->$var );\n";
 100             }
 101         }
 102         else  # must be some varargs format
 103         {
 104             my $func = $type;
 105             push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
 106             push @trace_lines, "    $func;\n";
 107             push @trace_lines, "    fputc( ',', stderr );\n" if ($#_ > 0);
 108         }
 109     }
 110     push @trace_lines, "}\n\n";
 111 }
 112
 113 ### Parse the request definitions
 114
 115 sub PARSE_REQUESTS()
 116 {
 117     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 118     my $state = 0;
 119     my $offset = 0;
 120     my $name = "";
 121     my @in_struct = ();
 122     my @out_struct = ();
 123
 124     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 125
 126     while (<PROTOCOL>)
 127     {
 128         my ($type, $var);
 129         # strip comments
 130         s!/\*.*\*/!!g;
 131         # strip white space at end of line
 132         s/\s+$//;
 133
 134         if (/^\@HEADER/)
 135         {
 136             die "Misplaced \@HEADER" unless $state == 0;
 137             $state++;
 138             next;
 139         }
 140
 141         # ignore everything while in state 0
 142         next if $state == 0;
 143
 144         if (/^\@REQ\(\s*(\w+)\s*\)/)
 145         {
 146             $name = $1;
 147             die "Misplaced \@REQ" unless $state == 1;
 148             # start a new request
 149             @in_struct = ();
 150             @out_struct = ();
 151             $offset = 12;
 152             print SERVER_PROT "struct ${name}_request\n{\n";
 153             print SERVER_PROT "    struct request_header __header;\n";
 154             $state++;
 155             next;
 156         }
 157
 158         if (/^\@REPLY/)
 159         {
 160             die "Misplaced \@REPLY" unless $state == 2;
 161             print SERVER_PROT "};\n";
 162             print SERVER_PROT "struct ${name}_reply\n{\n";
 163             print SERVER_PROT "    struct reply_header __header;\n";
 164             die "request $name too large ($offset)" if ($offset > $max_req_size);
 165             $offset = 8;
 166             $state++;
 167             next;
 168         }
 169
 170         if (/^\@END/)
 171         {
 172             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 173
 174             if ($offset & 7)  # all requests should be 8-byte aligned
 175             {
 176                 my $count = 8 - ($offset & 7);
 177                 print SERVER_PROT "    char __pad_$offset\[$count\];\n";
 178                 $offset += $count;
 179             }
 180             print SERVER_PROT "};\n";
 181             if ($state == 2)  # build dummy reply struct
 182             {
 183                 die "request $name too large ($offset)" if ($offset > $max_req_size);
 184                 push @asserts, "C_ASSERT( sizeof(struct ${name}_request) == $offset );\n";
 185                 print SERVER_PROT "struct ${name}_reply\n{\n";
 186                 print SERVER_PROT "    struct reply_header __header;\n";
 187                 print SERVER_PROT "};\n";
 188             }
 189             else
 190             {
 191                 die "reply $name too large ($offset)" if ($offset > $max_req_size);
 192                 push @asserts, "C_ASSERT( sizeof(struct ${name}_reply) == $offset );\n";
 193             }
 194             # got a complete request
 195             push @requests, $name;
 196             DO_DUMP_FUNC( $name, "request", @in_struct);
 197             if ($#out_struct >= 0)
 198             {
 199                 $replies{$name} = 1;
 200                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 201             }
 202             $state = 1;
 203             next;
 204         }
 205
 206         if ($state != 1)
 207         {
 208             # skip empty lines (but keep them in output file)
 209             if (/^$/)
 210             {
 211                 print SERVER_PROT "\n";
 212                 next;
 213             }
 214
 215             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 216             {
 217                 $var = $1;
 218                 $type = "dump_varargs_" . $2 . "( min(cur_size,req->" . $3 . ") )";
 219                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 220             }
 221             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 222             {
 223                 $var = $1;
 224                 $type = "dump_varargs_" . $2 . "( cur_size )";
 225                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 226             }
 227             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 228             {
 229                 $type = $1;
 230                 $var = $3;
 231                 die "Unrecognized type $type" unless defined($formats{$type});
 232                 my @fmt = @{$formats{$type}};
 233                 if ($offset & ($fmt[1] - 1))
 234                 {
 235                     my $count = $fmt[1] - ($offset & ($fmt[1] - 1));
 236                     print "protocol.def:$.: warning: $name $offset $type $var needs padding\n" if $warnings;
 237                     print SERVER_PROT "    char __pad_$offset\[$count\];\n";
 238                     $offset += $count;
 239                 }
 240                 if ($state == 2)
 241                 {
 242                     push @asserts, "C_ASSERT( FIELD_OFFSET(struct ${name}_request, $var) == $offset );\n";
 243                 }
 244                 else
 245                 {
 246                     push @asserts, "C_ASSERT( FIELD_OFFSET(struct ${name}_reply, $var) == $offset );\n";
 247                 }
 248                 $offset += $fmt[0];
 249             }
 250             else
 251             {
 252                 die "Unrecognized syntax $_";
 253             }
 254             if ($state == 2) { push @in_struct, $type, $var; }
 255             if ($state == 3) { push @out_struct, $type, $var; }
 256         }
 257
 258         # Pass it through into the output file
 259         print SERVER_PROT $_ . "\n";
 260     }
 261     close PROTOCOL;
 262 }
 263
 264 ### Retrieve the server protocol version from the existing server_protocol.h file
 265
 266 sub GET_PROTOCOL_VERSION()
 267 {
 268     my $protocol = 0;
 269     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 270     while (<SERVER_PROT>)
 271     {
 272         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 273     }
 274     close SERVER_PROT;
 275     return $protocol;
 276 }
 277
 278 ### Retrieve the list of status and errors used in the server
 279
 280 sub GET_ERROR_NAMES()
 281 {
 282     my %errors = ();
 283     foreach my $f (glob "server/*.c")
 284     {
 285         next if $f eq "server/trace.c";
 286         open FILE, $f or die "Can't open $f";
 287         while (<FILE>)
 288         {
 289             if (/STATUS_(\w+)/)
 290             {
 291                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 292             }
 293             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 294             {
 295                 $errors{$1} = "0xc0010000 | $1";
 296             }
 297         }
 298         close FILE;
 299     }
 300     return %errors;
 301 }
 302
 303 # update a file if changed
 304 sub update_file($)
 305 {
 306     my $file = shift;
 307     my $ret = !(-f $file) || system "cmp $file $file.new >/dev/null";
 308     if (!$ret)
 309     {
 310         unlink "$file.new";
 311     }
 312     else
 313     {
 314         rename "$file.new", "$file";
 315         print "$file updated\n";
 316     }
 317     return $ret;
 318 }
 319
 320 # replace some lines in a file between two markers
 321 sub replace_in_file($$$@)
 322 {
 323     my $file = shift;
 324     my $start = shift;
 325     my $end = shift;
 326
 327     open NEW_FILE, ">$file.new" or die "cannot create $file.new";
 328
 329     if (defined($start))
 330     {
 331         open OLD_FILE, "$file" or die "cannot open $file";
 332         while (<OLD_FILE>)
 333         {
 334             print NEW_FILE $_;
 335             last if /$start/;
 336         }
 337     }
 338
 339     print NEW_FILE "\n", @_, "\n";
 340
 341     if (defined($end))
 342     {
 343         my $skip=1;
 344         while (<OLD_FILE>)
 345         {
 346             $skip = 0 if /$end/;
 347             print NEW_FILE $_ unless $skip;
 348         }
 349     }
 350
 351     close OLD_FILE if defined($start);
 352     close NEW_FILE;
 353     return update_file($file);
 354 }
 355
 356 ### Main
 357
 358 # Get the server protocol version
 359 my $protocol = GET_PROTOCOL_VERSION();
 360
 361 my %errors = GET_ERROR_NAMES();
 362
 363 ### Create server_protocol.h and print header
 364
 365 open SERVER_PROT, ">include/wine/server_protocol.h.new" or die "Cannot create include/wine/server_protocol.h.new";
 366 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 367 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 368 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 369 print SERVER_PROT " */\n\n";
 370 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 371 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 372
 373 ### Parse requests to find request/reply structure definitions
 374
 375 PARSE_REQUESTS();
 376
 377 ### Build the request list and structures
 378
 379 print SERVER_PROT "\n\nenum request\n{\n";
 380 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 381 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 382
 383 print SERVER_PROT "union generic_request\n{\n";
 384 print SERVER_PROT "    struct request_max_size max_size;\n";
 385 print SERVER_PROT "    struct request_header request_header;\n";
 386 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 387 print SERVER_PROT "};\n";
 388
 389 print SERVER_PROT "union generic_reply\n{\n";
 390 print SERVER_PROT "    struct request_max_size max_size;\n";
 391 print SERVER_PROT "    struct reply_header reply_header;\n";
 392 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 393 print SERVER_PROT "};\n\n";
 394
 395 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 396 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 397 close SERVER_PROT;
 398 update_file( "include/wine/server_protocol.h" );
 399
 400 ### Output the dumping function tables
 401
 402 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 403 foreach my $req (@requests)
 404 {
 405     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 406 }
 407 push @trace_lines, "};\n\n";
 408
 409 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 410 foreach my $req (@requests)
 411 {
 412     push @trace_lines, "    ", $replies{$req} ? "(dump_func)dump_${req}_reply,\n" : "NULL,\n";
 413 }
 414 push @trace_lines, "};\n\n";
 415
 416 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 417 foreach my $req (@requests)
 418 {
 419     push @trace_lines, "    \"$req\",\n";
 420 }
 421 push @trace_lines, "};\n\n";
 422
 423 push @trace_lines, "static const struct\n{\n";
 424 push @trace_lines, "    const char  *name;\n";
 425 push @trace_lines, "    unsigned int value;\n";
 426 push @trace_lines, "} status_names[] =\n{\n";
 427
 428 foreach my $err (sort keys %errors)
 429 {
 430     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 431 }
 432 push @trace_lines, "    { NULL, 0 }\n";
 433 push @trace_lines, "};\n";
 434
 435 replace_in_file( "server/trace.c",
 436                  "### make_requests begin ###",
 437                  "### make_requests end ###",
 438                  @trace_lines );
 439
 440 ### Output the request handlers list
 441
 442 my @request_lines = ();
 443
 444 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 445 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 446 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 447 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 448 foreach my $req (@requests)
 449 {
 450     push @request_lines, "    (req_handler)req_$req,\n";
 451 }
 452 push @request_lines, "};\n\n";
 453
 454 foreach my $type (sort keys %formats)
 455 {
 456     my $size = ${$formats{$type}}[0];
 457     push @request_lines, "C_ASSERT( sizeof($type) == $size );\n";
 458 }
 459 push @request_lines, @asserts;
 460 push @request_lines, "\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 461
 462 replace_in_file( "server/request.h",
 463                  "### make_requests begin ###",
 464                  "### make_requests end ###",
 465                  @request_lines );