git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.59d don't handle multi-line subst variables correctly
   8 AC_PREREQ(2.59d)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17
  18 dnl **** Command-line arguments ****
  19
  20 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  21 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  22 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  23 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]),
  24                                ,[AC_SUBST([MAINTAINER_MODE],[\#])])
  25
  26 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  28 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  30 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  31             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  32 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  33             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  34 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  36 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  37 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  38             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  39 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  40 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  41             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  42 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  43 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  44 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  45             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  46 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  47 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  48             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  49 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  50 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  52 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  54 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  55             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  56 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]),
  57             [if test "x$withval" = "xno"; then ac_cv_header_mpg123_h=no; fi])
  58 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  59             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  60 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  61             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  62 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  63 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  65 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  66             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  67 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  68             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  69 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  70             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  71 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  72 AC_ARG_WITH(tiff,       AS_HELP_STRING([--without-tiff],[do not use TIFF]),
  73             [if test "x$withval" = "xno"; then ac_cv_header_tiffio_h=no; fi])
  74 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  75 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  77 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  78             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  79 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  80             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  81 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  82             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  83 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  84 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  85             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  86 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  87             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  88 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  89             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  90 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  91             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  92 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  93 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
  94             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
  95
  96 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  97 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
  98
  99 AC_CANONICAL_HOST
 100
 101 dnl check for out of tree build with unclean source tree
 102 case "$srcdir" in
 103  .) ;;
 104  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 105       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 106 You need to run 'make distclean' in the source tree first.])
 107     fi ;;
 108 esac
 109
 110 dnl **** Check for some programs ****
 111
 112 AC_PROG_MAKE_SET
 113 AC_PROG_CC
 114 AC_PROG_CXX
 115 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 116 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 117 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 118
 119 case $host in
 120   *-darwin*)
 121     if test "x$enable_win64" = "xyes"
 122     then
 123       CC="$CC -m64"
 124       CXX="$CXX -m64"
 125       LD="${LD:-ld} -arch x86_64"
 126       AS="${AS:-as} -arch x86_64"
 127       host_cpu="x86_64"
 128       notice_platform="64-bit "
 129       AC_SUBST(TARGETFLAGS,"-m64")
 130     else
 131       CC="$CC -m32"
 132       CXX="$CXX -m32"
 133       LD="${LD:-ld} -arch i386"
 134       AS="${AS:-as} -arch i386"
 135       host_cpu="i386"
 136       notice_platform="32-bit "
 137       AC_SUBST(TARGETFLAGS,"-m32")
 138       enable_win16=${enable_win16:-yes}
 139     fi
 140     ;;
 141   x86_64*)
 142     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 143     then
 144       CC="$CC -m32"
 145       CXX="$CXX -m32"
 146       AC_MSG_CHECKING([whether $CC works])
 147       AC_LINK_IFELSE(AC_LANG_PROGRAM(),AC_MSG_RESULT([yes]),
 148                      [AC_MSG_RESULT([no])
 149                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 150       LD="${LD:-ld} -m elf_i386"
 151       AS="${AS:-as} --32"
 152       host_cpu="i386"
 153       notice_platform="32-bit "
 154       AC_SUBST(TARGETFLAGS,"-m32")
 155       enable_win16=${enable_win16:-yes}
 156     else
 157       if test "x${GCC}" = "xyes"
 158       then
 159         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 160         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 161                           [AC_MSG_RESULT([yes])],
 162                           [AC_MSG_RESULT([no])
 163                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 164       fi
 165       AC_SUBST(TARGETFLAGS,"-m64")
 166     fi
 167     ;;
 168   *-mingw32*|*-cygwin*)
 169     enable_win16=${enable_win16:-no}
 170     CFLAGS="$CFLAGS -D_WIN32"
 171     ;;
 172   i[[3456789]]86*)
 173     enable_win16=${enable_win16:-yes}
 174     ;;
 175 esac
 176
 177 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 178 enable_win16=${enable_win16:-no}
 179
 180 dnl Disable winetest too if tests are disabled
 181 enable_winetest=${enable_winetest:-$enable_tests}
 182
 183 dnl Some special cases for the wow64 build
 184 if test -n "$with_wine64"
 185 then
 186     if test "x$enable_win64" = "xyes"
 187     then
 188         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 189 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 190     fi
 191     AC_SUBST([WOW64_DISABLE],[\#])
 192     enable_fonts=${enable_fonts:-no}
 193     enable_server=${enable_server:-no}
 194     enable_tools=${enable_tools:-no}
 195     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib32"
 196 fi
 197
 198 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 199   [wine_cv_toolsdir="$with_wine_tools"
 200    if test -z "$with_wine_tools"; then
 201      if test "$cross_compiling" = "yes"; then
 202        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 203      elif test -n "$with_wine64"; then
 204        wine_cv_toolsdir="$with_wine64"
 205      fi
 206    fi
 207    if test -z "$wine_cv_toolsdir"; then
 208      wine_cv_toolsdir="\$(TOPOBJDIR)"
 209    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 210      case "$wine_cv_toolsdir" in
 211        /*) ;;
 212        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$wine_cv_toolsdir" ;;
 213      esac
 214    else
 215      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 216    fi])
 217 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 218 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 219 then
 220     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 221 fi
 222
 223 dnl Check for flex
 224 AC_CHECK_PROGS(FLEX,flex,none)
 225 if test "$FLEX" = "none"
 226 then
 227   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 228 fi
 229 AC_MSG_CHECKING([whether flex is recent enough])
 230 cat >conftest.l <<EOF
 231 %top{
 232 #include "prediluvian.h"
 233 }
 234 %%
 235 EOF
 236 if $FLEX -t conftest.l >/dev/null 2>&1
 237 then
 238   AC_MSG_RESULT([yes])
 239 else
 240   AC_MSG_RESULT([no])
 241   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 242 fi
 243
 244 dnl Check for bison
 245 AC_CHECK_PROGS(BISON,bison,none)
 246 if test "$BISON" = "none"
 247 then
 248   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 249 fi
 250
 251 AC_CHECK_TOOLS(AR,[ar gar],ar)
 252 AC_SUBST(ARFLAGS,rc)
 253 AC_PROG_RANLIB
 254 AC_CHECK_TOOL(STRIP,strip,strip)
 255 AC_PROG_LN_S
 256 AC_PROG_EGREP
 257 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 258 AC_PROG_INSTALL
 259 dnl Prepend src dir to install path dir if it's a relative path
 260 case "$INSTALL" in
 261   [[\\/$]]* | ?:[[\\/]]* ) ;;
 262   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 263 esac
 264
 265 dnl Check for lint
 266 AC_CHECK_PROGS(LINT, lclint lint)
 267 if test "$LINT" = "lint"
 268 then
 269   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 270   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 271 fi
 272 AC_SUBST(LINT)
 273 AC_SUBST(LINTFLAGS)
 274
 275 dnl Check for various programs
 276 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 277 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 278 AC_CHECK_PROGS(RSVG, rsvg, false)
 279 AC_CHECK_PROGS(CONVERT, convert, false)
 280 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 281
 282 if test "${enable_maintainer_mode+set}" = set
 283 then
 284   if test "$FONTFORGE" = "false"; then WINE_WARNING([fontforge is missing, fonts can't be rebuilt.]); fi
 285   if test "$RSVG" = "false"; then WINE_WARNING([rsvg is missing, icons can't be rebuilt.]); fi
 286   if test "$CONVERT" = "false"; then WINE_WARNING([imagemagick is missing, icons can't be rebuilt.]); fi
 287
 288   dnl Check the icotool version
 289   if test "$ICOTOOL" = false
 290   then
 291     WINE_WARNING([icotool is missing, icons can't be rebuilt.])
 292   else
 293     AC_MSG_CHECKING([for recent enough icotool])
 294     icotool_version=`icotool --version | head -n1`
 295     if test "x$icotool_version" != "x"
 296     then
 297       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\).[[0-9]]*'`
 298       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*.\([[0-9]]*\)'`
 299       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 300       then
 301         ICOTOOL=false
 302         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 303       fi
 304     fi
 305     if test "$ICOTOOL" = false
 306     then
 307       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 308     else
 309       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 310     fi
 311   fi
 312
 313 fi
 314
 315 case $host_cpu in
 316   *i[[3456789]]86*)
 317     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 318     ;;
 319 esac
 320
 321 dnl **** Check for some libraries ****
 322
 323 dnl Check for -li386 for NetBSD and OpenBSD
 324 AC_CHECK_LIB(i386,i386_set_ldt)
 325 dnl Check for -lossaudio for NetBSD
 326 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 327
 328 AC_SUBST(XLIB,"")
 329 AC_SUBST(OPENGL_LIBS,"")
 330
 331 dnl **** Check for header files ****
 332
 333 AC_SYS_LARGEFILE()
 334
 335 AC_CHECK_HEADERS(\
 336         AL/al.h \
 337         AudioToolbox/AudioConverter.h \
 338         AudioToolbox/AudioFile.h \
 339         AudioToolbox/AudioFileStream.h \
 340         AudioUnit/AudioUnit.h \
 341         Carbon/Carbon.h \
 342         CoreAudio/CoreAudio.h \
 343         DiskArbitration/DiskArbitration.h \
 344         IOKit/IOKitLib.h \
 345         IOKit/hid/IOHIDLib.h \
 346         OpenAL/al.h \
 347         alias.h \
 348         alsa/asoundlib.h \
 349         arpa/inet.h \
 350         arpa/nameser.h \
 351         asm/types.h \
 352         capi20.h \
 353         curses.h \
 354         direct.h \
 355         dirent.h \
 356         dlfcn.h \
 357         elf.h \
 358         float.h \
 359         fnmatch.h \
 360         fontconfig/fontconfig.h \
 361         getopt.h \
 362         grp.h \
 363         gsm.h \
 364         gsm/gsm.h \
 365         ieeefp.h \
 366         inet/mib2.h \
 367         io.h \
 368         jack/jack.h \
 369         jpeglib.h \
 370         kstat.h \
 371         lber.h \
 372         lcms.h \
 373         lcms/lcms.h \
 374         ldap.h \
 375         libaudioio.h \
 376         link.h \
 377         linux/cdrom.h \
 378         linux/compiler.h \
 379         linux/hdreg.h \
 380         linux/input.h \
 381         linux/ioctl.h \
 382         linux/joystick.h \
 383         linux/major.h \
 384         linux/param.h \
 385         linux/serial.h \
 386         linux/types.h \
 387         linux/ucdrom.h \
 388         mach-o/nlist.h \
 389         mach/mach.h \
 390         mach/machine.h \
 391         machine/cpu.h \
 392         machine/limits.h \
 393         machine/soundcard.h \
 394         mntent.h \
 395         mpg123.h \
 396         ncurses.h \
 397         netdb.h \
 398         netinet/in.h \
 399         netinet/in_systm.h \
 400         netinet/tcp.h \
 401         netinet/tcp_fsm.h \
 402         openssl/err.h \
 403         openssl/ssl.h \
 404         png.h \
 405         poll.h \
 406         port.h \
 407         process.h \
 408         pthread.h \
 409         pwd.h \
 410         regex.h \
 411         sched.h \
 412         scsi/scsi.h \
 413         scsi/scsi_ioctl.h \
 414         scsi/sg.h \
 415         soundcard.h \
 416         stdbool.h \
 417         stdint.h \
 418         strings.h \
 419         stropts.h \
 420         sys/asoundlib.h \
 421         sys/cdio.h \
 422         sys/elf32.h \
 423         sys/epoll.h \
 424         sys/errno.h \
 425         sys/event.h \
 426         sys/exec_elf.h \
 427         sys/filio.h \
 428         sys/inotify.h \
 429         sys/ioctl.h \
 430         sys/ipc.h \
 431         sys/limits.h \
 432         sys/link.h \
 433         sys/mman.h \
 434         sys/modem.h \
 435         sys/msg.h \
 436         sys/mtio.h \
 437         sys/param.h \
 438         sys/poll.h \
 439         sys/prctl.h \
 440         sys/protosw.h \
 441         sys/ptrace.h \
 442         sys/resource.h \
 443         sys/scsiio.h \
 444         sys/shm.h \
 445         sys/signal.h \
 446         sys/socket.h \
 447         sys/socketvar.h \
 448         sys/sockio.h \
 449         sys/soundcard.h \
 450         sys/statvfs.h \
 451         sys/strtio.h \
 452         sys/syscall.h \
 453         sys/tihdr.h \
 454         sys/time.h \
 455         sys/timeout.h \
 456         sys/times.h \
 457         sys/uio.h \
 458         sys/un.h \
 459         sys/utsname.h \
 460         sys/vm86.h \
 461         sys/wait.h \
 462         syscall.h \
 463         termios.h \
 464         tiffio.h \
 465         unistd.h \
 466         utime.h \
 467         valgrind/memcheck.h \
 468         valgrind/valgrind.h \
 469         zlib.h
 470 )
 471 AC_HEADER_STAT()
 472
 473 dnl **** Checks for headers that depend on other ones ****
 474
 475 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 476     [#include <sys/types.h>
 477      #ifdef HAVE_SYS_PARAM_H
 478      # include <sys/param.h>
 479      #endif])
 480
 481 AC_CHECK_HEADERS(\
 482         netinet/ip.h \
 483         net/if.h \
 484         net/if_arp.h \
 485         net/if_dl.h \
 486         net/if_types.h \
 487         net/route.h \
 488         netinet/if_ether.h \
 489         netinet/if_inarp.h \
 490         netinet/in_pcb.h \
 491         netinet/ip_icmp.h \
 492         netinet/ip_var.h \
 493         netinet/udp.h \
 494         netipx/ipx.h \
 495 ,,,[#include <sys/types.h>
 496      #ifdef HAVE_SYS_SOCKET_H
 497      # include <sys/socket.h>
 498      #endif
 499      #ifdef HAVE_SYS_SOCKETVAR_H
 500      # include <sys/socketvar.h>
 501      #endif
 502      #ifdef HAVE_NET_ROUTE_H
 503      # include <net/route.h>
 504      #endif
 505      #ifdef HAVE_NETINET_IN_H
 506      # include <netinet/in.h>
 507      #endif
 508      #ifdef HAVE_NETINET_IN_SYSTM_H
 509      # include <netinet/in_systm.h>
 510      #endif
 511      #ifdef HAVE_NET_IF_H
 512      # include <net/if.h>
 513      #endif
 514      #ifdef HAVE_NETINET_IP_H
 515      # include <netinet/ip.h>
 516      #endif])
 517
 518 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 519     [#include <sys/types.h>
 520      #ifdef HAVE_ALIAS_H
 521      # include <alias.h>
 522      #endif
 523      #ifdef HAVE_SYS_SOCKET_H
 524      # include <sys/socket.h>
 525      #endif
 526      #ifdef HAVE_SYS_SOCKETVAR_H
 527      # include <sys/socketvar.h>
 528      #endif
 529      #ifdef HAVE_SYS_TIMEOUT_H
 530      # include <sys/timeout.h>
 531      #endif
 532      #ifdef HAVE_NETINET_IN_H
 533      # include <netinet/in.h>
 534      #endif
 535      #ifdef HAVE_NETINET_IN_SYSTM_H
 536      # include <netinet/in_systm.h>
 537      #endif
 538      #ifdef HAVE_NETINET_IP_H
 539      # include <netinet/ip.h>
 540      #endif
 541      #ifdef HAVE_NETINET_IP_VAR_H
 542      # include <netinet/ip_var.h>
 543      #endif
 544      #ifdef HAVE_NETINET_IP_ICMP_H
 545      # include <netinet/ip_icmp.h>
 546      #endif
 547      #ifdef HAVE_NETINET_UDP_H
 548      # include <netinet/udp.h>
 549      #endif
 550      #ifdef HAVE_NETINET_TCP_H
 551      # include <netinet/tcp.h>
 552      #endif
 553      #ifdef HAVE_NETINET_TCP_TIMER_H
 554      #include <netinet/tcp_timer.h>
 555      #endif])
 556
 557 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h],,,
 558     [#include <sys/types.h>
 559      #ifdef HAVE_ASM_TYPES_H
 560      # include <asm/types.h>
 561      #endif
 562      #ifdef HAVE_SYS_SOCKET_H
 563      # include <sys/socket.h>
 564      #endif
 565      #ifdef HAVE_LINUX_TYPES_H
 566      # include <linux/types.h>
 567      #endif])
 568
 569 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 570     [#ifdef HAVE_STDBOOL_H
 571      # include <stdbool.h>
 572      #endif
 573      #ifdef HAVE_STDINT_H
 574      # include <stdint.h>
 575      #endif])
 576
 577 AC_CHECK_HEADERS([resolv.h],,,
 578     [#include <sys/types.h>
 579      #ifdef HAVE_SYS_SOCKET_H
 580      # include <sys/socket.h>
 581      #endif
 582      #ifdef HAVE_NETINET_IN_H
 583      # include <netinet/in.h>
 584      #endif
 585      #ifdef HAVE_ARPA_NAMESER_H
 586      # include <arpa/nameser.h>
 587      #endif])
 588
 589 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 590
 591 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 592
 593 AC_CHECK_HEADERS([sys/thr.h],,,
 594 [#include <sys/types.h>
 595 #ifdef HAVE_UCONTEXT_H
 596 #include <ucontext.h>
 597 #endif])
 598
 599 AC_CHECK_HEADERS([pthread_np.h],,,
 600 [#ifdef HAVE_PTHREAD_H
 601 #include <pthread.h>
 602 #endif])
 603
 604 AC_CHECK_HEADERS([linux/videodev.h],,,
 605 [#ifdef HAVE_SYS_TIME_H
 606 #include <sys/time.h>
 607 #endif
 608 #include <sys/types.h>
 609 #ifdef HAVE_ASM_TYPES_H
 610 #include <asm/types.h>
 611 #endif])
 612
 613 dnl Check for broken kernel header that doesn't define __user
 614 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 615
 616 dnl **** Check for working dll ****
 617
 618 AC_SUBST(DLLEXT,"")
 619 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 620 AC_SUBST(LDSHARED,"")
 621 AC_SUBST(LDDLLFLAGS,"")
 622 AC_SUBST(LIBEXT,"so")
 623 AC_SUBST(IMPLIBEXT,"def")
 624 AC_SUBST(LDRPATH_INSTALL,"")
 625 AC_SUBST(LDRPATH_LOCAL,"")
 626 STATIC_IMPLIBEXT="def.a"
 627 WINE_PATH_LDD
 628
 629 case $host_os in
 630   cygwin*|mingw32*)
 631     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 632     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 633     if test "$DLLWRAP" = "false"; then
 634       LIBEXT="a"
 635     else
 636       dnl FIXME - check whether dllwrap works correctly...
 637       LIBEXT="dll"
 638     fi
 639     IMPLIBEXT="a"
 640     STATIC_IMPLIBEXT="a"
 641     dnl Disable modules that can't be used on Windows
 642     enable_iphlpapi=${enable_iphlpapi:-no}
 643     enable_kernel32=${enable_kernel32:-no}
 644     enable_msvcrt=${enable_msvcrt:-no}
 645     enable_ntdll=${enable_ntdll:-no}
 646     enable_ws2_32=${enable_ws2_32:-no}
 647     enable_loader=${enable_loader:-no}
 648     enable_server=${enable_server:-no}
 649     dnl Disable dependencies that are not useful on Windows
 650     with_x=${with_x:-no}
 651     with_pthread=${with_pthread:-no}
 652     ;;
 653   darwin*|macosx*)
 654     DLLEXT=".so"
 655     LIBEXT="dylib"
 656     DLLFLAGS="$DLLFLAGS -fPIC"
 657     LDDLLFLAGS="-bundle -multiply_defined suppress"
 658     LIBWINE_LDFLAGS="-multiply_defined suppress"
 659     LDSHARED="\$(CC) -dynamiclib"
 660     STRIP="$STRIP -x"
 661     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 662     dnl declare needed frameworks
 663     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 664     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 665     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 666     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHAREDHEAP,0x7f000000"])
 667     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 668     then
 669         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 670         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 671     fi
 672     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 673     then
 674         dnl CoreServices needed by AudioUnit
 675         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 676         ac_save_LIBS="$LIBS"
 677         if test "$ac_cv_header_AudioToolbox_AudioFile_h" = "yes"
 678         then
 679             LIBS="$LIBS $COREAUDIO"
 680             AC_CHECK_FUNCS(AudioFileStreamOpen)
 681             LIBS="$ac_save_LIBS"
 682         fi
 683         test "x$ac_cv_func_AudioFileStreamOpen" = xyes || WINE_NOTICE([AudioToolbox version too old, mp3 codec won't be supported.])
 684     fi
 685     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 686     then
 687         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 688         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 689         ac_cv_lib_openal=yes
 690     fi
 691     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 692     then
 693         ac_save_LIBS="$LIBS"
 694         LIBS="$LIBS $IOKITLIB"
 695         AC_CHECK_FUNCS(IOHIDManagerCreate)
 696         LIBS="$ac_save_LIBS"
 697     fi
 698     case $host_cpu in
 699       *powerpc*)
 700         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 701         ;;
 702     esac
 703     dnl Enable quartz driver on Mac OS X
 704     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 705     then
 706         AC_SUBST(CARBONLIB,"-framework Carbon")
 707         enable_winequartz_drv=${enable_winequartz_drv:-yes}
 708     fi
 709     dnl Check for Xcode 3.x broken 16-bit support
 710     if test "x$enable_win16" = "xyes"
 711     then
 712         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 713         AC_RUN_IFELSE(AC_LANG_PROGRAM([[asm(".text\n"
 714                                             "bad:\tnop;nop\n"
 715                                             "good:\tnop;nop\n\t"
 716                                             ".globl _testfunc\n"
 717                                             "_testfunc:\tcallw good");
 718                                         extern void testfunc();]],
 719                                       [[unsigned short *p = (unsigned short *)testfunc;
 720                                         return p[[0]] != 0xe866 || p[[1]] != 0xfffa]]),
 721                                       AC_MSG_RESULT(yes),
 722                                       [AC_MSG_RESULT(no)
 723                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 724                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 725     fi
 726     ;;
 727   *)
 728     DLLFLAGS="$DLLFLAGS -fPIC"
 729     DLLEXT=".so"
 730     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 731         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 732                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 733     if test "$ac_cv_c_dll_gnuelf" = "yes"
 734     then
 735       LDSHARED="\$(CC) -shared"
 736       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 737       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 738                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 739                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 740                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 741
 742       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 743
 744       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 745                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 746
 747       echo '{ global: *; };' >conftest.map
 748       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 749                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 750       rm -f conftest.map
 751
 752       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 753                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 754
 755       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 756                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 757                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 758           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 759                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 760                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 761
 762       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 763                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 764
 765       case $host_cpu in
 766         *i[[3456789]]86* | x86_64)
 767           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 768                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 769           ;;
 770       esac
 771
 772     else
 773       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 774           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 775                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 776       if test "$ac_cv_c_dll_unixware" = "yes"
 777       then
 778         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 779         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 780
 781       else
 782         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 783           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 784         if test "$ac_cv_c_dll_hpux" = "yes"
 785         then
 786           LIBEXT="sl"
 787           DLLEXT=".sl"
 788           LDDLLFLAGS="-shared -fPIC"
 789           LDSHARED="\$(CC) -shared"
 790         fi
 791       fi
 792     fi
 793     ;;
 794 esac
 795
 796 enable_winequartz_drv=${enable_winequartz_drv:-no}
 797
 798 if test "$LIBEXT" = "a"; then
 799   AC_MSG_ERROR(
 800 [could not find a way to build shared libraries.
 801 It is currently not possible to build Wine without shared library
 802 (.so) support to allow transparent switch between .so and .dll files.
 803 If you are using Linux, you will need a newer binutils.]
 804 )
 805 fi
 806
 807 dnl Check for cross compiler to build test programs
 808 if test "$cross_compiling" = "no" -a "$LIBEXT" != "dll"
 809 then
 810     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 811     if test "$CROSSCC" != "false"
 812     then
 813         AC_SUBST(CROSSTEST,"\$(CROSSTEST)")
 814         set x $CROSSCC
 815         shift
 816         target=""
 817         while test $# -ge 1
 818         do
 819             case "$1" in
 820               *-gcc) target=`expr "$1" : '\(.*\)-gcc'` ;;
 821             esac
 822             shift
 823         done
 824         if test -n "$target"
 825         then
 826             AC_SUBST(CROSSTARGET,"$target")
 827         fi
 828     fi
 829 fi
 830
 831 dnl **** Check for pthread ****
 832
 833 if test "$ac_cv_header_pthread_h" = "yes"
 834 then
 835     AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])
 836 fi
 837 WINE_ERROR_WITH(pthread,[test "x$LIBPTHREAD" = "x"],[pthread ${notice_platform}development files not found.
 838 Wine cannot support threads without libpthread.])
 839
 840 dnl **** Check for X11 ****
 841
 842 AC_PATH_XTRA
 843
 844 if test "$have_x" = "yes"
 845 then
 846     XLIB="-lX11"
 847     ac_save_CPPFLAGS="$CPPFLAGS"
 848     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 849
 850     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 851     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 852
 853     dnl *** All of the following tests require X11/Xlib.h
 854     AC_CHECK_HEADERS([X11/Xlib.h \
 855                       X11/XKBlib.h \
 856                       X11/Xutil.h \
 857                       X11/Xcursor/Xcursor.h \
 858                       X11/extensions/shape.h \
 859                       X11/extensions/XInput.h \
 860                       X11/extensions/XShm.h \
 861                       X11/extensions/Xcomposite.h \
 862                       X11/extensions/Xinerama.h \
 863                       X11/extensions/Xrandr.h \
 864                       X11/extensions/Xrender.h \
 865                       X11/extensions/xf86vmode.h \
 866                       X11/extensions/xf86vmproto.h],,,
 867 [#ifdef HAVE_X11_XLIB_H
 868 # include <X11/Xlib.h>
 869 #endif
 870 #ifdef HAVE_X11_XUTIL_H
 871 # include <X11/Xutil.h>
 872 #endif])
 873
 874         dnl *** Check for X keyboard extension
 875         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 876         then
 877               AC_CHECK_LIB(X11, XkbQueryExtension,
 878               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 879               $X_LIBS $XLIB $X_EXTRA_LIBS)
 880         fi
 881
 882         dnl *** Check for X cursor
 883         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 884         then
 885             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 886         fi
 887         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 888                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
 889
 890         dnl *** Check for X input extension
 891         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 892         then
 893             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 894         fi
 895         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 896                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
 897
 898         dnl *** Check for X Shm extension
 899         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 900         then
 901               AC_CHECK_LIB(Xext, XShmQueryExtension,
 902               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 903               $X_LIBS $XLIB $X_EXTRA_LIBS)
 904         fi
 905         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 906                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
 907
 908         dnl *** Check for X shape extension
 909         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 910         then
 911               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 912               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 913               $X_LIBS $XLIB $X_EXTRA_LIBS)
 914         fi
 915         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 916                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
 917
 918         dnl *** Check for XFree86 VMODE extension
 919         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
 920         then
 921             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 922         fi
 923         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
 924                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
 925
 926         dnl *** Check for Transform functions in Xrender
 927         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 928         then
 929             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 930               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 931                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 932                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 933                 [$X_LIBS $XLIB $X_EXTRA_LIBS])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 934
 935         fi
 936         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 937                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
 938
 939         dnl *** Check for X RandR extension
 940         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 941         then
 942                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 943 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 944                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
 945         fi
 946         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 947                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
 948
 949         dnl *** Check for Xinerama extension
 950         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 951         then
 952                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 953 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 954                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
 955         fi
 956         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 957                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
 958
 959         dnl *** Check for X Composite extension
 960         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 961         then
 962             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 963         fi
 964         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 965                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
 966
 967         dnl *** Check for XICCallback struct
 968         AC_CHECK_MEMBERS([XICCallback.callback],,,
 969 [#ifdef HAVE_X11_XLIB_H
 970 #include <X11/Xlib.h>
 971 #endif])
 972
 973     dnl *** End of X11/Xlib.h check
 974
 975     dnl Check for the presence of OpenGL
 976     opengl_msg=""
 977     if test "x$with_opengl" != "xno"
 978     then
 979         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glu.h,,,
 980 [#ifdef HAVE_GL_GLX_H
 981 # include <GL/glx.h>
 982 #endif])
 983         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 984         then
 985             dnl Check for some problems due to old Mesa versions
 986             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 987               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 988                 [wine_cv_opengl_header_version_OK="yes"],
 989                 [wine_cv_opengl_header_version_OK="no"]))
 990
 991             if test "$wine_cv_opengl_header_version_OK" = "yes"
 992             then
 993                 dnl Check for the presence of the library
 994                 WINE_CHECK_SONAME(GL,glXCreateContext,
 995                              [OPENGL_LIBS="-lGL"
 996                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 997                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 998                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 999                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1000                                     [if test -f /usr/X11R6/lib/libGL.a
1001                                     then
1002                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1003 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1004                                     else
1005                                         opengl_msg="No OpenGL library found on this system."
1006                                     fi],
1007                                     $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1008                              $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1009                  if test "$ac_cv_header_GL_glu_h" = "yes"
1010                  then
1011                     WINE_CHECK_SONAME(GLU,gluLookAt,,,[$OPENGL_LIBS $X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1012                  fi
1013                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
1014                                  [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1015              else
1016                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
1017              fi
1018          else
1019              opengl_msg="OpenGL development headers not found."
1020          fi
1021          test -n "$opengl_msg" && enable_opengl32=${enable_opengl32:-no}
1022          test "x$ac_cv_lib_soname_GLU" = "x" && enable_glu32=${enable_glu32:-no}
1023     else
1024          enable_opengl32=${enable_opengl32:-no}
1025          enable_glu32=${enable_glu32:-no}
1026     fi
1027     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1028 OpenGL and Direct3D won't be supported.])
1029
1030     dnl **** Check for NAS ****
1031     AC_SUBST(NASLIBS,"")
1032     AC_CHECK_HEADERS(audio/audiolib.h,
1033          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
1034           AC_CHECK_LIB(audio,AuCreateFlow,
1035                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
1036                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
1037                           [NASLIBS="-lXau -laudio -lXt $X_LIBS $XLIB $X_EXTRA_LIBS"],
1038                           [NASLIBS="-laudio -lXt $X_LIBS $XLIB $X_EXTRA_LIBS"],
1039                           [$X_LIBS])
1040                        ],,
1041                        [-lXt $X_LIBS $XLIB $X_EXTRA_LIBS])])
1042
1043     CPPFLAGS="$ac_save_CPPFLAGS"
1044 else
1045     XLIB=""
1046     X_CFLAGS=""
1047     X_LIBS=""
1048     enable_winex11_drv=${enable_winex11_drv:-no}
1049     enable_opengl32=${enable_opengl32:-no}
1050     enable_glu32=${enable_glu32:-no}
1051 fi
1052 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1053 without X support, which probably isn't what you want. You will need to install
1054 ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1055
1056 dnl **** Check for libxml2 ****
1057
1058 AC_SUBST(XML2LIBS,"")
1059 AC_SUBST(XML2INCL,"")
1060 AC_SUBST(XSLTINCL,"")
1061 if test "x$with_xml" != "xno"
1062 then
1063     ac_save_CPPFLAGS="$CPPFLAGS"
1064     if test "$PKG_CONFIG" != "false"
1065     then
1066         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
1067         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
1068     else
1069         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
1070         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
1071     fi
1072     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
1073     AC_CHECK_HEADERS(libxml/parser.h,
1074             [AC_CHECK_LIB(xml2, xmlParseMemory,
1075                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
1076                  XML2LIBS="$ac_xml_libs"
1077                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
1078              AC_CHECK_LIB(xml2, xmlReadMemory,
1079                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
1080              AC_CHECK_LIB(xml2, xmlNewDocPI,
1081                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
1082         ])
1083     CPPFLAGS="$ac_save_CPPFLAGS"
1084 fi
1085 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1086                  [libxml2 ${notice_platform}development files not found, XML won't be supported.])
1087
1088 if test "x$with_xslt" != "xno"
1089 then
1090     if test "$PKG_CONFIG" != "false"
1091     then
1092         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
1093         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
1094     else
1095         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
1096         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
1097     fi
1098     ac_save_CPPFLAGS="$CPPFLAGS"
1099     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
1100     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1101     [#ifdef HAVE_LIBXSLT_PATTERN_H
1102 # include <libxslt/pattern.h>
1103 #endif])
1104     CPPFLAGS="$ac_save_CPPFLAGS"
1105     if test "$ac_cv_header_libxslt_transform_h" = "yes"
1106     then
1107         WINE_CHECK_SONAME(xslt,xsltCompilePattern,
1108                          [XSLTINCL="$ac_xslt_cflags"],,[$ac_xslt_libs])
1109     fi
1110 fi
1111 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1112                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1113
1114 dnl **** Check for libhal ****
1115 AC_SUBST(HALINCL,"")
1116 if test "x$with_hal" != "xno"
1117 then
1118     ac_save_CPPFLAGS="$CPPFLAGS"
1119     if test "$PKG_CONFIG" != "false"
1120     then
1121         ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
1122         ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
1123         CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
1124     fi
1125     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
1126     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
1127     then
1128         AC_CHECK_LIB(dbus-1, dbus_connection_close,
1129           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
1130             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
1131     fi
1132     CPPFLAGS="$ac_save_CPPFLAGS"
1133 fi
1134 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
1135                  [libhal/libdbus ${notice_platform}development files not found, no dynamic device support.])
1136
1137 dnl **** Check for libgnutls ****
1138 if test "x$with_gnutls" != "xno"
1139 then
1140     ac_save_CPPFLAGS="$CPPFLAGS"
1141     if test "$PKG_CONFIG" != "false"
1142     then
1143         ac_gnutls_libs="`$PKG_CONFIG --libs gnutls 2>/dev/null`"
1144         ac_gnutls_cflags="`$PKG_CONFIG --cflags gnutls 2>/dev/null`"
1145         CPPFLAGS="$CPPFLAGS $ac_gnutls_cflags"
1146     fi
1147     AC_CHECK_HEADER(gnutls/gnutls.h,
1148         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[typeof(gnutls_mac_get_key_size) *pfunc;]])],
1149             [WINE_CHECK_SONAME(gnutls,gnutls_global_init,
1150                 [AC_SUBST(GNUTLSINCL,"$ac_gnutls_cflags")],,[$ac_gnutls_libs])])])
1151     CPPFLAGS="$ac_save_CPPFLAGS"
1152 fi
1153 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1154                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1155
1156 dnl **** Check which curses lib to use ***
1157 CURSESLIBS=""
1158 if test "$ac_cv_header_ncurses_h" = "yes"
1159 then
1160     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1161 elif test "$ac_cv_header_curses_h" = "yes"
1162 then
1163     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1164 fi
1165 ac_save_LIBS="$LIBS"
1166 LIBS="$LIBS $CURSESLIBS"
1167 AC_CHECK_FUNCS(mousemask)
1168 LIBS="$ac_save_LIBS"
1169 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1170                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1171
1172 dnl **** Check for SANE ****
1173 if test "x$with_sane" != "xno"
1174 then
1175     ac_save_CPPFLAGS="$CPPFLAGS"
1176     AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
1177     if test "$sane_devel" != "no"
1178     then
1179         ac_sane_incl="`$sane_devel --cflags`"
1180         ac_sane_libs="`$sane_devel --ldflags`"
1181         CPPFLAGS="$CPPFLAGS $ac_sane_incl"
1182     fi
1183     AC_CHECK_HEADER(sane/sane.h,
1184         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
1185     CPPFLAGS="$ac_save_CPPFLAGS"
1186 fi
1187 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1188                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1189
1190 dnl **** Check for libv4l1 ****
1191 if test "x$with_v4l" != "xno"
1192 then
1193     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1194 fi
1195 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1196                  [libv4l ${notice_platform}development files not found.])
1197
1198 dnl **** Check for libgphoto2 ****
1199 if test "x$with_gphoto" != "xno"
1200 then
1201     ac_save_CPPFLAGS="$CPPFLAGS"
1202     AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
1203     AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
1204     if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
1205     then
1206         ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
1207         ac_gphoto2_libs=""
1208         for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
1209         do
1210             case "$i" in
1211             -L/usr/lib|-L/usr/lib64) ;;
1212             -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
1213             esac
1214         done
1215         CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
1216     fi
1217     ac_gphoto2_libs=${ac_gphoto2_libs:-"-lgphoto2"}
1218     AC_CHECK_HEADER(gphoto2-camera.h,
1219                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
1220                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
1221                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
1222                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
1223                                   [$ac_gphoto2_libs])])
1224     CPPFLAGS="$ac_save_CPPFLAGS"
1225 fi
1226 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1227                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1228
1229
1230 dnl **** Check for resolver library ***
1231 AC_SUBST(RESOLVLIBS,"")
1232 if test "$ac_cv_header_resolv_h" = "yes"
1233 then
1234     ac_save_LIBS="$LIBS"
1235     LIBS="$LIBS -lresolv"
1236     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1237 #include <netinet/in.h>
1238 #endif
1239 #include <resolv.h>]],[[res_init();]])],
1240         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1241          RESOLVLIBS="-lresolv"])
1242     LIBS="$ac_save_LIBS"
1243 fi
1244
1245 dnl **** Check for LittleCMS ***
1246 AC_SUBST(LCMSLIBS,"")
1247 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
1248 then
1249     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
1250         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
1251          LCMSLIBS="-llcms"])
1252 fi
1253 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
1254                  [liblcms ${notice_platform}development files not found, Color Management won't be supported.])
1255
1256 dnl **** Check for FreeType 2 ****
1257 if test "x$with_freetype" != "xno"
1258 then
1259     AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],no)
1260     if test "$ft_devel" != "no"
1261     then
1262         ac_freetype_incl=`$ft_devel --cflags`
1263         ac_freetype_libs=`$ft_devel --libs`
1264     fi
1265     ac_freetype_libs=${ac_freetype_libs:-"-lfreetype"}
1266     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
1267     if test "$ft_lib" = "yes"
1268     then
1269         ac_save_CPPFLAGS="$CPPFLAGS"
1270         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1271         AC_CHECK_HEADERS(ft2build.h \
1272                          freetype/freetype.h \
1273                          freetype/ftglyph.h \
1274                          freetype/fttypes.h \
1275                          freetype/tttables.h \
1276                          freetype/ftsnames.h \
1277                          freetype/ttnameid.h \
1278                          freetype/ftoutln.h \
1279                          freetype/ftwinfnt.h \
1280                          freetype/ftmodapi.h \
1281                          freetype/ftlcdfil.h \
1282                          freetype/internal/sfnt.h,,,
1283                          [#ifdef HAVE_FT2BUILD_H
1284                           # include <ft2build.h>
1285                           #endif])
1286         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1287                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1288           [Define if you have the <freetype/fttrigon.h> header file.])
1289                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1290         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1291         ac_save_CFLAGS="$CFLAGS"
1292         CFLAGS="$CFLAGS $ac_freetype_libs"
1293         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1294         CFLAGS="$ac_save_CFLAGS"
1295         CPPFLAGS="$ac_save_CPPFLAGS"
1296         dnl Check that we have at least freetype/freetype.h
1297         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1298         then
1299             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1300             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1301             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1302         fi
1303     fi
1304 fi
1305 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType ${notice_platform}development files not found. Fonts will not be built.])
1306 test "x$FREETYPELIBS" = "x" && enable_fonts=${enable_fonts:-no}
1307
1308 dnl **** Check for parport (currently Linux only) ****
1309 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1310  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1311 # include <sys/ioctl.h>
1312 #endif
1313 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1314     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1315 if test "$ac_cv_c_ppdev" = "yes"
1316 then
1317     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1318 fi
1319
1320 dnl **** Check for pthread functions ****
1321 WINE_CHECK_LIB_FUNCS(\
1322         pthread_attr_get_np \
1323         pthread_getattr_np \
1324         pthread_get_stackaddr_np \
1325         pthread_get_stacksize_np,
1326         [$LIBPTHREAD])
1327
1328 dnl **** Check for zlib ****
1329 if test "$ac_cv_header_zlib_h" = "yes"
1330 then
1331     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1332                             AC_SUBST(ZLIB,"-lz")])
1333 fi
1334
1335 dnl **** Check for EsounD ****
1336 if test "x$with_esd" != xno
1337 then
1338     save_CFLAGS="$CFLAGS"
1339     AC_PATH_PROG(ESDCONFIG, esd-config, no)
1340     if test "x$ESDCONFIG" != "xno"
1341     then
1342         ac_esd_incl=""
1343         for i in `$ESDCONFIG --cflags`
1344         do
1345             case "$i" in
1346                 -I*) ac_esd_incl="$ac_esd_incl $i";;
1347             esac
1348         done
1349         ac_esd_libs=`$ESDCONFIG --libs`
1350         CFLAGS="$CFLAGS $ac_esd_incl"
1351     fi
1352     ac_esd_libs=${ac_esd_libs:-"-lesd"}
1353     AC_CHECK_HEADER(esd.h,
1354         [AC_CHECK_LIB(esd,esd_open_sound,
1355             [AC_SUBST(ESDINCL, "$ac_esd_incl")
1356              AC_SUBST(ESDLIBS, "$ac_esd_libs")
1357              AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])],,
1358             [$ac_esd_libs])])
1359     CFLAGS="$save_CFLAGS"
1360 fi
1361
1362 dnl **** Check for ALSA 1.x ****
1363 AC_SUBST(ALSALIBS,"")
1364 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1365 then
1366     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1367         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1368 #include <alsa/asoundlib.h>
1369 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1370 #include <sys/asoundlib.h>
1371 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1372                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1373                          ALSALIBS="-lasound"],[])])
1374 fi
1375
1376 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1377 AC_SUBST(AUDIOIOLIBS,"")
1378 if test "$ac_cv_header_libaudioio_h" = "yes"
1379 then
1380     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1381                   [AUDIOIOLIBS="-laudioio"
1382                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1383 fi
1384
1385 dnl **** Check for capi4linux ****
1386
1387 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1388 then
1389     WINE_CHECK_SONAME(capi20,capi20_register)
1390 fi
1391 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1392                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1393
1394 dnl **** Check for cups ****
1395 AC_SUBST(CUPSINCL,"")
1396 if test "x$with_cups" != "xno"
1397 then
1398     ac_save_CPPFLAGS="$CPPFLAGS"
1399     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1400     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1401     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1402     AC_CHECK_HEADERS(cups/cups.h,
1403             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1404                        [CUPSINCL="$ac_cups_cflags"],,
1405                        [$ac_cups_libs])])
1406     CPPFLAGS="$ac_save_CPPFLAGS"
1407 fi
1408 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1409                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1410
1411 dnl **** Check for jack ****
1412 if test "$ac_cv_header_jack_jack_h" = "yes"
1413 then
1414     WINE_CHECK_SONAME(jack,jack_client_new,,,,[[libjack-*[[0-9.]]*]])
1415 fi
1416
1417 dnl **** Check for fontconfig ****
1418 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1419 then
1420     WINE_CHECK_SONAME(fontconfig,FcInit)
1421 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1422 then
1423     dnl fontconfig is in the X directory on Mac OS X
1424     ac_save_CPPFLAGS="$CPPFLAGS"
1425     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1426     $as_unset ac_cv_header_fontconfig_fontconfig_h
1427     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1428     CPPFLAGS="$ac_save_CPPFLAGS"
1429     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1430     then
1431         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1432         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1433     fi
1434 fi
1435 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1436                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1437
1438 dnl **** Check for SSL ****
1439 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1440 then
1441     WINE_CHECK_SONAME(ssl,SSL_library_init)
1442     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1443 fi
1444 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1445                  [OpenSSL ${notice_platform}development files not found, SSL won't be supported.])
1446
1447 dnl **** Check for gsm codec ****
1448 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1449 then
1450     WINE_CHECK_SONAME(gsm,gsm_create)
1451 fi
1452 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1453                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1454
1455 dnl **** Check for libjpeg ****
1456 if test "$ac_cv_header_jpeglib_h" = "yes"
1457 then
1458     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1459 fi
1460 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1461                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1462
1463 dnl **** Check for libpng ****
1464 if test "$ac_cv_header_png_h" = "yes"
1465 then
1466     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm -lz,[[libpng[[0-9]]*]])
1467     AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1468         [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])]
1469         ,,-lm -lz)
1470 elif test -n "$X_CFLAGS" -a "x$with_png" != "xno"
1471 then
1472     dnl libpng is in the X directory on Mac OS X
1473     ac_save_CPPFLAGS="$CPPFLAGS"
1474     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1475     $as_unset ac_cv_header_png_h
1476     AC_CHECK_HEADERS([png.h])
1477     CPPFLAGS="$ac_save_CPPFLAGS"
1478     if test "$ac_cv_header_png_h" = "yes"
1479     then
1480         AC_SUBST(PNGINCL,"$X_CFLAGS")
1481         WINE_CHECK_SONAME(png,png_create_read_struct,,,[$X_LIBS -lm -lz],[[libpng[[0-9]]*]])
1482         AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1483                 [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1)],,[$X_LIBS -lm -lz])
1484     fi
1485 fi
1486 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1487                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1488
1489 dnl **** Check for libtiff ****
1490 if test "$ac_cv_header_tiffio_h" = "yes"
1491 then
1492     WINE_CHECK_SONAME(tiff,TIFFClientOpen)
1493 fi
1494 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1495                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1496
1497 dnl **** Check for mpg123 ****
1498 if test "$ac_cv_header_mpg123_h" = "yes"
1499 then
1500     AC_CHECK_LIB(mpg123,mpg123_feed,[AC_SUBST(LIBMPG123,"-lmpg123")])
1501 fi
1502 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1503                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1504 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_func_AudioFileStreamOpen" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1505
1506 dnl **** Check for OpenAL 1.1 ****
1507 if test "$ac_cv_header_AL_al_h" = "yes"
1508 then
1509     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1510                       ac_cv_lib_openal=yes
1511                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1512 fi
1513 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1514                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1515 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1516
1517 dnl **** Check for libkstat ****
1518 if test "$ac_cv_header_kstat_h" = "yes"
1519 then
1520     AC_CHECK_LIB(kstat,kstat_open,
1521                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1522                   AC_SUBST(LIBKSTAT,"-lkstat")])
1523 fi
1524
1525 dnl **** Check for libodbc ****
1526 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1527
1528 dnl **** Check for any sound system ****
1529 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESDLIBS$ac_cv_lib_soname_jack" = "x" -a \
1530         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1531         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1532         "$ac_cv_header_soundcard_h" != "yes" -a \
1533         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1534 then
1535     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1536 fi
1537
1538 dnl **** Check for gcc specific options ****
1539
1540 AC_SUBST(EXTRACFLAGS,"")
1541 if test "x${GCC}" = "xyes"
1542 then
1543   EXTRACFLAGS="-Wall -pipe"
1544
1545   dnl Check for strength-reduce bug
1546   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1547                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1548 [[static int Array[[3]];
1549   unsigned int B = 3;
1550   int i;
1551   for(i=0; i<B; i++) Array[[i]] = i - 3;
1552   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1553   L[[i]] = 4;
1554   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1555     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1556   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1557   then
1558     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1559   fi
1560
1561   dnl Check for some compiler flags
1562   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1563   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1564   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1565   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1566   WINE_TRY_CFLAGS([-Wtype-limits])
1567   WINE_TRY_CFLAGS([-Wwrite-strings])
1568
1569   dnl Check for noisy string.h
1570   saved_CFLAGS="$CFLAGS"
1571   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1572   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1573       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1574   CFLAGS="$saved_CFLAGS"
1575   if test "$ac_cv_c_string_h_warnings" = "no"
1576   then
1577     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1578   fi
1579
1580   dnl Enable -Werror for maintainer mode
1581   if test "${enable_maintainer_mode+set}" = set
1582   then
1583       WINE_TRY_CFLAGS([-Werror])
1584   fi
1585
1586   dnl Check for ms_hook_prologue support
1587   saved_CFLAGS="$CFLAGS"
1588   CFLAGS="$CFLAGS -Werror"
1589   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1590                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1591                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1592   CFLAGS="$saved_CFLAGS"
1593   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1594   then
1595       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1596                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1597   else
1598       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1599   fi
1600 fi
1601
1602 dnl **** Check for underscore on external symbols ****
1603
1604 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1605     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1606                       [extern int ac_test;],
1607                       [if (ac_test) return 1],
1608                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1609
1610 case $host_cpu in
1611   *i[[3456789]]86*)
1612     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1613         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1614 [#ifndef _MSC_VER
1615 #define __stdcall __attribute__((__stdcall__))
1616 #endif
1617 int __stdcall ac_test(int i) { return i; }],
1618                           [if (ac_test(1)) return 1],
1619                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1620   *) ac_cv_c_stdcall_suffix="no" ;;
1621 esac
1622
1623 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1624 if test "$ac_cv_c_extern_prefix" = "yes"
1625 then
1626     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1627     asm_name_prefix="_"
1628 else
1629     AC_DEFINE([__ASM_NAME(name)], [name])
1630     asm_name_prefix=""
1631 fi
1632
1633 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1634 if test "$ac_cv_c_stdcall_suffix" = "yes"
1635 then
1636     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1637 else
1638     AC_DEFINE([__ASM_STDCALL(args)],[""])
1639 fi
1640
1641 dnl **** Check how to define a function in assembly code ****
1642
1643 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1644   WINE_TRY_ASM_LINK(
1645       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1646       ac_cv_asm_func_def=".def",
1647     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1648       ac_cv_asm_func_def=".type @function",
1649     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1650       ac_cv_asm_func_def=".type 2",
1651       ac_cv_asm_func_def="unknown")])]))
1652
1653 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1654 case "$ac_cv_asm_func_def" in
1655   ".def")
1656      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1657      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1658   ".type @function")
1659      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1660      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1661   ".type 2")
1662      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1663      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1664   *)
1665      AC_DEFINE([__ASM_FUNC(name)], [""])
1666      asm_func_header="" ;;
1667 esac
1668
1669 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1670     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1671                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1672
1673 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1674     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1675                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1676
1677 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1678     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1679                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1680
1681 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1682 asm_func_trailer=""
1683 if test "$ac_cv_c_dot_previous" = "yes"
1684 then
1685    asm_func_trailer="\\n\\t.previous"
1686 fi
1687 if test "$ac_cv_c_cfi_support" = "yes"
1688 then
1689    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1690    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1691    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1692    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1693 else
1694    AC_DEFINE([__ASM_CFI(str)],[""])
1695 fi
1696
1697 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1698
1699 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1700 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1701 then
1702     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1703 else
1704     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1705 fi
1706 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1707           [Define to a macro to generate an assembly function with C calling convention])
1708 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1709           [Define to a macro to generate an assembly function with stdcall calling convention])
1710
1711 dnl **** Platform-specific checks ****
1712
1713 AC_SUBST(LDPATH,"")
1714 case $build_os in
1715   cygwin*|mingw32*)
1716     AC_SUBST(TOOLSEXT,".exe")
1717     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1718     ;;
1719   darwin*|macosx*)
1720     ;;
1721   *)
1722     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1723     ;;
1724 esac
1725
1726 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1727 case $host_os in
1728   mingw32*)
1729     AC_SUBST(CRTLIBS,"-lmsvcrt")
1730     AC_SUBST(SOCKETLIBS,"-L\$(TOPOBJDIR)/dlls/ws2_32 -lws2_32")
1731     ;;
1732 esac
1733
1734 AC_SUBST(MAIN_BINARY,"wine")
1735 test -z "$with_wine64" || MAIN_BINARY="wine32"
1736
1737 case $host_cpu in
1738   *i[[3456789]]86*)
1739     case $host_os in
1740       linux*)
1741         AC_SUBST(EXTRA_BINARIES,"wine-preloader") ;;
1742     esac
1743     ;;
1744 esac
1745
1746 dnl **** Check for functions ****
1747
1748 ac_save_CFLAGS="$CFLAGS"
1749 CFLAGS="$CFLAGS $BUILTINFLAG"
1750 AC_CHECK_FUNCS(\
1751         _pclose \
1752         _popen \
1753         _snprintf \
1754         _spawnvp \
1755         _strdup \
1756         _stricmp \
1757         _strnicmp \
1758         _strtoi64 \
1759         _strtoui64 \
1760         _vsnprintf \
1761         asctime_r \
1762         chsize \
1763         dlopen \
1764         epoll_create \
1765         ffs \
1766         finite \
1767         fnmatch \
1768         fork \
1769         fpclass \
1770         fstatfs \
1771         fstatvfs \
1772         ftruncate \
1773         futimes \
1774         futimesat \
1775         getdirentries \
1776         getopt_long \
1777         getpagesize \
1778         getpwuid \
1779         gettid \
1780         gettimeofday \
1781         getuid \
1782         kqueue \
1783         lstat \
1784         memmove \
1785         mmap \
1786         pclose \
1787         pipe2 \
1788         poll \
1789         popen \
1790         port_create \
1791         prctl \
1792         pread \
1793         pwrite \
1794         readdir \
1795         readlink \
1796         sched_setaffinity \
1797         sched_yield \
1798         select \
1799         setproctitle \
1800         setrlimit \
1801         settimeofday \
1802         sigaltstack \
1803         sigprocmask \
1804         snprintf \
1805         spawnvp \
1806         statfs \
1807         statvfs \
1808         strcasecmp \
1809         strdup \
1810         strerror \
1811         strncasecmp \
1812         strtold \
1813         strtoll \
1814         strtoull \
1815         symlink \
1816         tcgetattr \
1817         thr_kill2 \
1818         timegm \
1819         usleep \
1820         vsnprintf \
1821         wait4 \
1822         waitpid \
1823 )
1824 CFLAGS="$ac_save_CFLAGS"
1825
1826 dnl Check for -ldl
1827 if test "$ac_cv_func_dlopen" = no
1828 then
1829     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1830 fi
1831 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1832
1833 dnl Check for -lpoll for Mac OS X/Darwin
1834 if test "$ac_cv_func_poll" = no
1835 then
1836     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1837 fi
1838
1839 dnl Check for -lnsl for Solaris
1840 AC_SEARCH_LIBS(gethostbyname, nsl)
1841
1842 dnl Check for -lsocket for Solaris
1843 AC_SEARCH_LIBS(connect, socket)
1844
1845 dnl Check for -lresolv for Solaris
1846 AC_SEARCH_LIBS(inet_aton, resolv)
1847
1848 dnl **** Check for functions which may rely on -lsocket on Solaris.
1849 AC_CHECK_FUNCS(\
1850         getaddrinfo \
1851         getnameinfo \
1852         getnetbyname \
1853         getprotobyname \
1854         getprotobynumber \
1855         getservbyport \
1856         inet_network \
1857         inet_ntop \
1858         inet_pton \
1859         sendmsg \
1860         socketpair \
1861 )
1862
1863 dnl **** Check for OpenLDAP ***
1864 AC_SUBST(LDAPLIBS,"")
1865 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
1866 then
1867     AC_CHECK_TYPE(LDAPSortKey,
1868         [AC_CHECK_LIB(ldap_r, ldap_initialize,
1869             [AC_CHECK_LIB(lber, ber_init,
1870                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
1871                  LDAPLIBS="-lldap_r -llber"],,
1872                  [$LIBPTHREAD])],,
1873                  [$LIBPTHREAD])],,
1874         [#include <ldap.h>])
1875     WINE_CHECK_LIB_FUNCS(\
1876         ldap_count_references \
1877         ldap_first_reference \
1878         ldap_next_reference \
1879         ldap_parse_reference \
1880         ldap_parse_sort_control \
1881         ldap_parse_sortresponse_control \
1882         ldap_parse_vlv_control \
1883         ldap_parse_vlvresponse_control,
1884         [$LDAPLIBS $LIBPTHREAD])
1885 fi
1886 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
1887                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
1888
1889 AC_CACHE_CHECK([whether mkdir takes only one argument],
1890         wine_cv_one_arg_mkdir,
1891         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
1892                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
1893 if test "$wine_cv_one_arg_mkdir" = "yes"
1894 then
1895   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
1896 fi
1897
1898 dnl **** Check for types ****
1899
1900 AC_C_CONST
1901 AC_C_INLINE
1902 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1903 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
1904 #include <signal.h>])
1905 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1906
1907 AC_CHECK_TYPES([struct xinpgen],,,
1908 [#include <sys/types.h>
1909 #ifdef HAVE_SYS_SOCKET_H
1910 #include <sys/socket.h>
1911 #endif
1912 #ifdef HAVE_SYS_SOCKETVAR_H
1913 #include <sys/socketvar.h>
1914 #endif
1915 #ifdef HAVE_NET_ROUTE_H
1916 #include <net/route.h>
1917 #endif
1918 #ifdef HAVE_NETINET_IN_H
1919 #include <netinet/in.h>
1920 #endif
1921 #ifdef HAVE_NETINET_IN_SYSTM_H
1922 #include <netinet/in_systm.h>
1923 #endif
1924 #ifdef HAVE_NETINET_IP_H
1925 #include <netinet/ip.h>
1926 #endif
1927 #ifdef HAVE_NETINET_IN_PCB_H
1928 #include <netinet/in_pcb.h>
1929 #endif])
1930
1931 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1932 [#ifdef HAVE_LINUX_INPUT_H
1933 #include <linux/input.h>
1934 #endif])
1935
1936 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1937                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1938 if test "$wine_cv_have_sigaddset" = "yes"
1939 then
1940   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1941 fi
1942
1943
1944 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1945         wine_cv_linux_gethostbyname_r_6,
1946         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1947     char *name=0;
1948     struct hostent he;
1949     struct hostent *result;
1950     char *buf=0;
1951     int bufsize=0;
1952     int res,errnr;
1953     char *addr=0;
1954     int addrlen=0;
1955     int addrtype=0;
1956     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1957     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1958     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1959         ])
1960    )
1961    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1962    then
1963       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1964                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1965    fi
1966
1967 if test "$ac_cv_header_linux_joystick_h" = "yes"
1968 then
1969    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1970         wine_cv_linux_joystick_22_api,
1971         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1972         #include <sys/ioctl.h>
1973         #include <sys/types.h>
1974         #include <linux/joystick.h>
1975
1976         struct js_event blub;
1977         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1978         #error "no 2.2 header"
1979         #endif
1980         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1981    )
1982    if test "$wine_cv_linux_joystick_22_api" = "yes"
1983    then
1984       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1985                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1986    fi
1987 fi
1988
1989 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1990
1991 dnl Check for statfs members
1992 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1993 [#include <sys/types.h>
1994 #ifdef HAVE_SYS_PARAM_H
1995 # include <sys/param.h>
1996 #endif
1997 #ifdef HAVE_SYS_MOUNT_H
1998 # include <sys/mount.h>
1999 #endif
2000 #ifdef HAVE_SYS_VFS_H
2001 # include <sys/vfs.h>
2002 #endif
2003 #ifdef HAVE_SYS_STATFS_H
2004 # include <sys/statfs.h>
2005 #endif])
2006
2007 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2008 [#ifdef HAVE_SYS_STATVFS_H
2009 #include <sys/statvfs.h>
2010 #endif])
2011
2012 dnl Check for socket structure members
2013 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2014 [#include <sys/types.h>
2015 #ifdef HAVE_SYS_SOCKET_H
2016 # include <sys/socket.h>
2017 #endif
2018 #ifdef HAVE_SYS_UN_H
2019 # include <sys/un.h>
2020 #endif])
2021
2022 dnl Check for scsireq_t and sg_io_hdr_t members
2023 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2024 [#include <sys/types.h>
2025 #ifdef HAVE_SCSI_SG_H
2026 #include <scsi/sg.h>
2027 #endif])
2028
2029 dnl Check for siginfo_t members
2030 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2031
2032 dnl Check for struct mtget members
2033 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2034 [#include <sys/types.h>
2035 #ifdef HAVE_SYS_MTIO_H
2036 #include <sys/mtio.h>
2037 #endif])
2038
2039 dnl Check for struct option
2040 AC_CHECK_MEMBERS([struct option.name],,,
2041 [#ifdef HAVE_GETOPT_H
2042 #include <getopt.h>
2043 #endif])
2044
2045 dnl Check for stat.st_blocks and ns-resolved times
2046 AC_CHECK_MEMBERS([struct stat.st_blocks,struct stat.st_mtim,struct stat.st_ctim,struct stat.st_atim])
2047
2048 dnl Check for sin6_scope_id
2049 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2050 [#ifdef HAVE_SYS_TYPES_H
2051 #include <sys/types.h>
2052 #endif
2053 #ifdef HAVE_NETINET_IN_H
2054 #include <netinet/in.h>
2055 #endif])
2056
2057 dnl Check for ns_msg ptr member
2058 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2059 [#ifdef HAVE_SYS_TYPES_H
2060 #include <sys/types.h>
2061 #endif
2062 #ifdef HAVE_NETINET_IN_H
2063 # include <netinet/in.h>
2064 #endif
2065 #ifdef HAVE_ARPA_NAMESER_H
2066 # include <arpa/nameser.h>
2067 #endif])
2068
2069 dnl Check for struct icmpstat.icps_outhist
2070 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2071 [#ifdef HAVE_SYS_TYPES_H
2072 #include <sys/types.h>
2073 #endif
2074 #ifdef HAVE_ALIAS_H
2075 #include <alias.h>
2076 #endif
2077 #ifdef HAVE_SYS_SOCKET_H
2078 #include <sys/socket.h>
2079 #endif
2080 #ifdef HAVE_SYS_SOCKETVAR_H
2081 #include <sys/socketvar.h>
2082 #endif
2083 #ifdef HAVE_SYS_TIMEOUT_H
2084 #include <sys/timeout.h>
2085 #endif
2086 #ifdef HAVE_NETINET_IN_H
2087 #include <netinet/in.h>
2088 #endif
2089 #ifdef HAVE_NETINET_IN_SYSTM_H
2090 #include <netinet/in_systm.h>
2091 #endif
2092 #ifdef HAVE_NETINET_IP_H
2093 #include <netinet/ip.h>
2094 #endif
2095 #ifdef HAVE_NETINET_IP_VAR_H
2096 #include <netinet/ip_var.h>
2097 #endif
2098 #ifdef HAVE_NETINET_IP_ICMP_H
2099 #include <netinet/ip_icmp.h>
2100 #endif
2101 #ifdef HAVE_NETINET_ICMP_VAR
2102 #include <netinet/icmp_var.h>
2103 #endif])
2104
2105 dnl Check for struct ifreq.ifr_hwaddr
2106 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2107 [#ifdef HAVE_SYS_TYPES_H
2108 #include <sys/types.h>
2109 #endif
2110 #ifdef HAVE_NET_IF_H
2111 # include <net/if.h>
2112 #endif])
2113
2114 dnl Check for the external timezone variables timezone and daylight
2115 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2116                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2117 if test "$ac_cv_have_timezone" = "yes"
2118 then
2119     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2120 fi
2121 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2122                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2123 if test "$ac_cv_have_daylight" = "yes"
2124 then
2125     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2126 fi
2127
2128 dnl Check for isinf
2129 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2130                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2131 if test "$ac_cv_have_isinf" = "yes"
2132 then
2133     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2134 fi
2135
2136 dnl Check for isnan
2137 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2138                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2139 if test "$ac_cv_have_isnan" = "yes"
2140 then
2141     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2142 fi
2143
2144 dnl *** check for the need to define platform-specific symbols
2145
2146 case $host_cpu in
2147   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2148   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2149   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
2150   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2151   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2152 esac
2153
2154 case $host_vendor in
2155   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2156 esac
2157
2158 dnl **** Generate output files ****
2159
2160 AH_TOP([#ifndef WINE_CROSSTEST
2161 #define __WINE_CONFIG_H])
2162 AH_BOTTOM([#endif /* WINE_CROSSTEST */])
2163
2164 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2165
2166 WINE_CONFIG_SYMLINK(dlls/wineps.drv/generic.ppd)
2167 WINE_CONFIG_SYMLINK(fonts/marlett.ttf,,enable_fonts)
2168 WINE_CONFIG_SYMLINK(fonts/symbol.ttf,,enable_fonts)
2169 WINE_CONFIG_SYMLINK(fonts/tahoma.ttf,,enable_fonts)
2170 WINE_CONFIG_SYMLINK(fonts/tahomabd.ttf,,enable_fonts)
2171 WINE_CONFIG_SYMLINK(wine,tools/winewrapper)
2172
2173 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2174 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2175 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2176 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2177 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2178 WINE_CONFIG_EXTRA_DIR(include/wine)
2179
2180 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2181 WINE_CONFIG_MAKERULES([Maketest.rules],[MAKE_TEST_RULES],[Make.rules])
2182 WINE_CONFIG_MAKERULES([dlls/Makedll.rules],[MAKE_DLL_RULES],[Make.rules])
2183 WINE_CONFIG_MAKERULES([dlls/Makeimplib.rules],[MAKE_IMPLIB_RULES],[Make.rules])
2184 WINE_CONFIG_MAKERULES([programs/Makeprog.rules],[MAKE_PROG_RULES],[Make.rules])
2185
2186 WINE_CONFIG_DLL(acledit)
2187 WINE_CONFIG_DLL(aclui,,[aclui])
2188 WINE_CONFIG_DLL(activeds,,[activeds])
2189 WINE_CONFIG_DLL(actxprxy)
2190 WINE_CONFIG_LIB(adsiid)
2191 WINE_CONFIG_DLL(advapi32,,[advapi32])
2192 WINE_CONFIG_TEST(dlls/advapi32/tests)
2193 WINE_CONFIG_DLL(advpack,,[advpack])
2194 WINE_CONFIG_TEST(dlls/advpack/tests)
2195 WINE_CONFIG_DLL(amstream)
2196 WINE_CONFIG_TEST(dlls/amstream/tests)
2197 WINE_CONFIG_DLL(appwiz.cpl)
2198 WINE_CONFIG_DLL(atl,,[atl])
2199 WINE_CONFIG_DLL(authz)
2200 WINE_CONFIG_DLL(avicap32,,[avicap32])
2201 WINE_CONFIG_DLL(avifil32,,[avifil32])
2202 WINE_CONFIG_TEST(dlls/avifil32/tests)
2203 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2204 WINE_CONFIG_DLL(avrt,,[avrt])
2205 WINE_CONFIG_DLL(bcrypt)
2206 WINE_CONFIG_DLL(browseui)
2207 WINE_CONFIG_TEST(dlls/browseui/tests)
2208 WINE_CONFIG_DLL(cabinet,,[cabinet])
2209 WINE_CONFIG_TEST(dlls/cabinet/tests)
2210 WINE_CONFIG_DLL(capi2032,,[capi2032])
2211 WINE_CONFIG_DLL(cards,,[cards])
2212 WINE_CONFIG_DLL(cfgmgr32,,[cfgmgr32])
2213 WINE_CONFIG_DLL(clusapi,,[clusapi])
2214 WINE_CONFIG_DLL(comcat)
2215 WINE_CONFIG_TEST(dlls/comcat/tests)
2216 WINE_CONFIG_DLL(comctl32,,[comctl32])
2217 WINE_CONFIG_TEST(dlls/comctl32/tests)
2218 WINE_CONFIG_DLL(comdlg32,,[comdlg32])
2219 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2220 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2221 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2222 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2223 WINE_CONFIG_DLL(compstui,,[compstui])
2224 WINE_CONFIG_DLL(credui,,[credui])
2225 WINE_CONFIG_TEST(dlls/credui/tests)
2226 WINE_CONFIG_DLL(crtdll,,[crtdll])
2227 WINE_CONFIG_DLL(crypt32,,[crypt32])
2228 WINE_CONFIG_TEST(dlls/crypt32/tests)
2229 WINE_CONFIG_DLL(cryptdlg)
2230 WINE_CONFIG_DLL(cryptdll,,[cryptdll])
2231 WINE_CONFIG_DLL(cryptnet,,[cryptnet])
2232 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2233 WINE_CONFIG_DLL(cryptui,,[cryptui])
2234 WINE_CONFIG_TEST(dlls/cryptui/tests)
2235 WINE_CONFIG_DLL(ctapi32)
2236 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2237 WINE_CONFIG_DLL(ctl3d32,,[ctl3d32])
2238 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2239 WINE_CONFIG_DLL(d3d10,,[d3d10])
2240 WINE_CONFIG_TEST(dlls/d3d10/tests)
2241 WINE_CONFIG_DLL(d3d10core,,[d3d10core])
2242 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2243 WINE_CONFIG_DLL(d3d8,,[d3d8])
2244 WINE_CONFIG_TEST(dlls/d3d8/tests)
2245 WINE_CONFIG_DLL(d3d9,,[d3d9])
2246 WINE_CONFIG_TEST(dlls/d3d9/tests)
2247 WINE_CONFIG_DLL(d3dim,,[d3dim])
2248 WINE_CONFIG_DLL(d3drm,,[d3drm])
2249 WINE_CONFIG_TEST(dlls/d3drm/tests)
2250 WINE_CONFIG_DLL(d3dx9_24)
2251 WINE_CONFIG_DLL(d3dx9_25)
2252 WINE_CONFIG_DLL(d3dx9_26)
2253 WINE_CONFIG_DLL(d3dx9_27)
2254 WINE_CONFIG_DLL(d3dx9_28)
2255 WINE_CONFIG_DLL(d3dx9_29)
2256 WINE_CONFIG_DLL(d3dx9_30)
2257 WINE_CONFIG_DLL(d3dx9_31)
2258 WINE_CONFIG_DLL(d3dx9_32)
2259 WINE_CONFIG_DLL(d3dx9_33)
2260 WINE_CONFIG_DLL(d3dx9_34)
2261 WINE_CONFIG_DLL(d3dx9_35)
2262 WINE_CONFIG_DLL(d3dx9_36,,[d3dx9])
2263 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2264 WINE_CONFIG_DLL(d3dx9_37)
2265 WINE_CONFIG_DLL(d3dx9_38)
2266 WINE_CONFIG_DLL(d3dx9_39)
2267 WINE_CONFIG_DLL(d3dx9_40)
2268 WINE_CONFIG_DLL(d3dx9_41)
2269 WINE_CONFIG_DLL(d3dx9_42)
2270 WINE_CONFIG_DLL(d3dxof,,[d3dxof])
2271 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2272 WINE_CONFIG_DLL(dbghelp,,[dbghelp])
2273 WINE_CONFIG_DLL(dciman32,,[dciman32])
2274 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2275 WINE_CONFIG_DLL(ddraw,,[ddraw])
2276 WINE_CONFIG_TEST(dlls/ddraw/tests)
2277 WINE_CONFIG_DLL(ddrawex)
2278 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2279 WINE_CONFIG_DLL(devenum)
2280 WINE_CONFIG_DLL(dinput,,[dinput],[data_formats.c])
2281 WINE_CONFIG_TEST(dlls/dinput/tests)
2282 WINE_CONFIG_DLL(dinput8,,[dinput8])
2283 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2284 WINE_CONFIG_DLL(dispex)
2285 WINE_CONFIG_TEST(dlls/dispex/tests)
2286 WINE_CONFIG_DLL(display.drv16,enable_win16)
2287 WINE_CONFIG_DLL(dmband)
2288 WINE_CONFIG_DLL(dmcompos)
2289 WINE_CONFIG_DLL(dmime)
2290 WINE_CONFIG_DLL(dmloader)
2291 WINE_CONFIG_TEST(dlls/dmloader/tests)
2292 WINE_CONFIG_DLL(dmscript)
2293 WINE_CONFIG_DLL(dmstyle)
2294 WINE_CONFIG_DLL(dmsynth)
2295 WINE_CONFIG_DLL(dmusic)
2296 WINE_CONFIG_DLL(dmusic32,,[dmusic32])
2297 WINE_CONFIG_DLL(dnsapi,,[dnsapi])
2298 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2299 WINE_CONFIG_DLL(dplay,,[dplay])
2300 WINE_CONFIG_DLL(dplayx,,[dplayx])
2301 WINE_CONFIG_TEST(dlls/dplayx/tests)
2302 WINE_CONFIG_DLL(dpnaddr)
2303 WINE_CONFIG_DLL(dpnet,,[dpnet])
2304 WINE_CONFIG_DLL(dpnhpast)
2305 WINE_CONFIG_DLL(dpnlobby)
2306 WINE_CONFIG_DLL(dpwsockx)
2307 WINE_CONFIG_DLL(drmclien)
2308 WINE_CONFIG_DLL(dsound,,[dsound])
2309 WINE_CONFIG_TEST(dlls/dsound/tests)
2310 WINE_CONFIG_DLL(dssenh)
2311 WINE_CONFIG_DLL(dswave)
2312 WINE_CONFIG_DLL(dwmapi,,[dwmapi])
2313 WINE_CONFIG_DLL(dxdiagn)
2314 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2315 WINE_CONFIG_LIB(dxerr8)
2316 WINE_CONFIG_LIB(dxerr9)
2317 WINE_CONFIG_DLL(dxgi,,[dxgi])
2318 WINE_CONFIG_TEST(dlls/dxgi/tests)
2319 WINE_CONFIG_LIB(dxguid)
2320 WINE_CONFIG_DLL(faultrep)
2321 WINE_CONFIG_DLL(fltlib)
2322 WINE_CONFIG_DLL(fusion)
2323 WINE_CONFIG_TEST(dlls/fusion/tests)
2324 WINE_CONFIG_DLL(fwpuclnt)
2325 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2326 WINE_CONFIG_DLL(gdi32,,[gdi32])
2327 WINE_CONFIG_TEST(dlls/gdi32/tests)
2328 WINE_CONFIG_DLL(gdiplus,,[gdiplus])
2329 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2330 WINE_CONFIG_DLL(glu32,,[glu32])
2331 WINE_CONFIG_DLL(gphoto2.ds)
2332 WINE_CONFIG_DLL(gpkcsp)
2333 WINE_CONFIG_DLL(hal)
2334 WINE_CONFIG_DLL(hhctrl.ocx)
2335 WINE_CONFIG_DLL(hid,,[hid])
2336 WINE_CONFIG_DLL(hlink,,[hlink])
2337 WINE_CONFIG_TEST(dlls/hlink/tests)
2338 WINE_CONFIG_DLL(hnetcfg)
2339 WINE_CONFIG_DLL(httpapi)
2340 WINE_CONFIG_DLL(iccvid)
2341 WINE_CONFIG_DLL(icmp)
2342 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2343 WINE_CONFIG_DLL(imaadp32.acm)
2344 WINE_CONFIG_DLL(imagehlp,,[imagehlp])
2345 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2346 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2347 WINE_CONFIG_DLL(imm32,,[imm32])
2348 WINE_CONFIG_TEST(dlls/imm32/tests)
2349 WINE_CONFIG_DLL(inetcomm,,[inetcomm])
2350 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2351 WINE_CONFIG_DLL(inetmib1)
2352 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2353 WINE_CONFIG_DLL(infosoft)
2354 WINE_CONFIG_TEST(dlls/infosoft/tests)
2355 WINE_CONFIG_DLL(initpki)
2356 WINE_CONFIG_DLL(inkobj)
2357 WINE_CONFIG_DLL(inseng)
2358 WINE_CONFIG_DLL(iphlpapi,,[iphlpapi])
2359 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2360 WINE_CONFIG_DLL(itircl)
2361 WINE_CONFIG_DLL(itss)
2362 WINE_CONFIG_TEST(dlls/itss/tests)
2363 WINE_CONFIG_DLL(jscript)
2364 WINE_CONFIG_TEST(dlls/jscript/tests)
2365 WINE_CONFIG_DLL(kernel32,,[kernel32])
2366 WINE_CONFIG_TEST(dlls/kernel32/tests)
2367 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2368 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[kernel])
2369 WINE_CONFIG_DLL(loadperf,,[loadperf])
2370 WINE_CONFIG_DLL(localspl)
2371 WINE_CONFIG_TEST(dlls/localspl/tests)
2372 WINE_CONFIG_DLL(localui)
2373 WINE_CONFIG_TEST(dlls/localui/tests)
2374 WINE_CONFIG_DLL(lz32,,[lz32])
2375 WINE_CONFIG_TEST(dlls/lz32/tests)
2376 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2377 WINE_CONFIG_DLL(mapi32,,[mapi32])
2378 WINE_CONFIG_TEST(dlls/mapi32/tests)
2379 WINE_CONFIG_DLL(mapistub)
2380 WINE_CONFIG_DLL(mciavi32)
2381 WINE_CONFIG_DLL(mcicda)
2382 WINE_CONFIG_DLL(mciqtz32)
2383 WINE_CONFIG_DLL(mciseq)
2384 WINE_CONFIG_DLL(mciwave)
2385 WINE_CONFIG_DLL(midimap)
2386 WINE_CONFIG_DLL(mlang,,[mlang])
2387 WINE_CONFIG_TEST(dlls/mlang/tests)
2388 WINE_CONFIG_DLL(mmdevapi)
2389 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2390 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2391 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2392 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2393 WINE_CONFIG_DLL(mountmgr.sys)
2394 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2395 WINE_CONFIG_DLL(mpr,,[mpr])
2396 WINE_CONFIG_DLL(mprapi,,[mprapi])
2397 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2398 WINE_CONFIG_DLL(msacm32.drv)
2399 WINE_CONFIG_DLL(msacm32,,[msacm32])
2400 WINE_CONFIG_TEST(dlls/msacm32/tests)
2401 WINE_CONFIG_DLL(msadp32.acm)
2402 WINE_CONFIG_DLL(mscat32)
2403 WINE_CONFIG_DLL(mscms,,[mscms])
2404 WINE_CONFIG_TEST(dlls/mscms/tests)
2405 WINE_CONFIG_DLL(mscoree)
2406 WINE_CONFIG_DLL(msctf)
2407 WINE_CONFIG_TEST(dlls/msctf/tests)
2408 WINE_CONFIG_DLL(msdaps)
2409 WINE_CONFIG_DLL(msdmo,,[msdmo])
2410 WINE_CONFIG_DLL(msftedit)
2411 WINE_CONFIG_DLL(msg711.acm)
2412 WINE_CONFIG_DLL(msgsm32.acm)
2413 WINE_CONFIG_DLL(mshtml.tlb)
2414 WINE_CONFIG_DLL(mshtml,,[mshtml])
2415 WINE_CONFIG_TEST(dlls/mshtml/tests)
2416 WINE_CONFIG_DLL(msi,,[msi])
2417 WINE_CONFIG_TEST(dlls/msi/tests)
2418 WINE_CONFIG_DLL(msimg32,,[msimg32])
2419 WINE_CONFIG_DLL(msimtf)
2420 WINE_CONFIG_DLL(msisip)
2421 WINE_CONFIG_DLL(msisys.ocx)
2422 WINE_CONFIG_DLL(msnet32)
2423 WINE_CONFIG_DLL(msrle32)
2424 WINE_CONFIG_DLL(mssign32)
2425 WINE_CONFIG_DLL(mssip32)
2426 WINE_CONFIG_DLL(mstask)
2427 WINE_CONFIG_TEST(dlls/mstask/tests)
2428 WINE_CONFIG_DLL(msvcirt)
2429 WINE_CONFIG_DLL(msvcr70,,[msvcr70])
2430 WINE_CONFIG_DLL(msvcr71,,[msvcr71])
2431 WINE_CONFIG_DLL(msvcr80)
2432 WINE_CONFIG_DLL(msvcr90)
2433 WINE_CONFIG_TEST(dlls/msvcr90/tests)
2434 WINE_CONFIG_DLL(msvcrt,,[msvcrt])
2435 WINE_CONFIG_TEST(dlls/msvcrt/tests)
2436 WINE_CONFIG_DLL(msvcrt20,,[msvcrt20])
2437 WINE_CONFIG_DLL(msvcrt40,,[msvcrt40])
2438 WINE_CONFIG_DLL(msvcrtd,,[msvcrtd])
2439 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
2440 WINE_CONFIG_DLL(msvfw32,,[msvfw32])
2441 WINE_CONFIG_TEST(dlls/msvfw32/tests)
2442 WINE_CONFIG_DLL(msvidc32)
2443 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
2444 WINE_CONFIG_DLL(mswsock,,[mswsock])
2445 WINE_CONFIG_DLL(msxml3)
2446 WINE_CONFIG_TEST(dlls/msxml3/tests)
2447 WINE_CONFIG_DLL(msxml4)
2448 WINE_CONFIG_DLL(nddeapi,,[nddeapi])
2449 WINE_CONFIG_DLL(netapi32,,[netapi32])
2450 WINE_CONFIG_TEST(dlls/netapi32/tests)
2451 WINE_CONFIG_DLL(newdev,,[newdev])
2452 WINE_CONFIG_DLL(ntdll,,[ntdll])
2453 WINE_CONFIG_TEST(dlls/ntdll/tests)
2454 WINE_CONFIG_DLL(ntdsapi,,[ntdsapi])
2455 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
2456 WINE_CONFIG_DLL(ntoskrnl.exe,,[ntoskrnl.exe])
2457 WINE_CONFIG_DLL(ntprint)
2458 WINE_CONFIG_TEST(dlls/ntprint/tests)
2459 WINE_CONFIG_DLL(objsel)
2460 WINE_CONFIG_DLL(odbc32,,[odbc32])
2461 WINE_CONFIG_DLL(odbccp32,,[odbccp32])
2462 WINE_CONFIG_TEST(dlls/odbccp32/tests)
2463 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
2464 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
2465 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
2466 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
2467 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
2468 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
2469 WINE_CONFIG_DLL(ole32,,[ole32])
2470 WINE_CONFIG_TEST(dlls/ole32/tests)
2471 WINE_CONFIG_DLL(oleacc,,[oleacc])
2472 WINE_CONFIG_TEST(dlls/oleacc/tests)
2473 WINE_CONFIG_DLL(oleaut32,,[oleaut32])
2474 WINE_CONFIG_TEST(dlls/oleaut32/tests)
2475 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
2476 WINE_CONFIG_DLL(olecli32,,[olecli32])
2477 WINE_CONFIG_DLL(oledb32)
2478 WINE_CONFIG_TEST(dlls/oledb32/tests)
2479 WINE_CONFIG_DLL(oledlg,,[oledlg])
2480 WINE_CONFIG_DLL(olepro32,,[olepro32])
2481 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
2482 WINE_CONFIG_DLL(olesvr32,,[olesvr32])
2483 WINE_CONFIG_DLL(olethk32)
2484 WINE_CONFIG_DLL(openal32)
2485 WINE_CONFIG_DLL(opengl32,,[opengl32])
2486 WINE_CONFIG_TEST(dlls/opengl32/tests)
2487 WINE_CONFIG_DLL(pdh,,[pdh])
2488 WINE_CONFIG_TEST(dlls/pdh/tests)
2489 WINE_CONFIG_DLL(pidgen)
2490 WINE_CONFIG_DLL(powrprof,,[powrprof])
2491 WINE_CONFIG_DLL(printui)
2492 WINE_CONFIG_DLL(propsys)
2493 WINE_CONFIG_DLL(psapi,,[psapi])
2494 WINE_CONFIG_TEST(dlls/psapi/tests)
2495 WINE_CONFIG_DLL(pstorec)
2496 WINE_CONFIG_DLL(qcap)
2497 WINE_CONFIG_DLL(qedit)
2498 WINE_CONFIG_TEST(dlls/qedit/tests)
2499 WINE_CONFIG_DLL(qmgr)
2500 WINE_CONFIG_TEST(dlls/qmgr/tests)
2501 WINE_CONFIG_DLL(qmgrprxy)
2502 WINE_CONFIG_DLL(quartz,,[quartz])
2503 WINE_CONFIG_TEST(dlls/quartz/tests)
2504 WINE_CONFIG_DLL(query)
2505 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
2506 WINE_CONFIG_DLL(rasapi32,,[rasapi32])
2507 WINE_CONFIG_TEST(dlls/rasapi32/tests)
2508 WINE_CONFIG_DLL(rasdlg,,[rasdlg])
2509 WINE_CONFIG_DLL(resutils,,[resutils])
2510 WINE_CONFIG_DLL(riched20,,[riched20])
2511 WINE_CONFIG_TEST(dlls/riched20/tests)
2512 WINE_CONFIG_DLL(riched32)
2513 WINE_CONFIG_TEST(dlls/riched32/tests)
2514 WINE_CONFIG_DLL(rpcrt4,,[rpcrt4])
2515 WINE_CONFIG_TEST(dlls/rpcrt4/tests)
2516 WINE_CONFIG_DLL(rsabase)
2517 WINE_CONFIG_DLL(rsaenh,,[rsaenh])
2518 WINE_CONFIG_TEST(dlls/rsaenh/tests)
2519 WINE_CONFIG_DLL(rtutils,,[rtutils])
2520 WINE_CONFIG_DLL(sane.ds)
2521 WINE_CONFIG_DLL(sccbase)
2522 WINE_CONFIG_DLL(schannel)
2523 WINE_CONFIG_TEST(dlls/schannel/tests)
2524 WINE_CONFIG_DLL(secur32,,[secur32])
2525 WINE_CONFIG_TEST(dlls/secur32/tests)
2526 WINE_CONFIG_DLL(security)
2527 WINE_CONFIG_DLL(sensapi,,[sensapi])
2528 WINE_CONFIG_DLL(serialui,,[serialui])
2529 WINE_CONFIG_TEST(dlls/serialui/tests)
2530 WINE_CONFIG_DLL(setupapi,,[setupapi])
2531 WINE_CONFIG_TEST(dlls/setupapi/tests)
2532 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
2533 WINE_CONFIG_DLL(sfc,,[sfc])
2534 WINE_CONFIG_DLL(sfc_os,,[sfc_os])
2535 WINE_CONFIG_DLL(shdoclc)
2536 WINE_CONFIG_DLL(shdocvw,,[shdocvw])
2537 WINE_CONFIG_TEST(dlls/shdocvw/tests)
2538 WINE_CONFIG_DLL(shell.dll16,enable_win16)
2539 WINE_CONFIG_DLL(shell32,,[shell32])
2540 WINE_CONFIG_TEST(dlls/shell32/tests)
2541 WINE_CONFIG_DLL(shfolder,,[shfolder])
2542 WINE_CONFIG_DLL(shlwapi,,[shlwapi])
2543 WINE_CONFIG_TEST(dlls/shlwapi/tests)
2544 WINE_CONFIG_DLL(slbcsp)
2545 WINE_CONFIG_DLL(slc,,[slc])
2546 WINE_CONFIG_DLL(snmpapi,,[snmpapi])
2547 WINE_CONFIG_TEST(dlls/snmpapi/tests)
2548 WINE_CONFIG_DLL(softpub)
2549 WINE_CONFIG_DLL(sound.drv16,enable_win16)
2550 WINE_CONFIG_DLL(spoolss,,[spoolss])
2551 WINE_CONFIG_TEST(dlls/spoolss/tests)
2552 WINE_CONFIG_DLL(stdole2.tlb)
2553 WINE_CONFIG_DLL(stdole32.tlb)
2554 WINE_CONFIG_DLL(sti,,[sti])
2555 WINE_CONFIG_TEST(dlls/sti/tests)
2556 WINE_CONFIG_DLL(storage.dll16,enable_win16)
2557 WINE_CONFIG_DLL(stress.dll16,enable_win16)
2558 WINE_CONFIG_LIB(strmiids)
2559 WINE_CONFIG_DLL(svrapi)
2560 WINE_CONFIG_DLL(sxs)
2561 WINE_CONFIG_DLL(system.drv16,enable_win16)
2562 WINE_CONFIG_DLL(t2embed)
2563 WINE_CONFIG_DLL(tapi32,,[tapi32])
2564 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
2565 WINE_CONFIG_DLL(traffic)
2566 WINE_CONFIG_DLL(twain.dll16,enable_win16)
2567 WINE_CONFIG_DLL(twain_32)
2568 WINE_CONFIG_TEST(dlls/twain_32/tests)
2569 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
2570 WINE_CONFIG_DLL(unicows,,[unicows])
2571 WINE_CONFIG_DLL(updspapi)
2572 WINE_CONFIG_DLL(url,,[url])
2573 WINE_CONFIG_DLL(urlmon,,[urlmon])
2574 WINE_CONFIG_TEST(dlls/urlmon/tests)
2575 WINE_CONFIG_DLL(usbd.sys,,[usbd.sys])
2576 WINE_CONFIG_DLL(user.exe16,enable_win16)
2577 WINE_CONFIG_DLL(user32,,[user32])
2578 WINE_CONFIG_TEST(dlls/user32/tests)
2579 WINE_CONFIG_DLL(userenv,,[userenv])
2580 WINE_CONFIG_TEST(dlls/userenv/tests)
2581 WINE_CONFIG_DLL(usp10,,[usp10])
2582 WINE_CONFIG_TEST(dlls/usp10/tests)
2583 WINE_CONFIG_LIB(uuid)
2584 WINE_CONFIG_DLL(uxtheme,,[uxtheme])
2585 WINE_CONFIG_TEST(dlls/uxtheme/tests)
2586 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
2587 WINE_CONFIG_DLL(vdmdbg,,[vdmdbg])
2588 WINE_CONFIG_DLL(ver.dll16,enable_win16)
2589 WINE_CONFIG_DLL(version,,[version])
2590 WINE_CONFIG_TEST(dlls/version/tests)
2591 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
2592 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
2593 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
2594 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
2595 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
2596 WINE_CONFIG_DLL(w32skrnl,enable_win16)
2597 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
2598 WINE_CONFIG_DLL(wbemprox)
2599 WINE_CONFIG_DLL(wiaservc)
2600 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
2601 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
2602 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
2603 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
2604 WINE_CONFIG_DLL(windowscodecs,,[windowscodecs])
2605 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
2606 WINE_CONFIG_DLL(winealsa.drv)
2607 WINE_CONFIG_DLL(wineaudioio.drv)
2608 WINE_CONFIG_DLL(winecoreaudio.drv)
2609 WINE_CONFIG_LIB(winecrt0)
2610 WINE_CONFIG_DLL(wined3d,,[wined3d])
2611 WINE_CONFIG_DLL(wineesd.drv)
2612 WINE_CONFIG_DLL(winejack.drv)
2613 WINE_CONFIG_DLL(winejoystick.drv)
2614 WINE_CONFIG_DLL(winemapi)
2615 WINE_CONFIG_DLL(winemp3.acm)
2616 WINE_CONFIG_DLL(winenas.drv)
2617 WINE_CONFIG_DLL(wineoss.drv)
2618 WINE_CONFIG_DLL(wineps.drv)
2619 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
2620 WINE_CONFIG_DLL(winequartz.drv)
2621 WINE_CONFIG_DLL(winex11.drv)
2622 WINE_CONFIG_DLL(wing.dll16,enable_win16)
2623 WINE_CONFIG_DLL(wing32)
2624 WINE_CONFIG_DLL(winhttp,,[winhttp])
2625 WINE_CONFIG_TEST(dlls/winhttp/tests)
2626 WINE_CONFIG_DLL(wininet,,[wininet])
2627 WINE_CONFIG_TEST(dlls/wininet/tests)
2628 WINE_CONFIG_DLL(winmm,,[winmm])
2629 WINE_CONFIG_TEST(dlls/winmm/tests)
2630 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
2631 WINE_CONFIG_DLL(winnls32,,[winnls32])
2632 WINE_CONFIG_DLL(winscard,,[winscard])
2633 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
2634 WINE_CONFIG_DLL(winspool.drv,,[winspool])
2635 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
2636 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
2637 WINE_CONFIG_DLL(wintab32,,[wintab32])
2638 WINE_CONFIG_TEST(dlls/wintab32/tests)
2639 WINE_CONFIG_DLL(wintrust,,[wintrust])
2640 WINE_CONFIG_TEST(dlls/wintrust/tests)
2641 WINE_CONFIG_DLL(wldap32,,[wldap32])
2642 WINE_CONFIG_TEST(dlls/wldap32/tests)
2643 WINE_CONFIG_DLL(wmi)
2644 WINE_CONFIG_DLL(wmiutils)
2645 WINE_CONFIG_DLL(wnaspi32,,[wnaspi32])
2646 WINE_CONFIG_DLL(wow32,enable_win16,[wow32])
2647 WINE_CONFIG_DLL(ws2_32,,[ws2_32])
2648 WINE_CONFIG_TEST(dlls/ws2_32/tests)
2649 WINE_CONFIG_DLL(wsock32,,[wsock32])
2650 WINE_CONFIG_DLL(wtsapi32,,[wtsapi32])
2651 WINE_CONFIG_DLL(wuapi)
2652 WINE_CONFIG_DLL(wuaueng)
2653 WINE_CONFIG_DLL(xinput1_1)
2654 WINE_CONFIG_DLL(xinput1_2)
2655 WINE_CONFIG_DLL(xinput1_3,,[xinput])
2656 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
2657 WINE_CONFIG_DLL(xinput9_1_0)
2658 WINE_CONFIG_DLL(xmllite)
2659 WINE_CONFIG_TEST(dlls/xmllite/tests)
2660 WINE_CONFIG_MAKEFILE([documentation])
2661 WINE_CONFIG_MAKEFILE([fonts])
2662 WINE_CONFIG_MAKEFILE([include])
2663 WINE_CONFIG_MAKEFILE([libs/port])
2664 WINE_CONFIG_MAKEFILE([libs/wine])
2665 WINE_CONFIG_MAKEFILE([libs/wpp])
2666 WINE_CONFIG_MAKEFILE([loader])
2667 WINE_CONFIG_PROGRAM(attrib,install)
2668 WINE_CONFIG_PROGRAM(cacls,install)
2669 WINE_CONFIG_PROGRAM(clock,install)
2670 WINE_CONFIG_PROGRAM(cmd,install)
2671 WINE_CONFIG_TEST(programs/cmd/tests)
2672 WINE_CONFIG_PROGRAM(cmdlgtst)
2673 WINE_CONFIG_PROGRAM(control,install)
2674 WINE_CONFIG_PROGRAM(dxdiag,install)
2675 WINE_CONFIG_PROGRAM(eject,install)
2676 WINE_CONFIG_PROGRAM(expand,install)
2677 WINE_CONFIG_PROGRAM(explorer,install)
2678 WINE_CONFIG_PROGRAM(extrac32,install)
2679 WINE_CONFIG_PROGRAM(hh,install)
2680 WINE_CONFIG_PROGRAM(icinfo,install)
2681 WINE_CONFIG_PROGRAM(iexplore,install)
2682 WINE_CONFIG_PROGRAM(lodctr,install)
2683 WINE_CONFIG_PROGRAM(mshta,install)
2684 WINE_CONFIG_PROGRAM(msiexec,installbin)
2685 WINE_CONFIG_PROGRAM(net,install)
2686 WINE_CONFIG_PROGRAM(ngen,install)
2687 WINE_CONFIG_PROGRAM(notepad,installbin)
2688 WINE_CONFIG_PROGRAM(oleview,install)
2689 WINE_CONFIG_PROGRAM(ping,install)
2690 WINE_CONFIG_PROGRAM(progman,install)
2691 WINE_CONFIG_PROGRAM(reg,install)
2692 WINE_CONFIG_PROGRAM(regedit,installbin)
2693 WINE_CONFIG_PROGRAM(regsvr32,installbin)
2694 WINE_CONFIG_PROGRAM(rpcss,install)
2695 WINE_CONFIG_PROGRAM(rundll32,install)
2696 WINE_CONFIG_PROGRAM(secedit,install)
2697 WINE_CONFIG_PROGRAM(services,install)
2698 WINE_CONFIG_PROGRAM(spoolsv,install)
2699 WINE_CONFIG_PROGRAM(start,install)
2700 WINE_CONFIG_PROGRAM(svchost,install)
2701 WINE_CONFIG_PROGRAM(taskmgr,install)
2702 WINE_CONFIG_PROGRAM(termsv,install)
2703 WINE_CONFIG_PROGRAM(uninstaller,install)
2704 WINE_CONFIG_PROGRAM(unlodctr,install)
2705 WINE_CONFIG_PROGRAM(view)
2706 WINE_CONFIG_PROGRAM(wineboot,installbin)
2707 WINE_CONFIG_PROGRAM(winebrowser,install)
2708 WINE_CONFIG_PROGRAM(winecfg,installbin)
2709 WINE_CONFIG_PROGRAM(wineconsole,installbin)
2710 WINE_CONFIG_PROGRAM(winedbg,installbin)
2711 WINE_CONFIG_PROGRAM(winedevice,install)
2712 WINE_CONFIG_PROGRAM(winefile,installbin)
2713 WINE_CONFIG_PROGRAM(winemenubuilder,install)
2714 WINE_CONFIG_PROGRAM(winemine,installbin)
2715 WINE_CONFIG_PROGRAM(winepath,installbin)
2716 WINE_CONFIG_PROGRAM(winetest)
2717 WINE_CONFIG_PROGRAM(winevdm,install,enable_win16)
2718 WINE_CONFIG_PROGRAM(winhelp.exe16,install,enable_win16)
2719 WINE_CONFIG_PROGRAM(winhlp32,install)
2720 WINE_CONFIG_PROGRAM(winoldap.mod16,install,enable_win16)
2721 WINE_CONFIG_PROGRAM(winver,install)
2722 WINE_CONFIG_PROGRAM(wordpad,install)
2723 WINE_CONFIG_PROGRAM(write,install)
2724 WINE_CONFIG_PROGRAM(xcopy,install)
2725 WINE_CONFIG_MAKEFILE([server])
2726 WINE_CONFIG_TOOL(tools)
2727 WINE_CONFIG_TOOL(tools/widl)
2728 WINE_CONFIG_TOOL(tools/winebuild)
2729 WINE_CONFIG_TOOL(tools/winedump)
2730 WINE_CONFIG_TOOL(tools/winegcc)
2731 WINE_CONFIG_TOOL(tools/wmc)
2732 WINE_CONFIG_TOOL(tools/wrc)
2733 dnl End of auto-generated output commands
2734
2735 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
2736 [wine_fn_output_makefile ()
2737 {
2738     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
2739 $ALL_MAKEFILE_DEPENDS
2740 _WINE_EOF
2741     AS_ERROR([could not create Makefile])
2742 }])
2743
2744 AC_CONFIG_FILES([Make.tmp:Makefile.in])
2745
2746 dnl Some final makefile rules
2747
2748 if test -n "$with_wine64"
2749 then
2750 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
2751 [all: fonts server $with_wine64/loader/wine32
2752 fonts server:
2753         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
2754 $with_wine64/loader/wine32:
2755         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine32 \$[@]
2756 clean::
2757         \$(RM) fonts server $with_wine64/loader/wine32])
2758 fi
2759
2760 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
2761 [uninstall::
2762         -rmdir \$(DESTDIR)\$(datadir)/wine \$(DESTDIR)\$(fakedlldir) \$(DESTDIR)\$(dlldir)])
2763
2764 AC_OUTPUT
2765
2766 if test "$no_create" = "yes"
2767 then
2768   exit 0
2769 fi
2770
2771 WINE_PRINT_MESSAGES
2772
2773 echo "
2774 $as_me: Finished.  Do '${ac_make}' to compile Wine.
2775 " >&AS_MESSAGE_FD
2776
2777 dnl Local Variables:
2778 dnl comment-start: "dnl "
2779 dnl comment-end: ""
2780 dnl comment-start-skip: "\\bdnl\\b\\s *"
2781 dnl compile-command: "autoreconf --warnings=all"
2782 dnl End: