git.oblomov.eu Git - wine/blob - dlls/vbscript/parser.y

   1 /*
   2  * Copyright 2011 Jacek Caban for CodeWeavers
   3  *
   4  * This library is free software; you can redistribute it and/or
   5  * modify it under the terms of the GNU Lesser General Public
   6  * License as published by the Free Software Foundation; either
   7  * version 2.1 of the License, or (at your option) any later version.
   8  *
   9  * This library is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * Lesser General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU Lesser General Public
  15  * License along with this library; if not, write to the Free Software
  16  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  17  */
  18
  19 %{
  20
  21 #include "vbscript.h"
  22 #include "parse.h"
  23
  24 #include "wine/debug.h"
  25
  26 WINE_DEFAULT_DEBUG_CHANNEL(vbscript);
  27
  28
  29 #define YYLEX_PARAM ctx
  30 #define YYPARSE_PARAM ctx
  31
  32 static int parser_error(const char*);
  33
  34  static void parse_complete(parser_ctx_t*,BOOL);
  35
  36 static void source_add_statement(parser_ctx_t*,statement_t*);
  37 static void source_add_class(parser_ctx_t*,class_decl_t*);
  38
  39 static void *new_expression(parser_ctx_t*,expression_type_t,size_t);
  40 static expression_t *new_bool_expression(parser_ctx_t*,VARIANT_BOOL);
  41 static expression_t *new_string_expression(parser_ctx_t*,const WCHAR*);
  42 static expression_t *new_long_expression(parser_ctx_t*,expression_type_t,LONG);
  43 static expression_t *new_double_expression(parser_ctx_t*,double);
  44 static expression_t *new_unary_expression(parser_ctx_t*,expression_type_t,expression_t*);
  45 static expression_t *new_binary_expression(parser_ctx_t*,expression_type_t,expression_t*,expression_t*);
  46
  47 static member_expression_t *new_member_expression(parser_ctx_t*,expression_t*,const WCHAR*);
  48
  49 static void *new_statement(parser_ctx_t*,statement_type_t,size_t);
  50 static statement_t *new_call_statement(parser_ctx_t*,member_expression_t*);
  51 static statement_t *new_assign_statement(parser_ctx_t*,member_expression_t*,expression_t*);
  52 static statement_t *new_dim_statement(parser_ctx_t*,dim_decl_t*);
  53 static statement_t *new_if_statement(parser_ctx_t*,expression_t*,statement_t*,elseif_decl_t*,statement_t*);
  54 static statement_t *new_function_statement(parser_ctx_t*,function_decl_t*);
  55
  56 static dim_decl_t *new_dim_decl(parser_ctx_t*,const WCHAR*,dim_decl_t*);
  57 static elseif_decl_t *new_elseif_decl(parser_ctx_t*,expression_t*,statement_t*);
  58 static function_decl_t *new_function_decl(parser_ctx_t*,const WCHAR*,function_type_t,arg_decl_t*,statement_t*);
  59 static arg_decl_t *new_argument_decl(parser_ctx_t*,const WCHAR*,BOOL);
  60 static class_decl_t *new_class_decl(parser_ctx_t*);
  61
  62 #define CHECK_ERROR if(((parser_ctx_t*)ctx)->hres != S_OK) YYABORT
  63
  64 %}
  65
  66 %pure_parser
  67 %start Program
  68
  69 %union {
  70     const WCHAR *string;
  71     statement_t *statement;
  72     expression_t *expression;
  73     member_expression_t *member;
  74     elseif_decl_t *elseif;
  75     dim_decl_t *dim_decl;
  76     function_decl_t *func_decl;
  77     arg_decl_t *arg_decl;
  78     class_decl_t *class_decl;
  79     LONG lng;
  80     BOOL bool;
  81     double dbl;
  82 }
  83
  84 %token tEOF tNL tREM tEMPTYBRACKETS
  85 %token tTRUE tFALSE
  86 %token tNOT tAND tOR tXOR tEQV tIMP tNEQ
  87 %token tIS tLTEQ tGTEQ tMOD
  88 %token tCALL tDIM tSUB tFUNCTION tPROPERTY tGET tLET
  89 %token tIF tELSE tELSEIF tEND tTHEN tEXIT
  90 %token tWHILE tWEND tDO tLOOP tUNTIL
  91 %token tBYREF tBYVAL
  92 %token tOPTION tEXPLICIT
  93 %token tSTOP
  94 %token tNOTHING tEMPTY tNULL
  95 %token tCLASS tSET tNEW tPUBLIC tPRIVATE tDEFAULT tME
  96 %token tERROR tNEXT tON tRESUME tGOTO
  97 %token <string> tIdentifier tString
  98 %token <lng> tLong tShort
  99 %token <dbl> tDouble
 100
 101 %type <statement> Statement StatementNl StatementsNl StatementsNl_opt IfStatement Else_opt
 102 %type <expression> Expression LiteralExpression PrimaryExpression EqualityExpression CallExpression
 103 %type <expression> ConcatExpression AdditiveExpression ModExpression IntdivExpression MultiplicativeExpression ExpExpression
 104 %type <expression> NotExpression UnaryExpression AndExpression OrExpression XorExpression EqvExpression
 105 %type <member> MemberExpression
 106 %type <expression> Arguments_opt ArgumentList_opt ArgumentList
 107 %type <bool> OptionExplicit_opt
 108 %type <arg_decl> ArgumentsDecl_opt ArgumentDeclList ArgumentDecl
 109 %type <func_decl> FunctionDecl
 110 %type <elseif> ElseIfs_opt ElseIfs ElseIf
 111 %type <class_decl> ClassDeclaration ClassBody
 112 %type <dim_decl> DimDeclList
 113
 114 %%
 115
 116 Program
 117     : OptionExplicit_opt SourceElements tEOF    { parse_complete(ctx, $1); }
 118
 119 OptionExplicit_opt
 120     : /* empty */                { $$ = FALSE; }
 121     | tOPTION tEXPLICIT tNL      { $$ = TRUE; }
 122
 123 SourceElements
 124     : /* empty */
 125     | SourceElements StatementNl            { source_add_statement(ctx, $2); }
 126     | SourceElements ClassDeclaration       { source_add_class(ctx, $2); }
 127
 128 StatementsNl_opt
 129     : /* empty */                           { $$ = NULL; }
 130     | StatementsNl                          { $$ = $1; }
 131
 132 StatementsNl
 133     : StatementNl                           { $$ = $1; }
 134     | StatementNl StatementsNl              { $1->next = $2; $$ = $1; }
 135
 136 StatementNl
 137     : Statement tNL                 { $$ = $1; }
 138
 139 Statement
 140     : MemberExpression ArgumentList_opt     { $1->args = $2; $$ = new_call_statement(ctx, $1); CHECK_ERROR; }
 141     | tCALL MemberExpression Arguments_opt  { $2->args = $3; $$ = new_call_statement(ctx, $2); CHECK_ERROR; }
 142     | MemberExpression Arguments_opt '=' Expression
 143                                             { $1->args = $2; $$ = new_assign_statement(ctx, $1, $4); CHECK_ERROR; }
 144     | tDIM DimDeclList                      { $$ = new_dim_statement(ctx, $2); CHECK_ERROR; }
 145     | IfStatement                           { $$ = $1; }
 146     | FunctionDecl                          { $$ = new_function_statement(ctx, $1); CHECK_ERROR; }
 147     | tEXIT tFUNCTION                       { $$ = new_statement(ctx, STAT_EXITFUNC, 0); CHECK_ERROR; }
 148     | tEXIT tSUB                            { $$ = new_statement(ctx, STAT_EXITSUB, 0); CHECK_ERROR; }
 149
 150 MemberExpression
 151     : tIdentifier                           { $$ = new_member_expression(ctx, NULL, $1); CHECK_ERROR; }
 152     | CallExpression '.' tIdentifier        { $$ = new_member_expression(ctx, $1, $3); CHECK_ERROR; }
 153
 154 DimDeclList /* FIXME: Support arrays */
 155     : tIdentifier                           { $$ = new_dim_decl(ctx, $1, NULL); CHECK_ERROR; }
 156     | tIdentifier ',' DimDeclList           { $$ = new_dim_decl(ctx, $1, $3); CHECK_ERROR; }
 157
 158 IfStatement
 159     : tIF Expression tTHEN tNL StatementsNl ElseIfs_opt Else_opt tEND tIF
 160                                             { $$ = new_if_statement(ctx, $2, $5, $6, $7); CHECK_ERROR; }
 161     /* FIXME: short if statement */
 162
 163 ElseIfs_opt
 164     : /* empty */                           { $$ = NULL; }
 165     | ElseIfs                               { $$ = $1; }
 166
 167 ElseIfs
 168     : ElseIf                                { $$ = $1; }
 169     | ElseIf ElseIfs                        { $1->next = $2; $$ = $1; }
 170
 171 ElseIf
 172     : tELSEIF Expression tTHEN tNL StatementsNl
 173                                             { $$ = new_elseif_decl(ctx, $2, $5); }
 174
 175 Else_opt
 176     : /* empty */                           { $$ = NULL; }
 177     | tELSE tNL StatementsNl                { $$ = $3; }
 178
 179 Arguments_opt
 180     : EmptyBrackets_opt             { $$ = NULL; }
 181     | '(' ArgumentList ')'          { $$ = $2; }
 182
 183 ArgumentList_opt
 184     : EmptyBrackets_opt             { $$ = NULL; }
 185     | ArgumentList                  { $$ = $1; }
 186
 187 ArgumentList
 188     : Expression                    { $$ = $1; }
 189     | Expression ',' ArgumentList   { $1->next = $3; $$ = $1; }
 190
 191 EmptyBrackets_opt
 192     : /* empty */
 193     | tEMPTYBRACKETS
 194
 195 Expression
 196     : EqvExpression                             { $$ = $1; }
 197     | Expression tIMP EqvExpression             { $$ = new_binary_expression(ctx, EXPR_IMP, $1, $3); CHECK_ERROR; }
 198
 199 EqvExpression
 200     : XorExpression                             { $$ = $1; }
 201     | EqvExpression tEQV XorExpression          { $$ = new_binary_expression(ctx, EXPR_EQV, $1, $3); CHECK_ERROR; }
 202
 203 XorExpression
 204     : OrExpression                              { $$ = $1; }
 205     | XorExpression tXOR OrExpression           { $$ = new_binary_expression(ctx, EXPR_XOR, $1, $3); CHECK_ERROR; }
 206
 207 OrExpression
 208     : AndExpression                             { $$ = $1; }
 209     | OrExpression tOR AndExpression            { $$ = new_binary_expression(ctx, EXPR_OR, $1, $3); CHECK_ERROR; }
 210
 211 AndExpression
 212     : NotExpression                             { $$ = $1; }
 213     | AndExpression tAND NotExpression          { $$ = new_binary_expression(ctx, EXPR_AND, $1, $3); CHECK_ERROR; }
 214
 215 NotExpression
 216     : EqualityExpression            { $$ = $1; }
 217     | tNOT NotExpression            { $$ = new_unary_expression(ctx, EXPR_NOT, $2); CHECK_ERROR; }
 218
 219 EqualityExpression
 220     : ConcatExpression                          { $$ = $1; }
 221     | EqualityExpression '=' ConcatExpression   { $$ = new_binary_expression(ctx, EXPR_EQUAL, $1, $3); CHECK_ERROR; }
 222     | EqualityExpression tNEQ ConcatExpression  { $$ = new_binary_expression(ctx, EXPR_NEQUAL, $1, $3); CHECK_ERROR; }
 223
 224 ConcatExpression
 225     : AdditiveExpression                        { $$ = $1; }
 226     | ConcatExpression '&' AdditiveExpression   { $$ = new_binary_expression(ctx, EXPR_CONCAT, $1, $3); CHECK_ERROR; }
 227
 228 AdditiveExpression
 229     : ModExpression                             { $$ = $1; }
 230     | AdditiveExpression '+' ModExpression      { $$ = new_binary_expression(ctx, EXPR_ADD, $1, $3); CHECK_ERROR; }
 231     | AdditiveExpression '-' ModExpression      { $$ = new_binary_expression(ctx, EXPR_SUB, $1, $3); CHECK_ERROR; }
 232
 233 ModExpression
 234     : IntdivExpression                          { $$ = $1; }
 235     | ModExpression tMOD IntdivExpression       { $$ = new_binary_expression(ctx, EXPR_MOD, $1, $3); CHECK_ERROR; }
 236
 237 IntdivExpression
 238     : MultiplicativeExpression                  { $$ = $1; }
 239     | IntdivExpression '\\' MultiplicativeExpression
 240                                                 { $$ = new_binary_expression(ctx, EXPR_IDIV, $1, $3); CHECK_ERROR; }
 241
 242 MultiplicativeExpression
 243     : ExpExpression                             { $$ = $1; }
 244     | MultiplicativeExpression '*' ExpExpression
 245                                                 { $$ = new_binary_expression(ctx, EXPR_MUL, $1, $3); CHECK_ERROR; }
 246     | MultiplicativeExpression '/' ExpExpression
 247                                                 { $$ = new_binary_expression(ctx, EXPR_DIV, $1, $3); CHECK_ERROR; }
 248
 249 ExpExpression
 250     : UnaryExpression                           { $$ = $1; }
 251     | ExpExpression '^' UnaryExpression         { $$ = new_binary_expression(ctx, EXPR_EXP, $1, $3); CHECK_ERROR; }
 252
 253 UnaryExpression
 254     : LiteralExpression             { $$ = $1; }
 255     | CallExpression                { $$ = $1; }
 256     | '-' UnaryExpression           { $$ = new_unary_expression(ctx, EXPR_NEG, $2); CHECK_ERROR; }
 257
 258 CallExpression
 259     : PrimaryExpression                 { $$ = $1; }
 260     | MemberExpression Arguments_opt    { $1->args = $2; $$ = &$1->expr; }
 261
 262 LiteralExpression
 263     : tTRUE                         { $$ = new_bool_expression(ctx, VARIANT_TRUE); CHECK_ERROR; }
 264     | tFALSE                        { $$ = new_bool_expression(ctx, VARIANT_FALSE); CHECK_ERROR; }
 265     | tString                       { $$ = new_string_expression(ctx, $1); CHECK_ERROR; }
 266     | tShort                        { $$ = new_long_expression(ctx, EXPR_USHORT, $1); CHECK_ERROR; }
 267     | '0'                           { $$ = new_long_expression(ctx, EXPR_USHORT, 0); CHECK_ERROR; }
 268     | tLong                         { $$ = new_long_expression(ctx, EXPR_ULONG, $1); CHECK_ERROR; }
 269     | tDouble                       { $$ = new_double_expression(ctx, $1); CHECK_ERROR; }
 270     | tEMPTY                        { $$ = new_expression(ctx, EXPR_EMPTY, 0); CHECK_ERROR; }
 271     | tNULL                         { $$ = new_expression(ctx, EXPR_NULL, 0); CHECK_ERROR; }
 272
 273 PrimaryExpression
 274     : '(' Expression ')'            { $$ = $2; }
 275
 276 ClassDeclaration
 277     : tCLASS tIdentifier tNL ClassBody tEND tCLASS tNL      { $4->name = $2; $$ = $4; }
 278
 279 ClassBody
 280     : /* empty */                               { $$ = new_class_decl(ctx); }
 281
 282 FunctionDecl
 283     : /* Storage_opt */ tSUB tIdentifier ArgumentsDecl_opt tNL StatementsNl_opt tEND tSUB
 284                                     { $$ = new_function_decl(ctx, $2, FUNC_SUB, $3, $5); CHECK_ERROR; }
 285     | /* Storage_opt */ tFUNCTION tIdentifier ArgumentsDecl_opt tNL StatementsNl_opt tEND tFUNCTION
 286                                     { $$ = new_function_decl(ctx, $2, FUNC_FUNCTION, $3, $5); CHECK_ERROR; }
 287
 288 ArgumentsDecl_opt
 289     : EmptyBrackets_opt                         { $$ = NULL; }
 290     | '(' ArgumentDeclList ')'                  { $$ = $2; }
 291
 292 ArgumentDeclList
 293     : ArgumentDecl                              { $$ = $1; }
 294     | ArgumentDecl ',' ArgumentDeclList         { $1->next = $3; $$ = $1; }
 295
 296 ArgumentDecl
 297     : tIdentifier                               { $$ = new_argument_decl(ctx, $1, TRUE); }
 298     | tBYREF tIdentifier                        { $$ = new_argument_decl(ctx, $2, TRUE); }
 299     | tBYVAL tIdentifier                        { $$ = new_argument_decl(ctx, $2, FALSE); }
 300
 301 %%
 302
 303 static int parser_error(const char *str)
 304 {
 305     return 0;
 306 }
 307
 308 static void source_add_statement(parser_ctx_t *ctx, statement_t *stat)
 309 {
 310     if(ctx->stats) {
 311         ctx->stats_tail->next = stat;
 312         ctx->stats_tail = stat;
 313     }else {
 314         ctx->stats = ctx->stats_tail = stat;
 315     }
 316 }
 317
 318 static void source_add_class(parser_ctx_t *ctx, class_decl_t *class_decl)
 319 {
 320     class_decl->next = ctx->class_decls;
 321     ctx->class_decls = class_decl;
 322 }
 323
 324 static void parse_complete(parser_ctx_t *ctx, BOOL option_explicit)
 325 {
 326     ctx->parse_complete = TRUE;
 327     ctx->option_explicit = option_explicit;
 328 }
 329
 330 static void *new_expression(parser_ctx_t *ctx, expression_type_t type, size_t size)
 331 {
 332     expression_t *expr;
 333
 334     expr = parser_alloc(ctx, size ? size : sizeof(*expr));
 335     if(expr) {
 336         expr->type = type;
 337         expr->next = NULL;
 338     }
 339
 340     return expr;
 341 }
 342
 343 static expression_t *new_bool_expression(parser_ctx_t *ctx, VARIANT_BOOL value)
 344 {
 345     bool_expression_t *expr;
 346
 347     expr = new_expression(ctx, EXPR_BOOL, sizeof(*expr));
 348     if(!expr)
 349         return NULL;
 350
 351     expr->value = value;
 352     return &expr->expr;
 353 }
 354
 355 static expression_t *new_string_expression(parser_ctx_t *ctx, const WCHAR *value)
 356 {
 357     string_expression_t *expr;
 358
 359     expr = new_expression(ctx, EXPR_STRING, sizeof(*expr));
 360     if(!expr)
 361         return NULL;
 362
 363     expr->value = value;
 364     return &expr->expr;
 365 }
 366
 367 static expression_t *new_long_expression(parser_ctx_t *ctx, expression_type_t type, LONG value)
 368 {
 369     int_expression_t *expr;
 370
 371     expr = new_expression(ctx, type, sizeof(*expr));
 372     if(!expr)
 373         return NULL;
 374
 375     expr->value = value;
 376     return &expr->expr;
 377 }
 378
 379 static expression_t *new_double_expression(parser_ctx_t *ctx, double value)
 380 {
 381     double_expression_t *expr;
 382
 383     expr = new_expression(ctx, EXPR_DOUBLE, sizeof(*expr));
 384     if(!expr)
 385         return NULL;
 386
 387     expr->value = value;
 388     return &expr->expr;
 389 }
 390
 391 static expression_t *new_unary_expression(parser_ctx_t *ctx, expression_type_t type, expression_t *subexpr)
 392 {
 393     unary_expression_t *expr;
 394
 395     expr = new_expression(ctx, type, sizeof(*expr));
 396     if(!expr)
 397         return NULL;
 398
 399     expr->subexpr = subexpr;
 400     return &expr->expr;
 401 }
 402
 403 static expression_t *new_binary_expression(parser_ctx_t *ctx, expression_type_t type, expression_t *left, expression_t *right)
 404 {
 405     binary_expression_t *expr;
 406
 407     expr = new_expression(ctx, type, sizeof(*expr));
 408     if(!expr)
 409         return NULL;
 410
 411     expr->left = left;
 412     expr->right = right;
 413     return &expr->expr;
 414 }
 415
 416 static member_expression_t *new_member_expression(parser_ctx_t *ctx, expression_t *obj_expr, const WCHAR *identifier)
 417 {
 418     member_expression_t *expr;
 419
 420     expr = new_expression(ctx, EXPR_MEMBER, sizeof(*expr));
 421     if(!expr)
 422         return NULL;
 423
 424     expr->obj_expr = obj_expr;
 425     expr->identifier = identifier;
 426     expr->args = NULL;
 427     return expr;
 428 }
 429
 430 static void *new_statement(parser_ctx_t *ctx, statement_type_t type, size_t size)
 431 {
 432     statement_t *stat;
 433
 434     stat = parser_alloc(ctx, size ? size : sizeof(*stat));
 435     if(stat) {
 436         stat->type = type;
 437         stat->next = NULL;
 438     }
 439
 440     return stat;
 441 }
 442
 443 static statement_t *new_call_statement(parser_ctx_t *ctx, member_expression_t *expr)
 444 {
 445     call_statement_t *stat;
 446
 447     stat = new_statement(ctx, STAT_CALL, sizeof(*stat));
 448     if(!stat)
 449         return NULL;
 450
 451     stat->expr = expr;
 452     return &stat->stat;
 453 }
 454
 455 static statement_t *new_assign_statement(parser_ctx_t *ctx, member_expression_t *left, expression_t *right)
 456 {
 457     assign_statement_t *stat;
 458
 459     stat = new_statement(ctx, STAT_ASSIGN, sizeof(*stat));
 460     if(!stat)
 461         return NULL;
 462
 463     stat->member_expr = left;
 464     stat->value_expr = right;
 465     return &stat->stat;
 466 }
 467
 468 static dim_decl_t *new_dim_decl(parser_ctx_t *ctx, const WCHAR *name, dim_decl_t *next)
 469 {
 470     dim_decl_t *decl;
 471
 472     decl = parser_alloc(ctx, sizeof(*decl));
 473     if(!decl)
 474         return NULL;
 475
 476     decl->name = name;
 477     decl->next = next;
 478     return decl;
 479 }
 480
 481 static statement_t *new_dim_statement(parser_ctx_t *ctx, dim_decl_t *decls)
 482 {
 483     dim_statement_t *stat;
 484
 485     stat = new_statement(ctx, STAT_DIM, sizeof(*stat));
 486     if(!stat)
 487         return NULL;
 488
 489     stat->dim_decls = decls;
 490     return &stat->stat;
 491 }
 492
 493 static elseif_decl_t *new_elseif_decl(parser_ctx_t *ctx, expression_t *expr, statement_t *stat)
 494 {
 495     elseif_decl_t *decl;
 496
 497     decl = parser_alloc(ctx, sizeof(*decl));
 498     if(!decl)
 499         return NULL;
 500
 501     decl->expr = expr;
 502     decl->stat = stat;
 503     decl->next = NULL;
 504     return decl;
 505 }
 506
 507 static statement_t *new_if_statement(parser_ctx_t *ctx, expression_t *expr, statement_t *if_stat, elseif_decl_t *elseif_decl,
 508         statement_t *else_stat)
 509 {
 510     if_statement_t *stat;
 511
 512     stat = new_statement(ctx, STAT_IF, sizeof(*stat));
 513     if(!stat)
 514         return NULL;
 515
 516     stat->expr = expr;
 517     stat->if_stat = if_stat;
 518     stat->elseifs = elseif_decl;
 519     stat->else_stat = else_stat;
 520     return &stat->stat;
 521 }
 522
 523 static arg_decl_t *new_argument_decl(parser_ctx_t *ctx, const WCHAR *name, BOOL by_ref)
 524 {
 525     arg_decl_t *arg_decl;
 526
 527     arg_decl = parser_alloc(ctx, sizeof(*arg_decl));
 528     if(!arg_decl)
 529         return NULL;
 530
 531     arg_decl->name = name;
 532     arg_decl->by_ref = by_ref;
 533     arg_decl->next = NULL;
 534     return arg_decl;
 535 }
 536
 537 static function_decl_t *new_function_decl(parser_ctx_t *ctx, const WCHAR *name, function_type_t type,
 538         arg_decl_t *arg_decl, statement_t *body)
 539 {
 540     function_decl_t *decl;
 541
 542     decl = parser_alloc(ctx, sizeof(*decl));
 543     if(!decl)
 544         return NULL;
 545
 546     decl->name = name;
 547     decl->type = type;
 548     decl->args = arg_decl;
 549     decl->body = body;
 550     return decl;
 551 }
 552
 553 static statement_t *new_function_statement(parser_ctx_t *ctx, function_decl_t *decl)
 554 {
 555     function_statement_t *stat;
 556
 557     stat = new_statement(ctx, STAT_FUNC, sizeof(*stat));
 558     if(!stat)
 559         return NULL;
 560
 561     stat->func_decl = decl;
 562     return &stat->stat;
 563 }
 564
 565 static class_decl_t *new_class_decl(parser_ctx_t *ctx)
 566 {
 567     class_decl_t *class_decl;
 568
 569     class_decl = parser_alloc(ctx, sizeof(*class_decl));
 570     if(!class_decl)
 571         return NULL;
 572
 573     class_decl->next = NULL;
 574     return class_decl;
 575 }
 576
 577 void *parser_alloc(parser_ctx_t *ctx, size_t size)
 578 {
 579     void *ret;
 580
 581     ret = vbsheap_alloc(&ctx->heap, size);
 582     if(!ret)
 583         ctx->hres = E_OUTOFMEMORY;
 584     return ret;
 585 }
 586
 587 HRESULT parse_script(parser_ctx_t *ctx, const WCHAR *code)
 588 {
 589     ctx->code = ctx->ptr = code;
 590     ctx->end = ctx->code + strlenW(ctx->code);
 591
 592     vbsheap_init(&ctx->heap);
 593
 594     ctx->parse_complete = FALSE;
 595     ctx->hres = S_OK;
 596
 597     ctx->last_token = tNL;
 598     ctx->last_nl = 0;
 599     ctx->stats = ctx->stats_tail = NULL;
 600     ctx->class_decls = NULL;
 601     ctx->option_explicit = FALSE;
 602
 603     parser_parse(ctx);
 604
 605     if(FAILED(ctx->hres))
 606         return ctx->hres;
 607     if(!ctx->parse_complete) {
 608         FIXME("parser failed on parsing %s\n", debugstr_w(ctx->ptr));
 609         return E_FAIL;
 610     }
 611
 612     return S_OK;
 613 }
 614
 615 void parser_release(parser_ctx_t *ctx)
 616 {
 617     vbsheap_free(&ctx->heap);
 618 }