git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION)
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(nptl,      AC_HELP_STRING([--with-nptl],[use glibc NPTL threading support]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  26 if test "x$enable_win16" = "xno"
  27 then
  28   WIN16_FILES=""
  29   WIN16_INSTALL=""
  30 fi
  31 if test "x$enable_debug" = "xno"
  32 then
  33     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  34 fi
  35 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  36 then
  37     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  38 fi
  39
  40 dnl **** Check for some programs ****
  41
  42 AC_CANONICAL_HOST
  43 AC_PROG_MAKE_SET
  44 AC_PROG_CC
  45 AC_PROG_CPP
  46
  47 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  48   [if test -z "$with_wine_tools"; then
  49      if test "$cross_compiling" = "yes"; then
  50        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  51      else
  52        wine_cv_toolsdir="\$(TOPOBJDIR)"
  53      fi
  54    elif test -d "$with_wine_tools/tools/winebuild"; then
  55      case $with_wine_tools in
  56        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  57        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  58      esac
  59    else
  60      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  61    fi])
  62 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  63
  64 AC_PATH_XTRA
  65 AC_PROG_YACC
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
  71 if test "$XYACC" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
  74 fi
  75 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  76 if test "$XLEX" = "none"
  77 then
  78   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  79 fi
  80
  81 AC_CHECK_TOOLS(AS,[gas as],as)
  82 AC_CHECK_TOOL(LD,ld,ld)
  83 AC_CHECK_TOOL(AR,ar,ar)
  84 AC_PROG_RANLIB
  85 AC_CHECK_TOOL(STRIP,strip,strip)
  86 AC_CHECK_TOOL(WINDRES,windres,false)
  87 AC_PROG_LN_S
  88 WINE_PROG_LN
  89 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  90 AC_PROG_INSTALL
  91 dnl Prepend src dir to install path dir if it's a relative path
  92 case "$INSTALL" in
  93   [[\\/$]]* | ?:[[\\/]]* ) ;;
  94   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  95 esac
  96
  97 dnl Check for lint
  98 AC_CHECK_PROGS(LINT, lclint lint)
  99 if test "$LINT" = "lint"
 100 then
 101   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 102   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 103 fi
 104 AC_SUBST(LINT)
 105 AC_SUBST(LINTFLAGS)
 106
 107 dnl Check for db2html
 108 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 109 AC_SUBST(DB2HTML)
 110
 111 dnl Check for db2pdf
 112 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 113 AC_SUBST(DB2PDF)
 114
 115 dnl Check for db2ps
 116 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 117 AC_SUBST(DB2PS)
 118
 119 dnl Check for db2txt
 120 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 121 AC_SUBST(DB2TXT)
 122
 123 dnl **** Check for some libraries ****
 124
 125 dnl Check for -lm
 126 AC_CHECK_LIB(m,sqrt)
 127 dnl Check for -li386 for NetBSD and OpenBSD
 128 AC_CHECK_LIB(i386,i386_set_ldt)
 129 dnl Check for -lossaudio for NetBSD
 130 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 131 dnl Check for -lw for Solaris
 132 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 133 dnl Check for -lnsl for Solaris
 134 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 135 dnl Check for -lsocket for Solaris
 136 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 137 dnl Check for -lresolv for Solaris
 138 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 139 dnl Check for -lxpg4 for FreeBSD
 140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 141 dnl Check for -lpthread
 142 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 143
 144 JPEGLIB=""
 145 AC_SUBST(JPEGLIB)
 146 AC_CHECK_HEADERS(jpeglib.h,
 147     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 148         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 149         JPEGLIB="-ljpeg"
 150     )
 151 )
 152
 153 AC_SUBST(GIFLIB,"")
 154 AC_CHECK_HEADERS(gif_lib.h,
 155     AC_CHECK_LIB(ungif,DGifOpen,
 156         [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
 157          GIFLIB="-lungif"],
 158         [AC_CHECK_LIB(gif,DGifOpen,
 159                       [AC_DEFINE(HAVE_LIBGIF,1)
 160                        GIFLIB="-lgif"])]))
 161
 162 AC_SUBST(XLIB)
 163 AC_SUBST(XFILES)
 164 XFILES=""
 165 AC_SUBST(OPENGLFILES)
 166 OPENGLFILES=""
 167 AC_SUBST(GLU32FILES)
 168 GLU32FILES=""
 169 AC_SUBST(OPENGL_LIBS)
 170 OPENGL_LIBS=""
 171 if test "$have_x" = "yes"
 172 then
 173     XLIB="-lXext -lX11"
 174     ac_save_CPPFLAGS="$CPPFLAGS"
 175     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 176
 177     dnl *** All of the following tests require X11/Xlib.h
 178     AC_CHECK_HEADERS(X11/Xlib.h,
 179       [
 180         AC_CHECK_HEADERS([X11/XKBlib.h \
 181                           X11/Xutil.h \
 182                           X11/extensions/shape.h \
 183                           X11/extensions/XShm.h \
 184                           X11/extensions/Xrandr.h \
 185                           X11/extensions/Xrender.h \
 186                           X11/extensions/Xvlib.h \
 187                           X11/extensions/xf86dga.h \
 188                           X11/extensions/xf86vmode.h],,,
 189                          [#include <X11/Xlib.h>
 190                           #ifdef HAVE_X11_XUTIL_H
 191                           # include <X11/Xutil.h>
 192                           #endif])
 193
 194         dnl *** Check for X keyboard extension
 195         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 196         then
 197               AC_CHECK_LIB(X11, XkbQueryExtension,
 198               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 199               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 200         fi
 201
 202         dnl *** Check for X Shm extension
 203         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 204         then
 205               AC_CHECK_LIB(Xext, XShmQueryExtension,
 206               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 207               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 208         fi
 209
 210         dnl *** Check for X shape extension
 211         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 212         then
 213               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 214               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 215               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 216         fi
 217
 218         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 219         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 220         then
 221               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 222                 [ dnl *** If found...
 223                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 224                             [Define if you have the Xxf86dga library version 2])
 225                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 226                ],
 227                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 228                   dnl *** instead (DGA 2.0 not found)...
 229                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 230                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 231                                 [Define if you have the Xxf86dga library version 1])
 232                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 233                     ],,
 234                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 235                   )
 236                 ],
 237                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 238         fi
 239
 240         dnl *** Check for XFree86 VMODE extension
 241         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 242         then
 243                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 244                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 245                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 246                   ],,
 247                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 248         fi
 249
 250         dnl *** Check for X RandR extension
 251         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 252         then
 253                 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
 254                   [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
 255                      X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
 256                   ],,
 257                   $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
 258         fi
 259
 260         dnl *** Check for XVideo extension supporting XvImages
 261         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 262         then
 263                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 264                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 265                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 266                   ],,
 267                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 268         fi
 269       ]
 270     ) dnl *** End of X11/Xlib.h check
 271
 272     dnl Check for the presence of OpenGL
 273     if test "x$with_opengl" != "xno"
 274     then
 275         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 276         then
 277             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 278 This prevents linking to OpenGL. Delete the file and restart configure.])
 279         fi
 280
 281         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 282         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 283         then
 284             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 285             dnl Check for some problems due to old Mesa versions
 286             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 287               AC_TRY_COMPILE(
 288                 [#include <GL/gl.h>],
 289                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 290                 [wine_cv_opengl_version_OK="yes"],
 291                 [wine_cv_opengl_version_OK="no"]
 292               )
 293             )
 294
 295             if test "$wine_cv_opengl_version_OK" = "yes"
 296             then
 297                 dnl Check for the presence of the library
 298                 AC_CHECK_LIB(GL,glXCreateContext,
 299                              OPENGL_LIBS="-lGL"
 300                              ,,
 301                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 302
 303                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 304                 then
 305                         OPENGLFILES='$(OPENGLFILES)'
 306                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 307
 308                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 309                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 310                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 311                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 312
 313                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 314                         then
 315                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 316                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 317                                                   #ifdef HAVE_GL_GLEXT_H
 318                                                   # include <GL/glext.h>
 319                                                   #endif
 320                                                   ],
 321                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 322                                                  [wine_cv_extension_prototypes="yes"],
 323                                                  [wine_cv_extension_prototypes="no"]
 324                                   )]
 325                                 )
 326                                 if test "$wine_cv_extension_prototypes" = "yes"
 327                                 then
 328                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 329                                               [Define if the OpenGL headers define extension typedefs])
 330                                 fi
 331                         fi
 332
 333                 fi
 334                 dnl Check for GLU32 library.
 335                 AC_CHECK_LIB(GLU,gluLookAt,
 336                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 337                              GLU32FILES='$(GLU32FILES)']
 338                              ,,
 339                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 340                 )
 341              fi
 342          fi
 343     fi
 344
 345     dnl **** Check for NAS ****
 346     AC_SUBST(NASLIBS,"")
 347     AC_CHECK_HEADERS(audio/audiolib.h,
 348          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 349           AC_CHECK_LIB(audio,AuCreateFlow,
 350                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 351                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 352                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 353
 354     CPPFLAGS="$ac_save_CPPFLAGS"
 355     XFILES='$(XFILES)'
 356 else
 357     XLIB=""
 358     X_CFLAGS=""
 359     X_LIBS=""
 360 fi
 361
 362 dnl **** Check which curses lib to use ***
 363 CURSESLIBS=""
 364 if test "x$with_curses" != "xno"
 365 then
 366     AC_CHECK_HEADERS(ncurses.h,
 367         [AC_CHECK_LIB(ncurses,waddch,
 368             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 369              CURSESLIBS="-lncurses"],
 370              [AC_CHECK_HEADERS(curses.h,
 371                  [AC_CHECK_LIB(curses,waddch,
 372                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 373                       CURSESLIBS="-lcurses"])])])])
 374     saved_libs="$LIBS"
 375     LIBS="$CURSESLIBS $LIBS"
 376     AC_CHECK_FUNCS(getbkgd resizeterm)
 377     LIBS="$saved_libs"
 378 fi
 379 AC_SUBST(CURSESLIBS)
 380
 381 dnl **** Check for SANE ****
 382 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 383 if test "$sane_devel" = "no"
 384 then
 385     SANELIBS=""
 386     SANEINCL=""
 387 else
 388     SANELIBS="`$sane_devel --libs`"
 389     SANEINCL="`$sane_devel --cflags`"
 390     ac_save_CPPFLAGS="$CPPFLAGS"
 391     ac_save_LIBS="$LIBS"
 392     CPPFLAGS="$CPPFLAGS $SANEINCL"
 393     LIBS="$LIBS $SANELIBS"
 394     AC_CHECK_HEADER(sane/sane.h,
 395                     [AC_CHECK_LIB(sane,sane_open,
 396                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 397                                   [SANELIBS=""
 398                                   SANEINCL=""])],
 399                     [SANELIBS=""
 400                     SANEINCL=""])
 401     LIBS="$ac_save_LIBS"
 402     CPPFLAGS="$ac_save_CPPFLAGS"
 403 fi
 404 AC_SUBST(SANELIBS)
 405 AC_SUBST(SANEINCL)
 406
 407 dnl **** Check for the ICU library ****
 408 AC_CHECK_HEADERS(unicode/ubidi.h)
 409 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 410 then
 411     AC_CACHE_CHECK([whether we can statically link the ICU libraries], ac_cv_lib_icu,
 412         [saved_libs="$LIBS"
 413          ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 414          ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
 415          ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
 416          LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 417          AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 418                      [ac_cv_lib_icu="yes"],[ac_cv_lib_icu="no"])
 419         LIBS="$saved_libs"])
 420     if test "$ac_cv_lib_icu" = "yes"
 421     then
 422         AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 423         AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 424     fi
 425 fi
 426
 427 dnl **** Check for FreeType 2 ****
 428 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 429 if test "$ft_lib" = "no"
 430 then
 431     FREETYPEINCL=""
 432     wine_cv_msg_freetype=no
 433 else
 434     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 435     if test "$ft_devel" = "no"
 436     then
 437         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 438         if test "$ft_devel2" = "freetype2-config"
 439         then
 440                 ft_devel=$ft_devel2
 441         fi
 442     fi
 443     if test "$ft_devel" = "no"
 444     then
 445         FREETYPEINCL=""
 446         wine_cv_msg_freetype=yes
 447     else
 448         FREETYPEINCL=`$ft_devel --cflags`
 449         ac_save_CPPFLAGS="$CPPFLAGS"
 450         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 451         AC_CHECK_HEADERS(freetype/freetype.h \
 452                          freetype/ftglyph.h \
 453                          freetype/tttables.h \
 454                          freetype/ftnames.h \
 455                          freetype/ftsnames.h \
 456                          freetype/ttnameid.h \
 457                          freetype/ftoutln.h \
 458                          freetype/internal/sfnt.h)
 459         AC_TRY_CPP([#include <ft2build.h>
 460                     #include <freetype/fttrigon.h>],
 461                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 462           [Define if you have the <freetype/fttrigon.h> header file.])
 463                     wine_cv_fttrigon=yes],
 464                     wine_cv_fttrigon=no)
 465         CPPFLAGS="$ac_save_CPPFLAGS"
 466         dnl Check that we have at least freetype/freetype.h
 467         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 468         then
 469             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 470             wine_cv_msg_freetype=no
 471         else
 472             FREETYPEINCL=""
 473             wine_cv_msg_freetype=yes
 474         fi
 475     fi
 476 fi
 477 AC_SUBST(FREETYPEINCL)
 478
 479 dnl **** Check for parport (currently Linux only) ****
 480 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 481  AC_TRY_COMPILE(
 482    [#include <linux/ppdev.h>],
 483    [ioctl (1,PPCLAIM,0)],
 484    [ac_cv_c_ppdev="yes"],
 485    [ac_cv_c_ppdev="no"])
 486  )
 487 if test "$ac_cv_c_ppdev" = "yes"
 488 then
 489     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 490 fi
 491
 492 dnl **** Check for va_copy ****
 493 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 494  AC_TRY_LINK(
 495    [#include <stdarg.h>],
 496    [va_list ap1, ap2;
 497     va_copy(ap1,ap2);
 498    ],
 499    [ac_cv_c_va_copy="yes"],
 500    [ac_cv_c_va_copy="no"])
 501  )
 502 if test "$ac_cv_c_va_copy" = "yes"
 503 then
 504     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 505 fi
 506 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 507  AC_TRY_LINK(
 508    [#include <stdarg.h>],
 509    [va_list ap1, ap2;
 510     __va_copy(ap1,ap2);
 511    ],
 512    [ac_cv_c___va_copy="yes"],
 513    [ac_cv_c___va_copy="no"])
 514  )
 515 if test "$ac_cv_c___va_copy" = "yes"
 516 then
 517     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 518 fi
 519
 520 dnl **** Check for sigsetjmp ****
 521 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 522  AC_TRY_LINK(
 523    [#include <setjmp.h>],
 524    [sigjmp_buf buf;
 525     sigsetjmp( buf, 1 );
 526     siglongjmp( buf, 1 );],
 527    [ac_cv_c_sigsetjmp="yes"],
 528    [ac_cv_c_sigsetjmp="no"])
 529  )
 530 if test "$ac_cv_c_sigsetjmp" = "yes"
 531 then
 532     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 533 fi
 534
 535 dnl **** Check for pthread_rwlock_t ****
 536 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 537 #include <pthread.h>])
 538
 539 dnl **** Check for Open Sound System ****
 540 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 541
 542 AC_CACHE_CHECK([for Open Sound System],
 543         ac_cv_c_opensoundsystem,
 544         AC_TRY_COMPILE([
 545         #if defined(HAVE_SYS_SOUNDCARD_H)
 546                 #include <sys/soundcard.h>
 547         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 548                 #include <machine/soundcard.h>
 549         #elif defined(HAVE_SOUNDCARD_H)
 550                 #include <soundcard.h>
 551         #endif
 552         ],[
 553
 554 /* check for one of the Open Sound System specific SNDCTL_ defines */
 555 #if !defined(SNDCTL_DSP_STEREO)
 556 #error No open sound system
 557 #endif
 558 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 559
 560 if test "$ac_cv_c_opensoundsystem" = "yes"
 561 then
 562     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 563 fi
 564
 565 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 566         ac_cv_c_opensoundsystem_midi,
 567         AC_TRY_COMPILE([
 568         #if defined(HAVE_SYS_SOUNDCARD_H)
 569                 #include <sys/soundcard.h>
 570         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 571                 #include <machine/soundcard.h>
 572         #elif defined(HAVE_SOUNDCARD_H)
 573                 #include <soundcard.h>
 574         #endif
 575         ],[
 576
 577 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 578 #if !defined(SNDCTL_SEQ_SYNC)
 579 #error No open sound system MIDI interface
 580 #endif
 581 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 582
 583 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 584 then
 585     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 586 fi
 587
 588 dnl **** Check for aRts Sound Server ****
 589 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 590 AC_CACHE_CHECK([for aRts Sound server],
 591         ac_cv_c_artsserver,
 592         if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
 593         then
 594             ac_cv_c_artsserver=no
 595         else
 596             ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
 597             ARTSC_LIBS=`$ARTSCCONFIG --libs`
 598             ac_cv_c_artsserver=no
 599             save_CFLAGS="$CFLAGS"
 600             CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 601             AC_TRY_COMPILE([
 602              #include <artsc.h>
 603             ],[
 604              arts_stream_t stream;
 605             ],[
 606             ac_cv_c_artsserver=yes
 607             ])
 608             CFLAGS="$save_CFLAGS"
 609         fi)
 610
 611 if test "$ac_cv_c_artsserver" = "yes"
 612 then
 613     AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 614     AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 615
 616     AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
 617 fi
 618
 619 dnl **** Check for ALSA ****
 620 AC_SUBST(ALSALIBS,"")
 621 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 622 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 623 then
 624     AC_CHECK_LIB(asound,snd_pcm_open,
 625         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 626         ALSALIBS="-lasound")
 627 fi
 628
 629 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 630
 631 AC_SUBST(AUDIOIOLIBS,"")
 632 AC_CHECK_HEADERS(libaudioio.h,
 633     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 634                   [AUDIOIOLIBS="-laudioio"
 635                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 636
 637 dnl **** Check for capi4linux ****
 638
 639 AC_CHECK_HEADERS(capi20.h,[
 640         AC_CHECK_HEADERS(linux/capi.h,[
 641                 AC_CHECK_LIB(capi20,capi20_register,[
 642                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 643                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 644                 ])
 645         ])
 646 ])
 647
 648 dnl **** Check for broken glibc mmap64 ****
 649
 650 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 651         AC_TRY_RUN([
 652                 #define _FILE_OFFSET_BITS 64
 653                 #include <stdio.h>
 654                 #include <unistd.h>
 655                 #include <fcntl.h>
 656                 #include <sys/mman.h>
 657                 #include <errno.h>
 658
 659                 int main(int argc,char **argv) {
 660                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 661                         if (fd == -1) exit(1);
 662
 663                         unlink("conftest.map");
 664
 665                         write(fd,"test",4);
 666
 667                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 668                             (errno == EINVAL)
 669                         ) {
 670                                 exit(1);
 671                         }
 672                         close(fd);
 673                         fprintf(stderr,"success!\n");
 674                         exit(0);
 675                 }
 676
 677         ],
 678     ac_cv_mmap64_works="yes",
 679     ac_cv_mmap64_works="no",
 680     ac_cv_mmap64_works="no") )
 681
 682 if test "$ac_cv_mmap64_works" = "yes"
 683 then
 684     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 685 fi
 686
 687 dnl **** Check for gcc specific options ****
 688
 689 AC_SUBST(EXTRACFLAGS,"")
 690 if test "x${GCC}" = "xyes"
 691 then
 692   EXTRACFLAGS=-Wall
 693
 694   dnl Check for strength-reduce bug
 695   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 696                   AC_TRY_RUN([
 697 int     L[[4]] = {0,1,2,3};
 698 int main(void) {
 699   static int Array[[3]];
 700   unsigned int B = 3;
 701   int i;
 702   for(i=0; i<B; i++) Array[[i]] = i - 3;
 703   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 704   L[[i]] = 4;
 705
 706   exit( Array[[1]] != -2 || L[[2]] != 3);
 707 }],
 708     ac_cv_c_gcc_strength_bug="no",
 709     ac_cv_c_gcc_strength_bug="yes",
 710     ac_cv_c_gcc_strength_bug="yes") )
 711   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 712   then
 713     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 714   fi
 715
 716   dnl Check for -mpreferred-stack-boundary
 717   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 718       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 719                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 720   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 721   then
 722     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 723   fi
 724
 725   dnl Check for -fno-strict-aliasing
 726   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 727       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 728                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 729   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 730   then
 731     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 732   fi
 733
 734   dnl Check for -gstabs+ option
 735   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 736       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 737   if test "$ac_cv_c_gcc_gstabs" = "yes"
 738   then
 739     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 740   fi
 741
 742   dnl Check for noisy string.h
 743   saved_CFLAGS="$CFLAGS"
 744   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 745   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 746       AC_TRY_COMPILE([#include <string.h>],[],
 747                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 748   CFLAGS="$saved_CFLAGS"
 749   if test "$ac_cv_c_string_h_warnings" = "no"
 750   then
 751     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 752   fi
 753 fi
 754
 755 dnl **** Check how to define a function in assembly code ****
 756
 757 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 758   WINE_TRY_ASM_LINK(
 759       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 760       ac_cv_asm_func_def=".def",
 761     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 762       ac_cv_asm_func_def=".type @function",
 763     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 764       ac_cv_asm_func_def=".type 2",
 765       ac_cv_asm_func_def="unknown")])]))
 766
 767 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 768 case "$ac_cv_asm_func_def" in
 769   ".def")
 770      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 771   ".type @function")
 772      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 773   ".type 2")
 774      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 775   *)
 776      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 777 esac
 778
 779 dnl **** Check for underscore on external symbols ****
 780
 781 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 782     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 783                       [extern int ac_test;],
 784                       [if (ac_test) return 1],
 785                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 786
 787 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 788 if test "$ac_cv_c_extern_prefix" = "yes"
 789 then
 790   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 791 else
 792   AC_DEFINE([__ASM_NAME(name)], [name])
 793 fi
 794
 795 dnl **** Check how to do strings in assembler ****
 796
 797 AC_CACHE_CHECK([whether assembler accepts .string], ac_cv_c_asm_string,
 798     WINE_TRY_ASM_LINK([".data\n\t.string \"test\"\n\t.text"],,,
 799                       ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no"))
 800 if test "$ac_cv_c_asm_string" = "yes"
 801 then
 802   AC_DEFINE(__ASM_STRING, [".string"], [Define to the assembler keyword used to specify an ASCII string])
 803 else
 804     AC_CACHE_CHECK([whether assembler accepts .asciz], ac_cv_c_asm_asciz,
 805         WINE_TRY_ASM_LINK([".data\n\t.asciz \"test\"\n\t.text"],,,
 806                       ac_cv_c_asm_asciz="yes",ac_cv_c_asm_asciz="no"))
 807     if test "$ac_cv_c_asm_asciz" = "yes"
 808     then
 809       AC_DEFINE(__ASM_STRING, [".asciz"])
 810     else
 811       AC_DEFINE(__ASM_STRING, [".ascii"])
 812     fi
 813 fi
 814
 815 dnl **** Check for .short in assembler ****
 816
 817 AC_CACHE_CHECK([whether assembler accepts .short], ac_cv_c_asm_short,
 818     WINE_TRY_ASM_LINK([".data\n\t.short 1\n\t.text"],,,
 819                       ac_cv_c_asm_short="yes",ac_cv_c_asm_short="no"))
 820 if test "$ac_cv_c_asm_short" = "yes"
 821 then
 822   AC_DEFINE(__ASM_SHORT, [".short"], [Define to the assembler keyword used to specify a word value])
 823 else
 824   AC_DEFINE(__ASM_SHORT, [".half"])
 825 fi
 826
 827 dnl **** Check for working dll ****
 828
 829 AC_SUBST(DLLEXT,"")
 830 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 831 AC_SUBST(DLLIBS,"")
 832 AC_SUBST(LDSHARED,"")
 833 AC_SUBST(LDDLL,"")
 834 AC_SUBST(LIBEXT,"so")
 835 AC_SUBST(IMPLIBEXT,"def")
 836
 837 case $host_os in
 838   cygwin*|mingw32*)
 839     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 840     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 841     if test "$DLLWRAP" = "false"; then
 842       LIBEXT="a"
 843     else
 844       dnl FIXME - check whether dllwrap works correctly...
 845       LIBEXT="dll"
 846     fi
 847     IMPLIBEXT="a"
 848     ;;
 849   *)
 850     AC_CHECK_HEADERS(dlfcn.h,
 851         [AC_CHECK_FUNCS(dlopen,,
 852             [AC_CHECK_LIB(dl,dlopen,
 853                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 854                           DLLIBS="-ldl"],
 855                          [LIBEXT="a"])])],
 856         [LIBEXT="a"])
 857
 858     if test "$LIBEXT" = "so"
 859     then
 860       DLLFLAGS="$DLLFLAGS -fPIC"
 861       DLLEXT=".so"
 862       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 863           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 864                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 865       if test "$ac_cv_c_dll_gnuelf" = "yes"
 866       then
 867         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 868         LDDLL="\$(CC) -shared -Wl,-Bsymbolic"
 869         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 870           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 871                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 872         if test "$ac_cv_c_dll_zdefs" = "yes"
 873         then
 874           LDDLL="$LDDLL,-z,defs"
 875         fi
 876         AC_CACHE_CHECK([whether we can relocate the executable to 0x3c000000], ac_cv_ld_reloc_exec,
 877           [saved_CFLAGS="$CFLAGS"
 878            CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x3c000100"
 879            AC_TRY_RUN([#include <unistd.h>
 880                        int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
 881                       ac_cv_ld_reloc_exec="yes",
 882                       ac_cv_ld_reloc_exec="no",
 883                       ac_cv_ld_reloc_exec="no")
 884            CFLAGS="$saved_CFLAGS"])
 885         if test "$ac_cv_ld_reloc_exec" = "yes"
 886         then
 887           AC_SUBST(LDEXECFLAGS,["-Wl,--section-start,.interp=0x3c000100"])
 888         fi
 889       else
 890         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 891             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 892                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 893         if test "$ac_cv_c_dll_unixware" = "yes"
 894         then
 895           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 896           LDDLL="\$(CC) -Wl,-G,-B,symbolic"
 897         fi
 898       fi
 899     fi
 900
 901     dnl Check for cross compiler to build test programs
 902     AC_SUBST(CROSSTEST,"")
 903     if test "$cross_compiling" = "no"
 904     then
 905       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc,false)
 906       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool,false)
 907       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres,false)
 908       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 909     fi
 910     ;;
 911 esac
 912
 913 if test "$LIBEXT" = "a"; then
 914   AC_MSG_ERROR(
 915 [could not find a way to build shared libraries.
 916 It is currently not possible to build Wine without shared library
 917 (.so) support to allow transparent switch between .so and .dll files.
 918 If you are using Linux, you will need a newer binutils.]
 919 )
 920 fi
 921
 922 case $build_os in
 923   cygwin*|mingw32*)
 924     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 925   *)
 926     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 927 esac
 928
 929 dnl Mingw needs explicit msvcrt for linking libwine
 930 case $host_os in
 931   mingw32*)
 932     AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
 933 esac
 934
 935 case $host_os in
 936   linux*)
 937     AC_SUBST(WINE_BINARIES,"wine-kthread wine-pthread")
 938     if test "x$with_nptl" = "xyes"
 939     then
 940         AC_SUBST(MAIN_BINARY,"wine-pthread")
 941     else
 942         AC_SUBST(MAIN_BINARY,"wine-kthread")
 943     fi
 944     ;;
 945   *)
 946     AC_SUBST(WINE_BINARIES,"wine-kthread")
 947     AC_SUBST(MAIN_BINARY,"wine-kthread")
 948     ;;
 949 esac
 950
 951 dnl **** Get the soname for libraries that we load dynamically ****
 952
 953 if test "$LIBEXT" = "so"
 954 then
 955   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
 956   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 957   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 958   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
 959   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
 960   WINE_GET_SONAME(cups,cupsGetDefault)
 961   WINE_GET_SONAME(jack,jack_client_new)
 962   WINE_GET_SONAME(fontconfig, FcInit);
 963   WINE_GET_SONAME(ssl,SSL_library_init)
 964   WINE_GET_SONAME(crypto,BIO_new_socket)
 965   WINE_GET_SONAME(ncurses,waddch)
 966   WINE_GET_SONAME(curses,waddch)
 967 fi
 968
 969
 970 dnl **** Check for functions ****
 971
 972 AC_FUNC_ALLOCA()
 973 AC_CHECK_FUNCS(\
 974         _lwp_create \
 975         _lwp_self \
 976         _pclose \
 977         _popen \
 978         _snprintf \
 979         _spawnvp \
 980         _stricmp \
 981         _strnicmp \
 982         _vsnprintf \
 983         chsize \
 984         clone \
 985         finite \
 986         fpclass \
 987         ftruncate \
 988         ftruncate64 \
 989         getnetbyaddr \
 990         getnetbyname \
 991         getopt_long \
 992         getpagesize \
 993         getprotobyname \
 994         getprotobynumber \
 995         getpwuid \
 996         getservbyport \
 997         gettid \
 998         gettimeofday \
 999         inet_network \
1000         lseek64 \
1001         lstat \
1002         memmove \
1003         mmap \
1004         pclose \
1005         popen \
1006         pread \
1007         pwrite \
1008         rfork \
1009         select \
1010         sendmsg \
1011         settimeofday \
1012         sigaltstack \
1013         snprintf \
1014         spawnvp \
1015         statfs \
1016         strcasecmp \
1017         strerror \
1018         strncasecmp \
1019         tcgetattr \
1020         timegm \
1021         usleep \
1022         vfscanf \
1023         vsnprintf \
1024         wait4 \
1025         waitpid \
1026 )
1027
1028 dnl **** Check for header files ****
1029
1030 AC_CHECK_HEADERS(\
1031         arpa/inet.h \
1032         arpa/nameser.h \
1033         cups/cups.h \
1034         direct.h \
1035         elf.h \
1036         float.h \
1037         fontconfig/fontconfig.h \
1038         getopt.h \
1039         ieeefp.h \
1040         io.h \
1041         jack/jack.h \
1042         libio.h \
1043         libutil.h \
1044         link.h \
1045         linux/cdrom.h \
1046         linux/hdreg.h \
1047         linux/input.h \
1048         linux/joystick.h \
1049         linux/major.h \
1050         linux/param.h \
1051         linux/serial.h \
1052         linux/ucdrom.h \
1053         machine/cpu.h \
1054         netdb.h \
1055         netinet/in.h \
1056         netinet/in_systm.h \
1057         netinet/tcp.h \
1058         netinet/tcp_fsm.h \
1059         openssl/ssl.h \
1060         process.h \
1061         pthread.h \
1062         pty.h \
1063         pwd.h \
1064         regex.h \
1065         sched.h \
1066         scsi/sg.h \
1067         scsi/scsi.h \
1068         scsi/scsi_ioctl.h \
1069         socket.h \
1070         stdint.h \
1071         strings.h \
1072         sys/cdio.h \
1073         sys/errno.h \
1074         sys/file.h \
1075         sys/filio.h \
1076         sys/inttypes.h \
1077         sys/ioctl.h \
1078         sys/ipc.h \
1079         sys/link.h \
1080         sys/lwp.h \
1081         sys/mman.h \
1082         sys/modem.h \
1083         sys/msg.h \
1084         sys/param.h \
1085         sys/poll.h \
1086         sys/ptrace.h \
1087         sys/reg.h \
1088         sys/scsiio.h \
1089         sys/shm.h \
1090         sys/signal.h \
1091         sys/socket.h \
1092         sys/sockio.h \
1093         sys/statfs.h \
1094         sys/strtio.h \
1095         sys/syscall.h \
1096         sys/sysctl.h \
1097         sys/time.h \
1098         sys/times.h \
1099         sys/uio.h \
1100         sys/un.h \
1101         sys/v86.h \
1102         sys/v86intr.h \
1103         sys/vfs.h \
1104         sys/vm86.h \
1105         sys/wait.h \
1106         syscall.h \
1107         termios.h \
1108         unistd.h \
1109         utime.h \
1110         valgrind/memcheck.h
1111 )
1112 AC_HEADER_STAT()
1113
1114 dnl **** Checks for headers that depend on other ones ****
1115
1116 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1117     [#include <sys/types.h>
1118      #if HAVE_SYS_PARAM_H
1119      # include <sys/param.h>
1120      #endif])
1121
1122 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1123     [#include <sys/types.h>
1124      #if HAVE_SYS_SOCKET_H
1125      # include <sys/socket.h>
1126      #endif])
1127
1128 AC_CHECK_HEADERS([resolv.h],,,
1129     [#include <sys/types.h>
1130      #if HAVE_SYS_SOCKET_H
1131      # include <sys/socket.h>
1132      #endif
1133      #if HAVE_NETINET_IN_H
1134      # include <netinet/in.h>
1135      #endif
1136      #if HAVE_ARPA_NAMESER_H
1137      # include <arpa/nameser.h>
1138      #endif])
1139
1140 AC_CHECK_HEADERS(netinet/ip.h,,,
1141     [#include <sys/types.h>
1142      #if HAVE_SYS_SOCKET_H
1143      # include <sys/socket.h>
1144      #endif
1145      #if HAVE_NETINET_IN_SYSTM_H
1146      # include <netinet/in_systm.h>
1147      #endif])
1148
1149 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1150
1151 dnl **** Check for IPX headers (currently Linux only) ****
1152
1153 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1154  AC_TRY_COMPILE(
1155    [#include <sys/types.h>
1156     #ifdef HAVE_SYS_SOCKET_H
1157     # include <sys/socket.h>
1158     #endif
1159     #include <netipx/ipx.h>],
1160    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1161    [ac_cv_c_ipx_gnu="yes"],
1162    [ac_cv_c_ipx_gnu="no"])
1163  )
1164 if test "$ac_cv_c_ipx_gnu" = "yes"
1165 then
1166     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1167 fi
1168
1169 if test "$ac_cv_c_ipx_gnu" = "no"
1170 then
1171  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1172   AC_TRY_COMPILE(
1173     [#include <sys/types.h>
1174      #ifdef HAVE_SYS_SOCKET_H
1175      # include <sys/socket.h>
1176      #endif
1177      #include <asm/types.h>
1178      #include <linux/ipx.h>],
1179     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1180     [ac_cv_c_ipx_linux="yes"],
1181     [ac_cv_c_ipx_linux="no"])
1182   )
1183   if test "$ac_cv_c_ipx_linux" = "yes"
1184   then
1185       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1186   fi
1187 fi
1188
1189 dnl **** Check for types ****
1190
1191 AC_C_CONST
1192 AC_C_INLINE
1193 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1194 AC_CHECK_SIZEOF(long long,0)
1195
1196 AC_CACHE_CHECK([whether linux/input.h is for real],
1197         wine_cv_linux_input_h,
1198         AC_TRY_COMPILE([
1199             #include <linux/input.h>
1200         ] , [
1201             int foo = EVIOCGBIT(EV_ABS,42);
1202             int bar = BTN_PINKIE;
1203             int fortytwo = 42;
1204         ],
1205         wine_cv_linux_input_h=yes,
1206         wine_cv_linux_input_h=no,
1207         no
1208         )
1209     )
1210     if test "$wine_cv_linux_input_h" = "yes"
1211     then
1212         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1213                   [Define if we have linux/input.h AND it contains the INPUT event API])
1214     fi
1215
1216
1217 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1218         wine_cv_linux_gethostbyname_r_6,
1219         AC_TRY_COMPILE([
1220 #include <netdb.h>
1221         ], [
1222     char *name=NULL;
1223     struct hostent he;
1224     struct hostent *result;
1225     char *buf=NULL;
1226     int bufsize=0;
1227     int res,errnr;
1228     char *addr=NULL;
1229     int addrlen=0;
1230     int addrtype=0;
1231     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1232     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1233     ],
1234         wine_cv_linux_gethostbyname_r_6=yes,
1235         wine_cv_linux_gethostbyname_r_6=no
1236         )
1237    )
1238    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1239    then
1240       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1241                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1242    fi
1243
1244 if test "$ac_cv_header_linux_joystick_h" = "yes"
1245 then
1246    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1247         wine_cv_linux_joystick_22_api,
1248         AC_TRY_COMPILE([
1249         #include <sys/ioctl.h>
1250         #include <linux/joystick.h>
1251
1252         struct js_event blub;
1253         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1254         #error "no 2.2 header"
1255         #endif
1256         ],/*empty*/,
1257         wine_cv_linux_joystick_22_api=yes,
1258         wine_cv_linux_joystick_22_api=no,
1259         wine_cv_linux_joystick_22_api=no
1260         )
1261    )
1262    if test "$wine_cv_linux_joystick_22_api" = "yes"
1263    then
1264       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1265                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1266    fi
1267 fi
1268
1269 dnl **** statfs checks ****
1270
1271 if test "$ac_cv_header_sys_vfs_h" = "yes"
1272 then
1273     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1274                     wine_cv_sys_vfs_has_statfs,
1275         AC_TRY_COMPILE([
1276         #include <sys/types.h>
1277         #ifdef HAVE_SYS_PARAM_H
1278         # include <sys/param.h>
1279         #endif
1280         #include <sys/vfs.h>
1281         ],[
1282                 struct statfs stfs;
1283
1284                 memset(&stfs,0,sizeof(stfs));
1285         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1286         )
1287     )
1288     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1289     then
1290       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1291                 [Define if the struct statfs is defined by <sys/vfs.h>])
1292     fi
1293 fi
1294
1295 if test "$ac_cv_header_sys_statfs_h" = "yes"
1296 then
1297     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1298                     wine_cv_sys_statfs_has_statfs,
1299         AC_TRY_COMPILE([
1300         #include <sys/types.h>
1301         #ifdef HAVE_SYS_PARAM_H
1302         # include <sys/param.h>
1303         #endif
1304         #include <sys/statfs.h>
1305         ],[
1306                 struct statfs stfs;
1307         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1308         )
1309     )
1310     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1311     then
1312       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1313                 [Define if the struct statfs is defined by <sys/statfs.h>])
1314     fi
1315 fi
1316
1317 if test "$ac_cv_header_sys_mount_h" = "yes"
1318 then
1319     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1320                     wine_cv_sys_mount_has_statfs,
1321         AC_TRY_COMPILE([
1322         #include <sys/types.h>
1323         #ifdef HAVE_SYS_PARAM_H
1324         # include <sys/param.h>
1325         #endif
1326         #include <sys/mount.h>
1327         ],[
1328                 struct statfs stfs;
1329         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1330         )
1331     )
1332     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1333     then
1334       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1335                 [Define if the struct statfs is defined by <sys/mount.h>])
1336     fi
1337 fi
1338
1339 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1340
1341 dnl Check for statfs members
1342 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1343 [#include <sys/types.h>
1344 #ifdef HAVE_SYS_PARAM_H
1345 # include <sys/param.h>
1346 #endif
1347 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1348 # include <sys/mount.h>
1349 #else
1350 # ifdef STATFS_DEFINED_BY_SYS_VFS
1351 #  include <sys/vfs.h>
1352 # else
1353 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1354 #   include <sys/statfs.h>
1355 #  endif
1356 # endif
1357 #endif])
1358
1359 dnl Check for socket structure members
1360 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1361 [#include <sys/types.h>
1362 #ifdef HAVE_SYS_SOCKET_H
1363 # include <sys/socket.h>
1364 #endif
1365 #ifdef HAVE_SYS_UN_H
1366 # include <sys/un.h>
1367 #endif])
1368
1369 dnl Check for siginfo_t members
1370 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1371
1372 dnl Check for struct option
1373 AC_CHECK_MEMBERS([struct option.name],,,
1374 [#ifdef HAVE_GETOPT_H
1375 #include <getopt.h>
1376 #endif])
1377
1378 dnl Check for stat.st_blocks
1379 AC_CHECK_MEMBERS([struct stat.st_blocks])
1380
1381 dnl *** check for the need to define platform-specific symbols
1382
1383 case $host_cpu in
1384   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1385   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1386   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1387   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1388 esac
1389
1390 case $host_vendor in
1391   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1392 esac
1393
1394 dnl **** Generate output files ****
1395
1396 AH_TOP([#define __WINE_CONFIG_H])
1397
1398 WINE_CONFIG_EXTRA_DIR(controls)
1399 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1400 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1401 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1402 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1403 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1404 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1405 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1406 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1407 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1408 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1409 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1410 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1411 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1412 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1413 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1414 WINE_CONFIG_EXTRA_DIR(files)
1415 WINE_CONFIG_EXTRA_DIR(graphics)
1416 WINE_CONFIG_EXTRA_DIR(graphics/x11drv)
1417 WINE_CONFIG_EXTRA_DIR(include/wine)
1418 WINE_CONFIG_EXTRA_DIR(memory)
1419 WINE_CONFIG_EXTRA_DIR(misc)
1420 WINE_CONFIG_EXTRA_DIR(msdos)
1421 WINE_CONFIG_EXTRA_DIR(objects)
1422 WINE_CONFIG_EXTRA_DIR(programs/regapi/tests)
1423 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1424 WINE_CONFIG_EXTRA_DIR(windows)
1425
1426 MAKE_RULES=Make.rules
1427 AC_SUBST_FILE(MAKE_RULES)
1428
1429 MAKE_DLL_RULES=dlls/Makedll.rules
1430 AC_SUBST_FILE(MAKE_DLL_RULES)
1431
1432 MAKE_TEST_RULES=dlls/Maketest.rules
1433 AC_SUBST_FILE(MAKE_TEST_RULES)
1434
1435 MAKE_LIB_RULES=libs/Makelib.rules
1436 AC_SUBST_FILE(MAKE_LIB_RULES)
1437
1438 MAKE_PROG_RULES=programs/Makeprog.rules
1439 AC_SUBST_FILE(MAKE_PROG_RULES)
1440
1441 AC_CONFIG_FILES([
1442 Make.rules
1443 dlls/Makedll.rules
1444 dlls/Maketest.rules
1445 libs/Makelib.rules
1446 programs/Makeprog.rules
1447 Makefile
1448 dlls/Makefile
1449 dlls/advapi32/Makefile
1450 dlls/advapi32/tests/Makefile
1451 dlls/avicap32/Makefile
1452 dlls/avifil32/Makefile
1453 dlls/cabinet/Makefile
1454 dlls/capi2032/Makefile
1455 dlls/cfgmgr32/Makefile
1456 dlls/comcat/Makefile
1457 dlls/comctl32/Makefile
1458 dlls/comctl32/tests/Makefile
1459 dlls/commdlg/Makefile
1460 dlls/crtdll/Makefile
1461 dlls/crypt32/Makefile
1462 dlls/ctl3d/Makefile
1463 dlls/d3d8/Makefile
1464 dlls/d3d9/Makefile
1465 dlls/d3dim/Makefile
1466 dlls/d3dx8/Makefile
1467 dlls/dciman32/Makefile
1468 dlls/ddraw/Makefile
1469 dlls/devenum/Makefile
1470 dlls/dinput/Makefile
1471 dlls/dinput8/Makefile
1472 dlls/dmband/Makefile
1473 dlls/dmcompos/Makefile
1474 dlls/dmime/Makefile
1475 dlls/dmloader/Makefile
1476 dlls/dmscript/Makefile
1477 dlls/dmstyle/Makefile
1478 dlls/dmsynth/Makefile
1479 dlls/dmusic/Makefile
1480 dlls/dmusic32/Makefile
1481 dlls/dplay/Makefile
1482 dlls/dplayx/Makefile
1483 dlls/dpnhpast/Makefile
1484 dlls/dsound/Makefile
1485 dlls/dsound/tests/Makefile
1486 dlls/gdi/Makefile
1487 dlls/gdi/tests/Makefile
1488 dlls/glu32/Makefile
1489 dlls/icmp/Makefile
1490 dlls/imagehlp/Makefile
1491 dlls/imm32/Makefile
1492 dlls/iphlpapi/Makefile
1493 dlls/kernel/Makefile
1494 dlls/kernel/tests/Makefile
1495 dlls/lzexpand/Makefile
1496 dlls/mapi32/Makefile
1497 dlls/mpr/Makefile
1498 dlls/msacm/Makefile
1499 dlls/msacm/imaadp32/Makefile
1500 dlls/msacm/msadp32/Makefile
1501 dlls/msacm/msg711/Makefile
1502 dlls/msacm/winemp3/Makefile
1503 dlls/msdmo/Makefile
1504 dlls/mshtml/Makefile
1505 dlls/msi/Makefile
1506 dlls/msimg32/Makefile
1507 dlls/msisys/Makefile
1508 dlls/msnet32/Makefile
1509 dlls/msvcrt/Makefile
1510 dlls/msvcrt/tests/Makefile
1511 dlls/msvcrt20/Makefile
1512 dlls/msvcrtd/Makefile
1513 dlls/msvideo/Makefile
1514 dlls/msvideo/msrle32/Makefile
1515 dlls/mswsock/Makefile
1516 dlls/netapi32/Makefile
1517 dlls/netapi32/tests/Makefile
1518 dlls/ntdll/Makefile
1519 dlls/ntdll/tests/Makefile
1520 dlls/odbc32/Makefile
1521 dlls/ole32/Makefile
1522 dlls/oleacc/Makefile
1523 dlls/oleaut32/Makefile
1524 dlls/oleaut32/tests/Makefile
1525 dlls/olecli/Makefile
1526 dlls/oledlg/Makefile
1527 dlls/olepro32/Makefile
1528 dlls/olesvr/Makefile
1529 dlls/opengl32/Makefile
1530 dlls/psapi/Makefile
1531 dlls/qcap/Makefile
1532 dlls/quartz/Makefile
1533 dlls/rasapi32/Makefile
1534 dlls/richedit/Makefile
1535 dlls/rpcrt4/Makefile
1536 dlls/rpcrt4/tests/Makefile
1537 dlls/serialui/Makefile
1538 dlls/setupapi/Makefile
1539 dlls/shdocvw/Makefile
1540 dlls/shell32/Makefile
1541 dlls/shell32/tests/Makefile
1542 dlls/shfolder/Makefile
1543 dlls/shlwapi/Makefile
1544 dlls/shlwapi/tests/Makefile
1545 dlls/snmpapi/Makefile
1546 dlls/sti/Makefile
1547 dlls/tapi32/Makefile
1548 dlls/ttydrv/Makefile
1549 dlls/twain/Makefile
1550 dlls/url/Makefile
1551 dlls/urlmon/Makefile
1552 dlls/urlmon/tests/Makefile
1553 dlls/user/Makefile
1554 dlls/user/tests/Makefile
1555 dlls/uxtheme/Makefile
1556 dlls/version/Makefile
1557 dlls/win32s/Makefile
1558 dlls/winaspi/Makefile
1559 dlls/winedos/Makefile
1560 dlls/wineps/Makefile
1561 dlls/wininet/Makefile
1562 dlls/wininet/tests/Makefile
1563 dlls/winmm/Makefile
1564 dlls/winmm/joystick/Makefile
1565 dlls/winmm/mcianim/Makefile
1566 dlls/winmm/mciavi/Makefile
1567 dlls/winmm/mcicda/Makefile
1568 dlls/winmm/mciseq/Makefile
1569 dlls/winmm/mciwave/Makefile
1570 dlls/winmm/midimap/Makefile
1571 dlls/winmm/tests/Makefile
1572 dlls/winmm/wavemap/Makefile
1573 dlls/winmm/winealsa/Makefile
1574 dlls/winmm/winearts/Makefile
1575 dlls/winmm/wineaudioio/Makefile
1576 dlls/winmm/winenas/Makefile
1577 dlls/winmm/winejack/Makefile
1578 dlls/winmm/wineoss/Makefile
1579 dlls/winnls/Makefile
1580 dlls/winsock/Makefile
1581 dlls/winsock/tests/Makefile
1582 dlls/winspool/Makefile
1583 dlls/winspool/tests/Makefile
1584 dlls/wintab32/Makefile
1585 dlls/wintrust/Makefile
1586 dlls/wow32/Makefile
1587 dlls/wsock32/Makefile
1588 dlls/x11drv/Makefile
1589 documentation/Makefile
1590 include/Makefile
1591 libs/Makefile
1592 libs/port/Makefile
1593 libs/unicode/Makefile
1594 libs/uuid/Makefile
1595 libs/wine/Makefile
1596 libs/wpp/Makefile
1597 loader/Makefile
1598 programs/Makefile
1599 programs/avitools/Makefile
1600 programs/clock/Makefile
1601 programs/cmdlgtst/Makefile
1602 programs/control/Makefile
1603 programs/expand/Makefile
1604 programs/notepad/Makefile
1605 programs/osversioncheck/Makefile
1606 programs/progman/Makefile
1607 programs/regapi/Makefile
1608 programs/regedit/Makefile
1609 programs/regsvr32/Makefile
1610 programs/regtest/Makefile
1611 programs/rpcss/Makefile
1612 programs/rundll32/Makefile
1613 programs/start/Makefile
1614 programs/uninstaller/Makefile
1615 programs/view/Makefile
1616 programs/wcmd/Makefile
1617 programs/wineboot/Makefile
1618 programs/winecfg/Makefile
1619 programs/wineconsole/Makefile
1620 programs/winedbg/Makefile
1621 programs/winefile/Makefile
1622 programs/winemenubuilder/Makefile
1623 programs/winemine/Makefile
1624 programs/winepath/Makefile
1625 programs/winevdm/Makefile
1626 programs/winhelp/Makefile
1627 programs/winver/Makefile
1628 server/Makefile
1629 tools/Makefile
1630 tools/widl/Makefile
1631 tools/winapi/Makefile
1632 tools/winebuild/Makefile
1633 tools/winedump/Makefile
1634 tools/winegcc/Makefile
1635 tools/wmc/Makefile
1636 tools/wrc/Makefile])
1637
1638 AC_OUTPUT
1639
1640 if test "$have_x" = "no"
1641 then
1642   echo
1643   echo "*** Warning: X development files not found. Wine will be built without"
1644   echo "*** X support, which currently does not work, and would probably not be"
1645   echo "*** what you want anyway. You will need to install devel packages of"
1646   echo "*** Xlib/Xfree86 at the very least."
1647 fi
1648
1649 if test "$wine_cv_opengl_version_OK" = "no"
1650 then
1651   echo
1652   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1653   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1654 fi
1655
1656 if test "$wine_cv_msg_freetype" = "yes"
1657 then
1658   echo
1659   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1660   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1661   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1662   echo "*** enable Wine to use TrueType fonts."
1663 fi
1664
1665 echo
1666 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1667 echo
1668
1669 dnl Local Variables:
1670 dnl comment-start: "dnl "
1671 dnl comment-end: ""
1672 dnl comment-start-skip: "\\bdnl\\b\\s *"
1673 dnl compile-command: "autoconf"
1674 dnl End: