git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  47
  48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  49   [if test -z "$with_wine_tools"; then
  50      if test "$cross_compiling" = "yes"; then
  51        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  52      else
  53        wine_cv_toolsdir="\$(TOPOBJDIR)"
  54      fi
  55    elif test -d "$with_wine_tools/tools/winebuild"; then
  56      case $with_wine_tools in
  57        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  58        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  59      esac
  60    else
  61      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  62    fi])
  63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  64
  65 AC_PATH_XTRA
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  71 if test "$XLEX" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  74 fi
  75
  76 dnl Check for bison
  77 AC_CHECK_PROGS(BISON,bison,none)
  78 if test "$BISON" = "none"
  79 then
  80   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  81 fi
  82
  83 AC_CHECK_TOOLS(AS,[gas as],as)
  84 AC_CHECK_TOOL(LD,ld,ld)
  85 AC_CHECK_TOOL(AR,ar,ar)
  86 AC_PROG_RANLIB
  87 AC_CHECK_TOOL(STRIP,strip,strip)
  88 AC_CHECK_TOOL(WINDRES,windres,false)
  89 AC_PROG_LN_S
  90 WINE_PROG_LN
  91 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  92 AC_PROG_INSTALL
  93 dnl Prepend src dir to install path dir if it's a relative path
  94 case "$INSTALL" in
  95   [[\\/$]]* | ?:[[\\/]]* ) ;;
  96   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  97 esac
  98
  99 dnl Check for lint
 100 AC_CHECK_PROGS(LINT, lclint lint)
 101 if test "$LINT" = "lint"
 102 then
 103   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 104   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 105 fi
 106 AC_SUBST(LINT)
 107 AC_SUBST(LINTFLAGS)
 108
 109 dnl Check for db2html
 110 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 111 AC_SUBST(DB2HTML)
 112
 113 dnl Check for db2pdf
 114 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 115 AC_SUBST(DB2PDF)
 116
 117 dnl Check for db2ps
 118 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 119 AC_SUBST(DB2PS)
 120
 121 dnl Check for db2txt
 122 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 123 AC_SUBST(DB2TXT)
 124
 125 dnl **** Check for some libraries ****
 126
 127 dnl Check for -li386 for NetBSD and OpenBSD
 128 AC_CHECK_LIB(i386,i386_set_ldt)
 129 dnl Check for -lossaudio for NetBSD
 130 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 131 dnl Check for -lw for Solaris
 132 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 133 dnl Check for -lnsl for Solaris
 134 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 135 dnl Check for -lsocket for Solaris
 136 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 137 dnl Check for -lresolv for Solaris
 138 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 139 dnl Check for -lxpg4 for FreeBSD
 140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 141 dnl Check for -lpoll for Mac OS X/Darwin
 142 AC_CHECK_LIB(poll,poll)
 143 dnl Check for -lpthread
 144 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 145
 146 JPEGLIB=""
 147 AC_SUBST(JPEGLIB)
 148 AC_CHECK_HEADERS(jpeglib.h,
 149     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 150         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 151         JPEGLIB="-ljpeg"
 152     )
 153 )
 154
 155 AC_SUBST(GIFLIB,"")
 156 AC_CHECK_HEADERS(gif_lib.h,
 157     AC_CHECK_LIB(ungif,DGifOpen,
 158         [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
 159          GIFLIB="-lungif"],
 160         [AC_CHECK_LIB(gif,DGifOpen,
 161                       [AC_DEFINE(HAVE_LIBGIF,1)
 162                        GIFLIB="-lgif"])]))
 163
 164 AC_SUBST(XLIB)
 165 AC_SUBST(XFILES)
 166 XFILES=""
 167 AC_SUBST(OPENGLFILES)
 168 OPENGLFILES=""
 169 AC_SUBST(GLU32FILES)
 170 GLU32FILES=""
 171 AC_SUBST(OPENGL_LIBS)
 172 OPENGL_LIBS=""
 173 if test "$have_x" = "yes"
 174 then
 175     XLIB="-lXext -lX11"
 176     ac_save_CPPFLAGS="$CPPFLAGS"
 177     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 178
 179     dnl *** All of the following tests require X11/Xlib.h
 180     AC_CHECK_HEADERS(X11/Xlib.h,
 181       [
 182         AC_CHECK_HEADERS([X11/XKBlib.h \
 183                           X11/Xutil.h \
 184                           X11/extensions/shape.h \
 185                           X11/extensions/XInput.h \
 186                           X11/extensions/XShm.h \
 187                           X11/extensions/Xrandr.h \
 188                           X11/extensions/Xrender.h \
 189                           X11/extensions/Xvlib.h \
 190                           X11/extensions/xf86dga.h \
 191                           X11/extensions/xf86vmode.h],,,
 192                          [#include <X11/Xlib.h>
 193                           #ifdef HAVE_X11_XUTIL_H
 194                           # include <X11/Xutil.h>
 195                           #endif])
 196
 197         dnl *** Check for X keyboard extension
 198         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 199         then
 200               AC_CHECK_LIB(X11, XkbQueryExtension,
 201               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 202               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 203         fi
 204
 205         dnl *** Check for X Shm extension
 206         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 207         then
 208               AC_CHECK_LIB(Xext, XShmQueryExtension,
 209               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 210               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 211         fi
 212
 213         dnl *** Check for X shape extension
 214         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 215         then
 216               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 217               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 218               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 219         fi
 220
 221         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 222         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 223         then
 224               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 225                 [ dnl *** If found...
 226                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 227                             [Define if you have the Xxf86dga library version 2])
 228                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 229                ],
 230                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 231                   dnl *** instead (DGA 2.0 not found)...
 232                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 233                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 234                                 [Define if you have the Xxf86dga library version 1])
 235                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 236                     ],,
 237                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 238                   )
 239                 ],
 240                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 241         fi
 242
 243         dnl *** Check for XFree86 VMODE extension
 244         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 245         then
 246                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 247                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 248                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 249                   ],,
 250                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 251         fi
 252
 253         dnl *** Check for X RandR extension
 254         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 255         then
 256                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 257 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 258                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 259         fi
 260
 261         dnl *** Check for XVideo extension supporting XvImages
 262         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 263         then
 264                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 265                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 266                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 267                   ],,
 268                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 269         fi
 270       ]
 271     ) dnl *** End of X11/Xlib.h check
 272
 273     dnl Check for the presence of OpenGL
 274     if test "x$with_opengl" != "xno"
 275     then
 276         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 277         then
 278             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 279 This prevents linking to OpenGL. Delete the file and restart configure.])
 280         fi
 281
 282         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 283         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 284         then
 285             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 286             dnl Check for some problems due to old Mesa versions
 287             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 288               AC_TRY_COMPILE(
 289                 [#include <GL/gl.h>],
 290                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 291                 [wine_cv_opengl_version_OK="yes"],
 292                 [wine_cv_opengl_version_OK="no"]
 293               )
 294             )
 295
 296             if test "$wine_cv_opengl_version_OK" = "yes"
 297             then
 298                 dnl Check for the presence of the library
 299                 AC_CHECK_LIB(GL,glXCreateContext,
 300                              OPENGL_LIBS="-lGL"
 301                              ,,
 302                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 303
 304                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 305                 then
 306                         OPENGLFILES='$(OPENGLFILES)'
 307                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 308
 309                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 310                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 311                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 312                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 313
 314                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 315                         then
 316                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 317                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 318                                                   #ifdef HAVE_GL_GLEXT_H
 319                                                   # include <GL/glext.h>
 320                                                   #endif
 321                                                   ],
 322                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 323                                                  [wine_cv_extension_prototypes="yes"],
 324                                                  [wine_cv_extension_prototypes="no"]
 325                                   )]
 326                                 )
 327                                 if test "$wine_cv_extension_prototypes" = "yes"
 328                                 then
 329                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 330                                               [Define if the OpenGL headers define extension typedefs])
 331                                 fi
 332                         fi
 333
 334                 fi
 335                 dnl Check for GLU32 library.
 336                 AC_CHECK_LIB(GLU,gluLookAt,
 337                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 338                              GLU32FILES='$(GLU32FILES)']
 339                              ,,
 340                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 341                 )
 342              fi
 343
 344              dnl Check for glut32 library.
 345              AC_CHECK_LIB(glut,glutMainLoop,
 346                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 347                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 348                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 349          fi
 350     fi
 351
 352     dnl **** Check for NAS ****
 353     AC_SUBST(NASLIBS,"")
 354     AC_CHECK_HEADERS(audio/audiolib.h,
 355          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 356           AC_CHECK_LIB(audio,AuCreateFlow,
 357                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 358                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 359                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 360
 361     CPPFLAGS="$ac_save_CPPFLAGS"
 362     XFILES='$(XFILES)'
 363 else
 364     XLIB=""
 365     X_CFLAGS=""
 366     X_LIBS=""
 367 fi
 368
 369 dnl **** Check which curses lib to use ***
 370 CURSESLIBS=""
 371 if test "x$with_curses" != "xno"
 372 then
 373     AC_CHECK_HEADERS(ncurses.h,
 374         [AC_CHECK_LIB(ncurses,waddch,
 375             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 376              CURSESLIBS="-lncurses"],
 377              [AC_CHECK_HEADERS(curses.h,
 378                  [AC_CHECK_LIB(curses,waddch,
 379                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 380                       CURSESLIBS="-lcurses"])])])])
 381     saved_libs="$LIBS"
 382     LIBS="$CURSESLIBS $LIBS"
 383     AC_CHECK_FUNCS(getbkgd resizeterm)
 384     LIBS="$saved_libs"
 385 fi
 386 AC_SUBST(CURSESLIBS)
 387
 388 dnl **** Check for SANE ****
 389 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 390 if test "$sane_devel" = "no"
 391 then
 392     SANELIBS=""
 393     SANEINCL=""
 394 else
 395     SANELIBS="`$sane_devel --libs`"
 396     SANEINCL="`$sane_devel --cflags`"
 397     ac_save_CPPFLAGS="$CPPFLAGS"
 398     ac_save_LIBS="$LIBS"
 399     CPPFLAGS="$CPPFLAGS $SANEINCL"
 400     LIBS="$LIBS $SANELIBS"
 401     AC_CHECK_HEADER(sane/sane.h,
 402                     [AC_CHECK_LIB(sane,sane_open,
 403                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 404                                   [SANELIBS=""
 405                                   SANEINCL=""])],
 406                     [SANELIBS=""
 407                     SANEINCL=""])
 408     LIBS="$ac_save_LIBS"
 409     CPPFLAGS="$ac_save_CPPFLAGS"
 410 fi
 411 AC_SUBST(SANELIBS)
 412 AC_SUBST(SANEINCL)
 413
 414 dnl **** Check for the ICU library ****
 415 AC_CHECK_HEADERS(unicode/ubidi.h)
 416 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 417 then
 418     saved_libs="$LIBS"
 419     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 420     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 421     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 422     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 423     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 424     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 425                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 426                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 427                  AC_MSG_RESULT(yes)],
 428                 [AC_MSG_RESULT(no)])
 429     LIBS="$saved_libs"
 430 fi
 431
 432 dnl **** Check for FreeType 2 ****
 433 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 434 if test "$ft_lib" = "no"
 435 then
 436     FREETYPEINCL=""
 437     wine_cv_msg_freetype=no
 438 else
 439     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 440     if test "$ft_devel" = "no"
 441     then
 442         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 443         if test "$ft_devel2" = "freetype2-config"
 444         then
 445                 ft_devel=$ft_devel2
 446         fi
 447     fi
 448     if test "$ft_devel" = "no"
 449     then
 450         FREETYPEINCL=""
 451         wine_cv_msg_freetype=yes
 452     else
 453         FREETYPEINCL=`$ft_devel --cflags`
 454         ac_save_CPPFLAGS="$CPPFLAGS"
 455         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 456         AC_CHECK_HEADERS(ft2build.h \
 457                          freetype/freetype.h \
 458                          freetype/ftglyph.h \
 459                          freetype/tttables.h \
 460                          freetype/ftnames.h \
 461                          freetype/ftsnames.h \
 462                          freetype/ttnameid.h \
 463                          freetype/ftoutln.h \
 464                          freetype/internal/sfnt.h,,,
 465                          [#if HAVE_FT2BUILD_H
 466                           #include <ft2build.h>
 467                           #endif])
 468         AC_TRY_CPP([#include <ft2build.h>
 469                     #include <freetype/fttrigon.h>],
 470                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 471           [Define if you have the <freetype/fttrigon.h> header file.])
 472                     wine_cv_fttrigon=yes],
 473                     wine_cv_fttrigon=no)
 474         CPPFLAGS="$ac_save_CPPFLAGS"
 475         dnl Check that we have at least freetype/freetype.h
 476         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 477         then
 478             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 479             wine_cv_msg_freetype=no
 480         else
 481             FREETYPEINCL=""
 482             wine_cv_msg_freetype=yes
 483         fi
 484     fi
 485 fi
 486 AC_SUBST(FREETYPEINCL)
 487
 488 dnl **** Check for parport (currently Linux only) ****
 489 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 490  AC_TRY_COMPILE(
 491    [#include <linux/ppdev.h>],
 492    [ioctl (1,PPCLAIM,0)],
 493    [ac_cv_c_ppdev="yes"],
 494    [ac_cv_c_ppdev="no"])
 495  )
 496 if test "$ac_cv_c_ppdev" = "yes"
 497 then
 498     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 499 fi
 500
 501 dnl **** Check for va_copy ****
 502 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 503  AC_TRY_LINK(
 504    [#include <stdarg.h>],
 505    [va_list ap1, ap2;
 506     va_copy(ap1,ap2);
 507    ],
 508    [ac_cv_c_va_copy="yes"],
 509    [ac_cv_c_va_copy="no"])
 510  )
 511 if test "$ac_cv_c_va_copy" = "yes"
 512 then
 513     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 514 fi
 515 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 516  AC_TRY_LINK(
 517    [#include <stdarg.h>],
 518    [va_list ap1, ap2;
 519     __va_copy(ap1,ap2);
 520    ],
 521    [ac_cv_c___va_copy="yes"],
 522    [ac_cv_c___va_copy="no"])
 523  )
 524 if test "$ac_cv_c___va_copy" = "yes"
 525 then
 526     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 527 fi
 528
 529 dnl **** Check for sigsetjmp ****
 530 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 531  AC_TRY_LINK(
 532    [#include <setjmp.h>],
 533    [sigjmp_buf buf;
 534     sigsetjmp( buf, 1 );
 535     siglongjmp( buf, 1 );],
 536    [ac_cv_c_sigsetjmp="yes"],
 537    [ac_cv_c_sigsetjmp="no"])
 538  )
 539 if test "$ac_cv_c_sigsetjmp" = "yes"
 540 then
 541     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 542 fi
 543
 544 dnl **** Check for pthread_rwlock_t ****
 545 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 546 #include <pthread.h>])
 547
 548 dnl **** Check for pthread_getattr_np ****
 549 ac_save_LIBS="$LIBS"
 550 LIBS="$LIBS $LIBPTHREAD"
 551 AC_CHECK_FUNCS(pthread_getattr_np)
 552 LIBS="$ac_save_LIBS"
 553
 554 dnl **** Check for Open Sound System ****
 555 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 556
 557 AC_CACHE_CHECK([for Open Sound System],
 558         ac_cv_c_opensoundsystem,
 559         AC_TRY_COMPILE([
 560         #if defined(HAVE_SYS_SOUNDCARD_H)
 561                 #include <sys/soundcard.h>
 562         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 563                 #include <machine/soundcard.h>
 564         #elif defined(HAVE_SOUNDCARD_H)
 565                 #include <soundcard.h>
 566         #endif
 567         ],[
 568
 569 /* check for one of the Open Sound System specific SNDCTL_ defines */
 570 #if !defined(SNDCTL_DSP_STEREO)
 571 #error No open sound system
 572 #endif
 573 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 574
 575 if test "$ac_cv_c_opensoundsystem" = "yes"
 576 then
 577     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 578 fi
 579
 580 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 581         ac_cv_c_opensoundsystem_midi,
 582         AC_TRY_COMPILE([
 583         #if defined(HAVE_SYS_SOUNDCARD_H)
 584                 #include <sys/soundcard.h>
 585         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 586                 #include <machine/soundcard.h>
 587         #elif defined(HAVE_SOUNDCARD_H)
 588                 #include <soundcard.h>
 589         #endif
 590         ],[
 591
 592 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 593 #if !defined(SNDCTL_SEQ_SYNC)
 594 #error No open sound system MIDI interface
 595 #endif
 596 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 597
 598 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 599 then
 600     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 601 fi
 602
 603 dnl **** Check for aRts Sound Server ****
 604 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 605 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 606 then
 607     ARTSC_CFLAGS=""
 608     for i in `$ARTSCCONFIG --cflags`
 609     do
 610       case "$i" in
 611         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 612       esac
 613     done
 614     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 615     save_CFLAGS="$CFLAGS"
 616     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 617     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 618         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 619          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 620          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 621     CFLAGS="$save_CFLAGS"
 622 fi
 623
 624 dnl **** Check for ALSA ****
 625 AC_SUBST(ALSALIBS,"")
 626 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 627 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 628 then
 629     AC_CHECK_LIB(asound,snd_pcm_open,
 630         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 631         ALSALIBS="-lasound")
 632 fi
 633
 634 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 635
 636 AC_SUBST(AUDIOIOLIBS,"")
 637 AC_CHECK_HEADERS(libaudioio.h,
 638     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 639                   [AUDIOIOLIBS="-laudioio"
 640                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 641
 642 dnl **** Check for capi4linux ****
 643
 644 AC_CHECK_HEADERS(capi20.h,[
 645         AC_CHECK_HEADERS(linux/capi.h,[
 646                 AC_CHECK_LIB(capi20,capi20_register,[
 647                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 648                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 649                 ])
 650         ])
 651 ])
 652
 653 dnl **** Check for broken glibc mmap64 ****
 654
 655 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 656         AC_TRY_RUN([
 657                 #define _FILE_OFFSET_BITS 64
 658                 #include <stdio.h>
 659                 #include <unistd.h>
 660                 #include <fcntl.h>
 661                 #include <sys/mman.h>
 662                 #include <errno.h>
 663
 664                 int main(int argc,char **argv) {
 665                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 666                         if (fd == -1) exit(1);
 667
 668                         unlink("conftest.map");
 669
 670                         write(fd,"test",4);
 671
 672                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 673                             (errno == EINVAL)
 674                         ) {
 675                                 exit(1);
 676                         }
 677                         close(fd);
 678                         fprintf(stderr,"success!\n");
 679                         exit(0);
 680                 }
 681
 682         ],
 683     ac_cv_mmap64_works="yes",
 684     ac_cv_mmap64_works="no",
 685     ac_cv_mmap64_works="no") )
 686
 687 if test "$ac_cv_mmap64_works" = "yes"
 688 then
 689     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 690 fi
 691
 692 dnl **** Check for gcc specific options ****
 693
 694 AC_SUBST(EXTRACFLAGS,"")
 695 if test "x${GCC}" = "xyes"
 696 then
 697   EXTRACFLAGS="-Wall -pipe"
 698
 699   dnl Check for strength-reduce bug
 700   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 701                   AC_TRY_RUN([
 702 int     L[[4]] = {0,1,2,3};
 703 int main(void) {
 704   static int Array[[3]];
 705   unsigned int B = 3;
 706   int i;
 707   for(i=0; i<B; i++) Array[[i]] = i - 3;
 708   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 709   L[[i]] = 4;
 710
 711   exit( Array[[1]] != -2 || L[[2]] != 3);
 712 }],
 713     ac_cv_c_gcc_strength_bug="no",
 714     ac_cv_c_gcc_strength_bug="yes",
 715     ac_cv_c_gcc_strength_bug="yes") )
 716   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 717   then
 718     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 719   fi
 720
 721   dnl Check for -fshort-wchar
 722   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 723       [WINE_TRY_CFLAGS([-fshort-wchar],
 724                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 725   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 726   then
 727       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 728   fi
 729
 730   dnl Check for -mpreferred-stack-boundary
 731   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 732       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 733                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 734   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 735   then
 736     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 737   fi
 738
 739   dnl Check for -fno-strict-aliasing
 740   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 741       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 742                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 743   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 744   then
 745     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 746   fi
 747
 748   dnl Check for -gstabs+ option
 749   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 750       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 751   if test "$ac_cv_c_gcc_gstabs" = "yes"
 752   then
 753     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 754   fi
 755
 756   dnl Check for noisy string.h
 757   saved_CFLAGS="$CFLAGS"
 758   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 759   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 760       AC_TRY_COMPILE([#include <string.h>],[],
 761                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 762   CFLAGS="$saved_CFLAGS"
 763   if test "$ac_cv_c_string_h_warnings" = "no"
 764   then
 765     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 766   fi
 767 fi
 768
 769 dnl **** Check how to define a function in assembly code ****
 770
 771 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 772   WINE_TRY_ASM_LINK(
 773       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 774       ac_cv_asm_func_def=".def",
 775     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 776       ac_cv_asm_func_def=".type @function",
 777     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 778       ac_cv_asm_func_def=".type 2",
 779       ac_cv_asm_func_def="unknown")])]))
 780
 781 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 782 case "$ac_cv_asm_func_def" in
 783   ".def")
 784      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 785   ".type @function")
 786      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 787   ".type 2")
 788      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 789   *)
 790      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 791 esac
 792
 793 dnl **** Check for underscore on external symbols ****
 794
 795 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 796     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 797                       [extern int ac_test;],
 798                       [if (ac_test) return 1],
 799                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 800
 801 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 802 if test "$ac_cv_c_extern_prefix" = "yes"
 803 then
 804   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 805 else
 806   AC_DEFINE([__ASM_NAME(name)], [name])
 807 fi
 808
 809 dnl **** Check how to do strings in assembler ****
 810
 811 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 812     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 813       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 814         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 815           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 816
 817 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 818                    [Define to the assembler keyword used to specify an ASCII string])
 819
 820 dnl **** Check for .short in assembler ****
 821
 822 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 823     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 824       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 825         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 826
 827 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 828                    [Define to the assembler keyword used to specify a word value])
 829
 830 dnl **** Check for working dll ****
 831
 832 AC_SUBST(DLLEXT,"")
 833 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 834 AC_SUBST(DLLIBS,"")
 835 AC_SUBST(LDSHARED,"")
 836 AC_SUBST(LDDLLFLAGS,"")
 837 AC_SUBST(LIBEXT,"so")
 838 AC_SUBST(IMPLIBEXT,"def")
 839
 840 case $host_os in
 841   cygwin*|mingw32*)
 842     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 843     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 844     if test "$DLLWRAP" = "false"; then
 845       LIBEXT="a"
 846     else
 847       dnl FIXME - check whether dllwrap works correctly...
 848       LIBEXT="dll"
 849     fi
 850     IMPLIBEXT="a"
 851     ;;
 852   *)
 853     AC_CHECK_HEADERS(dlfcn.h,
 854         [AC_CHECK_FUNCS(dlopen,,
 855             [AC_CHECK_LIB(dl,dlopen,
 856                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 857                           DLLIBS="-ldl"],
 858                          [LIBEXT="a"])])],
 859         [LIBEXT="a"])
 860
 861     if test "$LIBEXT" = "so"
 862     then
 863       DLLFLAGS="$DLLFLAGS -fPIC"
 864       DLLEXT=".so"
 865       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 866           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 867                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 868       if test "$ac_cv_c_dll_gnuelf" = "yes"
 869       then
 870         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 871         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 872         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 873           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 874                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 875         if test "$ac_cv_c_dll_zdefs" = "yes"
 876         then
 877           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 878         fi
 879
 880         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 881           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 882                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 883         if test "$ac_cv_c_dll_init_fini" = "yes"
 884         then
 885           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 886         fi
 887
 888         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 889           [echo '{ global: *; };' >conftest.map
 890            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 891                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 892            rm -f conftest.map])
 893         if test "$ac_cv_c_ld_version_scripts" = "yes"
 894         then
 895           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 896         fi
 897
 898         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 899           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 900                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 901         if test "$ac_cv_c_export_dynamic" = "yes"
 902         then
 903           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 904         fi
 905
 906         case $host_cpu in
 907           *i[[3456789]]86*)
 908             AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
 909               [saved_CFLAGS="$CFLAGS"
 910                CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
 911                AC_TRY_RUN([#include <unistd.h>
 912                            int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
 913                           ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
 914                CFLAGS="$saved_CFLAGS"])
 915             if test "$ac_cv_ld_reloc_exec" = "yes"
 916             then
 917               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
 918             fi
 919             ;;
 920         esac
 921
 922       else
 923         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 924             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 925                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 926         if test "$ac_cv_c_dll_unixware" = "yes"
 927         then
 928           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 929           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 930
 931         else
 932           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 933             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 934           if test "$ac_cv_c_dll_macho" = "yes"
 935           then
 936             LIBEXT="dylib"
 937             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 938             LDSHARED="\$(CC) -dynamiclib"
 939             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 940           fi
 941         fi
 942       fi
 943     fi
 944
 945     dnl Check for cross compiler to build test programs
 946     AC_SUBST(CROSSTEST,"")
 947     if test "$cross_compiling" = "no"
 948     then
 949       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 950       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 951       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 952       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 953     fi
 954     ;;
 955 esac
 956
 957 if test "$LIBEXT" = "a"; then
 958   AC_MSG_ERROR(
 959 [could not find a way to build shared libraries.
 960 It is currently not possible to build Wine without shared library
 961 (.so) support to allow transparent switch between .so and .dll files.
 962 If you are using Linux, you will need a newer binutils.]
 963 )
 964 fi
 965
 966 case $build_os in
 967   cygwin*|mingw32*)
 968     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 969   darwin*|macosx*)
 970     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 971   *)
 972     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 973 esac
 974
 975 dnl Mingw needs explicit msvcrt for linking libwine
 976 case $host_os in
 977   mingw32*)
 978     AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
 979 esac
 980
 981 case $host_os in
 982   linux*)
 983     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
 984     AC_SUBST(MAIN_BINARY,"wine-glibc")
 985     ;;
 986   *)
 987     AC_SUBST(WINE_BINARIES,"wine-kthread")
 988     AC_SUBST(MAIN_BINARY,"wine-kthread")
 989     ;;
 990 esac
 991
 992 dnl **** Get the soname for libraries that we load dynamically ****
 993
 994 if test "$LIBEXT" = "so"
 995 then
 996   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
 997   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 998   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 999   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1000   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1001   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1002   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1003   WINE_GET_SONAME(cups,cupsGetDefault)
1004   WINE_GET_SONAME(jack,jack_client_new)
1005   WINE_GET_SONAME(fontconfig,FcInit)
1006   WINE_GET_SONAME(ssl,SSL_library_init)
1007   WINE_GET_SONAME(crypto,BIO_new_socket)
1008   WINE_GET_SONAME(ncurses,waddch)
1009   WINE_GET_SONAME(curses,waddch)
1010 fi
1011
1012
1013 dnl **** Check for functions ****
1014
1015 AC_FUNC_ALLOCA()
1016 AC_CHECK_FUNCS(\
1017         _lwp_create \
1018         _lwp_self \
1019         _pclose \
1020         _popen \
1021         _snprintf \
1022         _spawnvp \
1023         _stricmp \
1024         _strnicmp \
1025         _vsnprintf \
1026         chsize \
1027         clone \
1028         finite \
1029         fpclass \
1030         fstatfs \
1031         fstatvfs \
1032         ftruncate \
1033         ftruncate64 \
1034         futimes \
1035         getnetbyaddr \
1036         getnetbyname \
1037         getopt_long \
1038         getpagesize \
1039         getprotobyname \
1040         getprotobynumber \
1041         getpwuid \
1042         getservbyport \
1043         gettid \
1044         gettimeofday \
1045         inet_network \
1046         lseek64 \
1047         lstat \
1048         memmove \
1049         mmap \
1050         pclose \
1051         popen \
1052         pread \
1053         pwrite \
1054         readlink \
1055         rfork \
1056         select \
1057         sendmsg \
1058         settimeofday \
1059         sigaltstack \
1060         snprintf \
1061         spawnvp \
1062         statfs \
1063         statvfs \
1064         strcasecmp \
1065         strerror \
1066         strncasecmp \
1067         tcgetattr \
1068         timegm \
1069         usleep \
1070         vfscanf \
1071         vsnprintf \
1072         wait4 \
1073         waitpid \
1074 )
1075
1076 dnl **** Check for header files ****
1077
1078 AC_CHECK_HEADERS(\
1079         arpa/inet.h \
1080         arpa/nameser.h \
1081         cups/cups.h \
1082         direct.h \
1083         elf.h \
1084         float.h \
1085         fontconfig/fontconfig.h \
1086         getopt.h \
1087         ieeefp.h \
1088         io.h \
1089         jack/jack.h \
1090         libio.h \
1091         libutil.h \
1092         link.h \
1093         linux/cdrom.h \
1094         linux/hdreg.h \
1095         linux/input.h \
1096         linux/ioctl.h \
1097         linux/joystick.h \
1098         linux/major.h \
1099         linux/param.h \
1100         linux/serial.h \
1101         linux/ucdrom.h \
1102         machine/cpu.h \
1103         netdb.h \
1104         netinet/in.h \
1105         netinet/in_systm.h \
1106         netinet/tcp.h \
1107         netinet/tcp_fsm.h \
1108         openssl/ssl.h \
1109         process.h \
1110         pthread.h \
1111         pty.h \
1112         pwd.h \
1113         regex.h \
1114         sched.h \
1115         scsi/sg.h \
1116         scsi/scsi.h \
1117         scsi/scsi_ioctl.h \
1118         socket.h \
1119         stdint.h \
1120         strings.h \
1121         sys/cdio.h \
1122         sys/elf32.h \
1123         sys/errno.h \
1124         sys/exec_elf.h \
1125         sys/file.h \
1126         sys/filio.h \
1127         sys/inttypes.h \
1128         sys/ioctl.h \
1129         sys/ipc.h \
1130         sys/link.h \
1131         sys/lwp.h \
1132         sys/mman.h \
1133         sys/modem.h \
1134         sys/msg.h \
1135         sys/param.h \
1136         sys/poll.h \
1137         sys/ptrace.h \
1138         sys/reg.h \
1139         sys/scsiio.h \
1140         sys/shm.h \
1141         sys/signal.h \
1142         sys/socket.h \
1143         sys/sockio.h \
1144         sys/statfs.h \
1145         sys/statvfs.h \
1146         sys/strtio.h \
1147         sys/syscall.h \
1148         sys/sysctl.h \
1149         sys/time.h \
1150         sys/times.h \
1151         sys/uio.h \
1152         sys/un.h \
1153         sys/v86.h \
1154         sys/v86intr.h \
1155         sys/vfs.h \
1156         sys/vm86.h \
1157         sys/wait.h \
1158         syscall.h \
1159         termios.h \
1160         unistd.h \
1161         utime.h \
1162         valgrind/memcheck.h
1163 )
1164 AC_HEADER_STAT()
1165
1166 dnl **** Checks for headers that depend on other ones ****
1167
1168 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1169     [#include <sys/types.h>
1170      #if HAVE_SYS_PARAM_H
1171      # include <sys/param.h>
1172      #endif])
1173
1174 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1175     [#include <sys/types.h>
1176      #if HAVE_SYS_SOCKET_H
1177      # include <sys/socket.h>
1178      #endif])
1179
1180 AC_CHECK_HEADERS([resolv.h],,,
1181     [#include <sys/types.h>
1182      #if HAVE_SYS_SOCKET_H
1183      # include <sys/socket.h>
1184      #endif
1185      #if HAVE_NETINET_IN_H
1186      # include <netinet/in.h>
1187      #endif
1188      #if HAVE_ARPA_NAMESER_H
1189      # include <arpa/nameser.h>
1190      #endif])
1191
1192 AC_CHECK_HEADERS(netinet/ip.h,,,
1193     [#include <sys/types.h>
1194      #if HAVE_SYS_SOCKET_H
1195      # include <sys/socket.h>
1196      #endif
1197      #if HAVE_NETINET_IN_SYSTM_H
1198      # include <netinet/in_systm.h>
1199      #endif])
1200
1201 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1202
1203 dnl **** Check for IPX headers (currently Linux only) ****
1204
1205 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1206  AC_TRY_COMPILE(
1207    [#include <sys/types.h>
1208     #ifdef HAVE_SYS_SOCKET_H
1209     # include <sys/socket.h>
1210     #endif
1211     #include <netipx/ipx.h>],
1212    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1213    [ac_cv_c_ipx_gnu="yes"],
1214    [ac_cv_c_ipx_gnu="no"])
1215  )
1216 if test "$ac_cv_c_ipx_gnu" = "yes"
1217 then
1218     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1219 fi
1220
1221 if test "$ac_cv_c_ipx_gnu" = "no"
1222 then
1223  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1224   AC_TRY_COMPILE(
1225     [#include <sys/types.h>
1226      #ifdef HAVE_SYS_SOCKET_H
1227      # include <sys/socket.h>
1228      #endif
1229      #include <asm/types.h>
1230      #include <linux/ipx.h>],
1231     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1232     [ac_cv_c_ipx_linux="yes"],
1233     [ac_cv_c_ipx_linux="no"])
1234   )
1235   if test "$ac_cv_c_ipx_linux" = "yes"
1236   then
1237       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1238   fi
1239 fi
1240
1241 dnl **** Check for types ****
1242
1243 AC_C_CONST
1244 AC_C_INLINE
1245 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1246
1247 AC_CACHE_CHECK([whether linux/input.h is for real],
1248         wine_cv_linux_input_h,
1249         AC_TRY_COMPILE([
1250             #include <linux/input.h>
1251         ] , [
1252             int foo = EVIOCGBIT(EV_ABS,42);
1253             int bar = BTN_PINKIE;
1254             int fortytwo = 42;
1255         ],
1256         wine_cv_linux_input_h=yes,
1257         wine_cv_linux_input_h=no,
1258         no
1259         )
1260     )
1261     if test "$wine_cv_linux_input_h" = "yes"
1262     then
1263         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1264                   [Define if we have linux/input.h AND it contains the INPUT event API])
1265     fi
1266
1267
1268 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1269         wine_cv_linux_gethostbyname_r_6,
1270         AC_TRY_LINK([
1271 #include <netdb.h>
1272         ], [
1273     char *name=NULL;
1274     struct hostent he;
1275     struct hostent *result;
1276     char *buf=NULL;
1277     int bufsize=0;
1278     int res,errnr;
1279     char *addr=NULL;
1280     int addrlen=0;
1281     int addrtype=0;
1282     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1283     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1284     ],
1285         wine_cv_linux_gethostbyname_r_6=yes,
1286         wine_cv_linux_gethostbyname_r_6=no
1287         )
1288    )
1289    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1290    then
1291       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1292                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1293    fi
1294
1295 if test "$ac_cv_header_linux_joystick_h" = "yes"
1296 then
1297    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1298         wine_cv_linux_joystick_22_api,
1299         AC_TRY_COMPILE([
1300         #include <sys/ioctl.h>
1301         #include <linux/joystick.h>
1302
1303         struct js_event blub;
1304         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1305         #error "no 2.2 header"
1306         #endif
1307         ],/*empty*/,
1308         wine_cv_linux_joystick_22_api=yes,
1309         wine_cv_linux_joystick_22_api=no,
1310         wine_cv_linux_joystick_22_api=no
1311         )
1312    )
1313    if test "$wine_cv_linux_joystick_22_api" = "yes"
1314    then
1315       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1316                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1317    fi
1318 fi
1319
1320 dnl **** statfs checks ****
1321
1322 if test "$ac_cv_header_sys_vfs_h" = "yes"
1323 then
1324     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1325                     wine_cv_sys_vfs_has_statfs,
1326         AC_TRY_COMPILE([
1327         #include <sys/types.h>
1328         #ifdef HAVE_SYS_PARAM_H
1329         # include <sys/param.h>
1330         #endif
1331         #include <sys/vfs.h>
1332         ],[
1333                 struct statfs stfs;
1334
1335                 memset(&stfs,0,sizeof(stfs));
1336         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1337         )
1338     )
1339     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1340     then
1341       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1342                 [Define if the struct statfs is defined by <sys/vfs.h>])
1343     fi
1344 fi
1345
1346 if test "$ac_cv_header_sys_statfs_h" = "yes"
1347 then
1348     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1349                     wine_cv_sys_statfs_has_statfs,
1350         AC_TRY_COMPILE([
1351         #include <sys/types.h>
1352         #ifdef HAVE_SYS_PARAM_H
1353         # include <sys/param.h>
1354         #endif
1355         #include <sys/statfs.h>
1356         ],[
1357                 struct statfs stfs;
1358         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1359         )
1360     )
1361     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1362     then
1363       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1364                 [Define if the struct statfs is defined by <sys/statfs.h>])
1365     fi
1366 fi
1367
1368 if test "$ac_cv_header_sys_mount_h" = "yes"
1369 then
1370     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1371                     wine_cv_sys_mount_has_statfs,
1372         AC_TRY_COMPILE([
1373         #include <sys/types.h>
1374         #ifdef HAVE_SYS_PARAM_H
1375         # include <sys/param.h>
1376         #endif
1377         #include <sys/mount.h>
1378         ],[
1379                 struct statfs stfs;
1380         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1381         )
1382     )
1383     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1384     then
1385       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1386                 [Define if the struct statfs is defined by <sys/mount.h>])
1387     fi
1388 fi
1389
1390 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1391
1392 dnl Check for statfs members
1393 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1394 [#include <sys/types.h>
1395 #ifdef HAVE_SYS_PARAM_H
1396 # include <sys/param.h>
1397 #endif
1398 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1399 # include <sys/mount.h>
1400 #else
1401 # ifdef STATFS_DEFINED_BY_SYS_VFS
1402 #  include <sys/vfs.h>
1403 # else
1404 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1405 #   include <sys/statfs.h>
1406 #  endif
1407 # endif
1408 #endif])
1409
1410 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1411 [#ifdef HAVE_SYS_STATVFS_H
1412 #include <sys/statvfs.h>
1413 #endif])
1414
1415 dnl Check for socket structure members
1416 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1417 [#include <sys/types.h>
1418 #ifdef HAVE_SYS_SOCKET_H
1419 # include <sys/socket.h>
1420 #endif
1421 #ifdef HAVE_SYS_UN_H
1422 # include <sys/un.h>
1423 #endif])
1424
1425 dnl Check for siginfo_t members
1426 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1427
1428 dnl Check for struct option
1429 AC_CHECK_MEMBERS([struct option.name],,,
1430 [#ifdef HAVE_GETOPT_H
1431 #include <getopt.h>
1432 #endif])
1433
1434 dnl Check for stat.st_blocks
1435 AC_CHECK_MEMBERS([struct stat.st_blocks])
1436
1437 dnl *** check for the need to define platform-specific symbols
1438
1439 case $host_cpu in
1440   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1441   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1442   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1443   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1444 esac
1445
1446 case $host_vendor in
1447   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1448 esac
1449
1450 dnl **** Generate output files ****
1451
1452 AH_TOP([#define __WINE_CONFIG_H])
1453
1454 WINE_CONFIG_EXTRA_DIR(controls)
1455 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1456 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1457 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1458 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1459 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1460 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1461 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1462 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1463 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1464 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1465 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1466 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1467 WINE_CONFIG_EXTRA_DIR(files)
1468 WINE_CONFIG_EXTRA_DIR(include/wine)
1469 WINE_CONFIG_EXTRA_DIR(misc)
1470 WINE_CONFIG_EXTRA_DIR(objects)
1471 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1472 WINE_CONFIG_EXTRA_DIR(windows)
1473
1474 MAKE_RULES=Make.rules
1475 AC_SUBST_FILE(MAKE_RULES)
1476
1477 MAKE_DLL_RULES=dlls/Makedll.rules
1478 AC_SUBST_FILE(MAKE_DLL_RULES)
1479
1480 MAKE_TEST_RULES=dlls/Maketest.rules
1481 AC_SUBST_FILE(MAKE_TEST_RULES)
1482
1483 MAKE_LIB_RULES=libs/Makelib.rules
1484 AC_SUBST_FILE(MAKE_LIB_RULES)
1485
1486 MAKE_PROG_RULES=programs/Makeprog.rules
1487 AC_SUBST_FILE(MAKE_PROG_RULES)
1488
1489 AC_CONFIG_FILES([
1490 Make.rules
1491 dlls/Makedll.rules
1492 dlls/Maketest.rules
1493 libs/Makelib.rules
1494 programs/Makeprog.rules
1495 Makefile
1496 dlls/Makefile
1497 dlls/advapi32/Makefile
1498 dlls/advapi32/tests/Makefile
1499 dlls/amstream/Makefile
1500 dlls/avicap32/Makefile
1501 dlls/avifil32/Makefile
1502 dlls/cabinet/Makefile
1503 dlls/capi2032/Makefile
1504 dlls/cards/Makefile
1505 dlls/cfgmgr32/Makefile
1506 dlls/comcat/Makefile
1507 dlls/comctl32/Makefile
1508 dlls/comctl32/tests/Makefile
1509 dlls/commdlg/Makefile
1510 dlls/crtdll/Makefile
1511 dlls/crypt32/Makefile
1512 dlls/ctl3d/Makefile
1513 dlls/d3d8/Makefile
1514 dlls/d3d9/Makefile
1515 dlls/d3dim/Makefile
1516 dlls/d3dx8/Makefile
1517 dlls/dbghelp/Makefile
1518 dlls/dciman32/Makefile
1519 dlls/ddraw/Makefile
1520 dlls/ddraw/tests/Makefile
1521 dlls/devenum/Makefile
1522 dlls/dinput/Makefile
1523 dlls/dinput8/Makefile
1524 dlls/dmband/Makefile
1525 dlls/dmcompos/Makefile
1526 dlls/dmime/Makefile
1527 dlls/dmloader/Makefile
1528 dlls/dmscript/Makefile
1529 dlls/dmstyle/Makefile
1530 dlls/dmsynth/Makefile
1531 dlls/dmusic/Makefile
1532 dlls/dmusic32/Makefile
1533 dlls/dplay/Makefile
1534 dlls/dplayx/Makefile
1535 dlls/dpnhpast/Makefile
1536 dlls/dsound/Makefile
1537 dlls/dsound/tests/Makefile
1538 dlls/dswave/Makefile
1539 dlls/dxerr8/Makefile
1540 dlls/dxerr9/Makefile
1541 dlls/dxguid/Makefile
1542 dlls/gdi/Makefile
1543 dlls/gdi/tests/Makefile
1544 dlls/glu32/Makefile
1545 dlls/glut32/Makefile
1546 dlls/iccvid/Makefile
1547 dlls/icmp/Makefile
1548 dlls/ifsmgr.vxd/Makefile
1549 dlls/imagehlp/Makefile
1550 dlls/imm32/Makefile
1551 dlls/iphlpapi/Makefile
1552 dlls/iphlpapi/tests/Makefile
1553 dlls/kernel/Makefile
1554 dlls/kernel/tests/Makefile
1555 dlls/lzexpand/Makefile
1556 dlls/mapi32/Makefile
1557 dlls/mmdevldr.vxd/Makefile
1558 dlls/monodebg.vxd/Makefile
1559 dlls/mpr/Makefile
1560 dlls/msacm/Makefile
1561 dlls/msacm/imaadp32/Makefile
1562 dlls/msacm/msadp32/Makefile
1563 dlls/msacm/msg711/Makefile
1564 dlls/msacm/winemp3/Makefile
1565 dlls/msdmo/Makefile
1566 dlls/mshtml/Makefile
1567 dlls/msi/Makefile
1568 dlls/msimg32/Makefile
1569 dlls/msisys/Makefile
1570 dlls/msnet32/Makefile
1571 dlls/msrle32/Makefile
1572 dlls/msvcrt/Makefile
1573 dlls/msvcrt/tests/Makefile
1574 dlls/msvcrt20/Makefile
1575 dlls/msvcrt40/Makefile
1576 dlls/msvcrtd/Makefile
1577 dlls/msvidc32/Makefile
1578 dlls/msvideo/Makefile
1579 dlls/mswsock/Makefile
1580 dlls/netapi32/Makefile
1581 dlls/netapi32/tests/Makefile
1582 dlls/newdev/Makefile
1583 dlls/ntdll/Makefile
1584 dlls/ntdll/tests/Makefile
1585 dlls/odbc32/Makefile
1586 dlls/ole32/Makefile
1587 dlls/oleacc/Makefile
1588 dlls/oleaut32/Makefile
1589 dlls/oleaut32/tests/Makefile
1590 dlls/olecli/Makefile
1591 dlls/oledlg/Makefile
1592 dlls/olepro32/Makefile
1593 dlls/olesvr/Makefile
1594 dlls/opengl32/Makefile
1595 dlls/psapi/Makefile
1596 dlls/qcap/Makefile
1597 dlls/quartz/Makefile
1598 dlls/rasapi32/Makefile
1599 dlls/richedit/Makefile
1600 dlls/rpcrt4/Makefile
1601 dlls/rpcrt4/tests/Makefile
1602 dlls/rsabase/Makefile
1603 dlls/secur32/Makefile
1604 dlls/serialui/Makefile
1605 dlls/setupapi/Makefile
1606 dlls/shdocvw/Makefile
1607 dlls/shell32/Makefile
1608 dlls/shell32/tests/Makefile
1609 dlls/shfolder/Makefile
1610 dlls/shlwapi/Makefile
1611 dlls/shlwapi/tests/Makefile
1612 dlls/snmpapi/Makefile
1613 dlls/sti/Makefile
1614 dlls/tapi32/Makefile
1615 dlls/ttydrv/Makefile
1616 dlls/twain/Makefile
1617 dlls/unicows/Makefile
1618 dlls/url/Makefile
1619 dlls/urlmon/Makefile
1620 dlls/urlmon/tests/Makefile
1621 dlls/user/Makefile
1622 dlls/user/tests/Makefile
1623 dlls/uuid/Makefile
1624 dlls/uxtheme/Makefile
1625 dlls/vdhcp.vxd/Makefile
1626 dlls/vdmdbg/Makefile
1627 dlls/version/Makefile
1628 dlls/version/tests/Makefile
1629 dlls/vmm.vxd/Makefile
1630 dlls/vnbt.vxd/Makefile
1631 dlls/vnetbios.vxd/Makefile
1632 dlls/vtdapi.vxd/Makefile
1633 dlls/vwin32.vxd/Makefile
1634 dlls/win32s/Makefile
1635 dlls/winaspi/Makefile
1636 dlls/wined3d/Makefile
1637 dlls/winedos/Makefile
1638 dlls/wineps/Makefile
1639 dlls/wininet/Makefile
1640 dlls/wininet/tests/Makefile
1641 dlls/winmm/Makefile
1642 dlls/winmm/joystick/Makefile
1643 dlls/winmm/mcianim/Makefile
1644 dlls/winmm/mciavi/Makefile
1645 dlls/winmm/mcicda/Makefile
1646 dlls/winmm/mciseq/Makefile
1647 dlls/winmm/mciwave/Makefile
1648 dlls/winmm/midimap/Makefile
1649 dlls/winmm/tests/Makefile
1650 dlls/winmm/wavemap/Makefile
1651 dlls/winmm/winealsa/Makefile
1652 dlls/winmm/winearts/Makefile
1653 dlls/winmm/wineaudioio/Makefile
1654 dlls/winmm/winejack/Makefile
1655 dlls/winmm/winenas/Makefile
1656 dlls/winmm/wineoss/Makefile
1657 dlls/winnls/Makefile
1658 dlls/winsock/Makefile
1659 dlls/winsock/tests/Makefile
1660 dlls/winspool/Makefile
1661 dlls/winspool/tests/Makefile
1662 dlls/wintab32/Makefile
1663 dlls/wintrust/Makefile
1664 dlls/wow32/Makefile
1665 dlls/wsock32/Makefile
1666 dlls/x11drv/Makefile
1667 documentation/Makefile
1668 include/Makefile
1669 libs/Makefile
1670 libs/port/Makefile
1671 libs/unicode/Makefile
1672 libs/wine/Makefile
1673 libs/wpp/Makefile
1674 loader/Makefile
1675 programs/Makefile
1676 programs/avitools/Makefile
1677 programs/clock/Makefile
1678 programs/cmdlgtst/Makefile
1679 programs/control/Makefile
1680 programs/expand/Makefile
1681 programs/notepad/Makefile
1682 programs/progman/Makefile
1683 programs/regedit/Makefile
1684 programs/regsvr32/Makefile
1685 programs/rpcss/Makefile
1686 programs/rundll32/Makefile
1687 programs/start/Makefile
1688 programs/taskmgr/Makefile
1689 programs/uninstaller/Makefile
1690 programs/view/Makefile
1691 programs/wcmd/Makefile
1692 programs/wineboot/Makefile
1693 programs/winebrowser/Makefile
1694 programs/winecfg/Makefile
1695 programs/wineconsole/Makefile
1696 programs/winedbg/Makefile
1697 programs/winefile/Makefile
1698 programs/winemenubuilder/Makefile
1699 programs/winemine/Makefile
1700 programs/winepath/Makefile
1701 programs/winetest/Makefile
1702 programs/winevdm/Makefile
1703 programs/winhelp/Makefile
1704 programs/winver/Makefile
1705 server/Makefile
1706 tools/Makefile
1707 tools/widl/Makefile
1708 tools/winapi/Makefile
1709 tools/winebuild/Makefile
1710 tools/winedump/Makefile
1711 tools/winegcc/Makefile
1712 tools/wmc/Makefile
1713 tools/wrc/Makefile])
1714
1715 AC_OUTPUT
1716
1717 if test "$have_x" = "no"
1718 then
1719   echo
1720   echo "*** Warning: X development files not found. Wine will be built without"
1721   echo "*** X support, which currently does not work, and would probably not be"
1722   echo "*** what you want anyway. You will need to install devel packages of"
1723   echo "*** Xlib/Xfree86 at the very least."
1724 fi
1725
1726 if test "$wine_cv_opengl_version_OK" = "no"
1727 then
1728   echo
1729   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1730   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1731 fi
1732
1733 if test "$wine_cv_msg_freetype" = "yes"
1734 then
1735   echo
1736   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1737   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1738   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1739   echo "*** enable Wine to use TrueType fonts."
1740 fi
1741
1742 echo
1743 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1744 echo
1745
1746 dnl Local Variables:
1747 dnl comment-start: "dnl "
1748 dnl comment-end: ""
1749 dnl comment-start-skip: "\\bdnl\\b\\s *"
1750 dnl compile-command: "autoconf"
1751 dnl End: