git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41 #include "typegen.h"
  42
  43 #if defined(YYBYACC)
  44         /* Berkeley yacc (byacc) doesn't seem to know about these */
  45         /* Some *BSD supplied versions do define these though */
  46 # ifndef YYEMPTY
  47 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  48 # endif
  49 # ifndef YYLEX
  50 #  define YYLEX         yylex()
  51 # endif
  52
  53 #elif defined(YYBISON)
  54         /* Bison was used for original development */
  55         /* #define YYEMPTY -2 */
  56         /* #define YYLEX   yylex() */
  57
  58 #else
  59         /* No yacc we know yet */
  60 # if !defined(YYEMPTY) || !defined(YYLEX)
  61 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  62 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  63 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  64   /* #else we just take a chance that it works... */
  65 # endif
  66 #endif
  67
  68 unsigned char pointer_default = RPC_FC_UP;
  69
  70 typedef struct list typelist_t;
  71 struct typenode {
  72   type_t *type;
  73   struct list entry;
  74 };
  75
  76 typelist_t incomplete_types = LIST_INIT(incomplete_types);
  77
  78 static void add_incomplete(type_t *t);
  79 static void fix_incomplete(void);
  80
  81 static str_list_t *append_str(str_list_t *list, char *str);
  82 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr);
  83 static attr_t *make_attr(enum attr_type type);
  84 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  85 static attr_t *make_attrp(enum attr_type type, void *val);
  86 static expr_t *make_expr(enum expr_type type);
  87 static expr_t *make_exprl(enum expr_type type, long val);
  88 static expr_t *make_exprd(enum expr_type type, double val);
  89 static expr_t *make_exprs(enum expr_type type, char *val);
  90 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr);
  91 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  92 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  93 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  94 static type_t *make_type(unsigned char type, type_t *ref);
  95 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr);
  96 static array_dims_t *append_array(array_dims_t *list, expr_t *expr);
  97 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr, int top);
  98 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface);
  99 static ifref_t *make_ifref(type_t *iface);
 100 static var_list_t *append_var(var_list_t *list, var_t *var);
 101 static var_t *make_var(char *name);
 102 static pident_list_t *append_pident(pident_list_t *list, pident_t *p);
 103 static pident_t *make_pident(var_t *var);
 104 static func_list_t *append_func(func_list_t *list, func_t *func);
 105 static func_t *make_func(var_t *def, var_list_t *args);
 106 static type_t *make_class(char *name);
 107 static type_t *make_safearray(type_t *type);
 108 static type_t *make_builtin(char *name);
 109 static type_t *make_int(int sign);
 110
 111 static type_t *reg_type(type_t *type, const char *name, int t);
 112 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs);
 113 static type_t *find_type(const char *name, int t);
 114 static type_t *find_type2(char *name, int t);
 115 static type_t *get_type(unsigned char type, char *name, int t);
 116 static type_t *get_typev(unsigned char type, var_t *name, int t);
 117 static int get_struct_type(var_list_t *fields);
 118
 119 static var_t *reg_const(var_t *var);
 120 static var_t *find_const(char *name, int f);
 121
 122 static void write_libid(const char *name, const attr_list_t *attr);
 123 static void write_clsid(type_t *cls);
 124 static void write_diid(type_t *iface);
 125 static void write_iid(type_t *iface);
 126
 127 static int compute_method_indexes(type_t *iface);
 128 static char *gen_name(void);
 129 static void process_typedefs(var_list_t *names);
 130 static void check_arg(var_t *arg);
 131 static void check_all_user_types(ifref_list_t *ifaces);
 132
 133 #define tsENUM   1
 134 #define tsSTRUCT 2
 135 #define tsUNION  3
 136
 137 %}
 138 %union {
 139         attr_t *attr;
 140         attr_list_t *attr_list;
 141         str_list_t *str_list;
 142         expr_t *expr;
 143         expr_list_t *expr_list;
 144         array_dims_t *array_dims;
 145         type_t *type;
 146         var_t *var;
 147         var_list_t *var_list;
 148         pident_t *pident;
 149         pident_list_t *pident_list;
 150         func_t *func;
 151         func_list_t *func_list;
 152         ifref_t *ifref;
 153         ifref_list_t *ifref_list;
 154         char *str;
 155         UUID *uuid;
 156         unsigned int num;
 157         double dbl;
 158 }
 159
 160 %token <str> aIDENTIFIER
 161 %token <str> aKNOWNTYPE
 162 %token <num> aNUM aHEXNUM
 163 %token <dbl> aDOUBLE
 164 %token <str> aSTRING
 165 %token <uuid> aUUID
 166 %token aEOF
 167 %token SHL SHR
 168 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 169 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 170 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 171 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 172 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 173 %token tDEFAULT
 174 %token tDEFAULTCOLLELEM
 175 %token tDEFAULTVALUE
 176 %token tDEFAULTVTABLE
 177 %token tDISPLAYBIND
 178 %token tDISPINTERFACE
 179 %token tDLLNAME tDOUBLE tDUAL
 180 %token tENDPOINT
 181 %token tENTRY tENUM tERRORSTATUST
 182 %token tEXPLICITHANDLE tEXTERN
 183 %token tFALSE
 184 %token tFLOAT
 185 %token tHANDLE
 186 %token tHANDLET
 187 %token tHELPCONTEXT tHELPFILE
 188 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 189 %token tHIDDEN
 190 %token tHYPER tID tIDEMPOTENT
 191 %token tIIDIS
 192 %token tIMMEDIATEBIND
 193 %token tIMPLICITHANDLE
 194 %token tIMPORT tIMPORTLIB
 195 %token tIN tINLINE
 196 %token tINPUTSYNC
 197 %token tINT tINT64
 198 %token tINTERFACE
 199 %token tLCID
 200 %token tLENGTHIS tLIBRARY
 201 %token tLOCAL
 202 %token tLONG
 203 %token tMETHODS
 204 %token tMODULE
 205 %token tNONBROWSABLE
 206 %token tNONCREATABLE
 207 %token tNONEXTENSIBLE
 208 %token tOBJECT tODL tOLEAUTOMATION
 209 %token tOPTIONAL
 210 %token tOUT
 211 %token tPOINTERDEFAULT
 212 %token tPROPERTIES
 213 %token tPROPGET tPROPPUT tPROPPUTREF
 214 %token tPTR
 215 %token tPUBLIC
 216 %token tRANGE
 217 %token tREADONLY tREF
 218 %token tREQUESTEDIT
 219 %token tRESTRICTED
 220 %token tRETVAL
 221 %token tSAFEARRAY
 222 %token tSHORT
 223 %token tSIGNED
 224 %token tSINGLE
 225 %token tSIZEIS tSIZEOF
 226 %token tSMALL
 227 %token tSOURCE
 228 %token tSTDCALL
 229 %token tSTRING tSTRUCT
 230 %token tSWITCH tSWITCHIS tSWITCHTYPE
 231 %token tTRANSMITAS
 232 %token tTRUE
 233 %token tTYPEDEF
 234 %token tUNION
 235 %token tUNIQUE
 236 %token tUNSIGNED
 237 %token tUUID
 238 %token tV1ENUM
 239 %token tVARARG
 240 %token tVERSION
 241 %token tVOID
 242 %token tWCHAR tWIREMARSHAL
 243
 244 %type <attr> attribute
 245 %type <attr_list> m_attributes attributes attrib_list
 246 %type <str_list> str_list
 247 %type <expr> m_expr expr expr_const
 248 %type <expr_list> m_exprs /* exprs expr_list */ expr_list_const
 249 %type <array_dims> array array_list
 250 %type <type> inherit interface interfacehdr interfacedef interfacedec
 251 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 252 %type <type> module modulehdr moduledef
 253 %type <type> base_type int_std
 254 %type <type> enumdef structdef uniondef
 255 %type <type> type
 256 %type <ifref> coclass_int
 257 %type <ifref_list> gbl_statements coclass_ints
 258 %type <var> arg field s_field case enum constdef externdef
 259 %type <var_list> m_args no_args args fields cases enums enum_list dispint_props
 260 %type <var> m_ident t_ident ident
 261 %type <pident> p_ident pident
 262 %type <pident_list> pident_list
 263 %type <func> funcdef
 264 %type <func_list> int_statements dispint_meths
 265 %type <type> coclass coclasshdr coclassdef
 266 %type <num> pointer_type version
 267 %type <str> libraryhdr
 268
 269 %left ','
 270 %right '?' ':'
 271 %left '|'
 272 %left '&'
 273 %left '-' '+'
 274 %left '*' '/'
 275 %left SHL SHR
 276 %right '~'
 277 %right CAST
 278 %right PPTR
 279 %right NEG
 280
 281 %%
 282
 283 input:   gbl_statements                         { fix_incomplete();
 284                                                   check_all_user_types($1);
 285                                                   write_proxies($1);
 286                                                   write_client($1);
 287                                                   write_server($1);
 288                                                 }
 289         ;
 290
 291 gbl_statements:                                 { $$ = NULL; }
 292         | gbl_statements interfacedec           { $$ = $1; }
 293         | gbl_statements interfacedef           { $$ = append_ifref( $1, make_ifref($2) ); }
 294         | gbl_statements coclass ';'            { $$ = $1;
 295                                                   reg_type($2, $2->name, 0);
 296                                                   if (!parse_only && do_header) write_coclass_forward($2);
 297                                                 }
 298         | gbl_statements coclassdef             { $$ = $1;
 299                                                   add_typelib_entry($2);
 300                                                   reg_type($2, $2->name, 0);
 301                                                   if (!parse_only && do_header) write_coclass_forward($2);
 302                                                 }
 303         | gbl_statements moduledef              { $$ = $1; add_typelib_entry($2); }
 304         | gbl_statements librarydef             { $$ = $1; }
 305         | gbl_statements statement              { $$ = $1; }
 306         ;
 307
 308 imp_statements:                                 {}
 309         | imp_statements interfacedec           { if (!parse_only) add_typelib_entry($2); }
 310         | imp_statements interfacedef           { if (!parse_only) add_typelib_entry($2); }
 311         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 312         | imp_statements coclassdef             { if (!parse_only) add_typelib_entry($2);
 313                                                   reg_type($2, $2->name, 0);
 314                                                   if (!parse_only && do_header) write_coclass_forward($2);
 315                                                 }
 316         | imp_statements moduledef              { if (!parse_only) add_typelib_entry($2); }
 317         | imp_statements statement              {}
 318         | imp_statements importlib              {}
 319         ;
 320
 321 int_statements:                                 { $$ = NULL; }
 322         | int_statements funcdef ';'            { $$ = append_func( $1, $2 ); }
 323         | int_statements statement              { $$ = $1; }
 324         ;
 325
 326 statement: ';'                                  {}
 327         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 328         | cppquote                              {}
 329         | enumdef ';'                           { if (!parse_only && do_header) {
 330                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 331                                                     fprintf(header, ";\n\n");
 332                                                   }
 333                                                 }
 334         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 335         | import                                {}
 336         | structdef ';'                         { if (!parse_only && do_header) {
 337                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 338                                                     fprintf(header, ";\n\n");
 339                                                   }
 340                                                 }
 341         | typedef ';'                           {}
 342         | uniondef ';'                          { if (!parse_only && do_header) {
 343                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 344                                                     fprintf(header, ";\n\n");
 345                                                   }
 346                                                 }
 347         ;
 348
 349 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 350         ;
 351 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 352                                                   if (!do_import($2)) yychar = aEOF; }
 353         ;
 354 import:   import_start imp_statements aEOF      {}
 355         ;
 356
 357 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 358         ;
 359
 360 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 361         ;
 362 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 363                                                   if (!parse_only && do_header) write_library($2, $1);
 364                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 365                                                 }
 366         ;
 367 librarydef: library_start imp_statements '}'    { end_typelib(); }
 368         ;
 369
 370 m_args:                                         { $$ = NULL; }
 371         | args
 372         ;
 373
 374 no_args:  tVOID                                 { $$ = NULL; }
 375         ;
 376
 377 args:     arg                                   { check_arg($1); $$ = append_var( NULL, $1 ); }
 378         | args ',' arg                          { check_arg($3); $$ = append_var( $1, $3); }
 379         | no_args
 380         ;
 381
 382 /* split into two rules to get bison to resolve a tVOID conflict */
 383 arg:      attributes type pident array          { $$ = $3->var;
 384                                                   $$->attrs = $1;
 385                                                   set_type($$, $2, $3->ptr_level, $4, TRUE);
 386                                                   free($3);
 387                                                 }
 388         | type pident array                     { $$ = $2->var;
 389                                                   set_type($$, $1, $2->ptr_level, $3, TRUE);
 390                                                   free($2);
 391                                                 }
 392         | attributes type pident '(' m_args ')' { $$ = $3->var;
 393                                                   $$->attrs = $1;
 394                                                   set_type($$, $2, $3->ptr_level - 1, NULL, TRUE);
 395                                                   free($3);
 396                                                   $$->args = $5;
 397                                                 }
 398         | type pident '(' m_args ')'            { $$ = $2->var;
 399                                                   set_type($$, $1, $2->ptr_level - 1, NULL, TRUE);
 400                                                   free($2);
 401                                                   $$->args = $4;
 402                                                 }
 403         ;
 404
 405 array:                                          { $$ = NULL; }
 406         | '[' array_list ']'                    { $$ = $2; }
 407         | '[' '*' ']'                           { $$ = append_array( NULL, make_expr(EXPR_VOID) ); }
 408         ;
 409
 410 array_list: m_expr /* size of first dimension is optional */ { $$ = append_array( NULL, $1 ); }
 411         | array_list ',' expr                   { $$ = append_array( $1, $3 ); }
 412         | array_list ']' '[' expr               { $$ = append_array( $1, $4 ); }
 413         ;
 414
 415 m_attributes:                                   { $$ = NULL; }
 416         | attributes
 417         ;
 418
 419 attributes:
 420           '[' attrib_list ']'                   { $$ = $2;
 421                                                   if (!$$)
 422                                                     yyerror("empty attribute lists unsupported");
 423                                                 }
 424         ;
 425
 426 attrib_list: attribute                          { $$ = append_attr( NULL, $1 ); }
 427         | attrib_list ',' attribute             { $$ = append_attr( $1, $3 ); }
 428         | attrib_list ']' '[' attribute         { $$ = append_attr( $1, $4 ); }
 429         ;
 430
 431 str_list: aSTRING                               { $$ = append_str( NULL, $1 ); }
 432         | str_list ',' aSTRING                  { $$ = append_str( $1, $3 ); }
 433         ;
 434
 435 attribute:                                      { $$ = NULL; }
 436         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 437         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 438         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 439         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 440         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 441         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 442         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 443         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 444         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 445         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 446         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 447         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 448         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 449         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 450         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 451         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 452         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 453         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 454         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 455         | tENDPOINT '(' str_list ')'            { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 456         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 457         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 458         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 459         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 460         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 461         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 462         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 463         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 464         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 465         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 466         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 467         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 468         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 469         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 470         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 471         | tIN                                   { $$ = make_attr(ATTR_IN); }
 472         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 473         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 474         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 475         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 476         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 477         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 478         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 479         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 480         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 481         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 482         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 483         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 484         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 485         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 486         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 487         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 488         | tRANGE '(' expr_const ',' expr_const ')' { expr_list_t *list = append_expr( NULL, $3 );
 489                                                      list = append_expr( list, $5 );
 490                                                      $$ = make_attrp(ATTR_RANGE, list); }
 491         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 492         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 493         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 494         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 495         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 496         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 497         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 498         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 499         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, $3); }
 500         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, $3); }
 501         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 502         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 503         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 504         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 505         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, $3); }
 506         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 507         ;
 508
 509 callconv:
 510         | tSTDCALL
 511         ;
 512
 513 cases:                                          { $$ = NULL; }
 514         | cases case                            { $$ = append_var( $1, $2 ); }
 515         ;
 516
 517 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, append_expr( NULL, $2 ));
 518                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 519                                                   $$->attrs = append_attr( $$->attrs, a );
 520                                                 }
 521         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 522                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 523                                                   $$->attrs = append_attr( $$->attrs, a );
 524                                                 }
 525         ;
 526
 527 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 528                                                   set_type($$, $2, 0, NULL, FALSE);
 529                                                   $$->eval = $5;
 530                                                 }
 531         ;
 532
 533 enums:                                          { $$ = NULL; }
 534         | enum_list ','                         { $$ = $1; }
 535         | enum_list
 536         ;
 537
 538 enum_list: enum                                 { if (!$1->eval)
 539                                                     $1->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 540                                                   $$ = append_var( NULL, $1 );
 541                                                 }
 542         | enum_list ',' enum                    { if (!$3->eval)
 543                                                   {
 544                                                     var_t *last = LIST_ENTRY( list_tail($$), var_t, entry );
 545                                                     $3->eval = make_exprl(EXPR_NUM, last->eval->cval + 1);
 546                                                   }
 547                                                   $$ = append_var( $1, $3 );
 548                                                 }
 549         ;
 550
 551 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 552                                                   $$->eval = $3;
 553                                                   $$->type = make_int(0);
 554                                                 }
 555         | ident                                 { $$ = reg_const($1);
 556                                                   $$->type = make_int(0);
 557                                                 }
 558         ;
 559
 560 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 561                                                   $$->kind = TKIND_ENUM;
 562                                                   $$->fields = $4;
 563                                                   $$->defined = TRUE;
 564                                                   if(in_typelib)
 565                                                       add_typelib_entry($$);
 566                                                 }
 567         ;
 568
 569 m_exprs:  m_expr                                { $$ = append_expr( NULL, $1 ); }
 570         | m_exprs ',' m_expr                    { $$ = append_expr( $1, $3 ); }
 571         ;
 572
 573 /*
 574 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 575         | expr_list
 576         ;
 577
 578 expr_list: expr
 579         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 580         ;
 581 */
 582
 583 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 584         | expr
 585         ;
 586
 587 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 588         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 589         | aDOUBLE                               { $$ = make_exprd(EXPR_DOUBLE, $1); }
 590         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 591         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 592         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 593         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 594         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 595         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 596         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 597         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 598         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 599         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 600         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 601         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 602         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 603         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 604         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 605         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 606         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 607         | '(' expr ')'                          { $$ = $2; }
 608         ;
 609
 610 expr_list_const: expr_const                     { $$ = append_expr( NULL, $1 ); }
 611         | expr_list_const ',' expr_const        { $$ = append_expr( $1, $3 ); }
 612         ;
 613
 614 expr_const: expr                                { $$ = $1;
 615                                                   if (!$$->is_const)
 616                                                       yyerror("expression is not constant");
 617                                                 }
 618         ;
 619
 620 externdef: tEXTERN tCONST type ident            { $$ = $4;
 621                                                   set_type($$, $3, 0, NULL, FALSE);
 622                                                 }
 623         ;
 624
 625 fields:                                         { $$ = NULL; }
 626         | fields field                          { $$ = append_var( $1, $2 ); }
 627         ;
 628
 629 field:    s_field ';'                           { $$ = $1; }
 630         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 631         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 632         | ';'                                   { $$ = NULL; }
 633         ;
 634
 635 s_field:  m_attributes type pident array        { $$ = $3->var;
 636                                                   $$->attrs = $1;
 637                                                   set_type($$, $2, $3->ptr_level, $4, FALSE);
 638                                                   free($3);
 639                                                 }
 640         ;
 641
 642 funcdef:
 643           m_attributes type callconv pident
 644           '(' m_args ')'                        { var_t *v = $4->var;
 645                                                   v->attrs = $1;
 646                                                   set_type(v, $2, $4->ptr_level, NULL, FALSE);
 647                                                   free($4);
 648                                                   $$ = make_func(v, $6);
 649                                                   if (is_attr(v->attrs, ATTR_IN)) {
 650                                                     yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
 651                                                   }
 652                                                 }
 653         ;
 654
 655 m_ident:                                        { $$ = NULL; }
 656         | ident
 657         ;
 658
 659 t_ident:                                        { $$ = NULL; }
 660         | aIDENTIFIER                           { $$ = make_var($1); }
 661         | aKNOWNTYPE                            { $$ = make_var($1); }
 662         ;
 663
 664 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 665 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 666         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 667         ;
 668
 669 base_type: tBYTE                                { $$ = make_builtin($<str>1); }
 670         | tWCHAR                                { $$ = make_builtin($<str>1); }
 671         | int_std
 672         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 673         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 674                                                   switch ($$->type) {
 675                                                   case RPC_FC_CHAR:  break;
 676                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 677                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 678                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 679                                                   case RPC_FC_HYPER:
 680                                                     if ($$->name[0] == 'h') /* hyper, as opposed to __int64 */
 681                                                     {
 682                                                       $$ = alias($$, "MIDL_uhyper");
 683                                                       $$->sign = 0;
 684                                                     }
 685                                                     break;
 686                                                   default: break;
 687                                                   }
 688                                                 }
 689         | tUNSIGNED                             { $$ = make_int(-1); }
 690         | tFLOAT                                { $$ = make_builtin($<str>1); }
 691         | tSINGLE                               { $$ = duptype(find_type("float", 0), 1); }
 692         | tDOUBLE                               { $$ = make_builtin($<str>1); }
 693         | tBOOLEAN                              { $$ = make_builtin($<str>1); }
 694         | tERRORSTATUST                         { $$ = make_builtin($<str>1); }
 695         | tHANDLET                              { $$ = make_builtin($<str>1); }
 696         ;
 697
 698 m_int:
 699         | tINT
 700         ;
 701
 702 int_std:  tINT                                  { $$ = make_builtin($<str>1); }
 703         | tSHORT m_int                          { $$ = make_builtin($<str>1); }
 704         | tSMALL                                { $$ = make_builtin($<str>1); }
 705         | tLONG m_int                           { $$ = make_builtin($<str>1); }
 706         | tHYPER m_int                          { $$ = make_builtin($<str>1); }
 707         | tINT64                                { $$ = make_builtin($<str>1); }
 708         | tCHAR                                 { $$ = make_builtin($<str>1); }
 709         ;
 710
 711 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 712         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 713                                                   if ($$->defined) yyerror("multiple definition error");
 714                                                   if ($$->kind != TKIND_COCLASS) yyerror("%s was not declared a coclass", $2);
 715                                                 }
 716         ;
 717
 718 coclasshdr: attributes coclass                  { $$ = $2;
 719                                                   $$->attrs = $1;
 720                                                   if (!parse_only && do_header)
 721                                                     write_coclass($$);
 722                                                   if (!parse_only && do_idfile)
 723                                                     write_clsid($$);
 724                                                 }
 725         ;
 726
 727 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 728                                                   $$->ifaces = $3;
 729                                                   $$->defined = TRUE;
 730                                                 }
 731         ;
 732
 733 coclass_ints:                                   { $$ = NULL; }
 734         | coclass_ints coclass_int              { $$ = append_ifref( $1, $2 ); }
 735         ;
 736
 737 coclass_int:
 738           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 739         ;
 740
 741 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 742         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 743         ;
 744
 745 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 746                                                   $$ = $2;
 747                                                   if ($$->defined) yyerror("multiple definition error");
 748                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 749                                                   $$->attrs = append_attr( $1, attrs );
 750                                                   $$->ref = find_type("IDispatch", 0);
 751                                                   if (!$$->ref) yyerror("IDispatch is undefined");
 752                                                   $$->defined = TRUE;
 753                                                   if (!parse_only && do_header) write_forward($$);
 754                                                 }
 755         ;
 756
 757 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 758         | dispint_props s_field ';'             { $$ = append_var( $1, $2 ); }
 759         ;
 760
 761 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 762         | dispint_meths funcdef ';'             { $$ = append_func( $1, $2 ); }
 763         ;
 764
 765 dispinterfacedef: dispinterfacehdr '{'
 766           dispint_props
 767           dispint_meths
 768           '}'                                   { $$ = $1;
 769                                                   $$->fields = $3;
 770                                                   $$->funcs = $4;
 771                                                   if (!parse_only && do_header) write_dispinterface($$);
 772                                                   if (!parse_only && do_idfile) write_diid($$);
 773                                                 }
 774         | dispinterfacehdr
 775          '{' interface ';' '}'                  { $$ = $1;
 776                                                   $$->fields = $3->fields;
 777                                                   $$->funcs = $3->funcs;
 778                                                   if (!parse_only && do_header) write_dispinterface($$);
 779                                                   if (!parse_only && do_idfile) write_diid($$);
 780                                                 }
 781         ;
 782
 783 inherit:                                        { $$ = NULL; }
 784         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 785         ;
 786
 787 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 788         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 789         ;
 790
 791 interfacehdr: attributes interface              { $$ = $2;
 792                                                   if ($$->defined) yyerror("multiple definition error");
 793                                                   $$->attrs = $1;
 794                                                   $$->defined = TRUE;
 795                                                   if (!parse_only && do_header) write_forward($$);
 796                                                 }
 797         ;
 798
 799 interfacedef: interfacehdr inherit
 800           '{' int_statements '}'                { $$ = $1;
 801                                                   $$->ref = $2;
 802                                                   $$->funcs = $4;
 803                                                   compute_method_indexes($$);
 804                                                   if (!parse_only && do_header) write_interface($$);
 805                                                   if (!parse_only && do_idfile) write_iid($$);
 806                                                 }
 807 /* MIDL is able to import the definition of a base class from inside the
 808  * definition of a derived class, I'll try to support it with this rule */
 809         | interfacehdr ':' aIDENTIFIER
 810           '{' import int_statements '}'         { $$ = $1;
 811                                                   $$->ref = find_type2($3, 0);
 812                                                   if (!$$->ref) yyerror("base class '%s' not found in import", $3);
 813                                                   $$->funcs = $6;
 814                                                   compute_method_indexes($$);
 815                                                   if (!parse_only && do_header) write_interface($$);
 816                                                   if (!parse_only && do_idfile) write_iid($$);
 817                                                 }
 818         | dispinterfacedef                      { $$ = $1; }
 819         ;
 820
 821 interfacedec:
 822           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 823         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 824         ;
 825
 826 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 827         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 828         ;
 829
 830 modulehdr: attributes module                    { $$ = $2;
 831                                                   $$->attrs = $1;
 832                                                 }
 833         ;
 834
 835 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 836                                                   $$->funcs = $3;
 837                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 838                                                 }
 839         ;
 840
 841 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 842         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 843         ;
 844
 845 pident:   ident                                 { $$ = make_pident($1); }
 846         | p_ident
 847         | '(' pident ')'                        { $$ = $2; }
 848         ;
 849
 850 pident_list:
 851         pident                                  { $$ = append_pident( NULL, $1 ); }
 852         | pident_list ',' pident                { $$ = append_pident( $1, $3 ); }
 853         ;
 854
 855 pointer_type:
 856           tREF                                  { $$ = RPC_FC_RP; }
 857         | tUNIQUE                               { $$ = RPC_FC_UP; }
 858         | tPTR                                  { $$ = RPC_FC_FP; }
 859         ;
 860
 861 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 862                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 863                                                   $$->type = get_struct_type( $4 );
 864                                                   $$->kind = TKIND_RECORD;
 865                                                   $$->fields = $4;
 866                                                   $$->defined = TRUE;
 867                                                   if(in_typelib)
 868                                                       add_typelib_entry($$);
 869                                                 }
 870         ;
 871
 872 type:     tVOID                                 { $$ = duptype(find_type("void", 0), 1); }
 873         | aKNOWNTYPE                            { $$ = find_type($1, 0); }
 874         | base_type                             { $$ = $1; }
 875         | tCONST type                           { $$ = duptype($2, 1); $$->is_const = TRUE; }
 876         | enumdef                               { $$ = $1; }
 877         | tENUM aIDENTIFIER                     { $$ = find_type2($2, tsENUM); }
 878         | structdef                             { $$ = $1; }
 879         | tSTRUCT aIDENTIFIER                   { $$ = get_type(RPC_FC_STRUCT, $2, tsSTRUCT); }
 880         | uniondef                              { $$ = $1; }
 881         | tUNION aIDENTIFIER                    { $$ = find_type2($2, tsUNION); }
 882         | tSAFEARRAY '(' type ')'               { $$ = make_safearray($3); }
 883         ;
 884
 885 typedef: tTYPEDEF m_attributes type pident_list { reg_typedefs($3, $4, $2);
 886                                                   process_typedefs($4);
 887                                                 }
 888         ;
 889
 890 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 891                                                   $$->kind = TKIND_UNION;
 892                                                   $$->fields = $4;
 893                                                   $$->defined = TRUE;
 894                                                 }
 895         | tUNION t_ident
 896           tSWITCH '(' s_field ')'
 897           m_ident '{' cases '}'                 { var_t *u = $7;
 898                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 899                                                   $$->kind = TKIND_UNION;
 900                                                   if (!u) u = make_var( xstrdup("tagged_union") );
 901                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 902                                                   u->type->kind = TKIND_UNION;
 903                                                   u->type->fields = $9;
 904                                                   u->type->defined = TRUE;
 905                                                   $$->fields = append_var( $$->fields, $5 );
 906                                                   $$->fields = append_var( $$->fields, u );
 907                                                   $$->defined = TRUE;
 908                                                 }
 909         ;
 910
 911 version:
 912           aNUM                                  { $$ = MAKELONG($1, 0); }
 913         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 914         ;
 915
 916 %%
 917
 918 static void decl_builtin(const char *name, unsigned char type)
 919 {
 920   type_t *t = make_type(type, NULL);
 921   t->name = xstrdup(name);
 922   reg_type(t, name, 0);
 923 }
 924
 925 static type_t *make_builtin(char *name)
 926 {
 927   /* NAME is strdup'd in the lexer */
 928   type_t *t = duptype(find_type(name, 0), 0);
 929   t->name = name;
 930   return t;
 931 }
 932
 933 static type_t *make_int(int sign)
 934 {
 935   type_t *t = duptype(find_type("int", 0), 1);
 936
 937   t->sign = sign;
 938   if (sign < 0)
 939     t->type = t->type == RPC_FC_LONG ? RPC_FC_ULONG : RPC_FC_USHORT;
 940
 941   return t;
 942 }
 943
 944 void init_types(void)
 945 {
 946   decl_builtin("void", 0);
 947   decl_builtin("byte", RPC_FC_BYTE);
 948   decl_builtin("wchar_t", RPC_FC_WCHAR);
 949   decl_builtin("int", RPC_FC_LONG);     /* win32 */
 950   decl_builtin("short", RPC_FC_SHORT);
 951   decl_builtin("small", RPC_FC_SMALL);
 952   decl_builtin("long", RPC_FC_LONG);
 953   decl_builtin("hyper", RPC_FC_HYPER);
 954   decl_builtin("__int64", RPC_FC_HYPER);
 955   decl_builtin("char", RPC_FC_CHAR);
 956   decl_builtin("float", RPC_FC_FLOAT);
 957   decl_builtin("double", RPC_FC_DOUBLE);
 958   decl_builtin("boolean", RPC_FC_BYTE);
 959   decl_builtin("error_status_t", RPC_FC_ERROR_STATUS_T);
 960   decl_builtin("handle_t", RPC_FC_BIND_PRIMITIVE);
 961 }
 962
 963 static str_list_t *append_str(str_list_t *list, char *str)
 964 {
 965     struct str_list_entry_t *entry;
 966
 967     if (!str) return list;
 968     if (!list)
 969     {
 970         list = xmalloc( sizeof(*list) );
 971         list_init( list );
 972     }
 973     entry = xmalloc( sizeof(*entry) );
 974     entry->str = str;
 975     list_add_tail( list, &entry->entry );
 976     return list;
 977 }
 978
 979 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr)
 980 {
 981     if (!attr) return list;
 982     if (!list)
 983     {
 984         list = xmalloc( sizeof(*list) );
 985         list_init( list );
 986     }
 987     list_add_tail( list, &attr->entry );
 988     return list;
 989 }
 990
 991 static attr_t *make_attr(enum attr_type type)
 992 {
 993   attr_t *a = xmalloc(sizeof(attr_t));
 994   a->type = type;
 995   a->u.ival = 0;
 996   return a;
 997 }
 998
 999 static attr_t *make_attrv(enum attr_type type, unsigned long val)
