git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$LD" || LD="ld -m elf_i386"
  28       test -n "$AS" || AS="as --32"
  29       host_cpu="i386"
  30     fi
  31     ;;
  32 esac
  33
  34 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  35 case $host_cpu in
  36   *i[[3456789]]86*)
  37     if test "x$enable_win16" != "xno"
  38     then
  39       enable_win16="yes"
  40     fi
  41     ;;
  42 esac
  43
  44 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  45 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  46 if test "x$enable_win16" != "xyes"
  47 then
  48   WIN16_FILES=""
  49   WIN16_INSTALL=""
  50 fi
  51
  52 dnl check for out of tree build with unclean source tree
  53 case "$srcdir" in
  54  .) ;;
  55  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  56       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  57 You need to run 'make distclean' in the source tree first.])
  58     fi ;;
  59 esac
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  67 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  68
  69 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  70   [if test -z "$with_wine_tools"; then
  71      if test "$cross_compiling" = "yes"; then
  72        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  73      else
  74        wine_cv_toolsdir="\$(TOPOBJDIR)"
  75      fi
  76    elif test -d "$with_wine_tools/tools/winebuild"; then
  77      case $with_wine_tools in
  78        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  79        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  80      esac
  81    else
  82      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  83    fi])
  84 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  85
  86 AC_PATH_XTRA
  87
  88 dnl Check for flex
  89 AC_CHECK_PROGS(FLEX,flex,none)
  90 if test "$FLEX" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  93 fi
  94
  95 dnl Check for bison
  96 AC_CHECK_PROGS(BISON,bison,none)
  97 if test "$BISON" = "none"
  98 then
  99   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 100 fi
 101
 102 AC_CHECK_TOOLS(AS,[gas as],as)
 103 AC_CHECK_TOOL(LD,ld,ld)
 104 AC_CHECK_TOOL(AR,ar,ar)
 105 AC_PROG_RANLIB
 106 AC_CHECK_TOOL(STRIP,strip,strip)
 107 AC_CHECK_TOOL(WINDRES,windres,false)
 108 AC_PROG_LN_S
 109 WINE_PROG_LN
 110 AC_PROG_EGREP
 111 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 112 AC_PROG_INSTALL
 113 dnl Prepend src dir to install path dir if it's a relative path
 114 case "$INSTALL" in
 115   [[\\/$]]* | ?:[[\\/]]* ) ;;
 116   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 117 esac
 118
 119 dnl Check for lint
 120 AC_CHECK_PROGS(LINT, lclint lint)
 121 if test "$LINT" = "lint"
 122 then
 123   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 124   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 125 fi
 126 AC_SUBST(LINT)
 127 AC_SUBST(LINTFLAGS)
 128
 129 dnl Check for various programs
 130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 131 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 132
 133 case $host_cpu in
 134   *i[[3456789]]86*)
 135     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 136     ;;
 137 esac
 138
 139 dnl **** Check for some libraries ****
 140
 141 dnl Check for -li386 for NetBSD and OpenBSD
 142 AC_CHECK_LIB(i386,i386_set_ldt)
 143 dnl Check for -lossaudio for NetBSD
 144 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpthread
 148 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 149
 150 AC_SUBST(XLIB,"")
 151 AC_SUBST(XFILES,"")
 152 AC_SUBST(OPENGLFILES,"")
 153 AC_SUBST(GLU32FILES,"")
 154 AC_SUBST(OPENGL_LIBS,"")
 155 AC_SUBST(QUARTZFILES,"")
 156
 157 dnl **** Check for header files ****
 158
 159 AC_CHECK_HEADERS(\
 160         AudioUnit/AudioUnit.h \
 161         Carbon/Carbon.h \
 162         CoreAudio/CoreAudio.h \
 163         DiskArbitration/DiskArbitration.h \
 164         IOKit/IOKitLib.h \
 165         alsa/asoundlib.h \
 166         arpa/inet.h \
 167         arpa/nameser.h \
 168         asm/types.h \
 169         capi20.h \
 170         cups/cups.h \
 171         curses.h \
 172         direct.h \
 173         dlfcn.h \
 174         elf.h \
 175         float.h \
 176         fontconfig/fontconfig.h \
 177         getopt.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/mach.h \
 199         mach/machine.h \
 200         machine/cpu.h \
 201         machine/limits.h \
 202         machine/soundcard.h \
 203         mntent.h \
 204         ncurses.h \
 205         netdb.h \
 206         netinet/in.h \
 207         netinet/in_systm.h \
 208         netinet/tcp.h \
 209         netinet/tcp_fsm.h \
 210         openssl/err.h \
 211         openssl/ssl.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/sockio.h \
 252         sys/soundcard.h \
 253         sys/statvfs.h \
 254         sys/strtio.h \
 255         sys/syscall.h \
 256         sys/sysctl.h \
 257         sys/time.h \
 258         sys/times.h \
 259         sys/uio.h \
 260         sys/un.h \
 261         sys/vm86.h \
 262         sys/wait.h \
 263         syscall.h \
 264         termios.h \
 265         unicode/ubidi.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285
 286 AC_CHECK_HEADERS([linux/ipx.h],,,
 287     [#include <sys/types.h>
 288      #ifdef HAVE_ASM_TYPES_H
 289      # include <asm/types.h>
 290      #endif
 291      #if HAVE_SYS_SOCKET_H
 292      # include <sys/socket.h>
 293      #endif])
 294
 295 AC_CHECK_HEADERS([resolv.h],,,
 296     [#include <sys/types.h>
 297      #if HAVE_SYS_SOCKET_H
 298      # include <sys/socket.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #if HAVE_ARPA_NAMESER_H
 304      # include <arpa/nameser.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 308
 309 AC_CHECK_HEADERS([pthread_np.h],,,
 310 [#ifdef HAVE_PTHREAD_H
 311 #include <pthread.h>
 312 #endif])
 313
 314 AC_CHECK_HEADERS([linux/videodev.h],,,
 315 [#ifdef HAVE_SYS_TIME_H
 316 #include <sys/time.h>
 317 #endif
 318 #include <sys/types.h>
 319 #ifdef HAVE_ASM_TYPES_H
 320 #include <asm/types.h>
 321 #endif])
 322
 323 dnl Check for broken kernel header that doesn't define __user
 324 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 325
 326 dnl **** Check for X11 ****
 327
 328 if test "$have_x" = "yes"
 329 then
 330     XLIB="-lXext -lX11"
 331     ac_save_CPPFLAGS="$CPPFLAGS"
 332     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 333
 334     dnl *** All of the following tests require X11/Xlib.h
 335     AC_CHECK_HEADERS([X11/Xlib.h \
 336                       X11/XKBlib.h \
 337                       X11/Xutil.h \
 338                       X11/Xcursor/Xcursor.h \
 339                       X11/extensions/shape.h \
 340                       X11/extensions/XInput.h \
 341                       X11/extensions/XShm.h \
 342                       X11/extensions/Xinerama.h \
 343                       X11/extensions/Xrandr.h \
 344                       X11/extensions/Xrender.h \
 345                       X11/extensions/xf86vmode.h],,,
 346 [#ifdef HAVE_X11_XLIB_H
 347 # include <X11/Xlib.h>
 348 #endif
 349 #ifdef HAVE_X11_XUTIL_H
 350 # include <X11/Xutil.h>
 351 #endif])
 352
 353         dnl *** Check for X keyboard extension
 354         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 355         then
 356               AC_CHECK_LIB(X11, XkbQueryExtension,
 357               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 358               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 359         fi
 360
 361         dnl *** Check for X Shm extension
 362         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 363         then
 364               AC_CHECK_LIB(Xext, XShmQueryExtension,
 365               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 366               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 367         fi
 368
 369         dnl *** Check for X shape extension
 370         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 371         then
 372               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 373               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 374               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 375         fi
 376
 377         dnl *** Check for XFree86 VMODE extension
 378         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 379         then
 380                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 381                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 382                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 383                   ],,
 384                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 385         fi
 386
 387         dnl *** Check for X RandR extension
 388         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 389         then
 390                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 391 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 392                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])],[])
 393         fi
 394
 395         dnl *** Check for Transform functions in Xrender
 396         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 397         then
 398               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 399                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 400                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 401                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 402         fi
 403
 404         dnl *** Check for Xinerama extension
 405         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 406         then
 407                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 408 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 409                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])],[])
 410         fi
 411
 412     dnl *** End of X11/Xlib.h check
 413
 414     dnl Check for the presence of OpenGL
 415     if test "x$with_opengl" != "xno"
 416     then
 417         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 418 [#ifdef HAVE_GL_GLX_H
 419 # include <GL/glx.h>
 420 #endif])
 421         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 422         then
 423             dnl Check for some problems due to old Mesa versions
 424             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 425               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 426                 [wine_cv_opengl_header_version_OK="yes"],
 427                 [wine_cv_opengl_header_version_OK="no"]))
 428
 429             if test "$wine_cv_opengl_header_version_OK" = "yes"
 430             then
 431                 dnl Check for the presence of the library
 432                 AC_CHECK_LIB(GL,glXCreateContext,
 433                              [OPENGL_LIBS="-lGL"
 434                              OPENGLFILES='$(OPENGLFILES)'
 435                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 436                              ,,
 437                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 438
 439                 dnl Check for GLU32 library.
 440                 AC_CHECK_LIB(GLU,gluLookAt,
 441                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 442                              GLU32FILES='$(GLU32FILES)']
 443                              ,,
 444                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 445                 )
 446              fi
 447          else
 448              wine_cv_opengl_headers_found="no"
 449          fi
 450     fi
 451     dnl **** Check for NAS ****
 452     AC_SUBST(NASLIBS,"")
 453     AC_CHECK_HEADERS(audio/audiolib.h,
 454          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 455           AC_CHECK_LIB(audio,AuCreateFlow,
 456                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 457                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 458                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 459                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 460                           [$X_LIBS])
 461                        ],,
 462                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 463
 464     CPPFLAGS="$ac_save_CPPFLAGS"
 465     XFILES='$(XFILES)'
 466 else
 467     XLIB=""
 468     X_CFLAGS=""
 469     X_LIBS=""
 470 fi
 471
 472 dnl **** Check for libxml2 ****
 473
 474 AC_SUBST(XML2LIBS,"")
 475 AC_SUBST(XML2INCL,"")
 476 AC_SUBST(XSLTLIBS,"")
 477 AC_SUBST(XSLTINCL,"")
 478 ac_save_CPPFLAGS="$CPPFLAGS"
 479 if test "$PKG_CONFIG" != "false"
 480 then
 481     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 482     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 483 else
 484     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 485     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 486 fi
 487 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 488 AC_CHECK_HEADERS(libxml/parser.h,
 489         [AC_CHECK_LIB(xml2, xmlParseMemory,
 490             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 491              XML2LIBS="$ac_xml_libs"
 492              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 493          AC_CHECK_LIB(xml2, xmlReadMemory,
 494             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 495          AC_CHECK_LIB(xml2, xmlNewDocPI,
 496             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 497     ])
 498 CPPFLAGS="$ac_save_CPPFLAGS"
 499 if test "$PKG_CONFIG" != "false"
 500 then
 501     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 502     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 503 else
 504     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 505     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 506 fi
 507 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 508 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 509         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 510             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 511              XSLTLIBS="$ac_xslt_libs"
 512              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 513         ],,
 514 [#ifdef HAVE_LIBXSLT_PATTERN_H
 515 # include <libxslt/pattern.h>
 516 #endif])
 517 CPPFLAGS="$ac_save_CPPFLAGS"
 518
 519 dnl **** Check for libhal ****
 520 AC_SUBST(HALINCL,"")
 521 if test "$PKG_CONFIG" != "false"
 522 then
 523     ac_save_CPPFLAGS="$CPPFLAGS"
 524     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 525     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 526     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 527     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 528     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 529     then
 530         AC_CHECK_LIB(hal, libhal_ctx_new,
 531           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 532             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 533              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 534     fi
 535     CPPFLAGS="$ac_save_CPPFLAGS"
 536 fi
 537
 538 dnl **** Check which curses lib to use ***
 539 CURSESLIBS=""
 540 if test "$ac_cv_header_ncurses_h" = "yes"
 541 then
 542     AC_CHECK_LIB(ncurses,waddch,[CURSESLIBS="-lncurses"])
 543 elif test "$ac_cv_header_curses_h" = "yes"
 544 then
 545     AC_CHECK_LIB(curses,waddch,[CURSESLIBS="-lcurses"])
 546 fi
 547 ac_save_LIBS="$LIBS"
 548 LIBS="$LIBS $CURSESLIBS"
 549 AC_CHECK_FUNCS(mousemask)
 550 LIBS="$ac_save_LIBS"
 551
 552 dnl **** Check for SANE ****
 553 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 554 AC_SUBST(SANEINCL,"")
 555 if test "$sane_devel" != "no"
 556 then
 557     SANEINCL="`$sane_devel --cflags`"
 558     ac_save_CPPFLAGS="$CPPFLAGS"
 559     CPPFLAGS="$CPPFLAGS $SANEINCL"
 560     AC_CHECK_HEADER(sane/sane.h,
 561                     [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 562                     [SANEINCL=""])
 563     CPPFLAGS="$ac_save_CPPFLAGS"
 564 fi
 565
 566 dnl **** Check for libgphoto2 ****
 567 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 568 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 569 AC_SUBST(GPHOTO2LIBS,"")
 570 AC_SUBST(GPHOTO2INCL,"")
 571 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 572 then
 573     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 574     GPHOTO2LIBS=""
 575     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 576     do
 577       case "$i" in
 578         -L/usr/lib|-L/usr/lib64) ;;
 579         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 580       esac
 581     done
 582     ac_save_CPPFLAGS="$CPPFLAGS"
 583     ac_save_LIBS="$LIBS"
 584     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 585     LIBS="$LIBS $GPHOTO2LIBS"
 586     AC_CHECK_HEADER(gphoto2-camera.h,
 587                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 588                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 589                                   [GPHOTO2LIBS=""
 590                                   GPHOTO2INCL=""])],
 591                     [GPHOTO2LIBS=""
 592                     GPHOTO2INCL=""])
 593     LIBS="$ac_save_LIBS"
 594     CPPFLAGS="$ac_save_CPPFLAGS"
 595 fi
 596
 597 dnl **** Check for the ICU library ****
 598 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 599 then
 600     saved_libs="$LIBS"
 601     icu_libs="-lsicuuc -lsicudata -lstdc++ -lgcc_s"
 602     if test -n "$ICU_LIB_DIR"
 603     then
 604         icu_libs="-L$ICU_LIB_DIR $icu_libs"
 605     fi
 606     AC_MSG_CHECKING(whether can link with ICU libraries)
 607     LIBS="$saved_libs $icu_libs"
 608     AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <unicode/ubidi.h>]],[[ubidi_open()]])],
 609                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 610                  AC_SUBST(ICULIBS,"$icu_libs")
 611                  AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 612     LIBS="$saved_libs"
 613 fi
 614
 615 dnl **** Check for resolver library ***
 616 AC_SUBST(RESOLVLIBS,"")
 617 if test "$ac_cv_header_resolv_h" = "yes"
 618 then
 619     AC_CHECK_LIB(resolv, res_query,
 620         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 621          RESOLVLIBS="-lresolv"])
 622 fi
 623
 624 dnl **** Check for LittleCMS ***
 625 AC_SUBST(LCMSLIBS,"")
 626 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 627 then
 628     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 629         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 630          LCMSLIBS="-llcms"])
 631 fi
 632
 633 dnl **** Check for OpenLDAP ***
 634 AC_SUBST(LDAPLIBS,"")
 635 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 636 then
 637     AC_CHECK_LIB(ldap_r, ldap_initialize,
 638         [AC_CHECK_LIB(lber, ber_init,
 639             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 640              LDAPLIBS="-lldap_r -llber"],,
 641              [$LIBPTHREAD])],,
 642              [$LIBPTHREAD])
 643     WINE_CHECK_LIB_FUNCS(\
 644         ldap_count_references \
 645         ldap_first_reference \
 646         ldap_next_reference \
 647         ldap_parse_reference,
 648         [$LDAPLIBS $LIBPTHREAD])
 649 fi
 650
 651 dnl **** Check for FreeType 2 ****
 652 AC_SUBST(FREETYPELIBS,"")
 653 AC_SUBST(FREETYPEINCL,"")
 654 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 655 if test "$ft_devel" = "no"
 656 then
 657     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 658     if test "$ft_devel2" = "freetype2-config"
 659     then
 660         ft_devel=$ft_devel2
 661     fi
 662 fi
 663
 664 if test "$ft_devel" = "no"
 665 then
 666     wine_cv_msg_freetype=yes
 667 else
 668     FREETYPELIBS=`$ft_devel --libs`
 669     FREETYPEINCL=`$ft_devel --cflags`
 670     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 671     if test "$ft_lib" = "no"
 672     then
 673         wine_cv_msg_freetype=yes
 674         FREETYPELIBS=""
 675         FREETYPEINCL=""
 676     else
 677         ac_save_CPPFLAGS="$CPPFLAGS"
 678         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 679         AC_CHECK_HEADERS(ft2build.h \
 680                          freetype/freetype.h \
 681                          freetype/ftglyph.h \
 682                          freetype/tttables.h \
 683                          freetype/ftnames.h \
 684                          freetype/ftsnames.h \
 685                          freetype/ttnameid.h \
 686                          freetype/ftoutln.h \
 687                          freetype/ftwinfnt.h \
 688                          freetype/ftmodapi.h \
 689                          freetype/internal/sfnt.h,,,
 690                          [#if HAVE_FT2BUILD_H
 691                           #include <ft2build.h>
 692                           #endif])
 693         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 694                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 695           [Define if you have the <freetype/fttrigon.h> header file.])
 696                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 697         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 698         ac_save_CFLAGS="$CFLAGS"
 699         CFLAGS="$CFLAGS $FREETYPELIBS"
 700         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 701         CFLAGS="$ac_save_CFLAGS"
 702         CPPFLAGS="$ac_save_CPPFLAGS"
 703         dnl Check that we have at least freetype/freetype.h
 704         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 705         then
 706             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 707             wine_cv_msg_freetype=no
 708         else
 709             FREETYPELIBS=""
 710             FREETYPEINCL=""
 711             wine_cv_msg_freetype=yes
 712         fi
 713     fi
 714 fi
 715
 716 dnl Only build the fonts dir if we have both freetype and fontforge
 717 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 718 then
 719   AC_SUBST(FONTSSUBDIRS,"fonts")
 720 fi
 721
 722 dnl **** Check for parport (currently Linux only) ****
 723 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 724  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 725     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 726 if test "$ac_cv_c_ppdev" = "yes"
 727 then
 728     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 729 fi
 730
 731 dnl **** Check for va_copy ****
 732 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 733  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 734     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 735  )
 736 if test "$ac_cv_c_va_copy" = "yes"
 737 then
 738     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 739 fi
 740 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 741  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 742     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 743  )
 744 if test "$ac_cv_c___va_copy" = "yes"
 745 then
 746     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 747 fi
 748
 749 dnl **** Check for sigsetjmp ****
 750 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 751  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 752     sigsetjmp( buf, 1 );
 753     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 754  )
 755 if test "$ac_cv_c_sigsetjmp" = "yes"
 756 then
 757     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 758 fi
 759
 760 dnl **** Check for pthread_rwlock_t ****
 761 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 762 #include <pthread.h>])
 763
 764 dnl **** Check for pthread functions ****
 765 WINE_CHECK_LIB_FUNCS(\
 766         pthread_attr_get_np \
 767         pthread_getattr_np \
 768         pthread_get_stackaddr_np \
 769         pthread_get_stacksize_np,
 770         [$LIBPTHREAD])
 771
 772 dnl **** Check for EsounD ****
 773 AC_PATH_PROG(ESDCONFIG, esd-config)
 774 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 775 then
 776     ESD_CFLAGS=""
 777     for i in `$ESDCONFIG --cflags`
 778     do
 779       case "$i" in
 780         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 781       esac
 782     done
 783     ESD_LIBS=`$ESDCONFIG --libs`
 784     save_CFLAGS="$CFLAGS"
 785     CFLAGS="$CFLAGS $ESD_CFLAGS"
 786     AC_CHECK_LIB(esd,esd_open_sound,
 787         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 788          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 789          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 790     CFLAGS="$save_CFLAGS"
 791 fi
 792
 793 dnl **** Check for ALSA 1.x ****
 794 AC_SUBST(ALSALIBS,"")
 795 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 796 then
 797     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 798         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
 799 #include <alsa/asoundlib.h>
 800 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 801 #include <sys/asoundlib.h>
 802 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
 803                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 804                          ALSALIBS="-lasound"],[])])
 805 fi
 806
 807 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 808
 809 AC_SUBST(AUDIOIOLIBS,"")
 810 if test "$ac_cv_header_libaudioio_h" = "yes"
 811 then
 812     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 813                   [AUDIOIOLIBS="-laudioio"
 814                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 815 fi
 816
 817 dnl **** Check for capi4linux ****
 818
 819 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 820 then
 821     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 822 fi
 823
 824 dnl **** Check for gcc specific options ****
 825
 826 AC_SUBST(EXTRACFLAGS,"")
 827 if test "x${GCC}" = "xyes"
 828 then
 829   EXTRACFLAGS="-Wall -pipe"
 830
 831   dnl Check for strength-reduce bug
 832   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 833                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
 834 [[static int Array[[3]];
 835   unsigned int B = 3;
 836   int i;
 837   for(i=0; i<B; i++) Array[[i]] = i - 3;
 838   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 839   L[[i]] = 4;
 840   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
 841     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
 842   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 843   then
 844     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 845   fi
 846
 847   dnl Check for some compiler flags
 848
 849   WINE_TRY_CFLAGS([-fshort-wchar],
 850                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
 851                              [Specifies the compiler flag that forces a short wchar_t])])
 852   WINE_TRY_CFLAGS([-fno-strict-aliasing])
 853   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
 854   WINE_TRY_CFLAGS([-Wwrite-strings])
 855
 856   dnl Check for noisy string.h
 857   saved_CFLAGS="$CFLAGS"
 858   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 859   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 860       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 861   CFLAGS="$saved_CFLAGS"
 862   if test "$ac_cv_c_string_h_warnings" = "no"
 863   then
 864     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 865   fi
 866
 867   AC_SUBST(BUILTINFLAG,"")
 868   saved_CFLAGS="$CFLAGS"
 869   CFLAGS="$CFLAGS -Werror"
 870   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 871       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 872   CFLAGS="$saved_CFLAGS"
 873   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 874   then
 875     BUILTINFLAG="-fno-builtin"
 876   fi
 877 fi
 878
 879 dnl **** Check how to define a function in assembly code ****
 880
 881 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 882   WINE_TRY_ASM_LINK(
 883       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 884       ac_cv_asm_func_def=".def",
 885     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 886       ac_cv_asm_func_def=".type @function",
 887     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 888       ac_cv_asm_func_def=".type 2",
 889       ac_cv_asm_func_def="unknown")])]))
 890
 891 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 892 case "$ac_cv_asm_func_def" in
 893   ".def")
 894      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 895   ".type @function")
 896      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 897   ".type 2")
 898      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 899   *)
 900      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 901 esac
 902
 903 dnl **** Check for underscore on external symbols ****
 904
 905 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 906     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 907                       [extern int ac_test;],
 908                       [if (ac_test) return 1],
 909                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 910
 911 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 912 if test "$ac_cv_c_extern_prefix" = "yes"
 913 then
 914   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 915 else
 916   AC_DEFINE([__ASM_NAME(name)], [name])
 917 fi
 918
 919 dnl **** Check for working dll ****
 920
 921 AC_SUBST(DLLEXT,"")
 922 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 923 AC_SUBST(LDSHARED,"")
 924 AC_SUBST(LDDLLFLAGS,"")
 925 AC_SUBST(LIBEXT,"so")
 926 AC_SUBST(IMPLIBEXT,"def")
 927 AC_SUBST(LDRPATH_INSTALL,"")
 928 AC_SUBST(LDRPATH_LOCAL,"")
 929
 930 case $host_os in
 931   cygwin*|mingw32*)
 932     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 933     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 934     AC_CHECK_TOOL(MINGWAR,ar,false)
 935     if test "$DLLWRAP" = "false"; then
 936       LIBEXT="a"
 937     else
 938       dnl FIXME - check whether dllwrap works correctly...
 939       LIBEXT="dll"
 940     fi
 941     IMPLIBEXT="a"
 942     dnl We can't build 16-bit NE dlls
 943     WIN16_FILES=""
 944     WIN16_INSTALL=""
 945     ;;
 946   darwin*|macosx*)
 947     DLLEXT=".so"
 948     LIBEXT="dylib"
 949     DLLFLAGS="$DLLFLAGS -fPIC"
 950     LDDLLFLAGS="-bundle -multiply_defined suppress"
 951     LIBWINE_LDFLAGS="-multiply_defined suppress"
 952     LDSHARED="\$(CC) -dynamiclib"
 953     STRIP="$STRIP -x"
 954     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 955     dnl declare needed frameworks
 956     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 957     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 958     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 959     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 960     then
 961         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 962         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 963     fi
 964     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 965     then
 966         dnl CoreServices needed by AudioUnit
 967         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 968     fi
 969     case $host_cpu in
 970       *powerpc*)
 971         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 972         ;;
 973     esac
 974     dnl Enable quartz driver on Mac OS X
 975     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 976     then
 977         AC_SUBST(CARBONLIB,"-framework Carbon")
 978         QUARTZFILES='$(QUARTZFILES)'
 979     fi
 980     ;;
 981   *)
 982     DLLFLAGS="$DLLFLAGS -fPIC"
 983     DLLEXT=".so"
 984     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 985         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 986                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 987     if test "$ac_cv_c_dll_gnuelf" = "yes"
 988     then
 989       LDSHARED="\$(CC) -shared"
 990       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 991       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 992                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 993                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 994                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 995
 996       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 997
 998       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 999                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
1000
1001       echo '{ global: *; };' >conftest.map
1002       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1003                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
1004       rm -f conftest.map
1005
1006       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1007                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
1008
1009       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1010                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
1011                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
1012           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
1013                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
1014                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
1015
1016       case $host_cpu in
1017         *i[[3456789]]86* | x86_64)
1018           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1019                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
1020           ;;
1021       esac
1022
1023     else
1024       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1025           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1026                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1027       if test "$ac_cv_c_dll_unixware" = "yes"
1028       then
1029         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1030         LDDLLFLAGS="-Wl,-G,-B,symbolic"
1031
1032       else
1033         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1034           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1035         if test "$ac_cv_c_dll_hpux" = "yes"
1036         then
1037           LIBEXT="sl"
1038           DLLEXT=".sl"
1039           LDDLLFLAGS="-shared -fPIC"
1040           LDSHARED="\$(CC) -shared"
1041         fi
1042       fi
1043     fi
1044
1045     dnl Check for cross compiler to build test programs
1046     AC_SUBST(CROSSTEST,"")
1047     if test "$cross_compiling" = "no"
1048     then
1049       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
1050       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
1051       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
1052       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
1053       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1054     fi
1055     ;;
1056 esac
1057
1058 if test "$LIBEXT" = "a"; then
1059   AC_MSG_ERROR(
1060 [could not find a way to build shared libraries.
1061 It is currently not possible to build Wine without shared library
1062 (.so) support to allow transparent switch between .so and .dll files.
1063 If you are using Linux, you will need a newer binutils.]
1064 )
1065 fi
1066
1067 AC_SUBST(LDPATH,"")
1068 case $build_os in
1069   cygwin*|mingw32*)
1070     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1071     ;;
1072   darwin*|macosx*)
1073     ;;
1074   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1075     if test -z "$LDRPATH_LOCAL"
1076     then
1077       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1078     fi
1079     ;;
1080   *)
1081     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1082     ;;
1083 esac
1084
1085 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1086 case $host_os in
1087   mingw32*)
1088     AC_SUBST(CRTLIBS,"-lmsvcrt")
1089     AC_SUBST(SOCKETLIBS,"-lws2_32")
1090     ;;
1091 esac
1092
1093 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1094 case $host_cpu in
1095   *i[[3456789]]86*)
1096     case $host_os in
1097       linux* | k*bsd*-gnu)
1098         AC_SUBST(MAIN_BINARY,"wine-glibc")
1099         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1100     esac
1101     ;;
1102 esac
1103
1104 dnl **** Get the soname for libraries that we load dynamically ****
1105
1106 AC_DEFINE_UNQUOTED(SONAME_EXT,[".$LIBEXT"],[Define to the file extension of shared libraries.])
1107
1108 WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
1109 WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1110 WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1111 WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1112 WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1113 WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1114 WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1115 WINE_CHECK_SONAME(freetype,FT_Init_FreeType,,,[$X_LIBS])
1116 WINE_CHECK_SONAME(GL,glXQueryExtension,,,[$X_LIBS $X_EXTRA_LIBS])
1117 WINE_CHECK_SONAME(hal,libhal_ctx_new)
1118 WINE_CHECK_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1119 WINE_CHECK_SONAME(cups,cupsGetDefault)
1120 WINE_CHECK_SONAME(jack,jack_client_new)
1121 WINE_CHECK_SONAME(fontconfig,FcInit)
1122 WINE_CHECK_SONAME(ssl,SSL_library_init)
1123 WINE_CHECK_SONAME(crypto,BIO_new_socket)
1124 WINE_CHECK_SONAME(ncurses,waddch)
1125 WINE_CHECK_SONAME(curses,waddch)
1126 WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1127 WINE_CHECK_SONAME(capi20,capi20_isinstalled)
1128 WINE_CHECK_SONAME(sane,sane_init)
1129
1130
1131 dnl **** Check for functions ****
1132
1133 AC_CHECK_FUNCS(\
1134         _pclose \
1135         _popen \
1136         _snprintf \
1137         _spawnvp \
1138         _stricmp \
1139         _strnicmp \
1140         _vsnprintf \
1141         asctime_r \
1142         chsize \
1143         clone \
1144         dlopen \
1145         epoll_create \
1146         ffs \
1147         finite \
1148         fork \
1149         fpclass \
1150         fstatfs \
1151         fstatvfs \
1152         ftruncate \
1153         futimes \
1154         futimesat \
1155         getdirentries \
1156         getopt_long \
1157         getpagesize \
1158         getpwuid \
1159         gettid \
1160         gettimeofday \
1161         getuid \
1162         inet_pton \
1163         kqueue \
1164         lstat \
1165         memmove \
1166         mmap \
1167         pclose \
1168         poll \
1169         popen \
1170         prctl \
1171         pread \
1172         pwrite \
1173         readlink \
1174         rfork \
1175         sched_yield \
1176         select \
1177         setrlimit \
1178         settimeofday \
1179         sigaltstack \
1180         sigprocmask \
1181         snprintf \
1182         spawnvp \
1183         statfs \
1184         statvfs \
1185         strcasecmp \
1186         strerror \
1187         strncasecmp \
1188         strtold \
1189         tcgetattr \
1190         timegm \
1191         usleep \
1192         vsnprintf \
1193         wait4 \
1194         waitpid \
1195 )
1196
1197 dnl Check for -ldl
1198 if test "$ac_cv_func_dlopen" = no
1199 then
1200     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1201 fi
1202 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1203
1204 dnl Check for -lpoll for Mac OS X/Darwin
1205 if test "$ac_cv_func_poll" = no
1206 then
1207     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1208 fi
1209
1210 dnl Check for -lnsl for Solaris
1211 AC_SEARCH_LIBS(gethostbyname, nsl)
1212
1213 dnl Check for -lsocket for Solaris
1214 AC_SEARCH_LIBS(connect, socket)
1215
1216 dnl Check for -lresolv for Solaris
1217 AC_SEARCH_LIBS(inet_aton, resolv)
1218
1219 dnl **** Check for functions which may rely on -lsocket on Solaris.
1220 AC_CHECK_FUNCS(\
1221         getaddrinfo \
1222         getnameinfo \
1223         getnetbyname \
1224         getprotobyname \
1225         getprotobynumber \
1226         getservbyport \
1227         inet_network \
1228         sendmsg \
1229 )
1230
1231 dnl **** Check for types ****
1232
1233 AC_C_CONST
1234 AC_C_INLINE
1235 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1236 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1237 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1238
1239 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1240 [#ifdef HAVE_LINUX_INPUT_H
1241 #include <linux/input.h>
1242 #endif])
1243
1244 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1245                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1246 if test "$wine_cv_have_sigaddset" = "yes"
1247 then
1248   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1249 fi
1250
1251
1252 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1253         wine_cv_linux_gethostbyname_r_6,
1254         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1255     char *name=NULL;
1256     struct hostent he;
1257     struct hostent *result;
1258     char *buf=NULL;
1259     int bufsize=0;
1260     int res,errnr;
1261     char *addr=NULL;
1262     int addrlen=0;
1263     int addrtype=0;
1264     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1265     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1266     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1267         ])
1268    )
1269    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1270    then
1271       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1272                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1273    fi
1274
1275 if test "$ac_cv_header_linux_joystick_h" = "yes"
1276 then
1277    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1278         wine_cv_linux_joystick_22_api,
1279         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1280         #include <sys/ioctl.h>
1281         #include <sys/types.h>
1282         #include <linux/joystick.h>
1283
1284         struct js_event blub;
1285         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1286         #error "no 2.2 header"
1287         #endif
1288         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1289    )
1290    if test "$wine_cv_linux_joystick_22_api" = "yes"
1291    then
1292       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1293                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1294    fi
1295 fi
1296
1297 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1298
1299 dnl Check for statfs members
1300 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1301 [#include <sys/types.h>
1302 #ifdef HAVE_SYS_PARAM_H
1303 # include <sys/param.h>
1304 #endif
1305 #ifdef HAVE_SYS_MOUNT_H
1306 # include <sys/mount.h>
1307 #endif
1308 #ifdef HAVE_SYS_VFS_H
1309 # include <sys/vfs.h>
1310 #endif
1311 #ifdef HAVE_SYS_STATFS_H
1312 # include <sys/statfs.h>
1313 #endif])
1314
1315 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1316 [#ifdef HAVE_SYS_STATVFS_H
1317 #include <sys/statvfs.h>
1318 #endif])
1319
1320 dnl Check for socket structure members
1321 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1322 [#include <sys/types.h>
1323 #ifdef HAVE_SYS_SOCKET_H
1324 # include <sys/socket.h>
1325 #endif
1326 #ifdef HAVE_SYS_UN_H
1327 # include <sys/un.h>
1328 #endif])
1329
1330 dnl Check for scsireq_t and sg_io_hdr_t members
1331 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1332 [#include <sys/types.h>
1333 #ifdef HAVE_SCSI_SG_H
1334 #include <scsi/sg.h>
1335 #endif])
1336
1337 dnl Check for siginfo_t members
1338 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1339
1340 dnl Check for struct mtget members
1341 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1342 [#include <sys/types.h>
1343 #ifdef HAVE_SYS_MTIO_H
1344 #include <sys/mtio.h>
1345 #endif])
1346
1347 dnl Check for struct option
1348 AC_CHECK_MEMBERS([struct option.name],,,
1349 [#ifdef HAVE_GETOPT_H
1350 #include <getopt.h>
1351 #endif])
1352
1353 dnl Check for stat.st_blocks
1354 AC_CHECK_MEMBERS([struct stat.st_blocks])
1355
1356 dnl Check for sin6_scope_id
1357 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1358 [#ifdef HAVE_SYS_TYPES_H
1359 #include <sys/types.h>
1360 #endif
1361 #ifdef HAVE_NETINET_IN_H
1362 #include <netinet/in.h>
1363 #endif])
1364
1365 dnl Check for ns_msg ptr member
1366 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1367 [#ifdef HAVE_SYS_TYPES_H
1368 #include <sys/types.h>
1369 #endif
1370 #ifdef HAVE_NETINET_IN_H
1371 # include <netinet/in.h>
1372 #endif
1373 #ifdef HAVE_ARPA_NAMESER_H
1374 # include <arpa/nameser.h>
1375 #endif])
1376
1377 dnl Check for the external timezone variables timezone and daylight
1378 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1379                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1380 if test "$ac_cv_have_timezone" = "yes"
1381 then
1382     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1383 fi
1384 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1385                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1386 if test "$ac_cv_have_daylight" = "yes"
1387 then
1388     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1389 fi
1390
1391 dnl *** check for the need to define platform-specific symbols
1392
1393 case $host_cpu in
1394   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1395   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1396   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1397   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1398   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1399 esac
1400
1401 case $host_vendor in
1402   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1403 esac
1404
1405 dnl **** Generate output files ****
1406
1407 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1408 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1409 ["### Dependencies:\\
1410 \\
1411 .INIT: Makefile\\
1412 .BEGIN: Makefile\\
1413 Makefile: dummy\\
1414         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1415 \\
1416 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1417 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1418 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1419 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1420 ["### Dependencies:
1421
1422 .INIT: Makefile
1423 .BEGIN: Makefile
1424 Makefile: dummy
1425         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1426
1427 \$(OBJS): \$(IDL_GEN_HEADERS)
1428 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1429 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1430 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1431
1432 AH_TOP([#define __WINE_CONFIG_H])
1433
1434 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1435
1436 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1437 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1438 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1439 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1440 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1441 WINE_CONFIG_EXTRA_DIR(include/wine)
1442
1443 MAKE_RULES=Make.rules
1444 AC_SUBST_FILE(MAKE_RULES)
1445
1446 MAKE_DLL_RULES=dlls/Makedll.rules
1447 AC_SUBST_FILE(MAKE_DLL_RULES)
1448
1449 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1450 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1451
1452 MAKE_TEST_RULES=dlls/Maketest.rules
1453 AC_SUBST_FILE(MAKE_TEST_RULES)
1454
1455 MAKE_PROG_RULES=programs/Makeprog.rules
1456 AC_SUBST_FILE(MAKE_PROG_RULES)
1457
1458 AC_CONFIG_FILES([Make.rules])
1459 AC_CONFIG_FILES([dlls/Makedll.rules])
1460 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1461 AC_CONFIG_FILES([dlls/Maketest.rules])
1462 AC_CONFIG_FILES([programs/Makeprog.rules])
1463 AC_CONFIG_FILES([Makefile])
1464 AC_CONFIG_FILES([dlls/Makefile])
1465 AC_CONFIG_FILES([dlls/acledit/Makefile])
1466 AC_CONFIG_FILES([dlls/activeds/Makefile])
1467 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1468 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1469 AC_CONFIG_FILES([dlls/advpack/Makefile])
1470 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1471 AC_CONFIG_FILES([dlls/amstream/Makefile])
1472 AC_CONFIG_FILES([dlls/atl/Makefile])
1473 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1474 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1475 AC_CONFIG_FILES([dlls/browseui/Makefile])
1476 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1477 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1478 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1479 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1480 AC_CONFIG_FILES([dlls/cards/Makefile])
1481 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1482 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1483 AC_CONFIG_FILES([dlls/comcat/Makefile])
1484 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1485 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1486 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1487 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1488 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1489 AC_CONFIG_FILES([dlls/compstui/Makefile])
1490 AC_CONFIG_FILES([dlls/credui/Makefile])
1491 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1492 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1493 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1494 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1495 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1496 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1497 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1498 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1499 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1500 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1501 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1502 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1503 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1504 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1505 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1506 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1507 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1508 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1509 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1510 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1511 AC_CONFIG_FILES([dlls/devenum/Makefile])
1512 AC_CONFIG_FILES([dlls/dinput/Makefile])
1513 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1514 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1515 AC_CONFIG_FILES([dlls/dmband/Makefile])
1516 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1517 AC_CONFIG_FILES([dlls/dmime/Makefile])
1518 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1519 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1520 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1521 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1522 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1523 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1524 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1525 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1526 AC_CONFIG_FILES([dlls/dplay/Makefile])
1527 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1528 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1529 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1530 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1531 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1532 AC_CONFIG_FILES([dlls/dsound/Makefile])
1533 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1534 AC_CONFIG_FILES([dlls/dswave/Makefile])
1535 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1536 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1537 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1538 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1539 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1540 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1541 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1542 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1543 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1544 AC_CONFIG_FILES([dlls/glu32/Makefile])
1545 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1546 AC_CONFIG_FILES([dlls/hal/Makefile])
1547 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1548 AC_CONFIG_FILES([dlls/hid/Makefile])
1549 AC_CONFIG_FILES([dlls/hlink/Makefile])
1550 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1551 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1552 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1553 AC_CONFIG_FILES([dlls/icmp/Makefile])
1554 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1555 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1556 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1557 AC_CONFIG_FILES([dlls/imm32/Makefile])
1558 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1559 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1560 AC_CONFIG_FILES([dlls/inseng/Makefile])
1561 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1562 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1563 AC_CONFIG_FILES([dlls/itss/Makefile])
1564 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1565 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1566 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1567 AC_CONFIG_FILES([dlls/localspl/Makefile])
1568 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1569 AC_CONFIG_FILES([dlls/localui/Makefile])
1570 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1571 AC_CONFIG_FILES([dlls/lz32/Makefile])
1572 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1573 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1574 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1575 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1576 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1577 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1578 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1579 AC_CONFIG_FILES([dlls/midimap/Makefile])
1580 AC_CONFIG_FILES([dlls/mlang/Makefile])
1581 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1582 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1583 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1584 AC_CONFIG_FILES([dlls/mpr/Makefile])
1585 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1586 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1587 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1588 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1589 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1590 AC_CONFIG_FILES([dlls/mscms/Makefile])
1591 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1592 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1593 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1594 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1595 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1596 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1597 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1598 AC_CONFIG_FILES([dlls/msi/Makefile])
1599 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1600 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1601 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1602 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1603 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1604 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1605 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1606 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1607 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1608 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1609 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1610 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1611 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1612 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1613 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1614 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1615 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1616 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1617 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1618 AC_CONFIG_FILES([dlls/newdev/Makefile])
1619 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1620 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1621 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1622 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1623 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1624 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1625 AC_CONFIG_FILES([dlls/objsel/Makefile])
1626 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1627 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1628 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1629 AC_CONFIG_FILES([dlls/ole32/Makefile])
1630 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1631 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1632 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1633 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1634 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1635 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1636 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1637 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1638 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1639 AC_CONFIG_FILES([dlls/pdh/Makefile])
1640 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1641 AC_CONFIG_FILES([dlls/printui/Makefile])
1642 AC_CONFIG_FILES([dlls/psapi/Makefile])
1643 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1644 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1645 AC_CONFIG_FILES([dlls/qcap/Makefile])
1646 AC_CONFIG_FILES([dlls/quartz/Makefile])
1647 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1648 AC_CONFIG_FILES([dlls/query/Makefile])
1649 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1650 AC_CONFIG_FILES([dlls/resutils/Makefile])
1651 AC_CONFIG_FILES([dlls/riched20/Makefile])
1652 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1653 AC_CONFIG_FILES([dlls/riched32/Makefile])
1654 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1655 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1656 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1657 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1658 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1659 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1660 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1661 AC_CONFIG_FILES([dlls/schannel/Makefile])
1662 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1663 AC_CONFIG_FILES([dlls/secur32/Makefile])
1664 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1665 AC_CONFIG_FILES([dlls/security/Makefile])
1666 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1667 AC_CONFIG_FILES([dlls/serialui/Makefile])
1668 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1669 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1670 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1671 AC_CONFIG_FILES([dlls/sfc/Makefile])
1672 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1673 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1674 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1675 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1676 AC_CONFIG_FILES([dlls/shell32/Makefile])
1677 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1678 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1679 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1680 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1681 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1682 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1684 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1685 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1686 AC_CONFIG_FILES([dlls/sti/Makefile])
1687 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1688 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1689 AC_CONFIG_FILES([dlls/sxs/Makefile])
1690 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1691 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1692 AC_CONFIG_FILES([dlls/unicows/Makefile])
1693 AC_CONFIG_FILES([dlls/url/Makefile])
1694 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1695 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1696 AC_CONFIG_FILES([dlls/user32/Makefile])
1697 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1698 AC_CONFIG_FILES([dlls/userenv/Makefile])
1699 AC_CONFIG_FILES([dlls/usp10/Makefile])
1700 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1701 AC_CONFIG_FILES([dlls/uuid/Makefile])
1702 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1703 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1704 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1705 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1706 AC_CONFIG_FILES([dlls/version/Makefile])
1707 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1708 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1709 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1710 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1711 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1712 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1713 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1714 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1715 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1716 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1717 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1718 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1719 AC_CONFIG_FILES([dlls/winedos/Makefile])
1720 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1721 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1722 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1723 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1724 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1725 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1726 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1727 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1728 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1729 AC_CONFIG_FILES([dlls/wing32/Makefile])
1730 AC_CONFIG_FILES([dlls/wininet/Makefile])
1731 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1732 AC_CONFIG_FILES([dlls/winmm/Makefile])
1733 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1734 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1735 AC_CONFIG_FILES([dlls/winscard/Makefile])
1736 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1737 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1738 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1739 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1740 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1741 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1742 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1743 AC_CONFIG_FILES([dlls/wow32/Makefile])
1744 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1745 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1746 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1747 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1748 AC_CONFIG_FILES([documentation/Makefile])
1749 AC_CONFIG_FILES([fonts/Makefile])
1750 AC_CONFIG_FILES([include/Makefile])
1751 AC_CONFIG_FILES([libs/Makefile])
1752 AC_CONFIG_FILES([libs/port/Makefile])
1753 AC_CONFIG_FILES([libs/wine/Makefile])
1754 AC_CONFIG_FILES([libs/wpp/Makefile])
1755 AC_CONFIG_FILES([loader/Makefile])
1756 AC_CONFIG_FILES([programs/Makefile])
1757 AC_CONFIG_FILES([programs/clock/Makefile])
1758 AC_CONFIG_FILES([programs/cmd/Makefile])
1759 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1760 AC_CONFIG_FILES([programs/control/Makefile])
1761 AC_CONFIG_FILES([programs/eject/Makefile])
1762 AC_CONFIG_FILES([programs/expand/Makefile])
1763 AC_CONFIG_FILES([programs/explorer/Makefile])
1764 AC_CONFIG_FILES([programs/hh/Makefile])
1765 AC_CONFIG_FILES([programs/icinfo/Makefile])
1766 AC_CONFIG_FILES([programs/iexplore/Makefile])
1767 AC_CONFIG_FILES([programs/msiexec/Makefile])
1768 AC_CONFIG_FILES([programs/net/Makefile])
1769 AC_CONFIG_FILES([programs/notepad/Makefile])
1770 AC_CONFIG_FILES([programs/oleview/Makefile])
1771 AC_CONFIG_FILES([programs/progman/Makefile])
1772 AC_CONFIG_FILES([programs/regedit/Makefile])
1773 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1774 AC_CONFIG_FILES([programs/rpcss/Makefile])
1775 AC_CONFIG_FILES([programs/rundll32/Makefile])
1776 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1777 AC_CONFIG_FILES([programs/start/Makefile])
1778 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1779 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1780 AC_CONFIG_FILES([programs/view/Makefile])
1781 AC_CONFIG_FILES([programs/wineboot/Makefile])
1782 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1783 AC_CONFIG_FILES([programs/winecfg/Makefile])
1784 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1785 AC_CONFIG_FILES([programs/winedbg/Makefile])
1786 AC_CONFIG_FILES([programs/winedevice/Makefile])
1787 AC_CONFIG_FILES([programs/winefile/Makefile])
1788 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1789 AC_CONFIG_FILES([programs/winemine/Makefile])
1790 AC_CONFIG_FILES([programs/winepath/Makefile])
1791 AC_CONFIG_FILES([programs/winetest/Makefile])
1792 AC_CONFIG_FILES([programs/winevdm/Makefile])
1793 AC_CONFIG_FILES([programs/winhelp/Makefile])
1794 AC_CONFIG_FILES([programs/winver/Makefile])
1795 AC_CONFIG_FILES([programs/wordpad/Makefile])
1796 AC_CONFIG_FILES([programs/xcopy/Makefile])
1797 AC_CONFIG_FILES([server/Makefile])
1798 AC_CONFIG_FILES([tools/Makefile])
1799 AC_CONFIG_FILES([tools/widl/Makefile])
1800 AC_CONFIG_FILES([tools/winebuild/Makefile])
1801 AC_CONFIG_FILES([tools/winedump/Makefile])
1802 AC_CONFIG_FILES([tools/winegcc/Makefile])
1803 AC_CONFIG_FILES([tools/wmc/Makefile])
1804 AC_CONFIG_FILES([tools/wrc/Makefile])
1805
1806 AC_OUTPUT
1807
1808 dnl **** Display messages about additional packages ***
1809
1810 if test "$no_create" = "yes"
1811 then
1812   exit 0
1813 fi
1814
1815 if test "$verbose" = "yes"
1816 then
1817   dnl **** libcapi20-dev devel package ***
1818   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1819   then
1820     echo >&2
1821     AC_MSG_NOTICE([libcapi20 development files not found.])
1822     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1823   fi
1824
1825   dnl **** libcupsys-dev devel package ***
1826   if test "$ac_cv_header_cups_cups_h" != "yes"
1827   then
1828     echo >&2
1829     AC_MSG_NOTICE([libcups development files not found.])
1830     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1831   fi
1832
1833   dnl **** libcurses devel package: see libncurses ***
1834   dnl **** libdbus-1 devel package ***
1835   dnl **** libdbus-1-dev is required for libhal-dev ***
1836
1837   dnl **** libgphoto2 devel package ***
1838   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1839   then
1840     echo >&2
1841     AC_MSG_NOTICE([libgphoto2 development files not found.])
1842     if test "$ac_cv_header_sane_sane_h" = "yes"
1843     then
1844       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1845     else
1846       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1847     fi
1848   fi
1849
1850   dnl **** libhal devel package ***
1851   dnl **** libhal-dev depends on libdbus-1-dev ***
1852   if test "$ac_cv_header_hal_libhal_h" != "yes"
1853   then
1854     echo >&2
1855     AC_MSG_NOTICE([libhal development files not found.])
1856     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1857   fi
1858
1859   dnl **** libicu devel package ****
1860   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1861   then
1862     echo >&2
1863     AC_MSG_NOTICE([libicu development files not found.])
1864     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1865   fi
1866
1867   dnl **** liblcms devel package ****
1868   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1869   then
1870     echo >&2
1871     AC_MSG_NOTICE([liblcms development files not found.])
1872     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1873   fi
1874
1875   dnl **** libldap devel package ****
1876   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1877   then
1878     echo >&2
1879     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1880     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1881   fi
1882
1883   dnl **** libncurses / libcurses devel package ***
1884   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1885   then
1886     echo >&2
1887     AC_MSG_NOTICE([lib(n)curses development files not found.])
1888     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1889   fi
1890
1891   dnl **** libsane devel package ***
1892   if test "$ac_cv_header_sane_sane_h" != "yes"
1893   then
1894     echo >&2
1895     AC_MSG_NOTICE([libsane development files not found.])
1896     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1897   fi
1898
1899   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1900   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1901   if test "$have_x" = "yes"
1902   then
1903     dnl **** libX11 - extension: Xext ***
1904     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1905     then
1906       echo >&2
1907       AC_MSG_NOTICE([libxext development files not found.])
1908       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1909     fi
1910
1911     dnl **** libX11 - extension: Xrandr ***
1912     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1913     then
1914       echo >&2
1915       AC_MSG_NOTICE([libXrandr development files not found.])
1916       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1917     fi
1918
1919     dnl **** libX11 - extension: Xrender ***
1920     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1921     then
1922       echo >&2
1923       AC_MSG_NOTICE([libXrender development files not found.])
1924       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1925     fi
1926
1927     dnl **** libX11 - extension: Xxf86vm ***
1928     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1929     then
1930       echo >&2
1931       AC_MSG_NOTICE([libXxf86vm development files not found.])
1932       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1933     fi
1934   fi
1935
1936   dnl **** libxml2 devel package ***
1937   if test "$ac_cv_header_libxml_parser_h" != "yes"
1938   then
1939     echo >&2
1940     AC_MSG_NOTICE([libxml2 development files not found.])
1941     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1942   fi
1943
1944   dnl **** libxslt devel package ***
1945   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1946   then
1947     echo >&2
1948     AC_MSG_NOTICE([libxslt development files not found.])
1949     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1950   fi
1951 fi
1952
1953
1954 dnl **** Display warnings about important packages ***
1955 if test "$have_x" = "no"
1956 then
1957   echo >&2
1958   AC_MSG_WARN([X development files not found. Wine will be built without])
1959   AC_MSG_WARN([X support, which currently does not work, and probably])
1960   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1961   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1962 fi
1963
1964 if test -z "$OPENGLFILES"
1965 then
1966   echo >&2
1967   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
1968   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
1969   if test "$wine_cv_opengl_headers_found" = "no"
1970   then
1971     AC_MSG_WARN([No OpenGL development headers were found])
1972   fi
1973   if test "$wine_cv_opengl_header_version_OK" = "no"
1974   then
1975     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1976   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
1977   then
1978      if test -f /usr/X11R6/lib/libGL.a
1979      then
1980         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
1981 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
1982      else
1983         AC_MSG_WARN([No OpenGL library found on this system.])
1984      fi
1985   fi
1986 fi
1987
1988 if test "$wine_cv_msg_freetype" = "yes"
1989 then
1990   echo >&2
1991   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
1992   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
1993   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
1994   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
1995 fi
1996
1997 if test -z "$FONTSSUBDIRS"
1998 then
1999   echo >&2
2000   if test "$FONTFORGE" = "false"
2001   then
2002     AC_MSG_WARN([FontForge is missing.])
2003   else
2004     AC_MSG_WARN([FreeType is missing.])
2005   fi
2006   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2007 fi
2008
2009 if test -z "$ALSALIBS" -a \
2010         -z "$AUDIOIOLIBS" -a \
2011         -z "$NASLIBS" -a \
2012         -z "$ESD_LIBS" -a \
2013         -z "$ac_cv_lib_soname_jack" -a \
2014         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2015         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2016         "$ac_cv_header_soundcard_h" != "yes"
2017 then
2018   echo >&2
2019   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2020   AC_MSG_WARN([The currently supported sound systems are:])
2021   AC_MSG_WARN([ALSA, EsounD, AudioIO, Jack, NAS and OSS])
2022 fi
2023
2024 echo
2025 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2026 echo
2027
2028 dnl Local Variables:
2029 dnl comment-start: "dnl "
2030 dnl comment-end: ""
2031 dnl comment-start-skip: "\\bdnl\\b\\s *"
2032 dnl compile-command: "autoreconf --warnings=all"
2033 dnl End: