git.oblomov.eu Git - wine/blob - aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_GET_SONAME(LIBRARY, FUNCTION, [OTHER_LIBRARIES])
  34 dnl
  35 AC_DEFUN([WINE_GET_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])
  37 AC_CACHE_CHECK([for -l$1 soname], ac_cv_lib_soname_$1,
  38 [ac_get_soname_save_LIBS=$LIBS
  39 LIBS="-l$1 $3 $LIBS"
  40   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  41   [ac_cv_lib_soname_$1=`$ac_cv_path_LDD conftest$ac_exeext | grep lib$1\\.so | sed 's/^.*\(lib$1\.so[[^  ]]*\).*$/\1/'`
  42   if test "x$ac_cv_lib_soname_$1" = "x"
  43   then
  44      ac_cv_lib_soname_$1="lib$1.so"
  45   fi],
  46   [ac_cv_lib_soname_$1="lib$1.so"])
  47   LIBS=$ac_get_soname_save_LIBS])
  48 if test "x$ac_cv_lib_soname_$1" != xNONE
  49 then AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),"$ac_cv_lib_soname_$1",
  50                         [Define to the soname of the lib$1 library.])dnl
  51 fi])
  52
  53 dnl **** Link C code with an assembly file ****
  54 dnl
  55 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  56 dnl
  57 AC_DEFUN([WINE_TRY_ASM_LINK],
  58 [AC_TRY_LINK([void ac_asm(void) { asm([$1]); }
  59 [$2]],[$3],[$4],[$5])])
  60
  61 dnl **** Check if we can link an empty program with special CFLAGS ****
  62 dnl
  63 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  64 dnl
  65 AC_DEFUN([WINE_TRY_CFLAGS],
  66 [ac_wine_try_cflags_saved=$CFLAGS
  67 CFLAGS="$CFLAGS $1"
  68 AC_TRY_LINK([],[],[$2],[$3])
  69 CFLAGS=$ac_wine_try_cflags_saved])
  70
  71 dnl **** Check whether we need to define a symbol on the compiler command line ****
  72 dnl
  73 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  74 dnl
  75 AC_DEFUN([WINE_CHECK_DEFINE],
  76 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
  77 AC_CACHE_CHECK([whether we need to define $1],ac_var,
  78     AC_EGREP_CPP(yes,[#ifndef $1
  79 yes
  80 #endif],
  81     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
  82 AS_IF([test AS_VAR_GET(ac_var) = yes],
  83       [CFLAGS="$CFLAGS -D$1"
  84   LINTFLAGS="$LINTFLAGS -D$1"])dnl
  85 AS_VAR_POPDEF([ac_var])])
  86
  87 dnl **** Check for ln ****
  88 dnl
  89 dnl Usage: WINE_PROG_LN
  90 dnl
  91 AC_DEFUN([WINE_PROG_LN],
  92 [AC_MSG_CHECKING([whether ln works])
  93 rm -f conf$$ conf$$.file
  94 echo >conf$$.file
  95 if ln conf$$.file conf$$ 2>/dev/null; then
  96   AC_SUBST(LN,ln)
  97   AC_MSG_RESULT([yes])
  98 else
  99   AC_SUBST(LN,["cp -p"])
 100   AC_MSG_RESULT([no, using $LN])
 101 fi
 102 rm -f conf$$ conf$$.file])
 103
 104 dnl **** Create non-existent directories from config.status ****
 105 dnl
 106 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 107 dnl
 108 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 109 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])])