git.oblomov.eu Git - wine/blob - debugger/dbg.y

   1 %{
   2 /*
   3  * Parser for command lines in the Wine debugger
   4  *
   5  * Copyright 1993 Eric Youngdale
   6  * Copyright 1995 Morten Welinder
   7  * Copyright 2000 Eric Pouech
   8  */
   9
  10 #include "config.h"
  11
  12 #include <stdio.h>
  13 #include <stdlib.h>
  14 #include <string.h>
  15 #include <signal.h>
  16 #include <unistd.h>
  17
  18 #include "wine/exception.h"
  19 #include "debugger.h"
  20 #include "expr.h"
  21
  22 extern FILE * yyin;
  23
  24 static void issue_prompt(void);
  25 static void mode_command(int);
  26 int yylex(void);
  27 int yyerror(char *);
  28
  29 %}
  30
  31 %union
  32 {
  33     DBG_VALUE        value;
  34     char *           string;
  35     int              integer;
  36     struct list_id   listing;
  37     struct expr *    expression;
  38     struct datatype* type;
  39 }
  40
  41 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tINFO tWALK tUP tDOWN
  42 %token tENABLE tDISABLE tBREAK tWATCH tDELETE tSET tMODE tPRINT tEXAM tABORT tVM86
  43 %token tCLASS tMAPS tMODULE tSTACK tSEGMENTS tREGS tWND tQUEUE tLOCAL
  44 %token tPROCESS tTHREAD tMODREF tEOL
  45 %token tFRAME tSHARE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
  46 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS
  47 %token <string> tPATH
  48 %token <string> tIDENTIFIER tSTRING tDEBUGSTR tINTVAR
  49 %token <integer> tNUM tFORMAT
  50 %token tSYMBOLFILE tRUN tATTACH tNOPROCESS
  51
  52 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
  53 %token tSTRUCT tUNION tENUM
  54
  55 /* %left ',' */
  56 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
  57          OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
  58          OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
  59 /* %left OP_COND */ /* ... ? ... : ... */
  60 %left OP_LOR
  61 %left OP_LAND
  62 %left '|'
  63 %left '^'
  64 %left '&'
  65 %left OP_EQ OP_NE
  66 %left '<' '>' OP_LE OP_GE
  67 %left OP_SHL OP_SHR
  68 %left '+' '-'
  69 %left '*' '/' '%'
  70 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
  71 %left '.' '[' OP_DRF
  72 %nonassoc ':'
  73
  74 %type <expression> expr lval lvalue
  75 %type <type> type_cast type_expr
  76 %type <value> expr_addr lval_addr
  77 %type <integer> expr_value
  78 %type <string> pathname
  79
  80 %type <listing> list_arg
  81
  82 %%
  83
  84 input: line                     { issue_prompt(); }
  85     | input line                { issue_prompt(); }
  86
  87 line: command
  88     | tEOL
  89     | error tEOL                { yyerrok; }
  90
  91 command:
  92       tQUIT tEOL                { return FALSE; }
  93     | tHELP tEOL                { DEBUG_Help(); }
  94     | tHELP tINFO tEOL          { DEBUG_HelpInfo(); }
  95     | tCONT tEOL                { DEBUG_CurrThread->dbg_exec_count = 1;
  96                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_CONT; return TRUE; }
  97     | tPASS tEOL                { DEBUG_CurrThread->dbg_exec_count = 1;
  98                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_PASS; return TRUE; }
  99     | tCONT tNUM tEOL           { DEBUG_CurrThread->dbg_exec_count = $2;
 100                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_CONT; return TRUE; }
 101     | tSTEP tEOL                { DEBUG_CurrThread->dbg_exec_count = 1;
 102                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEP_INSTR; return TRUE; }
 103     | tNEXT tEOL                { DEBUG_CurrThread->dbg_exec_count = 1;
 104                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEP_OVER; return TRUE; }
 105     | tSTEP tNUM tEOL           { DEBUG_CurrThread->dbg_exec_count = $2;
 106                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEP_INSTR; return TRUE; }
 107     | tNEXT tNUM tEOL           { DEBUG_CurrThread->dbg_exec_count = $2;
 108                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEP_OVER; return TRUE; }
 109     | tSTEPI tEOL               { DEBUG_CurrThread->dbg_exec_count = 1;
 110                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEPI_INSTR; return TRUE; }
 111     | tNEXTI tEOL               { DEBUG_CurrThread->dbg_exec_count = 1;
 112                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEPI_OVER; return TRUE; }
 113     | tSTEPI tNUM tEOL          { DEBUG_CurrThread->dbg_exec_count = $2;
 114                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEPI_INSTR; return TRUE; }
 115     | tNEXTI tNUM tEOL          { DEBUG_CurrThread->dbg_exec_count = $2;
 116                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEPI_OVER; return TRUE; }
 117     | tABORT tEOL               { kill(getpid(), SIGABRT); }
 118     | tMODE tNUM tEOL           { mode_command($2); }
 119     | tMODE tVM86 tEOL          { DEBUG_CurrThread->dbg_mode = MODE_VM86; }
 120     | tENABLE tNUM tEOL         { DEBUG_EnableBreakpoint( $2, TRUE ); }
 121     | tDISABLE tNUM tEOL        { DEBUG_EnableBreakpoint( $2, FALSE ); }
 122     | tDELETE tBREAK tNUM tEOL  { DEBUG_DelBreakpoint( $3 ); }
 123     | tBACKTRACE tEOL           { DEBUG_BackTrace(TRUE); }
 124     | tUP tEOL                  { DEBUG_SetFrame( curr_frame + 1 );  }
 125     | tUP tNUM tEOL             { DEBUG_SetFrame( curr_frame + $2 ); }
 126     | tDOWN tEOL                { DEBUG_SetFrame( curr_frame - 1 );  }
 127     | tDOWN tNUM tEOL           { DEBUG_SetFrame( curr_frame - $2 ); }
 128     | tFRAME tNUM tEOL          { DEBUG_SetFrame( $2 ); }
 129     | tFINISH tEOL              { DEBUG_CurrThread->dbg_exec_count = 0;
 130                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_FINISH; return TRUE; }
 131     | tSHOW tDIR tEOL           { DEBUG_ShowDir(); }
 132     | tDIR pathname tEOL        { DEBUG_AddPath( $2 ); }
 133     | tDIR tEOL                 { DEBUG_NukePath(); }
 134     | tDISPLAY tEOL             { DEBUG_InfoDisplay(); }
 135     | tDISPLAY expr tEOL        { DEBUG_AddDisplay($2, 1, 0); }
 136     | tDISPLAY tFORMAT expr tEOL{ DEBUG_AddDisplay($3, $2 >> 8, $2 & 0xff); }
 137     | tDELETE tDISPLAY tNUM tEOL{ DEBUG_DelDisplay( $3 ); }
 138     | tDELETE tDISPLAY tEOL     { DEBUG_DelDisplay( -1 ); }
 139     | tUNDISPLAY tNUM tEOL      { DEBUG_DelDisplay( $2 ); }
 140     | tUNDISPLAY tEOL           { DEBUG_DelDisplay( -1 ); }
 141     | tCOND tNUM tEOL           { DEBUG_AddBPCondition($2, NULL); }
 142     | tCOND tNUM expr tEOL      { DEBUG_AddBPCondition($2, $3); }
 143     | tSYMBOLFILE pathname tEOL { DEBUG_ReadSymbolTable($2); }
 144     | tWHATIS expr_addr tEOL    { DEBUG_PrintType(&$2); DEBUG_FreeExprMem(); }
 145     | tATTACH tNUM tEOL         { if (DEBUG_Attach($2, FALSE)) return TRUE; }
 146     | list_command
 147     | disassemble_command
 148     | set_command
 149     | x_command
 150     | print_command
 151     | break_command
 152     | watch_command
 153     | info_command
 154     | walk_command
 155     | run_command
 156     | noprocess_state
 157
 158 set_command:
 159       tSET lval_addr '=' expr_value tEOL   { DEBUG_WriteMemory( &$2, $4 );
 160                                              DEBUG_FreeExprMem(); }
 161
 162 pathname:
 163       tIDENTIFIER              { $$ = $1; }
 164     | tPATH                    { $$ = $1; }
 165
 166 disassemble_command:
 167       tDISASSEMBLE tEOL              { DEBUG_Disassemble( NULL, NULL, 10 ); }
 168     | tDISASSEMBLE expr_addr tEOL    { DEBUG_Disassemble( & $2, NULL, 10 ); }
 169     | tDISASSEMBLE expr_addr ',' expr_addr tEOL { DEBUG_Disassemble( & $2, & $4, 0 ); }
 170
 171 list_command:
 172       tLIST tEOL               { DEBUG_List( NULL, NULL, 10 ); }
 173     | tLIST '-' tEOL           { DEBUG_List( NULL, NULL, -10 ); }
 174     | tLIST list_arg tEOL      { DEBUG_List( & $2, NULL, 10 ); }
 175     | tLIST ',' list_arg tEOL  { DEBUG_List( NULL, & $3, -10 ); }
 176     | tLIST list_arg ',' list_arg tEOL { DEBUG_List( & $2, & $4, 0 ); }
 177
 178 list_arg:
 179       tNUM                     { $$.sourcefile = NULL; $$.line = $1; }
 180     | pathname ':' tNUM        { $$.sourcefile = $1; $$.line = $3; }
 181     | tIDENTIFIER              { DEBUG_GetFuncInfo( & $$, NULL, $1); }
 182     | pathname ':' tIDENTIFIER { DEBUG_GetFuncInfo( & $$, $1, $3); }
 183     | '*' expr_addr            { DEBUG_FindNearestSymbol( & $2.addr, FALSE, NULL, 0, & $$ );
 184                                  DEBUG_FreeExprMem(); }
 185
 186 x_command:
 187       tEXAM expr_addr tEOL     { DEBUG_ExamineMemory( &$2, 1, 'x'); DEBUG_FreeExprMem(); }
 188     | tEXAM tFORMAT expr_addr tEOL  { DEBUG_ExamineMemory( &$3, $2>>8, $2&0xff );
 189                                       DEBUG_FreeExprMem(); }
 190
 191 print_command:
 192       tPRINT expr_addr tEOL    { DEBUG_Print( &$2, 1, 0, 0 ); DEBUG_FreeExprMem(); }
 193     | tPRINT tFORMAT expr_addr tEOL { DEBUG_Print( &$3, $2 >> 8, $2 & 0xff, 0 );
 194                                       DEBUG_FreeExprMem(); }
 195
 196 break_command:
 197       tBREAK '*' expr_addr tEOL{ DEBUG_AddBreakpoint( &$3, NULL ); DEBUG_FreeExprMem(); }
 198     | tBREAK tIDENTIFIER tEOL  { DEBUG_AddBreakpointFromId($2, -1); }
 199     | tBREAK tIDENTIFIER ':' tNUM tEOL  { DEBUG_AddBreakpointFromId($2, $4); }
 200     | tBREAK tNUM tEOL         { DEBUG_AddBreakpointFromLineno($2); }
 201     | tBREAK tEOL              { DEBUG_AddBreakpointFromLineno(-1); }
 202
 203 watch_command:
 204       tWATCH '*' expr_addr tEOL { DEBUG_AddWatchpoint( &$3, 1 ); DEBUG_FreeExprMem(); }
 205     | tWATCH tIDENTIFIER tEOL   { DEBUG_AddWatchpointFromId($2); }
 206
 207 info_command:
 208       tINFO tBREAK tEOL         { DEBUG_InfoBreakpoints(); }
 209     | tINFO tCLASS tSTRING tEOL { DEBUG_InfoClass( $3 ); }
 210     | tINFO tSHARE tEOL         { DEBUG_InfoShare(); }
 211     | tINFO tMODULE expr_value tEOL   { DEBUG_DumpModule( $3 ); DEBUG_FreeExprMem(); }
 212     | tINFO tQUEUE expr_value tEOL    { DEBUG_DumpQueue( $3 ); DEBUG_FreeExprMem(); }
 213     | tINFO tREGS tEOL          { DEBUG_InfoRegisters(); }
 214     | tINFO tSEGMENTS expr_value tEOL { DEBUG_InfoSegments( $3, 1 ); DEBUG_FreeExprMem(); }
 215     | tINFO tSEGMENTS tEOL      { DEBUG_InfoSegments( 0, -1 ); }
 216     | tINFO tSTACK tEOL         { DEBUG_InfoStack(); }
 217     | tINFO tMAPS tEOL          { DEBUG_InfoVirtual(); }
 218     | tINFO tWND expr_value tEOL{ DEBUG_InfoWindow( (HWND)$3 ); DEBUG_FreeExprMem(); }
 219     | tINFO tLOCAL tEOL         { DEBUG_InfoLocals(); }
 220     | tINFO tDISPLAY tEOL       { DEBUG_InfoDisplay(); }
 221
 222 walk_command:
 223       tWALK tCLASS tEOL         { DEBUG_WalkClasses(); }
 224     | tWALK tMODULE tEOL        { DEBUG_WalkModules(); }
 225     | tWALK tQUEUE tEOL         { DEBUG_WalkQueues(); }
 226     | tWALK tWND tEOL           { DEBUG_WalkWindows( 0, 0 ); }
 227     | tWALK tWND tNUM tEOL      { DEBUG_WalkWindows( (HWND)$3, 0 ); }
 228     | tWALK tPROCESS tEOL       { DEBUG_WalkProcess(); }
 229     | tWALK tTHREAD tEOL        { DEBUG_WalkThreads(); }
 230     | tWALK tMODREF expr_value tEOL   { DEBUG_WalkModref( $3 ); DEBUG_FreeExprMem(); }
 231
 232 run_command:
 233       tRUN tEOL                 { DEBUG_Run(NULL); }
 234     | tRUN tSTRING tEOL         { DEBUG_Run($2); }
 235
 236 noprocess_state:
 237       tNOPROCESS tEOL           {} /* <CR> shall not barf anything */
 238     | tNOPROCESS tSTRING tEOL   { DEBUG_Printf(DBG_CHN_MESG, "No process loaded, cannot execute '%s'\n", $2); }
 239
 240 type_cast:
 241       '(' type_expr ')'         { $$ = $2; }
 242
 243 type_expr:
 244       type_expr '*'             { $$ = DEBUG_FindOrMakePointerType($1); }
 245     |  tINT                     { $$ = DEBUG_TypeCast(DT_BASIC, "int"); }
 246     | tCHAR                     { $$ = DEBUG_TypeCast(DT_BASIC, "char"); }
 247     | tLONG tINT                { $$ = DEBUG_TypeCast(DT_BASIC, "long int"); }
 248     | tUNSIGNED tINT            { $$ = DEBUG_TypeCast(DT_BASIC, "unsigned int"); }
 249     | tLONG tUNSIGNED tINT      { $$ = DEBUG_TypeCast(DT_BASIC, "long unsigned int"); }
 250     | tLONG tLONG tINT          { $$ = DEBUG_TypeCast(DT_BASIC, "long long int"); }
 251     | tLONG tLONG tUNSIGNED tINT{ $$ = DEBUG_TypeCast(DT_BASIC, "long long unsigned int"); }
 252     | tSHORT tINT               { $$ = DEBUG_TypeCast(DT_BASIC, "short int"); }
 253     | tSHORT tUNSIGNED tINT     { $$ = DEBUG_TypeCast(DT_BASIC, "short unsigned int"); }
 254     | tSIGNED tCHAR             { $$ = DEBUG_TypeCast(DT_BASIC, "signed char"); }
 255     | tUNSIGNED tCHAR           { $$ = DEBUG_TypeCast(DT_BASIC, "unsigned char"); }
 256     | tFLOAT                    { $$ = DEBUG_TypeCast(DT_BASIC, "float"); }
 257     | tDOUBLE                   { $$ = DEBUG_TypeCast(DT_BASIC, "double"); }
 258     | tLONG tDOUBLE             { $$ = DEBUG_TypeCast(DT_BASIC, "long double"); }
 259     | tSTRUCT tIDENTIFIER       { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 260     | tUNION tIDENTIFIER        { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 261     | tENUM tIDENTIFIER         { $$ = DEBUG_TypeCast(DT_ENUM, $2); }
 262
 263 expr_addr:
 264       expr                      { $$ = DEBUG_EvalExpr($1); }
 265
 266 expr_value:
 267       expr                      { DBG_VALUE     value = DEBUG_EvalExpr($1);
 268                                   /* expr_value is typed as an integer */
 269                                   $$ = DEBUG_ReadMemory(&value); }
 270
 271 /*
 272  * The expr rule builds an expression tree.  When we are done, we call
 273  * EvalExpr to evaluate the value of the expression.  The advantage of
 274  * the two-step approach is that it is possible to save expressions for
 275  * use in 'display' commands, and in conditional watchpoints.
 276  */
 277 expr:
 278       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 279     | tSTRING                    { $$ = DEBUG_StringExpr($1); }
 280     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 281     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 282     | expr OP_DRF tIDENTIFIER    { $$ = DEBUG_StructPExpr($1, $3); }
 283     | expr '.' tIDENTIFIER       { $$ = DEBUG_StructExpr($1, $3); }
 284     | tIDENTIFIER '(' ')'        { $$ = DEBUG_CallExpr($1, 0); }
 285     | tIDENTIFIER '(' expr ')'   { $$ = DEBUG_CallExpr($1, 1, $3); }
 286     | tIDENTIFIER '(' expr ',' expr ')'  { $$ = DEBUG_CallExpr($1, 2, $3, $5); }
 287     | tIDENTIFIER '(' expr ',' expr ',' expr ')'         { $$ = DEBUG_CallExpr($1, 3, $3, $5, $7); }
 288     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ')'        { $$ = DEBUG_CallExpr($1, 4, $3, $5, $7, $9); }
 289     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ',' expr ')'       { $$ = DEBUG_CallExpr($1, 5, $3, $5, $7, $9, $11); }
 290     | expr '[' expr ']'          { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 291     | expr ':' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SEG, $1, $3); }
 292     | expr OP_LOR expr           { $$ = DEBUG_BinopExpr(EXP_OP_LOR, $1, $3); }
 293     | expr OP_LAND expr          { $$ = DEBUG_BinopExpr(EXP_OP_LAND, $1, $3); }
 294     | expr '|' expr              { $$ = DEBUG_BinopExpr(EXP_OP_OR, $1, $3); }
 295     | expr '&' expr              { $$ = DEBUG_BinopExpr(EXP_OP_AND, $1, $3); }
 296     | expr '^' expr              { $$ = DEBUG_BinopExpr(EXP_OP_XOR, $1, $3); }
 297     | expr OP_EQ expr            { $$ = DEBUG_BinopExpr(EXP_OP_EQ, $1, $3); }
 298     | expr '>' expr              { $$ = DEBUG_BinopExpr(EXP_OP_GT, $1, $3); }
 299     | expr '<' expr              { $$ = DEBUG_BinopExpr(EXP_OP_LT, $1, $3); }
 300     | expr OP_GE expr            { $$ = DEBUG_BinopExpr(EXP_OP_GE, $1, $3); }
 301     | expr OP_LE expr            { $$ = DEBUG_BinopExpr(EXP_OP_LE, $1, $3); }
 302     | expr OP_NE expr            { $$ = DEBUG_BinopExpr(EXP_OP_NE, $1, $3); }
 303     | expr OP_SHL expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHL, $1, $3); }
 304     | expr OP_SHR expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHR, $1, $3); }
 305     | expr '+' expr              { $$ = DEBUG_BinopExpr(EXP_OP_ADD, $1, $3); }
 306     | expr '-' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SUB, $1, $3); }
 307     | expr '*' expr              { $$ = DEBUG_BinopExpr(EXP_OP_MUL, $1, $3); }
 308     | expr '/' expr              { $$ = DEBUG_BinopExpr(EXP_OP_DIV, $1, $3); }
 309     | expr '%' expr              { $$ = DEBUG_BinopExpr(EXP_OP_REM, $1, $3); }
 310     | '-' expr %prec OP_SIGN     { $$ = DEBUG_UnopExpr(EXP_OP_NEG, $2); }
 311     | '+' expr %prec OP_SIGN     { $$ = $2; }
 312     | '!' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_NOT, $2); }
 313     | '~' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_LNOT, $2); }
 314     | '(' expr ')'               { $$ = $2; }
 315     | '*' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_DEREF, $2); }
 316     | '&' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_ADDR, $2); }
 317     | type_cast expr %prec OP_DEREF { $$ = DEBUG_TypeCastExpr($1, $2); }
 318
 319 /*
 320  * The lvalue rule builds an expression tree.  This is a limited form
 321  * of expression that is suitable to be used as an lvalue.
 322  */
 323 lval_addr:
 324     lval                         { $$ = DEBUG_EvalExpr($1); }
 325
 326 lval:
 327       lvalue                     { $$ = $1; }
 328     | '*' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_FORCE_DEREF, $2); }
 329
 330 lvalue:
 331       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 332     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 333     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 334     | lvalue OP_DRF tIDENTIFIER  { $$ = DEBUG_StructPExpr($1, $3); }
 335     | lvalue '.' tIDENTIFIER     { $$ = DEBUG_StructExpr($1, $3); }
 336     | lvalue '[' expr ']'        { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 337
 338 %%
 339
 340 static void issue_prompt(void)
 341 {
 342 #ifdef DONT_USE_READLINE
 343    DEBUG_Printf(DBG_CHN_MESG, "Wine-dbg>");
 344 #endif
 345 }
 346
 347 static void mode_command(int newmode)
 348 {
 349     switch(newmode)
 350     {
 351     case 16: DEBUG_CurrThread->dbg_mode = MODE_16; break;
 352     case 32: DEBUG_CurrThread->dbg_mode = MODE_32; break;
 353     default: DEBUG_Printf(DBG_CHN_MESG,"Invalid mode (use 16, 32 or vm86)\n");
 354     }
 355 }
 356
 357 void DEBUG_Exit(DWORD ec)
 358 {
 359    ExitProcess(ec);
 360 }
 361
 362 static WINE_EXCEPTION_FILTER(wine_dbg_cmd)
 363 {
 364    DEBUG_Printf(DBG_CHN_MESG, "\nwine_dbg_cmd: ");
 365    switch (GetExceptionCode()) {
 366    case DEBUG_STATUS_INTERNAL_ERROR:
 367       DEBUG_Printf(DBG_CHN_MESG, "WineDbg internal error\n");
 368       break;
 369    case DEBUG_STATUS_NO_SYMBOL:
 370       DEBUG_Printf(DBG_CHN_MESG, "Undefined symbol\n");
 371       break;
 372    case DEBUG_STATUS_DIV_BY_ZERO:
 373       DEBUG_Printf(DBG_CHN_MESG, "Division by zero\n");
 374       break;
 375    case DEBUG_STATUS_BAD_TYPE:
 376       DEBUG_Printf(DBG_CHN_MESG, "No type or type mismatch\n");
 377       break;
 378    default:
 379       DEBUG_Printf(DBG_CHN_MESG, "Exception %lx\n", GetExceptionCode());
 380       break;
 381    }
 382
 383    return EXCEPTION_EXECUTE_HANDLER;
 384 }
 385
 386 /***********************************************************************
 387  *           DEBUG_Parser
 388  *
 389  * Debugger editline parser
 390  */
 391 BOOL    DEBUG_Parser(void)
 392 {
 393     BOOL        ret_ok;
 394     BOOL        ret = TRUE;
 395 #ifdef YYDEBUG
 396     yydebug = 0;
 397 #endif
 398     yyin = stdin;
 399
 400     ret_ok = FALSE;
 401     do {
 402        __TRY {
 403           issue_prompt();
 404           ret_ok = TRUE;
 405           if ((ret = yyparse())) {
 406              DEBUG_FlushSymbols();
 407           }
 408        } __EXCEPT(wine_dbg_cmd) {
 409           ret_ok = FALSE;
 410        }
 411        __ENDTRY;
 412
 413     } while (!ret_ok);
 414     return ret;
 415 }
 416
 417 int yyerror(char* s)
 418 {
 419    DEBUG_Printf(DBG_CHN_MESG, "%s\n", s);
 420    return 0;
 421 }