git.oblomov.eu Git - wine/blob - tools/wrc/parser.l

   1 /* -*-C-*-
   2  *
   3  * Copyright 1998-2000  Bertho A. Stultiens (BS)
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9  *
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18  *
  19  * History:
  20  * 21-May-2000 BS       - Fixed the ident requirement of resource names
  21  *                        which can be keywords.
  22  * 30-Apr-2000 BS       - Reintegration into the wine-tree
  23  * 11-Jan-2000 BS       - Very drastic cleanup because we don't have a
  24  *                        preprocessor in here anymore.
  25  * 02-Jan-2000 BS       - Removed the preprocessor code
  26  * 23-Dec-1999 BS       - Removed the copyright for Martin von Loewis.
  27  *                        There is really nothing left of his code in
  28  *                        this parser.
  29  * 20-Jun-1998 BS       - Changed the filename conversion. Filenames are
  30  *                        case-sensitive inder *nix, but not under dos.
  31  *                        default behaviour is to convert to lower case.
  32  *                      - All backslashes are converted to forward and
  33  *                        both single and double slash is recognized as
  34  *                        MS/Borland does.
  35  *                      - Fixed a bug in 'yywf' case that prevented
  36  *                        double quoted names to be scanned propperly.
  37  *
  38  * 19-May-1998 BS       - Started to build a preprocessor.
  39  *                      - Changed keyword processing completely to
  40  *                        table-lookups.
  41  *
  42  * 20-Apr-1998 BS       - Added ';' comment stripping
  43  *
  44  * 17-Apr-1998 BS       - Made the win32 keywords optional when compiling in
  45  *                        16bit mode
  46  *
  47  * 15-Apr-1998 BS       - Changed string handling to include escapes
  48  *                      - Added unicode string handling (no codepage
  49  *                        translation though).
  50  *                      - 'Borrowed' the main idea of string scanning from
  51  *                        the flex manual pages.
  52  *                      - Added conditional handling of scanning depending
  53  *                        on the state of the parser. This was mainly required
  54  *                        to distinguish a file to load or raw data that
  55  *                        follows. MS's definition of filenames is rather
  56  *                        complex... It can be unquoted or double quoted. If
  57  *                        double quoted, then the '\\' char is not automatically
  58  *                        escaped according to Borland's rc compiler, but it
  59  *                        accepts both "\\path\\file.rc" and "\path\file.rc".
  60  *                        This makes life very hard! I go for the escaped
  61  *                        version, as this seems to be the documented way...
  62  *                      - Single quoted strings are now parsed and converted
  63  *                        here.
  64  *                      - Added comment stripping. The implementation is
  65  *                        'borrowed' from the flex manpages.
  66  *                      - Rebuild string processing so that it may contain
  67  *                        escaped '\0'.
  68  */
  69
  70 /* Exclusive string handling */
  71 %x tkstr
  72 /* Exclusive unicode string handling */
  73 %x tklstr
  74 /* Exclusive rcdata single quoted data handling */
  75 %x tkrcd
  76 /* Exclusive comment eating... */
  77 %x comment
  78 /* Set when stripping c-junk */
  79 %x pp_cstrip
  80 /* Set when scanning #line style directives */
  81 %x pp_line
  82 /* Set when scanning #pragma */
  83 %x pp_pragma
  84 %x pp_code_page
  85
  86 %option stack
  87 %option noinput nounput noyy_top_state noyywrap
  88 %option 8bit never-interactive
  89 %option prefix="parser_"
  90
  91 /* Some shortcut definitions */
  92 ws      [ \f\t\r]
  93 cident  [a-zA-Z_][0-9a-zA-Z_]*
  94
  95 %{
  96
  97 /*#define LEX_DEBUG*/
  98
  99 #include "config.h"
 100
 101 #include <stdio.h>
 102 #include <stdlib.h>
 103 #include <string.h>
 104 #include <ctype.h>
 105 #include <assert.h>
 106 #include <errno.h>
 107 #include <limits.h>
 108
 109 #ifdef HAVE_UNISTD_H
 110 #include <unistd.h>
 111 #else
 112 #define YY_NO_UNISTD_H
 113 #endif
 114
 115 #include "wine/unicode.h"
 116 #include "wrc.h"
 117 #include "utils.h"
 118 #include "parser.h"
 119 #include "newstruc.h"
 120
 121 #include "parser.tab.h"
 122
 123 /* Always update the current character position within a line */
 124 #define YY_USER_ACTION  char_number+=yyleng; wanted_id = want_id; want_id = 0;
 125
 126 #define YY_USER_INIT current_codepage = -1;
 127
 128 static void addcchar(char c);
 129 static void addwchar(WCHAR s);
 130 static string_t *get_buffered_cstring(void);
 131 static string_t *get_buffered_wstring(void);
 132 static string_t *make_string(char *s);
 133
 134 static char *cbuffer;           /* Buffers for string collection */
 135 static int cbufidx;
 136 static int cbufalloc = 0;
 137 static WCHAR *wbuffer;
 138 static int wbufidx;
 139 static int wbufalloc = 0;
 140
 141 static int current_codepage = -1;  /* use language default */
 142
 143 /*
 144  * This one is a bit tricky.
 145  * We set 'want_id' in the parser to get the first
 146  * identifier we get across in the scanner, but we
 147  * also want it to be reset at nearly any token we
 148  * see. Exceptions are:
 149  * - newlines
 150  * - comments
 151  * - whitespace
 152  *
 153  * The scanner will automatically reset 'want_id'
 154  * after *each* scanner reduction and puts is value
 155  * into the var below. In this way we can see the
 156  * state after the YY_RULE_SETUP (i.e. the user action;
 157  * see above) and don't have to worry too much when
 158  * it needs to be reset.
 159  */
 160 static int wanted_id = 0;
 161 static int save_wanted_id;      /* To save across comment reductions */
 162
 163 struct keyword {
 164         const char      *keyword;
 165         int             token;
 166         int             isextension;
 167         int             needcase;
 168         int             alwayskw;
 169 };
 170
 171 static struct keyword keywords[] = {
 172         { "ACCELERATORS",       tACCELERATORS,          0, 0, 0},
 173         { "ALT",                tALT,                   0, 0, 0},
 174         { "ASCII",              tASCII,                 0, 0, 0},
 175         { "AUTO3STATE",         tAUTO3STATE,            1, 0, 0},
 176         { "AUTOCHECKBOX",       tAUTOCHECKBOX,          1, 0, 0},
 177         { "AUTORADIOBUTTON",    tAUTORADIOBUTTON,       1, 0, 0},
 178         { "BEGIN",              tBEGIN,                 0, 0, 0},
 179         { "BITMAP",             tBITMAP,                0, 0, 0},
 180         { "BLOCK",              tBLOCK,                 0, 0, 0},
 181         { "BUTTON",             tBUTTON,                1, 0, 0},
 182         { "CAPTION",            tCAPTION,               0, 0, 0},
 183         { "CHARACTERISTICS",    tCHARACTERISTICS,       1, 0, 0},
 184         { "CHECKBOX",           tCHECKBOX,              0, 0, 0},
 185         { "CHECKED",            tCHECKED,               0, 0, 0},
 186         { "CLASS",              tCLASS,                 0, 0, 0},
 187         { "COMBOBOX",           tCOMBOBOX,              0, 0, 0},
 188         { "CONTROL",            tCONTROL,               0, 0, 0},
 189         { "CTEXT",              tCTEXT,                 0, 0, 0},
 190         { "CURSOR",             tCURSOR,                0, 0, 0},
 191         { "DEFPUSHBUTTON",      tDEFPUSHBUTTON,         0, 0, 0},
 192         { "DIALOG",             tDIALOG,                0, 0, 0},
 193         { "DIALOGEX",           tDIALOGEX,              1, 0, 0},
 194         { "DISCARDABLE",        tDISCARDABLE,           0, 0, 0},
 195         { "DLGINIT",            tDLGINIT,               0, 0, 0},
 196         { "EDITTEXT",           tEDITTEXT,              0, 0, 0},
 197         { "END",                tEND,                   0, 0, 0},
 198         { "EXSTYLE",            tEXSTYLE,               0, 0, 0},
 199         { "FILEFLAGS",          tFILEFLAGS,             0, 0, 0},
 200         { "FILEFLAGSMASK",      tFILEFLAGSMASK,         0, 0, 0},
 201         { "FILEOS",             tFILEOS,                0, 0, 0},
 202         { "FILESUBTYPE",        tFILESUBTYPE,           0, 0, 0},
 203         { "FILETYPE",           tFILETYPE,              0, 0, 0},
 204         { "FILEVERSION",        tFILEVERSION,           0, 0, 0},
 205         { "FIXED",              tFIXED,                 0, 0, 0},
 206         { "FONT",               tFONT,                  0, 0, 0},
 207         { "FONTDIR",            tFONTDIR,               0, 0, 0},       /* This is a Borland BRC extension */
 208         { "GRAYED",             tGRAYED,                0, 0, 0},
 209         { "GROUPBOX",           tGROUPBOX,              0, 0, 0},
 210         { "HELP",               tHELP,                  0, 0, 0},
 211         { "HTML",               tHTML,                  0, 0, 0},
 212         { "ICON",               tICON,                  0, 0, 0},
 213         { "IMPURE",             tIMPURE,                0, 0, 0},
 214         { "INACTIVE",           tINACTIVE,              0, 0, 0},
 215         { "LANGUAGE",           tLANGUAGE,              1, 0, 1},
 216         { "LISTBOX",            tLISTBOX,               0, 0, 0},
 217         { "LOADONCALL",         tLOADONCALL,            0, 0, 0},
 218         { "LTEXT",              tLTEXT,                 0, 0, 0},
 219         { "MENU",               tMENU,                  0, 0, 0},
 220         { "MENUBARBREAK",       tMENUBARBREAK,          0, 0, 0},
 221         { "MENUBREAK",          tMENUBREAK,             0, 0, 0},
 222         { "MENUEX",             tMENUEX,                1, 0, 0},
 223         { "MENUITEM",           tMENUITEM,              0, 0, 0},
 224         { "MESSAGETABLE",       tMESSAGETABLE,          1, 0, 0},
 225         { "MOVEABLE",           tMOVEABLE,              0, 0, 0},
 226         { "NOINVERT",           tNOINVERT,              0, 0, 0},
 227         { "NOT",                tNOT,                   0, 0, 0},
 228         { "POPUP",              tPOPUP,                 0, 0, 0},
 229         { "PRELOAD",            tPRELOAD,               0, 0, 0},
 230         { "PRODUCTVERSION",     tPRODUCTVERSION,        0, 0, 0},
 231         { "PURE",               tPURE,                  0, 0, 0},
 232         { "PUSHBUTTON",         tPUSHBUTTON,            0, 0, 0},
 233         { "RADIOBUTTON",        tRADIOBUTTON,           0, 0, 0},
 234         { "RCDATA",             tRCDATA,                0, 0, 0},
 235         { "RTEXT",              tRTEXT,                 0, 0, 0},
 236         { "SCROLLBAR",          tSCROLLBAR,             0, 0, 0},
 237         { "SEPARATOR",          tSEPARATOR,             0, 0, 0},
 238         { "SHIFT",              tSHIFT,                 0, 0, 0},
 239         { "STATE3",             tSTATE3,                1, 0, 0},
 240         { "STRING",             tSTRING,                0, 0, 0},
 241         { "STRINGTABLE",        tSTRINGTABLE,           0, 0, 1},
 242         { "STYLE",              tSTYLE,                 0, 0, 0},
 243         { "TOOLBAR",            tTOOLBAR,               1, 0, 0},
 244         { "VALUE",              tVALUE,                 0, 0, 0},
 245         { "VERSION",            tVERSION,               1, 0, 0},
 246         { "VERSIONINFO",        tVERSIONINFO,           0, 0, 0},
 247         { "VIRTKEY",            tVIRTKEY,               0, 0, 0}
 248 };
 249
 250 #define NKEYWORDS       (sizeof(keywords)/sizeof(keywords[0]))
 251 #define KWP(p)          ((const struct keyword *)(p))
 252 static int kw_cmp_func(const void *s1, const void *s2)
 253 {
 254         int ret;
 255         ret = strcasecmp(KWP(s1)->keyword, KWP(s2)->keyword);
 256         if(!ret && (KWP(s1)->needcase || KWP(s2)->needcase))
 257                 return strcmp(KWP(s1)->keyword, KWP(s2)->keyword);
 258         else
 259                 return ret;
 260 }
 261
 262 #define KW_BSEARCH
 263 #define DO_SORT
 264 static struct keyword *iskeyword(char *kw)
 265 {
 266         struct keyword *kwp;
 267         struct keyword key;
 268         key.keyword = kw;
 269         key.needcase = 0;
 270 #ifdef DO_SORT
 271         {
 272                 /* Make sure that it is sorted for bsearsh */
 273                 static int sorted = 0;
 274                 if(!sorted)
 275                 {
 276                         qsort(keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 277                         sorted = 1;
 278                 }
 279         }
 280 #endif
 281 #ifdef KW_BSEARCH
 282         kwp = bsearch(&key, keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 283 #else
 284         {
 285                 int i;
 286                 for(i = 0; i < NKEYWORDS; i++)
 287                 {
 288                         if(!kw_cmp_func(&key, &keywords[i]))
 289                                 break;
 290                 }
 291                 if(i < NKEYWORDS)
 292                         kwp = &keywords[i];
 293                 else
 294                         kwp = NULL;
 295         }
 296 #endif
 297
 298         if(kwp == NULL || (kwp->isextension && !extensions))
 299                 return NULL;
 300         else
 301                 return kwp;
 302 }
 303
 304 /* converts an integer in string form to an unsigned long and prints an error
 305  * on overflow */
 306 static unsigned long xstrtoul(const char *nptr, char **endptr, int base)
 307 {
 308     unsigned long l;
 309
 310     errno = 0;
 311     l = strtoul(nptr, endptr, base);
 312     if (l == ULONG_MAX && errno == ERANGE)
 313         parser_error("integer constant %s is too large", nptr);
 314     return l;
 315 }
 316
 317 %}
 318
 319 /*
 320  **************************************************************************
 321  * The flexer starts here
 322  **************************************************************************
 323  */
 324 %%
 325         /*
 326          * Catch the GCC-style line statements here and parse them.
 327          * This has the advantage that you can #include at any
 328          * stage in the resource file.
 329          * The preprocessor generates line directives in the format:
 330          * # <linenum> "filename" <codes>
 331          *
 332          * Codes can be a sequence of:
 333          * - 1 start of new file
 334          * - 2 returning to previous
 335          * - 3 system header
 336          * - 4 interpret as C-code
 337          *
 338          * 4 is not used and 1 mutually excludes 2
 339          * Anyhow, we are not really interested in these at all
 340          * because we only want to know the linenumber and
 341          * filename.
 342          */
 343 <INITIAL,pp_cstrip>^{ws}*\#{ws}*pragma{ws}+     yy_push_state(pp_pragma);
 344 <INITIAL,pp_cstrip>^{ws}*\#{ws}*        yy_push_state(pp_line);
 345 <pp_line>[^\n]* {
 346                 int lineno, len;
 347                 char *cptr;
 348                 char *fname;
 349                 yy_pop_state();
 350                 lineno = (int)strtol(yytext, &cptr, 10);
 351                 if(!lineno)
 352                         parser_error("Malformed '#...' line-directive; invalid linenumber");
 353                 fname = strchr(cptr, '"');
 354                 if(!fname)
 355                         parser_error("Malformed '#...' line-directive; missing filename");
 356                 fname++;
 357                 cptr = strchr(fname, '"');
 358                 if(!cptr)
 359                         parser_error("Malformed '#...' line-directive; missing terminating \"");
 360                 *cptr = '\0';
 361                 line_number = lineno - 1;       /* We didn't read the newline */
 362                 input_name = xstrdup(fname);
 363                 /* ignore contents of C include files */
 364                 len = strlen(input_name);
 365                 if (len > 1 && !strcasecmp( input_name + len - 2, ".h" ))
 366                     BEGIN(pp_cstrip);
 367                 else
 368                     BEGIN(INITIAL);
 369         }
 370
 371 <pp_pragma>code_page[^\n]*      yyless(9); yy_pop_state(); yy_push_state(pp_code_page);
 372 <pp_pragma>[^\n]*               yy_pop_state(); if (pedantic) parser_warning("Unrecognized #pragma directive '%s'\n",yytext);
 373
 374 <pp_code_page>\({ws}*default{ws}*\)[^\n]*       current_codepage = -1; yy_pop_state();
 375 <pp_code_page>\({ws}*utf8{ws}*\)[^\n]*          current_codepage = CP_UTF8; yy_pop_state();
 376 <pp_code_page>\({ws}*[0-9]+{ws}*\)[^\n]* {
 377         char *p = yytext;
 378         yy_pop_state();
 379         while (*p < '0' || *p > '9') p++;
 380         current_codepage = strtol( p, NULL, 10 );
 381         if (current_codepage != CP_UTF8 && !wine_cp_get_table( current_codepage ))
 382         {
 383             parser_error("Codepage %d not supported", current_codepage);
 384             current_codepage = 0;
 385         }
 386     }
 387 <pp_code_page>[^\n]*    yy_pop_state(); parser_error("Malformed #pragma code_page directive");
 388
 389         /*
 390          * Strip everything until a ';' taking
 391          * into account braces {} for structures,
 392          * classes and enums.
 393          */
 394 <pp_cstrip>\n                   line_number++; char_number = 1;
 395 <pp_cstrip>.                    ; /* ignore */
 396
 397 \{                      return tBEGIN;
 398 \}                      return tEND;
 399
 400 [0-9]+[lL]?             { parser_lval.num = xstrtoul(yytext,  0, 10); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 401 0[xX][0-9A-Fa-f]+[lL]?  { parser_lval.num = xstrtoul(yytext,  0, 16); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 402 0[oO][0-7]+[lL]?        { parser_lval.num = xstrtoul(yytext+2, 0, 8); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 403
 404         /*
 405          * The next two rules scan identifiers and filenames.
 406          * This is achieved by using the priority ruling
 407          * of the scanner where a '.' is valid in a filename
 408          * and *only* in a filename. In this case, the second
 409          * rule will be reduced because it is longer.
 410          */
 411 [A-Za-z_0-9.]+          {
 412                                 struct keyword *tok = iskeyword(yytext);
 413
 414                                 if(tok)
 415                                 {
 416                                         if(wanted_id && !tok->alwayskw)
 417                                         {
 418                                                 parser_lval.str = make_string(yytext);
 419                                                 return tIDENT;
 420                                         }
 421                                         else
 422                                                 return tok->token;
 423                                 }
 424                                 else
 425                                 {
 426                                         parser_lval.str = make_string(yytext);
 427                                         return tIDENT;
 428                                 }
 429                         }
 430 [A-Za-z_0-9./\\]+               parser_lval.str = make_string(yytext); return tFILENAME;
 431
 432         /*
 433          * Wide string scanning
 434          */
 435 L\"                     {
 436                                 yy_push_state(tklstr);
 437                                 wbufidx = 0;
 438                                 if(!win32)
 439                                         parser_warning("16bit resource contains unicode strings\n");
 440                         }
 441 <tklstr>\"{ws}+ |
 442 <tklstr>\"              {
 443                                 yy_pop_state();
 444                                 parser_lval.str = get_buffered_wstring();
 445                                 return tSTRING;
 446                         }
 447 <tklstr>\\[0-7]{1,6}    { /* octal escape sequence */
 448                                 unsigned int result;
 449                                 result = strtoul(yytext+1, 0, 8);
 450                                 if ( result > 0xffff )
 451                                         parser_error("Character constant out of range");
 452                                 addwchar((WCHAR)result);
 453                         }
 454 <tklstr>\\x[0-9a-fA-F]{4} {  /* hex escape sequence */
 455                                 unsigned int result;
 456                                 result = strtoul(yytext+2, 0, 16);
 457                                 addwchar((WCHAR)result);
 458                         }
 459 <tklstr>\\x[0-9a-fA-F]{1,3} {  parser_error("Invalid hex escape sequence '%s'", yytext); }
 460
 461 <tklstr>\\[0-9]+        parser_error("Bad escape sequence");
 462 <tklstr>\\\n{ws}*       line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 463 <tklstr>\\a             addwchar('\a');
 464 <tklstr>\\b             addwchar('\b');
 465 <tklstr>\\f             addwchar('\f');
 466 <tklstr>\\n             addwchar('\n');
 467 <tklstr>\\r             addwchar('\r');
 468 <tklstr>\\t             addwchar('\t');
 469 <tklstr>\\v             addwchar('\v');
 470 <tklstr>\\.             addwchar(yytext[1]);
 471 <tklstr>\\\r\n          addwchar(yytext[2]); line_number++; char_number = 1;
 472 <tklstr>\"\"            addwchar('\"');         /* "bla""bla"  -> "bla\"bla" */
 473 <tklstr>\\\"\"          addwchar('\"');         /* "bla\""bla" -> "bla\"bla" */
 474 <tklstr>\"{ws}+\"       ;                       /* "bla" "bla" -> "blabla" */
 475 <tklstr>[^\\\n\"]+      {
 476                                 char *yptr = yytext;
 477                                 while(*yptr)    /* FIXME: codepage translation */
 478                                         addwchar(*yptr++ & 0xff);
 479                         }
 480 <tklstr>\n              parser_error("Unterminated string");
 481
 482         /*
 483          * Normal string scanning
 484          */
 485 \"                      yy_push_state(tkstr); cbufidx = 0;
 486 <tkstr>\"{ws}+  |
 487 <tkstr>\"               {
 488                                 yy_pop_state();
 489                                 parser_lval.str = get_buffered_cstring();
 490                                 return tSTRING;
 491                         }
 492 <tkstr>\\[0-7]{1,3}     { /* octal escape sequence */
 493                                 int result;
 494                                 result = strtol(yytext+1, 0, 8);
 495                                 if ( result > 0xff )
 496                                         parser_error("Character constant out of range");
 497                                 addcchar((char)result);
 498                         }
 499 <tkstr>\\x[0-9a-fA-F]{2} {  /* hex escape sequence */
 500                                 int result;
 501                                 result = strtol(yytext+2, 0, 16);
 502                                 addcchar((char)result);
 503                         }
 504 <tkstr>\\x[0-9a-fA-F]   {  parser_error("Invalid hex escape sequence '%s'", yytext); }
 505
 506 <tkstr>\\[0-9]+         parser_error("Bad escape sequence");
 507 <tkstr>\\\n{ws}*        line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 508 <tkstr>\\a              addcchar('\a');
 509 <tkstr>\\b              addcchar('\b');
 510 <tkstr>\\f              addcchar('\f');
 511 <tkstr>\\n              addcchar('\n');
 512 <tkstr>\\r              addcchar('\r');
 513 <tkstr>\\t              addcchar('\t');
 514 <tkstr>\\v              addcchar('\v');
 515 <tkstr>\\.              addcchar(yytext[1]);
 516 <tkstr>\\\r\n           addcchar(yytext[2]); line_number++; char_number = 1;
 517 <tkstr>[^\\\n\"]+       {
 518                                 char *yptr = yytext;
 519                                 while(*yptr)
 520                                         addcchar(*yptr++);
 521                         }
 522 <tkstr>\"\"             addcchar('\"');         /* "bla""bla"   -> "bla\"bla" */
 523 <tkstr>\\\"\"           addcchar('\"');         /* "bla\""bla"  -> "bla\"bla" */
 524 <tkstr>\"{ws}+\"        ;                       /* "bla" "bla"  -> "blabla" */
 525 <tkstr>\n               parser_error("Unterminated string");
 526
 527         /*
 528          * Raw data scanning
 529          */
 530 \'                      yy_push_state(tkrcd); cbufidx = 0;
 531 <tkrcd>\'               {
 532                                 yy_pop_state();
 533                                 parser_lval.raw = new_raw_data();
 534                                 parser_lval.raw->size = cbufidx;
 535                                 parser_lval.raw->data = xmalloc(parser_lval.raw->size);
 536                                 memcpy(parser_lval.raw->data, cbuffer, parser_lval.raw->size);
 537                                 return tRAWDATA;
 538                         }
 539 <tkrcd>[0-9a-fA-F]{2}   {
 540                                 int result;
 541                                 result = strtol(yytext, 0, 16);
 542                                 addcchar((char)result);
 543                         }
 544 <tkrcd>{ws}+            ;       /* Ignore space */
 545 <tkrcd>\n               line_number++; char_number = 1;
 546 <tkrcd>.                parser_error("Malformed data-line");
 547
 548         /*
 549          * Comment stripping
 550          * Should never occur after preprocessing
 551          */
 552 <INITIAL,pp_cstrip>"/*" {
 553                                 yy_push_state(comment);
 554                                 save_wanted_id = wanted_id;
 555                                 if(!no_preprocess)
 556                                         parser_warning("Found comments after preprocessing, please report\n");
 557                         }
 558 <comment>[^*\n]*        ;
 559 <comment>"*"+[^*/\n]*   ;
 560 <comment>\n             line_number++; char_number = 1;
 561 <comment>"*"+"/"        yy_pop_state(); want_id = save_wanted_id;
 562
 563 ;[^\n]*                 want_id = wanted_id; /* not really comment, but left-over c-junk */
 564 "//"[^\n]*              want_id = wanted_id; if(!no_preprocess) parser_warning("Found comments after preprocessing, please report\n");
 565
 566 \n                      {
 567                                 want_id = wanted_id;
 568                                 line_number++;
 569                                 char_number = 1;
 570                                 if(want_nl)
 571                                 {
 572                                         want_nl = 0;
 573                                         return tNL;
 574                                 }
 575                         }
 576 {ws}+                   want_id = wanted_id;    /* Eat whitespace */
 577
 578 <INITIAL>[ -~]          return yytext[0];
 579
 580 <*>.|\n                 {
 581                                 /* Catch all rule to find any unmatched text */
 582                                 if(*yytext == '\n')
 583                                 {
 584                                         line_number++;
 585                                         char_number = 1;
 586                                 }
 587                                 parser_error("Unmatched text '%c' (0x%02x) YY_START=%d",
 588                                              isprint((unsigned char)*yytext) ? *yytext : '.', *yytext, YY_START);
 589                         }
 590
 591 %%
 592
 593 /* These dup functions copy the enclosed '\0' from
 594  * the resource string.
 595  */
 596 static void addcchar(char c)
 597 {
 598         if(cbufidx >= cbufalloc)
 599         {
 600                 cbufalloc += 1024;
 601                 cbuffer = xrealloc(cbuffer, cbufalloc * sizeof(cbuffer[0]));
 602                 if(cbufalloc > 65536)
 603                         parser_warning("Reallocating string buffer larger than 64kB\n");
 604         }
 605         cbuffer[cbufidx++] = c;
 606 }
 607
 608 static void addwchar(WCHAR s)
 609 {
 610         if(wbufidx >= wbufalloc)
 611         {
 612                 wbufalloc += 1024;
 613                 wbuffer = xrealloc(wbuffer, wbufalloc * sizeof(wbuffer[0]));
 614                 if(wbufalloc > 65536)
 615                         parser_warning("Reallocating wide string buffer larger than 64kB\n");
 616         }
 617         wbuffer[wbufidx++] = s;
 618 }
 619
 620 static string_t *get_buffered_cstring(void)
 621 {
 622     string_t *str = new_string();
 623
 624     str->size = cbufidx;
 625     str->type = str_char;
 626     str->str.cstr = xmalloc(cbufidx+1);
 627     memcpy(str->str.cstr, cbuffer, cbufidx);
 628     str->str.cstr[cbufidx] = '\0';
 629
 630     if (!current_codepage || current_codepage == -1 || !win32)  /* store as ANSI string */
 631     {
 632         if (!current_codepage) parser_error("Codepage set to Unicode only, cannot use ASCII string here");
 633         return str;
 634     }
 635     else  /* convert to Unicode before storing */
 636     {
 637         string_t *str_w = convert_string( str, str_unicode, current_codepage );
 638         if (!check_unicode_conversion( str, str_w, current_codepage ))
 639             parser_error("String %s does not convert identically to Unicode and back in codepage %d. "
 640                     "Try using a Unicode string instead", str->str.cstr, current_codepage );
 641         if (check_valid_utf8( str, current_codepage ))
 642             parser_warning( "string \"%s\" seems to be UTF-8 but codepage %u is in use.\n",
 643                             str->str.cstr, current_codepage );
 644         free_string( str );
 645         return str_w;
 646     }
 647 }
 648
 649 static string_t *get_buffered_wstring(void)
 650 {
 651         string_t *str = new_string();
 652         str->size = wbufidx;
 653         str->type = str_unicode;
 654         str->str.wstr = xmalloc((wbufidx+1)*sizeof(WCHAR));
 655         memcpy(str->str.wstr, wbuffer, wbufidx*sizeof(WCHAR));
 656         str->str.wstr[wbufidx] = 0;
 657         return str;
 658 }
 659
 660 static string_t *make_string(char *s)
 661 {
 662         string_t *str = new_string();
 663         str->size = strlen(s);
 664         str->type = str_char;
 665         str->str.cstr = xmalloc(str->size+1);
 666         memcpy(str->str.cstr, s, str->size+1);
 667         return str;
 668 }