git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(DLLDEFS,"")
  25 if test "x$enable_debug" = "xno"
  26 then
  27   DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
  28 fi
  29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  30 then
  31   DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
  32 fi
  33
  34 AC_CANONICAL_HOST
  35 case $host in
  36   x86_64*linux*)
  37     if test "x$enable_win64" != "xyes"
  38     then
  39       test -n "$CC" || CC="gcc -m32"
  40       test -n "$LD" || LD="ld -m elf_i386"
  41       test -n "$AS" || AS="as --32"
  42       host_cpu="i386"
  43     fi
  44     ;;
  45 esac
  46
  47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  48 case $host_cpu in
  49   *i[[3456789]]86*)
  50     if test "x$enable_win16" != "xno"
  51     then
  52       enable_win16="yes"
  53     fi
  54     ;;
  55 esac
  56
  57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  59 if test "x$enable_win16" != "xyes"
  60 then
  61   WIN16_FILES=""
  62   WIN16_INSTALL=""
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CXX
  70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  72
  73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  74   [if test -z "$with_wine_tools"; then
  75      if test "$cross_compiling" = "yes"; then
  76        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  77      else
  78        wine_cv_toolsdir="\$(TOPOBJDIR)"
  79      fi
  80    elif test -d "$with_wine_tools/tools/winebuild"; then
  81      case $with_wine_tools in
  82        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  83        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  84      esac
  85    else
  86      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  87    fi])
  88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  89
  90 AC_PATH_XTRA
  91 AC_PROG_LEX
  92
  93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  94 dnl **** without one present.
  95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  96 if test "$XLEX" = "none"
  97 then
  98   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  99 fi
 100
 101 dnl Check for bison
 102 AC_CHECK_PROGS(BISON,bison,none)
 103 if test "$BISON" = "none"
 104 then
 105   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 106 fi
 107
 108 AC_CHECK_TOOLS(AS,[gas as],as)
 109 AC_CHECK_TOOL(LD,ld,ld)
 110 AC_CHECK_TOOL(AR,ar,ar)
 111 AC_PROG_RANLIB
 112 AC_CHECK_TOOL(STRIP,strip,strip)
 113 AC_CHECK_TOOL(WINDRES,windres,false)
 114 AC_PROG_LN_S
 115 WINE_PROG_LN
 116 AC_PROG_EGREP
 117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 118 AC_PROG_INSTALL
 119 dnl Prepend src dir to install path dir if it's a relative path
 120 case "$INSTALL" in
 121   [[\\/$]]* | ?:[[\\/]]* ) ;;
 122   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 123 esac
 124
 125 dnl Check for lint
 126 AC_CHECK_PROGS(LINT, lclint lint)
 127 if test "$LINT" = "lint"
 128 then
 129   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 130   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 131 fi
 132 AC_SUBST(LINT)
 133 AC_SUBST(LINTFLAGS)
 134
 135 dnl Check for various programs
 136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 137
 138 dnl **** Check for some libraries ****
 139
 140 dnl Check for -li386 for NetBSD and OpenBSD
 141 AC_CHECK_LIB(i386,i386_set_ldt)
 142 dnl Check for -lossaudio for NetBSD
 143 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 144 dnl Check for -lw for Solaris
 145 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 146 dnl Check for -lnsl for Solaris
 147 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 148 dnl Check for -lsocket for Solaris
 149 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 150 dnl Check for -lresolv for Solaris
 151 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 152 dnl Check for -lxpg4 for FreeBSD
 153 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 154 dnl Check for -lpoll for Mac OS X/Darwin
 155 AC_CHECK_LIB(poll,poll)
 156 dnl Check for -lresolv for Mac OS X/Darwin
 157 AC_CHECK_LIB(resolv,res_9_init)
 158 dnl Check for -lpthread
 159 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 160
 161 AC_SUBST(XLIB)
 162 AC_SUBST(XFILES)
 163 XFILES=""
 164 AC_SUBST(OPENGLFILES)
 165 OPENGLFILES=""
 166 AC_SUBST(GLU32FILES)
 167 GLU32FILES=""
 168 AC_SUBST(OPENGL_LIBS)
 169 OPENGL_LIBS=""
 170
 171 dnl **** Check for header files ****
 172
 173 AC_CHECK_HEADERS(\
 174         IOKit/IOKitLib.h \
 175         arpa/inet.h \
 176         arpa/nameser.h \
 177         asm/types.h \
 178         cups/cups.h \
 179         direct.h \
 180         elf.h \
 181         float.h \
 182         fontconfig/fontconfig.h \
 183         getopt.h \
 184         gif_lib.h \
 185         ieeefp.h \
 186         io.h \
 187         jack/jack.h \
 188         jpeglib.h \
 189         lcms/lcms.h \
 190         lcms.h \
 191         link.h \
 192         linux/cdrom.h \
 193         linux/compiler.h \
 194         linux/hdreg.h \
 195         linux/input.h \
 196         linux/ioctl.h \
 197         linux/joystick.h \
 198         linux/major.h \
 199         linux/param.h \
 200         linux/serial.h \
 201         linux/ucdrom.h \
 202         mach/machine.h \
 203         machine/cpu.h \
 204         machine/limits.h \
 205         mntent.h \
 206         netdb.h \
 207         netinet/in.h \
 208         netinet/in_systm.h \
 209         netinet/tcp.h \
 210         netinet/tcp_fsm.h \
 211         openssl/ssl.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/sg.h \
 219         scsi/scsi.h \
 220         scsi/scsi_ioctl.h \
 221         stdint.h \
 222         strings.h \
 223         sys/cdio.h \
 224         sys/elf32.h \
 225         sys/errno.h \
 226         sys/epoll.h \
 227         sys/exec_elf.h \
 228         sys/filio.h \
 229         sys/ioctl.h \
 230         sys/ipc.h \
 231         sys/link.h \
 232         sys/lwp.h \
 233         sys/mman.h \
 234         sys/modem.h \
 235         sys/msg.h \
 236         sys/param.h \
 237         sys/poll.h \
 238         sys/ptrace.h \
 239         sys/reg.h \
 240         sys/scsiio.h \
 241         sys/shm.h \
 242         sys/signal.h \
 243         sys/socket.h \
 244         sys/sockio.h \
 245         sys/statfs.h \
 246         sys/statvfs.h \
 247         sys/strtio.h \
 248         sys/syscall.h \
 249         sys/sysctl.h \
 250         sys/time.h \
 251         sys/times.h \
 252         sys/uio.h \
 253         sys/un.h \
 254         sys/vfs.h \
 255         sys/vm86.h \
 256         sys/wait.h \
 257         syscall.h \
 258         termios.h \
 259         unistd.h \
 260         utime.h \
 261         valgrind/memcheck.h
 262 )
 263 AC_HEADER_STAT()
 264
 265 dnl **** Check for X11 ****
 266
 267 if test "$have_x" = "yes"
 268 then
 269     XLIB="-lXext -lX11"
 270     ac_save_CPPFLAGS="$CPPFLAGS"
 271     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 272
 273     dnl *** All of the following tests require X11/Xlib.h
 274     AC_CHECK_HEADERS(X11/Xlib.h,
 275       [
 276         AC_CHECK_HEADERS([X11/XKBlib.h \
 277                           X11/Xutil.h \
 278                           X11/extensions/shape.h \
 279                           X11/extensions/XInput.h \
 280                           X11/extensions/XShm.h \
 281                           X11/extensions/Xrandr.h \
 282                           X11/extensions/Xrender.h \
 283                           X11/extensions/xf86dga.h \
 284                           X11/extensions/xf86vmode.h],,,
 285                          [#include <X11/Xlib.h>
 286                           #ifdef HAVE_X11_XUTIL_H
 287                           # include <X11/Xutil.h>
 288                           #endif])
 289
 290         dnl *** Check for X keyboard extension
 291         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 292         then
 293               AC_CHECK_LIB(X11, XkbQueryExtension,
 294               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 295               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 296         fi
 297
 298         dnl *** Check for X Shm extension
 299         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 300         then
 301               AC_CHECK_LIB(Xext, XShmQueryExtension,
 302               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 303               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 304         fi
 305
 306         dnl *** Check for X shape extension
 307         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 308         then
 309               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 310               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 311               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 312         fi
 313
 314         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 315         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 316         then
 317               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 318                 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 319                             [Define if you have the Xxf86dga library version 2])
 320                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 321                 ],,
 322                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 323         fi
 324
 325         dnl *** Check for XFree86 VMODE extension
 326         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 327         then
 328                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 329                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 330                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 331                   ],,
 332                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 333         fi
 334
 335         dnl *** Check for X RandR extension
 336         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 337         then
 338                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 339 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 340                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 341         fi
 342
 343         dnl *** Check for Transform functions in Xrender
 344         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 345         then
 346               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 347                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 348                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 349                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 350         fi
 351       ]
 352     ) dnl *** End of X11/Xlib.h check
 353
 354     dnl Check for the presence of OpenGL
 355     if test "x$with_opengl" != "xno"
 356     then
 357         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so -a ! -f /usr/X11R6/lib/libGL.dylib
 358         then
 359             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 360 This prevents linking to OpenGL. Delete the file and restart configure.])
 361         fi
 362
 363         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 364         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 365         then
 366             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 367             dnl Check for some problems due to old Mesa versions
 368             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 369               AC_TRY_COMPILE(
 370                 [#include <GL/gl.h>],
 371                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 372                 [wine_cv_opengl_version_OK="yes"],
 373                 [wine_cv_opengl_version_OK="no"]
 374               )
 375             )
 376
 377             if test "$wine_cv_opengl_version_OK" = "yes"
 378             then
 379                 dnl Check for the presence of the library
 380                 AC_CHECK_LIB(GL,glXCreateContext,
 381                              OPENGL_LIBS="-lGL"
 382                              ,,
 383                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 384
 385                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 386                 then
 387                         OPENGLFILES='$(OPENGLFILES)'
 388                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 389                 fi
 390                 dnl Check for GLU32 library.
 391                 AC_CHECK_LIB(GLU,gluLookAt,
 392                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 393                              GLU32FILES='$(GLU32FILES)']
 394                              ,,
 395                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 396                 )
 397              fi
 398
 399              dnl Check for glut32 library.
 400              AC_CHECK_LIB(glut,glutMainLoop,
 401                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 402                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 403                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 404          fi
 405     fi
 406
 407     dnl **** Check for NAS ****
 408     AC_SUBST(NASLIBS,"")
 409     AC_CHECK_HEADERS(audio/audiolib.h,
 410          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 411           AC_CHECK_LIB(audio,AuCreateFlow,
 412                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 413                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 414                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 415
 416     CPPFLAGS="$ac_save_CPPFLAGS"
 417     XFILES='$(XFILES)'
 418 else
 419     XLIB=""
 420     X_CFLAGS=""
 421     X_LIBS=""
 422 fi
 423
 424 dnl **** Check which curses lib to use ***
 425 CURSESLIBS=""
 426 if test "x$with_curses" != "xno"
 427 then
 428     AC_CHECK_HEADERS(ncurses.h,
 429         [AC_CHECK_LIB(ncurses,waddch,
 430             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 431              CURSESLIBS="-lncurses"],
 432              [AC_CHECK_HEADERS(curses.h,
 433                  [AC_CHECK_LIB(curses,waddch,
 434                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 435                       CURSESLIBS="-lcurses"])])])])
 436 fi
 437 AC_SUBST(CURSESLIBS)
 438
 439 dnl **** Check for SANE ****
 440 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 441 if test "$sane_devel" = "no"
 442 then
 443     SANELIBS=""
 444     SANEINCL=""
 445 else
 446     SANELIBS="`$sane_devel --libs`"
 447     SANEINCL="`$sane_devel --cflags`"
 448     ac_save_CPPFLAGS="$CPPFLAGS"
 449     ac_save_LIBS="$LIBS"
 450     CPPFLAGS="$CPPFLAGS $SANEINCL"
 451     LIBS="$LIBS $SANELIBS"
 452     AC_CHECK_HEADER(sane/sane.h,
 453                     [AC_CHECK_LIB(sane,sane_open,
 454                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 455                                   [SANELIBS=""
 456                                   SANEINCL=""])],
 457                     [SANELIBS=""
 458                     SANEINCL=""])
 459     LIBS="$ac_save_LIBS"
 460     CPPFLAGS="$ac_save_CPPFLAGS"
 461 fi
 462 AC_SUBST(SANELIBS)
 463 AC_SUBST(SANEINCL)
 464
 465 dnl **** Check for the ICU library ****
 466 AC_CHECK_HEADERS(unicode/ubidi.h)
 467 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 468 then
 469     saved_libs="$LIBS"
 470     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 471     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 472     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 473     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 474     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 475     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 476                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 477                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 478                  AC_MSG_RESULT(yes)],
 479                 [AC_MSG_RESULT(no)])
 480     LIBS="$saved_libs"
 481 fi
 482
 483 dnl **** Check for FreeType 2 ****
 484 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 485 if test "$ft_lib" = "no"
 486 then
 487     FREETYPELIBS=""
 488     FREETYPEINCL=""
 489     wine_cv_msg_freetype=no
 490 else
 491     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 492     if test "$ft_devel" = "no"
 493     then
 494         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 495         if test "$ft_devel2" = "freetype2-config"
 496         then
 497                 ft_devel=$ft_devel2
 498         fi
 499     fi
 500     if test "$ft_devel" = "no"
 501     then
 502         FREETYPELIBS=""
 503         FREETYPEINCL=""
 504         wine_cv_msg_freetype=yes
 505     else
 506         FREETYPELIBS=`$ft_devel --libs`
 507         FREETYPEINCL=`$ft_devel --cflags`
 508         ac_save_CPPFLAGS="$CPPFLAGS"
 509         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 510         AC_CHECK_HEADERS(ft2build.h \
 511                          freetype/freetype.h \
 512                          freetype/ftglyph.h \
 513                          freetype/tttables.h \
 514                          freetype/ftnames.h \
 515                          freetype/ftsnames.h \
 516                          freetype/ttnameid.h \
 517                          freetype/ftoutln.h \
 518                          freetype/ftwinfnt.h \
 519                          freetype/internal/sfnt.h,,,
 520                          [#if HAVE_FT2BUILD_H
 521                           #include <ft2build.h>
 522                           #endif])
 523         AC_TRY_CPP([#include <ft2build.h>
 524                     #include <freetype/fttrigon.h>],
 525                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 526           [Define if you have the <freetype/fttrigon.h> header file.])
 527                     wine_cv_fttrigon=yes],
 528                     wine_cv_fttrigon=no)
 529         CPPFLAGS="$ac_save_CPPFLAGS"
 530         dnl Check that we have at least freetype/freetype.h
 531         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 532         then
 533             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 534             wine_cv_msg_freetype=no
 535         else
 536             FREETYPELIBS=""
 537             FREETYPEINCL=""
 538             wine_cv_msg_freetype=yes
 539         fi
 540     fi
 541 fi
 542 AC_SUBST(FREETYPELIBS)
 543 AC_SUBST(FREETYPEINCL)
 544
 545 dnl Only build the fonts dir if we have both freetype and fontforge
 546 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 547 then
 548   AC_SUBST(FONTSSUBDIRS,"fonts")
 549 fi
 550
 551 dnl **** Check for parport (currently Linux only) ****
 552 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 553  AC_TRY_COMPILE(
 554    [#include <linux/ppdev.h>],
 555    [ioctl (1,PPCLAIM,0)],
 556    [ac_cv_c_ppdev="yes"],
 557    [ac_cv_c_ppdev="no"])
 558  )
 559 if test "$ac_cv_c_ppdev" = "yes"
 560 then
 561     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 562 fi
 563
 564 dnl **** Check for va_copy ****
 565 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 566  AC_TRY_LINK(
 567    [#include <stdarg.h>],
 568    [va_list ap1, ap2;
 569     va_copy(ap1,ap2);
 570    ],
 571    [ac_cv_c_va_copy="yes"],
 572    [ac_cv_c_va_copy="no"])
 573  )
 574 if test "$ac_cv_c_va_copy" = "yes"
 575 then
 576     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 577 fi
 578 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 579  AC_TRY_LINK(
 580    [#include <stdarg.h>],
 581    [va_list ap1, ap2;
 582     __va_copy(ap1,ap2);
 583    ],
 584    [ac_cv_c___va_copy="yes"],
 585    [ac_cv_c___va_copy="no"])
 586  )
 587 if test "$ac_cv_c___va_copy" = "yes"
 588 then
 589     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 590 fi
 591
 592 dnl **** Check for sigsetjmp ****
 593 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 594  AC_TRY_LINK(
 595    [#include <setjmp.h>],
 596    [sigjmp_buf buf;
 597     sigsetjmp( buf, 1 );
 598     siglongjmp( buf, 1 );],
 599    [ac_cv_c_sigsetjmp="yes"],
 600    [ac_cv_c_sigsetjmp="no"])
 601  )
 602 if test "$ac_cv_c_sigsetjmp" = "yes"
 603 then
 604     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 605 fi
 606
 607 dnl **** Check for pthread_rwlock_t ****
 608 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 609 #include <pthread.h>])
 610
 611 dnl **** Check for pthread functions ****
 612 ac_save_LIBS="$LIBS"
 613 LIBS="$LIBS $LIBPTHREAD"
 614 AC_CHECK_FUNCS(\
 615         pthread_getattr_np \
 616         pthread_get_stackaddr_np \
 617         pthread_get_stacksize_np \
 618 )
 619 LIBS="$ac_save_LIBS"
 620
 621 dnl **** Check for Open Sound System ****
 622 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 623
 624 AC_CACHE_CHECK([for Open Sound System],
 625         ac_cv_c_opensoundsystem,
 626         AC_TRY_COMPILE([
 627         #if defined(HAVE_SYS_SOUNDCARD_H)
 628                 #include <sys/soundcard.h>
 629         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 630                 #include <machine/soundcard.h>
 631         #elif defined(HAVE_SOUNDCARD_H)
 632                 #include <soundcard.h>
 633         #endif
 634         ],[
 635
 636 /* check for one of the Open Sound System specific SNDCTL_ defines */
 637 #if !defined(SNDCTL_DSP_STEREO)
 638 #error No open sound system
 639 #endif
 640 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 641
 642 if test "$ac_cv_c_opensoundsystem" = "yes"
 643 then
 644     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 645 fi
 646
 647 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 648         ac_cv_c_opensoundsystem_midi,
 649         AC_TRY_COMPILE([
 650         #if defined(HAVE_SYS_SOUNDCARD_H)
 651                 #include <sys/soundcard.h>
 652         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 653                 #include <machine/soundcard.h>
 654         #elif defined(HAVE_SOUNDCARD_H)
 655                 #include <soundcard.h>
 656         #endif
 657         ],[
 658
 659 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 660 #if !defined(SNDCTL_SEQ_SYNC)
 661 #error No open sound system MIDI interface
 662 #endif
 663 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 664
 665 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 666 then
 667     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 668 fi
 669
 670 dnl **** Check for aRts Sound Server ****
 671 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 672 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 673 then
 674     ARTSC_CFLAGS=""
 675     for i in `$ARTSCCONFIG --cflags`
 676     do
 677       case "$i" in
 678         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 679       esac
 680     done
 681     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 682     save_CFLAGS="$CFLAGS"
 683     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 684     AC_CHECK_LIB(artsc,arts_init,
 685         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 686             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 687             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 688             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 689             $ARTSC_LIBS)
 690     CFLAGS="$save_CFLAGS"
 691 fi
 692
 693 dnl **** Check for ALSA 1.x ****
 694 AC_SUBST(ALSALIBS,"")
 695 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 696 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 697 then
 698     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 699         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 700 #include <alsa/asoundlib.h>
 701 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 702 #include <sys/asoundlib.h>
 703 #endif],
 704                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 705                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 706                          ALSALIBS="-lasound"])])
 707 fi
 708
 709 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 710
 711 AC_SUBST(AUDIOIOLIBS,"")
 712 AC_CHECK_HEADERS(libaudioio.h,
 713     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 714                   [AUDIOIOLIBS="-laudioio"
 715                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 716
 717 dnl **** Check for capi4linux ****
 718
 719 AC_CHECK_HEADERS(capi20.h,[
 720         AC_CHECK_HEADERS(linux/capi.h,[
 721                 AC_CHECK_LIB(capi20,capi20_register,[
 722                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 723                 ])
 724         ])
 725 ])
 726
 727 dnl **** Check for broken glibc mmap64 ****
 728
 729 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 730         AC_TRY_RUN([
 731                 #define _FILE_OFFSET_BITS 64
 732                 #include <stdio.h>
 733                 #include <unistd.h>
 734                 #include <fcntl.h>
 735                 #include <sys/mman.h>
 736                 #include <errno.h>
 737
 738                 int main(int argc,char **argv) {
 739                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 740                         if (fd == -1) exit(1);
 741
 742                         unlink("conftest.map");
 743
 744                         write(fd,"test",4);
 745
 746                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 747                             (errno == EINVAL)
 748                         ) {
 749                                 exit(1);
 750                         }
 751                         close(fd);
 752                         fprintf(stderr,"success!\n");
 753                         exit(0);
 754                 }
 755
 756         ],
 757     ac_cv_mmap64_works="yes",
 758     ac_cv_mmap64_works="no",
 759     ac_cv_mmap64_works="no") )
 760
 761 if test "$ac_cv_mmap64_works" = "yes"
 762 then
 763     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 764 fi
 765
 766 dnl **** Check for gcc specific options ****
 767
 768 AC_SUBST(EXTRACFLAGS,"")
 769 if test "x${GCC}" = "xyes"
 770 then
 771   EXTRACFLAGS="-Wall -pipe"
 772
 773   dnl Check for strength-reduce bug
 774   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 775                   AC_TRY_RUN([
 776 int     L[[4]] = {0,1,2,3};
 777 int main(void) {
 778   static int Array[[3]];
 779   unsigned int B = 3;
 780   int i;
 781   for(i=0; i<B; i++) Array[[i]] = i - 3;
 782   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 783   L[[i]] = 4;
 784
 785   exit( Array[[1]] != -2 || L[[2]] != 3);
 786 }],
 787     ac_cv_c_gcc_strength_bug="no",
 788     ac_cv_c_gcc_strength_bug="yes",
 789     ac_cv_c_gcc_strength_bug="yes") )
 790   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 791   then
 792     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 793   fi
 794
 795   dnl Check for -fshort-wchar
 796   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 797       [WINE_TRY_CFLAGS([-fshort-wchar],
 798                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 799   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 800   then
 801       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 802   fi
 803
 804   dnl Check for -mpreferred-stack-boundary
 805   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 806       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 807                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 808   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 809   then
 810     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 811   fi
 812
 813   dnl Check for -fno-strict-aliasing
 814   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 815       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 816                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 817   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 818   then
 819     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 820   fi
 821
 822   dnl Check for -gstabs+ option
 823   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 824       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 825   if test "$ac_cv_c_gcc_gstabs" = "yes"
 826   then
 827     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 828   fi
 829
 830   dnl Check for noisy string.h
 831   saved_CFLAGS="$CFLAGS"
 832   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 833   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 834       AC_TRY_COMPILE([#include <string.h>],[],
 835                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 836   CFLAGS="$saved_CFLAGS"
 837   if test "$ac_cv_c_string_h_warnings" = "no"
 838   then
 839     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 840   fi
 841 fi
 842
 843 dnl **** Check how to define a function in assembly code ****
 844
 845 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 846   WINE_TRY_ASM_LINK(
 847       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 848       ac_cv_asm_func_def=".def",
 849     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 850       ac_cv_asm_func_def=".type @function",
 851     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 852       ac_cv_asm_func_def=".type 2",
 853       ac_cv_asm_func_def="unknown")])]))
 854
 855 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 856 case "$ac_cv_asm_func_def" in
 857   ".def")
 858      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 859   ".type @function")
 860      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 861   ".type 2")
 862      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 863   *)
 864      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 865 esac
 866
 867 dnl **** Check for underscore on external symbols ****
 868
 869 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 870     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 871                       [extern int ac_test;],
 872                       [if (ac_test) return 1],
 873                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 874
 875 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 876 if test "$ac_cv_c_extern_prefix" = "yes"
 877 then
 878   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 879 else
 880   AC_DEFINE([__ASM_NAME(name)], [name])
 881 fi
 882
 883 dnl **** Check for working dll ****
 884
 885 AC_SUBST(DLLEXT,"")
 886 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 887 AC_SUBST(DLLIBS,"")
 888 AC_SUBST(LDSHARED,"")
 889 AC_SUBST(LDDLLFLAGS,"")
 890 AC_SUBST(LIBEXT,"so")
 891 AC_SUBST(IMPLIBEXT,"def")
 892
 893 case $host_os in
 894   cygwin*|mingw32*)
 895     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 896     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 897     if test "$DLLWRAP" = "false"; then
 898       LIBEXT="a"
 899     else
 900       dnl FIXME - check whether dllwrap works correctly...
 901       LIBEXT="dll"
 902     fi
 903     IMPLIBEXT="a"
 904     dnl We can't build 16-bit NE dlls
 905     WIN16_FILES=""
 906     WIN16_INSTALL=""
 907     ;;
 908   *)
 909     AC_CHECK_HEADERS(dlfcn.h,
 910         [AC_CHECK_FUNCS(dlopen,,
 911             [AC_CHECK_LIB(dl,dlopen,
 912                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 913                           DLLIBS="-ldl"],
 914                          [LIBEXT="a"])])],
 915         [LIBEXT="a"])
 916
 917     if test "$LIBEXT" = "so"
 918     then
 919       DLLFLAGS="$DLLFLAGS -fPIC"
 920       DLLEXT=".so"
 921       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 922           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 923                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 924       if test "$ac_cv_c_dll_gnuelf" = "yes"
 925       then
 926         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 927         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 928         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 929           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 930                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 931         if test "$ac_cv_c_dll_zdefs" = "yes"
 932         then
 933           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 934         fi
 935
 936         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 937           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 938                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 939         if test "$ac_cv_c_dll_init_fini" = "yes"
 940         then
 941           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 942         fi
 943
 944         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 945           [echo '{ global: *; };' >conftest.map
 946            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 947                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 948            rm -f conftest.map])
 949         if test "$ac_cv_c_ld_version_scripts" = "yes"
 950         then
 951           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 952         fi
 953
 954         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 955           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 956                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 957         if test "$ac_cv_c_export_dynamic" = "yes"
 958         then
 959           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 960         fi
 961
 962         case $host_cpu in
 963           *i[[3456789]]86*)
 964             AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
 965               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 966                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 967             if test "$ac_cv_ld_reloc_exec" = "yes"
 968             then
 969               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
 970             fi
 971             ;;
 972         esac
 973
 974       else
 975         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 976             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 977                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 978         if test "$ac_cv_c_dll_unixware" = "yes"
 979         then
 980           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 981           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 982
 983         else
 984           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 985             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 986           if test "$ac_cv_c_dll_macho" = "yes"
 987           then
 988             LIBEXT="dylib"
 989             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
 990             LDSHARED="\$(CC) -dynamiclib"
 991             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 992             STRIP="$STRIP -u -r"
 993             dnl Relocate wine executable
 994             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 995             dnl Relocate libwine.dyld too
 996             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 997             dnl declare needed frameworks
 998             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 999             AC_SUBST(IOKITLIB,"-framework IOKit")
1000             dnl using IOKit imply we use CoreFoundation too
1001             IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1002           else
1003             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1004               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1005             if test "$ac_cv_c_dll_hpux" = "yes"
1006             then
1007               LIBEXT="sl"
1008               DLLEXT=".sl"
1009               LDDLLFLAGS="-shared -fPIC"
1010               LDSHARED="\$(CC) -shared"
1011             fi
1012           fi
1013         fi
1014       fi
1015     fi
1016
1017     dnl Check for cross compiler to build test programs
1018     AC_SUBST(CROSSTEST,"")
1019     if test "$cross_compiling" = "no"
1020     then
1021       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1022       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1023       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1024       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1025     fi
1026     ;;
1027 esac
1028
1029 if test "$LIBEXT" = "a"; then
1030   AC_MSG_ERROR(
1031 [could not find a way to build shared libraries.
1032 It is currently not possible to build Wine without shared library
1033 (.so) support to allow transparent switch between .so and .dll files.
1034 If you are using Linux, you will need a newer binutils.]
1035 )
1036 fi
1037
1038 case $build_os in
1039   cygwin*|mingw32*)
1040     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1041   darwin*|macosx*)
1042     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1043   *)
1044     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1045 esac
1046
1047 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1048 case $host_os in
1049   mingw32*)
1050     AC_SUBST(CRTLIBS,"-lmsvcrt")
1051     AC_SUBST(SOCKETLIBS,"-lws2_32")
1052     ;;
1053 esac
1054
1055 case $host_os in
1056   linux*)
1057     case $host_cpu in
1058       *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1059       *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1060     esac
1061     AC_SUBST(MAIN_BINARY,"wine-glibc")
1062     ;;
1063   darwin*)
1064     AC_SUBST(WINE_BINARIES,"wine-pthread")
1065     AC_SUBST(MAIN_BINARY,"wine-pthread")
1066     ;;
1067   *)
1068     AC_SUBST(WINE_BINARIES,"wine-kthread")
1069     AC_SUBST(MAIN_BINARY,"wine-kthread")
1070     ;;
1071 esac
1072
1073 dnl **** Get the soname for libraries that we load dynamically ****
1074
1075 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1076 then
1077   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1078   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1079   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1080   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1081   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1082   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1083   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1084   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1085   WINE_GET_SONAME(cups,cupsGetDefault)
1086   WINE_GET_SONAME(jack,jack_client_new)
1087   WINE_GET_SONAME(fontconfig,FcInit)
1088   WINE_GET_SONAME(ssl,SSL_library_init)
1089   WINE_GET_SONAME(crypto,BIO_new_socket)
1090   WINE_GET_SONAME(ncurses,waddch)
1091   WINE_GET_SONAME(curses,waddch)
1092   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1093   WINE_GET_SONAME(ungif,DGifOpen)
1094   WINE_GET_SONAME(gif,DGifOpen)
1095   WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1096   WINE_GET_SONAME(capi20,capi20_isinstalled)
1097 fi
1098
1099
1100 dnl **** Check for functions ****
1101
1102 AC_FUNC_ALLOCA()
1103 AC_CHECK_FUNCS(\
1104         _lwp_create \
1105         _lwp_self \
1106         _pclose \
1107         _popen \
1108         _snprintf \
1109         _spawnvp \
1110         _stricmp \
1111         _strnicmp \
1112         _vsnprintf \
1113         chsize \
1114         clone \
1115         epoll_create \
1116         ffs \
1117         finite \
1118         fork \
1119         fpclass \
1120         fstatfs \
1121         fstatvfs \
1122         ftruncate \
1123         futimes \
1124         futimesat \
1125         getnetbyname \
1126         getopt_long \
1127         getpagesize \
1128         getprotobyname \
1129         getprotobynumber \
1130         getpwuid \
1131         getservbyport \
1132         gettid \
1133         gettimeofday \
1134         getuid \
1135         inet_network \
1136         lstat \
1137         memmove \
1138         mmap \
1139         pclose \
1140         popen \
1141         pread \
1142         pwrite \
1143         readlink \
1144         rfork \
1145         sched_yield \
1146         select \
1147         sendmsg \
1148         settimeofday \
1149         sigaltstack \
1150         sigprocmask \
1151         snprintf \
1152         spawnvp \
1153         statfs \
1154         statvfs \
1155         strcasecmp \
1156         strerror \
1157         strncasecmp \
1158         tcgetattr \
1159         timegm \
1160         usleep \
1161         vsnprintf \
1162         wait4 \
1163         waitpid \
1164 )
1165
1166 dnl **** Checks for headers that depend on other ones ****
1167
1168 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1169     [#include <sys/types.h>
1170      #if HAVE_SYS_PARAM_H
1171      # include <sys/param.h>
1172      #endif])
1173
1174 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1175     [#include <sys/types.h>
1176      #if HAVE_SYS_SOCKET_H
1177      # include <sys/socket.h>
1178      #endif])
1179
1180 AC_CHECK_HEADERS([resolv.h],,,
1181     [#include <sys/types.h>
1182      #if HAVE_SYS_SOCKET_H
1183      # include <sys/socket.h>
1184      #endif
1185      #if HAVE_NETINET_IN_H
1186      # include <netinet/in.h>
1187      #endif
1188      #if HAVE_ARPA_NAMESER_H
1189      # include <arpa/nameser.h>
1190      #endif])
1191
1192 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1193
1194 dnl **** Check for v4l(2) headers ****
1195
1196 AC_CHECK_HEADERS(linux/videodev.h,,,
1197 [#ifdef HAVE_SYS_TIME_H
1198 #include <sys/time.h>
1199 #endif
1200 #include <sys/types.h>
1201 #ifdef HAVE_ASM_TYPES_H
1202 #include <asm/types.h>
1203 #endif])
1204
1205 dnl **** Check for IPX headers (currently Linux only) ****
1206
1207 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1208  AC_TRY_COMPILE(
1209    [#include <sys/types.h>
1210     #ifdef HAVE_SYS_SOCKET_H
1211     # include <sys/socket.h>
1212     #endif
1213     #include <netipx/ipx.h>],
1214    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1215    [ac_cv_c_ipx_gnu="yes"],
1216    [ac_cv_c_ipx_gnu="no"])
1217  )
1218 if test "$ac_cv_c_ipx_gnu" = "yes"
1219 then
1220     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1221 fi
1222
1223 if test "$ac_cv_c_ipx_gnu" = "no"
1224 then
1225  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1226   AC_TRY_COMPILE(
1227     [#include <sys/types.h>
1228      #ifdef HAVE_SYS_SOCKET_H
1229      # include <sys/socket.h>
1230      #endif
1231      #include <asm/types.h>
1232      #include <linux/ipx.h>],
1233     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1234     [ac_cv_c_ipx_linux="yes"],
1235     [ac_cv_c_ipx_linux="no"])
1236   )
1237   if test "$ac_cv_c_ipx_linux" = "yes"
1238   then
1239       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1240   fi
1241 fi
1242
1243 dnl **** Check for types ****
1244
1245 AC_C_CONST
1246 AC_C_INLINE
1247 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1248 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1249 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1250
1251 AC_CACHE_CHECK([whether linux/input.h is for real],
1252         wine_cv_linux_input_h,
1253         AC_TRY_COMPILE([
1254             #include <linux/input.h>
1255         ] , [
1256             int foo = EVIOCGBIT(EV_ABS,42);
1257             int bar = BTN_PINKIE;
1258             int fortytwo = 42;
1259         ],
1260         wine_cv_linux_input_h=yes,
1261         wine_cv_linux_input_h=no,
1262         no
1263         )
1264     )
1265     if test "$wine_cv_linux_input_h" = "yes"
1266     then
1267         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1268                   [Define if we have linux/input.h AND it contains the INPUT event API])
1269     fi
1270
1271 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1272                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1273                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1274 if test "$wine_cv_have_sigaddset" = "yes"
1275 then
1276   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1277 fi
1278
1279
1280 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1281         wine_cv_linux_gethostbyname_r_6,
1282         AC_TRY_LINK([
1283 #include <netdb.h>
1284         ], [
1285     char *name=NULL;
1286     struct hostent he;
1287     struct hostent *result;
1288     char *buf=NULL;
1289     int bufsize=0;
1290     int res,errnr;
1291     char *addr=NULL;
1292     int addrlen=0;
1293     int addrtype=0;
1294     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1295     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1296     ],
1297         wine_cv_linux_gethostbyname_r_6=yes,
1298         wine_cv_linux_gethostbyname_r_6=no
1299         )
1300    )
1301    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1302    then
1303       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1304                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1305    fi
1306
1307 if test "$ac_cv_header_linux_joystick_h" = "yes"
1308 then
1309    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1310         wine_cv_linux_joystick_22_api,
1311         AC_TRY_COMPILE([
1312         #include <sys/ioctl.h>
1313         #include <linux/joystick.h>
1314
1315         struct js_event blub;
1316         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1317         #error "no 2.2 header"
1318         #endif
1319         ],/*empty*/,
1320         wine_cv_linux_joystick_22_api=yes,
1321         wine_cv_linux_joystick_22_api=no,
1322         wine_cv_linux_joystick_22_api=no
1323         )
1324    )
1325    if test "$wine_cv_linux_joystick_22_api" = "yes"
1326    then
1327       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1328                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1329    fi
1330 fi
1331
1332 dnl **** statfs checks ****
1333
1334 if test "$ac_cv_header_sys_vfs_h" = "yes"
1335 then
1336     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1337                     wine_cv_sys_vfs_has_statfs,
1338         AC_TRY_COMPILE([
1339         #include <sys/types.h>
1340         #ifdef HAVE_SYS_PARAM_H
1341         # include <sys/param.h>
1342         #endif
1343         #include <sys/vfs.h>
1344         ],[
1345                 struct statfs stfs;
1346
1347                 memset(&stfs,0,sizeof(stfs));
1348         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1349         )
1350     )
1351     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1352     then
1353       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1354                 [Define if the struct statfs is defined by <sys/vfs.h>])
1355     fi
1356 fi
1357
1358 if test "$ac_cv_header_sys_statfs_h" = "yes"
1359 then
1360     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1361                     wine_cv_sys_statfs_has_statfs,
1362         AC_TRY_COMPILE([
1363         #include <sys/types.h>
1364         #ifdef HAVE_SYS_PARAM_H
1365         # include <sys/param.h>
1366         #endif
1367         #include <sys/statfs.h>
1368         ],[
1369                 struct statfs stfs;
1370         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1371         )
1372     )
1373     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1374     then
1375       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1376                 [Define if the struct statfs is defined by <sys/statfs.h>])
1377     fi
1378 fi
1379
1380 if test "$ac_cv_header_sys_mount_h" = "yes"
1381 then
1382     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1383                     wine_cv_sys_mount_has_statfs,
1384         AC_TRY_COMPILE([
1385         #include <sys/types.h>
1386         #ifdef HAVE_SYS_PARAM_H
1387         # include <sys/param.h>
1388         #endif
1389         #include <sys/mount.h>
1390         ],[
1391                 struct statfs stfs;
1392         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1393         )
1394     )
1395     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1396     then
1397       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1398                 [Define if the struct statfs is defined by <sys/mount.h>])
1399     fi
1400 fi
1401
1402 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1403
1404 dnl Check for statfs members
1405 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1406 [#include <sys/types.h>
1407 #ifdef HAVE_SYS_PARAM_H
1408 # include <sys/param.h>
1409 #endif
1410 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1411 # include <sys/mount.h>
1412 #else
1413 # ifdef STATFS_DEFINED_BY_SYS_VFS
1414 #  include <sys/vfs.h>
1415 # else
1416 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1417 #   include <sys/statfs.h>
1418 #  endif
1419 # endif
1420 #endif])
1421
1422 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1423 [#ifdef HAVE_SYS_STATVFS_H
1424 #include <sys/statvfs.h>
1425 #endif])
1426
1427 dnl Check for socket structure members
1428 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1429 [#include <sys/types.h>
1430 #ifdef HAVE_SYS_SOCKET_H
1431 # include <sys/socket.h>
1432 #endif
1433 #ifdef HAVE_SYS_UN_H
1434 # include <sys/un.h>
1435 #endif])
1436
1437 dnl Check for scsireq_t and sg_io_hdr_t members
1438 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1439 [#include <sys/types.h>
1440 #ifdef HAVE_SCSI_SG_H
1441 #include <scsi/sg.h>
1442 #endif])
1443
1444 dnl Check for siginfo_t members
1445 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1446
1447 dnl Check for struct option
1448 AC_CHECK_MEMBERS([struct option.name],,,
1449 [#ifdef HAVE_GETOPT_H
1450 #include <getopt.h>
1451 #endif])
1452
1453 dnl Check for stat.st_blocks
1454 AC_CHECK_MEMBERS([struct stat.st_blocks])
1455
1456 dnl Check for the external timezone variables timezone and daylight
1457 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1458                AC_TRY_LINK([#include <time.h>],[timezone;],
1459                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1460 if test "$ac_cv_have_timezone" = "yes"
1461 then
1462     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1463 fi
1464 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1465                AC_TRY_LINK([#include <time.h>],[daylight;],
1466                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1467 if test "$ac_cv_have_daylight" = "yes"
1468 then
1469     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1470 fi
1471
1472 dnl *** check for the need to define platform-specific symbols
1473
1474 case $host_cpu in
1475   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1476   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1477   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1478   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1479 esac
1480
1481 case $host_vendor in
1482   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1483 esac
1484
1485 dnl **** Generate output files ****
1486
1487 AH_TOP([#define __WINE_CONFIG_H])
1488
1489 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1490 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1491 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1492 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1493 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1494 WINE_CONFIG_EXTRA_DIR(include/wine)
1495 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1496
1497 MAKE_RULES=Make.rules
1498 AC_SUBST_FILE(MAKE_RULES)
1499
1500 MAKE_DLL_RULES=dlls/Makedll.rules
1501 AC_SUBST_FILE(MAKE_DLL_RULES)
1502
1503 MAKE_TEST_RULES=dlls/Maketest.rules
1504 AC_SUBST_FILE(MAKE_TEST_RULES)
1505
1506 MAKE_LIB_RULES=libs/Makelib.rules
1507 AC_SUBST_FILE(MAKE_LIB_RULES)
1508
1509 MAKE_PROG_RULES=programs/Makeprog.rules
1510 AC_SUBST_FILE(MAKE_PROG_RULES)
1511
1512 AC_CONFIG_FILES([
1513 Make.rules
1514 dlls/Makedll.rules
1515 dlls/Maketest.rules
1516 libs/Makelib.rules
1517 programs/Makeprog.rules
1518 Makefile
1519 dlls/Makefile
1520 dlls/activeds/Makefile
1521 dlls/advapi32/Makefile
1522 dlls/advapi32/tests/Makefile
1523 dlls/advpack/Makefile
1524 dlls/advpack/tests/Makefile
1525 dlls/amstream/Makefile
1526 dlls/atl/Makefile
1527 dlls/avicap32/Makefile
1528 dlls/avifil32/Makefile
1529 dlls/cabinet/Makefile
1530 dlls/capi2032/Makefile
1531 dlls/cards/Makefile
1532 dlls/cfgmgr32/Makefile
1533 dlls/comcat/Makefile
1534 dlls/comctl32/Makefile
1535 dlls/comctl32/tests/Makefile
1536 dlls/commdlg/Makefile
1537 dlls/crtdll/Makefile
1538 dlls/crypt32/Makefile
1539 dlls/crypt32/tests/Makefile
1540 dlls/cryptdll/Makefile
1541 dlls/ctl3d/Makefile
1542 dlls/d3d8/Makefile
1543 dlls/d3d9/Makefile
1544 dlls/d3dim/Makefile
1545 dlls/d3drm/Makefile
1546 dlls/d3dx8/Makefile
1547 dlls/d3dxof/Makefile
1548 dlls/dbghelp/Makefile
1549 dlls/dciman32/Makefile
1550 dlls/ddraw/Makefile
1551 dlls/ddraw/tests/Makefile
1552 dlls/devenum/Makefile
1553 dlls/dinput/Makefile
1554 dlls/dinput/tests/Makefile
1555 dlls/dinput8/Makefile
1556 dlls/dmband/Makefile
1557 dlls/dmcompos/Makefile
1558 dlls/dmime/Makefile
1559 dlls/dmloader/Makefile
1560 dlls/dmscript/Makefile
1561 dlls/dmstyle/Makefile
1562 dlls/dmsynth/Makefile
1563 dlls/dmusic/Makefile
1564 dlls/dmusic32/Makefile
1565 dlls/dplay/Makefile
1566 dlls/dplayx/Makefile
1567 dlls/dpnet/Makefile
1568 dlls/dpnhpast/Makefile
1569 dlls/dsound/Makefile
1570 dlls/dsound/tests/Makefile
1571 dlls/dswave/Makefile
1572 dlls/dxdiagn/Makefile
1573 dlls/dxerr8/Makefile
1574 dlls/dxerr9/Makefile
1575 dlls/dxguid/Makefile
1576 dlls/gdi/Makefile
1577 dlls/gdi/tests/Makefile
1578 dlls/glu32/Makefile
1579 dlls/glut32/Makefile
1580 dlls/hhctrl.ocx/Makefile
1581 dlls/iccvid/Makefile
1582 dlls/icmp/Makefile
1583 dlls/ifsmgr.vxd/Makefile
1584 dlls/imagehlp/Makefile
1585 dlls/imm32/Makefile
1586 dlls/iphlpapi/Makefile
1587 dlls/iphlpapi/tests/Makefile
1588 dlls/itss/Makefile
1589 dlls/kernel/Makefile
1590 dlls/kernel/tests/Makefile
1591 dlls/lzexpand/Makefile
1592 dlls/lzexpand/tests/Makefile
1593 dlls/mapi32/Makefile
1594 dlls/mapi32/tests/Makefile
1595 dlls/mlang/Makefile
1596 dlls/mlang/tests/Makefile
1597 dlls/mmdevldr.vxd/Makefile
1598 dlls/monodebg.vxd/Makefile
1599 dlls/mpr/Makefile
1600 dlls/msacm/Makefile
1601 dlls/msacm/imaadp32/Makefile
1602 dlls/msacm/msadp32/Makefile
1603 dlls/msacm/msg711/Makefile
1604 dlls/msacm/winemp3/Makefile
1605 dlls/msacm/tests/Makefile
1606 dlls/mscms/Makefile
1607 dlls/mscms/tests/Makefile
1608 dlls/msdmo/Makefile
1609 dlls/mshtml/Makefile
1610 dlls/mshtml/tests/Makefile
1611 dlls/msi/Makefile
1612 dlls/msi/tests/Makefile
1613 dlls/msimg32/Makefile
1614 dlls/msisys/Makefile
1615 dlls/msnet32/Makefile
1616 dlls/msrle32/Makefile
1617 dlls/msvcrt/Makefile
1618 dlls/msvcrt/tests/Makefile
1619 dlls/msvcrt20/Makefile
1620 dlls/msvcrt40/Makefile
1621 dlls/msvcrtd/Makefile
1622 dlls/msvcrtd/tests/Makefile
1623 dlls/msvidc32/Makefile
1624 dlls/msvideo/Makefile
1625 dlls/mswsock/Makefile
1626 dlls/netapi32/Makefile
1627 dlls/netapi32/tests/Makefile
1628 dlls/newdev/Makefile
1629 dlls/ntdll/Makefile
1630 dlls/ntdll/tests/Makefile
1631 dlls/odbc32/Makefile
1632 dlls/odbccp32/Makefile
1633 dlls/ole32/Makefile
1634 dlls/ole32/tests/Makefile
1635 dlls/oleacc/Makefile
1636 dlls/oleaut32/Makefile
1637 dlls/oleaut32/tests/Makefile
1638 dlls/olecli/Makefile
1639 dlls/oledlg/Makefile
1640 dlls/olepro32/Makefile
1641 dlls/olesvr/Makefile
1642 dlls/opengl32/Makefile
1643 dlls/powrprof/Makefile
1644 dlls/psapi/Makefile
1645 dlls/psapi/tests/Makefile
1646 dlls/qcap/Makefile
1647 dlls/quartz/Makefile
1648 dlls/quartz/tests/Makefile
1649 dlls/rasapi32/Makefile
1650 dlls/riched20/Makefile
1651 dlls/richedit/Makefile
1652 dlls/rpcrt4/Makefile
1653 dlls/rpcrt4/tests/Makefile
1654 dlls/rsabase/Makefile
1655 dlls/rsabase/tests/Makefile
1656 dlls/rsaenh/Makefile
1657 dlls/rsaenh/tests/Makefile
1658 dlls/secur32/Makefile
1659 dlls/sensapi/Makefile
1660 dlls/serialui/Makefile
1661 dlls/setupapi/Makefile
1662 dlls/shdocvw/Makefile
1663 dlls/shell32/Makefile
1664 dlls/shell32/tests/Makefile
1665 dlls/shfolder/Makefile
1666 dlls/shlwapi/Makefile
1667 dlls/shlwapi/tests/Makefile
1668 dlls/snmpapi/Makefile
1669 dlls/stdole32.tlb/Makefile
1670 dlls/sti/Makefile
1671 dlls/strmiids/Makefile
1672 dlls/tapi32/Makefile
1673 dlls/ttydrv/Makefile
1674 dlls/twain/Makefile
1675 dlls/unicows/Makefile
1676 dlls/url/Makefile
1677 dlls/urlmon/Makefile
1678 dlls/urlmon/tests/Makefile
1679 dlls/user/Makefile
1680 dlls/user/tests/Makefile
1681 dlls/uuid/Makefile
1682 dlls/uxtheme/Makefile
1683 dlls/vdhcp.vxd/Makefile
1684 dlls/vdmdbg/Makefile
1685 dlls/version/Makefile
1686 dlls/version/tests/Makefile
1687 dlls/vmm.vxd/Makefile
1688 dlls/vnbt.vxd/Makefile
1689 dlls/vnetbios.vxd/Makefile
1690 dlls/vtdapi.vxd/Makefile
1691 dlls/vwin32.vxd/Makefile
1692 dlls/win32s/Makefile
1693 dlls/winaspi/Makefile
1694 dlls/wined3d/Makefile
1695 dlls/winedos/Makefile
1696 dlls/wineps/Makefile
1697 dlls/wininet/Makefile
1698 dlls/wininet/tests/Makefile
1699 dlls/winmm/Makefile
1700 dlls/winmm/joystick/Makefile
1701 dlls/winmm/mcianim/Makefile
1702 dlls/winmm/mciavi/Makefile
1703 dlls/winmm/mcicda/Makefile
1704 dlls/winmm/mciseq/Makefile
1705 dlls/winmm/mciwave/Makefile
1706 dlls/winmm/midimap/Makefile
1707 dlls/winmm/tests/Makefile
1708 dlls/winmm/wavemap/Makefile
1709 dlls/winmm/winealsa/Makefile
1710 dlls/winmm/winearts/Makefile
1711 dlls/winmm/wineaudioio/Makefile
1712 dlls/winmm/winejack/Makefile
1713 dlls/winmm/winenas/Makefile
1714 dlls/winmm/wineoss/Makefile
1715 dlls/winnls/Makefile
1716 dlls/winsock/Makefile
1717 dlls/winsock/tests/Makefile
1718 dlls/winspool/Makefile
1719 dlls/winspool/tests/Makefile
1720 dlls/wintab32/Makefile
1721 dlls/wintrust/Makefile
1722 dlls/wow32/Makefile
1723 dlls/wsock32/Makefile
1724 dlls/wtsapi32/Makefile
1725 dlls/x11drv/Makefile
1726 documentation/Makefile
1727 fonts/Makefile
1728 include/Makefile
1729 libs/Makefile
1730 libs/port/Makefile
1731 libs/unicode/Makefile
1732 libs/wine/Makefile
1733 libs/wpp/Makefile
1734 loader/Makefile
1735 programs/Makefile
1736 programs/avitools/Makefile
1737 programs/clock/Makefile
1738 programs/cmdlgtst/Makefile
1739 programs/control/Makefile
1740 programs/expand/Makefile
1741 programs/msiexec/Makefile
1742 programs/notepad/Makefile
1743 programs/progman/Makefile
1744 programs/regedit/Makefile
1745 programs/regsvr32/Makefile
1746 programs/rpcss/Makefile
1747 programs/rundll32/Makefile
1748 programs/start/Makefile
1749 programs/taskmgr/Makefile
1750 programs/uninstaller/Makefile
1751 programs/view/Makefile
1752 programs/wcmd/Makefile
1753 programs/wineboot/Makefile
1754 programs/winebrowser/Makefile
1755 programs/winecfg/Makefile
1756 programs/wineconsole/Makefile
1757 programs/winedbg/Makefile
1758 programs/winefile/Makefile
1759 programs/winemenubuilder/Makefile
1760 programs/winemine/Makefile
1761 programs/winepath/Makefile
1762 programs/winetest/Makefile
1763 programs/winevdm/Makefile
1764 programs/winhelp/Makefile
1765 programs/winver/Makefile
1766 server/Makefile
1767 tools/Makefile
1768 tools/widl/Makefile
1769 tools/winapi/Makefile
1770 tools/winebuild/Makefile
1771 tools/winedump/Makefile
1772 tools/winegcc/Makefile
1773 tools/wmc/Makefile
1774 tools/wrc/Makefile])
1775
1776 AC_OUTPUT
1777
1778 if test "$have_x" = "no"
1779 then
1780   echo
1781   echo "*** Warning: X development files not found. Wine will be built without"
1782   echo "*** X support, which currently does not work, and would probably not be"
1783   echo "*** what you want anyway. You will need to install devel packages of"
1784   echo "*** Xlib/Xfree86 at the very least."
1785 fi
1786
1787 if test "$wine_cv_opengl_version_OK" = "no"
1788 then
1789   echo
1790   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1791   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1792 fi
1793
1794 if test "$wine_cv_msg_freetype" = "yes"
1795 then
1796   echo
1797   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1798   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1799   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1800   echo "*** enable Wine to use TrueType fonts."
1801 fi
1802
1803 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1804         -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1805         "$ac_cv_c_opensoundsystem" = "no"
1806 then
1807     echo "*** No sound system was found. Windows applications will be silent."
1808     echo "*** The currently supported sound systems are:"
1809     echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1810 fi
1811
1812 echo
1813 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1814 echo
1815
1816 dnl Local Variables:
1817 dnl comment-start: "dnl "
1818 dnl comment-end: ""
1819 dnl comment-start-skip: "\\bdnl\\b\\s *"
1820 dnl compile-command: "autoconf"
1821 dnl End: