git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.62 don't handle source dir symlinks correctly
   8 AC_PREREQ(2.62)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND or AS_VAR_IF
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17 m4_ifdef([AS_VAR_IF],,[AC_DEFUN([AS_VAR_IF],
  18 [AS_LITERAL_IF([$1],
  19   [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
  20   [eval as_val=\$$1
  21    AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])])dnl
  22 dnl autoconf versions before 2.64 don't have AC_PACKAGE_URL
  23 m4_ifdef([AC_PACKAGE_URL],,
  24   [AC_DEFINE([PACKAGE_URL], ["http://www.winehq.org"], [Define to the home page for this package.])
  25    AC_SUBST([PACKAGE_URL], ["http://www.winehq.org"])])dnl
  26
  27 dnl **** Command-line arguments ****
  28
  29 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  30 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  31 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  32 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]))
  33
  34 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  36 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  37             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  38 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  40 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  41             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  42 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  43 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  45 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  47 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  48 AC_ARG_WITH(gettext,   AS_HELP_STRING([--without-gettext],[do not use gettext]))
  49 AC_ARG_WITH(gettextpo, AS_HELP_STRING([--with-gettextpo],[use the GetTextPO library to rebuild po files]),
  50             [if test "x$withval" = "xno"; then ac_cv_header_gettext_po_h=no; fi])
  51 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  52 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  54 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  55 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  57 AC_ARG_WITH(gstreamer, AS_HELP_STRING([--without-gstreamer],[do not use GStreamer (codecs support)]))
  58 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  59 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  61 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  63 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_mpg123_h=no; fi])
  65 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  66             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  67 AC_ARG_WITH(opencl,    AS_HELP_STRING([--without-opencl],[do not use OpenCL]),
  68             [if test "x$withval" = "xno"; then ac_cv_header_CL_cl_h=no; ac_cv_header_OpenCL_opencl_h=no; fi])
  69 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  70 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  72 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]))
  73 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  74             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  75 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  77 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  78 AC_ARG_WITH(tiff,       AS_HELP_STRING([--without-tiff],[do not use TIFF]),
  79             [if test "x$withval" = "xno"; then ac_cv_header_tiffio_h=no; fi])
  80 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  81 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  82             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  83 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  84             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  85 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  86             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  87 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  88             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  89 AC_ARG_WITH(xinput2,   AS_HELP_STRING([--without-xinput2],[do not use the Xinput 2 extension]),
  90             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput2_h=no; fi])
  91 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  92 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  93             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  94 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  95             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  96 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  97             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  98 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  99             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
 100 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
 101 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
 102             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
 103 AC_ARG_WITH(zlib,      AS_HELP_STRING([--without-zlib],[do not use Zlib (data compression)]),
 104             [if test "x$withval" = "xno"; then ac_cv_header_zlib_h=no; fi])
 105
 106 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
 107 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
 108
 109 AC_CANONICAL_HOST
 110
 111 dnl check for out of tree build with unclean source tree
 112 case "$srcdir" in
 113  .) ;;
 114  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 115       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 116 You need to run 'make distclean' in the source tree first.])
 117     fi ;;
 118 esac
 119
 120 dnl **** Check for some programs ****
 121
 122 AC_PROG_MAKE_SET
 123 AC_PROG_CC
 124 AC_PROG_CXX
 125 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 126 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 127 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 128
 129 case $host in
 130   *-darwin*)
 131     if test "x$enable_win64" = "xyes"
 132     then
 133       CC="$CC -m64"
 134       CXX="$CXX -m64"
 135       LD="${LD:-ld} -arch x86_64"
 136       AS="${AS:-as} -arch x86_64"
 137       host_cpu="x86_64"
 138       notice_platform="64-bit "
 139       AC_SUBST(TARGETFLAGS,"-m64")
 140     else
 141       CC="$CC -m32"
 142       CXX="$CXX -m32"
 143       LD="${LD:-ld} -arch i386"
 144       AS="${AS:-as} -arch i386"
 145       host_cpu="i386"
 146       notice_platform="32-bit "
 147       AC_SUBST(TARGETFLAGS,"-m32")
 148       enable_win16=${enable_win16:-yes}
 149     fi
 150     ;;
 151   x86_64*)
 152     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 153     then
 154       CC="$CC -m32"
 155       CXX="$CXX -m32"
 156       AC_MSG_CHECKING([whether $CC works])
 157       AC_LINK_IFELSE([AC_LANG_PROGRAM()],AC_MSG_RESULT([yes]),
 158                      [AC_MSG_RESULT([no])
 159                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 160       LD="${LD:-ld} -m elf_i386"
 161       AS="${AS:-as} --32"
 162       host_cpu="i386"
 163       notice_platform="32-bit "
 164       AC_SUBST(TARGETFLAGS,"-m32")
 165       enable_win16=${enable_win16:-yes}
 166     else
 167       if test "x${GCC}" = "xyes"
 168       then
 169         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 170         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 171                           [AC_MSG_RESULT([yes])],
 172                           [AC_MSG_RESULT([no])
 173                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 174       fi
 175       AC_SUBST(TARGETFLAGS,"-m64")
 176     fi
 177     ;;
 178   *-mingw32*|*-cygwin*)
 179     enable_win16=${enable_win16:-no}
 180     CFLAGS="$CFLAGS -D_WIN32"
 181     ;;
 182   i[[3456789]]86*)
 183     enable_win16=${enable_win16:-yes}
 184     ;;
 185 esac
 186
 187 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 188 enable_win16=${enable_win16:-no}
 189 enable_win64=${enable_win64:-no}
 190
 191 dnl Disable winetest too if tests are disabled
 192 enable_winetest=${enable_winetest:-$enable_tests}
 193
 194 dnl Some special cases for the wow64 build
 195 if test -n "$with_wine64"
 196 then
 197     if test "x$enable_win64" = "xyes"
 198     then
 199         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 200 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 201     fi
 202     AC_SUBST([WOW64_DISABLE],[\#])
 203     enable_fonts=${enable_fonts:-no}
 204     enable_server=${enable_server:-no}
 205     enable_tools=${enable_tools:-no}
 206 elif test "x$enable_win64" = "xyes"
 207 then
 208     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib64"
 209 fi
 210
 211 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 212   [wine_cv_toolsdir="$with_wine_tools"
 213    if test -z "$with_wine_tools"; then
 214      if test "$cross_compiling" = "yes"; then
 215        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 216      elif test -n "$with_wine64"; then
 217        wine_cv_toolsdir="$with_wine64"
 218      fi
 219    fi
 220    if test -z "$wine_cv_toolsdir"; then
 221      wine_cv_toolsdir="\$(top_builddir)"
 222    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 223      case "$wine_cv_toolsdir" in
 224        /*) ;;
 225        *)  wine_cv_toolsdir="\$(top_builddir)/$wine_cv_toolsdir" ;;
 226      esac
 227    else
 228      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 229    fi])
 230 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 231 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 232 then
 233     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 234 fi
 235
 236 dnl Check for flex
 237 AC_CHECK_PROGS(FLEX,flex,none)
 238 if test "$FLEX" = "none"
 239 then
 240   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 241 fi
 242 AC_MSG_CHECKING([whether flex is recent enough])
 243 cat >conftest.l <<EOF
 244 %top{
 245 #include "prediluvian.h"
 246 }
 247 %%
 248 EOF
 249 if $FLEX -t conftest.l >/dev/null 2>&AS_MESSAGE_LOG_FD
 250 then
 251   AC_MSG_RESULT([yes])
 252 else
 253   AC_MSG_RESULT([no])
 254   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 255 fi
 256
 257 dnl Check for bison
 258 AC_CHECK_PROGS(BISON,bison,none)
 259 if test "$BISON" = "none"
 260 then
 261   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 262 fi
 263
 264 AC_CHECK_TOOLS(AR,[ar gar],ar)
 265 AC_SUBST(ARFLAGS,rc)
 266 AC_PROG_RANLIB
 267 AC_PROG_LN_S
 268 AC_PROG_EGREP
 269 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 270 AC_PROG_INSTALL
 271 dnl Prepend src dir to install path dir if it's a relative path
 272 case "$INSTALL" in
 273   [[\\/$]]* | ?:[[\\/]]* ) ;;
 274   *)  INSTALL="\\\$(top_srcdir)/$INSTALL" ;;
 275 esac
 276
 277 dnl Check for lint
 278 AC_CHECK_PROGS(LINT, lclint lint)
 279 if test "$LINT" = "lint"
 280 then
 281   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 282   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 283 fi
 284 AC_SUBST(LINTFLAGS)
 285
 286 dnl Check for various programs
 287 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 288 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 289 AC_CHECK_PROGS(RSVG, rsvg, false)
 290 AC_CHECK_PROGS(CONVERT, convert, false)
 291 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 292 AC_CHECK_PROGS(MSGFMT, msgfmt, false)
 293
 294 if test "x$enable_maintainer_mode" != "xyes"
 295 then
 296   AC_SUBST([MAINTAINER_MODE],[\#])
 297 else
 298   if test "$FONTFORGE" = "false"; then AC_MSG_ERROR([You need fontforge to rebuild fonts in maintainer mode.]); fi
 299   if test "$RSVG" = "false"; then AC_MSG_ERROR([You need rsvg to rebuild icons in maintainer mode.]); fi
 300
 301   dnl Check the imagemagick version
 302   if test "$CONVERT" = false
 303   then
 304     AC_MSG_ERROR([You need imagemagick to rebuild icons in maintainer mode.])
 305   else
 306     AC_MSG_CHECKING([for recent enough imagemagick])
 307     convert_version=`convert --version | head -n1`
 308     if test "x$convert_version" != "x"
 309     then
 310       convert_version_major=`expr "$convert_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 311       convert_version_minor=`expr "$convert_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 312       if test "$convert_version_major" -eq 6 -a "$convert_version_minor" -lt 6
 313       then
 314         CONVERT=false
 315       fi
 316     fi
 317     if test "$CONVERT" = false
 318     then
 319       AC_MSG_RESULT([no ($convert_version_major.$convert_version_minor)])
 320       AC_MSG_ERROR([You need imagemagick version 6.6 or newer to rebuild icons in maintainer mode.])
 321     else
 322       AC_MSG_RESULT([yes ($convert_version_major.$convert_version_minor)])
 323     fi
 324   fi
 325
 326   dnl Check the icotool version
 327   if test "$ICOTOOL" = false
 328   then
 329     AC_MSG_ERROR([You need icotool to rebuild icons in maintainer mode.])
 330   else
 331     AC_MSG_CHECKING([for recent enough icotool])
 332     icotool_version=`icotool --version | head -n1`
 333     if test "x$icotool_version" != "x"
 334     then
 335       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 336       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 337       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 338       then
 339         ICOTOOL=false
 340         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 341       fi
 342     fi
 343     if test "$ICOTOOL" = false
 344     then
 345       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 346       AC_MSG_ERROR([You need icotool version 0.29.0 or newer to rebuild icons in maintainer mode.])
 347     else
 348       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 349     fi
 350   fi
 351
 352   dnl Maintainer mode requires gettext
 353   with_gettext=yes
 354   with_gettextpo=yes
 355   AS_UNSET(ac_cv_header_gettext_po_h)
 356 fi
 357
 358 test "x$with_gettext" != xno || MSGFMT=false
 359 WINE_WARNING_WITH(gettext,[test "$MSGFMT" = false],
 360                   [gettext tools not found, translations won't be built.])
 361
 362 dnl **** Check for some libraries ****
 363
 364 dnl Check for -li386 for NetBSD and OpenBSD
 365 AC_CHECK_LIB(i386,i386_set_ldt)
 366 dnl Check for -lossaudio for NetBSD
 367 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 368
 369 AC_SUBST(XLIB,"")
 370 AC_SUBST(OPENGL_LIBS,"")
 371
 372 dnl **** Check for header files ****
 373
 374 AC_SYS_LARGEFILE()
 375
 376 AC_CHECK_HEADERS(\
 377         AL/al.h \
 378         ApplicationServices/ApplicationServices.h \
 379         AudioToolbox/AudioConverter.h \
 380         AudioUnit/AudioUnit.h \
 381         AudioUnit/AudioComponent.h \
 382         CL/cl.h \
 383         Carbon/Carbon.h \
 384         CoreAudio/CoreAudio.h \
 385         DiskArbitration/DiskArbitration.h \
 386         IOKit/IOKitLib.h \
 387         IOKit/hid/IOHIDLib.h \
 388         OpenAL/al.h \
 389         OpenCL/opencl.h \
 390         QuickTime/ImageCompression.h \
 391         Security/Security.h \
 392         alias.h \
 393         alsa/asoundlib.h \
 394         arpa/inet.h \
 395         arpa/nameser.h \
 396         asm/types.h \
 397         capi20.h \
 398         curses.h \
 399         direct.h \
 400         dirent.h \
 401         dlfcn.h \
 402         elf.h \
 403         float.h \
 404         fnmatch.h \
 405         fontconfig/fontconfig.h \
 406         getopt.h \
 407         gettext-po.h \
 408         grp.h \
 409         gsm.h \
 410         gsm/gsm.h \
 411         ieeefp.h \
 412         inet/mib2.h \
 413         io.h \
 414         jpeglib.h \
 415         kstat.h \
 416         lber.h \
 417         lcms.h \
 418         lcms/lcms.h \
 419         ldap.h \
 420         link.h \
 421         linux/cdrom.h \
 422         linux/compiler.h \
 423         linux/hdreg.h \
 424         linux/input.h \
 425         linux/ioctl.h \
 426         linux/joystick.h \
 427         linux/major.h \
 428         linux/param.h \
 429         linux/serial.h \
 430         linux/types.h \
 431         linux/ucdrom.h \
 432         mach-o/nlist.h \
 433         mach-o/loader.h \
 434         mach/mach.h \
 435         mach/machine.h \
 436         machine/cpu.h \
 437         machine/limits.h \
 438         machine/sysarch.h \
 439         mntent.h \
 440         mpg123.h \
 441         ncurses.h \
 442         netdb.h \
 443         netinet/in.h \
 444         netinet/in_systm.h \
 445         netinet/tcp.h \
 446         netinet/tcp_fsm.h \
 447         openssl/err.h \
 448         openssl/ssl.h \
 449         png.h \
 450         poll.h \
 451         port.h \
 452         process.h \
 453         pthread.h \
 454         pwd.h \
 455         regex.h \
 456         sched.h \
 457         scsi/scsi.h \
 458         scsi/scsi_ioctl.h \
 459         scsi/sg.h \
 460         stdbool.h \
 461         stdint.h \
 462         strings.h \
 463         stropts.h \
 464         sys/asoundlib.h \
 465         sys/attr.h \
 466         sys/cdio.h \
 467         sys/elf32.h \
 468         sys/epoll.h \
 469         sys/errno.h \
 470         sys/event.h \
 471         sys/exec_elf.h \
 472         sys/filio.h \
 473         sys/inotify.h \
 474         sys/ioctl.h \
 475         sys/ipc.h \
 476         sys/limits.h \
 477         sys/link.h \
 478         sys/mman.h \
 479         sys/modem.h \
 480         sys/msg.h \
 481         sys/mtio.h \
 482         sys/param.h \
 483         sys/poll.h \
 484         sys/prctl.h \
 485         sys/protosw.h \
 486         sys/ptrace.h \
 487         sys/resource.h \
 488         sys/scsiio.h \
 489         sys/shm.h \
 490         sys/signal.h \
 491         sys/socket.h \
 492         sys/socketvar.h \
 493         sys/sockio.h \
 494         sys/statvfs.h \
 495         sys/strtio.h \
 496         sys/syscall.h \
 497         sys/tihdr.h \
 498         sys/time.h \
 499         sys/timeout.h \
 500         sys/times.h \
 501         sys/uio.h \
 502         sys/un.h \
 503         sys/utsname.h \
 504         sys/vm86.h \
 505         sys/wait.h \
 506         syscall.h \
 507         termios.h \
 508         tiffio.h \
 509         unistd.h \
 510         utime.h \
 511         valgrind/memcheck.h \
 512         valgrind/valgrind.h \
 513         zlib.h
 514 )
 515 AC_HEADER_STAT()
 516
 517 dnl **** Checks for headers that depend on other ones ****
 518
 519 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 520     [#include <sys/types.h>
 521      #ifdef HAVE_SYS_PARAM_H
 522      # include <sys/param.h>
 523      #endif])
 524
 525 AC_CHECK_HEADERS(\
 526         netinet/ip.h \
 527         net/if.h \
 528         net/if_arp.h \
 529         net/if_dl.h \
 530         net/if_types.h \
 531         net/route.h \
 532         netinet/if_ether.h \
 533         netinet/if_inarp.h \
 534         netinet/in_pcb.h \
 535         netinet/ip_icmp.h \
 536         netinet/ip_var.h \
 537         netinet/udp.h \
 538         netipx/ipx.h \
 539 ,,,[#include <sys/types.h>
 540      #ifdef HAVE_SYS_SOCKET_H
 541      # include <sys/socket.h>
 542      #endif
 543      #ifdef HAVE_SYS_SOCKETVAR_H
 544      # include <sys/socketvar.h>
 545      #endif
 546      #ifdef HAVE_NET_ROUTE_H
 547      # include <net/route.h>
 548      #endif
 549      #ifdef HAVE_NETINET_IN_H
 550      # include <netinet/in.h>
 551      #endif
 552      #ifdef HAVE_NETINET_IN_SYSTM_H
 553      # include <netinet/in_systm.h>
 554      #endif
 555      #ifdef HAVE_NET_IF_H
 556      # include <net/if.h>
 557      #endif
 558      #ifdef HAVE_NETINET_IP_H
 559      # include <netinet/ip.h>
 560      #endif])
 561
 562 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 563     [#include <sys/types.h>
 564      #ifdef HAVE_ALIAS_H
 565      # include <alias.h>
 566      #endif
 567      #ifdef HAVE_SYS_SOCKET_H
 568      # include <sys/socket.h>
 569      #endif
 570      #ifdef HAVE_SYS_SOCKETVAR_H
 571      # include <sys/socketvar.h>
 572      #endif
 573      #ifdef HAVE_SYS_TIMEOUT_H
 574      # include <sys/timeout.h>
 575      #endif
 576      #ifdef HAVE_NETINET_IN_H
 577      # include <netinet/in.h>
 578      #endif
 579      #ifdef HAVE_NETINET_IN_SYSTM_H
 580      # include <netinet/in_systm.h>
 581      #endif
 582      #ifdef HAVE_NETINET_IP_H
 583      # include <netinet/ip.h>
 584      #endif
 585      #ifdef HAVE_NETINET_IP_VAR_H
 586      # include <netinet/ip_var.h>
 587      #endif
 588      #ifdef HAVE_NETINET_IP_ICMP_H
 589      # include <netinet/ip_icmp.h>
 590      #endif
 591      #ifdef HAVE_NETINET_UDP_H
 592      # include <netinet/udp.h>
 593      #endif
 594      #ifdef HAVE_NETINET_TCP_H
 595      # include <netinet/tcp.h>
 596      #endif
 597      #ifdef HAVE_NETINET_TCP_TIMER_H
 598      #include <netinet/tcp_timer.h>
 599      #endif])
 600
 601 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h],,,
 602     [#include <sys/types.h>
 603      #ifdef HAVE_ASM_TYPES_H
 604      # include <asm/types.h>
 605      #endif
 606      #ifdef HAVE_SYS_SOCKET_H
 607      # include <sys/socket.h>
 608      #endif
 609      #ifdef HAVE_LINUX_TYPES_H
 610      # include <linux/types.h>
 611      #endif])
 612
 613 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 614     [#ifdef HAVE_STDBOOL_H
 615      # include <stdbool.h>
 616      #endif
 617      #ifdef HAVE_STDINT_H
 618      # include <stdint.h>
 619      #endif])
 620
 621 AC_CHECK_HEADERS([resolv.h],,,
 622     [#include <sys/types.h>
 623      #ifdef HAVE_SYS_SOCKET_H
 624      # include <sys/socket.h>
 625      #endif
 626      #ifdef HAVE_NETINET_IN_H
 627      # include <netinet/in.h>
 628      #endif
 629      #ifdef HAVE_ARPA_NAMESER_H
 630      # include <arpa/nameser.h>
 631      #endif])
 632
 633 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 634
 635 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 636
 637 AC_CHECK_HEADERS([sys/thr.h],,,
 638 [#include <sys/types.h>
 639 #ifdef HAVE_UCONTEXT_H
 640 #include <ucontext.h>
 641 #endif])
 642
 643 AC_CHECK_HEADERS([pthread_np.h],,,
 644 [#ifdef HAVE_PTHREAD_H
 645 #include <pthread.h>
 646 #endif])
 647
 648 AC_CHECK_HEADERS([linux/videodev.h linux/videodev2.h],,,
 649 [#ifdef HAVE_SYS_TIME_H
 650 #include <sys/time.h>
 651 #endif
 652 #include <sys/types.h>
 653 #ifdef HAVE_ASM_TYPES_H
 654 #include <asm/types.h>
 655 #endif])
 656
 657 dnl Check for broken kernel header that doesn't define __user
 658 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 659
 660 dnl **** Check for working dll ****
 661
 662 AC_SUBST(DLLEXT,"")
 663 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 664 AC_SUBST(LDSHARED,"")
 665 AC_SUBST(LDDLLFLAGS,"")
 666 AC_SUBST(LIBEXT,"so")
 667 AC_SUBST(IMPLIBEXT,"def")
 668 AC_SUBST(LDRPATH_INSTALL,"")
 669 AC_SUBST(LDRPATH_LOCAL,"")
 670 STATIC_IMPLIBEXT="def.a"
 671 WINE_PATH_LDD
 672
 673 case $host_os in
 674   cygwin*|mingw32*)
 675     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 676     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 677     if test "$DLLWRAP" = "false"; then
 678       LIBEXT="a"
 679     else
 680       dnl FIXME - check whether dllwrap works correctly...
 681       LIBEXT="dll"
 682     fi
 683     IMPLIBEXT="a"
 684     STATIC_IMPLIBEXT="a"
 685     dnl Disable modules that can't be used on Windows
 686     enable_iphlpapi=${enable_iphlpapi:-no}
 687     enable_kernel32=${enable_kernel32:-no}
 688     enable_msvcrt=${enable_msvcrt:-no}
 689     enable_ntdll=${enable_ntdll:-no}
 690     enable_ws2_32=${enable_ws2_32:-no}
 691     enable_loader=${enable_loader:-no}
 692     enable_server=${enable_server:-no}
 693     dnl Disable dependencies that are not useful on Windows
 694     with_x=${with_x:-no}
 695     with_pthread=${with_pthread:-no}
 696     ;;
 697   darwin*|macosx*)
 698     DLLEXT=".so"
 699     LIBEXT="dylib"
 700     DLLFLAGS="$DLLFLAGS -fPIC"
 701     LDDLLFLAGS="-bundle -multiply_defined suppress"
 702     LIBWINE_LDFLAGS="-multiply_defined suppress"
 703     LDSHARED="\$(CC) -dynamiclib"
 704     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(top_builddir)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 705     dnl declare needed frameworks
 706     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 707     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 708     AC_SUBST(APPLICATIONSERVICESLIB,"-framework ApplicationServices")
 709     case $host_os in
 710       darwin11*)
 711         AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-macosx_version_min,10.6,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000"]) ;;
 712       *)
 713         AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000"]) ;;
 714     esac
 715     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 716     then
 717         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 718         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 719     fi
 720     if test "$ac_cv_header_Security_Security_h" = "yes"
 721     then
 722         AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 723         with_gnutls=${with_gnutls:-no}
 724     fi
 725     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 726     then
 727         if test "$ac_cv_header_AudioUnit_AudioComponent_h" = "yes"
 728         then
 729             AC_SUBST(COREAUDIO,"-framework CoreFoundation -framework CoreAudio -framework AudioUnit -framework AudioToolbox -framework CoreMIDI")
 730         else
 731             dnl CoreServices needed by AudioUnit
 732             AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 733         fi
 734         dnl Check for the AUGraphAddNode function
 735         ac_save_LIBS="$LIBS"
 736         LIBS="$LIBS $COREAUDIO"
 737         AC_CHECK_FUNCS(AUGraphAddNode)
 738         LIBS="$ac_save_LIBS"
 739     fi
 740     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 741     then
 742         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 743         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 744         ac_cv_lib_openal=yes
 745     fi
 746     if test "$ac_cv_header_OpenCL_opencl_h" = "yes"
 747     then
 748         AC_SUBST(LIBOPENCL,"-framework OpenCL")
 749         ac_cv_lib_OpenCL_clGetPlatformInfo=yes
 750     fi
 751     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 752     then
 753         ac_save_LIBS="$LIBS"
 754         LIBS="$LIBS $IOKITLIB"
 755         AC_CHECK_FUNCS(IOHIDManagerCreate)
 756         LIBS="$ac_save_LIBS"
 757     fi
 758     case $host_cpu in
 759       *powerpc*)
 760         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 761         ;;
 762     esac
 763     if test "$ac_cv_header_QuickTime_ImageCompression_h" = "yes"
 764     then
 765         AC_SUBST(QUICKTIMELIB,"-framework QuickTime -framework ApplicationServices -framework CoreVideo")
 766         enable_wineqtdecoder=${enable_wineqtdecoder:-yes}
 767     else
 768         WINE_NOTICE([QuickTime ${notice_platform}development files not found, video decoding won't be supported.])
 769     fi
 770     dnl Enable quartz driver on Mac OS X
 771     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 772     then
 773         AC_SUBST(CARBONLIB,"-framework Carbon")
 774         enable_winequartz_drv=${enable_winequartz_drv:-yes}
 775     fi
 776     dnl Check for Xcode 3.x broken 16-bit support
 777     if test "x$enable_win16" = "xyes"
 778     then
 779         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 780         AC_RUN_IFELSE([AC_LANG_PROGRAM([[asm(".text\n"
 781                                             "bad:\tnop;nop\n"
 782                                             "good:\tnop;nop\n\t"
 783                                             ".globl _testfunc\n"
 784                                             "_testfunc:\tcallw good");
 785                                         extern void testfunc();]],
 786                                       [[unsigned short *p = (unsigned short *)testfunc;
 787                                         return p[0] != 0xe866 || p[1] != 0xfffa]])],
 788                                       AC_MSG_RESULT(yes),
 789                                       [AC_MSG_RESULT(no)
 790                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 791                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 792     fi
 793     ;;
 794   *)
 795     DLLFLAGS="$DLLFLAGS -fPIC"
 796     DLLEXT=".so"
 797     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 798         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 799                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 800     if test "$ac_cv_c_dll_gnuelf" = "yes"
 801     then
 802       LDSHARED="\$(CC) -shared"
 803       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 804       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 805                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 806                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 807                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 808
 809       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 810
 811       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 812                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 813
 814       echo '{ global: *; };' >conftest.map
 815       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 816                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 817       rm -f conftest.map
 818
 819       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 820                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 821
 822       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 823                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 824                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 825           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 826                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 827                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 828
 829       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 830                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 831
 832       case $host_cpu in
 833         *i[[3456789]]86* | x86_64)
 834           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 835                           [case $host_os in
 836                            freebsd* | kfreebsd*-gnu) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x60000400" ;;
 837                            *) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400" ;;
 838                            esac
 839                           ])
 840           AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 841           if test "x$PRELINK" = xfalse
 842           then
 843               WINE_WARNING([prelink not found, base address of core dlls won't be set correctly.])
 844           fi
 845           ;;
 846       esac
 847
 848     else
 849       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 850           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 851                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 852       if test "$ac_cv_c_dll_unixware" = "yes"
 853       then
 854         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 855         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 856
 857       else
 858         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 859           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 860         if test "$ac_cv_c_dll_hpux" = "yes"
 861         then
 862           LIBEXT="sl"
 863           DLLEXT=".sl"
 864           LDDLLFLAGS="-shared -fPIC"
 865           LDSHARED="\$(CC) -shared"
 866         fi
 867       fi
 868     fi
 869     ;;
 870 esac
 871
 872 enable_wineqtdecoder=${enable_wineqtdecoder:-no}
 873 enable_winequartz_drv=${enable_winequartz_drv:-no}
 874
 875 if test "$LIBEXT" = "a"; then
 876   AC_MSG_ERROR(
 877 [could not find a way to build shared libraries.
 878 It is currently not possible to build Wine without shared library
 879 (.so) support to allow transparent switch between .so and .dll files.
 880 If you are using Linux, you will need a newer binutils.]
 881 )
 882 fi
 883
 884 dnl Check for cross compiler to build test programs
 885 AC_SUBST([CROSSTEST_DISABLE],[\#])
 886 if test "$cross_compiling" = "no" -a "x$enable_tests" != xno -a "$LIBEXT" != "dll"
 887 then
 888     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 889     if test "$CROSSCC" != "false"
 890     then
 891         ac_save_CC="$CC"
 892         CC="$CROSSCC"
 893         AC_MSG_CHECKING([whether $CROSSCC works])
 894         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 895                           [AC_MSG_RESULT([yes])
 896                            set x $CROSSCC
 897                            shift
 898                            target=""
 899                            while test $# -ge 1
 900                            do
 901                                case "$1" in
 902                                  *-gcc) target=`expr "$1" : '\(.*\)-gcc'` ;;
 903                                esac
 904                                shift
 905                            done
 906                            if test -n "$target"
 907                            then
 908                                CROSSTEST_DISABLE=""
 909                                AC_SUBST(CROSSTARGET,"$target")
 910                            fi],
 911                           [AC_MSG_RESULT([no])])
 912         CC="$ac_save_CC"
 913     fi
 914 fi
 915
 916 dnl **** Check for pthread ****
 917
 918 if test "$ac_cv_header_pthread_h" = "yes"
 919 then
 920     AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])
 921 fi
 922 WINE_ERROR_WITH(pthread,[test "x$LIBPTHREAD" = "x"],[pthread ${notice_platform}development files not found.
 923 Wine cannot support threads without libpthread.])
 924
 925 dnl **** Check for X11 ****
 926
 927 AC_PATH_XTRA
 928
 929 if test "$have_x" = "yes"
 930 then
 931     XLIB="-lX11"
 932     ac_save_CPPFLAGS="$CPPFLAGS"
 933     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 934
 935     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 936     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 937
 938     dnl *** All of the following tests require X11/Xlib.h
 939     AC_CHECK_HEADERS([X11/Xlib.h \
 940                       X11/XKBlib.h \
 941                       X11/Xutil.h \
 942                       X11/Xcursor/Xcursor.h \
 943                       X11/extensions/shape.h \
 944                       X11/extensions/XInput.h \
 945                       X11/extensions/XInput2.h \
 946                       X11/extensions/XShm.h \
 947                       X11/extensions/Xcomposite.h \
 948                       X11/extensions/Xinerama.h \
 949                       X11/extensions/Xrandr.h \
 950                       X11/extensions/Xrender.h \
 951                       X11/extensions/xf86vmode.h \
 952                       X11/extensions/xf86vmproto.h],,,
 953 [#ifdef HAVE_X11_XLIB_H
 954 # include <X11/Xlib.h>
 955 #endif
 956 #ifdef HAVE_X11_XUTIL_H
 957 # include <X11/Xutil.h>
 958 #endif])
 959
 960         dnl *** Check for X keyboard extension
 961         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 962         then
 963               AC_CHECK_LIB(X11, XkbQueryExtension,
 964               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 965               $X_LIBS $XLIB $X_EXTRA_LIBS)
 966         fi
 967
 968         dnl *** Check for X cursor
 969         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 970         then
 971             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 972         fi
 973         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 974                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
 975
 976         dnl *** Check for X input extension
 977         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 978         then
 979             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 980         fi
 981         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 982                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
 983
 984         dnl *** Check for X input 2 extension
 985         if test "x$ac_cv_lib_soname_Xi" != x
 986         then
 987             WINE_NOTICE_WITH(xinput2,[test "$ac_cv_header_X11_extensions_XInput2_h" != "yes"],
 988                              [XInput2 headers not found, the XInput 2 extension won't be supported.])
 989         fi
 990
 991         dnl *** Check for X Shm extension
 992         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 993         then
 994               AC_CHECK_LIB(Xext, XShmQueryExtension,
 995               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 996               $X_LIBS $XLIB $X_EXTRA_LIBS)
 997         fi
 998         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 999                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
1000
1001         dnl *** Check for X shape extension
1002         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
1003         then
1004               AC_CHECK_LIB(Xext,XShapeQueryExtension,
1005               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
1006               $X_LIBS $XLIB $X_EXTRA_LIBS)
1007         fi
1008         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
1009                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
1010
1011         dnl *** Check for XFree86 VMODE extension
1012         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
1013         then
1014             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1015         fi
1016         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
1017                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
1018
1019         dnl *** Check for Transform functions in Xrender
1020         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
1021         then
1022             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
1023               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
1024                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
1025                  [Define if Xrender has the XRenderSetPictureTransform function])],,
1026                 [$X_LIBS $XLIB $X_EXTRA_LIBS])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1027
1028         fi
1029         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
1030                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
1031
1032         dnl *** Check for X RandR extension
1033         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
1034         then
1035                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1036 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func; if (func) return 0;]])],
1037                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1038         fi
1039         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
1040                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
1041
1042         dnl *** Check for Xinerama extension
1043         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
1044         then
1045                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1046 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func; if (func) return 0;]])],
1047                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1048         fi
1049         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
1050                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
1051
1052         dnl *** Check for X Composite extension
1053         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
1054         then
1055             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1056         fi
1057         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
1058                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
1059
1060         dnl *** Check for XICCallback struct
1061         AC_CHECK_MEMBERS([XICCallback.callback, XEvent.xcookie],,,
1062 [#ifdef HAVE_X11_XLIB_H
1063 #include <X11/Xlib.h>
1064 #endif])
1065
1066     dnl *** End of X11/Xlib.h check
1067
1068     dnl Check for the presence of OpenGL
1069     opengl_msg=""
1070     if test "x$with_opengl" != "xno"
1071     then
1072         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glu.h,,,
1073 [#ifdef HAVE_GL_GLX_H
1074 # include <GL/glx.h>
1075 #endif])
1076         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
1077         then
1078             dnl Check for some problems due to old Mesa versions
1079             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
1080               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;  return (test == GL_UNSIGNED_SHORT_5_6_5);]])],
1081                 [wine_cv_opengl_header_version_OK="yes"],
1082                 [wine_cv_opengl_header_version_OK="no"]))
1083
1084             if test "$wine_cv_opengl_header_version_OK" = "yes"
1085             then
1086                 dnl Check for the presence of the library
1087                 WINE_CHECK_SONAME(GL,glXCreateContext,
1088                              [OPENGL_LIBS="-lGL"
1089                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1090                              [WINE_CHECK_SONAME(GL,glXCreateContext,
1091                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
1092                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1093                                     [if test -f /usr/X11R6/lib/libGL.a
1094                                     then
1095                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1096 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1097                                     else
1098                                         opengl_msg="No OpenGL library found on this system."
1099                                     fi],
1100                                     $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1101                              $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1102                  if test "$ac_cv_header_GL_glu_h" = "yes"
1103                  then
1104                     WINE_CHECK_SONAME(GLU,gluLookAt,,,[$OPENGL_LIBS $X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1105                  fi
1106                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
1107                                  [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1108              else
1109                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
1110              fi
1111          else
1112              opengl_msg="OpenGL development headers not found."
1113          fi
1114          test -n "$opengl_msg" && enable_opengl32=${enable_opengl32:-no}
1115          test "x$ac_cv_lib_soname_GLU" = "x" && enable_glu32=${enable_glu32:-no}
1116     else
1117          enable_opengl32=${enable_opengl32:-no}
1118          enable_glu32=${enable_glu32:-no}
1119     fi
1120     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1121 OpenGL and Direct3D won't be supported.])
1122
1123     CPPFLAGS="$ac_save_CPPFLAGS"
1124 else
1125     XLIB=""
1126     X_CFLAGS=""
1127     X_LIBS=""
1128     enable_winex11_drv=${enable_winex11_drv:-no}
1129     enable_opengl32=${enable_opengl32:-no}
1130     enable_glu32=${enable_glu32:-no}
1131 fi
1132 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1133 without X support, which probably isn't what you want. You will need
1134 to install ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1135
1136 dnl **** Check for OpenCL ****
1137 if test "$ac_cv_header_CL_cl_h" = "yes"
1138 then
1139     AC_CHECK_LIB(OpenCL,clGetPlatformInfo,[AC_SUBST(LIBOPENCL,["-lOpenCL"])])
1140 fi
1141 WINE_NOTICE_WITH(opencl,[test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes],
1142                  [OpenCL ${notice_platform}development files not found, OpenCL won't be supported.])
1143 test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes && enable_opencl=${enable_opencl:-no}
1144
1145 dnl **** Check for libxml2 ****
1146
1147 AC_SUBST(XML2LIBS,"")
1148 AC_SUBST(XML2INCL,"")
1149 AC_SUBST(XSLTINCL,"")
1150 if test "x$with_xml" != "xno"
1151 then
1152     ac_save_CPPFLAGS="$CPPFLAGS"
1153     if test "$PKG_CONFIG" != "false"
1154     then
1155         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
1156         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
1157     else
1158         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
1159         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
1160     fi
1161     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
1162     AC_CHECK_HEADERS([libxml/parser.h libxml/xmlsave.h libxml/SAX2.h])
1163     if test "$ac_cv_header_libxml_parser_h" = "yes" -a "$ac_cv_header_libxml_xmlsave_h" = "yes" -a "$ac_cv_header_libxml_SAX2_h" = "yes"
1164     then
1165         AC_CHECK_LIB(xml2, xmlParseMemory,
1166             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
1167              XML2LIBS="$ac_xml_libs"
1168              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
1169         AC_CHECK_LIB(xml2, xmlReadMemory,
1170             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
1171         AC_CHECK_LIB(xml2, xmlNewDocPI,
1172             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
1173         AC_CHECK_LIB(xml2, xmlSchemaSetParserStructuredErrors,
1174             [AC_DEFINE(HAVE_XMLSCHEMASSETPARSERSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetParserStructuredErrors function])],,$ac_xml_libs)
1175         AC_CHECK_LIB(xml2, xmlSchemaSetValidStructuredErrors,
1176             [AC_DEFINE(HAVE_XMLSCHEMASSETVALIDSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetValidStructuredErrors function])],,$ac_xml_libs)
1177         AC_CHECK_LIB(xml2, xmlFirstElementChild,
1178             [AC_DEFINE(HAVE_XMLFIRSTELEMENTCHILD,1,[Define if libxml2 has the xmlFirstElementChild function])],,$ac_xml_libs)
1179         AC_CHECK_TYPE([xmlDocProperties],
1180             [AC_DEFINE(HAVE_XMLDOC_PROPERTIES,1,[Define if libxml2 has the xmlDocProperties enum])],,[[#include <libxml/tree.h>]])
1181     fi
1182     CPPFLAGS="$ac_save_CPPFLAGS"
1183 fi
1184 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1185                  [libxml2 ${notice_platform}development files not found (or too old), XML won't be supported.])
1186
1187 if test "x$with_xslt" != "xno"
1188 then
1189     if test "$PKG_CONFIG" != "false"
1190     then
1191         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
1192         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
1193     else
1194         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
1195         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
1196     fi
1197     ac_save_CPPFLAGS="$CPPFLAGS"
1198     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
1199     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1200     [#ifdef HAVE_LIBXSLT_PATTERN_H
1201 # include <libxslt/pattern.h>
1202 #endif])
1203     CPPFLAGS="$ac_save_CPPFLAGS"
1204     if test "$ac_cv_header_libxslt_transform_h" = "yes"
1205     then
1206         WINE_CHECK_SONAME(xslt,xsltCompilePattern,
1207                          [XSLTINCL="$ac_xslt_cflags"],,[$ac_xslt_libs])
1208     fi
1209 fi
1210 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1211                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1212
1213 dnl **** Check for libhal ****
1214 AC_SUBST(HALINCL,"")
1215 if test "x$with_hal" != "xno"
1216 then
1217     ac_save_CPPFLAGS="$CPPFLAGS"
1218     if test "$PKG_CONFIG" != "false"
1219     then
1220         ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
1221         ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
1222         CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
1223     fi
1224     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
1225     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
1226     then
1227         AC_CHECK_LIB(dbus-1, dbus_connection_close,
1228           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
1229             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
1230     fi
1231     CPPFLAGS="$ac_save_CPPFLAGS"
1232 fi
1233 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x" -a "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1234                  [libhal/libdbus ${notice_platform}development files not found, no dynamic device support.])
1235
1236 dnl **** Check for libgnutls ****
1237 if test "x$with_gnutls" != "xno"
1238 then
1239     ac_save_CPPFLAGS="$CPPFLAGS"
1240     if test "$PKG_CONFIG" != "false"
1241     then
1242         ac_gnutls_libs="`$PKG_CONFIG --libs gnutls 2>/dev/null`"
1243         ac_gnutls_cflags="`$PKG_CONFIG --cflags gnutls 2>/dev/null`"
1244         CPPFLAGS="$CPPFLAGS $ac_gnutls_cflags"
1245     fi
1246     AC_CHECK_HEADER(gnutls/gnutls.h,
1247         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[static typeof(gnutls_mac_get_key_size) *func; if (func) return 0;]])],
1248             [WINE_CHECK_SONAME(gnutls,gnutls_global_init,
1249                 [AC_SUBST(GNUTLSINCL,"$ac_gnutls_cflags")],,[$ac_gnutls_libs])])])
1250     CPPFLAGS="$ac_save_CPPFLAGS"
1251 fi
1252 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1253                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1254
1255 dnl **** Check which curses lib to use ***
1256 CURSESLIBS=""
1257 if test "$ac_cv_header_ncurses_h" = "yes"
1258 then
1259     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1260 elif test "$ac_cv_header_curses_h" = "yes"
1261 then
1262     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1263 fi
1264 ac_save_LIBS="$LIBS"
1265 LIBS="$LIBS $CURSESLIBS"
1266 AC_CHECK_FUNCS(mousemask)
1267 LIBS="$ac_save_LIBS"
1268 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1269                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1270
1271 dnl **** Check for SANE ****
1272 if test "x$with_sane" != "xno"
1273 then
1274     ac_save_CPPFLAGS="$CPPFLAGS"
1275     AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
1276     if test "$sane_devel" != "no"
1277     then
1278         ac_sane_incl="`$sane_devel --cflags`"
1279         ac_sane_libs="`$sane_devel --ldflags`"
1280         CPPFLAGS="$CPPFLAGS $ac_sane_incl"
1281     fi
1282     AC_CHECK_HEADER(sane/sane.h,
1283         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
1284     CPPFLAGS="$ac_save_CPPFLAGS"
1285 fi
1286 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1287                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1288
1289 dnl **** Check for libv4l1 ****
1290 if test "x$with_v4l" != "xno"
1291 then
1292     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1293 fi
1294 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1295                  [libv4l ${notice_platform}development files not found.])
1296
1297 dnl **** Check for libgphoto2 ****
1298 if test "x$with_gphoto" != "xno"
1299 then
1300     ac_save_CPPFLAGS="$CPPFLAGS"
1301     AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
1302     AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
1303     if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
1304     then
1305         ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
1306         ac_gphoto2_libs=""
1307         for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
1308         do
1309             case "$i" in
1310             -L/usr/lib|-L/usr/lib64) ;;
1311             -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
1312             esac
1313         done
1314         CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
1315     fi
1316     ac_gphoto2_libs=${ac_gphoto2_libs:-"-lgphoto2"}
1317     AC_CHECK_HEADER(gphoto2-camera.h,
1318                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
1319                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
1320                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
1321                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
1322                                   [$ac_gphoto2_libs])])
1323     CPPFLAGS="$ac_save_CPPFLAGS"
1324 fi
1325 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1326                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1327
1328
1329 dnl **** Check for resolver library ***
1330 if test "$ac_cv_header_resolv_h" = "yes"
1331 then
1332     ac_save_LIBS="$LIBS"
1333     for lib in '' -lresolv
1334     do
1335       LIBS="$lib $ac_save_LIBS"
1336       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1337 #include <netinet/in.h>
1338 #endif
1339 #include <resolv.h>]],[[res_query("foo",ns_c_in,0,0,0);]])],
1340         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1341          AC_SUBST(RESOLVLIBS,"$lib")])
1342       if test "${RESOLVLIBS+set}" = set; then
1343         break
1344       fi
1345     done
1346     LIBS="$ac_save_LIBS"
1347 fi
1348
1349 dnl **** Check for LittleCMS ***
1350 AC_SUBST(LCMSLIBS,"")
1351 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
1352 then
1353     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
1354         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
1355          LCMSLIBS="-llcms"])
1356 fi
1357 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
1358                  [liblcms ${notice_platform}development files not found, Color Management won't be supported.])
1359
1360 dnl **** Check for FreeType 2 ****
1361 if test "x$with_freetype" != "xno"
1362 then
1363     AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],no)
1364     if test "$ft_devel" != "no"
1365     then
1366         ac_freetype_incl=`$ft_devel --cflags`
1367         ac_freetype_libs=`$ft_devel --libs`
1368     fi
1369     ac_freetype_libs=${ac_freetype_libs:-"-lfreetype"}
1370     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
1371     if test "$ft_lib" = "yes"
1372     then
1373         ac_save_CPPFLAGS="$CPPFLAGS"
1374         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1375         AC_CHECK_HEADERS(ft2build.h \
1376                          freetype/freetype.h \
1377                          freetype/ftglyph.h \
1378                          freetype/fttypes.h \
1379                          freetype/tttables.h \
1380                          freetype/ftsnames.h \
1381                          freetype/ttnameid.h \
1382                          freetype/ftoutln.h \
1383                          freetype/ftwinfnt.h \
1384                          freetype/ftmodapi.h \
1385                          freetype/ftlcdfil.h,,,
1386                          [#ifdef HAVE_FT2BUILD_H
1387                           # include <ft2build.h>
1388                           #endif])
1389         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1390                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1391           [Define if you have the <freetype/fttrigon.h> header file.])
1392                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1393         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1394         dnl Check that we have at least freetype/freetype.h
1395         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1396         then
1397             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1398             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1399             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1400         fi
1401     fi
1402 fi
1403 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType ${notice_platform}development files not found. Fonts will not be built.])
1404 test "x$FREETYPELIBS" = "x" && enable_fonts=${enable_fonts:-no}
1405
1406 dnl **** Check for parport (currently Linux only) ****
1407 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1408  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1409 # include <sys/ioctl.h>
1410 #endif
1411 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1412     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1413 if test "$ac_cv_c_ppdev" = "yes"
1414 then
1415     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1416 fi
1417
1418 dnl **** Check for pthread functions ****
1419 WINE_CHECK_LIB_FUNCS(\
1420         pthread_attr_get_np \
1421         pthread_getattr_np \
1422         pthread_get_stackaddr_np \
1423         pthread_get_stacksize_np,
1424         [$LIBPTHREAD])
1425
1426 dnl **** Check for zlib ****
1427 if test "$ac_cv_header_zlib_h" = "yes"
1428 then
1429     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1430                             AC_SUBST(ZLIB,"-lz")])
1431 fi
1432 WINE_NOTICE_WITH(zlib,[test "x$ZLIB" = "x"],[libz ${notice_platform}development files not found, data compression won't be supported.])
1433
1434 dnl **** Check for gettextpo ****
1435 if test "x$enable_tools" != xno
1436 then
1437     if test "$ac_cv_header_gettext_po_h" = "yes"
1438     then
1439         AC_CHECK_LIB(gettextpo,po_message_msgctxt,
1440                      [AC_DEFINE(HAVE_LIBGETTEXTPO,1,[Define to 1 if you have the `gettextpo' library (-lgettextpo).])
1441                       AC_SUBST(LIBGETTEXTPO,"-lgettextpo")])
1442     fi
1443     test "x$with_gettextpo" != xyes || WINE_NOTICE_WITH(gettextpo,[test "x$LIBGETTEXTPO" = "x"],
1444           [GetText ${notice_platform}development files not found (or too old), po files can't be rebuilt.])
1445 fi
1446
1447 dnl **** Check for gstreamer ****
1448 if test "x$with_gstreamer" != "xno"
1449 then
1450     ac_save_CPPFLAGS="$CPPFLAGS"
1451     if test "$PKG_CONFIG" != "false"; then
1452         ac_gst_incl=""
1453         for i in `$PKG_CONFIG --cflags gstreamer-app-0.10 2>/dev/null`
1454         do
1455             case "$i" in
1456                 -I*) ac_gst_incl="$ac_gst_incl $i";;
1457             esac
1458         done
1459         ac_gst_libs="`$PKG_CONFIG --libs gstreamer-app-0.10 2>/dev/null`"
1460         CPPFLAGS="$CPPFLAGS $ac_gst_incl"
1461         AC_CHECK_HEADER([gst/gstpad.h],
1462           [AC_CHECK_HEADER([gst/app/gstappsink.h],
1463              [AC_MSG_CHECKING([whether gint64 defined by gst/app/gstappsink.h is indeed 64-bit])
1464               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gst/app/gstappsink.h>]],
1465                                                  [[static int a[sizeof(gint64) > 4 ? 1 : -1]; if (a[0]) return 0;]])],
1466                 [AC_MSG_RESULT([yes])
1467                  AC_CHECK_LIB(gstreamer-0.10,gst_pad_get_caps_reffed,
1468                    [AC_CHECK_LIB(gstapp-0.10,gst_app_buffer_new,
1469                       [AC_SUBST(GSTREAMER_LIBS,"$ac_gst_libs")
1470                        AC_SUBST(GSTREAMER_INCL,"$ac_gst_incl")],,[$ac_gst_libs])])],
1471                 [AC_MSG_RESULT([no])])])])
1472     fi
1473     CPPFLAGS="$ac_save_CPPFLAGS"
1474 fi
1475 WINE_NOTICE_WITH(gstreamer,[test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" != xyes -a "x$ac_cv_header_QuickTime_ImageCompression_h" != xyes],
1476                  [gstreamer-0.10 base plugins ${notice_platform}development files not found, gstreamer support disabled])
1477 test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" = xyes || enable_winegstreamer=${enable_winegstreamer:-no}
1478
1479 dnl **** Check for ALSA 1.x ****
1480 AC_SUBST(ALSALIBS,"")
1481 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1482 then
1483     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access_mask,
1484         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1485 #include <alsa/asoundlib.h>
1486 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1487 #include <sys/asoundlib.h>
1488 #endif]], [[snd_pcm_hw_params_get_access_mask(NULL, NULL)]])],
1489                         [ALSALIBS="-lasound"])])
1490 fi
1491
1492 dnl **** Check for OSSv4 ****
1493 if test "x$with_oss" != xno
1494 then
1495     ac_save_CPPFLAGS="$CPPFLAGS"
1496     if test -f /etc/oss.conf
1497     then
1498         . /etc/oss.conf
1499     fi
1500     ac_oss_incl="-I${OSSLIBDIR:-/usr/lib/oss}/include"
1501     CPPFLAGS="$CPPFLAGS $ac_oss_incl"
1502     AC_CHECK_HEADER([sys/soundcard.h],
1503         [AC_CHECK_MEMBERS([oss_sysinfo.numaudioengines],
1504                           [AC_SUBST(OSS4INCL,"$ac_oss_incl")],,
1505                           [#include <sys/soundcard.h>])])
1506     CPPFLAGS="$ac_save_CPPFLAGS"
1507     if test "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes
1508     then
1509         WINE_NOTICE([OSS sound system found but too old (OSSv4 needed), OSS won't be supported.])
1510     fi
1511 fi
1512
1513 dnl **** Check for capi4linux ****
1514
1515 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1516 then
1517     WINE_CHECK_SONAME(capi20,capi20_register)
1518 fi
1519 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1520                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1521
1522 dnl **** Check for cups ****
1523 AC_SUBST(CUPSINCL,"")
1524 if test "x$with_cups" != "xno"
1525 then
1526     ac_save_CPPFLAGS="$CPPFLAGS"
1527     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1528     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1529     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1530     AC_CHECK_HEADERS(cups/cups.h,
1531             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1532                        [CUPSINCL="$ac_cups_cflags"],,
1533                        [$ac_cups_libs])])
1534     CPPFLAGS="$ac_save_CPPFLAGS"
1535 fi
1536 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1537                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1538
1539 dnl **** Check for fontconfig ****
1540 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1541 then
1542     WINE_CHECK_SONAME(fontconfig,FcInit)
1543 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1544 then
1545     dnl fontconfig is in the X directory on Mac OS X
1546     ac_save_CPPFLAGS="$CPPFLAGS"
1547     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1548     $as_unset ac_cv_header_fontconfig_fontconfig_h
1549     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1550     CPPFLAGS="$ac_save_CPPFLAGS"
1551     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1552     then
1553         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1554         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1555     fi
1556 fi
1557 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1558                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1559
1560 dnl **** Check for SSL ****
1561 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1562 then
1563     WINE_CHECK_SONAME(ssl,SSL_library_init)
1564     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1565 fi
1566 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1567                  [OpenSSL ${notice_platform}development files not found, SSL won't be supported.])
1568
1569 dnl **** Check for gsm codec ****
1570 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1571 then
1572     WINE_CHECK_SONAME(gsm,gsm_create)
1573 fi
1574 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1575                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1576
1577 dnl **** Check for libjpeg ****
1578 if test "$ac_cv_header_jpeglib_h" = "yes"
1579 then
1580     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1581 fi
1582 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1583                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1584
1585 dnl **** Check for libpng ****
1586 if test "$ac_cv_header_png_h" = "yes"
1587 then
1588     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm -lz,[[libpng[[0-9]]*]])
1589     AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1590         [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])]
1591         ,,-lm -lz)
1592 elif test -n "$X_CFLAGS" -a "x$with_png" != "xno"
1593 then
1594     dnl libpng is in the X directory on Mac OS X
1595     ac_save_CPPFLAGS="$CPPFLAGS"
1596     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1597     $as_unset ac_cv_header_png_h
1598     AC_CHECK_HEADERS([png.h])
1599     CPPFLAGS="$ac_save_CPPFLAGS"
1600     if test "$ac_cv_header_png_h" = "yes"
1601     then
1602         AC_SUBST(PNGINCL,"$X_CFLAGS")
1603         WINE_CHECK_SONAME(png,png_create_read_struct,,,[$X_LIBS -lm -lz],[[libpng[[0-9]]*]])
1604         AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1605                 [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1)],,[$X_LIBS -lm -lz])
1606     fi
1607 fi
1608 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1609                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1610
1611 dnl **** Check for libtiff ****
1612 if test "$ac_cv_header_tiffio_h" = "yes"
1613 then
1614     WINE_CHECK_SONAME(tiff,TIFFClientOpen)
1615 fi
1616 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1617                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1618
1619 dnl **** Check for mpg123 ****
1620 if test "$ac_cv_header_mpg123_h" = "yes"
1621 then
1622     AC_CHECK_LIB(mpg123,mpg123_feed,[AC_SUBST(LIBMPG123,"-lmpg123")])
1623 fi
1624 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1625                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1626 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_header_AudioToolbox_AudioConverter_h" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1627
1628 dnl **** Check for OpenAL 1.1 ****
1629 if test "$ac_cv_header_AL_al_h" = "yes"
1630 then
1631     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1632                       ac_cv_lib_openal=yes
1633                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1634 fi
1635 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1636                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1637 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1638
1639 dnl **** Check for libkstat ****
1640 if test "$ac_cv_header_kstat_h" = "yes"
1641 then
1642     AC_CHECK_LIB(kstat,kstat_open,
1643                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1644                   AC_SUBST(LIBKSTAT,"-lkstat")])
1645 fi
1646
1647 dnl **** Check for libodbc ****
1648 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1649
1650 dnl **** Disable unsupported winmm drivers ****
1651 test -n "$ALSALIBS" || enable_winealsa_drv=${enable_winealsa_drv:-no}
1652 test -n "$COREAUDIO" || enable_winecoreaudio_drv=${enable_winecoreaudio_drv:-no}
1653 test "x$ac_cv_member_oss_sysinfo_numaudioengines" = xyes || enable_wineoss_drv=${enable_wineoss_drv:-no}
1654 test "$ac_cv_header_linux_joystick_h" = "yes" || enable_winejoystick_drv=${enable_winejoystick_drv:-no}
1655
1656 dnl **** Check for any sound system ****
1657 if test "x$ALSALIBS$COREAUDIO" = "x" -a \
1658         "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes -a \
1659         "x$with_alsa$with_coreaudio$with_oss" != xnonono
1660 then
1661     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1662 fi
1663
1664 dnl **** Check for gcc specific options ****
1665
1666 AC_SUBST(EXTRACFLAGS,"")
1667 if test "x${GCC}" = "xyes"
1668 then
1669   EXTRACFLAGS="-Wall -pipe"
1670
1671   dnl Check for strength-reduce bug
1672   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1673                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1674 [[static int Array[[3]];
1675   unsigned int B = 3;
1676   int i;
1677   for(i=0; i<B; i++) Array[[i]] = i - 3;
1678   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1679   L[[i]] = 4;
1680   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1681     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1682   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1683   then
1684     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1685   fi
1686
1687   dnl Check for some compiler flags
1688   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1689   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1690   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1691   WINE_TRY_CFLAGS([-Wempty-body])
1692   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1693   WINE_TRY_CFLAGS([-Wtype-limits])
1694   WINE_TRY_CFLAGS([-Wunused-but-set-parameter])
1695   WINE_TRY_CFLAGS([-Wwrite-strings])
1696
1697   dnl gcc-4.6+ omits frame pointers by default, breaking some copy protections
1698   case $host_cpu in
1699     *i[[3456789]]86*) WINE_TRY_CFLAGS([-fno-omit-frame-pointer]) ;;
1700   esac
1701
1702   dnl Check for noisy string.h
1703   saved_CFLAGS="$CFLAGS"
1704   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1705   AC_CACHE_CHECK([for broken string.h that generates warnings with -Wpointer-arith], ac_cv_c_string_h_warnings,
1706       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1707   CFLAGS="$saved_CFLAGS"
1708   if test "$ac_cv_c_string_h_warnings" = "no"
1709   then
1710     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1711   fi
1712
1713   dnl Check for noisy string.h on logical ops
1714   saved_CFLAGS="$CFLAGS"
1715   CFLAGS="$CFLAGS -Wlogical-op -Werror"
1716   AC_CACHE_CHECK([for broken string.h that generates warnings with -Wlogical-op], ac_cv_c_logicalop_noisy,
1717       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[char*f(const char *h,char n) {return strchr(h,n);}]])],[ac_cv_c_logicalop_noisy=no],[ac_cv_c_logicalop_noisy=yes]))
1718   CFLAGS="$saved_CFLAGS"
1719   if test "$ac_cv_c_logicalop_noisy" = "no"
1720   then
1721     EXTRACFLAGS="$EXTRACFLAGS -Wlogical-op"
1722   fi
1723
1724   dnl Enable -Werror for maintainer mode
1725   if test "x$enable_maintainer_mode" = "xyes"
1726   then
1727       WINE_TRY_CFLAGS([-Werror])
1728   fi
1729
1730   dnl Check for ms_hook_prologue support
1731   saved_CFLAGS="$CFLAGS"
1732   CFLAGS="$CFLAGS -Werror"
1733   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1734                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1735                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1736   CFLAGS="$saved_CFLAGS"
1737   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1738   then
1739       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1740                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1741   else
1742       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1743   fi
1744 fi
1745
1746 dnl **** Disable Fortify, it has too many false positives
1747
1748 AC_CACHE_CHECK([for the need to disable Fortify], ac_cv_c_fortify_enabled,
1749     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]],
1750 [[#if defined(__USE_FORTIFY_LEVEL) && __USE_FORTIFY_LEVEL > 0
1751 #error Fortify enabled
1752 #endif]])],
1753         [ac_cv_c_fortify_enabled=no],[ac_cv_c_fortify_enabled=yes]))
1754 if test "$ac_cv_c_fortify_enabled" = yes
1755 then
1756     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=0"
1757 fi
1758
1759 dnl **** Check for underscore on external symbols ****
1760
1761 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1762     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1763                       [extern int ac_test;],
1764                       [if (ac_test) return 1],
1765                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1766
1767 case $host_cpu in
1768   *i[[3456789]]86*)
1769     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1770         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1771 [#ifndef _MSC_VER
1772 #define __stdcall __attribute__((__stdcall__))
1773 #endif
1774 int __stdcall ac_test(int i) { return i; }],
1775                           [if (ac_test(1)) return 1],
1776                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1777   *) ac_cv_c_stdcall_suffix="no" ;;
1778 esac
1779
1780 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1781 if test "$ac_cv_c_extern_prefix" = "yes"
1782 then
1783     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1784     asm_name_prefix="_"
1785 else
1786     AC_DEFINE([__ASM_NAME(name)], [name])
1787     asm_name_prefix=""
1788 fi
1789
1790 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1791 if test "$ac_cv_c_stdcall_suffix" = "yes"
1792 then
1793     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1794 else
1795     AC_DEFINE([__ASM_STDCALL(args)],[""])
1796 fi
1797
1798 dnl **** Check how to define a function in assembly code ****
1799
1800 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1801   WINE_TRY_ASM_LINK(
1802       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1803       ac_cv_asm_func_def=".def",
1804     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1805       ac_cv_asm_func_def=".type @function",
1806     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1807       ac_cv_asm_func_def=".type 2",
1808       ac_cv_asm_func_def="unknown")])]))
1809
1810 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1811 case "$ac_cv_asm_func_def" in
1812   ".def")
1813      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1814      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1815   ".type @function")
1816      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1817      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1818   ".type 2")
1819      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1820      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1821   *)
1822      AC_DEFINE([__ASM_FUNC(name)], [""])
1823      asm_func_header="" ;;
1824 esac
1825
1826 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1827     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1828                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1829
1830 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1831     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1832                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1833
1834 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1835     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1836                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1837
1838 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1839 asm_func_trailer=""
1840 if test "$ac_cv_c_dot_previous" = "yes"
1841 then
1842    asm_func_trailer="\\n\\t.previous"
1843 fi
1844 if test "$ac_cv_c_cfi_support" = "yes"
1845 then
1846    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1847    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1848    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1849    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1850 else
1851    AC_DEFINE([__ASM_CFI(str)],[""])
1852 fi
1853
1854 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1855
1856 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1857 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1858 then
1859     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1860 else
1861     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1862 fi
1863 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1864           [Define to a macro to generate an assembly function with C calling convention])
1865 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1866           [Define to a macro to generate an assembly function with stdcall calling convention])
1867
1868 dnl **** Platform-specific checks ****
1869
1870 AC_SUBST(LDPATH,"")
1871 case $build_os in
1872   cygwin*|mingw32*)
1873     AC_SUBST(TOOLSEXT,".exe")
1874     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1875     ;;
1876   darwin*|macosx*)
1877     ;;
1878   *)
1879     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1880     ;;
1881 esac
1882
1883 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1884 case $host_os in
1885   mingw32*)
1886     AC_SUBST(CRTLIBS,"-lmsvcrt")
1887     AC_SUBST(SOCKETLIBS,"-L\$(top_builddir)/dlls/ws2_32 -lws2_32")
1888     ;;
1889 esac
1890
1891 AC_SUBST(MAIN_BINARY,"wine")
1892 test "x$enable_win64" != "xyes" || MAIN_BINARY="wine64"
1893
1894 case $host_os in
1895   linux*)
1896     case $host_cpu in
1897       *i[[3456789]]86*) AC_SUBST(EXTRA_BINARIES,"wine-preloader") ;;
1898       x86_64*) AC_SUBST(EXTRA_BINARIES,"wine64-preloader") ;;
1899     esac
1900     ;;
1901 esac
1902
1903 dnl **** Check for functions ****
1904
1905 ac_save_CFLAGS="$CFLAGS"
1906 CFLAGS="$CFLAGS $BUILTINFLAG"
1907 AC_CHECK_FUNCS(\
1908         _finite \
1909         _isnan \
1910         _pclose \
1911         _popen \
1912         _snprintf \
1913         _spawnvp \
1914         _strdup \
1915         _stricmp \
1916         _strnicmp \
1917         _strtoi64 \
1918         _strtoui64 \
1919         _vsnprintf \
1920         asctime_r \
1921         chsize \
1922         dlopen \
1923         epoll_create \
1924         ffs \
1925         finite \
1926         fnmatch \
1927         fork \
1928         fpclass \
1929         fstatfs \
1930         fstatvfs \
1931         ftruncate \
1932         futimes \
1933         futimesat \
1934         getattrlist \
1935         getdirentries \
1936         getopt_long \
1937         getpagesize \
1938         getpwuid \
1939         gettimeofday \
1940         getuid \
1941         kqueue \
1942         lstat \
1943         memmove \
1944         mmap \
1945         pclose \
1946         pipe2 \
1947         poll \
1948         popen \
1949         port_create \
1950         prctl \
1951         pread \
1952         pwrite \
1953         readdir \
1954         readlink \
1955         sched_yield \
1956         select \
1957         setproctitle \
1958         setrlimit \
1959         settimeofday \
1960         sigaltstack \
1961         sigprocmask \
1962         snprintf \
1963         spawnvp \
1964         statfs \
1965         statvfs \
1966         strcasecmp \
1967         strdup \
1968         strerror \
1969         strncasecmp \
1970         strtold \
1971         strtoll \
1972         strtoull \
1973         symlink \
1974         tcgetattr \
1975         thr_kill2 \
1976         timegm \
1977         usleep \
1978         vsnprintf \
1979         wait4 \
1980         waitpid \
1981 )
1982 CFLAGS="$ac_save_CFLAGS"
1983
1984 dnl Check for -ldl
1985 if test "$ac_cv_func_dlopen" = no
1986 then
1987     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1988 fi
1989 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1990
1991 dnl Check for -lpoll for Mac OS X/Darwin
1992 if test "$ac_cv_func_poll" = no
1993 then
1994     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1995 fi
1996
1997 dnl Check for -lnsl for Solaris
1998 AC_SEARCH_LIBS(gethostbyname, nsl)
1999
2000 dnl Check for -lsocket for Solaris
2001 AC_SEARCH_LIBS(connect, socket)
2002
2003 dnl Check for -lresolv for Solaris
2004 AC_SEARCH_LIBS(inet_aton, resolv)
2005
2006 dnl **** Check for functions which may rely on -lsocket on Solaris.
2007 AC_CHECK_FUNCS(\
2008         getaddrinfo \
2009         getnameinfo \
2010         getnetbyname \
2011         getprotobyname \
2012         getprotobynumber \
2013         getservbyport \
2014         inet_network \
2015         inet_ntop \
2016         inet_pton \
2017         sendmsg \
2018         socketpair \
2019 )
2020
2021 dnl **** Check for OpenLDAP ***
2022 AC_SUBST(LDAPLIBS,"")
2023 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
2024 then
2025     AC_CHECK_TYPE(LDAPSortKey,
2026         [AC_CHECK_LIB(ldap_r, ldap_initialize,
2027             [AC_CHECK_LIB(lber, ber_init,
2028                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
2029                  LDAPLIBS="-lldap_r -llber"],,
2030                  [$LIBPTHREAD])],,
2031                  [$LIBPTHREAD])],,
2032         [#include <ldap.h>])
2033     WINE_CHECK_LIB_FUNCS(\
2034         ldap_count_references \
2035         ldap_first_reference \
2036         ldap_next_reference \
2037         ldap_parse_reference \
2038         ldap_parse_sort_control \
2039         ldap_parse_sortresponse_control \
2040         ldap_parse_vlv_control \
2041         ldap_parse_vlvresponse_control,
2042         [$LDAPLIBS $LIBPTHREAD])
2043 fi
2044 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
2045                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
2046
2047 AC_CACHE_CHECK([whether mkdir takes only one argument],
2048         wine_cv_one_arg_mkdir,
2049         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
2050                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
2051 if test "$wine_cv_one_arg_mkdir" = "yes"
2052 then
2053   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
2054 fi
2055
2056 AC_CACHE_CHECK([for sched_setaffinity],wine_cv_have_sched_setaffinity,
2057                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2058 [[#define _GNU_SOURCE
2059 #include <sched.h>]], [[sched_setaffinity(0, 0, 0);]])],[wine_cv_have_sched_setaffinity=yes],[wine_cv_have_sched_setaffinity=no]))
2060 if test "$wine_cv_have_sched_setaffinity" = "yes"
2061 then
2062   AC_DEFINE(HAVE_SCHED_SETAFFINITY, 1, [Define to 1 if you have the `sched_setaffinity' function.])
2063 fi
2064
2065 dnl **** Check for types ****
2066
2067 AC_C_INLINE
2068 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
2069 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
2070 #include <signal.h>])
2071 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
2072
2073 AC_CHECK_TYPES([struct xinpgen],,,
2074 [#include <sys/types.h>
2075 #ifdef HAVE_SYS_SOCKET_H
2076 #include <sys/socket.h>
2077 #endif
2078 #ifdef HAVE_SYS_SOCKETVAR_H
2079 #include <sys/socketvar.h>
2080 #endif
2081 #ifdef HAVE_NET_ROUTE_H
2082 #include <net/route.h>
2083 #endif
2084 #ifdef HAVE_NETINET_IN_H
2085 #include <netinet/in.h>
2086 #endif
2087 #ifdef HAVE_NETINET_IN_SYSTM_H
2088 #include <netinet/in_systm.h>
2089 #endif
2090 #ifdef HAVE_NETINET_IP_H
2091 #include <netinet/ip.h>
2092 #endif
2093 #ifdef HAVE_NETINET_IN_PCB_H
2094 #include <netinet/in_pcb.h>
2095 #endif])
2096
2097 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
2098 [#ifdef HAVE_LINUX_INPUT_H
2099 #include <linux/input.h>
2100 #endif])
2101
2102 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
2103                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
2104 if test "$wine_cv_have_sigaddset" = "yes"
2105 then
2106   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
2107 fi
2108
2109
2110 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
2111         wine_cv_linux_gethostbyname_r_6,
2112         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
2113     char *name=0;
2114     struct hostent he;
2115     struct hostent *result;
2116     char *buf=0;
2117     int bufsize=0;
2118     int errnr;
2119     char *addr=0;
2120     int addrlen=0;
2121     int addrtype=0;
2122     gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
2123     gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
2124     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
2125         ])
2126    )
2127    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
2128    then
2129       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
2130                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
2131    fi
2132
2133 if test "$ac_cv_header_linux_joystick_h" = "yes"
2134 then
2135    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
2136         wine_cv_linux_joystick_22_api,
2137         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2138         #include <sys/ioctl.h>
2139         #include <sys/types.h>
2140         #include <linux/joystick.h>
2141
2142         struct js_event blub;
2143         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
2144         #error "no 2.2 header"
2145         #endif
2146         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
2147    )
2148    if test "$wine_cv_linux_joystick_22_api" = "yes"
2149    then
2150       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
2151                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
2152    fi
2153 fi
2154
2155 dnl **** FIXME: what about mixed cases, where we need two of them? ***
2156
2157 dnl Check for statfs members
2158 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
2159 [#include <sys/types.h>
2160 #ifdef HAVE_SYS_PARAM_H
2161 # include <sys/param.h>
2162 #endif
2163 #ifdef HAVE_SYS_MOUNT_H
2164 # include <sys/mount.h>
2165 #endif
2166 #ifdef HAVE_SYS_VFS_H
2167 # include <sys/vfs.h>
2168 #endif
2169 #ifdef HAVE_SYS_STATFS_H
2170 # include <sys/statfs.h>
2171 #endif])
2172
2173 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2174 [#ifdef HAVE_SYS_STATVFS_H
2175 #include <sys/statvfs.h>
2176 #endif])
2177
2178 dnl Check for socket structure members
2179 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2180 [#include <sys/types.h>
2181 #ifdef HAVE_SYS_SOCKET_H
2182 # include <sys/socket.h>
2183 #endif
2184 #ifdef HAVE_SYS_UN_H
2185 # include <sys/un.h>
2186 #endif])
2187
2188 dnl Check for scsireq_t and sg_io_hdr_t members
2189 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2190 [#include <sys/types.h>
2191 #ifdef HAVE_SCSI_SG_H
2192 #include <scsi/sg.h>
2193 #endif])
2194
2195 dnl Check for siginfo_t members
2196 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2197
2198 dnl Check for struct mtget members
2199 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2200 [#include <sys/types.h>
2201 #ifdef HAVE_SYS_MTIO_H
2202 #include <sys/mtio.h>
2203 #endif])
2204
2205 dnl Check for struct option
2206 AC_CHECK_MEMBERS([struct option.name],,,
2207 [#ifdef HAVE_GETOPT_H
2208 #include <getopt.h>
2209 #endif])
2210
2211 dnl Check for stat.st_blocks and ns-resolved times
2212 AC_CHECK_MEMBERS([struct stat.st_blocks,struct stat.st_mtim,struct stat.st_ctim,struct stat.st_atim])
2213
2214 dnl Check for sin6_scope_id
2215 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2216 [#ifdef HAVE_SYS_TYPES_H
2217 #include <sys/types.h>
2218 #endif
2219 #ifdef HAVE_NETINET_IN_H
2220 #include <netinet/in.h>
2221 #endif])
2222
2223 dnl Check for ns_msg ptr member
2224 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2225 [#ifdef HAVE_SYS_TYPES_H
2226 #include <sys/types.h>
2227 #endif
2228 #ifdef HAVE_NETINET_IN_H
2229 # include <netinet/in.h>
2230 #endif
2231 #ifdef HAVE_ARPA_NAMESER_H
2232 # include <arpa/nameser.h>
2233 #endif])
2234
2235 dnl Check for struct icmpstat.icps_outhist
2236 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2237 [#ifdef HAVE_SYS_TYPES_H
2238 #include <sys/types.h>
2239 #endif
2240 #ifdef HAVE_ALIAS_H
2241 #include <alias.h>
2242 #endif
2243 #ifdef HAVE_SYS_SOCKET_H
2244 #include <sys/socket.h>
2245 #endif
2246 #ifdef HAVE_SYS_SOCKETVAR_H
2247 #include <sys/socketvar.h>
2248 #endif
2249 #ifdef HAVE_SYS_TIMEOUT_H
2250 #include <sys/timeout.h>
2251 #endif
2252 #ifdef HAVE_NETINET_IN_H
2253 #include <netinet/in.h>
2254 #endif
2255 #ifdef HAVE_NETINET_IN_SYSTM_H
2256 #include <netinet/in_systm.h>
2257 #endif
2258 #ifdef HAVE_NETINET_IP_H
2259 #include <netinet/ip.h>
2260 #endif
2261 #ifdef HAVE_NETINET_IP_VAR_H
2262 #include <netinet/ip_var.h>
2263 #endif
2264 #ifdef HAVE_NETINET_IP_ICMP_H
2265 #include <netinet/ip_icmp.h>
2266 #endif
2267 #ifdef HAVE_NETINET_ICMP_VAR
2268 #include <netinet/icmp_var.h>
2269 #endif])
2270
2271 dnl Check for struct ifreq.ifr_hwaddr
2272 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2273 [#ifdef HAVE_SYS_TYPES_H
2274 #include <sys/types.h>
2275 #endif
2276 #ifdef HAVE_NET_IF_H
2277 # include <net/if.h>
2278 #endif])
2279
2280 dnl Check for the external timezone variables timezone and daylight
2281 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2282                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2283 if test "$ac_cv_have_timezone" = "yes"
2284 then
2285     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2286 fi
2287 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2288                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2289 if test "$ac_cv_have_daylight" = "yes"
2290 then
2291     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2292 fi
2293
2294 dnl Check for isinf
2295 ac_save_LIBS="$LIBS"
2296 LIBS="$LIBS -lm"
2297 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2298                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2299 if test "$ac_cv_have_isinf" = "yes"
2300 then
2301     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2302 fi
2303
2304 dnl Check for isnan
2305 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2306                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2307 if test "$ac_cv_have_isnan" = "yes"
2308 then
2309     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2310 fi
2311 LIBS="$ac_save_LIBS"
2312
2313 dnl *** check for the need to define platform-specific symbols
2314
2315 case $host_cpu in
2316   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2317   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2318   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2319   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2320   *arm*)            WINE_CHECK_DEFINE([__arm__]) ;;
2321 esac
2322
2323 case $host_vendor in
2324   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2325 esac
2326
2327 dnl **** Generate output files ****
2328
2329 AH_TOP([#ifndef WINE_CROSSTEST
2330 #define __WINE_CONFIG_H])
2331 AH_BOTTOM([#endif /* WINE_CROSSTEST */])
2332
2333 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2334
2335 WINE_CONFIG_SYMLINK(dlls/shell32/AUTHORS,AUTHORS)
2336 WINE_CONFIG_SYMLINK(dlls/wineps.drv/generic.ppd)
2337 WINE_CONFIG_SYMLINK(fonts/marlett.ttf,,enable_fonts)
2338 WINE_CONFIG_SYMLINK(fonts/symbol.ttf,,enable_fonts)
2339 WINE_CONFIG_SYMLINK(fonts/tahoma.ttf,,enable_fonts)
2340 WINE_CONFIG_SYMLINK(fonts/tahomabd.ttf,,enable_fonts)
2341 WINE_CONFIG_SYMLINK(po/LINGUAS)
2342 WINE_CONFIG_SYMLINK(tools/l_intl.nls,,enable_tools)
2343 WINE_CONFIG_SYMLINK(wine,tools/winewrapper)
2344 WINE_CONFIG_SYMLINK(wine64,tools/winewrapper,enable_win64)
2345
2346 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/dibdrv)
2347 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2348 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2349 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2350 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2351 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2352 WINE_CONFIG_EXTRA_DIR(include/wine)
2353
2354 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2355 WINE_CONFIG_MAKERULES([Maketest.rules],[MAKE_TEST_RULES],[Make.rules])
2356 WINE_CONFIG_MAKERULES([dlls/Makedll.rules],[MAKE_DLL_RULES],[Make.rules])
2357 WINE_CONFIG_MAKERULES([dlls/Makeimplib.rules],[MAKE_IMPLIB_RULES],[Make.rules])
2358 WINE_CONFIG_MAKERULES([programs/Makeprog.rules],[MAKE_PROG_RULES],[Make.rules])
2359
2360 WINE_CONFIG_DLL(acledit)
2361 WINE_CONFIG_DLL(aclui,,[implib])
2362 WINE_CONFIG_DLL(activeds,,[implib])
2363 WINE_CONFIG_DLL(actxprxy)
2364 WINE_CONFIG_LIB(adsiid)
2365 WINE_CONFIG_DLL(advapi32,,[implib])
2366 WINE_CONFIG_TEST(dlls/advapi32/tests)
2367 WINE_CONFIG_DLL(advpack,,[implib])
2368 WINE_CONFIG_TEST(dlls/advpack/tests)
2369 WINE_CONFIG_DLL(amstream)
2370 WINE_CONFIG_TEST(dlls/amstream/tests)
2371 WINE_CONFIG_DLL(appwiz.cpl,,[po])
2372 WINE_CONFIG_DLL(atl,,[implib])
2373 WINE_CONFIG_TEST(dlls/atl/tests)
2374 WINE_CONFIG_DLL(authz)
2375 WINE_CONFIG_DLL(avicap32,,[implib])
2376 WINE_CONFIG_DLL(avifil32,,[implib,po])
2377 WINE_CONFIG_TEST(dlls/avifil32/tests)
2378 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2379 WINE_CONFIG_DLL(avrt,,[implib])
2380 WINE_CONFIG_DLL(bcrypt)
2381 WINE_CONFIG_DLL(browseui,,[po])
2382 WINE_CONFIG_TEST(dlls/browseui/tests)
2383 WINE_CONFIG_DLL(cabinet,,[implib])
2384 WINE_CONFIG_TEST(dlls/cabinet/tests)
2385 WINE_CONFIG_DLL(capi2032,,[implib])
2386 WINE_CONFIG_DLL(cards,,[implib])
2387 WINE_CONFIG_DLL(cfgmgr32,,[implib])
2388 WINE_CONFIG_DLL(clusapi,,[implib])
2389 WINE_CONFIG_DLL(comcat)
2390 WINE_CONFIG_TEST(dlls/comcat/tests)
2391 WINE_CONFIG_DLL(comctl32,,[implib,po])
2392 WINE_CONFIG_TEST(dlls/comctl32/tests)
2393 WINE_CONFIG_DLL(comdlg32,,[implib,po])
2394 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2395 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2396 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2397 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2398 WINE_CONFIG_DLL(compstui,,[implib])
2399 WINE_CONFIG_DLL(credui,,[implib,po])
2400 WINE_CONFIG_TEST(dlls/credui/tests)
2401 WINE_CONFIG_DLL(crtdll,,[implib])
2402 WINE_CONFIG_DLL(crypt32,,[implib,po])
2403 WINE_CONFIG_TEST(dlls/crypt32/tests)
2404 WINE_CONFIG_DLL(cryptdlg,,[po])
2405 WINE_CONFIG_DLL(cryptdll,,[implib])
2406 WINE_CONFIG_DLL(cryptnet,,[implib])
2407 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2408 WINE_CONFIG_DLL(cryptui,,[implib,po])
2409 WINE_CONFIG_TEST(dlls/cryptui/tests)
2410 WINE_CONFIG_DLL(ctapi32)
2411 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2412 WINE_CONFIG_DLL(ctl3d32,,[implib])
2413 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2414 WINE_CONFIG_DLL(d3d10,,[implib])
2415 WINE_CONFIG_TEST(dlls/d3d10/tests)
2416 WINE_CONFIG_DLL(d3d10core,,[implib])
2417 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2418 WINE_CONFIG_DLL(d3d8,,[implib])
2419 WINE_CONFIG_TEST(dlls/d3d8/tests)
2420 WINE_CONFIG_DLL(d3d9,,[implib])
2421 WINE_CONFIG_TEST(dlls/d3d9/tests)
2422 WINE_CONFIG_DLL(d3dcompiler_33)
2423 WINE_CONFIG_DLL(d3dcompiler_34)
2424 WINE_CONFIG_DLL(d3dcompiler_35)
2425 WINE_CONFIG_DLL(d3dcompiler_36)
2426 WINE_CONFIG_DLL(d3dcompiler_37)
2427 WINE_CONFIG_DLL(d3dcompiler_38)
2428 WINE_CONFIG_DLL(d3dcompiler_39)
2429 WINE_CONFIG_DLL(d3dcompiler_40)
2430 WINE_CONFIG_DLL(d3dcompiler_41)
2431 WINE_CONFIG_DLL(d3dcompiler_42)
2432 WINE_CONFIG_DLL(d3dcompiler_43,,[implib],[d3dcompiler])
2433 WINE_CONFIG_TEST(dlls/d3dcompiler_43/tests)
2434 WINE_CONFIG_DLL(d3dim,,[implib])
2435 WINE_CONFIG_DLL(d3drm,,[implib])
2436 WINE_CONFIG_TEST(dlls/d3drm/tests)
2437 WINE_CONFIG_DLL(d3dx10_33)
2438 WINE_CONFIG_DLL(d3dx10_34)
2439 WINE_CONFIG_DLL(d3dx10_35)
2440 WINE_CONFIG_DLL(d3dx10_36)
2441 WINE_CONFIG_DLL(d3dx10_37)
2442 WINE_CONFIG_DLL(d3dx10_38)
2443 WINE_CONFIG_DLL(d3dx10_39)
2444 WINE_CONFIG_DLL(d3dx10_40)
2445 WINE_CONFIG_DLL(d3dx10_41)
2446 WINE_CONFIG_DLL(d3dx10_42)
2447 WINE_CONFIG_DLL(d3dx10_43)
2448 WINE_CONFIG_DLL(d3dx9_24)
2449 WINE_CONFIG_DLL(d3dx9_25)
2450 WINE_CONFIG_DLL(d3dx9_26)
2451 WINE_CONFIG_DLL(d3dx9_27)
2452 WINE_CONFIG_DLL(d3dx9_28)
2453 WINE_CONFIG_DLL(d3dx9_29)
2454 WINE_CONFIG_DLL(d3dx9_30)
2455 WINE_CONFIG_DLL(d3dx9_31)
2456 WINE_CONFIG_DLL(d3dx9_32)
2457 WINE_CONFIG_DLL(d3dx9_33)
2458 WINE_CONFIG_DLL(d3dx9_34)
2459 WINE_CONFIG_DLL(d3dx9_35)
2460 WINE_CONFIG_DLL(d3dx9_36,,[implib],[d3dx9])
2461 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2462 WINE_CONFIG_DLL(d3dx9_37)
2463 WINE_CONFIG_DLL(d3dx9_38)
2464 WINE_CONFIG_DLL(d3dx9_39)
2465 WINE_CONFIG_DLL(d3dx9_40)
2466 WINE_CONFIG_DLL(d3dx9_41)
2467 WINE_CONFIG_DLL(d3dx9_42)
2468 WINE_CONFIG_DLL(d3dx9_43)
2469 WINE_CONFIG_DLL(d3dxof,,[implib])
2470 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2471 WINE_CONFIG_DLL(dbgeng,,[implib])
2472 WINE_CONFIG_DLL(dbghelp,,[implib])
2473 WINE_CONFIG_DLL(dciman32,,[implib])
2474 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2475 WINE_CONFIG_DLL(ddraw,,[implib])
2476 WINE_CONFIG_TEST(dlls/ddraw/tests)
2477 WINE_CONFIG_DLL(ddrawex)
2478 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2479 WINE_CONFIG_DLL(devenum,,[po])
2480 WINE_CONFIG_DLL(dinput,,[implib,po,staticimplib])
2481 WINE_CONFIG_TEST(dlls/dinput/tests)
2482 WINE_CONFIG_DLL(dinput8,,[implib])
2483 WINE_CONFIG_TEST(dlls/dinput8/tests)
2484 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2485 WINE_CONFIG_DLL(dispex)
2486 WINE_CONFIG_TEST(dlls/dispex/tests)
2487 WINE_CONFIG_DLL(display.drv16,enable_win16)
2488 WINE_CONFIG_DLL(dmband)
2489 WINE_CONFIG_DLL(dmcompos)
2490 WINE_CONFIG_DLL(dmime)
2491 WINE_CONFIG_TEST(dlls/dmime/tests)
2492 WINE_CONFIG_DLL(dmloader)
2493 WINE_CONFIG_TEST(dlls/dmloader/tests)
2494 WINE_CONFIG_DLL(dmscript)
2495 WINE_CONFIG_DLL(dmstyle)
2496 WINE_CONFIG_DLL(dmsynth)
2497 WINE_CONFIG_DLL(dmusic)
2498 WINE_CONFIG_DLL(dmusic32,,[implib])
2499 WINE_CONFIG_DLL(dnsapi,,[implib])
2500 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2501 WINE_CONFIG_DLL(dplay,,[implib])
2502 WINE_CONFIG_DLL(dplayx,,[implib])
2503 WINE_CONFIG_TEST(dlls/dplayx/tests)
2504 WINE_CONFIG_DLL(dpnaddr)
2505 WINE_CONFIG_DLL(dpnet,,[implib])
2506 WINE_CONFIG_TEST(dlls/dpnet/tests)
2507 WINE_CONFIG_DLL(dpnhpast)
2508 WINE_CONFIG_DLL(dpnlobby)
2509 WINE_CONFIG_DLL(dpwsockx)
2510 WINE_CONFIG_DLL(drmclien)
2511 WINE_CONFIG_DLL(dsound,,[implib])
2512 WINE_CONFIG_TEST(dlls/dsound/tests)
2513 WINE_CONFIG_DLL(dssenh)
2514 WINE_CONFIG_DLL(dswave)
2515 WINE_CONFIG_DLL(dwmapi,,[implib])
2516 WINE_CONFIG_DLL(dxdiagn,,[po])
2517 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2518 WINE_CONFIG_LIB(dxerr8)
2519 WINE_CONFIG_LIB(dxerr9)
2520 WINE_CONFIG_DLL(dxgi,,[implib])
2521 WINE_CONFIG_TEST(dlls/dxgi/tests)
2522 WINE_CONFIG_LIB(dxguid)
2523 WINE_CONFIG_DLL(explorerframe)
2524 WINE_CONFIG_TEST(dlls/explorerframe/tests)
2525 WINE_CONFIG_DLL(faultrep,,[implib])
2526 WINE_CONFIG_TEST(dlls/faultrep/tests)
2527 WINE_CONFIG_DLL(fltlib)
2528 WINE_CONFIG_DLL(fusion)
2529 WINE_CONFIG_TEST(dlls/fusion/tests)
2530 WINE_CONFIG_DLL(fwpuclnt)
2531 WINE_CONFIG_DLL(gameux)
2532 WINE_CONFIG_TEST(dlls/gameux/tests)
2533 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2534 WINE_CONFIG_DLL(gdi32,,[implib])
2535 WINE_CONFIG_TEST(dlls/gdi32/tests)
2536 WINE_CONFIG_DLL(gdiplus,,[implib])
2537 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2538 WINE_CONFIG_DLL(glu32,,[implib])
2539 WINE_CONFIG_DLL(gphoto2.ds)
2540 WINE_CONFIG_DLL(gpkcsp)
2541 WINE_CONFIG_DLL(hal)
2542 WINE_CONFIG_DLL(hhctrl.ocx,,[po])
2543 WINE_CONFIG_DLL(hid,,[implib])
2544 WINE_CONFIG_DLL(hlink,,[implib])
2545 WINE_CONFIG_TEST(dlls/hlink/tests)
2546 WINE_CONFIG_DLL(hnetcfg)
2547 WINE_CONFIG_DLL(httpapi)
2548 WINE_CONFIG_DLL(iccvid,,[po])
2549 WINE_CONFIG_DLL(icmp)
2550 WINE_CONFIG_DLL(ieframe,,[implib,po])
2551 WINE_CONFIG_TEST(dlls/ieframe/tests)
2552 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2553 WINE_CONFIG_DLL(imaadp32.acm)
2554 WINE_CONFIG_DLL(imagehlp,,[implib])
2555 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2556 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2557 WINE_CONFIG_DLL(imm32,,[implib])
2558 WINE_CONFIG_TEST(dlls/imm32/tests)
2559 WINE_CONFIG_DLL(inetcomm,,[implib])
2560 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2561 WINE_CONFIG_DLL(inetcpl.cpl,,[po])
2562 WINE_CONFIG_DLL(inetmib1)
2563 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2564 WINE_CONFIG_DLL(infosoft)
2565 WINE_CONFIG_TEST(dlls/infosoft/tests)
2566 WINE_CONFIG_DLL(initpki)
2567 WINE_CONFIG_DLL(inkobj)
2568 WINE_CONFIG_DLL(inseng)
2569 WINE_CONFIG_DLL(iphlpapi,,[implib])
2570 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2571 WINE_CONFIG_DLL(itircl)
2572 WINE_CONFIG_DLL(itss)
2573 WINE_CONFIG_TEST(dlls/itss/tests)
2574 WINE_CONFIG_DLL(jscript,,[po])
2575 WINE_CONFIG_TEST(dlls/jscript/tests)
2576 WINE_CONFIG_DLL(kernel32,,[implib,mc])
2577 WINE_CONFIG_TEST(dlls/kernel32/tests)
2578 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2579 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[implib],[kernel])
2580 WINE_CONFIG_DLL(ktmw32)
2581 WINE_CONFIG_DLL(loadperf,,[implib])
2582 WINE_CONFIG_DLL(localspl,,[po])
2583 WINE_CONFIG_TEST(dlls/localspl/tests)
2584 WINE_CONFIG_DLL(localui,,[po])
2585 WINE_CONFIG_TEST(dlls/localui/tests)
2586 WINE_CONFIG_DLL(lz32,,[implib])
2587 WINE_CONFIG_TEST(dlls/lz32/tests)
2588 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2589 WINE_CONFIG_DLL(mapi32,,[implib,po])
2590 WINE_CONFIG_TEST(dlls/mapi32/tests)
2591 WINE_CONFIG_DLL(mapistub)
2592 WINE_CONFIG_DLL(mciavi32)
2593 WINE_CONFIG_DLL(mcicda)
2594 WINE_CONFIG_DLL(mciqtz32)
2595 WINE_CONFIG_DLL(mciseq)
2596 WINE_CONFIG_DLL(mciwave)
2597 WINE_CONFIG_DLL(midimap)
2598 WINE_CONFIG_DLL(mlang,,[implib])
2599 WINE_CONFIG_TEST(dlls/mlang/tests)
2600 WINE_CONFIG_DLL(mmcndmgr)
2601 WINE_CONFIG_DLL(mmdevapi)
2602 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2603 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2604 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2605 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2606 WINE_CONFIG_DLL(mountmgr.sys)
2607 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2608 WINE_CONFIG_DLL(mpr,,[implib,po])
2609 WINE_CONFIG_DLL(mprapi,,[implib])
2610 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2611 WINE_CONFIG_DLL(msacm32.drv)
2612 WINE_CONFIG_DLL(msacm32,,[implib])
2613 WINE_CONFIG_TEST(dlls/msacm32/tests)
2614 WINE_CONFIG_DLL(msadp32.acm)
2615 WINE_CONFIG_DLL(mscat32)
2616 WINE_CONFIG_DLL(mscms,,[implib])
2617 WINE_CONFIG_TEST(dlls/mscms/tests)
2618 WINE_CONFIG_DLL(mscoree)
2619 WINE_CONFIG_TEST(dlls/mscoree/tests)
2620 WINE_CONFIG_DLL(msctf)
2621 WINE_CONFIG_TEST(dlls/msctf/tests)
2622 WINE_CONFIG_DLL(msdaps)
2623 WINE_CONFIG_DLL(msdmo,,[implib])
2624 WINE_CONFIG_DLL(msftedit)
2625 WINE_CONFIG_DLL(msg711.acm)
2626 WINE_CONFIG_DLL(msgsm32.acm)
2627 WINE_CONFIG_DLL(mshtml.tlb)
2628 WINE_CONFIG_DLL(mshtml,,[implib,po])
2629 WINE_CONFIG_TEST(dlls/mshtml/tests)
2630 WINE_CONFIG_DLL(msi,,[implib,po])
2631 WINE_CONFIG_TEST(dlls/msi/tests)
2632 WINE_CONFIG_DLL(msimg32,,[implib])
2633 WINE_CONFIG_DLL(msimsg)
2634 WINE_CONFIG_DLL(msimtf)
2635 WINE_CONFIG_DLL(msisip)
2636 WINE_CONFIG_DLL(msisys.ocx)
2637 WINE_CONFIG_DLL(msnet32)
2638 WINE_CONFIG_DLL(mspatcha)
2639 WINE_CONFIG_DLL(msrle32,,[po])
2640 WINE_CONFIG_DLL(mssign32)
2641 WINE_CONFIG_DLL(mssip32)
2642 WINE_CONFIG_DLL(mstask)
2643 WINE_CONFIG_TEST(dlls/mstask/tests)
2644 WINE_CONFIG_DLL(msvcirt)
2645 WINE_CONFIG_DLL(msvcp100)
2646 WINE_CONFIG_DLL(msvcp60)
2647 WINE_CONFIG_DLL(msvcp70)
2648 WINE_CONFIG_DLL(msvcp71)
2649 WINE_CONFIG_DLL(msvcp80)
2650 WINE_CONFIG_DLL(msvcp90)
2651 WINE_CONFIG_TEST(dlls/msvcp90/tests)
2652 WINE_CONFIG_DLL(msvcr100)
2653 WINE_CONFIG_DLL(msvcr70,,[implib])
2654 WINE_CONFIG_DLL(msvcr71,,[implib])
2655 WINE_CONFIG_DLL(msvcr80)
2656 WINE_CONFIG_DLL(msvcr90)
2657 WINE_CONFIG_TEST(dlls/msvcr90/tests)
2658 WINE_CONFIG_DLL(msvcrt,,[implib])
2659 WINE_CONFIG_TEST(dlls/msvcrt/tests)
2660 WINE_CONFIG_DLL(msvcrt20,,[implib])
2661 WINE_CONFIG_DLL(msvcrt40,,[implib])
2662 WINE_CONFIG_DLL(msvcrtd,,[implib])
2663 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
2664 WINE_CONFIG_DLL(msvfw32,,[implib,po])
2665 WINE_CONFIG_TEST(dlls/msvfw32/tests)
2666 WINE_CONFIG_DLL(msvidc32,,[po])
2667 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
2668 WINE_CONFIG_DLL(mswsock,,[implib])
2669 WINE_CONFIG_DLL(msxml)
2670 WINE_CONFIG_DLL(msxml2)
2671 WINE_CONFIG_DLL(msxml3)
2672 WINE_CONFIG_TEST(dlls/msxml3/tests)
2673 WINE_CONFIG_DLL(msxml4)
2674 WINE_CONFIG_DLL(msxml6)
2675 WINE_CONFIG_DLL(nddeapi,,[implib])
2676 WINE_CONFIG_DLL(netapi32,,[implib])
2677 WINE_CONFIG_TEST(dlls/netapi32/tests)
2678 WINE_CONFIG_DLL(newdev,,[implib])
2679 WINE_CONFIG_DLL(normaliz,,[implib])
2680 WINE_CONFIG_DLL(npmshtml)
2681 WINE_CONFIG_DLL(ntdll,,[implib])
2682 WINE_CONFIG_TEST(dlls/ntdll/tests)
2683 WINE_CONFIG_DLL(ntdsapi,,[implib])
2684 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
2685 WINE_CONFIG_DLL(ntoskrnl.exe,,[implib])
2686 WINE_CONFIG_DLL(ntprint)
2687 WINE_CONFIG_TEST(dlls/ntprint/tests)
2688 WINE_CONFIG_DLL(objsel)
2689 WINE_CONFIG_DLL(odbc32,,[implib])
2690 WINE_CONFIG_DLL(odbccp32,,[implib])
2691 WINE_CONFIG_TEST(dlls/odbccp32/tests)
2692 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
2693 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
2694 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
2695 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
2696 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
2697 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
2698 WINE_CONFIG_DLL(ole32,,[implib])
2699 WINE_CONFIG_TEST(dlls/ole32/tests)
2700 WINE_CONFIG_DLL(oleacc,,[implib,po])
2701 WINE_CONFIG_TEST(dlls/oleacc/tests)
2702 WINE_CONFIG_DLL(oleaut32,,[implib,po])
2703 WINE_CONFIG_TEST(dlls/oleaut32/tests)
2704 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
2705 WINE_CONFIG_DLL(olecli32,,[implib])
2706 WINE_CONFIG_DLL(oledb32)
2707 WINE_CONFIG_TEST(dlls/oledb32/tests)
2708 WINE_CONFIG_DLL(oledlg,,[implib,po])
2709 WINE_CONFIG_DLL(olepro32,,[implib])
2710 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
2711 WINE_CONFIG_DLL(olesvr32,,[implib])
2712 WINE_CONFIG_DLL(olethk32)
2713 WINE_CONFIG_DLL(openal32)
2714 WINE_CONFIG_DLL(opencl)
2715 WINE_CONFIG_DLL(opengl32,,[implib])
2716 WINE_CONFIG_TEST(dlls/opengl32/tests)
2717 WINE_CONFIG_DLL(pdh,,[implib])
2718 WINE_CONFIG_TEST(dlls/pdh/tests)
2719 WINE_CONFIG_DLL(pidgen)
2720 WINE_CONFIG_DLL(powrprof,,[implib])
2721 WINE_CONFIG_DLL(printui)
2722 WINE_CONFIG_DLL(propsys,,[implib])
2723 WINE_CONFIG_TEST(dlls/propsys/tests)
2724 WINE_CONFIG_DLL(psapi,,[implib])
2725 WINE_CONFIG_TEST(dlls/psapi/tests)
2726 WINE_CONFIG_DLL(pstorec)
2727 WINE_CONFIG_DLL(qcap)
2728 WINE_CONFIG_DLL(qedit)
2729 WINE_CONFIG_TEST(dlls/qedit/tests)
2730 WINE_CONFIG_DLL(qmgr)
2731 WINE_CONFIG_TEST(dlls/qmgr/tests)
2732 WINE_CONFIG_DLL(qmgrprxy)
2733 WINE_CONFIG_DLL(quartz,,[implib])
2734 WINE_CONFIG_TEST(dlls/quartz/tests)
2735 WINE_CONFIG_DLL(query)
2736 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
2737 WINE_CONFIG_DLL(rasapi32,,[implib])
2738 WINE_CONFIG_TEST(dlls/rasapi32/tests)
2739 WINE_CONFIG_DLL(rasdlg,,[implib])
2740 WINE_CONFIG_DLL(regapi)
2741 WINE_CONFIG_DLL(resutils,,[implib])
2742 WINE_CONFIG_DLL(riched20,,[implib])
2743 WINE_CONFIG_TEST(dlls/riched20/tests)
2744 WINE_CONFIG_DLL(riched32)
2745 WINE_CONFIG_TEST(dlls/riched32/tests)
2746 WINE_CONFIG_DLL(rpcrt4,,[implib])
2747 WINE_CONFIG_TEST(dlls/rpcrt4/tests)
2748 WINE_CONFIG_DLL(rsabase)
2749 WINE_CONFIG_DLL(rsaenh,,[implib])
2750 WINE_CONFIG_TEST(dlls/rsaenh/tests)
2751 WINE_CONFIG_DLL(rstrtmgr)
2752 WINE_CONFIG_DLL(rtutils,,[implib])
2753 WINE_CONFIG_DLL(samlib)
2754 WINE_CONFIG_DLL(sane.ds,,[po])
2755 WINE_CONFIG_DLL(scarddlg)
2756 WINE_CONFIG_DLL(sccbase)
2757 WINE_CONFIG_DLL(schannel)
2758 WINE_CONFIG_TEST(dlls/schannel/tests)
2759 WINE_CONFIG_DLL(secur32,,[implib])
2760 WINE_CONFIG_TEST(dlls/secur32/tests)
2761 WINE_CONFIG_DLL(security)
2762 WINE_CONFIG_DLL(sensapi,,[implib])
2763 WINE_CONFIG_DLL(serialui,,[implib])
2764 WINE_CONFIG_TEST(dlls/serialui/tests)
2765 WINE_CONFIG_DLL(setupapi,,[implib,po])
2766 WINE_CONFIG_TEST(dlls/setupapi/tests)
2767 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
2768 WINE_CONFIG_DLL(sfc,,[implib])
2769 WINE_CONFIG_DLL(sfc_os,,[implib])
2770 WINE_CONFIG_DLL(shdoclc,,[po])
2771 WINE_CONFIG_DLL(shdocvw,,[implib])
2772 WINE_CONFIG_TEST(dlls/shdocvw/tests)
2773 WINE_CONFIG_DLL(shell.dll16,enable_win16)
2774 WINE_CONFIG_DLL(shell32,,[implib,po])
2775 WINE_CONFIG_TEST(dlls/shell32/tests)
2776 WINE_CONFIG_DLL(shfolder,,[implib])
2777 WINE_CONFIG_DLL(shlwapi,,[implib,po])
2778 WINE_CONFIG_TEST(dlls/shlwapi/tests)
2779 WINE_CONFIG_DLL(slbcsp)
2780 WINE_CONFIG_DLL(slc,,[implib])
2781 WINE_CONFIG_DLL(snmpapi,,[implib])
2782 WINE_CONFIG_TEST(dlls/snmpapi/tests)
2783 WINE_CONFIG_DLL(softpub)
2784 WINE_CONFIG_DLL(sound.drv16,enable_win16)
2785 WINE_CONFIG_DLL(spoolss,,[implib])
2786 WINE_CONFIG_TEST(dlls/spoolss/tests)
2787 WINE_CONFIG_DLL(stdole2.tlb)
2788 WINE_CONFIG_DLL(stdole32.tlb)
2789 WINE_CONFIG_DLL(sti,,[implib])
2790 WINE_CONFIG_TEST(dlls/sti/tests)
2791 WINE_CONFIG_DLL(storage.dll16,enable_win16)
2792 WINE_CONFIG_DLL(stress.dll16,enable_win16)
2793 WINE_CONFIG_LIB(strmbase)
2794 WINE_CONFIG_LIB(strmiids)
2795 WINE_CONFIG_DLL(svrapi)
2796 WINE_CONFIG_DLL(sxs)
2797 WINE_CONFIG_DLL(system.drv16,enable_win16)
2798 WINE_CONFIG_DLL(t2embed)
2799 WINE_CONFIG_DLL(tapi32,,[implib])
2800 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
2801 WINE_CONFIG_DLL(traffic)
2802 WINE_CONFIG_DLL(twain.dll16,enable_win16)
2803 WINE_CONFIG_DLL(twain_32)
2804 WINE_CONFIG_TEST(dlls/twain_32/tests)
2805 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
2806 WINE_CONFIG_DLL(unicows,,[implib])
2807 WINE_CONFIG_DLL(updspapi)
2808 WINE_CONFIG_DLL(url,,[implib])
2809 WINE_CONFIG_DLL(urlmon,,[implib])
2810 WINE_CONFIG_TEST(dlls/urlmon/tests)
2811 WINE_CONFIG_DLL(usbd.sys,,[implib])
2812 WINE_CONFIG_DLL(user.exe16,enable_win16)
2813 WINE_CONFIG_DLL(user32,,[implib,po])
2814 WINE_CONFIG_TEST(dlls/user32/tests)
2815 WINE_CONFIG_DLL(userenv,,[implib])
2816 WINE_CONFIG_TEST(dlls/userenv/tests)
2817 WINE_CONFIG_DLL(usp10,,[implib])
2818 WINE_CONFIG_TEST(dlls/usp10/tests)
2819 WINE_CONFIG_LIB(uuid)
2820 WINE_CONFIG_DLL(uxtheme,,[implib])
2821 WINE_CONFIG_TEST(dlls/uxtheme/tests)
2822 WINE_CONFIG_DLL(vbscript)
2823 WINE_CONFIG_TEST(dlls/vbscript/tests)
2824 WINE_CONFIG_DLL(vcomp)
2825 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
2826 WINE_CONFIG_DLL(vdmdbg,,[implib])
2827 WINE_CONFIG_DLL(ver.dll16,enable_win16)
2828 WINE_CONFIG_DLL(version,,[implib])
2829 WINE_CONFIG_TEST(dlls/version/tests)
2830 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
2831 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
2832 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
2833 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
2834 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
2835 WINE_CONFIG_DLL(w32skrnl,enable_win16)
2836 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
2837 WINE_CONFIG_DLL(wbemprox)
2838 WINE_CONFIG_DLL(wer,,[implib])
2839 WINE_CONFIG_TEST(dlls/wer/tests)
2840 WINE_CONFIG_DLL(wiaservc)
2841 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
2842 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
2843 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
2844 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
2845 WINE_CONFIG_DLL(windowscodecs,,[implib])
2846 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
2847 WINE_CONFIG_DLL(winealsa.drv)
2848 WINE_CONFIG_DLL(winecoreaudio.drv)
2849 WINE_CONFIG_LIB(winecrt0)
2850 WINE_CONFIG_DLL(wined3d,,[implib])
2851 WINE_CONFIG_DLL(winegstreamer)
2852 WINE_CONFIG_DLL(winejoystick.drv)
2853 WINE_CONFIG_DLL(winemapi)
2854 WINE_CONFIG_DLL(winemp3.acm)
2855 WINE_CONFIG_DLL(wineoss.drv)
2856 WINE_CONFIG_DLL(wineps.drv,,[install-lib])
2857 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
2858 WINE_CONFIG_DLL(wineqtdecoder)
2859 WINE_CONFIG_DLL(winequartz.drv)
2860 WINE_CONFIG_DLL(winex11.drv)
2861 WINE_CONFIG_DLL(wing.dll16,enable_win16)
2862 WINE_CONFIG_DLL(wing32)
2863 WINE_CONFIG_DLL(winhttp,,[implib])
2864 WINE_CONFIG_TEST(dlls/winhttp/tests)
2865 WINE_CONFIG_DLL(wininet,,[implib,po])
2866 WINE_CONFIG_TEST(dlls/wininet/tests)
2867 WINE_CONFIG_DLL(winmm,,[implib,po])
2868 WINE_CONFIG_TEST(dlls/winmm/tests)
2869 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
2870 WINE_CONFIG_DLL(winnls32,,[implib])
2871 WINE_CONFIG_DLL(winscard,,[implib])
2872 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
2873 WINE_CONFIG_DLL(winspool.drv,,[implib,po],[winspool])
2874 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
2875 WINE_CONFIG_DLL(winsta)
2876 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
2877 WINE_CONFIG_DLL(wintab32,,[implib])
2878 WINE_CONFIG_TEST(dlls/wintab32/tests)
2879 WINE_CONFIG_DLL(wintrust,,[implib])
2880 WINE_CONFIG_TEST(dlls/wintrust/tests)
2881 WINE_CONFIG_DLL(wlanapi)
2882 WINE_CONFIG_DLL(wldap32,,[implib,po])
2883 WINE_CONFIG_TEST(dlls/wldap32/tests)
2884 WINE_CONFIG_DLL(wmi)
2885 WINE_CONFIG_DLL(wmiutils)
2886 WINE_CONFIG_DLL(wnaspi32,,[implib])
2887 WINE_CONFIG_DLL(wow32,enable_win16,[implib])
2888 WINE_CONFIG_DLL(ws2_32,,[implib])
2889 WINE_CONFIG_TEST(dlls/ws2_32/tests)
2890 WINE_CONFIG_DLL(wshom.ocx)
2891 WINE_CONFIG_TEST(dlls/wshom.ocx/tests)
2892 WINE_CONFIG_DLL(wsock32,,[implib])
2893 WINE_CONFIG_DLL(wtsapi32,,[implib])
2894 WINE_CONFIG_DLL(wuapi)
2895 WINE_CONFIG_DLL(wuaueng)
2896 WINE_CONFIG_DLL(xapofx1_1)
2897 WINE_CONFIG_DLL(xinput1_1)
2898 WINE_CONFIG_DLL(xinput1_2)
2899 WINE_CONFIG_DLL(xinput1_3,,[implib],[xinput])
2900 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
2901 WINE_CONFIG_DLL(xinput9_1_0)
2902 WINE_CONFIG_DLL(xmllite)
2903 WINE_CONFIG_TEST(dlls/xmllite/tests)
2904 WINE_CONFIG_DLL(xolehlp)
2905 WINE_CONFIG_MAKEFILE([documentation])
2906 WINE_CONFIG_MAKEFILE([fonts],,[install-lib])
2907 WINE_CONFIG_MAKEFILE([include],,[install-dev])
2908 WINE_CONFIG_MAKEFILE([libs/port])
2909 WINE_CONFIG_MAKEFILE([libs/wine],,[install-dev,install-lib])
2910 WINE_CONFIG_MAKEFILE([libs/wpp])
2911 WINE_CONFIG_MAKEFILE([loader],,[install-lib,manpage])
2912 WINE_CONFIG_PROGRAM(aspnet_regiis,,[install])
2913 WINE_CONFIG_PROGRAM(attrib,,[install,po])
2914 WINE_CONFIG_PROGRAM(cabarc,,[install])
2915 WINE_CONFIG_PROGRAM(cacls,,[install])
2916 WINE_CONFIG_PROGRAM(clock,,[install,po])
2917 WINE_CONFIG_PROGRAM(cmd,,[install,po])
2918 WINE_CONFIG_TEST(programs/cmd/tests)
2919 WINE_CONFIG_PROGRAM(cmdlgtst)
2920 WINE_CONFIG_PROGRAM(control,,[install])
2921 WINE_CONFIG_PROGRAM(dxdiag,,[install,po])
2922 WINE_CONFIG_PROGRAM(eject,,[install])
2923 WINE_CONFIG_PROGRAM(expand,,[install])
2924 WINE_CONFIG_PROGRAM(explorer,,[install,po])
2925 WINE_CONFIG_PROGRAM(extrac32,,[install])
2926 WINE_CONFIG_PROGRAM(hh,,[install])
2927 WINE_CONFIG_PROGRAM(hostname,,[install,po])
2928 WINE_CONFIG_PROGRAM(icinfo,,[install])
2929 WINE_CONFIG_PROGRAM(iexplore,,[install])
2930 WINE_CONFIG_PROGRAM(ipconfig,,[install,po])
2931 WINE_CONFIG_PROGRAM(lodctr,,[install])
2932 WINE_CONFIG_PROGRAM(mofcomp,,[install])
2933 WINE_CONFIG_PROGRAM(mshta,,[install])
2934 WINE_CONFIG_PROGRAM(msiexec,,[install,installbin,manpage])
2935 WINE_CONFIG_PROGRAM(net,,[install,po])
2936 WINE_CONFIG_PROGRAM(netsh,,[install])
2937 WINE_CONFIG_PROGRAM(ngen,,[install])
2938 WINE_CONFIG_PROGRAM(notepad,,[install,installbin,manpage,po])
2939 WINE_CONFIG_PROGRAM(oleview,,[install,po])
2940 WINE_CONFIG_PROGRAM(ping,,[install])
2941 WINE_CONFIG_PROGRAM(plugplay,,[install])
2942 WINE_CONFIG_PROGRAM(presentationfontcache,,[install])
2943 WINE_CONFIG_PROGRAM(progman,,[install,po])
2944 WINE_CONFIG_PROGRAM(reg,,[install,po])
2945 WINE_CONFIG_PROGRAM(regasm,,[install])
2946 WINE_CONFIG_PROGRAM(regedit,,[install,installbin,manpage,po])
2947 WINE_CONFIG_TEST(programs/regedit/tests)
2948 WINE_CONFIG_PROGRAM(regsvcs,,[install])
2949 WINE_CONFIG_PROGRAM(regsvr32,,[install,installbin,manpage])
2950 WINE_CONFIG_PROGRAM(rpcss,,[install])
2951 WINE_CONFIG_PROGRAM(rundll.exe16,enable_win16,[install])
2952 WINE_CONFIG_PROGRAM(rundll32,,[install])
2953 WINE_CONFIG_PROGRAM(sc,,[install])
2954 WINE_CONFIG_PROGRAM(secedit,,[install])
2955 WINE_CONFIG_PROGRAM(servicemodelreg,,[install])
2956 WINE_CONFIG_PROGRAM(services,,[install])
2957 WINE_CONFIG_PROGRAM(spoolsv,,[install])
2958 WINE_CONFIG_PROGRAM(start,,[install,po])
2959 WINE_CONFIG_PROGRAM(svchost,,[install])
2960 WINE_CONFIG_PROGRAM(taskkill,,[install,po])
2961 WINE_CONFIG_PROGRAM(taskmgr,,[install,po])
2962 WINE_CONFIG_PROGRAM(termsv,,[install])
2963 WINE_CONFIG_PROGRAM(uninstaller,,[install,po])
2964 WINE_CONFIG_PROGRAM(unlodctr,,[install])
2965 WINE_CONFIG_PROGRAM(view,,[install,po])
2966 WINE_CONFIG_PROGRAM(wineboot,,[install,installbin,manpage])
2967 WINE_CONFIG_PROGRAM(winebrowser,,[install])
2968 WINE_CONFIG_PROGRAM(winecfg,,[install,installbin,manpage,po])
2969 WINE_CONFIG_PROGRAM(wineconsole,,[install,installbin,manpage,po])
2970 WINE_CONFIG_PROGRAM(winedbg,,[install,installbin,manpage,po])
2971 WINE_CONFIG_PROGRAM(winedevice,,[install])
2972 WINE_CONFIG_PROGRAM(winefile,,[install,installbin,manpage,po])
2973 WINE_CONFIG_PROGRAM(winemenubuilder,,[install])
2974 WINE_CONFIG_PROGRAM(winemine,,[install,installbin,manpage,po])
2975 WINE_CONFIG_PROGRAM(winemsibuilder,,[install])
2976 WINE_CONFIG_PROGRAM(winepath,,[install,installbin,manpage])
2977 WINE_CONFIG_PROGRAM(winetest)
2978 WINE_CONFIG_PROGRAM(winevdm,enable_win16,[install])
2979 WINE_CONFIG_PROGRAM(winhelp.exe16,enable_win16,[install])
2980 WINE_CONFIG_PROGRAM(winhlp32,,[install,po])
2981 WINE_CONFIG_PROGRAM(winoldap.mod16,enable_win16,[install])
2982 WINE_CONFIG_PROGRAM(winver,,[install])
2983 WINE_CONFIG_PROGRAM(wmic,,[install])
2984 WINE_CONFIG_PROGRAM(wordpad,,[install,po])
2985 WINE_CONFIG_PROGRAM(write,,[install,po])
2986 WINE_CONFIG_PROGRAM(wscript,,[install])
2987 WINE_CONFIG_TEST(programs/wscript/tests)
2988 WINE_CONFIG_PROGRAM(xcopy,,[install,po])
2989 WINE_CONFIG_MAKEFILE([server],,[install-lib,manpage])
2990 WINE_CONFIG_TOOL(tools,[install-dev,install-lib,manpage])
2991 WINE_CONFIG_TOOL(tools/widl,[install-dev,manpage])
2992 WINE_CONFIG_TOOL(tools/winebuild,[install-dev,manpage])
2993 WINE_CONFIG_TOOL(tools/winedump,[install-dev,manpage])
2994 WINE_CONFIG_TOOL(tools/winegcc,[install-dev,manpage])
2995 WINE_CONFIG_TOOL(tools/wmc,[install-dev,manpage])
2996 WINE_CONFIG_TOOL(tools/wrc,[install-dev,manpage])
2997
2998 AC_SUBST([LINGUAS],["\
2999 ar \
3000 bg \
3001 ca \
3002 cs \
3003 da \
3004 de \
3005 el \
3006 en \
3007 en_US \
3008 eo \
3009 es \
3010 fa \
3011 fi \
3012 fr \
3013 he \
3014 hi \
3015 hu \
3016 it \
3017 ja \
3018 ko \
3019 lt \
3020 ml \
3021 nb_NO \
3022 nl \
3023 or \
3024 pa \
3025 pl \
3026 pt_BR \
3027 pt_PT \
3028 rm \
3029 ro \
3030 ru \
3031 sk \
3032 sl \
3033 sr_RS@cyrillic \
3034 sr_RS@latin \
3035 sv \
3036 te \
3037 th \
3038 tr \
3039 uk \
3040 wa \
3041 zh_CN \
3042 zh_TW"])
3043
3044 dnl End of auto-generated output commands
3045
3046 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
3047 [wine_fn_output_makefile ()
3048 {
3049     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
3050 $ALL_MAKEFILE_DEPENDS
3051 _WINE_EOF
3052     AS_ERROR([could not create Makefile])
3053 }])
3054
3055 AC_CONFIG_FILES([Make.tmp:Make.vars.in:Makefile.in])
3056
3057 dnl Some final makefile rules
3058
3059 if test "x$enable_maintainer_mode" = xyes
3060 then
3061     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3062 [\$(srcdir)/configure: configure.ac aclocal.m4
3063         cd \$(srcdir) && autoconf --warnings=all
3064 \$(srcdir)/include/config.h.in: include/stamp-h.in
3065 \$(srcdir)/include/stamp-h.in: configure.ac aclocal.m4
3066         cd \$(srcdir) && autoheader --warnings=all
3067         @echo timestamp > \$[@]])
3068 fi
3069
3070 if test "x$with_gettextpo" = xyes
3071 then
3072     test "$srcdir" = . || AC_MSG_ERROR([Rebuilding po files is not supported for out of tree builds.])
3073     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3074 [ALL_POT_FILES =$ALL_POT_FILES
3075 \$(LINGUAS:%=po/%.po): \$(srcdir)/po/wine.pot
3076         msgmerge -q \$[@] \$(srcdir)/po/wine.pot | msgattrib --no-obsolete -o \$[@].new && mv \$[@].new \$[@]
3077 \$(srcdir)/po/wine.pot: \$(ALL_POT_FILES)
3078         msgcat -o \$[@] \$(ALL_POT_FILES)])
3079 fi
3080
3081 if test "$MSGFMT" != false
3082 then
3083     AC_SUBST([PORCFLAGS],["--po-dir=\$(top_builddir)/po"])
3084     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],[__builddeps__: \$(ALL_MO_FILES)])
3085 else
3086     LINGUAS=
3087 fi
3088
3089 if test "x$enable_tools" != xno
3090 then
3091     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3092 [\$(MAKEDEP): tools/Makefile
3093 clean:: __clean__
3094         \$(RM) tools/makedep\$(EXEEXT)])
3095 fi
3096
3097 if test -n "$with_wine64"
3098 then
3099 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3100 [all: fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader
3101 fonts server tools:
3102         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
3103 $with_wine64/loader/wine:
3104         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine \$[@]
3105 $with_wine64/loader/wine-preloader:
3106         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine-preloader \$[@]
3107 clean::
3108         \$(RM) fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader])
3109 fi
3110
3111 AC_OUTPUT
3112
3113 if test "$no_create" = "yes"
3114 then
3115   exit 0
3116 fi
3117
3118 WINE_PRINT_MESSAGES
3119
3120 echo "
3121 $as_me: Finished.  Do '${ac_make}' to compile Wine.
3122 " >&AS_MESSAGE_FD
3123
3124 dnl Local Variables:
3125 dnl comment-start: "dnl "
3126 dnl comment-end: ""
3127 dnl comment-start-skip: "\\bdnl\\b\\s *"
3128 dnl compile-command: "autoreconf --warnings=all"
3129 dnl End: