git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.62 don't handle source dir symlinks correctly
   8 AC_PREREQ(2.62)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND or AS_VAR_IF
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17 m4_ifdef([AS_VAR_IF],,[AC_DEFUN([AS_VAR_IF],
  18 [AS_LITERAL_IF([$1],
  19   [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
  20   [eval as_val=\$$1
  21    AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])])dnl
  22 dnl autoconf versions before 2.64 don't have AC_PACKAGE_URL
  23 m4_ifdef([AC_PACKAGE_URL],,
  24   [AC_DEFINE([PACKAGE_URL], ["http://www.winehq.org"], [Define to the home page for this package.])
  25    AC_SUBST([PACKAGE_URL], ["http://www.winehq.org"])])dnl
  26
  27 dnl **** Command-line arguments ****
  28
  29 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  30 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  31 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  32 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]))
  33
  34 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  36 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  37             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  38 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  40 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  41             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  42 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  43             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  44 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  45 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  47 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  48 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  49             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  50 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  51 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  52 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  54 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  55 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  57 AC_ARG_WITH(gstreamer, AS_HELP_STRING([--without-gstreamer],[do not use GStreamer (codecs support)]))
  58 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  59 AC_ARG_WITH(icns,      AS_HELP_STRING([--without-icns],[do not use ICNS icon support]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_icns_h=no; fi])
  61 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  63 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  65 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  66             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  67 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]),
  68             [if test "x$withval" = "xno"; then ac_cv_header_mpg123_h=no; fi])
  69 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  70             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  71 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  72             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  73 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  74 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  75             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  76 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  77             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  78 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  79             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  80 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  81             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  82 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  83 AC_ARG_WITH(tiff,       AS_HELP_STRING([--without-tiff],[do not use TIFF]),
  84             [if test "x$withval" = "xno"; then ac_cv_header_tiffio_h=no; fi])
  85 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  86 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  87             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  88 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  89             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  90 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  91             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  92 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  93             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  94 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  95 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  96             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  97 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  98             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  99 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
 100             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
 101 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
 102             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
 103 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
 104 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
 105             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
 106
 107 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
 108 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
 109
 110 AC_CANONICAL_HOST
 111
 112 dnl check for out of tree build with unclean source tree
 113 case "$srcdir" in
 114  .) ;;
 115  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 116       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 117 You need to run 'make distclean' in the source tree first.])
 118     fi ;;
 119 esac
 120
 121 dnl **** Check for some programs ****
 122
 123 AC_PROG_MAKE_SET
 124 AC_PROG_CC
 125 AC_PROG_CXX
 126 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 127 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 128 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 129
 130 case $host in
 131   *-darwin*)
 132     if test "x$enable_win64" = "xyes"
 133     then
 134       CC="$CC -m64"
 135       CXX="$CXX -m64"
 136       LD="${LD:-ld} -arch x86_64"
 137       AS="${AS:-as} -arch x86_64"
 138       host_cpu="x86_64"
 139       notice_platform="64-bit "
 140       AC_SUBST(TARGETFLAGS,"-m64")
 141     else
 142       CC="$CC -m32"
 143       CXX="$CXX -m32"
 144       LD="${LD:-ld} -arch i386"
 145       AS="${AS:-as} -arch i386"
 146       host_cpu="i386"
 147       notice_platform="32-bit "
 148       AC_SUBST(TARGETFLAGS,"-m32")
 149       enable_win16=${enable_win16:-yes}
 150     fi
 151     ;;
 152   x86_64*)
 153     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 154     then
 155       CC="$CC -m32"
 156       CXX="$CXX -m32"
 157       AC_MSG_CHECKING([whether $CC works])
 158       AC_LINK_IFELSE(AC_LANG_PROGRAM(),AC_MSG_RESULT([yes]),
 159                      [AC_MSG_RESULT([no])
 160                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 161       LD="${LD:-ld} -m elf_i386"
 162       AS="${AS:-as} --32"
 163       host_cpu="i386"
 164       notice_platform="32-bit "
 165       AC_SUBST(TARGETFLAGS,"-m32")
 166       enable_win16=${enable_win16:-yes}
 167     else
 168       if test "x${GCC}" = "xyes"
 169       then
 170         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 171         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 172                           [AC_MSG_RESULT([yes])],
 173                           [AC_MSG_RESULT([no])
 174                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 175       fi
 176       AC_SUBST(TARGETFLAGS,"-m64")
 177     fi
 178     ;;
 179   *-mingw32*|*-cygwin*)
 180     enable_win16=${enable_win16:-no}
 181     CFLAGS="$CFLAGS -D_WIN32"
 182     ;;
 183   i[[3456789]]86*)
 184     enable_win16=${enable_win16:-yes}
 185     ;;
 186 esac
 187
 188 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 189 enable_win16=${enable_win16:-no}
 190
 191 dnl Disable winetest too if tests are disabled
 192 enable_winetest=${enable_winetest:-$enable_tests}
 193
 194 dnl Some special cases for the wow64 build
 195 if test -n "$with_wine64"
 196 then
 197     if test "x$enable_win64" = "xyes"
 198     then
 199         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 200 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 201     fi
 202     AC_SUBST([WOW64_DISABLE],[\#])
 203     enable_fonts=${enable_fonts:-no}
 204     enable_server=${enable_server:-no}
 205     enable_tools=${enable_tools:-no}
 206 elif test "x$enable_win64" = "xyes"
 207 then
 208     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib64"
 209 fi
 210
 211 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 212   [wine_cv_toolsdir="$with_wine_tools"
 213    if test -z "$with_wine_tools"; then
 214      if test "$cross_compiling" = "yes"; then
 215        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 216      elif test -n "$with_wine64"; then
 217        wine_cv_toolsdir="$with_wine64"
 218      fi
 219    fi
 220    if test -z "$wine_cv_toolsdir"; then
 221      wine_cv_toolsdir="\$(top_builddir)"
 222    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 223      case "$wine_cv_toolsdir" in
 224        /*) ;;
 225        *)  wine_cv_toolsdir="\$(top_builddir)/$wine_cv_toolsdir" ;;
 226      esac
 227    else
 228      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 229    fi])
 230 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 231 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 232 then
 233     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 234 fi
 235
 236 dnl Check for flex
 237 AC_CHECK_PROGS(FLEX,flex,none)
 238 if test "$FLEX" = "none"
 239 then
 240   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 241 fi
 242 AC_MSG_CHECKING([whether flex is recent enough])
 243 cat >conftest.l <<EOF
 244 %top{
 245 #include "prediluvian.h"
 246 }
 247 %%
 248 EOF
 249 if $FLEX -t conftest.l >/dev/null 2>&AS_MESSAGE_LOG_FD
 250 then
 251   AC_MSG_RESULT([yes])
 252 else
 253   AC_MSG_RESULT([no])
 254   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 255 fi
 256
 257 dnl Check for bison
 258 AC_CHECK_PROGS(BISON,bison,none)
 259 if test "$BISON" = "none"
 260 then
 261   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 262 fi
 263
 264 AC_CHECK_TOOLS(AR,[ar gar],ar)
 265 AC_SUBST(ARFLAGS,rc)
 266 AC_PROG_RANLIB
 267 AC_CHECK_TOOL(STRIP,strip,strip)
 268 AC_PROG_LN_S
 269 AC_PROG_EGREP
 270 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 271 AC_PROG_INSTALL
 272 dnl Prepend src dir to install path dir if it's a relative path
 273 case "$INSTALL" in
 274   [[\\/$]]* | ?:[[\\/]]* ) ;;
 275   *)  INSTALL="\\\$(top_srcdir)/$INSTALL" ;;
 276 esac
 277
 278 dnl Check for lint
 279 AC_CHECK_PROGS(LINT, lclint lint)
 280 if test "$LINT" = "lint"
 281 then
 282   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 283   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 284 fi
 285 AC_SUBST(LINT)
 286 AC_SUBST(LINTFLAGS)
 287
 288 dnl Check for various programs
 289 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 290 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 291 AC_CHECK_PROGS(RSVG, rsvg, false)
 292 AC_CHECK_PROGS(CONVERT, convert, false)
 293 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 294
 295 if test "x$enable_maintainer_mode" != "xyes"
 296 then
 297   AC_SUBST([MAINTAINER_MODE],[\#])
 298 else
 299   if test "$FONTFORGE" = "false"; then AC_MSG_ERROR([You need fontforge to rebuild fonts in maintainer mode.]); fi
 300   if test "$RSVG" = "false"; then AC_MSG_ERROR([You need rsvg to rebuild icons in maintainer mode.]); fi
 301
 302   dnl Check the imagemagick version
 303   if test "$CONVERT" = false
 304   then
 305     AC_MSG_ERROR([You need imagemagick to rebuild icons in maintainer mode.])
 306   else
 307     AC_MSG_CHECKING([for recent enough imagemagick])
 308     convert_version=`convert --version | head -n1`
 309     if test "x$convert_version" != "x"
 310     then
 311       convert_version_major=`expr "$convert_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 312       convert_version_minor=`expr "$convert_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 313       if test "$convert_version_major" -eq 6 -a "$convert_version_minor" -lt 6
 314       then
 315         CONVERT=false
 316       fi
 317     fi
 318     if test "$CONVERT" = false
 319     then
 320       AC_MSG_RESULT([no ($convert_version_major.$convert_version_minor)])
 321       AC_MSG_ERROR([You need imagemagick version 6.6 or newer to rebuild icons in maintainer mode.])
 322     else
 323       AC_MSG_RESULT([yes ($convert_version_major.$convert_version_minor)])
 324     fi
 325   fi
 326
 327   dnl Check the icotool version
 328   if test "$ICOTOOL" = false
 329   then
 330     AC_MSG_ERROR([You need icotool to rebuild icons in maintainer mode.])
 331   else
 332     AC_MSG_CHECKING([for recent enough icotool])
 333     icotool_version=`icotool --version | head -n1`
 334     if test "x$icotool_version" != "x"
 335     then
 336       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 337       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 338       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 339       then
 340         ICOTOOL=false
 341         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 342       fi
 343     fi
 344     if test "$ICOTOOL" = false
 345     then
 346       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 347       AC_MSG_ERROR([You need icotool version 0.29.0 or newer to rebuild icons in maintainer mode.])
 348     else
 349       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 350     fi
 351   fi
 352
 353 fi
 354
 355 dnl **** Check for some libraries ****
 356
 357 dnl Check for -li386 for NetBSD and OpenBSD
 358 AC_CHECK_LIB(i386,i386_set_ldt)
 359 dnl Check for -lossaudio for NetBSD
 360 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 361
 362 AC_SUBST(XLIB,"")
 363 AC_SUBST(OPENGL_LIBS,"")
 364
 365 dnl **** Check for header files ****
 366
 367 AC_SYS_LARGEFILE()
 368
 369 AC_CHECK_HEADERS(\
 370         AL/al.h \
 371         AudioToolbox/AudioConverter.h \
 372         AudioUnit/AudioUnit.h \
 373         Carbon/Carbon.h \
 374         CoreAudio/CoreAudio.h \
 375         DiskArbitration/DiskArbitration.h \
 376         IOKit/IOKitLib.h \
 377         IOKit/hid/IOHIDLib.h \
 378         OpenAL/al.h \
 379         alias.h \
 380         alsa/asoundlib.h \
 381         arpa/inet.h \
 382         arpa/nameser.h \
 383         asm/types.h \
 384         capi20.h \
 385         curses.h \
 386         direct.h \
 387         dirent.h \
 388         dlfcn.h \
 389         elf.h \
 390         float.h \
 391         fnmatch.h \
 392         fontconfig/fontconfig.h \
 393         getopt.h \
 394         grp.h \
 395         gsm.h \
 396         gsm/gsm.h \
 397         icns.h \
 398         ieeefp.h \
 399         inet/mib2.h \
 400         io.h \
 401         jack/jack.h \
 402         jpeglib.h \
 403         kstat.h \
 404         lber.h \
 405         lcms.h \
 406         lcms/lcms.h \
 407         ldap.h \
 408         libaudioio.h \
 409         link.h \
 410         linux/cdrom.h \
 411         linux/compiler.h \
 412         linux/hdreg.h \
 413         linux/input.h \
 414         linux/ioctl.h \
 415         linux/joystick.h \
 416         linux/major.h \
 417         linux/param.h \
 418         linux/serial.h \
 419         linux/types.h \
 420         linux/ucdrom.h \
 421         mach-o/nlist.h \
 422         mach-o/loader.h \
 423         mach/mach.h \
 424         mach/machine.h \
 425         machine/cpu.h \
 426         machine/limits.h \
 427         machine/soundcard.h \
 428         machine/sysarch.h \
 429         mntent.h \
 430         mpg123.h \
 431         ncurses.h \
 432         netdb.h \
 433         netinet/in.h \
 434         netinet/in_systm.h \
 435         netinet/tcp.h \
 436         netinet/tcp_fsm.h \
 437         openssl/err.h \
 438         openssl/ssl.h \
 439         png.h \
 440         poll.h \
 441         port.h \
 442         process.h \
 443         pthread.h \
 444         pwd.h \
 445         regex.h \
 446         sched.h \
 447         scsi/scsi.h \
 448         scsi/scsi_ioctl.h \
 449         scsi/sg.h \
 450         soundcard.h \
 451         stdbool.h \
 452         stdint.h \
 453         strings.h \
 454         stropts.h \
 455         sys/asoundlib.h \
 456         sys/cdio.h \
 457         sys/elf32.h \
 458         sys/epoll.h \
 459         sys/errno.h \
 460         sys/event.h \
 461         sys/exec_elf.h \
 462         sys/filio.h \
 463         sys/inotify.h \
 464         sys/ioctl.h \
 465         sys/ipc.h \
 466         sys/limits.h \
 467         sys/link.h \
 468         sys/mman.h \
 469         sys/modem.h \
 470         sys/msg.h \
 471         sys/mtio.h \
 472         sys/param.h \
 473         sys/poll.h \
 474         sys/prctl.h \
 475         sys/protosw.h \
 476         sys/ptrace.h \
 477         sys/resource.h \
 478         sys/scsiio.h \
 479         sys/shm.h \
 480         sys/signal.h \
 481         sys/socket.h \
 482         sys/socketvar.h \
 483         sys/sockio.h \
 484         sys/soundcard.h \
 485         sys/statvfs.h \
 486         sys/strtio.h \
 487         sys/syscall.h \
 488         sys/tihdr.h \
 489         sys/time.h \
 490         sys/timeout.h \
 491         sys/times.h \
 492         sys/uio.h \
 493         sys/un.h \
 494         sys/utsname.h \
 495         sys/vm86.h \
 496         sys/wait.h \
 497         syscall.h \
 498         termios.h \
 499         tiffio.h \
 500         unistd.h \
 501         utime.h \
 502         valgrind/memcheck.h \
 503         valgrind/valgrind.h \
 504         zlib.h
 505 )
 506 AC_HEADER_STAT()
 507
 508 dnl **** Checks for headers that depend on other ones ****
 509
 510 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 511     [#include <sys/types.h>
 512      #ifdef HAVE_SYS_PARAM_H
 513      # include <sys/param.h>
 514      #endif])
 515
 516 AC_CHECK_HEADERS(\
 517         netinet/ip.h \
 518         net/if.h \
 519         net/if_arp.h \
 520         net/if_dl.h \
 521         net/if_types.h \
 522         net/route.h \
 523         netinet/if_ether.h \
 524         netinet/if_inarp.h \
 525         netinet/in_pcb.h \
 526         netinet/ip_icmp.h \
 527         netinet/ip_var.h \
 528         netinet/udp.h \
 529         netipx/ipx.h \
 530 ,,,[#include <sys/types.h>
 531      #ifdef HAVE_SYS_SOCKET_H
 532      # include <sys/socket.h>
 533      #endif
 534      #ifdef HAVE_SYS_SOCKETVAR_H
 535      # include <sys/socketvar.h>
 536      #endif
 537      #ifdef HAVE_NET_ROUTE_H
 538      # include <net/route.h>
 539      #endif
 540      #ifdef HAVE_NETINET_IN_H
 541      # include <netinet/in.h>
 542      #endif
 543      #ifdef HAVE_NETINET_IN_SYSTM_H
 544      # include <netinet/in_systm.h>
 545      #endif
 546      #ifdef HAVE_NET_IF_H
 547      # include <net/if.h>
 548      #endif
 549      #ifdef HAVE_NETINET_IP_H
 550      # include <netinet/ip.h>
 551      #endif])
 552
 553 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 554     [#include <sys/types.h>
 555      #ifdef HAVE_ALIAS_H
 556      # include <alias.h>
 557      #endif
 558      #ifdef HAVE_SYS_SOCKET_H
 559      # include <sys/socket.h>
 560      #endif
 561      #ifdef HAVE_SYS_SOCKETVAR_H
 562      # include <sys/socketvar.h>
 563      #endif
 564      #ifdef HAVE_SYS_TIMEOUT_H
 565      # include <sys/timeout.h>
 566      #endif
 567      #ifdef HAVE_NETINET_IN_H
 568      # include <netinet/in.h>
 569      #endif
 570      #ifdef HAVE_NETINET_IN_SYSTM_H
 571      # include <netinet/in_systm.h>
 572      #endif
 573      #ifdef HAVE_NETINET_IP_H
 574      # include <netinet/ip.h>
 575      #endif
 576      #ifdef HAVE_NETINET_IP_VAR_H
 577      # include <netinet/ip_var.h>
 578      #endif
 579      #ifdef HAVE_NETINET_IP_ICMP_H
 580      # include <netinet/ip_icmp.h>
 581      #endif
 582      #ifdef HAVE_NETINET_UDP_H
 583      # include <netinet/udp.h>
 584      #endif
 585      #ifdef HAVE_NETINET_TCP_H
 586      # include <netinet/tcp.h>
 587      #endif
 588      #ifdef HAVE_NETINET_TCP_TIMER_H
 589      #include <netinet/tcp_timer.h>
 590      #endif])
 591
 592 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h],,,
 593     [#include <sys/types.h>
 594      #ifdef HAVE_ASM_TYPES_H
 595      # include <asm/types.h>
 596      #endif
 597      #ifdef HAVE_SYS_SOCKET_H
 598      # include <sys/socket.h>
 599      #endif
 600      #ifdef HAVE_LINUX_TYPES_H
 601      # include <linux/types.h>
 602      #endif])
 603
 604 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 605     [#ifdef HAVE_STDBOOL_H
 606      # include <stdbool.h>
 607      #endif
 608      #ifdef HAVE_STDINT_H
 609      # include <stdint.h>
 610      #endif])
 611
 612 AC_CHECK_HEADERS([resolv.h],,,
 613     [#include <sys/types.h>
 614      #ifdef HAVE_SYS_SOCKET_H
 615      # include <sys/socket.h>
 616      #endif
 617      #ifdef HAVE_NETINET_IN_H
 618      # include <netinet/in.h>
 619      #endif
 620      #ifdef HAVE_ARPA_NAMESER_H
 621      # include <arpa/nameser.h>
 622      #endif])
 623
 624 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 625
 626 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 627
 628 AC_CHECK_HEADERS([sys/thr.h],,,
 629 [#include <sys/types.h>
 630 #ifdef HAVE_UCONTEXT_H
 631 #include <ucontext.h>
 632 #endif])
 633
 634 AC_CHECK_HEADERS([pthread_np.h],,,
 635 [#ifdef HAVE_PTHREAD_H
 636 #include <pthread.h>
 637 #endif])
 638
 639 AC_CHECK_HEADERS([linux/videodev.h],,,
 640 [#ifdef HAVE_SYS_TIME_H
 641 #include <sys/time.h>
 642 #endif
 643 #include <sys/types.h>
 644 #ifdef HAVE_ASM_TYPES_H
 645 #include <asm/types.h>
 646 #endif])
 647
 648 dnl Check for broken kernel header that doesn't define __user
 649 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 650
 651 dnl **** Check for working dll ****
 652
 653 AC_SUBST(DLLEXT,"")
 654 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 655 AC_SUBST(LDSHARED,"")
 656 AC_SUBST(LDDLLFLAGS,"")
 657 AC_SUBST(LIBEXT,"so")
 658 AC_SUBST(IMPLIBEXT,"def")
 659 AC_SUBST(LDRPATH_INSTALL,"")
 660 AC_SUBST(LDRPATH_LOCAL,"")
 661 STATIC_IMPLIBEXT="def.a"
 662 WINE_PATH_LDD
 663
 664 case $host_os in
 665   cygwin*|mingw32*)
 666     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 667     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 668     if test "$DLLWRAP" = "false"; then
 669       LIBEXT="a"
 670     else
 671       dnl FIXME - check whether dllwrap works correctly...
 672       LIBEXT="dll"
 673     fi
 674     IMPLIBEXT="a"
 675     STATIC_IMPLIBEXT="a"
 676     dnl Disable modules that can't be used on Windows
 677     enable_iphlpapi=${enable_iphlpapi:-no}
 678     enable_kernel32=${enable_kernel32:-no}
 679     enable_msvcrt=${enable_msvcrt:-no}
 680     enable_ntdll=${enable_ntdll:-no}
 681     enable_ws2_32=${enable_ws2_32:-no}
 682     enable_loader=${enable_loader:-no}
 683     enable_server=${enable_server:-no}
 684     dnl Disable dependencies that are not useful on Windows
 685     with_x=${with_x:-no}
 686     with_pthread=${with_pthread:-no}
 687     ;;
 688   darwin*|macosx*)
 689     DLLEXT=".so"
 690     LIBEXT="dylib"
 691     DLLFLAGS="$DLLFLAGS -fPIC"
 692     LDDLLFLAGS="-bundle -multiply_defined suppress"
 693     LIBWINE_LDFLAGS="-multiply_defined suppress"
 694     LDSHARED="\$(CC) -dynamiclib"
 695     STRIP="$STRIP -x"
 696     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(top_builddir)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 697     dnl declare needed frameworks
 698     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 699     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 700     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 701     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHAREDHEAP,0x7f000000"])
 702     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 703     then
 704         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 705         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 706     fi
 707     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 708     then
 709         dnl CoreServices needed by AudioUnit
 710         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 711     fi
 712     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 713     then
 714         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 715         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 716         ac_cv_lib_openal=yes
 717     fi
 718     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 719     then
 720         ac_save_LIBS="$LIBS"
 721         LIBS="$LIBS $IOKITLIB"
 722         AC_CHECK_FUNCS(IOHIDManagerCreate)
 723         LIBS="$ac_save_LIBS"
 724     fi
 725     case $host_cpu in
 726       *powerpc*)
 727         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 728         ;;
 729     esac
 730     dnl Enable quartz driver on Mac OS X
 731     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 732     then
 733         AC_SUBST(CARBONLIB,"-framework Carbon")
 734         enable_winequartz_drv=${enable_winequartz_drv:-yes}
 735     fi
 736     dnl Check for Xcode 3.x broken 16-bit support
 737     if test "x$enable_win16" = "xyes"
 738     then
 739         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 740         AC_RUN_IFELSE(AC_LANG_PROGRAM([[asm(".text\n"
 741                                             "bad:\tnop;nop\n"
 742                                             "good:\tnop;nop\n\t"
 743                                             ".globl _testfunc\n"
 744                                             "_testfunc:\tcallw good");
 745                                         extern void testfunc();]],
 746                                       [[unsigned short *p = (unsigned short *)testfunc;
 747                                         return p[[0]] != 0xe866 || p[[1]] != 0xfffa]]),
 748                                       AC_MSG_RESULT(yes),
 749                                       [AC_MSG_RESULT(no)
 750                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 751                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 752     fi
 753     ;;
 754   *)
 755     DLLFLAGS="$DLLFLAGS -fPIC"
 756     DLLEXT=".so"
 757     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 758         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 759                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 760     if test "$ac_cv_c_dll_gnuelf" = "yes"
 761     then
 762       LDSHARED="\$(CC) -shared"
 763       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 764       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 765                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 766                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 767                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 768
 769       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 770
 771       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 772                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 773
 774       echo '{ global: *; };' >conftest.map
 775       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 776                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 777       rm -f conftest.map
 778
 779       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 780                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 781
 782       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 783                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 784                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 785           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 786                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 787                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 788
 789       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 790                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 791
 792       case $host_cpu in
 793         *i[[3456789]]86* | x86_64)
 794           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 795                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 796           AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 797           if test "x$PRELINK" = xfalse
 798           then
 799               WINE_WARNING([prelink not found, base address of core dlls won't be set correctly.])
 800           fi
 801           ;;
 802       esac
 803
 804     else
 805       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 806           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 807                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 808       if test "$ac_cv_c_dll_unixware" = "yes"
 809       then
 810         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 811         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 812
 813       else
 814         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 815           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 816         if test "$ac_cv_c_dll_hpux" = "yes"
 817         then
 818           LIBEXT="sl"
 819           DLLEXT=".sl"
 820           LDDLLFLAGS="-shared -fPIC"
 821           LDSHARED="\$(CC) -shared"
 822         fi
 823       fi
 824     fi
 825     ;;
 826 esac
 827
 828 enable_winequartz_drv=${enable_winequartz_drv:-no}
 829
 830 if test "$LIBEXT" = "a"; then
 831   AC_MSG_ERROR(
 832 [could not find a way to build shared libraries.
 833 It is currently not possible to build Wine without shared library
 834 (.so) support to allow transparent switch between .so and .dll files.
 835 If you are using Linux, you will need a newer binutils.]
 836 )
 837 fi
 838
 839 dnl Check for cross compiler to build test programs
 840 AC_SUBST([CROSSTEST_DISABLE],[\#])
 841 if test "$cross_compiling" = "no" -a "x$enable_tests" != xno -a "$LIBEXT" != "dll"
 842 then
 843     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 844     if test "$CROSSCC" != "false"
 845     then
 846         ac_save_CC="$CC"
 847         CC="$CROSSCC"
 848         AC_MSG_CHECKING([whether $CROSSCC works])
 849         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 850                           [AC_MSG_RESULT([yes])
 851                            set x $CROSSCC
 852                            shift
 853                            target=""
 854                            while test $# -ge 1
 855                            do
 856                                case "$1" in
 857                                  *-gcc) target=`expr "$1" : '\(.*\)-gcc'` ;;
 858                                esac
 859                                shift
 860                            done
 861                            if test -n "$target"
 862                            then
 863                                CROSSTEST_DISABLE=""
 864                                AC_SUBST(CROSSTARGET,"$target")
 865                            fi],
 866                           [AC_MSG_RESULT([no])])
 867         CC="$ac_save_CC"
 868     fi
 869 fi
 870
 871 dnl **** Check for pthread ****
 872
 873 if test "$ac_cv_header_pthread_h" = "yes"
 874 then
 875     AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])
 876 fi
 877 WINE_ERROR_WITH(pthread,[test "x$LIBPTHREAD" = "x"],[pthread ${notice_platform}development files not found.
 878 Wine cannot support threads without libpthread.])
 879
 880 dnl **** Check for X11 ****
 881
 882 AC_PATH_XTRA
 883
 884 if test "$have_x" = "yes"
 885 then
 886     XLIB="-lX11"
 887     ac_save_CPPFLAGS="$CPPFLAGS"
 888     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 889
 890     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 891     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 892
 893     dnl *** All of the following tests require X11/Xlib.h
 894     AC_CHECK_HEADERS([X11/Xlib.h \
 895                       X11/XKBlib.h \
 896                       X11/Xutil.h \
 897                       X11/Xcursor/Xcursor.h \
 898                       X11/extensions/shape.h \
 899                       X11/extensions/XInput.h \
 900                       X11/extensions/XShm.h \
 901                       X11/extensions/Xcomposite.h \
 902                       X11/extensions/Xinerama.h \
 903                       X11/extensions/Xrandr.h \
 904                       X11/extensions/Xrender.h \
 905                       X11/extensions/xf86vmode.h \
 906                       X11/extensions/xf86vmproto.h],,,
 907 [#ifdef HAVE_X11_XLIB_H
 908 # include <X11/Xlib.h>
 909 #endif
 910 #ifdef HAVE_X11_XUTIL_H
 911 # include <X11/Xutil.h>
 912 #endif])
 913
 914         dnl *** Check for X keyboard extension
 915         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 916         then
 917               AC_CHECK_LIB(X11, XkbQueryExtension,
 918               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 919               $X_LIBS $XLIB $X_EXTRA_LIBS)
 920         fi
 921
 922         dnl *** Check for X cursor
 923         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 924         then
 925             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 926         fi
 927         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 928                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
 929
 930         dnl *** Check for X input extension
 931         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 932         then
 933             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 934         fi
 935         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 936                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
 937
 938         dnl *** Check for X Shm extension
 939         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 940         then
 941               AC_CHECK_LIB(Xext, XShmQueryExtension,
 942               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 943               $X_LIBS $XLIB $X_EXTRA_LIBS)
 944         fi
 945         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 946                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
 947
 948         dnl *** Check for X shape extension
 949         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 950         then
 951               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 952               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 953               $X_LIBS $XLIB $X_EXTRA_LIBS)
 954         fi
 955         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 956                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
 957
 958         dnl *** Check for XFree86 VMODE extension
 959         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
 960         then
 961             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 962         fi
 963         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
 964                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
 965
 966         dnl *** Check for Transform functions in Xrender
 967         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 968         then
 969             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 970               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 971                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 972                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 973                 [$X_LIBS $XLIB $X_EXTRA_LIBS])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 974
 975         fi
 976         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 977                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
 978
 979         dnl *** Check for X RandR extension
 980         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 981         then
 982                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 983 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 984                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
 985         fi
 986         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 987                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
 988
 989         dnl *** Check for Xinerama extension
 990         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 991         then
 992                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 993 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 994                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
 995         fi
 996         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 997                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
 998
 999         dnl *** Check for X Composite extension
1000         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
1001         then
1002             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1003         fi
1004         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
1005                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
1006
1007         dnl *** Check for XICCallback struct
1008         AC_CHECK_MEMBERS([XICCallback.callback],,,
1009 [#ifdef HAVE_X11_XLIB_H
1010 #include <X11/Xlib.h>
1011 #endif])
1012
1013     dnl *** End of X11/Xlib.h check
1014
1015     dnl Check for the presence of OpenGL
1016     opengl_msg=""
1017     if test "x$with_opengl" != "xno"
1018     then
1019         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glu.h,,,
1020 [#ifdef HAVE_GL_GLX_H
1021 # include <GL/glx.h>
1022 #endif])
1023         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
1024         then
1025             dnl Check for some problems due to old Mesa versions
1026             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
1027               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
1028                 [wine_cv_opengl_header_version_OK="yes"],
1029                 [wine_cv_opengl_header_version_OK="no"]))
1030
1031             if test "$wine_cv_opengl_header_version_OK" = "yes"
1032             then
1033                 dnl Check for the presence of the library
1034                 WINE_CHECK_SONAME(GL,glXCreateContext,
1035                              [OPENGL_LIBS="-lGL"
1036                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1037                              [WINE_CHECK_SONAME(GL,glXCreateContext,
1038                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
1039                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1040                                     [if test -f /usr/X11R6/lib/libGL.a
1041                                     then
1042                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1043 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1044                                     else
1045                                         opengl_msg="No OpenGL library found on this system."
1046                                     fi],
1047                                     $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1048                              $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1049                  if test "$ac_cv_header_GL_glu_h" = "yes"
1050                  then
1051                     WINE_CHECK_SONAME(GLU,gluLookAt,,,[$OPENGL_LIBS $X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1052                  fi
1053                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
1054                                  [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1055              else
1056                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
1057              fi
1058          else
1059              opengl_msg="OpenGL development headers not found."
1060          fi
1061          test -n "$opengl_msg" && enable_opengl32=${enable_opengl32:-no}
1062          test "x$ac_cv_lib_soname_GLU" = "x" && enable_glu32=${enable_glu32:-no}
1063     else
1064          enable_opengl32=${enable_opengl32:-no}
1065          enable_glu32=${enable_glu32:-no}
1066     fi
1067     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1068 OpenGL and Direct3D won't be supported.])
1069
1070     dnl **** Check for NAS ****
1071     AC_SUBST(NASLIBS,"")
1072     AC_CHECK_HEADERS(audio/audiolib.h,
1073          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
1074           AC_CHECK_LIB(audio,AuCreateFlow,
1075                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
1076                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
1077                           [NASLIBS="-lXau -laudio -lXt $X_LIBS $XLIB $X_EXTRA_LIBS"],
1078                           [NASLIBS="-laudio -lXt $X_LIBS $XLIB $X_EXTRA_LIBS"],
1079                           [$X_LIBS])
1080                        ],,
1081                        [-lXt $X_LIBS $XLIB $X_EXTRA_LIBS])])
1082
1083     CPPFLAGS="$ac_save_CPPFLAGS"
1084 else
1085     XLIB=""
1086     X_CFLAGS=""
1087     X_LIBS=""
1088     enable_winex11_drv=${enable_winex11_drv:-no}
1089     enable_opengl32=${enable_opengl32:-no}
1090     enable_glu32=${enable_glu32:-no}
1091 fi
1092 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1093 without X support, which probably isn't what you want. You will need
1094 to install ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1095
1096 dnl **** Check for libxml2 ****
1097
1098 AC_SUBST(XML2LIBS,"")
1099 AC_SUBST(XML2INCL,"")
1100 AC_SUBST(XSLTINCL,"")
1101 if test "x$with_xml" != "xno"
1102 then
1103     ac_save_CPPFLAGS="$CPPFLAGS"
1104     if test "$PKG_CONFIG" != "false"
1105     then
1106         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
1107         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
1108     else
1109         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
1110         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
1111     fi
1112     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
1113     AC_CHECK_HEADERS(libxml/parser.h,
1114             [AC_CHECK_LIB(xml2, xmlParseMemory,
1115                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
1116                  XML2LIBS="$ac_xml_libs"
1117                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
1118              AC_CHECK_LIB(xml2, xmlReadMemory,
1119                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
1120              AC_CHECK_LIB(xml2, xmlNewDocPI,
1121                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
1122              AC_CHECK_LIB(xml2, xmlSchemaSetParserStructuredErrors,
1123                 [AC_DEFINE(HAVE_XMLSCHEMASSETPARSERSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetParserStructuredErrors function])],,$ac_xml_libs)
1124              AC_CHECK_LIB(xml2, xmlSchemaSetValidStructuredErrors,
1125                 [AC_DEFINE(HAVE_XMLSCHEMASSETVALIDSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetValidStructuredErrors function])],,$ac_xml_libs)
1126              AC_CHECK_LIB(xml2, xmlFirstElementChild,
1127                 [AC_DEFINE(HAVE_XMLFIRSTELEMENTCHILD,1,[Define if libxml2 has the xmlFirstElementChild function])],,$ac_xml_libs)
1128              AC_CHECK_TYPE([xmlDocProperties],
1129                 [AC_DEFINE(HAVE_XMLDOC_PROPERTIES,1,[Define if libxml2 has the xmlDocProperties enum])],,[[#include <libxml/tree.h>]])
1130         ])
1131     CPPFLAGS="$ac_save_CPPFLAGS"
1132 fi
1133 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1134                  [libxml2 ${notice_platform}development files not found, XML won't be supported.])
1135
1136 if test "x$with_xslt" != "xno"
1137 then
1138     if test "$PKG_CONFIG" != "false"
1139     then
1140         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
1141         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
1142     else
1143         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
1144         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
1145     fi
1146     ac_save_CPPFLAGS="$CPPFLAGS"
1147     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
1148     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1149     [#ifdef HAVE_LIBXSLT_PATTERN_H
1150 # include <libxslt/pattern.h>
1151 #endif])
1152     CPPFLAGS="$ac_save_CPPFLAGS"
1153     if test "$ac_cv_header_libxslt_transform_h" = "yes"
1154     then
1155         WINE_CHECK_SONAME(xslt,xsltCompilePattern,
1156                          [XSLTINCL="$ac_xslt_cflags"],,[$ac_xslt_libs])
1157     fi
1158 fi
1159 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1160                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1161
1162 dnl **** Check for libhal ****
1163 AC_SUBST(HALINCL,"")
1164 if test "x$with_hal" != "xno"
1165 then
1166     ac_save_CPPFLAGS="$CPPFLAGS"
1167     if test "$PKG_CONFIG" != "false"
1168     then
1169         ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
1170         ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
1171         CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
1172     fi
1173     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
1174     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
1175     then
1176         AC_CHECK_LIB(dbus-1, dbus_connection_close,
1177           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
1178             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
1179     fi
1180     CPPFLAGS="$ac_save_CPPFLAGS"
1181 fi
1182 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x" -a "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1183                  [libhal/libdbus ${notice_platform}development files not found, no dynamic device support.])
1184
1185 dnl **** Check for libgnutls ****
1186 if test "x$with_gnutls" != "xno"
1187 then
1188     ac_save_CPPFLAGS="$CPPFLAGS"
1189     if test "$PKG_CONFIG" != "false"
1190     then
1191         ac_gnutls_libs="`$PKG_CONFIG --libs gnutls 2>/dev/null`"
1192         ac_gnutls_cflags="`$PKG_CONFIG --cflags gnutls 2>/dev/null`"
1193         CPPFLAGS="$CPPFLAGS $ac_gnutls_cflags"
1194     fi
1195     AC_CHECK_HEADER(gnutls/gnutls.h,
1196         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[typeof(gnutls_mac_get_key_size) *pfunc;]])],
1197             [WINE_CHECK_SONAME(gnutls,gnutls_global_init,
1198                 [AC_SUBST(GNUTLSINCL,"$ac_gnutls_cflags")],,[$ac_gnutls_libs])])])
1199     CPPFLAGS="$ac_save_CPPFLAGS"
1200 fi
1201 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1202                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1203
1204 dnl **** Check which curses lib to use ***
1205 CURSESLIBS=""
1206 if test "$ac_cv_header_ncurses_h" = "yes"
1207 then
1208     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1209 elif test "$ac_cv_header_curses_h" = "yes"
1210 then
1211     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1212 fi
1213 ac_save_LIBS="$LIBS"
1214 LIBS="$LIBS $CURSESLIBS"
1215 AC_CHECK_FUNCS(mousemask)
1216 LIBS="$ac_save_LIBS"
1217 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1218                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1219
1220 dnl **** Check for SANE ****
1221 if test "x$with_sane" != "xno"
1222 then
1223     ac_save_CPPFLAGS="$CPPFLAGS"
1224     AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
1225     if test "$sane_devel" != "no"
1226     then
1227         ac_sane_incl="`$sane_devel --cflags`"
1228         ac_sane_libs="`$sane_devel --ldflags`"
1229         CPPFLAGS="$CPPFLAGS $ac_sane_incl"
1230     fi
1231     AC_CHECK_HEADER(sane/sane.h,
1232         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
1233     CPPFLAGS="$ac_save_CPPFLAGS"
1234 fi
1235 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1236                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1237
1238 dnl **** Check for libv4l1 ****
1239 if test "x$with_v4l" != "xno"
1240 then
1241     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1242 fi
1243 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1244                  [libv4l ${notice_platform}development files not found.])
1245
1246 dnl **** Check for libgphoto2 ****
1247 if test "x$with_gphoto" != "xno"
1248 then
1249     ac_save_CPPFLAGS="$CPPFLAGS"
1250     AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
1251     AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
1252     if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
1253     then
1254         ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
1255         ac_gphoto2_libs=""
1256         for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
1257         do
1258             case "$i" in
1259             -L/usr/lib|-L/usr/lib64) ;;
1260             -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
1261             esac
1262         done
1263         CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
1264     fi
1265     ac_gphoto2_libs=${ac_gphoto2_libs:-"-lgphoto2"}
1266     AC_CHECK_HEADER(gphoto2-camera.h,
1267                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
1268                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
1269                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
1270                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
1271                                   [$ac_gphoto2_libs])])
1272     CPPFLAGS="$ac_save_CPPFLAGS"
1273 fi
1274 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1275                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1276
1277
1278 dnl **** Check for resolver library ***
1279 if test "$ac_cv_header_resolv_h" = "yes"
1280 then
1281     ac_save_LIBS="$LIBS"
1282     for lib in '' -lresolv
1283     do
1284       LIBS="$lib $ac_save_LIBS"
1285       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1286 #include <netinet/in.h>
1287 #endif
1288 #include <resolv.h>]],[[res_query("foo",ns_c_in,0,0,0);]])],
1289         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1290          AC_SUBST(RESOLVLIBS,"$lib")])
1291       if test "${RESOLVLIBS+set}" = set; then
1292         break
1293       fi
1294     done
1295     LIBS="$ac_save_LIBS"
1296 fi
1297
1298 dnl **** Check for LittleCMS ***
1299 AC_SUBST(LCMSLIBS,"")
1300 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
1301 then
1302     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
1303         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
1304          LCMSLIBS="-llcms"])
1305 fi
1306 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
1307                  [liblcms ${notice_platform}development files not found, Color Management won't be supported.])
1308
1309 dnl **** Check for FreeType 2 ****
1310 if test "x$with_freetype" != "xno"
1311 then
1312     AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],no)
1313     if test "$ft_devel" != "no"
1314     then
1315         ac_freetype_incl=`$ft_devel --cflags`
1316         ac_freetype_libs=`$ft_devel --libs`
1317     fi
1318     ac_freetype_libs=${ac_freetype_libs:-"-lfreetype"}
1319     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
1320     if test "$ft_lib" = "yes"
1321     then
1322         ac_save_CPPFLAGS="$CPPFLAGS"
1323         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1324         AC_CHECK_HEADERS(ft2build.h \
1325                          freetype/freetype.h \
1326                          freetype/ftglyph.h \
1327                          freetype/fttypes.h \
1328                          freetype/tttables.h \
1329                          freetype/ftsnames.h \
1330                          freetype/ttnameid.h \
1331                          freetype/ftoutln.h \
1332                          freetype/ftwinfnt.h \
1333                          freetype/ftmodapi.h \
1334                          freetype/ftlcdfil.h \
1335                          freetype/internal/sfnt.h,,,
1336                          [#ifdef HAVE_FT2BUILD_H
1337                           # include <ft2build.h>
1338                           #endif])
1339         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1340                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1341           [Define if you have the <freetype/fttrigon.h> header file.])
1342                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1343         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1344         ac_save_CFLAGS="$CFLAGS"
1345         CFLAGS="$CFLAGS $ac_freetype_libs"
1346         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1347         CFLAGS="$ac_save_CFLAGS"
1348         CPPFLAGS="$ac_save_CPPFLAGS"
1349         dnl Check that we have at least freetype/freetype.h
1350         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1351         then
1352             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1353             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1354             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1355         fi
1356     fi
1357 fi
1358 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType ${notice_platform}development files not found. Fonts will not be built.])
1359 test "x$FREETYPELIBS" = "x" && enable_fonts=${enable_fonts:-no}
1360
1361 dnl **** Check for parport (currently Linux only) ****
1362 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1363  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1364 # include <sys/ioctl.h>
1365 #endif
1366 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1367     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1368 if test "$ac_cv_c_ppdev" = "yes"
1369 then
1370     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1371 fi
1372
1373 dnl **** Check for pthread functions ****
1374 WINE_CHECK_LIB_FUNCS(\
1375         pthread_attr_get_np \
1376         pthread_getattr_np \
1377         pthread_get_stackaddr_np \
1378         pthread_get_stacksize_np,
1379         [$LIBPTHREAD])
1380
1381 dnl **** Check for zlib ****
1382 if test "$ac_cv_header_zlib_h" = "yes"
1383 then
1384     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1385                             AC_SUBST(ZLIB,"-lz")])
1386 fi
1387
1388 dnl **** Check for EsounD ****
1389 if test "x$with_esd" != xno
1390 then
1391     save_CFLAGS="$CFLAGS"
1392     AC_PATH_PROG(ESDCONFIG, esd-config, no)
1393     if test "x$ESDCONFIG" != "xno"
1394     then
1395         ac_esd_incl=""
1396         for i in `$ESDCONFIG --cflags`
1397         do
1398             case "$i" in
1399                 -I*) ac_esd_incl="$ac_esd_incl $i";;
1400             esac
1401         done
1402         ac_esd_libs=`$ESDCONFIG --libs`
1403         CFLAGS="$CFLAGS $ac_esd_incl"
1404     fi
1405     ac_esd_libs=${ac_esd_libs:-"-lesd"}
1406     AC_CHECK_HEADER(esd.h,
1407         [AC_CHECK_LIB(esd,esd_open_sound,
1408             [AC_SUBST(ESDINCL, "$ac_esd_incl")
1409              AC_SUBST(ESDLIBS, "$ac_esd_libs")
1410              AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])],,
1411             [$ac_esd_libs])])
1412     CFLAGS="$save_CFLAGS"
1413 fi
1414
1415 dnl **** Check for gstreamer ****
1416 if test "x$with_gstreamer" != "xno"
1417 then
1418     ac_save_CPPFLAGS="$CPPFLAGS"
1419     if test "$PKG_CONFIG" != "false"; then
1420         ac_gst_incl=""
1421         for i in `$PKG_CONFIG --cflags gstreamer-app-0.10 2>/dev/null`
1422         do
1423             case "$i" in
1424                 -I*) ac_gst_incl="$ac_gst_incl $i";;
1425             esac
1426         done
1427         ac_gst_libs="`$PKG_CONFIG --libs gstreamer-app-0.10 2>/dev/null`"
1428         CPPFLAGS="$CPPFLAGS $ac_gst_incl"
1429         AC_CHECK_HEADER([gst/gstpad.h],
1430           [AC_CHECK_HEADER([gst/app/gstappsink.h],
1431              [AC_CHECK_LIB(gstreamer-0.10,gst_pad_get_caps_reffed,
1432                 [AC_CHECK_LIB(gstapp-0.10,gst_app_buffer_new,
1433                     [AC_SUBST(GSTREAMER_LIBS,"$ac_gst_libs")
1434                      AC_SUBST(GSTREAMER_INCL,"$ac_gst_incl")],,[$ac_gst_libs])])])])
1435     fi
1436     CPPFLAGS="$ac_save_CPPFLAGS"
1437 fi
1438 WINE_NOTICE_WITH(gstreamer,[test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" != xyes],
1439                  [gstreamer-0.10 ${notice_platform}development files not found, gstreamer support disabled])
1440 test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" = xyes || enable_winegstreamer=${enable_winegstreamer:-no}
1441
1442 dnl **** Check for ALSA 1.x ****
1443 AC_SUBST(ALSALIBS,"")
1444 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1445 then
1446     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1447         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1448 #include <alsa/asoundlib.h>
1449 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1450 #include <sys/asoundlib.h>
1451 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1452                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1453                          ALSALIBS="-lasound"],[])])
1454 fi
1455
1456 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1457 AC_SUBST(AUDIOIOLIBS,"")
1458 if test "$ac_cv_header_libaudioio_h" = "yes"
1459 then
1460     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1461                   [AUDIOIOLIBS="-laudioio"
1462                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1463 fi
1464
1465 dnl **** Check for capi4linux ****
1466
1467 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1468 then
1469     WINE_CHECK_SONAME(capi20,capi20_register)
1470 fi
1471 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1472                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1473
1474 dnl **** Check for cups ****
1475 AC_SUBST(CUPSINCL,"")
1476 if test "x$with_cups" != "xno"
1477 then
1478     ac_save_CPPFLAGS="$CPPFLAGS"
1479     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1480     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1481     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1482     AC_CHECK_HEADERS(cups/cups.h,
1483             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1484                        [CUPSINCL="$ac_cups_cflags"],,
1485                        [$ac_cups_libs])])
1486     CPPFLAGS="$ac_save_CPPFLAGS"
1487 fi
1488 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1489                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1490
1491 dnl **** Check for jack ****
1492 if test "$ac_cv_header_jack_jack_h" = "yes"
1493 then
1494     WINE_CHECK_SONAME(jack,jack_client_new,,,,[[libjack-*[[0-9.]]*]])
1495 fi
1496
1497 dnl **** Check for fontconfig ****
1498 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1499 then
1500     WINE_CHECK_SONAME(fontconfig,FcInit)
1501 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1502 then
1503     dnl fontconfig is in the X directory on Mac OS X
1504     ac_save_CPPFLAGS="$CPPFLAGS"
1505     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1506     $as_unset ac_cv_header_fontconfig_fontconfig_h
1507     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1508     CPPFLAGS="$ac_save_CPPFLAGS"
1509     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1510     then
1511         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1512         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1513     fi
1514 fi
1515 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1516                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1517
1518 dnl **** Check for SSL ****
1519 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1520 then
1521     WINE_CHECK_SONAME(ssl,SSL_library_init)
1522     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1523 fi
1524 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1525                  [OpenSSL ${notice_platform}development files not found, SSL won't be supported.])
1526
1527 dnl **** Check for gsm codec ****
1528 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1529 then
1530     WINE_CHECK_SONAME(gsm,gsm_create)
1531 fi
1532 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1533                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1534
1535 dnl **** Check for libicns ****
1536 if test "$ac_cv_header_icns_h" = "yes"
1537 then
1538     WINE_CHECK_SONAME(icns,icns_write_family_to_file)
1539 fi
1540 case $host_os in
1541   darwin*|macosx*)
1542     WINE_NOTICE_WITH(icns,[test "x$ac_cv_lib_soname_icns" = "x"],
1543                      [libicns ${notice_platform}development files not found, ICNS icons won't be supported.]) ;;
1544 esac
1545
1546 dnl **** Check for libjpeg ****
1547 if test "$ac_cv_header_jpeglib_h" = "yes"
1548 then
1549     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1550 fi
1551 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1552                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1553
1554 dnl **** Check for libpng ****
1555 if test "$ac_cv_header_png_h" = "yes"
1556 then
1557     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm -lz,[[libpng[[0-9]]*]])
1558     AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1559         [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])]
1560         ,,-lm -lz)
1561 elif test -n "$X_CFLAGS" -a "x$with_png" != "xno"
1562 then
1563     dnl libpng is in the X directory on Mac OS X
1564     ac_save_CPPFLAGS="$CPPFLAGS"
1565     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1566     $as_unset ac_cv_header_png_h
1567     AC_CHECK_HEADERS([png.h])
1568     CPPFLAGS="$ac_save_CPPFLAGS"
1569     if test "$ac_cv_header_png_h" = "yes"
1570     then
1571         AC_SUBST(PNGINCL,"$X_CFLAGS")
1572         WINE_CHECK_SONAME(png,png_create_read_struct,,,[$X_LIBS -lm -lz],[[libpng[[0-9]]*]])
1573         AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1574                 [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1)],,[$X_LIBS -lm -lz])
1575     fi
1576 fi
1577 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1578                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1579
1580 dnl **** Check for libtiff ****
1581 if test "$ac_cv_header_tiffio_h" = "yes"
1582 then
1583     WINE_CHECK_SONAME(tiff,TIFFClientOpen)
1584 fi
1585 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1586                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1587
1588 dnl **** Check for mpg123 ****
1589 if test "$ac_cv_header_mpg123_h" = "yes"
1590 then
1591     AC_CHECK_LIB(mpg123,mpg123_feed,[AC_SUBST(LIBMPG123,"-lmpg123")])
1592 fi
1593 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1594                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1595 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_header_AudioToolbox_AudioConverter_h" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1596
1597 dnl **** Check for OpenAL 1.1 ****
1598 if test "$ac_cv_header_AL_al_h" = "yes"
1599 then
1600     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1601                       ac_cv_lib_openal=yes
1602                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1603 fi
1604 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1605                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1606 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1607
1608 dnl **** Check for libkstat ****
1609 if test "$ac_cv_header_kstat_h" = "yes"
1610 then
1611     AC_CHECK_LIB(kstat,kstat_open,
1612                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1613                   AC_SUBST(LIBKSTAT,"-lkstat")])
1614 fi
1615
1616 dnl **** Check for libodbc ****
1617 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1618
1619 dnl **** Check for any sound system ****
1620 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESDLIBS$ac_cv_lib_soname_jack" = "x" -a \
1621         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1622         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1623         "$ac_cv_header_soundcard_h" != "yes" -a \
1624         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1625 then
1626     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1627 fi
1628
1629 dnl **** Check for gcc specific options ****
1630
1631 AC_SUBST(EXTRACFLAGS,"")
1632 if test "x${GCC}" = "xyes"
1633 then
1634   EXTRACFLAGS="-Wall -pipe"
1635
1636   dnl Check for strength-reduce bug
1637   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1638                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1639 [[static int Array[[3]];
1640   unsigned int B = 3;
1641   int i;
1642   for(i=0; i<B; i++) Array[[i]] = i - 3;
1643   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1644   L[[i]] = 4;
1645   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1646     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1647   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1648   then
1649     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1650   fi
1651
1652   dnl Check for some compiler flags
1653   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1654   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1655   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1656   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1657   WINE_TRY_CFLAGS([-Wtype-limits])
1658   WINE_TRY_CFLAGS([-Wwrite-strings])
1659
1660   dnl Check for noisy string.h
1661   saved_CFLAGS="$CFLAGS"
1662   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1663   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1664       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1665   CFLAGS="$saved_CFLAGS"
1666   if test "$ac_cv_c_string_h_warnings" = "no"
1667   then
1668     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1669   fi
1670
1671   dnl Enable -Werror for maintainer mode
1672   if test "x$enable_maintainer_mode" = "xyes"
1673   then
1674       WINE_TRY_CFLAGS([-Werror])
1675   fi
1676
1677   dnl Check for ms_hook_prologue support
1678   saved_CFLAGS="$CFLAGS"
1679   CFLAGS="$CFLAGS -Werror"
1680   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1681                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1682                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1683   CFLAGS="$saved_CFLAGS"
1684   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1685   then
1686       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1687                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1688   else
1689       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1690   fi
1691 fi
1692
1693 dnl **** Disable Fortify, it has too many false positives
1694
1695 AC_CACHE_CHECK([for the need to disable Fortify], ac_cv_c_fortify_enabled,
1696     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]],
1697 [[#if defined(__USE_FORTIFY_LEVEL) && __USE_FORTIFY_LEVEL > 0
1698 #error Fortify enabled
1699 #endif]])],
1700         [ac_cv_c_fortify_enabled=no],[ac_cv_c_fortify_enabled=yes]))
1701 if test "$ac_cv_c_fortify_enabled" = yes
1702 then
1703     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=0"
1704 fi
1705
1706 dnl **** Check for underscore on external symbols ****
1707
1708 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1709     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1710                       [extern int ac_test;],
1711                       [if (ac_test) return 1],
1712                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1713
1714 case $host_cpu in
1715   *i[[3456789]]86*)
1716     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1717         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1718 [#ifndef _MSC_VER
1719 #define __stdcall __attribute__((__stdcall__))
1720 #endif
1721 int __stdcall ac_test(int i) { return i; }],
1722                           [if (ac_test(1)) return 1],
1723                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1724   *) ac_cv_c_stdcall_suffix="no" ;;
1725 esac
1726
1727 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1728 if test "$ac_cv_c_extern_prefix" = "yes"
1729 then
1730     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1731     asm_name_prefix="_"
1732 else
1733     AC_DEFINE([__ASM_NAME(name)], [name])
1734     asm_name_prefix=""
1735 fi
1736
1737 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1738 if test "$ac_cv_c_stdcall_suffix" = "yes"
1739 then
1740     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1741 else
1742     AC_DEFINE([__ASM_STDCALL(args)],[""])
1743 fi
1744
1745 dnl **** Check how to define a function in assembly code ****
1746
1747 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1748   WINE_TRY_ASM_LINK(
1749       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1750       ac_cv_asm_func_def=".def",
1751     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1752       ac_cv_asm_func_def=".type @function",
1753     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1754       ac_cv_asm_func_def=".type 2",
1755       ac_cv_asm_func_def="unknown")])]))
1756
1757 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1758 case "$ac_cv_asm_func_def" in
1759   ".def")
1760      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1761      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1762   ".type @function")
1763      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1764      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1765   ".type 2")
1766      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1767      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1768   *)
1769      AC_DEFINE([__ASM_FUNC(name)], [""])
1770      asm_func_header="" ;;
1771 esac
1772
1773 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1774     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1775                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1776
1777 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1778     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1779                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1780
1781 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1782     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1783                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1784
1785 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1786 asm_func_trailer=""
1787 if test "$ac_cv_c_dot_previous" = "yes"
1788 then
1789    asm_func_trailer="\\n\\t.previous"
1790 fi
1791 if test "$ac_cv_c_cfi_support" = "yes"
1792 then
1793    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1794    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1795    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1796    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1797 else
1798    AC_DEFINE([__ASM_CFI(str)],[""])
1799 fi
1800
1801 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1802
1803 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1804 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1805 then
1806     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1807 else
1808     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1809 fi
1810 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1811           [Define to a macro to generate an assembly function with C calling convention])
1812 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1813           [Define to a macro to generate an assembly function with stdcall calling convention])
1814
1815 dnl **** Platform-specific checks ****
1816
1817 AC_SUBST(LDPATH,"")
1818 case $build_os in
1819   cygwin*|mingw32*)
1820     AC_SUBST(TOOLSEXT,".exe")
1821     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1822     ;;
1823   darwin*|macosx*)
1824     ;;
1825   *)
1826     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1827     ;;
1828 esac
1829
1830 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1831 case $host_os in
1832   mingw32*)
1833     AC_SUBST(CRTLIBS,"-lmsvcrt")
1834     AC_SUBST(SOCKETLIBS,"-L\$(top_builddir)/dlls/ws2_32 -lws2_32")
1835     ;;
1836 esac
1837
1838 AC_SUBST(MAIN_BINARY,"wine")
1839 test "x$enable_win64" != "xyes" || MAIN_BINARY="wine64"
1840
1841 case $host_cpu in
1842   *i[[3456789]]86*)
1843     case $host_os in
1844       linux*)
1845         AC_SUBST(EXTRA_BINARIES,"wine-preloader") ;;
1846     esac
1847     ;;
1848 esac
1849
1850 dnl **** Check for functions ****
1851
1852 ac_save_CFLAGS="$CFLAGS"
1853 CFLAGS="$CFLAGS $BUILTINFLAG"
1854 AC_CHECK_FUNCS(\
1855         _pclose \
1856         _popen \
1857         _snprintf \
1858         _spawnvp \
1859         _strdup \
1860         _stricmp \
1861         _strnicmp \
1862         _strtoi64 \
1863         _strtoui64 \
1864         _vsnprintf \
1865         asctime_r \
1866         chsize \
1867         dlopen \
1868         epoll_create \
1869         ffs \
1870         finite \
1871         fnmatch \
1872         fork \
1873         fpclass \
1874         fstatfs \
1875         fstatvfs \
1876         ftruncate \
1877         futimes \
1878         futimesat \
1879         getdirentries \
1880         getopt_long \
1881         getpagesize \
1882         getpwuid \
1883         gettid \
1884         gettimeofday \
1885         getuid \
1886         kqueue \
1887         lstat \
1888         memmove \
1889         mmap \
1890         pclose \
1891         pipe2 \
1892         poll \
1893         popen \
1894         port_create \
1895         prctl \
1896         pread \
1897         pwrite \
1898         readdir \
1899         readlink \
1900         sched_setaffinity \
1901         sched_yield \
1902         select \
1903         setproctitle \
1904         setrlimit \
1905         settimeofday \
1906         sigaltstack \
1907         sigprocmask \
1908         snprintf \
1909         spawnvp \
1910         statfs \
1911         statvfs \
1912         strcasecmp \
1913         strdup \
1914         strerror \
1915         strncasecmp \
1916         strtold \
1917         strtoll \
1918         strtoull \
1919         symlink \
1920         tcgetattr \
1921         thr_kill2 \
1922         timegm \
1923         usleep \
1924         vsnprintf \
1925         wait4 \
1926         waitpid \
1927 )
1928 CFLAGS="$ac_save_CFLAGS"
1929
1930 dnl Check for -ldl
1931 if test "$ac_cv_func_dlopen" = no
1932 then
1933     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1934 fi
1935 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1936
1937 dnl Check for -lpoll for Mac OS X/Darwin
1938 if test "$ac_cv_func_poll" = no
1939 then
1940     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1941 fi
1942
1943 dnl Check for -lnsl for Solaris
1944 AC_SEARCH_LIBS(gethostbyname, nsl)
1945
1946 dnl Check for -lsocket for Solaris
1947 AC_SEARCH_LIBS(connect, socket)
1948
1949 dnl Check for -lresolv for Solaris
1950 AC_SEARCH_LIBS(inet_aton, resolv)
1951
1952 dnl **** Check for functions which may rely on -lsocket on Solaris.
1953 AC_CHECK_FUNCS(\
1954         getaddrinfo \
1955         getnameinfo \
1956         getnetbyname \
1957         getprotobyname \
1958         getprotobynumber \
1959         getservbyport \
1960         inet_network \
1961         inet_ntop \
1962         inet_pton \
1963         sendmsg \
1964         socketpair \
1965 )
1966
1967 dnl **** Check for OpenLDAP ***
1968 AC_SUBST(LDAPLIBS,"")
1969 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
1970 then
1971     AC_CHECK_TYPE(LDAPSortKey,
1972         [AC_CHECK_LIB(ldap_r, ldap_initialize,
1973             [AC_CHECK_LIB(lber, ber_init,
1974                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
1975                  LDAPLIBS="-lldap_r -llber"],,
1976                  [$LIBPTHREAD])],,
1977                  [$LIBPTHREAD])],,
1978         [#include <ldap.h>])
1979     WINE_CHECK_LIB_FUNCS(\
1980         ldap_count_references \
1981         ldap_first_reference \
1982         ldap_next_reference \
1983         ldap_parse_reference \
1984         ldap_parse_sort_control \
1985         ldap_parse_sortresponse_control \
1986         ldap_parse_vlv_control \
1987         ldap_parse_vlvresponse_control,
1988         [$LDAPLIBS $LIBPTHREAD])
1989 fi
1990 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
1991                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
1992
1993 AC_CACHE_CHECK([whether mkdir takes only one argument],
1994         wine_cv_one_arg_mkdir,
1995         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
1996                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
1997 if test "$wine_cv_one_arg_mkdir" = "yes"
1998 then
1999   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
2000 fi
2001
2002 dnl **** Check for types ****
2003
2004 AC_C_CONST
2005 AC_C_INLINE
2006 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
2007 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
2008 #include <signal.h>])
2009 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
2010
2011 AC_CHECK_TYPES([struct xinpgen],,,
2012 [#include <sys/types.h>
2013 #ifdef HAVE_SYS_SOCKET_H
2014 #include <sys/socket.h>
2015 #endif
2016 #ifdef HAVE_SYS_SOCKETVAR_H
2017 #include <sys/socketvar.h>
2018 #endif
2019 #ifdef HAVE_NET_ROUTE_H
2020 #include <net/route.h>
2021 #endif
2022 #ifdef HAVE_NETINET_IN_H
2023 #include <netinet/in.h>
2024 #endif
2025 #ifdef HAVE_NETINET_IN_SYSTM_H
2026 #include <netinet/in_systm.h>
2027 #endif
2028 #ifdef HAVE_NETINET_IP_H
2029 #include <netinet/ip.h>
2030 #endif
2031 #ifdef HAVE_NETINET_IN_PCB_H
2032 #include <netinet/in_pcb.h>
2033 #endif])
2034
2035 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
2036 [#ifdef HAVE_LINUX_INPUT_H
2037 #include <linux/input.h>
2038 #endif])
2039
2040 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
2041                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
2042 if test "$wine_cv_have_sigaddset" = "yes"
2043 then
2044   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
2045 fi
2046
2047
2048 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
2049         wine_cv_linux_gethostbyname_r_6,
2050         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
2051     char *name=0;
2052     struct hostent he;
2053     struct hostent *result;
2054     char *buf=0;
2055     int bufsize=0;
2056     int res,errnr;
2057     char *addr=0;
2058     int addrlen=0;
2059     int addrtype=0;
2060     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
2061     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
2062     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
2063         ])
2064    )
2065    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
2066    then
2067       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
2068                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
2069    fi
2070
2071 if test "$ac_cv_header_linux_joystick_h" = "yes"
2072 then
2073    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
2074         wine_cv_linux_joystick_22_api,
2075         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2076         #include <sys/ioctl.h>
2077         #include <sys/types.h>
2078         #include <linux/joystick.h>
2079
2080         struct js_event blub;
2081         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
2082         #error "no 2.2 header"
2083         #endif
2084         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
2085    )
2086    if test "$wine_cv_linux_joystick_22_api" = "yes"
2087    then
2088       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
2089                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
2090    fi
2091 fi
2092
2093 dnl **** FIXME: what about mixed cases, where we need two of them? ***
2094
2095 dnl Check for statfs members
2096 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
2097 [#include <sys/types.h>
2098 #ifdef HAVE_SYS_PARAM_H
2099 # include <sys/param.h>
2100 #endif
2101 #ifdef HAVE_SYS_MOUNT_H
2102 # include <sys/mount.h>
2103 #endif
2104 #ifdef HAVE_SYS_VFS_H
2105 # include <sys/vfs.h>
2106 #endif
2107 #ifdef HAVE_SYS_STATFS_H
2108 # include <sys/statfs.h>
2109 #endif])
2110
2111 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2112 [#ifdef HAVE_SYS_STATVFS_H
2113 #include <sys/statvfs.h>
2114 #endif])
2115
2116 dnl Check for socket structure members
2117 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2118 [#include <sys/types.h>
2119 #ifdef HAVE_SYS_SOCKET_H
2120 # include <sys/socket.h>
2121 #endif
2122 #ifdef HAVE_SYS_UN_H
2123 # include <sys/un.h>
2124 #endif])
2125
2126 dnl Check for scsireq_t and sg_io_hdr_t members
2127 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2128 [#include <sys/types.h>
2129 #ifdef HAVE_SCSI_SG_H
2130 #include <scsi/sg.h>
2131 #endif])
2132
2133 dnl Check for siginfo_t members
2134 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2135
2136 dnl Check for struct mtget members
2137 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2138 [#include <sys/types.h>
2139 #ifdef HAVE_SYS_MTIO_H
2140 #include <sys/mtio.h>
2141 #endif])
2142
2143 dnl Check for struct option
2144 AC_CHECK_MEMBERS([struct option.name],,,
2145 [#ifdef HAVE_GETOPT_H
2146 #include <getopt.h>
2147 #endif])
2148
2149 dnl Check for stat.st_blocks and ns-resolved times
2150 AC_CHECK_MEMBERS([struct stat.st_blocks,struct stat.st_mtim,struct stat.st_ctim,struct stat.st_atim])
2151
2152 dnl Check for sin6_scope_id
2153 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2154 [#ifdef HAVE_SYS_TYPES_H
2155 #include <sys/types.h>
2156 #endif
2157 #ifdef HAVE_NETINET_IN_H
2158 #include <netinet/in.h>
2159 #endif])
2160
2161 dnl Check for ns_msg ptr member
2162 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2163 [#ifdef HAVE_SYS_TYPES_H
2164 #include <sys/types.h>
2165 #endif
2166 #ifdef HAVE_NETINET_IN_H
2167 # include <netinet/in.h>
2168 #endif
2169 #ifdef HAVE_ARPA_NAMESER_H
2170 # include <arpa/nameser.h>
2171 #endif])
2172
2173 dnl Check for struct icmpstat.icps_outhist
2174 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2175 [#ifdef HAVE_SYS_TYPES_H
2176 #include <sys/types.h>
2177 #endif
2178 #ifdef HAVE_ALIAS_H
2179 #include <alias.h>
2180 #endif
2181 #ifdef HAVE_SYS_SOCKET_H
2182 #include <sys/socket.h>
2183 #endif
2184 #ifdef HAVE_SYS_SOCKETVAR_H
2185 #include <sys/socketvar.h>
2186 #endif
2187 #ifdef HAVE_SYS_TIMEOUT_H
2188 #include <sys/timeout.h>
2189 #endif
2190 #ifdef HAVE_NETINET_IN_H
2191 #include <netinet/in.h>
2192 #endif
2193 #ifdef HAVE_NETINET_IN_SYSTM_H
2194 #include <netinet/in_systm.h>
2195 #endif
2196 #ifdef HAVE_NETINET_IP_H
2197 #include <netinet/ip.h>
2198 #endif
2199 #ifdef HAVE_NETINET_IP_VAR_H
2200 #include <netinet/ip_var.h>
2201 #endif
2202 #ifdef HAVE_NETINET_IP_ICMP_H
2203 #include <netinet/ip_icmp.h>
2204 #endif
2205 #ifdef HAVE_NETINET_ICMP_VAR
2206 #include <netinet/icmp_var.h>
2207 #endif])
2208
2209 dnl Check for struct ifreq.ifr_hwaddr
2210 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2211 [#ifdef HAVE_SYS_TYPES_H
2212 #include <sys/types.h>
2213 #endif
2214 #ifdef HAVE_NET_IF_H
2215 # include <net/if.h>
2216 #endif])
2217
2218 dnl Check for the external timezone variables timezone and daylight
2219 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2220                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2221 if test "$ac_cv_have_timezone" = "yes"
2222 then
2223     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2224 fi
2225 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2226                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2227 if test "$ac_cv_have_daylight" = "yes"
2228 then
2229     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2230 fi
2231
2232 dnl Check for isinf
2233 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2234                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2235 if test "$ac_cv_have_isinf" = "yes"
2236 then
2237     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2238 fi
2239
2240 dnl Check for isnan
2241 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2242                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2243 if test "$ac_cv_have_isnan" = "yes"
2244 then
2245     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2246 fi
2247
2248 dnl *** check for the need to define platform-specific symbols
2249
2250 case $host_cpu in
2251   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2252   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2253   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
2254   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2255   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2256 esac
2257
2258 case $host_vendor in
2259   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2260 esac
2261
2262 dnl **** Generate output files ****
2263
2264 AH_TOP([#ifndef WINE_CROSSTEST
2265 #define __WINE_CONFIG_H])
2266 AH_BOTTOM([#endif /* WINE_CROSSTEST */])
2267
2268 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2269
2270 WINE_CONFIG_SYMLINK(dlls/shell32/AUTHORS,AUTHORS)
2271 WINE_CONFIG_SYMLINK(dlls/wineps.drv/generic.ppd)
2272 WINE_CONFIG_SYMLINK(fonts/marlett.ttf,,enable_fonts)
2273 WINE_CONFIG_SYMLINK(fonts/symbol.ttf,,enable_fonts)
2274 WINE_CONFIG_SYMLINK(fonts/tahoma.ttf,,enable_fonts)
2275 WINE_CONFIG_SYMLINK(fonts/tahomabd.ttf,,enable_fonts)
2276 WINE_CONFIG_SYMLINK(tools/l_intl.nls)
2277 WINE_CONFIG_SYMLINK(wine,tools/winewrapper)
2278
2279 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2280 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2281 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2282 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2283 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2284 WINE_CONFIG_EXTRA_DIR(include/wine)
2285
2286 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2287 WINE_CONFIG_MAKERULES([Maketest.rules],[MAKE_TEST_RULES],[Make.rules])
2288 WINE_CONFIG_MAKERULES([dlls/Makedll.rules],[MAKE_DLL_RULES],[Make.rules])
2289 WINE_CONFIG_MAKERULES([dlls/Makeimplib.rules],[MAKE_IMPLIB_RULES],[Make.rules])
2290 WINE_CONFIG_MAKERULES([programs/Makeprog.rules],[MAKE_PROG_RULES],[Make.rules])
2291
2292 WINE_CONFIG_DLL(acledit)
2293 WINE_CONFIG_DLL(aclui,,[aclui])
2294 WINE_CONFIG_DLL(activeds,,[activeds])
2295 WINE_CONFIG_DLL(actxprxy)
2296 WINE_CONFIG_LIB(adsiid)
2297 WINE_CONFIG_DLL(advapi32,,[advapi32])
2298 WINE_CONFIG_TEST(dlls/advapi32/tests)
2299 WINE_CONFIG_DLL(advpack,,[advpack])
2300 WINE_CONFIG_TEST(dlls/advpack/tests)
2301 WINE_CONFIG_DLL(amstream)
2302 WINE_CONFIG_TEST(dlls/amstream/tests)
2303 WINE_CONFIG_DLL(appwiz.cpl)
2304 WINE_CONFIG_DLL(atl,,[atl])
2305 WINE_CONFIG_TEST(dlls/atl/tests)
2306 WINE_CONFIG_DLL(authz)
2307 WINE_CONFIG_DLL(avicap32,,[avicap32])
2308 WINE_CONFIG_DLL(avifil32,,[avifil32])
2309 WINE_CONFIG_TEST(dlls/avifil32/tests)
2310 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2311 WINE_CONFIG_DLL(avrt,,[avrt])
2312 WINE_CONFIG_DLL(bcrypt)
2313 WINE_CONFIG_DLL(browseui)
2314 WINE_CONFIG_TEST(dlls/browseui/tests)
2315 WINE_CONFIG_DLL(cabinet,,[cabinet])
2316 WINE_CONFIG_TEST(dlls/cabinet/tests)
2317 WINE_CONFIG_DLL(capi2032,,[capi2032])
2318 WINE_CONFIG_DLL(cards,,[cards])
2319 WINE_CONFIG_DLL(cfgmgr32,,[cfgmgr32])
2320 WINE_CONFIG_DLL(clusapi,,[clusapi])
2321 WINE_CONFIG_DLL(comcat)
2322 WINE_CONFIG_TEST(dlls/comcat/tests)
2323 WINE_CONFIG_DLL(comctl32,,[comctl32])
2324 WINE_CONFIG_TEST(dlls/comctl32/tests)
2325 WINE_CONFIG_DLL(comdlg32,,[comdlg32])
2326 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2327 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2328 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2329 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2330 WINE_CONFIG_DLL(compstui,,[compstui])
2331 WINE_CONFIG_DLL(credui,,[credui])
2332 WINE_CONFIG_TEST(dlls/credui/tests)
2333 WINE_CONFIG_DLL(crtdll,,[crtdll])
2334 WINE_CONFIG_DLL(crypt32,,[crypt32])
2335 WINE_CONFIG_TEST(dlls/crypt32/tests)
2336 WINE_CONFIG_DLL(cryptdlg)
2337 WINE_CONFIG_DLL(cryptdll,,[cryptdll])
2338 WINE_CONFIG_DLL(cryptnet,,[cryptnet])
2339 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2340 WINE_CONFIG_DLL(cryptui,,[cryptui])
2341 WINE_CONFIG_TEST(dlls/cryptui/tests)
2342 WINE_CONFIG_DLL(ctapi32)
2343 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2344 WINE_CONFIG_DLL(ctl3d32,,[ctl3d32])
2345 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2346 WINE_CONFIG_DLL(d3d10,,[d3d10])
2347 WINE_CONFIG_TEST(dlls/d3d10/tests)
2348 WINE_CONFIG_DLL(d3d10core,,[d3d10core])
2349 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2350 WINE_CONFIG_DLL(d3d8,,[d3d8])
2351 WINE_CONFIG_TEST(dlls/d3d8/tests)
2352 WINE_CONFIG_DLL(d3d9,,[d3d9])
2353 WINE_CONFIG_TEST(dlls/d3d9/tests)
2354 WINE_CONFIG_DLL(d3dcompiler_33)
2355 WINE_CONFIG_DLL(d3dcompiler_34)
2356 WINE_CONFIG_DLL(d3dcompiler_35)
2357 WINE_CONFIG_DLL(d3dcompiler_36)
2358 WINE_CONFIG_DLL(d3dcompiler_37)
2359 WINE_CONFIG_DLL(d3dcompiler_38)
2360 WINE_CONFIG_DLL(d3dcompiler_39)
2361 WINE_CONFIG_DLL(d3dcompiler_40)
2362 WINE_CONFIG_DLL(d3dcompiler_41)
2363 WINE_CONFIG_DLL(d3dcompiler_42)
2364 WINE_CONFIG_DLL(d3dcompiler_43,,[d3dcompiler])
2365 WINE_CONFIG_TEST(dlls/d3dcompiler_43/tests)
2366 WINE_CONFIG_DLL(d3dim,,[d3dim])
2367 WINE_CONFIG_DLL(d3drm,,[d3drm])
2368 WINE_CONFIG_TEST(dlls/d3drm/tests)
2369 WINE_CONFIG_DLL(d3dx10_33)
2370 WINE_CONFIG_DLL(d3dx10_34)
2371 WINE_CONFIG_DLL(d3dx10_35)
2372 WINE_CONFIG_DLL(d3dx10_36)
2373 WINE_CONFIG_DLL(d3dx10_37)
2374 WINE_CONFIG_DLL(d3dx10_38)
2375 WINE_CONFIG_DLL(d3dx10_39)
2376 WINE_CONFIG_DLL(d3dx10_40)
2377 WINE_CONFIG_DLL(d3dx10_41)
2378 WINE_CONFIG_DLL(d3dx10_42)
2379 WINE_CONFIG_DLL(d3dx10_43)
2380 WINE_CONFIG_DLL(d3dx9_24)
2381 WINE_CONFIG_DLL(d3dx9_25)
2382 WINE_CONFIG_DLL(d3dx9_26)
2383 WINE_CONFIG_DLL(d3dx9_27)
2384 WINE_CONFIG_DLL(d3dx9_28)
2385 WINE_CONFIG_DLL(d3dx9_29)
2386 WINE_CONFIG_DLL(d3dx9_30)
2387 WINE_CONFIG_DLL(d3dx9_31)
2388 WINE_CONFIG_DLL(d3dx9_32)
2389 WINE_CONFIG_DLL(d3dx9_33)
2390 WINE_CONFIG_DLL(d3dx9_34)
2391 WINE_CONFIG_DLL(d3dx9_35)
2392 WINE_CONFIG_DLL(d3dx9_36,,[d3dx9])
2393 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2394 WINE_CONFIG_DLL(d3dx9_37)
2395 WINE_CONFIG_DLL(d3dx9_38)
2396 WINE_CONFIG_DLL(d3dx9_39)
2397 WINE_CONFIG_DLL(d3dx9_40)
2398 WINE_CONFIG_DLL(d3dx9_41)
2399 WINE_CONFIG_DLL(d3dx9_42)
2400 WINE_CONFIG_DLL(d3dx9_43)
2401 WINE_CONFIG_DLL(d3dxof,,[d3dxof])
2402 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2403 WINE_CONFIG_DLL(dbghelp,,[dbghelp])
2404 WINE_CONFIG_DLL(dciman32,,[dciman32])
2405 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2406 WINE_CONFIG_DLL(ddraw,,[ddraw])
2407 WINE_CONFIG_TEST(dlls/ddraw/tests)
2408 WINE_CONFIG_DLL(ddrawex)
2409 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2410 WINE_CONFIG_DLL(devenum)
2411 WINE_CONFIG_DLL(dinput,,[dinput],[data_formats.c])
2412 WINE_CONFIG_TEST(dlls/dinput/tests)
2413 WINE_CONFIG_DLL(dinput8,,[dinput8])
2414 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2415 WINE_CONFIG_DLL(dispex)
2416 WINE_CONFIG_TEST(dlls/dispex/tests)
2417 WINE_CONFIG_DLL(display.drv16,enable_win16)
2418 WINE_CONFIG_DLL(dmband)
2419 WINE_CONFIG_DLL(dmcompos)
2420 WINE_CONFIG_DLL(dmime)
2421 WINE_CONFIG_TEST(dlls/dmime/tests)
2422 WINE_CONFIG_DLL(dmloader)
2423 WINE_CONFIG_TEST(dlls/dmloader/tests)
2424 WINE_CONFIG_DLL(dmscript)
2425 WINE_CONFIG_DLL(dmstyle)
2426 WINE_CONFIG_DLL(dmsynth)
2427 WINE_CONFIG_DLL(dmusic)
2428 WINE_CONFIG_DLL(dmusic32,,[dmusic32])
2429 WINE_CONFIG_DLL(dnsapi,,[dnsapi])
2430 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2431 WINE_CONFIG_DLL(dplay,,[dplay])
2432 WINE_CONFIG_DLL(dplayx,,[dplayx])
2433 WINE_CONFIG_TEST(dlls/dplayx/tests)
2434 WINE_CONFIG_DLL(dpnaddr)
2435 WINE_CONFIG_DLL(dpnet,,[dpnet])
2436 WINE_CONFIG_DLL(dpnhpast)
2437 WINE_CONFIG_DLL(dpnlobby)
2438 WINE_CONFIG_DLL(dpwsockx)
2439 WINE_CONFIG_DLL(drmclien)
2440 WINE_CONFIG_DLL(dsound,,[dsound])
2441 WINE_CONFIG_TEST(dlls/dsound/tests)
2442 WINE_CONFIG_DLL(dssenh)
2443 WINE_CONFIG_DLL(dswave)
2444 WINE_CONFIG_DLL(dwmapi,,[dwmapi])
2445 WINE_CONFIG_DLL(dxdiagn)
2446 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2447 WINE_CONFIG_LIB(dxerr8)
2448 WINE_CONFIG_LIB(dxerr9)
2449 WINE_CONFIG_DLL(dxgi,,[dxgi])
2450 WINE_CONFIG_TEST(dlls/dxgi/tests)
2451 WINE_CONFIG_LIB(dxguid)
2452 WINE_CONFIG_DLL(explorerframe)
2453 WINE_CONFIG_TEST(dlls/explorerframe/tests)
2454 WINE_CONFIG_DLL(faultrep,,[faultrep])
2455 WINE_CONFIG_TEST(dlls/faultrep/tests)
2456 WINE_CONFIG_DLL(fltlib)
2457 WINE_CONFIG_DLL(fusion)
2458 WINE_CONFIG_TEST(dlls/fusion/tests)
2459 WINE_CONFIG_DLL(fwpuclnt)
2460 WINE_CONFIG_DLL(gameux)
2461 WINE_CONFIG_TEST(dlls/gameux/tests)
2462 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2463 WINE_CONFIG_DLL(gdi32,,[gdi32])
2464 WINE_CONFIG_TEST(dlls/gdi32/tests)
2465 WINE_CONFIG_DLL(gdiplus,,[gdiplus])
2466 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2467 WINE_CONFIG_DLL(glu32,,[glu32])
2468 WINE_CONFIG_DLL(gphoto2.ds)
2469 WINE_CONFIG_DLL(gpkcsp)
2470 WINE_CONFIG_DLL(hal)
2471 WINE_CONFIG_DLL(hhctrl.ocx)
2472 WINE_CONFIG_DLL(hid,,[hid])
2473 WINE_CONFIG_DLL(hlink,,[hlink])
2474 WINE_CONFIG_TEST(dlls/hlink/tests)
2475 WINE_CONFIG_DLL(hnetcfg)
2476 WINE_CONFIG_DLL(httpapi)
2477 WINE_CONFIG_DLL(iccvid)
2478 WINE_CONFIG_DLL(icmp)
2479 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2480 WINE_CONFIG_DLL(imaadp32.acm)
2481 WINE_CONFIG_DLL(imagehlp,,[imagehlp])
2482 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2483 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2484 WINE_CONFIG_DLL(imm32,,[imm32])
2485 WINE_CONFIG_TEST(dlls/imm32/tests)
2486 WINE_CONFIG_DLL(inetcomm,,[inetcomm])
2487 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2488 WINE_CONFIG_DLL(inetcpl.cpl)
2489 WINE_CONFIG_DLL(inetmib1)
2490 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2491 WINE_CONFIG_DLL(infosoft)
2492 WINE_CONFIG_TEST(dlls/infosoft/tests)
2493 WINE_CONFIG_DLL(initpki)
2494 WINE_CONFIG_DLL(inkobj)
2495 WINE_CONFIG_DLL(inseng)
2496 WINE_CONFIG_DLL(iphlpapi,,[iphlpapi])
2497 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2498 WINE_CONFIG_DLL(itircl)
2499 WINE_CONFIG_DLL(itss)
2500 WINE_CONFIG_TEST(dlls/itss/tests)
2501 WINE_CONFIG_DLL(jscript)
2502 WINE_CONFIG_TEST(dlls/jscript/tests)
2503 WINE_CONFIG_DLL(kernel32,,[kernel32])
2504 WINE_CONFIG_TEST(dlls/kernel32/tests)
2505 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2506 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[kernel])
2507 WINE_CONFIG_DLL(ktmw32)
2508 WINE_CONFIG_DLL(loadperf,,[loadperf])
2509 WINE_CONFIG_DLL(localspl)
2510 WINE_CONFIG_TEST(dlls/localspl/tests)
2511 WINE_CONFIG_DLL(localui)
2512 WINE_CONFIG_TEST(dlls/localui/tests)
2513 WINE_CONFIG_DLL(lz32,,[lz32])
2514 WINE_CONFIG_TEST(dlls/lz32/tests)
2515 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2516 WINE_CONFIG_DLL(mapi32,,[mapi32])
2517 WINE_CONFIG_TEST(dlls/mapi32/tests)
2518 WINE_CONFIG_DLL(mapistub)
2519 WINE_CONFIG_DLL(mciavi32)
2520 WINE_CONFIG_DLL(mcicda)
2521 WINE_CONFIG_DLL(mciqtz32)
2522 WINE_CONFIG_DLL(mciseq)
2523 WINE_CONFIG_DLL(mciwave)
2524 WINE_CONFIG_DLL(midimap)
2525 WINE_CONFIG_DLL(mlang,,[mlang])
2526 WINE_CONFIG_TEST(dlls/mlang/tests)
2527 WINE_CONFIG_DLL(mmdevapi)
2528 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2529 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2530 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2531 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2532 WINE_CONFIG_DLL(mountmgr.sys)
2533 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2534 WINE_CONFIG_DLL(mpr,,[mpr])
2535 WINE_CONFIG_DLL(mprapi,,[mprapi])
2536 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2537 WINE_CONFIG_DLL(msacm32.drv)
2538 WINE_CONFIG_DLL(msacm32,,[msacm32])
2539 WINE_CONFIG_TEST(dlls/msacm32/tests)
2540 WINE_CONFIG_DLL(msadp32.acm)
2541 WINE_CONFIG_DLL(mscat32)
2542 WINE_CONFIG_DLL(mscms,,[mscms])
2543 WINE_CONFIG_TEST(dlls/mscms/tests)
2544 WINE_CONFIG_DLL(mscoree)
2545 WINE_CONFIG_TEST(dlls/mscoree/tests)
2546 WINE_CONFIG_DLL(msctf)
2547 WINE_CONFIG_TEST(dlls/msctf/tests)
2548 WINE_CONFIG_DLL(msdaps)
2549 WINE_CONFIG_DLL(msdmo,,[msdmo])
2550 WINE_CONFIG_DLL(msftedit)
2551 WINE_CONFIG_DLL(msg711.acm)
2552 WINE_CONFIG_DLL(msgsm32.acm)
2553 WINE_CONFIG_DLL(mshtml.tlb)
2554 WINE_CONFIG_DLL(mshtml,,[mshtml])
2555 WINE_CONFIG_TEST(dlls/mshtml/tests)
2556 WINE_CONFIG_DLL(msi,,[msi])
2557 WINE_CONFIG_TEST(dlls/msi/tests)
2558 WINE_CONFIG_DLL(msimg32,,[msimg32])
2559 WINE_CONFIG_DLL(msimtf)
2560 WINE_CONFIG_DLL(msisip)
2561 WINE_CONFIG_DLL(msisys.ocx)
2562 WINE_CONFIG_DLL(msnet32)
2563 WINE_CONFIG_DLL(msrle32)
2564 WINE_CONFIG_DLL(mssign32)
2565 WINE_CONFIG_DLL(mssip32)
2566 WINE_CONFIG_DLL(mstask)
2567 WINE_CONFIG_TEST(dlls/mstask/tests)
2568 WINE_CONFIG_DLL(msvcirt)
2569 WINE_CONFIG_DLL(msvcp80)
2570 WINE_CONFIG_DLL(msvcp90)
2571 WINE_CONFIG_TEST(dlls/msvcp90/tests)
2572 WINE_CONFIG_DLL(msvcr100)
2573 WINE_CONFIG_DLL(msvcr70,,[msvcr70])
2574 WINE_CONFIG_DLL(msvcr71,,[msvcr71])
2575 WINE_CONFIG_DLL(msvcr80)
2576 WINE_CONFIG_DLL(msvcr90)
2577 WINE_CONFIG_TEST(dlls/msvcr90/tests)
2578 WINE_CONFIG_DLL(msvcrt,,[msvcrt])
2579 WINE_CONFIG_TEST(dlls/msvcrt/tests)
2580 WINE_CONFIG_DLL(msvcrt20,,[msvcrt20])
2581 WINE_CONFIG_DLL(msvcrt40,,[msvcrt40])
2582 WINE_CONFIG_DLL(msvcrtd,,[msvcrtd])
2583 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
2584 WINE_CONFIG_DLL(msvfw32,,[msvfw32])
2585 WINE_CONFIG_TEST(dlls/msvfw32/tests)
2586 WINE_CONFIG_DLL(msvidc32)
2587 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
2588 WINE_CONFIG_DLL(mswsock,,[mswsock])
2589 WINE_CONFIG_DLL(msxml3)
2590 WINE_CONFIG_TEST(dlls/msxml3/tests)
2591 WINE_CONFIG_DLL(msxml4)
2592 WINE_CONFIG_DLL(msxml6)
2593 WINE_CONFIG_DLL(nddeapi,,[nddeapi])
2594 WINE_CONFIG_DLL(netapi32,,[netapi32])
2595 WINE_CONFIG_TEST(dlls/netapi32/tests)
2596 WINE_CONFIG_DLL(newdev,,[newdev])
2597 WINE_CONFIG_DLL(ntdll,,[ntdll])
2598 WINE_CONFIG_TEST(dlls/ntdll/tests)
2599 WINE_CONFIG_DLL(ntdsapi,,[ntdsapi])
2600 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
2601 WINE_CONFIG_DLL(ntoskrnl.exe,,[ntoskrnl.exe])
2602 WINE_CONFIG_DLL(ntprint)
2603 WINE_CONFIG_TEST(dlls/ntprint/tests)
2604 WINE_CONFIG_DLL(objsel)
2605 WINE_CONFIG_DLL(odbc32,,[odbc32])
2606 WINE_CONFIG_DLL(odbccp32,,[odbccp32])
2607 WINE_CONFIG_TEST(dlls/odbccp32/tests)
2608 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
2609 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
2610 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
2611 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
2612 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
2613 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
2614 WINE_CONFIG_DLL(ole32,,[ole32])
2615 WINE_CONFIG_TEST(dlls/ole32/tests)
2616 WINE_CONFIG_DLL(oleacc,,[oleacc])
2617 WINE_CONFIG_TEST(dlls/oleacc/tests)
2618 WINE_CONFIG_DLL(oleaut32,,[oleaut32])
2619 WINE_CONFIG_TEST(dlls/oleaut32/tests)
2620 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
2621 WINE_CONFIG_DLL(olecli32,,[olecli32])
2622 WINE_CONFIG_DLL(oledb32)
2623 WINE_CONFIG_TEST(dlls/oledb32/tests)
2624 WINE_CONFIG_DLL(oledlg,,[oledlg])
2625 WINE_CONFIG_DLL(olepro32,,[olepro32])
2626 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
2627 WINE_CONFIG_DLL(olesvr32,,[olesvr32])
2628 WINE_CONFIG_DLL(olethk32)
2629 WINE_CONFIG_DLL(openal32)
2630 WINE_CONFIG_DLL(opengl32,,[opengl32])
2631 WINE_CONFIG_TEST(dlls/opengl32/tests)
2632 WINE_CONFIG_DLL(pdh,,[pdh])
2633 WINE_CONFIG_TEST(dlls/pdh/tests)
2634 WINE_CONFIG_DLL(pidgen)
2635 WINE_CONFIG_DLL(powrprof,,[powrprof])
2636 WINE_CONFIG_DLL(printui)
2637 WINE_CONFIG_DLL(propsys,,[propsys])
2638 WINE_CONFIG_TEST(dlls/propsys/tests)
2639 WINE_CONFIG_DLL(psapi,,[psapi])
2640 WINE_CONFIG_TEST(dlls/psapi/tests)
2641 WINE_CONFIG_DLL(pstorec)
2642 WINE_CONFIG_DLL(qcap)
2643 WINE_CONFIG_DLL(qedit)
2644 WINE_CONFIG_TEST(dlls/qedit/tests)
2645 WINE_CONFIG_DLL(qmgr)
2646 WINE_CONFIG_TEST(dlls/qmgr/tests)
2647 WINE_CONFIG_DLL(qmgrprxy)
2648 WINE_CONFIG_DLL(quartz,,[quartz])
2649 WINE_CONFIG_TEST(dlls/quartz/tests)
2650 WINE_CONFIG_DLL(query)
2651 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
2652 WINE_CONFIG_DLL(rasapi32,,[rasapi32])
2653 WINE_CONFIG_TEST(dlls/rasapi32/tests)
2654 WINE_CONFIG_DLL(rasdlg,,[rasdlg])
2655 WINE_CONFIG_DLL(resutils,,[resutils])
2656 WINE_CONFIG_DLL(riched20,,[riched20])
2657 WINE_CONFIG_TEST(dlls/riched20/tests)
2658 WINE_CONFIG_DLL(riched32)
2659 WINE_CONFIG_TEST(dlls/riched32/tests)
2660 WINE_CONFIG_DLL(rpcrt4,,[rpcrt4])
2661 WINE_CONFIG_TEST(dlls/rpcrt4/tests)
2662 WINE_CONFIG_DLL(rsabase)
2663 WINE_CONFIG_DLL(rsaenh,,[rsaenh])
2664 WINE_CONFIG_TEST(dlls/rsaenh/tests)
2665 WINE_CONFIG_DLL(rstrtmgr)
2666 WINE_CONFIG_DLL(rtutils,,[rtutils])
2667 WINE_CONFIG_DLL(samlib)
2668 WINE_CONFIG_DLL(sane.ds)
2669 WINE_CONFIG_DLL(sccbase)
2670 WINE_CONFIG_DLL(schannel)
2671 WINE_CONFIG_TEST(dlls/schannel/tests)
2672 WINE_CONFIG_DLL(secur32,,[secur32])
2673 WINE_CONFIG_TEST(dlls/secur32/tests)
2674 WINE_CONFIG_DLL(security)
2675 WINE_CONFIG_DLL(sensapi,,[sensapi])
2676 WINE_CONFIG_DLL(serialui,,[serialui])
2677 WINE_CONFIG_TEST(dlls/serialui/tests)
2678 WINE_CONFIG_DLL(setupapi,,[setupapi])
2679 WINE_CONFIG_TEST(dlls/setupapi/tests)
2680 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
2681 WINE_CONFIG_DLL(sfc,,[sfc])
2682 WINE_CONFIG_DLL(sfc_os,,[sfc_os])
2683 WINE_CONFIG_DLL(shdoclc)
2684 WINE_CONFIG_DLL(shdocvw,,[shdocvw])
2685 WINE_CONFIG_TEST(dlls/shdocvw/tests)
2686 WINE_CONFIG_DLL(shell.dll16,enable_win16)
2687 WINE_CONFIG_DLL(shell32,,[shell32])
2688 WINE_CONFIG_TEST(dlls/shell32/tests)
2689 WINE_CONFIG_DLL(shfolder,,[shfolder])
2690 WINE_CONFIG_DLL(shlwapi,,[shlwapi])
2691 WINE_CONFIG_TEST(dlls/shlwapi/tests)
2692 WINE_CONFIG_DLL(slbcsp)
2693 WINE_CONFIG_DLL(slc,,[slc])
2694 WINE_CONFIG_DLL(snmpapi,,[snmpapi])
2695 WINE_CONFIG_TEST(dlls/snmpapi/tests)
2696 WINE_CONFIG_DLL(softpub)
2697 WINE_CONFIG_DLL(sound.drv16,enable_win16)
2698 WINE_CONFIG_DLL(spoolss,,[spoolss])
2699 WINE_CONFIG_TEST(dlls/spoolss/tests)
2700 WINE_CONFIG_DLL(stdole2.tlb)
2701 WINE_CONFIG_DLL(stdole32.tlb)
2702 WINE_CONFIG_DLL(sti,,[sti])
2703 WINE_CONFIG_TEST(dlls/sti/tests)
2704 WINE_CONFIG_DLL(storage.dll16,enable_win16)
2705 WINE_CONFIG_DLL(stress.dll16,enable_win16)
2706 WINE_CONFIG_LIB(strmbase)
2707 WINE_CONFIG_LIB(strmiids)
2708 WINE_CONFIG_DLL(svrapi)
2709 WINE_CONFIG_DLL(sxs)
2710 WINE_CONFIG_DLL(system.drv16,enable_win16)
2711 WINE_CONFIG_DLL(t2embed)
2712 WINE_CONFIG_DLL(tapi32,,[tapi32])
2713 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
2714 WINE_CONFIG_DLL(traffic)
2715 WINE_CONFIG_DLL(twain.dll16,enable_win16)
2716 WINE_CONFIG_DLL(twain_32)
2717 WINE_CONFIG_TEST(dlls/twain_32/tests)
2718 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
2719 WINE_CONFIG_DLL(unicows,,[unicows])
2720 WINE_CONFIG_DLL(updspapi)
2721 WINE_CONFIG_DLL(url,,[url])
2722 WINE_CONFIG_DLL(urlmon,,[urlmon])
2723 WINE_CONFIG_TEST(dlls/urlmon/tests)
2724 WINE_CONFIG_DLL(usbd.sys,,[usbd.sys])
2725 WINE_CONFIG_DLL(user.exe16,enable_win16)
2726 WINE_CONFIG_DLL(user32,,[user32])
2727 WINE_CONFIG_TEST(dlls/user32/tests)
2728 WINE_CONFIG_DLL(userenv,,[userenv])
2729 WINE_CONFIG_TEST(dlls/userenv/tests)
2730 WINE_CONFIG_DLL(usp10,,[usp10])
2731 WINE_CONFIG_TEST(dlls/usp10/tests)
2732 WINE_CONFIG_LIB(uuid)
2733 WINE_CONFIG_DLL(uxtheme,,[uxtheme])
2734 WINE_CONFIG_TEST(dlls/uxtheme/tests)
2735 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
2736 WINE_CONFIG_DLL(vdmdbg,,[vdmdbg])
2737 WINE_CONFIG_DLL(ver.dll16,enable_win16)
2738 WINE_CONFIG_DLL(version,,[version])
2739 WINE_CONFIG_TEST(dlls/version/tests)
2740 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
2741 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
2742 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
2743 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
2744 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
2745 WINE_CONFIG_DLL(w32skrnl,enable_win16)
2746 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
2747 WINE_CONFIG_DLL(wbemprox)
2748 WINE_CONFIG_DLL(wer,,[wer])
2749 WINE_CONFIG_TEST(dlls/wer/tests)
2750 WINE_CONFIG_DLL(wiaservc)
2751 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
2752 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
2753 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
2754 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
2755 WINE_CONFIG_DLL(windowscodecs,,[windowscodecs])
2756 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
2757 WINE_CONFIG_DLL(winealsa.drv)
2758 WINE_CONFIG_DLL(wineaudioio.drv)
2759 WINE_CONFIG_DLL(winecoreaudio.drv)
2760 WINE_CONFIG_LIB(winecrt0)
2761 WINE_CONFIG_DLL(wined3d,,[wined3d])
2762 WINE_CONFIG_DLL(wineesd.drv)
2763 WINE_CONFIG_DLL(winegstreamer)
2764 WINE_CONFIG_DLL(winejack.drv)
2765 WINE_CONFIG_DLL(winejoystick.drv)
2766 WINE_CONFIG_DLL(winemapi)
2767 WINE_CONFIG_DLL(winemp3.acm)
2768 WINE_CONFIG_DLL(winenas.drv)
2769 WINE_CONFIG_DLL(wineoss.drv)
2770 WINE_CONFIG_DLL(wineps.drv)
2771 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
2772 WINE_CONFIG_DLL(winequartz.drv)
2773 WINE_CONFIG_DLL(winex11.drv)
2774 WINE_CONFIG_DLL(wing.dll16,enable_win16)
2775 WINE_CONFIG_DLL(wing32)
2776 WINE_CONFIG_DLL(winhttp,,[winhttp])
2777 WINE_CONFIG_TEST(dlls/winhttp/tests)
2778 WINE_CONFIG_DLL(wininet,,[wininet])
2779 WINE_CONFIG_TEST(dlls/wininet/tests)
2780 WINE_CONFIG_DLL(winmm,,[winmm])
2781 WINE_CONFIG_TEST(dlls/winmm/tests)
2782 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
2783 WINE_CONFIG_DLL(winnls32,,[winnls32])
2784 WINE_CONFIG_DLL(winscard,,[winscard])
2785 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
2786 WINE_CONFIG_DLL(winspool.drv,,[winspool])
2787 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
2788 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
2789 WINE_CONFIG_DLL(wintab32,,[wintab32])
2790 WINE_CONFIG_TEST(dlls/wintab32/tests)
2791 WINE_CONFIG_DLL(wintrust,,[wintrust])
2792 WINE_CONFIG_TEST(dlls/wintrust/tests)
2793 WINE_CONFIG_DLL(wlanapi)
2794 WINE_CONFIG_DLL(wldap32,,[wldap32])
2795 WINE_CONFIG_TEST(dlls/wldap32/tests)
2796 WINE_CONFIG_DLL(wmi)
2797 WINE_CONFIG_DLL(wmiutils)
2798 WINE_CONFIG_DLL(wnaspi32,,[wnaspi32])
2799 WINE_CONFIG_DLL(wow32,enable_win16,[wow32])
2800 WINE_CONFIG_DLL(ws2_32,,[ws2_32])
2801 WINE_CONFIG_TEST(dlls/ws2_32/tests)
2802 WINE_CONFIG_DLL(wsock32,,[wsock32])
2803 WINE_CONFIG_DLL(wtsapi32,,[wtsapi32])
2804 WINE_CONFIG_DLL(wuapi)
2805 WINE_CONFIG_DLL(wuaueng)
2806 WINE_CONFIG_DLL(xapofx1_1)
2807 WINE_CONFIG_DLL(xinput1_1)
2808 WINE_CONFIG_DLL(xinput1_2)
2809 WINE_CONFIG_DLL(xinput1_3,,[xinput])
2810 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
2811 WINE_CONFIG_DLL(xinput9_1_0)
2812 WINE_CONFIG_DLL(xmllite)
2813 WINE_CONFIG_TEST(dlls/xmllite/tests)
2814 WINE_CONFIG_MAKEFILE([documentation])
2815 WINE_CONFIG_MAKEFILE([fonts])
2816 WINE_CONFIG_MAKEFILE([include])
2817 WINE_CONFIG_MAKEFILE([libs/port])
2818 WINE_CONFIG_MAKEFILE([libs/wine])
2819 WINE_CONFIG_MAKEFILE([libs/wpp])
2820 WINE_CONFIG_MAKEFILE([loader])
2821 WINE_CONFIG_PROGRAM(aspnet_regiis,install)
2822 WINE_CONFIG_PROGRAM(attrib,install)
2823 WINE_CONFIG_PROGRAM(cacls,install)
2824 WINE_CONFIG_PROGRAM(clock,install)
2825 WINE_CONFIG_PROGRAM(cmd,install)
2826 WINE_CONFIG_TEST(programs/cmd/tests)
2827 WINE_CONFIG_PROGRAM(cmdlgtst)
2828 WINE_CONFIG_PROGRAM(control,install)
2829 WINE_CONFIG_PROGRAM(dxdiag,install)
2830 WINE_CONFIG_PROGRAM(eject,install)
2831 WINE_CONFIG_PROGRAM(expand,install)
2832 WINE_CONFIG_PROGRAM(explorer,install)
2833 WINE_CONFIG_PROGRAM(extrac32,install)
2834 WINE_CONFIG_PROGRAM(hh,install)
2835 WINE_CONFIG_PROGRAM(icinfo,install)
2836 WINE_CONFIG_PROGRAM(iexplore,install)
2837 WINE_CONFIG_PROGRAM(ipconfig,install)
2838 WINE_CONFIG_PROGRAM(lodctr,install)
2839 WINE_CONFIG_PROGRAM(mofcomp,install)
2840 WINE_CONFIG_PROGRAM(mshta,install)
2841 WINE_CONFIG_PROGRAM(msiexec,installbin)
2842 WINE_CONFIG_PROGRAM(net,install)
2843 WINE_CONFIG_PROGRAM(ngen,install)
2844 WINE_CONFIG_PROGRAM(notepad,installbin)
2845 WINE_CONFIG_PROGRAM(oleview,install)
2846 WINE_CONFIG_PROGRAM(ping,install)
2847 WINE_CONFIG_PROGRAM(progman,install)
2848 WINE_CONFIG_PROGRAM(reg,install)
2849 WINE_CONFIG_PROGRAM(regedit,installbin)
2850 WINE_CONFIG_TEST(programs/regedit/tests)
2851 WINE_CONFIG_PROGRAM(regsvcs,install)
2852 WINE_CONFIG_PROGRAM(regsvr32,installbin)
2853 WINE_CONFIG_PROGRAM(rpcss,install)
2854 WINE_CONFIG_PROGRAM(rundll.exe16,install,enable_win16)
2855 WINE_CONFIG_PROGRAM(rundll32,install)
2856 WINE_CONFIG_PROGRAM(sc,install)
2857 WINE_CONFIG_PROGRAM(secedit,install)
2858 WINE_CONFIG_PROGRAM(servicemodelreg,install)
2859 WINE_CONFIG_PROGRAM(services,install)
2860 WINE_CONFIG_PROGRAM(spoolsv,install)
2861 WINE_CONFIG_PROGRAM(start,install)
2862 WINE_CONFIG_PROGRAM(svchost,install)
2863 WINE_CONFIG_PROGRAM(taskkill,install)
2864 WINE_CONFIG_PROGRAM(taskmgr,install)
2865 WINE_CONFIG_PROGRAM(termsv,install)
2866 WINE_CONFIG_PROGRAM(uninstaller,install)
2867 WINE_CONFIG_PROGRAM(unlodctr,install)
2868 WINE_CONFIG_PROGRAM(view)
2869 WINE_CONFIG_PROGRAM(wineboot,installbin)
2870 WINE_CONFIG_PROGRAM(winebrowser,install)
2871 WINE_CONFIG_PROGRAM(winecfg,installbin)
2872 WINE_CONFIG_PROGRAM(wineconsole,installbin)
2873 WINE_CONFIG_PROGRAM(winedbg,installbin)
2874 WINE_CONFIG_PROGRAM(winedevice,install)
2875 WINE_CONFIG_PROGRAM(winefile,installbin)
2876 WINE_CONFIG_PROGRAM(winemenubuilder,install)
2877 WINE_CONFIG_PROGRAM(winemine,installbin)
2878 WINE_CONFIG_PROGRAM(winepath,installbin)
2879 WINE_CONFIG_PROGRAM(winetest)
2880 WINE_CONFIG_PROGRAM(winevdm,install,enable_win16)
2881 WINE_CONFIG_PROGRAM(winhelp.exe16,install,enable_win16)
2882 WINE_CONFIG_PROGRAM(winhlp32,install)
2883 WINE_CONFIG_PROGRAM(winoldap.mod16,install,enable_win16)
2884 WINE_CONFIG_PROGRAM(winver,install)
2885 WINE_CONFIG_PROGRAM(wordpad,install)
2886 WINE_CONFIG_PROGRAM(write,install)
2887 WINE_CONFIG_PROGRAM(wscript,install)
2888 WINE_CONFIG_PROGRAM(xcopy,install)
2889 WINE_CONFIG_MAKEFILE([server])
2890 WINE_CONFIG_TOOL(tools)
2891 WINE_CONFIG_TOOL(tools/widl)
2892 WINE_CONFIG_TOOL(tools/winebuild)
2893 WINE_CONFIG_TOOL(tools/winedump)
2894 WINE_CONFIG_TOOL(tools/winegcc)
2895 WINE_CONFIG_TOOL(tools/wmc)
2896 WINE_CONFIG_TOOL(tools/wrc)
2897 dnl End of auto-generated output commands
2898
2899 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
2900 [wine_fn_output_makefile ()
2901 {
2902     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
2903 $ALL_MAKEFILE_DEPENDS
2904 _WINE_EOF
2905     AS_ERROR([could not create Makefile])
2906 }])
2907
2908 AC_CONFIG_FILES([Make.tmp:Make.vars.in:Makefile.in])
2909
2910 dnl Some final makefile rules
2911
2912 if test -n "$with_wine64"
2913 then
2914 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
2915 [all: fonts server $with_wine64/loader/wine
2916 fonts server:
2917         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
2918 $with_wine64/loader/wine:
2919         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine \$[@]
2920 clean::
2921         \$(RM) fonts server $with_wine64/loader/wine])
2922 fi
2923
2924 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
2925 [uninstall::
2926         -rmdir \$(DESTDIR)\$(datadir)/wine \$(DESTDIR)\$(fakedlldir) \$(DESTDIR)\$(dlldir)])
2927
2928 AC_OUTPUT
2929
2930 if test "$no_create" = "yes"
2931 then
2932   exit 0
2933 fi
2934
2935 WINE_PRINT_MESSAGES
2936
2937 echo "
2938 $as_me: Finished.  Do '${ac_make}' to compile Wine.
2939 " >&AS_MESSAGE_FD
2940
2941 dnl Local Variables:
2942 dnl comment-start: "dnl "
2943 dnl comment-end: ""
2944 dnl comment-start-skip: "\\bdnl\\b\\s *"
2945 dnl compile-command: "autoreconf --warnings=all"
2946 dnl End: