git.oblomov.eu Git - wine/blob - programs/winedbg/debug.l

   1 /* -*-C-*-
   2  * Lexical scanner for command line parsing
   3  *
   4  * Copyright 1993 Eric Youngdale
   5  *           2000 Eric Pouech
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 %{
  23 #include <stdlib.h>
  24 #include <string.h>
  25 #include "winbase.h"
  26 #include "wincon.h"
  27 #include "debugger.h"
  28 #include "y.tab.h"
  29
  30 #undef YY_INPUT
  31
  32 HANDLE DEBUG_hParserInput;
  33 HANDLE DEBUG_hParserOutput;
  34
  35 static int DEBUG_FetchFromLine(const char* pfx, char* buf, int size);
  36
  37 #define YY_INPUT(buf,result,max_size) \
  38         if ( (result = DEBUG_FetchFromLine("Wine-dbg>", buf, max_size)) < 0 ) \
  39             YY_FATAL_ERROR( "FetchFromLine() in flex scanner failed" );
  40
  41 #define YY_NO_UNPUT
  42
  43 static int syntax_error;
  44 %}
  45
  46 DIGIT      [0-9]
  47 HEXDIGIT   [0-9a-fA-F]
  48 FORMAT     [ubcdgiswx]
  49 IDENTIFIER [_a-zA-Z~][_a-zA-Z0-9~@]*
  50 PATHNAME   [/_a-zA-Z\.~][/_a-zA-Z0-9\.~@]*
  51 STRING     \"[^\n"]+\"
  52
  53 %s FORMAT_EXPECTED
  54 %s PATH_EXPECTED
  55 %s INFO_CMD
  56 %s HELP_CMD
  57 %s DEL_CMD
  58 %s WALK_CMD
  59 %s SHOW_CMD
  60 %s MODE_CMD
  61 %s NOCMD
  62
  63 %x ASTRING_EXPECTED
  64 %x NOPROCESS
  65 %%
  66                                         /* set to special state when no process is loaded. */
  67                                         if (!DEBUG_CurrProcess && YYSTATE == INITIAL) {BEGIN(NOPROCESS);}
  68
  69 <<EOF>>                                 { return tEOF; }
  70 <*>\n                                   { BEGIN(INITIAL); syntax_error = 0; return tEOL; }
  71                                         /* Indicates end of command. Reset state. */
  72
  73 "||"                                    { return OP_LOR; }
  74 "&&"                                    { return OP_LAND; }
  75 "=="                                    { return OP_EQ; }
  76 "!="                                    { return OP_NE; }
  77 "<="                                    { return OP_LE; }
  78 ">="                                    { return OP_GE; }
  79 "<<"                                    { return OP_SHL; }
  80 ">>"                                    { return OP_SHR; }
  81 "->"                                    { return OP_DRF; }
  82 [-+<=>|&^()*/%:!~,\.]                   { return *yytext; }
  83 "["                                     { return *yytext; }
  84 "]"                                     { return *yytext; }
  85
  86 "0x"{HEXDIGIT}+                         { sscanf(yytext, "%x", &yylval.integer); return tNUM; }
  87 {DIGIT}+                                { sscanf(yytext, "%d", &yylval.integer); return tNUM; }
  88
  89 <FORMAT_EXPECTED>"/"{DIGIT}+{FORMAT}    { char* last;
  90                                           yylval.integer = strtol( yytext+1, &last, 0 ) << 8;
  91                                           yylval.integer |= *last;
  92                                           return tFORMAT; }
  93
  94 <FORMAT_EXPECTED>"/"{FORMAT}            { yylval.integer = (1 << 8) | yytext[1]; return tFORMAT; }
  95
  96 {STRING}                                { yylval.string = DEBUG_MakeSymbol(yytext); return tSTRING; }
  97 <ASTRING_EXPECTED>[^\n]+                { char* p = yytext; while (*p == ' ' || *p == '\t') p++;
  98                                           yylval.string = DEBUG_MakeSymbol(p); return tSTRING; }
  99
 100 <INITIAL>info|inf|in                    { BEGIN(INFO_CMD); return tINFO; }
 101 <INITIAL>up                             { BEGIN(NOCMD); return tUP; }
 102 <INITIAL>down|dow|do                    { BEGIN(NOCMD); return tDOWN; }
 103 <INITIAL>frame|fram|fra|fr              { BEGIN(NOCMD); return tFRAME; }
 104 <INITIAL>list|lis|li|l                  { BEGIN(PATH_EXPECTED); return tLIST; }
 105 <INITIAL>enable|enabl|enab|ena          { BEGIN(NOCMD); return tENABLE;}
 106 <INITIAL>disable|disabl|disab|disa|dis  { BEGIN(NOCMD); return tDISABLE; }
 107 <INITIAL>disassemble|disassembl|disassemb|disassem|disasse|disass|disas { BEGIN(NOCMD); return tDISASSEMBLE; }
 108 <INITIAL,INFO_CMD,DEL_CMD>display|displa|displ|disp     { BEGIN(FORMAT_EXPECTED); return tDISPLAY; }
 109 <INITIAL>undisplay|undispla|undispl|undisp|undis|undi|und       { BEGIN(NOCMD); return tUNDISPLAY; }
 110 <INITIAL>delete|delet|dele|del          { BEGIN(DEL_CMD); return tDELETE; }
 111 <INITIAL,NOPROCESS>quit|qui|qu|q        { BEGIN(NOCMD); return tQUIT; }
 112 <INITIAL>set|se                         { BEGIN(NOCMD); return tSET; }
 113 <INITIAL,NOPROCESS>walk|w               { BEGIN(WALK_CMD); return tWALK; }
 114 <INITIAL>x                              { BEGIN(FORMAT_EXPECTED); return tEXAM; }
 115 <INITIAL,NOPROCESS>help|hel|he|"?"              { BEGIN(HELP_CMD); return tHELP; }
 116
 117 <INITIAL>backtrace|backtrac|backtra|backt|back|bac|ba|bt { BEGIN(NOCMD); return tBACKTRACE; }
 118 <INITIAL>where|wher|whe                 { BEGIN(NOCMD); return tBACKTRACE; }
 119
 120 <INITIAL>cont|con|co|c                  { BEGIN(NOCMD); return tCONT; }
 121 <INITIAL>pass|pas|pa                    { BEGIN(NOCMD); return tPASS; }
 122 <INITIAL>condition|conditio|conditi|condit|condi|cond   { BEGIN(NOCMD); return tCOND; }
 123 <INITIAL>step|ste|st|s                  { BEGIN(NOCMD); return tSTEP; }
 124 <INITIAL>next|nex|ne|n                  { BEGIN(NOCMD); return tNEXT; }
 125 <INITIAL>stepi|si                       { BEGIN(NOCMD); return tSTEPI; }
 126 <INITIAL>nexti|ni                       { BEGIN(NOCMD); return tNEXTI; }
 127 <INITIAL>finish|finis|fini|fin|fi       { BEGIN(NOCMD); return tFINISH; }
 128
 129 <INITIAL>abort|abor|abo                 { BEGIN(NOCMD); return tABORT; }
 130 <INITIAL>print|prin|pri|pr|p            { BEGIN(FORMAT_EXPECTED); return tPRINT; }
 131
 132 <INITIAL>mode                           { BEGIN(MODE_CMD); return tMODE; }
 133 <INITIAL>show|sho|sh                    { BEGIN(SHOW_CMD); return tSHOW; }
 134 <INITIAL,NOPROCESS>source|sourc|sour|src { BEGIN(PATH_EXPECTED); return tSOURCE; }
 135 <INITIAL>symbolfile|symbols|symbol|sf   { BEGIN(PATH_EXPECTED); return tSYMBOLFILE; }
 136
 137 <INITIAL,INFO_CMD,DEL_CMD>break|brea|bre|br|b   { BEGIN(NOCMD); return tBREAK; }
 138 <INITIAL>watch|watc|wat                 { BEGIN(NOCMD); return tWATCH; }
 139 <INITIAL>whatis|whati|what              { BEGIN(NOCMD); return tWHATIS; }
 140 <INITIAL,NOPROCESS>run|ru|r             { BEGIN(ASTRING_EXPECTED); return tRUN;}
 141 <INITIAL>detach|detac|deta|det          { BEGIN(NOCMD); return tDETACH; }
 142 <NOPROCESS>attach|attac|atta|att        { BEGIN(NOCMD); return tATTACH; }
 143 <INFO_CMD>share|shar|sha                { return tSHARE; }
 144 <INFO_CMD>locals|local|loca|loc         { return tLOCAL; }
 145 <INFO_CMD,WALK_CMD>class|clas|cla       { return tCLASS; }
 146 <INFO_CMD,WALK_CMD>module|modul|modu|mod { return tMODULE; }
 147 <INFO_CMD,WALK_CMD>process|proces|proce|proc            { return tPROCESS; }
 148 <INFO_CMD,WALK_CMD>threads|thread|threa|thre|thr|th { return tTHREAD; }
 149 <WALK_CMD>exception|except|exc|ex       { return tEXCEPTION; }
 150 <INFO_CMD>registers|regs|reg|re         { return tREGS; }
 151 <INFO_CMD>segments|segment|segm|seg|se  { return tSEGMENTS; }
 152 <INFO_CMD>stack|stac|sta|st             { return tSTACK; }
 153 <INFO_CMD>symbol|sym                    { BEGIN(ASTRING_EXPECTED); return tSYMBOL; }
 154 <WALK_CMD>maps|map                      { return tMAPS; }
 155 <INFO_CMD,WALK_CMD>window|windo|wind|win|wnd    { return tWND; }
 156 <HELP_CMD>info|inf|in                   { return tINFO; }
 157 <MODE_CMD>vm86                          { return tVM86; }
 158
 159 <INITIAL,SHOW_CMD>directories|directorie|directori|director|directo|direct|direc|direc|dir {
 160                                           BEGIN(PATH_EXPECTED); return tDIR; }
 161
 162 char                                    { return tCHAR; }
 163 short                                   { return tSHORT; }
 164 int                                     { return tINT; }
 165 long                                    { return tLONG; }
 166 float                                   { return tFLOAT; }
 167 double                                  { return tDOUBLE; }
 168 unsigned                                { return tUNSIGNED; }
 169 signed                                  { return tSIGNED; }
 170 struct                                  { return tSTRUCT; }
 171 union                                   { return tUNION; }
 172 enum                                    { return tENUM; }
 173
 174 {IDENTIFIER}                            { yylval.string = DEBUG_MakeSymbol(yytext); return tIDENTIFIER; }
 175 "$"{IDENTIFIER}                         { yylval.string = DEBUG_MakeSymbol(yytext+1); return tINTVAR; }
 176
 177 <PATH_EXPECTED>{PATHNAME}               { yylval.string = DEBUG_MakeSymbol(yytext); return tPATH; }
 178
 179 <*>[ \t]+                               /* Eat up whitespace */
 180
 181 <NOPROCESS>.                            { BEGIN(ASTRING_EXPECTED); yyless(0); return tNOPROCESS;}
 182 <*>.                                    { if (syntax_error == 0) {
 183                                              syntax_error++;
 184                                              DEBUG_Printf(DBG_CHN_MESG, "Syntax Error (%s)\n", yytext); }
 185                                         }
 186 %%
 187
 188 #ifndef yywrap
 189 int yywrap(void) { return 1; }
 190 #endif
 191
 192 #ifndef whitespace
 193 #define whitespace(c) (((c) == ' ') || ((c) == '\t'))
 194 #endif
 195
 196
 197 /* Strip whitespace from the start and end of STRING. */
 198 static void stripwhite(char *string)
 199 {
 200     int         i, last;
 201
 202     for (i = 0; whitespace(string[i]); i++);
 203     if (i) strcpy(string, string + i);
 204
 205     last = i = strlen(string) - 1;
 206     if (string[last] == '\n') i--;
 207
 208     while (i > 0 && whitespace(string[i])) i--;
 209     if (string[last] == '\n')
 210         string[++i] = '\n';
 211     string[++i] = '\0';
 212 }
 213
 214 static int      DEBUG_FetchEntireLine(const char* pfx, char** line, size_t* alloc, BOOL check_nl)
 215 {
 216     char        buf_line[256];
 217     DWORD       nread;
 218     size_t      len;
 219
 220     /* as of today, console handles can be file handles... so better use file APIs rather than
 221      * consoles
 222      */
 223     WriteFile(DEBUG_hParserOutput, pfx, strlen(pfx), NULL, NULL);
 224
 225     len = 0;
 226     do
 227     {
 228         if (!ReadFile(DEBUG_hParserInput, buf_line, sizeof(buf_line) - 1, &nread, NULL) || nread == 0)
 229             break;
 230         buf_line[nread] = '\0';
 231
 232         if (check_nl && len == 0 && nread == 1 && buf_line[0] == '\n')
 233             return 0;
 234
 235         /* store stuff at the end of last_line */
 236         if (len + nread + 1 > *alloc)
 237         {
 238             *line = HeapReAlloc(GetProcessHeap(), 0, *line, *alloc += nread + 1);
 239         }
 240         strcpy(*line + len, buf_line);
 241         len += nread;
 242     } while (nread == 0 || buf_line[nread - 1] != '\n');
 243
 244     if (!len)
 245     {
 246         *line = HeapReAlloc(GetProcessHeap(), 0, *line, *alloc = 1);
 247         **line = '\0';
 248     }
 249
 250     /* Remove leading and trailing whitespace from the line */
 251     stripwhite(*line);
 252     return 1;
 253 }
 254
 255 static int DEBUG_FetchFromLine(const char* pfx, char* buf, int size)
 256 {
 257     size_t      len;
 258 static char*  last_line = NULL;
 259 static size_t last_line_size = 0;
 260 static size_t last_line_idx = 0;
 261
 262     /* first alloc of our current buffer */
 263     if (!last_line)
 264     {
 265         last_line = HeapAlloc(GetProcessHeap(), 0, last_line_size = 2);
 266         assert(last_line);
 267         last_line[0] = '\n';
 268         last_line[1] = '\0';
 269     }
 270
 271     /* try first to fetch the remaining of an existing line */
 272     if (last_line_idx == 0)
 273     {
 274         /* no remaining chars to be read from last line, grab a brand new line up to '\n' */
 275         DEBUG_FlushSymbols();
 276
 277         DEBUG_FetchEntireLine(pfx, &last_line, &last_line_size, TRUE);
 278     }
 279
 280     len = min(strlen(last_line + last_line_idx), size - 1);
 281     memcpy(buf, last_line + last_line_idx, len);
 282     buf[len] = '\0';
 283     if ((last_line_idx += len) >= strlen(last_line))
 284         last_line_idx = 0;
 285     return len;
 286 }
 287
 288 int DEBUG_ReadLine(const char* pfx, char* buf, int size)
 289 {
 290     char*       line = NULL;
 291     size_t      len = 0;
 292
 293     DEBUG_FetchEntireLine(pfx, &line, &len, FALSE);
 294     len = strlen(line);
 295     /* remove trailing \n */
 296     if (len > 0 && line[len - 1] == '\n') len--;
 297     len = min(size - 1, len);
 298     memcpy(buf, line, len);
 299     buf[len] = '\0';
 300     HeapFree(GetProcessHeap(), 0, line);
 301     return 1;
 302 }
 303
 304 static char** local_symbols /* = NULL */;
 305 static int next_symbol /* = 0 */;
 306 static int alloc_symbol /* = 0 */;
 307
 308 char* DEBUG_MakeSymbol(const char* symbol)
 309 {
 310     assert(0 <= next_symbol && next_symbol < alloc_symbol + 1);
 311     if (next_symbol >= alloc_symbol)
 312     {
 313         local_symbols = HeapReAlloc(GetProcessHeap(), 0, local_symbols,
 314                                     (alloc_symbol += 32) * sizeof(local_symbols[0]));
 315         assert(local_symbols);
 316     }
 317     return local_symbols[next_symbol++] = DBG_strdup(symbol);
 318 }
 319
 320 void DEBUG_FlushSymbols(void)
 321 {
 322     while(--next_symbol >= 0) DBG_free(local_symbols[next_symbol]);
 323     next_symbol = 0;
 324 }