git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  47
  48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  49   [if test -z "$with_wine_tools"; then
  50      if test "$cross_compiling" = "yes"; then
  51        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  52      else
  53        wine_cv_toolsdir="\$(TOPOBJDIR)"
  54      fi
  55    elif test -d "$with_wine_tools/tools/winebuild"; then
  56      case $with_wine_tools in
  57        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  58        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  59      esac
  60    else
  61      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  62    fi])
  63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  64
  65 AC_PATH_XTRA
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  71 if test "$XLEX" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  74 fi
  75
  76 dnl Check for bison
  77 AC_CHECK_PROGS(BISON,bison,none)
  78 if test "$BISON" = "none"
  79 then
  80   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  81 fi
  82
  83 AC_CHECK_TOOLS(AS,[gas as],as)
  84 AC_CHECK_TOOL(LD,ld,ld)
  85 AC_CHECK_TOOL(AR,ar,ar)
  86 AC_PROG_RANLIB
  87 AC_CHECK_TOOL(STRIP,strip,strip)
  88 AC_CHECK_TOOL(WINDRES,windres,false)
  89 AC_PROG_LN_S
  90 WINE_PROG_LN
  91 AC_PROG_EGREP
  92 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  93 AC_PROG_INSTALL
  94 dnl Prepend src dir to install path dir if it's a relative path
  95 case "$INSTALL" in
  96   [[\\/$]]* | ?:[[\\/]]* ) ;;
  97   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  98 esac
  99
 100 dnl Check for lint
 101 AC_CHECK_PROGS(LINT, lclint lint)
 102 if test "$LINT" = "lint"
 103 then
 104   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 105   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 106 fi
 107 AC_SUBST(LINT)
 108 AC_SUBST(LINTFLAGS)
 109
 110 dnl Check for various programs
 111 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 112 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 113 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 114 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 115 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 116
 117 dnl **** Check for some libraries ****
 118
 119 dnl Check for -li386 for NetBSD and OpenBSD
 120 AC_CHECK_LIB(i386,i386_set_ldt)
 121 dnl Check for -lossaudio for NetBSD
 122 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 123 dnl Check for -lw for Solaris
 124 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 125 dnl Check for -lnsl for Solaris
 126 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 127 dnl Check for -lsocket for Solaris
 128 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 129 dnl Check for -lresolv for Solaris
 130 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 131 dnl Check for -lxpg4 for FreeBSD
 132 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 133 dnl Check for -lpoll for Mac OS X/Darwin
 134 AC_CHECK_LIB(poll,poll)
 135 dnl Check for -lresolv for Mac OS X/Darwin
 136 AC_CHECK_LIB(resolv,res_9_init)
 137 dnl Check for -lpthread
 138 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 139
 140 AC_SUBST(XLIB)
 141 AC_SUBST(XFILES)
 142 XFILES=""
 143 AC_SUBST(OPENGLFILES)
 144 OPENGLFILES=""
 145 AC_SUBST(GLU32FILES)
 146 GLU32FILES=""
 147 AC_SUBST(OPENGL_LIBS)
 148 OPENGL_LIBS=""
 149 if test "$have_x" = "yes"
 150 then
 151     XLIB="-lXext -lX11"
 152     ac_save_CPPFLAGS="$CPPFLAGS"
 153     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 154
 155     dnl *** All of the following tests require X11/Xlib.h
 156     AC_CHECK_HEADERS(X11/Xlib.h,
 157       [
 158         AC_CHECK_HEADERS([X11/XKBlib.h \
 159                           X11/Xutil.h \
 160                           X11/extensions/shape.h \
 161                           X11/extensions/XInput.h \
 162                           X11/extensions/XShm.h \
 163                           X11/extensions/Xrandr.h \
 164                           X11/extensions/Xrender.h \
 165                           X11/extensions/Xvlib.h \
 166                           X11/extensions/xf86dga.h \
 167                           X11/extensions/xf86vmode.h],,,
 168                          [#include <X11/Xlib.h>
 169                           #ifdef HAVE_X11_XUTIL_H
 170                           # include <X11/Xutil.h>
 171                           #endif])
 172
 173         dnl *** Check for X keyboard extension
 174         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 175         then
 176               AC_CHECK_LIB(X11, XkbQueryExtension,
 177               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 178               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 179         fi
 180
 181         dnl *** Check for X Shm extension
 182         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 183         then
 184               AC_CHECK_LIB(Xext, XShmQueryExtension,
 185               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 186               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 187         fi
 188
 189         dnl *** Check for X shape extension
 190         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 191         then
 192               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 193               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 194               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 195         fi
 196
 197         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 198         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 199         then
 200               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 201                 [ dnl *** If found...
 202                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 203                             [Define if you have the Xxf86dga library version 2])
 204                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 205                ],
 206                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 207                   dnl *** instead (DGA 2.0 not found)...
 208                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 209                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 210                                 [Define if you have the Xxf86dga library version 1])
 211                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 212                     ],,
 213                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 214                   )
 215                 ],
 216                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 217         fi
 218
 219         dnl *** Check for XFree86 VMODE extension
 220         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 221         then
 222                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 223                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 224                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 225                   ],,
 226                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 227         fi
 228
 229         dnl *** Check for X RandR extension
 230         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 231         then
 232                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 233 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 234                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 235         fi
 236
 237         dnl *** Check for XVideo extension supporting XvImages
 238         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 239         then
 240                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 241                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 242                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 243                   ],,
 244                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 245         fi
 246       ]
 247     ) dnl *** End of X11/Xlib.h check
 248
 249     dnl Check for the presence of OpenGL
 250     if test "x$with_opengl" != "xno"
 251     then
 252         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 253         then
 254             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 255 This prevents linking to OpenGL. Delete the file and restart configure.])
 256         fi
 257
 258         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 259         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 260         then
 261             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 262             dnl Check for some problems due to old Mesa versions
 263             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 264               AC_TRY_COMPILE(
 265                 [#include <GL/gl.h>],
 266                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 267                 [wine_cv_opengl_version_OK="yes"],
 268                 [wine_cv_opengl_version_OK="no"]
 269               )
 270             )
 271
 272             if test "$wine_cv_opengl_version_OK" = "yes"
 273             then
 274                 dnl Check for the presence of the library
 275                 AC_CHECK_LIB(GL,glXCreateContext,
 276                              OPENGL_LIBS="-lGL"
 277                              ,,
 278                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 279
 280                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 281                 then
 282                         OPENGLFILES='$(OPENGLFILES)'
 283                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 284
 285                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 286                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 287                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 288                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 289
 290                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 291                         then
 292                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 293                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 294                                                   #ifdef HAVE_GL_GLEXT_H
 295                                                   # include <GL/glext.h>
 296                                                   #endif
 297                                                   ],
 298                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 299                                                  [wine_cv_extension_prototypes="yes"],
 300                                                  [wine_cv_extension_prototypes="no"]
 301                                   )]
 302                                 )
 303                                 if test "$wine_cv_extension_prototypes" = "yes"
 304                                 then
 305                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 306                                               [Define if the OpenGL headers define extension typedefs])
 307                                 fi
 308                         fi
 309
 310                 fi
 311                 dnl Check for GLU32 library.
 312                 AC_CHECK_LIB(GLU,gluLookAt,
 313                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 314                              GLU32FILES='$(GLU32FILES)']
 315                              ,,
 316                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 317                 )
 318              fi
 319
 320              dnl Check for glut32 library.
 321              AC_CHECK_LIB(glut,glutMainLoop,
 322                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 323                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 324                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 325          fi
 326     fi
 327
 328     dnl **** Check for NAS ****
 329     AC_SUBST(NASLIBS,"")
 330     AC_CHECK_HEADERS(audio/audiolib.h,
 331          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 332           AC_CHECK_LIB(audio,AuCreateFlow,
 333                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 334                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 335                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 336
 337     CPPFLAGS="$ac_save_CPPFLAGS"
 338     XFILES='$(XFILES)'
 339 else
 340     XLIB=""
 341     X_CFLAGS=""
 342     X_LIBS=""
 343 fi
 344
 345 dnl **** Check which curses lib to use ***
 346 CURSESLIBS=""
 347 if test "x$with_curses" != "xno"
 348 then
 349     AC_CHECK_HEADERS(ncurses.h,
 350         [AC_CHECK_LIB(ncurses,waddch,
 351             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 352              CURSESLIBS="-lncurses"],
 353              [AC_CHECK_HEADERS(curses.h,
 354                  [AC_CHECK_LIB(curses,waddch,
 355                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 356                       CURSESLIBS="-lcurses"])])])])
 357     saved_libs="$LIBS"
 358     LIBS="$CURSESLIBS $LIBS"
 359     AC_CHECK_FUNCS(getbkgd resizeterm)
 360     LIBS="$saved_libs"
 361 fi
 362 AC_SUBST(CURSESLIBS)
 363
 364 dnl **** Check for SANE ****
 365 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 366 if test "$sane_devel" = "no"
 367 then
 368     SANELIBS=""
 369     SANEINCL=""
 370 else
 371     SANELIBS="`$sane_devel --libs`"
 372     SANEINCL="`$sane_devel --cflags`"
 373     ac_save_CPPFLAGS="$CPPFLAGS"
 374     ac_save_LIBS="$LIBS"
 375     CPPFLAGS="$CPPFLAGS $SANEINCL"
 376     LIBS="$LIBS $SANELIBS"
 377     AC_CHECK_HEADER(sane/sane.h,
 378                     [AC_CHECK_LIB(sane,sane_open,
 379                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 380                                   [SANELIBS=""
 381                                   SANEINCL=""])],
 382                     [SANELIBS=""
 383                     SANEINCL=""])
 384     LIBS="$ac_save_LIBS"
 385     CPPFLAGS="$ac_save_CPPFLAGS"
 386 fi
 387 AC_SUBST(SANELIBS)
 388 AC_SUBST(SANEINCL)
 389
 390 dnl **** Check for the ICU library ****
 391 AC_CHECK_HEADERS(unicode/ubidi.h)
 392 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 393 then
 394     saved_libs="$LIBS"
 395     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 396     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 397     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 398     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 399     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 400     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 401                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 402                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 403                  AC_MSG_RESULT(yes)],
 404                 [AC_MSG_RESULT(no)])
 405     LIBS="$saved_libs"
 406 fi
 407
 408 dnl **** Check for FreeType 2 ****
 409 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 410 if test "$ft_lib" = "no"
 411 then
 412     FREETYPELIBS=""
 413     FREETYPEINCL=""
 414     wine_cv_msg_freetype=no
 415 else
 416     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 417     if test "$ft_devel" = "no"
 418     then
 419         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 420         if test "$ft_devel2" = "freetype2-config"
 421         then
 422                 ft_devel=$ft_devel2
 423         fi
 424     fi
 425     if test "$ft_devel" = "no"
 426     then
 427         FREETYPELIBS=""
 428         FREETYPEINCL=""
 429         wine_cv_msg_freetype=yes
 430     else
 431         FREETYPELIBS=`$ft_devel --libs`
 432         FREETYPEINCL=`$ft_devel --cflags`
 433         ac_save_CPPFLAGS="$CPPFLAGS"
 434         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 435         AC_CHECK_HEADERS(ft2build.h \
 436                          freetype/freetype.h \
 437                          freetype/ftglyph.h \
 438                          freetype/tttables.h \
 439                          freetype/ftnames.h \
 440                          freetype/ftsnames.h \
 441                          freetype/ttnameid.h \
 442                          freetype/ftoutln.h \
 443                          freetype/ftwinfnt.h \
 444                          freetype/internal/sfnt.h,,,
 445                          [#if HAVE_FT2BUILD_H
 446                           #include <ft2build.h>
 447                           #endif])
 448         AC_TRY_CPP([#include <ft2build.h>
 449                     #include <freetype/fttrigon.h>],
 450                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 451           [Define if you have the <freetype/fttrigon.h> header file.])
 452                     wine_cv_fttrigon=yes],
 453                     wine_cv_fttrigon=no)
 454         CPPFLAGS="$ac_save_CPPFLAGS"
 455         dnl Check that we have at least freetype/freetype.h
 456         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 457         then
 458             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 459             wine_cv_msg_freetype=no
 460         else
 461             FREETYPELIBS=""
 462             FREETYPEINCL=""
 463             wine_cv_msg_freetype=yes
 464         fi
 465     fi
 466 fi
 467 AC_SUBST(FREETYPELIBS)
 468 AC_SUBST(FREETYPEINCL)
 469
 470 dnl Only build the fonts dir if we have both freetype and fontforge
 471 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 472 then
 473   AC_SUBST(FONTSSUBDIRS,"fonts")
 474 fi
 475
 476 dnl **** Check for parport (currently Linux only) ****
 477 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 478  AC_TRY_COMPILE(
 479    [#include <linux/ppdev.h>],
 480    [ioctl (1,PPCLAIM,0)],
 481    [ac_cv_c_ppdev="yes"],
 482    [ac_cv_c_ppdev="no"])
 483  )
 484 if test "$ac_cv_c_ppdev" = "yes"
 485 then
 486     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 487 fi
 488
 489 dnl **** Check for va_copy ****
 490 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 491  AC_TRY_LINK(
 492    [#include <stdarg.h>],
 493    [va_list ap1, ap2;
 494     va_copy(ap1,ap2);
 495    ],
 496    [ac_cv_c_va_copy="yes"],
 497    [ac_cv_c_va_copy="no"])
 498  )
 499 if test "$ac_cv_c_va_copy" = "yes"
 500 then
 501     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 502 fi
 503 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 504  AC_TRY_LINK(
 505    [#include <stdarg.h>],
 506    [va_list ap1, ap2;
 507     __va_copy(ap1,ap2);
 508    ],
 509    [ac_cv_c___va_copy="yes"],
 510    [ac_cv_c___va_copy="no"])
 511  )
 512 if test "$ac_cv_c___va_copy" = "yes"
 513 then
 514     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 515 fi
 516
 517 dnl **** Check for sigsetjmp ****
 518 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 519  AC_TRY_LINK(
 520    [#include <setjmp.h>],
 521    [sigjmp_buf buf;
 522     sigsetjmp( buf, 1 );
 523     siglongjmp( buf, 1 );],
 524    [ac_cv_c_sigsetjmp="yes"],
 525    [ac_cv_c_sigsetjmp="no"])
 526  )
 527 if test "$ac_cv_c_sigsetjmp" = "yes"
 528 then
 529     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 530 fi
 531
 532 dnl **** Check for pthread_rwlock_t ****
 533 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 534 #include <pthread.h>])
 535
 536 dnl **** Check for pthread functions ****
 537 ac_save_LIBS="$LIBS"
 538 LIBS="$LIBS $LIBPTHREAD"
 539 AC_CHECK_FUNCS(\
 540         pthread_getattr_np \
 541         pthread_get_stackaddr_np \
 542         pthread_get_stacksize_np \
 543 )
 544 LIBS="$ac_save_LIBS"
 545
 546 dnl **** Check for Open Sound System ****
 547 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 548
 549 AC_CACHE_CHECK([for Open Sound System],
 550         ac_cv_c_opensoundsystem,
 551         AC_TRY_COMPILE([
 552         #if defined(HAVE_SYS_SOUNDCARD_H)
 553                 #include <sys/soundcard.h>
 554         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 555                 #include <machine/soundcard.h>
 556         #elif defined(HAVE_SOUNDCARD_H)
 557                 #include <soundcard.h>
 558         #endif
 559         ],[
 560
 561 /* check for one of the Open Sound System specific SNDCTL_ defines */
 562 #if !defined(SNDCTL_DSP_STEREO)
 563 #error No open sound system
 564 #endif
 565 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 566
 567 if test "$ac_cv_c_opensoundsystem" = "yes"
 568 then
 569     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 570 fi
 571
 572 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 573         ac_cv_c_opensoundsystem_midi,
 574         AC_TRY_COMPILE([
 575         #if defined(HAVE_SYS_SOUNDCARD_H)
 576                 #include <sys/soundcard.h>
 577         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 578                 #include <machine/soundcard.h>
 579         #elif defined(HAVE_SOUNDCARD_H)
 580                 #include <soundcard.h>
 581         #endif
 582         ],[
 583
 584 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 585 #if !defined(SNDCTL_SEQ_SYNC)
 586 #error No open sound system MIDI interface
 587 #endif
 588 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 589
 590 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 591 then
 592     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 593 fi
 594
 595 dnl **** Check for aRts Sound Server ****
 596 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 597 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 598 then
 599     ARTSC_CFLAGS=""
 600     for i in `$ARTSCCONFIG --cflags`
 601     do
 602       case "$i" in
 603         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 604       esac
 605     done
 606     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 607     save_CFLAGS="$CFLAGS"
 608     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 609     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 610         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 611          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 612          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 613     CFLAGS="$save_CFLAGS"
 614 fi
 615
 616 dnl **** Check for ALSA ****
 617 AC_SUBST(ALSALIBS,"")
 618 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 619 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 620 then
 621     AC_CHECK_LIB(asound,snd_pcm_open,
 622         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 623         ALSALIBS="-lasound")
 624 fi
 625
 626 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 627
 628 AC_SUBST(AUDIOIOLIBS,"")
 629 AC_CHECK_HEADERS(libaudioio.h,
 630     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 631                   [AUDIOIOLIBS="-laudioio"
 632                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 633
 634 dnl **** Check for capi4linux ****
 635
 636 AC_CHECK_HEADERS(capi20.h,[
 637         AC_CHECK_HEADERS(linux/capi.h,[
 638                 AC_CHECK_LIB(capi20,capi20_register,[
 639                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 640                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 641                 ])
 642         ])
 643 ])
 644
 645 dnl **** Check for broken glibc mmap64 ****
 646
 647 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 648         AC_TRY_RUN([
 649                 #define _FILE_OFFSET_BITS 64
 650                 #include <stdio.h>
 651                 #include <unistd.h>
 652                 #include <fcntl.h>
 653                 #include <sys/mman.h>
 654                 #include <errno.h>
 655
 656                 int main(int argc,char **argv) {
 657                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 658                         if (fd == -1) exit(1);
 659
 660                         unlink("conftest.map");
 661
 662                         write(fd,"test",4);
 663
 664                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 665                             (errno == EINVAL)
 666                         ) {
 667                                 exit(1);
 668                         }
 669                         close(fd);
 670                         fprintf(stderr,"success!\n");
 671                         exit(0);
 672                 }
 673
 674         ],
 675     ac_cv_mmap64_works="yes",
 676     ac_cv_mmap64_works="no",
 677     ac_cv_mmap64_works="no") )
 678
 679 if test "$ac_cv_mmap64_works" = "yes"
 680 then
 681     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 682 fi
 683
 684 dnl **** Check for gcc specific options ****
 685
 686 AC_SUBST(EXTRACFLAGS,"")
 687 if test "x${GCC}" = "xyes"
 688 then
 689   EXTRACFLAGS="-Wall -pipe"
 690
 691   dnl Check for strength-reduce bug
 692   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 693                   AC_TRY_RUN([
 694 int     L[[4]] = {0,1,2,3};
 695 int main(void) {
 696   static int Array[[3]];
 697   unsigned int B = 3;
 698   int i;
 699   for(i=0; i<B; i++) Array[[i]] = i - 3;
 700   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 701   L[[i]] = 4;
 702
 703   exit( Array[[1]] != -2 || L[[2]] != 3);
 704 }],
 705     ac_cv_c_gcc_strength_bug="no",
 706     ac_cv_c_gcc_strength_bug="yes",
 707     ac_cv_c_gcc_strength_bug="yes") )
 708   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 709   then
 710     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 711   fi
 712
 713   dnl Check for -fshort-wchar
 714   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 715       [WINE_TRY_CFLAGS([-fshort-wchar],
 716                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 717   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 718   then
 719       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 720   fi
 721
 722   dnl Check for -mpreferred-stack-boundary
 723   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 724       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 725                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 726   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 727   then
 728     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 729   fi
 730
 731   dnl Check for -fno-strict-aliasing
 732   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 733       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 734                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 735   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 736   then
 737     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 738   fi
 739
 740   dnl Check for -gstabs+ option
 741   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 742       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 743   if test "$ac_cv_c_gcc_gstabs" = "yes"
 744   then
 745     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 746   fi
 747
 748   dnl Check for noisy string.h
 749   saved_CFLAGS="$CFLAGS"
 750   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 751   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 752       AC_TRY_COMPILE([#include <string.h>],[],
 753                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 754   CFLAGS="$saved_CFLAGS"
 755   if test "$ac_cv_c_string_h_warnings" = "no"
 756   then
 757     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 758   fi
 759 fi
 760
 761 dnl **** Check how to define a function in assembly code ****
 762
 763 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 764   WINE_TRY_ASM_LINK(
 765       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 766       ac_cv_asm_func_def=".def",
 767     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 768       ac_cv_asm_func_def=".type @function",
 769     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 770       ac_cv_asm_func_def=".type 2",
 771       ac_cv_asm_func_def="unknown")])]))
 772
 773 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 774 case "$ac_cv_asm_func_def" in
 775   ".def")
 776      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 777   ".type @function")
 778      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 779   ".type 2")
 780      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 781   *)
 782      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 783 esac
 784
 785 dnl **** Check for underscore on external symbols ****
 786
 787 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 788     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 789                       [extern int ac_test;],
 790                       [if (ac_test) return 1],
 791                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 792
 793 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 794 if test "$ac_cv_c_extern_prefix" = "yes"
 795 then
 796   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 797 else
 798   AC_DEFINE([__ASM_NAME(name)], [name])
 799 fi
 800
 801 dnl **** Check how to do strings in assembler ****
 802
 803 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 804     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 805       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 806         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 807           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 808
 809 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 810                    [Define to the assembler keyword used to specify an ASCII string])
 811
 812 dnl **** Check for .short in assembler ****
 813
 814 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 815     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 816       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 817         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 818
 819 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 820                    [Define to the assembler keyword used to specify a word value])
 821
 822 dnl **** Check for .size in assembler ****
 823
 824 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 825     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 826                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 827
 828 if test "$ac_cv_c_asm_size" = "yes"
 829 then
 830   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 831 fi
 832
 833 dnl **** Check for working dll ****
 834
 835 AC_SUBST(DLLEXT,"")
 836 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 837 AC_SUBST(DLLIBS,"")
 838 AC_SUBST(LDSHARED,"")
 839 AC_SUBST(LDDLLFLAGS,"")
 840 AC_SUBST(LIBEXT,"so")
 841 AC_SUBST(IMPLIBEXT,"def")
 842
 843 case $host_os in
 844   cygwin*|mingw32*)
 845     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 846     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 847     if test "$DLLWRAP" = "false"; then
 848       LIBEXT="a"
 849     else
 850       dnl FIXME - check whether dllwrap works correctly...
 851       LIBEXT="dll"
 852     fi
 853     IMPLIBEXT="a"
 854     dnl We can't build 16-bit NE dlls
 855     WIN16_FILES=""
 856     WIN16_INSTALL=""
 857     ;;
 858   *)
 859     AC_CHECK_HEADERS(dlfcn.h,
 860         [AC_CHECK_FUNCS(dlopen,,
 861             [AC_CHECK_LIB(dl,dlopen,
 862                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 863                           DLLIBS="-ldl"],
 864                          [LIBEXT="a"])])],
 865         [LIBEXT="a"])
 866
 867     if test "$LIBEXT" = "so"
 868     then
 869       DLLFLAGS="$DLLFLAGS -fPIC"
 870       DLLEXT=".so"
 871       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 872           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 873                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 874       if test "$ac_cv_c_dll_gnuelf" = "yes"
 875       then
 876         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 877         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 878         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 879           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 880                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 881         if test "$ac_cv_c_dll_zdefs" = "yes"
 882         then
 883           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 884         fi
 885
 886         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 887           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 888                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 889         if test "$ac_cv_c_dll_init_fini" = "yes"
 890         then
 891           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 892         fi
 893
 894         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 895           [echo '{ global: *; };' >conftest.map
 896            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 897                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 898            rm -f conftest.map])
 899         if test "$ac_cv_c_ld_version_scripts" = "yes"
 900         then
 901           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 902         fi
 903
 904         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 905           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 906                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 907         if test "$ac_cv_c_export_dynamic" = "yes"
 908         then
 909           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 910         fi
 911
 912         case $host_cpu in
 913           *i[[3456789]]86*)
 914             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 915               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 916                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 917             if test "$ac_cv_ld_reloc_exec" = "yes"
 918             then
 919               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 920             fi
 921             ;;
 922         esac
 923
 924       else
 925         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 926             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 927                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 928         if test "$ac_cv_c_dll_unixware" = "yes"
 929         then
 930           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 931           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 932
 933         else
 934           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 935             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 936           if test "$ac_cv_c_dll_macho" = "yes"
 937           then
 938             LIBEXT="dylib"
 939             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 940             LDSHARED="\$(CC) -dynamiclib"
 941             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 942             STRIP="$STRIP -u -r"
 943             dnl Relocate wine executable
 944             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 945             dnl Relocate libwine.dyld too
 946             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 947             dnl declare needed frameworks
 948             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 949             AC_SUBST(IOKITLIB,"-framework IOKit")
 950             dnl using IOKit imply we use CoreFoundation too
 951             IOKITLIB = "$IOKITLIB $COREFOUNDATIONLIB"
 952           fi
 953         fi
 954       fi
 955     fi
 956
 957     dnl Check for cross compiler to build test programs
 958     AC_SUBST(CROSSTEST,"")
 959     if test "$cross_compiling" = "no"
 960     then
 961       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 962       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 963       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 964       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 965     fi
 966     ;;
 967 esac
 968
 969 if test "$LIBEXT" = "a"; then
 970   AC_MSG_ERROR(
 971 [could not find a way to build shared libraries.
 972 It is currently not possible to build Wine without shared library
 973 (.so) support to allow transparent switch between .so and .dll files.
 974 If you are using Linux, you will need a newer binutils.]
 975 )
 976 fi
 977
 978 case $build_os in
 979   cygwin*|mingw32*)
 980     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 981   darwin*|macosx*)
 982     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 983   *)
 984     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 985 esac
 986
 987 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
 988 case $host_os in
 989   mingw32*)
 990     AC_SUBST(CRTLIBS,"-lmsvcrt")
 991     AC_SUBST(SOCKETLIBS,"-lws2_32")
 992     ;;
 993 esac
 994
 995 case $host_os in
 996   linux*)
 997     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
 998     AC_SUBST(MAIN_BINARY,"wine-glibc")
 999     ;;
1000   darwin*)
1001     AC_SUBST(WINE_BINARIES,"wine-pthread")
1002     AC_SUBST(MAIN_BINARY,"wine-pthread")
1003     ;;
1004   *)
1005     AC_SUBST(WINE_BINARIES,"wine-kthread")
1006     AC_SUBST(MAIN_BINARY,"wine-kthread")
1007     ;;
1008 esac
1009
1010 dnl **** Get the soname for libraries that we load dynamically ****
1011
1012 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1013 then
1014   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1015   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1016   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1017   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1018   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1019   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1020   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1021   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1022   WINE_GET_SONAME(cups,cupsGetDefault)
1023   WINE_GET_SONAME(jack,jack_client_new)
1024   WINE_GET_SONAME(fontconfig,FcInit)
1025   WINE_GET_SONAME(ssl,SSL_library_init)
1026   WINE_GET_SONAME(crypto,BIO_new_socket)
1027   WINE_GET_SONAME(ncurses,waddch)
1028   WINE_GET_SONAME(curses,waddch)
1029   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1030   WINE_GET_SONAME(ungif,DGifOpen)
1031 fi
1032
1033
1034 dnl **** Check for functions ****
1035
1036 AC_FUNC_ALLOCA()
1037 AC_CHECK_FUNCS(\
1038         _lwp_create \
1039         _lwp_self \
1040         _pclose \
1041         _popen \
1042         _snprintf \
1043         _spawnvp \
1044         _stricmp \
1045         _strnicmp \
1046         _vsnprintf \
1047         chsize \
1048         clone \
1049         finite \
1050         fpclass \
1051         fstatfs \
1052         fstatvfs \
1053         ftruncate \
1054         ftruncate64 \
1055         futimes \
1056         getnetbyaddr \
1057         getnetbyname \
1058         getopt_long \
1059         getpagesize \
1060         getprotobyname \
1061         getprotobynumber \
1062         getpwuid \
1063         getservbyport \
1064         gettid \
1065         gettimeofday \
1066         inet_network \
1067         lseek64 \
1068         lstat \
1069         memmove \
1070         mmap \
1071         pclose \
1072         popen \
1073         pread \
1074         pwrite \
1075         readlink \
1076         rfork \
1077         select \
1078         sendmsg \
1079         settimeofday \
1080         sigaltstack \
1081         snprintf \
1082         spawnvp \
1083         statfs \
1084         statvfs \
1085         strcasecmp \
1086         strerror \
1087         strncasecmp \
1088         tcgetattr \
1089         timegm \
1090         usleep \
1091         vfscanf \
1092         vsnprintf \
1093         wait4 \
1094         waitpid \
1095 )
1096
1097 dnl **** Check for header files ****
1098
1099 AC_CHECK_HEADERS(\
1100         arpa/inet.h \
1101         arpa/nameser.h \
1102         cups/cups.h \
1103         direct.h \
1104         elf.h \
1105         float.h \
1106         fontconfig/fontconfig.h \
1107         getopt.h \
1108         gif_lib.h \
1109         ieeefp.h \
1110         io.h \
1111         jack/jack.h \
1112         jpeglib.h \
1113         libio.h \
1114         libutil.h \
1115         link.h \
1116         linux/cdrom.h \
1117         linux/hdreg.h \
1118         linux/input.h \
1119         linux/ioctl.h \
1120         linux/joystick.h \
1121         linux/major.h \
1122         linux/param.h \
1123         linux/serial.h \
1124         linux/ucdrom.h \
1125         machine/cpu.h \
1126         mntent.h \
1127         netdb.h \
1128         netinet/in.h \
1129         netinet/in_systm.h \
1130         netinet/tcp.h \
1131         netinet/tcp_fsm.h \
1132         openssl/ssl.h \
1133         process.h \
1134         pthread.h \
1135         pty.h \
1136         pwd.h \
1137         regex.h \
1138         sched.h \
1139         scsi/sg.h \
1140         scsi/scsi.h \
1141         scsi/scsi_ioctl.h \
1142         socket.h \
1143         stdint.h \
1144         strings.h \
1145         sys/cdio.h \
1146         sys/elf32.h \
1147         sys/errno.h \
1148         sys/exec_elf.h \
1149         sys/file.h \
1150         sys/filio.h \
1151         sys/inttypes.h \
1152         sys/ioctl.h \
1153         sys/ipc.h \
1154         sys/link.h \
1155         sys/lwp.h \
1156         sys/mman.h \
1157         sys/modem.h \
1158         sys/msg.h \
1159         sys/param.h \
1160         sys/poll.h \
1161         sys/ptrace.h \
1162         sys/reg.h \
1163         sys/scsiio.h \
1164         sys/shm.h \
1165         sys/signal.h \
1166         sys/socket.h \
1167         sys/sockio.h \
1168         sys/statfs.h \
1169         sys/statvfs.h \
1170         sys/strtio.h \
1171         sys/syscall.h \
1172         sys/sysctl.h \
1173         sys/time.h \
1174         sys/times.h \
1175         sys/uio.h \
1176         sys/un.h \
1177         sys/v86.h \
1178         sys/v86intr.h \
1179         sys/vfs.h \
1180         sys/vm86.h \
1181         sys/wait.h \
1182         syscall.h \
1183         termios.h \
1184         unistd.h \
1185         utime.h \
1186         valgrind/memcheck.h
1187 )
1188 AC_HEADER_STAT()
1189
1190 dnl **** Checks for headers that depend on other ones ****
1191
1192 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1193     [#include <sys/types.h>
1194      #if HAVE_SYS_PARAM_H
1195      # include <sys/param.h>
1196      #endif])
1197
1198 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1199     [#include <sys/types.h>
1200      #if HAVE_SYS_SOCKET_H
1201      # include <sys/socket.h>
1202      #endif])
1203
1204 AC_CHECK_HEADERS([resolv.h],,,
1205     [#include <sys/types.h>
1206      #if HAVE_SYS_SOCKET_H
1207      # include <sys/socket.h>
1208      #endif
1209      #if HAVE_NETINET_IN_H
1210      # include <netinet/in.h>
1211      #endif
1212      #if HAVE_ARPA_NAMESER_H
1213      # include <arpa/nameser.h>
1214      #endif])
1215
1216 AC_CHECK_HEADERS(netinet/ip.h,,,
1217     [#include <sys/types.h>
1218      #if HAVE_SYS_SOCKET_H
1219      # include <sys/socket.h>
1220      #endif
1221      #if HAVE_NETINET_IN_SYSTM_H
1222      # include <netinet/in_systm.h>
1223      #endif])
1224
1225 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1226
1227 dnl **** Check for IPX headers (currently Linux only) ****
1228
1229 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1230  AC_TRY_COMPILE(
1231    [#include <sys/types.h>
1232     #ifdef HAVE_SYS_SOCKET_H
1233     # include <sys/socket.h>
1234     #endif
1235     #include <netipx/ipx.h>],
1236    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1237    [ac_cv_c_ipx_gnu="yes"],
1238    [ac_cv_c_ipx_gnu="no"])
1239  )
1240 if test "$ac_cv_c_ipx_gnu" = "yes"
1241 then
1242     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1243 fi
1244
1245 if test "$ac_cv_c_ipx_gnu" = "no"
1246 then
1247  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1248   AC_TRY_COMPILE(
1249     [#include <sys/types.h>
1250      #ifdef HAVE_SYS_SOCKET_H
1251      # include <sys/socket.h>
1252      #endif
1253      #include <asm/types.h>
1254      #include <linux/ipx.h>],
1255     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1256     [ac_cv_c_ipx_linux="yes"],
1257     [ac_cv_c_ipx_linux="no"])
1258   )
1259   if test "$ac_cv_c_ipx_linux" = "yes"
1260   then
1261       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1262   fi
1263 fi
1264
1265 dnl **** Check for types ****
1266
1267 AC_C_CONST
1268 AC_C_INLINE
1269 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, socklen_t, long long, fsblkcnt_t, fsfilcnt_t])
1270
1271 AC_CACHE_CHECK([whether linux/input.h is for real],
1272         wine_cv_linux_input_h,
1273         AC_TRY_COMPILE([
1274             #include <linux/input.h>
1275         ] , [
1276             int foo = EVIOCGBIT(EV_ABS,42);
1277             int bar = BTN_PINKIE;
1278             int fortytwo = 42;
1279         ],
1280         wine_cv_linux_input_h=yes,
1281         wine_cv_linux_input_h=no,
1282         no
1283         )
1284     )
1285     if test "$wine_cv_linux_input_h" = "yes"
1286     then
1287         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1288                   [Define if we have linux/input.h AND it contains the INPUT event API])
1289     fi
1290
1291
1292 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1293         wine_cv_linux_gethostbyname_r_6,
1294         AC_TRY_LINK([
1295 #include <netdb.h>
1296         ], [
1297     char *name=NULL;
1298     struct hostent he;
1299     struct hostent *result;
1300     char *buf=NULL;
1301     int bufsize=0;
1302     int res,errnr;
1303     char *addr=NULL;
1304     int addrlen=0;
1305     int addrtype=0;
1306     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1307     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1308     ],
1309         wine_cv_linux_gethostbyname_r_6=yes,
1310         wine_cv_linux_gethostbyname_r_6=no
1311         )
1312    )
1313    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1314    then
1315       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1316                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1317    fi
1318
1319 if test "$ac_cv_header_linux_joystick_h" = "yes"
1320 then
1321    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1322         wine_cv_linux_joystick_22_api,
1323         AC_TRY_COMPILE([
1324         #include <sys/ioctl.h>
1325         #include <linux/joystick.h>
1326
1327         struct js_event blub;
1328         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1329         #error "no 2.2 header"
1330         #endif
1331         ],/*empty*/,
1332         wine_cv_linux_joystick_22_api=yes,
1333         wine_cv_linux_joystick_22_api=no,
1334         wine_cv_linux_joystick_22_api=no
1335         )
1336    )
1337    if test "$wine_cv_linux_joystick_22_api" = "yes"
1338    then
1339       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1340                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1341    fi
1342 fi
1343
1344 dnl **** statfs checks ****
1345
1346 if test "$ac_cv_header_sys_vfs_h" = "yes"
1347 then
1348     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1349                     wine_cv_sys_vfs_has_statfs,
1350         AC_TRY_COMPILE([
1351         #include <sys/types.h>
1352         #ifdef HAVE_SYS_PARAM_H
1353         # include <sys/param.h>
1354         #endif
1355         #include <sys/vfs.h>
1356         ],[
1357                 struct statfs stfs;
1358
1359                 memset(&stfs,0,sizeof(stfs));
1360         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1361         )
1362     )
1363     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1364     then
1365       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1366                 [Define if the struct statfs is defined by <sys/vfs.h>])
1367     fi
1368 fi
1369
1370 if test "$ac_cv_header_sys_statfs_h" = "yes"
1371 then
1372     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1373                     wine_cv_sys_statfs_has_statfs,
1374         AC_TRY_COMPILE([
1375         #include <sys/types.h>
1376         #ifdef HAVE_SYS_PARAM_H
1377         # include <sys/param.h>
1378         #endif
1379         #include <sys/statfs.h>
1380         ],[
1381                 struct statfs stfs;
1382         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1383         )
1384     )
1385     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1386     then
1387       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1388                 [Define if the struct statfs is defined by <sys/statfs.h>])
1389     fi
1390 fi
1391
1392 if test "$ac_cv_header_sys_mount_h" = "yes"
1393 then
1394     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1395                     wine_cv_sys_mount_has_statfs,
1396         AC_TRY_COMPILE([
1397         #include <sys/types.h>
1398         #ifdef HAVE_SYS_PARAM_H
1399         # include <sys/param.h>
1400         #endif
1401         #include <sys/mount.h>
1402         ],[
1403                 struct statfs stfs;
1404         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1405         )
1406     )
1407     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1408     then
1409       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1410                 [Define if the struct statfs is defined by <sys/mount.h>])
1411     fi
1412 fi
1413
1414 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1415
1416 dnl Check for statfs members
1417 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1418 [#include <sys/types.h>
1419 #ifdef HAVE_SYS_PARAM_H
1420 # include <sys/param.h>
1421 #endif
1422 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1423 # include <sys/mount.h>
1424 #else
1425 # ifdef STATFS_DEFINED_BY_SYS_VFS
1426 #  include <sys/vfs.h>
1427 # else
1428 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1429 #   include <sys/statfs.h>
1430 #  endif
1431 # endif
1432 #endif])
1433
1434 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1435 [#ifdef HAVE_SYS_STATVFS_H
1436 #include <sys/statvfs.h>
1437 #endif])
1438
1439 dnl Check for socket structure members
1440 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1441 [#include <sys/types.h>
1442 #ifdef HAVE_SYS_SOCKET_H
1443 # include <sys/socket.h>
1444 #endif
1445 #ifdef HAVE_SYS_UN_H
1446 # include <sys/un.h>
1447 #endif])
1448
1449 dnl Check for siginfo_t members
1450 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1451
1452 dnl Check for struct option
1453 AC_CHECK_MEMBERS([struct option.name],,,
1454 [#ifdef HAVE_GETOPT_H
1455 #include <getopt.h>
1456 #endif])
1457
1458 dnl Check for stat.st_blocks
1459 AC_CHECK_MEMBERS([struct stat.st_blocks])
1460
1461 dnl *** check for the need to define platform-specific symbols
1462
1463 case $host_cpu in
1464   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1465   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1466   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1467   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1468 esac
1469
1470 case $host_vendor in
1471   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1472 esac
1473
1474 dnl **** Generate output files ****
1475
1476 AH_TOP([#define __WINE_CONFIG_H])
1477
1478 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1479 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1480 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1481 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1482 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1483 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1484 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1485 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1486 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1487 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1488 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1489 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1490 WINE_CONFIG_EXTRA_DIR(include/wine)
1491 WINE_CONFIG_EXTRA_DIR(misc)
1492 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1493 WINE_CONFIG_EXTRA_DIR(windows)
1494
1495 MAKE_RULES=Make.rules
1496 AC_SUBST_FILE(MAKE_RULES)
1497
1498 MAKE_DLL_RULES=dlls/Makedll.rules
1499 AC_SUBST_FILE(MAKE_DLL_RULES)
1500
1501 MAKE_TEST_RULES=dlls/Maketest.rules
1502 AC_SUBST_FILE(MAKE_TEST_RULES)
1503
1504 MAKE_LIB_RULES=libs/Makelib.rules
1505 AC_SUBST_FILE(MAKE_LIB_RULES)
1506
1507 MAKE_PROG_RULES=programs/Makeprog.rules
1508 AC_SUBST_FILE(MAKE_PROG_RULES)
1509
1510 AC_CONFIG_FILES([
1511 Make.rules
1512 dlls/Makedll.rules
1513 dlls/Maketest.rules
1514 libs/Makelib.rules
1515 programs/Makeprog.rules
1516 Makefile
1517 dlls/Makefile
1518 dlls/advapi32/Makefile
1519 dlls/advapi32/tests/Makefile
1520 dlls/amstream/Makefile
1521 dlls/atl/Makefile
1522 dlls/avicap32/Makefile
1523 dlls/avifil32/Makefile
1524 dlls/cabinet/Makefile
1525 dlls/capi2032/Makefile
1526 dlls/cards/Makefile
1527 dlls/cfgmgr32/Makefile
1528 dlls/comcat/Makefile
1529 dlls/comctl32/Makefile
1530 dlls/comctl32/tests/Makefile
1531 dlls/commdlg/Makefile
1532 dlls/crtdll/Makefile
1533 dlls/crypt32/Makefile
1534 dlls/ctl3d/Makefile
1535 dlls/d3d8/Makefile
1536 dlls/d3d9/Makefile
1537 dlls/d3dim/Makefile
1538 dlls/d3drm/Makefile
1539 dlls/d3dx8/Makefile
1540 dlls/d3dxof/Makefile
1541 dlls/dbghelp/Makefile
1542 dlls/dciman32/Makefile
1543 dlls/ddraw/Makefile
1544 dlls/ddraw/tests/Makefile
1545 dlls/devenum/Makefile
1546 dlls/dinput/Makefile
1547 dlls/dinput8/Makefile
1548 dlls/dmband/Makefile
1549 dlls/dmcompos/Makefile
1550 dlls/dmime/Makefile
1551 dlls/dmloader/Makefile
1552 dlls/dmscript/Makefile
1553 dlls/dmstyle/Makefile
1554 dlls/dmsynth/Makefile
1555 dlls/dmusic/Makefile
1556 dlls/dmusic32/Makefile
1557 dlls/dplay/Makefile
1558 dlls/dplayx/Makefile
1559 dlls/dpnet/Makefile
1560 dlls/dpnhpast/Makefile
1561 dlls/dsound/Makefile
1562 dlls/dsound/tests/Makefile
1563 dlls/dswave/Makefile
1564 dlls/dxdiagn/Makefile
1565 dlls/dxerr8/Makefile
1566 dlls/dxerr9/Makefile
1567 dlls/dxguid/Makefile
1568 dlls/gdi/Makefile
1569 dlls/gdi/tests/Makefile
1570 dlls/glu32/Makefile
1571 dlls/glut32/Makefile
1572 dlls/hhctrl.ocx/Makefile
1573 dlls/iccvid/Makefile
1574 dlls/icmp/Makefile
1575 dlls/ifsmgr.vxd/Makefile
1576 dlls/imagehlp/Makefile
1577 dlls/imm32/Makefile
1578 dlls/iphlpapi/Makefile
1579 dlls/iphlpapi/tests/Makefile
1580 dlls/itss/Makefile
1581 dlls/kernel/Makefile
1582 dlls/kernel/tests/Makefile
1583 dlls/lzexpand/Makefile
1584 dlls/mapi32/Makefile
1585 dlls/mapi32/tests/Makefile
1586 dlls/mlang/Makefile
1587 dlls/mlang/tests/Makefile
1588 dlls/mmdevldr.vxd/Makefile
1589 dlls/monodebg.vxd/Makefile
1590 dlls/mpr/Makefile
1591 dlls/msacm/Makefile
1592 dlls/msacm/imaadp32/Makefile
1593 dlls/msacm/msadp32/Makefile
1594 dlls/msacm/msg711/Makefile
1595 dlls/msacm/winemp3/Makefile
1596 dlls/msacm/tests/Makefile
1597 dlls/msdmo/Makefile
1598 dlls/mshtml/Makefile
1599 dlls/msi/Makefile
1600 dlls/msimg32/Makefile
1601 dlls/msisys/Makefile
1602 dlls/msnet32/Makefile
1603 dlls/msrle32/Makefile
1604 dlls/msvcrt/Makefile
1605 dlls/msvcrt/tests/Makefile
1606 dlls/msvcrt20/Makefile
1607 dlls/msvcrt40/Makefile
1608 dlls/msvcrtd/Makefile
1609 dlls/msvcrtd/tests/Makefile
1610 dlls/msvidc32/Makefile
1611 dlls/msvideo/Makefile
1612 dlls/mswsock/Makefile
1613 dlls/netapi32/Makefile
1614 dlls/netapi32/tests/Makefile
1615 dlls/newdev/Makefile
1616 dlls/ntdll/Makefile
1617 dlls/ntdll/tests/Makefile
1618 dlls/odbc32/Makefile
1619 dlls/ole32/Makefile
1620 dlls/ole32/tests/Makefile
1621 dlls/oleacc/Makefile
1622 dlls/oleaut32/Makefile
1623 dlls/oleaut32/tests/Makefile
1624 dlls/olecli/Makefile
1625 dlls/oledlg/Makefile
1626 dlls/olepro32/Makefile
1627 dlls/olesvr/Makefile
1628 dlls/opengl32/Makefile
1629 dlls/psapi/Makefile
1630 dlls/psapi/tests/Makefile
1631 dlls/qcap/Makefile
1632 dlls/quartz/Makefile
1633 dlls/quartz/tests/Makefile
1634 dlls/rasapi32/Makefile
1635 dlls/richedit/Makefile
1636 dlls/rpcrt4/Makefile
1637 dlls/rpcrt4/tests/Makefile
1638 dlls/rsabase/Makefile
1639 dlls/rsabase/tests/Makefile
1640 dlls/secur32/Makefile
1641 dlls/serialui/Makefile
1642 dlls/setupapi/Makefile
1643 dlls/shdocvw/Makefile
1644 dlls/shell32/Makefile
1645 dlls/shell32/tests/Makefile
1646 dlls/shfolder/Makefile
1647 dlls/shlwapi/Makefile
1648 dlls/shlwapi/tests/Makefile
1649 dlls/snmpapi/Makefile
1650 dlls/sti/Makefile
1651 dlls/strmiids/Makefile
1652 dlls/tapi32/Makefile
1653 dlls/ttydrv/Makefile
1654 dlls/twain/Makefile
1655 dlls/unicows/Makefile
1656 dlls/url/Makefile
1657 dlls/urlmon/Makefile
1658 dlls/urlmon/tests/Makefile
1659 dlls/user/Makefile
1660 dlls/user/tests/Makefile
1661 dlls/uuid/Makefile
1662 dlls/uxtheme/Makefile
1663 dlls/vdhcp.vxd/Makefile
1664 dlls/vdmdbg/Makefile
1665 dlls/version/Makefile
1666 dlls/version/tests/Makefile
1667 dlls/vmm.vxd/Makefile
1668 dlls/vnbt.vxd/Makefile
1669 dlls/vnetbios.vxd/Makefile
1670 dlls/vtdapi.vxd/Makefile
1671 dlls/vwin32.vxd/Makefile
1672 dlls/win32s/Makefile
1673 dlls/winaspi/Makefile
1674 dlls/wined3d/Makefile
1675 dlls/winedos/Makefile
1676 dlls/wineps/Makefile
1677 dlls/wininet/Makefile
1678 dlls/wininet/tests/Makefile
1679 dlls/winmm/Makefile
1680 dlls/winmm/joystick/Makefile
1681 dlls/winmm/mcianim/Makefile
1682 dlls/winmm/mciavi/Makefile
1683 dlls/winmm/mcicda/Makefile
1684 dlls/winmm/mciseq/Makefile
1685 dlls/winmm/mciwave/Makefile
1686 dlls/winmm/midimap/Makefile
1687 dlls/winmm/tests/Makefile
1688 dlls/winmm/wavemap/Makefile
1689 dlls/winmm/winealsa/Makefile
1690 dlls/winmm/winearts/Makefile
1691 dlls/winmm/wineaudioio/Makefile
1692 dlls/winmm/winejack/Makefile
1693 dlls/winmm/winenas/Makefile
1694 dlls/winmm/wineoss/Makefile
1695 dlls/winnls/Makefile
1696 dlls/winsock/Makefile
1697 dlls/winsock/tests/Makefile
1698 dlls/winspool/Makefile
1699 dlls/winspool/tests/Makefile
1700 dlls/wintab32/Makefile
1701 dlls/wintrust/Makefile
1702 dlls/wow32/Makefile
1703 dlls/wsock32/Makefile
1704 dlls/x11drv/Makefile
1705 documentation/Makefile
1706 fonts/Makefile
1707 include/Makefile
1708 libs/Makefile
1709 libs/port/Makefile
1710 libs/unicode/Makefile
1711 libs/wine/Makefile
1712 libs/wpp/Makefile
1713 loader/Makefile
1714 programs/Makefile
1715 programs/avitools/Makefile
1716 programs/clock/Makefile
1717 programs/cmdlgtst/Makefile
1718 programs/control/Makefile
1719 programs/expand/Makefile
1720 programs/msiexec/Makefile
1721 programs/notepad/Makefile
1722 programs/progman/Makefile
1723 programs/regedit/Makefile
1724 programs/regsvr32/Makefile
1725 programs/rpcss/Makefile
1726 programs/rundll32/Makefile
1727 programs/start/Makefile
1728 programs/taskmgr/Makefile
1729 programs/uninstaller/Makefile
1730 programs/view/Makefile
1731 programs/wcmd/Makefile
1732 programs/wineboot/Makefile
1733 programs/winebrowser/Makefile
1734 programs/winecfg/Makefile
1735 programs/wineconsole/Makefile
1736 programs/winedbg/Makefile
1737 programs/winefile/Makefile
1738 programs/winemenubuilder/Makefile
1739 programs/winemine/Makefile
1740 programs/winepath/Makefile
1741 programs/winetest/Makefile
1742 programs/winevdm/Makefile
1743 programs/winhelp/Makefile
1744 programs/winver/Makefile
1745 server/Makefile
1746 tools/Makefile
1747 tools/widl/Makefile
1748 tools/winapi/Makefile
1749 tools/winebuild/Makefile
1750 tools/winedump/Makefile
1751 tools/winegcc/Makefile
1752 tools/wmc/Makefile
1753 tools/wrc/Makefile])
1754
1755 AC_OUTPUT
1756
1757 if test "$have_x" = "no"
1758 then
1759   echo
1760   echo "*** Warning: X development files not found. Wine will be built without"
1761   echo "*** X support, which currently does not work, and would probably not be"
1762   echo "*** what you want anyway. You will need to install devel packages of"
1763   echo "*** Xlib/Xfree86 at the very least."
1764 fi
1765
1766 if test "$wine_cv_opengl_version_OK" = "no"
1767 then
1768   echo
1769   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1770   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1771 fi
1772
1773 if test "$wine_cv_msg_freetype" = "yes"
1774 then
1775   echo
1776   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1777   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1778   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1779   echo "*** enable Wine to use TrueType fonts."
1780 fi
1781
1782 echo
1783 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1784 echo
1785
1786 dnl Local Variables:
1787 dnl comment-start: "dnl "
1788 dnl comment-end: ""
1789 dnl comment-start-skip: "\\bdnl\\b\\s *"
1790 dnl compile-command: "autoconf"
1791 dnl End: