git.oblomov.eu Git - wine/blob - aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE(AC_LANG_SOURCE([int main(int argc, char *argv[]) { return 0; }]),
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32,w64-mingw32],[x86_64-ac_wine_prefix-$2 ])" ;;
 132   *)
 133     ac_prefix_list="" ;;
 134 esac
 135 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 136
 137
 138 dnl **** Create nonexistent directories from config.status ****
 139 dnl
 140 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 141 dnl
 142 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 143 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])])
 144
 145 dnl **** Create symlinks from config.status ****
 146 dnl
 147 dnl Usage: WINE_CONFIG_SYMLINK(name,target)
 148 dnl
 149 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 150 m4_if([$2],,[test "$srcdir" = "." || ])ALL_SYMLINKS="$ALL_SYMLINKS \\
 151         $1"])
 152
 153 dnl **** Create a make rules file from config.status ****
 154 dnl
 155 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 156 dnl
 157 AC_DEFUN([WINE_CONFIG_MAKERULES],
 158 [ALL_MAKERULES="$ALL_MAKERULES \\
 159         $1"
 160 ALL_MAKEFILE_DEPENDS="$ALL_MAKEFILE_DEPENDS
 161 $1: m4_ifval([$3],[$1.in $3],[$1.in]) config.status"
 162 $2=$1
 163 AC_SUBST_FILE([$2])dnl
 164 AC_CONFIG_FILES([$1])])
 165
 166 dnl **** Create a makefile from config.status ****
 167 dnl
 168 dnl Usage: WINE_CONFIG_MAKEFILE(file,deps,prefix,var,enable)
 169 dnl
 170 AC_DEFUN([WINE_CONFIG_MAKEFILE],
 171 [m4_pushdef([ac_dir],m4_bpatsubst([$1],[^\($3/?\(.*\)/\)?Makefile$],[\2]))dnl
 172 m4_ifval(ac_dir,[ALL_MAKEFILES="$ALL_MAKEFILES \\
 173         $1"])
 174 AS_VAR_PUSHDEF([ac_enable],m4_default([$5],[enable_]ac_dir))dnl
 175 m4_ifval([$4],[test "x$ac_enable" != xno]m4_foreach([ac_var],[$4],[ && ac_var="$ac_var \\
 176         ac_dir"]))
 177 AS_VAR_POPDEF([ac_enable])dnl
 178 ALL_MAKEFILE_DEPENDS="$ALL_MAKEFILE_DEPENDS
 179 [$1: ]m4_ifval([$2],[$1.in $2],[$1.in]) config.status"
 180 AC_CONFIG_FILES([$1])dnl
 181 m4_popdef([ac_dir])])
 182
 183 dnl **** Create a dll makefile from config.status ****
 184 dnl
 185 dnl Usage: WINE_CONFIG_DLL(name,enable,implib,implibsrc)
 186 dnl
 187 AC_DEFUN([WINE_CONFIG_DLL],
 188 [m4_ifval([$3],[m4_ifval([$2],[test "x$[$2]" = xno || ])ALL_IMPORT_LIBS="$ALL_IMPORT_LIBS \\
 189         $1/lib$3.$IMPLIBEXT[]dnl
 190 m4_if($1,$3,,[ \\
 191         lib$3.$IMPLIBEXT])[]dnl
 192 m4_ifval([$4],[ \\
 193         $1/lib$3.$STATIC_IMPLIBEXT])"
 194 ALL_IMPORTLIB_RULES="$ALL_IMPORTLIB_RULES
 195 m4_if($1,$3,,[lib$3.a: $1/lib$3.a
 196         \$(RM) \$[@] && \$(LN_S) $1/lib$3.a \$[@]
 197 lib$3.cross.a: $1/lib$3.cross.a
 198         \$(RM) \$[@] && \$(LN_S) $1/lib$3.cross.a \$[@]
 199 lib$3.def: $1/lib$3.def
 200         \$(RM) \$[@] && \$(LN_S) $1/lib$3.def \$[@]
 201 clean::
 202         \$(RM) lib$3.def
 203 ])m4_ifval([$4],[$1/lib$3.def: $1/$1.spec \$(WINEBUILD)
 204         @cd $1 && \$(MAKE) \`basename \$[@]\`
 205 $1/lib$3.$STATIC_IMPLIBEXT $1/lib$3.cross.a: dummy
 206         @cd $1 && \$(MAKE) \`basename \$[@]\`],
 207 [$1/lib$3.def $1/lib$3.a $1/lib$3.cross.a: $1/$1.spec \$(WINEBUILD)
 208         @cd $1 && \$(MAKE) \`basename \$[@]\`])"
 209 ])dnl
 210 WINE_CONFIG_MAKEFILE([dlls/$1/Makefile],[dlls/Makedll.rules],[dlls],[ALL_DLL_DIRS],[$2])])
 211
 212 dnl **** Create a program makefile from config.status ****
 213 dnl
 214 dnl Usage: WINE_CONFIG_PROGRAM(name,var,enable)
 215 dnl
 216 AC_DEFUN([WINE_CONFIG_PROGRAM],
 217 [WINE_CONFIG_MAKEFILE([programs/$1/Makefile],[programs/Makeprog.rules],[programs],[$2],[$3])])
 218
 219 dnl **** Create a test makefile from config.status ****
 220 dnl
 221 dnl Usage: WINE_CONFIG_TEST(dir)
 222 dnl
 223 AC_DEFUN([WINE_CONFIG_TEST],
 224 [WINE_CONFIG_MAKEFILE([$1/Makefile],[dlls/Maketest.rules],[dlls],[ALL_TEST_DIRS],[enable_tests])])
 225
 226 dnl **** Create a static lib makefile from config.status ****
 227 dnl
 228 dnl Usage: WINE_CONFIG_LIB(name)
 229 dnl
 230 AC_DEFUN([WINE_CONFIG_LIB],
 231 [ALL_STATIC_LIBS="$ALL_STATIC_LIBS \\
 232         $1/lib$1.a"
 233 ALL_IMPORTLIB_RULES="$ALL_IMPORTLIB_RULES
 234 $1/lib$1.a: $1
 235 $1/lib$1.cross.a: dummy
 236         @cd $1 && \$(MAKE) lib$1.cross.a"
 237 WINE_CONFIG_MAKEFILE([dlls/$1/Makefile],[dlls/Makeimplib.rules],[dlls],[ALL_IMPLIB_DIRS])])
 238
 239 dnl **** Add a message to the list displayed at the end ****
 240 dnl
 241 dnl Usage: WINE_NOTICE(notice)
 242 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 243 dnl Usage: WINE_WARNING(warning)
 244 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 245 dnl Usage: WINE_PRINT_MESSAGES
 246 dnl
 247 AC_DEFUN([WINE_NOTICE],[wine_notices="$wine_notices|$1"])
 248 AC_DEFUN([WINE_WARNING],[wine_warnings="$wine_warnings|$1"])
 249
 250 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 251   x)   WINE_NOTICE([$3]) ;;
 252   xno) ;;
 253   *)   AC_MSG_ERROR([$3
 254 This is an error since --with-$1 was requested.]) ;;
 255 esac])])
 256
 257 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 258   x)   WINE_WARNING([$3]) ;;
 259   xno) ;;
 260   *)   AC_MSG_ERROR([$3
 261 This is an error since --with-$1 was requested.]) ;;
 262 esac])])
 263
 264 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 265   xno) ;;
 266   *)   AC_MSG_ERROR([$3
 267 Use the --without-$1 option if you really want this.]) ;;
 268 esac])])
 269
 270 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 271 if test "x$wine_notices != "x; then
 272     echo >&AS_MESSAGE_FD
 273     IFS="|"
 274     for msg in $wine_notices; do
 275         IFS="$ac_save_IFS"
 276         if test -n "$msg"; then
 277             AC_MSG_NOTICE([$msg])
 278         fi
 279     done
 280 fi
 281 IFS="|"
 282 for msg in $wine_warnings; do
 283     IFS="$ac_save_IFS"
 284     if test -n "$msg"; then
 285         echo >&2
 286         AC_MSG_WARN([$msg])
 287     fi
 288 done
 289 IFS="$ac_save_IFS"])
 290
 291 dnl Local Variables:
 292 dnl compile-command: "autoreconf --warnings=all"
 293 dnl End: