git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  47
  48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  49   [if test -z "$with_wine_tools"; then
  50      if test "$cross_compiling" = "yes"; then
  51        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  52      else
  53        wine_cv_toolsdir="\$(TOPOBJDIR)"
  54      fi
  55    elif test -d "$with_wine_tools/tools/winebuild"; then
  56      case $with_wine_tools in
  57        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  58        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  59      esac
  60    else
  61      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  62    fi])
  63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  64
  65 AC_PATH_XTRA
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  71 if test "$XLEX" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  74 fi
  75
  76 dnl Check for bison
  77 AC_CHECK_PROGS(BISON,bison,none)
  78 if test "$BISON" = "none"
  79 then
  80   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  81 fi
  82
  83 AC_CHECK_TOOLS(AS,[gas as],as)
  84 AC_CHECK_TOOL(LD,ld,ld)
  85 AC_CHECK_TOOL(AR,ar,ar)
  86 AC_PROG_RANLIB
  87 AC_CHECK_TOOL(STRIP,strip,strip)
  88 AC_CHECK_TOOL(WINDRES,windres,false)
  89 AC_PROG_LN_S
  90 WINE_PROG_LN
  91 AC_PROG_EGREP
  92 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  93 AC_PROG_INSTALL
  94 dnl Prepend src dir to install path dir if it's a relative path
  95 case "$INSTALL" in
  96   [[\\/$]]* | ?:[[\\/]]* ) ;;
  97   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  98 esac
  99
 100 dnl Check for lint
 101 AC_CHECK_PROGS(LINT, lclint lint)
 102 if test "$LINT" = "lint"
 103 then
 104   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 105   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 106 fi
 107 AC_SUBST(LINT)
 108 AC_SUBST(LINTFLAGS)
 109
 110 dnl Check for db2html
 111 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 112 AC_SUBST(DB2HTML)
 113
 114 dnl Check for db2pdf
 115 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 116 AC_SUBST(DB2PDF)
 117
 118 dnl Check for db2ps
 119 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 120 AC_SUBST(DB2PS)
 121
 122 dnl Check for db2txt
 123 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 124 AC_SUBST(DB2TXT)
 125
 126 dnl **** Check for some libraries ****
 127
 128 dnl Check for -li386 for NetBSD and OpenBSD
 129 AC_CHECK_LIB(i386,i386_set_ldt)
 130 dnl Check for -lossaudio for NetBSD
 131 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 132 dnl Check for -lw for Solaris
 133 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 134 dnl Check for -lnsl for Solaris
 135 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 136 dnl Check for -lsocket for Solaris
 137 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 138 dnl Check for -lresolv for Solaris
 139 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 140 dnl Check for -lxpg4 for FreeBSD
 141 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 142 dnl Check for -lpoll for Mac OS X/Darwin
 143 AC_CHECK_LIB(poll,poll)
 144 dnl Check for -lresolv for Mac OS X/Darwin
 145 AC_CHECK_LIB(resolv,res_9_init)
 146 dnl Check for -lpthread
 147 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 148
 149 AC_SUBST(XLIB)
 150 AC_SUBST(XFILES)
 151 XFILES=""
 152 AC_SUBST(OPENGLFILES)
 153 OPENGLFILES=""
 154 AC_SUBST(GLU32FILES)
 155 GLU32FILES=""
 156 AC_SUBST(OPENGL_LIBS)
 157 OPENGL_LIBS=""
 158 if test "$have_x" = "yes"
 159 then
 160     XLIB="-lXext -lX11"
 161     ac_save_CPPFLAGS="$CPPFLAGS"
 162     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 163
 164     dnl *** All of the following tests require X11/Xlib.h
 165     AC_CHECK_HEADERS(X11/Xlib.h,
 166       [
 167         AC_CHECK_HEADERS([X11/XKBlib.h \
 168                           X11/Xutil.h \
 169                           X11/extensions/shape.h \
 170                           X11/extensions/XInput.h \
 171                           X11/extensions/XShm.h \
 172                           X11/extensions/Xrandr.h \
 173                           X11/extensions/Xrender.h \
 174                           X11/extensions/Xvlib.h \
 175                           X11/extensions/xf86dga.h \
 176                           X11/extensions/xf86vmode.h],,,
 177                          [#include <X11/Xlib.h>
 178                           #ifdef HAVE_X11_XUTIL_H
 179                           # include <X11/Xutil.h>
 180                           #endif])
 181
 182         dnl *** Check for X keyboard extension
 183         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 184         then
 185               AC_CHECK_LIB(X11, XkbQueryExtension,
 186               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 187               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 188         fi
 189
 190         dnl *** Check for X Shm extension
 191         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 192         then
 193               AC_CHECK_LIB(Xext, XShmQueryExtension,
 194               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 195               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 196         fi
 197
 198         dnl *** Check for X shape extension
 199         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 200         then
 201               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 202               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 203               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 204         fi
 205
 206         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 207         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 208         then
 209               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 210                 [ dnl *** If found...
 211                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 212                             [Define if you have the Xxf86dga library version 2])
 213                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 214                ],
 215                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 216                   dnl *** instead (DGA 2.0 not found)...
 217                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 218                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 219                                 [Define if you have the Xxf86dga library version 1])
 220                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 221                     ],,
 222                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 223                   )
 224                 ],
 225                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 226         fi
 227
 228         dnl *** Check for XFree86 VMODE extension
 229         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 230         then
 231                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 232                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 233                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 234                   ],,
 235                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 236         fi
 237
 238         dnl *** Check for X RandR extension
 239         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 240         then
 241                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 242 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 243                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 244         fi
 245
 246         dnl *** Check for XVideo extension supporting XvImages
 247         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 248         then
 249                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 250                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 251                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 252                   ],,
 253                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 254         fi
 255       ]
 256     ) dnl *** End of X11/Xlib.h check
 257
 258     dnl Check for the presence of OpenGL
 259     if test "x$with_opengl" != "xno"
 260     then
 261         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 262         then
 263             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 264 This prevents linking to OpenGL. Delete the file and restart configure.])
 265         fi
 266
 267         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 268         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 269         then
 270             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 271             dnl Check for some problems due to old Mesa versions
 272             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 273               AC_TRY_COMPILE(
 274                 [#include <GL/gl.h>],
 275                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 276                 [wine_cv_opengl_version_OK="yes"],
 277                 [wine_cv_opengl_version_OK="no"]
 278               )
 279             )
 280
 281             if test "$wine_cv_opengl_version_OK" = "yes"
 282             then
 283                 dnl Check for the presence of the library
 284                 AC_CHECK_LIB(GL,glXCreateContext,
 285                              OPENGL_LIBS="-lGL"
 286                              ,,
 287                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 288
 289                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 290                 then
 291                         OPENGLFILES='$(OPENGLFILES)'
 292                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 293
 294                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 295                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 296                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 297                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 298
 299                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 300                         then
 301                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 302                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 303                                                   #ifdef HAVE_GL_GLEXT_H
 304                                                   # include <GL/glext.h>
 305                                                   #endif
 306                                                   ],
 307                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 308                                                  [wine_cv_extension_prototypes="yes"],
 309                                                  [wine_cv_extension_prototypes="no"]
 310                                   )]
 311                                 )
 312                                 if test "$wine_cv_extension_prototypes" = "yes"
 313                                 then
 314                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 315                                               [Define if the OpenGL headers define extension typedefs])
 316                                 fi
 317                         fi
 318
 319                 fi
 320                 dnl Check for GLU32 library.
 321                 AC_CHECK_LIB(GLU,gluLookAt,
 322                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 323                              GLU32FILES='$(GLU32FILES)']
 324                              ,,
 325                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 326                 )
 327              fi
 328
 329              dnl Check for glut32 library.
 330              AC_CHECK_LIB(glut,glutMainLoop,
 331                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 332                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 333                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 334          fi
 335     fi
 336
 337     dnl **** Check for NAS ****
 338     AC_SUBST(NASLIBS,"")
 339     AC_CHECK_HEADERS(audio/audiolib.h,
 340          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 341           AC_CHECK_LIB(audio,AuCreateFlow,
 342                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 343                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 344                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 345
 346     CPPFLAGS="$ac_save_CPPFLAGS"
 347     XFILES='$(XFILES)'
 348 else
 349     XLIB=""
 350     X_CFLAGS=""
 351     X_LIBS=""
 352 fi
 353
 354 dnl **** Check which curses lib to use ***
 355 CURSESLIBS=""
 356 if test "x$with_curses" != "xno"
 357 then
 358     AC_CHECK_HEADERS(ncurses.h,
 359         [AC_CHECK_LIB(ncurses,waddch,
 360             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 361              CURSESLIBS="-lncurses"],
 362              [AC_CHECK_HEADERS(curses.h,
 363                  [AC_CHECK_LIB(curses,waddch,
 364                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 365                       CURSESLIBS="-lcurses"])])])])
 366     saved_libs="$LIBS"
 367     LIBS="$CURSESLIBS $LIBS"
 368     AC_CHECK_FUNCS(getbkgd resizeterm)
 369     LIBS="$saved_libs"
 370 fi
 371 AC_SUBST(CURSESLIBS)
 372
 373 dnl **** Check for SANE ****
 374 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 375 if test "$sane_devel" = "no"
 376 then
 377     SANELIBS=""
 378     SANEINCL=""
 379 else
 380     SANELIBS="`$sane_devel --libs`"
 381     SANEINCL="`$sane_devel --cflags`"
 382     ac_save_CPPFLAGS="$CPPFLAGS"
 383     ac_save_LIBS="$LIBS"
 384     CPPFLAGS="$CPPFLAGS $SANEINCL"
 385     LIBS="$LIBS $SANELIBS"
 386     AC_CHECK_HEADER(sane/sane.h,
 387                     [AC_CHECK_LIB(sane,sane_open,
 388                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 389                                   [SANELIBS=""
 390                                   SANEINCL=""])],
 391                     [SANELIBS=""
 392                     SANEINCL=""])
 393     LIBS="$ac_save_LIBS"
 394     CPPFLAGS="$ac_save_CPPFLAGS"
 395 fi
 396 AC_SUBST(SANELIBS)
 397 AC_SUBST(SANEINCL)
 398
 399 dnl **** Check for the ICU library ****
 400 AC_CHECK_HEADERS(unicode/ubidi.h)
 401 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 402 then
 403     saved_libs="$LIBS"
 404     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 405     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 406     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 407     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 408     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 409     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 410                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 411                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 412                  AC_MSG_RESULT(yes)],
 413                 [AC_MSG_RESULT(no)])
 414     LIBS="$saved_libs"
 415 fi
 416
 417 dnl **** Check for FreeType 2 ****
 418 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 419 if test "$ft_lib" = "no"
 420 then
 421     FREETYPEINCL=""
 422     wine_cv_msg_freetype=no
 423 else
 424     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 425     if test "$ft_devel" = "no"
 426     then
 427         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 428         if test "$ft_devel2" = "freetype2-config"
 429         then
 430                 ft_devel=$ft_devel2
 431         fi
 432     fi
 433     if test "$ft_devel" = "no"
 434     then
 435         FREETYPEINCL=""
 436         wine_cv_msg_freetype=yes
 437     else
 438         FREETYPEINCL=`$ft_devel --cflags`
 439         ac_save_CPPFLAGS="$CPPFLAGS"
 440         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 441         AC_CHECK_HEADERS(ft2build.h \
 442                          freetype/freetype.h \
 443                          freetype/ftglyph.h \
 444                          freetype/tttables.h \
 445                          freetype/ftnames.h \
 446                          freetype/ftsnames.h \
 447                          freetype/ttnameid.h \
 448                          freetype/ftoutln.h \
 449                          freetype/ftwinfnt.h \
 450                          freetype/internal/sfnt.h,,,
 451                          [#if HAVE_FT2BUILD_H
 452                           #include <ft2build.h>
 453                           #endif])
 454         AC_TRY_CPP([#include <ft2build.h>
 455                     #include <freetype/fttrigon.h>],
 456                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 457           [Define if you have the <freetype/fttrigon.h> header file.])
 458                     wine_cv_fttrigon=yes],
 459                     wine_cv_fttrigon=no)
 460         CPPFLAGS="$ac_save_CPPFLAGS"
 461         dnl Check that we have at least freetype/freetype.h
 462         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 463         then
 464             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 465             wine_cv_msg_freetype=no
 466         else
 467             FREETYPEINCL=""
 468             wine_cv_msg_freetype=yes
 469         fi
 470     fi
 471 fi
 472 AC_SUBST(FREETYPEINCL)
 473
 474 dnl **** Check for parport (currently Linux only) ****
 475 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 476  AC_TRY_COMPILE(
 477    [#include <linux/ppdev.h>],
 478    [ioctl (1,PPCLAIM,0)],
 479    [ac_cv_c_ppdev="yes"],
 480    [ac_cv_c_ppdev="no"])
 481  )
 482 if test "$ac_cv_c_ppdev" = "yes"
 483 then
 484     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 485 fi
 486
 487 dnl **** Check for va_copy ****
 488 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 489  AC_TRY_LINK(
 490    [#include <stdarg.h>],
 491    [va_list ap1, ap2;
 492     va_copy(ap1,ap2);
 493    ],
 494    [ac_cv_c_va_copy="yes"],
 495    [ac_cv_c_va_copy="no"])
 496  )
 497 if test "$ac_cv_c_va_copy" = "yes"
 498 then
 499     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 500 fi
 501 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 502  AC_TRY_LINK(
 503    [#include <stdarg.h>],
 504    [va_list ap1, ap2;
 505     __va_copy(ap1,ap2);
 506    ],
 507    [ac_cv_c___va_copy="yes"],
 508    [ac_cv_c___va_copy="no"])
 509  )
 510 if test "$ac_cv_c___va_copy" = "yes"
 511 then
 512     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 513 fi
 514
 515 dnl **** Check for sigsetjmp ****
 516 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 517  AC_TRY_LINK(
 518    [#include <setjmp.h>],
 519    [sigjmp_buf buf;
 520     sigsetjmp( buf, 1 );
 521     siglongjmp( buf, 1 );],
 522    [ac_cv_c_sigsetjmp="yes"],
 523    [ac_cv_c_sigsetjmp="no"])
 524  )
 525 if test "$ac_cv_c_sigsetjmp" = "yes"
 526 then
 527     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 528 fi
 529
 530 dnl **** Check for pthread_rwlock_t ****
 531 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 532 #include <pthread.h>])
 533
 534 dnl **** Check for pthread functions ****
 535 ac_save_LIBS="$LIBS"
 536 LIBS="$LIBS $LIBPTHREAD"
 537 AC_CHECK_FUNCS(\
 538         pthread_getattr_np \
 539         pthread_get_stackaddr_np \
 540         pthread_get_stacksize_np \
 541 )
 542 LIBS="$ac_save_LIBS"
 543
 544 dnl **** Check for Open Sound System ****
 545 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 546
 547 AC_CACHE_CHECK([for Open Sound System],
 548         ac_cv_c_opensoundsystem,
 549         AC_TRY_COMPILE([
 550         #if defined(HAVE_SYS_SOUNDCARD_H)
 551                 #include <sys/soundcard.h>
 552         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 553                 #include <machine/soundcard.h>
 554         #elif defined(HAVE_SOUNDCARD_H)
 555                 #include <soundcard.h>
 556         #endif
 557         ],[
 558
 559 /* check for one of the Open Sound System specific SNDCTL_ defines */
 560 #if !defined(SNDCTL_DSP_STEREO)
 561 #error No open sound system
 562 #endif
 563 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 564
 565 if test "$ac_cv_c_opensoundsystem" = "yes"
 566 then
 567     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 568 fi
 569
 570 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 571         ac_cv_c_opensoundsystem_midi,
 572         AC_TRY_COMPILE([
 573         #if defined(HAVE_SYS_SOUNDCARD_H)
 574                 #include <sys/soundcard.h>
 575         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 576                 #include <machine/soundcard.h>
 577         #elif defined(HAVE_SOUNDCARD_H)
 578                 #include <soundcard.h>
 579         #endif
 580         ],[
 581
 582 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 583 #if !defined(SNDCTL_SEQ_SYNC)
 584 #error No open sound system MIDI interface
 585 #endif
 586 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 587
 588 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 589 then
 590     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 591 fi
 592
 593 dnl **** Check for aRts Sound Server ****
 594 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 595 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 596 then
 597     ARTSC_CFLAGS=""
 598     for i in `$ARTSCCONFIG --cflags`
 599     do
 600       case "$i" in
 601         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 602       esac
 603     done
 604     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 605     save_CFLAGS="$CFLAGS"
 606     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 607     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 608         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 609          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 610          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 611     CFLAGS="$save_CFLAGS"
 612 fi
 613
 614 dnl **** Check for ALSA ****
 615 AC_SUBST(ALSALIBS,"")
 616 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 617 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 618 then
 619     AC_CHECK_LIB(asound,snd_pcm_open,
 620         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 621         ALSALIBS="-lasound")
 622 fi
 623
 624 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 625
 626 AC_SUBST(AUDIOIOLIBS,"")
 627 AC_CHECK_HEADERS(libaudioio.h,
 628     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 629                   [AUDIOIOLIBS="-laudioio"
 630                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 631
 632 dnl **** Check for capi4linux ****
 633
 634 AC_CHECK_HEADERS(capi20.h,[
 635         AC_CHECK_HEADERS(linux/capi.h,[
 636                 AC_CHECK_LIB(capi20,capi20_register,[
 637                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 638                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 639                 ])
 640         ])
 641 ])
 642
 643 dnl **** Check for broken glibc mmap64 ****
 644
 645 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 646         AC_TRY_RUN([
 647                 #define _FILE_OFFSET_BITS 64
 648                 #include <stdio.h>
 649                 #include <unistd.h>
 650                 #include <fcntl.h>
 651                 #include <sys/mman.h>
 652                 #include <errno.h>
 653
 654                 int main(int argc,char **argv) {
 655                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 656                         if (fd == -1) exit(1);
 657
 658                         unlink("conftest.map");
 659
 660                         write(fd,"test",4);
 661
 662                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 663                             (errno == EINVAL)
 664                         ) {
 665                                 exit(1);
 666                         }
 667                         close(fd);
 668                         fprintf(stderr,"success!\n");
 669                         exit(0);
 670                 }
 671
 672         ],
 673     ac_cv_mmap64_works="yes",
 674     ac_cv_mmap64_works="no",
 675     ac_cv_mmap64_works="no") )
 676
 677 if test "$ac_cv_mmap64_works" = "yes"
 678 then
 679     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 680 fi
 681
 682 dnl **** Check for gcc specific options ****
 683
 684 AC_SUBST(EXTRACFLAGS,"")
 685 if test "x${GCC}" = "xyes"
 686 then
 687   EXTRACFLAGS="-Wall -pipe"
 688
 689   dnl Check for strength-reduce bug
 690   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 691                   AC_TRY_RUN([
 692 int     L[[4]] = {0,1,2,3};
 693 int main(void) {
 694   static int Array[[3]];
 695   unsigned int B = 3;
 696   int i;
 697   for(i=0; i<B; i++) Array[[i]] = i - 3;
 698   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 699   L[[i]] = 4;
 700
 701   exit( Array[[1]] != -2 || L[[2]] != 3);
 702 }],
 703     ac_cv_c_gcc_strength_bug="no",
 704     ac_cv_c_gcc_strength_bug="yes",
 705     ac_cv_c_gcc_strength_bug="yes") )
 706   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 707   then
 708     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 709   fi
 710
 711   dnl Check for -fshort-wchar
 712   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 713       [WINE_TRY_CFLAGS([-fshort-wchar],
 714                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 715   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 716   then
 717       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 718   fi
 719
 720   dnl Check for -mpreferred-stack-boundary
 721   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 722       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 723                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 724   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 725   then
 726     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 727   fi
 728
 729   dnl Check for -fno-strict-aliasing
 730   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 731       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 732                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 733   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 734   then
 735     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 736   fi
 737
 738   dnl Check for -gstabs+ option
 739   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 740       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 741   if test "$ac_cv_c_gcc_gstabs" = "yes"
 742   then
 743     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 744   fi
 745
 746   dnl Check for noisy string.h
 747   saved_CFLAGS="$CFLAGS"
 748   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 749   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 750       AC_TRY_COMPILE([#include <string.h>],[],
 751                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 752   CFLAGS="$saved_CFLAGS"
 753   if test "$ac_cv_c_string_h_warnings" = "no"
 754   then
 755     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 756   fi
 757 fi
 758
 759 dnl **** Check how to define a function in assembly code ****
 760
 761 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 762   WINE_TRY_ASM_LINK(
 763       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 764       ac_cv_asm_func_def=".def",
 765     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 766       ac_cv_asm_func_def=".type @function",
 767     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 768       ac_cv_asm_func_def=".type 2",
 769       ac_cv_asm_func_def="unknown")])]))
 770
 771 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 772 case "$ac_cv_asm_func_def" in
 773   ".def")
 774      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 775   ".type @function")
 776      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 777   ".type 2")
 778      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 779   *)
 780      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 781 esac
 782
 783 dnl **** Check for underscore on external symbols ****
 784
 785 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 786     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 787                       [extern int ac_test;],
 788                       [if (ac_test) return 1],
 789                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 790
 791 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 792 if test "$ac_cv_c_extern_prefix" = "yes"
 793 then
 794   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 795 else
 796   AC_DEFINE([__ASM_NAME(name)], [name])
 797 fi
 798
 799 dnl **** Check how to do strings in assembler ****
 800
 801 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 802     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 803       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 804         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 805           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 806
 807 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 808                    [Define to the assembler keyword used to specify an ASCII string])
 809
 810 dnl **** Check for .short in assembler ****
 811
 812 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 813     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 814       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 815         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 816
 817 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 818                    [Define to the assembler keyword used to specify a word value])
 819
 820 dnl **** Check for .size in assembler ****
 821
 822 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 823     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 824                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 825
 826 if test "$ac_cv_c_asm_size" = "yes"
 827 then
 828   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 829 fi
 830
 831 dnl **** Check for working dll ****
 832
 833 AC_SUBST(DLLEXT,"")
 834 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 835 AC_SUBST(DLLIBS,"")
 836 AC_SUBST(LDSHARED,"")
 837 AC_SUBST(LDDLLFLAGS,"")
 838 AC_SUBST(LIBEXT,"so")
 839 AC_SUBST(IMPLIBEXT,"def")
 840
 841 case $host_os in
 842   cygwin*|mingw32*)
 843     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 844     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 845     if test "$DLLWRAP" = "false"; then
 846       LIBEXT="a"
 847     else
 848       dnl FIXME - check whether dllwrap works correctly...
 849       LIBEXT="dll"
 850     fi
 851     IMPLIBEXT="a"
 852     dnl We can't build 16-bit NE dlls
 853     WIN16_FILES=""
 854     WIN16_INSTALL=""
 855     ;;
 856   *)
 857     AC_CHECK_HEADERS(dlfcn.h,
 858         [AC_CHECK_FUNCS(dlopen,,
 859             [AC_CHECK_LIB(dl,dlopen,
 860                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 861                           DLLIBS="-ldl"],
 862                          [LIBEXT="a"])])],
 863         [LIBEXT="a"])
 864
 865     if test "$LIBEXT" = "so"
 866     then
 867       DLLFLAGS="$DLLFLAGS -fPIC"
 868       DLLEXT=".so"
 869       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 870           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 871                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 872       if test "$ac_cv_c_dll_gnuelf" = "yes"
 873       then
 874         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 875         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 876         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 877           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 878                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 879         if test "$ac_cv_c_dll_zdefs" = "yes"
 880         then
 881           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 882         fi
 883
 884         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 885           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 886                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 887         if test "$ac_cv_c_dll_init_fini" = "yes"
 888         then
 889           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 890         fi
 891
 892         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 893           [echo '{ global: *; };' >conftest.map
 894            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 895                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 896            rm -f conftest.map])
 897         if test "$ac_cv_c_ld_version_scripts" = "yes"
 898         then
 899           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 900         fi
 901
 902         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 903           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 904                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 905         if test "$ac_cv_c_export_dynamic" = "yes"
 906         then
 907           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 908         fi
 909
 910         case $host_cpu in
 911           *i[[3456789]]86*)
 912             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 913               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 914                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 915             if test "$ac_cv_ld_reloc_exec" = "yes"
 916             then
 917               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 918             fi
 919             ;;
 920         esac
 921
 922       else
 923         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 924             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 925                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 926         if test "$ac_cv_c_dll_unixware" = "yes"
 927         then
 928           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 929           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 930
 931         else
 932           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 933             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 934           if test "$ac_cv_c_dll_macho" = "yes"
 935           then
 936             LIBEXT="dylib"
 937             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 938             LDSHARED="\$(CC) -dynamiclib"
 939             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 940             STRIP="$STRIP -u -r"
 941             dnl Relocate wine executable
 942             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 943             dnl Relocate libwine.dyld too
 944             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 945           fi
 946         fi
 947       fi
 948     fi
 949
 950     dnl Check for cross compiler to build test programs
 951     AC_SUBST(CROSSTEST,"")
 952     if test "$cross_compiling" = "no"
 953     then
 954       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 955       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 956       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 957       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 958     fi
 959     ;;
 960 esac
 961
 962 if test "$LIBEXT" = "a"; then
 963   AC_MSG_ERROR(
 964 [could not find a way to build shared libraries.
 965 It is currently not possible to build Wine without shared library
 966 (.so) support to allow transparent switch between .so and .dll files.
 967 If you are using Linux, you will need a newer binutils.]
 968 )
 969 fi
 970
 971 case $build_os in
 972   cygwin*|mingw32*)
 973     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 974   darwin*|macosx*)
 975     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 976   *)
 977     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 978 esac
 979
 980 dnl Mingw needs explicit msvcrt for linking libwine
 981 case $host_os in
 982   mingw32*)
 983     AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
 984 esac
 985
 986 case $host_os in
 987   linux*)
 988     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
 989     AC_SUBST(MAIN_BINARY,"wine-glibc")
 990     ;;
 991   darwin*)
 992     AC_SUBST(WINE_BINARIES,"wine-pthread")
 993     AC_SUBST(MAIN_BINARY,"wine-pthread")
 994     ;;
 995   *)
 996     AC_SUBST(WINE_BINARIES,"wine-kthread")
 997     AC_SUBST(MAIN_BINARY,"wine-kthread")
 998     ;;
 999 esac
1000
1001 dnl **** Get the soname for libraries that we load dynamically ****
1002
1003 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1004 then
1005   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1006   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1007   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1008   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1009   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1010   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1011   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1012   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1013   WINE_GET_SONAME(cups,cupsGetDefault)
1014   WINE_GET_SONAME(jack,jack_client_new)
1015   WINE_GET_SONAME(fontconfig,FcInit)
1016   WINE_GET_SONAME(ssl,SSL_library_init)
1017   WINE_GET_SONAME(crypto,BIO_new_socket)
1018   WINE_GET_SONAME(ncurses,waddch)
1019   WINE_GET_SONAME(curses,waddch)
1020   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1021   WINE_GET_SONAME(ungif,DGifOpen)
1022 fi
1023
1024
1025 dnl **** Check for functions ****
1026
1027 AC_FUNC_ALLOCA()
1028 AC_CHECK_FUNCS(\
1029         _lwp_create \
1030         _lwp_self \
1031         _pclose \
1032         _popen \
1033         _snprintf \
1034         _spawnvp \
1035         _stricmp \
1036         _strnicmp \
1037         _vsnprintf \
1038         chsize \
1039         clone \
1040         finite \
1041         fpclass \
1042         fstatfs \
1043         fstatvfs \
1044         ftruncate \
1045         ftruncate64 \
1046         futimes \
1047         getnetbyaddr \
1048         getnetbyname \
1049         getopt_long \
1050         getpagesize \
1051         getprotobyname \
1052         getprotobynumber \
1053         getpwuid \
1054         getservbyport \
1055         gettid \
1056         gettimeofday \
1057         inet_network \
1058         lseek64 \
1059         lstat \
1060         memmove \
1061         mmap \
1062         pclose \
1063         popen \
1064         pread \
1065         pwrite \
1066         readlink \
1067         rfork \
1068         select \
1069         sendmsg \
1070         settimeofday \
1071         sigaltstack \
1072         snprintf \
1073         spawnvp \
1074         statfs \
1075         statvfs \
1076         strcasecmp \
1077         strerror \
1078         strncasecmp \
1079         tcgetattr \
1080         timegm \
1081         usleep \
1082         vfscanf \
1083         vsnprintf \
1084         wait4 \
1085         waitpid \
1086 )
1087
1088 dnl **** Check for header files ****
1089
1090 AC_CHECK_HEADERS(\
1091         arpa/inet.h \
1092         arpa/nameser.h \
1093         cups/cups.h \
1094         direct.h \
1095         elf.h \
1096         float.h \
1097         fontconfig/fontconfig.h \
1098         getopt.h \
1099         gif_lib.h \
1100         ieeefp.h \
1101         io.h \
1102         jack/jack.h \
1103         jpeglib.h \
1104         libio.h \
1105         libutil.h \
1106         link.h \
1107         linux/cdrom.h \
1108         linux/hdreg.h \
1109         linux/input.h \
1110         linux/ioctl.h \
1111         linux/joystick.h \
1112         linux/major.h \
1113         linux/param.h \
1114         linux/serial.h \
1115         linux/ucdrom.h \
1116         machine/cpu.h \
1117         mntent.h \
1118         netdb.h \
1119         netinet/in.h \
1120         netinet/in_systm.h \
1121         netinet/tcp.h \
1122         netinet/tcp_fsm.h \
1123         openssl/ssl.h \
1124         process.h \
1125         pthread.h \
1126         pty.h \
1127         pwd.h \
1128         regex.h \
1129         sched.h \
1130         scsi/sg.h \
1131         scsi/scsi.h \
1132         scsi/scsi_ioctl.h \
1133         socket.h \
1134         stdint.h \
1135         strings.h \
1136         sys/cdio.h \
1137         sys/elf32.h \
1138         sys/errno.h \
1139         sys/exec_elf.h \
1140         sys/file.h \
1141         sys/filio.h \
1142         sys/inttypes.h \
1143         sys/ioctl.h \
1144         sys/ipc.h \
1145         sys/link.h \
1146         sys/lwp.h \
1147         sys/mman.h \
1148         sys/modem.h \
1149         sys/msg.h \
1150         sys/param.h \
1151         sys/poll.h \
1152         sys/ptrace.h \
1153         sys/reg.h \
1154         sys/scsiio.h \
1155         sys/shm.h \
1156         sys/signal.h \
1157         sys/socket.h \
1158         sys/sockio.h \
1159         sys/statfs.h \
1160         sys/statvfs.h \
1161         sys/strtio.h \
1162         sys/syscall.h \
1163         sys/sysctl.h \
1164         sys/time.h \
1165         sys/times.h \
1166         sys/uio.h \
1167         sys/un.h \
1168         sys/v86.h \
1169         sys/v86intr.h \
1170         sys/vfs.h \
1171         sys/vm86.h \
1172         sys/wait.h \
1173         syscall.h \
1174         termios.h \
1175         unistd.h \
1176         utime.h \
1177         valgrind/memcheck.h
1178 )
1179 AC_HEADER_STAT()
1180
1181 dnl **** Checks for headers that depend on other ones ****
1182
1183 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1184     [#include <sys/types.h>
1185      #if HAVE_SYS_PARAM_H
1186      # include <sys/param.h>
1187      #endif])
1188
1189 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1190     [#include <sys/types.h>
1191      #if HAVE_SYS_SOCKET_H
1192      # include <sys/socket.h>
1193      #endif])
1194
1195 AC_CHECK_HEADERS([resolv.h],,,
1196     [#include <sys/types.h>
1197      #if HAVE_SYS_SOCKET_H
1198      # include <sys/socket.h>
1199      #endif
1200      #if HAVE_NETINET_IN_H
1201      # include <netinet/in.h>
1202      #endif
1203      #if HAVE_ARPA_NAMESER_H
1204      # include <arpa/nameser.h>
1205      #endif])
1206
1207 AC_CHECK_HEADERS(netinet/ip.h,,,
1208     [#include <sys/types.h>
1209      #if HAVE_SYS_SOCKET_H
1210      # include <sys/socket.h>
1211      #endif
1212      #if HAVE_NETINET_IN_SYSTM_H
1213      # include <netinet/in_systm.h>
1214      #endif])
1215
1216 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1217
1218 dnl **** Check for IPX headers (currently Linux only) ****
1219
1220 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1221  AC_TRY_COMPILE(
1222    [#include <sys/types.h>
1223     #ifdef HAVE_SYS_SOCKET_H
1224     # include <sys/socket.h>
1225     #endif
1226     #include <netipx/ipx.h>],
1227    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1228    [ac_cv_c_ipx_gnu="yes"],
1229    [ac_cv_c_ipx_gnu="no"])
1230  )
1231 if test "$ac_cv_c_ipx_gnu" = "yes"
1232 then
1233     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1234 fi
1235
1236 if test "$ac_cv_c_ipx_gnu" = "no"
1237 then
1238  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1239   AC_TRY_COMPILE(
1240     [#include <sys/types.h>
1241      #ifdef HAVE_SYS_SOCKET_H
1242      # include <sys/socket.h>
1243      #endif
1244      #include <asm/types.h>
1245      #include <linux/ipx.h>],
1246     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1247     [ac_cv_c_ipx_linux="yes"],
1248     [ac_cv_c_ipx_linux="no"])
1249   )
1250   if test "$ac_cv_c_ipx_linux" = "yes"
1251   then
1252       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1253   fi
1254 fi
1255
1256 dnl **** Check for types ****
1257
1258 AC_C_CONST
1259 AC_C_INLINE
1260 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1261
1262 AC_CACHE_CHECK([whether linux/input.h is for real],
1263         wine_cv_linux_input_h,
1264         AC_TRY_COMPILE([
1265             #include <linux/input.h>
1266         ] , [
1267             int foo = EVIOCGBIT(EV_ABS,42);
1268             int bar = BTN_PINKIE;
1269             int fortytwo = 42;
1270         ],
1271         wine_cv_linux_input_h=yes,
1272         wine_cv_linux_input_h=no,
1273         no
1274         )
1275     )
1276     if test "$wine_cv_linux_input_h" = "yes"
1277     then
1278         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1279                   [Define if we have linux/input.h AND it contains the INPUT event API])
1280     fi
1281
1282
1283 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1284         wine_cv_linux_gethostbyname_r_6,
1285         AC_TRY_LINK([
1286 #include <netdb.h>
1287         ], [
1288     char *name=NULL;
1289     struct hostent he;
1290     struct hostent *result;
1291     char *buf=NULL;
1292     int bufsize=0;
1293     int res,errnr;
1294     char *addr=NULL;
1295     int addrlen=0;
1296     int addrtype=0;
1297     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1298     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1299     ],
1300         wine_cv_linux_gethostbyname_r_6=yes,
1301         wine_cv_linux_gethostbyname_r_6=no
1302         )
1303    )
1304    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1305    then
1306       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1307                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1308    fi
1309
1310 if test "$ac_cv_header_linux_joystick_h" = "yes"
1311 then
1312    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1313         wine_cv_linux_joystick_22_api,
1314         AC_TRY_COMPILE([
1315         #include <sys/ioctl.h>
1316         #include <linux/joystick.h>
1317
1318         struct js_event blub;
1319         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1320         #error "no 2.2 header"
1321         #endif
1322         ],/*empty*/,
1323         wine_cv_linux_joystick_22_api=yes,
1324         wine_cv_linux_joystick_22_api=no,
1325         wine_cv_linux_joystick_22_api=no
1326         )
1327    )
1328    if test "$wine_cv_linux_joystick_22_api" = "yes"
1329    then
1330       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1331                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1332    fi
1333 fi
1334
1335 dnl **** statfs checks ****
1336
1337 if test "$ac_cv_header_sys_vfs_h" = "yes"
1338 then
1339     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1340                     wine_cv_sys_vfs_has_statfs,
1341         AC_TRY_COMPILE([
1342         #include <sys/types.h>
1343         #ifdef HAVE_SYS_PARAM_H
1344         # include <sys/param.h>
1345         #endif
1346         #include <sys/vfs.h>
1347         ],[
1348                 struct statfs stfs;
1349
1350                 memset(&stfs,0,sizeof(stfs));
1351         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1352         )
1353     )
1354     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1355     then
1356       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1357                 [Define if the struct statfs is defined by <sys/vfs.h>])
1358     fi
1359 fi
1360
1361 if test "$ac_cv_header_sys_statfs_h" = "yes"
1362 then
1363     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1364                     wine_cv_sys_statfs_has_statfs,
1365         AC_TRY_COMPILE([
1366         #include <sys/types.h>
1367         #ifdef HAVE_SYS_PARAM_H
1368         # include <sys/param.h>
1369         #endif
1370         #include <sys/statfs.h>
1371         ],[
1372                 struct statfs stfs;
1373         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1374         )
1375     )
1376     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1377     then
1378       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1379                 [Define if the struct statfs is defined by <sys/statfs.h>])
1380     fi
1381 fi
1382
1383 if test "$ac_cv_header_sys_mount_h" = "yes"
1384 then
1385     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1386                     wine_cv_sys_mount_has_statfs,
1387         AC_TRY_COMPILE([
1388         #include <sys/types.h>
1389         #ifdef HAVE_SYS_PARAM_H
1390         # include <sys/param.h>
1391         #endif
1392         #include <sys/mount.h>
1393         ],[
1394                 struct statfs stfs;
1395         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1396         )
1397     )
1398     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1399     then
1400       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1401                 [Define if the struct statfs is defined by <sys/mount.h>])
1402     fi
1403 fi
1404
1405 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1406
1407 dnl Check for statfs members
1408 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1409 [#include <sys/types.h>
1410 #ifdef HAVE_SYS_PARAM_H
1411 # include <sys/param.h>
1412 #endif
1413 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1414 # include <sys/mount.h>
1415 #else
1416 # ifdef STATFS_DEFINED_BY_SYS_VFS
1417 #  include <sys/vfs.h>
1418 # else
1419 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1420 #   include <sys/statfs.h>
1421 #  endif
1422 # endif
1423 #endif])
1424
1425 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1426 [#ifdef HAVE_SYS_STATVFS_H
1427 #include <sys/statvfs.h>
1428 #endif])
1429
1430 dnl Check for socket structure members
1431 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1432 [#include <sys/types.h>
1433 #ifdef HAVE_SYS_SOCKET_H
1434 # include <sys/socket.h>
1435 #endif
1436 #ifdef HAVE_SYS_UN_H
1437 # include <sys/un.h>
1438 #endif])
1439
1440 dnl Check for siginfo_t members
1441 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1442
1443 dnl Check for struct option
1444 AC_CHECK_MEMBERS([struct option.name],,,
1445 [#ifdef HAVE_GETOPT_H
1446 #include <getopt.h>
1447 #endif])
1448
1449 dnl Check for stat.st_blocks
1450 AC_CHECK_MEMBERS([struct stat.st_blocks])
1451
1452 dnl *** check for the need to define platform-specific symbols
1453
1454 case $host_cpu in
1455   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1456   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1457   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1458   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1459 esac
1460
1461 case $host_vendor in
1462   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1463 esac
1464
1465 dnl **** Generate output files ****
1466
1467 AH_TOP([#define __WINE_CONFIG_H])
1468
1469 WINE_CONFIG_EXTRA_DIR(controls)
1470 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1471 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1472 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1473 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1474 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1475 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1476 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1477 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1478 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1479 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1480 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1481 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1482 WINE_CONFIG_EXTRA_DIR(include/wine)
1483 WINE_CONFIG_EXTRA_DIR(misc)
1484 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1485 WINE_CONFIG_EXTRA_DIR(windows)
1486
1487 MAKE_RULES=Make.rules
1488 AC_SUBST_FILE(MAKE_RULES)
1489
1490 MAKE_DLL_RULES=dlls/Makedll.rules
1491 AC_SUBST_FILE(MAKE_DLL_RULES)
1492
1493 MAKE_TEST_RULES=dlls/Maketest.rules
1494 AC_SUBST_FILE(MAKE_TEST_RULES)
1495
1496 MAKE_LIB_RULES=libs/Makelib.rules
1497 AC_SUBST_FILE(MAKE_LIB_RULES)
1498
1499 MAKE_PROG_RULES=programs/Makeprog.rules
1500 AC_SUBST_FILE(MAKE_PROG_RULES)
1501
1502 AC_CONFIG_FILES([
1503 Make.rules
1504 dlls/Makedll.rules
1505 dlls/Maketest.rules
1506 libs/Makelib.rules
1507 programs/Makeprog.rules
1508 Makefile
1509 dlls/Makefile
1510 dlls/advapi32/Makefile
1511 dlls/advapi32/tests/Makefile
1512 dlls/amstream/Makefile
1513 dlls/atl/Makefile
1514 dlls/avicap32/Makefile
1515 dlls/avifil32/Makefile
1516 dlls/cabinet/Makefile
1517 dlls/capi2032/Makefile
1518 dlls/cards/Makefile
1519 dlls/cfgmgr32/Makefile
1520 dlls/comcat/Makefile
1521 dlls/comctl32/Makefile
1522 dlls/comctl32/tests/Makefile
1523 dlls/commdlg/Makefile
1524 dlls/crtdll/Makefile
1525 dlls/crypt32/Makefile
1526 dlls/ctl3d/Makefile
1527 dlls/d3d8/Makefile
1528 dlls/d3d9/Makefile
1529 dlls/d3dim/Makefile
1530 dlls/d3drm/Makefile
1531 dlls/d3dx8/Makefile
1532 dlls/d3dxof/Makefile
1533 dlls/dbghelp/Makefile
1534 dlls/dciman32/Makefile
1535 dlls/ddraw/Makefile
1536 dlls/ddraw/tests/Makefile
1537 dlls/devenum/Makefile
1538 dlls/dinput/Makefile
1539 dlls/dinput8/Makefile
1540 dlls/dmband/Makefile
1541 dlls/dmcompos/Makefile
1542 dlls/dmime/Makefile
1543 dlls/dmloader/Makefile
1544 dlls/dmscript/Makefile
1545 dlls/dmstyle/Makefile
1546 dlls/dmsynth/Makefile
1547 dlls/dmusic/Makefile
1548 dlls/dmusic32/Makefile
1549 dlls/dplay/Makefile
1550 dlls/dplayx/Makefile
1551 dlls/dpnet/Makefile
1552 dlls/dpnhpast/Makefile
1553 dlls/dsound/Makefile
1554 dlls/dsound/tests/Makefile
1555 dlls/dswave/Makefile
1556 dlls/dxdiagn/Makefile
1557 dlls/dxerr8/Makefile
1558 dlls/dxerr9/Makefile
1559 dlls/dxguid/Makefile
1560 dlls/gdi/Makefile
1561 dlls/gdi/tests/Makefile
1562 dlls/glu32/Makefile
1563 dlls/glut32/Makefile
1564 dlls/hhctrl.ocx/Makefile
1565 dlls/iccvid/Makefile
1566 dlls/icmp/Makefile
1567 dlls/ifsmgr.vxd/Makefile
1568 dlls/imagehlp/Makefile
1569 dlls/imm32/Makefile
1570 dlls/iphlpapi/Makefile
1571 dlls/iphlpapi/tests/Makefile
1572 dlls/kernel/Makefile
1573 dlls/kernel/tests/Makefile
1574 dlls/lzexpand/Makefile
1575 dlls/mapi32/Makefile
1576 dlls/mapi32/tests/Makefile
1577 dlls/mlang/Makefile
1578 dlls/mlang/tests/Makefile
1579 dlls/mmdevldr.vxd/Makefile
1580 dlls/monodebg.vxd/Makefile
1581 dlls/mpr/Makefile
1582 dlls/msacm/Makefile
1583 dlls/msacm/imaadp32/Makefile
1584 dlls/msacm/msadp32/Makefile
1585 dlls/msacm/msg711/Makefile
1586 dlls/msacm/winemp3/Makefile
1587 dlls/msacm/tests/Makefile
1588 dlls/msdmo/Makefile
1589 dlls/mshtml/Makefile
1590 dlls/msi/Makefile
1591 dlls/msimg32/Makefile
1592 dlls/msisys/Makefile
1593 dlls/msnet32/Makefile
1594 dlls/msrle32/Makefile
1595 dlls/msvcrt/Makefile
1596 dlls/msvcrt/tests/Makefile
1597 dlls/msvcrt20/Makefile
1598 dlls/msvcrt40/Makefile
1599 dlls/msvcrtd/Makefile
1600 dlls/msvcrtd/tests/Makefile
1601 dlls/msvidc32/Makefile
1602 dlls/msvideo/Makefile
1603 dlls/mswsock/Makefile
1604 dlls/netapi32/Makefile
1605 dlls/netapi32/tests/Makefile
1606 dlls/newdev/Makefile
1607 dlls/ntdll/Makefile
1608 dlls/ntdll/tests/Makefile
1609 dlls/odbc32/Makefile
1610 dlls/ole32/Makefile
1611 dlls/ole32/tests/Makefile
1612 dlls/oleacc/Makefile
1613 dlls/oleaut32/Makefile
1614 dlls/oleaut32/tests/Makefile
1615 dlls/olecli/Makefile
1616 dlls/oledlg/Makefile
1617 dlls/olepro32/Makefile
1618 dlls/olesvr/Makefile
1619 dlls/opengl32/Makefile
1620 dlls/psapi/Makefile
1621 dlls/psapi/tests/Makefile
1622 dlls/qcap/Makefile
1623 dlls/quartz/Makefile
1624 dlls/rasapi32/Makefile
1625 dlls/richedit/Makefile
1626 dlls/rpcrt4/Makefile
1627 dlls/rpcrt4/tests/Makefile
1628 dlls/rsabase/Makefile
1629 dlls/rsabase/tests/Makefile
1630 dlls/secur32/Makefile
1631 dlls/serialui/Makefile
1632 dlls/setupapi/Makefile
1633 dlls/shdocvw/Makefile
1634 dlls/shell32/Makefile
1635 dlls/shell32/tests/Makefile
1636 dlls/shfolder/Makefile
1637 dlls/shlwapi/Makefile
1638 dlls/shlwapi/tests/Makefile
1639 dlls/snmpapi/Makefile
1640 dlls/sti/Makefile
1641 dlls/tapi32/Makefile
1642 dlls/ttydrv/Makefile
1643 dlls/twain/Makefile
1644 dlls/unicows/Makefile
1645 dlls/url/Makefile
1646 dlls/urlmon/Makefile
1647 dlls/urlmon/tests/Makefile
1648 dlls/user/Makefile
1649 dlls/user/tests/Makefile
1650 dlls/uuid/Makefile
1651 dlls/uxtheme/Makefile
1652 dlls/vdhcp.vxd/Makefile
1653 dlls/vdmdbg/Makefile
1654 dlls/version/Makefile
1655 dlls/version/tests/Makefile
1656 dlls/vmm.vxd/Makefile
1657 dlls/vnbt.vxd/Makefile
1658 dlls/vnetbios.vxd/Makefile
1659 dlls/vtdapi.vxd/Makefile
1660 dlls/vwin32.vxd/Makefile
1661 dlls/win32s/Makefile
1662 dlls/winaspi/Makefile
1663 dlls/wined3d/Makefile
1664 dlls/winedos/Makefile
1665 dlls/wineps/Makefile
1666 dlls/wininet/Makefile
1667 dlls/wininet/tests/Makefile
1668 dlls/winmm/Makefile
1669 dlls/winmm/joystick/Makefile
1670 dlls/winmm/mcianim/Makefile
1671 dlls/winmm/mciavi/Makefile
1672 dlls/winmm/mcicda/Makefile
1673 dlls/winmm/mciseq/Makefile
1674 dlls/winmm/mciwave/Makefile
1675 dlls/winmm/midimap/Makefile
1676 dlls/winmm/tests/Makefile
1677 dlls/winmm/wavemap/Makefile
1678 dlls/winmm/winealsa/Makefile
1679 dlls/winmm/winearts/Makefile
1680 dlls/winmm/wineaudioio/Makefile
1681 dlls/winmm/winejack/Makefile
1682 dlls/winmm/winenas/Makefile
1683 dlls/winmm/wineoss/Makefile
1684 dlls/winnls/Makefile
1685 dlls/winsock/Makefile
1686 dlls/winsock/tests/Makefile
1687 dlls/winspool/Makefile
1688 dlls/winspool/tests/Makefile
1689 dlls/wintab32/Makefile
1690 dlls/wintrust/Makefile
1691 dlls/wow32/Makefile
1692 dlls/wsock32/Makefile
1693 dlls/x11drv/Makefile
1694 documentation/Makefile
1695 include/Makefile
1696 libs/Makefile
1697 libs/port/Makefile
1698 libs/unicode/Makefile
1699 libs/wine/Makefile
1700 libs/wpp/Makefile
1701 loader/Makefile
1702 programs/Makefile
1703 programs/avitools/Makefile
1704 programs/clock/Makefile
1705 programs/cmdlgtst/Makefile
1706 programs/control/Makefile
1707 programs/expand/Makefile
1708 programs/msiexec/Makefile
1709 programs/notepad/Makefile
1710 programs/progman/Makefile
1711 programs/regedit/Makefile
1712 programs/regsvr32/Makefile
1713 programs/rpcss/Makefile
1714 programs/rundll32/Makefile
1715 programs/start/Makefile
1716 programs/taskmgr/Makefile
1717 programs/uninstaller/Makefile
1718 programs/view/Makefile
1719 programs/wcmd/Makefile
1720 programs/wineboot/Makefile
1721 programs/winebrowser/Makefile
1722 programs/winecfg/Makefile
1723 programs/wineconsole/Makefile
1724 programs/winedbg/Makefile
1725 programs/winefile/Makefile
1726 programs/winemenubuilder/Makefile
1727 programs/winemine/Makefile
1728 programs/winepath/Makefile
1729 programs/winetest/Makefile
1730 programs/winevdm/Makefile
1731 programs/winhelp/Makefile
1732 programs/winver/Makefile
1733 server/Makefile
1734 tools/Makefile
1735 tools/widl/Makefile
1736 tools/winapi/Makefile
1737 tools/winebuild/Makefile
1738 tools/winedump/Makefile
1739 tools/winegcc/Makefile
1740 tools/wmc/Makefile
1741 tools/wrc/Makefile])
1742
1743 AC_OUTPUT
1744
1745 if test "$have_x" = "no"
1746 then
1747   echo
1748   echo "*** Warning: X development files not found. Wine will be built without"
1749   echo "*** X support, which currently does not work, and would probably not be"
1750   echo "*** what you want anyway. You will need to install devel packages of"
1751   echo "*** Xlib/Xfree86 at the very least."
1752 fi
1753
1754 if test "$wine_cv_opengl_version_OK" = "no"
1755 then
1756   echo
1757   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1758   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1759 fi
1760
1761 if test "$wine_cv_msg_freetype" = "yes"
1762 then
1763   echo
1764   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1765   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1766   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1767   echo "*** enable Wine to use TrueType fonts."
1768 fi
1769
1770 echo
1771 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1772 echo
1773
1774 dnl Local Variables:
1775 dnl comment-start: "dnl "
1776 dnl comment-end: ""
1777 dnl comment-start-skip: "\\bdnl\\b\\s *"
1778 dnl compile-command: "autoconf"
1779 dnl End: