git.oblomov.eu Git - wine/blob - aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2]],[[asm($1); $3]])],[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]])],
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([AC_LANG_SOURCE([void myfunc() {}])],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[w64-mingw32, pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, w64-mingw32, mingw32msvc],
 132                         m4_foreach([ac_wine_cpu],[x86_64,amd64],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 133   *)
 134     ac_prefix_list="" ;;
 135 esac
 136 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 137
 138
 139 dnl **** Define helper functions for creating config.status files ****
 140 dnl
 141 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 142 dnl
 143 AC_DEFUN([WINE_CONFIG_HELPERS],
 144 [ALL_MAKEFILE_DEPENDS="
 145 # Rules automatically generated by configure
 146
 147 .INIT: Makefile
 148 .MAKEFILEDEPS:
 149 all: Makefile
 150 Makefile: Makefile.in Make.vars.in Make.rules config.status
 151         @./config.status Make.tmp Makefile"
 152
 153 ALL_POT_FILES=""
 154 AC_SUBST(ALL_TEST_RESOURCES,"")
 155
 156 wine_fn_append_file ()
 157 {
 158     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 159 }
 160
 161 wine_fn_append_rule ()
 162 {
 163     AS_VAR_APPEND($[1],"$as_nl$[2]")
 164 }
 165
 166 wine_fn_has_flag ()
 167 {
 168     expr ",$[2]," : ".*,$[1],.*" >/dev/null
 169 }
 170
 171 wine_fn_all_dir_rules ()
 172 {
 173     ac_dir=$[1]
 174     ac_alldeps=$[2]
 175     ac_makedep="\$(MAKEDEP)"
 176     ac_input=Make.vars.in:$ac_dir/Makefile.in
 177     if test $ac_dir != tools
 178     then
 179         dnl makedep is in tools so tools makefile cannot depend on it
 180         ac_alldeps="$[2] $ac_makedep"
 181     fi
 182     case $[2] in
 183       *.in) ac_input=$ac_input:$[2] ;;
 184       *) ac_makedep="$[2] $ac_makedep" ;;
 185     esac
 186
 187     wine_fn_append_file ALL_DIRS $ac_dir
 188     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 189 "__clean__: $ac_dir/__clean__
 190 .PHONY: $ac_dir/__clean__
 191 $ac_dir/__clean__: $ac_dir/Makefile
 192         @cd $ac_dir && \$(MAKE) clean
 193         \$(RM) $ac_dir/Makefile
 194 $ac_dir/Makefile: $ac_dir/Makefile.in Make.vars.in config.status $ac_alldeps
 195         @./config.status --file $ac_dir/Makefile:$ac_input && cd $ac_dir && \$(MAKE) depend
 196 depend: $ac_dir/__depend__
 197 .PHONY: $ac_dir/__depend__
 198 $ac_dir/__depend__: $ac_makedep dummy
 199         @./config.status --file $ac_dir/Makefile:$ac_input && cd $ac_dir && \$(MAKE) depend"
 200 }
 201
 202 wine_fn_config_makefile ()
 203 {
 204     ac_dir=$[1]
 205     ac_enable=$[2]
 206     AS_VAR_IF([$ac_enable],[no],[return 0])
 207
 208     wine_fn_all_dir_rules $ac_dir Make.rules
 209     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 210 "all: $ac_dir
 211 .PHONY: $ac_dir
 212 $ac_dir: $ac_dir/Makefile dummy
 213         @cd $ac_dir && \$(MAKE)
 214 install:: $ac_dir
 215         @cd $ac_dir && \$(MAKE) install
 216 install-lib:: $ac_dir
 217         @cd $ac_dir && \$(MAKE) install-lib
 218 install-dev:: $ac_dir
 219         @cd $ac_dir && \$(MAKE) install-dev
 220 uninstall:: $ac_dir/Makefile
 221         @cd $ac_dir && \$(MAKE) uninstall"
 222 }
 223
 224 wine_fn_config_lib ()
 225 {
 226     ac_name=$[1]
 227     ac_dir=dlls/$ac_name
 228     wine_fn_all_dir_rules $ac_dir dlls/Makeimplib.rules
 229     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 230 "all __builddeps__: $ac_dir
 231 $ac_dir: $ac_dir/Makefile tools/widl tools/winebuild tools/winegcc include dummy
 232         @cd $ac_dir && \$(MAKE)
 233 install install-dev:: $ac_dir
 234         @cd $ac_dir && \$(MAKE) install
 235 uninstall:: $ac_dir/Makefile
 236         @cd $ac_dir && \$(MAKE) uninstall"
 237 }
 238
 239 wine_fn_config_dll ()
 240 {
 241     ac_name=$[1]
 242     ac_dir=dlls/$ac_name
 243     ac_enable=$[2]
 244     ac_flags=$[3]
 245     ac_implib=${4:-$ac_name}
 246     ac_file=$ac_dir/lib$ac_implib
 247     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 248     ac_implibflags=""
 249
 250     case $ac_name in
 251       *16) ac_implibflags=" -m16" ;;
 252     esac
 253
 254     wine_fn_all_dir_rules $ac_dir dlls/Makedll.rules
 255
 256     AS_VAR_IF([$ac_enable],[no],
 257               dnl enable_win16 is special in that it disables import libs too
 258               [test "$ac_enable" != enable_win16 || return 0],
 259               [wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 260 "all: $ac_dir
 261 .PHONY: $ac_dir
 262 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 263         @cd $ac_dir && \$(MAKE)
 264 install:: $ac_dir/Makefile __builddeps__
 265         @cd $ac_dir && \$(MAKE) install
 266 install-lib:: $ac_dir/Makefile __builddeps__
 267         @cd $ac_dir && \$(MAKE) install-lib
 268 uninstall manpages htmlpages sgmlpages xmlpages:: $ac_dir/Makefile
 269         @cd $ac_dir && \$(MAKE) \$[@]"
 270
 271         if test "x$enable_maintainer_mode" = xyes
 272         then
 273             if wine_fn_has_flag mc $ac_flags
 274             then
 275                 wine_fn_append_file ALL_POT_FILES $ac_dir/msg.pot
 276                 wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 277 "$ac_dir/msg.pot: $ac_dir"
 278             fi
 279             if wine_fn_has_flag po $ac_flags
 280             then
 281                 wine_fn_append_file ALL_POT_FILES $ac_dir/rsrc.pot
 282                 wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 283 "$ac_dir/rsrc.pot: $ac_dir"
 284             fi
 285         fi])
 286
 287     if wine_fn_has_flag staticimplib $ac_flags
 288     then
 289         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 290 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 291 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 292 $ac_file.def: $ac_dir/$ac_name.spec $ac_dir/Makefile
 293         @cd $ac_dir && \$(MAKE) lib$ac_implib.def
 294 $ac_file.$STATIC_IMPLIBEXT: $ac_dir/Makefile dummy
 295         @cd $ac_dir && \$(MAKE) lib$ac_implib.$STATIC_IMPLIBEXT
 296 install-dev:: $ac_dir/Makefile __builddeps__
 297         @cd $ac_dir && \$(MAKE) install-dev"
 298         if test "x$CROSSTEST_DISABLE" = x
 299         then
 300             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 301 "__builddeps__: $ac_file.cross.a
 302 $ac_file.cross.a: $ac_dir/Makefile dummy
 303         @cd $ac_dir && \$(MAKE) lib$ac_implib.cross.a"
 304         fi
 305
 306     elif wine_fn_has_flag implib $ac_flags
 307     then
 308         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 309 "__builddeps__: $ac_file.$IMPLIBEXT
 310 $ac_file.def: $ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 311         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --def -o \$[@] --export \$(srcdir)/$ac_dir/$ac_name.spec
 312 $ac_file.a: $ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 313         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --implib -o \$[@] --export \$(srcdir)/$ac_dir/$ac_name.spec
 314 install-dev:: $ac_dir/Makefile __builddeps__
 315         @cd $ac_dir && \$(MAKE) install-dev"
 316         if test "x$CROSSTEST_DISABLE" = x
 317         then
 318             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 319 "__builddeps__: $ac_file.cross.a
 320 $ac_file.cross.a: $ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 321         \$(WINEBUILD) \$(CROSSTARGET:%=-b %)$ac_implibflags -w --implib -o \$[@] --export \$(srcdir)/$ac_dir/$ac_name.spec"
 322         fi
 323
 324         if test "$ac_name" != "$ac_implib"
 325         then
 326             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 327 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 328 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 329         \$(RM) \$[@] && \$(LN_S) $ac_name/lib$ac_implib.$IMPLIBEXT \$[@]
 330 clean::
 331         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 332             if test "x$CROSSTEST_DISABLE" = x
 333             then
 334                 wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 335 "__builddeps__: dlls/lib$ac_implib.cross.a
 336 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 337         \$(RM) \$[@] && \$(LN_S) $ac_name/lib$ac_implib.cross.a \$[@]"
 338             fi
 339         fi
 340     fi
 341 }
 342
 343 wine_fn_config_program ()
 344 {
 345     ac_name=$[1]
 346     ac_dir=programs/$ac_name
 347     ac_enable=$[2]
 348     ac_flags=$[3]
 349     wine_fn_all_dir_rules $ac_dir programs/Makeprog.rules
 350
 351     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 352 "all: $ac_dir
 353 .PHONY: $ac_dir
 354 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 355         @cd $ac_dir && \$(MAKE)"
 356
 357     if test "x$enable_maintainer_mode" = xyes
 358     then
 359         if wine_fn_has_flag mc $ac_flags
 360         then
 361             wine_fn_append_file ALL_POT_FILES $ac_dir/msg.pot
 362             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 363 "$ac_dir/msg.pot: $ac_dir"
 364         fi
 365         if wine_fn_has_flag po $ac_flags
 366         then
 367             wine_fn_append_file ALL_POT_FILES $ac_dir/rsrc.pot
 368             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 369 "$ac_dir/rsrc.pot: $ac_dir"
 370         fi
 371     fi
 372
 373     wine_fn_has_flag install $ac_flags || return
 374     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 375 "install install-lib:: $ac_dir/Makefile __builddeps__
 376         @cd $ac_dir && \$(MAKE) install
 377 uninstall:: $ac_dir/Makefile
 378         @cd $ac_dir && \$(MAKE) uninstall"
 379     if test -n "$DLLEXT" -a "x$enable_tools" != xno && wine_fn_has_flag installbin $ac_flags
 380     then
 381         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 382 "install install-lib:: tools \$(DESTDIR)\$(bindir)
 383         \$(INSTALL_SCRIPT) tools/wineapploader \$(DESTDIR)\$(bindir)/$ac_name
 384 uninstall::
 385         \$(RM) \$(DESTDIR)\$(bindir)/$ac_name"
 386     fi])
 387 }
 388
 389 wine_fn_config_test ()
 390 {
 391     ac_dir=$[1]
 392     ac_name=$[2]
 393     wine_fn_append_file ALL_TEST_RESOURCES $ac_name.res
 394     wine_fn_all_dir_rules $ac_dir Maketest.rules
 395
 396     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 397 "all: $ac_dir
 398 .PHONY: $ac_dir
 399 $ac_dir: $ac_dir/Makefile programs/winetest/Makefile __builddeps__ dummy
 400         @cd $ac_dir && \$(MAKE)
 401 programs/winetest: $ac_dir
 402 check test: $ac_dir/__test__
 403 .PHONY: $ac_dir/__test__
 404 $ac_dir/__test__: dummy
 405         @cd $ac_dir && \$(MAKE) test
 406 testclean::
 407         \$(RM) $ac_dir/*.ok"
 408
 409         if test "x$CROSSTEST_DISABLE" = x
 410         then
 411             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 412 "crosstest: $ac_dir/__crosstest__
 413 .PHONY: $ac_dir/__crosstest__
 414 $ac_dir/__crosstest__: $ac_dir/Makefile __builddeps__ dummy
 415         @cd $ac_dir && \$(MAKE) crosstest"
 416         fi])
 417 }
 418
 419 wine_fn_config_tool ()
 420 {
 421     ac_dir=$[1]
 422     AS_VAR_IF([enable_tools],[no],[return 0])
 423
 424     wine_fn_all_dir_rules $ac_dir Make.rules
 425
 426     case $ac_dir in
 427       dnl tools directory has both install-lib and install-dev
 428       tools) wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 429 "install:: $ac_dir
 430         @cd $ac_dir && \$(MAKE) install
 431 install-lib:: $ac_dir
 432         @cd $ac_dir && \$(MAKE) install-lib
 433 install-dev:: $ac_dir
 434         @cd $ac_dir && \$(MAKE) install-dev" ;;
 435       *)     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 436 "install install-dev:: $ac_dir
 437         @cd $ac_dir && \$(MAKE) install" ;;
 438     esac
 439     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 440 "uninstall:: $ac_dir/Makefile
 441         @cd $ac_dir && \$(MAKE) uninstall
 442 all __tooldeps__: $ac_dir
 443 .PHONY: $ac_dir
 444 $ac_dir: $ac_dir/Makefile libs/port dummy
 445         @cd $ac_dir && \$(MAKE)"
 446     case $ac_dir in
 447       tools/winebuild) wine_fn_append_rule ALL_MAKEFILE_DEPENDS "\$(WINEBUILD): $ac_dir" ;;
 448     esac
 449 }
 450
 451 wine_fn_config_makerules ()
 452 {
 453     ac_rules=$[1]
 454     ac_deps=$[2]
 455     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 456 "$ac_rules: $ac_rules.in $ac_deps config.status
 457         @./config.status $ac_rules
 458 distclean::
 459         \$(RM) $ac_rules"
 460 }
 461
 462 wine_fn_config_symlink ()
 463 {
 464     ac_link=$[1]
 465     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 466 "$ac_link:
 467         @./config.status $ac_link
 468 distclean::
 469         \$(RM) $ac_link"
 470 }
 471
 472 if test "x$CROSSTEST_DISABLE" != x
 473 then
 474     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 475 "crosstest:
 476         @echo \"crosstest is not supported (mingw not installed?)\" && false"
 477 fi])
 478
 479 dnl **** Define helper function to append a file to a makefile file list ****
 480 dnl
 481 dnl Usage: WINE_APPEND_FILE(var,file)
 482 dnl
 483 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 484
 485 dnl **** Define helper function to append a rule to a makefile command list ****
 486 dnl
 487 dnl Usage: WINE_APPEND_RULE(var,rule)
 488 dnl
 489 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 490
 491 dnl **** Create nonexistent directories from config.status ****
 492 dnl
 493 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 494 dnl
 495 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 496 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 497
 498 dnl **** Create symlinks from config.status ****
 499 dnl
 500 dnl Usage: WINE_CONFIG_SYMLINK(name,target,enable)
 501 dnl
 502 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 503 m4_ifval([$3],[if test "x$[$3]" != xno; then
 504 ])AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 505 m4_if([$2],,[test "$srcdir" = "." || ])wine_fn_config_symlink $1[]m4_ifval([$3],[
 506 fi])])
 507
 508 dnl **** Create a make rules file from config.status ****
 509 dnl
 510 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 511 dnl
 512 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 513 wine_fn_config_makerules $1 $3
 514 $2=$1
 515 AC_SUBST_FILE([$2])dnl
 516 AC_CONFIG_FILES([$1])])
 517
 518 dnl **** Create a makefile from config.status ****
 519 dnl
 520 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable)
 521 dnl
 522 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 523 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 524 wine_fn_config_makefile [$1] ac_enable[]dnl
 525 AS_VAR_POPDEF([ac_enable])])
 526
 527 dnl **** Create a dll makefile from config.status ****
 528 dnl
 529 dnl Usage: WINE_CONFIG_DLL(name,enable,flags,implib)
 530 dnl
 531 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 532 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 533 wine_fn_config_dll [$1] ac_enable [$3] [$4]dnl
 534 AS_VAR_POPDEF([ac_enable])])
 535
 536 dnl **** Create a program makefile from config.status ****
 537 dnl
 538 dnl Usage: WINE_CONFIG_PROGRAM(name,enable,flags)
 539 dnl
 540 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 541 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 542 wine_fn_config_program [$1] ac_enable [$3]dnl
 543 AS_VAR_POPDEF([ac_enable])])
 544
 545 dnl **** Create a test makefile from config.status ****
 546 dnl
 547 dnl Usage: WINE_CONFIG_TEST(dir)
 548 dnl
 549 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 550 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 551 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 552 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 553 m4_popdef([ac_suffix])dnl
 554 m4_popdef([ac_name])])
 555
 556 dnl **** Create a static lib makefile from config.status ****
 557 dnl
 558 dnl Usage: WINE_CONFIG_LIB(name)
 559 dnl
 560 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 561 wine_fn_config_lib $1])
 562
 563 dnl **** Create a tool makefile from config.status ****
 564 dnl
 565 dnl Usage: WINE_CONFIG_TOOL(name)
 566 dnl
 567 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 568 wine_fn_config_tool $1])
 569
 570 dnl **** Add a message to the list displayed at the end ****
 571 dnl
 572 dnl Usage: WINE_NOTICE(notice)
 573 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 574 dnl Usage: WINE_WARNING(warning)
 575 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 576 dnl Usage: WINE_PRINT_MESSAGES
 577 dnl
 578 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 579 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 580
 581 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 582   x)   WINE_NOTICE([$3]) ;;
 583   xno) ;;
 584   *)   AC_MSG_ERROR([$3
 585 This is an error since --with-$1 was requested.]) ;;
 586 esac])])
 587
 588 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 589   x)   WINE_WARNING([$3]) ;;
 590   xno) ;;
 591   *)   AC_MSG_ERROR([$3
 592 This is an error since --with-$1 was requested.]) ;;
 593 esac])])
 594
 595 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 596   xno) ;;
 597   *)   AC_MSG_ERROR([$3
 598 Use the --without-$1 option if you really want this.]) ;;
 599 esac])])
 600
 601 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 602 if test "x$wine_notices != "x; then
 603     echo >&AS_MESSAGE_FD
 604     IFS="|"
 605     for msg in $wine_notices; do
 606         IFS="$ac_save_IFS"
 607         if test -n "$msg"; then
 608             AC_MSG_NOTICE([$msg])
 609         fi
 610     done
 611 fi
 612 IFS="|"
 613 for msg in $wine_warnings; do
 614     IFS="$ac_save_IFS"
 615     if test -n "$msg"; then
 616         echo >&2
 617         AC_MSG_WARN([$msg])
 618     fi
 619 done
 620 IFS="$ac_save_IFS"])
 621
 622 dnl Local Variables:
 623 dnl compile-command: "autoreconf --warnings=all"
 624 dnl End: