git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  26 if test "x$enable_win16" = "xno"
  27 then
  28   WIN16_FILES=""
  29   WIN16_INSTALL=""
  30 fi
  31
  32 AC_SUBST(DLLDEFS,"")
  33 if test "x$enable_debug" = "xno"
  34 then
  35   DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
  36 fi
  37 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  38 then
  39   DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
  40 fi
  41
  42 dnl **** Check for some programs ****
  43
  44 AC_CANONICAL_HOST
  45 case $host in
  46   x86_64*linux*)
  47     if test "x$enable_win64" != "xyes"
  48     then
  49       test -n "$CC" || CC="gcc -m32"
  50       test -n "$LD" || LD="ld -m elf_i386"
  51       test -n "$AS" || AS="as --32"
  52     fi
  53     ;;
  54 esac
  55
  56 AC_PROG_MAKE_SET
  57 AC_PROG_CC
  58 AC_PROG_CXX
  59 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  60 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  61
  62 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  63   [if test -z "$with_wine_tools"; then
  64      if test "$cross_compiling" = "yes"; then
  65        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  66      else
  67        wine_cv_toolsdir="\$(TOPOBJDIR)"
  68      fi
  69    elif test -d "$with_wine_tools/tools/winebuild"; then
  70      case $with_wine_tools in
  71        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  72        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  73      esac
  74    else
  75      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  76    fi])
  77 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  78
  79 AC_PATH_XTRA
  80 AC_PROG_LEX
  81
  82 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  83 dnl **** without one present.
  84 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  85 if test "$XLEX" = "none"
  86 then
  87   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  88 fi
  89
  90 dnl Check for bison
  91 AC_CHECK_PROGS(BISON,bison,none)
  92 if test "$BISON" = "none"
  93 then
  94   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  95 fi
  96
  97 AC_CHECK_TOOLS(AS,[gas as],as)
  98 AC_CHECK_TOOL(LD,ld,ld)
  99 AC_CHECK_TOOL(AR,ar,ar)
 100 AC_PROG_RANLIB
 101 AC_CHECK_TOOL(STRIP,strip,strip)
 102 AC_CHECK_TOOL(WINDRES,windres,false)
 103 AC_PROG_LN_S
 104 WINE_PROG_LN
 105 AC_PROG_EGREP
 106 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 107 AC_PROG_INSTALL
 108 dnl Prepend src dir to install path dir if it's a relative path
 109 case "$INSTALL" in
 110   [[\\/$]]* | ?:[[\\/]]* ) ;;
 111   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 112 esac
 113
 114 dnl Check for lint
 115 AC_CHECK_PROGS(LINT, lclint lint)
 116 if test "$LINT" = "lint"
 117 then
 118   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 119   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 120 fi
 121 AC_SUBST(LINT)
 122 AC_SUBST(LINTFLAGS)
 123
 124 dnl Check for various programs
 125 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 126 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 127 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 128 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 129 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 130
 131 dnl **** Check for some libraries ****
 132
 133 dnl Check for -li386 for NetBSD and OpenBSD
 134 AC_CHECK_LIB(i386,i386_set_ldt)
 135 dnl Check for -lossaudio for NetBSD
 136 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 137 dnl Check for -lw for Solaris
 138 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 139 dnl Check for -lnsl for Solaris
 140 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 141 dnl Check for -lsocket for Solaris
 142 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 143 dnl Check for -lresolv for Solaris
 144 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpoll for Mac OS X/Darwin
 148 AC_CHECK_LIB(poll,poll)
 149 dnl Check for -lresolv for Mac OS X/Darwin
 150 AC_CHECK_LIB(resolv,res_9_init)
 151 dnl Check for -lpthread
 152 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 153
 154 AC_SUBST(XLIB)
 155 AC_SUBST(XFILES)
 156 XFILES=""
 157 AC_SUBST(OPENGLFILES)
 158 OPENGLFILES=""
 159 AC_SUBST(GLU32FILES)
 160 GLU32FILES=""
 161 AC_SUBST(OPENGL_LIBS)
 162 OPENGL_LIBS=""
 163 if test "$have_x" = "yes"
 164 then
 165     XLIB="-lXext -lX11"
 166     ac_save_CPPFLAGS="$CPPFLAGS"
 167     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 168
 169     dnl *** All of the following tests require X11/Xlib.h
 170     AC_CHECK_HEADERS(X11/Xlib.h,
 171       [
 172         AC_CHECK_HEADERS([X11/XKBlib.h \
 173                           X11/Xutil.h \
 174                           X11/extensions/shape.h \
 175                           X11/extensions/XInput.h \
 176                           X11/extensions/XShm.h \
 177                           X11/extensions/Xrandr.h \
 178                           X11/extensions/Xrender.h \
 179                           X11/extensions/Xvlib.h \
 180                           X11/extensions/xf86dga.h \
 181                           X11/extensions/xf86vmode.h],,,
 182                          [#include <X11/Xlib.h>
 183                           #ifdef HAVE_X11_XUTIL_H
 184                           # include <X11/Xutil.h>
 185                           #endif])
 186
 187         dnl *** Check for X keyboard extension
 188         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 189         then
 190               AC_CHECK_LIB(X11, XkbQueryExtension,
 191               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 192               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 193         fi
 194
 195         dnl *** Check for X Shm extension
 196         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 197         then
 198               AC_CHECK_LIB(Xext, XShmQueryExtension,
 199               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 200               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 201         fi
 202
 203         dnl *** Check for X shape extension
 204         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 205         then
 206               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 207               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 208               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 209         fi
 210
 211         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 212         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 213         then
 214               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 215                 [ dnl *** If found...
 216                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 217                             [Define if you have the Xxf86dga library version 2])
 218                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 219                ],
 220                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 221                   dnl *** instead (DGA 2.0 not found)...
 222                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 223                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 224                                 [Define if you have the Xxf86dga library version 1])
 225                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 226                     ],,
 227                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 228                   )
 229                 ],
 230                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 231         fi
 232
 233         dnl *** Check for XFree86 VMODE extension
 234         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 235         then
 236                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 237                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 238                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 239                   ],,
 240                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 241         fi
 242
 243         dnl *** Check for X RandR extension
 244         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 245         then
 246                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 247 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 248                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 249         fi
 250
 251         dnl *** Check for XVideo extension supporting XvImages
 252         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 253         then
 254                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 255                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 256                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 257                   ],,
 258                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 259         fi
 260
 261         dnl *** Check for Transform functions in Xrender
 262         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 263         then
 264               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 265                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 266                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 267                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 268         fi
 269       ]
 270     ) dnl *** End of X11/Xlib.h check
 271
 272     dnl Check for the presence of OpenGL
 273     if test "x$with_opengl" != "xno"
 274     then
 275         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 276         then
 277             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 278 This prevents linking to OpenGL. Delete the file and restart configure.])
 279         fi
 280
 281         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 282         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 283         then
 284             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 285             dnl Check for some problems due to old Mesa versions
 286             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 287               AC_TRY_COMPILE(
 288                 [#include <GL/gl.h>],
 289                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 290                 [wine_cv_opengl_version_OK="yes"],
 291                 [wine_cv_opengl_version_OK="no"]
 292               )
 293             )
 294
 295             if test "$wine_cv_opengl_version_OK" = "yes"
 296             then
 297                 dnl Check for the presence of the library
 298                 AC_CHECK_LIB(GL,glXCreateContext,
 299                              OPENGL_LIBS="-lGL"
 300                              ,,
 301                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 302
 303                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 304                 then
 305                         OPENGLFILES='$(OPENGLFILES)'
 306                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 307
 308                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 309                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 310                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 311                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 312
 313                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 314                         then
 315                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 316                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 317                                                   #ifdef HAVE_GL_GLEXT_H
 318                                                   # include <GL/glext.h>
 319                                                   #endif
 320                                                   ],
 321                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 322                                                  [wine_cv_extension_prototypes="yes"],
 323                                                  [wine_cv_extension_prototypes="no"]
 324                                   )]
 325                                 )
 326                                 if test "$wine_cv_extension_prototypes" = "yes"
 327                                 then
 328                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 329                                               [Define if the OpenGL headers define extension typedefs])
 330                                 fi
 331                         fi
 332
 333                 fi
 334                 dnl Check for GLU32 library.
 335                 AC_CHECK_LIB(GLU,gluLookAt,
 336                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 337                              GLU32FILES='$(GLU32FILES)']
 338                              ,,
 339                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 340                 )
 341              fi
 342
 343              dnl Check for glut32 library.
 344              AC_CHECK_LIB(glut,glutMainLoop,
 345                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 346                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 347                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 348          fi
 349     fi
 350
 351     dnl **** Check for NAS ****
 352     AC_SUBST(NASLIBS,"")
 353     AC_CHECK_HEADERS(audio/audiolib.h,
 354          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 355           AC_CHECK_LIB(audio,AuCreateFlow,
 356                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 357                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 358                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 359
 360     CPPFLAGS="$ac_save_CPPFLAGS"
 361     XFILES='$(XFILES)'
 362 else
 363     XLIB=""
 364     X_CFLAGS=""
 365     X_LIBS=""
 366 fi
 367
 368 dnl **** Check which curses lib to use ***
 369 CURSESLIBS=""
 370 if test "x$with_curses" != "xno"
 371 then
 372     AC_CHECK_HEADERS(ncurses.h,
 373         [AC_CHECK_LIB(ncurses,waddch,
 374             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 375              CURSESLIBS="-lncurses"],
 376              [AC_CHECK_HEADERS(curses.h,
 377                  [AC_CHECK_LIB(curses,waddch,
 378                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 379                       CURSESLIBS="-lcurses"])])])])
 380     saved_libs="$LIBS"
 381     LIBS="$CURSESLIBS $LIBS"
 382     AC_CHECK_FUNCS(getbkgd resizeterm)
 383     LIBS="$saved_libs"
 384 fi
 385 AC_SUBST(CURSESLIBS)
 386
 387 dnl **** Check for SANE ****
 388 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 389 if test "$sane_devel" = "no"
 390 then
 391     SANELIBS=""
 392     SANEINCL=""
 393 else
 394     SANELIBS="`$sane_devel --libs`"
 395     SANEINCL="`$sane_devel --cflags`"
 396     ac_save_CPPFLAGS="$CPPFLAGS"
 397     ac_save_LIBS="$LIBS"
 398     CPPFLAGS="$CPPFLAGS $SANEINCL"
 399     LIBS="$LIBS $SANELIBS"
 400     AC_CHECK_HEADER(sane/sane.h,
 401                     [AC_CHECK_LIB(sane,sane_open,
 402                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 403                                   [SANELIBS=""
 404                                   SANEINCL=""])],
 405                     [SANELIBS=""
 406                     SANEINCL=""])
 407     LIBS="$ac_save_LIBS"
 408     CPPFLAGS="$ac_save_CPPFLAGS"
 409 fi
 410 AC_SUBST(SANELIBS)
 411 AC_SUBST(SANEINCL)
 412
 413 dnl **** Check for the ICU library ****
 414 AC_CHECK_HEADERS(unicode/ubidi.h)
 415 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 416 then
 417     saved_libs="$LIBS"
 418     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 419     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 420     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 421     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 422     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 423     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 424                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 425                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 426                  AC_MSG_RESULT(yes)],
 427                 [AC_MSG_RESULT(no)])
 428     LIBS="$saved_libs"
 429 fi
 430
 431 dnl **** Check for FreeType 2 ****
 432 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 433 if test "$ft_lib" = "no"
 434 then
 435     FREETYPELIBS=""
 436     FREETYPEINCL=""
 437     wine_cv_msg_freetype=no
 438 else
 439     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 440     if test "$ft_devel" = "no"
 441     then
 442         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 443         if test "$ft_devel2" = "freetype2-config"
 444         then
 445                 ft_devel=$ft_devel2
 446         fi
 447     fi
 448     if test "$ft_devel" = "no"
 449     then
 450         FREETYPELIBS=""
 451         FREETYPEINCL=""
 452         wine_cv_msg_freetype=yes
 453     else
 454         FREETYPELIBS=`$ft_devel --libs`
 455         FREETYPEINCL=`$ft_devel --cflags`
 456         ac_save_CPPFLAGS="$CPPFLAGS"
 457         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 458         AC_CHECK_HEADERS(ft2build.h \
 459                          freetype/freetype.h \
 460                          freetype/ftglyph.h \
 461                          freetype/tttables.h \
 462                          freetype/ftnames.h \
 463                          freetype/ftsnames.h \
 464                          freetype/ttnameid.h \
 465                          freetype/ftoutln.h \
 466                          freetype/ftwinfnt.h \
 467                          freetype/internal/sfnt.h,,,
 468                          [#if HAVE_FT2BUILD_H
 469                           #include <ft2build.h>
 470                           #endif])
 471         AC_TRY_CPP([#include <ft2build.h>
 472                     #include <freetype/fttrigon.h>],
 473                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 474           [Define if you have the <freetype/fttrigon.h> header file.])
 475                     wine_cv_fttrigon=yes],
 476                     wine_cv_fttrigon=no)
 477         CPPFLAGS="$ac_save_CPPFLAGS"
 478         dnl Check that we have at least freetype/freetype.h
 479         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 480         then
 481             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 482             wine_cv_msg_freetype=no
 483         else
 484             FREETYPELIBS=""
 485             FREETYPEINCL=""
 486             wine_cv_msg_freetype=yes
 487         fi
 488     fi
 489 fi
 490 AC_SUBST(FREETYPELIBS)
 491 AC_SUBST(FREETYPEINCL)
 492
 493 dnl Only build the fonts dir if we have both freetype and fontforge
 494 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 495 then
 496   AC_SUBST(FONTSSUBDIRS,"fonts")
 497 fi
 498
 499 dnl **** Check for parport (currently Linux only) ****
 500 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 501  AC_TRY_COMPILE(
 502    [#include <linux/ppdev.h>],
 503    [ioctl (1,PPCLAIM,0)],
 504    [ac_cv_c_ppdev="yes"],
 505    [ac_cv_c_ppdev="no"])
 506  )
 507 if test "$ac_cv_c_ppdev" = "yes"
 508 then
 509     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 510 fi
 511
 512 dnl **** Check for va_copy ****
 513 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 514  AC_TRY_LINK(
 515    [#include <stdarg.h>],
 516    [va_list ap1, ap2;
 517     va_copy(ap1,ap2);
 518    ],
 519    [ac_cv_c_va_copy="yes"],
 520    [ac_cv_c_va_copy="no"])
 521  )
 522 if test "$ac_cv_c_va_copy" = "yes"
 523 then
 524     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 525 fi
 526 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 527  AC_TRY_LINK(
 528    [#include <stdarg.h>],
 529    [va_list ap1, ap2;
 530     __va_copy(ap1,ap2);
 531    ],
 532    [ac_cv_c___va_copy="yes"],
 533    [ac_cv_c___va_copy="no"])
 534  )
 535 if test "$ac_cv_c___va_copy" = "yes"
 536 then
 537     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 538 fi
 539
 540 dnl **** Check for sigsetjmp ****
 541 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 542  AC_TRY_LINK(
 543    [#include <setjmp.h>],
 544    [sigjmp_buf buf;
 545     sigsetjmp( buf, 1 );
 546     siglongjmp( buf, 1 );],
 547    [ac_cv_c_sigsetjmp="yes"],
 548    [ac_cv_c_sigsetjmp="no"])
 549  )
 550 if test "$ac_cv_c_sigsetjmp" = "yes"
 551 then
 552     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 553 fi
 554
 555 dnl **** Check for pthread_rwlock_t ****
 556 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 557 #include <pthread.h>])
 558
 559 dnl **** Check for pthread functions ****
 560 ac_save_LIBS="$LIBS"
 561 LIBS="$LIBS $LIBPTHREAD"
 562 AC_CHECK_FUNCS(\
 563         pthread_getattr_np \
 564         pthread_get_stackaddr_np \
 565         pthread_get_stacksize_np \
 566 )
 567 LIBS="$ac_save_LIBS"
 568
 569 dnl **** Check for Open Sound System ****
 570 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 571
 572 AC_CACHE_CHECK([for Open Sound System],
 573         ac_cv_c_opensoundsystem,
 574         AC_TRY_COMPILE([
 575         #if defined(HAVE_SYS_SOUNDCARD_H)
 576                 #include <sys/soundcard.h>
 577         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 578                 #include <machine/soundcard.h>
 579         #elif defined(HAVE_SOUNDCARD_H)
 580                 #include <soundcard.h>
 581         #endif
 582         ],[
 583
 584 /* check for one of the Open Sound System specific SNDCTL_ defines */
 585 #if !defined(SNDCTL_DSP_STEREO)
 586 #error No open sound system
 587 #endif
 588 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 589
 590 if test "$ac_cv_c_opensoundsystem" = "yes"
 591 then
 592     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 593 fi
 594
 595 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 596         ac_cv_c_opensoundsystem_midi,
 597         AC_TRY_COMPILE([
 598         #if defined(HAVE_SYS_SOUNDCARD_H)
 599                 #include <sys/soundcard.h>
 600         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 601                 #include <machine/soundcard.h>
 602         #elif defined(HAVE_SOUNDCARD_H)
 603                 #include <soundcard.h>
 604         #endif
 605         ],[
 606
 607 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 608 #if !defined(SNDCTL_SEQ_SYNC)
 609 #error No open sound system MIDI interface
 610 #endif
 611 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 612
 613 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 614 then
 615     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 616 fi
 617
 618 dnl **** Check for aRts Sound Server ****
 619 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 620 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 621 then
 622     ARTSC_CFLAGS=""
 623     for i in `$ARTSCCONFIG --cflags`
 624     do
 625       case "$i" in
 626         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 627       esac
 628     done
 629     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 630     save_CFLAGS="$CFLAGS"
 631     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 632     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 633         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 634          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 635          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 636     CFLAGS="$save_CFLAGS"
 637 fi
 638
 639 dnl **** Check for ALSA ****
 640 AC_SUBST(ALSALIBS,"")
 641 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 642 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 643 then
 644     AC_CHECK_LIB(asound,snd_pcm_open,
 645         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 646         ALSALIBS="-lasound")
 647 fi
 648
 649 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 650
 651 AC_SUBST(AUDIOIOLIBS,"")
 652 AC_CHECK_HEADERS(libaudioio.h,
 653     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 654                   [AUDIOIOLIBS="-laudioio"
 655                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 656
 657 dnl **** Check for capi4linux ****
 658
 659 AC_CHECK_HEADERS(capi20.h,[
 660         AC_CHECK_HEADERS(linux/capi.h,[
 661                 AC_CHECK_LIB(capi20,capi20_register,[
 662                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 663                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 664                 ])
 665         ])
 666 ])
 667
 668 dnl **** Check for broken glibc mmap64 ****
 669
 670 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 671         AC_TRY_RUN([
 672                 #define _FILE_OFFSET_BITS 64
 673                 #include <stdio.h>
 674                 #include <unistd.h>
 675                 #include <fcntl.h>
 676                 #include <sys/mman.h>
 677                 #include <errno.h>
 678
 679                 int main(int argc,char **argv) {
 680                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 681                         if (fd == -1) exit(1);
 682
 683                         unlink("conftest.map");
 684
 685                         write(fd,"test",4);
 686
 687                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 688                             (errno == EINVAL)
 689                         ) {
 690                                 exit(1);
 691                         }
 692                         close(fd);
 693                         fprintf(stderr,"success!\n");
 694                         exit(0);
 695                 }
 696
 697         ],
 698     ac_cv_mmap64_works="yes",
 699     ac_cv_mmap64_works="no",
 700     ac_cv_mmap64_works="no") )
 701
 702 if test "$ac_cv_mmap64_works" = "yes"
 703 then
 704     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 705 fi
 706
 707 dnl **** Check for gcc specific options ****
 708
 709 AC_SUBST(EXTRACFLAGS,"")
 710 if test "x${GCC}" = "xyes"
 711 then
 712   EXTRACFLAGS="-Wall -pipe"
 713
 714   dnl Check for strength-reduce bug
 715   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 716                   AC_TRY_RUN([
 717 int     L[[4]] = {0,1,2,3};
 718 int main(void) {
 719   static int Array[[3]];
 720   unsigned int B = 3;
 721   int i;
 722   for(i=0; i<B; i++) Array[[i]] = i - 3;
 723   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 724   L[[i]] = 4;
 725
 726   exit( Array[[1]] != -2 || L[[2]] != 3);
 727 }],
 728     ac_cv_c_gcc_strength_bug="no",
 729     ac_cv_c_gcc_strength_bug="yes",
 730     ac_cv_c_gcc_strength_bug="yes") )
 731   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 732   then
 733     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 734   fi
 735
 736   dnl Check for -fshort-wchar
 737   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 738       [WINE_TRY_CFLAGS([-fshort-wchar],
 739                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 740   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 741   then
 742       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 743   fi
 744
 745   dnl Check for -mpreferred-stack-boundary
 746   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 747       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 748                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 749   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 750   then
 751     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 752   fi
 753
 754   dnl Check for -fno-strict-aliasing
 755   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 756       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 757                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 758   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 759   then
 760     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 761   fi
 762
 763   dnl Check for -gstabs+ option
 764   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 765       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 766   if test "$ac_cv_c_gcc_gstabs" = "yes"
 767   then
 768     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 769   fi
 770
 771   dnl Check for noisy string.h
 772   saved_CFLAGS="$CFLAGS"
 773   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 774   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 775       AC_TRY_COMPILE([#include <string.h>],[],
 776                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 777   CFLAGS="$saved_CFLAGS"
 778   if test "$ac_cv_c_string_h_warnings" = "no"
 779   then
 780     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 781   fi
 782 fi
 783
 784 dnl **** Check how to define a function in assembly code ****
 785
 786 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 787   WINE_TRY_ASM_LINK(
 788       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 789       ac_cv_asm_func_def=".def",
 790     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 791       ac_cv_asm_func_def=".type @function",
 792     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 793       ac_cv_asm_func_def=".type 2",
 794       ac_cv_asm_func_def="unknown")])]))
 795
 796 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 797 case "$ac_cv_asm_func_def" in
 798   ".def")
 799      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 800   ".type @function")
 801      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 802   ".type 2")
 803      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 804   *)
 805      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 806 esac
 807
 808 dnl **** Check for underscore on external symbols ****
 809
 810 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 811     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 812                       [extern int ac_test;],
 813                       [if (ac_test) return 1],
 814                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 815
 816 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 817 if test "$ac_cv_c_extern_prefix" = "yes"
 818 then
 819   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 820 else
 821   AC_DEFINE([__ASM_NAME(name)], [name])
 822 fi
 823
 824 dnl **** Check how to do strings in assembler ****
 825
 826 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 827     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 828       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 829         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 830           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 831
 832 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 833                    [Define to the assembler keyword used to specify an ASCII string])
 834
 835 dnl **** Check for .short in assembler ****
 836
 837 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 838     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 839       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 840         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 841
 842 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 843                    [Define to the assembler keyword used to specify a word value])
 844
 845 dnl **** Check for .size in assembler ****
 846
 847 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 848     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 849                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 850
 851 if test "$ac_cv_c_asm_size" = "yes"
 852 then
 853   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 854 fi
 855
 856 dnl **** Check for working dll ****
 857
 858 AC_SUBST(DLLEXT,"")
 859 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 860 AC_SUBST(DLLIBS,"")
 861 AC_SUBST(LDSHARED,"")
 862 AC_SUBST(LDDLLFLAGS,"")
 863 AC_SUBST(LIBEXT,"so")
 864 AC_SUBST(IMPLIBEXT,"def")
 865
 866 case $host_os in
 867   cygwin*|mingw32*)
 868     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 869     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 870     if test "$DLLWRAP" = "false"; then
 871       LIBEXT="a"
 872     else
 873       dnl FIXME - check whether dllwrap works correctly...
 874       LIBEXT="dll"
 875     fi
 876     IMPLIBEXT="a"
 877     dnl We can't build 16-bit NE dlls
 878     WIN16_FILES=""
 879     WIN16_INSTALL=""
 880     ;;
 881   *)
 882     AC_CHECK_HEADERS(dlfcn.h,
 883         [AC_CHECK_FUNCS(dlopen,,
 884             [AC_CHECK_LIB(dl,dlopen,
 885                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 886                           DLLIBS="-ldl"],
 887                          [LIBEXT="a"])])],
 888         [LIBEXT="a"])
 889
 890     if test "$LIBEXT" = "so"
 891     then
 892       DLLFLAGS="$DLLFLAGS -fPIC"
 893       DLLEXT=".so"
 894       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 895           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 896                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 897       if test "$ac_cv_c_dll_gnuelf" = "yes"
 898       then
 899         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 900         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 901         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 902           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 903                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 904         if test "$ac_cv_c_dll_zdefs" = "yes"
 905         then
 906           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 907         fi
 908
 909         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 910           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 911                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 912         if test "$ac_cv_c_dll_init_fini" = "yes"
 913         then
 914           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 915         fi
 916
 917         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 918           [echo '{ global: *; };' >conftest.map
 919            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 920                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 921            rm -f conftest.map])
 922         if test "$ac_cv_c_ld_version_scripts" = "yes"
 923         then
 924           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 925         fi
 926
 927         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 928           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 929                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 930         if test "$ac_cv_c_export_dynamic" = "yes"
 931         then
 932           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 933         fi
 934
 935         case $host_cpu in
 936           *i[[3456789]]86*)
 937             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 938               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 939                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 940             if test "$ac_cv_ld_reloc_exec" = "yes"
 941             then
 942               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 943             fi
 944             ;;
 945         esac
 946
 947       else
 948         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 949             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 950                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 951         if test "$ac_cv_c_dll_unixware" = "yes"
 952         then
 953           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 954           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 955
 956         else
 957           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 958             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 959           if test "$ac_cv_c_dll_macho" = "yes"
 960           then
 961             LIBEXT="dylib"
 962             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 963             LDSHARED="\$(CC) -dynamiclib"
 964             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 965             STRIP="$STRIP -u -r"
 966             dnl Relocate wine executable
 967             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 968             dnl Relocate libwine.dyld too
 969             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 970             dnl declare needed frameworks
 971             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 972             AC_SUBST(IOKITLIB,"-framework IOKit")
 973             dnl using IOKit imply we use CoreFoundation too
 974             IOKITLIB = "$IOKITLIB $COREFOUNDATIONLIB"
 975           else
 976             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 977               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 978             if test "$ac_cv_c_dll_hpux" = "yes"
 979             then
 980               LIBEXT="sl"
 981               DLLEXT=".sl"
 982               LDDLLFLAGS="-shared -fPIC"
 983               LDSHARED="\$(CC) -shared"
 984             fi
 985           fi
 986         fi
 987       fi
 988     fi
 989
 990     dnl Check for cross compiler to build test programs
 991     AC_SUBST(CROSSTEST,"")
 992     if test "$cross_compiling" = "no"
 993     then
 994       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 995       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 996       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 997       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 998     fi
 999     ;;
1000 esac
1001
1002 if test "$LIBEXT" = "a"; then
1003   AC_MSG_ERROR(
1004 [could not find a way to build shared libraries.
1005 It is currently not possible to build Wine without shared library
1006 (.so) support to allow transparent switch between .so and .dll files.
1007 If you are using Linux, you will need a newer binutils.]
1008 )
1009 fi
1010
1011 case $build_os in
1012   cygwin*|mingw32*)
1013     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1014   darwin*|macosx*)
1015     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1016   *)
1017     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1018 esac
1019
1020 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1021 case $host_os in
1022   mingw32*)
1023     AC_SUBST(CRTLIBS,"-lmsvcrt")
1024     AC_SUBST(SOCKETLIBS,"-lws2_32")
1025     ;;
1026 esac
1027
1028 case $host_os in
1029   linux*)
1030     case $host_cpu in
1031       *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1032       *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1033     esac
1034     AC_SUBST(MAIN_BINARY,"wine-glibc")
1035     ;;
1036   darwin*)
1037     AC_SUBST(WINE_BINARIES,"wine-pthread")
1038     AC_SUBST(MAIN_BINARY,"wine-pthread")
1039     ;;
1040   *)
1041     AC_SUBST(WINE_BINARIES,"wine-kthread")
1042     AC_SUBST(MAIN_BINARY,"wine-kthread")
1043     ;;
1044 esac
1045
1046 dnl **** Get the soname for libraries that we load dynamically ****
1047
1048 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1049 then
1050   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1051   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1052   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1053   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1054   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1055   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1056   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1057   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1058   WINE_GET_SONAME(cups,cupsGetDefault)
1059   WINE_GET_SONAME(jack,jack_client_new)
1060   WINE_GET_SONAME(fontconfig,FcInit)
1061   WINE_GET_SONAME(ssl,SSL_library_init)
1062   WINE_GET_SONAME(crypto,BIO_new_socket)
1063   WINE_GET_SONAME(ncurses,waddch)
1064   WINE_GET_SONAME(curses,waddch)
1065   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1066   WINE_GET_SONAME(ungif,DGifOpen)
1067   WINE_GET_SONAME(gif,DGifOpen)
1068   WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1069 fi
1070
1071
1072 dnl **** Check for functions ****
1073
1074 AC_FUNC_ALLOCA()
1075 AC_CHECK_FUNCS(\
1076         _lwp_create \
1077         _lwp_self \
1078         _pclose \
1079         _popen \
1080         _snprintf \
1081         _spawnvp \
1082         _stricmp \
1083         _strnicmp \
1084         _vsnprintf \
1085         chsize \
1086         clone \
1087         epoll_create \
1088         ffs \
1089         finite \
1090         fork \
1091         fpclass \
1092         fstatfs \
1093         fstatvfs \
1094         ftruncate \
1095         ftruncate64 \
1096         futimes \
1097         getnetbyaddr \
1098         getnetbyname \
1099         getopt_long \
1100         getpagesize \
1101         getprotobyname \
1102         getprotobynumber \
1103         getpwuid \
1104         getservbyport \
1105         gettid \
1106         gettimeofday \
1107         getuid \
1108         inet_network \
1109         lseek64 \
1110         lstat \
1111         memmove \
1112         mmap \
1113         pclose \
1114         popen \
1115         pread \
1116         pwrite \
1117         readlink \
1118         rfork \
1119         sched_yield \
1120         select \
1121         sendmsg \
1122         settimeofday \
1123         sigaltstack \
1124         snprintf \
1125         spawnvp \
1126         statfs \
1127         statvfs \
1128         strcasecmp \
1129         strerror \
1130         strncasecmp \
1131         tcgetattr \
1132         timegm \
1133         usleep \
1134         vfscanf \
1135         vsnprintf \
1136         wait4 \
1137         waitpid \
1138 )
1139
1140 dnl **** Check for header files ****
1141
1142 AC_CHECK_HEADERS(\
1143         arpa/inet.h \
1144         arpa/nameser.h \
1145         cups/cups.h \
1146         direct.h \
1147         elf.h \
1148         float.h \
1149         fontconfig/fontconfig.h \
1150         getopt.h \
1151         gif_lib.h \
1152         ieeefp.h \
1153         io.h \
1154         jack/jack.h \
1155         jpeglib.h \
1156         lcms.h \
1157         libio.h \
1158         libutil.h \
1159         link.h \
1160         linux/cdrom.h \
1161         linux/compiler.h \
1162         linux/hdreg.h \
1163         linux/input.h \
1164         linux/ioctl.h \
1165         linux/joystick.h \
1166         linux/major.h \
1167         linux/param.h \
1168         linux/serial.h \
1169         linux/ucdrom.h \
1170         machine/cpu.h \
1171         mntent.h \
1172         netdb.h \
1173         netinet/in.h \
1174         netinet/in_systm.h \
1175         netinet/tcp.h \
1176         netinet/tcp_fsm.h \
1177         openssl/ssl.h \
1178         process.h \
1179         pthread.h \
1180         pty.h \
1181         pwd.h \
1182         regex.h \
1183         sched.h \
1184         scsi/sg.h \
1185         scsi/scsi.h \
1186         scsi/scsi_ioctl.h \
1187         socket.h \
1188         stdint.h \
1189         strings.h \
1190         sys/cdio.h \
1191         sys/elf32.h \
1192         sys/errno.h \
1193         sys/epoll.h \
1194         sys/exec_elf.h \
1195         sys/file.h \
1196         sys/filio.h \
1197         sys/inttypes.h \
1198         sys/ioctl.h \
1199         sys/ipc.h \
1200         sys/link.h \
1201         sys/lwp.h \
1202         sys/mman.h \
1203         sys/modem.h \
1204         sys/msg.h \
1205         sys/param.h \
1206         sys/poll.h \
1207         sys/ptrace.h \
1208         sys/reg.h \
1209         sys/scsiio.h \
1210         sys/shm.h \
1211         sys/signal.h \
1212         sys/socket.h \
1213         sys/sockio.h \
1214         sys/statfs.h \
1215         sys/statvfs.h \
1216         sys/strtio.h \
1217         sys/syscall.h \
1218         sys/sysctl.h \
1219         sys/time.h \
1220         sys/times.h \
1221         sys/uio.h \
1222         sys/un.h \
1223         sys/v86.h \
1224         sys/v86intr.h \
1225         sys/vfs.h \
1226         sys/vm86.h \
1227         sys/wait.h \
1228         syscall.h \
1229         termios.h \
1230         unistd.h \
1231         utime.h \
1232         valgrind/memcheck.h
1233 )
1234 AC_HEADER_STAT()
1235
1236 dnl **** Checks for headers that depend on other ones ****
1237
1238 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1239     [#include <sys/types.h>
1240      #if HAVE_SYS_PARAM_H
1241      # include <sys/param.h>
1242      #endif])
1243
1244 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1245     [#include <sys/types.h>
1246      #if HAVE_SYS_SOCKET_H
1247      # include <sys/socket.h>
1248      #endif])
1249
1250 AC_CHECK_HEADERS([resolv.h],,,
1251     [#include <sys/types.h>
1252      #if HAVE_SYS_SOCKET_H
1253      # include <sys/socket.h>
1254      #endif
1255      #if HAVE_NETINET_IN_H
1256      # include <netinet/in.h>
1257      #endif
1258      #if HAVE_ARPA_NAMESER_H
1259      # include <arpa/nameser.h>
1260      #endif])
1261
1262 AC_CHECK_HEADERS(netinet/ip.h,,,
1263     [#include <sys/types.h>
1264      #if HAVE_SYS_SOCKET_H
1265      # include <sys/socket.h>
1266      #endif
1267      #if HAVE_NETINET_IN_SYSTM_H
1268      # include <netinet/in_systm.h>
1269      #endif])
1270
1271 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1272
1273 dnl **** Check for IPX headers (currently Linux only) ****
1274
1275 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1276  AC_TRY_COMPILE(
1277    [#include <sys/types.h>
1278     #ifdef HAVE_SYS_SOCKET_H
1279     # include <sys/socket.h>
1280     #endif
1281     #include <netipx/ipx.h>],
1282    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1283    [ac_cv_c_ipx_gnu="yes"],
1284    [ac_cv_c_ipx_gnu="no"])
1285  )
1286 if test "$ac_cv_c_ipx_gnu" = "yes"
1287 then
1288     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1289 fi
1290
1291 if test "$ac_cv_c_ipx_gnu" = "no"
1292 then
1293  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1294   AC_TRY_COMPILE(
1295     [#include <sys/types.h>
1296      #ifdef HAVE_SYS_SOCKET_H
1297      # include <sys/socket.h>
1298      #endif
1299      #include <asm/types.h>
1300      #include <linux/ipx.h>],
1301     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1302     [ac_cv_c_ipx_linux="yes"],
1303     [ac_cv_c_ipx_linux="no"])
1304   )
1305   if test "$ac_cv_c_ipx_linux" = "yes"
1306   then
1307       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1308   fi
1309 fi
1310
1311 dnl **** Check for types ****
1312
1313 AC_C_CONST
1314 AC_C_INLINE
1315 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1316
1317 AC_CACHE_CHECK([whether linux/input.h is for real],
1318         wine_cv_linux_input_h,
1319         AC_TRY_COMPILE([
1320             #include <linux/input.h>
1321         ] , [
1322             int foo = EVIOCGBIT(EV_ABS,42);
1323             int bar = BTN_PINKIE;
1324             int fortytwo = 42;
1325         ],
1326         wine_cv_linux_input_h=yes,
1327         wine_cv_linux_input_h=no,
1328         no
1329         )
1330     )
1331     if test "$wine_cv_linux_input_h" = "yes"
1332     then
1333         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1334                   [Define if we have linux/input.h AND it contains the INPUT event API])
1335     fi
1336
1337
1338 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1339         wine_cv_linux_gethostbyname_r_6,
1340         AC_TRY_LINK([
1341 #include <netdb.h>
1342         ], [
1343     char *name=NULL;
1344     struct hostent he;
1345     struct hostent *result;
1346     char *buf=NULL;
1347     int bufsize=0;
1348     int res,errnr;
1349     char *addr=NULL;
1350     int addrlen=0;
1351     int addrtype=0;
1352     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1353     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1354     ],
1355         wine_cv_linux_gethostbyname_r_6=yes,
1356         wine_cv_linux_gethostbyname_r_6=no
1357         )
1358    )
1359    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1360    then
1361       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1362                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1363    fi
1364
1365 if test "$ac_cv_header_linux_joystick_h" = "yes"
1366 then
1367    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1368         wine_cv_linux_joystick_22_api,
1369         AC_TRY_COMPILE([
1370         #include <sys/ioctl.h>
1371         #include <linux/joystick.h>
1372
1373         struct js_event blub;
1374         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1375         #error "no 2.2 header"
1376         #endif
1377         ],/*empty*/,
1378         wine_cv_linux_joystick_22_api=yes,
1379         wine_cv_linux_joystick_22_api=no,
1380         wine_cv_linux_joystick_22_api=no
1381         )
1382    )
1383    if test "$wine_cv_linux_joystick_22_api" = "yes"
1384    then
1385       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1386                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1387    fi
1388 fi
1389
1390 dnl **** statfs checks ****
1391
1392 if test "$ac_cv_header_sys_vfs_h" = "yes"
1393 then
1394     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1395                     wine_cv_sys_vfs_has_statfs,
1396         AC_TRY_COMPILE([
1397         #include <sys/types.h>
1398         #ifdef HAVE_SYS_PARAM_H
1399         # include <sys/param.h>
1400         #endif
1401         #include <sys/vfs.h>
1402         ],[
1403                 struct statfs stfs;
1404
1405                 memset(&stfs,0,sizeof(stfs));
1406         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1407         )
1408     )
1409     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1410     then
1411       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1412                 [Define if the struct statfs is defined by <sys/vfs.h>])
1413     fi
1414 fi
1415
1416 if test "$ac_cv_header_sys_statfs_h" = "yes"
1417 then
1418     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1419                     wine_cv_sys_statfs_has_statfs,
1420         AC_TRY_COMPILE([
1421         #include <sys/types.h>
1422         #ifdef HAVE_SYS_PARAM_H
1423         # include <sys/param.h>
1424         #endif
1425         #include <sys/statfs.h>
1426         ],[
1427                 struct statfs stfs;
1428         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1429         )
1430     )
1431     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1432     then
1433       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1434                 [Define if the struct statfs is defined by <sys/statfs.h>])
1435     fi
1436 fi
1437
1438 if test "$ac_cv_header_sys_mount_h" = "yes"
1439 then
1440     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1441                     wine_cv_sys_mount_has_statfs,
1442         AC_TRY_COMPILE([
1443         #include <sys/types.h>
1444         #ifdef HAVE_SYS_PARAM_H
1445         # include <sys/param.h>
1446         #endif
1447         #include <sys/mount.h>
1448         ],[
1449                 struct statfs stfs;
1450         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1451         )
1452     )
1453     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1454     then
1455       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1456                 [Define if the struct statfs is defined by <sys/mount.h>])
1457     fi
1458 fi
1459
1460 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1461
1462 dnl Check for statfs members
1463 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1464 [#include <sys/types.h>
1465 #ifdef HAVE_SYS_PARAM_H
1466 # include <sys/param.h>
1467 #endif
1468 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1469 # include <sys/mount.h>
1470 #else
1471 # ifdef STATFS_DEFINED_BY_SYS_VFS
1472 #  include <sys/vfs.h>
1473 # else
1474 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1475 #   include <sys/statfs.h>
1476 #  endif
1477 # endif
1478 #endif])
1479
1480 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1481 [#ifdef HAVE_SYS_STATVFS_H
1482 #include <sys/statvfs.h>
1483 #endif])
1484
1485 dnl Check for socket structure members
1486 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1487 [#include <sys/types.h>
1488 #ifdef HAVE_SYS_SOCKET_H
1489 # include <sys/socket.h>
1490 #endif
1491 #ifdef HAVE_SYS_UN_H
1492 # include <sys/un.h>
1493 #endif])
1494
1495 dnl Check for siginfo_t members
1496 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1497
1498 dnl Check for struct option
1499 AC_CHECK_MEMBERS([struct option.name],,,
1500 [#ifdef HAVE_GETOPT_H
1501 #include <getopt.h>
1502 #endif])
1503
1504 dnl Check for stat.st_blocks
1505 AC_CHECK_MEMBERS([struct stat.st_blocks])
1506
1507 dnl *** check for the need to define platform-specific symbols
1508
1509 case $host_cpu in
1510   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1511   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1512   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1513   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1514 esac
1515
1516 case $host_vendor in
1517   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1518 esac
1519
1520 dnl **** Generate output files ****
1521
1522 AH_TOP([#define __WINE_CONFIG_H])
1523
1524 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1525 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1526 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1527 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1528 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1529 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1530 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1531 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1532 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1533 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1534 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1535 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1536 WINE_CONFIG_EXTRA_DIR(include/wine)
1537 WINE_CONFIG_EXTRA_DIR(misc)
1538 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1539 WINE_CONFIG_EXTRA_DIR(windows)
1540
1541 MAKE_RULES=Make.rules
1542 AC_SUBST_FILE(MAKE_RULES)
1543
1544 MAKE_DLL_RULES=dlls/Makedll.rules
1545 AC_SUBST_FILE(MAKE_DLL_RULES)
1546
1547 MAKE_TEST_RULES=dlls/Maketest.rules
1548 AC_SUBST_FILE(MAKE_TEST_RULES)
1549
1550 MAKE_LIB_RULES=libs/Makelib.rules
1551 AC_SUBST_FILE(MAKE_LIB_RULES)
1552
1553 MAKE_PROG_RULES=programs/Makeprog.rules
1554 AC_SUBST_FILE(MAKE_PROG_RULES)
1555
1556 AC_CONFIG_FILES([
1557 Make.rules
1558 dlls/Makedll.rules
1559 dlls/Maketest.rules
1560 libs/Makelib.rules
1561 programs/Makeprog.rules
1562 Makefile
1563 dlls/Makefile
1564 dlls/advapi32/Makefile
1565 dlls/advapi32/tests/Makefile
1566 dlls/advpack/Makefile
1567 dlls/amstream/Makefile
1568 dlls/atl/Makefile
1569 dlls/avicap32/Makefile
1570 dlls/avifil32/Makefile
1571 dlls/cabinet/Makefile
1572 dlls/capi2032/Makefile
1573 dlls/cards/Makefile
1574 dlls/cfgmgr32/Makefile
1575 dlls/comcat/Makefile
1576 dlls/comctl32/Makefile
1577 dlls/comctl32/tests/Makefile
1578 dlls/commdlg/Makefile
1579 dlls/crtdll/Makefile
1580 dlls/crypt32/Makefile
1581 dlls/ctl3d/Makefile
1582 dlls/d3d8/Makefile
1583 dlls/d3d9/Makefile
1584 dlls/d3dim/Makefile
1585 dlls/d3drm/Makefile
1586 dlls/d3dx8/Makefile
1587 dlls/d3dxof/Makefile
1588 dlls/dbghelp/Makefile
1589 dlls/dciman32/Makefile
1590 dlls/ddraw/Makefile
1591 dlls/ddraw/tests/Makefile
1592 dlls/devenum/Makefile
1593 dlls/dinput/Makefile
1594 dlls/dinput8/Makefile
1595 dlls/dmband/Makefile
1596 dlls/dmcompos/Makefile
1597 dlls/dmime/Makefile
1598 dlls/dmloader/Makefile
1599 dlls/dmscript/Makefile
1600 dlls/dmstyle/Makefile
1601 dlls/dmsynth/Makefile
1602 dlls/dmusic/Makefile
1603 dlls/dmusic32/Makefile
1604 dlls/dplay/Makefile
1605 dlls/dplayx/Makefile
1606 dlls/dpnet/Makefile
1607 dlls/dpnhpast/Makefile
1608 dlls/dsound/Makefile
1609 dlls/dsound/tests/Makefile
1610 dlls/dswave/Makefile
1611 dlls/dxdiagn/Makefile
1612 dlls/dxerr8/Makefile
1613 dlls/dxerr9/Makefile
1614 dlls/dxguid/Makefile
1615 dlls/gdi/Makefile
1616 dlls/gdi/tests/Makefile
1617 dlls/glu32/Makefile
1618 dlls/glut32/Makefile
1619 dlls/hhctrl.ocx/Makefile
1620 dlls/iccvid/Makefile
1621 dlls/icmp/Makefile
1622 dlls/ifsmgr.vxd/Makefile
1623 dlls/imagehlp/Makefile
1624 dlls/imm32/Makefile
1625 dlls/iphlpapi/Makefile
1626 dlls/iphlpapi/tests/Makefile
1627 dlls/itss/Makefile
1628 dlls/kernel/Makefile
1629 dlls/kernel/tests/Makefile
1630 dlls/lzexpand/Makefile
1631 dlls/mapi32/Makefile
1632 dlls/mapi32/tests/Makefile
1633 dlls/mlang/Makefile
1634 dlls/mlang/tests/Makefile
1635 dlls/mmdevldr.vxd/Makefile
1636 dlls/monodebg.vxd/Makefile
1637 dlls/mpr/Makefile
1638 dlls/msacm/Makefile
1639 dlls/msacm/imaadp32/Makefile
1640 dlls/msacm/msadp32/Makefile
1641 dlls/msacm/msg711/Makefile
1642 dlls/msacm/winemp3/Makefile
1643 dlls/msacm/tests/Makefile
1644 dlls/mscms/Makefile
1645 dlls/mscms/tests/Makefile
1646 dlls/msdmo/Makefile
1647 dlls/mshtml/Makefile
1648 dlls/msi/Makefile
1649 dlls/msimg32/Makefile
1650 dlls/msisys/Makefile
1651 dlls/msnet32/Makefile
1652 dlls/msrle32/Makefile
1653 dlls/msvcrt/Makefile
1654 dlls/msvcrt/tests/Makefile
1655 dlls/msvcrt20/Makefile
1656 dlls/msvcrt40/Makefile
1657 dlls/msvcrtd/Makefile
1658 dlls/msvcrtd/tests/Makefile
1659 dlls/msvidc32/Makefile
1660 dlls/msvideo/Makefile
1661 dlls/mswsock/Makefile
1662 dlls/netapi32/Makefile
1663 dlls/netapi32/tests/Makefile
1664 dlls/newdev/Makefile
1665 dlls/ntdll/Makefile
1666 dlls/ntdll/tests/Makefile
1667 dlls/odbc32/Makefile
1668 dlls/ole32/Makefile
1669 dlls/ole32/tests/Makefile
1670 dlls/oleacc/Makefile
1671 dlls/oleaut32/Makefile
1672 dlls/oleaut32/tests/Makefile
1673 dlls/olecli/Makefile
1674 dlls/oledlg/Makefile
1675 dlls/olepro32/Makefile
1676 dlls/olesvr/Makefile
1677 dlls/opengl32/Makefile
1678 dlls/psapi/Makefile
1679 dlls/psapi/tests/Makefile
1680 dlls/qcap/Makefile
1681 dlls/quartz/Makefile
1682 dlls/quartz/tests/Makefile
1683 dlls/rasapi32/Makefile
1684 dlls/richedit/Makefile
1685 dlls/rpcrt4/Makefile
1686 dlls/rpcrt4/tests/Makefile
1687 dlls/rsabase/Makefile
1688 dlls/rsabase/tests/Makefile
1689 dlls/secur32/Makefile
1690 dlls/serialui/Makefile
1691 dlls/setupapi/Makefile
1692 dlls/shdocvw/Makefile
1693 dlls/shell32/Makefile
1694 dlls/shell32/tests/Makefile
1695 dlls/shfolder/Makefile
1696 dlls/shlwapi/Makefile
1697 dlls/shlwapi/tests/Makefile
1698 dlls/snmpapi/Makefile
1699 dlls/sti/Makefile
1700 dlls/strmiids/Makefile
1701 dlls/tapi32/Makefile
1702 dlls/ttydrv/Makefile
1703 dlls/twain/Makefile
1704 dlls/unicows/Makefile
1705 dlls/url/Makefile
1706 dlls/urlmon/Makefile
1707 dlls/urlmon/tests/Makefile
1708 dlls/user/Makefile
1709 dlls/user/tests/Makefile
1710 dlls/uuid/Makefile
1711 dlls/uxtheme/Makefile
1712 dlls/vdhcp.vxd/Makefile
1713 dlls/vdmdbg/Makefile
1714 dlls/version/Makefile
1715 dlls/version/tests/Makefile
1716 dlls/vmm.vxd/Makefile
1717 dlls/vnbt.vxd/Makefile
1718 dlls/vnetbios.vxd/Makefile
1719 dlls/vtdapi.vxd/Makefile
1720 dlls/vwin32.vxd/Makefile
1721 dlls/win32s/Makefile
1722 dlls/winaspi/Makefile
1723 dlls/wined3d/Makefile
1724 dlls/winedos/Makefile
1725 dlls/wineps/Makefile
1726 dlls/wininet/Makefile
1727 dlls/wininet/tests/Makefile
1728 dlls/winmm/Makefile
1729 dlls/winmm/joystick/Makefile
1730 dlls/winmm/mcianim/Makefile
1731 dlls/winmm/mciavi/Makefile
1732 dlls/winmm/mcicda/Makefile
1733 dlls/winmm/mciseq/Makefile
1734 dlls/winmm/mciwave/Makefile
1735 dlls/winmm/midimap/Makefile
1736 dlls/winmm/tests/Makefile
1737 dlls/winmm/wavemap/Makefile
1738 dlls/winmm/winealsa/Makefile
1739 dlls/winmm/winearts/Makefile
1740 dlls/winmm/wineaudioio/Makefile
1741 dlls/winmm/winejack/Makefile
1742 dlls/winmm/winenas/Makefile
1743 dlls/winmm/wineoss/Makefile
1744 dlls/winnls/Makefile
1745 dlls/winsock/Makefile
1746 dlls/winsock/tests/Makefile
1747 dlls/winspool/Makefile
1748 dlls/winspool/tests/Makefile
1749 dlls/wintab32/Makefile
1750 dlls/wintrust/Makefile
1751 dlls/wow32/Makefile
1752 dlls/wsock32/Makefile
1753 dlls/x11drv/Makefile
1754 documentation/Makefile
1755 fonts/Makefile
1756 include/Makefile
1757 libs/Makefile
1758 libs/port/Makefile
1759 libs/unicode/Makefile
1760 libs/wine/Makefile
1761 libs/wpp/Makefile
1762 loader/Makefile
1763 programs/Makefile
1764 programs/avitools/Makefile
1765 programs/clock/Makefile
1766 programs/cmdlgtst/Makefile
1767 programs/control/Makefile
1768 programs/expand/Makefile
1769 programs/msiexec/Makefile
1770 programs/notepad/Makefile
1771 programs/progman/Makefile
1772 programs/regedit/Makefile
1773 programs/regsvr32/Makefile
1774 programs/rpcss/Makefile
1775 programs/rundll32/Makefile
1776 programs/start/Makefile
1777 programs/taskmgr/Makefile
1778 programs/uninstaller/Makefile
1779 programs/view/Makefile
1780 programs/wcmd/Makefile
1781 programs/wineboot/Makefile
1782 programs/winebrowser/Makefile
1783 programs/winecfg/Makefile
1784 programs/wineconsole/Makefile
1785 programs/winedbg/Makefile
1786 programs/winefile/Makefile
1787 programs/winemenubuilder/Makefile
1788 programs/winemine/Makefile
1789 programs/winepath/Makefile
1790 programs/winetest/Makefile
1791 programs/winevdm/Makefile
1792 programs/winhelp/Makefile
1793 programs/winver/Makefile
1794 server/Makefile
1795 tools/Makefile
1796 tools/widl/Makefile
1797 tools/winapi/Makefile
1798 tools/winebuild/Makefile
1799 tools/winedump/Makefile
1800 tools/winegcc/Makefile
1801 tools/wmc/Makefile
1802 tools/wrc/Makefile])
1803
1804 AC_OUTPUT
1805
1806 if test "$have_x" = "no"
1807 then
1808   echo
1809   echo "*** Warning: X development files not found. Wine will be built without"
1810   echo "*** X support, which currently does not work, and would probably not be"
1811   echo "*** what you want anyway. You will need to install devel packages of"
1812   echo "*** Xlib/Xfree86 at the very least."
1813 fi
1814
1815 if test "$wine_cv_opengl_version_OK" = "no"
1816 then
1817   echo
1818   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1819   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1820 fi
1821
1822 if test "$wine_cv_msg_freetype" = "yes"
1823 then
1824   echo
1825   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1826   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1827   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1828   echo "*** enable Wine to use TrueType fonts."
1829 fi
1830
1831 echo
1832 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1833 echo
1834
1835 dnl Local Variables:
1836 dnl comment-start: "dnl "
1837 dnl comment-end: ""
1838 dnl comment-start-skip: "\\bdnl\\b\\s *"
1839 dnl compile-command: "autoconf"
1840 dnl End: