git.oblomov.eu Git - wine/blob - tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of include/wine/server.h.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (
  26     "int"           => "%d",
  27     "short int"     => "%d",
  28     "char"          => "%c",
  29     "unsigned char" => "%02x",
  30     "unsigned short"=> "%04x",
  31     "unsigned int"  => "%08x",
  32     "unsigned long" => "%lx",
  33     "void*"         => "%p",
  34     "time_t"        => "%ld (long)",
  35     "size_t"        => "%lu (unsigned long)",
  36     "data_size_t"   => "%u",
  37     "obj_handle_t"  => "%p",
  38     "atom_t"        => "%04x",
  39     "user_handle_t" => "%p",
  40     "process_id_t"  => "%04x",
  41     "thread_id_t"   => "%04x",
  42     "timeout_t"     => "&dump_timeout",
  43     "rectangle_t"   => "&dump_rectangle",
  44     "char_info_t"   => "&dump_char_info",
  45     "apc_call_t"    => "&dump_apc_call",
  46     "apc_result_t"  => "&dump_apc_result",
  47     "async_data_t"  => "&dump_async_data",
  48     "luid_t"        => "&dump_luid",
  49     "ioctl_code_t"  => "&dump_ioctl_code",
  50 );
  51
  52 my @requests = ();
  53 my %replies = ();
  54
  55 my @trace_lines = ();
  56
  57
  58
  59 ### Generate a dumping function
  60
  61 sub DO_DUMP_FUNC($$@)
  62 {
  63     my $name = shift;
  64     my $req = shift;
  65     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  66     while ($#_ >= 0)
  67     {
  68         my $type = shift;
  69         my $var = shift;
  70         if (defined($formats{$type}))
  71         {
  72             if ($formats{$type} =~ /^&(.*)/)
  73             {
  74                 my $func = $1;
  75                 push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  76                 push @trace_lines, "    $func( &req->$var );\n";
  77                 push @trace_lines, "    fprintf( stderr, \",\" );\n" if ($#_ > 0);
  78             }
  79             elsif ($formats{$type} =~ /^(%.*)\s+\((.*)\)/)
  80             {
  81                 my ($format, $cast) = ($1, $2);
  82                 push @trace_lines, "    fprintf( stderr, \" $var=$format";
  83                 push @trace_lines, "," if ($#_ > 0);
  84                 push @trace_lines, "\", ($cast)req->$var );\n";
  85             }
  86             else
  87             {
  88                 push @trace_lines, "    fprintf( stderr, \" $var=$formats{$type}";
  89                 push @trace_lines, "," if ($#_ > 0);
  90                 push @trace_lines, "\", req->$var );\n";
  91             }
  92         }
  93         else  # must be some varargs format
  94         {
  95             my $func = $type;
  96             push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  97             push @trace_lines, "    $func;\n";
  98             push @trace_lines, "    fputc( ',', stderr );\n" if ($#_ > 0);
  99         }
 100     }
 101     push @trace_lines, "}\n\n";
 102 }
 103
 104 ### Parse the request definitions
 105
 106 sub PARSE_REQUESTS()
 107 {
 108     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 109     my $state = 0;
 110     my $name = "";
 111     my @in_struct = ();
 112     my @out_struct = ();
 113
 114     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 115
 116     while (<PROTOCOL>)
 117     {
 118         my ($type, $var);
 119         # strip comments
 120         s!/\*.*\*/!!g;
 121         # strip white space at end of line
 122         s/\s+$//;
 123
 124         if (/^\@HEADER/)
 125         {
 126             die "Misplaced \@HEADER" unless $state == 0;
 127             $state++;
 128             next;
 129         }
 130
 131         # ignore everything while in state 0
 132         next if $state == 0;
 133
 134         if (/^\@REQ\(\s*(\w+)\s*\)/)
 135         {
 136             $name = $1;
 137             die "Misplaced \@REQ" unless $state == 1;
 138             # start a new request
 139             @in_struct = ();
 140             @out_struct = ();
 141             print SERVER_PROT "struct ${name}_request\n{\n";
 142             print SERVER_PROT "    struct request_header __header;\n";
 143             $state++;
 144             next;
 145         }
 146
 147         if (/^\@REPLY/)
 148         {
 149             die "Misplaced \@REPLY" unless $state == 2;
 150             print SERVER_PROT "};\n";
 151             print SERVER_PROT "struct ${name}_reply\n{\n";
 152             print SERVER_PROT "    struct reply_header __header;\n";
 153             $state++;
 154             next;
 155         }
 156
 157         if (/^\@END/)
 158         {
 159             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 160             print SERVER_PROT "};\n";
 161
 162             if ($state == 2)  # build dummy reply struct
 163             {
 164                 print SERVER_PROT "struct ${name}_reply\n{\n";
 165                 print SERVER_PROT "    struct reply_header __header;\n";
 166                 print SERVER_PROT "};\n";
 167             }
 168
 169             # got a complete request
 170             push @requests, $name;
 171             DO_DUMP_FUNC( $name, "request", @in_struct);
 172             if ($#out_struct >= 0)
 173             {
 174                 $replies{$name} = 1;
 175                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 176             }
 177             $state = 1;
 178             next;
 179         }
 180
 181         if ($state != 1)
 182         {
 183             # skip empty lines (but keep them in output file)
 184             if (/^$/)
 185             {
 186                 print SERVER_PROT "\n";
 187                 next;
 188             }
 189
 190             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 191             {
 192                 $var = $1;
 193                 $type = "dump_varargs_" . $2 . "( min(cur_size,req->" . $3 . ") )";
 194                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 195             }
 196             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 197             {
 198                 $var = $1;
 199                 $type = "dump_varargs_" . $2 . "( cur_size )";
 200                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 201             }
 202             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 203             {
 204                 $type = $1;
 205                 $var = $3;
 206                 die "Unrecognized type $type" unless defined($formats{$type});
 207             }
 208             else
 209             {
 210                 die "Unrecognized syntax $_";
 211             }
 212             if ($state == 2) { push @in_struct, $type, $var; }
 213             if ($state == 3) { push @out_struct, $type, $var; }
 214         }
 215
 216         # Pass it through into the output file
 217         print SERVER_PROT $_ . "\n";
 218     }
 219     close PROTOCOL;
 220 }
 221
 222 ### Retrieve the server protocol version from the existing server_protocol.h file
 223
 224 sub GET_PROTOCOL_VERSION()
 225 {
 226     my $protocol = 0;
 227     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 228     while (<SERVER_PROT>)
 229     {
 230         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 231     }
 232     close SERVER_PROT;
 233     return $protocol;
 234 }
 235
 236 ### Retrieve the list of status and errors used in the server
 237
 238 sub GET_ERROR_NAMES()
 239 {
 240     my %errors = ();
 241     foreach my $f (glob "server/*.c")
 242     {
 243         next if $f eq "server/trace.c";
 244         open FILE, $f or die "Can't open $f";
 245         while (<FILE>)
 246         {
 247             if (/STATUS_(\w+)/)
 248             {
 249                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 250             }
 251             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 252             {
 253                 $errors{$1} = "0xc0010000 | $1";
 254             }
 255         }
 256         close FILE;
 257     }
 258     return %errors;
 259 }
 260
 261 ### Replace the contents of a file between ### make_requests ### marks
 262
 263 sub REPLACE_IN_FILE($@)
 264 {
 265     my $name = shift;
 266     my @data = @_;
 267     my @lines = ();
 268     open(FILE,$name) or die "Can't open $name";
 269     while (<FILE>)
 270     {
 271         push @lines, $_;
 272         last if /\#\#\# make_requests begin \#\#\#/;
 273     }
 274     push @lines, "\n", @data;
 275     while (<FILE>)
 276     {
 277         if (/\#\#\# make_requests end \#\#\#/) { push @lines, "\n", $_; last; }
 278     }
 279     push @lines, <FILE>;
 280     open(FILE,">$name") or die "Can't modify $name";
 281     print FILE @lines;
 282     close(FILE);
 283 }
 284
 285 ### Main
 286
 287 # Get the server protocol version
 288 my $protocol = GET_PROTOCOL_VERSION();
 289
 290 my %errors = GET_ERROR_NAMES();
 291
 292 ### Create server_protocol.h and print header
 293
 294 open SERVER_PROT, ">include/wine/server_protocol.h" or die "Cannot create include/wine/server_protocol.h";
 295 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 296 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 297 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 298 print SERVER_PROT " */\n\n";
 299 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 300 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 301
 302 ### Parse requests to find request/reply structure definitions
 303
 304 PARSE_REQUESTS();
 305
 306 ### Build the request list and structures
 307
 308 print SERVER_PROT "\n\nenum request\n{\n";
 309 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 310 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 311
 312 print SERVER_PROT "union generic_request\n{\n";
 313 print SERVER_PROT "    struct request_max_size max_size;\n";
 314 print SERVER_PROT "    struct request_header request_header;\n";
 315 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 316 print SERVER_PROT "};\n";
 317
 318 print SERVER_PROT "union generic_reply\n{\n";
 319 print SERVER_PROT "    struct request_max_size max_size;\n";
 320 print SERVER_PROT "    struct reply_header reply_header;\n";
 321 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 322 print SERVER_PROT "};\n\n";
 323
 324 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 325 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 326 close SERVER_PROT;
 327
 328 ### Output the dumping function tables
 329
 330 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 331 foreach my $req (@requests)
 332 {
 333     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 334 }
 335 push @trace_lines, "};\n\n";
 336
 337 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 338 foreach my $req (@requests)
 339 {
 340     push @trace_lines, "    (dump_func)", $replies{$req} ? "dump_${req}_reply,\n" : "0,\n";
 341 }
 342 push @trace_lines, "};\n\n";
 343
 344 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 345 foreach my $req (@requests)
 346 {
 347     push @trace_lines, "    \"$req\",\n";
 348 }
 349 push @trace_lines, "};\n\n";
 350
 351 push @trace_lines, "static const struct\n{\n";
 352 push @trace_lines, "    const char  *name;\n";
 353 push @trace_lines, "    unsigned int value;\n";
 354 push @trace_lines, "} status_names[] =\n{\n";
 355
 356 foreach my $err (sort keys %errors)
 357 {
 358     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 359 }
 360 push @trace_lines, "    { NULL, 0 }\n";
 361 push @trace_lines, "};\n";
 362
 363 REPLACE_IN_FILE( "server/trace.c", @trace_lines );
 364
 365 ### Output the request handlers list
 366
 367 my @request_lines = ();
 368
 369 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 370 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 371 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 372 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 373 foreach my $req (@requests)
 374 {
 375     push @request_lines, "    (req_handler)req_$req,\n";
 376 }
 377 push @request_lines, "};\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 378
 379 REPLACE_IN_FILE( "server/request.h", @request_lines );