git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]),
  18                                ,[AC_SUBST([MAINTAINER_MODE],[\#])])
  19
  20 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  21             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  22 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  23             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  24 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  25             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  26 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  28 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  30 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]),
  31             [if test "x$withval" = "xno"; then ac_cv_header_cups_cups_h=no; fi])
  32 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  33             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  34 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  35 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  36             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  37 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  38 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  39 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  40             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  41 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  43 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  45 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  47 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  48 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  49             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  50 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  52 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  54 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  55 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  57 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  59 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  61 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  63 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  64 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  65             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  66 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  68 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  70 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  72 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  73 AC_ARG_WITH(xvidmode,  AS_HELP_STRING([--without-xvidmode],[do not use XFree video mode extension]),
  74             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; fi])
  75
  76 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  77
  78 AC_CANONICAL_HOST
  79 case $host in
  80   x86_64*linux*)
  81     if test "x$enable_win64" != "xyes"
  82     then
  83       test -n "$CC" || CC="gcc -m32"
  84       test -n "$CXX"|| CXX="g++ -m32"
  85       test -n "$LD" || LD="ld -m elf_i386"
  86       test -n "$AS" || AS="as --32"
  87       host_cpu="i386"
  88     fi
  89     ;;
  90 esac
  91
  92 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  93 case $host_cpu in
  94   *i[[3456789]]86*)
  95     if test "x$enable_win16" != "xno"
  96     then
  97       enable_win16="yes"
  98     fi
  99     ;;
 100 esac
 101
 102 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
 103 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
 104 if test "x$enable_win16" != "xyes"
 105 then
 106   WIN16_FILES=""
 107   WIN16_INSTALL=""
 108 fi
 109
 110 dnl check for out of tree build with unclean source tree
 111 case "$srcdir" in
 112  .) ;;
 113  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 114       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 115 You need to run 'make distclean' in the source tree first.])
 116     fi ;;
 117 esac
 118
 119 dnl **** Check for some programs ****
 120
 121 AC_PROG_MAKE_SET
 122 AC_PROG_CC
 123 AC_PROG_CXX
 124 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 125 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 126
 127 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 128   [if test -z "$with_wine_tools"; then
 129      if test "$cross_compiling" = "yes"; then
 130        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 131      else
 132        wine_cv_toolsdir="\$(TOPOBJDIR)"
 133      fi
 134    elif test -d "$with_wine_tools/tools/winebuild"; then
 135      case $with_wine_tools in
 136        /*) wine_cv_toolsdir="$with_wine_tools" ;;
 137        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
 138      esac
 139    else
 140      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
 141    fi])
 142 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 143
 144 AC_PATH_XTRA
 145
 146 dnl Check for flex
 147 AC_CHECK_PROGS(FLEX,flex,none)
 148 if test "$FLEX" = "none"
 149 then
 150   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 151 fi
 152
 153 dnl Check for bison
 154 AC_CHECK_PROGS(BISON,bison,none)
 155 if test "$BISON" = "none"
 156 then
 157   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 158 fi
 159
 160 AC_CHECK_TOOLS(AS,[gas as],as)
 161 AC_CHECK_TOOL(LD,ld,ld)
 162 AC_CHECK_TOOL(AR,ar,ar)
 163 AC_SUBST(ARFLAGS,rc)
 164 AC_PROG_RANLIB
 165 AC_CHECK_TOOL(STRIP,strip,strip)
 166 AC_CHECK_TOOL(WINDRES,windres,false)
 167 AC_PROG_LN_S
 168 WINE_PROG_LN
 169 AC_PROG_EGREP
 170 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 171 AC_PROG_INSTALL
 172 dnl Prepend src dir to install path dir if it's a relative path
 173 case "$INSTALL" in
 174   [[\\/$]]* | ?:[[\\/]]* ) ;;
 175   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 176 esac
 177
 178 dnl Check for lint
 179 AC_CHECK_PROGS(LINT, lclint lint)
 180 if test "$LINT" = "lint"
 181 then
 182   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 183   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 184 fi
 185 AC_SUBST(LINT)
 186 AC_SUBST(LINTFLAGS)
 187
 188 dnl Check for various programs
 189 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 190 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 191 AC_CHECK_PROGS(RSVG, rsvg, false)
 192 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 193
 194 if test "${enable_maintainer_mode+set}" = set
 195 then
 196   if test "$FONTFORGE" = "false"; then WINE_WARNING([fontforge is missing, fonts can't be rebuilt.]); fi
 197   if test "$RSVG" = "false"; then WINE_WARNING([rsvg is missing, icons can't be rebuilt.]); fi
 198   if test "$ICOTOOL" = "false"; then WINE_WARNING([icotool is missing, icons can't be rebuilt.]); fi
 199 fi
 200
 201 case $host_cpu in
 202   *i[[3456789]]86*)
 203     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 204     ;;
 205 esac
 206
 207 dnl **** Check for some libraries ****
 208
 209 dnl Check for -li386 for NetBSD and OpenBSD
 210 AC_CHECK_LIB(i386,i386_set_ldt)
 211 dnl Check for -lossaudio for NetBSD
 212 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 213 dnl Check for -lpthread
 214 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 215
 216 AC_SUBST(XLIB,"")
 217 AC_SUBST(XFILES,"")
 218 AC_SUBST(OPENGLFILES,"")
 219 AC_SUBST(GLU32FILES,"")
 220 AC_SUBST(OPENGL_LIBS,"")
 221 AC_SUBST(QUARTZFILES,"")
 222
 223 dnl **** Check for header files ****
 224
 225 AC_CHECK_HEADERS(\
 226         AudioUnit/AudioUnit.h \
 227         Carbon/Carbon.h \
 228         CoreAudio/CoreAudio.h \
 229         DiskArbitration/DiskArbitration.h \
 230         IOKit/IOKitLib.h \
 231         alsa/asoundlib.h \
 232         arpa/inet.h \
 233         arpa/nameser.h \
 234         asm/types.h \
 235         capi20.h \
 236         cups/cups.h \
 237         curses.h \
 238         direct.h \
 239         dlfcn.h \
 240         elf.h \
 241         float.h \
 242         fontconfig/fontconfig.h \
 243         getopt.h \
 244         ieeefp.h \
 245         io.h \
 246         jack/jack.h \
 247         jpeglib.h \
 248         lber.h \
 249         lcms.h \
 250         lcms/lcms.h \
 251         ldap.h \
 252         libaudioio.h \
 253         link.h \
 254         linux/cdrom.h \
 255         linux/compiler.h \
 256         linux/hdreg.h \
 257         linux/input.h \
 258         linux/ioctl.h \
 259         linux/joystick.h \
 260         linux/major.h \
 261         linux/param.h \
 262         linux/serial.h \
 263         linux/ucdrom.h \
 264         mach/mach.h \
 265         mach/machine.h \
 266         machine/cpu.h \
 267         machine/limits.h \
 268         machine/soundcard.h \
 269         mntent.h \
 270         ncurses.h \
 271         netdb.h \
 272         netinet/in.h \
 273         netinet/in_systm.h \
 274         netinet/tcp.h \
 275         netinet/tcp_fsm.h \
 276         openssl/err.h \
 277         openssl/ssl.h \
 278         png.h \
 279         poll.h \
 280         process.h \
 281         pthread.h \
 282         pwd.h \
 283         regex.h \
 284         sched.h \
 285         scsi/scsi.h \
 286         scsi/scsi_ioctl.h \
 287         scsi/sg.h \
 288         soundcard.h \
 289         stdint.h \
 290         strings.h \
 291         sys/asoundlib.h \
 292         sys/cdio.h \
 293         sys/elf32.h \
 294         sys/epoll.h \
 295         sys/errno.h \
 296         sys/event.h \
 297         sys/exec_elf.h \
 298         sys/filio.h \
 299         sys/ioctl.h \
 300         sys/ipc.h \
 301         sys/limits.h \
 302         sys/link.h \
 303         sys/lwp.h \
 304         sys/mman.h \
 305         sys/modem.h \
 306         sys/msg.h \
 307         sys/mtio.h \
 308         sys/param.h \
 309         sys/poll.h \
 310         sys/prctl.h \
 311         sys/ptrace.h \
 312         sys/reg.h \
 313         sys/resource.h \
 314         sys/scsiio.h \
 315         sys/shm.h \
 316         sys/signal.h \
 317         sys/socket.h \
 318         sys/socketvar.h \
 319         sys/sockio.h \
 320         sys/soundcard.h \
 321         sys/statvfs.h \
 322         sys/strtio.h \
 323         sys/syscall.h \
 324         sys/sysctl.h \
 325         sys/time.h \
 326         sys/times.h \
 327         sys/uio.h \
 328         sys/un.h \
 329         sys/vm86.h \
 330         sys/wait.h \
 331         syscall.h \
 332         termios.h \
 333         unistd.h \
 334         utime.h \
 335         valgrind/memcheck.h
 336 )
 337 AC_HEADER_STAT()
 338
 339 dnl **** Checks for headers that depend on other ones ****
 340
 341 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 342     [#include <sys/types.h>
 343      #ifdef HAVE_SYS_PARAM_H
 344      # include <sys/param.h>
 345      #endif])
 346
 347 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 348     [#include <sys/types.h>
 349      #ifdef HAVE_SYS_SOCKET_H
 350      # include <sys/socket.h>
 351      #endif
 352      #ifdef HAVE_SYS_SOCKETVAR_H
 353      # include <sys/socketvar.h>
 354      #endif
 355      #ifdef HAVE_NETINET_IN_H
 356      # include <netinet/in.h>
 357      #endif])
 358
 359 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 360     [#include <sys/types.h>
 361      #ifdef HAVE_SYS_SOCKET_H
 362      # include <sys/socket.h>
 363      #endif
 364      #ifdef HAVE_SYS_SOCKETVAR_H
 365      # include <sys/socketvar.h>
 366      #endif
 367      #ifdef HAVE_NETINET_IN_H
 368      # include <netinet/in.h>
 369      #endif
 370      #ifdef HAVE_NETINET_TCP_H
 371      # include <netinet/tcp.h>
 372      #endif])
 373
 374 AC_CHECK_HEADERS([linux/ipx.h],,,
 375     [#include <sys/types.h>
 376      #ifdef HAVE_ASM_TYPES_H
 377      # include <asm/types.h>
 378      #endif
 379      #ifdef HAVE_SYS_SOCKET_H
 380      # include <sys/socket.h>
 381      #endif])
 382
 383 AC_CHECK_HEADERS([resolv.h],,,
 384     [#include <sys/types.h>
 385      #ifdef HAVE_SYS_SOCKET_H
 386      # include <sys/socket.h>
 387      #endif
 388      #ifdef HAVE_NETINET_IN_H
 389      # include <netinet/in.h>
 390      #endif
 391      #ifdef HAVE_ARPA_NAMESER_H
 392      # include <arpa/nameser.h>
 393      #endif])
 394
 395 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 396
 397 AC_CHECK_HEADERS([sys/thr.h],,,
 398 [#include <sys/types.h>
 399 #ifdef HAVE_UCONTEXT_H
 400 #include <ucontext.h>
 401 #endif])
 402
 403 AC_CHECK_HEADERS([pthread_np.h],,,
 404 [#ifdef HAVE_PTHREAD_H
 405 #include <pthread.h>
 406 #endif])
 407
 408 AC_CHECK_HEADERS([linux/videodev.h],,,
 409 [#ifdef HAVE_SYS_TIME_H
 410 #include <sys/time.h>
 411 #endif
 412 #include <sys/types.h>
 413 #ifdef HAVE_ASM_TYPES_H
 414 #include <asm/types.h>
 415 #endif])
 416
 417 dnl Check for broken kernel header that doesn't define __user
 418 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 419
 420 dnl **** Check for working dll ****
 421
 422 AC_SUBST(DLLEXT,"")
 423 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 424 AC_SUBST(LDSHARED,"")
 425 AC_SUBST(LDDLLFLAGS,"")
 426 AC_SUBST(LIBEXT,"so")
 427 AC_SUBST(IMPLIBEXT,"def")
 428 AC_SUBST(LDRPATH_INSTALL,"")
 429 AC_SUBST(LDRPATH_LOCAL,"")
 430 WINE_PATH_LDD
 431
 432 case $host_os in
 433   cygwin*|mingw32*)
 434     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 435     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 436     AC_CHECK_TOOL(MINGWAR,ar,false)
 437     if test "$DLLWRAP" = "false"; then
 438       LIBEXT="a"
 439     else
 440       dnl FIXME - check whether dllwrap works correctly...
 441       LIBEXT="dll"
 442     fi
 443     IMPLIBEXT="a"
 444     dnl We can't build 16-bit NE dlls
 445     WIN16_FILES=""
 446     WIN16_INSTALL=""
 447     ;;
 448   darwin*|macosx*)
 449     DLLEXT=".so"
 450     LIBEXT="dylib"
 451     DLLFLAGS="$DLLFLAGS -fPIC"
 452     LDDLLFLAGS="-bundle -multiply_defined suppress"
 453     LIBWINE_LDFLAGS="-multiply_defined suppress"
 454     LDSHARED="\$(CC) -dynamiclib"
 455     STRIP="$STRIP -x"
 456     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 457     dnl declare needed frameworks
 458     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 459     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 460     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 461     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 462     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 463     then
 464         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 465         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 466     fi
 467     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 468     then
 469         dnl CoreServices needed by AudioUnit
 470         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 471     fi
 472     case $host_cpu in
 473       *powerpc*)
 474         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 475         ;;
 476     esac
 477     dnl Enable quartz driver on Mac OS X
 478     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 479     then
 480         AC_SUBST(CARBONLIB,"-framework Carbon")
 481         QUARTZFILES='$(QUARTZFILES)'
 482     fi
 483     ;;
 484   *)
 485     DLLFLAGS="$DLLFLAGS -fPIC"
 486     DLLEXT=".so"
 487     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 488         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 489                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 490     if test "$ac_cv_c_dll_gnuelf" = "yes"
 491     then
 492       LDSHARED="\$(CC) -shared"
 493       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 494       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 495                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 496                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 497                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 498
 499       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 500
 501       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 502                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 503
 504       echo '{ global: *; };' >conftest.map
 505       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 506                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 507       rm -f conftest.map
 508
 509       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 510                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 511
 512       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 513                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 514                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 515           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 516                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 517                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 518
 519       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 520                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 521
 522       case $host_cpu in
 523         *i[[3456789]]86* | x86_64)
 524           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 525                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 526           ;;
 527       esac
 528
 529     else
 530       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 531           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 532                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 533       if test "$ac_cv_c_dll_unixware" = "yes"
 534       then
 535         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 536         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 537
 538       else
 539         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 540           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 541         if test "$ac_cv_c_dll_hpux" = "yes"
 542         then
 543           LIBEXT="sl"
 544           DLLEXT=".sl"
 545           LDDLLFLAGS="-shared -fPIC"
 546           LDSHARED="\$(CC) -shared"
 547         fi
 548       fi
 549     fi
 550
 551     dnl Check for cross compiler to build test programs
 552     AC_SUBST(CROSSTEST,"")
 553     if test "$cross_compiling" = "no"
 554     then
 555       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 556       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 557       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 558       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 559       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 560     fi
 561     ;;
 562 esac
 563
 564 if test "$LIBEXT" = "a"; then
 565   AC_MSG_ERROR(
 566 [could not find a way to build shared libraries.
 567 It is currently not possible to build Wine without shared library
 568 (.so) support to allow transparent switch between .so and .dll files.
 569 If you are using Linux, you will need a newer binutils.]
 570 )
 571 fi
 572
 573 dnl **** Check for X11 ****
 574
 575 if test "$have_x" = "yes"
 576 then
 577     XLIB="-lXext -lX11"
 578     ac_save_CPPFLAGS="$CPPFLAGS"
 579     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 580
 581     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 582     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 583
 584     dnl *** All of the following tests require X11/Xlib.h
 585     AC_CHECK_HEADERS([X11/Xlib.h \
 586                       X11/XKBlib.h \
 587                       X11/Xutil.h \
 588                       X11/Xcursor/Xcursor.h \
 589                       X11/extensions/shape.h \
 590                       X11/extensions/XInput.h \
 591                       X11/extensions/XShm.h \
 592                       X11/extensions/Xcomposite.h \
 593                       X11/extensions/Xinerama.h \
 594                       X11/extensions/Xrandr.h \
 595                       X11/extensions/Xrender.h \
 596                       X11/extensions/xf86vmode.h],,,
 597 [#ifdef HAVE_X11_XLIB_H
 598 # include <X11/Xlib.h>
 599 #endif
 600 #ifdef HAVE_X11_XUTIL_H
 601 # include <X11/Xutil.h>
 602 #endif])
 603
 604         dnl *** Check for X keyboard extension
 605         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 606         then
 607               AC_CHECK_LIB(X11, XkbQueryExtension,
 608               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 609               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 610         fi
 611
 612         dnl *** Check for X cursor
 613         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 614         then
 615             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 616         fi
 617         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 618                          [libxcursor development files not found, the Xcursor extension won't be supported.])
 619
 620         dnl *** Check for X input extension
 621         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 622         then
 623             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 624         fi
 625         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 626                          [libxi development files not found, the Xinput extension won't be supported.])
 627
 628         dnl *** Check for X Shm extension
 629         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 630         then
 631               AC_CHECK_LIB(Xext, XShmQueryExtension,
 632               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 633               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 634         fi
 635         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 636                          [XShm development files not found, X Shared Memory won't be supported.])
 637
 638         dnl *** Check for X shape extension
 639         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 640         then
 641               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 642               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 643               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 644         fi
 645         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 646                          [XShape development files not found, XShape won't be supported.])
 647
 648         dnl *** Check for XFree86 VMODE extension
 649         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 650         then
 651                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 652                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 653                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 654                   ],,
 655                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 656         fi
 657         WINE_NOTICE_WITH(xvidmode,[test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],
 658                          [libXxf86vm development files not found, XFree86 Vidmode won't be supported.])
 659
 660         dnl *** Check for Transform functions in Xrender
 661         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 662         then
 663             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 664               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 665                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 666                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 667                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 668
 669         fi
 670         WINE_NOTICE_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 671                          [libxrender development files not found, XRender won't be supported.])
 672
 673         dnl *** Check for X RandR extension
 674         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 675         then
 676                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 677 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 678                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 679         fi
 680         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 681                          [libxrandr development files not found, XRandr won't be supported.])
 682
 683         dnl *** Check for Xinerama extension
 684         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 685         then
 686                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 687 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 688                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 689         fi
 690         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 691                          [libxinerama development files not found, multi-monitor setups won't be supported.])
 692
 693         dnl *** Check for X Composite extension
 694         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 695         then
 696             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 697         fi
 698         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 699                          [libxcomposite development files not found, Xcomposite won't be supported.])
 700
 701     dnl *** End of X11/Xlib.h check
 702
 703     dnl Check for the presence of OpenGL
 704     opengl_msg=""
 705     if test "x$with_opengl" != "xno"
 706     then
 707         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 708 [#ifdef HAVE_GL_GLX_H
 709 # include <GL/glx.h>
 710 #endif])
 711         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 712         then
 713             dnl Check for some problems due to old Mesa versions
 714             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 715               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 716                 [wine_cv_opengl_header_version_OK="yes"],
 717                 [wine_cv_opengl_header_version_OK="no"]))
 718
 719             if test "$wine_cv_opengl_header_version_OK" = "yes"
 720             then
 721                 dnl Check for the presence of the library
 722                 WINE_CHECK_SONAME(GL,glXCreateContext,
 723                              [OPENGL_LIBS="-lGL"
 724                              OPENGLFILES='$(OPENGLFILES)'
 725                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 726                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 727                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 728                                     OPENGLFILES='$(OPENGLFILES)'
 729                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 730                                     [if test -f /usr/X11R6/lib/libGL.a
 731                                     then
 732                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
 733 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
 734                                     else
 735                                         opengl_msg="No OpenGL library found on this system."
 736                                     fi],
 737                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 738                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 739
 740                 dnl Check for GLU32 library.
 741                 AC_CHECK_LIB(GLU,gluLookAt,
 742                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 743                              GLU32FILES='$(GLU32FILES)']
 744                              ,,
 745                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 746              else
 747                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
 748              fi
 749          else
 750              opengl_msg="OpenGL development headers not found."
 751          fi
 752     fi
 753     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
 754 OpenGL and Direct3D won't be supported.])
 755
 756     dnl **** Check for NAS ****
 757     AC_SUBST(NASLIBS,"")
 758     AC_CHECK_HEADERS(audio/audiolib.h,
 759          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 760           AC_CHECK_LIB(audio,AuCreateFlow,
 761                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 762                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 763                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 764                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 765                           [$X_LIBS])
 766                        ],,
 767                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 768
 769     CPPFLAGS="$ac_save_CPPFLAGS"
 770     XFILES='$(XFILES)'
 771 else
 772     XLIB=""
 773     X_CFLAGS=""
 774     X_LIBS=""
 775 fi
 776 WINE_WARNING_WITH(x,[test "x$XLIB" = "x"],[X development files not found. Wine will be built
 777 without X support, which probably isn't what you want. You will need to install
 778 development packages of Xlib/Xfree86 at the very least.])
 779
 780 dnl **** Check for libxml2 ****
 781
 782 AC_SUBST(XML2LIBS,"")
 783 AC_SUBST(XML2INCL,"")
 784 AC_SUBST(XSLTLIBS,"")
 785 AC_SUBST(XSLTINCL,"")
 786 if test "x$with_xml" != "xno"
 787 then
 788     ac_save_CPPFLAGS="$CPPFLAGS"
 789     if test "$PKG_CONFIG" != "false"
 790     then
 791         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 792         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 793     else
 794         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 795         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 796     fi
 797     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 798     AC_CHECK_HEADERS(libxml/parser.h,
 799             [AC_CHECK_LIB(xml2, xmlParseMemory,
 800                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 801                  XML2LIBS="$ac_xml_libs"
 802                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 803              AC_CHECK_LIB(xml2, xmlReadMemory,
 804                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 805              AC_CHECK_LIB(xml2, xmlNewDocPI,
 806                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 807         ])
 808     CPPFLAGS="$ac_save_CPPFLAGS"
 809 fi
 810 WINE_NOTICE_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
 811                  [libxml2 development files not found, XML won't be supported.])
 812
 813 if test "x$with_xslt" != "xno"
 814 then
 815     if test "$PKG_CONFIG" != "false"
 816     then
 817         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 818         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 819     else
 820         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 821         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 822     fi
 823     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 824     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 825             [AC_CHECK_LIB(xslt, xsltCompilePattern,
 826                 [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 827                  XSLTLIBS="$ac_xslt_libs"
 828                  XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 829             ],,
 830     [#ifdef HAVE_LIBXSLT_PATTERN_H
 831 # include <libxslt/pattern.h>
 832 #endif])
 833     CPPFLAGS="$ac_save_CPPFLAGS"
 834 fi
 835 WINE_NOTICE_WITH(xslt,[test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],
 836                  [libxslt development files not found, xslt won't be supported.])
 837
 838 dnl **** Check for libhal ****
 839 AC_SUBST(HALINCL,"")
 840 if test "x$with_hal" != "xno" -a "$PKG_CONFIG" != "false"
 841 then
 842     ac_save_CPPFLAGS="$CPPFLAGS"
 843     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 844     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 845     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 846     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 847     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 848     then
 849         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 850           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 851             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 852     fi
 853     CPPFLAGS="$ac_save_CPPFLAGS"
 854 fi
 855 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
 856                  [libhal development files not found, no dynamic device support.])
 857
 858 dnl **** Check which curses lib to use ***
 859 CURSESLIBS=""
 860 if test "$ac_cv_header_ncurses_h" = "yes"
 861 then
 862     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 863 elif test "$ac_cv_header_curses_h" = "yes"
 864 then
 865     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 866 fi
 867 ac_save_LIBS="$LIBS"
 868 LIBS="$LIBS $CURSESLIBS"
 869 AC_CHECK_FUNCS(mousemask)
 870 LIBS="$ac_save_LIBS"
 871 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
 872                  [lib(n)curses development files not found, curses won't be supported.])
 873
 874 dnl **** Check for SANE ****
 875 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 876 if test "$sane_devel" != "no" -a "x$with_sane" != "xno"
 877 then
 878     ac_sane_incl="`$sane_devel --cflags`"
 879     ac_save_CPPFLAGS="$CPPFLAGS"
 880     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 881     AC_CHECK_HEADER(sane/sane.h,
 882         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 883     CPPFLAGS="$ac_save_CPPFLAGS"
 884 fi
 885 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
 886                  [libsane development files not found, scanners won't be supported.])
 887
 888 dnl **** Check for libgphoto2 ****
 889 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 890 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 891 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no" -a "x$with_gphoto" != "xno"
 892 then
 893     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 894     ac_gphoto2_libs=""
 895     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 896     do
 897       case "$i" in
 898         -L/usr/lib|-L/usr/lib64) ;;
 899         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 900       esac
 901     done
 902     ac_save_CPPFLAGS="$CPPFLAGS"
 903     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 904     AC_CHECK_HEADER(gphoto2-camera.h,
 905                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 906                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 907                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 908                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 909                                   [$GPHOTO2LIBS])])
 910     CPPFLAGS="$ac_save_CPPFLAGS"
 911 fi
 912 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
 913                  [libgphoto2 development files not found, digital cameras won't be supported.])
 914
 915
 916 dnl **** Check for resolver library ***
 917 AC_SUBST(RESOLVLIBS,"")
 918 if test "$ac_cv_header_resolv_h" = "yes"
 919 then
 920     AC_CHECK_LIB(resolv, res_query,
 921         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 922          RESOLVLIBS="-lresolv"])
 923 fi
 924
 925 dnl **** Check for LittleCMS ***
 926 AC_SUBST(LCMSLIBS,"")
 927 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 928 then
 929     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 930         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 931          LCMSLIBS="-llcms"])
 932 fi
 933 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
 934                  [liblcms development files not found, Color Management won't be supported.])
 935
 936 dnl **** Check for OpenLDAP ***
 937 AC_SUBST(LDAPLIBS,"")
 938 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 939 then
 940     AC_CHECK_LIB(ldap_r, ldap_initialize,
 941         [AC_CHECK_LIB(lber, ber_init,
 942             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 943              LDAPLIBS="-lldap_r -llber"],,
 944              [$LIBPTHREAD])],,
 945              [$LIBPTHREAD])
 946     WINE_CHECK_LIB_FUNCS(\
 947         ldap_count_references \
 948         ldap_first_reference \
 949         ldap_next_reference \
 950         ldap_parse_reference \
 951         ldap_parse_sort_control \
 952         ldap_parse_sortresponse_control \
 953         ldap_parse_vlv_control \
 954         ldap_parse_vlvresponse_control,
 955         [$LDAPLIBS $LIBPTHREAD])
 956 fi
 957 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
 958                  [libldap (OpenLDAP) development files not found, LDAP won't be supported.])
 959
 960 dnl **** Check for FreeType 2 ****
 961 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 962 if test "$ft_devel" != "false"
 963 then
 964     ac_freetype_libs=`$ft_devel --libs`
 965     ac_freetype_incl=`$ft_devel --cflags`
 966     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 967     if test "$ft_lib" = "yes"
 968     then
 969         ac_save_CPPFLAGS="$CPPFLAGS"
 970         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 971         AC_CHECK_HEADERS(ft2build.h \
 972                          freetype/freetype.h \
 973                          freetype/ftglyph.h \
 974                          freetype/fttypes.h \
 975                          freetype/tttables.h \
 976                          freetype/ftnames.h \
 977                          freetype/ftsnames.h \
 978                          freetype/ttnameid.h \
 979                          freetype/ftoutln.h \
 980                          freetype/ftwinfnt.h \
 981                          freetype/ftmodapi.h \
 982                          freetype/internal/sfnt.h,,,
 983                          [#ifdef HAVE_FT2BUILD_H
 984                           # include <ft2build.h>
 985                           #endif])
 986         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 987                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 988           [Define if you have the <freetype/fttrigon.h> header file.])
 989                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 990         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 991         ac_save_CFLAGS="$CFLAGS"
 992         CFLAGS="$CFLAGS $ac_freetype_libs"
 993         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 994         CFLAGS="$ac_save_CFLAGS"
 995         CPPFLAGS="$ac_save_CPPFLAGS"
 996         dnl Check that we have at least freetype/freetype.h
 997         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 998         then
 999             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1000             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1001             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1002         fi
1003     fi
1004 fi
1005
1006 dnl Only build the fonts dir if we have freetype
1007 if test "x$FREETYPELIBS" = "x"
1008 then
1009     WINE_WARNING([FreeType development files not found.
1010 Fonts will not be built. Dialog text may be invisible or unaligned.])
1011 else
1012   AC_SUBST(FONTSSUBDIRS,"fonts")
1013 fi
1014
1015 dnl **** Check for parport (currently Linux only) ****
1016 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1017  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1018     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1019 if test "$ac_cv_c_ppdev" = "yes"
1020 then
1021     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1022 fi
1023
1024 dnl **** Check for va_copy ****
1025 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
1026  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
1027     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
1028  )
1029 if test "$ac_cv_c_va_copy" = "yes"
1030 then
1031     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
1032 fi
1033 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
1034  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
1035     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
1036  )
1037 if test "$ac_cv_c___va_copy" = "yes"
1038 then
1039     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
1040 fi
1041
1042 dnl **** Check for sigsetjmp ****
1043 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
1044  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
1045     sigsetjmp( buf, 1 );
1046     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
1047  )
1048 if test "$ac_cv_c_sigsetjmp" = "yes"
1049 then
1050     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
1051 fi
1052
1053 dnl **** Check for pthread_rwlock_t ****
1054 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
1055 #include <pthread.h>])
1056
1057 dnl **** Check for pthread functions ****
1058 WINE_CHECK_LIB_FUNCS(\
1059         pthread_attr_get_np \
1060         pthread_getattr_np \
1061         pthread_get_stackaddr_np \
1062         pthread_get_stacksize_np,
1063         [$LIBPTHREAD])
1064
1065 dnl **** Check for EsounD ****
1066 AC_PATH_PROG(ESDCONFIG, esd-config)
1067 if test "x$with_esd" != xno -a "x$ESDCONFIG" != x -a "x$ESDCONFIG" != x'"$ESDCONFIG"';
1068 then
1069     ESD_CFLAGS=""
1070     for i in `$ESDCONFIG --cflags`
1071     do
1072       case "$i" in
1073         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
1074       esac
1075     done
1076     ESD_LIBS=`$ESDCONFIG --libs`
1077     save_CFLAGS="$CFLAGS"
1078     CFLAGS="$CFLAGS $ESD_CFLAGS"
1079     AC_CHECK_LIB(esd,esd_open_sound,
1080         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1081          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1082          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1083     CFLAGS="$save_CFLAGS"
1084 fi
1085
1086 dnl **** Check for ALSA 1.x ****
1087 AC_SUBST(ALSALIBS,"")
1088 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1089 then
1090     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1091         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1092 #include <alsa/asoundlib.h>
1093 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1094 #include <sys/asoundlib.h>
1095 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1096                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1097                          ALSALIBS="-lasound"],[])])
1098 fi
1099
1100 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1101 AC_SUBST(AUDIOIOLIBS,"")
1102 if test "$ac_cv_header_libaudioio_h" = "yes"
1103 then
1104     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1105                   [AUDIOIOLIBS="-laudioio"
1106                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1107 fi
1108
1109 dnl **** Check for capi4linux ****
1110
1111 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1112 then
1113     WINE_CHECK_SONAME(capi20,capi20_register)
1114 fi
1115 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1116                  [libcapi20 development files not found, ISDN won't be supported.])
1117
1118 dnl **** Check for cups ****
1119 if test "$ac_cv_header_cups_cups_h" = "yes"
1120 then
1121     WINE_CHECK_SONAME(cups,cupsGetDefault)
1122 fi
1123 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1124                  [libcups development files not found, CUPS won't be supported.])
1125
1126 dnl **** Check for jack ****
1127 if test "$ac_cv_header_jack_jack_h" = "yes"
1128 then
1129     WINE_CHECK_SONAME(jack,jack_client_new)
1130 fi
1131
1132 dnl **** Check for fontconfig ****
1133 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1134 then
1135     WINE_CHECK_SONAME(fontconfig,FcInit)
1136 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1137 then
1138     dnl fontconfig is in the X directory on Mac OS X
1139     ac_save_CPPFLAGS="$CPPFLAGS"
1140     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1141     $as_unset ac_cv_header_fontconfig_fontconfig_h
1142     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1143     CPPFLAGS="$ac_save_CPPFLAGS"
1144     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1145     then
1146         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1147         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1148     fi
1149 fi
1150 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1151                  [fontconfig development files not found, fontconfig won't be supported.])
1152
1153 dnl **** Check for SSL ****
1154 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1155 then
1156     WINE_CHECK_SONAME(ssl,SSL_library_init)
1157     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1158 fi
1159 WINE_NOTICE_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x"],
1160                  [OpenSSL development files not found, SSL won't be supported.])
1161
1162 dnl **** Check for libjpeg ****
1163 if test "$ac_cv_header_jpeglib_h" = "yes"
1164 then
1165     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1166 fi
1167 WINE_NOTICE_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1168                  [libjpeg development files not found, JPEG won't be supported.])
1169
1170 dnl **** Check for libpng ****
1171 if test "$ac_cv_header_png_h" = "yes"
1172 then
1173     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1174 fi
1175 WINE_NOTICE_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1176                  [libpng development files not found, PNG won't be supported.])
1177
1178 dnl **** Check for libodbc ****
1179 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1180
1181 dnl **** Check for any sound system ****
1182 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1183         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1184         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1185         "$ac_cv_header_soundcard_h" != "yes" -a \
1186         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1187 then
1188     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1189 fi
1190
1191 dnl **** Check for gcc specific options ****
1192
1193 AC_SUBST(EXTRACFLAGS,"")
1194 if test "x${GCC}" = "xyes"
1195 then
1196   EXTRACFLAGS="-Wall -pipe"
1197
1198   dnl Check for strength-reduce bug
1199   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1200                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1201 [[static int Array[[3]];
1202   unsigned int B = 3;
1203   int i;
1204   for(i=0; i<B; i++) Array[[i]] = i - 3;
1205   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1206   L[[i]] = 4;
1207   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1208     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1209   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1210   then
1211     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1212   fi
1213
1214   dnl Check for some compiler flags
1215
1216   WINE_TRY_CFLAGS([-fshort-wchar],
1217                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1218                              [Specifies the compiler flag that forces a short wchar_t])])
1219   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1220   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1221   WINE_TRY_CFLAGS([-Wwrite-strings])
1222   WINE_TRY_CFLAGS([-Wtype-limits])
1223
1224   dnl Check for noisy string.h
1225   saved_CFLAGS="$CFLAGS"
1226   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1227   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1228       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1229   CFLAGS="$saved_CFLAGS"
1230   if test "$ac_cv_c_string_h_warnings" = "no"
1231   then
1232     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1233   fi
1234
1235   AC_SUBST(BUILTINFLAG,"")
1236   saved_CFLAGS="$CFLAGS"
1237   CFLAGS="$CFLAGS -Werror"
1238   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1239       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1240   CFLAGS="$saved_CFLAGS"
1241   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1242   then
1243     BUILTINFLAG="-fno-builtin"
1244   fi
1245 fi
1246
1247 dnl **** Check how to define a function in assembly code ****
1248
1249 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1250   WINE_TRY_ASM_LINK(
1251       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1252       ac_cv_asm_func_def=".def",
1253     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1254       ac_cv_asm_func_def=".type @function",
1255     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1256       ac_cv_asm_func_def=".type 2",
1257       ac_cv_asm_func_def="unknown")])]))
1258
1259 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1260 case "$ac_cv_asm_func_def" in
1261   ".def")
1262      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1263   ".type @function")
1264      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1265   ".type 2")
1266      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1267   *)
1268      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1269 esac
1270
1271 dnl **** Check for underscore on external symbols ****
1272
1273 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1274     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1275                       [extern int ac_test;],
1276                       [if (ac_test) return 1],
1277                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1278
1279 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1280 if test "$ac_cv_c_extern_prefix" = "yes"
1281 then
1282   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1283 else
1284   AC_DEFINE([__ASM_NAME(name)], [name])
1285 fi
1286
1287 dnl **** Platform-specific checks ****
1288
1289 AC_SUBST(LDPATH,"")
1290 case $build_os in
1291   cygwin*|mingw32*)
1292     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1293     ;;
1294   darwin*|macosx*)
1295     ;;
1296   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1297     if test -z "$LDRPATH_LOCAL"
1298     then
1299       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1300     fi
1301     ;;
1302   *)
1303     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1304     ;;
1305 esac
1306
1307 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1308 case $host_os in
1309   mingw32*)
1310     AC_SUBST(CRTLIBS,"-lmsvcrt")
1311     AC_SUBST(SOCKETLIBS,"-lws2_32")
1312     ;;
1313 esac
1314
1315 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1316 case $host_cpu in
1317   *i[[3456789]]86*)
1318     case $host_os in
1319       linux* | k*bsd*-gnu)
1320         AC_SUBST(MAIN_BINARY,"wine-glibc")
1321         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1322       freebsd*)
1323         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1324         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1325     esac
1326     ;;
1327 esac
1328
1329 dnl **** Check for functions ****
1330
1331 AC_CHECK_FUNCS(\
1332         _pclose \
1333         _popen \
1334         _snprintf \
1335         _spawnvp \
1336         _strdup \
1337         _stricmp \
1338         _strnicmp \
1339         _strtoi64 \
1340         _strtoui64 \
1341         _vsnprintf \
1342         asctime_r \
1343         chsize \
1344         clone \
1345         dlopen \
1346         epoll_create \
1347         ffs \
1348         finite \
1349         fork \
1350         fpclass \
1351         fstatfs \
1352         fstatvfs \
1353         ftruncate \
1354         futimes \
1355         futimesat \
1356         getdirentries \
1357         getopt_long \
1358         getpagesize \
1359         getpwuid \
1360         gettid \
1361         gettimeofday \
1362         getuid \
1363         inet_pton \
1364         kqueue \
1365         lstat \
1366         memmove \
1367         mmap \
1368         pclose \
1369         poll \
1370         popen \
1371         prctl \
1372         pread \
1373         pwrite \
1374         readlink \
1375         rfork \
1376         sched_yield \
1377         select \
1378         setproctitle \
1379         setrlimit \
1380         settimeofday \
1381         sigaltstack \
1382         sigprocmask \
1383         snprintf \
1384         spawnvp \
1385         statfs \
1386         statvfs \
1387         strcasecmp \
1388         strdup \
1389         strerror \
1390         strncasecmp \
1391         strtold \
1392         strtoll \
1393         strtoull \
1394         tcgetattr \
1395         thr_kill2 \
1396         timegm \
1397         usleep \
1398         vsnprintf \
1399         wait4 \
1400         waitpid \
1401 )
1402
1403 dnl Check for -ldl
1404 if test "$ac_cv_func_dlopen" = no
1405 then
1406     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1407 fi
1408 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1409
1410 dnl Check for -lpoll for Mac OS X/Darwin
1411 if test "$ac_cv_func_poll" = no
1412 then
1413     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1414 fi
1415
1416 dnl Check for -lnsl for Solaris
1417 AC_SEARCH_LIBS(gethostbyname, nsl)
1418
1419 dnl Check for -lsocket for Solaris
1420 AC_SEARCH_LIBS(connect, socket)
1421
1422 dnl Check for -lresolv for Solaris
1423 AC_SEARCH_LIBS(inet_aton, resolv)
1424
1425 dnl **** Check for functions which may rely on -lsocket on Solaris.
1426 AC_CHECK_FUNCS(\
1427         getaddrinfo \
1428         getnameinfo \
1429         getnetbyname \
1430         getprotobyname \
1431         getprotobynumber \
1432         getservbyport \
1433         inet_network \
1434         sendmsg \
1435 )
1436
1437 dnl **** Check for types ****
1438
1439 AC_C_CONST
1440 AC_C_INLINE
1441 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1442 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1443 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1444
1445 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1446 [#ifdef HAVE_LINUX_INPUT_H
1447 #include <linux/input.h>
1448 #endif])
1449
1450 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1451                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1452 if test "$wine_cv_have_sigaddset" = "yes"
1453 then
1454   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1455 fi
1456
1457
1458 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1459         wine_cv_linux_gethostbyname_r_6,
1460         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1461     char *name=0;
1462     struct hostent he;
1463     struct hostent *result;
1464     char *buf=0;
1465     int bufsize=0;
1466     int res,errnr;
1467     char *addr=0;
1468     int addrlen=0;
1469     int addrtype=0;
1470     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1471     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1472     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1473         ])
1474    )
1475    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1476    then
1477       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1478                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1479    fi
1480
1481 if test "$ac_cv_header_linux_joystick_h" = "yes"
1482 then
1483    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1484         wine_cv_linux_joystick_22_api,
1485         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1486         #include <sys/ioctl.h>
1487         #include <sys/types.h>
1488         #include <linux/joystick.h>
1489
1490         struct js_event blub;
1491         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1492         #error "no 2.2 header"
1493         #endif
1494         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1495    )
1496    if test "$wine_cv_linux_joystick_22_api" = "yes"
1497    then
1498       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1499                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1500    fi
1501 fi
1502
1503 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1504
1505 dnl Check for statfs members
1506 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1507 [#include <sys/types.h>
1508 #ifdef HAVE_SYS_PARAM_H
1509 # include <sys/param.h>
1510 #endif
1511 #ifdef HAVE_SYS_MOUNT_H
1512 # include <sys/mount.h>
1513 #endif
1514 #ifdef HAVE_SYS_VFS_H
1515 # include <sys/vfs.h>
1516 #endif
1517 #ifdef HAVE_SYS_STATFS_H
1518 # include <sys/statfs.h>
1519 #endif])
1520
1521 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1522 [#ifdef HAVE_SYS_STATVFS_H
1523 #include <sys/statvfs.h>
1524 #endif])
1525
1526 dnl Check for socket structure members
1527 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1528 [#include <sys/types.h>
1529 #ifdef HAVE_SYS_SOCKET_H
1530 # include <sys/socket.h>
1531 #endif
1532 #ifdef HAVE_SYS_UN_H
1533 # include <sys/un.h>
1534 #endif])
1535
1536 dnl Check for scsireq_t and sg_io_hdr_t members
1537 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1538 [#include <sys/types.h>
1539 #ifdef HAVE_SCSI_SG_H
1540 #include <scsi/sg.h>
1541 #endif])
1542
1543 dnl Check for siginfo_t members
1544 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1545
1546 dnl Check for struct mtget members
1547 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1548 [#include <sys/types.h>
1549 #ifdef HAVE_SYS_MTIO_H
1550 #include <sys/mtio.h>
1551 #endif])
1552
1553 dnl Check for struct option
1554 AC_CHECK_MEMBERS([struct option.name],,,
1555 [#ifdef HAVE_GETOPT_H
1556 #include <getopt.h>
1557 #endif])
1558
1559 dnl Check for stat.st_blocks
1560 AC_CHECK_MEMBERS([struct stat.st_blocks])
1561
1562 dnl Check for sin6_scope_id
1563 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1564 [#ifdef HAVE_SYS_TYPES_H
1565 #include <sys/types.h>
1566 #endif
1567 #ifdef HAVE_NETINET_IN_H
1568 #include <netinet/in.h>
1569 #endif])
1570
1571 dnl Check for ns_msg ptr member
1572 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1573 [#ifdef HAVE_SYS_TYPES_H
1574 #include <sys/types.h>
1575 #endif
1576 #ifdef HAVE_NETINET_IN_H
1577 # include <netinet/in.h>
1578 #endif
1579 #ifdef HAVE_ARPA_NAMESER_H
1580 # include <arpa/nameser.h>
1581 #endif])
1582
1583 dnl Check for the external timezone variables timezone and daylight
1584 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1585                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1586 if test "$ac_cv_have_timezone" = "yes"
1587 then
1588     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1589 fi
1590 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1591                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1592 if test "$ac_cv_have_daylight" = "yes"
1593 then
1594     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1595 fi
1596
1597 dnl *** check for the need to define platform-specific symbols
1598
1599 case $host_cpu in
1600   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1601   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1602   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1603   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1604   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1605 esac
1606
1607 case $host_vendor in
1608   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1609 esac
1610
1611 dnl **** Generate output files ****
1612
1613 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1614 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1615 ["### Dependencies:\\
1616 \\
1617 .INIT: Makefile\\
1618 .BEGIN: Makefile\\
1619 Makefile: dummy\\
1620         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1621 \\
1622 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1623 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1624 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1625 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1626 ["### Dependencies:
1627
1628 .INIT: Makefile
1629 .BEGIN: Makefile
1630 Makefile: dummy
1631         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1632
1633 \$(OBJS): \$(IDL_GEN_HEADERS)
1634 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1635 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1636 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1637
1638 AH_TOP([#define __WINE_CONFIG_H])
1639
1640 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1641
1642 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1643 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1644 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1645 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1646 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1647 WINE_CONFIG_EXTRA_DIR(include/wine)
1648
1649 MAKE_RULES=Make.rules
1650 AC_SUBST_FILE(MAKE_RULES)
1651
1652 MAKE_DLL_RULES=dlls/Makedll.rules
1653 AC_SUBST_FILE(MAKE_DLL_RULES)
1654
1655 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1656 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1657
1658 MAKE_TEST_RULES=dlls/Maketest.rules
1659 AC_SUBST_FILE(MAKE_TEST_RULES)
1660
1661 MAKE_PROG_RULES=programs/Makeprog.rules
1662 AC_SUBST_FILE(MAKE_PROG_RULES)
1663
1664 AC_CONFIG_FILES([Make.rules])
1665 AC_CONFIG_FILES([dlls/Makedll.rules])
1666 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1667 AC_CONFIG_FILES([dlls/Maketest.rules])
1668 AC_CONFIG_FILES([programs/Makeprog.rules])
1669 AC_CONFIG_FILES([Makefile])
1670 AC_CONFIG_FILES([dlls/Makefile])
1671 AC_CONFIG_FILES([dlls/acledit/Makefile])
1672 AC_CONFIG_FILES([dlls/activeds/Makefile])
1673 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1674 AC_CONFIG_FILES([dlls/adsiid/Makefile])
1675 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1676 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1677 AC_CONFIG_FILES([dlls/advpack/Makefile])
1678 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1679 AC_CONFIG_FILES([dlls/amstream/Makefile])
1680 AC_CONFIG_FILES([dlls/atl/Makefile])
1681 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1682 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1683 AC_CONFIG_FILES([dlls/browseui/Makefile])
1684 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1685 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1686 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1687 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1688 AC_CONFIG_FILES([dlls/cards/Makefile])
1689 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1690 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1691 AC_CONFIG_FILES([dlls/comcat/Makefile])
1692 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1693 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1694 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1695 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1696 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1697 AC_CONFIG_FILES([dlls/compstui/Makefile])
1698 AC_CONFIG_FILES([dlls/credui/Makefile])
1699 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1700 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1701 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1702 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1703 AC_CONFIG_FILES([dlls/cryptdlg/Makefile])
1704 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1705 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1706 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1707 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1708 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1709 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1710 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1711 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1712 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1713 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1714 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1715 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1716 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1717 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1718 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1719 AC_CONFIG_FILES([dlls/d3dx9_24/Makefile])
1720 AC_CONFIG_FILES([dlls/d3dx9_25/Makefile])
1721 AC_CONFIG_FILES([dlls/d3dx9_26/Makefile])
1722 AC_CONFIG_FILES([dlls/d3dx9_27/Makefile])
1723 AC_CONFIG_FILES([dlls/d3dx9_28/Makefile])
1724 AC_CONFIG_FILES([dlls/d3dx9_29/Makefile])
1725 AC_CONFIG_FILES([dlls/d3dx9_30/Makefile])
1726 AC_CONFIG_FILES([dlls/d3dx9_31/Makefile])
1727 AC_CONFIG_FILES([dlls/d3dx9_32/Makefile])
1728 AC_CONFIG_FILES([dlls/d3dx9_33/Makefile])
1729 AC_CONFIG_FILES([dlls/d3dx9_34/Makefile])
1730 AC_CONFIG_FILES([dlls/d3dx9_35/Makefile])
1731 AC_CONFIG_FILES([dlls/d3dx9_36/Makefile])
1732 AC_CONFIG_FILES([dlls/d3dx9_36/tests/Makefile])
1733 AC_CONFIG_FILES([dlls/d3dx9_37/Makefile])
1734 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1735 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1736 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1737 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1738 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1740 AC_CONFIG_FILES([dlls/devenum/Makefile])
1741 AC_CONFIG_FILES([dlls/dinput/Makefile])
1742 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1743 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1744 AC_CONFIG_FILES([dlls/dmband/Makefile])
1745 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1746 AC_CONFIG_FILES([dlls/dmime/Makefile])
1747 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1748 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1749 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1750 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1751 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1752 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1753 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1754 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1755 AC_CONFIG_FILES([dlls/dplay/Makefile])
1756 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1757 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1758 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1759 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1760 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1761 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1762 AC_CONFIG_FILES([dlls/dsound/Makefile])
1763 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1764 AC_CONFIG_FILES([dlls/dssenh/Makefile])
1765 AC_CONFIG_FILES([dlls/dswave/Makefile])
1766 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1767 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1768 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1769 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1770 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1771 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1772 AC_CONFIG_FILES([dlls/fusion/Makefile])
1773 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1774 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1775 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1776 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1777 AC_CONFIG_FILES([dlls/glu32/Makefile])
1778 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1779 AC_CONFIG_FILES([dlls/gpkcsp/Makefile])
1780 AC_CONFIG_FILES([dlls/hal/Makefile])
1781 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1782 AC_CONFIG_FILES([dlls/hid/Makefile])
1783 AC_CONFIG_FILES([dlls/hlink/Makefile])
1784 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1785 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1786 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1787 AC_CONFIG_FILES([dlls/icmp/Makefile])
1788 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1789 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1790 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1791 AC_CONFIG_FILES([dlls/imm32/Makefile])
1792 AC_CONFIG_FILES([dlls/imm32/tests/Makefile])
1793 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1794 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1795 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1796 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1797 AC_CONFIG_FILES([dlls/initpki/Makefile])
1798 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1799 AC_CONFIG_FILES([dlls/inseng/Makefile])
1800 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1801 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1802 AC_CONFIG_FILES([dlls/itircl/Makefile])
1803 AC_CONFIG_FILES([dlls/itss/Makefile])
1804 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1805 AC_CONFIG_FILES([dlls/jscript/Makefile])
1806 AC_CONFIG_FILES([dlls/jscript/tests/Makefile])
1807 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1808 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1809 AC_CONFIG_FILES([dlls/localspl/Makefile])
1810 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1811 AC_CONFIG_FILES([dlls/localui/Makefile])
1812 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1813 AC_CONFIG_FILES([dlls/lz32/Makefile])
1814 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1815 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1816 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1817 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1818 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1819 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1820 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1821 AC_CONFIG_FILES([dlls/midimap/Makefile])
1822 AC_CONFIG_FILES([dlls/mlang/Makefile])
1823 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1824 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1825 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1826 AC_CONFIG_FILES([dlls/mountmgr.sys/Makefile])
1827 AC_CONFIG_FILES([dlls/mpr/Makefile])
1828 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1829 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1830 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1831 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1832 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1833 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1834 AC_CONFIG_FILES([dlls/mscms/Makefile])
1835 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1836 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1837 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1838 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1839 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1840 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1841 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1842 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1843 AC_CONFIG_FILES([dlls/msi/Makefile])
1844 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1845 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1846 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1847 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1848 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1849 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1850 AC_CONFIG_FILES([dlls/mssip32/Makefile])
1851 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1852 AC_CONFIG_FILES([dlls/msvcr71/Makefile])
1853 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1854 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1855 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1856 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1857 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1858 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1859 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1860 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1861 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1862 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1863 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1864 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1865 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1866 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1867 AC_CONFIG_FILES([dlls/newdev/Makefile])
1868 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1869 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1870 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1871 AC_CONFIG_FILES([dlls/ntdsapi/tests/Makefile])
1872 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1873 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1874 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1875 AC_CONFIG_FILES([dlls/objsel/Makefile])
1876 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1877 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1878 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1879 AC_CONFIG_FILES([dlls/ole32/Makefile])
1880 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1881 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1882 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1883 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1884 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1885 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1886 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1887 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1888 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1889 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1890 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1891 AC_CONFIG_FILES([dlls/pdh/Makefile])
1892 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1893 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1894 AC_CONFIG_FILES([dlls/printui/Makefile])
1895 AC_CONFIG_FILES([dlls/propsys/Makefile])
1896 AC_CONFIG_FILES([dlls/psapi/Makefile])
1897 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1898 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1899 AC_CONFIG_FILES([dlls/qcap/Makefile])
1900 AC_CONFIG_FILES([dlls/qedit/Makefile])
1901 AC_CONFIG_FILES([dlls/qedit/tests/Makefile])
1902 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1903 AC_CONFIG_FILES([dlls/qmgr/tests/Makefile])
1904 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1905 AC_CONFIG_FILES([dlls/quartz/Makefile])
1906 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1907 AC_CONFIG_FILES([dlls/query/Makefile])
1908 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1909 AC_CONFIG_FILES([dlls/resutils/Makefile])
1910 AC_CONFIG_FILES([dlls/riched20/Makefile])
1911 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1912 AC_CONFIG_FILES([dlls/riched32/Makefile])
1913 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1914 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1915 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1916 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1917 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1918 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1919 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1920 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1921 AC_CONFIG_FILES([dlls/sccbase/Makefile])
1922 AC_CONFIG_FILES([dlls/schannel/Makefile])
1923 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1924 AC_CONFIG_FILES([dlls/secur32/Makefile])
1925 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1926 AC_CONFIG_FILES([dlls/security/Makefile])
1927 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1928 AC_CONFIG_FILES([dlls/serialui/Makefile])
1929 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1930 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1931 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1932 AC_CONFIG_FILES([dlls/sfc/Makefile])
1933 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1934 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1935 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1936 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1937 AC_CONFIG_FILES([dlls/shell32/Makefile])
1938 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1939 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1940 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1941 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1942 AC_CONFIG_FILES([dlls/slbcsp/Makefile])
1943 AC_CONFIG_FILES([dlls/slc/Makefile])
1944 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1945 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1946 AC_CONFIG_FILES([dlls/softpub/Makefile])
1947 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1948 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
1949 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1950 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1951 AC_CONFIG_FILES([dlls/sti/Makefile])
1952 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1953 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1954 AC_CONFIG_FILES([dlls/sxs/Makefile])
1955 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1956 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1957 AC_CONFIG_FILES([dlls/unicows/Makefile])
1958 AC_CONFIG_FILES([dlls/url/Makefile])
1959 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1960 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1961 AC_CONFIG_FILES([dlls/user32/Makefile])
1962 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1963 AC_CONFIG_FILES([dlls/userenv/Makefile])
1964 AC_CONFIG_FILES([dlls/usp10/Makefile])
1965 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1966 AC_CONFIG_FILES([dlls/uuid/Makefile])
1967 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1968 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1969 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1970 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1971 AC_CONFIG_FILES([dlls/version/Makefile])
1972 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1973 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1974 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1975 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1976 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1977 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1978 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1979 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1980 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1981 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1982 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1983 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1984 AC_CONFIG_FILES([dlls/winedos/Makefile])
1985 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1986 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1987 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1988 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1989 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1990 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1991 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1992 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1993 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1994 AC_CONFIG_FILES([dlls/wing32/Makefile])
1995 AC_CONFIG_FILES([dlls/winhttp/Makefile])
1996 AC_CONFIG_FILES([dlls/wininet/Makefile])
1997 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1998 AC_CONFIG_FILES([dlls/winmm/Makefile])
1999 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
2000 AC_CONFIG_FILES([dlls/winnls32/Makefile])
2001 AC_CONFIG_FILES([dlls/winscard/Makefile])
2002 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
2003 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
2004 AC_CONFIG_FILES([dlls/wintab32/Makefile])
2005 AC_CONFIG_FILES([dlls/wintrust/Makefile])
2006 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
2007 AC_CONFIG_FILES([dlls/wldap32/Makefile])
2008 AC_CONFIG_FILES([dlls/wmi/Makefile])
2009 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
2010 AC_CONFIG_FILES([dlls/wow32/Makefile])
2011 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
2012 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
2013 AC_CONFIG_FILES([dlls/wsock32/Makefile])
2014 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
2015 AC_CONFIG_FILES([documentation/Makefile])
2016 AC_CONFIG_FILES([fonts/Makefile])
2017 AC_CONFIG_FILES([include/Makefile])
2018 AC_CONFIG_FILES([libs/Makefile])
2019 AC_CONFIG_FILES([libs/port/Makefile])
2020 AC_CONFIG_FILES([libs/wine/Makefile])
2021 AC_CONFIG_FILES([libs/wpp/Makefile])
2022 AC_CONFIG_FILES([loader/Makefile])
2023 AC_CONFIG_FILES([programs/Makefile])
2024 AC_CONFIG_FILES([programs/clock/Makefile])
2025 AC_CONFIG_FILES([programs/cmd/Makefile])
2026 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
2027 AC_CONFIG_FILES([programs/control/Makefile])
2028 AC_CONFIG_FILES([programs/eject/Makefile])
2029 AC_CONFIG_FILES([programs/expand/Makefile])
2030 AC_CONFIG_FILES([programs/explorer/Makefile])
2031 AC_CONFIG_FILES([programs/hh/Makefile])
2032 AC_CONFIG_FILES([programs/icinfo/Makefile])
2033 AC_CONFIG_FILES([programs/iexplore/Makefile])
2034 AC_CONFIG_FILES([programs/msiexec/Makefile])
2035 AC_CONFIG_FILES([programs/net/Makefile])
2036 AC_CONFIG_FILES([programs/notepad/Makefile])
2037 AC_CONFIG_FILES([programs/oleview/Makefile])
2038 AC_CONFIG_FILES([programs/progman/Makefile])
2039 AC_CONFIG_FILES([programs/reg/Makefile])
2040 AC_CONFIG_FILES([programs/regedit/Makefile])
2041 AC_CONFIG_FILES([programs/regsvr32/Makefile])
2042 AC_CONFIG_FILES([programs/rpcss/Makefile])
2043 AC_CONFIG_FILES([programs/rundll32/Makefile])
2044 AC_CONFIG_FILES([programs/secedit/Makefile])
2045 AC_CONFIG_FILES([programs/spoolsv/Makefile])
2046 AC_CONFIG_FILES([programs/start/Makefile])
2047 AC_CONFIG_FILES([programs/svchost/Makefile])
2048 AC_CONFIG_FILES([programs/taskmgr/Makefile])
2049 AC_CONFIG_FILES([programs/uninstaller/Makefile])
2050 AC_CONFIG_FILES([programs/view/Makefile])
2051 AC_CONFIG_FILES([programs/wineboot/Makefile])
2052 AC_CONFIG_FILES([programs/winebrowser/Makefile])
2053 AC_CONFIG_FILES([programs/winecfg/Makefile])
2054 AC_CONFIG_FILES([programs/wineconsole/Makefile])
2055 AC_CONFIG_FILES([programs/winedbg/Makefile])
2056 AC_CONFIG_FILES([programs/winedevice/Makefile])
2057 AC_CONFIG_FILES([programs/winefile/Makefile])
2058 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
2059 AC_CONFIG_FILES([programs/winemine/Makefile])
2060 AC_CONFIG_FILES([programs/winepath/Makefile])
2061 AC_CONFIG_FILES([programs/winetest/Makefile])
2062 AC_CONFIG_FILES([programs/winevdm/Makefile])
2063 AC_CONFIG_FILES([programs/winhelp/Makefile])
2064 AC_CONFIG_FILES([programs/winver/Makefile])
2065 AC_CONFIG_FILES([programs/wordpad/Makefile])
2066 AC_CONFIG_FILES([programs/write/Makefile])
2067 AC_CONFIG_FILES([programs/xcopy/Makefile])
2068 AC_CONFIG_FILES([server/Makefile])
2069 AC_CONFIG_FILES([tools/Makefile])
2070 AC_CONFIG_FILES([tools/widl/Makefile])
2071 AC_CONFIG_FILES([tools/winebuild/Makefile])
2072 AC_CONFIG_FILES([tools/winedump/Makefile])
2073 AC_CONFIG_FILES([tools/winegcc/Makefile])
2074 AC_CONFIG_FILES([tools/wmc/Makefile])
2075 AC_CONFIG_FILES([tools/wrc/Makefile])
2076
2077 AC_OUTPUT
2078
2079 if test "$no_create" = "yes"
2080 then
2081   exit 0
2082 fi
2083
2084 WINE_PRINT_MESSAGES
2085
2086 echo "
2087 $as_me: Finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine.
2088 " >&AS_MESSAGE_FD
2089
2090 dnl Local Variables:
2091 dnl comment-start: "dnl "
2092 dnl comment-end: ""
2093 dnl comment-start-skip: "\\bdnl\\b\\s *"
2094 dnl compile-command: "autoreconf --warnings=all"
2095 dnl End: