git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41
  42 #if defined(YYBYACC)
  43         /* Berkeley yacc (byacc) doesn't seem to know about these */
  44         /* Some *BSD supplied versions do define these though */
  45 # ifndef YYEMPTY
  46 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  47 # endif
  48 # ifndef YYLEX
  49 #  define YYLEX         yylex()
  50 # endif
  51
  52 #elif defined(YYBISON)
  53         /* Bison was used for original development */
  54         /* #define YYEMPTY -2 */
  55         /* #define YYLEX   yylex() */
  56
  57 #else
  58         /* No yacc we know yet */
  59 # if !defined(YYEMPTY) || !defined(YYLEX)
  60 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  61 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  62 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  63   /* #else we just take a chance that it works... */
  64 # endif
  65 #endif
  66
  67 static attr_t *make_attr(enum attr_type type);
  68 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  69 static attr_t *make_attrp(enum attr_type type, void *val);
  70 static expr_t *make_expr(enum expr_type type);
  71 static expr_t *make_exprl(enum expr_type type, long val);
  72 static expr_t *make_exprs(enum expr_type type, char *val);
  73 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  74 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  75 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  76 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  77 static type_t *make_type(unsigned char type, type_t *ref);
  78 static typeref_t *make_tref(char *name, type_t *ref);
  79 static typeref_t *uniq_tref(typeref_t *ref);
  80 static type_t *type_ref(typeref_t *ref);
  81 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  82 static ifref_t *make_ifref(type_t *iface);
  83 static var_t *make_var(char *name);
  84 static func_t *make_func(var_t *def, var_t *args);
  85 static class_t *make_class(char *name);
  86
  87 static type_t *reg_type(type_t *type, char *name, int t);
  88 static type_t *reg_types(type_t *type, var_t *names, int t);
  89 static type_t *find_type(const char *name, int t);
  90 static type_t *find_type2(char *name, int t);
  91 static type_t *get_type(unsigned char type, char *name, int t);
  92 static type_t *get_typev(unsigned char type, var_t *name, int t);
  93 static int get_struct_type(var_t *fields);
  94
  95 static var_t *reg_const(var_t *var);
  96 static var_t *find_const(char *name, int f);
  97
  98 #define tsENUM   1
  99 #define tsSTRUCT 2
 100 #define tsUNION  3
 101
 102 static type_t std_bool = { "boolean" };
 103 static type_t std_int = { "int" };
 104 static type_t std_int64 = { "__int64" };
 105 static type_t std_uhyper = { "MIDL_uhyper" };
 106
 107 %}
 108 %union {
 109         attr_t *attr;
 110         expr_t *expr;
 111         type_t *type;
 112         typeref_t *tref;
 113         var_t *var;
 114         func_t *func;
 115         ifref_t *ifref;
 116         class_t *clas;
 117         char *str;
 118         UUID *uuid;
 119         unsigned int num;
 120 }
 121
 122 %token <str> aIDENTIFIER
 123 %token <str> aKNOWNTYPE
 124 %token <num> aNUM aHEXNUM
 125 %token <str> aSTRING
 126 %token <uuid> aUUID
 127 %token aEOF
 128 %token SHL SHR
 129 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
 130 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 131 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 132 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 133 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 134 %token tDEFAULT
 135 %token tDEFAULTVALUE
 136 %token tDISPINTERFACE
 137 %token tDLLNAME tDOUBLE tDUAL
 138 %token tENDPOINT
 139 %token tENTRY tENUM tERRORSTATUST
 140 %token tEXPLICITHANDLE tEXTERN
 141 %token tFLOAT
 142 %token tHANDLE
 143 %token tHANDLET
 144 %token tHELPCONTEXT tHELPFILE
 145 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 146 %token tHIDDEN
 147 %token tHYPER tID tIDEMPOTENT
 148 %token tIIDIS
 149 %token tIMPLICITHANDLE
 150 %token tIMPORT tIMPORTLIB
 151 %token tIN tINCLUDE tINLINE
 152 %token tINPUTSYNC
 153 %token tINT tINT64
 154 %token tINTERFACE
 155 %token tLENGTHIS tLIBRARY
 156 %token tLOCAL
 157 %token tLONG
 158 %token tMETHODS
 159 %token tMODULE
 160 %token tNONCREATABLE
 161 %token tOBJECT tODL tOLEAUTOMATION
 162 %token tOPTIONAL
 163 %token tOUT
 164 %token tPOINTERDEFAULT
 165 %token tPROPERTIES
 166 %token tPROPGET tPROPPUT tPROPPUTREF
 167 %token tPTR
 168 %token tPUBLIC
 169 %token tRANGE
 170 %token tREADONLY tREF
 171 %token tRESTRICTED
 172 %token tRETVAL
 173 %token tSHORT
 174 %token tSIGNED
 175 %token tSINGLE
 176 %token tSIZEIS tSIZEOF
 177 %token tSMALL
 178 %token tSOURCE
 179 %token tSTDCALL
 180 %token tSTRING tSTRUCT
 181 %token tSWITCH tSWITCHIS tSWITCHTYPE
 182 %token tTRANSMITAS
 183 %token tTYPEDEF
 184 %token tUNION
 185 %token tUNIQUE
 186 %token tUNSIGNED
 187 %token tUUID
 188 %token tV1ENUM
 189 %token tVARARG
 190 %token tVERSION
 191 %token tVOID
 192 %token tWCHAR tWIREMARSHAL
 193
 194 /* used in attr_t */
 195 %token tPOINTERTYPE
 196
 197 %type <attr> m_attributes attributes attrib_list attribute
 198 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 199 %type <expr> array array_list
 200 %type <type> inherit interface interfacehdr interfacedef interfacedec
 201 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 202 %type <type> module modulehdr moduledef
 203 %type <type> base_type int_std
 204 %type <type> enumdef structdef typedef uniondef
 205 %type <ifref> gbl_statements coclass_ints coclass_int
 206 %type <tref> type
 207 %type <var> m_args no_args args arg
 208 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 209 %type <var> m_ident t_ident ident p_ident pident pident_list
 210 %type <var> dispint_props
 211 %type <func> funcdef int_statements
 212 %type <func> dispint_meths
 213 %type <clas> coclass coclasshdr coclassdef
 214 %type <num> pointer_type version
 215 %type <str> libraryhdr
 216
 217 %left ','
 218 %right COND
 219 %left '|'
 220 %left '&'
 221 %left '-' '+'
 222 %left '*' '/'
 223 %left SHL SHR
 224 %right '~'
 225 %right CAST
 226 %right PPTR
 227 %right NEG
 228
 229 %%
 230
 231 input:   gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 232         ;
 233
 234 gbl_statements:                                 { $$ = NULL; }
 235         | gbl_statements interfacedec           { $$ = $1; }
 236         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 237         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 238         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 239         | gbl_statements librarydef             { $$ = $1; }
 240         | gbl_statements statement              { $$ = $1; }
 241         ;
 242
 243 imp_statements:                                 {}
 244         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 245         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 246         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 247         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 248         | imp_statements statement              {}
 249         ;
 250
 251 int_statements:                                 { $$ = NULL; }
 252         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 253         | int_statements statement              { $$ = $1; }
 254         ;
 255
 256 statement: ';'                                  {}
 257         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 258         | cppquote                              {}
 259         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 260         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 261         | import                                {}
 262         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 263         | typedef ';'                           {}
 264         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 265         ;
 266
 267 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 268         ;
 269 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 270                                                   if (!do_import($2)) yychar = aEOF; }
 271         ;
 272 import:   import_start imp_statements aEOF      {}
 273         ;
 274
 275 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 276         ;
 277 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 278                                                   if (!parse_only && do_header) write_library($2, $1); }
 279         ;
 280 librarydef: library_start imp_statements '}'    { end_typelib(); }
 281         ;
 282
 283 m_args:                                         { $$ = NULL; }
 284         | args
 285         ;
 286
 287 no_args:  tVOID                                 { $$ = NULL; }
 288         ;
 289
 290 args:     arg
 291         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 292         | no_args
 293         ;
 294
 295 /* split into two rules to get bison to resolve a tVOID conflict */
 296 arg:      attributes type pident array          { $$ = $3;
 297                                                   set_type($$, $2, $4);
 298                                                   $$->attrs = $1;
 299                                                 }
 300         | type pident array                     { $$ = $2;
 301                                                   set_type($$, $1, $3);
 302                                                 }
 303         | attributes type pident '(' m_args ')' { $$ = $3;
 304                                                   $$->ptr_level--;
 305                                                   set_type($$, $2, NULL);
 306                                                   $$->attrs = $1;
 307                                                   $$->args = $5;
 308                                                 }
 309         | type pident '(' m_args ')'            { $$ = $2;
 310                                                   $$->ptr_level--;
 311                                                   set_type($$, $1, NULL);
 312                                                   $$->args = $4;
 313                                                 }
 314         ;
 315
 316 array:                                          { $$ = NULL; }
 317         | '[' array_list ']'                    { $$ = $2; }
 318         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 319         ;
 320
 321 array_list: m_expr /* size of first dimension is optional */
 322         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 323         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 324         ;
 325
 326 m_attributes:                                   { $$ = NULL; }
 327         | attributes
 328         ;
 329
 330 attributes:
 331           '[' attrib_list ']'                   { $$ = $2; }
 332         ;
 333
 334 attrib_list: attribute
 335         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 336         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 337         ;
 338
 339 attribute:
 340           tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 341         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 342         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 343         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 344         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 345         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 346         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 347         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 348         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 349         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 350         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 351         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 352         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 353         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 354         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 355         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 356         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 357         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 358         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 359         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 360         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 361         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 362         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 363         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 364         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 365         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 366         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 367         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 368         | tIN                                   { $$ = make_attr(ATTR_IN); }
 369         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 370         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 371         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 372         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 373         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 374         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 375         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 376         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 377         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 378         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 379         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 380         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 381         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 382         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 383         | tRANGE '(' expr_const ',' expr_const ')' { LINK($5, $3); $$ = make_attrp(ATTR_RANGE, $5); }
 384         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 385         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 386         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 387         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 388         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 389         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 390         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 391         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 392         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 393         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 394         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 395         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 396         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 397         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 398         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 399         ;
 400
 401 callconv:
 402         | tSTDCALL
 403         ;
 404
 405 cases:                                          { $$ = NULL; }
 406         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 407                                                   else { $$ = $1; }
 408                                                 }
 409         ;
 410
 411 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 412                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 413                                                   LINK(a, $$->attrs); $$->attrs = a;
 414                                                 }
 415         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 416                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 417                                                   LINK(a, $$->attrs); $$->attrs = a;
 418                                                 }
 419         ;
 420
 421 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 422                                                   set_type($$, $2, NULL);
 423                                                   $$->eval = $5;
 424                                                   $$->lval = $5->cval;
 425                                                 }
 426         ;
 427
 428 enums:                                          { $$ = NULL; }
 429         | enum_list ','                         { $$ = $1; }
 430         | enum_list
 431         ;
 432
 433 enum_list: enum
 434         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 435                                                   if ($1 && !$3->eval)
 436                                                     $3->lval = $1->lval + 1;
 437                                                 }
 438         ;
 439
 440 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 441                                                   $$->eval = $3;
 442                                                   $$->lval = $3->cval;
 443                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 444                                                 }
 445         | ident                                 { $$ = reg_const($1);
 446                                                   $$->lval = 0; /* default for first enum entry */
 447                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 448                                                 }
 449         ;
 450
 451 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 452                                                   $$->fields = $4;
 453                                                   $$->defined = TRUE;
 454                                                   if(in_typelib)
 455                                                       add_enum($$);
 456                                                 }
 457         ;
 458
 459 m_exprs:  m_expr
 460         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 461         ;
 462
 463 /*
 464 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 465         | expr_list
 466         ;
 467
 468 expr_list: expr
 469         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 470         ;
 471 */
 472
 473 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 474         | expr
 475         ;
 476
 477 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 478         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 479         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 480         | expr '?' expr ':' expr %prec COND     { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 481         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 482         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 483         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 484         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 485         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 486         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 487         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 488         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 489         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 490         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 491         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 492         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 493         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 494         | '(' expr ')'                          { $$ = $2; }
 495         ;
 496
 497 expr_list_const: expr_const
 498         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 499         ;
 500
 501 expr_const: expr                                { $$ = $1;
 502                                                   if (!$$->is_const)
 503                                                       yyerror("expression is not constant\n");
 504                                                 }
 505         ;
 506
 507 externdef: tEXTERN tCONST type ident            { $$ = $4;
 508                                                   set_type($$, $3, NULL);
 509                                                 }
 510         ;
 511
 512 fields:                                         { $$ = NULL; }
 513         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 514                                                   else { $$ = $1; }
 515                                                 }
 516         ;
 517
 518 field:    s_field ';'                           { $$ = $1; }
 519         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 520         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 521         | ';'                                   { $$ = NULL; }
 522         ;
 523
 524 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 525         ;
 526
 527 funcdef:
 528           m_attributes type callconv pident
 529           '(' m_args ')'                        { set_type($4, $2, NULL);
 530                                                   $4->attrs = $1;
 531                                                   $$ = make_func($4, $6);
 532                                                   if (is_attr($4->attrs, ATTR_IN)) {
 533                                                     yyerror("Inapplicable attribute");
 534                                                   }
 535                                                 }
 536         ;
 537
 538 m_ident:                                        { $$ = NULL; }
 539         | ident
 540         ;
 541
 542 t_ident:                                        { $$ = NULL; }
 543         | aIDENTIFIER                           { $$ = make_var($1); }
 544         | aKNOWNTYPE                            { $$ = make_var($1); }
 545         ;
 546
 547 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 548 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 549         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 550         | tASYNC                                { $$ = make_var($<str>1); }
 551         | tID                                   { $$ = make_var($<str>1); }
 552         | tRANGE                                { $$ = make_var($<str>1); }
 553         | tRETVAL                               { $$ = make_var($<str>1); }
 554         | tVERSION                              { $$ = make_var($<str>1); }
 555         ;
 556
 557 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 558         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 559         | int_std
 560         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 561         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 562                                                   switch ($$->type) {
 563                                                   case RPC_FC_CHAR:  $$->type = RPC_FC_BYTE; $$->sign = 0; break;
 564                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 565                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 566                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 567                                                   case RPC_FC_HYPER:
 568                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 569                                                     break;
 570                                                   default: break;
 571                                                   }
 572                                                 }
 573         | tUNSIGNED                             { $$ = make_type(RPC_FC_ULONG, &std_int); $$->sign = -1; }
 574         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 575         | tSINGLE                               { $$ = make_type(RPC_FC_FLOAT, NULL); }
 576         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 577         | tBOOLEAN                              { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
 578         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 579         | tHANDLET                              { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
 580         ;
 581
 582 m_int:
 583         | tINT
 584         ;
 585
 586 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 587         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 588         | tSMALL                                { $$ = make_type(RPC_FC_SHORT, NULL); }
 589         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 590         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 591         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 592         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 593         ;
 594
 595 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 596         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 597         ;
 598
 599 coclasshdr: attributes coclass                  { $$ = $2;
 600                                                   $$->attrs = $1;
 601                                                   if (!parse_only && do_header)
 602                                                     write_coclass($$);
 603                                                 }
 604         ;
 605
 606 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 607                                                   $$->ifaces = $3;
 608                                                 }
 609         ;
 610
 611 coclass_ints:                                   { $$ = NULL; }
 612         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 613         ;
 614
 615 coclass_int:
 616           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 617         ;
 618
 619 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 620         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 621         ;
 622
 623 dispinterfacehdr: attributes dispinterface      { $$ = $2;
 624                                                   if ($$->defined) yyerror("multiple definition error\n");
 625                                                   $$->attrs = $1;
 626                                                   $$->attrs = make_attr(ATTR_DISPINTERFACE);
 627                                                   LINK($$->attrs, $1);
 628                                                   $$->ref = find_type("IDispatch", 0);
 629                                                   if (!$$->ref) yyerror("IDispatch is undefined\n");
 630                                                   $$->defined = TRUE;
 631                                                   if (!parse_only && do_header) write_forward($$);
 632                                                 }
 633         ;
 634
 635 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 636         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 637         ;
 638
 639 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 640         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 641         ;
 642
 643 dispinterfacedef: dispinterfacehdr '{'
 644           dispint_props
 645           dispint_meths
 646           '}'                                   { $$ = $1;
 647                                                   $$->fields = $3;
 648                                                   $$->funcs = $4;
 649                                                   if (!parse_only && do_header) write_dispinterface($$);
 650                                                 }
 651 /* FIXME: not sure how to handle this yet
 652         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 653                                                   if (!parse_only && do_header) write_interface($$);
 654                                                 }
 655 */
 656         ;
 657
 658 inherit:                                        { $$ = NULL; }
 659         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 660         ;
 661
 662 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 663         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 664         ;
 665
 666 interfacehdr: attributes interface              { $$ = $2;
 667                                                   if ($$->defined) yyerror("multiple definition error\n");
 668                                                   $$->attrs = $1;
 669                                                   $$->defined = TRUE;
 670                                                   if (!parse_only && do_header) write_forward($$);
 671                                                 }
 672         ;
 673
 674 interfacedef: interfacehdr inherit
 675           '{' int_statements '}'                { $$ = $1;
 676                                                   $$->ref = $2;
 677                                                   $$->funcs = $4;
 678                                                   if (!parse_only && do_header) write_interface($$);
 679                                                 }
 680 /* MIDL is able to import the definition of a base class from inside the
 681  * definition of a derived class, I'll try to support it with this rule */
 682         | interfacehdr ':' aIDENTIFIER
 683           '{' import int_statements '}'         { $$ = $1;
 684                                                   $$->ref = find_type2($3, 0);
 685                                                   if (!$$->ref) yyerror("base class %s not found in import\n", $3);
 686                                                   $$->funcs = $6;
 687                                                   if (!parse_only && do_header) write_interface($$);
 688                                                 }
 689         | dispinterfacedef                      { $$ = $1; }
 690         ;
 691
 692 interfacedec:
 693           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 694         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 695         ;
 696
 697 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 698         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 699         ;
 700
 701 modulehdr: attributes module                    { $$ = $2;
 702                                                   $$->attrs = $1;
 703                                                 }
 704         ;
 705
 706 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 707                                                   $$->funcs = $3;
 708                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 709                                                 }
 710         ;
 711
 712 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 713         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 714         ;
 715
 716 pident:   ident
 717         | p_ident
 718         | '(' pident ')'                        { $$ = $2; }
 719         ;
 720
 721 pident_list:
 722           pident
 723         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 724         ;
 725
 726 pointer_type:
 727           tREF                                  { $$ = RPC_FC_RP; }
 728         | tUNIQUE                               { $$ = RPC_FC_UP; }
 729         | tPTR                                  { $$ = RPC_FC_FP; }
 730         ;
 731
 732 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 733                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 734                                                   $$->type = get_struct_type( $4 );
 735                                                   $$->fields = $4;
 736                                                   $$->defined = TRUE;
 737                                                   if(in_typelib)
 738                                                       add_struct($$);
 739                                                 }
 740         ;
 741
 742 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 743         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 744         | base_type                             { $$ = make_tref(NULL, $1); }
 745         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 746         | enumdef                               { $$ = make_tref(NULL, $1); }
 747         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 748         | structdef                             { $$ = make_tref(NULL, $1); }
 749         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 750         | uniondef                              { $$ = make_tref(NULL, $1); }
 751         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 752         ;
 753
 754 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 755                                                   $4->tname = tref->name;
 756                                                   tref->name = NULL;
 757                                                   $$ = type_ref(tref);
 758                                                   $$->attrs = $2;
 759                                                   if (!parse_only && do_header)
 760                                                     write_typedef($$, $4);
 761                                                   if (in_typelib && $$->attrs)
 762                                                     add_typedef($$, $4);
 763                                                   reg_types($$, $4, 0);
 764                                                 }
 765         ;
 766
 767 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 768                                                   $$->fields = $4;
 769                                                   $$->defined = TRUE;
 770                                                 }
 771         | tUNION t_ident
 772           tSWITCH '(' s_field ')'
 773           m_ident '{' cases '}'                 { var_t *u = $7;
 774                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 775                                                   if (!u) u = make_var("tagged_union");
 776                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 777                                                   u->type->fields = $9;
 778                                                   u->type->defined = TRUE;
 779                                                   LINK(u, $5); $$->fields = u;
 780                                                   $$->defined = TRUE;
 781                                                 }
 782         ;
 783
 784 version:
 785           aNUM                                  { $$ = MAKELONG($1, 0); }
 786         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 787         ;
 788
 789 %%
 790
 791 static attr_t *make_attr(enum attr_type type)
 792 {
 793   attr_t *a = xmalloc(sizeof(attr_t));
 794   a->type = type;
 795   a->u.ival = 0;
 796   INIT_LINK(a);
 797   return a;
 798 }
 799
 800 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 801 {
 802   attr_t *a = xmalloc(sizeof(attr_t));
 803   a->type = type;
 804   a->u.ival = val;
 805   INIT_LINK(a);
 806   return a;
 807 }
 808
 809 static attr_t *make_attrp(enum attr_type type, void *val)
 810 {
 811   attr_t *a = xmalloc(sizeof(attr_t));
 812   a->type = type;
 813   a->u.pval = val;
 814   INIT_LINK(a);
 815   return a;
 816 }
 817
 818 static expr_t *make_expr(enum expr_type type)
 819 {
 820   expr_t *e = xmalloc(sizeof(expr_t));
 821   e->type = type;
 822   e->ref = NULL;
 823   e->u.lval = 0;
 824   e->is_const = FALSE;
 825   INIT_LINK(e);
 826   return e;
 827 }
 828
 829 static expr_t *make_exprl(enum expr_type type, long val)
 830 {
 831   expr_t *e = xmalloc(sizeof(expr_t));
 832   e->type = type;
 833   e->ref = NULL;
 834   e->u.lval = val;
 835   e->is_const = FALSE;
 836   INIT_LINK(e);
 837   /* check for numeric constant */
 838   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 839     e->is_const = TRUE;
 840     e->cval = val;
 841   }
 842   return e;
 843 }
 844
 845 static expr_t *make_exprs(enum expr_type type, char *val)
 846 {
 847   expr_t *e;
 848   e = xmalloc(sizeof(expr_t));
 849   e->type = type;
 850   e->ref = NULL;
 851   e->u.sval = val;
 852   e->is_const = FALSE;
 853   INIT_LINK(e);
 854   /* check for predefined constants */
 855   if (type == EXPR_IDENTIFIER) {
 856     var_t *c = find_const(val, 0);
 857     if (c) {
 858       e->u.sval = c->name;
 859       free(val);
 860       e->is_const = TRUE;
 861       e->cval = c->lval;
 862     }
 863   }
 864   return e;
 865 }
 866
 867 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 868 {
 869   expr_t *e;
 870   e = xmalloc(sizeof(expr_t));
 871   e->type = type;
 872   e->ref = expr;
 873   e->u.tref = tref;
 874   e->is_const = FALSE;
 875   INIT_LINK(e);
 876   /* check for cast of constant expression */
 877   if (type == EXPR_CAST && expr->is_const) {
 878     e->is_const = TRUE;
 879     e->cval = expr->cval;
 880   }
 881   return e;
 882 }
 883
 884 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 885 {
 886   expr_t *e;
 887   e = xmalloc(sizeof(expr_t));
 888   e->type = type;
 889   e->ref = expr;
 890   e->u.lval = 0;
 891   e->is_const = FALSE;
 892   INIT_LINK(e);
 893   /* check for compile-time optimization */
 894   if (expr->is_const) {
 895     e->is_const = TRUE;
 896     switch (type) {
 897     case EXPR_NEG:
 898       e->cval = -expr->cval;
 899       break;
 900     case EXPR_NOT:
 901       e->cval = ~expr->cval;
 902       break;
 903     default:
 904       e->is_const = FALSE;
 905       break;
 906     }
 907   }
 908   return e;
 909 }
 910
 911 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 912 {
 913   expr_t *e;
 914   e = xmalloc(sizeof(expr_t));
 915   e->type = type;
 916   e->ref = expr1;
 917   e->u.ext = expr2;
 918   e->is_const = FALSE;
 919   INIT_LINK(e);
 920   /* check for compile-time optimization */
 921   if (expr1->is_const && expr2->is_const) {
 922     e->is_const = TRUE;
 923     switch (type) {
 924     case EXPR_ADD:
 925       e->cval = expr1->cval + expr2->cval;
 926       break;
 927     case EXPR_SUB:
 928       e->cval = expr1->cval - expr2->cval;
 929       break;
 930     case EXPR_MUL:
 931       e->cval = expr1->cval * expr2->cval;
 932       break;
 933     case EXPR_DIV:
 934       e->cval = expr1->cval / expr2->cval;
 935       break;
 936     case EXPR_OR:
 937       e->cval = expr1->cval | expr2->cval;
 938       break;
 939     case EXPR_AND:
 940       e->cval = expr1->cval & expr2->cval;
 941       break;
 942     case EXPR_SHL:
 943       e->cval = expr1->cval << expr2->cval;
 944       break;
 945     case EXPR_SHR:
 946       e->cval = expr1->cval >> expr2->cval;
 947       break;
 948     default:
 949       e->is_const = FALSE;
 950       break;
 951     }
 952   }
 953   return e;
 954 }
 955
 956 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
 957 {
 958   expr_t *e;
 959   e = xmalloc(sizeof(expr_t));
 960   e->type = type;
 961   e->ref = expr1;
 962   e->u.ext = expr2;
 963   e->ext2 = expr3;
 964   e->is_const = FALSE;
 965   INIT_LINK(e);
 966   /* check for compile-time optimization */
 967   if (expr1->is_const && expr2->is_const && expr3->is_const) {
 968     e->is_const = TRUE;
 969     switch (type) {
 970     case EXPR_COND:
 971       e->cval = expr1->cval ? expr2->cval : expr3->cval;
 972       break;
 973     default:
 974       e->is_const = FALSE;
 975       break;
 976     }
 977   }
 978   return e;
 979 }
 980
 981 static type_t *make_type(unsigned char type, type_t *ref)
 982 {
 983   type_t *t = xmalloc(sizeof(type_t));
 984   t->name = NULL;
 985   t->type = type;
 986   t->ref = ref;
 987   t->rname = NULL;
 988   t->attrs = NULL;
 989   t->funcs = NULL;
 990   t->fields = NULL;
 991   t->ignore = parse_only;
 992   t->is_const = FALSE;
 993   t->sign = 0;
 994   t->defined = FALSE;
 995   t->written = FALSE;
 996   t->typelib_idx = -1;
 997   INIT_LINK(t);
 998   return t;
 999 }
