git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$LD" || LD="ld -m elf_i386"
  28       test -n "$AS" || AS="as --32"
  29       host_cpu="i386"
  30     fi
  31     ;;
  32 esac
  33
  34 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  35 case $host_cpu in
  36   *i[[3456789]]86*)
  37     if test "x$enable_win16" != "xno"
  38     then
  39       enable_win16="yes"
  40     fi
  41     ;;
  42 esac
  43
  44 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  45 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  46 if test "x$enable_win16" != "xyes"
  47 then
  48   WIN16_FILES=""
  49   WIN16_INSTALL=""
  50 fi
  51
  52 dnl check for out of tree build with unclean source tree
  53 case "$srcdir" in
  54  .) ;;
  55  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  56       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  57 You need to run 'make distclean' in the source tree first.])
  58     fi ;;
  59 esac
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  67 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  68
  69 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  70   [if test -z "$with_wine_tools"; then
  71      if test "$cross_compiling" = "yes"; then
  72        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  73      else
  74        wine_cv_toolsdir="\$(TOPOBJDIR)"
  75      fi
  76    elif test -d "$with_wine_tools/tools/winebuild"; then
  77      case $with_wine_tools in
  78        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  79        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  80      esac
  81    else
  82      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  83    fi])
  84 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  85
  86 AC_PATH_XTRA
  87
  88 dnl Check for flex
  89 AC_CHECK_PROGS(FLEX,flex,none)
  90 if test "$FLEX" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  93 fi
  94
  95 dnl Check for bison
  96 AC_CHECK_PROGS(BISON,bison,none)
  97 if test "$BISON" = "none"
  98 then
  99   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 100 fi
 101
 102 AC_CHECK_TOOLS(AS,[gas as],as)
 103 AC_CHECK_TOOL(LD,ld,ld)
 104 AC_CHECK_TOOL(AR,ar,ar)
 105 AC_PROG_RANLIB
 106 AC_CHECK_TOOL(STRIP,strip,strip)
 107 AC_CHECK_TOOL(WINDRES,windres,false)
 108 AC_PROG_LN_S
 109 WINE_PROG_LN
 110 AC_PROG_EGREP
 111 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 112 AC_PROG_INSTALL
 113 dnl Prepend src dir to install path dir if it's a relative path
 114 case "$INSTALL" in
 115   [[\\/$]]* | ?:[[\\/]]* ) ;;
 116   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 117 esac
 118
 119 dnl Check for lint
 120 AC_CHECK_PROGS(LINT, lclint lint)
 121 if test "$LINT" = "lint"
 122 then
 123   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 124   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 125 fi
 126 AC_SUBST(LINT)
 127 AC_SUBST(LINTFLAGS)
 128
 129 dnl Check for various programs
 130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 131 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 132
 133 case $host_cpu in
 134   *i[[3456789]]86*)
 135     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 136     ;;
 137 esac
 138
 139 dnl **** Check for some libraries ****
 140
 141 dnl Check for -li386 for NetBSD and OpenBSD
 142 AC_CHECK_LIB(i386,i386_set_ldt)
 143 dnl Check for -lossaudio for NetBSD
 144 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpthread
 148 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 149
 150 AC_SUBST(XLIB,"")
 151 AC_SUBST(XFILES,"")
 152 AC_SUBST(OPENGLFILES,"")
 153 AC_SUBST(GLU32FILES,"")
 154 AC_SUBST(OPENGL_LIBS,"")
 155 AC_SUBST(QUARTZFILES,"")
 156
 157 dnl **** Check for header files ****
 158
 159 AC_CHECK_HEADERS(\
 160         AudioUnit/AudioUnit.h \
 161         Carbon/Carbon.h \
 162         CoreAudio/CoreAudio.h \
 163         DiskArbitration/DiskArbitration.h \
 164         IOKit/IOKitLib.h \
 165         alsa/asoundlib.h \
 166         arpa/inet.h \
 167         arpa/nameser.h \
 168         asm/types.h \
 169         capi20.h \
 170         cups/cups.h \
 171         curses.h \
 172         direct.h \
 173         dlfcn.h \
 174         elf.h \
 175         float.h \
 176         fontconfig/fontconfig.h \
 177         getopt.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/mach.h \
 199         mach/machine.h \
 200         machine/cpu.h \
 201         machine/limits.h \
 202         machine/soundcard.h \
 203         mntent.h \
 204         ncurses.h \
 205         netdb.h \
 206         netinet/in.h \
 207         netinet/in_systm.h \
 208         netinet/tcp.h \
 209         netinet/tcp_fsm.h \
 210         openssl/err.h \
 211         openssl/ssl.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/sockio.h \
 252         sys/soundcard.h \
 253         sys/statvfs.h \
 254         sys/strtio.h \
 255         sys/syscall.h \
 256         sys/sysctl.h \
 257         sys/time.h \
 258         sys/times.h \
 259         sys/uio.h \
 260         sys/un.h \
 261         sys/vm86.h \
 262         sys/wait.h \
 263         syscall.h \
 264         termios.h \
 265         unicode/ubidi.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285
 286 AC_CHECK_HEADERS([linux/ipx.h],,,
 287     [#include <sys/types.h>
 288      #ifdef HAVE_ASM_TYPES_H
 289      # include <asm/types.h>
 290      #endif
 291      #if HAVE_SYS_SOCKET_H
 292      # include <sys/socket.h>
 293      #endif])
 294
 295 AC_CHECK_HEADERS([resolv.h],,,
 296     [#include <sys/types.h>
 297      #if HAVE_SYS_SOCKET_H
 298      # include <sys/socket.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #if HAVE_ARPA_NAMESER_H
 304      # include <arpa/nameser.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 308
 309 AC_CHECK_HEADERS([pthread_np.h],,,
 310 [#ifdef HAVE_PTHREAD_H
 311 #include <pthread.h>
 312 #endif])
 313
 314 AC_CHECK_HEADERS([linux/videodev.h],,,
 315 [#ifdef HAVE_SYS_TIME_H
 316 #include <sys/time.h>
 317 #endif
 318 #include <sys/types.h>
 319 #ifdef HAVE_ASM_TYPES_H
 320 #include <asm/types.h>
 321 #endif])
 322
 323 dnl Check for broken kernel header that doesn't define __user
 324 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 325
 326 dnl **** Check for working dll ****
 327
 328 AC_SUBST(DLLEXT,"")
 329 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 330 AC_SUBST(LDSHARED,"")
 331 AC_SUBST(LDDLLFLAGS,"")
 332 AC_SUBST(LIBEXT,"so")
 333 AC_SUBST(IMPLIBEXT,"def")
 334 AC_SUBST(LDRPATH_INSTALL,"")
 335 AC_SUBST(LDRPATH_LOCAL,"")
 336 WINE_PATH_LDD
 337
 338 case $host_os in
 339   cygwin*|mingw32*)
 340     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 341     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 342     AC_CHECK_TOOL(MINGWAR,ar,false)
 343     if test "$DLLWRAP" = "false"; then
 344       LIBEXT="a"
 345     else
 346       dnl FIXME - check whether dllwrap works correctly...
 347       LIBEXT="dll"
 348     fi
 349     IMPLIBEXT="a"
 350     dnl We can't build 16-bit NE dlls
 351     WIN16_FILES=""
 352     WIN16_INSTALL=""
 353     ;;
 354   darwin*|macosx*)
 355     DLLEXT=".so"
 356     LIBEXT="dylib"
 357     DLLFLAGS="$DLLFLAGS -fPIC"
 358     LDDLLFLAGS="-bundle -multiply_defined suppress"
 359     LIBWINE_LDFLAGS="-multiply_defined suppress"
 360     LDSHARED="\$(CC) -dynamiclib"
 361     STRIP="$STRIP -x"
 362     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 363     dnl declare needed frameworks
 364     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 365     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 366     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 367     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 368     then
 369         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 370         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 371     fi
 372     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 373     then
 374         dnl CoreServices needed by AudioUnit
 375         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 376     fi
 377     case $host_cpu in
 378       *powerpc*)
 379         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 380         ;;
 381     esac
 382     dnl Enable quartz driver on Mac OS X
 383     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 384     then
 385         AC_SUBST(CARBONLIB,"-framework Carbon")
 386         QUARTZFILES='$(QUARTZFILES)'
 387     fi
 388     ;;
 389   *)
 390     DLLFLAGS="$DLLFLAGS -fPIC"
 391     DLLEXT=".so"
 392     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 393         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 394                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 395     if test "$ac_cv_c_dll_gnuelf" = "yes"
 396     then
 397       LDSHARED="\$(CC) -shared"
 398       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 399       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 400                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 401                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 402                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 403
 404       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 405
 406       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 407                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 408
 409       echo '{ global: *; };' >conftest.map
 410       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 411                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 412       rm -f conftest.map
 413
 414       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 415                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 416
 417       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 418                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 419                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 420           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 421                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 422                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 423
 424       case $host_cpu in
 425         *i[[3456789]]86* | x86_64)
 426           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 427                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 428           ;;
 429       esac
 430
 431     else
 432       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 433           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 434                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 435       if test "$ac_cv_c_dll_unixware" = "yes"
 436       then
 437         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 438         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 439
 440       else
 441         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 442           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 443         if test "$ac_cv_c_dll_hpux" = "yes"
 444         then
 445           LIBEXT="sl"
 446           DLLEXT=".sl"
 447           LDDLLFLAGS="-shared -fPIC"
 448           LDSHARED="\$(CC) -shared"
 449         fi
 450       fi
 451     fi
 452
 453     dnl Check for cross compiler to build test programs
 454     AC_SUBST(CROSSTEST,"")
 455     if test "$cross_compiling" = "no"
 456     then
 457       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 458       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 459       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 460       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 461       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 462     fi
 463     ;;
 464 esac
 465
 466 if test "$LIBEXT" = "a"; then
 467   AC_MSG_ERROR(
 468 [could not find a way to build shared libraries.
 469 It is currently not possible to build Wine without shared library
 470 (.so) support to allow transparent switch between .so and .dll files.
 471 If you are using Linux, you will need a newer binutils.]
 472 )
 473 fi
 474
 475 dnl **** Check for X11 ****
 476
 477 if test "$have_x" = "yes"
 478 then
 479     XLIB="-lXext -lX11"
 480     ac_save_CPPFLAGS="$CPPFLAGS"
 481     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 482
 483     dnl *** All of the following tests require X11/Xlib.h
 484     AC_CHECK_HEADERS([X11/Xlib.h \
 485                       X11/XKBlib.h \
 486                       X11/Xutil.h \
 487                       X11/Xcursor/Xcursor.h \
 488                       X11/extensions/shape.h \
 489                       X11/extensions/XInput.h \
 490                       X11/extensions/XShm.h \
 491                       X11/extensions/Xinerama.h \
 492                       X11/extensions/Xrandr.h \
 493                       X11/extensions/Xrender.h \
 494                       X11/extensions/xf86vmode.h],,,
 495 [#ifdef HAVE_X11_XLIB_H
 496 # include <X11/Xlib.h>
 497 #endif
 498 #ifdef HAVE_X11_XUTIL_H
 499 # include <X11/Xutil.h>
 500 #endif])
 501
 502         dnl *** Check for X keyboard extension
 503         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 504         then
 505               AC_CHECK_LIB(X11, XkbQueryExtension,
 506               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 507               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 508         fi
 509
 510         dnl *** Check for X Shm extension
 511         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 512         then
 513               AC_CHECK_LIB(Xext, XShmQueryExtension,
 514               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 515               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 516         fi
 517
 518         dnl *** Check for X shape extension
 519         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 520         then
 521               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 522               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 523               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 524         fi
 525
 526         dnl *** Check for XFree86 VMODE extension
 527         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 528         then
 529                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 530                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 531                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 532                   ],,
 533                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 534         fi
 535
 536         dnl *** Check for X RandR extension
 537         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 538         then
 539                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 540 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 541                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])],[])
 542         fi
 543
 544         dnl *** Check for Transform functions in Xrender
 545         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 546         then
 547               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 548                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 549                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 550                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 551         fi
 552
 553         dnl *** Check for Xinerama extension
 554         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 555         then
 556                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 557 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 558                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])],[])
 559         fi
 560
 561     dnl *** End of X11/Xlib.h check
 562
 563     dnl Check for the presence of OpenGL
 564     if test "x$with_opengl" != "xno"
 565     then
 566         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 567 [#ifdef HAVE_GL_GLX_H
 568 # include <GL/glx.h>
 569 #endif])
 570         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 571         then
 572             dnl Check for some problems due to old Mesa versions
 573             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 574               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 575                 [wine_cv_opengl_header_version_OK="yes"],
 576                 [wine_cv_opengl_header_version_OK="no"]))
 577
 578             if test "$wine_cv_opengl_header_version_OK" = "yes"
 579             then
 580                 dnl Check for the presence of the library
 581                 AC_CHECK_LIB(GL,glXCreateContext,
 582                              [OPENGL_LIBS="-lGL"
 583                              OPENGLFILES='$(OPENGLFILES)'
 584                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 585                              ,,
 586                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 587
 588                 dnl Check for GLU32 library.
 589                 AC_CHECK_LIB(GLU,gluLookAt,
 590                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 591                              GLU32FILES='$(GLU32FILES)']
 592                              ,,
 593                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 594                 )
 595              fi
 596          else
 597              wine_cv_opengl_headers_found="no"
 598          fi
 599     fi
 600     dnl **** Check for NAS ****
 601     AC_SUBST(NASLIBS,"")
 602     AC_CHECK_HEADERS(audio/audiolib.h,
 603          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 604           AC_CHECK_LIB(audio,AuCreateFlow,
 605                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 606                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 607                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 608                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 609                           [$X_LIBS])
 610                        ],,
 611                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 612
 613     CPPFLAGS="$ac_save_CPPFLAGS"
 614     XFILES='$(XFILES)'
 615 else
 616     XLIB=""
 617     X_CFLAGS=""
 618     X_LIBS=""
 619 fi
 620
 621 dnl **** Check for libxml2 ****
 622
 623 AC_SUBST(XML2LIBS,"")
 624 AC_SUBST(XML2INCL,"")
 625 AC_SUBST(XSLTLIBS,"")
 626 AC_SUBST(XSLTINCL,"")
 627 ac_save_CPPFLAGS="$CPPFLAGS"
 628 if test "$PKG_CONFIG" != "false"
 629 then
 630     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 631     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 632 else
 633     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 634     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 635 fi
 636 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 637 AC_CHECK_HEADERS(libxml/parser.h,
 638         [AC_CHECK_LIB(xml2, xmlParseMemory,
 639             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 640              XML2LIBS="$ac_xml_libs"
 641              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 642          AC_CHECK_LIB(xml2, xmlReadMemory,
 643             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 644          AC_CHECK_LIB(xml2, xmlNewDocPI,
 645             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 646     ])
 647 CPPFLAGS="$ac_save_CPPFLAGS"
 648 if test "$PKG_CONFIG" != "false"
 649 then
 650     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 651     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 652 else
 653     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 654     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 655 fi
 656 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 657 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 658         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 659             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 660              XSLTLIBS="$ac_xslt_libs"
 661              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 662         ],,
 663 [#ifdef HAVE_LIBXSLT_PATTERN_H
 664 # include <libxslt/pattern.h>
 665 #endif])
 666 CPPFLAGS="$ac_save_CPPFLAGS"
 667
 668 dnl **** Check for libhal ****
 669 AC_SUBST(HALINCL,"")
 670 if test "$PKG_CONFIG" != "false"
 671 then
 672     ac_save_CPPFLAGS="$CPPFLAGS"
 673     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 674     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 675     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 676     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 677     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 678     then
 679         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 680           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 681             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 682     fi
 683     CPPFLAGS="$ac_save_CPPFLAGS"
 684 fi
 685
 686 dnl **** Check which curses lib to use ***
 687 CURSESLIBS=""
 688 if test "$ac_cv_header_ncurses_h" = "yes"
 689 then
 690     AC_CHECK_LIB(ncurses,waddch,[CURSESLIBS="-lncurses"])
 691 elif test "$ac_cv_header_curses_h" = "yes"
 692 then
 693     AC_CHECK_LIB(curses,waddch,[CURSESLIBS="-lcurses"])
 694 fi
 695 ac_save_LIBS="$LIBS"
 696 LIBS="$LIBS $CURSESLIBS"
 697 AC_CHECK_FUNCS(mousemask)
 698 LIBS="$ac_save_LIBS"
 699
 700 dnl **** Check for SANE ****
 701 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 702 AC_SUBST(SANEINCL,"")
 703 if test "$sane_devel" != "no"
 704 then
 705     SANEINCL="`$sane_devel --cflags`"
 706     ac_save_CPPFLAGS="$CPPFLAGS"
 707     CPPFLAGS="$CPPFLAGS $SANEINCL"
 708     AC_CHECK_HEADER(sane/sane.h,
 709                     [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 710                     [SANEINCL=""])
 711     CPPFLAGS="$ac_save_CPPFLAGS"
 712 fi
 713
 714 dnl **** Check for libgphoto2 ****
 715 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 716 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 717 AC_SUBST(GPHOTO2LIBS,"")
 718 AC_SUBST(GPHOTO2INCL,"")
 719 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 720 then
 721     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 722     GPHOTO2LIBS=""
 723     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 724     do
 725       case "$i" in
 726         -L/usr/lib|-L/usr/lib64) ;;
 727         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 728       esac
 729     done
 730     ac_save_CPPFLAGS="$CPPFLAGS"
 731     ac_save_LIBS="$LIBS"
 732     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 733     LIBS="$LIBS $GPHOTO2LIBS"
 734     AC_CHECK_HEADER(gphoto2-camera.h,
 735                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 736                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 737                                   [GPHOTO2LIBS=""
 738                                   GPHOTO2INCL=""])],
 739                     [GPHOTO2LIBS=""
 740                     GPHOTO2INCL=""])
 741     LIBS="$ac_save_LIBS"
 742     CPPFLAGS="$ac_save_CPPFLAGS"
 743 fi
 744
 745 dnl **** Check for the ICU library ****
 746 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 747 then
 748     saved_libs="$LIBS"
 749     icu_libs="-lsicuuc -lsicudata -lstdc++ -lgcc_s"
 750     if test -n "$ICU_LIB_DIR"
 751     then
 752         icu_libs="-L$ICU_LIB_DIR $icu_libs"
 753     fi
 754     AC_MSG_CHECKING(whether can link with ICU libraries)
 755     LIBS="$saved_libs $icu_libs"
 756     AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <unicode/ubidi.h>]],[[ubidi_open()]])],
 757                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 758                  AC_SUBST(ICULIBS,"$icu_libs")
 759                  AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 760     LIBS="$saved_libs"
 761 fi
 762
 763 dnl **** Check for resolver library ***
 764 AC_SUBST(RESOLVLIBS,"")
 765 if test "$ac_cv_header_resolv_h" = "yes"
 766 then
 767     AC_CHECK_LIB(resolv, res_query,
 768         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 769          RESOLVLIBS="-lresolv"])
 770 fi
 771
 772 dnl **** Check for LittleCMS ***
 773 AC_SUBST(LCMSLIBS,"")
 774 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 775 then
 776     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 777         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 778          LCMSLIBS="-llcms"])
 779 fi
 780
 781 dnl **** Check for OpenLDAP ***
 782 AC_SUBST(LDAPLIBS,"")
 783 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 784 then
 785     AC_CHECK_LIB(ldap_r, ldap_initialize,
 786         [AC_CHECK_LIB(lber, ber_init,
 787             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 788              LDAPLIBS="-lldap_r -llber"],,
 789              [$LIBPTHREAD])],,
 790              [$LIBPTHREAD])
 791     WINE_CHECK_LIB_FUNCS(\
 792         ldap_count_references \
 793         ldap_first_reference \
 794         ldap_next_reference \
 795         ldap_parse_reference,
 796         [$LDAPLIBS $LIBPTHREAD])
 797 fi
 798
 799 dnl **** Check for FreeType 2 ****
 800 AC_SUBST(FREETYPELIBS,"")
 801 AC_SUBST(FREETYPEINCL,"")
 802 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 803 if test "$ft_devel" = "no"
 804 then
 805     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 806     if test "$ft_devel2" = "freetype2-config"
 807     then
 808         ft_devel=$ft_devel2
 809     fi
 810 fi
 811
 812 if test "$ft_devel" = "no"
 813 then
 814     wine_cv_msg_freetype=yes
 815 else
 816     FREETYPELIBS=`$ft_devel --libs`
 817     FREETYPEINCL=`$ft_devel --cflags`
 818     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 819     if test "$ft_lib" = "no"
 820     then
 821         wine_cv_msg_freetype=yes
 822         FREETYPELIBS=""
 823         FREETYPEINCL=""
 824     else
 825         ac_save_CPPFLAGS="$CPPFLAGS"
 826         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 827         AC_CHECK_HEADERS(ft2build.h \
 828                          freetype/freetype.h \
 829                          freetype/ftglyph.h \
 830                          freetype/tttables.h \
 831                          freetype/ftnames.h \
 832                          freetype/ftsnames.h \
 833                          freetype/ttnameid.h \
 834                          freetype/ftoutln.h \
 835                          freetype/ftwinfnt.h \
 836                          freetype/ftmodapi.h \
 837                          freetype/internal/sfnt.h,,,
 838                          [#if HAVE_FT2BUILD_H
 839                           #include <ft2build.h>
 840                           #endif])
 841         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 842                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 843           [Define if you have the <freetype/fttrigon.h> header file.])
 844                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 845         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 846         ac_save_CFLAGS="$CFLAGS"
 847         CFLAGS="$CFLAGS $FREETYPELIBS"
 848         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 849         CFLAGS="$ac_save_CFLAGS"
 850         CPPFLAGS="$ac_save_CPPFLAGS"
 851         dnl Check that we have at least freetype/freetype.h
 852         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 853         then
 854             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 855             wine_cv_msg_freetype=no
 856         else
 857             FREETYPELIBS=""
 858             FREETYPEINCL=""
 859             wine_cv_msg_freetype=yes
 860         fi
 861     fi
 862 fi
 863
 864 dnl Only build the fonts dir if we have both freetype and fontforge
 865 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 866 then
 867   AC_SUBST(FONTSSUBDIRS,"fonts")
 868 fi
 869
 870 dnl **** Check for parport (currently Linux only) ****
 871 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 872  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 873     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 874 if test "$ac_cv_c_ppdev" = "yes"
 875 then
 876     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 877 fi
 878
 879 dnl **** Check for va_copy ****
 880 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 881  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 882     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 883  )
 884 if test "$ac_cv_c_va_copy" = "yes"
 885 then
 886     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 887 fi
 888 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 889  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 890     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 891  )
 892 if test "$ac_cv_c___va_copy" = "yes"
 893 then
 894     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 895 fi
 896
 897 dnl **** Check for sigsetjmp ****
 898 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 899  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 900     sigsetjmp( buf, 1 );
 901     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 902  )
 903 if test "$ac_cv_c_sigsetjmp" = "yes"
 904 then
 905     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 906 fi
 907
 908 dnl **** Check for pthread_rwlock_t ****
 909 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 910 #include <pthread.h>])
 911
 912 dnl **** Check for pthread functions ****
 913 WINE_CHECK_LIB_FUNCS(\
 914         pthread_attr_get_np \
 915         pthread_getattr_np \
 916         pthread_get_stackaddr_np \
 917         pthread_get_stacksize_np,
 918         [$LIBPTHREAD])
 919
 920 dnl **** Check for EsounD ****
 921 AC_PATH_PROG(ESDCONFIG, esd-config)
 922 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 923 then
 924     ESD_CFLAGS=""
 925     for i in `$ESDCONFIG --cflags`
 926     do
 927       case "$i" in
 928         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 929       esac
 930     done
 931     ESD_LIBS=`$ESDCONFIG --libs`
 932     save_CFLAGS="$CFLAGS"
 933     CFLAGS="$CFLAGS $ESD_CFLAGS"
 934     AC_CHECK_LIB(esd,esd_open_sound,
 935         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 936          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 937          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 938     CFLAGS="$save_CFLAGS"
 939 fi
 940
 941 dnl **** Check for ALSA 1.x ****
 942 AC_SUBST(ALSALIBS,"")
 943 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 944 then
 945     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 946         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
 947 #include <alsa/asoundlib.h>
 948 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 949 #include <sys/asoundlib.h>
 950 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
 951                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 952                          ALSALIBS="-lasound"],[])])
 953 fi
 954
 955 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 956
 957 AC_SUBST(AUDIOIOLIBS,"")
 958 if test "$ac_cv_header_libaudioio_h" = "yes"
 959 then
 960     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 961                   [AUDIOIOLIBS="-laudioio"
 962                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 963 fi
 964
 965 dnl **** Check for capi4linux ****
 966
 967 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 968 then
 969     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 970 fi
 971
 972 dnl **** Check for gcc specific options ****
 973
 974 AC_SUBST(EXTRACFLAGS,"")
 975 if test "x${GCC}" = "xyes"
 976 then
 977   EXTRACFLAGS="-Wall -pipe"
 978
 979   dnl Check for strength-reduce bug
 980   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 981                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
 982 [[static int Array[[3]];
 983   unsigned int B = 3;
 984   int i;
 985   for(i=0; i<B; i++) Array[[i]] = i - 3;
 986   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 987   L[[i]] = 4;
 988   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
 989     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
 990   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 991   then
 992     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 993   fi
 994
 995   dnl Check for some compiler flags
 996
 997   WINE_TRY_CFLAGS([-fshort-wchar],
 998                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
 999                              [Specifies the compiler flag that forces a short wchar_t])])
1000   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1001   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1002   WINE_TRY_CFLAGS([-Wwrite-strings])
1003
1004   dnl Check for noisy string.h
1005   saved_CFLAGS="$CFLAGS"
1006   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1007   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1008       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1009   CFLAGS="$saved_CFLAGS"
1010   if test "$ac_cv_c_string_h_warnings" = "no"
1011   then
1012     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1013   fi
1014
1015   AC_SUBST(BUILTINFLAG,"")
1016   saved_CFLAGS="$CFLAGS"
1017   CFLAGS="$CFLAGS -Werror"
1018   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1019       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1020   CFLAGS="$saved_CFLAGS"
1021   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1022   then
1023     BUILTINFLAG="-fno-builtin"
1024   fi
1025 fi
1026
1027 dnl **** Check how to define a function in assembly code ****
1028
1029 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1030   WINE_TRY_ASM_LINK(
1031       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1032       ac_cv_asm_func_def=".def",
1033     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1034       ac_cv_asm_func_def=".type @function",
1035     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1036       ac_cv_asm_func_def=".type 2",
1037       ac_cv_asm_func_def="unknown")])]))
1038
1039 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1040 case "$ac_cv_asm_func_def" in
1041   ".def")
1042      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1043   ".type @function")
1044      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1045   ".type 2")
1046      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1047   *)
1048      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1049 esac
1050
1051 dnl **** Check for underscore on external symbols ****
1052
1053 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1054     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1055                       [extern int ac_test;],
1056                       [if (ac_test) return 1],
1057                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1058
1059 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1060 if test "$ac_cv_c_extern_prefix" = "yes"
1061 then
1062   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1063 else
1064   AC_DEFINE([__ASM_NAME(name)], [name])
1065 fi
1066
1067 dnl **** Platform-specific checks ****
1068
1069 AC_SUBST(LDPATH,"")
1070 case $build_os in
1071   cygwin*|mingw32*)
1072     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1073     ;;
1074   darwin*|macosx*)
1075     ;;
1076   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1077     if test -z "$LDRPATH_LOCAL"
1078     then
1079       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1080     fi
1081     ;;
1082   *)
1083     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1084     ;;
1085 esac
1086
1087 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1088 case $host_os in
1089   mingw32*)
1090     AC_SUBST(CRTLIBS,"-lmsvcrt")
1091     AC_SUBST(SOCKETLIBS,"-lws2_32")
1092     ;;
1093 esac
1094
1095 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1096 case $host_cpu in
1097   *i[[3456789]]86*)
1098     case $host_os in
1099       linux* | k*bsd*-gnu)
1100         AC_SUBST(MAIN_BINARY,"wine-glibc")
1101         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1102     esac
1103     ;;
1104 esac
1105
1106 dnl **** Get the soname for libraries that we load dynamically ****
1107
1108 AC_DEFINE_UNQUOTED(SONAME_EXT,[".$LIBEXT"],[Define to the file extension of shared libraries.])
1109
1110 WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
1111 WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1112 WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1113 WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1114 WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1115 WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1116 WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1117 WINE_CHECK_SONAME(freetype,FT_Init_FreeType,,,[$X_LIBS])
1118 WINE_CHECK_SONAME(GL,glXQueryExtension,,,[$X_LIBS $X_EXTRA_LIBS])
1119 WINE_CHECK_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1120 WINE_CHECK_SONAME(cups,cupsGetDefault)
1121 WINE_CHECK_SONAME(jack,jack_client_new)
1122 WINE_CHECK_SONAME(fontconfig,FcInit)
1123 WINE_CHECK_SONAME(ssl,SSL_library_init)
1124 WINE_CHECK_SONAME(crypto,BIO_new_socket)
1125 WINE_CHECK_SONAME(ncurses,waddch)
1126 WINE_CHECK_SONAME(curses,waddch)
1127 WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1128 WINE_CHECK_SONAME(capi20,capi20_isinstalled)
1129 WINE_CHECK_SONAME(sane,sane_init)
1130
1131
1132 dnl **** Check for functions ****
1133
1134 AC_CHECK_FUNCS(\
1135         _pclose \
1136         _popen \
1137         _snprintf \
1138         _spawnvp \
1139         _stricmp \
1140         _strnicmp \
1141         _vsnprintf \
1142         asctime_r \
1143         chsize \
1144         clone \
1145         dlopen \
1146         epoll_create \
1147         ffs \
1148         finite \
1149         fork \
1150         fpclass \
1151         fstatfs \
1152         fstatvfs \
1153         ftruncate \
1154         futimes \
1155         futimesat \
1156         getdirentries \
1157         getopt_long \
1158         getpagesize \
1159         getpwuid \
1160         gettid \
1161         gettimeofday \
1162         getuid \
1163         inet_pton \
1164         kqueue \
1165         lstat \
1166         memmove \
1167         mmap \
1168         pclose \
1169         poll \
1170         popen \
1171         prctl \
1172         pread \
1173         pwrite \
1174         readlink \
1175         rfork \
1176         sched_yield \
1177         select \
1178         setrlimit \
1179         settimeofday \
1180         sigaltstack \
1181         sigprocmask \
1182         snprintf \
1183         spawnvp \
1184         statfs \
1185         statvfs \
1186         strcasecmp \
1187         strerror \
1188         strncasecmp \
1189         strtold \
1190         tcgetattr \
1191         timegm \
1192         usleep \
1193         vsnprintf \
1194         wait4 \
1195         waitpid \
1196 )
1197
1198 dnl Check for -ldl
1199 if test "$ac_cv_func_dlopen" = no
1200 then
1201     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1202 fi
1203 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1204
1205 dnl Check for -lpoll for Mac OS X/Darwin
1206 if test "$ac_cv_func_poll" = no
1207 then
1208     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1209 fi
1210
1211 dnl Check for -lnsl for Solaris
1212 AC_SEARCH_LIBS(gethostbyname, nsl)
1213
1214 dnl Check for -lsocket for Solaris
1215 AC_SEARCH_LIBS(connect, socket)
1216
1217 dnl Check for -lresolv for Solaris
1218 AC_SEARCH_LIBS(inet_aton, resolv)
1219
1220 dnl **** Check for functions which may rely on -lsocket on Solaris.
1221 AC_CHECK_FUNCS(\
1222         getaddrinfo \
1223         getnameinfo \
1224         getnetbyname \
1225         getprotobyname \
1226         getprotobynumber \
1227         getservbyport \
1228         inet_network \
1229         sendmsg \
1230 )
1231
1232 dnl **** Check for types ****
1233
1234 AC_C_CONST
1235 AC_C_INLINE
1236 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1237 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1238 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1239
1240 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1241 [#ifdef HAVE_LINUX_INPUT_H
1242 #include <linux/input.h>
1243 #endif])
1244
1245 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1246                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1247 if test "$wine_cv_have_sigaddset" = "yes"
1248 then
1249   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1250 fi
1251
1252
1253 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1254         wine_cv_linux_gethostbyname_r_6,
1255         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1256     char *name=NULL;
1257     struct hostent he;
1258     struct hostent *result;
1259     char *buf=NULL;
1260     int bufsize=0;
1261     int res,errnr;
1262     char *addr=NULL;
1263     int addrlen=0;
1264     int addrtype=0;
1265     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1266     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1267     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1268         ])
1269    )
1270    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1271    then
1272       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1273                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1274    fi
1275
1276 if test "$ac_cv_header_linux_joystick_h" = "yes"
1277 then
1278    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1279         wine_cv_linux_joystick_22_api,
1280         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1281         #include <sys/ioctl.h>
1282         #include <sys/types.h>
1283         #include <linux/joystick.h>
1284
1285         struct js_event blub;
1286         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1287         #error "no 2.2 header"
1288         #endif
1289         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1290    )
1291    if test "$wine_cv_linux_joystick_22_api" = "yes"
1292    then
1293       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1294                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1295    fi
1296 fi
1297
1298 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1299
1300 dnl Check for statfs members
1301 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1302 [#include <sys/types.h>
1303 #ifdef HAVE_SYS_PARAM_H
1304 # include <sys/param.h>
1305 #endif
1306 #ifdef HAVE_SYS_MOUNT_H
1307 # include <sys/mount.h>
1308 #endif
1309 #ifdef HAVE_SYS_VFS_H
1310 # include <sys/vfs.h>
1311 #endif
1312 #ifdef HAVE_SYS_STATFS_H
1313 # include <sys/statfs.h>
1314 #endif])
1315
1316 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1317 [#ifdef HAVE_SYS_STATVFS_H
1318 #include <sys/statvfs.h>
1319 #endif])
1320
1321 dnl Check for socket structure members
1322 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1323 [#include <sys/types.h>
1324 #ifdef HAVE_SYS_SOCKET_H
1325 # include <sys/socket.h>
1326 #endif
1327 #ifdef HAVE_SYS_UN_H
1328 # include <sys/un.h>
1329 #endif])
1330
1331 dnl Check for scsireq_t and sg_io_hdr_t members
1332 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1333 [#include <sys/types.h>
1334 #ifdef HAVE_SCSI_SG_H
1335 #include <scsi/sg.h>
1336 #endif])
1337
1338 dnl Check for siginfo_t members
1339 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1340
1341 dnl Check for struct mtget members
1342 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1343 [#include <sys/types.h>
1344 #ifdef HAVE_SYS_MTIO_H
1345 #include <sys/mtio.h>
1346 #endif])
1347
1348 dnl Check for struct option
1349 AC_CHECK_MEMBERS([struct option.name],,,
1350 [#ifdef HAVE_GETOPT_H
1351 #include <getopt.h>
1352 #endif])
1353
1354 dnl Check for stat.st_blocks
1355 AC_CHECK_MEMBERS([struct stat.st_blocks])
1356
1357 dnl Check for sin6_scope_id
1358 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1359 [#ifdef HAVE_SYS_TYPES_H
1360 #include <sys/types.h>
1361 #endif
1362 #ifdef HAVE_NETINET_IN_H
1363 #include <netinet/in.h>
1364 #endif])
1365
1366 dnl Check for ns_msg ptr member
1367 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1368 [#ifdef HAVE_SYS_TYPES_H
1369 #include <sys/types.h>
1370 #endif
1371 #ifdef HAVE_NETINET_IN_H
1372 # include <netinet/in.h>
1373 #endif
1374 #ifdef HAVE_ARPA_NAMESER_H
1375 # include <arpa/nameser.h>
1376 #endif])
1377
1378 dnl Check for the external timezone variables timezone and daylight
1379 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1380                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1381 if test "$ac_cv_have_timezone" = "yes"
1382 then
1383     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1384 fi
1385 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1386                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1387 if test "$ac_cv_have_daylight" = "yes"
1388 then
1389     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1390 fi
1391
1392 dnl *** check for the need to define platform-specific symbols
1393
1394 case $host_cpu in
1395   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1396   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1397   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1398   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1399   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1400 esac
1401
1402 case $host_vendor in
1403   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1404 esac
1405
1406 dnl **** Generate output files ****
1407
1408 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1409 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1410 ["### Dependencies:\\
1411 \\
1412 .INIT: Makefile\\
1413 .BEGIN: Makefile\\
1414 Makefile: dummy\\
1415         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1416 \\
1417 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1418 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1419 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1420 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1421 ["### Dependencies:
1422
1423 .INIT: Makefile
1424 .BEGIN: Makefile
1425 Makefile: dummy
1426         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1427
1428 \$(OBJS): \$(IDL_GEN_HEADERS)
1429 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1430 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1431 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1432
1433 AH_TOP([#define __WINE_CONFIG_H])
1434
1435 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1436
1437 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1438 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1439 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1440 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1441 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1442 WINE_CONFIG_EXTRA_DIR(include/wine)
1443
1444 MAKE_RULES=Make.rules
1445 AC_SUBST_FILE(MAKE_RULES)
1446
1447 MAKE_DLL_RULES=dlls/Makedll.rules
1448 AC_SUBST_FILE(MAKE_DLL_RULES)
1449
1450 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1451 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1452
1453 MAKE_TEST_RULES=dlls/Maketest.rules
1454 AC_SUBST_FILE(MAKE_TEST_RULES)
1455
1456 MAKE_PROG_RULES=programs/Makeprog.rules
1457 AC_SUBST_FILE(MAKE_PROG_RULES)
1458
1459 AC_CONFIG_FILES([Make.rules])
1460 AC_CONFIG_FILES([dlls/Makedll.rules])
1461 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1462 AC_CONFIG_FILES([dlls/Maketest.rules])
1463 AC_CONFIG_FILES([programs/Makeprog.rules])
1464 AC_CONFIG_FILES([Makefile])
1465 AC_CONFIG_FILES([dlls/Makefile])
1466 AC_CONFIG_FILES([dlls/acledit/Makefile])
1467 AC_CONFIG_FILES([dlls/activeds/Makefile])
1468 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1469 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1470 AC_CONFIG_FILES([dlls/advpack/Makefile])
1471 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1472 AC_CONFIG_FILES([dlls/amstream/Makefile])
1473 AC_CONFIG_FILES([dlls/atl/Makefile])
1474 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1475 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1476 AC_CONFIG_FILES([dlls/browseui/Makefile])
1477 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1478 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1479 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1480 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1481 AC_CONFIG_FILES([dlls/cards/Makefile])
1482 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1483 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1484 AC_CONFIG_FILES([dlls/comcat/Makefile])
1485 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1486 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1487 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1488 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1489 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1490 AC_CONFIG_FILES([dlls/compstui/Makefile])
1491 AC_CONFIG_FILES([dlls/credui/Makefile])
1492 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1493 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1494 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1495 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1496 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1497 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1498 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1499 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1500 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1501 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1502 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1503 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1504 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1505 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1506 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1507 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1508 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1509 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1510 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1511 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1512 AC_CONFIG_FILES([dlls/devenum/Makefile])
1513 AC_CONFIG_FILES([dlls/dinput/Makefile])
1514 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1515 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1516 AC_CONFIG_FILES([dlls/dmband/Makefile])
1517 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1518 AC_CONFIG_FILES([dlls/dmime/Makefile])
1519 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1520 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1521 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1522 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1523 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1524 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1525 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1526 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1527 AC_CONFIG_FILES([dlls/dplay/Makefile])
1528 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1529 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1530 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1531 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1532 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1533 AC_CONFIG_FILES([dlls/dsound/Makefile])
1534 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1535 AC_CONFIG_FILES([dlls/dswave/Makefile])
1536 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1537 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1538 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1539 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1540 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1541 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1542 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1543 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1544 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1545 AC_CONFIG_FILES([dlls/glu32/Makefile])
1546 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1547 AC_CONFIG_FILES([dlls/hal/Makefile])
1548 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1549 AC_CONFIG_FILES([dlls/hid/Makefile])
1550 AC_CONFIG_FILES([dlls/hlink/Makefile])
1551 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1552 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1553 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1554 AC_CONFIG_FILES([dlls/icmp/Makefile])
1555 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1556 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1557 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1558 AC_CONFIG_FILES([dlls/imm32/Makefile])
1559 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1560 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1561 AC_CONFIG_FILES([dlls/inseng/Makefile])
1562 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1563 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1564 AC_CONFIG_FILES([dlls/itss/Makefile])
1565 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1566 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1567 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1568 AC_CONFIG_FILES([dlls/localspl/Makefile])
1569 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1570 AC_CONFIG_FILES([dlls/localui/Makefile])
1571 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1572 AC_CONFIG_FILES([dlls/lz32/Makefile])
1573 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1574 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1575 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1576 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1577 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1578 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1579 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1580 AC_CONFIG_FILES([dlls/midimap/Makefile])
1581 AC_CONFIG_FILES([dlls/mlang/Makefile])
1582 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1583 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1584 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1585 AC_CONFIG_FILES([dlls/mpr/Makefile])
1586 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1587 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1588 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1589 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1590 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1591 AC_CONFIG_FILES([dlls/mscms/Makefile])
1592 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1593 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1594 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1595 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1596 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1597 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1598 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1599 AC_CONFIG_FILES([dlls/msi/Makefile])
1600 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1601 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1602 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1603 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1604 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1605 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1606 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1607 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1608 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1609 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1610 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1611 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1612 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1613 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1614 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1615 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1616 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1617 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1618 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1619 AC_CONFIG_FILES([dlls/newdev/Makefile])
1620 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1621 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1622 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1623 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1624 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1625 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1626 AC_CONFIG_FILES([dlls/objsel/Makefile])
1627 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1628 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1629 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1630 AC_CONFIG_FILES([dlls/ole32/Makefile])
1631 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1632 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1633 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1634 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1635 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1636 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1637 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1638 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1639 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1640 AC_CONFIG_FILES([dlls/pdh/Makefile])
1641 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1642 AC_CONFIG_FILES([dlls/printui/Makefile])
1643 AC_CONFIG_FILES([dlls/psapi/Makefile])
1644 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1645 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1646 AC_CONFIG_FILES([dlls/qcap/Makefile])
1647 AC_CONFIG_FILES([dlls/quartz/Makefile])
1648 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1649 AC_CONFIG_FILES([dlls/query/Makefile])
1650 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1651 AC_CONFIG_FILES([dlls/resutils/Makefile])
1652 AC_CONFIG_FILES([dlls/riched20/Makefile])
1653 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1654 AC_CONFIG_FILES([dlls/riched32/Makefile])
1655 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1656 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1657 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1658 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1659 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1660 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1661 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1662 AC_CONFIG_FILES([dlls/schannel/Makefile])
1663 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1664 AC_CONFIG_FILES([dlls/secur32/Makefile])
1665 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1666 AC_CONFIG_FILES([dlls/security/Makefile])
1667 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1668 AC_CONFIG_FILES([dlls/serialui/Makefile])
1669 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1670 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1671 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1672 AC_CONFIG_FILES([dlls/sfc/Makefile])
1673 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1674 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1675 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1676 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1677 AC_CONFIG_FILES([dlls/shell32/Makefile])
1678 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1679 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1680 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1681 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1682 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1683 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1684 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1685 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1686 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1687 AC_CONFIG_FILES([dlls/sti/Makefile])
1688 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1689 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1690 AC_CONFIG_FILES([dlls/sxs/Makefile])
1691 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1692 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1693 AC_CONFIG_FILES([dlls/unicows/Makefile])
1694 AC_CONFIG_FILES([dlls/url/Makefile])
1695 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1696 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1697 AC_CONFIG_FILES([dlls/user32/Makefile])
1698 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1699 AC_CONFIG_FILES([dlls/userenv/Makefile])
1700 AC_CONFIG_FILES([dlls/usp10/Makefile])
1701 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1702 AC_CONFIG_FILES([dlls/uuid/Makefile])
1703 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1704 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1705 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1706 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1707 AC_CONFIG_FILES([dlls/version/Makefile])
1708 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1710 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1711 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1712 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1713 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1714 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1715 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1716 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1717 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1718 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1719 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1720 AC_CONFIG_FILES([dlls/winedos/Makefile])
1721 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1722 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1723 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1724 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1725 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1726 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1727 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1728 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1729 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1730 AC_CONFIG_FILES([dlls/wing32/Makefile])
1731 AC_CONFIG_FILES([dlls/wininet/Makefile])
1732 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1733 AC_CONFIG_FILES([dlls/winmm/Makefile])
1734 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1735 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1736 AC_CONFIG_FILES([dlls/winscard/Makefile])
1737 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1738 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1740 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1741 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1742 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1743 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1744 AC_CONFIG_FILES([dlls/wow32/Makefile])
1745 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1746 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1747 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1748 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1749 AC_CONFIG_FILES([documentation/Makefile])
1750 AC_CONFIG_FILES([fonts/Makefile])
1751 AC_CONFIG_FILES([include/Makefile])
1752 AC_CONFIG_FILES([libs/Makefile])
1753 AC_CONFIG_FILES([libs/port/Makefile])
1754 AC_CONFIG_FILES([libs/wine/Makefile])
1755 AC_CONFIG_FILES([libs/wpp/Makefile])
1756 AC_CONFIG_FILES([loader/Makefile])
1757 AC_CONFIG_FILES([programs/Makefile])
1758 AC_CONFIG_FILES([programs/clock/Makefile])
1759 AC_CONFIG_FILES([programs/cmd/Makefile])
1760 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1761 AC_CONFIG_FILES([programs/control/Makefile])
1762 AC_CONFIG_FILES([programs/eject/Makefile])
1763 AC_CONFIG_FILES([programs/expand/Makefile])
1764 AC_CONFIG_FILES([programs/explorer/Makefile])
1765 AC_CONFIG_FILES([programs/hh/Makefile])
1766 AC_CONFIG_FILES([programs/icinfo/Makefile])
1767 AC_CONFIG_FILES([programs/iexplore/Makefile])
1768 AC_CONFIG_FILES([programs/msiexec/Makefile])
1769 AC_CONFIG_FILES([programs/net/Makefile])
1770 AC_CONFIG_FILES([programs/notepad/Makefile])
1771 AC_CONFIG_FILES([programs/oleview/Makefile])
1772 AC_CONFIG_FILES([programs/progman/Makefile])
1773 AC_CONFIG_FILES([programs/regedit/Makefile])
1774 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1775 AC_CONFIG_FILES([programs/rpcss/Makefile])
1776 AC_CONFIG_FILES([programs/rundll32/Makefile])
1777 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1778 AC_CONFIG_FILES([programs/start/Makefile])
1779 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1780 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1781 AC_CONFIG_FILES([programs/view/Makefile])
1782 AC_CONFIG_FILES([programs/wineboot/Makefile])
1783 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1784 AC_CONFIG_FILES([programs/winecfg/Makefile])
1785 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1786 AC_CONFIG_FILES([programs/winedbg/Makefile])
1787 AC_CONFIG_FILES([programs/winedevice/Makefile])
1788 AC_CONFIG_FILES([programs/winefile/Makefile])
1789 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1790 AC_CONFIG_FILES([programs/winemine/Makefile])
1791 AC_CONFIG_FILES([programs/winepath/Makefile])
1792 AC_CONFIG_FILES([programs/winetest/Makefile])
1793 AC_CONFIG_FILES([programs/winevdm/Makefile])
1794 AC_CONFIG_FILES([programs/winhelp/Makefile])
1795 AC_CONFIG_FILES([programs/winver/Makefile])
1796 AC_CONFIG_FILES([programs/wordpad/Makefile])
1797 AC_CONFIG_FILES([programs/xcopy/Makefile])
1798 AC_CONFIG_FILES([server/Makefile])
1799 AC_CONFIG_FILES([tools/Makefile])
1800 AC_CONFIG_FILES([tools/widl/Makefile])
1801 AC_CONFIG_FILES([tools/winebuild/Makefile])
1802 AC_CONFIG_FILES([tools/winedump/Makefile])
1803 AC_CONFIG_FILES([tools/winegcc/Makefile])
1804 AC_CONFIG_FILES([tools/wmc/Makefile])
1805 AC_CONFIG_FILES([tools/wrc/Makefile])
1806
1807 AC_OUTPUT
1808
1809 dnl **** Display messages about additional packages ***
1810
1811 if test "$no_create" = "yes"
1812 then
1813   exit 0
1814 fi
1815
1816 if test "$verbose" = "yes"
1817 then
1818   dnl **** libcapi20-dev devel package ***
1819   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1820   then
1821     echo >&2
1822     AC_MSG_NOTICE([libcapi20 development files not found.])
1823     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1824   fi
1825
1826   dnl **** libcupsys-dev devel package ***
1827   if test "$ac_cv_header_cups_cups_h" != "yes"
1828   then
1829     echo >&2
1830     AC_MSG_NOTICE([libcups development files not found.])
1831     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1832   fi
1833
1834   dnl **** libcurses devel package: see libncurses ***
1835   dnl **** libdbus-1 devel package ***
1836   dnl **** libdbus-1-dev is required for libhal-dev ***
1837
1838   dnl **** libgphoto2 devel package ***
1839   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1840   then
1841     echo >&2
1842     AC_MSG_NOTICE([libgphoto2 development files not found.])
1843     if test "$ac_cv_header_sane_sane_h" = "yes"
1844     then
1845       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1846     else
1847       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1848     fi
1849   fi
1850
1851   dnl **** libhal devel package ***
1852   dnl **** libhal-dev depends on libdbus-1-dev ***
1853   if test "$ac_cv_header_hal_libhal_h" != "yes"
1854   then
1855     echo >&2
1856     AC_MSG_NOTICE([libhal development files not found.])
1857     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1858   fi
1859
1860   dnl **** libicu devel package ****
1861   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1862   then
1863     echo >&2
1864     AC_MSG_NOTICE([libicu development files not found.])
1865     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1866   fi
1867
1868   dnl **** liblcms devel package ****
1869   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1870   then
1871     echo >&2
1872     AC_MSG_NOTICE([liblcms development files not found.])
1873     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1874   fi
1875
1876   dnl **** libldap devel package ****
1877   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1878   then
1879     echo >&2
1880     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1881     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1882   fi
1883
1884   dnl **** libncurses / libcurses devel package ***
1885   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1886   then
1887     echo >&2
1888     AC_MSG_NOTICE([lib(n)curses development files not found.])
1889     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1890   fi
1891
1892   dnl **** libsane devel package ***
1893   if test "$ac_cv_header_sane_sane_h" != "yes"
1894   then
1895     echo >&2
1896     AC_MSG_NOTICE([libsane development files not found.])
1897     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1898   fi
1899
1900   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1901   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1902   if test "$have_x" = "yes"
1903   then
1904     dnl **** libX11 - extension: Xext ***
1905     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1906     then
1907       echo >&2
1908       AC_MSG_NOTICE([libxext development files not found.])
1909       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1910     fi
1911
1912     dnl **** libX11 - extension: Xrandr ***
1913     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1914     then
1915       echo >&2
1916       AC_MSG_NOTICE([libXrandr development files not found.])
1917       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1918     fi
1919
1920     dnl **** libX11 - extension: Xrender ***
1921     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1922     then
1923       echo >&2
1924       AC_MSG_NOTICE([libXrender development files not found.])
1925       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1926     fi
1927
1928     dnl **** libX11 - extension: Xxf86vm ***
1929     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1930     then
1931       echo >&2
1932       AC_MSG_NOTICE([libXxf86vm development files not found.])
1933       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1934     fi
1935   fi
1936
1937   dnl **** libxml2 devel package ***
1938   if test "$ac_cv_header_libxml_parser_h" != "yes"
1939   then
1940     echo >&2
1941     AC_MSG_NOTICE([libxml2 development files not found.])
1942     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1943   fi
1944
1945   dnl **** libxslt devel package ***
1946   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1947   then
1948     echo >&2
1949     AC_MSG_NOTICE([libxslt development files not found.])
1950     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1951   fi
1952 fi
1953
1954
1955 dnl **** Display warnings about important packages ***
1956 if test "$have_x" = "no"
1957 then
1958   echo >&2
1959   AC_MSG_WARN([X development files not found. Wine will be built without])
1960   AC_MSG_WARN([X support, which currently does not work, and probably])
1961   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1962   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1963 fi
1964
1965 if test -z "$OPENGLFILES"
1966 then
1967   echo >&2
1968   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
1969   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
1970   if test "$wine_cv_opengl_headers_found" = "no"
1971   then
1972     AC_MSG_WARN([No OpenGL development headers were found])
1973   fi
1974   if test "$wine_cv_opengl_header_version_OK" = "no"
1975   then
1976     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1977   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
1978   then
1979      if test -f /usr/X11R6/lib/libGL.a
1980      then
1981         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
1982 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
1983      else
1984         AC_MSG_WARN([No OpenGL library found on this system.])
1985      fi
1986   fi
1987 fi
1988
1989 if test "$wine_cv_msg_freetype" = "yes"
1990 then
1991   echo >&2
1992   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
1993   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
1994   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
1995   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
1996 fi
1997
1998 if test -z "$FONTSSUBDIRS"
1999 then
2000   echo >&2
2001   if test "$FONTFORGE" = "false"
2002   then
2003     AC_MSG_WARN([FontForge is missing.])
2004   else
2005     AC_MSG_WARN([FreeType is missing.])
2006   fi
2007   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2008 fi
2009
2010 if test -z "$ALSALIBS" -a \
2011         -z "$AUDIOIOLIBS" -a \
2012         -z "$NASLIBS" -a \
2013         -z "$ESD_LIBS" -a \
2014         -z "$ac_cv_lib_soname_jack" -a \
2015         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2016         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2017         "$ac_cv_header_soundcard_h" != "yes"
2018 then
2019   echo >&2
2020   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2021   AC_MSG_WARN([The currently supported sound systems are:])
2022   AC_MSG_WARN([ALSA, EsounD, AudioIO, Jack, NAS and OSS])
2023 fi
2024
2025 echo
2026 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2027 echo
2028
2029 dnl Local Variables:
2030 dnl comment-start: "dnl "
2031 dnl comment-end: ""
2032 dnl comment-start-skip: "\\bdnl\\b\\s *"
2033 dnl compile-command: "autoreconf --warnings=all"
2034 dnl End: