git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41 #include "typegen.h"
  42
  43 #if defined(YYBYACC)
  44         /* Berkeley yacc (byacc) doesn't seem to know about these */
  45         /* Some *BSD supplied versions do define these though */
  46 # ifndef YYEMPTY
  47 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  48 # endif
  49 # ifndef YYLEX
  50 #  define YYLEX         yylex()
  51 # endif
  52
  53 #elif defined(YYBISON)
  54         /* Bison was used for original development */
  55         /* #define YYEMPTY -2 */
  56         /* #define YYLEX   yylex() */
  57
  58 #else
  59         /* No yacc we know yet */
  60 # if !defined(YYEMPTY) || !defined(YYLEX)
  61 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  62 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  63 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  64   /* #else we just take a chance that it works... */
  65 # endif
  66 #endif
  67
  68 typedef struct list typelist_t;
  69 struct typenode {
  70   type_t *type;
  71   struct list entry;
  72 };
  73
  74 typelist_t incomplete_types = LIST_INIT(incomplete_types);
  75
  76 static void add_incomplete(type_t *t);
  77 static void fix_incomplete(void);
  78
  79 static str_list_t *append_str(str_list_t *list, char *str);
  80 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr);
  81 static attr_t *make_attr(enum attr_type type);
  82 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  83 static attr_t *make_attrp(enum attr_type type, void *val);
  84 static expr_t *make_expr(enum expr_type type);
  85 static expr_t *make_exprl(enum expr_type type, long val);
  86 static expr_t *make_exprs(enum expr_type type, char *val);
  87 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr);
  88 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  89 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  90 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  91 static type_t *make_type(unsigned char type, type_t *ref);
  92 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr);
  93 static array_dims_t *append_array(array_dims_t *list, expr_t *expr);
  94 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr);
  95 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface);
  96 static ifref_t *make_ifref(type_t *iface);
  97 static var_list_t *append_var(var_list_t *list, var_t *var);
  98 static var_t *make_var(char *name);
  99 static pident_list_t *append_pident(pident_list_t *list, pident_t *p);
 100 static pident_t *make_pident(var_t *var);
 101 static func_list_t *append_func(func_list_t *list, func_t *func);
 102 static func_t *make_func(var_t *def, var_list_t *args);
 103 static type_t *make_class(char *name);
 104 static type_t *make_safearray(type_t *type);
 105 static type_t *make_builtin(char *name);
 106 static type_t *make_int(int sign);
 107
 108 static type_t *reg_type(type_t *type, const char *name, int t);
 109 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs);
 110 static type_t *find_type(const char *name, int t);
 111 static type_t *find_type2(char *name, int t);
 112 static type_t *get_type(unsigned char type, char *name, int t);
 113 static type_t *get_typev(unsigned char type, var_t *name, int t);
 114 static int get_struct_type(var_list_t *fields);
 115
 116 static var_t *reg_const(var_t *var);
 117 static var_t *find_const(char *name, int f);
 118
 119 static void write_libid(const char *name, const attr_list_t *attr);
 120 static void write_clsid(type_t *cls);
 121 static void write_diid(type_t *iface);
 122 static void write_iid(type_t *iface);
 123
 124 static int compute_method_indexes(type_t *iface);
 125 static char *gen_name(void);
 126 static void process_typedefs(var_list_t *names);
 127 static void check_arg(var_t *arg);
 128
 129 #define tsENUM   1
 130 #define tsSTRUCT 2
 131 #define tsUNION  3
 132
 133 %}
 134 %union {
 135         attr_t *attr;
 136         attr_list_t *attr_list;
 137         str_list_t *str_list;
 138         expr_t *expr;
 139         expr_list_t *expr_list;
 140         array_dims_t *array_dims;
 141         type_t *type;
 142         var_t *var;
 143         var_list_t *var_list;
 144         pident_t *pident;
 145         pident_list_t *pident_list;
 146         func_t *func;
 147         func_list_t *func_list;
 148         ifref_t *ifref;
 149         ifref_list_t *ifref_list;
 150         char *str;
 151         UUID *uuid;
 152         unsigned int num;
 153 }
 154
 155 %token <str> aIDENTIFIER
 156 %token <str> aKNOWNTYPE
 157 %token <num> aNUM aHEXNUM
 158 %token <str> aSTRING
 159 %token <uuid> aUUID
 160 %token aEOF
 161 %token SHL SHR
 162 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 163 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 164 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 165 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 166 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 167 %token tDEFAULT
 168 %token tDEFAULTCOLLELEM
 169 %token tDEFAULTVALUE
 170 %token tDEFAULTVTABLE
 171 %token tDISPLAYBIND
 172 %token tDISPINTERFACE
 173 %token tDLLNAME tDOUBLE tDUAL
 174 %token tENDPOINT
 175 %token tENTRY tENUM tERRORSTATUST
 176 %token tEXPLICITHANDLE tEXTERN
 177 %token tFALSE
 178 %token tFLOAT
 179 %token tHANDLE
 180 %token tHANDLET
 181 %token tHELPCONTEXT tHELPFILE
 182 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 183 %token tHIDDEN
 184 %token tHYPER tID tIDEMPOTENT
 185 %token tIIDIS
 186 %token tIMMEDIATEBIND
 187 %token tIMPLICITHANDLE
 188 %token tIMPORT tIMPORTLIB
 189 %token tIN tINLINE
 190 %token tINPUTSYNC
 191 %token tINT tINT64
 192 %token tINTERFACE
 193 %token tLCID
 194 %token tLENGTHIS tLIBRARY
 195 %token tLOCAL
 196 %token tLONG
 197 %token tMETHODS
 198 %token tMODULE
 199 %token tNONBROWSABLE
 200 %token tNONCREATABLE
 201 %token tNONEXTENSIBLE
 202 %token tOBJECT tODL tOLEAUTOMATION
 203 %token tOPTIONAL
 204 %token tOUT
 205 %token tPOINTERDEFAULT
 206 %token tPROPERTIES
 207 %token tPROPGET tPROPPUT tPROPPUTREF
 208 %token tPTR
 209 %token tPUBLIC
 210 %token tRANGE
 211 %token tREADONLY tREF
 212 %token tREQUESTEDIT
 213 %token tRESTRICTED
 214 %token tRETVAL
 215 %token tSAFEARRAY
 216 %token tSHORT
 217 %token tSIGNED
 218 %token tSINGLE
 219 %token tSIZEIS tSIZEOF
 220 %token tSMALL
 221 %token tSOURCE
 222 %token tSTDCALL
 223 %token tSTRING tSTRUCT
 224 %token tSWITCH tSWITCHIS tSWITCHTYPE
 225 %token tTRANSMITAS
 226 %token tTRUE
 227 %token tTYPEDEF
 228 %token tUNION
 229 %token tUNIQUE
 230 %token tUNSIGNED
 231 %token tUUID
 232 %token tV1ENUM
 233 %token tVARARG
 234 %token tVERSION
 235 %token tVOID
 236 %token tWCHAR tWIREMARSHAL
 237
 238 %type <attr> attribute
 239 %type <attr_list> m_attributes attributes attrib_list
 240 %type <str_list> str_list
 241 %type <expr> m_expr expr expr_const
 242 %type <expr_list> m_exprs /* exprs expr_list */ expr_list_const
 243 %type <array_dims> array array_list
 244 %type <type> inherit interface interfacehdr interfacedef interfacedec
 245 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 246 %type <type> module modulehdr moduledef
 247 %type <type> base_type int_std
 248 %type <type> enumdef structdef uniondef
 249 %type <type> type
 250 %type <ifref> coclass_int
 251 %type <ifref_list> gbl_statements coclass_ints
 252 %type <var> arg field s_field case enum constdef externdef
 253 %type <var_list> m_args no_args args fields cases enums enum_list dispint_props
 254 %type <var> m_ident t_ident ident
 255 %type <pident> p_ident pident
 256 %type <pident_list> pident_list
 257 %type <func> funcdef
 258 %type <func_list> int_statements dispint_meths
 259 %type <type> coclass coclasshdr coclassdef
 260 %type <num> pointer_type version
 261 %type <str> libraryhdr
 262
 263 %left ','
 264 %right '?' ':'
 265 %left '|'
 266 %left '&'
 267 %left '-' '+'
 268 %left '*' '/'
 269 %left SHL SHR
 270 %right '~'
 271 %right CAST
 272 %right PPTR
 273 %right NEG
 274
 275 %%
 276
 277 input:   gbl_statements                         { fix_incomplete();
 278                                                   write_proxies($1);
 279                                                   write_client($1);
 280                                                   write_server($1);
 281                                                 }
 282         ;
 283
 284 gbl_statements:                                 { $$ = NULL; }
 285         | gbl_statements interfacedec           { $$ = $1; }
 286         | gbl_statements interfacedef           { $$ = append_ifref( $1, make_ifref($2) ); }
 287         | gbl_statements coclass ';'            { $$ = $1;
 288                                                   reg_type($2, $2->name, 0);
 289                                                   if (!parse_only && do_header) write_coclass_forward($2);
 290                                                 }
 291         | gbl_statements coclassdef             { $$ = $1;
 292                                                   add_typelib_entry($2);
 293                                                   reg_type($2, $2->name, 0);
 294                                                   if (!parse_only && do_header) write_coclass_forward($2);
 295                                                 }
 296         | gbl_statements moduledef              { $$ = $1; add_typelib_entry($2); }
 297         | gbl_statements librarydef             { $$ = $1; }
 298         | gbl_statements statement              { $$ = $1; }
 299         ;
 300
 301 imp_statements:                                 {}
 302         | imp_statements interfacedec           { if (!parse_only) add_typelib_entry($2); }
 303         | imp_statements interfacedef           { if (!parse_only) add_typelib_entry($2); }
 304         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 305         | imp_statements coclassdef             { if (!parse_only) add_typelib_entry($2);
 306                                                   reg_type($2, $2->name, 0);
 307                                                   if (!parse_only && do_header) write_coclass_forward($2);
 308                                                 }
 309         | imp_statements moduledef              { if (!parse_only) add_typelib_entry($2); }
 310         | imp_statements statement              {}
 311         | imp_statements importlib              {}
 312         ;
 313
 314 int_statements:                                 { $$ = NULL; }
 315         | int_statements funcdef ';'            { $$ = append_func( $1, $2 ); }
 316         | int_statements statement              { $$ = $1; }
 317         ;
 318
 319 statement: ';'                                  {}
 320         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 321         | cppquote                              {}
 322         | enumdef ';'                           { if (!parse_only && do_header) {
 323                                                     write_type(header, $1, FALSE, NULL);
 324                                                     fprintf(header, ";\n\n");
 325                                                   }
 326                                                 }
 327         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 328         | import                                {}
 329         | structdef ';'                         { if (!parse_only && do_header) {
 330                                                     write_type(header, $1, FALSE, NULL);
 331                                                     fprintf(header, ";\n\n");
 332                                                   }
 333                                                 }
 334         | typedef ';'                           {}
 335         | uniondef ';'                          { if (!parse_only && do_header) {
 336                                                     write_type(header, $1, FALSE, NULL);
 337                                                     fprintf(header, ";\n\n");
 338                                                   }
 339                                                 }
 340         ;
 341
 342 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 343         ;
 344 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 345                                                   if (!do_import($2)) yychar = aEOF; }
 346         ;
 347 import:   import_start imp_statements aEOF      {}
 348         ;
 349
 350 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 351         ;
 352
 353 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 354         ;
 355 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 356                                                   if (!parse_only && do_header) write_library($2, $1);
 357                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 358                                                 }
 359         ;
 360 librarydef: library_start imp_statements '}'    { end_typelib(); }
 361         ;
 362
 363 m_args:                                         { $$ = NULL; }
 364         | args
 365         ;
 366
 367 no_args:  tVOID                                 { $$ = NULL; }
 368         ;
 369
 370 args:     arg                                   { check_arg($1); $$ = append_var( NULL, $1 ); }
 371         | args ',' arg                          { check_arg($3); $$ = append_var( $1, $3); }
 372         | no_args
 373         ;
 374
 375 /* split into two rules to get bison to resolve a tVOID conflict */
 376 arg:      attributes type pident array          { $$ = $3->var;
 377                                                   $$->attrs = $1;
 378                                                   set_type($$, $2, $3->ptr_level, $4);
 379                                                   free($3);
 380                                                 }
 381         | type pident array                     { $$ = $2->var;
 382                                                   set_type($$, $1, $2->ptr_level, $3);
 383                                                   free($2);
 384                                                 }
 385         | attributes type pident '(' m_args ')' { $$ = $3->var;
 386                                                   $$->attrs = $1;
 387                                                   set_type($$, $2, $3->ptr_level - 1, NULL);
 388                                                   free($3);
 389                                                   $$->args = $5;
 390                                                 }
 391         | type pident '(' m_args ')'            { $$ = $2->var;
 392                                                   set_type($$, $1, $2->ptr_level - 1, NULL);
 393                                                   free($2);
 394                                                   $$->args = $4;
 395                                                 }
 396         ;
 397
 398 array:                                          { $$ = NULL; }
 399         | '[' array_list ']'                    { $$ = $2; }
 400         | '[' '*' ']'                           { $$ = append_array( NULL, make_expr(EXPR_VOID) ); }
 401         ;
 402
 403 array_list: m_expr /* size of first dimension is optional */ { $$ = append_array( NULL, $1 ); }
 404         | array_list ',' expr                   { $$ = append_array( $1, $3 ); }
 405         | array_list ']' '[' expr               { $$ = append_array( $1, $4 ); }
 406         ;
 407
 408 m_attributes:                                   { $$ = NULL; }
 409         | attributes
 410         ;
 411
 412 attributes:
 413           '[' attrib_list ']'                   { $$ = $2;
 414                                                   if (!$$)
 415                                                     yyerror("empty attribute lists unsupported");
 416                                                 }
 417         ;
 418
 419 attrib_list: attribute                          { $$ = append_attr( NULL, $1 ); }
 420         | attrib_list ',' attribute             { $$ = append_attr( $1, $3 ); }
 421         | attrib_list ']' '[' attribute         { $$ = append_attr( $1, $4 ); }
 422         ;
 423
 424 str_list: aSTRING                               { $$ = append_str( NULL, $1 ); }
 425         | str_list ',' aSTRING                  { $$ = append_str( $1, $3 ); }
 426         ;
 427
 428 attribute:                                      { $$ = NULL; }
 429         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 430         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 431         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 432         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 433         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 434         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 435         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 436         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 437         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 438         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 439         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 440         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 441         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 442         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 443         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 444         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 445         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 446         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 447         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 448         | tENDPOINT '(' str_list ')'            { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 449         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 450         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 451         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 452         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 453         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 454         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 455         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 456         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 457         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 458         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 459         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 460         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 461         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 462         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 463         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 464         | tIN                                   { $$ = make_attr(ATTR_IN); }
 465         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 466         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 467         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 468         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 469         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 470         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 471         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 472         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 473         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 474         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 475         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 476         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 477         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 478         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 479         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 480         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 481         | tRANGE '(' expr_const ',' expr_const ')' { expr_list_t *list = append_expr( NULL, $3 );
 482                                                      list = append_expr( list, $5 );
 483                                                      $$ = make_attrp(ATTR_RANGE, list); }
 484         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 485         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 486         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 487         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 488         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 489         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 490         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 491         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 492         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, $3); }
 493         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, $3); }
 494         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 495         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 496         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 497         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 498         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, $3); }
 499         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 500         ;
 501
 502 callconv:
 503         | tSTDCALL
 504         ;
 505
 506 cases:                                          { $$ = NULL; }
 507         | cases case                            { $$ = append_var( $1, $2 ); }
 508         ;
 509
 510 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 511                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 512                                                   $$->attrs = append_attr( $$->attrs, a );
 513                                                 }
 514         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 515                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 516                                                   $$->attrs = append_attr( $$->attrs, a );
 517                                                 }
 518         ;
 519
 520 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 521                                                   set_type($$, $2, 0, NULL);
 522                                                   $$->eval = $5;
 523                                                 }
 524         ;
 525
 526 enums:                                          { $$ = NULL; }
 527         | enum_list ','                         { $$ = $1; }
 528         | enum_list
 529         ;
 530
 531 enum_list: enum                                 { if (!$1->eval)
 532                                                     $1->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 533                                                   $$ = append_var( NULL, $1 );
 534                                                 }
 535         | enum_list ',' enum                    { if (!$3->eval)
 536                                                   {
 537                                                     var_t *last = LIST_ENTRY( list_tail($$), var_t, entry );
 538                                                     $3->eval = make_exprl(EXPR_NUM, last->eval->cval + 1);
 539                                                   }
 540                                                   $$ = append_var( $1, $3 );
 541                                                 }
 542         ;
 543
 544 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 545                                                   $$->eval = $3;
 546                                                   $$->type = make_int(0);
 547                                                 }
 548         | ident                                 { $$ = reg_const($1);
 549                                                   $$->type = make_int(0);
 550                                                 }
 551         ;
 552
 553 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 554                                                   $$->kind = TKIND_ENUM;
 555                                                   $$->fields = $4;
 556                                                   $$->defined = TRUE;
 557                                                   if(in_typelib)
 558                                                       add_typelib_entry($$);
 559                                                 }
 560         ;
 561
 562 m_exprs:  m_expr                                { $$ = append_expr( NULL, $1 ); }
 563         | m_exprs ',' m_expr                    { $$ = append_expr( $1, $3 ); }
 564         ;
 565
 566 /*
 567 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 568         | expr_list
 569         ;
 570
 571 expr_list: expr
 572         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 573         ;
 574 */
 575
 576 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 577         | expr
 578         ;
 579
 580 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 581         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 582         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 583         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 584         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 585         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 586         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 587         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 588         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 589         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 590         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 591         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 592         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 593         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 594         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 595         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 596         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 597         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 598         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 599         | '(' expr ')'                          { $$ = $2; }
 600         ;
 601
 602 expr_list_const: expr_const                     { $$ = append_expr( NULL, $1 ); }
 603         | expr_list_const ',' expr_const        { $$ = append_expr( $1, $3 ); }
 604         ;
 605
 606 expr_const: expr                                { $$ = $1;
 607                                                   if (!$$->is_const)
 608                                                       yyerror("expression is not constant");
 609                                                 }
 610         ;
 611
 612 externdef: tEXTERN tCONST type ident            { $$ = $4;
 613                                                   set_type($$, $3, 0, NULL);
 614                                                 }
 615         ;
 616
 617 fields:                                         { $$ = NULL; }
 618         | fields field                          { $$ = append_var( $1, $2 ); }
 619         ;
 620
 621 field:    s_field ';'                           { $$ = $1; }
 622         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 623         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 624         | ';'                                   { $$ = NULL; }
 625         ;
 626
 627 s_field:  m_attributes type pident array        { $$ = $3->var;
 628                                                   $$->attrs = $1;
 629                                                   set_type($$, $2, $3->ptr_level, $4);
 630                                                   free($3);
 631                                                 }
 632         ;
 633
 634 funcdef:
 635           m_attributes type callconv pident
 636           '(' m_args ')'                        { var_t *v = $4->var;
 637                                                   v->attrs = $1;
 638                                                   set_type(v, $2, $4->ptr_level, NULL);
 639                                                   free($4);
 640                                                   $$ = make_func(v, $6);
 641                                                   if (is_attr(v->attrs, ATTR_IN)) {
 642                                                     yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
 643                                                   }
 644                                                 }
 645         ;
 646
 647 m_ident:                                        { $$ = NULL; }
 648         | ident
 649         ;
 650
 651 t_ident:                                        { $$ = NULL; }
 652         | aIDENTIFIER                           { $$ = make_var($1); }
 653         | aKNOWNTYPE                            { $$ = make_var($1); }
 654         ;
 655
 656 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 657 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 658         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 659         ;
 660
 661 base_type: tBYTE                                { $$ = make_builtin($<str>1); }
 662         | tWCHAR                                { $$ = make_builtin($<str>1); }
 663         | int_std
 664         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 665         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 666                                                   switch ($$->type) {
 667                                                   case RPC_FC_CHAR:  break;
 668                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 669                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 670                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 671                                                   case RPC_FC_HYPER:
 672                                                     if ($$->name[0] == 'h') /* hyper, as opposed to __int64 */
 673                                                     {
 674                                                       $$ = alias($$, "MIDL_uhyper");
 675                                                       $$->sign = 0;
 676                                                     }
 677                                                     break;
 678                                                   default: break;
 679                                                   }
 680                                                 }
 681         | tUNSIGNED                             { $$ = make_int(-1); }
 682         | tFLOAT                                { $$ = make_builtin($<str>1); }
 683         | tSINGLE                               { $$ = duptype(find_type("float", 0), 1); }
 684         | tDOUBLE                               { $$ = make_builtin($<str>1); }
 685         | tBOOLEAN                              { $$ = make_builtin($<str>1); }
 686         | tERRORSTATUST                         { $$ = make_builtin($<str>1); }
 687         | tHANDLET                              { $$ = make_builtin($<str>1); }
 688         ;
 689
 690 m_int:
 691         | tINT
 692         ;
 693
 694 int_std:  tINT                                  { $$ = make_builtin($<str>1); }
 695         | tSHORT m_int                          { $$ = make_builtin($<str>1); }
 696         | tSMALL                                { $$ = make_builtin($<str>1); }
 697         | tLONG m_int                           { $$ = make_builtin($<str>1); }
 698         | tHYPER m_int                          { $$ = make_builtin($<str>1); }
 699         | tINT64                                { $$ = make_builtin($<str>1); }
 700         | tCHAR                                 { $$ = make_builtin($<str>1); }
 701         ;
 702
 703 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 704         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 705                                                   if ($$->defined) yyerror("multiple definition error");
 706                                                   if ($$->kind != TKIND_COCLASS) yyerror("%s was not declared a coclass", $2);
 707                                                 }
 708         ;
 709
 710 coclasshdr: attributes coclass                  { $$ = $2;
 711                                                   $$->attrs = $1;
 712                                                   if (!parse_only && do_header)
 713                                                     write_coclass($$);
 714                                                   if (!parse_only && do_idfile)
 715                                                     write_clsid($$);
 716                                                 }
 717         ;
 718
 719 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 720                                                   $$->ifaces = $3;
 721                                                   $$->defined = TRUE;
 722                                                 }
 723         ;
 724
 725 coclass_ints:                                   { $$ = NULL; }
 726         | coclass_ints coclass_int              { $$ = append_ifref( $1, $2 ); }
 727         ;
 728
 729 coclass_int:
 730           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 731         ;
 732
 733 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 734         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 735         ;
 736
 737 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 738                                                   $$ = $2;
 739                                                   if ($$->defined) yyerror("multiple definition error");
 740                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 741                                                   $$->attrs = append_attr( $1, attrs );
 742                                                   $$->ref = find_type("IDispatch", 0);
 743                                                   if (!$$->ref) yyerror("IDispatch is undefined");
 744                                                   $$->defined = TRUE;
 745                                                   if (!parse_only && do_header) write_forward($$);
 746                                                 }
 747         ;
 748
 749 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 750         | dispint_props s_field ';'             { $$ = append_var( $1, $2 ); }
 751         ;
 752
 753 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 754         | dispint_meths funcdef ';'             { $$ = append_func( $1, $2 ); }
 755         ;
 756
 757 dispinterfacedef: dispinterfacehdr '{'
 758           dispint_props
 759           dispint_meths
 760           '}'                                   { $$ = $1;
 761                                                   $$->fields = $3;
 762                                                   $$->funcs = $4;
 763                                                   if (!parse_only && do_header) write_dispinterface($$);
 764                                                   if (!parse_only && do_idfile) write_diid($$);
 765                                                 }
 766         | dispinterfacehdr
 767          '{' interface ';' '}'                  { $$ = $1;
 768                                                   $$->fields = $3->fields;
 769                                                   $$->funcs = $3->funcs;
 770                                                   if (!parse_only && do_header) write_dispinterface($$);
 771                                                   if (!parse_only && do_idfile) write_diid($$);
 772                                                 }
 773         ;
 774
 775 inherit:                                        { $$ = NULL; }
 776         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 777         ;
 778
 779 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 780         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 781         ;
 782
 783 interfacehdr: attributes interface              { $$ = $2;
 784                                                   if ($$->defined) yyerror("multiple definition error");
 785                                                   $$->attrs = $1;
 786                                                   $$->defined = TRUE;
 787                                                   if (!parse_only && do_header) write_forward($$);
 788                                                 }
 789         ;
 790
 791 interfacedef: interfacehdr inherit
 792           '{' int_statements '}'                { $$ = $1;
 793                                                   $$->ref = $2;
 794                                                   $$->funcs = $4;
 795                                                   compute_method_indexes($$);
 796                                                   if (!parse_only && do_header) write_interface($$);
 797                                                   if (!parse_only && do_idfile) write_iid($$);
 798                                                 }
 799 /* MIDL is able to import the definition of a base class from inside the
 800  * definition of a derived class, I'll try to support it with this rule */
 801         | interfacehdr ':' aIDENTIFIER
 802           '{' import int_statements '}'         { $$ = $1;
 803                                                   $$->ref = find_type2($3, 0);
 804                                                   if (!$$->ref) yyerror("base class '%s' not found in import", $3);
 805                                                   $$->funcs = $6;
 806                                                   compute_method_indexes($$);
 807                                                   if (!parse_only && do_header) write_interface($$);
 808                                                   if (!parse_only && do_idfile) write_iid($$);
 809                                                 }
 810         | dispinterfacedef                      { $$ = $1; }
 811         ;
 812
 813 interfacedec:
 814           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 815         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 816         ;
 817
 818 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 819         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 820         ;
 821
 822 modulehdr: attributes module                    { $$ = $2;
 823                                                   $$->attrs = $1;
 824                                                 }
 825         ;
 826
 827 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 828                                                   $$->funcs = $3;
 829                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 830                                                 }
 831         ;
 832
 833 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 834         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 835         ;
 836
 837 pident:   ident                                 { $$ = make_pident($1); }
 838         | p_ident
 839         | '(' pident ')'                        { $$ = $2; }
 840         ;
 841
 842 pident_list:
 843         pident                                  { $$ = append_pident( NULL, $1 ); }
 844         | pident_list ',' pident                { $$ = append_pident( $1, $3 ); }
 845         ;
 846
 847 pointer_type:
 848           tREF                                  { $$ = RPC_FC_RP; }
 849         | tUNIQUE                               { $$ = RPC_FC_UP; }
 850         | tPTR                                  { $$ = RPC_FC_FP; }
 851         ;
 852
 853 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 854                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 855                                                   $$->type = get_struct_type( $4 );
 856                                                   $$->kind = TKIND_RECORD;
 857                                                   $$->fields = $4;
 858                                                   $$->defined = TRUE;
 859                                                   if(in_typelib)
 860                                                       add_typelib_entry($$);
 861                                                 }
 862         ;
 863
 864 type:     tVOID                                 { $$ = duptype(find_type("void", 0), 1); }
 865         | aKNOWNTYPE                            { $$ = find_type($1, 0); }
 866         | base_type                             { $$ = $1; }
 867         | tCONST type                           { $$ = duptype($2, 1); $$->is_const = TRUE; }
 868         | enumdef                               { $$ = $1; }
 869         | tENUM aIDENTIFIER                     { $$ = find_type2($2, tsENUM); }
 870         | structdef                             { $$ = $1; }
 871         | tSTRUCT aIDENTIFIER                   { $$ = get_type(RPC_FC_STRUCT, $2, tsSTRUCT); }
 872         | uniondef                              { $$ = $1; }
 873         | tUNION aIDENTIFIER                    { $$ = find_type2($2, tsUNION); }
 874         | tSAFEARRAY '(' type ')'               { $$ = make_safearray($3); }
 875         ;
 876
 877 typedef: tTYPEDEF m_attributes type pident_list { reg_typedefs($3, $4, $2);
 878                                                   process_typedefs($4);
 879                                                 }
 880         ;
 881
 882 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 883                                                   $$->kind = TKIND_UNION;
 884                                                   $$->fields = $4;
 885                                                   $$->defined = TRUE;
 886                                                 }
 887         | tUNION t_ident
 888           tSWITCH '(' s_field ')'
 889           m_ident '{' cases '}'                 { var_t *u = $7;
 890                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 891                                                   $$->kind = TKIND_UNION;
 892                                                   if (!u) u = make_var( xstrdup("tagged_union") );
 893                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 894                                                   u->type->kind = TKIND_UNION;
 895                                                   u->type->fields = $9;
 896                                                   u->type->defined = TRUE;
 897                                                   $$->fields = append_var( $$->fields, $5 );
 898                                                   $$->fields = append_var( $$->fields, u );
 899                                                   $$->defined = TRUE;
 900                                                 }
 901         ;
 902
 903 version:
 904           aNUM                                  { $$ = MAKELONG($1, 0); }
 905         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 906         ;
 907
 908 %%
 909
 910 static void decl_builtin(const char *name, unsigned char type)
 911 {
 912   type_t *t = make_type(type, NULL);
 913   t->name = xstrdup(name);
 914   reg_type(t, name, 0);
 915 }
 916
 917 static type_t *make_builtin(char *name)
 918 {
 919   /* NAME is strdup'd in the lexer */
 920   type_t *t = duptype(find_type(name, 0), 0);
 921   t->name = name;
 922   return t;
 923 }
 924
 925 static type_t *make_int(int sign)
 926 {
 927   type_t *t = duptype(find_type("int", 0), 1);
 928
 929   t->sign = sign;
 930   if (sign < 0)
 931     t->type = t->type == RPC_FC_LONG ? RPC_FC_ULONG : RPC_FC_USHORT;
 932
 933   return t;
 934 }
 935
 936 void init_types(void)
 937 {
 938   decl_builtin("void", 0);
 939   decl_builtin("byte", RPC_FC_BYTE);
 940   decl_builtin("wchar_t", RPC_FC_WCHAR);
 941   decl_builtin("int", RPC_FC_LONG);     /* win32 */
 942   decl_builtin("short", RPC_FC_SHORT);
 943   decl_builtin("small", RPC_FC_SMALL);
 944   decl_builtin("long", RPC_FC_LONG);
 945   decl_builtin("hyper", RPC_FC_HYPER);
 946   decl_builtin("__int64", RPC_FC_HYPER);
 947   decl_builtin("char", RPC_FC_CHAR);
 948   decl_builtin("float", RPC_FC_FLOAT);
 949   decl_builtin("double", RPC_FC_DOUBLE);
 950   decl_builtin("boolean", RPC_FC_BYTE);
 951   decl_builtin("error_status_t", RPC_FC_ERROR_STATUS_T);
 952   decl_builtin("handle_t", RPC_FC_BIND_PRIMITIVE);
 953 }
 954
 955 static str_list_t *append_str(str_list_t *list, char *str)
 956 {
 957     struct str_list_entry_t *entry;
 958
 959     if (!str) return list;
 960     if (!list)
 961     {
 962         list = xmalloc( sizeof(*list) );
 963         list_init( list );
 964     }
 965     entry = xmalloc( sizeof(*entry) );
 966     entry->str = str;
 967     list_add_tail( list, &entry->entry );
 968     return list;
 969 }
 970
 971 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr)
 972 {
 973     if (!attr) return list;
 974     if (!list)
 975     {
 976         list = xmalloc( sizeof(*list) );
 977         list_init( list );
 978     }
 979     list_add_tail( list, &attr->entry );
 980     return list;
 981 }
 982
 983 static attr_t *make_attr(enum attr_type type)
 984 {
 985   attr_t *a = xmalloc(sizeof(attr_t));
 986   a->type = type;
 987   a->u.ival = 0;
 988   return a;
 989 }
 990
 991 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 992 {
 993   attr_t *a = xmalloc(sizeof(attr_t));
 994   a->type = type;
 995   a->u.ival = val;
 996   return a;
 997 }
 998
 999 static attr_t *make_attrp(enum attr_type type, void *val)
1000 {
1001   attr_t *a = xmalloc(sizeof(attr_t));
1002   a->type = type;
1003   a->u.pval = val;
1004   return a;
1005 }
1006
1007 static expr_t *make_expr(enum expr_type type)
1008 {
1009   expr_t *e = xmalloc(sizeof(expr_t));
1010   e->type = type;
1011   e->ref = NULL;
1012   e->u.lval = 0;
1013   e->is_const = FALSE;
1014   return e;
1015 }
1016
1017 static expr_t *make_exprl(enum expr_type type, long val)
1018 {
1019   expr_t *e = xmalloc(sizeof(expr_t));
1020   e->type = type;
1021   e->ref = NULL;
1022   e->u.lval = val;
1023   e->is_const = FALSE;
1024   /* check for numeric constant */
1025   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
1026     /* make sure true/false value is valid */
1027     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
1028     e->is_const = TRUE;
1029     e->cval = val;
1030   }
1031   return e;
1032 }
1033
1034 static expr_t *make_exprs(enum expr_type type, char *val)
1035 {
1036   expr_t *e;
1037   e = xmalloc(sizeof(expr_t));
1038   e->type = type;
1039   e->ref = NULL;
1040   e->u.sval = val;
1041   e->is_const = FALSE;
1042   /* check for predefined constants */
1043   if (type == EXPR_IDENTIFIER) {
1044     var_t *c = find_const(val, 0);
1045     if (c) {
1046       e->u.sval = c->name;
1047       free(val);
1048       e->is_const = TRUE;
1049       e->cval = c->eval->cval;
1050     }
1051   }
1052   return e;
1053 }
1054
1055 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr)
1056 {
1057   expr_t *e;
1058   e = xmalloc(sizeof(expr_t));
1059   e->type = type;
1060   e->ref = expr;
1061   e->u.tref = tref;
1062   e->is_const = FALSE;
1063   /* check for cast of constant expression */
1064   if (type == EXPR_SIZEOF) {
1065     switch (tref->type) {
1066       case RPC_FC_BYTE:
1067       case RPC_FC_CHAR:
1068       case RPC_FC_SMALL:
1069       case RPC_FC_USMALL:
1070         e->is_const = TRUE;
1071         e->cval = 1;
1072         break;
1073       case RPC_FC_WCHAR:
1074       case RPC_FC_USHORT:
1075       case RPC_FC_SHORT:
1076         e->is_const = TRUE;
1077         e->cval = 2;
1078         break;
1079       case RPC_FC_LONG:
1080       case RPC_FC_ULONG:
1081       case RPC_FC_FLOAT:
1082       case RPC_FC_ERROR_STATUS_T:
1083         e->is_const = TRUE;
1084         e->cval = 4;
1085         break;
1086       case RPC_FC_HYPER:
1087       case RPC_FC_DOUBLE:
1088         e->is_const = TRUE;
1089         e->cval = 8;
1090         break;
1091     }
1092   }
1093   if (type == EXPR_CAST && expr->is_const) {
1094     e->is_const = TRUE;
1095     e->cval = expr->cval;
1096   }
1097   return e;
1098 }
1099
1100 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
1101 {
1102   expr_t *e;
1103   e = xmalloc(sizeof(expr_t));
1104   e->type = type;
1105   e->ref = expr;
1106   e->u.lval = 0;
1107   e->is_const = FALSE;
1108   /* check for compile-time optimization */
1109   if (expr->is_const) {
1110     e->is_const = TRUE;
1111     switch (type) {
1112     case EXPR_NEG:
1113       e->cval = -expr->cval;
1114       break;
1115     case EXPR_NOT:
1116       e->cval = ~expr->cval;
1117       break;
1118     default:
1119       e->is_const = FALSE;
1120       break;
1121     }
1122   }
1123   return e;
1124 }
1125
1126 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1127 {
1128   expr_t *e;
1129   e = xmalloc(sizeof(expr_t));
1130   e->type = type;
1131   e->ref = expr1;
1132   e->u.ext = expr2;
1133   e->is_const = FALSE;
1134   /* check for compile-time optimization */
1135   if (expr1->is_const && expr2->is_const) {
1136     e->is_const = TRUE;
1137     switch (type) {
1138     case EXPR_ADD:
1139       e->cval = expr1->cval + expr2->cval;
1140       break;
1141     case EXPR_SUB:
1142       e->cval = expr1->cval - expr2->cval;
1143       break;
1144     case EXPR_MUL:
1145       e->cval = expr1->cval * expr2->cval;
1146       break;
1147     case EXPR_DIV:
1148       e->cval = expr1->cval / expr2->cval;
1149       break;
1150     case EXPR_OR:
1151       e->cval = expr1->cval | expr2->cval;
1152       break;
1153     case EXPR_AND:
1154       e->cval = expr1->cval & expr2->cval;
1155       break;
1156     case EXPR_SHL:
1157       e->cval = expr1->cval << expr2->cval;
1158       break;
1159     case EXPR_SHR:
1160       e->cval = expr1->cval >> expr2->cval;
1161       break;
1162     default:
1163       e->is_const = FALSE;
1164       break;
1165     }
1166   }
1167   return e;
1168 }
1169
1170 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1171 {
1172   expr_t *e;
1173   e = xmalloc(sizeof(expr_t));
1174   e->type = type;
1175   e->ref = expr1;
1176   e->u.ext = expr2;
1177   e->ext2 = expr3;
1178   e->is_const = FALSE;
1179   /* check for compile-time optimization */
1180   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1181     e->is_const = TRUE;
1182     switch (type) {
1183     case EXPR_COND:
1184       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1185       break;
1186     default:
1187       e->is_const = FALSE;
1188       break;
1189     }
1190   }
1191   return e;
1192 }
1193
1194 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr)
1195 {
1196     if (!expr) return list;
1197     if (!list)
1198     {
1199         list = xmalloc( sizeof(*list) );
1200         list_init( list );
1201     }
1202     list_add_tail( list, &expr->entry );
1203     return list;
1204 }
1205
1206 static array_dims_t *append_array(array_dims_t *list, expr_t *expr)
1207 {
1208     if (!expr) return list;
1209     if (!list)
1210     {
1211         list = xmalloc( sizeof(*list) );
1212         list_init( list );
1213     }
1214     list_add_tail( list, &expr->entry );
1215     return list;
1216 }
1217
1218 static type_t *make_type(unsigned char type, type_t *ref)
1219 {
1220   type_t *t = xmalloc(sizeof(type_t));
1221   t->name = NULL;
1222   t->kind = TKIND_PRIMITIVE;
1223   t->type = type;
1224   t->ref = ref;
1225   t->attrs = NULL;
1226   t->orig = NULL;
1227   t->funcs = NULL;
1228   t->fields = NULL;
1229   t->ifaces = NULL;
1230   t->dim = 0;
1231   t->size_is = NULL;
1232   t->length_is = NULL;
1233   t->typestring_offset = 0;
1234   t->declarray = FALSE;
1235   t->ignore = (parse_only != 0);
1236   t->is_const = FALSE;
1237   t->sign = 0;
1238   t->defined = FALSE;
1239   t->written = FALSE;
1240   t->user_types_registered = FALSE;
1241   t->tfswrite = FALSE;
1242   t->typelib_idx = -1;
1243   return t;
1244 }
1245
1246 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr)
1247 {
1248   expr_list_t *sizes = get_attrp(v->attrs, ATTR_SIZEIS);
1249   expr_list_t *lengs = get_attrp(v->attrs, ATTR_LENGTHIS);
1250   int sizeless, has_varconf;
1251   expr_t *dim;
1252   type_t *atype, **ptype;
1253
1254   v->type = type;
1255
1256   for ( ; 0 < ptr_level; --ptr_level)
1257     v->type = make_type(RPC_FC_RP, v->type);
1258
1259   sizeless = FALSE;
1260   if (arr) LIST_FOR_EACH_ENTRY_REV(dim, arr, expr_t, entry)
1261   {
1262     if (sizeless)
1263       error("%s: only the first array dimension can be unspecified\n", v->name);
1264
1265     if (dim->is_const)
1266     {
1267       unsigned int align = 0;
1268       size_t size = type_memsize(v->type, &align);
1269
1270       if (dim->cval <= 0)
1271         error("%s: array dimension must be positive\n", v->name);
1272
1273       if (0xffffffffuL / size < (unsigned long) dim->cval)
1274         error("%s: total array size is too large", v->name);
1275       else if (0xffffuL < size * dim->cval)
1276         v->type = make_type(RPC_FC_LGFARRAY, v->type);
1277       else
1278         v->type = make_type(RPC_FC_SMFARRAY, v->type);
1279     }
1280     else
1281     {
1282       sizeless = TRUE;
1283       v->type = make_type(RPC_FC_CARRAY, v->type);
1284     }
1285
1286     v->type->declarray = TRUE;
1287     v->type->dim = dim->cval;
1288   }
1289
1290   ptype = &v->type;
1291   has_varconf = FALSE;
1292   if (sizes) LIST_FOR_EACH_ENTRY(dim, sizes, expr_t, entry)
1293   {
1294     if (dim->type != EXPR_VOID)
1295     {
1296       has_varconf = TRUE;
1297       atype = *ptype = duptype(*ptype, 0);
1298
1299       if (atype->type == RPC_FC_SMFARRAY || atype->type == RPC_FC_LGFARRAY)
1300         error("%s: cannot specify size_is for a fixed sized array\n", v->name);
1301
1302       if (atype->type != RPC_FC_CARRAY && !is_ptr(atype))
1303         error("%s: size_is attribute applied to illegal type\n", v->name);
1304
1305       atype->type = RPC_FC_CARRAY;
1306       atype->size_is = dim;
1307     }
1308
1309     ptype = &(*ptype)->ref;
1310     if (*ptype == NULL)
1311       error("%s: too many expressions in size_is attribute\n", v->name);
1312   }
1313
1314   ptype = &v->type;
1315   if (lengs) LIST_FOR_EACH_ENTRY(dim, lengs, expr_t, entry)
1316   {
1317     if (dim->type != EXPR_VOID)
1318     {
1319       has_varconf = TRUE;
1320       atype = *ptype = duptype(*ptype, 0);
1321
1322       if (atype->type == RPC_FC_SMFARRAY)
1323         atype->type = RPC_FC_SMVARRAY;
1324       else if (atype->type == RPC_FC_LGFARRAY)
1325         atype->type = RPC_FC_LGVARRAY;
1326       else if (atype->type == RPC_FC_CARRAY)
1327         atype->type = RPC_FC_CVARRAY;
1328       else
1329         error("%s: length_is attribute applied to illegal type\n", v->name);
1330
1331       atype->length_is = dim;
1332     }
1333
1334     ptype = &(*ptype)->ref;
1335     if (*ptype == NULL)
1336       error("%s: too many expressions in length_is attribute\n", v->name);
1337   }
1338
1339   if (has_varconf && !last_array(v->type))
1340   {
1341     ptype = &v->type;
1342     for (ptype = &v->type; is_array(*ptype); ptype = &(*ptype)->ref)
1343     {
1344       *ptype = duptype(*ptype, 0);
1345       (*ptype)->type = RPC_FC_BOGUS_ARRAY;
1346     }
1347   }
1348 }
1349
1350 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface)
1351 {
1352     if (!iface) return list;
1353     if (!list)
1354     {
1355         list = xmalloc( sizeof(*list) );
1356         list_init( list );
1357     }
1358     list_add_tail( list, &iface->entry );
1359     return list;
1360 }
1361
1362 static ifref_t *make_ifref(type_t *iface)
1363 {
1364   ifref_t *l = xmalloc(sizeof(ifref_t));
1365   l->iface = iface;
1366   l->attrs = NULL;
1367   return l;
1368 }
1369
1370 static var_list_t *append_var(var_list_t *list, var_t *var)
1371 {
1372     if (!var) return list;
1373     if (!list)
1374     {
1375         list = xmalloc( sizeof(*list) );
1376         list_init( list );
1377     }
1378     list_add_tail( list, &var->entry );
1379     return list;
1380 }
1381
1382 static var_t *make_var(char *name)
1383 {
1384   var_t *v = xmalloc(sizeof(var_t));
1385   v->name = name;
1386   v->type = NULL;
1387   v->args = NULL;
1388   v->attrs = NULL;
1389   v->eval = NULL;
1390   return v;
1391 }
1392
1393 static pident_list_t *append_pident(pident_list_t *list, pident_t *p)
1394 {
1395   if (!p) return list;
1396   if (!list) {
1397     list = xmalloc(sizeof(*list));
1398     list_init(list);
1399   }
1400   list_add_tail(list, &p->entry);
1401   return list;
1402 }
1403
1404 static pident_t *make_pident(var_t *var)
1405 {
1406   pident_t *p = xmalloc(sizeof(*p));
1407   p->var = var;
1408   p->ptr_level = 0;
1409   return p;
1410 }
1411
1412 static func_list_t *append_func(func_list_t *list, func_t *func)
1413 {
1414     if (!func) return list;
1415     if (!list)
1416     {
1417         list = xmalloc( sizeof(*list) );
1418         list_init( list );
1419     }
1420     list_add_tail( list, &func->entry );
1421     return list;
1422 }
1423
1424 static func_t *make_func(var_t *def, var_list_t *args)
1425 {
1426   func_t *f = xmalloc(sizeof(func_t));
1427   f->def = def;
1428   f->args = args;
1429   f->ignore = parse_only;
1430   f->idx = -1;
1431   return f;
1432 }
1433
1434 static type_t *make_class(char *name)
1435 {
1436   type_t *c = make_type(0, NULL);
1437   c->name = name;
1438   c->kind = TKIND_COCLASS;
1439   return c;
1440 }
1441
1442 static type_t *make_safearray(type_t *type)
1443 {
1444   type_t *sa = duptype(find_type("SAFEARRAY", 0), 1);
1445   sa->ref = type;
1446   return make_type(RPC_FC_FP, sa);
1447 }
1448
1449 #define HASHMAX 64
1450
1451 static int hash_ident(const char *name)
1452 {
1453   const char *p = name;
1454   int sum = 0;
1455   /* a simple sum hash is probably good enough */
1456   while (*p) {
1457     sum += *p;
1458     p++;
1459   }
1460   return sum & (HASHMAX-1);
1461 }
1462
1463 /***** type repository *****/
1464
1465 struct rtype {
1466   const char *name;
1467   type_t *type;
1468   int t;
1469   struct rtype *next;
1470 };
1471
1472 struct rtype *type_hash[HASHMAX];
1473
1474 static type_t *reg_type(type_t *type, const char *name, int t)
1475 {
1476   struct rtype *nt;
1477   int hash;
1478   if (!name) {
1479     yyerror("registering named type without name");
1480     return type;
1481   }
1482   hash = hash_ident(name);
1483   nt = xmalloc(sizeof(struct rtype));
1484   nt->name = name;
1485   nt->type = type;
1486   nt->t = t;
1487   nt->next = type_hash[hash];
1488   type_hash[hash] = nt;
1489   return type;
1490 }
1491
1492 static int is_incomplete(const type_t *t)
1493 {
1494   return !t->defined && (is_struct(t->type) || is_union(t->type));
1495 }
1496
1497 static void add_incomplete(type_t *t)
1498 {
1499   struct typenode *tn = xmalloc(sizeof *tn);
1500   tn->type = t;
1501   list_add_tail(&incomplete_types, &tn->entry);
1502 }
1503
1504 static void fix_type(type_t *t)
1505 {
1506   if (t->kind == TKIND_ALIAS && is_incomplete(t)) {
1507     type_t *ot = t->orig;
1508     fix_type(ot);
1509     t->fields = ot->fields;
1510     t->defined = ot->defined;
1511   }
1512 }
1513
1514 static void fix_incomplete(void)
1515 {
1516   struct typenode *tn, *next;
1517
1518   LIST_FOR_EACH_ENTRY_SAFE(tn, next, &incomplete_types, struct typenode, entry) {
1519     fix_type(tn->type);
1520     free(tn);
1521   }
1522 }
1523
1524 static type_t *reg_typedefs(type_t *type, pident_list_t *pidents, attr_list_t *attrs)
1525 {
1526   type_t *ptr = type;
1527   const pident_t *pident;
1528   int ptrc = 0;
1529   int is_str = is_attr(attrs, ATTR_STRING);
1530   unsigned char ptr_type = get_attrv(attrs, ATTR_POINTERTYPE);
1531
1532   if (is_str)
1533   {
1534     type_t *t = type;
1535     unsigned char c;
1536
1537     while (is_ptr(t))
1538       t = t->ref;
1539
1540     c = t->type;
1541     if (c != RPC_FC_CHAR && c != RPC_FC_BYTE && c != RPC_FC_WCHAR)
1542     {
1543       pident = LIST_ENTRY( list_head( pidents ), const pident_t, entry );
1544       yyerror("'%s': [string] attribute is only valid on 'char', 'byte', or 'wchar_t' pointers and arrays",
1545               pident->var->name);
1546     }
1547   }
1548
1549   /* We must generate names for tagless enum, struct or union.
1550      Typedef-ing a tagless enum, struct or union means we want the typedef
1551      to be included in a library whether it has other attributes or not,
1552      hence the public attribute.  */
1553   if ((type->kind == TKIND_ENUM || type->kind == TKIND_RECORD
1554        || type->kind == TKIND_UNION) && ! type->name && ! parse_only)
1555   {
1556     if (! is_attr(attrs, ATTR_PUBLIC))
1557       attrs = append_attr( attrs, make_attr(ATTR_PUBLIC) );
1558     type->name = gen_name();
1559   }
1560
1561   LIST_FOR_EACH_ENTRY( pident, pidents, const pident_t, entry )
1562   {
1563     var_t *name = pident->var;
1564
1565     if (name->name) {
1566       type_t *cur = ptr;
1567       int cptr = pident->ptr_level;
1568       if (cptr > ptrc) {
1569         while (cptr > ptrc) {
1570           cur = ptr = make_type(RPC_FC_RP, cur);
1571           ptrc++;
1572         }
1573       } else {
1574         while (cptr < ptrc) {
1575           cur = cur->ref;
1576           cptr++;
1577         }
1578       }
1579       cur = alias(cur, name->name);
1580       cur->attrs = attrs;
1581       if (ptr_type)
1582       {
1583         if (is_ptr(cur))
1584           cur->type = ptr_type;
1585         else
1586           yyerror("'%s': pointer attribute applied to non-pointer type",
1587                   cur->name);
1588       }
1589       else if (is_str && ! is_ptr(cur))
1590         yyerror("'%s': [string] attribute applied to non-pointer type",
1591                 cur->name);
1592
1593       if (is_incomplete(cur))
1594         add_incomplete(cur);
1595       reg_type(cur, cur->name, 0);
1596     }
1597   }
1598   return type;
1599 }
1600
1601 static type_t *find_type(const char *name, int t)
1602 {
1603   struct rtype *cur = type_hash[hash_ident(name)];
1604   while (cur && (cur->t != t || strcmp(cur->name, name)))
1605     cur = cur->next;
1606   if (!cur) {
1607     yyerror("type '%s' not found", name);
1608     return NULL;
1609   }
1610   return cur->type;
1611 }
1612
1613 static type_t *find_type2(char *name, int t)
1614 {
1615   type_t *tp = find_type(name, t);
1616   free(name);
1617   return tp;
1618 }
1619
1620 int is_type(const char *name)
1621 {
1622   struct rtype *cur = type_hash[hash_ident(name)];
1623   while (cur && (cur->t || strcmp(cur->name, name)))
1624     cur = cur->next;
1625   if (cur) return TRUE;
1626   return FALSE;
1627 }
1628
1629 static type_t *get_type(unsigned char type, char *name, int t)
1630 {
1631   struct rtype *cur = NULL;
1632   type_t *tp;
1633   if (name) {
1634     cur = type_hash[hash_ident(name)];
1635     while (cur && (cur->t != t || strcmp(cur->name, name)))
1636       cur = cur->next;
1637   }
1638   if (cur) {
1639     free(name);
1640     return cur->type;
1641   }
1642   tp = make_type(type, NULL);
1643   tp->name = name;
1644   if (!name) return tp;
1645   return reg_type(tp, name, t);
1646 }
1647
1648 static type_t *get_typev(unsigned char type, var_t *name, int t)
1649 {
1650   char *sname = NULL;
1651   if (name) {
1652     sname = name->name;
1653     free(name);
1654   }
1655   return get_type(type, sname, t);
1656 }
1657
1658 static int get_struct_type(var_list_t *fields)
1659 {
1660   int has_pointer = 0;
1661   int has_conformance = 0;
1662   int has_variance = 0;
1663   var_t *field;
1664
1665   if (fields) LIST_FOR_EACH_ENTRY( field, fields, var_t, entry )
1666   {
1667     type_t *t = field->type;
1668
1669     if (is_ptr(field->type))
1670     {
1671         has_pointer = 1;
1672         continue;
1673     }
1674
1675     if (field->type->declarray)
1676     {
1677         if (is_string_type(field->attrs, field->type))
1678         {
1679             has_conformance = 1;
1680             has_variance = 1;
1681             continue;
1682         }
1683
1684         if (is_array(field->type->ref))
1685             return RPC_FC_BOGUS_STRUCT;
1686
1687         if (is_conformant_array(field->type))
1688         {
1689             has_conformance = 1;
1690             if (field->type->declarray && list_next(fields, &field->entry))
1691                 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1692                         field->name);
1693         }
1694         if (field->type->length_is)
1695             has_variance = 1;
1696
1697         t = field->type->ref;
1698     }
1699
1700     switch (t->type)
1701     {
1702     /*
1703      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1704      *  Simple types don't effect the type of struct.
1705      *  A struct containing a simple struct is still a simple struct.
1706      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1707      */
1708     case 0: /* void pointer */
1709     case RPC_FC_BYTE:
1710     case RPC_FC_CHAR:
1711     case RPC_FC_SMALL:
1712     case RPC_FC_USMALL:
1713     case RPC_FC_WCHAR:
1714     case RPC_FC_SHORT:
1715     case RPC_FC_USHORT:
1716     case RPC_FC_LONG:
1717     case RPC_FC_ULONG:
1718     case RPC_FC_INT3264:
1719     case RPC_FC_UINT3264:
1720     case RPC_FC_HYPER:
1721     case RPC_FC_FLOAT:
1722     case RPC_FC_DOUBLE:
1723     case RPC_FC_STRUCT:
1724     case RPC_FC_ENUM16:
1725     case RPC_FC_ENUM32:
1726       break;
1727
1728     case RPC_FC_RP:
1729     case RPC_FC_UP:
1730     case RPC_FC_FP:
1731     case RPC_FC_OP:
1732     case RPC_FC_CARRAY:
1733     case RPC_FC_CVARRAY:
1734       has_pointer = 1;
1735       break;
1736
1737     /*
1738      * Propagate member attributes
1739      *  a struct should be at least as complex as its member
1740      */
1741     case RPC_FC_CVSTRUCT:
1742       has_conformance = 1;
1743       has_variance = 1;
1744       has_pointer = 1;
1745       break;
1746
1747     case RPC_FC_CPSTRUCT:
1748       has_conformance = 1;
1749       if (list_next( fields, &field->entry ))
1750           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1751                   field->name);
1752       has_pointer = 1;
1753       break;
1754
1755     case RPC_FC_CSTRUCT:
1756       has_conformance = 1;
1757       if (list_next( fields, &field->entry ))
1758           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1759                   field->name);
1760       break;
1761
1762     case RPC_FC_PSTRUCT:
1763       has_pointer = 1;
1764       break;
1765
1766     default:
1767       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1768               field->name, t->type);
1769       /* fallthru - treat it as complex */
1770
1771     /* as soon as we see one of these these members, it's bogus... */
1772     case RPC_FC_IP:
1773     case RPC_FC_ENCAPSULATED_UNION:
1774     case RPC_FC_NON_ENCAPSULATED_UNION:
1775     case RPC_FC_TRANSMIT_AS:
1776     case RPC_FC_REPRESENT_AS:
1777     case RPC_FC_PAD:
1778     case RPC_FC_EMBEDDED_COMPLEX:
1779     case RPC_FC_BOGUS_STRUCT:
1780       return RPC_FC_BOGUS_STRUCT;
1781     }
1782   }
1783
1784   if( has_variance )
1785   {
1786     if ( has_conformance )
1787       return RPC_FC_CVSTRUCT;
1788     else
1789       return RPC_FC_BOGUS_STRUCT;
1790   }
1791   if( has_conformance && has_pointer )
1792     return RPC_FC_CPSTRUCT;
1793   if( has_conformance )
1794     return RPC_FC_CSTRUCT;
1795   if( has_pointer )
1796     return RPC_FC_PSTRUCT;
1797   return RPC_FC_STRUCT;
1798 }
1799
1800 /***** constant repository *****/
1801
1802 struct rconst {
1803   char *name;
1804   var_t *var;
1805   struct rconst *next;
1806 };
1807
1808 struct rconst *const_hash[HASHMAX];
1809
1810 static var_t *reg_const(var_t *var)
1811 {
1812   struct rconst *nc;
1813   int hash;
1814   if (!var->name) {
1815     yyerror("registering constant without name");
1816     return var;
1817   }
1818   hash = hash_ident(var->name);
1819   nc = xmalloc(sizeof(struct rconst));
1820   nc->name = var->name;
1821   nc->var = var;
1822   nc->next = const_hash[hash];
1823   const_hash[hash] = nc;
1824   return var;
1825 }
1826
1827 static var_t *find_const(char *name, int f)
1828 {
1829   struct rconst *cur = const_hash[hash_ident(name)];
1830   while (cur && strcmp(cur->name, name))
1831     cur = cur->next;
1832   if (!cur) {
1833     if (f) yyerror("constant '%s' not found", name);
1834     return NULL;
1835   }
1836   return cur->var;
1837 }
1838
1839 static void write_libid(const char *name, const attr_list_t *attr)
1840 {
1841   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1842   write_guid(idfile, "LIBID", name, uuid);
1843 }
1844
1845 static void write_clsid(type_t *cls)
1846 {
1847   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1848   write_guid(idfile, "CLSID", cls->name, uuid);
1849 }
1850
1851 static void write_diid(type_t *iface)
1852 {
1853   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1854   write_guid(idfile, "DIID", iface->name, uuid);
1855 }
1856
1857 static void write_iid(type_t *iface)
1858 {
1859   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1860   write_guid(idfile, "IID", iface->name, uuid);
1861 }
1862
1863 static int compute_method_indexes(type_t *iface)
1864 {
1865   int idx;
1866   func_t *f;
1867
1868   if (iface->ref)
1869     idx = compute_method_indexes(iface->ref);
1870   else
1871     idx = 0;
1872
1873   if (!iface->funcs)
1874     return idx;
1875
1876   LIST_FOR_EACH_ENTRY( f, iface->funcs, func_t, entry )
1877     if (! is_callas(f->def->attrs))
1878       f->idx = idx++;
1879
1880   return idx;
1881 }
1882
1883 static char *gen_name(void)
1884 {
1885   static const char format[] = "__WIDL_%s_generated_name_%08lX";
1886   static unsigned long n = 0;
1887   static const char *file_id;
1888   static size_t size;
1889   char *name;
1890
1891   if (! file_id)
1892   {
1893     char *dst = dup_basename(input_name, ".idl");
1894     file_id = dst;
1895
1896     for (; *dst; ++dst)
1897       if (! isalnum((unsigned char) *dst))
1898         *dst = '_';
1899
1900     size = sizeof format - 7 + strlen(file_id) + 8;
1901   }
1902
1903   name = xmalloc(size);
1904   sprintf(name, format, file_id, n++);
1905   return name;
1906 }
1907
1908 static void process_typedefs(pident_list_t *pidents)
1909 {
1910   pident_t *pident, *next;
1911
1912   if (!pidents) return;
1913   LIST_FOR_EACH_ENTRY_SAFE( pident, next, pidents, pident_t, entry )
1914   {
1915     var_t *var = pident->var;
1916     type_t *type = find_type(var->name, 0);
1917
1918     if (! parse_only && do_header)
1919       write_typedef(type);
1920     if (in_typelib && type->attrs)
1921       add_typelib_entry(type);
1922
1923     free(pident);
1924     free(var);
1925   }
1926 }
1927
1928 static void check_arg(var_t *arg)
1929 {
1930   type_t *t = arg->type;
1931
1932   if (t->type == 0 && ! is_var_ptr(arg))
1933     yyerror("argument '%s' has void type", arg->name);
1934 }