1000 {
1001   attr_t *a = xmalloc(sizeof(attr_t));
1002   a->type = type;
1003   a->u.ival = val;
1004   return a;
1005 }
1006
1007 static attr_t *make_attrp(enum attr_type type, void *val)
1008 {
1009   attr_t *a = xmalloc(sizeof(attr_t));
1010   a->type = type;
1011   a->u.pval = val;
1012   return a;
1013 }
1014
1015 static expr_t *make_expr(enum expr_type type)
1016 {
1017   expr_t *e = xmalloc(sizeof(expr_t));
1018   e->type = type;
1019   e->ref = NULL;
1020   e->u.lval = 0;
1021   e->is_const = FALSE;
1022   e->cval = 0;
1023   return e;
1024 }
1025
1026 static expr_t *make_exprl(enum expr_type type, long val)
1027 {
1028   expr_t *e = xmalloc(sizeof(expr_t));
1029   e->type = type;
1030   e->ref = NULL;
1031   e->u.lval = val;
1032   e->is_const = FALSE;
1033   /* check for numeric constant */
1034   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
1035     /* make sure true/false value is valid */
1036     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
1037     e->is_const = TRUE;
1038     e->cval = val;
1039   }
1040   return e;
1041 }
1042
1043 static expr_t *make_exprd(enum expr_type type, double val)
1044 {
1045   expr_t *e = xmalloc(sizeof(expr_t));
1046   e->type = type;
1047   e->ref = NULL;
1048   e->u.dval = val;
1049   e->is_const = TRUE;
1050   e->cval = val;
1051   return e;
1052 }
1053
1054 static expr_t *make_exprs(enum expr_type type, char *val)
1055 {
1056   expr_t *e;
1057   e = xmalloc(sizeof(expr_t));
1058   e->type = type;
1059   e->ref = NULL;
1060   e->u.sval = val;
1061   e->is_const = FALSE;
1062   /* check for predefined constants */
1063   if (type == EXPR_IDENTIFIER) {
1064     var_t *c = find_const(val, 0);
1065     if (c) {
1066       e->u.sval = c->name;
1067       free(val);
1068       e->is_const = TRUE;
1069       e->cval = c->eval->cval;
1070     }
1071   }
1072   return e;
1073 }
1074
1075 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr)
1076 {
1077   expr_t *e;
1078   e = xmalloc(sizeof(expr_t));
1079   e->type = type;
1080   e->ref = expr;
1081   e->u.tref = tref;
1082   e->is_const = FALSE;
1083   /* check for cast of constant expression */
1084   if (type == EXPR_SIZEOF) {
1085     switch (tref->type) {
1086       case RPC_FC_BYTE:
1087       case RPC_FC_CHAR:
1088       case RPC_FC_SMALL:
1089       case RPC_FC_USMALL:
1090         e->is_const = TRUE;
1091         e->cval = 1;
1092         break;
1093       case RPC_FC_WCHAR:
1094       case RPC_FC_USHORT:
1095       case RPC_FC_SHORT:
1096         e->is_const = TRUE;
1097         e->cval = 2;
1098         break;
1099       case RPC_FC_LONG:
1100       case RPC_FC_ULONG:
1101       case RPC_FC_FLOAT:
1102       case RPC_FC_ERROR_STATUS_T:
1103         e->is_const = TRUE;
1104         e->cval = 4;
1105         break;
1106       case RPC_FC_HYPER:
1107       case RPC_FC_DOUBLE:
1108         e->is_const = TRUE;
1109         e->cval = 8;
1110         break;
1111     }
1112   }
1113   if (type == EXPR_CAST && expr->is_const) {
1114     e->is_const = TRUE;
1115     e->cval = expr->cval;
1116   }
1117   return e;
1118 }
1119
1120 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
1121 {
1122   expr_t *e;
1123   e = xmalloc(sizeof(expr_t));
1124   e->type = type;
1125   e->ref = expr;
1126   e->u.lval = 0;
1127   e->is_const = FALSE;
1128   /* check for compile-time optimization */
1129   if (expr->is_const) {
1130     e->is_const = TRUE;
1131     switch (type) {
1132     case EXPR_NEG:
1133       e->cval = -expr->cval;
1134       break;
1135     case EXPR_NOT:
1136       e->cval = ~expr->cval;
1137       break;
1138     default:
1139       e->is_const = FALSE;
1140       break;
1141     }
1142   }
1143   return e;
1144 }
1145
1146 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1147 {
1148   expr_t *e;
1149   e = xmalloc(sizeof(expr_t));
1150   e->type = type;
1151   e->ref = expr1;
1152   e->u.ext = expr2;
1153   e->is_const = FALSE;
1154   /* check for compile-time optimization */
1155   if (expr1->is_const && expr2->is_const) {
1156     e->is_const = TRUE;
1157     switch (type) {
1158     case EXPR_ADD:
1159       e->cval = expr1->cval + expr2->cval;
1160       break;
1161     case EXPR_SUB:
1162       e->cval = expr1->cval - expr2->cval;
1163       break;
1164     case EXPR_MUL:
1165       e->cval = expr1->cval * expr2->cval;
1166       break;
1167     case EXPR_DIV:
1168       e->cval = expr1->cval / expr2->cval;
1169       break;
1170     case EXPR_OR:
1171       e->cval = expr1->cval | expr2->cval;
1172       break;
1173     case EXPR_AND:
1174       e->cval = expr1->cval & expr2->cval;
1175       break;
1176     case EXPR_SHL:
1177       e->cval = expr1->cval << expr2->cval;
1178       break;
1179     case EXPR_SHR:
1180       e->cval = expr1->cval >> expr2->cval;
1181       break;
1182     default:
1183       e->is_const = FALSE;
1184       break;
1185     }
1186   }
1187   return e;
1188 }
1189
1190 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1191 {
1192   expr_t *e;
1193   e = xmalloc(sizeof(expr_t));
1194   e->type = type;
1195   e->ref = expr1;
1196   e->u.ext = expr2;
1197   e->ext2 = expr3;
1198   e->is_const = FALSE;
1199   /* check for compile-time optimization */
1200   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1201     e->is_const = TRUE;
1202     switch (type) {
1203     case EXPR_COND:
1204       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1205       break;
1206     default:
1207       e->is_const = FALSE;
1208       break;
1209     }
1210   }
1211   return e;
1212 }
1213
1214 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr)
1215 {
1216     if (!expr) return list;
1217     if (!list)
1218     {
1219         list = xmalloc( sizeof(*list) );
1220         list_init( list );
1221     }
1222     list_add_tail( list, &expr->entry );
1223     return list;
1224 }
1225
1226 static array_dims_t *append_array(array_dims_t *list, expr_t *expr)
1227 {
1228     if (!expr) return list;
1229     if (!list)
1230     {
1231         list = xmalloc( sizeof(*list) );
1232         list_init( list );
1233     }
1234     list_add_tail( list, &expr->entry );
1235     return list;
1236 }
1237
1238 static type_t *make_type(unsigned char type, type_t *ref)
1239 {
1240   type_t *t = xmalloc(sizeof(type_t));
1241   t->name = NULL;
1242   t->kind = TKIND_PRIMITIVE;
1243   t->type = type;
1244   t->ref = ref;
1245   t->attrs = NULL;
1246   t->orig = NULL;
1247   t->funcs = NULL;
1248   t->fields = NULL;
1249   t->ifaces = NULL;
1250   t->dim = 0;
1251   t->size_is = NULL;
1252   t->length_is = NULL;
1253   t->typestring_offset = 0;
1254   t->ptrdesc = 0;
1255   t->declarray = FALSE;
1256   t->ignore = (parse_only != 0);
1257   t->is_const = FALSE;
1258   t->sign = 0;
1259   t->defined = FALSE;
1260   t->written = FALSE;
1261   t->user_types_registered = FALSE;
1262   t->tfswrite = FALSE;
1263   t->typelib_idx = -1;
1264   return t;
1265 }
1266
1267 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr,
1268                      int top)
1269 {
1270   expr_list_t *sizes = get_attrp(v->attrs, ATTR_SIZEIS);
1271   expr_list_t *lengs = get_attrp(v->attrs, ATTR_LENGTHIS);
1272   int ptr_attr = get_attrv(v->attrs, ATTR_POINTERTYPE);
1273   int ptr_type = ptr_attr;
1274   int sizeless, has_varconf;
1275   expr_t *dim;
1276   type_t *atype, **ptype;
1277
1278   v->type = type;
1279
1280   if (!ptr_type && top)
1281     ptr_type = RPC_FC_RP;
1282
1283   for ( ; 0 < ptr_level; --ptr_level)
1284   {
1285     v->type = make_type(pointer_default, v->type);
1286     if (ptr_level == 1 && ptr_type && !arr)
1287     {
1288       v->type->type = ptr_type;
1289       ptr_type = 0;
1290     }
1291   }
1292
1293   if (ptr_type)
1294   {
1295     if (is_ptr(v->type))
1296     {
1297       if (v->type->type != ptr_type)
1298       {
1299         v->type = duptype(v->type, 1);
1300         v->type->type = ptr_type;
1301       }
1302     }
1303     else if (!arr && ptr_attr)
1304       error("%s: pointer attribute applied to non-pointer type\n", v->name);
1305   }
1306
1307   sizeless = FALSE;
1308   if (arr) LIST_FOR_EACH_ENTRY_REV(dim, arr, expr_t, entry)
1309   {
1310     if (sizeless)
1311       error("%s: only the first array dimension can be unspecified\n", v->name);
1312
1313     if (dim->is_const)
1314     {
1315       unsigned int align = 0;
1316       size_t size = type_memsize(v->type, &align);
1317
1318       if (dim->cval <= 0)
1319         error("%s: array dimension must be positive\n", v->name);
1320
1321       if (0xffffffffuL / size < (unsigned long) dim->cval)
1322         error("%s: total array size is too large\n", v->name);
1323       else if (0xffffuL < size * dim->cval)
1324         v->type = make_type(RPC_FC_LGFARRAY, v->type);
1325       else
1326         v->type = make_type(RPC_FC_SMFARRAY, v->type);
1327     }
1328     else
1329     {
1330       sizeless = TRUE;
1331       v->type = make_type(RPC_FC_CARRAY, v->type);
1332     }
1333
1334     v->type->declarray = TRUE;
1335     v->type->dim = dim->cval;
1336   }
1337
1338   ptype = &v->type;
1339   has_varconf = FALSE;
1340   if (sizes) LIST_FOR_EACH_ENTRY(dim, sizes, expr_t, entry)
1341   {
1342     if (dim->type != EXPR_VOID)
1343     {
1344       has_varconf = TRUE;
1345       atype = *ptype = duptype(*ptype, 0);
1346
1347       if (atype->type == RPC_FC_SMFARRAY || atype->type == RPC_FC_LGFARRAY)
1348         error("%s: cannot specify size_is for a fixed sized array\n", v->name);
1349
1350       if (atype->type != RPC_FC_CARRAY && !is_ptr(atype))
1351         error("%s: size_is attribute applied to illegal type\n", v->name);
1352
1353       atype->type = RPC_FC_CARRAY;
1354       atype->size_is = dim;
1355     }
1356
1357     ptype = &(*ptype)->ref;
1358     if (*ptype == NULL)
1359       error("%s: too many expressions in size_is attribute\n", v->name);
1360   }
1361
1362   ptype = &v->type;
1363   if (lengs) LIST_FOR_EACH_ENTRY(dim, lengs, expr_t, entry)
1364   {
1365     if (dim->type != EXPR_VOID)
1366     {
1367       has_varconf = TRUE;
1368       atype = *ptype = duptype(*ptype, 0);
1369
1370       if (atype->type == RPC_FC_SMFARRAY)
1371         atype->type = RPC_FC_SMVARRAY;
1372       else if (atype->type == RPC_FC_LGFARRAY)
1373         atype->type = RPC_FC_LGVARRAY;
1374       else if (atype->type == RPC_FC_CARRAY)
1375         atype->type = RPC_FC_CVARRAY;
1376       else
1377         error("%s: length_is attribute applied to illegal type\n", v->name);
1378
1379       atype->length_is = dim;
1380     }
1381
1382     ptype = &(*ptype)->ref;
1383     if (*ptype == NULL)
1384       error("%s: too many expressions in length_is attribute\n", v->name);
1385   }
1386
1387   if (has_varconf && !last_array(v->type))
1388   {
1389     ptype = &v->type;
1390     for (ptype = &v->type; is_array(*ptype); ptype = &(*ptype)->ref)
1391     {
1392       *ptype = duptype(*ptype, 0);
1393       (*ptype)->type = RPC_FC_BOGUS_ARRAY;
1394     }
1395   }
1396
1397   if (is_array(v->type))
1398   {
1399     const type_t *rt = v->type->ref;
1400     switch (rt->type)
1401     {
1402     case RPC_FC_BOGUS_STRUCT:
1403     case RPC_FC_NON_ENCAPSULATED_UNION:
1404     case RPC_FC_ENCAPSULATED_UNION:
1405     case RPC_FC_ENUM16:
1406       v->type->type = RPC_FC_BOGUS_ARRAY;
1407       break;
1408     /* FC_RP should be above, but widl overuses these, and will break things.  */
1409     case RPC_FC_UP:
1410     case RPC_FC_RP:
1411       if (rt->ref->type == RPC_FC_IP)
1412         v->type->type = RPC_FC_BOGUS_ARRAY;
1413       break;
1414     default:
1415       if (is_user_type(rt))
1416         v->type->type = RPC_FC_BOGUS_ARRAY;
1417     }
1418   }
1419 }
1420
1421 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface)
1422 {
1423     if (!iface) return list;
1424     if (!list)
1425     {
1426         list = xmalloc( sizeof(*list) );
1427         list_init( list );
1428     }
1429     list_add_tail( list, &iface->entry );
1430     return list;
1431 }
1432
1433 static ifref_t *make_ifref(type_t *iface)
1434 {
1435   ifref_t *l = xmalloc(sizeof(ifref_t));
1436   l->iface = iface;
1437   l->attrs = NULL;
1438   return l;
1439 }
1440
1441 static var_list_t *append_var(var_list_t *list, var_t *var)
1442 {
1443     if (!var) return list;
1444     if (!list)
1445     {
1446         list = xmalloc( sizeof(*list) );
1447         list_init( list );
1448     }
1449     list_add_tail( list, &var->entry );
1450     return list;
1451 }
1452
1453 static var_t *make_var(char *name)
1454 {
1455   var_t *v = xmalloc(sizeof(var_t));
1456   v->name = name;
1457   v->type = NULL;
1458   v->args = NULL;
1459   v->attrs = NULL;
1460   v->eval = NULL;
1461   return v;
1462 }
1463
1464 static pident_list_t *append_pident(pident_list_t *list, pident_t *p)
1465 {
1466   if (!p) return list;
1467   if (!list) {
1468     list = xmalloc(sizeof(*list));
1469     list_init(list);
1470   }
1471   list_add_tail(list, &p->entry);
1472   return list;
1473 }
1474
1475 static pident_t *make_pident(var_t *var)
1476 {
1477   pident_t *p = xmalloc(sizeof(*p));
1478   p->var = var;
1479   p->ptr_level = 0;
1480   return p;
1481 }
1482
1483 static func_list_t *append_func(func_list_t *list, func_t *func)
1484 {
1485     if (!func) return list;
1486     if (!list)
1487     {
1488         list = xmalloc( sizeof(*list) );
1489         list_init( list );
1490     }
1491     list_add_tail( list, &func->entry );
1492     return list;
1493 }
1494
1495 static func_t *make_func(var_t *def, var_list_t *args)
1496 {
1497   func_t *f = xmalloc(sizeof(func_t));
1498   f->def = def;
1499   f->args = args;
1500   f->ignore = parse_only;
1501   f->idx = -1;
1502   return f;
1503 }
1504
1505 static type_t *make_class(char *name)
1506 {
1507   type_t *c = make_type(0, NULL);
1508   c->name = name;
1509   c->kind = TKIND_COCLASS;
1510   return c;
1511 }
1512
1513 static type_t *make_safearray(type_t *type)
1514 {
1515   type_t *sa = duptype(find_type("SAFEARRAY", 0), 1);
1516   sa->ref = type;
1517   return make_type(pointer_default, sa);
1518 }
1519
1520 #define HASHMAX 64
1521
1522 static int hash_ident(const char *name)
1523 {
1524   const char *p = name;
1525   int sum = 0;
1526   /* a simple sum hash is probably good enough */
1527   while (*p) {
1528     sum += *p;
1529     p++;
1530   }
1531   return sum & (HASHMAX-1);
1532 }
1533
1534 /***** type repository *****/
1535
1536 struct rtype {
1537   const char *name;
1538   type_t *type;
1539   int t;
1540   struct rtype *next;
1541 };
1542
1543 struct rtype *type_hash[HASHMAX];
1544
1545 static type_t *reg_type(type_t *type, const char *name, int t)
1546 {
1547   struct rtype *nt;
1548   int hash;
1549   if (!name) {
1550     yyerror("registering named type without name");
1551     return type;
1552   }
1553   hash = hash_ident(name);
1554   nt = xmalloc(sizeof(struct rtype));
1555   nt->name = name;
1556   nt->type = type;
1557   nt->t = t;
1558   nt->next = type_hash[hash];
1559   type_hash[hash] = nt;
1560   return type;
1561 }
1562
1563 static int is_incomplete(const type_t *t)
1564 {
1565   return !t->defined && (is_struct(t->type) || is_union(t->type));
1566 }
1567
1568 static void add_incomplete(type_t *t)
1569 {
1570   struct typenode *tn = xmalloc(sizeof *tn);
1571   tn->type = t;
1572   list_add_tail(&incomplete_types, &tn->entry);
1573 }
1574
1575 static void fix_type(type_t *t)
1576 {
1577   if (t->kind == TKIND_ALIAS && is_incomplete(t)) {
1578     type_t *ot = t->orig;
1579     fix_type(ot);
1580     t->fields = ot->fields;
1581     t->defined = ot->defined;
1582   }
1583 }
1584
1585 static void fix_incomplete(void)
1586 {
1587   struct typenode *tn, *next;
1588
1589   LIST_FOR_EACH_ENTRY_SAFE(tn, next, &incomplete_types, struct typenode, entry) {
1590     fix_type(tn->type);
1591     free(tn);
1592   }
1593 }
1594
1595 static type_t *reg_typedefs(type_t *type, pident_list_t *pidents, attr_list_t *attrs)
1596 {
1597   type_t *ptr = type;
1598   const pident_t *pident;
1599   int ptrc = 0;
1600   int is_str = is_attr(attrs, ATTR_STRING);
1601   unsigned char ptr_type = get_attrv(attrs, ATTR_POINTERTYPE);
1602
1603   if (is_str)
1604   {
1605     type_t *t = type;
1606     unsigned char c;
1607
1608     while (is_ptr(t))
1609       t = t->ref;
1610
1611     c = t->type;
1612     if (c != RPC_FC_CHAR && c != RPC_FC_BYTE && c != RPC_FC_WCHAR)
1613     {
1614       pident = LIST_ENTRY( list_head( pidents ), const pident_t, entry );
1615       yyerror("'%s': [string] attribute is only valid on 'char', 'byte', or 'wchar_t' pointers and arrays",
1616               pident->var->name);
1617     }
1618   }
1619
1620   /* We must generate names for tagless enum, struct or union.
1621      Typedef-ing a tagless enum, struct or union means we want the typedef
1622      to be included in a library whether it has other attributes or not,
1623      hence the public attribute.  */
1624   if ((type->kind == TKIND_ENUM || type->kind == TKIND_RECORD
1625        || type->kind == TKIND_UNION) && ! type->name && ! parse_only)
1626   {
1627     if (! is_attr(attrs, ATTR_PUBLIC))
1628       attrs = append_attr( attrs, make_attr(ATTR_PUBLIC) );
1629     type->name = gen_name();
1630   }
1631
1632   LIST_FOR_EACH_ENTRY( pident, pidents, const pident_t, entry )
1633   {
1634     var_t *name = pident->var;
1635
1636     if (name->name) {
1637       type_t *cur = ptr;
1638       int cptr = pident->ptr_level;
1639       if (cptr > ptrc) {
1640         while (cptr > ptrc) {
1641           cur = ptr = make_type(pointer_default, cur);
1642           ptrc++;
1643         }
1644       } else {
1645         while (cptr < ptrc) {
1646           cur = cur->ref;
1647           cptr++;
1648         }
1649       }
1650       cur = alias(cur, name->name);
1651       cur->attrs = attrs;
1652       if (ptr_type)
1653       {
1654         if (is_ptr(cur))
1655           cur->type = ptr_type;
1656         else
1657           yyerror("'%s': pointer attribute applied to non-pointer type",
1658                   cur->name);
1659       }
1660       else if (is_str && ! is_ptr(cur))
1661         yyerror("'%s': [string] attribute applied to non-pointer type",
1662                 cur->name);
1663
1664       if (is_incomplete(cur))
1665         add_incomplete(cur);
1666       reg_type(cur, cur->name, 0);
1667     }
1668   }
1669   return type;
1670 }
1671
1672 static type_t *find_type(const char *name, int t)
1673 {
1674   struct rtype *cur = type_hash[hash_ident(name)];
1675   while (cur && (cur->t != t || strcmp(cur->name, name)))
1676     cur = cur->next;
1677   if (!cur) {
1678     yyerror("type '%s' not found", name);
1679     return NULL;
1680   }
1681   return cur->type;
1682 }
1683
1684 static type_t *find_type2(char *name, int t)
1685 {
1686   type_t *tp = find_type(name, t);
1687   free(name);
1688   return tp;
1689 }
1690
1691 int is_type(const char *name)
1692 {
1693   struct rtype *cur = type_hash[hash_ident(name)];
1694   while (cur && (cur->t || strcmp(cur->name, name)))
1695     cur = cur->next;
1696   if (cur) return TRUE;
1697   return FALSE;
1698 }
1699
1700 static type_t *get_type(unsigned char type, char *name, int t)
1701 {
1702   struct rtype *cur = NULL;
1703   type_t *tp;
1704   if (name) {
1705     cur = type_hash[hash_ident(name)];
1706     while (cur && (cur->t != t || strcmp(cur->name, name)))
1707       cur = cur->next;
1708   }
1709   if (cur) {
1710     free(name);
1711     return cur->type;
1712   }
1713   tp = make_type(type, NULL);
1714   tp->name = name;
1715   if (!name) return tp;
1716   return reg_type(tp, name, t);
1717 }
1718
1719 static type_t *get_typev(unsigned char type, var_t *name, int t)
1720 {
1721   char *sname = NULL;
1722   if (name) {
1723     sname = name->name;
1724     free(name);
1725   }
1726   return get_type(type, sname, t);
1727 }
1728
1729 static int get_struct_type(var_list_t *fields)
1730 {
1731   int has_pointer = 0;
1732   int has_conformance = 0;
1733   int has_variance = 0;
1734   var_t *field;
1735
1736   if (get_padding(fields))
1737     return RPC_FC_BOGUS_STRUCT;
1738
1739   if (fields) LIST_FOR_EACH_ENTRY( field, fields, var_t, entry )
1740   {
1741     type_t *t = field->type;
1742
1743     if (is_ptr(t))
1744     {
1745         do
1746             t = t->ref;
1747         while (is_ptr(t));
1748
1749         switch (t->type)
1750         {
1751         case RPC_FC_IP:
1752         case RPC_FC_ENCAPSULATED_UNION:
1753         case RPC_FC_NON_ENCAPSULATED_UNION:
1754         case RPC_FC_BOGUS_STRUCT:
1755             return RPC_FC_BOGUS_STRUCT;
1756         }
1757
1758         has_pointer = 1;
1759         continue;
1760     }
1761
1762     if (field->type->declarray)
1763     {
1764         if (is_string_type(field->attrs, field->type))
1765         {
1766             if (is_conformant_array(field->type))
1767                 has_conformance = 1;
1768             has_variance = 1;
1769             continue;
1770         }
1771
1772         if (is_array(field->type->ref))
1773             return RPC_FC_BOGUS_STRUCT;
1774
1775         if (is_conformant_array(field->type))
1776         {
1777             has_conformance = 1;
1778             if (field->type->declarray && list_next(fields, &field->entry))
1779                 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1780                         field->name);
1781         }
1782         if (field->type->length_is)
1783             has_variance = 1;
1784
1785         t = field->type->ref;
1786     }
1787
1788     switch (t->type)
1789     {
1790     /*
1791      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1792      *  Simple types don't effect the type of struct.
1793      *  A struct containing a simple struct is still a simple struct.
1794      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1795      */
1796     case 0: /* void pointer */
1797     case RPC_FC_BYTE:
1798     case RPC_FC_CHAR:
1799     case RPC_FC_SMALL:
1800     case RPC_FC_USMALL:
1801     case RPC_FC_WCHAR:
1802     case RPC_FC_SHORT:
1803     case RPC_FC_USHORT:
1804     case RPC_FC_LONG:
1805     case RPC_FC_ULONG:
1806     case RPC_FC_INT3264:
1807     case RPC_FC_UINT3264:
1808     case RPC_FC_HYPER:
1809     case RPC_FC_FLOAT:
1810     case RPC_FC_DOUBLE:
1811     case RPC_FC_STRUCT:
1812     case RPC_FC_ENUM16:
1813     case RPC_FC_ENUM32:
1814       break;
1815
1816     case RPC_FC_RP:
1817     case RPC_FC_UP:
1818     case RPC_FC_FP:
1819     case RPC_FC_OP:
1820     case RPC_FC_CARRAY:
1821     case RPC_FC_CVARRAY:
1822       has_pointer = 1;
1823       break;
1824
1825     /*
1826      * Propagate member attributes
1827      *  a struct should be at least as complex as its member
1828      */
1829     case RPC_FC_CVSTRUCT:
1830       has_conformance = 1;
1831       has_variance = 1;
1832       has_pointer = 1;
1833       break;
1834
1835     case RPC_FC_CPSTRUCT:
1836       has_conformance = 1;
1837       if (list_next( fields, &field->entry ))
1838           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1839                   field->name);
1840       has_pointer = 1;
1841       break;
1842
1843     case RPC_FC_CSTRUCT:
1844       has_conformance = 1;
1845       if (list_next( fields, &field->entry ))
1846           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1847                   field->name);
1848       break;
1849
1850     case RPC_FC_PSTRUCT:
1851       has_pointer = 1;
1852       break;
1853
1854     default:
1855       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1856               field->name, t->type);
1857       /* fallthru - treat it as complex */
1858
1859     /* as soon as we see one of these these members, it's bogus... */
1860     case RPC_FC_IP:
1861     case RPC_FC_ENCAPSULATED_UNION:
1862     case RPC_FC_NON_ENCAPSULATED_UNION:
1863     case RPC_FC_TRANSMIT_AS:
1864     case RPC_FC_REPRESENT_AS:
1865     case RPC_FC_PAD:
1866     case RPC_FC_EMBEDDED_COMPLEX:
1867     case RPC_FC_BOGUS_STRUCT:
1868     case RPC_FC_BOGUS_ARRAY:
1869       return RPC_FC_BOGUS_STRUCT;
1870     }
1871   }
1872
1873   if( has_variance )
1874   {
1875     if ( has_conformance )
1876       return RPC_FC_CVSTRUCT;
1877     else
1878       return RPC_FC_BOGUS_STRUCT;
1879   }
1880   if( has_conformance && has_pointer )
1881     return RPC_FC_CPSTRUCT;
1882   if( has_conformance )
1883     return RPC_FC_CSTRUCT;
1884   if( has_pointer )
1885     return RPC_FC_PSTRUCT;
1886   return RPC_FC_STRUCT;
1887 }
1888
1889 /***** constant repository *****/
1890
1891 struct rconst {
1892   char *name;
1893   var_t *var;
1894   struct rconst *next;
1895 };
1896
1897 struct rconst *const_hash[HASHMAX];
1898
1899 static var_t *reg_const(var_t *var)
1900 {
1901   struct rconst *nc;
1902   int hash;
1903   if (!var->name) {
1904     yyerror("registering constant without name");
1905     return var;
1906   }
1907   hash = hash_ident(var->name);
1908   nc = xmalloc(sizeof(struct rconst));
1909   nc->name = var->name;
1910   nc->var = var;
1911   nc->next = const_hash[hash];
1912   const_hash[hash] = nc;
1913   return var;
1914 }
1915
1916 static var_t *find_const(char *name, int f)
1917 {
1918   struct rconst *cur = const_hash[hash_ident(name)];
1919   while (cur && strcmp(cur->name, name))
1920     cur = cur->next;
1921   if (!cur) {
1922     if (f) yyerror("constant '%s' not found", name);
1923     return NULL;
1924   }
1925   return cur->var;
1926 }
1927
1928 static void write_libid(const char *name, const attr_list_t *attr)
1929 {
1930   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1931   write_guid(idfile, "LIBID", name, uuid);
1932 }
1933
1934 static void write_clsid(type_t *cls)
1935 {
1936   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1937   write_guid(idfile, "CLSID", cls->name, uuid);
1938 }
1939
1940 static void write_diid(type_t *iface)
1941 {
1942   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1943   write_guid(idfile, "DIID", iface->name, uuid);
1944 }
1945
1946 static void write_iid(type_t *iface)
1947 {
1948   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1949   write_guid(idfile, "IID", iface->name, uuid);
1950 }
1951
1952 static int compute_method_indexes(type_t *iface)
1953 {
1954   int idx;
1955   func_t *f;
1956
1957   if (iface->ref)
1958     idx = compute_method_indexes(iface->ref);
1959   else
1960     idx = 0;
1961
1962   if (!iface->funcs)
1963     return idx;
1964
1965   LIST_FOR_EACH_ENTRY( f, iface->funcs, func_t, entry )
1966     if (! is_callas(f->def->attrs))
1967       f->idx = idx++;
1968
1969   return idx;
1970 }
1971
1972 static char *gen_name(void)
1973 {
1974   static const char format[] = "__WIDL_%s_generated_name_%08lX";
1975   static unsigned long n = 0;
1976   static const char *file_id;
1977   static size_t size;
1978   char *name;
1979
1980   if (! file_id)
1981   {
1982     char *dst = dup_basename(input_name, ".idl");
1983     file_id = dst;
1984
1985     for (; *dst; ++dst)
1986       if (! isalnum((unsigned char) *dst))
1987         *dst = '_';
1988
1989     size = sizeof format - 7 + strlen(file_id) + 8;
1990   }
1991
1992   name = xmalloc(size);
1993   sprintf(name, format, file_id, n++);
1994   return name;
1995 }
1996
1997 static void process_typedefs(pident_list_t *pidents)
1998 {
1999   pident_t *pident, *next;
2000
2001   if (!pidents) return;
2002   LIST_FOR_EACH_ENTRY_SAFE( pident, next, pidents, pident_t, entry )
2003   {
2004     var_t *var = pident->var;
2005     type_t *type = find_type(var->name, 0);
2006
2007     if (! parse_only && do_header)
2008       write_typedef(type);
2009     if (in_typelib && type->attrs)
2010       add_typelib_entry(type);
2011
2012     free(pident);
2013     free(var);
2014   }
2015 }
2016
2017 static void check_arg(var_t *arg)
2018 {
2019   type_t *t = arg->type;
2020
2021   if (t->type == 0 && ! is_var_ptr(arg))
2022     yyerror("argument '%s' has void type", arg->name);
2023 }
2024
2025 static void check_all_user_types(ifref_list_t *ifrefs)
2026 {
2027   const ifref_t *ifref;
2028   const func_t *f;
2029
2030   if (ifrefs) LIST_FOR_EACH_ENTRY(ifref, ifrefs, const ifref_t, entry)
2031   {
2032     const func_list_t *fs = ifref->iface->funcs;
2033     if (fs) LIST_FOR_EACH_ENTRY(f, fs, const func_t, entry)
2034       check_for_user_types_and_context_handles(f->args);
2035   }
2036 }