git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 dnl Ported to autoconf 2.5x by bero@redhat.com
   5 AC_REVISION([configure.in 1.00])
   6 AC_INIT(controls/edit.c)
   7 AC_CONFIG_HEADER(include/config.h)
   8 AC_CONFIG_AUX_DIR(tools)
   9
  10 dnl **** Command-line arguments ****
  11
  12 dnl Default values
  13 LIBEXT=so       # library type .so or .a
  14 TRACE_MSGS=yes  # the TRACE() macro
  15 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  16 CURSES=yes
  17 OPENGL=normal
  18
  19 AC_ARG_ENABLE(debug,
  20 [  --disable-debug         compile out all debugging messages],
  21 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  22
  23 AC_ARG_ENABLE(opengl,
  24 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  25 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  26
  27 AC_ARG_ENABLE(trace,
  28 [  --disable-trace         compile out TRACE messages],
  29 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  30
  31 AC_ARG_WITH(curses,
  32 [  --without-curses        do not use curses],
  33 [if test "$withval" = "no"; then CURSES="no"; fi])
  34
  35 AC_ARG_WITH(reentrant-x,
  36 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  37
  38 AC_SUBST(OPTIONS)
  39
  40 if test "$DEBUG_MSGS" = "no"
  41 then
  42     AC_DEFINE(NO_DEBUG_MSGS, 1, [Define if all debug messages are to be compiled out])
  43 fi
  44
  45 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
  46 then
  47     AC_DEFINE(NO_TRACE_MSGS, 1, [Define if TRACE messages are to be compiled out])
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_PROG_RANLIB
  66 AC_PROG_INSTALL
  67 AC_PROG_LN_S
  68 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  69 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  70 AC_CYGWIN
  71 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  72
  73 dnl Check for lint
  74 AC_CHECK_PROGS(LINT, lclint lint)
  75 if test "$LINT" = "lint"
  76 then
  77   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  78   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  79 fi
  80 AC_SUBST(LINT)
  81 AC_SUBST(LINTFLAGS)
  82
  83 if test "$CYGWIN" = "yes"
  84 then
  85     LDCOMBINE="ld -r --enable-stdcall-fixup"
  86 else
  87     LDCOMBINE="ld -r"
  88 fi
  89 AC_SUBST(LDCOMBINE)
  90
  91 dnl **** Check for some libraries ****
  92
  93 dnl Check for -lm
  94 AC_CHECK_LIB(m,sqrt)
  95 dnl Check for -li386 for NetBSD and OpenBSD
  96 AC_CHECK_LIB(i386,i386_set_ldt)
  97 dnl Check for -lossaudio for NetBSD
  98 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  99 dnl Check for -lw for Solaris
 100 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 101 dnl Check for -lnsl for Solaris
 102 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 103 dnl Check for -lsocket for Solaris
 104 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 105 dnl Check for -lxpg4 for FreeBSD
 106 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 107 dnl Check for -lmmap for OS/2
 108 AC_CHECK_LIB(mmap,mmap)
 109 dnl Check for openpty
 110 AC_CHECK_FUNCS(openpty,,
 111         [AC_CHECK_LIB(util,openpty,
 112                 [AC_DEFINE(HAVE_OPENPTY)
 113                 LIBS="$LIBS -lutil"]
 114         )])
 115
 116 AC_CHECK_HEADERS(dlfcn.h,
 117     [AC_CHECK_FUNCS(dlopen,,
 118         [AC_CHECK_LIB(dl,dlopen,
 119                      [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 120                      LIBS="$LIBS -ldl"],
 121                      LIBEXT="a")]
 122         )],
 123         LIBEXT="a"
 124     )
 125
 126 JPEGLIB=""
 127 AC_SUBST(JPEGLIB)
 128 AC_CHECK_HEADERS(jpeglib.h,
 129     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 130         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 131         JPEGLIB="-ljpeg"
 132     )
 133 )
 134
 135
 136 AC_SUBST(XLIB)
 137 AC_SUBST(XFILES)
 138 XFILES=""
 139 AC_SUBST(OPENGLFILES)
 140 OPENGLFILES=""
 141 AC_SUBST(GLU32FILES)
 142 GLU32FILES=""
 143 if test "$have_x" = "yes"
 144 then
 145     XLIB="-lXext -lX11"
 146     ac_save_CPPFLAGS="$CPPFLAGS"
 147     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 148
 149     dnl *** Check for -lXpm
 150     AC_CHECK_HEADERS(X11/xpm.h,
 151       [ dnl *** If X11/xpm.h exists...
 152         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 153           [ AC_DEFINE(HAVE_LIBXXPM, 1, [Define if you have the Xpm library])
 154             X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 155           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 156         )
 157       ],
 158       [ dnl *** If X11/xpm.h does not exist...
 159         dnl NOTE: autoconf does not allow commas inside the third
 160         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 161         dnl       magic it does.
 162         echo "Install the following packages:"
 163         echo "Red Hat < 7.1     :       xpm xpm-devel"
 164         echo "Red Hat >= 7.1    :       XFree86-devel"
 165         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 166         echo "SuSE              :       xpm"
 167         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 168         echo "Solaris 8         :       SFWxpm"
 169         echo
 170         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 171         echo "the directory /contrib/libraries."
 172         echo
 173         exit 1
 174       ]
 175     )
 176
 177     dnl *** All of the following tests require X11/Xlib.h
 178     AC_CHECK_HEADERS(X11/Xlib.h,
 179       [
 180         dnl *** Check for X keyboard extension
 181         AC_CHECK_HEADERS(X11/XKBlib.h,
 182             [ dnl *** If X11/XKBlib.h exists...
 183               AC_CHECK_LIB(X11, XkbQueryExtension,
 184               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 185               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 186             ],
 187             AC_MSG_WARN([XKB extension not found!!])
 188         )
 189
 190         dnl *** Check for X Shm extension
 191         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 192             [ dnl *** If X11/extensions/XShm.h exists...
 193               AC_CHECK_LIB(Xext, XShmQueryExtension,
 194               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 195               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 196             ],
 197             AC_MSG_WARN([Xshm extension not found!!])
 198         )
 199
 200         dnl *** Check for X shape extension
 201         AC_CHECK_HEADERS(X11/extensions/shape.h,
 202             [ dnl *** If X11/extensions/shape.h exists...
 203               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 204               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 205               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 206             ],
 207             AC_MSG_WARN([XShape extension not found!!])
 208         )
 209
 210         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 211         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 212             [ dnl *** If X11/extensions/xf86dga.h exists, check
 213               dnl *** for XDGAQueryExtension()...
 214               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 215                 [ dnl *** If found...
 216                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 217                             [Define if you have the Xxf86dga library version 2])
 218                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 219                ],
 220                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 221                   dnl *** instead (DGA 2.0 not found)...
 222                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 223                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 224                                 [Define if you have the Xxf86dga library version 1])
 225                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 226                     ],,
 227                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 228                   )
 229                 ],
 230                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 231               )
 232             ],
 233             AC_MSG_WARN([DGA extension not found!!])
 234         )
 235
 236         dnl *** Check for XFree86 VMODE extension
 237         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 238             [ dnl *** If X11/extensions/xf86vmode.h exists...
 239                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 240                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 241                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 242                   ],,
 243                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 244                 )
 245             ],
 246             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 247         )
 248
 249         dnl *** Check for XVideo extension supporting XvImages
 250         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 251             [ dnl *** If X11/extensions/Xvlib.h exists...
 252                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 253                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 254                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 255                   ],,
 256                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 257                 )
 258             ],
 259             AC_MSG_WARN([XVideo extension not found !!])
 260         )
 261
 262         dnl *** Check for XRender extension
 263         AC_CHECK_HEADERS(X11/extensions/Xrender.h,
 264             [ dnl *** If X11/extensions/Xrender.h exists...
 265                 AC_CHECK_LIB(Xrender, XRenderQueryExtension,
 266                   [ AC_DEFINE(HAVE_LIBXRENDER, 1, [Define if you have the XRender extension library])
 267                      X_PRE_LIBS="$X_PRE_LIBS -lXrender"
 268                   ],,
 269                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 270                 )
 271             ],
 272             AC_MSG_WARN([XRender extension not found !!])
 273         )
 274
 275       ]
 276     ) dnl *** End of X11/Xlib.h check
 277
 278     dnl Check for the presence of OpenGL
 279     if test $OPENGL = "yes" -o $OPENGL = "normal"
 280     then
 281         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 282         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 283         then
 284             dnl Check for some problems due to old Mesa versions
 285             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 286               AC_TRY_COMPILE(
 287                 [#include <GL/gl.h>],
 288                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 289                 [wine_cv_opengl_version_OK="yes"],
 290                 [wine_cv_opengl_version_OK="no"]
 291               )
 292             )
 293
 294             dnl Check for the thread-safety of the OpenGL library
 295             AC_CACHE_CHECK([for thread-safe OpenGL version],
 296                            wine_cv_opengl_version_threadsafe,
 297               [saved_libs=$LIBS
 298                LIBS="$X_LIBS -lGL"
 299                AC_TRY_LINK([],[pthread_getspecific();],
 300                               [wine_cv_opengl_version_threadsafe="yes"],
 301                               [wine_cv_opengl_version_threadsafe="no"])
 302                LIBS=$saved_libs]
 303             )
 304
 305             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 306             then
 307                 dnl Check for the presence of the library
 308                 AC_CHECK_LIB(GL,glXCreateContext,
 309                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 310                              ,,
 311                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 312
 313                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 314                 then
 315
 316                         OPENGLFILES='$(OPENGLFILES)'
 317                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 318
 319                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 320                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 321                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 322                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 323
 324                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 325                         then
 326                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 327                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 328                                                   #ifdef HAVE_GL_GLEXT_H
 329                                                   # include <GL/glext.h>
 330                                                   #endif
 331                                                   ],
 332                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 333                                                  [wine_cv_extension_prototypes="yes"],
 334                                                  [wine_cv_extension_prototypes="no"]
 335                                   )]
 336                                 )
 337                                 if test $wine_cv_extension_prototypes = "yes"
 338                                 then
 339                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 340                                               [Define if the OpenGL headers define extension typedefs])
 341                                 fi
 342                         fi
 343
 344                 fi
 345                 dnl Check for GLU32 library.
 346                 AC_CHECK_LIB(GLU,gluLookAt,
 347                              [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
 348                              GLU32FILES='$(GLU32FILES)']
 349                              ,,
 350                              $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 351                 )
 352              fi
 353          fi
 354     fi
 355
 356     CPPFLAGS="$ac_save_CPPFLAGS"
 357     XFILES='$(XFILES)'
 358 else
 359     XLIB=""
 360     X_CFLAGS=""
 361     X_LIBS=""
 362 fi
 363
 364 dnl **** Check which curses lib to use ***
 365 if test "$CURSES" = "yes"
 366 then
 367     AC_CHECK_HEADERS(ncurses.h,
 368         AC_CHECK_LIB(ncurses,waddch),
 369         [AC_CHECK_HEADERS(curses.h,[AC_CHECK_LIB(curses,waddch)])])
 370     AC_CHECK_FUNCS(getbkgd resizeterm)
 371 fi
 372
 373 CUPSLIBS=""
 374 dnl **** Check for CUPS ****
 375 wine_cv_warn_cups_h=no
 376 AC_CHECK_LIB(cups,cupsGetPPD,
 377         [AC_CHECK_HEADER(cups/cups.h,
 378             [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
 379             CUPSLIBS="-lcups"],
 380             wine_cv_warn_cups_h=yes)]
 381 )
 382 AC_SUBST(CUPSLIBS)
 383
 384 dnl **** Check for FreeType 2 ****
 385 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no)
 386 if test "$ft_lib" = "no"
 387 then
 388     FREETYPELIBS=""
 389     FREETYPEINCL=""
 390     wine_cv_msg_freetype=no
 391 else
 392     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 393     if test "$ft_devel" = "no"
 394     then
 395         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 396         if test "$ft_devel2" = "freetype2-config"
 397         then
 398                 ft_devel=$ft_devel2
 399         fi
 400     fi
 401     if test "$ft_devel" = "no"
 402     then
 403         FREETYPELIBS=""
 404         FREETYPEINCL=""
 405         wine_cv_msg_freetype=yes
 406     else
 407         AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 408         FREETYPELIBS=`$ft_devel --libs`
 409         FREETYPEINCL=`$ft_devel --cflags`
 410         ac_save_CPPFLAGS="$CPPFLAGS"
 411         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 412         AC_CHECK_HEADERS(freetype/freetype.h \
 413                          freetype/ftglyph.h \
 414                          freetype/tttables.h \
 415                          freetype/ftnames.h \
 416                          freetype/ftsnames.h \
 417                          freetype/ttnameid.h \
 418                          freetype/ftoutln.h \
 419                          freetype/internal/sfnt.h)
 420         CPPFLAGS="$ac_save_CPPFLAGS"
 421         wine_cv_msg_freetype=no
 422     fi
 423 fi
 424 AC_SUBST(FREETYPELIBS)
 425 AC_SUBST(FREETYPEINCL)
 426
 427 dnl **** Check for parport (currently Linux only) ****
 428 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 429  AC_TRY_COMPILE(
 430    [#include <linux/ppdev.h>],
 431    [ioctl (1,PPCLAIM,0)],
 432    [ac_cv_c_ppdev="yes"],
 433    [ac_cv_c_ppdev="no"])
 434  )
 435 if test "$ac_cv_c_ppdev" = "yes"
 436 then
 437     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 438 fi
 439
 440 dnl **** Check for IPX (currently Linux only) ****
 441 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
 442  AC_TRY_COMPILE(
 443    [#include <sys/socket.h>
 444     #include <netipx/ipx.h>],
 445    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 446    [ac_cv_c_ipx_gnu="yes"],
 447    [ac_cv_c_ipx_gnu="no"])
 448  )
 449 if test "$ac_cv_c_ipx_gnu" = "yes"
 450 then
 451     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
 452 fi
 453
 454 if test "$ac_cv_c_ipx_gnu" = "no"
 455 then
 456  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
 457   AC_TRY_COMPILE(
 458     [#include <sys/socket.h>
 459      #include <asm/types.h>
 460      #include <linux/ipx.h>],
 461     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 462     [ac_cv_c_ipx_linux="yes"],
 463     [ac_cv_c_ipx_linux="no"])
 464   )
 465   if test "$ac_cv_c_ipx_linux" = "yes"
 466   then
 467       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
 468   fi
 469 fi
 470
 471 dnl **** Check for Open Sound System ****
 472 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 473
 474 AC_CACHE_CHECK([for Open Sound System],
 475         ac_cv_c_opensoundsystem,
 476         AC_TRY_COMPILE([
 477         #if defined(HAVE_SYS_SOUNDCARD_H)
 478                 #include <sys/soundcard.h>
 479         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 480                 #include <machine/soundcard.h>
 481         #elif defined(HAVE_SOUNDCARD_H)
 482                 #include <soundcard.h>
 483         #endif
 484         ],[
 485
 486 /* check for one of the Open Sound System specific SNDCTL_ defines */
 487 #if !defined(SNDCTL_DSP_STEREO)
 488 #error No open sound system
 489 #endif
 490 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 491
 492 if test "$ac_cv_c_opensoundsystem" = "yes"
 493 then
 494     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 495 fi
 496
 497 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 498         ac_cv_c_opensoundsystem_midi,
 499         AC_TRY_COMPILE([
 500         #if defined(HAVE_SYS_SOUNDCARD_H)
 501                 #include <sys/soundcard.h>
 502         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 503                 #include <machine/soundcard.h>
 504         #elif defined(HAVE_SOUNDCARD_H)
 505                 #include <soundcard.h>
 506         #endif
 507         ],[
 508
 509 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 510 #if !defined(SNDCTL_SEQ_SYNC)
 511 #error No open sound system MIDI interface
 512 #endif
 513 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 514
 515 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 516 then
 517     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 518 fi
 519
 520 dnl **** If ln -s doesn't work, use cp instead ****
 521 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 522
 523 dnl **** Check for broken glibc mmap64 ****
 524
 525 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 526         AC_TRY_RUN([
 527                 #define _FILE_OFFSET_BITS 64
 528                 #include <stdio.h>
 529                 #include <unistd.h>
 530                 #include <fcntl.h>
 531                 #include <sys/mman.h>
 532                 #include <errno.h>
 533
 534                 int main(int argc,char **argv) {
 535                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 536                         if (fd == -1) exit(1);
 537
 538                         unlink("conftest.map");
 539
 540                         write(fd,"test",4);
 541
 542                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 543                             (errno == EINVAL)
 544                         ) {
 545                                 exit(1);
 546                         }
 547                         close(fd);
 548                         fprintf(stderr,"success!\n");
 549                         exit(0);
 550                 }
 551
 552         ],
 553     ac_cv_mmap64_works="yes",
 554     ac_cv_mmap64_works="no",
 555     ac_cv_mmap64_works="no") )
 556
 557 if test "$ac_cv_mmap64_works" = "yes"
 558 then
 559     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 560 fi
 561
 562 dnl **** Check for gcc strength-reduce bug ****
 563
 564 if test "x${GCC}" = "xyes"
 565 then
 566   CFLAGS="$CFLAGS -Wall"
 567   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 568                   AC_TRY_RUN([
 569 int     L[[4]] = {0,1,2,3};
 570 int main(void) {
 571   static int Array[[3]];
 572   unsigned int B = 3;
 573   int i;
 574   for(i=0; i<B; i++) Array[[i]] = i - 3;
 575   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 576   L[[i]] = 4;
 577
 578   exit( Array[[1]] != -2 || L[[2]] != 3);
 579 }],
 580     ac_cv_c_gcc_strength_bug="no",
 581     ac_cv_c_gcc_strength_bug="yes",
 582     ac_cv_c_gcc_strength_bug="yes") )
 583   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 584   then
 585     CFLAGS="$CFLAGS -fno-strength-reduce"
 586   fi
 587
 588   dnl Check for -mpreferred-stack-boundary
 589   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support],
 590                  ac_cv_c_gcc_stack_boundary,
 591   [saved_cflags=$CFLAGS
 592   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 593   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 594   CFLAGS=$saved_cflags
 595   ])
 596   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 597   then
 598     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 599   fi
 600 fi
 601
 602 dnl **** Check if we need to place .type inside a .def directive ****
 603
 604 AC_CACHE_CHECK([whether .type must sit inside a .def directive],
 605                ac_cv_c_type_in_def,
 606 [saved_libs=$LIBS
 607 LIBS="conftest_asm.s $LIBS"
 608 cat > conftest_asm.s <<EOF
 609         .globl _ac_test
 610         .def _ac_test; .scl 2; .type 32; .endef
 611 _ac_test:
 612         .long 0
 613 EOF
 614 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 615 LIBS=$saved_libs])
 616 if test "$ac_cv_c_type_in_def" = "yes"
 617 then
 618   AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
 619 fi
 620
 621 dnl **** Check for underscore on external symbols ****
 622
 623 AC_CACHE_CHECK([whether external symbols need an underscore prefix],
 624                ac_cv_c_extern_prefix,
 625 [saved_libs=$LIBS
 626 LIBS="conftest_asm.s $LIBS"
 627 cat > conftest_asm.s <<EOF
 628         .globl _ac_test
 629 _ac_test:
 630         .long 0
 631 EOF
 632 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 633             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 634 LIBS=$saved_libs])
 635 if test "$ac_cv_c_extern_prefix" = "yes"
 636 then
 637   AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
 638             [Define if symbols declared in assembly code need an underscore prefix])
 639 fi
 640
 641 dnl **** Check for .string in assembler ****
 642
 643 AC_CACHE_CHECK([whether assembler accepts .string],
 644                ac_cv_c_asm_string,
 645 [saved_libs=$LIBS
 646 LIBS="conftest_asm.s $LIBS"
 647 cat > conftest_asm.s <<EOF
 648         .string "test"
 649 EOF
 650 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 651 LIBS=$saved_libs])
 652 if test "$ac_cv_c_asm_string" = "yes"
 653 then
 654   AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
 655 fi
 656
 657 dnl **** Check for working dll ****
 658
 659 LDSHARED=""
 660 LDDLLFLAGS=""
 661 if test "$LIBEXT" = "so"
 662 then
 663   AC_CACHE_CHECK([whether we can build a GNU style ELF dll],
 664                  ac_cv_c_dll_gnuelf,
 665   [saved_cflags=$CFLAGS
 666   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 667   AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
 668   CFLAGS=$saved_cflags
 669   ])
 670   if test "$ac_cv_c_dll_gnuelf" = "yes"
 671   then
 672     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 673     LDDLLFLAGS="-Wl,-Bsymbolic"
 674   else
 675     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 676                  ac_cv_c_dll_unixware,
 677     [saved_cflags=$CFLAGS
 678     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 679     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 680     CFLAGS=$saved_cflags
 681     ])
 682     if test "$ac_cv_c_dll_unixware" = "yes"
 683     then
 684       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 685       LDDLLFLAGS="-Wl,-B,symbolic"
 686     fi
 687   fi
 688   if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
 689   then
 690     LIBEXT="a"
 691     if test "$DLLWRAP" = "dllwrap"; then
 692       dnl FIXME - check whether dllwrap works correctly...
 693       if test "$CYGWIN" = "yes"; then
 694         echo "*** use dllwrap for building shared library."
 695         LIBEXT="dll"
 696       fi
 697     fi
 698   fi
 699 fi
 700
 701 if test "$LIBEXT" = "a"; then
 702   echo "*** It is currently not possible to build WINE without shared"
 703   echo "*** library (.so) support to allow transparent switch between .so"
 704   echo "*** and .dll files."
 705   echo "*** If you are using Linux, you will need a newer binutils."
 706   exit 1
 707 fi
 708
 709 DLLFLAGS=""
 710 LDPATH=""
 711
 712 if test "$LIBEXT" = "so"; then
 713     DLLFLAGS="-fPIC"
 714     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 715 elif test "$LIBEXT" = "dll"; then
 716     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 717     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 718 fi
 719
 720 AC_SUBST(DLLFLAGS)
 721 AC_SUBST(LDSHARED)
 722 AC_SUBST(LDDLLFLAGS)
 723 AC_SUBST(LIBEXT)
 724 AC_SUBST(LDPATH)
 725
 726 dnl **** Check for reentrant libc ****
 727 dnl
 728 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 729 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 730
 731 AC_DEFUN([WINE_CHECK_ERRNO],
 732 [
 733   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 734   [AC_TRY_RUN([int myerrno = 0;
 735 char buf[256];
 736 int *$1(){return &myerrno;}
 737 main(){connect(0,buf,255); exit(!myerrno);}],
 738   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 739   wine_cv_libc_r_$1=yes )
 740 ])
 741 if test "$wine_cv_libc_r_$1" = "yes"
 742 then
 743     wine_cv_libc_reentrant=$1
 744 fi
 745 ])
 746
 747 wine_cv_libc_reentrant=no
 748 dnl Linux style errno location
 749 WINE_CHECK_ERRNO(__errno_location)
 750 dnl FreeBSD style errno location
 751 WINE_CHECK_ERRNO(__error)
 752 dnl Solaris style errno location
 753 WINE_CHECK_ERRNO(___errno)
 754 dnl UnixWare style errno location
 755 WINE_CHECK_ERRNO(__thr_errno)
 756 dnl NetBSD style errno location
 757 WINE_CHECK_ERRNO(__errno)
 758
 759 if test "$wine_cv_libc_reentrant" != "no"
 760 then
 761   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
 762                      [Define to the name of the function returning errno for reentrant libc])
 763 fi
 764
 765 dnl **** Check for reentrant X libraries ****
 766 dnl
 767 dnl This may fail to determine whether X libraries are reentrant if
 768 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 769 dnl is possible with the --without-reentrant-x option.
 770
 771 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 772 then
 773 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
 774   [ if test "x$with_reentrant_x" = "xno"
 775     then
 776         wine_cv_x_reentrant=no
 777     else
 778         libX11_check=none
 779         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 780             if test -r $dir/libX11.so; then
 781                 libX11_check="-D $dir/libX11.so"
 782                 break 1
 783             fi
 784             if test -r $dir/libX11.a; then
 785                 libX11_check="$dir/libX11.a"
 786                 break 1
 787             fi
 788         done
 789         if test "$libX11_check" != "none"; then
 790             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 791             then
 792                 wine_cv_x_reentrant=yes
 793             else
 794                 wine_cv_x_reentrant=no
 795             fi
 796         else
 797             wine_cv_x_reentrant=unknown
 798         fi
 799     fi ] )
 800 else
 801     wine_cv_x_reentrant=no
 802 fi
 803 if test "$wine_cv_x_reentrant" = "no"
 804 then
 805   AC_DEFINE(NO_REENTRANT_X11, 1,
 806             [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
 807 fi
 808
 809
 810 dnl **** Check for functions ****
 811
 812 AC_FUNC_ALLOCA()
 813 AC_CHECK_FUNCS(\
 814         __libc_fork \
 815         _lwp_create \
 816         clone \
 817         ecvt \
 818         finite \
 819         fpclass \
 820         ftruncate64 \
 821         getnetbyaddr \
 822         getnetbyname \
 823         getpagesize \
 824         getprotobyname \
 825         getprotobynumber \
 826         getrlimit \
 827         getservbyport \
 828         getsockopt \
 829         inet_network \
 830         lseek64 \
 831         lstat \
 832         memmove \
 833         mmap \
 834         rfork \
 835         select \
 836         sendmsg \
 837         settimeofday \
 838         sigaltstack \
 839         statfs \
 840         strcasecmp \
 841         strerror \
 842         strncasecmp \
 843         tcgetattr \
 844         timegm \
 845         usleep \
 846         vfscanf \
 847         wait4 \
 848         waitpid \
 849 )
 850
 851 dnl **** Check for header files ****
 852
 853 AC_CHECK_HEADERS(\
 854         arpa/inet.h \
 855         arpa/nameser.h \
 856         elf.h \
 857         float.h \
 858         ieeefp.h \
 859         libio.h \
 860         libutil.h \
 861         link.h \
 862         linux/cdrom.h \
 863         linux/input.h \
 864         linux/joystick.h \
 865         linux/ucdrom.h \
 866         net/if.h \
 867         netdb.h \
 868         netinet/in.h \
 869         netinet/in_systm.h \
 870         netinet/ip.h \
 871         netinet/tcp.h \
 872         pty.h \
 873         resolv.h \
 874         sched.h \
 875         socket.h \
 876         strings.h \
 877         sys/cdio.h \
 878         sys/errno.h \
 879         sys/file.h \
 880         sys/filio.h \
 881         sys/ipc.h \
 882         sys/link.h \
 883         sys/lwp.h \
 884         sys/mman.h \
 885         sys/modem.h \
 886         sys/mount.h \
 887         sys/msg.h \
 888         sys/param.h \
 889         sys/ptrace.h \
 890         sys/reg.h \
 891         sys/signal.h \
 892         sys/shm.h \
 893         sys/socket.h \
 894         sys/sockio.h \
 895         sys/statfs.h \
 896         sys/strtio.h \
 897         sys/syscall.h \
 898         sys/user.h \
 899         sys/wait.h \
 900         sys/v86.h \
 901         sys/v86intr.h \
 902         sys/vfs.h \
 903         sys/vm86.h \
 904         syscall.h \
 905         ucontext.h \
 906 )
 907 AC_HEADER_STAT()
 908
 909 dnl **** Check for types ****
 910
 911 AC_C_CONST()
 912 AC_C_INLINE()
 913 AC_TYPE_SIZE_T()
 914 AC_CHECK_SIZEOF(long long,0)
 915
 916 AC_CACHE_CHECK([whether linux/input.h is for real],
 917         wine_cv_linux_input_h,
 918         AC_TRY_COMPILE([
 919             #include <linux/input.h>
 920         ] , [
 921             int foo = EVIOCGBIT(EV_ABS,42);
 922             int bar = BTN_PINKIE;
 923             int fortytwo = 42;
 924         ],
 925         wine_cv_linux_input_h=yes,
 926         wine_cv_linux_input_h=no,
 927         no
 928         )
 929     )
 930     if test "$wine_cv_linux_input_h" = "yes"
 931     then
 932         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
 933                   [Define if we have linux/input.h AND it contains the INPUT event API])
 934     fi
 935
 936
 937 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
 938         wine_cv_linux_gethostbyname_r_6,
 939         AC_TRY_COMPILE([
 940 #include <netdb.h>
 941         ], [
 942     char *name=NULL;
 943     struct hostent he;
 944     struct hostent *result;
 945     char *buf=NULL;
 946     int bufsize=0;
 947     int res,errnr;
 948     char *addr=NULL;
 949     int addrlen=0;
 950     int addrtype=0;
 951     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 952     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 953     ],
 954         wine_cv_linux_gethostbyname_r_6=yes,
 955         wine_cv_linux_gethostbyname_r_6=no
 956         )
 957    )
 958    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 959    then
 960       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
 961                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
 962    fi
 963
 964 if test "$ac_cv_header_linux_joystick_h" = "yes"
 965 then
 966    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
 967         wine_cv_linux_joystick_22_api,
 968         AC_TRY_COMPILE([
 969         #include <sys/ioctl.h>
 970         #include <linux/joystick.h>
 971
 972         struct js_event blub;
 973         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 974         #error "no 2.2 header"
 975         #endif
 976         ],/*empty*/,
 977         wine_cv_linux_joystick_22_api=yes,
 978         wine_cv_linux_joystick_22_api=no,
 979         wine_cv_linux_joystick_22_api=no
 980         )
 981    )
 982    if test "$wine_cv_linux_joystick_22_api" = "yes"
 983    then
 984       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
 985                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
 986    fi
 987 fi
 988
 989 dnl **** statfs checks ****
 990
 991 if test "$ac_cv_header_sys_vfs_h" = "yes"
 992 then
 993     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
 994                     wine_cv_sys_vfs_has_statfs,
 995         AC_TRY_COMPILE([
 996         #include <sys/types.h>
 997         #ifdef HAVE_SYS_PARAM_H
 998         # include <sys/param.h>
 999         #endif
1000         #include <sys/vfs.h>
1001         ],[
1002                 struct statfs stfs;
1003
1004                 memset(&stfs,0,sizeof(stfs));
1005         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1006         )
1007     )
1008     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1009     then
1010       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1011                 [Define if the struct statfs is defined by <sys/vfs.h>])
1012     fi
1013 fi
1014
1015 if test "$ac_cv_header_sys_statfs_h" = "yes"
1016 then
1017     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1018                     wine_cv_sys_statfs_has_statfs,
1019         AC_TRY_COMPILE([
1020         #include <sys/types.h>
1021         #ifdef HAVE_SYS_PARAM_H
1022         # include <sys/param.h>
1023         #endif
1024         #include <sys/statfs.h>
1025         ],[
1026                 struct statfs stfs;
1027         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1028         )
1029     )
1030     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1031     then
1032       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1033                 [Define if the struct statfs is defined by <sys/statfs.h>])
1034     fi
1035 fi
1036
1037 if test "$ac_cv_header_sys_mount_h" = "yes"
1038 then
1039     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1040                     wine_cv_sys_mount_has_statfs,
1041         AC_TRY_COMPILE([
1042         #include <sys/types.h>
1043         #ifdef HAVE_SYS_PARAM_H
1044         # include <sys/param.h>
1045         #endif
1046         #include <sys/mount.h>
1047         ],[
1048                 struct statfs stfs;
1049         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1050         )
1051     )
1052     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1053     then
1054       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1055                 [Define if the struct statfs is defined by <sys/mount.h>])
1056     fi
1057 fi
1058
1059 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1060
1061 AC_CACHE_CHECK( [for statfs.f_bfree], wine_cv_statfs_bfree,
1062   [ if test "x$statfs_bfree" = "xno"
1063     then
1064         wine_cv_statfs_bfree=no
1065     else
1066         AC_TRY_COMPILE([
1067         #include <sys/types.h>
1068         #ifdef HAVE_SYS_PARAM_H
1069         # include <sys/param.h>
1070         #endif
1071         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1072         # include <sys/mount.h>
1073         #else
1074         # ifdef STATFS_DEFINED_BY_SYS_VFS
1075         #  include <sys/vfs.h>
1076         # else
1077         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1078         #   include <sys/statfs.h>
1079         #  endif
1080         # endif
1081         #endif
1082         ],[
1083                 struct statfs stfs;
1084
1085                 stfs.f_bfree++;
1086         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1087         )
1088     fi ] )
1089 if test "$wine_cv_statfs_bfree" = "yes"
1090 then
1091   AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1092 fi
1093
1094 AC_CACHE_CHECK( [for statfs.f_bavail], wine_cv_statfs_bavail,
1095   [ if test "x$statfs_bavail" = "xno"
1096     then
1097         wine_cv_statfs_bavail=no
1098     else
1099         AC_TRY_COMPILE([
1100         #include <sys/types.h>
1101         #ifdef HAVE_SYS_PARAM_H
1102         # include <sys/param.h>
1103         #endif
1104         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1105         # include <sys/mount.h>
1106         #else
1107         # ifdef STATFS_DEFINED_BY_SYS_VFS
1108         #  include <sys/vfs.h>
1109         # else
1110         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1111         #   include <sys/statfs.h>
1112         #  endif
1113         # endif
1114         #endif
1115         ],[
1116                 struct statfs stfs;
1117
1118                 stfs.f_bavail++;
1119         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1120         )
1121     fi ] )
1122 if test "$wine_cv_statfs_bavail" = "yes"
1123 then
1124   AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1125 fi
1126
1127 dnl *** check for file descriptor passing with msg_accrights
1128
1129 AC_CACHE_CHECK([for msg_accrights in struct msghdr], ac_cv_c_msg_accrights,
1130  AC_TRY_COMPILE([#include <sys/types.h>
1131 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1132                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1133 if test "$ac_cv_c_msg_accrights" = "yes"
1134 then
1135     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1136 fi
1137
1138 dnl *** Check for the sa_len member in struct sockaddr
1139
1140 AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_c_sockaddr_sa_len,
1141  AC_TRY_COMPILE([#include <sys/types.h>
1142 #include <sys/socket.h>
1143 ], [static struct sockaddr addr; addr.sa_len = 1],
1144                 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1145 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1146 then
1147     AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1148 fi
1149
1150 dnl *** Check for the sun_len member in struct sockaddr_un
1151
1152 AC_CACHE_CHECK([for sun_len in struct sockaddr_un], ac_cv_c_sockaddr_sun_len,
1153  AC_TRY_COMPILE([#include <sys/types.h>
1154 #include <sys/socket.h>
1155 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1156                 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1157 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1158 then
1159     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1160 fi
1161
1162 dnl *** check for the need to define __i386__
1163
1164 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1165  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1166 yes
1167 #endif],
1168  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1169 if test "$ac_cv_cpp_def_i386" = "yes"
1170 then
1171     CFLAGS="$CFLAGS -D__i386__"
1172     LINTFLAGS="$LINTFLAGS -D__i386__"
1173 fi
1174
1175 dnl $GCC is set by autoconf
1176 GCC_NO_BUILTIN=""
1177 if test "$GCC" = "yes"
1178 then
1179     GCC_NO_BUILTIN="-fno-builtin"
1180 fi
1181 AC_SUBST(GCC_NO_BUILTIN)
1182
1183 dnl **** Generate output files ****
1184
1185 AC_OUTPUT_COMMANDS([
1186 extra_subdirs="\
1187 dlls/ddraw/d3ddevice \
1188 dlls/ddraw/dclipper \
1189 dlls/ddraw/ddraw \
1190 dlls/ddraw/direct3d \
1191 dlls/ddraw/dpalette \
1192 dlls/ddraw/dsurface \
1193 dlls/dinput/joystick \
1194 dlls/dinput/keyboard \
1195 dlls/dinput/mouse \
1196 dlls/kernel/messages \
1197 dlls/user/dde \
1198 dlls/user/resources \
1199 dlls/wineps/data \
1200 "
1201 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1202
1203 MAKE_RULES=Make.rules
1204 AC_SUBST_FILE(MAKE_RULES)
1205
1206 MAKE_DLL_RULES=dlls/Makedll.rules
1207 AC_SUBST_FILE(MAKE_DLL_RULES)
1208
1209 MAKE_PROG_RULES=programs/Makeprog.rules
1210 AC_SUBST_FILE(MAKE_PROG_RULES)
1211
1212 AC_OUTPUT([
1213 Make.rules
1214 dlls/Makedll.rules
1215 programs/Makeprog.rules
1216 Makefile
1217 console/Makefile
1218 controls/Makefile
1219 debugger/Makefile
1220 dlls/Makefile
1221 dlls/advapi32/Makefile
1222 dlls/avifil32/Makefile
1223 dlls/comctl32/Makefile
1224 dlls/commdlg/Makefile
1225 dlls/crtdll/Makefile
1226 dlls/dciman32/Makefile
1227 dlls/ddraw/Makefile
1228 dlls/devenum/Makefile
1229 dlls/dinput/Makefile
1230 dlls/dplay/Makefile
1231 dlls/dplayx/Makefile
1232 dlls/dsound/Makefile
1233 dlls/gdi/Makefile
1234 dlls/glu32/Makefile
1235 dlls/icmp/Makefile
1236 dlls/imagehlp/Makefile
1237 dlls/imm32/Makefile
1238 dlls/kernel/Makefile
1239 dlls/lzexpand/Makefile
1240 dlls/mapi32/Makefile
1241 dlls/mpr/Makefile
1242 dlls/msacm/Makefile
1243 dlls/msdmo/Makefile
1244 dlls/msimg32/Makefile
1245 dlls/msnet32/Makefile
1246 dlls/msvcrt/Makefile
1247 dlls/msvideo/Makefile
1248 dlls/ntdll/Makefile
1249 dlls/odbc32/Makefile
1250 dlls/ole32/Makefile
1251 dlls/oleaut32/Makefile
1252 dlls/olecli/Makefile
1253 dlls/oledlg/Makefile
1254 dlls/olepro32/Makefile
1255 dlls/olesvr/Makefile
1256 dlls/opengl32/Makefile
1257 dlls/psapi/Makefile
1258 dlls/qcap/Makefile
1259 dlls/quartz/Makefile
1260 dlls/rasapi32/Makefile
1261 dlls/richedit/Makefile
1262 dlls/rpcrt4/Makefile
1263 dlls/serialui/Makefile
1264 dlls/setupapi/Makefile
1265 dlls/shdocvw/Makefile
1266 dlls/shell32/Makefile
1267 dlls/shfolder/Makefile
1268 dlls/shlwapi/Makefile
1269 dlls/sti/Makefile
1270 dlls/tapi32/Makefile
1271 dlls/ttydrv/Makefile
1272 dlls/url/Makefile
1273 dlls/urlmon/Makefile
1274 dlls/user/Makefile
1275 dlls/version/Makefile
1276 dlls/win32s/Makefile
1277 dlls/winaspi/Makefile
1278 dlls/winedos/Makefile
1279 dlls/wineps/Makefile
1280 dlls/wininet/Makefile
1281 dlls/winmm/Makefile
1282 dlls/winmm/joystick/Makefile
1283 dlls/winmm/mcianim/Makefile
1284 dlls/winmm/mciavi/Makefile
1285 dlls/winmm/mcicda/Makefile
1286 dlls/winmm/mciseq/Makefile
1287 dlls/winmm/mciwave/Makefile
1288 dlls/winmm/midimap/Makefile
1289 dlls/winmm/wavemap/Makefile
1290 dlls/winmm/wineoss/Makefile
1291 dlls/winnls/Makefile
1292 dlls/winsock/Makefile
1293 dlls/winspool/Makefile
1294 dlls/wintrust/Makefile
1295 dlls/wow32/Makefile
1296 dlls/wsock32/Makefile
1297 dlls/x11drv/Makefile
1298 documentation/Makefile
1299 documentation/wine.conf.man
1300 documentation/wine.man
1301 files/Makefile
1302 graphics/Makefile
1303 graphics/enhmetafiledrv/Makefile
1304 graphics/metafiledrv/Makefile
1305 graphics/win16drv/Makefile
1306 graphics/x11drv/Makefile
1307 if1632/Makefile
1308 include/Makefile
1309 library/Makefile
1310 libtest/Makefile
1311 loader/Makefile
1312 loader/dos/Makefile
1313 loader/ne/Makefile
1314 memory/Makefile
1315 misc/Makefile
1316 miscemu/Makefile
1317 msdos/Makefile
1318 objects/Makefile
1319 ole/Makefile
1320 programs/Makefile
1321 programs/avitools/Makefile
1322 programs/clock/Makefile
1323 programs/cmdlgtst/Makefile
1324 programs/control/Makefile
1325 programs/notepad/Makefile
1326 programs/osversioncheck/Makefile
1327 programs/progman/Makefile
1328 programs/regapi/Makefile
1329 programs/regtest/Makefile
1330 programs/uninstaller/Makefile
1331 programs/view/Makefile
1332 programs/wcmd/Makefile
1333 programs/winemine/Makefile
1334 programs/winetest/Makefile
1335 programs/winhelp/Makefile
1336 programs/winver/Makefile
1337 relay32/Makefile
1338 scheduler/Makefile
1339 server/Makefile
1340 tools/Makefile
1341 tools/winapi/Makefile
1342 tools/winebuild/Makefile
1343 tools/winedump/Makefile
1344 tools/winelauncher
1345 tools/wmc/Makefile
1346 tools/wrc/Makefile
1347 tsx11/Makefile
1348 unicode/Makefile
1349 win32/Makefile
1350 windows/Makefile
1351 windows/x11drv/Makefile ])
1352
1353 if test "$have_x" = "no"
1354 then
1355   echo
1356   echo "*** Warning: X development files not found. Wine will be built without"
1357   echo "*** X support, which currently does not work, and would probably not be"
1358   echo "*** what you want anyway. You will need to install devel packages of"
1359   echo "*** Xlib/Xfree86 and Xpm at the very least."
1360 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1361 then
1362   echo
1363   echo "*** Warning: Xpm development files not found. Wine will be built without"
1364   echo "*** Xpm support, which currently does not work. You will need to install"
1365   echo "*** devel packages of Xpm."
1366 fi
1367
1368 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1369 then
1370   echo
1371   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1372   echo "*** terminal resize support. Consider upgrading ncurses."
1373 fi
1374
1375 if test "$wine_cv_libc_reentrant" = "no"
1376 then
1377   echo
1378   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1379   echo "*** thread support. Consider upgrading libc to a more recent"
1380   echo "*** reentrant version of libc."
1381 fi
1382
1383 if test "$wine_cv_opengl_version_OK" = "no"
1384 then
1385   echo
1386   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1387   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1388 fi
1389
1390 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1391 then
1392   echo
1393   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1394   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1395   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1396   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1397 fi
1398
1399 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1400 then
1401   echo
1402   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1403   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1404   echo "*** support before reporting bugs."
1405 fi
1406
1407 if test "$wine_cv_warn_cups_h" = "yes"
1408 then
1409   echo
1410   echo "*** Note: You have cups runtime libraries, but no development"
1411   echo "*** libraries. Install the cups-devel package or whichever package"
1412   echo "*** contains cups.h to enable CUPS support in WINE."
1413 fi
1414
1415 if test "$wine_cv_msg_freetype" = "yes"
1416 then
1417   echo
1418   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1419   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1420   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1421   echo "*** enable Wine to use TrueType fonts."
1422 fi
1423
1424 echo
1425 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1426 echo
1427
1428 dnl Local Variables:
1429 dnl comment-start: "dnl "
1430 dnl comment-end: ""
1431 dnl comment-start-skip: "\\bdnl\\b\\s *"
1432 dnl compile-command: "autoconf"
1433 dnl End: