git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  26 if test "x$enable_win16" = "xno"
  27 then
  28   WIN16_FILES=""
  29   WIN16_INSTALL=""
  30 fi
  31
  32 AC_SUBST(DLLDEFS,"")
  33 if test "x$enable_debug" = "xno"
  34 then
  35   DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
  36 fi
  37 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  38 then
  39   DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
  40 fi
  41
  42 dnl **** Check for some programs ****
  43
  44 AC_CANONICAL_HOST
  45 case $host in
  46   x86_64*linux*)
  47     if test "x$enable_win64" != "xyes"
  48     then
  49       test -n "$CC" || CC="gcc -m32"
  50       test -n "$LD" || LD="ld -m elf_i386"
  51       test -n "$AS" || AS="as --32"
  52       host_cpu="i386"
  53     fi
  54     ;;
  55 esac
  56
  57 AC_PROG_MAKE_SET
  58 AC_PROG_CC
  59 AC_PROG_CXX
  60 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  61 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  62
  63 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  64   [if test -z "$with_wine_tools"; then
  65      if test "$cross_compiling" = "yes"; then
  66        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  67      else
  68        wine_cv_toolsdir="\$(TOPOBJDIR)"
  69      fi
  70    elif test -d "$with_wine_tools/tools/winebuild"; then
  71      case $with_wine_tools in
  72        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  73        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  74      esac
  75    else
  76      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  77    fi])
  78 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  79
  80 AC_PATH_XTRA
  81 AC_PROG_LEX
  82
  83 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  84 dnl **** without one present.
  85 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  86 if test "$XLEX" = "none"
  87 then
  88   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  89 fi
  90
  91 dnl Check for bison
  92 AC_CHECK_PROGS(BISON,bison,none)
  93 if test "$BISON" = "none"
  94 then
  95   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  96 fi
  97
  98 AC_CHECK_TOOLS(AS,[gas as],as)
  99 AC_CHECK_TOOL(LD,ld,ld)
 100 AC_CHECK_TOOL(AR,ar,ar)
 101 AC_PROG_RANLIB
 102 AC_CHECK_TOOL(STRIP,strip,strip)
 103 AC_CHECK_TOOL(WINDRES,windres,false)
 104 AC_PROG_LN_S
 105 WINE_PROG_LN
 106 AC_PROG_EGREP
 107 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 108 AC_PROG_INSTALL
 109 dnl Prepend src dir to install path dir if it's a relative path
 110 case "$INSTALL" in
 111   [[\\/$]]* | ?:[[\\/]]* ) ;;
 112   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 113 esac
 114
 115 dnl Check for lint
 116 AC_CHECK_PROGS(LINT, lclint lint)
 117 if test "$LINT" = "lint"
 118 then
 119   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 120   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 121 fi
 122 AC_SUBST(LINT)
 123 AC_SUBST(LINTFLAGS)
 124
 125 dnl Check for various programs
 126 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 127
 128 dnl **** Check for some libraries ****
 129
 130 dnl Check for -li386 for NetBSD and OpenBSD
 131 AC_CHECK_LIB(i386,i386_set_ldt)
 132 dnl Check for -lossaudio for NetBSD
 133 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 134 dnl Check for -lw for Solaris
 135 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 136 dnl Check for -lnsl for Solaris
 137 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 138 dnl Check for -lsocket for Solaris
 139 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 140 dnl Check for -lresolv for Solaris
 141 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 142 dnl Check for -lxpg4 for FreeBSD
 143 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 144 dnl Check for -lpoll for Mac OS X/Darwin
 145 AC_CHECK_LIB(poll,poll)
 146 dnl Check for -lresolv for Mac OS X/Darwin
 147 AC_CHECK_LIB(resolv,res_9_init)
 148 dnl Check for -lpthread
 149 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 150
 151 AC_SUBST(XLIB)
 152 AC_SUBST(XFILES)
 153 XFILES=""
 154 AC_SUBST(OPENGLFILES)
 155 OPENGLFILES=""
 156 AC_SUBST(GLU32FILES)
 157 GLU32FILES=""
 158 AC_SUBST(OPENGL_LIBS)
 159 OPENGL_LIBS=""
 160
 161 dnl **** Check for header files ****
 162
 163 AC_CHECK_HEADERS(\
 164         arpa/inet.h \
 165         arpa/nameser.h \
 166         asm/types.h \
 167         cups/cups.h \
 168         direct.h \
 169         elf.h \
 170         float.h \
 171         fontconfig/fontconfig.h \
 172         getopt.h \
 173         gif_lib.h \
 174         ieeefp.h \
 175         io.h \
 176         jack/jack.h \
 177         jpeglib.h \
 178         lcms/lcms.h \
 179         lcms.h \
 180         link.h \
 181         linux/cdrom.h \
 182         linux/compiler.h \
 183         linux/hdreg.h \
 184         linux/input.h \
 185         linux/ioctl.h \
 186         linux/joystick.h \
 187         linux/major.h \
 188         linux/param.h \
 189         linux/serial.h \
 190         linux/ucdrom.h \
 191         machine/cpu.h \
 192         mntent.h \
 193         netdb.h \
 194         netinet/in.h \
 195         netinet/in_systm.h \
 196         netinet/tcp.h \
 197         netinet/tcp_fsm.h \
 198         openssl/ssl.h \
 199         poll.h \
 200         process.h \
 201         pthread.h \
 202         pwd.h \
 203         regex.h \
 204         sched.h \
 205         scsi/sg.h \
 206         scsi/scsi.h \
 207         scsi/scsi_ioctl.h \
 208         stdint.h \
 209         strings.h \
 210         sys/cdio.h \
 211         sys/elf32.h \
 212         sys/errno.h \
 213         sys/epoll.h \
 214         sys/exec_elf.h \
 215         sys/filio.h \
 216         sys/ioctl.h \
 217         sys/ipc.h \
 218         sys/link.h \
 219         sys/lwp.h \
 220         sys/mman.h \
 221         sys/modem.h \
 222         sys/msg.h \
 223         sys/param.h \
 224         sys/poll.h \
 225         sys/ptrace.h \
 226         sys/reg.h \
 227         sys/scsiio.h \
 228         sys/shm.h \
 229         sys/signal.h \
 230         sys/socket.h \
 231         sys/sockio.h \
 232         sys/statfs.h \
 233         sys/statvfs.h \
 234         sys/strtio.h \
 235         sys/syscall.h \
 236         sys/sysctl.h \
 237         sys/time.h \
 238         sys/times.h \
 239         sys/uio.h \
 240         sys/un.h \
 241         sys/vfs.h \
 242         sys/vm86.h \
 243         sys/wait.h \
 244         syscall.h \
 245         termios.h \
 246         unistd.h \
 247         utime.h \
 248         valgrind/memcheck.h
 249 )
 250 AC_HEADER_STAT()
 251
 252 dnl **** Check for X11 ****
 253
 254 if test "$have_x" = "yes"
 255 then
 256     XLIB="-lXext -lX11"
 257     ac_save_CPPFLAGS="$CPPFLAGS"
 258     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 259
 260     dnl *** All of the following tests require X11/Xlib.h
 261     AC_CHECK_HEADERS(X11/Xlib.h,
 262       [
 263         AC_CHECK_HEADERS([X11/XKBlib.h \
 264                           X11/Xutil.h \
 265                           X11/extensions/shape.h \
 266                           X11/extensions/XInput.h \
 267                           X11/extensions/XShm.h \
 268                           X11/extensions/Xrandr.h \
 269                           X11/extensions/Xrender.h \
 270                           X11/extensions/xf86dga.h \
 271                           X11/extensions/xf86vmode.h],,,
 272                          [#include <X11/Xlib.h>
 273                           #ifdef HAVE_X11_XUTIL_H
 274                           # include <X11/Xutil.h>
 275                           #endif])
 276
 277         dnl *** Check for X keyboard extension
 278         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 279         then
 280               AC_CHECK_LIB(X11, XkbQueryExtension,
 281               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 282               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 283         fi
 284
 285         dnl *** Check for X Shm extension
 286         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 287         then
 288               AC_CHECK_LIB(Xext, XShmQueryExtension,
 289               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 290               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 291         fi
 292
 293         dnl *** Check for X shape extension
 294         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 295         then
 296               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 297               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 298               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 299         fi
 300
 301         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 302         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 303         then
 304               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 305                 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 306                             [Define if you have the Xxf86dga library version 2])
 307                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 308                 ],,
 309                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 310         fi
 311
 312         dnl *** Check for XFree86 VMODE extension
 313         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 314         then
 315                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 316                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 317                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 318                   ],,
 319                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 320         fi
 321
 322         dnl *** Check for X RandR extension
 323         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 324         then
 325                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 326 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 327                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 328         fi
 329
 330         dnl *** Check for Transform functions in Xrender
 331         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 332         then
 333               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 334                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 335                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 336                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 337         fi
 338       ]
 339     ) dnl *** End of X11/Xlib.h check
 340
 341     dnl Check for the presence of OpenGL
 342     if test "x$with_opengl" != "xno"
 343     then
 344         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 345         then
 346             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 347 This prevents linking to OpenGL. Delete the file and restart configure.])
 348         fi
 349
 350         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 351         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 352         then
 353             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 354             dnl Check for some problems due to old Mesa versions
 355             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 356               AC_TRY_COMPILE(
 357                 [#include <GL/gl.h>],
 358                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 359                 [wine_cv_opengl_version_OK="yes"],
 360                 [wine_cv_opengl_version_OK="no"]
 361               )
 362             )
 363
 364             if test "$wine_cv_opengl_version_OK" = "yes"
 365             then
 366                 dnl Check for the presence of the library
 367                 AC_CHECK_LIB(GL,glXCreateContext,
 368                              OPENGL_LIBS="-lGL"
 369                              ,,
 370                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 371
 372                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 373                 then
 374                         OPENGLFILES='$(OPENGLFILES)'
 375                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 376                 fi
 377                 dnl Check for GLU32 library.
 378                 AC_CHECK_LIB(GLU,gluLookAt,
 379                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 380                              GLU32FILES='$(GLU32FILES)']
 381                              ,,
 382                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 383                 )
 384              fi
 385
 386              dnl Check for glut32 library.
 387              AC_CHECK_LIB(glut,glutMainLoop,
 388                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 389                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 390                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 391          fi
 392     fi
 393
 394     dnl **** Check for NAS ****
 395     AC_SUBST(NASLIBS,"")
 396     AC_CHECK_HEADERS(audio/audiolib.h,
 397          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 398           AC_CHECK_LIB(audio,AuCreateFlow,
 399                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 400                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 401                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 402
 403     CPPFLAGS="$ac_save_CPPFLAGS"
 404     XFILES='$(XFILES)'
 405 else
 406     XLIB=""
 407     X_CFLAGS=""
 408     X_LIBS=""
 409 fi
 410
 411 dnl **** Check which curses lib to use ***
 412 CURSESLIBS=""
 413 if test "x$with_curses" != "xno"
 414 then
 415     AC_CHECK_HEADERS(ncurses.h,
 416         [AC_CHECK_LIB(ncurses,waddch,
 417             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 418              CURSESLIBS="-lncurses"],
 419              [AC_CHECK_HEADERS(curses.h,
 420                  [AC_CHECK_LIB(curses,waddch,
 421                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 422                       CURSESLIBS="-lcurses"])])])])
 423 fi
 424 AC_SUBST(CURSESLIBS)
 425
 426 dnl **** Check for SANE ****
 427 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 428 if test "$sane_devel" = "no"
 429 then
 430     SANELIBS=""
 431     SANEINCL=""
 432 else
 433     SANELIBS="`$sane_devel --libs`"
 434     SANEINCL="`$sane_devel --cflags`"
 435     ac_save_CPPFLAGS="$CPPFLAGS"
 436     ac_save_LIBS="$LIBS"
 437     CPPFLAGS="$CPPFLAGS $SANEINCL"
 438     LIBS="$LIBS $SANELIBS"
 439     AC_CHECK_HEADER(sane/sane.h,
 440                     [AC_CHECK_LIB(sane,sane_open,
 441                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 442                                   [SANELIBS=""
 443                                   SANEINCL=""])],
 444                     [SANELIBS=""
 445                     SANEINCL=""])
 446     LIBS="$ac_save_LIBS"
 447     CPPFLAGS="$ac_save_CPPFLAGS"
 448 fi
 449 AC_SUBST(SANELIBS)
 450 AC_SUBST(SANEINCL)
 451
 452 dnl **** Check for the ICU library ****
 453 AC_CHECK_HEADERS(unicode/ubidi.h)
 454 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 455 then
 456     saved_libs="$LIBS"
 457     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 458     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 459     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 460     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 461     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 462     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 463                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 464                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 465                  AC_MSG_RESULT(yes)],
 466                 [AC_MSG_RESULT(no)])
 467     LIBS="$saved_libs"
 468 fi
 469
 470 dnl **** Check for FreeType 2 ****
 471 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 472 if test "$ft_lib" = "no"
 473 then
 474     FREETYPELIBS=""
 475     FREETYPEINCL=""
 476     wine_cv_msg_freetype=no
 477 else
 478     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 479     if test "$ft_devel" = "no"
 480     then
 481         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 482         if test "$ft_devel2" = "freetype2-config"
 483         then
 484                 ft_devel=$ft_devel2
 485         fi
 486     fi
 487     if test "$ft_devel" = "no"
 488     then
 489         FREETYPELIBS=""
 490         FREETYPEINCL=""
 491         wine_cv_msg_freetype=yes
 492     else
 493         FREETYPELIBS=`$ft_devel --libs`
 494         FREETYPEINCL=`$ft_devel --cflags`
 495         ac_save_CPPFLAGS="$CPPFLAGS"
 496         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 497         AC_CHECK_HEADERS(ft2build.h \
 498                          freetype/freetype.h \
 499                          freetype/ftglyph.h \
 500                          freetype/tttables.h \
 501                          freetype/ftnames.h \
 502                          freetype/ftsnames.h \
 503                          freetype/ttnameid.h \
 504                          freetype/ftoutln.h \
 505                          freetype/ftwinfnt.h \
 506                          freetype/internal/sfnt.h,,,
 507                          [#if HAVE_FT2BUILD_H
 508                           #include <ft2build.h>
 509                           #endif])
 510         AC_TRY_CPP([#include <ft2build.h>
 511                     #include <freetype/fttrigon.h>],
 512                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 513           [Define if you have the <freetype/fttrigon.h> header file.])
 514                     wine_cv_fttrigon=yes],
 515                     wine_cv_fttrigon=no)
 516         CPPFLAGS="$ac_save_CPPFLAGS"
 517         dnl Check that we have at least freetype/freetype.h
 518         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 519         then
 520             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 521             wine_cv_msg_freetype=no
 522         else
 523             FREETYPELIBS=""
 524             FREETYPEINCL=""
 525             wine_cv_msg_freetype=yes
 526         fi
 527     fi
 528 fi
 529 AC_SUBST(FREETYPELIBS)
 530 AC_SUBST(FREETYPEINCL)
 531
 532 dnl Only build the fonts dir if we have both freetype and fontforge
 533 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 534 then
 535   AC_SUBST(FONTSSUBDIRS,"fonts")
 536 fi
 537
 538 dnl **** Check for parport (currently Linux only) ****
 539 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 540  AC_TRY_COMPILE(
 541    [#include <linux/ppdev.h>],
 542    [ioctl (1,PPCLAIM,0)],
 543    [ac_cv_c_ppdev="yes"],
 544    [ac_cv_c_ppdev="no"])
 545  )
 546 if test "$ac_cv_c_ppdev" = "yes"
 547 then
 548     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 549 fi
 550
 551 dnl **** Check for va_copy ****
 552 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 553  AC_TRY_LINK(
 554    [#include <stdarg.h>],
 555    [va_list ap1, ap2;
 556     va_copy(ap1,ap2);
 557    ],
 558    [ac_cv_c_va_copy="yes"],
 559    [ac_cv_c_va_copy="no"])
 560  )
 561 if test "$ac_cv_c_va_copy" = "yes"
 562 then
 563     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 564 fi
 565 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 566  AC_TRY_LINK(
 567    [#include <stdarg.h>],
 568    [va_list ap1, ap2;
 569     __va_copy(ap1,ap2);
 570    ],
 571    [ac_cv_c___va_copy="yes"],
 572    [ac_cv_c___va_copy="no"])
 573  )
 574 if test "$ac_cv_c___va_copy" = "yes"
 575 then
 576     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 577 fi
 578
 579 dnl **** Check for sigsetjmp ****
 580 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 581  AC_TRY_LINK(
 582    [#include <setjmp.h>],
 583    [sigjmp_buf buf;
 584     sigsetjmp( buf, 1 );
 585     siglongjmp( buf, 1 );],
 586    [ac_cv_c_sigsetjmp="yes"],
 587    [ac_cv_c_sigsetjmp="no"])
 588  )
 589 if test "$ac_cv_c_sigsetjmp" = "yes"
 590 then
 591     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 592 fi
 593
 594 dnl **** Check for pthread_rwlock_t ****
 595 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 596 #include <pthread.h>])
 597
 598 dnl **** Check for pthread functions ****
 599 ac_save_LIBS="$LIBS"
 600 LIBS="$LIBS $LIBPTHREAD"
 601 AC_CHECK_FUNCS(\
 602         pthread_getattr_np \
 603         pthread_get_stackaddr_np \
 604         pthread_get_stacksize_np \
 605 )
 606 LIBS="$ac_save_LIBS"
 607
 608 dnl **** Check for Open Sound System ****
 609 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 610
 611 AC_CACHE_CHECK([for Open Sound System],
 612         ac_cv_c_opensoundsystem,
 613         AC_TRY_COMPILE([
 614         #if defined(HAVE_SYS_SOUNDCARD_H)
 615                 #include <sys/soundcard.h>
 616         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 617                 #include <machine/soundcard.h>
 618         #elif defined(HAVE_SOUNDCARD_H)
 619                 #include <soundcard.h>
 620         #endif
 621         ],[
 622
 623 /* check for one of the Open Sound System specific SNDCTL_ defines */
 624 #if !defined(SNDCTL_DSP_STEREO)
 625 #error No open sound system
 626 #endif
 627 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 628
 629 if test "$ac_cv_c_opensoundsystem" = "yes"
 630 then
 631     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 632 fi
 633
 634 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 635         ac_cv_c_opensoundsystem_midi,
 636         AC_TRY_COMPILE([
 637         #if defined(HAVE_SYS_SOUNDCARD_H)
 638                 #include <sys/soundcard.h>
 639         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 640                 #include <machine/soundcard.h>
 641         #elif defined(HAVE_SOUNDCARD_H)
 642                 #include <soundcard.h>
 643         #endif
 644         ],[
 645
 646 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 647 #if !defined(SNDCTL_SEQ_SYNC)
 648 #error No open sound system MIDI interface
 649 #endif
 650 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 651
 652 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 653 then
 654     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 655 fi
 656
 657 dnl **** Check for aRts Sound Server ****
 658 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 659 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 660 then
 661     ARTSC_CFLAGS=""
 662     for i in `$ARTSCCONFIG --cflags`
 663     do
 664       case "$i" in
 665         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 666       esac
 667     done
 668     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 669     save_CFLAGS="$CFLAGS"
 670     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 671     AC_CHECK_LIB(artsc,arts_init,
 672         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 673             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 674             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 675             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],)
 676     CFLAGS="$save_CFLAGS"
 677 fi
 678
 679 dnl **** Check for ALSA 1.x ****
 680 AC_SUBST(ALSALIBS,"")
 681 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 682 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 683 then
 684     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 685         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 686 #include <alsa/asoundlib.h>
 687 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 688 #include <sys/asoundlib.h>
 689 #endif],
 690                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 691                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 692                          ALSALIBS="-lasound"])])
 693 fi
 694
 695 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 696
 697 AC_SUBST(AUDIOIOLIBS,"")
 698 AC_CHECK_HEADERS(libaudioio.h,
 699     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 700                   [AUDIOIOLIBS="-laudioio"
 701                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 702
 703 dnl **** Check for capi4linux ****
 704
 705 AC_CHECK_HEADERS(capi20.h,[
 706         AC_CHECK_HEADERS(linux/capi.h,[
 707                 AC_CHECK_LIB(capi20,capi20_register,[
 708                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 709                 ])
 710         ])
 711 ])
 712
 713 dnl **** Check for broken glibc mmap64 ****
 714
 715 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 716         AC_TRY_RUN([
 717                 #define _FILE_OFFSET_BITS 64
 718                 #include <stdio.h>
 719                 #include <unistd.h>
 720                 #include <fcntl.h>
 721                 #include <sys/mman.h>
 722                 #include <errno.h>
 723
 724                 int main(int argc,char **argv) {
 725                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 726                         if (fd == -1) exit(1);
 727
 728                         unlink("conftest.map");
 729
 730                         write(fd,"test",4);
 731
 732                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 733                             (errno == EINVAL)
 734                         ) {
 735                                 exit(1);
 736                         }
 737                         close(fd);
 738                         fprintf(stderr,"success!\n");
 739                         exit(0);
 740                 }
 741
 742         ],
 743     ac_cv_mmap64_works="yes",
 744     ac_cv_mmap64_works="no",
 745     ac_cv_mmap64_works="no") )
 746
 747 if test "$ac_cv_mmap64_works" = "yes"
 748 then
 749     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 750 fi
 751
 752 dnl **** Check for gcc specific options ****
 753
 754 AC_SUBST(EXTRACFLAGS,"")
 755 if test "x${GCC}" = "xyes"
 756 then
 757   EXTRACFLAGS="-Wall -pipe"
 758
 759   dnl Check for strength-reduce bug
 760   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 761                   AC_TRY_RUN([
 762 int     L[[4]] = {0,1,2,3};
 763 int main(void) {
 764   static int Array[[3]];
 765   unsigned int B = 3;
 766   int i;
 767   for(i=0; i<B; i++) Array[[i]] = i - 3;
 768   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 769   L[[i]] = 4;
 770
 771   exit( Array[[1]] != -2 || L[[2]] != 3);
 772 }],
 773     ac_cv_c_gcc_strength_bug="no",
 774     ac_cv_c_gcc_strength_bug="yes",
 775     ac_cv_c_gcc_strength_bug="yes") )
 776   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 777   then
 778     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 779   fi
 780
 781   dnl Check for -fshort-wchar
 782   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 783       [WINE_TRY_CFLAGS([-fshort-wchar],
 784                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 785   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 786   then
 787       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 788   fi
 789
 790   dnl Check for -mpreferred-stack-boundary
 791   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 792       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 793                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 794   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 795   then
 796     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 797   fi
 798
 799   dnl Check for -fno-strict-aliasing
 800   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 801       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 802                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 803   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 804   then
 805     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 806   fi
 807
 808   dnl Check for -gstabs+ option
 809   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 810       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 811   if test "$ac_cv_c_gcc_gstabs" = "yes"
 812   then
 813     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 814   fi
 815
 816   dnl Check for noisy string.h
 817   saved_CFLAGS="$CFLAGS"
 818   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 819   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 820       AC_TRY_COMPILE([#include <string.h>],[],
 821                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 822   CFLAGS="$saved_CFLAGS"
 823   if test "$ac_cv_c_string_h_warnings" = "no"
 824   then
 825     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 826   fi
 827 fi
 828
 829 dnl **** Check how to define a function in assembly code ****
 830
 831 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 832   WINE_TRY_ASM_LINK(
 833       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 834       ac_cv_asm_func_def=".def",
 835     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 836       ac_cv_asm_func_def=".type @function",
 837     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 838       ac_cv_asm_func_def=".type 2",
 839       ac_cv_asm_func_def="unknown")])]))
 840
 841 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 842 case "$ac_cv_asm_func_def" in
 843   ".def")
 844      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 845   ".type @function")
 846      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 847   ".type 2")
 848      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 849   *)
 850      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 851 esac
 852
 853 dnl **** Check for underscore on external symbols ****
 854
 855 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 856     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 857                       [extern int ac_test;],
 858                       [if (ac_test) return 1],
 859                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 860
 861 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 862 if test "$ac_cv_c_extern_prefix" = "yes"
 863 then
 864   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 865 else
 866   AC_DEFINE([__ASM_NAME(name)], [name])
 867 fi
 868
 869 dnl **** Check how to do strings in assembler ****
 870
 871 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 872     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 873       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 874         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 875           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 876
 877 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 878                    [Define to the assembler keyword used to specify an ASCII string])
 879
 880 dnl **** Check for .short in assembler ****
 881
 882 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 883     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 884       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 885         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 886
 887 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 888                    [Define to the assembler keyword used to specify a word value])
 889
 890 dnl **** Check for .size in assembler ****
 891
 892 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 893     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 894                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 895
 896 if test "$ac_cv_c_asm_size" = "yes"
 897 then
 898   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 899 fi
 900
 901 dnl **** Check for working dll ****
 902
 903 AC_SUBST(DLLEXT,"")
 904 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 905 AC_SUBST(DLLIBS,"")
 906 AC_SUBST(LDSHARED,"")
 907 AC_SUBST(LDDLLFLAGS,"")
 908 AC_SUBST(LIBEXT,"so")
 909 AC_SUBST(IMPLIBEXT,"def")
 910
 911 case $host_os in
 912   cygwin*|mingw32*)
 913     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 914     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 915     if test "$DLLWRAP" = "false"; then
 916       LIBEXT="a"
 917     else
 918       dnl FIXME - check whether dllwrap works correctly...
 919       LIBEXT="dll"
 920     fi
 921     IMPLIBEXT="a"
 922     dnl We can't build 16-bit NE dlls
 923     WIN16_FILES=""
 924     WIN16_INSTALL=""
 925     ;;
 926   *)
 927     AC_CHECK_HEADERS(dlfcn.h,
 928         [AC_CHECK_FUNCS(dlopen,,
 929             [AC_CHECK_LIB(dl,dlopen,
 930                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 931                           DLLIBS="-ldl"],
 932                          [LIBEXT="a"])])],
 933         [LIBEXT="a"])
 934
 935     if test "$LIBEXT" = "so"
 936     then
 937       DLLFLAGS="$DLLFLAGS -fPIC"
 938       DLLEXT=".so"
 939       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 940           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 941                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 942       if test "$ac_cv_c_dll_gnuelf" = "yes"
 943       then
 944         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 945         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 946         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 947           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 948                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 949         if test "$ac_cv_c_dll_zdefs" = "yes"
 950         then
 951           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 952         fi
 953
 954         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 955           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 956                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 957         if test "$ac_cv_c_dll_init_fini" = "yes"
 958         then
 959           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 960         fi
 961
 962         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 963           [echo '{ global: *; };' >conftest.map
 964            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 965                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 966            rm -f conftest.map])
 967         if test "$ac_cv_c_ld_version_scripts" = "yes"
 968         then
 969           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 970         fi
 971
 972         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 973           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 974                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 975         if test "$ac_cv_c_export_dynamic" = "yes"
 976         then
 977           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 978         fi
 979
 980         case $host_cpu in
 981           *i[[3456789]]86*)
 982             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 983               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 984                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 985             if test "$ac_cv_ld_reloc_exec" = "yes"
 986             then
 987               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 988             fi
 989             ;;
 990         esac
 991
 992       else
 993         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 994             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 995                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 996         if test "$ac_cv_c_dll_unixware" = "yes"
 997         then
 998           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 999           LDDLLFLAGS="-Wl,-G,-B,symbolic"
1000
1001         else
1002           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1003             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1004           if test "$ac_cv_c_dll_macho" = "yes"
1005           then
1006             LIBEXT="dylib"
1007             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
1008             LDSHARED="\$(CC) -dynamiclib"
1009             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1010             STRIP="$STRIP -u -r"
1011             dnl Relocate wine executable
1012             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1013             dnl Relocate libwine.dyld too
1014             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1015             dnl declare needed frameworks
1016             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1017             AC_SUBST(IOKITLIB,"-framework IOKit")
1018             dnl using IOKit imply we use CoreFoundation too
1019             IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1020           else
1021             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1022               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1023             if test "$ac_cv_c_dll_hpux" = "yes"
1024             then
1025               LIBEXT="sl"
1026               DLLEXT=".sl"
1027               LDDLLFLAGS="-shared -fPIC"
1028               LDSHARED="\$(CC) -shared"
1029             fi
1030           fi
1031         fi
1032       fi
1033     fi
1034
1035     dnl Check for cross compiler to build test programs
1036     AC_SUBST(CROSSTEST,"")
1037     if test "$cross_compiling" = "no"
1038     then
1039       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1040       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1041       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1042       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1043     fi
1044     ;;
1045 esac
1046
1047 if test "$LIBEXT" = "a"; then
1048   AC_MSG_ERROR(
1049 [could not find a way to build shared libraries.
1050 It is currently not possible to build Wine without shared library
1051 (.so) support to allow transparent switch between .so and .dll files.
1052 If you are using Linux, you will need a newer binutils.]
1053 )
1054 fi
1055
1056 case $build_os in
1057   cygwin*|mingw32*)
1058     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1059   darwin*|macosx*)
1060     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1061   *)
1062     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1063 esac
1064
1065 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1066 case $host_os in
1067   mingw32*)
1068     AC_SUBST(CRTLIBS,"-lmsvcrt")
1069     AC_SUBST(SOCKETLIBS,"-lws2_32")
1070     ;;
1071 esac
1072
1073 case $host_os in
1074   linux*)
1075     case $host_cpu in
1076       *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1077       *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1078     esac
1079     AC_SUBST(MAIN_BINARY,"wine-glibc")
1080     ;;
1081   darwin*)
1082     AC_SUBST(WINE_BINARIES,"wine-pthread")
1083     AC_SUBST(MAIN_BINARY,"wine-pthread")
1084     ;;
1085   *)
1086     AC_SUBST(WINE_BINARIES,"wine-kthread")
1087     AC_SUBST(MAIN_BINARY,"wine-kthread")
1088     ;;
1089 esac
1090
1091 dnl **** Get the soname for libraries that we load dynamically ****
1092
1093 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1094 then
1095   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1096   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1097   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1098   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1099   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1100   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1101   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1102   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1103   WINE_GET_SONAME(cups,cupsGetDefault)
1104   WINE_GET_SONAME(jack,jack_client_new)
1105   WINE_GET_SONAME(fontconfig,FcInit)
1106   WINE_GET_SONAME(ssl,SSL_library_init)
1107   WINE_GET_SONAME(crypto,BIO_new_socket)
1108   WINE_GET_SONAME(ncurses,waddch)
1109   WINE_GET_SONAME(curses,waddch)
1110   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1111   WINE_GET_SONAME(ungif,DGifOpen)
1112   WINE_GET_SONAME(gif,DGifOpen)
1113   WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1114   WINE_GET_SONAME(capi20,capi20_isinstalled)
1115 fi
1116
1117
1118 dnl **** Check for functions ****
1119
1120 AC_FUNC_ALLOCA()
1121 AC_CHECK_FUNCS(\
1122         _lwp_create \
1123         _lwp_self \
1124         _pclose \
1125         _popen \
1126         _snprintf \
1127         _spawnvp \
1128         _stricmp \
1129         _strnicmp \
1130         _vsnprintf \
1131         chsize \
1132         clone \
1133         epoll_create \
1134         ffs \
1135         finite \
1136         fork \
1137         fpclass \
1138         fstatfs \
1139         fstatvfs \
1140         ftruncate \
1141         futimes \
1142         futimesat \
1143         getnetbyname \
1144         getopt_long \
1145         getpagesize \
1146         getprotobyname \
1147         getprotobynumber \
1148         getpwuid \
1149         getservbyport \
1150         gettid \
1151         gettimeofday \
1152         getuid \
1153         inet_network \
1154         lstat \
1155         memmove \
1156         mmap \
1157         pclose \
1158         popen \
1159         pread \
1160         pwrite \
1161         readlink \
1162         rfork \
1163         sched_yield \
1164         select \
1165         sendmsg \
1166         settimeofday \
1167         sigaltstack \
1168         sigprocmask \
1169         snprintf \
1170         spawnvp \
1171         statfs \
1172         statvfs \
1173         strcasecmp \
1174         strerror \
1175         strncasecmp \
1176         tcgetattr \
1177         timegm \
1178         usleep \
1179         vsnprintf \
1180         wait4 \
1181         waitpid \
1182 )
1183
1184 dnl **** Checks for headers that depend on other ones ****
1185
1186 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1187     [#include <sys/types.h>
1188      #if HAVE_SYS_PARAM_H
1189      # include <sys/param.h>
1190      #endif])
1191
1192 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1193     [#include <sys/types.h>
1194      #if HAVE_SYS_SOCKET_H
1195      # include <sys/socket.h>
1196      #endif])
1197
1198 AC_CHECK_HEADERS([resolv.h],,,
1199     [#include <sys/types.h>
1200      #if HAVE_SYS_SOCKET_H
1201      # include <sys/socket.h>
1202      #endif
1203      #if HAVE_NETINET_IN_H
1204      # include <netinet/in.h>
1205      #endif
1206      #if HAVE_ARPA_NAMESER_H
1207      # include <arpa/nameser.h>
1208      #endif])
1209
1210 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1211
1212 dnl **** Check for v4l(2) headers ****
1213
1214 AC_CHECK_HEADERS(linux/videodev.h,,,
1215 [#ifdef HAVE_SYS_TIME_H
1216 #include <sys/time.h>
1217 #endif
1218 #ifdef HAVE_ASM_TYPES_H
1219 #include <asm/types.h>
1220 #endif])
1221
1222 dnl **** Check for IPX headers (currently Linux only) ****
1223
1224 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1225  AC_TRY_COMPILE(
1226    [#include <sys/types.h>
1227     #ifdef HAVE_SYS_SOCKET_H
1228     # include <sys/socket.h>
1229     #endif
1230     #include <netipx/ipx.h>],
1231    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1232    [ac_cv_c_ipx_gnu="yes"],
1233    [ac_cv_c_ipx_gnu="no"])
1234  )
1235 if test "$ac_cv_c_ipx_gnu" = "yes"
1236 then
1237     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1238 fi
1239
1240 if test "$ac_cv_c_ipx_gnu" = "no"
1241 then
1242  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1243   AC_TRY_COMPILE(
1244     [#include <sys/types.h>
1245      #ifdef HAVE_SYS_SOCKET_H
1246      # include <sys/socket.h>
1247      #endif
1248      #include <asm/types.h>
1249      #include <linux/ipx.h>],
1250     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1251     [ac_cv_c_ipx_linux="yes"],
1252     [ac_cv_c_ipx_linux="no"])
1253   )
1254   if test "$ac_cv_c_ipx_linux" = "yes"
1255   then
1256       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1257   fi
1258 fi
1259
1260 dnl **** Check for types ****
1261
1262 AC_C_CONST
1263 AC_C_INLINE
1264 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1265 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1266
1267 AC_CACHE_CHECK([whether linux/input.h is for real],
1268         wine_cv_linux_input_h,
1269         AC_TRY_COMPILE([
1270             #include <linux/input.h>
1271         ] , [
1272             int foo = EVIOCGBIT(EV_ABS,42);
1273             int bar = BTN_PINKIE;
1274             int fortytwo = 42;
1275         ],
1276         wine_cv_linux_input_h=yes,
1277         wine_cv_linux_input_h=no,
1278         no
1279         )
1280     )
1281     if test "$wine_cv_linux_input_h" = "yes"
1282     then
1283         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1284                   [Define if we have linux/input.h AND it contains the INPUT event API])
1285     fi
1286
1287 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1288                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1289                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1290 if test "$wine_cv_have_sigaddset" = "yes"
1291 then
1292   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1293 fi
1294
1295
1296 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1297         wine_cv_linux_gethostbyname_r_6,
1298         AC_TRY_LINK([
1299 #include <netdb.h>
1300         ], [
1301     char *name=NULL;
1302     struct hostent he;
1303     struct hostent *result;
1304     char *buf=NULL;
1305     int bufsize=0;
1306     int res,errnr;
1307     char *addr=NULL;
1308     int addrlen=0;
1309     int addrtype=0;
1310     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1311     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1312     ],
1313         wine_cv_linux_gethostbyname_r_6=yes,
1314         wine_cv_linux_gethostbyname_r_6=no
1315         )
1316    )
1317    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1318    then
1319       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1320                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1321    fi
1322
1323 if test "$ac_cv_header_linux_joystick_h" = "yes"
1324 then
1325    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1326         wine_cv_linux_joystick_22_api,
1327         AC_TRY_COMPILE([
1328         #include <sys/ioctl.h>
1329         #include <linux/joystick.h>
1330
1331         struct js_event blub;
1332         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1333         #error "no 2.2 header"
1334         #endif
1335         ],/*empty*/,
1336         wine_cv_linux_joystick_22_api=yes,
1337         wine_cv_linux_joystick_22_api=no,
1338         wine_cv_linux_joystick_22_api=no
1339         )
1340    )
1341    if test "$wine_cv_linux_joystick_22_api" = "yes"
1342    then
1343       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1344                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1345    fi
1346 fi
1347
1348 dnl **** statfs checks ****
1349
1350 if test "$ac_cv_header_sys_vfs_h" = "yes"
1351 then
1352     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1353                     wine_cv_sys_vfs_has_statfs,
1354         AC_TRY_COMPILE([
1355         #include <sys/types.h>
1356         #ifdef HAVE_SYS_PARAM_H
1357         # include <sys/param.h>
1358         #endif
1359         #include <sys/vfs.h>
1360         ],[
1361                 struct statfs stfs;
1362
1363                 memset(&stfs,0,sizeof(stfs));
1364         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1365         )
1366     )
1367     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1368     then
1369       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1370                 [Define if the struct statfs is defined by <sys/vfs.h>])
1371     fi
1372 fi
1373
1374 if test "$ac_cv_header_sys_statfs_h" = "yes"
1375 then
1376     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1377                     wine_cv_sys_statfs_has_statfs,
1378         AC_TRY_COMPILE([
1379         #include <sys/types.h>
1380         #ifdef HAVE_SYS_PARAM_H
1381         # include <sys/param.h>
1382         #endif
1383         #include <sys/statfs.h>
1384         ],[
1385                 struct statfs stfs;
1386         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1387         )
1388     )
1389     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1390     then
1391       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1392                 [Define if the struct statfs is defined by <sys/statfs.h>])
1393     fi
1394 fi
1395
1396 if test "$ac_cv_header_sys_mount_h" = "yes"
1397 then
1398     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1399                     wine_cv_sys_mount_has_statfs,
1400         AC_TRY_COMPILE([
1401         #include <sys/types.h>
1402         #ifdef HAVE_SYS_PARAM_H
1403         # include <sys/param.h>
1404         #endif
1405         #include <sys/mount.h>
1406         ],[
1407                 struct statfs stfs;
1408         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1409         )
1410     )
1411     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1412     then
1413       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1414                 [Define if the struct statfs is defined by <sys/mount.h>])
1415     fi
1416 fi
1417
1418 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1419
1420 dnl Check for statfs members
1421 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1422 [#include <sys/types.h>
1423 #ifdef HAVE_SYS_PARAM_H
1424 # include <sys/param.h>
1425 #endif
1426 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1427 # include <sys/mount.h>
1428 #else
1429 # ifdef STATFS_DEFINED_BY_SYS_VFS
1430 #  include <sys/vfs.h>
1431 # else
1432 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1433 #   include <sys/statfs.h>
1434 #  endif
1435 # endif
1436 #endif])
1437
1438 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1439 [#ifdef HAVE_SYS_STATVFS_H
1440 #include <sys/statvfs.h>
1441 #endif])
1442
1443 dnl Check for socket structure members
1444 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1445 [#include <sys/types.h>
1446 #ifdef HAVE_SYS_SOCKET_H
1447 # include <sys/socket.h>
1448 #endif
1449 #ifdef HAVE_SYS_UN_H
1450 # include <sys/un.h>
1451 #endif])
1452
1453 dnl Check for siginfo_t members
1454 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1455
1456 dnl Check for struct option
1457 AC_CHECK_MEMBERS([struct option.name],,,
1458 [#ifdef HAVE_GETOPT_H
1459 #include <getopt.h>
1460 #endif])
1461
1462 dnl Check for stat.st_blocks
1463 AC_CHECK_MEMBERS([struct stat.st_blocks])
1464
1465 dnl *** check for the need to define platform-specific symbols
1466
1467 case $host_cpu in
1468   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1469   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1470   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1471   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1472 esac
1473
1474 case $host_vendor in
1475   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1476 esac
1477
1478 dnl **** Generate output files ****
1479
1480 AH_TOP([#define __WINE_CONFIG_H])
1481
1482 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1483 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1484 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1485 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1486 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1487 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1488 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1489 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1490 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1491 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1492 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1493 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1494 WINE_CONFIG_EXTRA_DIR(include/wine)
1495 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1496 WINE_CONFIG_EXTRA_DIR(windows)
1497
1498 MAKE_RULES=Make.rules
1499 AC_SUBST_FILE(MAKE_RULES)
1500
1501 MAKE_DLL_RULES=dlls/Makedll.rules
1502 AC_SUBST_FILE(MAKE_DLL_RULES)
1503
1504 MAKE_TEST_RULES=dlls/Maketest.rules
1505 AC_SUBST_FILE(MAKE_TEST_RULES)
1506
1507 MAKE_LIB_RULES=libs/Makelib.rules
1508 AC_SUBST_FILE(MAKE_LIB_RULES)
1509
1510 MAKE_PROG_RULES=programs/Makeprog.rules
1511 AC_SUBST_FILE(MAKE_PROG_RULES)
1512
1513 AC_CONFIG_FILES([
1514 Make.rules
1515 dlls/Makedll.rules
1516 dlls/Maketest.rules
1517 libs/Makelib.rules
1518 programs/Makeprog.rules
1519 Makefile
1520 dlls/Makefile
1521 dlls/advapi32/Makefile
1522 dlls/advapi32/tests/Makefile
1523 dlls/advpack/Makefile
1524 dlls/advpack/tests/Makefile
1525 dlls/amstream/Makefile
1526 dlls/atl/Makefile
1527 dlls/avicap32/Makefile
1528 dlls/avifil32/Makefile
1529 dlls/cabinet/Makefile
1530 dlls/capi2032/Makefile
1531 dlls/cards/Makefile
1532 dlls/cfgmgr32/Makefile
1533 dlls/comcat/Makefile
1534 dlls/comctl32/Makefile
1535 dlls/comctl32/tests/Makefile
1536 dlls/commdlg/Makefile
1537 dlls/crtdll/Makefile
1538 dlls/crypt32/Makefile
1539 dlls/cryptdll/Makefile
1540 dlls/ctl3d/Makefile
1541 dlls/d3d8/Makefile
1542 dlls/d3d9/Makefile
1543 dlls/d3dim/Makefile
1544 dlls/d3drm/Makefile
1545 dlls/d3dx8/Makefile
1546 dlls/d3dxof/Makefile
1547 dlls/dbghelp/Makefile
1548 dlls/dciman32/Makefile
1549 dlls/ddraw/Makefile
1550 dlls/ddraw/tests/Makefile
1551 dlls/devenum/Makefile
1552 dlls/dinput/Makefile
1553 dlls/dinput/tests/Makefile
1554 dlls/dinput8/Makefile
1555 dlls/dmband/Makefile
1556 dlls/dmcompos/Makefile
1557 dlls/dmime/Makefile
1558 dlls/dmloader/Makefile
1559 dlls/dmscript/Makefile
1560 dlls/dmstyle/Makefile
1561 dlls/dmsynth/Makefile
1562 dlls/dmusic/Makefile
1563 dlls/dmusic32/Makefile
1564 dlls/dplay/Makefile
1565 dlls/dplayx/Makefile
1566 dlls/dpnet/Makefile
1567 dlls/dpnhpast/Makefile
1568 dlls/dsound/Makefile
1569 dlls/dsound/tests/Makefile
1570 dlls/dswave/Makefile
1571 dlls/dxdiagn/Makefile
1572 dlls/dxerr8/Makefile
1573 dlls/dxerr9/Makefile
1574 dlls/dxguid/Makefile
1575 dlls/gdi/Makefile
1576 dlls/gdi/tests/Makefile
1577 dlls/glu32/Makefile
1578 dlls/glut32/Makefile
1579 dlls/hhctrl.ocx/Makefile
1580 dlls/iccvid/Makefile
1581 dlls/icmp/Makefile
1582 dlls/ifsmgr.vxd/Makefile
1583 dlls/imagehlp/Makefile
1584 dlls/imm32/Makefile
1585 dlls/iphlpapi/Makefile
1586 dlls/iphlpapi/tests/Makefile
1587 dlls/itss/Makefile
1588 dlls/kernel/Makefile
1589 dlls/kernel/tests/Makefile
1590 dlls/lzexpand/Makefile
1591 dlls/lzexpand/tests/Makefile
1592 dlls/mapi32/Makefile
1593 dlls/mapi32/tests/Makefile
1594 dlls/mlang/Makefile
1595 dlls/mlang/tests/Makefile
1596 dlls/mmdevldr.vxd/Makefile
1597 dlls/monodebg.vxd/Makefile
1598 dlls/mpr/Makefile
1599 dlls/msacm/Makefile
1600 dlls/msacm/imaadp32/Makefile
1601 dlls/msacm/msadp32/Makefile
1602 dlls/msacm/msg711/Makefile
1603 dlls/msacm/winemp3/Makefile
1604 dlls/msacm/tests/Makefile
1605 dlls/mscms/Makefile
1606 dlls/mscms/tests/Makefile
1607 dlls/msdmo/Makefile
1608 dlls/mshtml/Makefile
1609 dlls/msi/Makefile
1610 dlls/msi/tests/Makefile
1611 dlls/msimg32/Makefile
1612 dlls/msisys/Makefile
1613 dlls/msnet32/Makefile
1614 dlls/msrle32/Makefile
1615 dlls/msvcrt/Makefile
1616 dlls/msvcrt/tests/Makefile
1617 dlls/msvcrt20/Makefile
1618 dlls/msvcrt40/Makefile
1619 dlls/msvcrtd/Makefile
1620 dlls/msvcrtd/tests/Makefile
1621 dlls/msvidc32/Makefile
1622 dlls/msvideo/Makefile
1623 dlls/mswsock/Makefile
1624 dlls/netapi32/Makefile
1625 dlls/netapi32/tests/Makefile
1626 dlls/newdev/Makefile
1627 dlls/ntdll/Makefile
1628 dlls/ntdll/tests/Makefile
1629 dlls/odbc32/Makefile
1630 dlls/ole32/Makefile
1631 dlls/ole32/tests/Makefile
1632 dlls/oleacc/Makefile
1633 dlls/oleaut32/Makefile
1634 dlls/oleaut32/tests/Makefile
1635 dlls/olecli/Makefile
1636 dlls/oledlg/Makefile
1637 dlls/olepro32/Makefile
1638 dlls/olesvr/Makefile
1639 dlls/opengl32/Makefile
1640 dlls/powrprof/Makefile
1641 dlls/psapi/Makefile
1642 dlls/psapi/tests/Makefile
1643 dlls/qcap/Makefile
1644 dlls/quartz/Makefile
1645 dlls/quartz/tests/Makefile
1646 dlls/rasapi32/Makefile
1647 dlls/riched20/Makefile
1648 dlls/richedit/Makefile
1649 dlls/rpcrt4/Makefile
1650 dlls/rpcrt4/tests/Makefile
1651 dlls/rsabase/Makefile
1652 dlls/rsabase/tests/Makefile
1653 dlls/rsaenh/Makefile
1654 dlls/rsaenh/tests/Makefile
1655 dlls/secur32/Makefile
1656 dlls/sensapi/Makefile
1657 dlls/serialui/Makefile
1658 dlls/setupapi/Makefile
1659 dlls/shdocvw/Makefile
1660 dlls/shell32/Makefile
1661 dlls/shell32/tests/Makefile
1662 dlls/shfolder/Makefile
1663 dlls/shlwapi/Makefile
1664 dlls/shlwapi/tests/Makefile
1665 dlls/snmpapi/Makefile
1666 dlls/stdole32.tlb/Makefile
1667 dlls/sti/Makefile
1668 dlls/strmiids/Makefile
1669 dlls/tapi32/Makefile
1670 dlls/ttydrv/Makefile
1671 dlls/twain/Makefile
1672 dlls/unicows/Makefile
1673 dlls/url/Makefile
1674 dlls/urlmon/Makefile
1675 dlls/urlmon/tests/Makefile
1676 dlls/user/Makefile
1677 dlls/user/tests/Makefile
1678 dlls/uuid/Makefile
1679 dlls/uxtheme/Makefile
1680 dlls/vdhcp.vxd/Makefile
1681 dlls/vdmdbg/Makefile
1682 dlls/version/Makefile
1683 dlls/version/tests/Makefile
1684 dlls/vmm.vxd/Makefile
1685 dlls/vnbt.vxd/Makefile
1686 dlls/vnetbios.vxd/Makefile
1687 dlls/vtdapi.vxd/Makefile
1688 dlls/vwin32.vxd/Makefile
1689 dlls/win32s/Makefile
1690 dlls/winaspi/Makefile
1691 dlls/wined3d/Makefile
1692 dlls/winedos/Makefile
1693 dlls/wineps/Makefile
1694 dlls/wininet/Makefile
1695 dlls/wininet/tests/Makefile
1696 dlls/winmm/Makefile
1697 dlls/winmm/joystick/Makefile
1698 dlls/winmm/mcianim/Makefile
1699 dlls/winmm/mciavi/Makefile
1700 dlls/winmm/mcicda/Makefile
1701 dlls/winmm/mciseq/Makefile
1702 dlls/winmm/mciwave/Makefile
1703 dlls/winmm/midimap/Makefile
1704 dlls/winmm/tests/Makefile
1705 dlls/winmm/wavemap/Makefile
1706 dlls/winmm/winealsa/Makefile
1707 dlls/winmm/winearts/Makefile
1708 dlls/winmm/wineaudioio/Makefile
1709 dlls/winmm/winejack/Makefile
1710 dlls/winmm/winenas/Makefile
1711 dlls/winmm/wineoss/Makefile
1712 dlls/winnls/Makefile
1713 dlls/winsock/Makefile
1714 dlls/winsock/tests/Makefile
1715 dlls/winspool/Makefile
1716 dlls/winspool/tests/Makefile
1717 dlls/wintab32/Makefile
1718 dlls/wintrust/Makefile
1719 dlls/wow32/Makefile
1720 dlls/wsock32/Makefile
1721 dlls/wtsapi32/Makefile
1722 dlls/x11drv/Makefile
1723 documentation/Makefile
1724 fonts/Makefile
1725 include/Makefile
1726 libs/Makefile
1727 libs/port/Makefile
1728 libs/unicode/Makefile
1729 libs/wine/Makefile
1730 libs/wpp/Makefile
1731 loader/Makefile
1732 programs/Makefile
1733 programs/avitools/Makefile
1734 programs/clock/Makefile
1735 programs/cmdlgtst/Makefile
1736 programs/control/Makefile
1737 programs/expand/Makefile
1738 programs/msiexec/Makefile
1739 programs/notepad/Makefile
1740 programs/progman/Makefile
1741 programs/regedit/Makefile
1742 programs/regsvr32/Makefile
1743 programs/rpcss/Makefile
1744 programs/rundll32/Makefile
1745 programs/start/Makefile
1746 programs/taskmgr/Makefile
1747 programs/uninstaller/Makefile
1748 programs/view/Makefile
1749 programs/wcmd/Makefile
1750 programs/wineboot/Makefile
1751 programs/winebrowser/Makefile
1752 programs/winecfg/Makefile
1753 programs/wineconsole/Makefile
1754 programs/winedbg/Makefile
1755 programs/winefile/Makefile
1756 programs/winemenubuilder/Makefile
1757 programs/winemine/Makefile
1758 programs/winepath/Makefile
1759 programs/winetest/Makefile
1760 programs/winevdm/Makefile
1761 programs/winhelp/Makefile
1762 programs/winver/Makefile
1763 server/Makefile
1764 tools/Makefile
1765 tools/widl/Makefile
1766 tools/winapi/Makefile
1767 tools/winebuild/Makefile
1768 tools/winedump/Makefile
1769 tools/winegcc/Makefile
1770 tools/wmc/Makefile
1771 tools/wrc/Makefile])
1772
1773 AC_OUTPUT
1774
1775 if test "$have_x" = "no"
1776 then
1777   echo
1778   echo "*** Warning: X development files not found. Wine will be built without"
1779   echo "*** X support, which currently does not work, and would probably not be"
1780   echo "*** what you want anyway. You will need to install devel packages of"
1781   echo "*** Xlib/Xfree86 at the very least."
1782 fi
1783
1784 if test "$wine_cv_opengl_version_OK" = "no"
1785 then
1786   echo
1787   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1788   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1789 fi
1790
1791 if test "$wine_cv_msg_freetype" = "yes"
1792 then
1793   echo
1794   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1795   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1796   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1797   echo "*** enable Wine to use TrueType fonts."
1798 fi
1799
1800 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1801         -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1802         "$ac_cv_c_opensoundsystem" = "no"
1803 then
1804     echo "*** No sound system was found. Windows applications will be silent."
1805     echo "*** The currently supported sound systems are:"
1806     echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1807 fi
1808
1809 echo
1810 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1811 echo
1812
1813 dnl Local Variables:
1814 dnl comment-start: "dnl "
1815 dnl comment-end: ""
1816 dnl comment-start-skip: "\\bdnl\\b\\s *"
1817 dnl compile-command: "autoconf"
1818 dnl End: