git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41
  42 #if defined(YYBYACC)
  43         /* Berkeley yacc (byacc) doesn't seem to know about these */
  44         /* Some *BSD supplied versions do define these though */
  45 # ifndef YYEMPTY
  46 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  47 # endif
  48 # ifndef YYLEX
  49 #  define YYLEX         yylex()
  50 # endif
  51
  52 #elif defined(YYBISON)
  53         /* Bison was used for original development */
  54         /* #define YYEMPTY -2 */
  55         /* #define YYLEX   yylex() */
  56
  57 #else
  58         /* No yacc we know yet */
  59 # if !defined(YYEMPTY) || !defined(YYLEX)
  60 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  61 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  62 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  63   /* #else we just take a chance that it works... */
  64 # endif
  65 #endif
  66
  67 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr);
  68 static attr_t *make_attr(enum attr_type type);
  69 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  70 static attr_t *make_attrp(enum attr_type type, void *val);
  71 static expr_t *make_expr(enum expr_type type);
  72 static expr_t *make_exprl(enum expr_type type, long val);
  73 static expr_t *make_exprs(enum expr_type type, char *val);
  74 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  75 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  76 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  77 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  78 static type_t *make_type(unsigned char type, type_t *ref);
  79 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr);
  80 static array_dims_t *append_array(array_dims_t *list, expr_t *expr);
  81 static typeref_t *make_tref(char *name, type_t *ref);
  82 static typeref_t *uniq_tref(typeref_t *ref);
  83 static type_t *type_ref(typeref_t *ref);
  84 static void set_type(var_t *v, typeref_t *ref, array_dims_t *arr);
  85 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface);
  86 static ifref_t *make_ifref(type_t *iface);
  87 static var_list_t *append_var(var_list_t *list, var_t *var);
  88 static var_t *make_var(char *name);
  89 static func_list_t *append_func(func_list_t *list, func_t *func);
  90 static func_t *make_func(var_t *def, var_list_t *args);
  91 static type_t *make_class(char *name);
  92 static type_t *make_safearray(void);
  93 static type_t *make_builtin(char *name);
  94 static type_t *make_int(int sign);
  95
  96 static type_t *reg_type(type_t *type, const char *name, int t);
  97 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs);
  98 static type_t *find_type(const char *name, int t);
  99 static type_t *find_type2(char *name, int t);
 100 static type_t *get_type(unsigned char type, char *name, int t);
 101 static type_t *get_typev(unsigned char type, var_t *name, int t);
 102 static int get_struct_type(var_list_t *fields);
 103
 104 static var_t *reg_const(var_t *var);
 105 static var_t *find_const(char *name, int f);
 106
 107 static void write_libid(const char *name, const attr_list_t *attr);
 108 static void write_clsid(type_t *cls);
 109 static void write_diid(type_t *iface);
 110 static void write_iid(type_t *iface);
 111
 112 static int compute_method_indexes(type_t *iface);
 113 static char *gen_name(void);
 114 static void process_typedefs(var_list_t *names);
 115 static void check_arg(var_t *arg);
 116
 117 #define tsENUM   1
 118 #define tsSTRUCT 2
 119 #define tsUNION  3
 120
 121 %}
 122 %union {
 123         attr_t *attr;
 124         attr_list_t *attr_list;
 125         expr_t *expr;
 126         expr_list_t *expr_list;
 127         array_dims_t *array_dims;
 128         type_t *type;
 129         typeref_t *tref;
 130         var_t *var;
 131         var_list_t *var_list;
 132         func_t *func;
 133         func_list_t *func_list;
 134         ifref_t *ifref;
 135         ifref_list_t *ifref_list;
 136         char *str;
 137         UUID *uuid;
 138         unsigned int num;
 139 }
 140
 141 %token <str> aIDENTIFIER
 142 %token <str> aKNOWNTYPE
 143 %token <num> aNUM aHEXNUM
 144 %token <str> aSTRING
 145 %token <uuid> aUUID
 146 %token aEOF
 147 %token SHL SHR
 148 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 149 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 150 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 151 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 152 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 153 %token tDEFAULT
 154 %token tDEFAULTCOLLELEM
 155 %token tDEFAULTVALUE
 156 %token tDEFAULTVTABLE
 157 %token tDISPLAYBIND
 158 %token tDISPINTERFACE
 159 %token tDLLNAME tDOUBLE tDUAL
 160 %token tENDPOINT
 161 %token tENTRY tENUM tERRORSTATUST
 162 %token tEXPLICITHANDLE tEXTERN
 163 %token tFALSE
 164 %token tFLOAT
 165 %token tHANDLE
 166 %token tHANDLET
 167 %token tHELPCONTEXT tHELPFILE
 168 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 169 %token tHIDDEN
 170 %token tHYPER tID tIDEMPOTENT
 171 %token tIIDIS
 172 %token tIMMEDIATEBIND
 173 %token tIMPLICITHANDLE
 174 %token tIMPORT tIMPORTLIB
 175 %token tIN tINLINE
 176 %token tINPUTSYNC
 177 %token tINT tINT64
 178 %token tINTERFACE
 179 %token tLCID
 180 %token tLENGTHIS tLIBRARY
 181 %token tLOCAL
 182 %token tLONG
 183 %token tMETHODS
 184 %token tMODULE
 185 %token tNONBROWSABLE
 186 %token tNONCREATABLE
 187 %token tNONEXTENSIBLE
 188 %token tOBJECT tODL tOLEAUTOMATION
 189 %token tOPTIONAL
 190 %token tOUT
 191 %token tPOINTERDEFAULT
 192 %token tPROPERTIES
 193 %token tPROPGET tPROPPUT tPROPPUTREF
 194 %token tPTR
 195 %token tPUBLIC
 196 %token tRANGE
 197 %token tREADONLY tREF
 198 %token tREQUESTEDIT
 199 %token tRESTRICTED
 200 %token tRETVAL
 201 %token tSAFEARRAY
 202 %token tSHORT
 203 %token tSIGNED
 204 %token tSINGLE
 205 %token tSIZEIS tSIZEOF
 206 %token tSMALL
 207 %token tSOURCE
 208 %token tSTDCALL
 209 %token tSTRING tSTRUCT
 210 %token tSWITCH tSWITCHIS tSWITCHTYPE
 211 %token tTRANSMITAS
 212 %token tTRUE
 213 %token tTYPEDEF
 214 %token tUNION
 215 %token tUNIQUE
 216 %token tUNSIGNED
 217 %token tUUID
 218 %token tV1ENUM
 219 %token tVARARG
 220 %token tVERSION
 221 %token tVOID
 222 %token tWCHAR tWIREMARSHAL
 223
 224 %type <attr> attribute
 225 %type <attr_list> m_attributes attributes attrib_list
 226 %type <expr> m_expr expr expr_const
 227 %type <expr_list> m_exprs /* exprs expr_list */ expr_list_const
 228 %type <array_dims> array array_list
 229 %type <type> inherit interface interfacehdr interfacedef interfacedec
 230 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 231 %type <type> module modulehdr moduledef
 232 %type <type> base_type int_std
 233 %type <type> enumdef structdef uniondef
 234 %type <ifref> coclass_int
 235 %type <ifref_list> gbl_statements coclass_ints
 236 %type <tref> type
 237 %type <var> arg field s_field case enum constdef externdef
 238 %type <var_list> m_args no_args args fields cases enums enum_list pident_list dispint_props
 239 %type <var> m_ident t_ident ident p_ident pident
 240 %type <func> funcdef
 241 %type <func_list> int_statements dispint_meths
 242 %type <type> coclass coclasshdr coclassdef
 243 %type <num> pointer_type version
 244 %type <str> libraryhdr
 245
 246 %left ','
 247 %right '?' ':'
 248 %left '|'
 249 %left '&'
 250 %left '-' '+'
 251 %left '*' '/'
 252 %left SHL SHR
 253 %right '~'
 254 %right CAST
 255 %right PPTR
 256 %right NEG
 257
 258 %%
 259
 260 input:   gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 261         ;
 262
 263 gbl_statements:                                 { $$ = NULL; }
 264         | gbl_statements interfacedec           { $$ = $1; }
 265         | gbl_statements interfacedef           { $$ = append_ifref( $1, make_ifref($2) ); }
 266         | gbl_statements coclass ';'            { $$ = $1;
 267                                                   reg_type($2, $2->name, 0);
 268                                                   if (!parse_only && do_header) write_coclass_forward($2);
 269                                                 }
 270         | gbl_statements coclassdef             { $$ = $1;
 271                                                   add_typelib_entry($2);
 272                                                   reg_type($2, $2->name, 0);
 273                                                   if (!parse_only && do_header) write_coclass_forward($2);
 274                                                 }
 275         | gbl_statements moduledef              { $$ = $1; add_typelib_entry($2); }
 276         | gbl_statements librarydef             { $$ = $1; }
 277         | gbl_statements statement              { $$ = $1; }
 278         ;
 279
 280 imp_statements:                                 {}
 281         | imp_statements interfacedec           { if (!parse_only) add_typelib_entry($2); }
 282         | imp_statements interfacedef           { if (!parse_only) add_typelib_entry($2); }
 283         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 284         | imp_statements coclassdef             { if (!parse_only) add_typelib_entry($2);
 285                                                   reg_type($2, $2->name, 0);
 286                                                   if (!parse_only && do_header) write_coclass_forward($2);
 287                                                 }
 288         | imp_statements moduledef              { if (!parse_only) add_typelib_entry($2); }
 289         | imp_statements statement              {}
 290         | imp_statements importlib              {}
 291         ;
 292
 293 int_statements:                                 { $$ = NULL; }
 294         | int_statements funcdef ';'            { $$ = append_func( $1, $2 ); }
 295         | int_statements statement              { $$ = $1; }
 296         ;
 297
 298 statement: ';'                                  {}
 299         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 300         | cppquote                              {}
 301         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 302         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 303         | import                                {}
 304         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 305         | typedef ';'                           {}
 306         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 307         ;
 308
 309 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 310         ;
 311 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 312                                                   if (!do_import($2)) yychar = aEOF; }
 313         ;
 314 import:   import_start imp_statements aEOF      {}
 315         ;
 316
 317 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 318         ;
 319
 320 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 321         ;
 322 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 323                                                   if (!parse_only && do_header) write_library($2, $1);
 324                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 325                                                 }
 326         ;
 327 librarydef: library_start imp_statements '}'    { end_typelib(); }
 328         ;
 329
 330 m_args:                                         { $$ = NULL; }
 331         | args
 332         ;
 333
 334 no_args:  tVOID                                 { $$ = NULL; }
 335         ;
 336
 337 args:     arg                                   { check_arg($1); $$ = append_var( NULL, $1 ); }
 338         | args ',' arg                          { check_arg($3); $$ = append_var( $1, $3); }
 339         | no_args
 340         ;
 341
 342 /* split into two rules to get bison to resolve a tVOID conflict */
 343 arg:      attributes type pident array          { $$ = $3;
 344                                                   set_type($$, $2, $4);
 345                                                   $$->attrs = $1;
 346                                                 }
 347         | type pident array                     { $$ = $2;
 348                                                   set_type($$, $1, $3);
 349                                                 }
 350         | attributes type pident '(' m_args ')' { $$ = $3;
 351                                                   $$->ptr_level--;
 352                                                   set_type($$, $2, NULL);
 353                                                   $$->attrs = $1;
 354                                                   $$->args = $5;
 355                                                 }
 356         | type pident '(' m_args ')'            { $$ = $2;
 357                                                   $$->ptr_level--;
 358                                                   set_type($$, $1, NULL);
 359                                                   $$->args = $4;
 360                                                 }
 361         ;
 362
 363 array:                                          { $$ = NULL; }
 364         | '[' array_list ']'                    { $$ = $2; }
 365         | '[' '*' ']'                           { $$ = append_array( NULL, make_expr(EXPR_VOID) ); }
 366         ;
 367
 368 array_list: m_expr /* size of first dimension is optional */ { $$ = append_array( NULL, $1 ); }
 369         | array_list ',' expr                   { $$ = append_array( $1, $3 ); }
 370         | array_list ']' '[' expr               { $$ = append_array( $1, $4 ); }
 371         ;
 372
 373 m_attributes:                                   { $$ = NULL; }
 374         | attributes
 375         ;
 376
 377 attributes:
 378           '[' attrib_list ']'                   { $$ = $2;
 379                                                   if (!$$)
 380                                                     yyerror("empty attribute lists unsupported");
 381                                                 }
 382         ;
 383
 384 attrib_list: attribute                          { $$ = append_attr( NULL, $1 ); }
 385         | attrib_list ',' attribute             { $$ = append_attr( $1, $3 ); }
 386         | attrib_list ']' '[' attribute         { $$ = append_attr( $1, $4 ); }
 387         ;
 388
 389 attribute:                                      { $$ = NULL; }
 390         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 391         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 392         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 393         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 394         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 395         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 396         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 397         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 398         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 399         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 400         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 401         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 402         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 403         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 404         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 405         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 406         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 407         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 408         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 409         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 410         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 411         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 412         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 413         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 414         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 415         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 416         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 417         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 418         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 419         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 420         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 421         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 422         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 423         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 424         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 425         | tIN                                   { $$ = make_attr(ATTR_IN); }
 426         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 427         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 428         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 429         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 430         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 431         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 432         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 433         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 434         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 435         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 436         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 437         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 438         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 439         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 440         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 441         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 442         | tRANGE '(' expr_const ',' expr_const ')' { expr_list_t *list = append_expr( NULL, $3 );
 443                                                      list = append_expr( list, $5 );
 444                                                      $$ = make_attrp(ATTR_RANGE, list); }
 445         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 446         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 447         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 448         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 449         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 450         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 451         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 452         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 453         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 454         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 455         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 456         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 457         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 458         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 459         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 460         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 461         ;
 462
 463 callconv:
 464         | tSTDCALL
 465         ;
 466
 467 cases:                                          { $$ = NULL; }
 468         | cases case                            { $$ = append_var( $1, $2 ); }
 469         ;
 470
 471 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 472                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 473                                                   $$->attrs = append_attr( $$->attrs, a );
 474                                                 }
 475         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 476                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 477                                                   $$->attrs = append_attr( $$->attrs, a );
 478                                                 }
 479         ;
 480
 481 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 482                                                   set_type($$, $2, NULL);
 483                                                   $$->eval = $5;
 484                                                 }
 485         ;
 486
 487 enums:                                          { $$ = NULL; }
 488         | enum_list ','                         { $$ = $1; }
 489         | enum_list
 490         ;
 491
 492 enum_list: enum                                 { if (!$1->eval)
 493                                                     $1->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 494                                                   $$ = append_var( NULL, $1 );
 495                                                 }
 496         | enum_list ',' enum                    { if (!$3->eval)
 497                                                   {
 498                                                     var_t *last = LIST_ENTRY( list_tail($$), var_t, entry );
 499                                                     $3->eval = make_exprl(EXPR_NUM, last->eval->cval + 1);
 500                                                   }
 501                                                   $$ = append_var( $1, $3 );
 502                                                 }
 503         ;
 504
 505 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 506                                                   $$->eval = $3;
 507                                                   $$->type = make_int(0);
 508                                                 }
 509         | ident                                 { $$ = reg_const($1);
 510                                                   $$->type = make_int(0);
 511                                                 }
 512         ;
 513
 514 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 515                                                   $$->kind = TKIND_ENUM;
 516                                                   $$->fields = $4;
 517                                                   $$->defined = TRUE;
 518                                                   if(in_typelib)
 519                                                       add_typelib_entry($$);
 520                                                 }
 521         ;
 522
 523 m_exprs:  m_expr                                { $$ = append_expr( NULL, $1 ); }
 524         | m_exprs ',' m_expr                    { $$ = append_expr( $1, $3 ); }
 525         ;
 526
 527 /*
 528 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 529         | expr_list
 530         ;
 531
 532 expr_list: expr
 533         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 534         ;
 535 */
 536
 537 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 538         | expr
 539         ;
 540
 541 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 542         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 543         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 544         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 545         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 546         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 547         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 548         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 549         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 550         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 551         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 552         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 553         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 554         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 555         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 556         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 557         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 558         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 559         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 560         | '(' expr ')'                          { $$ = $2; }
 561         ;
 562
 563 expr_list_const: expr_const                     { $$ = append_expr( NULL, $1 ); }
 564         | expr_list_const ',' expr_const        { $$ = append_expr( $1, $3 ); }
 565         ;
 566
 567 expr_const: expr                                { $$ = $1;
 568                                                   if (!$$->is_const)
 569                                                       yyerror("expression is not constant");
 570                                                 }
 571         ;
 572
 573 externdef: tEXTERN tCONST type ident            { $$ = $4;
 574                                                   set_type($$, $3, NULL);
 575                                                 }
 576         ;
 577
 578 fields:                                         { $$ = NULL; }
 579         | fields field                          { $$ = append_var( $1, $2 ); }
 580         ;
 581
 582 field:    s_field ';'                           { $$ = $1; }
 583         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 584         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 585         | ';'                                   { $$ = NULL; }
 586         ;
 587
 588 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 589         ;
 590
 591 funcdef:
 592           m_attributes type callconv pident
 593           '(' m_args ')'                        { set_type($4, $2, NULL);
 594                                                   $4->attrs = $1;
 595                                                   $$ = make_func($4, $6);
 596                                                   if (is_attr($4->attrs, ATTR_IN)) {
 597                                                     yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
 598                                                   }
 599                                                 }
 600         ;
 601
 602 m_ident:                                        { $$ = NULL; }
 603         | ident
 604         ;
 605
 606 t_ident:                                        { $$ = NULL; }
 607         | aIDENTIFIER                           { $$ = make_var($1); }
 608         | aKNOWNTYPE                            { $$ = make_var($1); }
 609         ;
 610
 611 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 612 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 613         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 614         | tASYNC                                { $$ = make_var($<str>1); }
 615         | tID                                   { $$ = make_var($<str>1); }
 616         | tLCID                                 { $$ = make_var($<str>1); }
 617         | tOBJECT                               { $$ = make_var($<str>1); }
 618         | tRANGE                                { $$ = make_var($<str>1); }
 619         | tRETVAL                               { $$ = make_var($<str>1); }
 620         | tUUID                                 { $$ = make_var($<str>1); }
 621         | tVERSION                              { $$ = make_var($<str>1); }
 622         ;
 623
 624 base_type: tBYTE                                { $$ = make_builtin($<str>1); }
 625         | tWCHAR                                { $$ = make_builtin($<str>1); }
 626         | int_std
 627         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 628         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 629                                                   switch ($$->type) {
 630                                                   case RPC_FC_CHAR:  break;
 631                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 632                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 633                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 634                                                   case RPC_FC_HYPER:
 635                                                     if ($$->name[0] == 'h') /* hyper, as opposed to __int64 */
 636                                                     {
 637                                                       $$ = alias($$, "MIDL_uhyper");
 638                                                       $$->sign = 0;
 639                                                     }
 640                                                     break;
 641                                                   default: break;
 642                                                   }
 643                                                 }
 644         | tUNSIGNED                             { $$ = make_int(-1); }
 645         | tFLOAT                                { $$ = make_builtin($<str>1); }
 646         | tSINGLE                               { $$ = duptype(find_type("float", 0), 1); }
 647         | tDOUBLE                               { $$ = make_builtin($<str>1); }
 648         | tBOOLEAN                              { $$ = make_builtin($<str>1); }
 649         | tERRORSTATUST                         { $$ = make_builtin($<str>1); }
 650         | tHANDLET                              { $$ = make_builtin($<str>1); }
 651         ;
 652
 653 m_int:
 654         | tINT
 655         ;
 656
 657 int_std:  tINT                                  { $$ = make_builtin($<str>1); }
 658         | tSHORT m_int                          { $$ = make_builtin($<str>1); }
 659         | tSMALL                                { $$ = make_builtin($<str>1); }
 660         | tLONG m_int                           { $$ = make_builtin($<str>1); }
 661         | tHYPER m_int                          { $$ = make_builtin($<str>1); }
 662         | tINT64                                { $$ = make_builtin($<str>1); }
 663         | tCHAR                                 { $$ = make_builtin($<str>1); }
 664         ;
 665
 666 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 667         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 668                                                   if ($$->defined) yyerror("multiple definition error");
 669                                                   if ($$->kind != TKIND_COCLASS) yyerror("%s was not declared a coclass", $2);
 670                                                 }
 671         ;
 672
 673 coclasshdr: attributes coclass                  { $$ = $2;
 674                                                   $$->attrs = $1;
 675                                                   if (!parse_only && do_header)
 676                                                     write_coclass($$);
 677                                                   if (!parse_only && do_idfile)
 678                                                     write_clsid($$);
 679                                                 }
 680         ;
 681
 682 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 683                                                   $$->ifaces = $3;
 684                                                   $$->defined = TRUE;
 685                                                 }
 686         ;
 687
 688 coclass_ints:                                   { $$ = NULL; }
 689         | coclass_ints coclass_int              { $$ = append_ifref( $1, $2 ); }
 690         ;
 691
 692 coclass_int:
 693           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 694         ;
 695
 696 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 697         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 698         ;
 699
 700 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 701                                                   $$ = $2;
 702                                                   if ($$->defined) yyerror("multiple definition error");
 703                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 704                                                   $$->attrs = append_attr( $1, attrs );
 705                                                   $$->ref = find_type("IDispatch", 0);
 706                                                   if (!$$->ref) yyerror("IDispatch is undefined");
 707                                                   $$->defined = TRUE;
 708                                                   if (!parse_only && do_header) write_forward($$);
 709                                                 }
 710         ;
 711
 712 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 713         | dispint_props s_field ';'             { $$ = append_var( $1, $2 ); }
 714         ;
 715
 716 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 717         | dispint_meths funcdef ';'             { $$ = append_func( $1, $2 ); }
 718         ;
 719
 720 dispinterfacedef: dispinterfacehdr '{'
 721           dispint_props
 722           dispint_meths
 723           '}'                                   { $$ = $1;
 724                                                   $$->fields = $3;
 725                                                   $$->funcs = $4;
 726                                                   if (!parse_only && do_header) write_dispinterface($$);
 727                                                   if (!parse_only && do_idfile) write_diid($$);
 728                                                 }
 729         | dispinterfacehdr
 730          '{' interface ';' '}'                  { $$ = $1;
 731                                                   $$->fields = $3->fields;
 732                                                   $$->funcs = $3->funcs;
 733                                                   if (!parse_only && do_header) write_dispinterface($$);
 734                                                   if (!parse_only && do_idfile) write_diid($$);
 735                                                 }
 736         ;
 737
 738 inherit:                                        { $$ = NULL; }
 739         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 740         ;
 741
 742 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 743         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 744         ;
 745
 746 interfacehdr: attributes interface              { $$ = $2;
 747                                                   if ($$->defined) yyerror("multiple definition error");
 748                                                   $$->attrs = $1;
 749                                                   $$->defined = TRUE;
 750                                                   if (!parse_only && do_header) write_forward($$);
 751                                                 }
 752         ;
 753
 754 interfacedef: interfacehdr inherit
 755           '{' int_statements '}'                { $$ = $1;
 756                                                   $$->ref = $2;
 757                                                   $$->funcs = $4;
 758                                                   compute_method_indexes($$);
 759                                                   if (!parse_only && do_header) write_interface($$);
 760                                                   if (!parse_only && do_idfile) write_iid($$);
 761                                                 }
 762 /* MIDL is able to import the definition of a base class from inside the
 763  * definition of a derived class, I'll try to support it with this rule */
 764         | interfacehdr ':' aIDENTIFIER
 765           '{' import int_statements '}'         { $$ = $1;
 766                                                   $$->ref = find_type2($3, 0);
 767                                                   if (!$$->ref) yyerror("base class '%s' not found in import", $3);
 768                                                   $$->funcs = $6;
 769                                                   compute_method_indexes($$);
 770                                                   if (!parse_only && do_header) write_interface($$);
 771                                                   if (!parse_only && do_idfile) write_iid($$);
 772                                                 }
 773         | dispinterfacedef                      { $$ = $1; }
 774         ;
 775
 776 interfacedec:
 777           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 778         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 779         ;
 780
 781 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 782         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 783         ;
 784
 785 modulehdr: attributes module                    { $$ = $2;
 786                                                   $$->attrs = $1;
 787                                                 }
 788         ;
 789
 790 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 791                                                   $$->funcs = $3;
 792                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 793                                                 }
 794         ;
 795
 796 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 797         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 798         ;
 799
 800 pident:   ident
 801         | p_ident
 802         | '(' pident ')'                        { $$ = $2; }
 803         ;
 804
 805 pident_list:
 806         pident                                  { $$ = append_var( NULL, $1 ); }
 807         | pident_list ',' pident                { $$ = append_var( $1, $3 ); }
 808         ;
 809
 810 pointer_type:
 811           tREF                                  { $$ = RPC_FC_RP; }
 812         | tUNIQUE                               { $$ = RPC_FC_UP; }
 813         | tPTR                                  { $$ = RPC_FC_FP; }
 814         ;
 815
 816 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 817                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 818                                                   $$->type = get_struct_type( $4 );
 819                                                   $$->kind = TKIND_RECORD;
 820                                                   $$->fields = $4;
 821                                                   $$->defined = TRUE;
 822                                                   if(in_typelib)
 823                                                       add_typelib_entry($$);
 824                                                 }
 825         ;
 826
 827 type:     tVOID                                 { $$ = make_tref(NULL, duptype(find_type("void", 0), 1)); }
 828         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 829         | base_type                             { $$ = make_tref(NULL, $1); }
 830         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 831         | enumdef                               { $$ = make_tref(NULL, $1); }
 832         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 833         | structdef                             { $$ = make_tref(NULL, $1); }
 834         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 835         | uniondef                              { $$ = make_tref(NULL, $1); }
 836         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 837         | tSAFEARRAY '(' type ')'               { $$ = make_tref(NULL, make_safearray()); }
 838         ;
 839
 840 typedef: tTYPEDEF m_attributes type pident_list { reg_typedefs(type_ref($3), $4, $2);
 841                                                   process_typedefs($4);
 842                                                 }
 843         ;
 844
 845 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 846                                                   $$->kind = TKIND_UNION;
 847                                                   $$->fields = $4;
 848                                                   $$->defined = TRUE;
 849                                                 }
 850         | tUNION t_ident
 851           tSWITCH '(' s_field ')'
 852           m_ident '{' cases '}'                 { var_t *u = $7;
 853                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 854                                                   $$->kind = TKIND_UNION;
 855                                                   if (!u) u = make_var( xstrdup("tagged_union") );
 856                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 857                                                   u->type->kind = TKIND_UNION;
 858                                                   u->type->fields = $9;
 859                                                   u->type->defined = TRUE;
 860                                                   $$->fields = append_var( $$->fields, $5 );
 861                                                   $$->fields = append_var( $$->fields, u );
 862                                                   $$->defined = TRUE;
 863                                                 }
 864         ;
 865
 866 version:
 867           aNUM                                  { $$ = MAKELONG($1, 0); }
 868         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 869         ;
 870
 871 %%
 872
 873 static void decl_builtin(const char *name, unsigned char type)
 874 {
 875   type_t *t = make_type(type, NULL);
 876   t->name = xstrdup(name);
 877   reg_type(t, name, 0);
 878 }
 879
 880 static type_t *make_builtin(char *name)
 881 {
 882   /* NAME is strdup'd in the lexer */
 883   type_t *t = duptype(find_type(name, 0), 0);
 884   t->name = name;
 885   return t;
 886 }
 887
 888 static type_t *make_int(int sign)
 889 {
 890   type_t *t = duptype(find_type("int", 0), 1);
 891
 892   t->sign = sign;
 893   if (sign < 0)
 894     t->type = t->type == RPC_FC_LONG ? RPC_FC_ULONG : RPC_FC_USHORT;
 895
 896   return t;
 897 }
 898
 899 void init_types(void)
 900 {
 901   decl_builtin("void", 0);
 902   decl_builtin("byte", RPC_FC_BYTE);
 903   decl_builtin("wchar_t", RPC_FC_WCHAR);
 904   decl_builtin("int", RPC_FC_LONG);     /* win32 */
 905   decl_builtin("short", RPC_FC_SHORT);
 906   decl_builtin("small", RPC_FC_SMALL);
 907   decl_builtin("long", RPC_FC_LONG);
 908   decl_builtin("hyper", RPC_FC_HYPER);
 909   decl_builtin("__int64", RPC_FC_HYPER);
 910   decl_builtin("char", RPC_FC_CHAR);
 911   decl_builtin("float", RPC_FC_FLOAT);
 912   decl_builtin("double", RPC_FC_DOUBLE);
 913   decl_builtin("boolean", RPC_FC_BYTE);
 914   decl_builtin("error_status_t", RPC_FC_ERROR_STATUS_T);
 915   decl_builtin("handle_t", RPC_FC_BIND_PRIMITIVE);
 916 }
 917
 918 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr)
 919 {
 920     if (!attr) return list;
 921     if (!list)
 922     {
 923         list = xmalloc( sizeof(*list) );
 924         list_init( list );
 925     }
 926     list_add_tail( list, &attr->entry );
 927     return list;
 928 }
 929
 930 static attr_t *make_attr(enum attr_type type)
 931 {
 932   attr_t *a = xmalloc(sizeof(attr_t));
 933   a->type = type;
 934   a->u.ival = 0;
 935   return a;
 936 }
 937
 938 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 939 {
 940   attr_t *a = xmalloc(sizeof(attr_t));
 941   a->type = type;
 942   a->u.ival = val;
 943   return a;
 944 }
 945
 946 static attr_t *make_attrp(enum attr_type type, void *val)
 947 {
 948   attr_t *a = xmalloc(sizeof(attr_t));
 949   a->type = type;
 950   a->u.pval = val;
 951   return a;
 952 }
 953
 954 static expr_t *make_expr(enum expr_type type)
 955 {
 956   expr_t *e = xmalloc(sizeof(expr_t));
 957   e->type = type;
 958   e->ref = NULL;
 959   e->u.lval = 0;
 960   e->is_const = FALSE;
 961   return e;
 962 }
 963
 964 static expr_t *make_exprl(enum expr_type type, long val)
 965 {
 966   expr_t *e = xmalloc(sizeof(expr_t));
 967   e->type = type;
 968   e->ref = NULL;
 969   e->u.lval = val;
 970   e->is_const = FALSE;
 971   /* check for numeric constant */
 972   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
 973     /* make sure true/false value is valid */
 974     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
 975     e->is_const = TRUE;
 976     e->cval = val;
 977   }
 978   return e;
 979 }
 980
 981 static expr_t *make_exprs(enum expr_type type, char *val)
 982 {
 983   expr_t *e;
 984   e = xmalloc(sizeof(expr_t));
 985   e->type = type;
 986   e->ref = NULL;
 987   e->u.sval = val;
 988   e->is_const = FALSE;
 989   /* check for predefined constants */
 990   if (type == EXPR_IDENTIFIER) {
 991     var_t *c = find_const(val, 0);
 992     if (c) {
 993       e->u.sval = c->name;
 994       free(val);
 995       e->is_const = TRUE;
 996       e->cval = c->eval->cval;
 997     }
 998   }
 999   return e;
1000 }
1001
1002 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
1003 {
1004   expr_t *e;
1005   e = xmalloc(sizeof(expr_t));
1006   e->type = type;
1007   e->ref = expr;
1008   e->u.tref = tref;
1009   e->is_const = FALSE;
1010   /* check for cast of constant expression */
1011   if (type == EXPR_SIZEOF) {
1012     switch (tref->ref->type) {
1013       case RPC_FC_BYTE:
1014       case RPC_FC_CHAR:
1015       case RPC_FC_SMALL:
1016       case RPC_FC_USMALL:
1017         e->is_const = TRUE;
1018         e->cval = 1;
1019         break;
1020       case RPC_FC_WCHAR:
1021       case RPC_FC_USHORT:
1022       case RPC_FC_SHORT:
1023         e->is_const = TRUE;
1024         e->cval = 2;
1025         break;
1026       case RPC_FC_LONG:
1027       case RPC_FC_ULONG:
1028       case RPC_FC_FLOAT:
1029       case RPC_FC_ERROR_STATUS_T:
1030         e->is_const = TRUE;
1031         e->cval = 4;
1032         break;
1033       case RPC_FC_HYPER:
1034       case RPC_FC_DOUBLE:
1035         e->is_const = TRUE;
1036         e->cval = 8;
1037         break;
1038     }
1039   }
1040   if (type == EXPR_CAST && expr->is_const) {
1041     e->is_const = TRUE;
1042     e->cval = expr->cval;
1043   }
1044   return e;
1045 }
1046
1047 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
1048 {
1049   expr_t *e;
1050   e = xmalloc(sizeof(expr_t));
1051   e->type = type;
1052   e->ref = expr;
1053   e->u.lval = 0;
1054   e->is_const = FALSE;
1055   /* check for compile-time optimization */
1056   if (expr->is_const) {
1057     e->is_const = TRUE;
1058     switch (type) {
1059     case EXPR_NEG:
1060       e->cval = -expr->cval;
1061       break;
1062     case EXPR_NOT:
1063       e->cval = ~expr->cval;
1064       break;
1065     default:
1066       e->is_const = FALSE;
1067       break;
1068     }
1069   }
1070   return e;
1071 }
1072
1073 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1074 {
1075   expr_t *e;
1076   e = xmalloc(sizeof(expr_t));
1077   e->type = type;
1078   e->ref = expr1;
1079   e->u.ext = expr2;
1080   e->is_const = FALSE;
1081   /* check for compile-time optimization */
1082   if (expr1->is_const && expr2->is_const) {
1083     e->is_const = TRUE;
1084     switch (type) {
1085     case EXPR_ADD:
1086       e->cval = expr1->cval + expr2->cval;
1087       break;
1088     case EXPR_SUB:
1089       e->cval = expr1->cval - expr2->cval;
1090       break;
1091     case EXPR_MUL:
1092       e->cval = expr1->cval * expr2->cval;
1093       break;
1094     case EXPR_DIV:
1095       e->cval = expr1->cval / expr2->cval;
1096       break;
1097     case EXPR_OR:
1098       e->cval = expr1->cval | expr2->cval;
1099       break;
1100     case EXPR_AND:
1101       e->cval = expr1->cval & expr2->cval;
1102       break;
1103     case EXPR_SHL:
1104       e->cval = expr1->cval << expr2->cval;
1105       break;
1106     case EXPR_SHR:
1107       e->cval = expr1->cval >> expr2->cval;
1108       break;
1109     default:
1110       e->is_const = FALSE;
1111       break;
1112     }
1113   }
1114   return e;
1115 }
1116
1117 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1118 {
1119   expr_t *e;
1120   e = xmalloc(sizeof(expr_t));
1121   e->type = type;
1122   e->ref = expr1;
1123   e->u.ext = expr2;
1124   e->ext2 = expr3;
1125   e->is_const = FALSE;
1126   /* check for compile-time optimization */
1127   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1128     e->is_const = TRUE;
1129     switch (type) {
1130     case EXPR_COND:
1131       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1132       break;
1133     default:
1134       e->is_const = FALSE;
1135       break;
1136     }
1137   }
1138   return e;
1139 }
1140
1141 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr)
1142 {
1143     if (!expr) return list;
1144     if (!list)
1145     {
1146         list = xmalloc( sizeof(*list) );
1147         list_init( list );
1148     }
1149     list_add_tail( list, &expr->entry );
1150     return list;
1151 }
1152
1153 static array_dims_t *append_array(array_dims_t *list, expr_t *expr)
1154 {
1155     if (!expr) return list;
1156     if (!list)
1157     {
1158         list = xmalloc( sizeof(*list) );
1159         list_init( list );
1160     }
1161     list_add_tail( list, &expr->entry );
1162     return list;
1163 }
1164
1165 static type_t *make_type(unsigned char type, type_t *ref)
1166 {
1167   type_t *t = xmalloc(sizeof(type_t));
1168   t->name = NULL;
1169   t->kind = TKIND_PRIMITIVE;
1170   t->type = type;
1171   t->ref = ref;
1172   t->attrs = NULL;
1173   t->orig = NULL;
1174   t->funcs = NULL;
1175   t->fields = NULL;
1176   t->ifaces = NULL;
1177   t->ignore = parse_only;
1178   t->is_const = FALSE;
1179   t->sign = 0;
1180   t->defined = FALSE;
1181   t->written = FALSE;
1182   t->user_types_registered = FALSE;
1183   t->typelib_idx = -1;
1184   return t;
1185 }
1186
1187 static typeref_t *make_tref(char *name, type_t *ref)
1188 {
1189   typeref_t *t = xmalloc(sizeof(typeref_t));
1190   t->name = name;
1191   t->ref = ref;
1192   t->uniq = ref ? 0 : 1;
1193   return t;
1194 }
1195
1196 static typeref_t *uniq_tref(typeref_t *ref)
1197 {
1198   typeref_t *t = ref;
1199   type_t *tp;
1200   if (t->uniq) return t;
1201
1202   if (t->name)
1203   {
1204     tp = duptype(t->ref, 0);
1205     tp->name = t->name;
1206   }
1207   else
1208     tp = duptype(t->ref, 1);
1209
1210   t->name = NULL;
1211   t->ref = tp;
1212   t->uniq = 1;
1213   return t;
1214 }
1215
1216 static type_t *type_ref(typeref_t *ref)
1217 {
1218   type_t *t = ref->ref;
1219   free(ref->name);
1220   free(ref);
1221   return t;
1222 }
1223
1224 static void set_type(var_t *v, typeref_t *ref, array_dims_t *arr)
1225 {
1226   v->type = ref->ref;
1227   v->tname = ref->name;
1228   ref->name = NULL;
1229   free(ref);
1230   v->array = arr;
1231 }
1232
1233 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface)
1234 {
1235     if (!iface) return list;
1236     if (!list)
1237     {
1238         list = xmalloc( sizeof(*list) );
1239         list_init( list );
1240     }
1241     list_add_tail( list, &iface->entry );
1242     return list;
1243 }
1244
1245 static ifref_t *make_ifref(type_t *iface)
1246 {
1247   ifref_t *l = xmalloc(sizeof(ifref_t));
1248   l->iface = iface;
1249   l->attrs = NULL;
1250   return l;
1251 }
1252
1253 static var_list_t *append_var(var_list_t *list, var_t *var)
1254 {
1255     if (!var) return list;
1256     if (!list)
1257     {
1258         list = xmalloc( sizeof(*list) );
1259         list_init( list );
1260     }
1261     list_add_tail( list, &var->entry );
1262     return list;
1263 }
1264
1265 static var_t *make_var(char *name)
1266 {
1267   var_t *v = xmalloc(sizeof(var_t));
1268   v->name = name;
1269   v->ptr_level = 0;
1270   v->type = NULL;
1271   v->args = NULL;
1272   v->tname = NULL;
1273   v->attrs = NULL;
1274   v->array = NULL;
1275   v->eval = NULL;
1276   return v;
1277 }
1278
1279 static func_list_t *append_func(func_list_t *list, func_t *func)
1280 {
1281     if (!func) return list;
1282     if (!list)
1283     {
1284         list = xmalloc( sizeof(*list) );
1285         list_init( list );
1286     }
1287     list_add_tail( list, &func->entry );
1288     return list;
1289 }
1290
1291 static func_t *make_func(var_t *def, var_list_t *args)
1292 {
1293   func_t *f = xmalloc(sizeof(func_t));
1294   f->def = def;
1295   f->args = args;
1296   f->ignore = parse_only;
1297   f->idx = -1;
1298   return f;
1299 }
1300
1301 static type_t *make_class(char *name)
1302 {
1303   type_t *c = make_type(0, NULL);
1304   c->name = name;
1305   c->kind = TKIND_COCLASS;
1306   return c;
1307 }
1308
1309 static type_t *make_safearray(void)
1310 {
1311   return make_type(RPC_FC_FP, find_type("SAFEARRAY", 0));
1312 }
1313
1314 #define HASHMAX 64
1315
1316 static int hash_ident(const char *name)
1317 {
1318   const char *p = name;
1319   int sum = 0;
1320   /* a simple sum hash is probably good enough */
1321   while (*p) {
1322     sum += *p;
1323     p++;
1324   }
1325   return sum & (HASHMAX-1);
1326 }
1327
1328 /***** type repository *****/
1329
1330 struct rtype {
1331   const char *name;
1332   type_t *type;
1333   int t;
1334   struct rtype *next;
1335 };
1336
1337 struct rtype *type_hash[HASHMAX];
1338
1339 static type_t *reg_type(type_t *type, const char *name, int t)
1340 {
1341   struct rtype *nt;
1342   int hash;
1343   if (!name) {
1344     yyerror("registering named type without name");
1345     return type;
1346   }
1347   hash = hash_ident(name);
1348   nt = xmalloc(sizeof(struct rtype));
1349   nt->name = name;
1350   nt->type = type;
1351   nt->t = t;
1352   nt->next = type_hash[hash];
1353   type_hash[hash] = nt;
1354   return type;
1355 }
1356
1357 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs)
1358 {
1359   type_t *ptr = type;
1360   const var_t *name;
1361   int ptrc = 0;
1362   int is_str = is_attr(attrs, ATTR_STRING);
1363   unsigned char ptr_type = get_attrv(attrs, ATTR_POINTERTYPE);
1364
1365   if (is_str)
1366   {
1367     type_t *t = type;
1368     unsigned char c;
1369
1370     while (is_ptr(t))
1371       t = t->ref;
1372
1373     c = t->type;
1374     if (c != RPC_FC_CHAR && c != RPC_FC_BYTE && c != RPC_FC_WCHAR)
1375     {
1376       name = LIST_ENTRY( list_head( names ), const var_t, entry );
1377       yyerror("'%s': [string] attribute is only valid on 'char', 'byte', or 'wchar_t' pointers and arrays",
1378               name->name);
1379     }
1380   }
1381
1382   /* We must generate names for tagless enum, struct or union.
1383      Typedef-ing a tagless enum, struct or union means we want the typedef
1384      to be included in a library whether it has other attributes or not,
1385      hence the public attribute.  */
1386   if ((type->kind == TKIND_ENUM || type->kind == TKIND_RECORD
1387        || type->kind == TKIND_UNION) && ! type->name && ! parse_only)
1388   {
1389     if (! is_attr(attrs, ATTR_PUBLIC))
1390       attrs = append_attr( attrs, make_attr(ATTR_PUBLIC) );
1391     type->name = gen_name();
1392   }
1393
1394   LIST_FOR_EACH_ENTRY( name, names, const var_t, entry )
1395   {
1396     if (name->name) {
1397       type_t *cur = ptr;
1398       int cptr = name->ptr_level;
1399       if (cptr > ptrc) {
1400         while (cptr > ptrc) {
1401           cur = ptr = make_type(RPC_FC_RP, cur);
1402           ptrc++;
1403         }
1404       } else {
1405         while (cptr < ptrc) {
1406           cur = cur->ref;
1407           cptr++;
1408         }
1409       }
1410       cur = alias(cur, name->name);
1411       cur->attrs = attrs;
1412       if (ptr_type)
1413       {
1414         if (is_ptr(cur))
1415           cur->type = ptr_type;
1416         else
1417           yyerror("'%s': pointer attribute applied to non-pointer type",
1418                   cur->name);
1419       }
1420       else if (is_str && ! is_ptr(cur))
1421         yyerror("'%s': [string] attribute applied to non-pointer type",
1422                 cur->name);
1423
1424       reg_type(cur, cur->name, 0);
1425     }
1426   }
1427   return type;
1428 }
1429
1430 static type_t *find_type(const char *name, int t)
1431 {
1432   struct rtype *cur = type_hash[hash_ident(name)];
1433   while (cur && (cur->t != t || strcmp(cur->name, name)))
1434     cur = cur->next;
1435   if (!cur) {
1436     yyerror("type '%s' not found", name);
1437     return NULL;
1438   }
1439   return cur->type;
1440 }
1441
1442 static type_t *find_type2(char *name, int t)
1443 {
1444   type_t *tp = find_type(name, t);
1445   free(name);
1446   return tp;
1447 }
1448
1449 int is_type(const char *name)
1450 {
1451   struct rtype *cur = type_hash[hash_ident(name)];
1452   while (cur && (cur->t || strcmp(cur->name, name)))
1453     cur = cur->next;
1454   if (cur) return TRUE;
1455   return FALSE;
1456 }
1457
1458 static type_t *get_type(unsigned char type, char *name, int t)
1459 {
1460   struct rtype *cur = NULL;
1461   type_t *tp;
1462   if (name) {
1463     cur = type_hash[hash_ident(name)];
1464     while (cur && (cur->t != t || strcmp(cur->name, name)))
1465       cur = cur->next;
1466   }
1467   if (cur) {
1468     free(name);
1469     return cur->type;
1470   }
1471   tp = make_type(type, NULL);
1472   tp->name = name;
1473   if (!name) return tp;
1474   return reg_type(tp, name, t);
1475 }
1476
1477 static type_t *get_typev(unsigned char type, var_t *name, int t)
1478 {
1479   char *sname = NULL;
1480   if (name) {
1481     sname = name->name;
1482     free(name);
1483   }
1484   return get_type(type, sname, t);
1485 }
1486
1487 static int get_struct_type(var_list_t *fields)
1488 {
1489   int has_pointer = 0;
1490   int has_conformance = 0;
1491   int has_variance = 0;
1492   var_t *field;
1493
1494   if (fields) LIST_FOR_EACH_ENTRY( field, fields, var_t, entry )
1495   {
1496     type_t *t = field->type;
1497
1498     if (field->ptr_level > 0)
1499     {
1500         has_pointer = 1;
1501         continue;
1502     }
1503
1504     if (is_string_type(field->attrs, 0, field->array))
1505     {
1506         has_conformance = 1;
1507         has_variance = 1;
1508         continue;
1509     }
1510
1511     if (is_array_type(field->attrs, 0, field->array))
1512     {
1513         if (field->array && is_conformant_array(field->array))
1514         {
1515             has_conformance = 1;
1516             if (list_next( fields, &field->entry ))
1517                 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1518                         field->name);
1519         }
1520         if (is_attr(field->attrs, ATTR_LENGTHIS))
1521             has_variance = 1;
1522     }
1523
1524     switch (t->type)
1525     {
1526     /*
1527      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1528      *  Simple types don't effect the type of struct.
1529      *  A struct containing a simple struct is still a simple struct.
1530      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1531      */
1532     case 0: /* void pointer */
1533     case RPC_FC_BYTE:
1534     case RPC_FC_CHAR:
1535     case RPC_FC_SMALL:
1536     case RPC_FC_USMALL:
1537     case RPC_FC_WCHAR:
1538     case RPC_FC_SHORT:
1539     case RPC_FC_USHORT:
1540     case RPC_FC_LONG:
1541     case RPC_FC_ULONG:
1542     case RPC_FC_INT3264:
1543     case RPC_FC_UINT3264:
1544     case RPC_FC_HYPER:
1545     case RPC_FC_FLOAT:
1546     case RPC_FC_DOUBLE:
1547     case RPC_FC_STRUCT:
1548     case RPC_FC_ENUM16:
1549     case RPC_FC_ENUM32:
1550       break;
1551
1552     case RPC_FC_RP:
1553     case RPC_FC_UP:
1554     case RPC_FC_FP:
1555     case RPC_FC_OP:
1556       has_pointer = 1;
1557       break;
1558     case RPC_FC_CARRAY:
1559       has_conformance = 1;
1560       if (list_next( fields, &field->entry ))
1561           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1562                   field->name);
1563       break;
1564
1565     /*
1566      * Propagate member attributes
1567      *  a struct should be at least as complex as its member
1568      */
1569     case RPC_FC_CVSTRUCT:
1570       has_conformance = 1;
1571       has_variance = 1;
1572       has_pointer = 1;
1573       break;
1574
1575     case RPC_FC_CPSTRUCT:
1576       has_conformance = 1;
1577       if (list_next( fields, &field->entry ))
1578           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1579                   field->name);
1580       has_pointer = 1;
1581       break;
1582
1583     case RPC_FC_CSTRUCT:
1584       has_conformance = 1;
1585       if (list_next( fields, &field->entry ))
1586           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1587                   field->name);
1588       break;
1589
1590     case RPC_FC_PSTRUCT:
1591       has_pointer = 1;
1592       break;
1593
1594     default:
1595       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1596               field->name, t->type);
1597       /* fallthru - treat it as complex */
1598
1599     /* as soon as we see one of these these members, it's bogus... */
1600     case RPC_FC_IP:
1601     case RPC_FC_ENCAPSULATED_UNION:
1602     case RPC_FC_NON_ENCAPSULATED_UNION:
1603     case RPC_FC_TRANSMIT_AS:
1604     case RPC_FC_REPRESENT_AS:
1605     case RPC_FC_PAD:
1606     case RPC_FC_EMBEDDED_COMPLEX:
1607     case RPC_FC_BOGUS_STRUCT:
1608       return RPC_FC_BOGUS_STRUCT;
1609     }
1610   }
1611
1612   if( has_variance )
1613     return RPC_FC_CVSTRUCT;
1614   if( has_conformance && has_pointer )
1615     return RPC_FC_CPSTRUCT;
1616   if( has_conformance )
1617     return RPC_FC_CSTRUCT;
1618   if( has_pointer )
1619     return RPC_FC_PSTRUCT;
1620   return RPC_FC_STRUCT;
1621 }
1622
1623 /***** constant repository *****/
1624
1625 struct rconst {
1626   char *name;
1627   var_t *var;
1628   struct rconst *next;
1629 };
1630
1631 struct rconst *const_hash[HASHMAX];
1632
1633 static var_t *reg_const(var_t *var)
1634 {
1635   struct rconst *nc;
1636   int hash;
1637   if (!var->name) {
1638     yyerror("registering constant without name");
1639     return var;
1640   }
1641   hash = hash_ident(var->name);
1642   nc = xmalloc(sizeof(struct rconst));
1643   nc->name = var->name;
1644   nc->var = var;
1645   nc->next = const_hash[hash];
1646   const_hash[hash] = nc;
1647   return var;
1648 }
1649
1650 static var_t *find_const(char *name, int f)
1651 {
1652   struct rconst *cur = const_hash[hash_ident(name)];
1653   while (cur && strcmp(cur->name, name))
1654     cur = cur->next;
1655   if (!cur) {
1656     if (f) yyerror("constant '%s' not found", name);
1657     return NULL;
1658   }
1659   return cur->var;
1660 }
1661
1662 static void write_libid(const char *name, const attr_list_t *attr)
1663 {
1664   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1665   write_guid(idfile, "LIBID", name, uuid);
1666 }
1667
1668 static void write_clsid(type_t *cls)
1669 {
1670   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1671   write_guid(idfile, "CLSID", cls->name, uuid);
1672 }
1673
1674 static void write_diid(type_t *iface)
1675 {
1676   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1677   write_guid(idfile, "DIID", iface->name, uuid);
1678 }
1679
1680 static void write_iid(type_t *iface)
1681 {
1682   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1683   write_guid(idfile, "IID", iface->name, uuid);
1684 }
1685
1686 static int compute_method_indexes(type_t *iface)
1687 {
1688   int idx;
1689   func_t *f;
1690
1691   if (iface->ref)
1692     idx = compute_method_indexes(iface->ref);
1693   else
1694     idx = 0;
1695
1696   if (!iface->funcs)
1697     return idx;
1698
1699   LIST_FOR_EACH_ENTRY( f, iface->funcs, func_t, entry )
1700     if (! is_callas(f->def->attrs))
1701       f->idx = idx++;
1702
1703   return idx;
1704 }
1705
1706 static char *gen_name(void)
1707 {
1708   static const char format[] = "__WIDL_%s_generated_name_%08lX";
1709   static unsigned long n = 0;
1710   static const char *file_id;
1711   static size_t size;
1712   char *name;
1713
1714   if (! file_id)
1715   {
1716     char *dst = dup_basename(input_name, ".idl");
1717     file_id = dst;
1718
1719     for (; *dst; ++dst)
1720       if (! isalnum((unsigned char) *dst))
1721         *dst = '_';
1722
1723     size = sizeof format - 7 + strlen(file_id) + 8;
1724   }
1725
1726   name = xmalloc(size);
1727   sprintf(name, format, file_id, n++);
1728   return name;
1729 }
1730
1731 static void process_typedefs(var_list_t *names)
1732 {
1733   var_t *name, *next;
1734
1735   if (!names) return;
1736   LIST_FOR_EACH_ENTRY_SAFE( name, next, names, var_t, entry )
1737   {
1738     type_t *type = find_type(name->name, 0);
1739
1740     if (! parse_only && do_header)
1741       write_typedef(type);
1742     if (in_typelib && type->attrs)
1743       add_typelib_entry(type);
1744
1745     free(name);
1746   }
1747 }
1748
1749 static void check_arg(var_t *arg)
1750 {
1751   type_t *t = arg->type;
1752
1753   if (t->type == 0 && ! is_var_ptr(arg))
1754     yyerror("argument '%s' has void type", arg->name);
1755 }