git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION)
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(OPTIONS)
  24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  26 if test "x$enable_win16" = "xno"
  27 then
  28   WIN16_FILES=""
  29   WIN16_INSTALL=""
  30 fi
  31 if test "x$enable_debug" = "xno"
  32 then
  33     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  34 fi
  35 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  36 then
  37     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  38 fi
  39
  40 dnl **** Check for some programs ****
  41
  42 AC_CANONICAL_HOST
  43 AC_PROG_MAKE_SET
  44 AC_PROG_CC
  45 AC_PROG_CPP
  46
  47 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  48   [if test -z "$with_wine_tools"; then
  49      if test "$cross_compiling" = "yes"; then
  50        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  51      else
  52        wine_cv_toolsdir="\$(TOPOBJDIR)"
  53      fi
  54    elif test -d "$with_wine_tools/tools/winebuild"; then
  55      case $with_wine_tools in
  56        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  57        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  58      esac
  59    else
  60      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  61    fi])
  62 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  63
  64 AC_PATH_XTRA
  65 AC_PROG_YACC
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
  71 if test "$XYACC" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
  74 fi
  75 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  76 if test "$XLEX" = "none"
  77 then
  78   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  79 fi
  80
  81 AC_CHECK_TOOL(AS,as,as)
  82 AC_CHECK_TOOL(LD,ld,ld)
  83 AC_CHECK_TOOL(AR,ar,ar)
  84 AC_PROG_RANLIB
  85 AC_CHECK_TOOL(STRIP,strip,strip)
  86 AC_CHECK_TOOL(WINDRES,windres,false)
  87 AC_PROG_LN_S
  88 WINE_PROG_LN
  89 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  90 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  91 AC_PROG_INSTALL
  92 dnl Prepend src dir to install path dir if it's a relative path
  93 case "$INSTALL" in
  94   [[\\/$]]* | ?:[[\\/]]* ) ;;
  95   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  96 esac
  97
  98 dnl Check for lint
  99 AC_CHECK_PROGS(LINT, lclint lint)
 100 if test "$LINT" = "lint"
 101 then
 102   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 103   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 104 fi
 105 AC_SUBST(LINT)
 106 AC_SUBST(LINTFLAGS)
 107
 108 dnl Check for db2html
 109 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 110 AC_SUBST(DB2HTML)
 111
 112 dnl Check for db2pdf
 113 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 114 AC_SUBST(DB2PDF)
 115
 116 dnl Check for db2ps
 117 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 118 AC_SUBST(DB2PS)
 119
 120 dnl **** Check for some libraries ****
 121
 122 dnl Check for -lm
 123 AC_CHECK_LIB(m,sqrt)
 124 dnl Check for -li386 for NetBSD and OpenBSD
 125 AC_CHECK_LIB(i386,i386_set_ldt)
 126 dnl Check for -lossaudio for NetBSD
 127 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 128 dnl Check for -lw for Solaris
 129 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 130 dnl Check for -lnsl for Solaris
 131 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 132 dnl Check for -lsocket for Solaris
 133 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 134 dnl Check for -lresolv for Solaris
 135 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 136 dnl Check for -lxpg4 for FreeBSD
 137 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 138 dnl Check for -lmmap for OS/2
 139 AC_CHECK_LIB(mmap,mmap)
 140
 141 JPEGLIB=""
 142 AC_SUBST(JPEGLIB)
 143 AC_CHECK_HEADERS(jpeglib.h,
 144     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 145         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 146         JPEGLIB="-ljpeg"
 147     )
 148 )
 149
 150 AC_SUBST(GIFLIB,"")
 151 AC_CHECK_HEADERS(gif_lib.h,
 152     AC_CHECK_LIB(ungif,DGifOpen,
 153         [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
 154          GIFLIB="-lungif"],
 155         [AC_CHECK_LIB(gif,DGifOpen,
 156                       [AC_DEFINE(HAVE_LIBGIF,1)
 157                        GIFLIB="-lgif"])]))
 158
 159
 160 AC_SUBST(XLIB)
 161 AC_SUBST(XFILES)
 162 XFILES=""
 163 AC_SUBST(OPENGLFILES)
 164 OPENGLFILES=""
 165 AC_SUBST(GLU32FILES)
 166 GLU32FILES=""
 167 AC_SUBST(OPENGL_LIBS)
 168 OPENGL_LIBS=""
 169 if test "$have_x" = "yes"
 170 then
 171     XLIB="-lXext -lX11"
 172     ac_save_CPPFLAGS="$CPPFLAGS"
 173     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 174
 175     dnl *** All of the following tests require X11/Xlib.h
 176     AC_CHECK_HEADERS(X11/Xlib.h,
 177       [
 178         dnl *** Check for X keyboard extension
 179         AC_CHECK_HEADERS(X11/XKBlib.h,
 180             [ dnl *** If X11/XKBlib.h exists...
 181               AC_CHECK_LIB(X11, XkbQueryExtension,
 182               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 183               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 184             ],
 185             AC_MSG_WARN([[Xkb extension not found, Wine will be built without it]]),
 186             [#include <X11/Xlib.h>])
 187
 188         dnl *** Check for X Shm extension
 189         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 190             [ dnl *** If X11/extensions/XShm.h exists...
 191               AC_CHECK_LIB(Xext, XShmQueryExtension,
 192               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 193               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 194             ],
 195             AC_MSG_WARN([[XShm extension not found, Wine will be built without it]]),
 196             [#include <X11/Xlib.h>])
 197
 198         dnl *** Check for Xutil
 199         AC_CHECK_HEADERS(X11/Xutil.h,,,
 200             [#include <X11/Xlib.h>])
 201
 202         dnl *** Check for X shape extension
 203         AC_CHECK_HEADERS(X11/extensions/shape.h,
 204             [ dnl *** If X11/extensions/shape.h exists...
 205               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 206               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 207               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 208             ],
 209             AC_MSG_WARN([[XShape extension not found, Wine will be built without it]]),
 210             [#include <X11/Xlib.h>
 211              #ifdef HAVE_X11_XUTIL_H
 212              # include <X11/Xutil.h>
 213              #endif])
 214
 215         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 216         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 217             [ dnl *** If X11/extensions/xf86dga.h exists, check
 218               dnl *** for XDGAQueryExtension()...
 219               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 220                 [ dnl *** If found...
 221                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 222                             [Define if you have the Xxf86dga library version 2])
 223                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 224                ],
 225                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 226                   dnl *** instead (DGA 2.0 not found)...
 227                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 228                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 229                                 [Define if you have the Xxf86dga library version 1])
 230                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 231                     ],,
 232                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 233                   )
 234                 ],
 235                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 236               )
 237             ],
 238             AC_MSG_WARN([[DGA extension not found, Wine will be built without it]]),
 239             [#include <X11/Xlib.h>])
 240
 241         dnl *** Check for XFree86 VMODE extension
 242         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 243             [ dnl *** If X11/extensions/xf86vmode.h exists...
 244                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 245                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 246                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 247                   ],,
 248                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 249                 )
 250             ],
 251             AC_MSG_WARN([[XFree86 VMODE extension not found, Wine will be built without it]]),
 252             [#include <X11/Xlib.h>])
 253
 254         dnl *** Check for XVideo extension supporting XvImages
 255         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 256             [ dnl *** If X11/extensions/Xvlib.h exists...
 257                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 258                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 259                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 260                   ],,
 261                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 262                 )
 263             ],
 264             AC_MSG_WARN([[XVideo extension not found, Wine will be built without it]]),
 265             [#include <X11/Xlib.h>])
 266
 267         dnl *** Check for XRender include file
 268         AC_CHECK_HEADERS(X11/extensions/Xrender.h,,,[#include <X11/Xlib.h>])
 269       ]
 270     ) dnl *** End of X11/Xlib.h check
 271
 272     dnl Check for the presence of OpenGL
 273     if test "x$with_opengl" != "xno"
 274     then
 275         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 276         then
 277             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 278 This prevents linking to OpenGL. Delete the file and restart configure.])
 279         fi
 280
 281         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 282         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 283         then
 284             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 285             dnl Check for some problems due to old Mesa versions
 286             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 287               AC_TRY_COMPILE(
 288                 [#include <GL/gl.h>],
 289                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 290                 [wine_cv_opengl_version_OK="yes"],
 291                 [wine_cv_opengl_version_OK="no"]
 292               )
 293             )
 294
 295             if test "$wine_cv_opengl_version_OK" = "yes"
 296             then
 297                 dnl Check for the presence of the library
 298                 AC_CHECK_LIB(GL,glXCreateContext,
 299                              OPENGL_LIBS="-lGL"
 300                              ,,
 301                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 302
 303                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 304                 then
 305                         OPENGLFILES='$(OPENGLFILES)'
 306                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 307
 308                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 309                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 310                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 311                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 312
 313                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 314                         then
 315                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 316                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 317                                                   #ifdef HAVE_GL_GLEXT_H
 318                                                   # include <GL/glext.h>
 319                                                   #endif
 320                                                   ],
 321                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 322                                                  [wine_cv_extension_prototypes="yes"],
 323                                                  [wine_cv_extension_prototypes="no"]
 324                                   )]
 325                                 )
 326                                 if test "$wine_cv_extension_prototypes" = "yes"
 327                                 then
 328                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 329                                               [Define if the OpenGL headers define extension typedefs])
 330                                 fi
 331                         fi
 332
 333                 fi
 334                 dnl Check for GLU32 library.
 335                 AC_CHECK_LIB(GLU,gluLookAt,
 336                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 337                              GLU32FILES='$(GLU32FILES)']
 338                              ,,
 339                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 340                 )
 341              fi
 342          fi
 343     fi
 344
 345     dnl **** Check for NAS ****
 346     AC_SUBST(NASLIBS,"")
 347     AC_CHECK_HEADERS(audio/audiolib.h,
 348          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 349           AC_CHECK_LIB(audio,AuCreateFlow,
 350                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 351                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 352                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 353
 354     CPPFLAGS="$ac_save_CPPFLAGS"
 355     XFILES='$(XFILES)'
 356 else
 357     XLIB=""
 358     X_CFLAGS=""
 359     X_LIBS=""
 360 fi
 361
 362 dnl **** Check which curses lib to use ***
 363 CURSESLIBS=""
 364 if test "x$with_curses" != "xno"
 365 then
 366     AC_CHECK_HEADERS(ncurses.h,
 367         [AC_CHECK_LIB(ncurses,waddch,
 368             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 369              CURSESLIBS="-lncurses"],
 370              [AC_CHECK_HEADERS(curses.h,
 371                  [AC_CHECK_LIB(curses,waddch,
 372                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 373                       CURSESLIBS="-lcurses"])])])])
 374     saved_libs="$LIBS"
 375     LIBS="$CURSESLIBS $LIBS"
 376     AC_CHECK_FUNCS(getbkgd resizeterm)
 377     LIBS="$saved_libs"
 378 fi
 379 AC_SUBST(CURSESLIBS)
 380
 381 dnl **** Check for SANE ****
 382 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 383 if test "$sane_devel" = "no"
 384 then
 385     SANELIBS=""
 386     SANEINCL=""
 387 else
 388     SANELIBS="`$sane_devel --libs`"
 389     SANEINCL="`$sane_devel --cflags`"
 390     ac_save_CPPFLAGS="$CPPFLAGS"
 391     ac_save_LIBS="$LIBS"
 392     CPPFLAGS="$CPPFLAGS $SANEINCL"
 393     LIBS="$LIBS $SANELIBS"
 394     AC_CHECK_HEADER(sane/sane.h,
 395                     [AC_CHECK_LIB(sane,sane_open,
 396                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 397                                   [SANELIBS=""
 398                                   SANEINCL=""])],
 399                     [SANELIBS=""
 400                     SANEINCL=""])
 401     LIBS="$ac_save_LIBS"
 402     CPPFLAGS="$ac_save_CPPFLAGS"
 403 fi
 404 AC_SUBST(SANELIBS)
 405 AC_SUBST(SANEINCL)
 406
 407 dnl **** Check for FreeType 2 ****
 408 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 409 if test "$ft_lib" = "no"
 410 then
 411     FREETYPEINCL=""
 412     wine_cv_msg_freetype=no
 413 else
 414     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 415     if test "$ft_devel" = "no"
 416     then
 417         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 418         if test "$ft_devel2" = "freetype2-config"
 419         then
 420                 ft_devel=$ft_devel2
 421         fi
 422     fi
 423     if test "$ft_devel" = "no"
 424     then
 425         FREETYPEINCL=""
 426         wine_cv_msg_freetype=yes
 427     else
 428         FREETYPEINCL=`$ft_devel --cflags`
 429         ac_save_CPPFLAGS="$CPPFLAGS"
 430         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 431         AC_CHECK_HEADERS(freetype/freetype.h \
 432                          freetype/ftglyph.h \
 433                          freetype/tttables.h \
 434                          freetype/ftnames.h \
 435                          freetype/ftsnames.h \
 436                          freetype/ttnameid.h \
 437                          freetype/ftoutln.h \
 438                          freetype/internal/sfnt.h)
 439         AC_TRY_CPP([#include <ft2build.h>
 440                     #include <freetype/fttrigon.h>],
 441                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 442           [Define if you have the <freetype/fttrigon.h> header file.])
 443                     wine_cv_fttrigon=yes],
 444                     wine_cv_fttrigon=no)
 445         CPPFLAGS="$ac_save_CPPFLAGS"
 446         dnl Check that we have at least freetype/freetype.h
 447         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 448         then
 449             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 450             wine_cv_msg_freetype=no
 451         else
 452             FREETYPEINCL=""
 453             wine_cv_msg_freetype=yes
 454         fi
 455     fi
 456 fi
 457 AC_SUBST(FREETYPEINCL)
 458
 459 dnl **** Check for parport (currently Linux only) ****
 460 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 461  AC_TRY_COMPILE(
 462    [#include <linux/ppdev.h>],
 463    [ioctl (1,PPCLAIM,0)],
 464    [ac_cv_c_ppdev="yes"],
 465    [ac_cv_c_ppdev="no"])
 466  )
 467 if test "$ac_cv_c_ppdev" = "yes"
 468 then
 469     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 470 fi
 471
 472 dnl **** Check for va_copy ****
 473 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 474  AC_TRY_LINK(
 475    [#include <stdarg.h>],
 476    [va_list ap1, ap2;
 477     va_copy(ap1,ap2);
 478    ],
 479    [ac_cv_c_va_copy="yes"],
 480    [ac_cv_c_va_copy="no"])
 481  )
 482 if test "$ac_cv_c_va_copy" = "yes"
 483 then
 484     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 485 fi
 486 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 487  AC_TRY_LINK(
 488    [#include <stdarg.h>],
 489    [va_list ap1, ap2;
 490     __va_copy(ap1,ap2);
 491    ],
 492    [ac_cv_c___va_copy="yes"],
 493    [ac_cv_c___va_copy="no"])
 494  )
 495 if test "$ac_cv_c___va_copy" = "yes"
 496 then
 497     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 498 fi
 499
 500 dnl **** Check for Open Sound System ****
 501 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 502
 503 AC_CACHE_CHECK([for Open Sound System],
 504         ac_cv_c_opensoundsystem,
 505         AC_TRY_COMPILE([
 506         #if defined(HAVE_SYS_SOUNDCARD_H)
 507                 #include <sys/soundcard.h>
 508         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 509                 #include <machine/soundcard.h>
 510         #elif defined(HAVE_SOUNDCARD_H)
 511                 #include <soundcard.h>
 512         #endif
 513         ],[
 514
 515 /* check for one of the Open Sound System specific SNDCTL_ defines */
 516 #if !defined(SNDCTL_DSP_STEREO)
 517 #error No open sound system
 518 #endif
 519 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 520
 521 if test "$ac_cv_c_opensoundsystem" = "yes"
 522 then
 523     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 524 fi
 525
 526 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 527         ac_cv_c_opensoundsystem_midi,
 528         AC_TRY_COMPILE([
 529         #if defined(HAVE_SYS_SOUNDCARD_H)
 530                 #include <sys/soundcard.h>
 531         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 532                 #include <machine/soundcard.h>
 533         #elif defined(HAVE_SOUNDCARD_H)
 534                 #include <soundcard.h>
 535         #endif
 536         ],[
 537
 538 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 539 #if !defined(SNDCTL_SEQ_SYNC)
 540 #error No open sound system MIDI interface
 541 #endif
 542 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 543
 544 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 545 then
 546     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 547 fi
 548
 549 dnl **** Check for aRts Sound Server ****
 550 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 551 AC_CACHE_CHECK([for aRts Sound server],
 552         ac_cv_c_artsserver,
 553         if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
 554         then
 555             ac_cv_c_artsserver=no
 556         else
 557             ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
 558             ARTSC_LIBS=`$ARTSCCONFIG --libs`
 559             ac_cv_c_artsserver=no
 560             save_CFLAGS="$CFLAGS"
 561             CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 562             AC_TRY_COMPILE([
 563              #include <artsc.h>
 564             ],[
 565              arts_stream_t stream;
 566             ],[
 567             ac_cv_c_artsserver=yes
 568             ])
 569             CFLAGS="$save_CFLAGS"
 570         fi)
 571
 572 if test "$ac_cv_c_artsserver" = "yes"
 573 then
 574     AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 575     AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 576
 577     AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
 578 fi
 579
 580 dnl **** Check for ALSA ****
 581 AC_SUBST(ALSALIBS,"")
 582 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 583 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 584 then
 585     AC_CHECK_LIB(asound,snd_pcm_open,
 586         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 587         ALSALIBS="-lasound")
 588 fi
 589
 590 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 591
 592 AC_SUBST(AUDIOIOLIBS,"")
 593 AC_CHECK_HEADERS(libaudioio.h,
 594     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 595                   [AUDIOIOLIBS="-laudioio"
 596                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 597
 598 dnl **** Check for broken glibc mmap64 ****
 599
 600 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 601         AC_TRY_RUN([
 602                 #define _FILE_OFFSET_BITS 64
 603                 #include <stdio.h>
 604                 #include <unistd.h>
 605                 #include <fcntl.h>
 606                 #include <sys/mman.h>
 607                 #include <errno.h>
 608
 609                 int main(int argc,char **argv) {
 610                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 611                         if (fd == -1) exit(1);
 612
 613                         unlink("conftest.map");
 614
 615                         write(fd,"test",4);
 616
 617                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 618                             (errno == EINVAL)
 619                         ) {
 620                                 exit(1);
 621                         }
 622                         close(fd);
 623                         fprintf(stderr,"success!\n");
 624                         exit(0);
 625                 }
 626
 627         ],
 628     ac_cv_mmap64_works="yes",
 629     ac_cv_mmap64_works="no",
 630     ac_cv_mmap64_works="no") )
 631
 632 if test "$ac_cv_mmap64_works" = "yes"
 633 then
 634     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 635 fi
 636
 637 dnl **** Check for gcc specific options ****
 638
 639 if test "x${GCC}" = "xyes"
 640 then
 641   CFLAGS="$CFLAGS -Wall"
 642
 643   dnl Check for strength-reduce bug
 644   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 645                   AC_TRY_RUN([
 646 int     L[[4]] = {0,1,2,3};
 647 int main(void) {
 648   static int Array[[3]];
 649   unsigned int B = 3;
 650   int i;
 651   for(i=0; i<B; i++) Array[[i]] = i - 3;
 652   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 653   L[[i]] = 4;
 654
 655   exit( Array[[1]] != -2 || L[[2]] != 3);
 656 }],
 657     ac_cv_c_gcc_strength_bug="no",
 658     ac_cv_c_gcc_strength_bug="yes",
 659     ac_cv_c_gcc_strength_bug="yes") )
 660   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 661   then
 662     CFLAGS="$CFLAGS -fno-strength-reduce"
 663   fi
 664
 665   dnl Check for -mpreferred-stack-boundary
 666   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 667       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 668                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 669   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 670   then
 671     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 672   fi
 673
 674   dnl Check for -gstabs+ option
 675   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 676       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 677   if test "$ac_cv_c_gcc_gstabs" = "yes"
 678   then
 679     CFLAGS="$CFLAGS -gstabs+"
 680   fi
 681
 682   dnl Check for noisy string.h
 683   saved_CFLAGS=$CFLAGS
 684   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 685   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 686       AC_TRY_COMPILE([#include <string.h>],[],
 687                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 688   CFLAGS=$saved_CFLAGS
 689   if test "$ac_cv_c_string_h_warnings" = "no"
 690   then
 691     CFLAGS="$CFLAGS -Wpointer-arith"
 692   fi
 693 fi
 694
 695 dnl **** Check how to define a function in assembly code ****
 696
 697 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 698   WINE_TRY_ASM_LINK(
 699       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 700       ac_cv_asm_func_def=".def",
 701     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 702       ac_cv_asm_func_def=".type @function",
 703     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 704       ac_cv_asm_func_def=".type 2",
 705       ac_cv_asm_func_def="unknown")])]))
 706
 707 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 708 case "$ac_cv_asm_func_def" in
 709   ".def")
 710      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 711   ".type @function")
 712      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 713   ".type 2")
 714      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 715   *)
 716      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 717 esac
 718
 719 dnl **** Check for underscore on external symbols ****
 720
 721 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 722     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 723                       [extern int ac_test;],
 724                       [if (ac_test) return 1],
 725                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 726
 727 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 728 if test "$ac_cv_c_extern_prefix" = "yes"
 729 then
 730   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 731 else
 732   AC_DEFINE([__ASM_NAME(name)], [name])
 733 fi
 734
 735 dnl **** Check for .string in assembler ****
 736
 737 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
 738     WINE_TRY_ASM_LINK([".data\n\t.string \"test\"\n\t.text"],,,
 739                       ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
 740 if test "$ac_cv_c_asm_string" = "yes"
 741 then
 742   AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
 743 fi
 744
 745 dnl **** Check for working dll ****
 746
 747 AC_SUBST(DLLEXT,"")
 748 AC_SUBST(DLLFLAGS,"")
 749 AC_SUBST(DLLIBS,"")
 750 AC_SUBST(LDDLLFLAGS,"")
 751 AC_SUBST(LDSHARED,"")
 752 AC_SUBST(LIBEXT,"so")
 753 AC_SUBST(IMPLIBEXT,"def")
 754
 755 case $host_os in
 756   cygwin*|mingw32*)
 757     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 758     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 759     if test "$DLLWRAP" = "false"; then
 760       LIBEXT="a"
 761     else
 762       dnl FIXME - check whether dllwrap works correctly...
 763       LIBEXT="dll"
 764     fi
 765     IMPLIBEXT="a"
 766     ;;
 767   *)
 768     AC_CHECK_HEADERS(dlfcn.h,
 769         [AC_CHECK_FUNCS(dlopen,,
 770             [AC_CHECK_LIB(dl,dlopen,
 771                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 772                           DLLIBS="-ldl"],
 773                          [LIBEXT="a"])])],
 774         [LIBEXT="a"])
 775
 776     if test "$LIBEXT" = "so"
 777     then
 778       DLLFLAGS="-fPIC"
 779       DLLEXT=".so"
 780       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 781           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 782                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 783       if test "$ac_cv_c_dll_gnuelf" = "yes"
 784       then
 785         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 786         LDDLLFLAGS="-Wl,-Bsymbolic"
 787         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 788           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 789                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 790         if test "$ac_cv_c_dll_zdefs" = "yes"
 791         then
 792           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 793         fi
 794       else
 795         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 796             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 797                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 798         if test "$ac_cv_c_dll_unixware" = "yes"
 799         then
 800           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 801           LDDLLFLAGS="-Wl,-B,symbolic"
 802         fi
 803       fi
 804     fi
 805
 806     dnl Check for cross compiler to build test programs
 807     AC_SUBST(CROSSTEST,"")
 808     if test "$cross_compiling" = "no"
 809     then
 810       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc,false)
 811       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool,false)
 812       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 813     fi
 814     ;;
 815 esac
 816
 817 if test "$LIBEXT" = "a"; then
 818   AC_MSG_ERROR(
 819 [could not find a way to build shared libraries.
 820 It is currently not possible to build Wine without shared library
 821 (.so) support to allow transparent switch between .so and .dll files.
 822 If you are using Linux, you will need a newer binutils.]
 823 )
 824 fi
 825
 826 case $build_os in
 827   cygwin*|mingw32*)
 828     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 829   *)
 830     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 831 esac
 832
 833 dnl Mingw needs explicit msvcrt for linking libwine
 834 AC_SUBST(CRTLIBS,"")
 835 case $host_os in
 836   mingw32*)
 837     CRTLIBS="-lmsvcrt" ;;
 838 esac
 839
 840 dnl **** Get the soname for libraries that we load dynamically ****
 841
 842 if test "$LIBEXT" = "so"
 843 then
 844   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
 845   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 846   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 847   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
 848   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
 849   WINE_GET_SONAME(cups,cupsGetDefault)
 850   WINE_GET_SONAME(jack,jack_client_new)
 851 fi
 852
 853
 854 dnl **** Check for reentrant libc ****
 855
 856 wine_cv_libc_reentrant=no
 857 dnl Linux style errno location
 858 WINE_CHECK_ERRNO([__errno_location], [wine_cv_libc_reentrant=__errno_location],
 859   dnl FreeBSD style errno location
 860   WINE_CHECK_ERRNO([__error], [wine_cv_libc_reentrant=__error],
 861     dnl Solaris style errno location
 862     WINE_CHECK_ERRNO([___errno], [wine_cv_libc_reentrant=___errno],
 863       dnl UnixWare style errno location
 864       WINE_CHECK_ERRNO([__thr_errno], [wine_cv_libc_reentrant=__thr_errno],
 865         dnl NetBSD style errno location
 866         WINE_CHECK_ERRNO([__errno], [wine_cv_libc_reentrant=__errno])
 867 ))))
 868
 869 if test "$wine_cv_libc_reentrant" != "no"
 870 then
 871   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
 872                      [Define to the name of the function returning errno for reentrant libc])
 873 fi
 874
 875 dnl **** Check for reentrant X libraries ****
 876 dnl
 877 dnl This may fail to determine whether X libraries are reentrant if
 878 dnl AC_PATH_XTRA does not set x_libraries.
 879
 880 if test "$have_x" = "yes"
 881 then
 882 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
 883     [libX11_check=none
 884     for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 885         if test -r $dir/libX11.so; then
 886             libX11_check="-D $dir/libX11.so"
 887             break
 888         fi
 889         if test -r $dir/libX11.a; then
 890             libX11_check="$dir/libX11.a"
 891             break
 892         fi
 893     done
 894     if test "$libX11_check" != "none"; then
 895         if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 896         then
 897             wine_cv_x_reentrant=yes
 898         else
 899             wine_cv_x_reentrant=no
 900         fi
 901     else
 902         wine_cv_x_reentrant=unknown
 903     fi])
 904 fi
 905
 906 dnl **** Check for functions ****
 907
 908 AC_FUNC_ALLOCA()
 909 AC_CHECK_FUNCS(\
 910         _lwp_create \
 911         _pclose \
 912         _popen \
 913         _snprintf \
 914         _stricmp \
 915         _strnicmp \
 916         _vsnprintf \
 917         chsize \
 918         clone \
 919         finite \
 920         fpclass \
 921         ftruncate \
 922         ftruncate64 \
 923         getnetbyaddr \
 924         getnetbyname \
 925         getopt_long \
 926         getpagesize \
 927         getprotobyname \
 928         getprotobynumber \
 929         getpwuid \
 930         getservbyport \
 931         inet_network \
 932         lseek64 \
 933         lstat \
 934         memmove \
 935         mmap \
 936         pclose \
 937         popen \
 938         pread \
 939         pthread_getspecific \
 940         pthread_key_create \
 941         pthread_mutex_lock \
 942         pthread_mutex_unlock \
 943         pthread_setspecific \
 944         pwrite \
 945         rfork \
 946         select \
 947         sendmsg \
 948         settimeofday \
 949         sigaltstack \
 950         snprintf \
 951         statfs \
 952         strcasecmp \
 953         strerror \
 954         strncasecmp \
 955         tcgetattr \
 956         timegm \
 957         usleep \
 958         vfscanf \
 959         vsnprintf \
 960         wait4 \
 961         waitpid \
 962 )
 963
 964 dnl **** Check for header files ****
 965
 966 AC_CHECK_HEADERS(\
 967         arpa/inet.h \
 968         arpa/nameser.h \
 969         cups/cups.h \
 970         direct.h \
 971         elf.h \
 972         float.h \
 973         getopt.h \
 974         ieeefp.h \
 975         io.h \
 976         jack/jack.h \
 977         libio.h \
 978         libutil.h \
 979         link.h \
 980         linux/cdrom.h \
 981         linux/hdreg.h \
 982         linux/input.h \
 983         linux/joystick.h \
 984         linux/major.h \
 985         linux/param.h \
 986         linux/serial.h \
 987         linux/ucdrom.h \
 988         netdb.h \
 989         netinet/in.h \
 990         netinet/in_systm.h \
 991         netinet/tcp.h \
 992         pty.h \
 993         pwd.h \
 994         regex.h \
 995         sched.h \
 996         scsi/sg.h \
 997         socket.h \
 998         stdint.h \
 999         strings.h \
1000         sys/cdio.h \
1001         sys/errno.h \
1002         sys/file.h \
1003         sys/filio.h \
1004         sys/inttypes.h \
1005         sys/ioctl.h \
1006         sys/ipc.h \
1007         sys/link.h \
1008         sys/lwp.h \
1009         sys/mman.h \
1010         sys/modem.h \
1011         sys/msg.h \
1012         sys/param.h \
1013         sys/poll.h \
1014         sys/ptrace.h \
1015         sys/reg.h \
1016         sys/shm.h \
1017         sys/signal.h \
1018         sys/socket.h \
1019         sys/sockio.h \
1020         sys/statfs.h \
1021         sys/strtio.h \
1022         sys/syscall.h \
1023         sys/sysctl.h \
1024         sys/time.h \
1025         sys/times.h \
1026         sys/uio.h \
1027         sys/un.h \
1028         sys/v86.h \
1029         sys/v86intr.h \
1030         sys/vfs.h \
1031         sys/vm86.h \
1032         sys/wait.h \
1033         syscall.h \
1034         termios.h \
1035         unistd.h \
1036         utime.h \
1037 )
1038 AC_HEADER_STAT()
1039
1040 dnl **** Checks for headers that depend on other ones ****
1041
1042 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1043     [#include <sys/types.h>
1044      #if HAVE_SYS_PARAM_H
1045      # include <sys/param.h>
1046      #endif])
1047
1048 AC_CHECK_HEADERS(net/if.h,,,
1049     [#include <sys/types.h>
1050      #if HAVE_SYS_SOCKET_H
1051      # include <sys/socket.h>
1052      #endif])
1053
1054 AC_CHECK_HEADERS(netinet/ip.h,,,
1055     [#include <sys/types.h>
1056      #if HAVE_SYS_SOCKET_H
1057      # include <sys/socket.h>
1058      #endif
1059      #if HAVE_NETINET_IN_SYSTM_H
1060      # include <netinet/in_systm.h>
1061      #endif])
1062
1063 AC_CHECK_HEADERS(resolv.h,,,
1064     [#include <sys/types.h>
1065      #if HAVE_SYS_SOCKET_H
1066      # include <sys/socket.h>
1067      #endif])
1068
1069 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1070
1071 dnl **** Check for IPX headers (currently Linux only) ****
1072
1073 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1074  AC_TRY_COMPILE(
1075    [#include <sys/types.h>
1076     #ifdef HAVE_SYS_SOCKET_H
1077     # include <sys/socket.h>
1078     #endif
1079     #include <netipx/ipx.h>],
1080    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1081    [ac_cv_c_ipx_gnu="yes"],
1082    [ac_cv_c_ipx_gnu="no"])
1083  )
1084 if test "$ac_cv_c_ipx_gnu" = "yes"
1085 then
1086     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1087 fi
1088
1089 if test "$ac_cv_c_ipx_gnu" = "no"
1090 then
1091  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1092   AC_TRY_COMPILE(
1093     [#include <sys/types.h>
1094      #ifdef HAVE_SYS_SOCKET_H
1095      # include <sys/socket.h>
1096      #endif
1097      #include <asm/types.h>
1098      #include <linux/ipx.h>],
1099     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1100     [ac_cv_c_ipx_linux="yes"],
1101     [ac_cv_c_ipx_linux="no"])
1102   )
1103   if test "$ac_cv_c_ipx_linux" = "yes"
1104   then
1105       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1106   fi
1107 fi
1108
1109 dnl **** Check for types ****
1110
1111 AC_C_CONST
1112 AC_C_INLINE
1113 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1114 AC_CHECK_SIZEOF(long long,0)
1115
1116 AC_CACHE_CHECK([whether linux/input.h is for real],
1117         wine_cv_linux_input_h,
1118         AC_TRY_COMPILE([
1119             #include <linux/input.h>
1120         ] , [
1121             int foo = EVIOCGBIT(EV_ABS,42);
1122             int bar = BTN_PINKIE;
1123             int fortytwo = 42;
1124         ],
1125         wine_cv_linux_input_h=yes,
1126         wine_cv_linux_input_h=no,
1127         no
1128         )
1129     )
1130     if test "$wine_cv_linux_input_h" = "yes"
1131     then
1132         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1133                   [Define if we have linux/input.h AND it contains the INPUT event API])
1134     fi
1135
1136
1137 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1138         wine_cv_linux_gethostbyname_r_6,
1139         AC_TRY_COMPILE([
1140 #include <netdb.h>
1141         ], [
1142     char *name=NULL;
1143     struct hostent he;
1144     struct hostent *result;
1145     char *buf=NULL;
1146     int bufsize=0;
1147     int res,errnr;
1148     char *addr=NULL;
1149     int addrlen=0;
1150     int addrtype=0;
1151     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1152     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1153     ],
1154         wine_cv_linux_gethostbyname_r_6=yes,
1155         wine_cv_linux_gethostbyname_r_6=no
1156         )
1157    )
1158    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1159    then
1160       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1161                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1162    fi
1163
1164 if test "$ac_cv_header_linux_joystick_h" = "yes"
1165 then
1166    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1167         wine_cv_linux_joystick_22_api,
1168         AC_TRY_COMPILE([
1169         #include <sys/ioctl.h>
1170         #include <linux/joystick.h>
1171
1172         struct js_event blub;
1173         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1174         #error "no 2.2 header"
1175         #endif
1176         ],/*empty*/,
1177         wine_cv_linux_joystick_22_api=yes,
1178         wine_cv_linux_joystick_22_api=no,
1179         wine_cv_linux_joystick_22_api=no
1180         )
1181    )
1182    if test "$wine_cv_linux_joystick_22_api" = "yes"
1183    then
1184       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1185                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1186    fi
1187 fi
1188
1189 dnl **** statfs checks ****
1190
1191 if test "$ac_cv_header_sys_vfs_h" = "yes"
1192 then
1193     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1194                     wine_cv_sys_vfs_has_statfs,
1195         AC_TRY_COMPILE([
1196         #include <sys/types.h>
1197         #ifdef HAVE_SYS_PARAM_H
1198         # include <sys/param.h>
1199         #endif
1200         #include <sys/vfs.h>
1201         ],[
1202                 struct statfs stfs;
1203
1204                 memset(&stfs,0,sizeof(stfs));
1205         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1206         )
1207     )
1208     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1209     then
1210       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1211                 [Define if the struct statfs is defined by <sys/vfs.h>])
1212     fi
1213 fi
1214
1215 if test "$ac_cv_header_sys_statfs_h" = "yes"
1216 then
1217     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1218                     wine_cv_sys_statfs_has_statfs,
1219         AC_TRY_COMPILE([
1220         #include <sys/types.h>
1221         #ifdef HAVE_SYS_PARAM_H
1222         # include <sys/param.h>
1223         #endif
1224         #include <sys/statfs.h>
1225         ],[
1226                 struct statfs stfs;
1227         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1228         )
1229     )
1230     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1231     then
1232       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1233                 [Define if the struct statfs is defined by <sys/statfs.h>])
1234     fi
1235 fi
1236
1237 if test "$ac_cv_header_sys_mount_h" = "yes"
1238 then
1239     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1240                     wine_cv_sys_mount_has_statfs,
1241         AC_TRY_COMPILE([
1242         #include <sys/types.h>
1243         #ifdef HAVE_SYS_PARAM_H
1244         # include <sys/param.h>
1245         #endif
1246         #include <sys/mount.h>
1247         ],[
1248                 struct statfs stfs;
1249         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1250         )
1251     )
1252     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1253     then
1254       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1255                 [Define if the struct statfs is defined by <sys/mount.h>])
1256     fi
1257 fi
1258
1259 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1260
1261 WINE_CHECK_STRUCT_MEMBER(statfs,f_bfree,
1262 [#include <sys/types.h>
1263 #ifdef HAVE_SYS_PARAM_H
1264 # include <sys/param.h>
1265 #endif
1266 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1267 # include <sys/mount.h>
1268 #else
1269 # ifdef STATFS_DEFINED_BY_SYS_VFS
1270 #  include <sys/vfs.h>
1271 # else
1272 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1273 #   include <sys/statfs.h>
1274 #  endif
1275 # endif
1276 #endif],
1277     [AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])])
1278
1279 WINE_CHECK_STRUCT_MEMBER(statfs,f_bavail,
1280 [#include <sys/types.h>
1281 #ifdef HAVE_SYS_PARAM_H
1282 # include <sys/param.h>
1283 #endif
1284 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1285 # include <sys/mount.h>
1286 #else
1287 # ifdef STATFS_DEFINED_BY_SYS_VFS
1288 #  include <sys/vfs.h>
1289 # else
1290 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1291 #   include <sys/statfs.h>
1292 #  endif
1293 # endif
1294 #endif],
1295     [AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])])
1296
1297 dnl Check for file descriptor passing with msg_accrights
1298 WINE_CHECK_STRUCT_MEMBER(msghdr,msg_accrights,
1299 [#include <sys/types.h>
1300 #ifdef HAVE_SYS_SOCKET_H
1301 # include <sys/socket.h>
1302 #endif],
1303     [AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])])
1304
1305 dnl Check for the sa_len member in struct sockaddr
1306 WINE_CHECK_STRUCT_MEMBER(sockaddr,sa_len,
1307 [#include <sys/types.h>
1308 #ifdef HAVE_SYS_SOCKET_H
1309 # include <sys/socket.h>
1310 #endif],
1311     [AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])])
1312
1313 dnl Check for the sun_len member in struct sockaddr_un
1314 WINE_CHECK_STRUCT_MEMBER(sockaddr_un,sun_len,
1315 [#include <sys/types.h>
1316 #ifdef HAVE_SYS_SOCKET_H
1317 # include <sys/socket.h>
1318 #endif
1319 #ifdef HAVE_SYS_UN_H
1320 # include <sys/un.h>
1321 #endif],
1322     [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])])
1323
1324 dnl *** check for the need to define platform-specific symbols
1325
1326 case $host_cpu in
1327   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1328   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1329   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1330 esac
1331
1332 case $host_vendor in
1333   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1334 esac
1335
1336 dnl **** Generate output files ****
1337
1338 AH_TOP([#define __WINE_CONFIG_H])
1339
1340 WINE_CONFIG_EXTRA_DIR(controls)
1341 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1342 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1343 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1344 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1345 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1346 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1347 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1348 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1349 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1350 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1351 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1352 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1353 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1354 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1355 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1356 WINE_CONFIG_EXTRA_DIR(files)
1357 WINE_CONFIG_EXTRA_DIR(graphics)
1358 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1359 WINE_CONFIG_EXTRA_DIR(if1632)
1360 WINE_CONFIG_EXTRA_DIR(include/wine)
1361 WINE_CONFIG_EXTRA_DIR(loader)
1362 WINE_CONFIG_EXTRA_DIR(loader/ne)
1363 WINE_CONFIG_EXTRA_DIR(memory)
1364 WINE_CONFIG_EXTRA_DIR(misc)
1365 WINE_CONFIG_EXTRA_DIR(msdos)
1366 WINE_CONFIG_EXTRA_DIR(objects)
1367 WINE_CONFIG_EXTRA_DIR(ole)
1368 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1369 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1370 WINE_CONFIG_EXTRA_DIR(relay32)
1371 WINE_CONFIG_EXTRA_DIR(scheduler)
1372 WINE_CONFIG_EXTRA_DIR(win32)
1373 WINE_CONFIG_EXTRA_DIR(windows)
1374
1375 MAKE_RULES=Make.rules
1376 AC_SUBST_FILE(MAKE_RULES)
1377
1378 MAKE_DLL_RULES=dlls/Makedll.rules
1379 AC_SUBST_FILE(MAKE_DLL_RULES)
1380
1381 MAKE_TEST_RULES=dlls/Maketest.rules
1382 AC_SUBST_FILE(MAKE_TEST_RULES)
1383
1384 MAKE_PROG_RULES=programs/Makeprog.rules
1385 AC_SUBST_FILE(MAKE_PROG_RULES)
1386
1387 AC_CONFIG_FILES([
1388 Make.rules
1389 dlls/Makedll.rules
1390 dlls/Maketest.rules
1391 programs/Makeprog.rules
1392 Makefile
1393 dlls/Makefile
1394 dlls/advapi32/Makefile
1395 dlls/advapi32/tests/Makefile
1396 dlls/avicap32/Makefile
1397 dlls/avifil32/Makefile
1398 dlls/cabinet/Makefile
1399 dlls/comcat/Makefile
1400 dlls/comctl32/Makefile
1401 dlls/commdlg/Makefile
1402 dlls/crtdll/Makefile
1403 dlls/crypt32/Makefile
1404 dlls/ctl3d/Makefile
1405 dlls/d3d8/Makefile
1406 dlls/d3dim/Makefile
1407 dlls/d3dx8/Makefile
1408 dlls/dciman32/Makefile
1409 dlls/ddraw/Makefile
1410 dlls/devenum/Makefile
1411 dlls/dinput/Makefile
1412 dlls/dinput8/Makefile
1413 dlls/dmusic/Makefile
1414 dlls/dplay/Makefile
1415 dlls/dplayx/Makefile
1416 dlls/dsound/Makefile
1417 dlls/dsound/tests/Makefile
1418 dlls/gdi/Makefile
1419 dlls/gdi/tests/Makefile
1420 dlls/glu32/Makefile
1421 dlls/icmp/Makefile
1422 dlls/imagehlp/Makefile
1423 dlls/imm32/Makefile
1424 dlls/kernel/Makefile
1425 dlls/kernel/tests/Makefile
1426 dlls/lzexpand/Makefile
1427 dlls/mapi32/Makefile
1428 dlls/mpr/Makefile
1429 dlls/msacm/Makefile
1430 dlls/msacm/imaadp32/Makefile
1431 dlls/msacm/msadp32/Makefile
1432 dlls/msacm/msg711/Makefile
1433 dlls/msacm/winemp3/Makefile
1434 dlls/msdmo/Makefile
1435 dlls/msimg32/Makefile
1436 dlls/msisys/Makefile
1437 dlls/msnet32/Makefile
1438 dlls/msvcrt/Makefile
1439 dlls/msvcrt/tests/Makefile
1440 dlls/msvcrt20/Makefile
1441 dlls/msvideo/Makefile
1442 dlls/msvideo/msrle32/Makefile
1443 dlls/netapi32/Makefile
1444 dlls/netapi32/tests/Makefile
1445 dlls/ntdll/Makefile
1446 dlls/ntdll/tests/Makefile
1447 dlls/odbc32/Makefile
1448 dlls/ole32/Makefile
1449 dlls/oleaut32/Makefile
1450 dlls/oleaut32/tests/Makefile
1451 dlls/olecli/Makefile
1452 dlls/oledlg/Makefile
1453 dlls/olepro32/Makefile
1454 dlls/olesvr/Makefile
1455 dlls/opengl32/Makefile
1456 dlls/psapi/Makefile
1457 dlls/qcap/Makefile
1458 dlls/quartz/Makefile
1459 dlls/rasapi32/Makefile
1460 dlls/richedit/Makefile
1461 dlls/rpcrt4/Makefile
1462 dlls/rpcrt4/tests/Makefile
1463 dlls/serialui/Makefile
1464 dlls/setupapi/Makefile
1465 dlls/shdocvw/Makefile
1466 dlls/shell32/Makefile
1467 dlls/shell32/tests/Makefile
1468 dlls/shfolder/Makefile
1469 dlls/shlwapi/Makefile
1470 dlls/shlwapi/tests/Makefile
1471 dlls/snmpapi/Makefile
1472 dlls/sti/Makefile
1473 dlls/tapi32/Makefile
1474 dlls/ttydrv/Makefile
1475 dlls/twain/Makefile
1476 dlls/url/Makefile
1477 dlls/urlmon/Makefile
1478 dlls/urlmon/tests/Makefile
1479 dlls/user/Makefile
1480 dlls/user/tests/Makefile
1481 dlls/version/Makefile
1482 dlls/win32s/Makefile
1483 dlls/winaspi/Makefile
1484 dlls/winedos/Makefile
1485 dlls/wineps/Makefile
1486 dlls/wininet/Makefile
1487 dlls/wininet/tests/Makefile
1488 dlls/winmm/Makefile
1489 dlls/winmm/joystick/Makefile
1490 dlls/winmm/mcianim/Makefile
1491 dlls/winmm/mciavi/Makefile
1492 dlls/winmm/mcicda/Makefile
1493 dlls/winmm/mciseq/Makefile
1494 dlls/winmm/mciwave/Makefile
1495 dlls/winmm/midimap/Makefile
1496 dlls/winmm/tests/Makefile
1497 dlls/winmm/wavemap/Makefile
1498 dlls/winmm/winealsa/Makefile
1499 dlls/winmm/winearts/Makefile
1500 dlls/winmm/wineaudioio/Makefile
1501 dlls/winmm/winenas/Makefile
1502 dlls/winmm/winejack/Makefile
1503 dlls/winmm/wineoss/Makefile
1504 dlls/winnls/Makefile
1505 dlls/winsock/Makefile
1506 dlls/winsock/tests/Makefile
1507 dlls/winspool/Makefile
1508 dlls/winspool/tests/Makefile
1509 dlls/wintab32/Makefile
1510 dlls/wintrust/Makefile
1511 dlls/wow32/Makefile
1512 dlls/wsock32/Makefile
1513 dlls/x11drv/Makefile
1514 documentation/Makefile
1515 include/Makefile
1516 library/Makefile
1517 libs/Makefile
1518 libs/port/Makefile
1519 libs/unicode/Makefile
1520 libs/uuid/Makefile
1521 miscemu/Makefile
1522 programs/Makefile
1523 programs/avitools/Makefile
1524 programs/clock/Makefile
1525 programs/cmdlgtst/Makefile
1526 programs/control/Makefile
1527 programs/expand/Makefile
1528 programs/notepad/Makefile
1529 programs/osversioncheck/Makefile
1530 programs/progman/Makefile
1531 programs/regapi/Makefile
1532 programs/regedit/Makefile
1533 programs/regsvr32/Makefile
1534 programs/regtest/Makefile
1535 programs/rpcss/Makefile
1536 programs/rundll32/Makefile
1537 programs/start/Makefile
1538 programs/uninstaller/Makefile
1539 programs/view/Makefile
1540 programs/wcmd/Makefile
1541 programs/wineboot/Makefile
1542 programs/wineconsole/Makefile
1543 programs/winedbg/Makefile
1544 programs/winefile/Makefile
1545 programs/winemine/Makefile
1546 programs/winepath/Makefile
1547 programs/winhelp/Makefile
1548 programs/winver/Makefile
1549 server/Makefile
1550 tools/Makefile
1551 tools/widl/Makefile
1552 tools/winapi/Makefile
1553 tools/winebuild/Makefile
1554 tools/winedump/Makefile
1555 tools/wmc/Makefile
1556 tools/wpp/Makefile
1557 tools/wrc/Makefile])
1558
1559 AC_OUTPUT
1560
1561 if test "$have_x" = "no"
1562 then
1563   echo
1564   echo "*** Warning: X development files not found. Wine will be built without"
1565   echo "*** X support, which currently does not work, and would probably not be"
1566   echo "*** what you want anyway. You will need to install devel packages of"
1567   echo "*** Xlib/Xfree86 at the very least."
1568 fi
1569
1570 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1571 then
1572   echo
1573   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1574   echo "*** terminal resize support. Consider upgrading ncurses."
1575 fi
1576
1577 if test "$wine_cv_libc_reentrant" = "no"
1578 then
1579   echo
1580   echo "*** Warning: non-reentrant libc detected. Wine will be built without"
1581   echo "*** threading support. Consider upgrading libc to a more recent"
1582   echo "*** reentrant version of libc."
1583 fi
1584
1585 if test "$have_x" = "yes" -a "$wine_cv_x_reentrant" != "yes"
1586 then
1587   echo
1588   echo "*** Warning: non-reentrant X11 library detected. Multi-threaded"
1589   echo "*** applications won't work properly. You should upgrade your X11 library."
1590 fi
1591
1592 if test "$wine_cv_opengl_version_OK" = "no"
1593 then
1594   echo
1595   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1596   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1597 fi
1598
1599 if test "$wine_cv_msg_freetype" = "yes"
1600 then
1601   echo
1602   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1603   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1604   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1605   echo "*** enable Wine to use TrueType fonts."
1606 fi
1607
1608 echo
1609 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1610 echo
1611
1612 dnl Local Variables:
1613 dnl comment-start: "dnl "
1614 dnl comment-end: ""
1615 dnl comment-start-skip: "\\bdnl\\b\\s *"
1616 dnl compile-command: "autoconf"
1617 dnl End: