git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  19             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  20 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  21             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  22 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  23             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  24 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  25             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  26 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  28 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_cups_cups_h=no; fi])
  30 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  31             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  32 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  33 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  34             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  35 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  36 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  37 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  38             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  39 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  40             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  41 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  43 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  45 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  46 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  47             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  48 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  49             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  50 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  52 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  53 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  54             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  55 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  57 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  59 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  61 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  62 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  63             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  64 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  65             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  66 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  68 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  70 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  71 AC_ARG_WITH(xvidmode,  AS_HELP_STRING([--without-xvidmode],[do not use XFree video mode extension]),
  72             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; fi])
  73
  74 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  75
  76 AC_CANONICAL_HOST
  77 case $host in
  78   x86_64*linux*)
  79     if test "x$enable_win64" != "xyes"
  80     then
  81       test -n "$CC" || CC="gcc -m32"
  82       test -n "$CXX"|| CXX="g++ -m32"
  83       test -n "$LD" || LD="ld -m elf_i386"
  84       test -n "$AS" || AS="as --32"
  85       host_cpu="i386"
  86     fi
  87     ;;
  88 esac
  89
  90 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  91 case $host_cpu in
  92   *i[[3456789]]86*)
  93     if test "x$enable_win16" != "xno"
  94     then
  95       enable_win16="yes"
  96     fi
  97     ;;
  98 esac
  99
 100 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
 101 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
 102 if test "x$enable_win16" != "xyes"
 103 then
 104   WIN16_FILES=""
 105   WIN16_INSTALL=""
 106 fi
 107
 108 dnl check for out of tree build with unclean source tree
 109 case "$srcdir" in
 110  .) ;;
 111  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 112       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 113 You need to run 'make distclean' in the source tree first.])
 114     fi ;;
 115 esac
 116
 117 dnl **** Check for some programs ****
 118
 119 AC_PROG_MAKE_SET
 120 AC_PROG_CC
 121 AC_PROG_CXX
 122 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 123 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 124
 125 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 126   [if test -z "$with_wine_tools"; then
 127      if test "$cross_compiling" = "yes"; then
 128        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 129      else
 130        wine_cv_toolsdir="\$(TOPOBJDIR)"
 131      fi
 132    elif test -d "$with_wine_tools/tools/winebuild"; then
 133      case $with_wine_tools in
 134        /*) wine_cv_toolsdir="$with_wine_tools" ;;
 135        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
 136      esac
 137    else
 138      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
 139    fi])
 140 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 141
 142 AC_PATH_XTRA
 143
 144 dnl Check for flex
 145 AC_CHECK_PROGS(FLEX,flex,none)
 146 if test "$FLEX" = "none"
 147 then
 148   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 149 fi
 150
 151 dnl Check for bison
 152 AC_CHECK_PROGS(BISON,bison,none)
 153 if test "$BISON" = "none"
 154 then
 155   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 156 fi
 157
 158 AC_CHECK_TOOLS(AS,[gas as],as)
 159 AC_CHECK_TOOL(LD,ld,ld)
 160 AC_CHECK_TOOL(AR,ar,ar)
 161 AC_PROG_RANLIB
 162 AC_CHECK_TOOL(STRIP,strip,strip)
 163 AC_CHECK_TOOL(WINDRES,windres,false)
 164 AC_PROG_LN_S
 165 WINE_PROG_LN
 166 AC_PROG_EGREP
 167 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 168 AC_PROG_INSTALL
 169 dnl Prepend src dir to install path dir if it's a relative path
 170 case "$INSTALL" in
 171   [[\\/$]]* | ?:[[\\/]]* ) ;;
 172   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 173 esac
 174
 175 dnl Check for lint
 176 AC_CHECK_PROGS(LINT, lclint lint)
 177 if test "$LINT" = "lint"
 178 then
 179   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 180   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 181 fi
 182 AC_SUBST(LINT)
 183 AC_SUBST(LINTFLAGS)
 184
 185 dnl Check for various programs
 186 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 187 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 188
 189 case $host_cpu in
 190   *i[[3456789]]86*)
 191     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 192     ;;
 193 esac
 194
 195 dnl **** Check for some libraries ****
 196
 197 dnl Check for -li386 for NetBSD and OpenBSD
 198 AC_CHECK_LIB(i386,i386_set_ldt)
 199 dnl Check for -lossaudio for NetBSD
 200 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 201 dnl Check for -lpthread
 202 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 203
 204 AC_SUBST(XLIB,"")
 205 AC_SUBST(XFILES,"")
 206 AC_SUBST(OPENGLFILES,"")
 207 AC_SUBST(GLU32FILES,"")
 208 AC_SUBST(OPENGL_LIBS,"")
 209 AC_SUBST(QUARTZFILES,"")
 210
 211 dnl **** Check for header files ****
 212
 213 AC_CHECK_HEADERS(\
 214         AudioUnit/AudioUnit.h \
 215         Carbon/Carbon.h \
 216         CoreAudio/CoreAudio.h \
 217         DiskArbitration/DiskArbitration.h \
 218         IOKit/IOKitLib.h \
 219         alsa/asoundlib.h \
 220         arpa/inet.h \
 221         arpa/nameser.h \
 222         asm/types.h \
 223         capi20.h \
 224         cups/cups.h \
 225         curses.h \
 226         direct.h \
 227         dlfcn.h \
 228         elf.h \
 229         float.h \
 230         fontconfig/fontconfig.h \
 231         getopt.h \
 232         ieeefp.h \
 233         io.h \
 234         jack/jack.h \
 235         jpeglib.h \
 236         lber.h \
 237         lcms.h \
 238         lcms/lcms.h \
 239         ldap.h \
 240         libaudioio.h \
 241         link.h \
 242         linux/cdrom.h \
 243         linux/compiler.h \
 244         linux/hdreg.h \
 245         linux/input.h \
 246         linux/ioctl.h \
 247         linux/joystick.h \
 248         linux/major.h \
 249         linux/param.h \
 250         linux/serial.h \
 251         linux/ucdrom.h \
 252         mach/mach.h \
 253         mach/machine.h \
 254         machine/cpu.h \
 255         machine/limits.h \
 256         machine/soundcard.h \
 257         mntent.h \
 258         ncurses.h \
 259         netdb.h \
 260         netinet/in.h \
 261         netinet/in_systm.h \
 262         netinet/tcp.h \
 263         netinet/tcp_fsm.h \
 264         openssl/err.h \
 265         openssl/ssl.h \
 266         png.h \
 267         poll.h \
 268         process.h \
 269         pthread.h \
 270         pwd.h \
 271         regex.h \
 272         sched.h \
 273         scsi/scsi.h \
 274         scsi/scsi_ioctl.h \
 275         scsi/sg.h \
 276         soundcard.h \
 277         stdint.h \
 278         strings.h \
 279         sys/asoundlib.h \
 280         sys/cdio.h \
 281         sys/elf32.h \
 282         sys/epoll.h \
 283         sys/errno.h \
 284         sys/event.h \
 285         sys/exec_elf.h \
 286         sys/filio.h \
 287         sys/ioctl.h \
 288         sys/ipc.h \
 289         sys/limits.h \
 290         sys/link.h \
 291         sys/lwp.h \
 292         sys/mman.h \
 293         sys/modem.h \
 294         sys/msg.h \
 295         sys/mtio.h \
 296         sys/param.h \
 297         sys/poll.h \
 298         sys/prctl.h \
 299         sys/ptrace.h \
 300         sys/reg.h \
 301         sys/resource.h \
 302         sys/scsiio.h \
 303         sys/shm.h \
 304         sys/signal.h \
 305         sys/socket.h \
 306         sys/socketvar.h \
 307         sys/sockio.h \
 308         sys/soundcard.h \
 309         sys/statvfs.h \
 310         sys/strtio.h \
 311         sys/syscall.h \
 312         sys/sysctl.h \
 313         sys/time.h \
 314         sys/times.h \
 315         sys/uio.h \
 316         sys/un.h \
 317         sys/vm86.h \
 318         sys/wait.h \
 319         syscall.h \
 320         termios.h \
 321         unistd.h \
 322         utime.h \
 323         valgrind/memcheck.h
 324 )
 325 AC_HEADER_STAT()
 326
 327 dnl **** Checks for headers that depend on other ones ****
 328
 329 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 330     [#include <sys/types.h>
 331      #if HAVE_SYS_PARAM_H
 332      # include <sys/param.h>
 333      #endif])
 334
 335 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 336     [#include <sys/types.h>
 337      #if HAVE_SYS_SOCKET_H
 338      # include <sys/socket.h>
 339      #endif
 340      #if HAVE_SYS_SOCKETVAR_H
 341      # include <sys/socketvar.h>
 342      #endif
 343      #if HAVE_NETINET_IN_H
 344      # include <netinet/in.h>
 345      #endif])
 346
 347 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 348     [#include <sys/types.h>
 349      #if HAVE_SYS_SOCKET_H
 350      # include <sys/socket.h>
 351      #endif
 352      #if HAVE_SYS_SOCKETVAR_H
 353      # include <sys/socketvar.h>
 354      #endif
 355      #if HAVE_NETINET_IN_H
 356      # include <netinet/in.h>
 357      #endif
 358      #ifdef HAVE_NETINET_TCP_H
 359      # include <netinet/tcp.h>
 360      #endif])
 361
 362 AC_CHECK_HEADERS([linux/ipx.h],,,
 363     [#include <sys/types.h>
 364      #ifdef HAVE_ASM_TYPES_H
 365      # include <asm/types.h>
 366      #endif
 367      #if HAVE_SYS_SOCKET_H
 368      # include <sys/socket.h>
 369      #endif])
 370
 371 AC_CHECK_HEADERS([resolv.h],,,
 372     [#include <sys/types.h>
 373      #if HAVE_SYS_SOCKET_H
 374      # include <sys/socket.h>
 375      #endif
 376      #if HAVE_NETINET_IN_H
 377      # include <netinet/in.h>
 378      #endif
 379      #if HAVE_ARPA_NAMESER_H
 380      # include <arpa/nameser.h>
 381      #endif])
 382
 383 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 384
 385 AC_CHECK_HEADERS([sys/thr.h],,,
 386 [#include <sys/types.h>
 387 #if HAVE_UCONTEXT_H
 388 #include <ucontext.h>
 389 #endif])
 390
 391 AC_CHECK_HEADERS([pthread_np.h],,,
 392 [#ifdef HAVE_PTHREAD_H
 393 #include <pthread.h>
 394 #endif])
 395
 396 AC_CHECK_HEADERS([linux/videodev.h],,,
 397 [#ifdef HAVE_SYS_TIME_H
 398 #include <sys/time.h>
 399 #endif
 400 #include <sys/types.h>
 401 #ifdef HAVE_ASM_TYPES_H
 402 #include <asm/types.h>
 403 #endif])
 404
 405 dnl Check for broken kernel header that doesn't define __user
 406 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 407
 408 dnl **** Check for working dll ****
 409
 410 AC_SUBST(DLLEXT,"")
 411 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 412 AC_SUBST(LDSHARED,"")
 413 AC_SUBST(LDDLLFLAGS,"")
 414 AC_SUBST(LIBEXT,"so")
 415 AC_SUBST(IMPLIBEXT,"def")
 416 AC_SUBST(LDRPATH_INSTALL,"")
 417 AC_SUBST(LDRPATH_LOCAL,"")
 418 WINE_PATH_LDD
 419
 420 case $host_os in
 421   cygwin*|mingw32*)
 422     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 423     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 424     AC_CHECK_TOOL(MINGWAR,ar,false)
 425     if test "$DLLWRAP" = "false"; then
 426       LIBEXT="a"
 427     else
 428       dnl FIXME - check whether dllwrap works correctly...
 429       LIBEXT="dll"
 430     fi
 431     IMPLIBEXT="a"
 432     dnl We can't build 16-bit NE dlls
 433     WIN16_FILES=""
 434     WIN16_INSTALL=""
 435     ;;
 436   darwin*|macosx*)
 437     DLLEXT=".so"
 438     LIBEXT="dylib"
 439     DLLFLAGS="$DLLFLAGS -fPIC"
 440     LDDLLFLAGS="-bundle -multiply_defined suppress"
 441     LIBWINE_LDFLAGS="-multiply_defined suppress"
 442     LDSHARED="\$(CC) -dynamiclib"
 443     STRIP="$STRIP -x"
 444     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 445     dnl declare needed frameworks
 446     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 447     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 448     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 449     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 450     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 451     then
 452         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 453         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 454     fi
 455     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 456     then
 457         dnl CoreServices needed by AudioUnit
 458         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 459     fi
 460     case $host_cpu in
 461       *powerpc*)
 462         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 463         ;;
 464     esac
 465     dnl Enable quartz driver on Mac OS X
 466     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 467     then
 468         AC_SUBST(CARBONLIB,"-framework Carbon")
 469         QUARTZFILES='$(QUARTZFILES)'
 470     fi
 471     ;;
 472   *)
 473     DLLFLAGS="$DLLFLAGS -fPIC"
 474     DLLEXT=".so"
 475     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 476         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 477                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 478     if test "$ac_cv_c_dll_gnuelf" = "yes"
 479     then
 480       LDSHARED="\$(CC) -shared"
 481       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 482       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 483                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 484                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 485                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 486
 487       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 488
 489       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 490                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 491
 492       echo '{ global: *; };' >conftest.map
 493       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 494                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 495       rm -f conftest.map
 496
 497       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 498                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 499
 500       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 501                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 502                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 503           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 504                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 505                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 506
 507       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 508                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 509
 510       case $host_cpu in
 511         *i[[3456789]]86* | x86_64)
 512           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 513                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 514           ;;
 515       esac
 516
 517     else
 518       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 519           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 520                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 521       if test "$ac_cv_c_dll_unixware" = "yes"
 522       then
 523         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 524         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 525
 526       else
 527         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 528           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 529         if test "$ac_cv_c_dll_hpux" = "yes"
 530         then
 531           LIBEXT="sl"
 532           DLLEXT=".sl"
 533           LDDLLFLAGS="-shared -fPIC"
 534           LDSHARED="\$(CC) -shared"
 535         fi
 536       fi
 537     fi
 538
 539     dnl Check for cross compiler to build test programs
 540     AC_SUBST(CROSSTEST,"")
 541     if test "$cross_compiling" = "no"
 542     then
 543       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 544       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 545       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 546       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 547       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 548     fi
 549     ;;
 550 esac
 551
 552 if test "$LIBEXT" = "a"; then
 553   AC_MSG_ERROR(
 554 [could not find a way to build shared libraries.
 555 It is currently not possible to build Wine without shared library
 556 (.so) support to allow transparent switch between .so and .dll files.
 557 If you are using Linux, you will need a newer binutils.]
 558 )
 559 fi
 560
 561 dnl **** Check for X11 ****
 562
 563 if test "$have_x" = "yes"
 564 then
 565     XLIB="-lXext -lX11"
 566     ac_save_CPPFLAGS="$CPPFLAGS"
 567     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 568
 569     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 570     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 571
 572     dnl *** All of the following tests require X11/Xlib.h
 573     AC_CHECK_HEADERS([X11/Xlib.h \
 574                       X11/XKBlib.h \
 575                       X11/Xutil.h \
 576                       X11/Xcursor/Xcursor.h \
 577                       X11/extensions/shape.h \
 578                       X11/extensions/XInput.h \
 579                       X11/extensions/XShm.h \
 580                       X11/extensions/Xcomposite.h \
 581                       X11/extensions/Xinerama.h \
 582                       X11/extensions/Xrandr.h \
 583                       X11/extensions/Xrender.h \
 584                       X11/extensions/xf86vmode.h],,,
 585 [#ifdef HAVE_X11_XLIB_H
 586 # include <X11/Xlib.h>
 587 #endif
 588 #ifdef HAVE_X11_XUTIL_H
 589 # include <X11/Xutil.h>
 590 #endif])
 591
 592         dnl *** Check for X keyboard extension
 593         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 594         then
 595               AC_CHECK_LIB(X11, XkbQueryExtension,
 596               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 597               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 598         fi
 599
 600         dnl *** Check for X cursor
 601         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 602         then
 603             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 604         fi
 605         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 606                          [libxcursor development files not found, the Xcursor extension won't be supported.])
 607
 608         dnl *** Check for X input extension
 609         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 610         then
 611             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 612         fi
 613         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 614                          [libxi development files not found, the Xinput extension won't be supported.])
 615
 616         dnl *** Check for X Shm extension
 617         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 618         then
 619               AC_CHECK_LIB(Xext, XShmQueryExtension,
 620               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 621               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 622         fi
 623         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 624                          [XShm development files not found, X Shared Memory won't be supported.])
 625
 626         dnl *** Check for X shape extension
 627         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 628         then
 629               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 630               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 631               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 632         fi
 633         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 634                          [XShape development files not found, XShape won't be supported.])
 635
 636         dnl *** Check for XFree86 VMODE extension
 637         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 638         then
 639                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 640                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 641                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 642                   ],,
 643                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 644         fi
 645         WINE_NOTICE_WITH(xvidmode,[test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],
 646                          [libxxf86vm development files not found, XFree86 Vidmode won't be supported.])
 647
 648         dnl *** Check for Transform functions in Xrender
 649         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 650         then
 651             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 652               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 653                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 654                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 655                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 656
 657         fi
 658         WINE_NOTICE_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 659                          [libxrender development files not found, XRender won't be supported.])
 660
 661         dnl *** Check for X RandR extension
 662         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 663         then
 664                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 665 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 666                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 667         fi
 668         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 669                          [libxrandr development files not found, XRandr won't be supported.])
 670
 671         dnl *** Check for Xinerama extension
 672         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 673         then
 674                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 675 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 676                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 677         fi
 678         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 679                          [libxinerama development files not found, multi-monitor setups won't be supported.])
 680
 681         dnl *** Check for X Composite extension
 682         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 683         then
 684             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 685         fi
 686         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 687                          [libxcomposite development files not found, Xcomposite won't be supported.])
 688
 689     dnl *** End of X11/Xlib.h check
 690
 691     dnl Check for the presence of OpenGL
 692     opengl_msg=""
 693     if test "x$with_opengl" != "xno"
 694     then
 695         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 696 [#ifdef HAVE_GL_GLX_H
 697 # include <GL/glx.h>
 698 #endif])
 699         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 700         then
 701             dnl Check for some problems due to old Mesa versions
 702             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 703               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 704                 [wine_cv_opengl_header_version_OK="yes"],
 705                 [wine_cv_opengl_header_version_OK="no"]))
 706
 707             if test "$wine_cv_opengl_header_version_OK" = "yes"
 708             then
 709                 dnl Check for the presence of the library
 710                 WINE_CHECK_SONAME(GL,glXCreateContext,
 711                              [OPENGL_LIBS="-lGL"
 712                              OPENGLFILES='$(OPENGLFILES)'
 713                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 714                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 715                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 716                                     OPENGLFILES='$(OPENGLFILES)'
 717                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 718                                     [if test -f /usr/X11R6/lib/libGL.a
 719                                     then
 720                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
 721 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
 722                                     else
 723                                         opengl_msg="No OpenGL library found on this system."
 724                                     fi],
 725                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 726                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 727
 728                 dnl Check for GLU32 library.
 729                 AC_CHECK_LIB(GLU,gluLookAt,
 730                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 731                              GLU32FILES='$(GLU32FILES)']
 732                              ,,
 733                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 734              else
 735                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
 736              fi
 737          else
 738              opengl_msg="OpenGL development headers not found."
 739          fi
 740     fi
 741     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
 742 OpenGL and Direct3D won't be supported.])
 743
 744     dnl **** Check for NAS ****
 745     AC_SUBST(NASLIBS,"")
 746     AC_CHECK_HEADERS(audio/audiolib.h,
 747          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 748           AC_CHECK_LIB(audio,AuCreateFlow,
 749                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 750                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 751                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 752                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 753                           [$X_LIBS])
 754                        ],,
 755                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 756
 757     CPPFLAGS="$ac_save_CPPFLAGS"
 758     XFILES='$(XFILES)'
 759 else
 760     XLIB=""
 761     X_CFLAGS=""
 762     X_LIBS=""
 763 fi
 764 WINE_WARNING_WITH(x,[test "x$XLIB" = "x"],[X development files not found. Wine will be built
 765 without X support, which probably isn't what you want. You will need to install
 766 development packages of Xlib/Xfree86 at the very least.])
 767
 768 dnl **** Check for libxml2 ****
 769
 770 AC_SUBST(XML2LIBS,"")
 771 AC_SUBST(XML2INCL,"")
 772 AC_SUBST(XSLTLIBS,"")
 773 AC_SUBST(XSLTINCL,"")
 774 if test "x$with_xml" != "xno"
 775 then
 776     ac_save_CPPFLAGS="$CPPFLAGS"
 777     if test "$PKG_CONFIG" != "false"
 778     then
 779         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 780         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 781     else
 782         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 783         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 784     fi
 785     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 786     AC_CHECK_HEADERS(libxml/parser.h,
 787             [AC_CHECK_LIB(xml2, xmlParseMemory,
 788                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 789                  XML2LIBS="$ac_xml_libs"
 790                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 791              AC_CHECK_LIB(xml2, xmlReadMemory,
 792                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 793              AC_CHECK_LIB(xml2, xmlNewDocPI,
 794                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 795         ])
 796     CPPFLAGS="$ac_save_CPPFLAGS"
 797 fi
 798 WINE_NOTICE_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
 799                  [libxml2 development files not found, XML won't be supported.])
 800
 801 if test "x$with_xslt" != "xno"
 802 then
 803     if test "$PKG_CONFIG" != "false"
 804     then
 805         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 806         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 807     else
 808         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 809         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 810     fi
 811     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 812     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 813             [AC_CHECK_LIB(xslt, xsltCompilePattern,
 814                 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 815                  XSLTLIBS="$ac_xslt_libs"
 816                  XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 817             ],,
 818     [#ifdef HAVE_LIBXSLT_PATTERN_H
 819 # include <libxslt/pattern.h>
 820 #endif])
 821     CPPFLAGS="$ac_save_CPPFLAGS"
 822 fi
 823 WINE_NOTICE_WITH(xslt,[test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],
 824                  [libxslt development files not found, xslt won't be supported.])
 825
 826 dnl **** Check for libhal ****
 827 AC_SUBST(HALINCL,"")
 828 if test "x$with_hal" != "xno" -a "$PKG_CONFIG" != "false"
 829 then
 830     ac_save_CPPFLAGS="$CPPFLAGS"
 831     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 832     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 833     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 834     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 835     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 836     then
 837         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 838           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 839             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 840     fi
 841     CPPFLAGS="$ac_save_CPPFLAGS"
 842 fi
 843 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
 844                  [libhal development files not found, no dynamic device support.])
 845
 846 dnl **** Check which curses lib to use ***
 847 CURSESLIBS=""
 848 if test "$ac_cv_header_ncurses_h" = "yes"
 849 then
 850     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 851 elif test "$ac_cv_header_curses_h" = "yes"
 852 then
 853     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 854 fi
 855 ac_save_LIBS="$LIBS"
 856 LIBS="$LIBS $CURSESLIBS"
 857 AC_CHECK_FUNCS(mousemask)
 858 LIBS="$ac_save_LIBS"
 859 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
 860                  [lib(n)curses development files not found, curses won't be supported.])
 861
 862 dnl **** Check for SANE ****
 863 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 864 if test "$sane_devel" != "no" -a "x$with_sane" != "xno"
 865 then
 866     ac_sane_incl="`$sane_devel --cflags`"
 867     ac_save_CPPFLAGS="$CPPFLAGS"
 868     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 869     AC_CHECK_HEADER(sane/sane.h,
 870         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 871     CPPFLAGS="$ac_save_CPPFLAGS"
 872 fi
 873 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
 874                  [libsane development files not found, scanners won't be supported.])
 875
 876 dnl **** Check for libgphoto2 ****
 877 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 878 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 879 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no" -a "x$with_gphoto" != "xno"
 880 then
 881     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 882     ac_gphoto2_libs=""
 883     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 884     do
 885       case "$i" in
 886         -L/usr/lib|-L/usr/lib64) ;;
 887         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 888       esac
 889     done
 890     ac_save_CPPFLAGS="$CPPFLAGS"
 891     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 892     AC_CHECK_HEADER(gphoto2-camera.h,
 893                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 894                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 895                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 896                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 897                                   [$GPHOTO2LIBS])])
 898     CPPFLAGS="$ac_save_CPPFLAGS"
 899 fi
 900 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
 901                  [libgphoto2 development files not found, digital cameras won't be supported.])
 902
 903
 904 dnl **** Check for resolver library ***
 905 AC_SUBST(RESOLVLIBS,"")
 906 if test "$ac_cv_header_resolv_h" = "yes"
 907 then
 908     AC_CHECK_LIB(resolv, res_query,
 909         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 910          RESOLVLIBS="-lresolv"])
 911 fi
 912
 913 dnl **** Check for LittleCMS ***
 914 AC_SUBST(LCMSLIBS,"")
 915 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 916 then
 917     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 918         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 919          LCMSLIBS="-llcms"])
 920 fi
 921 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
 922                  [liblcms development files not found, Color Management won't be supported.])
 923
 924 dnl **** Check for OpenLDAP ***
 925 AC_SUBST(LDAPLIBS,"")
 926 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 927 then
 928     AC_CHECK_LIB(ldap_r, ldap_initialize,
 929         [AC_CHECK_LIB(lber, ber_init,
 930             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 931              LDAPLIBS="-lldap_r -llber"],,
 932              [$LIBPTHREAD])],,
 933              [$LIBPTHREAD])
 934     WINE_CHECK_LIB_FUNCS(\
 935         ldap_count_references \
 936         ldap_first_reference \
 937         ldap_next_reference \
 938         ldap_parse_reference \
 939         ldap_parse_sort_control \
 940         ldap_parse_sortresponse_control \
 941         ldap_parse_vlv_control \
 942         ldap_parse_vlvresponse_control,
 943         [$LDAPLIBS $LIBPTHREAD])
 944 fi
 945 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
 946                  [libldap (OpenLDAP) development files not found, LDAP won't be supported.])
 947
 948 dnl **** Check for FreeType 2 ****
 949 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 950 if test "$ft_devel" != "false"
 951 then
 952     ac_freetype_libs=`$ft_devel --libs`
 953     ac_freetype_incl=`$ft_devel --cflags`
 954     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 955     if test "$ft_lib" = "yes"
 956     then
 957         ac_save_CPPFLAGS="$CPPFLAGS"
 958         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 959         AC_CHECK_HEADERS(ft2build.h \
 960                          freetype/freetype.h \
 961                          freetype/ftglyph.h \
 962                          freetype/fttypes.h \
 963                          freetype/tttables.h \
 964                          freetype/ftnames.h \
 965                          freetype/ftsnames.h \
 966                          freetype/ttnameid.h \
 967                          freetype/ftoutln.h \
 968                          freetype/ftwinfnt.h \
 969                          freetype/ftmodapi.h \
 970                          freetype/internal/sfnt.h,,,
 971                          [#if HAVE_FT2BUILD_H
 972                           #include <ft2build.h>
 973                           #endif])
 974         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 975                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 976           [Define if you have the <freetype/fttrigon.h> header file.])
 977                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 978         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 979         ac_save_CFLAGS="$CFLAGS"
 980         CFLAGS="$CFLAGS $ac_freetype_libs"
 981         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 982         CFLAGS="$ac_save_CFLAGS"
 983         CPPFLAGS="$ac_save_CPPFLAGS"
 984         dnl Check that we have at least freetype/freetype.h
 985         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 986         then
 987             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 988             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
 989             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
 990         fi
 991     fi
 992 fi
 993
 994 dnl Only build the fonts dir if we have both freetype and fontforge
 995 if test "$FONTFORGE" = "false"
 996 then
 997     WINE_WARNING([FontForge is missing.
 998 Fonts will not be built. Dialog text may be invisible or unaligned.])
 999 elif test "x$FREETYPELIBS" = "x"
1000 then
1001     WINE_WARNING([FreeType development files not found.
1002 Fonts will not be built. Dialog text may be invisible or unaligned.])
1003 else
1004   AC_SUBST(FONTSSUBDIRS,"fonts")
1005 fi
1006
1007 dnl **** Check for parport (currently Linux only) ****
1008 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1009  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1010     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1011 if test "$ac_cv_c_ppdev" = "yes"
1012 then
1013     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1014 fi
1015
1016 dnl **** Check for va_copy ****
1017 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
1018  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
1019     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
1020  )
1021 if test "$ac_cv_c_va_copy" = "yes"
1022 then
1023     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
1024 fi
1025 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
1026  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
1027     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
1028  )
1029 if test "$ac_cv_c___va_copy" = "yes"
1030 then
1031     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
1032 fi
1033
1034 dnl **** Check for sigsetjmp ****
1035 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
1036  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
1037     sigsetjmp( buf, 1 );
1038     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
1039  )
1040 if test "$ac_cv_c_sigsetjmp" = "yes"
1041 then
1042     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
1043 fi
1044
1045 dnl **** Check for pthread_rwlock_t ****
1046 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
1047 #include <pthread.h>])
1048
1049 dnl **** Check for pthread functions ****
1050 WINE_CHECK_LIB_FUNCS(\
1051         pthread_attr_get_np \
1052         pthread_getattr_np \
1053         pthread_get_stackaddr_np \
1054         pthread_get_stacksize_np,
1055         [$LIBPTHREAD])
1056
1057 dnl **** Check for EsounD ****
1058 AC_PATH_PROG(ESDCONFIG, esd-config)
1059 if test "x$with_esd" != xno -a "x$ESDCONFIG" != x -a "x$ESDCONFIG" != x'"$ESDCONFIG"';
1060 then
1061     ESD_CFLAGS=""
1062     for i in `$ESDCONFIG --cflags`
1063     do
1064       case "$i" in
1065         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
1066       esac
1067     done
1068     ESD_LIBS=`$ESDCONFIG --libs`
1069     save_CFLAGS="$CFLAGS"
1070     CFLAGS="$CFLAGS $ESD_CFLAGS"
1071     AC_CHECK_LIB(esd,esd_open_sound,
1072         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1073          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1074          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1075     CFLAGS="$save_CFLAGS"
1076 fi
1077
1078 dnl **** Check for ALSA 1.x ****
1079 AC_SUBST(ALSALIBS,"")
1080 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1081 then
1082     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1083         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1084 #include <alsa/asoundlib.h>
1085 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1086 #include <sys/asoundlib.h>
1087 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1088                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1089                          ALSALIBS="-lasound"],[])])
1090 fi
1091
1092 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1093 AC_SUBST(AUDIOIOLIBS,"")
1094 if test "$ac_cv_header_libaudioio_h" = "yes"
1095 then
1096     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1097                   [AUDIOIOLIBS="-laudioio"
1098                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1099 fi
1100
1101 dnl **** Check for capi4linux ****
1102
1103 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1104 then
1105     WINE_CHECK_SONAME(capi20,capi20_register)
1106 fi
1107 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1108                  [libcapi20 development files not found, ISDN won't be supported.])
1109
1110 dnl **** Check for cups ****
1111 if test "$ac_cv_header_cups_cups_h" = "yes"
1112 then
1113     WINE_CHECK_SONAME(cups,cupsGetDefault)
1114 fi
1115 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1116                  [libcups development files not found, CUPS won't be supported.])
1117
1118 dnl **** Check for jack ****
1119 if test "$ac_cv_header_jack_jack_h" = "yes"
1120 then
1121     WINE_CHECK_SONAME(jack,jack_client_new)
1122 fi
1123
1124 dnl **** Check for fontconfig ****
1125 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1126 then
1127     WINE_CHECK_SONAME(fontconfig,FcInit)
1128 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1129 then
1130     dnl fontconfig is in the X directory on Mac OS X
1131     ac_save_CPPFLAGS="$CPPFLAGS"
1132     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1133     $as_unset ac_cv_header_fontconfig_fontconfig_h
1134     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1135     CPPFLAGS="$ac_save_CPPFLAGS"
1136     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1137     then
1138         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1139         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1140     fi
1141 fi
1142 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1143                  [fontconfig development files not found, fontconfig won't be supported.])
1144
1145 dnl **** Check for SSL ****
1146 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1147 then
1148     WINE_CHECK_SONAME(ssl,SSL_library_init)
1149     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1150 fi
1151 WINE_NOTICE_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x"],
1152                  [OpenSSL development files not found, SSL won't be supported.])
1153
1154 dnl **** Check for libjpeg ****
1155 if test "$ac_cv_header_jpeglib_h" = "yes"
1156 then
1157     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1158 fi
1159 WINE_NOTICE_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1160                  [libjpeg development files not found, JPEG won't be supported.])
1161
1162 dnl **** Check for libpng ****
1163 if test "$ac_cv_header_png_h" = "yes"
1164 then
1165     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1166 fi
1167 WINE_NOTICE_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1168                  [libpng development files not found, PNG won't be supported.])
1169
1170 dnl **** Check for libodbc ****
1171 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1172
1173 dnl **** Check for any sound system ****
1174 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1175         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1176         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1177         "$ac_cv_header_soundcard_h" != "yes" -a \
1178         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1179 then
1180     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1181 fi
1182
1183 dnl **** Check for gcc specific options ****
1184
1185 AC_SUBST(EXTRACFLAGS,"")
1186 if test "x${GCC}" = "xyes"
1187 then
1188   EXTRACFLAGS="-Wall -pipe"
1189
1190   dnl Check for strength-reduce bug
1191   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1192                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1193 [[static int Array[[3]];
1194   unsigned int B = 3;
1195   int i;
1196   for(i=0; i<B; i++) Array[[i]] = i - 3;
1197   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1198   L[[i]] = 4;
1199   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1200     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1201   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1202   then
1203     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1204   fi
1205
1206   dnl Check for some compiler flags
1207
1208   WINE_TRY_CFLAGS([-fshort-wchar],
1209                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1210                              [Specifies the compiler flag that forces a short wchar_t])])
1211   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1212   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1213   WINE_TRY_CFLAGS([-Wwrite-strings])
1214   WINE_TRY_CFLAGS([-Wtype-limits])
1215
1216   dnl Check for noisy string.h
1217   saved_CFLAGS="$CFLAGS"
1218   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1219   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1220       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1221   CFLAGS="$saved_CFLAGS"
1222   if test "$ac_cv_c_string_h_warnings" = "no"
1223   then
1224     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1225   fi
1226
1227   AC_SUBST(BUILTINFLAG,"")
1228   saved_CFLAGS="$CFLAGS"
1229   CFLAGS="$CFLAGS -Werror"
1230   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1231       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1232   CFLAGS="$saved_CFLAGS"
1233   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1234   then
1235     BUILTINFLAG="-fno-builtin"
1236   fi
1237 fi
1238
1239 dnl **** Check how to define a function in assembly code ****
1240
1241 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1242   WINE_TRY_ASM_LINK(
1243       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1244       ac_cv_asm_func_def=".def",
1245     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1246       ac_cv_asm_func_def=".type @function",
1247     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1248       ac_cv_asm_func_def=".type 2",
1249       ac_cv_asm_func_def="unknown")])]))
1250
1251 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1252 case "$ac_cv_asm_func_def" in
1253   ".def")
1254      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1255   ".type @function")
1256      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1257   ".type 2")
1258      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1259   *)
1260      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1261 esac
1262
1263 dnl **** Check for underscore on external symbols ****
1264
1265 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1266     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1267                       [extern int ac_test;],
1268                       [if (ac_test) return 1],
1269                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1270
1271 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1272 if test "$ac_cv_c_extern_prefix" = "yes"
1273 then
1274   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1275 else
1276   AC_DEFINE([__ASM_NAME(name)], [name])
1277 fi
1278
1279 dnl **** Platform-specific checks ****
1280
1281 AC_SUBST(LDPATH,"")
1282 case $build_os in
1283   cygwin*|mingw32*)
1284     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1285     ;;
1286   darwin*|macosx*)
1287     ;;
1288   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1289     if test -z "$LDRPATH_LOCAL"
1290     then
1291       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1292     fi
1293     ;;
1294   *)
1295     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1296     ;;
1297 esac
1298
1299 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1300 case $host_os in
1301   mingw32*)
1302     AC_SUBST(CRTLIBS,"-lmsvcrt")
1303     AC_SUBST(SOCKETLIBS,"-lws2_32")
1304     ;;
1305 esac
1306
1307 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1308 case $host_cpu in
1309   *i[[3456789]]86*)
1310     case $host_os in
1311       linux* | k*bsd*-gnu)
1312         AC_SUBST(MAIN_BINARY,"wine-glibc")
1313         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1314       freebsd*)
1315         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1316         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1317     esac
1318     ;;
1319 esac
1320
1321 dnl **** Check for functions ****
1322
1323 AC_CHECK_FUNCS(\
1324         _pclose \
1325         _popen \
1326         _snprintf \
1327         _spawnvp \
1328         _strdup \
1329         _stricmp \
1330         _strnicmp \
1331         _vsnprintf \
1332         asctime_r \
1333         chsize \
1334         clone \
1335         dlopen \
1336         epoll_create \
1337         ffs \
1338         finite \
1339         fork \
1340         fpclass \
1341         fstatfs \
1342         fstatvfs \
1343         ftruncate \
1344         futimes \
1345         futimesat \
1346         getdirentries \
1347         getopt_long \
1348         getpagesize \
1349         getpwuid \
1350         gettid \
1351         gettimeofday \
1352         getuid \
1353         inet_pton \
1354         kqueue \
1355         lstat \
1356         memmove \
1357         mmap \
1358         pclose \
1359         poll \
1360         popen \
1361         prctl \
1362         pread \
1363         pwrite \
1364         readlink \
1365         rfork \
1366         sched_yield \
1367         select \
1368         setproctitle \
1369         setrlimit \
1370         settimeofday \
1371         sigaltstack \
1372         sigprocmask \
1373         snprintf \
1374         spawnvp \
1375         statfs \
1376         statvfs \
1377         strcasecmp \
1378         strdup \
1379         strerror \
1380         strncasecmp \
1381         strtold \
1382         tcgetattr \
1383         thr_kill2 \
1384         timegm \
1385         usleep \
1386         vsnprintf \
1387         wait4 \
1388         waitpid \
1389 )
1390
1391 dnl Check for -ldl
1392 if test "$ac_cv_func_dlopen" = no
1393 then
1394     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1395 fi
1396 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1397
1398 dnl Check for -lpoll for Mac OS X/Darwin
1399 if test "$ac_cv_func_poll" = no
1400 then
1401     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1402 fi
1403
1404 dnl Check for -lnsl for Solaris
1405 AC_SEARCH_LIBS(gethostbyname, nsl)
1406
1407 dnl Check for -lsocket for Solaris
1408 AC_SEARCH_LIBS(connect, socket)
1409
1410 dnl Check for -lresolv for Solaris
1411 AC_SEARCH_LIBS(inet_aton, resolv)
1412
1413 dnl **** Check for functions which may rely on -lsocket on Solaris.
1414 AC_CHECK_FUNCS(\
1415         getaddrinfo \
1416         getnameinfo \
1417         getnetbyname \
1418         getprotobyname \
1419         getprotobynumber \
1420         getservbyport \
1421         inet_network \
1422         sendmsg \
1423 )
1424
1425 dnl **** Check for types ****
1426
1427 AC_C_CONST
1428 AC_C_INLINE
1429 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1430 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1431 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1432
1433 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1434 [#ifdef HAVE_LINUX_INPUT_H
1435 #include <linux/input.h>
1436 #endif])
1437
1438 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1439                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1440 if test "$wine_cv_have_sigaddset" = "yes"
1441 then
1442   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1443 fi
1444
1445
1446 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1447         wine_cv_linux_gethostbyname_r_6,
1448         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1449     char *name=0;
1450     struct hostent he;
1451     struct hostent *result;
1452     char *buf=0;
1453     int bufsize=0;
1454     int res,errnr;
1455     char *addr=0;
1456     int addrlen=0;
1457     int addrtype=0;
1458     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1459     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1460     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1461         ])
1462    )
1463    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1464    then
1465       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1466                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1467    fi
1468
1469 if test "$ac_cv_header_linux_joystick_h" = "yes"
1470 then
1471    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1472         wine_cv_linux_joystick_22_api,
1473         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1474         #include <sys/ioctl.h>
1475         #include <sys/types.h>
1476         #include <linux/joystick.h>
1477
1478         struct js_event blub;
1479         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1480         #error "no 2.2 header"
1481         #endif
1482         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1483    )
1484    if test "$wine_cv_linux_joystick_22_api" = "yes"
1485    then
1486       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1487                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1488    fi
1489 fi
1490
1491 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1492
1493 dnl Check for statfs members
1494 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1495 [#include <sys/types.h>
1496 #ifdef HAVE_SYS_PARAM_H
1497 # include <sys/param.h>
1498 #endif
1499 #ifdef HAVE_SYS_MOUNT_H
1500 # include <sys/mount.h>
1501 #endif
1502 #ifdef HAVE_SYS_VFS_H
1503 # include <sys/vfs.h>
1504 #endif
1505 #ifdef HAVE_SYS_STATFS_H
1506 # include <sys/statfs.h>
1507 #endif])
1508
1509 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1510 [#ifdef HAVE_SYS_STATVFS_H
1511 #include <sys/statvfs.h>
1512 #endif])
1513
1514 dnl Check for socket structure members
1515 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1516 [#include <sys/types.h>
1517 #ifdef HAVE_SYS_SOCKET_H
1518 # include <sys/socket.h>
1519 #endif
1520 #ifdef HAVE_SYS_UN_H
1521 # include <sys/un.h>
1522 #endif])
1523
1524 dnl Check for scsireq_t and sg_io_hdr_t members
1525 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1526 [#include <sys/types.h>
1527 #ifdef HAVE_SCSI_SG_H
1528 #include <scsi/sg.h>
1529 #endif])
1530
1531 dnl Check for siginfo_t members
1532 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1533
1534 dnl Check for struct mtget members
1535 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1536 [#include <sys/types.h>
1537 #ifdef HAVE_SYS_MTIO_H
1538 #include <sys/mtio.h>
1539 #endif])
1540
1541 dnl Check for struct option
1542 AC_CHECK_MEMBERS([struct option.name],,,
1543 [#ifdef HAVE_GETOPT_H
1544 #include <getopt.h>
1545 #endif])
1546
1547 dnl Check for stat.st_blocks
1548 AC_CHECK_MEMBERS([struct stat.st_blocks])
1549
1550 dnl Check for sin6_scope_id
1551 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1552 [#ifdef HAVE_SYS_TYPES_H
1553 #include <sys/types.h>
1554 #endif
1555 #ifdef HAVE_NETINET_IN_H
1556 #include <netinet/in.h>
1557 #endif])
1558
1559 dnl Check for ns_msg ptr member
1560 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1561 [#ifdef HAVE_SYS_TYPES_H
1562 #include <sys/types.h>
1563 #endif
1564 #ifdef HAVE_NETINET_IN_H
1565 # include <netinet/in.h>
1566 #endif
1567 #ifdef HAVE_ARPA_NAMESER_H
1568 # include <arpa/nameser.h>
1569 #endif])
1570
1571 dnl Check for the external timezone variables timezone and daylight
1572 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1573                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1574 if test "$ac_cv_have_timezone" = "yes"
1575 then
1576     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1577 fi
1578 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1579                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1580 if test "$ac_cv_have_daylight" = "yes"
1581 then
1582     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1583 fi
1584
1585 dnl *** check for the need to define platform-specific symbols
1586
1587 case $host_cpu in
1588   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1589   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1590   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1591   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1592   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1593 esac
1594
1595 case $host_vendor in
1596   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1597 esac
1598
1599 dnl **** Generate output files ****
1600
1601 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1602 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1603 ["### Dependencies:\\
1604 \\
1605 .INIT: Makefile\\
1606 .BEGIN: Makefile\\
1607 Makefile: dummy\\
1608         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1609 \\
1610 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1611 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1612 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1613 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1614 ["### Dependencies:
1615
1616 .INIT: Makefile
1617 .BEGIN: Makefile
1618 Makefile: dummy
1619         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1620
1621 \$(OBJS): \$(IDL_GEN_HEADERS)
1622 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1623 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1624 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1625
1626 AH_TOP([#define __WINE_CONFIG_H])
1627
1628 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1629
1630 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1631 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1632 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1633 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1634 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1635 WINE_CONFIG_EXTRA_DIR(include/wine)
1636
1637 MAKE_RULES=Make.rules
1638 AC_SUBST_FILE(MAKE_RULES)
1639
1640 MAKE_DLL_RULES=dlls/Makedll.rules
1641 AC_SUBST_FILE(MAKE_DLL_RULES)
1642
1643 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1644 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1645
1646 MAKE_TEST_RULES=dlls/Maketest.rules
1647 AC_SUBST_FILE(MAKE_TEST_RULES)
1648
1649 MAKE_PROG_RULES=programs/Makeprog.rules
1650 AC_SUBST_FILE(MAKE_PROG_RULES)
1651
1652 AC_CONFIG_FILES([Make.rules])
1653 AC_CONFIG_FILES([dlls/Makedll.rules])
1654 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1655 AC_CONFIG_FILES([dlls/Maketest.rules])
1656 AC_CONFIG_FILES([programs/Makeprog.rules])
1657 AC_CONFIG_FILES([Makefile])
1658 AC_CONFIG_FILES([dlls/Makefile])
1659 AC_CONFIG_FILES([dlls/acledit/Makefile])
1660 AC_CONFIG_FILES([dlls/activeds/Makefile])
1661 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1662 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1663 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1664 AC_CONFIG_FILES([dlls/advpack/Makefile])
1665 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1666 AC_CONFIG_FILES([dlls/amstream/Makefile])
1667 AC_CONFIG_FILES([dlls/atl/Makefile])
1668 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1669 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1670 AC_CONFIG_FILES([dlls/browseui/Makefile])
1671 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1672 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1673 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1674 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1675 AC_CONFIG_FILES([dlls/cards/Makefile])
1676 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1677 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1678 AC_CONFIG_FILES([dlls/comcat/Makefile])
1679 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1680 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1681 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1682 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1683 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1684 AC_CONFIG_FILES([dlls/compstui/Makefile])
1685 AC_CONFIG_FILES([dlls/credui/Makefile])
1686 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1687 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1688 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1689 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1690 AC_CONFIG_FILES([dlls/cryptdlg/Makefile])
1691 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1692 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1693 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1694 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1695 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1696 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1697 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1698 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1699 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1700 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1701 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1702 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1703 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1704 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1705 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1706 AC_CONFIG_FILES([dlls/d3dx9_24/Makefile])
1707 AC_CONFIG_FILES([dlls/d3dx9_25/Makefile])
1708 AC_CONFIG_FILES([dlls/d3dx9_26/Makefile])
1709 AC_CONFIG_FILES([dlls/d3dx9_27/Makefile])
1710 AC_CONFIG_FILES([dlls/d3dx9_28/Makefile])
1711 AC_CONFIG_FILES([dlls/d3dx9_29/Makefile])
1712 AC_CONFIG_FILES([dlls/d3dx9_30/Makefile])
1713 AC_CONFIG_FILES([dlls/d3dx9_31/Makefile])
1714 AC_CONFIG_FILES([dlls/d3dx9_32/Makefile])
1715 AC_CONFIG_FILES([dlls/d3dx9_33/Makefile])
1716 AC_CONFIG_FILES([dlls/d3dx9_34/Makefile])
1717 AC_CONFIG_FILES([dlls/d3dx9_35/Makefile])
1718 AC_CONFIG_FILES([dlls/d3dx9_36/Makefile])
1719 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1720 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1721 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1722 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1723 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1724 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1725 AC_CONFIG_FILES([dlls/devenum/Makefile])
1726 AC_CONFIG_FILES([dlls/dinput/Makefile])
1727 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1728 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1729 AC_CONFIG_FILES([dlls/dmband/Makefile])
1730 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1731 AC_CONFIG_FILES([dlls/dmime/Makefile])
1732 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1733 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1734 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1735 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1736 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1737 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1738 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1739 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1740 AC_CONFIG_FILES([dlls/dplay/Makefile])
1741 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1742 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1743 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1744 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1745 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1746 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1747 AC_CONFIG_FILES([dlls/dsound/Makefile])
1748 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1749 AC_CONFIG_FILES([dlls/dssenh/Makefile])
1750 AC_CONFIG_FILES([dlls/dswave/Makefile])
1751 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1752 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1753 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1754 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1755 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1756 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1757 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1758 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1759 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1760 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1761 AC_CONFIG_FILES([dlls/glu32/Makefile])
1762 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1763 AC_CONFIG_FILES([dlls/gpkcsp/Makefile])
1764 AC_CONFIG_FILES([dlls/hal/Makefile])
1765 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1766 AC_CONFIG_FILES([dlls/hid/Makefile])
1767 AC_CONFIG_FILES([dlls/hlink/Makefile])
1768 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1769 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1770 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1771 AC_CONFIG_FILES([dlls/icmp/Makefile])
1772 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1773 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1774 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1775 AC_CONFIG_FILES([dlls/imm32/Makefile])
1776 AC_CONFIG_FILES([dlls/imm32/tests/Makefile])
1777 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1778 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1779 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1780 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1781 AC_CONFIG_FILES([dlls/initpki/Makefile])
1782 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1783 AC_CONFIG_FILES([dlls/inseng/Makefile])
1784 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1785 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1786 AC_CONFIG_FILES([dlls/itircl/Makefile])
1787 AC_CONFIG_FILES([dlls/itss/Makefile])
1788 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1789 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1790 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1791 AC_CONFIG_FILES([dlls/localspl/Makefile])
1792 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1793 AC_CONFIG_FILES([dlls/localui/Makefile])
1794 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1795 AC_CONFIG_FILES([dlls/lz32/Makefile])
1796 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1797 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1798 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1799 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1800 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1801 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1802 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1803 AC_CONFIG_FILES([dlls/midimap/Makefile])
1804 AC_CONFIG_FILES([dlls/mlang/Makefile])
1805 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1806 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1807 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1808 AC_CONFIG_FILES([dlls/mountmgr.sys/Makefile])
1809 AC_CONFIG_FILES([dlls/mpr/Makefile])
1810 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1811 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1812 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1813 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1814 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1815 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1816 AC_CONFIG_FILES([dlls/mscms/Makefile])
1817 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1818 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1819 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1820 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1821 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1822 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1823 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1824 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1825 AC_CONFIG_FILES([dlls/msi/Makefile])
1826 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1827 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1828 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1829 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1830 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1831 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1832 AC_CONFIG_FILES([dlls/mssip32/Makefile])
1833 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1834 AC_CONFIG_FILES([dlls/msvcr71/Makefile])
1835 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1836 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1837 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1838 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1839 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1840 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1841 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1842 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1843 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1844 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1845 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1846 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1847 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1848 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1849 AC_CONFIG_FILES([dlls/newdev/Makefile])
1850 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1851 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1852 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1853 AC_CONFIG_FILES([dlls/ntdsapi/tests/Makefile])
1854 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1855 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1856 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1857 AC_CONFIG_FILES([dlls/objsel/Makefile])
1858 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1859 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1860 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1861 AC_CONFIG_FILES([dlls/ole32/Makefile])
1862 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1863 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1864 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1865 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1866 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1867 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1868 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1869 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1870 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1871 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1872 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1873 AC_CONFIG_FILES([dlls/pdh/Makefile])
1874 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1875 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1876 AC_CONFIG_FILES([dlls/printui/Makefile])
1877 AC_CONFIG_FILES([dlls/propsys/Makefile])
1878 AC_CONFIG_FILES([dlls/psapi/Makefile])
1879 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1880 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1881 AC_CONFIG_FILES([dlls/qcap/Makefile])
1882 AC_CONFIG_FILES([dlls/qedit/Makefile])
1883 AC_CONFIG_FILES([dlls/qedit/tests/Makefile])
1884 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1885 AC_CONFIG_FILES([dlls/qmgr/tests/Makefile])
1886 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1887 AC_CONFIG_FILES([dlls/quartz/Makefile])
1888 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1889 AC_CONFIG_FILES([dlls/query/Makefile])
1890 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1891 AC_CONFIG_FILES([dlls/resutils/Makefile])
1892 AC_CONFIG_FILES([dlls/riched20/Makefile])
1893 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1894 AC_CONFIG_FILES([dlls/riched32/Makefile])
1895 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1896 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1897 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1898 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1899 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1900 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1901 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1902 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1903 AC_CONFIG_FILES([dlls/sccbase/Makefile])
1904 AC_CONFIG_FILES([dlls/schannel/Makefile])
1905 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1906 AC_CONFIG_FILES([dlls/secur32/Makefile])
1907 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1908 AC_CONFIG_FILES([dlls/security/Makefile])
1909 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1910 AC_CONFIG_FILES([dlls/serialui/Makefile])
1911 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1912 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1913 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1914 AC_CONFIG_FILES([dlls/sfc/Makefile])
1915 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1916 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1917 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1918 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1919 AC_CONFIG_FILES([dlls/shell32/Makefile])
1920 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1921 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1922 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1923 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1924 AC_CONFIG_FILES([dlls/slbcsp/Makefile])
1925 AC_CONFIG_FILES([dlls/slc/Makefile])
1926 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1927 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1928 AC_CONFIG_FILES([dlls/softpub/Makefile])
1929 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1930 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
1931 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1932 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1933 AC_CONFIG_FILES([dlls/sti/Makefile])
1934 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1935 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1936 AC_CONFIG_FILES([dlls/sxs/Makefile])
1937 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1938 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1939 AC_CONFIG_FILES([dlls/unicows/Makefile])
1940 AC_CONFIG_FILES([dlls/url/Makefile])
1941 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1942 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1943 AC_CONFIG_FILES([dlls/user32/Makefile])
1944 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1945 AC_CONFIG_FILES([dlls/userenv/Makefile])
1946 AC_CONFIG_FILES([dlls/usp10/Makefile])
1947 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1948 AC_CONFIG_FILES([dlls/uuid/Makefile])
1949 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1950 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1951 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1952 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1953 AC_CONFIG_FILES([dlls/version/Makefile])
1954 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1955 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1956 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1957 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1958 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1959 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1960 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1961 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1962 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1963 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1964 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1965 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1966 AC_CONFIG_FILES([dlls/winedos/Makefile])
1967 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1968 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1969 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1970 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1971 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1972 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1973 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1974 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1975 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1976 AC_CONFIG_FILES([dlls/wing32/Makefile])
1977 AC_CONFIG_FILES([dlls/winhttp/Makefile])
1978 AC_CONFIG_FILES([dlls/wininet/Makefile])
1979 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1980 AC_CONFIG_FILES([dlls/winmm/Makefile])
1981 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1982 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1983 AC_CONFIG_FILES([dlls/winscard/Makefile])
1984 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1985 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1986 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1987 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1988 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1989 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1990 AC_CONFIG_FILES([dlls/wmi/Makefile])
1991 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1992 AC_CONFIG_FILES([dlls/wow32/Makefile])
1993 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1994 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1995 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1996 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1997 AC_CONFIG_FILES([documentation/Makefile])
1998 AC_CONFIG_FILES([fonts/Makefile])
1999 AC_CONFIG_FILES([include/Makefile])
2000 AC_CONFIG_FILES([libs/Makefile])
2001 AC_CONFIG_FILES([libs/port/Makefile])
2002 AC_CONFIG_FILES([libs/wine/Makefile])
2003 AC_CONFIG_FILES([libs/wpp/Makefile])
2004 AC_CONFIG_FILES([loader/Makefile])
2005 AC_CONFIG_FILES([programs/Makefile])
2006 AC_CONFIG_FILES([programs/clock/Makefile])
2007 AC_CONFIG_FILES([programs/cmd/Makefile])
2008 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
2009 AC_CONFIG_FILES([programs/control/Makefile])
2010 AC_CONFIG_FILES([programs/eject/Makefile])
2011 AC_CONFIG_FILES([programs/expand/Makefile])
2012 AC_CONFIG_FILES([programs/explorer/Makefile])
2013 AC_CONFIG_FILES([programs/hh/Makefile])
2014 AC_CONFIG_FILES([programs/icinfo/Makefile])
2015 AC_CONFIG_FILES([programs/iexplore/Makefile])
2016 AC_CONFIG_FILES([programs/msiexec/Makefile])
2017 AC_CONFIG_FILES([programs/net/Makefile])
2018 AC_CONFIG_FILES([programs/notepad/Makefile])
2019 AC_CONFIG_FILES([programs/oleview/Makefile])
2020 AC_CONFIG_FILES([programs/progman/Makefile])
2021 AC_CONFIG_FILES([programs/regedit/Makefile])
2022 AC_CONFIG_FILES([programs/regsvr32/Makefile])
2023 AC_CONFIG_FILES([programs/rpcss/Makefile])
2024 AC_CONFIG_FILES([programs/rundll32/Makefile])
2025 AC_CONFIG_FILES([programs/secedit/Makefile])
2026 AC_CONFIG_FILES([programs/spoolsv/Makefile])
2027 AC_CONFIG_FILES([programs/start/Makefile])
2028 AC_CONFIG_FILES([programs/svchost/Makefile])
2029 AC_CONFIG_FILES([programs/taskmgr/Makefile])
2030 AC_CONFIG_FILES([programs/uninstaller/Makefile])
2031 AC_CONFIG_FILES([programs/view/Makefile])
2032 AC_CONFIG_FILES([programs/wineboot/Makefile])
2033 AC_CONFIG_FILES([programs/winebrowser/Makefile])
2034 AC_CONFIG_FILES([programs/winecfg/Makefile])
2035 AC_CONFIG_FILES([programs/wineconsole/Makefile])
2036 AC_CONFIG_FILES([programs/winedbg/Makefile])
2037 AC_CONFIG_FILES([programs/winedevice/Makefile])
2038 AC_CONFIG_FILES([programs/winefile/Makefile])
2039 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
2040 AC_CONFIG_FILES([programs/winemine/Makefile])
2041 AC_CONFIG_FILES([programs/winepath/Makefile])
2042 AC_CONFIG_FILES([programs/winetest/Makefile])
2043 AC_CONFIG_FILES([programs/winevdm/Makefile])
2044 AC_CONFIG_FILES([programs/winhelp/Makefile])
2045 AC_CONFIG_FILES([programs/winver/Makefile])
2046 AC_CONFIG_FILES([programs/wordpad/Makefile])
2047 AC_CONFIG_FILES([programs/write/Makefile])
2048 AC_CONFIG_FILES([programs/xcopy/Makefile])
2049 AC_CONFIG_FILES([server/Makefile])
2050 AC_CONFIG_FILES([tools/Makefile])
2051 AC_CONFIG_FILES([tools/widl/Makefile])
2052 AC_CONFIG_FILES([tools/winebuild/Makefile])
2053 AC_CONFIG_FILES([tools/winedump/Makefile])
2054 AC_CONFIG_FILES([tools/winegcc/Makefile])
2055 AC_CONFIG_FILES([tools/wmc/Makefile])
2056 AC_CONFIG_FILES([tools/wrc/Makefile])
2057
2058 AC_OUTPUT
2059
2060 if test "$no_create" = "yes"
2061 then
2062   exit 0
2063 fi
2064
2065 WINE_PRINT_MESSAGES
2066
2067 echo "
2068 $as_me: Finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine.
2069 " >&AS_MESSAGE_FD
2070
2071 dnl Local Variables:
2072 dnl comment-start: "dnl "
2073 dnl comment-end: ""
2074 dnl comment-start-skip: "\\bdnl\\b\\s *"
2075 dnl compile-command: "autoreconf --warnings=all"
2076 dnl End: