git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 dnl Ported to autoconf 2.5x by bero@redhat.com
   5 AC_REVISION([configure.in 1.00])
   6 AC_INIT(controls/edit.c)
   7 AC_CONFIG_HEADER(include/config.h)
   8 AC_CONFIG_AUX_DIR(tools)
   9
  10 dnl **** Command-line arguments ****
  11
  12 dnl Default values
  13 LIBEXT=so       # library type .so or .a
  14 TRACE_MSGS=yes  # the TRACE() macro
  15 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  16 CURSES=yes
  17 OPENGL=normal
  18
  19 AC_ARG_ENABLE(debug,
  20 [  --disable-debug         compile out all debugging messages],
  21 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  22
  23 AC_ARG_ENABLE(opengl,
  24 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  25 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  26
  27 AC_ARG_ENABLE(trace,
  28 [  --disable-trace         compile out TRACE messages],
  29 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  30
  31 AC_ARG_WITH(curses,
  32 [  --without-curses        do not use curses],
  33 [if test "$withval" = "no"; then CURSES="no"; fi])
  34
  35 AC_ARG_WITH(reentrant-x,
  36 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  37
  38 AC_SUBST(OPTIONS)
  39
  40 if test "$DEBUG_MSGS" = "no"
  41 then
  42     AC_DEFINE(NO_DEBUG_MSGS, 1, [Define if all debug messages are to be compiled out])
  43 fi
  44
  45 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
  46 then
  47     AC_DEFINE(NO_TRACE_MSGS, 1, [Define if TRACE messages are to be compiled out])
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_PROG_RANLIB
  66 AC_PROG_INSTALL
  67 AC_PROG_LN_S
  68 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  69 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  70 AC_CYGWIN
  71 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  72
  73 dnl Check for lint
  74 AC_CHECK_PROGS(LINT, lclint lint)
  75 if test "$LINT" = "lint"
  76 then
  77   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  78   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  79 fi
  80 AC_SUBST(LINT)
  81 AC_SUBST(LINTFLAGS)
  82
  83 if test "$CYGWIN" = "yes"
  84 then
  85     LDCOMBINE="ld -r --enable-stdcall-fixup"
  86 else
  87     LDCOMBINE="ld -r"
  88 fi
  89 AC_SUBST(LDCOMBINE)
  90
  91 dnl **** Check for some libraries ****
  92
  93 dnl Check for -lm
  94 AC_CHECK_LIB(m,sqrt)
  95 dnl Check for -li386 for NetBSD and OpenBSD
  96 AC_CHECK_LIB(i386,i386_set_ldt)
  97 dnl Check for -lossaudio for NetBSD
  98 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  99 dnl Check for -lw for Solaris
 100 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 101 dnl Check for -lnsl for Solaris
 102 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 103 dnl Check for -lsocket for Solaris
 104 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 105 dnl Check for -lxpg4 for FreeBSD
 106 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 107 dnl Check for -lmmap for OS/2
 108 AC_CHECK_LIB(mmap,mmap)
 109 dnl Check for openpty
 110 AC_CHECK_FUNCS(openpty,,
 111         [AC_CHECK_LIB(util,openpty,
 112                 [AC_DEFINE(HAVE_OPENPTY)
 113                 LIBS="$LIBS -lutil"]
 114         )])
 115
 116 AC_CHECK_HEADERS(dlfcn.h,
 117     [AC_CHECK_FUNCS(dlopen,,
 118         [AC_CHECK_LIB(dl,dlopen,
 119                      [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 120                      LIBS="$LIBS -ldl"],
 121                      LIBEXT="a")]
 122         )],
 123         LIBEXT="a"
 124     )
 125
 126 JPEGLIB=""
 127 AC_SUBST(JPEGLIB)
 128 AC_CHECK_HEADERS(jpeglib.h,
 129     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 130         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 131         JPEGLIB="-ljpeg"
 132     )
 133 )
 134
 135
 136 AC_SUBST(XLIB)
 137 AC_SUBST(XFILES)
 138 XFILES=""
 139 AC_SUBST(OPENGLFILES)
 140 OPENGLFILES=""
 141 AC_SUBST(GLU32FILES)
 142 GLU32FILES=""
 143 if test "$have_x" = "yes"
 144 then
 145     XLIB="-lXext -lX11"
 146     ac_save_CPPFLAGS="$CPPFLAGS"
 147     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 148
 149     dnl *** Check for -lXpm
 150     AC_CHECK_HEADERS(X11/xpm.h,
 151       [ dnl *** If X11/xpm.h exists...
 152         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 153           [ AC_DEFINE(HAVE_LIBXXPM, 1, [Define if you have the Xpm library])
 154             X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 155           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 156         )
 157       ],
 158       [ dnl *** If X11/xpm.h does not exist...
 159         dnl NOTE: autoconf does not allow commas inside the third
 160         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 161         dnl       magic it does.
 162         echo "Install the following packages:"
 163         echo "Red Hat < 7.1     :       xpm xpm-devel"
 164         echo "Red Hat >= 7.1    :       XFree86-devel"
 165         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 166         echo "SuSE              :       xpm"
 167         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 168         echo
 169         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 170         echo "the directory /contrib/libraries."
 171         echo
 172         exit 1
 173       ]
 174     )
 175
 176     dnl *** All of the following tests require X11/Xlib.h
 177     AC_CHECK_HEADERS(X11/Xlib.h,
 178       [
 179         dnl *** Check for X keyboard extension
 180         AC_CHECK_HEADERS(X11/XKBlib.h,
 181             [ dnl *** If X11/XKBlib.h exists...
 182               AC_CHECK_LIB(X11, XkbQueryExtension,
 183               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 184               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 185             ],
 186             AC_MSG_WARN([XKB extension not found!!])
 187         )
 188
 189         dnl *** Check for X Shm extension
 190         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 191             [ dnl *** If X11/extensions/XShm.h exists...
 192               AC_CHECK_LIB(Xext, XShmQueryExtension,
 193               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 194               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 195             ],
 196             AC_MSG_WARN([Xshm extension not found!!])
 197         )
 198
 199         dnl *** Check for X shape extension
 200         AC_CHECK_HEADERS(X11/extensions/shape.h,
 201             [ dnl *** If X11/extensions/shape.h exists...
 202               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 203               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 204               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 205             ],
 206             AC_MSG_WARN([XShape extension not found!!])
 207         )
 208
 209         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 210         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 211             [ dnl *** If X11/extensions/xf86dga.h exists, check
 212               dnl *** for XDGAQueryExtension()...
 213               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 214                 [ dnl *** If found...
 215                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 216                             [Define if you have the Xxf86dga library version 2])
 217                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 218                ],
 219                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 220                   dnl *** instead (DGA 2.0 not found)...
 221                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 222                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 223                                 [Define if you have the Xxf86dga library version 1])
 224                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 225                     ],,
 226                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 227                   )
 228                 ],
 229                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 230               )
 231             ],
 232             AC_MSG_WARN([DGA extension not found!!])
 233         )
 234
 235         dnl *** Check for XFree86 VMODE extension
 236         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 237             [ dnl *** If X11/extensions/xf86vmode.h exists...
 238                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 239                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 240                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 241                   ],,
 242                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 243                 )
 244             ],
 245             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 246         )
 247
 248         dnl *** Check for XVideo extension supporting XvImages
 249         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 250             [ dnl *** If X11/extensions/Xvlib.h exists...
 251                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 252                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 253                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 254                   ],,
 255                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 256                 )
 257             ],
 258             AC_MSG_WARN([XVideo extension not found !!])
 259         )
 260
 261         dnl *** Check for XRender extension
 262         AC_CHECK_HEADERS(X11/extensions/Xrender.h,
 263             [ dnl *** If X11/extensions/Xrender.h exists...
 264                 AC_CHECK_LIB(Xrender, XRenderQueryExtension,
 265                   [ AC_DEFINE(HAVE_LIBXRENDER, 1, [Define if you have the XRender extension library])
 266                      X_PRE_LIBS="$X_PRE_LIBS -lXrender"
 267                   ],,
 268                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 269                 )
 270             ],
 271             AC_MSG_WARN([XRender extension not found !!])
 272         )
 273
 274       ]
 275     ) dnl *** End of X11/Xlib.h check
 276
 277     dnl Check for the presence of OpenGL
 278     if test $OPENGL = "yes" -o $OPENGL = "normal"
 279     then
 280         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 281         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 282         then
 283             dnl Check for some problems due to old Mesa versions
 284             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 285               AC_TRY_COMPILE(
 286                 [#include <GL/gl.h>],
 287                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 288                 [wine_cv_opengl_version_OK="yes"],
 289                 [wine_cv_opengl_version_OK="no"]
 290               )
 291             )
 292
 293             dnl Check for the thread-safety of the OpenGL library
 294             AC_CACHE_CHECK([for thread-safe OpenGL version],
 295                            wine_cv_opengl_version_threadsafe,
 296               [saved_libs=$LIBS
 297                LIBS="$X_LIBS -lGL"
 298                AC_TRY_LINK([],[pthread_getspecific();],
 299                               [wine_cv_opengl_version_threadsafe="yes"],
 300                               [wine_cv_opengl_version_threadsafe="no"])
 301                LIBS=$saved_libs]
 302             )
 303
 304             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 305             then
 306                 dnl Check for the presence of the library
 307                 AC_CHECK_LIB(GL,glXCreateContext,
 308                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 309                              ,,
 310                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 311
 312                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 313                 then
 314
 315                         OPENGLFILES='$(OPENGLFILES)'
 316                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 317
 318                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 319                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 320                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 321                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 322
 323                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 324                         then
 325                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 326                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 327                                                   #ifdef HAVE_GL_GLEXT_H
 328                                                   # include <GL/glext.h>
 329                                                   #endif
 330                                                   ],
 331                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 332                                                  [wine_cv_extension_prototypes="yes"],
 333                                                  [wine_cv_extension_prototypes="no"]
 334                                   )]
 335                                 )
 336                                 if test $wine_cv_extension_prototypes = "yes"
 337                                 then
 338                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 339                                               [Define if the OpenGL headers define extension typedefs])
 340                                 fi
 341                         fi
 342
 343                 fi
 344                 dnl Check for GLU32 library.
 345                 AC_CHECK_LIB(GLU,gluLookAt,
 346                              [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
 347                              GLU32FILES='$(GLU32FILES)']
 348                              ,,
 349                              $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 350                 )
 351              fi
 352          fi
 353     fi
 354
 355     CPPFLAGS="$ac_save_CPPFLAGS"
 356     XFILES='$(XFILES)'
 357 else
 358     XLIB=""
 359     X_CFLAGS=""
 360     X_LIBS=""
 361 fi
 362
 363 dnl **** Check which curses lib to use ***
 364 if test "$CURSES" = "yes"
 365 then
 366     AC_CHECK_HEADERS(ncurses.h,
 367         AC_CHECK_LIB(ncurses,waddch),
 368         [AC_CHECK_HEADERS(curses.h,[AC_CHECK_LIB(curses,waddch)])])
 369     AC_CHECK_FUNCS(getbkgd resizeterm)
 370 fi
 371
 372 CUPSLIBS=""
 373 dnl **** Check for CUPS ****
 374 wine_cv_warn_cups_h=no
 375 AC_CHECK_LIB(cups,cupsGetPPD,
 376         [AC_CHECK_HEADER(cups/cups.h,
 377             [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
 378             CUPSLIBS="-lcups"],
 379             wine_cv_warn_cups_h=yes)]
 380 )
 381 AC_SUBST(CUPSLIBS)
 382
 383 dnl **** Check for FreeType 2 ****
 384 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no)
 385 if test "$ft_lib" = "no"
 386 then
 387     FREETYPELIBS=""
 388     FREETYPEINCL=""
 389     wine_cv_msg_freetype=no
 390 else
 391     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 392     if test "$ft_devel" = "no"
 393     then
 394         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 395         if test "$ft_devel2" = "freetype2-config"
 396         then
 397                 ft_devel=$ft_devel2
 398         fi
 399     fi
 400     if test "$ft_devel" = "no"
 401     then
 402         FREETYPELIBS=""
 403         FREETYPEINCL=""
 404         wine_cv_msg_freetype=yes
 405     else
 406         AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 407         FREETYPELIBS=`$ft_devel --libs`
 408         FREETYPEINCL=`$ft_devel --cflags`
 409         ac_save_CPPFLAGS="$CPPFLAGS"
 410         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 411         AC_CHECK_HEADERS(freetype/freetype.h \
 412                          freetype/ftglyph.h \
 413                          freetype/tttables.h \
 414                          freetype/ftnames.h \
 415                          freetype/ftsnames.h \
 416                          freetype/ttnameid.h \
 417                          freetype/ftoutln.h)
 418         CPPFLAGS="$ac_save_CPPFLAGS"
 419         wine_cv_msg_freetype=no
 420     fi
 421 fi
 422 AC_SUBST(FREETYPELIBS)
 423 AC_SUBST(FREETYPEINCL)
 424
 425 dnl **** Check for parport (currently Linux only) ****
 426 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 427  AC_TRY_COMPILE(
 428    [#include <linux/ppdev.h>],
 429    [ioctl (1,PPCLAIM,0)],
 430    [ac_cv_c_ppdev="yes"],
 431    [ac_cv_c_ppdev="no"])
 432  )
 433 if test "$ac_cv_c_ppdev" = "yes"
 434 then
 435     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 436 fi
 437
 438 dnl **** Check for IPX (currently Linux only) ****
 439 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
 440  AC_TRY_COMPILE(
 441    [#include <sys/socket.h>
 442     #include <netipx/ipx.h>],
 443    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 444    [ac_cv_c_ipx_gnu="yes"],
 445    [ac_cv_c_ipx_gnu="no"])
 446  )
 447 if test "$ac_cv_c_ipx_gnu" = "yes"
 448 then
 449     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
 450 fi
 451
 452 if test "$ac_cv_c_ipx_gnu" = "no"
 453 then
 454  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
 455   AC_TRY_COMPILE(
 456     [#include <sys/socket.h>
 457      #include <asm/types.h>
 458      #include <linux/ipx.h>],
 459     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 460     [ac_cv_c_ipx_linux="yes"],
 461     [ac_cv_c_ipx_linux="no"])
 462   )
 463   if test "$ac_cv_c_ipx_linux" = "yes"
 464   then
 465       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
 466   fi
 467 fi
 468
 469 dnl **** Check for Open Sound System ****
 470 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 471
 472 AC_CACHE_CHECK([for Open Sound System],
 473         ac_cv_c_opensoundsystem,
 474         AC_TRY_COMPILE([
 475         #if defined(HAVE_SYS_SOUNDCARD_H)
 476                 #include <sys/soundcard.h>
 477         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 478                 #include <machine/soundcard.h>
 479         #elif defined(HAVE_SOUNDCARD_H)
 480                 #include <soundcard.h>
 481         #endif
 482         ],[
 483
 484 /* check for one of the Open Sound System specific SNDCTL_ defines */
 485 #if !defined(SNDCTL_DSP_STEREO)
 486 #error No open sound system
 487 #endif
 488 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 489
 490 if test "$ac_cv_c_opensoundsystem" = "yes"
 491 then
 492     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 493 fi
 494
 495 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 496         ac_cv_c_opensoundsystem_midi,
 497         AC_TRY_COMPILE([
 498         #if defined(HAVE_SYS_SOUNDCARD_H)
 499                 #include <sys/soundcard.h>
 500         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 501                 #include <machine/soundcard.h>
 502         #elif defined(HAVE_SOUNDCARD_H)
 503                 #include <soundcard.h>
 504         #endif
 505         ],[
 506
 507 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 508 #if !defined(SNDCTL_SEQ_SYNC)
 509 #error No open sound system MIDI interface
 510 #endif
 511 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 512
 513 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 514 then
 515     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 516 fi
 517
 518 dnl **** If ln -s doesn't work, use cp instead ****
 519 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 520
 521 dnl **** Check for broken glibc mmap64 ****
 522
 523 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 524         AC_TRY_RUN([
 525                 #define _FILE_OFFSET_BITS 64
 526                 #include <stdio.h>
 527                 #include <unistd.h>
 528                 #include <fcntl.h>
 529                 #include <sys/mman.h>
 530                 #include <errno.h>
 531
 532                 int main(int argc,char **argv) {
 533                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 534                         if (fd == -1) exit(1);
 535
 536                         unlink("conftest.map");
 537
 538                         write(fd,"test",4);
 539
 540                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 541                             (errno == EINVAL)
 542                         ) {
 543                                 exit(1);
 544                         }
 545                         close(fd);
 546                         fprintf(stderr,"success!\n");
 547                         exit(0);
 548                 }
 549
 550         ],
 551     ac_cv_mmap64_works="yes",
 552     ac_cv_mmap64_works="no",
 553     ac_cv_mmap64_works="no") )
 554
 555 if test "$ac_cv_mmap64_works" = "yes"
 556 then
 557     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 558 fi
 559
 560 dnl **** Check for gcc strength-reduce bug ****
 561
 562 if test "x${GCC}" = "xyes"
 563 then
 564   CFLAGS="$CFLAGS -Wall"
 565   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 566                   AC_TRY_RUN([
 567 int     L[[4]] = {0,1,2,3};
 568 int main(void) {
 569   static int Array[[3]];
 570   unsigned int B = 3;
 571   int i;
 572   for(i=0; i<B; i++) Array[[i]] = i - 3;
 573   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 574   L[[i]] = 4;
 575
 576   exit( Array[[1]] != -2 || L[[2]] != 3);
 577 }],
 578     ac_cv_c_gcc_strength_bug="no",
 579     ac_cv_c_gcc_strength_bug="yes",
 580     ac_cv_c_gcc_strength_bug="yes") )
 581   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 582   then
 583     CFLAGS="$CFLAGS -fno-strength-reduce"
 584   fi
 585
 586   dnl Check for -mpreferred-stack-boundary
 587   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support],
 588                  ac_cv_c_gcc_stack_boundary,
 589   [saved_cflags=$CFLAGS
 590   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 591   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 592   CFLAGS=$saved_cflags
 593   ])
 594   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 595   then
 596     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 597   fi
 598 fi
 599
 600 dnl **** Check if we need to place .type inside a .def directive ****
 601
 602 AC_CACHE_CHECK([whether .type must sit inside a .def directive],
 603                ac_cv_c_type_in_def,
 604 [saved_libs=$LIBS
 605 LIBS="conftest_asm.s $LIBS"
 606 cat > conftest_asm.s <<EOF
 607         .globl _ac_test
 608         .def _ac_test; .scl 2; .type 32; .endef
 609 _ac_test:
 610         .long 0
 611 EOF
 612 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 613 LIBS=$saved_libs])
 614 if test "$ac_cv_c_type_in_def" = "yes"
 615 then
 616   AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
 617 fi
 618
 619 dnl **** Check for underscore on external symbols ****
 620
 621 AC_CACHE_CHECK([whether external symbols need an underscore prefix],
 622                ac_cv_c_extern_prefix,
 623 [saved_libs=$LIBS
 624 LIBS="conftest_asm.s $LIBS"
 625 cat > conftest_asm.s <<EOF
 626         .globl _ac_test
 627 _ac_test:
 628         .long 0
 629 EOF
 630 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 631             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 632 LIBS=$saved_libs])
 633 if test "$ac_cv_c_extern_prefix" = "yes"
 634 then
 635   AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
 636             [Define if symbols declared in assembly code need an underscore prefix])
 637 fi
 638
 639 dnl **** Check for .string in assembler ****
 640
 641 AC_CACHE_CHECK([whether assembler accepts .string],
 642                ac_cv_c_asm_string,
 643 [saved_libs=$LIBS
 644 LIBS="conftest_asm.s $LIBS"
 645 cat > conftest_asm.s <<EOF
 646         .string "test"
 647 EOF
 648 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 649 LIBS=$saved_libs])
 650 if test "$ac_cv_c_asm_string" = "yes"
 651 then
 652   AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
 653 fi
 654
 655 dnl **** Check for working dll ****
 656
 657 LDSHARED=""
 658 LDDLLFLAGS=""
 659 if test "$LIBEXT" = "so"
 660 then
 661   AC_CACHE_CHECK([whether we can build a GNU style ELF dll],
 662                  ac_cv_c_dll_gnuelf,
 663   [saved_cflags=$CFLAGS
 664   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 665   AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
 666   CFLAGS=$saved_cflags
 667   ])
 668   if test "$ac_cv_c_dll_gnuelf" = "yes"
 669   then
 670     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 671     LDDLLFLAGS="-Wl,-Bsymbolic"
 672   else
 673     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 674                  ac_cv_c_dll_unixware,
 675     [saved_cflags=$CFLAGS
 676     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 677     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 678     CFLAGS=$saved_cflags
 679     ])
 680     if test "$ac_cv_c_dll_unixware" = "yes"
 681     then
 682       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 683       LDDLLFLAGS="-Wl,-B,symbolic"
 684     fi
 685   fi
 686   if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
 687   then
 688     LIBEXT="a"
 689     if test "$DLLWRAP" = "dllwrap"; then
 690       dnl FIXME - check whether dllwrap works correctly...
 691       if test "$CYGWIN" = "yes"; then
 692         echo "*** use dllwrap for building shared library."
 693         LIBEXT="dll"
 694       fi
 695     fi
 696   fi
 697 fi
 698
 699 if test "$LIBEXT" = "a"; then
 700   echo "*** It is currently not possible to build WINE without shared"
 701   echo "*** library (.so) support to allow transparent switch between .so"
 702   echo "*** and .dll files."
 703   echo "*** If you are using Linux, you will need a newer binutils."
 704   exit 1
 705 fi
 706
 707 DLLFLAGS=""
 708 LDPATH=""
 709
 710 if test "$LIBEXT" = "so"; then
 711     DLLFLAGS="-fPIC"
 712     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 713 elif test "$LIBEXT" = "dll"; then
 714     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 715     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 716 fi
 717
 718 AC_SUBST(DLLFLAGS)
 719 AC_SUBST(LDSHARED)
 720 AC_SUBST(LDDLLFLAGS)
 721 AC_SUBST(LIBEXT)
 722 AC_SUBST(LDPATH)
 723
 724 dnl **** Check for reentrant libc ****
 725 dnl
 726 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 727 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 728
 729 AC_DEFUN([WINE_CHECK_ERRNO],
 730 [
 731   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 732   [AC_TRY_RUN([int myerrno = 0;
 733 char buf[256];
 734 int *$1(){return &myerrno;}
 735 main(){connect(0,buf,255); exit(!myerrno);}],
 736   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 737   wine_cv_libc_r_$1=yes )
 738 ])
 739 if test "$wine_cv_libc_r_$1" = "yes"
 740 then
 741     wine_cv_libc_reentrant=$1
 742 fi
 743 ])
 744
 745 wine_cv_libc_reentrant=no
 746 dnl Linux style errno location
 747 WINE_CHECK_ERRNO(__errno_location)
 748 dnl FreeBSD style errno location
 749 WINE_CHECK_ERRNO(__error)
 750 dnl Solaris style errno location
 751 WINE_CHECK_ERRNO(___errno)
 752 dnl UnixWare style errno location
 753 WINE_CHECK_ERRNO(__thr_errno)
 754 dnl NetBSD style errno location
 755 WINE_CHECK_ERRNO(__errno)
 756
 757 if test "$wine_cv_libc_reentrant" != "no"
 758 then
 759   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
 760                      [Define to the name of the function returning errno for reentrant libc])
 761 fi
 762
 763 dnl **** Check for reentrant X libraries ****
 764 dnl
 765 dnl This may fail to determine whether X libraries are reentrant if
 766 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 767 dnl is possible with the --without-reentrant-x option.
 768
 769 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 770 then
 771 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
 772   [ if test "x$with_reentrant_x" = "xno"
 773     then
 774         wine_cv_x_reentrant=no
 775     else
 776         libX11_check=none
 777         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 778             if test -r $dir/libX11.so; then
 779                 libX11_check="-D $dir/libX11.so"
 780                 break 1
 781             fi
 782             if test -r $dir/libX11.a; then
 783                 libX11_check="$dir/libX11.a"
 784                 break 1
 785             fi
 786         done
 787         if test "$libX11_check" != "none"; then
 788             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 789             then
 790                 wine_cv_x_reentrant=yes
 791             else
 792                 wine_cv_x_reentrant=no
 793             fi
 794         else
 795             wine_cv_x_reentrant=unknown
 796         fi
 797     fi ] )
 798 else
 799     wine_cv_x_reentrant=no
 800 fi
 801 if test "$wine_cv_x_reentrant" = "no"
 802 then
 803   AC_DEFINE(NO_REENTRANT_X11, 1,
 804             [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
 805 fi
 806
 807
 808 dnl **** Check for functions ****
 809
 810 AC_FUNC_ALLOCA()
 811 AC_CHECK_FUNCS(\
 812         __libc_fork \
 813         _lwp_create \
 814         clone \
 815         ecvt \
 816         finite \
 817         fpclass \
 818         ftruncate64 \
 819         getnetbyaddr \
 820         getnetbyname \
 821         getpagesize \
 822         getprotobyname \
 823         getprotobynumber \
 824         getrlimit \
 825         getservbyport \
 826         getsockopt \
 827         inet_network \
 828         lseek64 \
 829         lstat \
 830         memmove \
 831         mmap \
 832         rfork \
 833         select \
 834         sendmsg \
 835         settimeofday \
 836         sigaltstack \
 837         statfs \
 838         strcasecmp \
 839         strerror \
 840         strncasecmp \
 841         tcgetattr \
 842         timegm \
 843         usleep \
 844         vfscanf \
 845         wait4 \
 846         waitpid \
 847 )
 848
 849 dnl **** Check for header files ****
 850
 851 AC_CHECK_HEADERS(\
 852         arpa/inet.h \
 853         arpa/nameser.h \
 854         elf.h \
 855         float.h \
 856         ieeefp.h \
 857         libio.h \
 858         libutil.h \
 859         link.h \
 860         linux/cdrom.h \
 861         linux/input.h \
 862         linux/joystick.h \
 863         linux/ucdrom.h \
 864         net/if.h \
 865         netdb.h \
 866         netinet/in.h \
 867         netinet/in_systm.h \
 868         netinet/ip.h \
 869         netinet/tcp.h \
 870         pty.h \
 871         resolv.h \
 872         sched.h \
 873         socket.h \
 874         strings.h \
 875         sys/cdio.h \
 876         sys/errno.h \
 877         sys/file.h \
 878         sys/filio.h \
 879         sys/ipc.h \
 880         sys/link.h \
 881         sys/lwp.h \
 882         sys/mman.h \
 883         sys/modem.h \
 884         sys/mount.h \
 885         sys/msg.h \
 886         sys/param.h \
 887         sys/ptrace.h \
 888         sys/reg.h \
 889         sys/signal.h \
 890         sys/shm.h \
 891         sys/socket.h \
 892         sys/sockio.h \
 893         sys/statfs.h \
 894         sys/strtio.h \
 895         sys/syscall.h \
 896         sys/user.h \
 897         sys/wait.h \
 898         sys/v86.h \
 899         sys/v86intr.h \
 900         sys/vfs.h \
 901         sys/vm86.h \
 902         syscall.h \
 903         ucontext.h \
 904 )
 905 AC_HEADER_STAT()
 906
 907 dnl **** Check for types ****
 908
 909 AC_C_CONST()
 910 AC_C_INLINE()
 911 AC_TYPE_SIZE_T()
 912 AC_CHECK_SIZEOF(long long,0)
 913
 914 AC_CACHE_CHECK([whether linux/input.h is for real],
 915         wine_cv_linux_input_h,
 916         AC_TRY_COMPILE([
 917             #include <linux/input.h>
 918         ] , [
 919             int foo = EVIOCGBIT(EV_ABS,42);
 920             int bar = BTN_PINKIE;
 921             int fortytwo = 42;
 922         ],
 923         wine_cv_linux_input_h=yes,
 924         wine_cv_linux_input_h=no,
 925         no
 926         )
 927     )
 928     if test "$wine_cv_linux_input_h" = "yes"
 929     then
 930         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
 931                   [Define if we have linux/input.h AND it contains the INPUT event API])
 932     fi
 933
 934
 935 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
 936         wine_cv_linux_gethostbyname_r_6,
 937         AC_TRY_COMPILE([
 938 #include <netdb.h>
 939         ], [
 940     char *name=NULL;
 941     struct hostent he;
 942     struct hostent *result;
 943     char *buf=NULL;
 944     int bufsize=0;
 945     int res,errnr;
 946     char *addr=NULL;
 947     int addrlen=0;
 948     int addrtype=0;
 949     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 950     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 951     ],
 952         wine_cv_linux_gethostbyname_r_6=yes,
 953         wine_cv_linux_gethostbyname_r_6=no
 954         )
 955    )
 956    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 957    then
 958       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
 959                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
 960    fi
 961
 962 if test "$ac_cv_header_linux_joystick_h" = "yes"
 963 then
 964    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
 965         wine_cv_linux_joystick_22_api,
 966         AC_TRY_COMPILE([
 967         #include <sys/ioctl.h>
 968         #include <linux/joystick.h>
 969
 970         struct js_event blub;
 971         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 972         #error "no 2.2 header"
 973         #endif
 974         ],/*empty*/,
 975         wine_cv_linux_joystick_22_api=yes,
 976         wine_cv_linux_joystick_22_api=no,
 977         wine_cv_linux_joystick_22_api=no
 978         )
 979    )
 980    if test "$wine_cv_linux_joystick_22_api" = "yes"
 981    then
 982       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
 983                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
 984    fi
 985 fi
 986
 987 dnl **** statfs checks ****
 988
 989 if test "$ac_cv_header_sys_vfs_h" = "yes"
 990 then
 991     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
 992                     wine_cv_sys_vfs_has_statfs,
 993         AC_TRY_COMPILE([
 994         #include <sys/types.h>
 995         #ifdef HAVE_SYS_PARAM_H
 996         # include <sys/param.h>
 997         #endif
 998         #include <sys/vfs.h>
 999         ],[
1000                 struct statfs stfs;
1001
1002                 memset(&stfs,0,sizeof(stfs));
1003         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1004         )
1005     )
1006     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1007     then
1008       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1009                 [Define if the struct statfs is defined by <sys/vfs.h>])
1010     fi
1011 fi
1012
1013 if test "$ac_cv_header_sys_statfs_h" = "yes"
1014 then
1015     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1016                     wine_cv_sys_statfs_has_statfs,
1017         AC_TRY_COMPILE([
1018         #include <sys/types.h>
1019         #ifdef HAVE_SYS_PARAM_H
1020         # include <sys/param.h>
1021         #endif
1022         #include <sys/statfs.h>
1023         ],[
1024                 struct statfs stfs;
1025         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1026         )
1027     )
1028     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1029     then
1030       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1031                 [Define if the struct statfs is defined by <sys/statfs.h>])
1032     fi
1033 fi
1034
1035 if test "$ac_cv_header_sys_mount_h" = "yes"
1036 then
1037     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1038                     wine_cv_sys_mount_has_statfs,
1039         AC_TRY_COMPILE([
1040         #include <sys/types.h>
1041         #ifdef HAVE_SYS_PARAM_H
1042         # include <sys/param.h>
1043         #endif
1044         #include <sys/mount.h>
1045         ],[
1046                 struct statfs stfs;
1047         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1048         )
1049     )
1050     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1051     then
1052       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1053                 [Define if the struct statfs is defined by <sys/mount.h>])
1054     fi
1055 fi
1056
1057 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1058
1059 AC_CACHE_CHECK( [for statfs.f_bfree], wine_cv_statfs_bfree,
1060   [ if test "x$statfs_bfree" = "xno"
1061     then
1062         wine_cv_statfs_bfree=no
1063     else
1064         AC_TRY_COMPILE([
1065         #include <sys/types.h>
1066         #ifdef HAVE_SYS_PARAM_H
1067         # include <sys/param.h>
1068         #endif
1069         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1070         # include <sys/mount.h>
1071         #else
1072         # ifdef STATFS_DEFINED_BY_SYS_VFS
1073         #  include <sys/vfs.h>
1074         # else
1075         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1076         #   include <sys/statfs.h>
1077         #  endif
1078         # endif
1079         #endif
1080         ],[
1081                 struct statfs stfs;
1082
1083                 stfs.f_bfree++;
1084         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1085         )
1086     fi ] )
1087 if test "$wine_cv_statfs_bfree" = "yes"
1088 then
1089   AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1090 fi
1091
1092 AC_CACHE_CHECK( [for statfs.f_bavail], wine_cv_statfs_bavail,
1093   [ if test "x$statfs_bavail" = "xno"
1094     then
1095         wine_cv_statfs_bavail=no
1096     else
1097         AC_TRY_COMPILE([
1098         #include <sys/types.h>
1099         #ifdef HAVE_SYS_PARAM_H
1100         # include <sys/param.h>
1101         #endif
1102         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1103         # include <sys/mount.h>
1104         #else
1105         # ifdef STATFS_DEFINED_BY_SYS_VFS
1106         #  include <sys/vfs.h>
1107         # else
1108         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1109         #   include <sys/statfs.h>
1110         #  endif
1111         # endif
1112         #endif
1113         ],[
1114                 struct statfs stfs;
1115
1116                 stfs.f_bavail++;
1117         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1118         )
1119     fi ] )
1120 if test "$wine_cv_statfs_bavail" = "yes"
1121 then
1122   AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1123 fi
1124
1125 dnl *** check for file descriptor passing with msg_accrights
1126
1127 AC_CACHE_CHECK([for msg_accrights in struct msghdr], ac_cv_c_msg_accrights,
1128  AC_TRY_COMPILE([#include <sys/types.h>
1129 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1130                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1131 if test "$ac_cv_c_msg_accrights" = "yes"
1132 then
1133     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1134 fi
1135
1136 dnl *** Check for the sa_len member in struct sockaddr
1137
1138 AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_c_sockaddr_sa_len,
1139  AC_TRY_COMPILE([#include <sys/types.h>
1140 #include <sys/socket.h>
1141 ], [static struct sockaddr addr; addr.sa_len = 1],
1142                 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1143 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1144 then
1145     AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1146 fi
1147
1148 dnl *** Check for the sun_len member in struct sockaddr_un
1149
1150 AC_CACHE_CHECK([for sun_len in struct sockaddr_un], ac_cv_c_sockaddr_sun_len,
1151  AC_TRY_COMPILE([#include <sys/types.h>
1152 #include <sys/socket.h>
1153 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1154                 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1155 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1156 then
1157     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1158 fi
1159
1160 dnl *** check for the need to define __i386__
1161
1162 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1163  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1164 yes
1165 #endif],
1166  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1167 if test "$ac_cv_cpp_def_i386" = "yes"
1168 then
1169     CFLAGS="$CFLAGS -D__i386__"
1170     LINTFLAGS="$LINTFLAGS -D__i386__"
1171 fi
1172
1173 dnl $GCC is set by autoconf
1174 GCC_NO_BUILTIN=""
1175 if test "$GCC" = "yes"
1176 then
1177     GCC_NO_BUILTIN="-fno-builtin"
1178 fi
1179 AC_SUBST(GCC_NO_BUILTIN)
1180
1181 dnl **** Generate output files ****
1182
1183 AC_OUTPUT_COMMANDS([
1184 extra_subdirs="\
1185 dlls/ddraw/d3ddevice \
1186 dlls/ddraw/dclipper \
1187 dlls/ddraw/ddraw \
1188 dlls/ddraw/direct3d \
1189 dlls/ddraw/dpalette \
1190 dlls/ddraw/dsurface \
1191 dlls/dinput/joystick \
1192 dlls/dinput/keyboard \
1193 dlls/dinput/mouse \
1194 dlls/kernel/messages \
1195 dlls/user/dde \
1196 dlls/user/resources \
1197 dlls/wineps/data \
1198 "
1199 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1200
1201 MAKE_RULES=Make.rules
1202 AC_SUBST_FILE(MAKE_RULES)
1203
1204 MAKE_DLL_RULES=dlls/Makedll.rules
1205 AC_SUBST_FILE(MAKE_DLL_RULES)
1206
1207 MAKE_PROG_RULES=programs/Makeprog.rules
1208 AC_SUBST_FILE(MAKE_PROG_RULES)
1209
1210 AC_OUTPUT([
1211 Make.rules
1212 dlls/Makedll.rules
1213 programs/Makeprog.rules
1214 Makefile
1215 console/Makefile
1216 controls/Makefile
1217 debugger/Makefile
1218 dlls/Makefile
1219 dlls/advapi32/Makefile
1220 dlls/avifil32/Makefile
1221 dlls/comctl32/Makefile
1222 dlls/commdlg/Makefile
1223 dlls/crtdll/Makefile
1224 dlls/dciman32/Makefile
1225 dlls/ddraw/Makefile
1226 dlls/dinput/Makefile
1227 dlls/dplay/Makefile
1228 dlls/dplayx/Makefile
1229 dlls/dsound/Makefile
1230 dlls/gdi/Makefile
1231 dlls/glu32/Makefile
1232 dlls/icmp/Makefile
1233 dlls/imagehlp/Makefile
1234 dlls/imm32/Makefile
1235 dlls/kernel/Makefile
1236 dlls/lzexpand/Makefile
1237 dlls/mapi32/Makefile
1238 dlls/mpr/Makefile
1239 dlls/msacm/Makefile
1240 dlls/msimg32/Makefile
1241 dlls/msnet32/Makefile
1242 dlls/msvcrt/Makefile
1243 dlls/msvideo/Makefile
1244 dlls/ntdll/Makefile
1245 dlls/odbc32/Makefile
1246 dlls/ole32/Makefile
1247 dlls/oleaut32/Makefile
1248 dlls/olecli/Makefile
1249 dlls/oledlg/Makefile
1250 dlls/olepro32/Makefile
1251 dlls/olesvr/Makefile
1252 dlls/opengl32/Makefile
1253 dlls/psapi/Makefile
1254 dlls/quartz/Makefile
1255 dlls/rasapi32/Makefile
1256 dlls/richedit/Makefile
1257 dlls/rpcrt4/Makefile
1258 dlls/serialui/Makefile
1259 dlls/setupapi/Makefile
1260 dlls/shdocvw/Makefile
1261 dlls/shell32/Makefile
1262 dlls/shfolder/Makefile
1263 dlls/shlwapi/Makefile
1264 dlls/sti/Makefile
1265 dlls/tapi32/Makefile
1266 dlls/ttydrv/Makefile
1267 dlls/url/Makefile
1268 dlls/urlmon/Makefile
1269 dlls/user/Makefile
1270 dlls/version/Makefile
1271 dlls/win32s/Makefile
1272 dlls/winaspi/Makefile
1273 dlls/winedos/Makefile
1274 dlls/wineps/Makefile
1275 dlls/wininet/Makefile
1276 dlls/winmm/Makefile
1277 dlls/winmm/joystick/Makefile
1278 dlls/winmm/mcianim/Makefile
1279 dlls/winmm/mciavi/Makefile
1280 dlls/winmm/mcicda/Makefile
1281 dlls/winmm/mciseq/Makefile
1282 dlls/winmm/mciwave/Makefile
1283 dlls/winmm/midimap/Makefile
1284 dlls/winmm/wavemap/Makefile
1285 dlls/winmm/wineoss/Makefile
1286 dlls/winnls/Makefile
1287 dlls/winsock/Makefile
1288 dlls/winspool/Makefile
1289 dlls/wintrust/Makefile
1290 dlls/wow32/Makefile
1291 dlls/wsock32/Makefile
1292 dlls/x11drv/Makefile
1293 documentation/Makefile
1294 documentation/wine.conf.man
1295 documentation/wine.man
1296 files/Makefile
1297 graphics/Makefile
1298 graphics/enhmetafiledrv/Makefile
1299 graphics/metafiledrv/Makefile
1300 graphics/win16drv/Makefile
1301 graphics/x11drv/Makefile
1302 if1632/Makefile
1303 include/Makefile
1304 library/Makefile
1305 libtest/Makefile
1306 loader/Makefile
1307 loader/dos/Makefile
1308 loader/ne/Makefile
1309 memory/Makefile
1310 misc/Makefile
1311 miscemu/Makefile
1312 msdos/Makefile
1313 objects/Makefile
1314 ole/Makefile
1315 programs/Makefile
1316 programs/avitools/Makefile
1317 programs/clock/Makefile
1318 programs/cmdlgtst/Makefile
1319 programs/control/Makefile
1320 programs/notepad/Makefile
1321 programs/osversioncheck/Makefile
1322 programs/progman/Makefile
1323 programs/regapi/Makefile
1324 programs/regtest/Makefile
1325 programs/uninstaller/Makefile
1326 programs/view/Makefile
1327 programs/wcmd/Makefile
1328 programs/winemine/Makefile
1329 programs/winetest/Makefile
1330 programs/winhelp/Makefile
1331 programs/winver/Makefile
1332 relay32/Makefile
1333 scheduler/Makefile
1334 server/Makefile
1335 tools/Makefile
1336 tools/winapi/Makefile
1337 tools/winebuild/Makefile
1338 tools/winedump/Makefile
1339 tools/winelauncher
1340 tools/wmc/Makefile
1341 tools/wrc/Makefile
1342 tsx11/Makefile
1343 unicode/Makefile
1344 win32/Makefile
1345 windows/Makefile
1346 windows/x11drv/Makefile ])
1347
1348 if test "$have_x" = "no"
1349 then
1350   echo
1351   echo "*** Warning: X development files not found. Wine will be built without"
1352   echo "*** X support, which currently does not work, and would probably not be"
1353   echo "*** what you want anyway. You will need to install devel packages of"
1354   echo "*** Xlib/Xfree86 and Xpm at the very least."
1355 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1356 then
1357   echo
1358   echo "*** Warning: Xpm development files not found. Wine will be built without"
1359   echo "*** Xpm support, which currently does not work. You will need to install"
1360   echo "*** devel packages of Xpm."
1361 fi
1362
1363 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1364 then
1365   echo
1366   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1367   echo "*** terminal resize support. Consider upgrading ncurses."
1368 fi
1369
1370 if test "$wine_cv_libc_reentrant" = "no"
1371 then
1372   echo
1373   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1374   echo "*** thread support. Consider upgrading libc to a more recent"
1375   echo "*** reentrant version of libc."
1376 fi
1377
1378 if test "$wine_cv_opengl_version_OK" = "no"
1379 then
1380   echo
1381   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1382   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1383 fi
1384
1385 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1386 then
1387   echo
1388   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1389   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1390   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1391   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1392 fi
1393
1394 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1395 then
1396   echo
1397   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1398   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1399   echo "*** support before reporting bugs."
1400 fi
1401
1402 if test "$wine_cv_warn_cups_h" = "yes"
1403 then
1404   echo
1405   echo "*** Note: You have cups runtime libraries, but no development"
1406   echo "*** libraries. Install the cups-devel package or whichever package"
1407   echo "*** contains cups.h to enable CUPS support in WINE."
1408 fi
1409
1410 if test "$wine_cv_msg_freetype" = "yes"
1411 then
1412   echo
1413   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1414   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1415   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1416   echo "*** enable Wine to use TrueType fonts."
1417 fi
1418
1419 echo
1420 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1421 echo
1422
1423 dnl Local Variables:
1424 dnl comment-start: "dnl "
1425 dnl comment-end: ""
1426 dnl comment-start-skip: "\\bdnl\\b\\s *"
1427 dnl compile-command: "autoconf"
1428 dnl End: