git.oblomov.eu Git - wine/blob - tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of include/wine/server.h.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (
  26     "int"           => "%d",
  27     "short int"     => "%d",
  28     "char"          => "%c",
  29     "unsigned char" => "%02x",
  30     "unsigned short"=> "%04x",
  31     "unsigned int"  => "%08x",
  32     "unsigned long" => "%lx",
  33     "void*"         => "%p",
  34     "time_t"        => "%ld (long)",
  35     "size_t"        => "%lu (unsigned long)",
  36     "obj_handle_t"  => "%p",
  37     "atom_t"        => "%04x",
  38     "user_handle_t" => "%p",
  39     "process_id_t"  => "%04x",
  40     "thread_id_t"   => "%04x",
  41     "abs_time_t"    => "&dump_abs_time",
  42     "rectangle_t"   => "&dump_rectangle",
  43     "char_info_t"   => "&dump_char_info",
  44 );
  45
  46 my @requests = ();
  47 my %replies = ();
  48
  49 my @trace_lines = ();
  50
  51
  52
  53 ### Generate a dumping function
  54
  55 sub DO_DUMP_FUNC($$@)
  56 {
  57     my $name = shift;
  58     my $req = shift;
  59     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  60     while ($#_ >= 0)
  61     {
  62         my $type = shift;
  63         my $var = shift;
  64         if (defined($formats{$type}))
  65         {
  66             if ($formats{$type} =~ /^&(.*)/)
  67             {
  68                 my $func = $1;
  69                 push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  70                 push @trace_lines, "    $func( &req->$var );\n";
  71                 push @trace_lines, "    fprintf( stderr, \",\" );\n" if ($#_ > 0);
  72             }
  73             elsif ($formats{$type} =~ /^(%.*)\s+\((.*)\)/)
  74             {
  75                 my ($format, $cast) = ($1, $2);
  76                 push @trace_lines, "    fprintf( stderr, \" $var=$format";
  77                 push @trace_lines, "," if ($#_ > 0);
  78                 push @trace_lines, "\", ($cast)req->$var );\n";
  79             }
  80             else
  81             {
  82                 push @trace_lines, "    fprintf( stderr, \" $var=$formats{$type}";
  83                 push @trace_lines, "," if ($#_ > 0);
  84                 push @trace_lines, "\", req->$var );\n";
  85             }
  86         }
  87         else  # must be some varargs format
  88         {
  89             my $func = $type;
  90             push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  91             push @trace_lines, "    $func;\n";
  92             push @trace_lines, "    fputc( ',', stderr );\n" if ($#_ > 0);
  93         }
  94     }
  95     push @trace_lines, "}\n\n";
  96 }
  97
  98 ### Parse the request definitions
  99
 100 sub PARSE_REQUESTS()
 101 {
 102     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 103     my $state = 0;
 104     my $name = "";
 105     my @in_struct = ();
 106     my @out_struct = ();
 107
 108     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 109
 110     while (<PROTOCOL>)
 111     {
 112         my ($type, $var);
 113         # strip comments
 114         s!/\*.*\*/!!g;
 115         # strip white space at end of line
 116         s/\s+$//;
 117
 118         if (/^\@HEADER/)
 119         {
 120             die "Misplaced \@HEADER" unless $state == 0;
 121             $state++;
 122             next;
 123         }
 124
 125         # ignore everything while in state 0
 126         next if $state == 0;
 127
 128         if (/^\@REQ\(\s*(\w+)\s*\)/)
 129         {
 130             $name = $1;
 131             die "Misplaced \@REQ" unless $state == 1;
 132             # start a new request
 133             @in_struct = ();
 134             @out_struct = ();
 135             print SERVER_PROT "struct ${name}_request\n{\n";
 136             print SERVER_PROT "    struct request_header __header;\n";
 137             $state++;
 138             next;
 139         }
 140
 141         if (/^\@REPLY/)
 142         {
 143             die "Misplaced \@REPLY" unless $state == 2;
 144             print SERVER_PROT "};\n";
 145             print SERVER_PROT "struct ${name}_reply\n{\n";
 146             print SERVER_PROT "    struct reply_header __header;\n";
 147             $state++;
 148             next;
 149         }
 150
 151         if (/^\@END/)
 152         {
 153             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 154             print SERVER_PROT "};\n";
 155
 156             if ($state == 2)  # build dummy reply struct
 157             {
 158                 print SERVER_PROT "struct ${name}_reply\n{\n";
 159                 print SERVER_PROT "    struct reply_header __header;\n";
 160                 print SERVER_PROT "};\n";
 161             }
 162
 163             # got a complete request
 164             push @requests, $name;
 165             DO_DUMP_FUNC( $name, "request", @in_struct);
 166             if ($#out_struct >= 0)
 167             {
 168                 $replies{$name} = 1;
 169                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 170             }
 171             $state = 1;
 172             next;
 173         }
 174
 175         if ($state != 1)
 176         {
 177             # skip empty lines (but keep them in output file)
 178             if (/^$/)
 179             {
 180                 print SERVER_PROT "\n";
 181                 next;
 182             }
 183
 184             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 185             {
 186                 $var = $1;
 187                 $type = "dump_varargs_" . $2 . "( min(cur_size,req->" . $3 . ") )";
 188                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 189             }
 190             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 191             {
 192                 $var = $1;
 193                 $type = "dump_varargs_" . $2 . "( cur_size )";
 194                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 195             }
 196             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 197             {
 198                 $type = $1;
 199                 $var = $3;
 200                 die "Unrecognized type $type" unless defined($formats{$type});
 201             }
 202             else
 203             {
 204                 die "Unrecognized syntax $_";
 205             }
 206             if ($state == 2) { push @in_struct, $type, $var; }
 207             if ($state == 3) { push @out_struct, $type, $var; }
 208         }
 209
 210         # Pass it through into the output file
 211         print SERVER_PROT $_ . "\n";
 212     }
 213     close PROTOCOL;
 214 }
 215
 216 ### Retrieve the server protocol version from the existing server_protocol.h file
 217
 218 sub GET_PROTOCOL_VERSION()
 219 {
 220     my $protocol = 0;
 221     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 222     while (<SERVER_PROT>)
 223     {
 224         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 225     }
 226     close SERVER_PROT;
 227     return $protocol;
 228 }
 229
 230 ### Retrieve the list of status and errors used in the server
 231
 232 sub GET_ERROR_NAMES()
 233 {
 234     my %errors = ();
 235     foreach my $f (glob "server/*.c")
 236     {
 237         open FILE, $f or die "Can't open $f";
 238         while (<FILE>)
 239         {
 240             if (/set_error\s*\(\s*STATUS_(\w+)\s*\)/)
 241             {
 242                 $errors{$1} = "STATUS_$1";
 243             }
 244             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 245             {
 246                 $errors{$1} = "0xc0010000 | $1";
 247             }
 248         }
 249         close FILE;
 250     }
 251     return %errors;
 252 }
 253
 254 ### Replace the contents of a file between ### make_requests ### marks
 255
 256 sub REPLACE_IN_FILE($@)
 257 {
 258     my $name = shift;
 259     my @data = @_;
 260     my @lines = ();
 261     open(FILE,$name) or die "Can't open $name";
 262     while (<FILE>)
 263     {
 264         push @lines, $_;
 265         last if /\#\#\# make_requests begin \#\#\#/;
 266     }
 267     push @lines, "\n", @data;
 268     while (<FILE>)
 269     {
 270         if (/\#\#\# make_requests end \#\#\#/) { push @lines, "\n", $_; last; }
 271     }
 272     push @lines, <FILE>;
 273     open(FILE,">$name") or die "Can't modify $name";
 274     print FILE @lines;
 275     close(FILE);
 276 }
 277
 278 ### Main
 279
 280 # Get the server protocol version
 281 my $protocol = GET_PROTOCOL_VERSION();
 282
 283 my %errors = GET_ERROR_NAMES();
 284
 285 ### Create server_protocol.h and print header
 286
 287 open SERVER_PROT, ">include/wine/server_protocol.h" or die "Cannot create include/wine/server_protocol.h";
 288 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 289 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 290 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 291 print SERVER_PROT " */\n\n";
 292 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 293 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 294
 295 ### Parse requests to find request/reply structure definitions
 296
 297 PARSE_REQUESTS();
 298
 299 ### Build the request list and structures
 300
 301 print SERVER_PROT "\n\nenum request\n{\n";
 302 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 303 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 304
 305 print SERVER_PROT "union generic_request\n{\n";
 306 print SERVER_PROT "    struct request_max_size max_size;\n";
 307 print SERVER_PROT "    struct request_header request_header;\n";
 308 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 309 print SERVER_PROT "};\n";
 310
 311 print SERVER_PROT "union generic_reply\n{\n";
 312 print SERVER_PROT "    struct request_max_size max_size;\n";
 313 print SERVER_PROT "    struct reply_header reply_header;\n";
 314 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 315 print SERVER_PROT "};\n\n";
 316
 317 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 318 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 319 close SERVER_PROT;
 320
 321 ### Output the dumping function tables
 322
 323 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 324 foreach my $req (@requests)
 325 {
 326     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 327 }
 328 push @trace_lines, "};\n\n";
 329
 330 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 331 foreach my $req (@requests)
 332 {
 333     push @trace_lines, "    (dump_func)", $replies{$req} ? "dump_${req}_reply,\n" : "0,\n";
 334 }
 335 push @trace_lines, "};\n\n";
 336
 337 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 338 foreach my $req (@requests)
 339 {
 340     push @trace_lines, "    \"$req\",\n";
 341 }
 342 push @trace_lines, "};\n\n";
 343
 344 push @trace_lines, "static const struct\n{\n";
 345 push @trace_lines, "    const char  *name;\n";
 346 push @trace_lines, "    unsigned int value;\n";
 347 push @trace_lines, "} status_names[] =\n{\n";
 348
 349 foreach my $err (sort keys %errors)
 350 {
 351     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 352 }
 353 push @trace_lines, "    { NULL, 0 }\n";
 354 push @trace_lines, "};\n";
 355
 356 REPLACE_IN_FILE( "server/trace.c", @trace_lines );
 357
 358 ### Output the request handlers list
 359
 360 my @request_lines = ();
 361
 362 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 363 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 364 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 365 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 366 foreach my $req (@requests)
 367 {
 368     push @request_lines, "    (req_handler)req_$req,\n";
 369 }
 370 push @request_lines, "};\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 371
 372 REPLACE_IN_FILE( "server/request.h", @request_lines );