git.oblomov.eu Git - wine/blob - tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of include/wine/server.h.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (                     # size align format
  26     "int"           => [  4,   4,  "%d" ],
  27     "short int"     => [  2,   2,  "%d" ],
  28     "char"          => [  1,   1,  "%c" ],
  29     "unsigned char" => [  1,   1,  "%02x" ],
  30     "unsigned short"=> [  2,   2,  "%04x" ],
  31     "unsigned int"  => [  4,   4,  "%08x" ],
  32     "void*"         => [  4,   4,  "%p" ],
  33     "data_size_t"   => [  4,   4,  "%u" ],
  34     "obj_handle_t"  => [  4,   4,  "%04x" ],
  35     "atom_t"        => [  2,   2,  "%04x" ],
  36     "user_handle_t" => [  4,   4,  "%08x" ],
  37     "process_id_t"  => [  4,   4,  "%04x" ],
  38     "thread_id_t"   => [  4,   4,  "%04x" ],
  39     "lparam_t"      => [  4,   4,  "%lx" ],
  40     "apc_param_t"   => [  8,   8,  "&dump_uint64" ],
  41     "file_pos_t"    => [  8,   8,  "&dump_uint64" ],
  42     "mem_size_t"    => [  8,   8,  "&dump_uint64" ],
  43     "timeout_t"     => [  8,   8,  "&dump_timeout" ],
  44     "rectangle_t"   => [  16,  4,  "&dump_rectangle" ],
  45     "char_info_t"   => [  4,   2,  "&dump_char_info" ],
  46     "apc_call_t"    => [  40,  8,  "&dump_apc_call" ],
  47     "apc_result_t"  => [  40,  8,  "&dump_apc_result" ],
  48     "async_data_t"  => [  28,  8,  "&dump_async_data" ],
  49     "luid_t"        => [  8,   4,  "&dump_luid" ],
  50     "ioctl_code_t"  => [  4,   4,  "&dump_ioctl_code" ],
  51 );
  52
  53 my @requests = ();
  54 my %replies = ();
  55
  56 my @trace_lines = ();
  57
  58 my $max_req_size = 64;
  59
  60 my $warnings = scalar(@ARGV) && $ARGV[0] eq "-w";
  61
  62 ### Generate a dumping function
  63
  64 sub DO_DUMP_FUNC($$@)
  65 {
  66     my $name = shift;
  67     my $req = shift;
  68     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  69     while ($#_ >= 0)
  70     {
  71         my $type = shift;
  72         my $var = shift;
  73         if (defined($formats{$type}))
  74         {
  75             my $fmt = ${$formats{$type}}[2];
  76             if ($fmt =~ /^&(.*)/)
  77             {
  78                 my $func = $1;
  79                 push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  80                 push @trace_lines, "    $func( &req->$var );\n";
  81                 push @trace_lines, "    fprintf( stderr, \",\" );\n" if ($#_ > 0);
  82             }
  83             elsif ($fmt =~ /^(%.*)\s+\((.*)\)/)
  84             {
  85                 my ($format, $cast) = ($1, $2);
  86                 push @trace_lines, "    fprintf( stderr, \" $var=$format";
  87                 push @trace_lines, "," if ($#_ > 0);
  88                 push @trace_lines, "\", ($cast)req->$var );\n";
  89             }
  90             else
  91             {
  92                 push @trace_lines, "    fprintf( stderr, \" $var=$fmt";
  93                 push @trace_lines, "," if ($#_ > 0);
  94                 push @trace_lines, "\", req->$var );\n";
  95             }
  96         }
  97         else  # must be some varargs format
  98         {
  99             my $func = $type;
 100             push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
 101             push @trace_lines, "    $func;\n";
 102             push @trace_lines, "    fputc( ',', stderr );\n" if ($#_ > 0);
 103         }
 104     }
 105     push @trace_lines, "}\n\n";
 106 }
 107
 108 ### Parse the request definitions
 109
 110 sub PARSE_REQUESTS()
 111 {
 112     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 113     my $state = 0;
 114     my $offset = 0;
 115     my $name = "";
 116     my @in_struct = ();
 117     my @out_struct = ();
 118
 119     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 120
 121     while (<PROTOCOL>)
 122     {
 123         my ($type, $var);
 124         # strip comments
 125         s!/\*.*\*/!!g;
 126         # strip white space at end of line
 127         s/\s+$//;
 128
 129         if (/^\@HEADER/)
 130         {
 131             die "Misplaced \@HEADER" unless $state == 0;
 132             $state++;
 133             next;
 134         }
 135
 136         # ignore everything while in state 0
 137         next if $state == 0;
 138
 139         if (/^\@REQ\(\s*(\w+)\s*\)/)
 140         {
 141             $name = $1;
 142             die "Misplaced \@REQ" unless $state == 1;
 143             # start a new request
 144             @in_struct = ();
 145             @out_struct = ();
 146             $offset = 12;
 147             print SERVER_PROT "struct ${name}_request\n{\n";
 148             print SERVER_PROT "    struct request_header __header;\n";
 149             $state++;
 150             next;
 151         }
 152
 153         if (/^\@REPLY/)
 154         {
 155             die "Misplaced \@REPLY" unless $state == 2;
 156             print SERVER_PROT "};\n";
 157             print SERVER_PROT "struct ${name}_reply\n{\n";
 158             print SERVER_PROT "    struct reply_header __header;\n";
 159             die "request $name too large ($offset)" if ($offset > $max_req_size);
 160             $offset = 8;
 161             $state++;
 162             next;
 163         }
 164
 165         if (/^\@END/)
 166         {
 167             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 168             print SERVER_PROT "};\n";
 169
 170             if ($state == 2)  # build dummy reply struct
 171             {
 172                 die "request $name too large ($offset)" if ($offset > $max_req_size);
 173                 print SERVER_PROT "struct ${name}_reply\n{\n";
 174                 print SERVER_PROT "    struct reply_header __header;\n";
 175                 print SERVER_PROT "};\n";
 176             }
 177             else
 178             {
 179                 die "reply $name too large ($offset)" if ($offset > $max_req_size);
 180             }
 181             # got a complete request
 182             push @requests, $name;
 183             DO_DUMP_FUNC( $name, "request", @in_struct);
 184             if ($#out_struct >= 0)
 185             {
 186                 $replies{$name} = 1;
 187                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 188             }
 189             $state = 1;
 190             next;
 191         }
 192
 193         if ($state != 1)
 194         {
 195             # skip empty lines (but keep them in output file)
 196             if (/^$/)
 197             {
 198                 print SERVER_PROT "\n";
 199                 next;
 200             }
 201
 202             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 203             {
 204                 $var = $1;
 205                 $type = "dump_varargs_" . $2 . "( min(cur_size,req->" . $3 . ") )";
 206                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 207             }
 208             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 209             {
 210                 $var = $1;
 211                 $type = "dump_varargs_" . $2 . "( cur_size )";
 212                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 213             }
 214             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 215             {
 216                 $type = $1;
 217                 $var = $3;
 218                 die "Unrecognized type $type" unless defined($formats{$type});
 219                 my @fmt = @{$formats{$type}};
 220                 if ($offset & ($fmt[1] - 1))
 221                 {
 222                     print "protocol.def:$.: warning: $name $offset $type $var needs padding\n" if $warnings;
 223                 }
 224                 $offset = ($offset + $fmt[1] - 1) & ~($fmt[1] - 1);
 225                 $offset += $fmt[0];
 226             }
 227             else
 228             {
 229                 die "Unrecognized syntax $_";
 230             }
 231             if ($state == 2) { push @in_struct, $type, $var; }
 232             if ($state == 3) { push @out_struct, $type, $var; }
 233         }
 234
 235         # Pass it through into the output file
 236         print SERVER_PROT $_ . "\n";
 237     }
 238     close PROTOCOL;
 239 }
 240
 241 ### Retrieve the server protocol version from the existing server_protocol.h file
 242
 243 sub GET_PROTOCOL_VERSION()
 244 {
 245     my $protocol = 0;
 246     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 247     while (<SERVER_PROT>)
 248     {
 249         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 250     }
 251     close SERVER_PROT;
 252     return $protocol;
 253 }
 254
 255 ### Retrieve the list of status and errors used in the server
 256
 257 sub GET_ERROR_NAMES()
 258 {
 259     my %errors = ();
 260     foreach my $f (glob "server/*.c")
 261     {
 262         next if $f eq "server/trace.c";
 263         open FILE, $f or die "Can't open $f";
 264         while (<FILE>)
 265         {
 266             if (/STATUS_(\w+)/)
 267             {
 268                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 269             }
 270             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 271             {
 272                 $errors{$1} = "0xc0010000 | $1";
 273             }
 274         }
 275         close FILE;
 276     }
 277     return %errors;
 278 }
 279
 280 # update a file if changed
 281 sub update_file($)
 282 {
 283     my $file = shift;
 284     my $ret = !(-f $file) || system "cmp $file $file.new >/dev/null";
 285     if (!$ret)
 286     {
 287         unlink "$file.new";
 288     }
 289     else
 290     {
 291         rename "$file.new", "$file";
 292         print "$file updated\n";
 293     }
 294     return $ret;
 295 }
 296
 297 # replace some lines in a file between two markers
 298 sub replace_in_file($$$@)
 299 {
 300     my $file = shift;
 301     my $start = shift;
 302     my $end = shift;
 303
 304     open NEW_FILE, ">$file.new" or die "cannot create $file.new";
 305
 306     if (defined($start))
 307     {
 308         open OLD_FILE, "$file" or die "cannot open $file";
 309         while (<OLD_FILE>)
 310         {
 311             print NEW_FILE $_;
 312             last if /$start/;
 313         }
 314     }
 315
 316     print NEW_FILE "\n", @_, "\n";
 317
 318     if (defined($end))
 319     {
 320         my $skip=1;
 321         while (<OLD_FILE>)
 322         {
 323             $skip = 0 if /$end/;
 324             print NEW_FILE $_ unless $skip;
 325         }
 326     }
 327
 328     close OLD_FILE if defined($start);
 329     close NEW_FILE;
 330     return update_file($file);
 331 }
 332
 333 ### Main
 334
 335 # Get the server protocol version
 336 my $protocol = GET_PROTOCOL_VERSION();
 337
 338 my %errors = GET_ERROR_NAMES();
 339
 340 ### Create server_protocol.h and print header
 341
 342 open SERVER_PROT, ">include/wine/server_protocol.h.new" or die "Cannot create include/wine/server_protocol.h.new";
 343 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 344 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 345 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 346 print SERVER_PROT " */\n\n";
 347 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 348 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 349
 350 ### Parse requests to find request/reply structure definitions
 351
 352 PARSE_REQUESTS();
 353
 354 ### Build the request list and structures
 355
 356 print SERVER_PROT "\n\nenum request\n{\n";
 357 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 358 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 359
 360 print SERVER_PROT "union generic_request\n{\n";
 361 print SERVER_PROT "    struct request_max_size max_size;\n";
 362 print SERVER_PROT "    struct request_header request_header;\n";
 363 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 364 print SERVER_PROT "};\n";
 365
 366 print SERVER_PROT "union generic_reply\n{\n";
 367 print SERVER_PROT "    struct request_max_size max_size;\n";
 368 print SERVER_PROT "    struct reply_header reply_header;\n";
 369 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 370 print SERVER_PROT "};\n\n";
 371
 372 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 373 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 374 close SERVER_PROT;
 375 update_file( "include/wine/server_protocol.h" );
 376
 377 ### Output the dumping function tables
 378
 379 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 380 foreach my $req (@requests)
 381 {
 382     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 383 }
 384 push @trace_lines, "};\n\n";
 385
 386 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 387 foreach my $req (@requests)
 388 {
 389     push @trace_lines, "    ", $replies{$req} ? "(dump_func)dump_${req}_reply,\n" : "NULL,\n";
 390 }
 391 push @trace_lines, "};\n\n";
 392
 393 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 394 foreach my $req (@requests)
 395 {
 396     push @trace_lines, "    \"$req\",\n";
 397 }
 398 push @trace_lines, "};\n\n";
 399
 400 push @trace_lines, "static const struct\n{\n";
 401 push @trace_lines, "    const char  *name;\n";
 402 push @trace_lines, "    unsigned int value;\n";
 403 push @trace_lines, "} status_names[] =\n{\n";
 404
 405 foreach my $err (sort keys %errors)
 406 {
 407     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 408 }
 409 push @trace_lines, "    { NULL, 0 }\n";
 410 push @trace_lines, "};\n";
 411
 412 replace_in_file( "server/trace.c",
 413                  "### make_requests begin ###",
 414                  "### make_requests end ###",
 415                  @trace_lines );
 416
 417 ### Output the request handlers list
 418
 419 my @request_lines = ();
 420
 421 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 422 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 423 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 424 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 425 foreach my $req (@requests)
 426 {
 427     push @request_lines, "    (req_handler)req_$req,\n";
 428 }
 429 push @request_lines, "};\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 430
 431 replace_in_file( "server/request.h",
 432                  "### make_requests begin ###",
 433                  "### make_requests end ###",
 434                  @request_lines );