git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "widl.h"
  35 #include "utils.h"
  36 #include "parser.h"
  37 #include "header.h"
  38 #include "typelib.h"
  39 #include "typegen.h"
  40
  41 #if defined(YYBYACC)
  42         /* Berkeley yacc (byacc) doesn't seem to know about these */
  43         /* Some *BSD supplied versions do define these though */
  44 # ifndef YYEMPTY
  45 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  46 # endif
  47 # ifndef YYLEX
  48 #  define YYLEX         yylex()
  49 # endif
  50
  51 #elif defined(YYBISON)
  52         /* Bison was used for original development */
  53         /* #define YYEMPTY -2 */
  54         /* #define YYLEX   yylex() */
  55
  56 #else
  57         /* No yacc we know yet */
  58 # if !defined(YYEMPTY) || !defined(YYLEX)
  59 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  60 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  61 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  62   /* #else we just take a chance that it works... */
  63 # endif
  64 #endif
  65
  66 unsigned char pointer_default = RPC_FC_UP;
  67
  68 typedef struct list typelist_t;
  69 struct typenode {
  70   type_t *type;
  71   struct list entry;
  72 };
  73
  74 typelist_t incomplete_types = LIST_INIT(incomplete_types);
  75
  76 static void add_incomplete(type_t *t);
  77 static void fix_incomplete(void);
  78
  79 static str_list_t *append_str(str_list_t *list, char *str);
  80 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr);
  81 static attr_t *make_attr(enum attr_type type);
  82 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  83 static attr_t *make_attrp(enum attr_type type, void *val);
  84 static expr_t *make_expr(enum expr_type type);
  85 static expr_t *make_exprl(enum expr_type type, long val);
  86 static expr_t *make_exprd(enum expr_type type, double val);
  87 static expr_t *make_exprs(enum expr_type type, char *val);
  88 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr);
  89 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  90 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  91 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  92 static type_t *make_type(unsigned char type, type_t *ref);
  93 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr);
  94 static array_dims_t *append_array(array_dims_t *list, expr_t *expr);
  95 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr, int top);
  96 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface);
  97 static ifref_t *make_ifref(type_t *iface);
  98 static var_list_t *append_var(var_list_t *list, var_t *var);
  99 static var_t *make_var(char *name);
 100 static pident_list_t *append_pident(pident_list_t *list, pident_t *p);
 101 static pident_t *make_pident(var_t *var);
 102 static func_list_t *append_func(func_list_t *list, func_t *func);
 103 static func_t *make_func(var_t *def, var_list_t *args);
 104 static type_t *make_class(char *name);
 105 static type_t *make_safearray(type_t *type);
 106 static type_t *make_builtin(char *name);
 107 static type_t *make_int(int sign);
 108
 109 static type_t *reg_type(type_t *type, const char *name, int t);
 110 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs);
 111 static type_t *find_type(const char *name, int t);
 112 static type_t *find_type2(char *name, int t);
 113 static type_t *get_type(unsigned char type, char *name, int t);
 114 static type_t *get_typev(unsigned char type, var_t *name, int t);
 115 static int get_struct_type(var_list_t *fields);
 116
 117 static var_t *reg_const(var_t *var);
 118 static var_t *find_const(char *name, int f);
 119
 120 static void write_libid(const char *name, const attr_list_t *attr);
 121 static void write_clsid(type_t *cls);
 122 static void write_diid(type_t *iface);
 123 static void write_iid(type_t *iface);
 124
 125 static int compute_method_indexes(type_t *iface);
 126 static char *gen_name(void);
 127 static void process_typedefs(var_list_t *names);
 128 static void check_arg(var_t *arg);
 129 static void check_all_user_types(ifref_list_t *ifaces);
 130
 131 #define tsENUM   1
 132 #define tsSTRUCT 2
 133 #define tsUNION  3
 134
 135 %}
 136 %union {
 137         attr_t *attr;
 138         attr_list_t *attr_list;
 139         str_list_t *str_list;
 140         expr_t *expr;
 141         expr_list_t *expr_list;
 142         array_dims_t *array_dims;
 143         type_t *type;
 144         var_t *var;
 145         var_list_t *var_list;
 146         pident_t *pident;
 147         pident_list_t *pident_list;
 148         func_t *func;
 149         func_list_t *func_list;
 150         ifref_t *ifref;
 151         ifref_list_t *ifref_list;
 152         char *str;
 153         UUID *uuid;
 154         unsigned int num;
 155         double dbl;
 156         interface_info_t ifinfo;
 157 }
 158
 159 %token <str> aIDENTIFIER
 160 %token <str> aKNOWNTYPE
 161 %token <num> aNUM aHEXNUM
 162 %token <dbl> aDOUBLE
 163 %token <str> aSTRING
 164 %token <uuid> aUUID
 165 %token aEOF
 166 %token SHL SHR
 167 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 168 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 169 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 170 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 171 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 172 %token tDEFAULT
 173 %token tDEFAULTCOLLELEM
 174 %token tDEFAULTVALUE
 175 %token tDEFAULTVTABLE
 176 %token tDISPLAYBIND
 177 %token tDISPINTERFACE
 178 %token tDLLNAME tDOUBLE tDUAL
 179 %token tENDPOINT
 180 %token tENTRY tENUM tERRORSTATUST
 181 %token tEXPLICITHANDLE tEXTERN
 182 %token tFALSE
 183 %token tFLOAT
 184 %token tHANDLE
 185 %token tHANDLET
 186 %token tHELPCONTEXT tHELPFILE
 187 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 188 %token tHIDDEN
 189 %token tHYPER tID tIDEMPOTENT
 190 %token tIIDIS
 191 %token tIMMEDIATEBIND
 192 %token tIMPLICITHANDLE
 193 %token tIMPORT tIMPORTLIB
 194 %token tIN tINLINE
 195 %token tINPUTSYNC
 196 %token tINT tINT64
 197 %token tINTERFACE
 198 %token tLCID
 199 %token tLENGTHIS tLIBRARY
 200 %token tLOCAL
 201 %token tLONG
 202 %token tMETHODS
 203 %token tMODULE
 204 %token tNONBROWSABLE
 205 %token tNONCREATABLE
 206 %token tNONEXTENSIBLE
 207 %token tOBJECT tODL tOLEAUTOMATION
 208 %token tOPTIONAL
 209 %token tOUT
 210 %token tPOINTERDEFAULT
 211 %token tPROPERTIES
 212 %token tPROPGET tPROPPUT tPROPPUTREF
 213 %token tPTR
 214 %token tPUBLIC
 215 %token tRANGE
 216 %token tREADONLY tREF
 217 %token tREQUESTEDIT
 218 %token tRESTRICTED
 219 %token tRETVAL
 220 %token tSAFEARRAY
 221 %token tSHORT
 222 %token tSIGNED
 223 %token tSINGLE
 224 %token tSIZEIS tSIZEOF
 225 %token tSMALL
 226 %token tSOURCE
 227 %token tSTDCALL
 228 %token tSTRING tSTRUCT
 229 %token tSWITCH tSWITCHIS tSWITCHTYPE
 230 %token tTRANSMITAS
 231 %token tTRUE
 232 %token tTYPEDEF
 233 %token tUNION
 234 %token tUNIQUE
 235 %token tUNSIGNED
 236 %token tUUID
 237 %token tV1ENUM
 238 %token tVARARG
 239 %token tVERSION
 240 %token tVOID
 241 %token tWCHAR tWIREMARSHAL
 242
 243 %type <attr> attribute
 244 %type <attr_list> m_attributes attributes attrib_list
 245 %type <str_list> str_list
 246 %type <expr> m_expr expr expr_const
 247 %type <expr_list> m_exprs /* exprs expr_list */ expr_list_const
 248 %type <array_dims> array array_list
 249 %type <ifinfo> interfacehdr
 250 %type <type> inherit interface interfacedef interfacedec
 251 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 252 %type <type> module modulehdr moduledef
 253 %type <type> base_type int_std
 254 %type <type> enumdef structdef uniondef
 255 %type <type> type
 256 %type <ifref> coclass_int
 257 %type <ifref_list> gbl_statements coclass_ints
 258 %type <var> arg field s_field case enum constdef externdef
 259 %type <var_list> m_args no_args args fields cases enums enum_list dispint_props
 260 %type <var> m_ident t_ident ident
 261 %type <pident> p_ident pident
 262 %type <pident_list> pident_list
 263 %type <func> funcdef
 264 %type <func_list> int_statements dispint_meths
 265 %type <type> coclass coclasshdr coclassdef
 266 %type <num> pointer_type version
 267 %type <str> libraryhdr
 268 %type <uuid> uuid_string
 269
 270 %left ','
 271 %right '?' ':'
 272 %left '|'
 273 %left '&'
 274 %left '-' '+'
 275 %left '*' '/'
 276 %left SHL SHR
 277 %right '~'
 278 %right CAST
 279 %right PPTR
 280 %right NEG
 281 %right ADDRESSOF
 282
 283 %%
 284
 285 input:   gbl_statements                         { fix_incomplete();
 286                                                   check_all_user_types($1);
 287                                                   write_proxies($1);
 288                                                   write_client($1);
 289                                                   write_server($1);
 290                                                   write_dlldata($1);
 291                                                 }
 292         ;
 293
 294 gbl_statements:                                 { $$ = NULL; }
 295         | gbl_statements interfacedec           { $$ = $1; }
 296         | gbl_statements interfacedef           { $$ = append_ifref( $1, make_ifref($2) ); }
 297         | gbl_statements coclass ';'            { $$ = $1;
 298                                                   reg_type($2, $2->name, 0);
 299                                                   if (!parse_only && do_header) write_coclass_forward($2);
 300                                                 }
 301         | gbl_statements coclassdef             { $$ = $1;
 302                                                   add_typelib_entry($2);
 303                                                   reg_type($2, $2->name, 0);
 304                                                   if (!parse_only && do_header) write_coclass_forward($2);
 305                                                 }
 306         | gbl_statements moduledef              { $$ = $1; add_typelib_entry($2); }
 307         | gbl_statements librarydef             { $$ = $1; }
 308         | gbl_statements statement              { $$ = $1; }
 309         ;
 310
 311 imp_statements:                                 {}
 312         | imp_statements interfacedec           { if (!parse_only) add_typelib_entry($2); }
 313         | imp_statements interfacedef           { if (!parse_only) add_typelib_entry($2); }
 314         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 315         | imp_statements coclassdef             { if (!parse_only) add_typelib_entry($2);
 316                                                   reg_type($2, $2->name, 0);
 317                                                   if (!parse_only && do_header) write_coclass_forward($2);
 318                                                 }
 319         | imp_statements moduledef              { if (!parse_only) add_typelib_entry($2); }
 320         | imp_statements statement              {}
 321         | imp_statements importlib              {}
 322         ;
 323
 324 int_statements:                                 { $$ = NULL; }
 325         | int_statements funcdef ';'            { $$ = append_func( $1, $2 ); }
 326         | int_statements statement              { $$ = $1; }
 327         ;
 328
 329 statement: ';'                                  {}
 330         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 331         | cppquote                              {}
 332         | enumdef ';'                           { if (!parse_only && do_header) {
 333                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 334                                                     fprintf(header, ";\n\n");
 335                                                   }
 336                                                 }
 337         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 338         | import                                {}
 339         | structdef ';'                         { if (!parse_only && do_header) {
 340                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 341                                                     fprintf(header, ";\n\n");
 342                                                   }
 343                                                 }
 344         | typedef ';'                           {}
 345         | uniondef ';'                          { if (!parse_only && do_header) {
 346                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 347                                                     fprintf(header, ";\n\n");
 348                                                   }
 349                                                 }
 350         ;
 351
 352 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 353         ;
 354 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 355                                                   if (!do_import($2)) yychar = aEOF; }
 356         ;
 357 import:   import_start imp_statements aEOF      {}
 358         ;
 359
 360 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 361         ;
 362
 363 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 364         ;
 365 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 366                                                   if (!parse_only && do_header) write_library($2, $1);
 367                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 368                                                 }
 369         ;
 370 librarydef: library_start imp_statements '}'    { end_typelib(); }
 371         ;
 372
 373 m_args:                                         { $$ = NULL; }
 374         | args
 375         ;
 376
 377 no_args:  tVOID                                 { $$ = NULL; }
 378         ;
 379
 380 args:     arg                                   { check_arg($1); $$ = append_var( NULL, $1 ); }
 381         | args ',' arg                          { check_arg($3); $$ = append_var( $1, $3); }
 382         | no_args
 383         ;
 384
 385 /* split into two rules to get bison to resolve a tVOID conflict */
 386 arg:      attributes type pident array          { $$ = $3->var;
 387                                                   $$->attrs = $1;
 388                                                   set_type($$, $2, $3->ptr_level, $4, TRUE);
 389                                                   free($3);
 390                                                 }
 391         | type pident array                     { $$ = $2->var;
 392                                                   set_type($$, $1, $2->ptr_level, $3, TRUE);
 393                                                   free($2);
 394                                                 }
 395         | attributes type pident '(' m_args ')' { $$ = $3->var;
 396                                                   $$->attrs = $1;
 397                                                   set_type($$, $2, $3->ptr_level - 1, NULL, TRUE);
 398                                                   free($3);
 399                                                   $$->args = $5;
 400                                                 }
 401         | type pident '(' m_args ')'            { $$ = $2->var;
 402                                                   set_type($$, $1, $2->ptr_level - 1, NULL, TRUE);
 403                                                   free($2);
 404                                                   $$->args = $4;
 405                                                 }
 406         ;
 407
 408 array:                                          { $$ = NULL; }
 409         | '[' array_list ']'                    { $$ = $2; }
 410         | '[' '*' ']'                           { $$ = append_array( NULL, make_expr(EXPR_VOID) ); }
 411         ;
 412
 413 array_list: m_expr /* size of first dimension is optional */ { $$ = append_array( NULL, $1 ); }
 414         | array_list ',' expr                   { $$ = append_array( $1, $3 ); }
 415         | array_list ']' '[' expr               { $$ = append_array( $1, $4 ); }
 416         ;
 417
 418 m_attributes:                                   { $$ = NULL; }
 419         | attributes
 420         ;
 421
 422 attributes:
 423           '[' attrib_list ']'                   { $$ = $2;
 424                                                   if (!$$)
 425                                                     error_loc("empty attribute lists unsupported\n");
 426                                                 }
 427         ;
 428
 429 attrib_list: attribute                          { $$ = append_attr( NULL, $1 ); }
 430         | attrib_list ',' attribute             { $$ = append_attr( $1, $3 ); }
 431         | attrib_list ']' '[' attribute         { $$ = append_attr( $1, $4 ); }
 432         ;
 433
 434 str_list: aSTRING                               { $$ = append_str( NULL, $1 ); }
 435         | str_list ',' aSTRING                  { $$ = append_str( $1, $3 ); }
 436         ;
 437
 438 attribute:                                      { $$ = NULL; }
 439         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 440         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 441         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 442         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 443         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 444         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 445         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 446         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 447         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 448         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 449         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 450         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 451         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 452         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 453         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 454         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 455         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 456         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 457         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 458         | tENDPOINT '(' str_list ')'            { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 459         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 460         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 461         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 462         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 463         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 464         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 465         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 466         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 467         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 468         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 469         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 470         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 471         | tIIDIS '(' expr ')'                   { $$ = make_attrp(ATTR_IIDIS, $3); }
 472         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 473         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 474         | tIN                                   { $$ = make_attr(ATTR_IN); }
 475         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 476         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 477         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 478         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 479         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 480         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 481         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 482         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 483         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 484         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 485         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 486         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 487         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 488         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 489         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 490         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 491         | tRANGE '(' expr_const ',' expr_const ')' { expr_list_t *list = append_expr( NULL, $3 );
 492                                                      list = append_expr( list, $5 );
 493                                                      $$ = make_attrp(ATTR_RANGE, list); }
 494         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 495         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 496         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 497         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 498         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 499         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 500         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 501         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 502         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, $3); }
 503         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, $3); }
 504         | tUUID '(' uuid_string ')'             { $$ = make_attrp(ATTR_UUID, $3); }
 505         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 506         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 507         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 508         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, $3); }
 509         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 510         ;
 511
 512 uuid_string:
 513           aUUID
 514         | aSTRING                               { if (!is_valid_uuid($1))
 515                                                     error_loc("invalid UUID: %s\n", $1);
 516                                                   $$ = parse_uuid($1); }
 517         ;
 518
 519 callconv:
 520         | tSTDCALL
 521         ;
 522
 523 cases:                                          { $$ = NULL; }
 524         | cases case                            { $$ = append_var( $1, $2 ); }
 525         ;
 526
 527 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, append_expr( NULL, $2 ));
 528                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 529                                                   $$->attrs = append_attr( $$->attrs, a );
 530                                                 }
 531         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 532                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 533                                                   $$->attrs = append_attr( $$->attrs, a );
 534                                                 }
 535         ;
 536
 537 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 538                                                   set_type($$, $2, 0, NULL, FALSE);
 539                                                   $$->eval = $5;
 540                                                 }
 541         ;
 542
 543 enums:                                          { $$ = NULL; }
 544         | enum_list ','                         { $$ = $1; }
 545         | enum_list
 546         ;
 547
 548 enum_list: enum                                 { if (!$1->eval)
 549                                                     $1->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 550                                                   $$ = append_var( NULL, $1 );
 551                                                 }
 552         | enum_list ',' enum                    { if (!$3->eval)
 553                                                   {
 554                                                     var_t *last = LIST_ENTRY( list_tail($$), var_t, entry );
 555                                                     $3->eval = make_exprl(EXPR_NUM, last->eval->cval + 1);
 556                                                   }
 557                                                   $$ = append_var( $1, $3 );
 558                                                 }
 559         ;
 560
 561 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 562                                                   $$->eval = $3;
 563                                                   $$->type = make_int(0);
 564                                                 }
 565         | ident                                 { $$ = reg_const($1);
 566                                                   $$->type = make_int(0);
 567                                                 }
 568         ;
 569
 570 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 571                                                   $$->kind = TKIND_ENUM;
 572                                                   $$->fields = $4;
 573                                                   $$->defined = TRUE;
 574                                                   if(in_typelib)
 575                                                       add_typelib_entry($$);
 576                                                 }
 577         ;
 578
 579 m_exprs:  m_expr                                { $$ = append_expr( NULL, $1 ); }
 580         | m_exprs ',' m_expr                    { $$ = append_expr( $1, $3 ); }
 581         ;
 582
 583 /*
 584 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 585         | expr_list
 586         ;
 587
 588 expr_list: expr
 589         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 590         ;
 591 */
 592
 593 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 594         | expr
 595         ;
 596
 597 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 598         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 599         | aDOUBLE                               { $$ = make_exprd(EXPR_DOUBLE, $1); }
 600         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 601         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 602         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 603         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 604         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 605         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 606         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 607         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 608         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 609         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 610         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 611         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 612         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 613         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 614         | '&' expr %prec ADDRESSOF      { $$ = make_expr1(EXPR_ADDRESSOF, $2); }
 615         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 616         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 617         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 618         | '(' expr ')'                          { $$ = $2; }
 619         ;
 620
 621 expr_list_const: expr_const                     { $$ = append_expr( NULL, $1 ); }
 622         | expr_list_const ',' expr_const        { $$ = append_expr( $1, $3 ); }
 623         ;
 624
 625 expr_const: expr                                { $$ = $1;
 626                                                   if (!$$->is_const)
 627                                                       error_loc("expression is not constant\n");
 628                                                 }
 629         ;
 630
 631 externdef: tEXTERN tCONST type ident            { $$ = $4;
 632                                                   set_type($$, $3, 0, NULL, FALSE);
 633                                                 }
 634         ;
 635
 636 fields:                                         { $$ = NULL; }
 637         | fields field                          { $$ = append_var( $1, $2 ); }
 638         ;
 639
 640 field:    s_field ';'                           { $$ = $1; }
 641         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 642         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 643         | ';'                                   { $$ = NULL; }
 644         ;
 645
 646 s_field:  m_attributes type pident array        { $$ = $3->var;
 647                                                   $$->attrs = $1;
 648                                                   set_type($$, $2, $3->ptr_level, $4, FALSE);
 649                                                   free($3);
 650                                                 }
 651         ;
 652
 653 funcdef:
 654           m_attributes type callconv pident
 655           '(' m_args ')'                        { var_t *v = $4->var;
 656                                                   v->attrs = $1;
 657                                                   set_type(v, $2, $4->ptr_level, NULL, FALSE);
 658                                                   free($4);
 659                                                   $$ = make_func(v, $6);
 660                                                   if (is_attr(v->attrs, ATTR_IN)) {
 661                                                     error_loc("inapplicable attribute [in] for function '%s'\n",$$->def->name);
 662                                                   }
 663                                                 }
 664         ;
 665
 666 m_ident:                                        { $$ = NULL; }
 667         | ident
 668         ;
 669
 670 t_ident:                                        { $$ = NULL; }
 671         | aIDENTIFIER                           { $$ = make_var($1); }
 672         | aKNOWNTYPE                            { $$ = make_var($1); }
 673         ;
 674
 675 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 676 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 677         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 678         ;
 679
 680 base_type: tBYTE                                { $$ = make_builtin($<str>1); }
 681         | tWCHAR                                { $$ = make_builtin($<str>1); }
 682         | int_std
 683         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 684         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 685                                                   switch ($$->type) {
 686                                                   case RPC_FC_CHAR:  break;
 687                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 688                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 689                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 690                                                   case RPC_FC_HYPER:
 691                                                     if ($$->name[0] == 'h') /* hyper, as opposed to __int64 */
 692                                                     {
 693                                                       $$ = alias($$, "MIDL_uhyper");
 694                                                       $$->sign = 0;
 695                                                     }
 696                                                     break;
 697                                                   default: break;
 698                                                   }
 699                                                 }
 700         | tUNSIGNED                             { $$ = make_int(-1); }
 701         | tFLOAT                                { $$ = make_builtin($<str>1); }
 702         | tSINGLE                               { $$ = duptype(find_type("float", 0), 1); }
 703         | tDOUBLE                               { $$ = make_builtin($<str>1); }
 704         | tBOOLEAN                              { $$ = make_builtin($<str>1); }
 705         | tERRORSTATUST                         { $$ = make_builtin($<str>1); }
 706         | tHANDLET                              { $$ = make_builtin($<str>1); }
 707         ;
 708
 709 m_int:
 710         | tINT
 711         ;
 712
 713 int_std:  tINT                                  { $$ = make_builtin($<str>1); }
 714         | tSHORT m_int                          { $$ = make_builtin($<str>1); }
 715         | tSMALL                                { $$ = make_builtin($<str>1); }
 716         | tLONG m_int                           { $$ = make_builtin($<str>1); }
 717         | tHYPER m_int                          { $$ = make_builtin($<str>1); }
 718         | tINT64                                { $$ = make_builtin($<str>1); }
 719         | tCHAR                                 { $$ = make_builtin($<str>1); }
 720         ;
 721
 722 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 723         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 724                                                   if ($$->defined) error_loc("multiple definition error\n");
 725                                                   if ($$->kind != TKIND_COCLASS) error_loc("%s was not declared a coclass\n", $2);
 726                                                 }
 727         ;
 728
 729 coclasshdr: attributes coclass                  { $$ = $2;
 730                                                   $$->attrs = $1;
 731                                                   if (!parse_only && do_header)
 732                                                     write_coclass($$);
 733                                                   if (!parse_only && do_idfile)
 734                                                     write_clsid($$);
 735                                                 }
 736         ;
 737
 738 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 739                                                   $$->ifaces = $3;
 740                                                   $$->defined = TRUE;
 741                                                 }
 742         ;
 743
 744 coclass_ints:                                   { $$ = NULL; }
 745         | coclass_ints coclass_int              { $$ = append_ifref( $1, $2 ); }
 746         ;
 747
 748 coclass_int:
 749           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 750         ;
 751
 752 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 753         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 754         ;
 755
 756 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 757                                                   $$ = $2;
 758                                                   if ($$->defined) error_loc("multiple definition error\n");
 759                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 760                                                   $$->attrs = append_attr( $1, attrs );
 761                                                   $$->ref = find_type("IDispatch", 0);
 762                                                   if (!$$->ref) error_loc("IDispatch is undefined\n");
 763                                                   $$->defined = TRUE;
 764                                                   if (!parse_only && do_header) write_forward($$);
 765                                                 }
 766         ;
 767
 768 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 769         | dispint_props s_field ';'             { $$ = append_var( $1, $2 ); }
 770         ;
 771
 772 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 773         | dispint_meths funcdef ';'             { $$ = append_func( $1, $2 ); }
 774         ;
 775
 776 dispinterfacedef: dispinterfacehdr '{'
 777           dispint_props
 778           dispint_meths
 779           '}'                                   { $$ = $1;
 780                                                   $$->fields = $3;
 781                                                   $$->funcs = $4;
 782                                                   if (!parse_only && do_header) write_dispinterface($$);
 783                                                   if (!parse_only && do_idfile) write_diid($$);
 784                                                 }
 785         | dispinterfacehdr
 786          '{' interface ';' '}'                  { $$ = $1;
 787                                                   $$->fields = $3->fields;
 788                                                   $$->funcs = $3->funcs;
 789                                                   if (!parse_only && do_header) write_dispinterface($$);
 790                                                   if (!parse_only && do_idfile) write_diid($$);
 791                                                 }
 792         ;
 793
 794 inherit:                                        { $$ = NULL; }
 795         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 796         ;
 797
 798 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 799         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 800         ;
 801
 802 interfacehdr: attributes interface              { $$.interface = $2;
 803                                                   $$.old_pointer_default = pointer_default;
 804                                                   if (is_attr($1, ATTR_POINTERDEFAULT))
 805                                                     pointer_default = get_attrv($1, ATTR_POINTERDEFAULT);
 806                                                   if ($2->defined) error_loc("multiple definition error\n");
 807                                                   $2->attrs = $1;
 808                                                   $2->defined = TRUE;
 809                                                   if (!parse_only && do_header) write_forward($2);
 810                                                 }
 811         ;
 812
 813 interfacedef: interfacehdr inherit
 814           '{' int_statements '}'                { $$ = $1.interface;
 815                                                   $$->ref = $2;
 816                                                   $$->funcs = $4;
 817                                                   compute_method_indexes($$);
 818                                                   if (!parse_only && do_header) write_interface($$);
 819                                                   if (!parse_only && local_stubs) write_locals(local_stubs, $$, TRUE);
 820                                                   if (!parse_only && do_idfile) write_iid($$);
 821                                                   pointer_default = $1.old_pointer_default;
 822                                                 }
 823 /* MIDL is able to import the definition of a base class from inside the
 824  * definition of a derived class, I'll try to support it with this rule */
 825         | interfacehdr ':' aIDENTIFIER
 826           '{' import int_statements '}'         { $$ = $1.interface;
 827                                                   $$->ref = find_type2($3, 0);
 828                                                   if (!$$->ref) error_loc("base class '%s' not found in import\n", $3);
 829                                                   $$->funcs = $6;
 830                                                   compute_method_indexes($$);
 831                                                   if (!parse_only && do_header) write_interface($$);
 832                                                   if (!parse_only && local_stubs) write_locals(local_stubs, $$, TRUE);
 833                                                   if (!parse_only && do_idfile) write_iid($$);
 834                                                   pointer_default = $1.old_pointer_default;
 835                                                 }
 836         | dispinterfacedef                      { $$ = $1; }
 837         ;
 838
 839 interfacedec:
 840           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 841         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 842         ;
 843
 844 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 845         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 846         ;
 847
 848 modulehdr: attributes module                    { $$ = $2;
 849                                                   $$->attrs = $1;
 850                                                 }
 851         ;
 852
 853 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 854                                                   $$->funcs = $3;
 855                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 856                                                 }
 857         ;
 858
 859 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 860         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 861         ;
 862
 863 pident:   ident                                 { $$ = make_pident($1); }
 864         | p_ident
 865         | '(' pident ')'                        { $$ = $2; }
 866         ;
 867
 868 pident_list:
 869         pident                                  { $$ = append_pident( NULL, $1 ); }
 870         | pident_list ',' pident                { $$ = append_pident( $1, $3 ); }
 871         ;
 872
 873 pointer_type:
 874           tREF                                  { $$ = RPC_FC_RP; }
 875         | tUNIQUE                               { $$ = RPC_FC_UP; }
 876         | tPTR                                  { $$ = RPC_FC_FP; }
 877         ;
 878
 879 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 880                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 881                                                   $$->type = get_struct_type( $4 );
 882                                                   $$->kind = TKIND_RECORD;
 883                                                   $$->fields = $4;
 884                                                   $$->defined = TRUE;
 885                                                   if(in_typelib)
 886                                                       add_typelib_entry($$);
 887                                                 }
 888         ;
 889
 890 type:     tVOID                                 { $$ = duptype(find_type("void", 0), 1); }
 891         | aKNOWNTYPE                            { $$ = find_type($1, 0); }
 892         | base_type                             { $$ = $1; }
 893         | tCONST type                           { $$ = duptype($2, 1); $$->is_const = TRUE; }
 894         | enumdef                               { $$ = $1; }
 895         | tENUM aIDENTIFIER                     { $$ = find_type2($2, tsENUM); }
 896         | structdef                             { $$ = $1; }
 897         | tSTRUCT aIDENTIFIER                   { $$ = get_type(RPC_FC_STRUCT, $2, tsSTRUCT); }
 898         | uniondef                              { $$ = $1; }
 899         | tUNION aIDENTIFIER                    { $$ = find_type2($2, tsUNION); }
 900         | tSAFEARRAY '(' type ')'               { $$ = make_safearray($3); }
 901         ;
 902
 903 typedef: tTYPEDEF m_attributes type pident_list { reg_typedefs($3, $4, $2);
 904                                                   process_typedefs($4);
 905                                                 }
 906         ;
 907
 908 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 909                                                   $$->kind = TKIND_UNION;
 910                                                   $$->fields = $4;
 911                                                   $$->defined = TRUE;
 912                                                 }
 913         | tUNION t_ident
 914           tSWITCH '(' s_field ')'
 915           m_ident '{' cases '}'                 { var_t *u = $7;
 916                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 917                                                   $$->kind = TKIND_UNION;
 918                                                   if (!u) u = make_var( xstrdup("tagged_union") );
 919                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 920                                                   u->type->kind = TKIND_UNION;
 921                                                   u->type->fields = $9;
 922                                                   u->type->defined = TRUE;
 923                                                   $$->fields = append_var( $$->fields, $5 );
 924                                                   $$->fields = append_var( $$->fields, u );
 925                                                   $$->defined = TRUE;
 926                                                 }
 927         ;
 928
 929 version:
 930           aNUM                                  { $$ = MAKEVERSION($1, 0); }
 931         | aNUM '.' aNUM                         { $$ = MAKEVERSION($1, $3); }
 932         ;
 933
 934 %%
 935
 936 static void decl_builtin(const char *name, unsigned char type)
 937 {
 938   type_t *t = make_type(type, NULL);
 939   t->name = xstrdup(name);
 940   reg_type(t, name, 0);
 941 }
 942
 943 static type_t *make_builtin(char *name)
 944 {
 945   /* NAME is strdup'd in the lexer */
 946   type_t *t = duptype(find_type(name, 0), 0);
 947   t->name = name;
 948   return t;
 949 }
 950
 951 static type_t *make_int(int sign)
 952 {
 953   type_t *t = duptype(find_type("int", 0), 1);
 954
 955   t->sign = sign;
 956   if (sign < 0)
 957     t->type = t->type == RPC_FC_LONG ? RPC_FC_ULONG : RPC_FC_USHORT;
 958
 959   return t;
 960 }
 961
 962 void init_types(void)
 963 {
 964   decl_builtin("void", 0);
 965   decl_builtin("byte", RPC_FC_BYTE);
 966   decl_builtin("wchar_t", RPC_FC_WCHAR);
 967   decl_builtin("int", RPC_FC_LONG);     /* win32 */
 968   decl_builtin("short", RPC_FC_SHORT);
 969   decl_builtin("small", RPC_FC_SMALL);
 970   decl_builtin("long", RPC_FC_LONG);
 971   decl_builtin("hyper", RPC_FC_HYPER);
 972   decl_builtin("__int64", RPC_FC_HYPER);
 973   decl_builtin("char", RPC_FC_CHAR);
 974   decl_builtin("float", RPC_FC_FLOAT);
 975   decl_builtin("double", RPC_FC_DOUBLE);
 976   decl_builtin("boolean", RPC_FC_BYTE);
 977   decl_builtin("error_status_t", RPC_FC_ERROR_STATUS_T);
 978   decl_builtin("handle_t", RPC_FC_BIND_PRIMITIVE);
 979 }
 980
 981 static str_list_t *append_str(str_list_t *list, char *str)
 982 {
 983     struct str_list_entry_t *entry;
 984
 985     if (!str) return list;
 986     if (!list)
 987     {
 988         list = xmalloc( sizeof(*list) );
 989         list_init( list );
 990     }
 991     entry = xmalloc( sizeof(*entry) );
 992     entry->str = str;
 993     list_add_tail( list, &entry->entry );
 994     return list;
 995 }
 996
 997 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr)
 998 {
 999     if (!attr) return list;
1000     if (!list)
1001     {
1002         list = xmalloc( sizeof(*list) );
1003         list_init( list );
1004     }
1005     list_add_tail( list, &attr->entry );
1006     return list;
1007 }
1008
1009 static attr_t *make_attr(enum attr_type type)
1010 {
1011   attr_t *a = xmalloc(sizeof(attr_t));
1012   a->type = type;
1013   a->u.ival = 0;
1014   return a;
1015 }
1016
1017 static attr_t *make_attrv(enum attr_type type, unsigned long val)
1018 {
1019   attr_t *a = xmalloc(sizeof(attr_t));
1020   a->type = type;
1021   a->u.ival = val;
1022   return a;
1023 }
1024
1025 static attr_t *make_attrp(enum attr_type type, void *val)
1026 {
1027   attr_t *a = xmalloc(sizeof(attr_t));
1028   a->type = type;
1029   a->u.pval = val;
1030   return a;
1031 }
1032
1033 static expr_t *make_expr(enum expr_type type)
1034 {
1035   expr_t *e = xmalloc(sizeof(expr_t));
1036   e->type = type;
1037   e->ref = NULL;
1038   e->u.lval = 0;
1039   e->is_const = FALSE;
1040   e->cval = 0;
1041   return e;
1042 }
1043
1044 static expr_t *make_exprl(enum expr_type type, long val)
1045 {
1046   expr_t *e = xmalloc(sizeof(expr_t));
1047   e->type = type;
1048   e->ref = NULL;
1049   e->u.lval = val;
1050   e->is_const = FALSE;
1051   /* check for numeric constant */
1052   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
1053     /* make sure true/false value is valid */
1054     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
1055     e->is_const = TRUE;
1056     e->cval = val;
1057   }
1058   return e;
1059 }
1060
1061 static expr_t *make_exprd(enum expr_type type, double val)
1062 {
1063   expr_t *e = xmalloc(sizeof(expr_t));
1064   e->type = type;
1065   e->ref = NULL;
1066   e->u.dval = val;
1067   e->is_const = TRUE;
1068   e->cval = val;
1069   return e;
1070 }
1071
1072 static expr_t *make_exprs(enum expr_type type, char *val)
1073 {
1074   expr_t *e;
1075   e = xmalloc(sizeof(expr_t));
1076   e->type = type;
1077   e->ref = NULL;
1078   e->u.sval = val;
1079   e->is_const = FALSE;
1080   /* check for predefined constants */
1081   if (type == EXPR_IDENTIFIER) {
1082     var_t *c = find_const(val, 0);
1083     if (c) {
1084       e->u.sval = c->name;
1085       free(val);
1086       e->is_const = TRUE;
1087       e->cval = c->eval->cval;
1088     }
1089   }
1090   return e;
1091 }
1092
1093 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr)
1094 {
1095   expr_t *e;
1096   e = xmalloc(sizeof(expr_t));
1097   e->type = type;
1098   e->ref = expr;
1099   e->u.tref = tref;
1100   e->is_const = FALSE;
1101   /* check for cast of constant expression */
1102   if (type == EXPR_SIZEOF) {
1103     switch (tref->type) {
1104       case RPC_FC_BYTE:
1105       case RPC_FC_CHAR:
1106       case RPC_FC_SMALL:
1107       case RPC_FC_USMALL:
1108         e->is_const = TRUE;
1109         e->cval = 1;
1110         break;
1111       case RPC_FC_WCHAR:
1112       case RPC_FC_USHORT:
1113       case RPC_FC_SHORT:
1114         e->is_const = TRUE;
1115         e->cval = 2;
1116         break;
1117       case RPC_FC_LONG:
1118       case RPC_FC_ULONG:
1119       case RPC_FC_FLOAT:
1120       case RPC_FC_ERROR_STATUS_T:
1121         e->is_const = TRUE;
1122         e->cval = 4;
1123         break;
1124       case RPC_FC_HYPER:
1125       case RPC_FC_DOUBLE:
1126         e->is_const = TRUE;
1127         e->cval = 8;
1128         break;
1129     }
1130   }
1131   if (type == EXPR_CAST && expr->is_const) {
1132     e->is_const = TRUE;
1133     e->cval = expr->cval;
1134   }
1135   return e;
1136 }
1137
1138 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
1139 {
1140   expr_t *e;
1141   if (type == EXPR_ADDRESSOF && expr->type != EXPR_IDENTIFIER)
1142     error("address-of operator applied to invalid expression\n");
1143   e = xmalloc(sizeof(expr_t));
1144   e->type = type;
1145   e->ref = expr;
1146   e->u.lval = 0;
1147   e->is_const = FALSE;
1148   /* check for compile-time optimization */
1149   if (expr->is_const) {
1150     e->is_const = TRUE;
1151     switch (type) {
1152     case EXPR_NEG:
1153       e->cval = -expr->cval;
1154       break;
1155     case EXPR_NOT:
1156       e->cval = ~expr->cval;
1157       break;
1158     default:
1159       e->is_const = FALSE;
1160       break;
1161     }
1162   }
1163   return e;
1164 }
1165
1166 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1167 {
1168   expr_t *e;
1169   e = xmalloc(sizeof(expr_t));
1170   e->type = type;
1171   e->ref = expr1;
1172   e->u.ext = expr2;
1173   e->is_const = FALSE;
1174   /* check for compile-time optimization */
1175   if (expr1->is_const && expr2->is_const) {
1176     e->is_const = TRUE;
1177     switch (type) {
1178     case EXPR_ADD:
1179       e->cval = expr1->cval + expr2->cval;
1180       break;
1181     case EXPR_SUB:
1182       e->cval = expr1->cval - expr2->cval;
1183       break;
1184     case EXPR_MUL:
1185       e->cval = expr1->cval * expr2->cval;
1186       break;
1187     case EXPR_DIV:
1188       e->cval = expr1->cval / expr2->cval;
1189       break;
1190     case EXPR_OR:
1191       e->cval = expr1->cval | expr2->cval;
1192       break;
1193     case EXPR_AND:
1194       e->cval = expr1->cval & expr2->cval;
1195       break;
1196     case EXPR_SHL:
1197       e->cval = expr1->cval << expr2->cval;
1198       break;
1199     case EXPR_SHR:
1200       e->cval = expr1->cval >> expr2->cval;
1201       break;
1202     default:
1203       e->is_const = FALSE;
1204       break;
1205     }
1206   }
1207   return e;
1208 }
1209
1210 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1211 {
1212   expr_t *e;
1213   e = xmalloc(sizeof(expr_t));
1214   e->type = type;
1215   e->ref = expr1;
1216   e->u.ext = expr2;
1217   e->ext2 = expr3;
1218   e->is_const = FALSE;
1219   /* check for compile-time optimization */
1220   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1221     e->is_const = TRUE;
1222     switch (type) {
1223     case EXPR_COND:
1224       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1225       break;
1226     default:
1227       e->is_const = FALSE;
1228       break;
1229     }
1230   }
1231   return e;
1232 }
1233
1234 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr)
1235 {
1236     if (!expr) return list;
1237     if (!list)
1238     {
1239         list = xmalloc( sizeof(*list) );
1240         list_init( list );
1241     }
1242     list_add_tail( list, &expr->entry );
1243     return list;
1244 }
1245
1246 static array_dims_t *append_array(array_dims_t *list, expr_t *expr)
1247 {
1248     if (!expr) return list;
1249     if (!list)
1250     {
1251         list = xmalloc( sizeof(*list) );
1252         list_init( list );
1253     }
1254     list_add_tail( list, &expr->entry );
1255     return list;
1256 }
1257
1258 static struct list type_pool = LIST_INIT(type_pool);
1259 typedef struct
1260 {
1261   type_t data;
1262   struct list link;
1263 } type_pool_node_t;
1264
1265 type_t *alloc_type(void)
1266 {
1267   type_pool_node_t *node = xmalloc(sizeof *node);
1268   list_add_tail(&type_pool, &node->link);
1269   return &node->data;
1270 }
1271
1272 void set_all_tfswrite(int val)
1273 {
1274   type_pool_node_t *node;
1275   LIST_FOR_EACH_ENTRY(node, &type_pool, type_pool_node_t, link)
1276     node->data.tfswrite = val;
1277 }
1278
1279 static type_t *make_type(unsigned char type, type_t *ref)
1280 {
1281   type_t *t = alloc_type();
1282   t->name = NULL;
1283   t->kind = TKIND_PRIMITIVE;
1284   t->type = type;
1285   t->ref = ref;
1286   t->attrs = NULL;
1287   t->orig = NULL;
1288   t->funcs = NULL;
1289   t->fields = NULL;
1290   t->ifaces = NULL;
1291   t->dim = 0;
1292   t->size_is = NULL;
1293   t->length_is = NULL;
1294   t->typestring_offset = 0;
1295   t->ptrdesc = 0;
1296   t->declarray = FALSE;
1297   t->ignore = (parse_only != 0);
1298   t->is_const = FALSE;
1299   t->sign = 0;
1300   t->defined = FALSE;
1301   t->written = FALSE;
1302   t->user_types_registered = FALSE;
1303   t->tfswrite = FALSE;
1304   t->typelib_idx = -1;
1305   return t;
1306 }
1307
1308 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr,
1309                      int top)
1310 {
1311   expr_list_t *sizes = get_attrp(v->attrs, ATTR_SIZEIS);
1312   expr_list_t *lengs = get_attrp(v->attrs, ATTR_LENGTHIS);
1313   int ptr_attr = get_attrv(v->attrs, ATTR_POINTERTYPE);
1314   int ptr_type = ptr_attr;
1315   int sizeless, has_varconf;
1316   expr_t *dim;
1317   type_t *atype, **ptype;
1318
1319   v->type = type;
1320
1321   if (!ptr_type && top)
1322     ptr_type = RPC_FC_RP;
1323
1324   for ( ; 0 < ptr_level; --ptr_level)
1325   {
1326     v->type = make_type(pointer_default, v->type);
1327     if (ptr_level == 1 && ptr_type && !arr)
1328     {
1329       v->type->type = ptr_type;
1330       ptr_type = 0;
1331     }
1332   }
1333
1334   if (ptr_type && !arr)
1335   {
1336     if (is_ptr(v->type))
1337     {
1338       if (v->type->type != ptr_type)
1339       {
1340         v->type = duptype(v->type, 1);
1341         v->type->type = ptr_type;
1342       }
1343     }
1344     else if (!arr && ptr_attr)
1345       error("%s: pointer attribute applied to non-pointer type\n", v->name);
1346   }
1347
1348   sizeless = FALSE;
1349   if (arr) LIST_FOR_EACH_ENTRY_REV(dim, arr, expr_t, entry)
1350   {
1351     if (sizeless)
1352       error("%s: only the first array dimension can be unspecified\n", v->name);
1353
1354     if (dim->is_const)
1355     {
1356       unsigned int align = 0;
1357       size_t size = type_memsize(v->type, &align);
1358
1359       if (dim->cval <= 0)
1360         error("%s: array dimension must be positive\n", v->name);
1361
1362       if (0xffffffffuL / size < (unsigned long) dim->cval)
1363         error("%s: total array size is too large\n", v->name);
1364       else if (0xffffuL < size * dim->cval)
1365         v->type = make_type(RPC_FC_LGFARRAY, v->type);
1366       else
1367         v->type = make_type(RPC_FC_SMFARRAY, v->type);
1368     }
1369     else
1370     {
1371       sizeless = TRUE;
1372       v->type = make_type(RPC_FC_CARRAY, v->type);
1373     }
1374
1375     v->type->declarray = TRUE;
1376     v->type->dim = dim->cval;
1377   }
1378
1379   ptype = &v->type;
1380   has_varconf = FALSE;
1381   if (sizes) LIST_FOR_EACH_ENTRY(dim, sizes, expr_t, entry)
1382   {
1383     if (dim->type != EXPR_VOID)
1384     {
1385       has_varconf = TRUE;
1386       atype = *ptype = duptype(*ptype, 0);
1387
1388       if (atype->type == RPC_FC_SMFARRAY || atype->type == RPC_FC_LGFARRAY)
1389         error("%s: cannot specify size_is for a fixed sized array\n", v->name);
1390
1391       if (atype->type != RPC_FC_CARRAY && !is_ptr(atype))
1392         error("%s: size_is attribute applied to illegal type\n", v->name);
1393
1394       atype->type = RPC_FC_CARRAY;
1395       atype->size_is = dim;
1396     }
1397
1398     ptype = &(*ptype)->ref;
1399     if (*ptype == NULL)
1400       error("%s: too many expressions in size_is attribute\n", v->name);
1401   }
1402
1403   ptype = &v->type;
1404   if (lengs) LIST_FOR_EACH_ENTRY(dim, lengs, expr_t, entry)
1405   {
1406     if (dim->type != EXPR_VOID)
1407     {
1408       has_varconf = TRUE;
1409       atype = *ptype = duptype(*ptype, 0);
1410
1411       if (atype->type == RPC_FC_SMFARRAY)
1412         atype->type = RPC_FC_SMVARRAY;
1413       else if (atype->type == RPC_FC_LGFARRAY)
1414         atype->type = RPC_FC_LGVARRAY;
1415       else if (atype->type == RPC_FC_CARRAY)
1416         atype->type = RPC_FC_CVARRAY;
1417       else
1418         error("%s: length_is attribute applied to illegal type\n", v->name);
1419
1420       atype->length_is = dim;
1421     }
1422
1423     ptype = &(*ptype)->ref;
1424     if (*ptype == NULL)
1425       error("%s: too many expressions in length_is attribute\n", v->name);
1426   }
1427
1428   if (has_varconf && !last_array(v->type))
1429   {
1430     ptype = &v->type;
1431     for (ptype = &v->type; is_array(*ptype); ptype = &(*ptype)->ref)
1432     {
1433       *ptype = duptype(*ptype, 0);
1434       (*ptype)->type = RPC_FC_BOGUS_ARRAY;
1435     }
1436   }
1437
1438   if (is_array(v->type))
1439   {
1440     const type_t *rt = v->type->ref;
1441     if (is_user_type(rt))
1442       v->type->type = RPC_FC_BOGUS_ARRAY;
1443     else
1444       switch (rt->type)
1445         {
1446         case RPC_FC_BOGUS_STRUCT:
1447         case RPC_FC_NON_ENCAPSULATED_UNION:
1448         case RPC_FC_ENCAPSULATED_UNION:
1449         case RPC_FC_ENUM16:
1450           v->type->type = RPC_FC_BOGUS_ARRAY;
1451           break;
1452           /* FC_RP should be above, but widl overuses these, and will break things.  */
1453         case RPC_FC_UP:
1454         case RPC_FC_RP:
1455           if (rt->ref->type == RPC_FC_IP)
1456             v->type->type = RPC_FC_BOGUS_ARRAY;
1457           break;
1458         }
1459   }
1460 }
1461
1462 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface)
1463 {
1464     if (!iface) return list;
1465     if (!list)
1466     {
1467         list = xmalloc( sizeof(*list) );
1468         list_init( list );
1469     }
1470     list_add_tail( list, &iface->entry );
1471     return list;
1472 }
1473
1474 static ifref_t *make_ifref(type_t *iface)
1475 {
1476   ifref_t *l = xmalloc(sizeof(ifref_t));
1477   l->iface = iface;
1478   l->attrs = NULL;
1479   return l;
1480 }
1481
1482 static var_list_t *append_var(var_list_t *list, var_t *var)
1483 {
1484     if (!var) return list;
1485     if (!list)
1486     {
1487         list = xmalloc( sizeof(*list) );
1488         list_init( list );
1489     }
1490     list_add_tail( list, &var->entry );
1491     return list;
1492 }
1493
1494 static var_t *make_var(char *name)
1495 {
1496   var_t *v = xmalloc(sizeof(var_t));
1497   v->name = name;
1498   v->type = NULL;
1499   v->args = NULL;
1500   v->attrs = NULL;
1501   v->eval = NULL;
1502   return v;
1503 }
1504
1505 static pident_list_t *append_pident(pident_list_t *list, pident_t *p)
1506 {
1507   if (!p) return list;
1508   if (!list) {
1509     list = xmalloc(sizeof(*list));
1510     list_init(list);
1511   }
1512   list_add_tail(list, &p->entry);
1513   return list;
1514 }
1515
1516 static pident_t *make_pident(var_t *var)
1517 {
1518   pident_t *p = xmalloc(sizeof(*p));
1519   p->var = var;
1520   p->ptr_level = 0;
1521   return p;
1522 }
1523
1524 static func_list_t *append_func(func_list_t *list, func_t *func)
1525 {
1526     if (!func) return list;
1527     if (!list)
1528     {
1529         list = xmalloc( sizeof(*list) );
1530         list_init( list );
1531     }
1532     list_add_tail( list, &func->entry );
1533     return list;
1534 }
1535
1536 static func_t *make_func(var_t *def, var_list_t *args)
1537 {
1538   func_t *f = xmalloc(sizeof(func_t));
1539   f->def = def;
1540   f->args = args;
1541   f->ignore = parse_only;
1542   f->idx = -1;
1543   return f;
1544 }
1545
1546 static type_t *make_class(char *name)
1547 {
1548   type_t *c = make_type(0, NULL);
1549   c->name = name;
1550   c->kind = TKIND_COCLASS;
1551   return c;
1552 }
1553
1554 static type_t *make_safearray(type_t *type)
1555 {
1556   type_t *sa = duptype(find_type("SAFEARRAY", 0), 1);
1557   sa->ref = type;
1558   return make_type(pointer_default, sa);
1559 }
1560
1561 #define HASHMAX 64
1562
1563 static int hash_ident(const char *name)
1564 {
1565   const char *p = name;
1566   int sum = 0;
1567   /* a simple sum hash is probably good enough */
1568   while (*p) {
1569     sum += *p;
1570     p++;
1571   }
1572   return sum & (HASHMAX-1);
1573 }
1574
1575 /***** type repository *****/
1576
1577 struct rtype {
1578   const char *name;
1579   type_t *type;
1580   int t;
1581   struct rtype *next;
1582 };
1583
1584 struct rtype *type_hash[HASHMAX];
1585
1586 static type_t *reg_type(type_t *type, const char *name, int t)
1587 {
1588   struct rtype *nt;
1589   int hash;
1590   if (!name) {
1591     error_loc("registering named type without name\n");
1592     return type;
1593   }
1594   hash = hash_ident(name);
1595   nt = xmalloc(sizeof(struct rtype));
1596   nt->name = name;
1597   nt->type = type;
1598   nt->t = t;
1599   nt->next = type_hash[hash];
1600   type_hash[hash] = nt;
1601   return type;
1602 }
1603
1604 static int is_incomplete(const type_t *t)
1605 {
1606   return !t->defined && (is_struct(t->type) || is_union(t->type));
1607 }
1608
1609 static void add_incomplete(type_t *t)
1610 {
1611   struct typenode *tn = xmalloc(sizeof *tn);
1612   tn->type = t;
1613   list_add_tail(&incomplete_types, &tn->entry);
1614 }
1615
1616 static void fix_type(type_t *t)
1617 {
1618   if (t->kind == TKIND_ALIAS && is_incomplete(t)) {
1619     type_t *ot = t->orig;
1620     fix_type(ot);
1621     t->fields = ot->fields;
1622     t->defined = ot->defined;
1623   }
1624 }
1625
1626 static void fix_incomplete(void)
1627 {
1628   struct typenode *tn, *next;
1629
1630   LIST_FOR_EACH_ENTRY_SAFE(tn, next, &incomplete_types, struct typenode, entry) {
1631     fix_type(tn->type);
1632     free(tn);
1633   }
1634 }
1635
1636 static type_t *reg_typedefs(type_t *type, pident_list_t *pidents, attr_list_t *attrs)
1637 {
1638   type_t *ptr = type;
1639   const pident_t *pident;
1640   int ptrc = 0;
1641   int is_str = is_attr(attrs, ATTR_STRING);
1642   unsigned char ptr_type = get_attrv(attrs, ATTR_POINTERTYPE);
1643
1644   if (is_str)
1645   {
1646     type_t *t = type;
1647     unsigned char c;
1648
1649     while (is_ptr(t))
1650       t = t->ref;
1651
1652     c = t->type;
1653     if (c != RPC_FC_CHAR && c != RPC_FC_BYTE && c != RPC_FC_WCHAR)
1654     {
1655       pident = LIST_ENTRY( list_head( pidents ), const pident_t, entry );
1656       error_loc("'%s': [string] attribute is only valid on 'char', 'byte', or 'wchar_t' pointers and arrays\n",
1657               pident->var->name);
1658     }
1659   }
1660
1661   /* We must generate names for tagless enum, struct or union.
1662      Typedef-ing a tagless enum, struct or union means we want the typedef
1663      to be included in a library whether it has other attributes or not,
1664      hence the public attribute.  */
1665   if ((type->kind == TKIND_ENUM || type->kind == TKIND_RECORD
1666        || type->kind == TKIND_UNION) && ! type->name && ! parse_only)
1667   {
1668     if (! is_attr(attrs, ATTR_PUBLIC))
1669       attrs = append_attr( attrs, make_attr(ATTR_PUBLIC) );
1670     type->name = gen_name();
1671   }
1672
1673   LIST_FOR_EACH_ENTRY( pident, pidents, const pident_t, entry )
1674   {
1675     var_t *name = pident->var;
1676
1677     if (name->name) {
1678       type_t *cur = ptr;
1679       int cptr = pident->ptr_level;
1680       if (cptr > ptrc) {
1681         while (cptr > ptrc) {
1682           cur = ptr = make_type(pointer_default, cur);
1683           ptrc++;
1684         }
1685       } else {
1686         while (cptr < ptrc) {
1687           cur = cur->ref;
1688           cptr++;
1689         }
1690       }
1691       cur = alias(cur, name->name);
1692       cur->attrs = attrs;
1693       if (ptr_type)
1694       {
1695         if (is_ptr(cur))
1696           cur->type = ptr_type;
1697         else
1698           error_loc("'%s': pointer attribute applied to non-pointer type\n",
1699                   cur->name);
1700       }
1701       else if (is_str && ! is_ptr(cur))
1702         error_loc("'%s': [string] attribute applied to non-pointer type\n",
1703                 cur->name);
1704
1705       if (is_incomplete(cur))
1706         add_incomplete(cur);
1707       reg_type(cur, cur->name, 0);
1708     }
1709   }
1710   return type;
1711 }
1712
1713 static type_t *find_type(const char *name, int t)
1714 {
1715   struct rtype *cur = type_hash[hash_ident(name)];
1716   while (cur && (cur->t != t || strcmp(cur->name, name)))
1717     cur = cur->next;
1718   if (!cur) {
1719     error_loc("type '%s' not found\n", name);
1720     return NULL;
1721   }
1722   return cur->type;
1723 }
1724
1725 static type_t *find_type2(char *name, int t)
1726 {
1727   type_t *tp = find_type(name, t);
1728   free(name);
1729   return tp;
1730 }
1731
1732 int is_type(const char *name)
1733 {
1734   struct rtype *cur = type_hash[hash_ident(name)];
1735   while (cur && (cur->t || strcmp(cur->name, name)))
1736     cur = cur->next;
1737   if (cur) return TRUE;
1738   return FALSE;
1739 }
1740
1741 static type_t *get_type(unsigned char type, char *name, int t)
1742 {
1743   struct rtype *cur = NULL;
1744   type_t *tp;
1745   if (name) {
1746     cur = type_hash[hash_ident(name)];
1747     while (cur && (cur->t != t || strcmp(cur->name, name)))
1748       cur = cur->next;
1749   }
1750   if (cur) {
1751     free(name);
1752     return cur->type;
1753   }
1754   tp = make_type(type, NULL);
1755   tp->name = name;
1756   if (!name) return tp;
1757   return reg_type(tp, name, t);
1758 }
1759
1760 static type_t *get_typev(unsigned char type, var_t *name, int t)
1761 {
1762   char *sname = NULL;
1763   if (name) {
1764     sname = name->name;
1765     free(name);
1766   }
1767   return get_type(type, sname, t);
1768 }
1769
1770 static int get_struct_type(var_list_t *fields)
1771 {
1772   int has_pointer = 0;
1773   int has_conformance = 0;
1774   int has_variance = 0;
1775   var_t *field;
1776
1777   if (get_padding(fields))
1778     return RPC_FC_BOGUS_STRUCT;
1779
1780   if (fields) LIST_FOR_EACH_ENTRY( field, fields, var_t, entry )
1781   {
1782     type_t *t = field->type;
1783
1784     if (is_user_type(t))
1785       return RPC_FC_BOGUS_STRUCT;
1786
1787     if (is_ptr(t))
1788     {
1789         do
1790             t = t->ref;
1791         while (is_ptr(t));
1792
1793         switch (t->type)
1794         {
1795         case RPC_FC_IP:
1796         case RPC_FC_ENCAPSULATED_UNION:
1797         case RPC_FC_NON_ENCAPSULATED_UNION:
1798         case RPC_FC_BOGUS_STRUCT:
1799             return RPC_FC_BOGUS_STRUCT;
1800         }
1801
1802         has_pointer = 1;
1803         continue;
1804     }
1805
1806     if (field->type->declarray)
1807     {
1808         if (is_string_type(field->attrs, field->type))
1809         {
1810             if (is_conformant_array(field->type))
1811                 has_conformance = 1;
1812             has_variance = 1;
1813             continue;
1814         }
1815
1816         if (is_array(field->type->ref))
1817             return RPC_FC_BOGUS_STRUCT;
1818
1819         if (is_conformant_array(field->type))
1820         {
1821             has_conformance = 1;
1822             if (field->type->declarray && list_next(fields, &field->entry))
1823                 error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1824                         field->name);
1825         }
1826         if (field->type->length_is)
1827             has_variance = 1;
1828
1829         t = field->type->ref;
1830     }
1831
1832     switch (t->type)
1833     {
1834     /*
1835      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1836      *  Simple types don't effect the type of struct.
1837      *  A struct containing a simple struct is still a simple struct.
1838      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1839      */
1840     case 0: /* void pointer */
1841     case RPC_FC_BYTE:
1842     case RPC_FC_CHAR:
1843     case RPC_FC_SMALL:
1844     case RPC_FC_USMALL:
1845     case RPC_FC_WCHAR:
1846     case RPC_FC_SHORT:
1847     case RPC_FC_USHORT:
1848     case RPC_FC_LONG:
1849     case RPC_FC_ULONG:
1850     case RPC_FC_INT3264:
1851     case RPC_FC_UINT3264:
1852     case RPC_FC_HYPER:
1853     case RPC_FC_FLOAT:
1854     case RPC_FC_DOUBLE:
1855     case RPC_FC_STRUCT:
1856     case RPC_FC_ENUM16:
1857     case RPC_FC_ENUM32:
1858       break;
1859
1860     case RPC_FC_RP:
1861     case RPC_FC_UP:
1862     case RPC_FC_FP:
1863     case RPC_FC_OP:
1864     case RPC_FC_CARRAY:
1865     case RPC_FC_CVARRAY:
1866     case RPC_FC_BOGUS_ARRAY:
1867       has_pointer = 1;
1868       break;
1869
1870     /*
1871      * Propagate member attributes
1872      *  a struct should be at least as complex as its member
1873      */
1874     case RPC_FC_CVSTRUCT:
1875       has_conformance = 1;
1876       has_variance = 1;
1877       has_pointer = 1;
1878       break;
1879
1880     case RPC_FC_CPSTRUCT:
1881       has_conformance = 1;
1882       if (list_next( fields, &field->entry ))
1883           error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1884                   field->name);
1885       has_pointer = 1;
1886       break;
1887
1888     case RPC_FC_CSTRUCT:
1889       has_conformance = 1;
1890       if (list_next( fields, &field->entry ))
1891           error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1892                   field->name);
1893       break;
1894
1895     case RPC_FC_PSTRUCT:
1896       has_pointer = 1;
1897       break;
1898
1899     default:
1900       error_loc("Unknown struct member %s with type (0x%02x)\n", field->name, t->type);
1901       /* fallthru - treat it as complex */
1902
1903     /* as soon as we see one of these these members, it's bogus... */
1904     case RPC_FC_ENCAPSULATED_UNION:
1905     case RPC_FC_NON_ENCAPSULATED_UNION:
1906     case RPC_FC_BOGUS_STRUCT:
1907       return RPC_FC_BOGUS_STRUCT;
1908     }
1909   }
1910
1911   if( has_variance )
1912   {
1913     if ( has_conformance )
1914       return RPC_FC_CVSTRUCT;
1915     else
1916       return RPC_FC_BOGUS_STRUCT;
1917   }
1918   if( has_conformance && has_pointer )
1919     return RPC_FC_CPSTRUCT;
1920   if( has_conformance )
1921     return RPC_FC_CSTRUCT;
1922   if( has_pointer )
1923     return RPC_FC_PSTRUCT;
1924   return RPC_FC_STRUCT;
1925 }
1926
1927 /***** constant repository *****/
1928
1929 struct rconst {
1930   char *name;
1931   var_t *var;
1932   struct rconst *next;
1933 };
1934
1935 struct rconst *const_hash[HASHMAX];
1936
1937 static var_t *reg_const(var_t *var)
1938 {
1939   struct rconst *nc;
1940   int hash;
1941   if (!var->name) {
1942     error_loc("registering constant without name\n");
1943     return var;
1944   }
1945   hash = hash_ident(var->name);
1946   nc = xmalloc(sizeof(struct rconst));
1947   nc->name = var->name;
1948   nc->var = var;
1949   nc->next = const_hash[hash];
1950   const_hash[hash] = nc;
1951   return var;
1952 }
1953
1954 static var_t *find_const(char *name, int f)
1955 {
1956   struct rconst *cur = const_hash[hash_ident(name)];
1957   while (cur && strcmp(cur->name, name))
1958     cur = cur->next;
1959   if (!cur) {
1960     if (f) error_loc("constant '%s' not found\n", name);
1961     return NULL;
1962   }
1963   return cur->var;
1964 }
1965
1966 static void write_libid(const char *name, const attr_list_t *attr)
1967 {
1968   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1969   write_guid(idfile, "LIBID", name, uuid);
1970 }
1971
1972 static void write_clsid(type_t *cls)
1973 {
1974   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1975   write_guid(idfile, "CLSID", cls->name, uuid);
1976 }
1977
1978 static void write_diid(type_t *iface)
1979 {
1980   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1981   write_guid(idfile, "DIID", iface->name, uuid);
1982 }
1983
1984 static void write_iid(type_t *iface)
1985 {
1986   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1987   write_guid(idfile, "IID", iface->name, uuid);
1988 }
1989
1990 static int compute_method_indexes(type_t *iface)
1991 {
1992   int idx;
1993   func_t *f;
1994
1995   if (iface->ref)
1996     idx = compute_method_indexes(iface->ref);
1997   else
1998     idx = 0;
1999
2000   if (!iface->funcs)
2001     return idx;
2002
2003   LIST_FOR_EACH_ENTRY( f, iface->funcs, func_t, entry )
2004     if (! is_callas(f->def->attrs))
2005       f->idx = idx++;
2006
2007   return idx;
2008 }
2009
2010 static char *gen_name(void)
2011 {
2012   static const char format[] = "__WIDL_%s_generated_name_%08lX";
2013   static unsigned long n = 0;
2014   static const char *file_id;
2015   static size_t size;
2016   char *name;
2017
2018   if (! file_id)
2019   {
2020     char *dst = dup_basename(input_name, ".idl");
2021     file_id = dst;
2022
2023     for (; *dst; ++dst)
2024       if (! isalnum((unsigned char) *dst))
2025         *dst = '_';
2026
2027     size = sizeof format - 7 + strlen(file_id) + 8;
2028   }
2029
2030   name = xmalloc(size);
2031   sprintf(name, format, file_id, n++);
2032   return name;
2033 }
2034
2035 static void process_typedefs(pident_list_t *pidents)
2036 {
2037   pident_t *pident, *next;
2038
2039   if (!pidents) return;
2040   LIST_FOR_EACH_ENTRY_SAFE( pident, next, pidents, pident_t, entry )
2041   {
2042     var_t *var = pident->var;
2043     type_t *type = find_type(var->name, 0);
2044
2045     if (! parse_only && do_header)
2046       write_typedef(type);
2047     if (in_typelib && type->attrs)
2048       add_typelib_entry(type);
2049
2050     free(pident);
2051     free(var);
2052   }
2053 }
2054
2055 static void check_arg(var_t *arg)
2056 {
2057   type_t *t = arg->type;
2058
2059   if (t->type == 0 && ! is_var_ptr(arg))
2060     error_loc("argument '%s' has void type\n", arg->name);
2061 }
2062
2063 static void check_all_user_types(ifref_list_t *ifrefs)
2064 {
2065   const ifref_t *ifref;
2066   const func_t *f;
2067
2068   if (ifrefs) LIST_FOR_EACH_ENTRY(ifref, ifrefs, const ifref_t, entry)
2069   {
2070     const func_list_t *fs = ifref->iface->funcs;
2071     if (fs) LIST_FOR_EACH_ENTRY(f, fs, const func_t, entry)
2072       check_for_user_types_and_context_handles(f->args);
2073   }
2074 }
2075
2076 int is_valid_uuid(const char *s)
2077 {
2078   int i;
2079
2080   for (i = 0; i < 36; ++i)
2081     if (i == 8 || i == 13 || i == 18 || i == 23)
2082     {
2083       if (s[i] != '-')
2084         return FALSE;
2085     }
2086     else
2087       if (!isxdigit(s[i]))
2088         return FALSE;
2089
2090   return s[i] == '\0';
2091 }