1000
1001 static typeref_t *make_tref(char *name, type_t *ref)
1002 {
1003   typeref_t *t = xmalloc(sizeof(typeref_t));
1004   t->name = name;
1005   t->ref = ref;
1006   t->uniq = ref ? 0 : 1;
1007   return t;
1008 }
1009
1010 static typeref_t *uniq_tref(typeref_t *ref)
1011 {
1012   typeref_t *t = ref;
1013   type_t *tp;
1014   if (t->uniq) return t;
1015   tp = make_type(0, t->ref);
1016   tp->name = t->name;
1017   t->name = NULL;
1018   t->ref = tp;
1019   t->uniq = 1;
1020   return t;
1021 }
1022
1023 static type_t *type_ref(typeref_t *ref)
1024 {
1025   type_t *t = ref->ref;
1026   if (ref->name) free(ref->name);
1027   free(ref);
1028   return t;
1029 }
1030
1031 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1032 {
1033   v->type = ref->ref;
1034   v->tname = ref->name;
1035   ref->name = NULL;
1036   free(ref);
1037   v->array = arr;
1038 }
1039
1040 static ifref_t *make_ifref(type_t *iface)
1041 {
1042   ifref_t *l = xmalloc(sizeof(ifref_t));
1043   l->iface = iface;
1044   l->attrs = NULL;
1045   INIT_LINK(l);
1046   return l;
1047 }
1048
1049 static var_t *make_var(char *name)
1050 {
1051   var_t *v = xmalloc(sizeof(var_t));
1052   v->name = name;
1053   v->ptr_level = 0;
1054   v->type = NULL;
1055   v->tname = NULL;
1056   v->attrs = NULL;
1057   v->array = NULL;
1058   v->eval = NULL;
1059   v->lval = 0;
1060   INIT_LINK(v);
1061   return v;
1062 }
1063
1064 static func_t *make_func(var_t *def, var_t *args)
1065 {
1066   func_t *f = xmalloc(sizeof(func_t));
1067   f->def = def;
1068   f->args = args;
1069   f->ignore = parse_only;
1070   f->idx = -1;
1071   INIT_LINK(f);
1072   return f;
1073 }
1074
1075 static class_t *make_class(char *name)
1076 {
1077   class_t *c = xmalloc(sizeof(class_t));
1078   c->name = name;
1079   c->attrs = NULL;
1080   c->ifaces = NULL;
1081   INIT_LINK(c);
1082   return c;
1083 }
1084
1085 #define HASHMAX 64
1086
1087 static int hash_ident(const char *name)
1088 {
1089   const char *p = name;
1090   int sum = 0;
1091   /* a simple sum hash is probably good enough */
1092   while (*p) {
1093     sum += *p;
1094     p++;
1095   }
1096   return sum & (HASHMAX-1);
1097 }
1098
1099 /***** type repository *****/
1100
1101 struct rtype {
1102   char *name;
1103   type_t *type;
1104   int t;
1105   struct rtype *next;
1106 };
1107
1108 struct rtype *type_hash[HASHMAX];
1109
1110 static type_t *reg_type(type_t *type, char *name, int t)
1111 {
1112   struct rtype *nt;
1113   int hash;
1114   if (!name) {
1115     yyerror("registering named type without name\n");
1116     return type;
1117   }
1118   hash = hash_ident(name);
1119   nt = xmalloc(sizeof(struct rtype));
1120   nt->name = name;
1121   nt->type = type;
1122   nt->t = t;
1123   nt->next = type_hash[hash];
1124   type_hash[hash] = nt;
1125   return type;
1126 }
1127
1128 /* determine pointer type from attrs */
1129 static unsigned char get_pointer_type( type_t *type )
1130 {
1131   int t;
1132   if (is_attr( type->attrs, ATTR_STRING ))
1133   {
1134     type_t *t = type;
1135     while( t->type == 0 && t->ref )
1136       t = t->ref;
1137     switch( t->type )
1138     {
1139     case RPC_FC_CHAR:
1140       return RPC_FC_C_CSTRING;
1141     case RPC_FC_WCHAR:
1142       return RPC_FC_C_WSTRING;
1143     }
1144   }
1145   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1146   if (t) return t;
1147   return RPC_FC_FP;
1148 }
1149
1150 static type_t *reg_types(type_t *type, var_t *names, int t)
1151 {
1152   type_t *ptr = type;
1153   int ptrc = 0;
1154
1155   while (names) {
1156     var_t *next = NEXT_LINK(names);
1157     if (names->name) {
1158       type_t *cur = ptr;
1159       int cptr = names->ptr_level;
1160       if (cptr > ptrc) {
1161         while (cptr > ptrc) {
1162           int t = get_pointer_type( cur );
1163           cur = ptr = make_type(t, cur);
1164           ptrc++;
1165         }
1166       } else {
1167         while (cptr < ptrc) {
1168           cur = cur->ref;
1169           cptr++;
1170         }
1171       }
1172       reg_type(cur, names->name, t);
1173     }
1174     free(names);
1175     names = next;
1176   }
1177   return type;
1178 }
1179
1180 static type_t *find_type(const char *name, int t)
1181 {
1182   struct rtype *cur = type_hash[hash_ident(name)];
1183   while (cur && (cur->t != t || strcmp(cur->name, name)))
1184     cur = cur->next;
1185   if (!cur) {
1186     yyerror("type %s not found\n", name);
1187     return NULL;
1188   }
1189   return cur->type;
1190 }
1191
1192 static type_t *find_type2(char *name, int t)
1193 {
1194   type_t *tp = find_type(name, t);
1195   free(name);
1196   return tp;
1197 }
1198
1199 int is_type(const char *name)
1200 {
1201   struct rtype *cur = type_hash[hash_ident(name)];
1202   while (cur && (cur->t || strcmp(cur->name, name)))
1203     cur = cur->next;
1204   if (cur) return TRUE;
1205   return FALSE;
1206 }
1207
1208 static type_t *get_type(unsigned char type, char *name, int t)
1209 {
1210   struct rtype *cur = NULL;
1211   type_t *tp;
1212   if (name) {
1213     cur = type_hash[hash_ident(name)];
1214     while (cur && (cur->t != t || strcmp(cur->name, name)))
1215       cur = cur->next;
1216   }
1217   if (cur) {
1218     free(name);
1219     return cur->type;
1220   }
1221   tp = make_type(type, NULL);
1222   tp->name = name;
1223   if (!name) return tp;
1224   return reg_type(tp, name, t);
1225 }
1226
1227 static type_t *get_typev(unsigned char type, var_t *name, int t)
1228 {
1229   char *sname = NULL;
1230   if (name) {
1231     sname = name->name;
1232     free(name);
1233   }
1234   return get_type(type, sname, t);
1235 }
1236
1237 static int get_struct_type(var_t *field)
1238 {
1239   int has_pointer = 0;
1240   int has_conformant_array = 0;
1241   int has_conformant_string = 0;
1242
1243   while (field)
1244   {
1245     type_t *t = field->type;
1246
1247     /* get the base type */
1248     while( (t->type == 0) && t->ref )
1249       t = t->ref;
1250
1251     switch (t->type)
1252     {
1253     /*
1254      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1255      *  Simple types don't effect the type of struct.
1256      *  A struct containing a simple struct is still a simple struct.
1257      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1258      */
1259     case 0: /* void pointer */
1260     case RPC_FC_BYTE:
1261     case RPC_FC_CHAR:
1262     case RPC_FC_SMALL:
1263     case RPC_FC_USMALL:
1264     case RPC_FC_WCHAR:
1265     case RPC_FC_SHORT:
1266     case RPC_FC_USHORT:
1267     case RPC_FC_LONG:
1268     case RPC_FC_ULONG:
1269     case RPC_FC_INT3264:
1270     case RPC_FC_UINT3264:
1271     case RPC_FC_HYPER:
1272     case RPC_FC_FLOAT:
1273     case RPC_FC_DOUBLE:
1274     case RPC_FC_STRUCT:
1275     case RPC_FC_ENUM16:
1276     case RPC_FC_ENUM32:
1277       break;
1278
1279     case RPC_FC_UP:
1280     case RPC_FC_FP:
1281       has_pointer = 1;
1282       break;
1283     case RPC_FC_CARRAY:
1284       has_conformant_array = 1;
1285       break;
1286     case RPC_FC_C_CSTRING:
1287     case RPC_FC_C_WSTRING:
1288       has_conformant_string = 1;
1289       break;
1290
1291     /*
1292      * Propagate member attributes
1293      *  a struct should be at least as complex as its member
1294      */
1295     case RPC_FC_CVSTRUCT:
1296       has_conformant_string = 1;
1297       has_pointer = 1;
1298       break;
1299
1300     case RPC_FC_CPSTRUCT:
1301       has_conformant_array = 1;
1302       has_pointer = 1;
1303       break;
1304
1305     case RPC_FC_CSTRUCT:
1306       has_conformant_array = 1;
1307       break;
1308
1309     case RPC_FC_PSTRUCT:
1310       has_pointer = 1;
1311       break;
1312
1313     default:
1314       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1315               field->name, t->type);
1316       /* fallthru - treat it as complex */
1317
1318     /* as soon as we see one of these these members, it's bogus... */
1319     case RPC_FC_IP:
1320     case RPC_FC_ENCAPSULATED_UNION:
1321     case RPC_FC_NON_ENCAPSULATED_UNION:
1322     case RPC_FC_TRANSMIT_AS:
1323     case RPC_FC_REPRESENT_AS:
1324     case RPC_FC_PAD:
1325     case RPC_FC_EMBEDDED_COMPLEX:
1326     case RPC_FC_BOGUS_STRUCT:
1327       return RPC_FC_BOGUS_STRUCT;
1328     }
1329     field = NEXT_LINK(field);
1330   }
1331
1332   if( has_conformant_string && has_pointer )
1333     return RPC_FC_CVSTRUCT;
1334   if( has_conformant_array && has_pointer )
1335     return RPC_FC_CPSTRUCT;
1336   if( has_conformant_array )
1337     return RPC_FC_CSTRUCT;
1338   if( has_pointer )
1339     return RPC_FC_PSTRUCT;
1340   return RPC_FC_STRUCT;
1341 }
1342
1343 /***** constant repository *****/
1344
1345 struct rconst {
1346   char *name;
1347   var_t *var;
1348   struct rconst *next;
1349 };
1350
1351 struct rconst *const_hash[HASHMAX];
1352
1353 static var_t *reg_const(var_t *var)
1354 {
1355   struct rconst *nc;
1356   int hash;
1357   if (!var->name) {
1358     yyerror("registering constant without name\n");
1359     return var;
1360   }
1361   hash = hash_ident(var->name);
1362   nc = xmalloc(sizeof(struct rconst));
1363   nc->name = var->name;
1364   nc->var = var;
1365   nc->next = const_hash[hash];
1366   const_hash[hash] = nc;
1367   return var;
1368 }
1369
1370 static var_t *find_const(char *name, int f)
1371 {
1372   struct rconst *cur = const_hash[hash_ident(name)];
1373   while (cur && strcmp(cur->name, name))
1374     cur = cur->next;
1375   if (!cur) {
1376     if (f) yyerror("constant %s not found\n", name);
1377     return NULL;
1378   }
1379   return cur->var;
1380 }