git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.62 don't handle source dir symlinks correctly
   8 AC_PREREQ(2.62)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND or AS_VAR_IF
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17 m4_ifdef([AS_VAR_IF],,[AC_DEFUN([AS_VAR_IF],
  18 [AS_LITERAL_IF([$1],
  19   [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
  20   [eval as_val=\$$1
  21    AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])])dnl
  22 dnl autoconf versions before 2.64 don't have AC_PACKAGE_URL
  23 m4_ifdef([AC_PACKAGE_URL],,
  24   [AC_DEFINE([PACKAGE_URL], ["http://www.winehq.org"], [Define to the home page for this package.])
  25    AC_SUBST([PACKAGE_URL], ["http://www.winehq.org"])])dnl
  26
  27 dnl **** Command-line arguments ****
  28
  29 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  30 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  31 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  32 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]))
  33
  34 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  36 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  37             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  38 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  40 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  41             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  42 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  43 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  45 AC_ARG_WITH(dbus,      AS_HELP_STRING([--without-dbus],[do not use DBus (dynamic device support)]))
  46 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]))
  47 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  48 AC_ARG_WITH(gettext,   AS_HELP_STRING([--without-gettext],[do not use gettext]))
  49 AC_ARG_WITH(gettextpo, AS_HELP_STRING([--with-gettextpo],[use the GetTextPO library to rebuild po files]),
  50             [if test "x$withval" = "xno"; then ac_cv_header_gettext_po_h=no; fi])
  51 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  52 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  54 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  55 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  57 AC_ARG_WITH(gstreamer, AS_HELP_STRING([--without-gstreamer],[do not use GStreamer (codecs support)]))
  58 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  59 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  61 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  63 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_mpg123_h=no; fi])
  65 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  66             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  67 AC_ARG_WITH(opencl,    AS_HELP_STRING([--without-opencl],[do not use OpenCL]),
  68             [if test "x$withval" = "xno"; then ac_cv_header_CL_cl_h=no; ac_cv_header_OpenCL_opencl_h=no; fi])
  69 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  70 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  72 AC_ARG_WITH(osmesa,     AS_HELP_STRING([--without-osmesa],[do not use the OSMesa library]),
  73             [if test "x$withval" = "xno"; then ac_cv_header_GL_osmesa_h=no; fi])
  74 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]))
  75 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  77 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  78             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  79 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  80 AC_ARG_WITH(tiff,       AS_HELP_STRING([--without-tiff],[do not use TIFF]),
  81             [if test "x$withval" = "xno"; then ac_cv_header_tiffio_h=no; fi])
  82 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  83 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  84             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  85 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  86             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  87 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  88             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  89 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  90             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  91 AC_ARG_WITH(xinput2,   AS_HELP_STRING([--without-xinput2],[do not use the Xinput 2 extension]),
  92             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput2_h=no; fi])
  93 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  94 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  95             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  96 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  97             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  98 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  99             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
 100 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
 101 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
 102             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
 103 AC_ARG_WITH(zlib,      AS_HELP_STRING([--without-zlib],[do not use Zlib (data compression)]),
 104             [if test "x$withval" = "xno"; then ac_cv_header_zlib_h=no; fi])
 105
 106 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
 107 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
 108
 109 AC_CANONICAL_HOST
 110
 111 dnl check for out of tree build with unclean source tree
 112 case "$srcdir" in
 113  .) ;;
 114  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 115       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 116 You need to run 'make distclean' in the source tree first.])
 117     fi ;;
 118 esac
 119
 120 dnl **** Check for some programs ****
 121
 122 AC_PROG_MAKE_SET
 123 AC_PROG_CC
 124 AC_PROG_CXX
 125 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 126 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 127 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 128
 129 case $host in
 130   *-darwin*)
 131     if test "x$enable_win64" = "xyes"
 132     then
 133       CC="$CC -m64"
 134       CXX="$CXX -m64"
 135       host_cpu="x86_64"
 136       notice_platform="64-bit "
 137       AC_SUBST(TARGETFLAGS,"-m64")
 138     else
 139       CC="$CC -m32"
 140       CXX="$CXX -m32"
 141       host_cpu="i386"
 142       notice_platform="32-bit "
 143       AC_SUBST(TARGETFLAGS,"-m32")
 144       enable_win16=${enable_win16:-yes}
 145     fi
 146     with_fontconfig=${with_fontconfig:-no}
 147     ;;
 148   x86_64*)
 149     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 150     then
 151       CC="$CC -m32"
 152       CXX="$CXX -m32"
 153       AC_MSG_CHECKING([whether $CC works])
 154       AC_LINK_IFELSE([AC_LANG_PROGRAM()],AC_MSG_RESULT([yes]),
 155                      [AC_MSG_RESULT([no])
 156                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 157       host_cpu="i386"
 158       notice_platform="32-bit "
 159       AC_SUBST(TARGETFLAGS,"-m32")
 160       enable_win16=${enable_win16:-yes}
 161     else
 162       if test "x${GCC}" = "xyes"
 163       then
 164         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 165         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 166                           [AC_MSG_RESULT([yes])],
 167                           [AC_MSG_RESULT([no])
 168                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 169       fi
 170       AC_SUBST(TARGETFLAGS,"-m64")
 171     fi
 172     ;;
 173   arm*)
 174     AC_MSG_CHECKING([whether $CC supports Thumb])
 175     WINE_TRY_ASM_LINK([".thumb\nblx ac_test\n.arm"],[int ac_test(int i) { return i; }], [if (ac_test(1)) return 1],
 176                       [AC_MSG_RESULT([yes])],
 177                       [AC_MSG_RESULT([no])
 178                        AC_MSG_ERROR([You need a target with Thumb support to build Wine for ARM.])])
 179     CFLAGS="$CFLAGS -marm"
 180     ;;
 181   *-mingw32*|*-cygwin*)
 182     enable_win16=${enable_win16:-no}
 183     CFLAGS="$CFLAGS -D_WIN32"
 184     ;;
 185   i[[3456789]]86*)
 186     enable_win16=${enable_win16:-yes}
 187     ;;
 188 esac
 189
 190 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 191 enable_win16=${enable_win16:-no}
 192 enable_win64=${enable_win64:-no}
 193
 194 dnl Disable winetest too if tests are disabled
 195 enable_winetest=${enable_winetest:-$enable_tests}
 196
 197 dnl Some special cases for the wow64 build
 198 if test -n "$with_wine64"
 199 then
 200     if test "x$enable_win64" = "xyes"
 201     then
 202         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 203 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 204     fi
 205     AC_SUBST([WOW64_DISABLE],[\#])
 206     enable_fonts=${enable_fonts:-no}
 207     enable_server=${enable_server:-no}
 208     enable_tools=${enable_tools:-no}
 209 elif test "x$enable_win64" = "xyes"
 210 then
 211     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib64"
 212 fi
 213
 214 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 215   [wine_cv_toolsdir="$with_wine_tools"
 216    if test -z "$with_wine_tools"; then
 217      if test "$cross_compiling" = "yes"; then
 218        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 219      elif test -n "$with_wine64"; then
 220        wine_cv_toolsdir="$with_wine64"
 221      fi
 222    fi
 223    if test -z "$wine_cv_toolsdir"; then
 224      wine_cv_toolsdir="\$(top_builddir)"
 225    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 226      case "$wine_cv_toolsdir" in
 227        /*) ;;
 228        *)  wine_cv_toolsdir="\$(top_builddir)/$wine_cv_toolsdir" ;;
 229      esac
 230    else
 231      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 232    fi])
 233 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 234 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 235 then
 236     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 237 fi
 238
 239 dnl Check for flex
 240 AC_CHECK_PROGS(FLEX,flex,none)
 241 if test "$FLEX" = "none"
 242 then
 243   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 244 fi
 245 AC_MSG_CHECKING([whether flex is recent enough])
 246 cat >conftest.l <<EOF
 247 %top{
 248 #include "prediluvian.h"
 249 }
 250 %%
 251 EOF
 252 if $FLEX -t conftest.l >/dev/null 2>&AS_MESSAGE_LOG_FD
 253 then
 254   AC_MSG_RESULT([yes])
 255 else
 256   AC_MSG_RESULT([no])
 257   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 258 fi
 259
 260 dnl Check for bison
 261 AC_CHECK_PROGS(BISON,bison,none)
 262 if test "$BISON" = "none"
 263 then
 264   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 265 fi
 266
 267 AC_CHECK_TOOLS(AR,[ar gar],ar)
 268 AC_SUBST(ARFLAGS,rc)
 269 AC_PROG_RANLIB
 270 AC_PROG_LN_S
 271 AC_PROG_EGREP
 272 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 273 AC_PROG_INSTALL
 274 dnl Prepend src dir to install path dir if it's a relative path
 275 case "$INSTALL" in
 276   [[\\/$]]* | ?:[[\\/]]* ) ;;
 277   *)  INSTALL="\\\$(top_srcdir)/$INSTALL" ;;
 278 esac
 279
 280 dnl Check for lint
 281 AC_CHECK_PROGS(LINT, lclint lint)
 282 if test "$LINT" = "lint"
 283 then
 284   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 285   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 286 fi
 287 AC_SUBST(LINTFLAGS)
 288
 289 dnl Check for various programs
 290 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 291 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 292 AC_CHECK_PROGS(RSVG, rsvg, false)
 293 AC_CHECK_PROGS(CONVERT, convert, false)
 294 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 295 AC_CHECK_PROGS(MSGFMT, msgfmt, false)
 296
 297 if test "x$enable_maintainer_mode" != "xyes"
 298 then
 299   AC_SUBST([MAINTAINER_MODE],[\#])
 300 else
 301   if test "$FONTFORGE" = "false"; then AC_MSG_ERROR([You need fontforge to rebuild fonts in maintainer mode.]); fi
 302   if test "$RSVG" = "false"; then AC_MSG_ERROR([You need rsvg to rebuild icons in maintainer mode.]); fi
 303
 304   dnl Check the imagemagick version
 305   if test "$CONVERT" = false
 306   then
 307     AC_MSG_ERROR([You need imagemagick to rebuild icons in maintainer mode.])
 308   else
 309     AC_MSG_CHECKING([for recent enough imagemagick])
 310     convert_version=`convert --version | head -n1`
 311     if test "x$convert_version" != "x"
 312     then
 313       convert_version_major=`expr "$convert_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 314       convert_version_minor=`expr "$convert_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 315       if test "$convert_version_major" -eq 6 -a "$convert_version_minor" -lt 6
 316       then
 317         CONVERT=false
 318       fi
 319     fi
 320     if test "$CONVERT" = false
 321     then
 322       AC_MSG_RESULT([no ($convert_version_major.$convert_version_minor)])
 323       AC_MSG_ERROR([You need imagemagick version 6.6 or newer to rebuild icons in maintainer mode.])
 324     else
 325       AC_MSG_RESULT([yes ($convert_version_major.$convert_version_minor)])
 326     fi
 327   fi
 328
 329   dnl Check the icotool version
 330   if test "$ICOTOOL" = false
 331   then
 332     AC_MSG_ERROR([You need icotool to rebuild icons in maintainer mode.])
 333   else
 334     AC_MSG_CHECKING([for recent enough icotool])
 335     icotool_version=`icotool --version | head -n1`
 336     if test "x$icotool_version" != "x"
 337     then
 338       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 339       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 340       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 341       then
 342         ICOTOOL=false
 343         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 344       fi
 345     fi
 346     if test "$ICOTOOL" = false
 347     then
 348       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 349       AC_MSG_ERROR([You need icotool version 0.29.0 or newer to rebuild icons in maintainer mode.])
 350     else
 351       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 352     fi
 353   fi
 354
 355   dnl Maintainer mode requires gettext
 356   with_gettext=yes
 357   with_gettextpo=yes
 358   AS_UNSET(ac_cv_header_gettext_po_h)
 359 fi
 360
 361 test "x$with_gettext" != xno || MSGFMT=false
 362 if test "$MSGFMT" != "false"
 363 then
 364   AC_MSG_CHECKING([whether msgfmt supports contexts])
 365   cat >conftest.po <<EOF
 366 # comment
 367 msgctxt "ctxt"
 368 msgid "id"
 369 msgstr "str"
 370 EOF
 371   if $MSGFMT -o /dev/null conftest.po 2>&AS_MESSAGE_LOG_FD
 372   then
 373     AC_MSG_RESULT([yes])
 374   else
 375     AC_MSG_RESULT([no])
 376     MSGFMT=false
 377   fi
 378 fi
 379 WINE_WARNING_WITH(gettext,[test "$MSGFMT" = false],
 380                   [gettext tools not found (or too old), translations won't be built.])
 381
 382 dnl **** Check for some libraries ****
 383
 384 dnl Check for -li386 for NetBSD and OpenBSD
 385 AC_CHECK_LIB(i386,i386_set_ldt)
 386 dnl Check for -lossaudio for NetBSD
 387 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 388
 389 AC_SUBST(XLIB,"")
 390 AC_SUBST(OPENGL_LIBS,"")
 391
 392 dnl **** Check for header files ****
 393
 394 test "x$with_fontconfig" != "xno" || ac_cv_header_fontconfig_fontconfig_h=no
 395
 396 AC_SYS_LARGEFILE()
 397
 398 AC_CHECK_HEADERS(\
 399         AL/al.h \
 400         ApplicationServices/ApplicationServices.h \
 401         AudioToolbox/AudioConverter.h \
 402         AudioUnit/AudioUnit.h \
 403         AudioUnit/AudioComponent.h \
 404         CL/cl.h \
 405         Carbon/Carbon.h \
 406         CoreAudio/CoreAudio.h \
 407         CoreServices/CoreServices.h \
 408         DiskArbitration/DiskArbitration.h \
 409         IOKit/IOKitLib.h \
 410         IOKit/hid/IOHIDLib.h \
 411         OpenAL/al.h \
 412         OpenCL/opencl.h \
 413         QuickTime/ImageCompression.h \
 414         Security/Security.h \
 415         alias.h \
 416         alsa/asoundlib.h \
 417         arpa/inet.h \
 418         arpa/nameser.h \
 419         asm/types.h \
 420         capi20.h \
 421         curses.h \
 422         direct.h \
 423         dirent.h \
 424         dlfcn.h \
 425         elf.h \
 426         float.h \
 427         fnmatch.h \
 428         fontconfig/fontconfig.h \
 429         getopt.h \
 430         gettext-po.h \
 431         grp.h \
 432         gsm.h \
 433         gsm/gsm.h \
 434         ieeefp.h \
 435         inet/mib2.h \
 436         io.h \
 437         jpeglib.h \
 438         kstat.h \
 439         lber.h \
 440         lcms.h \
 441         lcms/lcms.h \
 442         ldap.h \
 443         link.h \
 444         linux/cdrom.h \
 445         linux/compiler.h \
 446         linux/hdreg.h \
 447         linux/input.h \
 448         linux/ioctl.h \
 449         linux/joystick.h \
 450         linux/major.h \
 451         linux/param.h \
 452         linux/serial.h \
 453         linux/types.h \
 454         linux/ucdrom.h \
 455         lwp.h \
 456         mach-o/nlist.h \
 457         mach-o/loader.h \
 458         mach/mach.h \
 459         mach/machine.h \
 460         machine/cpu.h \
 461         machine/limits.h \
 462         machine/sysarch.h \
 463         mntent.h \
 464         mpg123.h \
 465         ncurses.h \
 466         netdb.h \
 467         netinet/in.h \
 468         netinet/in_systm.h \
 469         netinet/tcp.h \
 470         netinet/tcp_fsm.h \
 471         openssl/err.h \
 472         openssl/ssl.h \
 473         png.h \
 474         poll.h \
 475         port.h \
 476         process.h \
 477         pthread.h \
 478         pwd.h \
 479         sched.h \
 480         scsi/scsi.h \
 481         scsi/scsi_ioctl.h \
 482         scsi/sg.h \
 483         stdbool.h \
 484         stdint.h \
 485         strings.h \
 486         stropts.h \
 487         sys/asoundlib.h \
 488         sys/attr.h \
 489         sys/cdio.h \
 490         sys/elf32.h \
 491         sys/epoll.h \
 492         sys/event.h \
 493         sys/exec_elf.h \
 494         sys/filio.h \
 495         sys/inotify.h \
 496         sys/ioctl.h \
 497         sys/ipc.h \
 498         sys/limits.h \
 499         sys/link.h \
 500         sys/mman.h \
 501         sys/modem.h \
 502         sys/msg.h \
 503         sys/mtio.h \
 504         sys/param.h \
 505         sys/poll.h \
 506         sys/prctl.h \
 507         sys/protosw.h \
 508         sys/ptrace.h \
 509         sys/resource.h \
 510         sys/scsiio.h \
 511         sys/shm.h \
 512         sys/signal.h \
 513         sys/socket.h \
 514         sys/socketvar.h \
 515         sys/sockio.h \
 516         sys/statvfs.h \
 517         sys/strtio.h \
 518         sys/syscall.h \
 519         sys/tihdr.h \
 520         sys/time.h \
 521         sys/timeout.h \
 522         sys/times.h \
 523         sys/uio.h \
 524         sys/un.h \
 525         sys/utsname.h \
 526         sys/vm86.h \
 527         sys/wait.h \
 528         syscall.h \
 529         termios.h \
 530         tiffio.h \
 531         unistd.h \
 532         utime.h \
 533         valgrind/memcheck.h \
 534         valgrind/valgrind.h \
 535         zlib.h
 536 )
 537 AC_HEADER_STAT()
 538
 539 dnl **** Checks for headers that depend on other ones ****
 540
 541 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 542     [#include <sys/types.h>
 543      #ifdef HAVE_SYS_PARAM_H
 544      # include <sys/param.h>
 545      #endif])
 546
 547 AC_CHECK_HEADERS(\
 548         netinet/ip.h \
 549         net/if.h \
 550         net/if_arp.h \
 551         net/if_dl.h \
 552         net/if_types.h \
 553         net/route.h \
 554         netinet/if_ether.h \
 555         netinet/if_inarp.h \
 556         netinet/in_pcb.h \
 557         netinet/ip_icmp.h \
 558         netinet/ip_var.h \
 559         netinet/udp.h \
 560         netipx/ipx.h \
 561 ,,,[#include <sys/types.h>
 562      #ifdef HAVE_SYS_SOCKET_H
 563      # include <sys/socket.h>
 564      #endif
 565      #ifdef HAVE_SYS_SOCKETVAR_H
 566      # include <sys/socketvar.h>
 567      #endif
 568      #ifdef HAVE_NET_ROUTE_H
 569      # include <net/route.h>
 570      #endif
 571      #ifdef HAVE_NETINET_IN_H
 572      # include <netinet/in.h>
 573      #endif
 574      #ifdef HAVE_NETINET_IN_SYSTM_H
 575      # include <netinet/in_systm.h>
 576      #endif
 577      #ifdef HAVE_NET_IF_H
 578      # include <net/if.h>
 579      #endif
 580      #ifdef HAVE_NETINET_IP_H
 581      # include <netinet/ip.h>
 582      #endif])
 583
 584 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 585     [#include <sys/types.h>
 586      #ifdef HAVE_ALIAS_H
 587      # include <alias.h>
 588      #endif
 589      #ifdef HAVE_SYS_SOCKET_H
 590      # include <sys/socket.h>
 591      #endif
 592      #ifdef HAVE_SYS_SOCKETVAR_H
 593      # include <sys/socketvar.h>
 594      #endif
 595      #ifdef HAVE_SYS_TIMEOUT_H
 596      # include <sys/timeout.h>
 597      #endif
 598      #ifdef HAVE_NETINET_IN_H
 599      # include <netinet/in.h>
 600      #endif
 601      #ifdef HAVE_NETINET_IN_SYSTM_H
 602      # include <netinet/in_systm.h>
 603      #endif
 604      #ifdef HAVE_NETINET_IP_H
 605      # include <netinet/ip.h>
 606      #endif
 607      #ifdef HAVE_NETINET_IP_VAR_H
 608      # include <netinet/ip_var.h>
 609      #endif
 610      #ifdef HAVE_NETINET_IP_ICMP_H
 611      # include <netinet/ip_icmp.h>
 612      #endif
 613      #ifdef HAVE_NETINET_UDP_H
 614      # include <netinet/udp.h>
 615      #endif
 616      #ifdef HAVE_NETINET_TCP_H
 617      # include <netinet/tcp.h>
 618      #endif
 619      #ifdef HAVE_NETINET_TCP_TIMER_H
 620      #include <netinet/tcp_timer.h>
 621      #endif])
 622
 623 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h],,,
 624     [#include <sys/types.h>
 625      #ifdef HAVE_ASM_TYPES_H
 626      # include <asm/types.h>
 627      #endif
 628      #ifdef HAVE_SYS_SOCKET_H
 629      # include <sys/socket.h>
 630      #endif
 631      #ifdef HAVE_LINUX_TYPES_H
 632      # include <linux/types.h>
 633      #endif])
 634
 635 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 636     [#ifdef HAVE_STDBOOL_H
 637      # include <stdbool.h>
 638      #endif
 639      #ifdef HAVE_STDINT_H
 640      # include <stdint.h>
 641      #endif])
 642
 643 AC_CHECK_HEADERS([resolv.h],,,
 644     [#include <sys/types.h>
 645      #ifdef HAVE_SYS_SOCKET_H
 646      # include <sys/socket.h>
 647      #endif
 648      #ifdef HAVE_NETINET_IN_H
 649      # include <netinet/in.h>
 650      #endif
 651      #ifdef HAVE_ARPA_NAMESER_H
 652      # include <arpa/nameser.h>
 653      #endif])
 654
 655 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 656
 657 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 658
 659 AC_CHECK_HEADERS([sys/thr.h],,,
 660 [#include <sys/types.h>
 661 #ifdef HAVE_UCONTEXT_H
 662 #include <ucontext.h>
 663 #endif])
 664
 665 AC_CHECK_HEADERS([pthread_np.h],,,
 666 [#ifdef HAVE_PTHREAD_H
 667 #include <pthread.h>
 668 #endif])
 669
 670 AC_CHECK_HEADERS([linux/videodev.h linux/videodev2.h],,,
 671 [#ifdef HAVE_SYS_TIME_H
 672 #include <sys/time.h>
 673 #endif
 674 #include <sys/types.h>
 675 #ifdef HAVE_ASM_TYPES_H
 676 #include <asm/types.h>
 677 #endif])
 678
 679 dnl Check for broken kernel header that doesn't define __user
 680 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 681
 682 dnl **** Check for working dll ****
 683
 684 AC_SUBST(DLLEXT,"")
 685 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 686 AC_SUBST(LDSHARED,"")
 687 AC_SUBST(LDDLLFLAGS,"")
 688 AC_SUBST(LIBEXT,"so")
 689 AC_SUBST(IMPLIBEXT,"def")
 690 AC_SUBST(LDRPATH_INSTALL,"")
 691 AC_SUBST(LDRPATH_LOCAL,"")
 692 STATIC_IMPLIBEXT="def.a"
 693 WINE_PATH_LDD
 694
 695 case $host_os in
 696   cygwin*|mingw32*)
 697     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 698     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 699     if test "$DLLWRAP" = "false"; then
 700       LIBEXT="a"
 701     else
 702       dnl FIXME - check whether dllwrap works correctly...
 703       LIBEXT="dll"
 704     fi
 705     IMPLIBEXT="a"
 706     STATIC_IMPLIBEXT="a"
 707     dnl Disable modules that can't be used on Windows
 708     enable_iphlpapi=${enable_iphlpapi:-no}
 709     enable_kernel32=${enable_kernel32:-no}
 710     enable_msvcrt=${enable_msvcrt:-no}
 711     enable_ntdll=${enable_ntdll:-no}
 712     enable_ws2_32=${enable_ws2_32:-no}
 713     enable_loader=${enable_loader:-no}
 714     enable_server=${enable_server:-no}
 715     dnl Disable dependencies that are not useful on Windows
 716     with_x=${with_x:-no}
 717     with_pthread=${with_pthread:-no}
 718     ;;
 719   darwin*|macosx*)
 720     DLLEXT=".so"
 721     LIBEXT="dylib"
 722     DLLFLAGS="$DLLFLAGS -fPIC"
 723     LDDLLFLAGS="-bundle -multiply_defined suppress"
 724     LIBWINE_LDFLAGS="-multiply_defined suppress"
 725     LDSHARED="\$(CC) -dynamiclib"
 726     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(top_builddir)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 727     dnl declare needed frameworks
 728     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 729     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 730     AC_SUBST(APPLICATIONSERVICESLIB,"-framework ApplicationServices")
 731     AC_SUBST(CORESERVICESLIB,"-framework CoreServices")
 732     case $host_os in
 733       darwin11*)
 734         AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-macosx_version_min,10.6,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000"]) ;;
 735       *)
 736         AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000"]) ;;
 737     esac
 738     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 739     then
 740         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 741         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 742     fi
 743     if test "$ac_cv_header_Security_Security_h" = "yes"
 744     then
 745         AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 746         dnl Check for the SSLCopyPeerCertificates function
 747         ac_save_LIBS="$LIBS"
 748         LIBS="$LIBS $SECURITYLIB"
 749         AC_CHECK_FUNCS(SSLCopyPeerCertificates)
 750         LIBS="$ac_save_LIBS"
 751         with_gnutls=${with_gnutls:-no}
 752     fi
 753     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 754     then
 755         if test "$ac_cv_header_AudioUnit_AudioComponent_h" = "yes"
 756         then
 757             AC_SUBST(COREAUDIO,"-framework CoreFoundation -framework CoreAudio -framework AudioUnit -framework AudioToolbox -framework CoreMIDI")
 758         else
 759             dnl CoreServices needed by AudioUnit
 760             AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 761         fi
 762         dnl Check for the AUGraphAddNode function
 763         ac_save_LIBS="$LIBS"
 764         LIBS="$LIBS $COREAUDIO"
 765         AC_CHECK_FUNCS(AUGraphAddNode)
 766         LIBS="$ac_save_LIBS"
 767     fi
 768     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 769     then
 770         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 771         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 772         ac_cv_lib_openal=yes
 773     fi
 774     if test "$ac_cv_header_OpenCL_opencl_h" = "yes"
 775     then
 776         AC_SUBST(LIBOPENCL,"-framework OpenCL")
 777         ac_cv_lib_OpenCL_clGetPlatformInfo=yes
 778     fi
 779     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 780     then
 781         ac_save_LIBS="$LIBS"
 782         LIBS="$LIBS $IOKITLIB"
 783         AC_CHECK_FUNCS(IOHIDManagerCreate)
 784         LIBS="$ac_save_LIBS"
 785     fi
 786     case $host_cpu in
 787       *powerpc*)
 788         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 789         ;;
 790     esac
 791     if test "$ac_cv_header_QuickTime_ImageCompression_h" = "yes"
 792     then
 793         AC_SUBST(QUICKTIMELIB,"-framework QuickTime -framework ApplicationServices -framework CoreVideo")
 794         enable_wineqtdecoder=${enable_wineqtdecoder:-yes}
 795     else
 796         WINE_NOTICE([QuickTime ${notice_platform}development files not found, video decoding won't be supported.])
 797     fi
 798     dnl Enable quartz driver on Mac OS X
 799     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 800     then
 801         AC_SUBST(CARBONLIB,"-framework Carbon")
 802         enable_winequartz_drv=${enable_winequartz_drv:-yes}
 803     fi
 804     dnl Check for Xcode 3.x broken 16-bit support
 805     if test "x$enable_win16" = "xyes"
 806     then
 807         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 808         AC_RUN_IFELSE([AC_LANG_PROGRAM([[asm(".text\n"
 809                                             "bad:\tnop;nop\n"
 810                                             "good:\tnop;nop\n\t"
 811                                             ".globl _testfunc\n"
 812                                             "_testfunc:\tcallw good");
 813                                         extern void testfunc();]],
 814                                       [[unsigned short *p = (unsigned short *)testfunc;
 815                                         return p[0] != 0xe866 || p[1] != 0xfffa]])],
 816                                       AC_MSG_RESULT(yes),
 817                                       [AC_MSG_RESULT(no)
 818                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 819                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 820     fi
 821     ;;
 822   *)
 823     DLLFLAGS="$DLLFLAGS -fPIC"
 824     DLLEXT=".so"
 825     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 826         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 827                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 828     if test "$ac_cv_c_dll_gnuelf" = "yes"
 829     then
 830       LDSHARED="\$(CC) -shared"
 831       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 832       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 833                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 834                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 835                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 836
 837       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 838
 839       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 840                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 841
 842       echo '{ global: *; };' >conftest.map
 843       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 844                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 845       rm -f conftest.map
 846
 847       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 848                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 849
 850       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 851                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 852                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 853           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 854                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 855                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 856
 857       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 858                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 859
 860       case $host_cpu in
 861         *i[[3456789]]86* | x86_64)
 862           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 863                           [case $host_os in
 864                            freebsd* | kfreebsd*-gnu) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x60000400" ;;
 865                            *) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400" ;;
 866                            esac
 867                           ])
 868           AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 869           if test "x$PRELINK" = xfalse
 870           then
 871               WINE_WARNING([prelink not found, base address of core dlls won't be set correctly.])
 872           fi
 873           ;;
 874       esac
 875
 876     else
 877       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 878           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 879                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 880       if test "$ac_cv_c_dll_unixware" = "yes"
 881       then
 882         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 883         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 884
 885       else
 886         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 887           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 888         if test "$ac_cv_c_dll_hpux" = "yes"
 889         then
 890           LIBEXT="sl"
 891           DLLEXT=".sl"
 892           LDDLLFLAGS="-shared -fPIC"
 893           LDSHARED="\$(CC) -shared"
 894         fi
 895       fi
 896     fi
 897     ;;
 898 esac
 899
 900 enable_wineqtdecoder=${enable_wineqtdecoder:-no}
 901 enable_winequartz_drv=${enable_winequartz_drv:-no}
 902
 903 if test "$LIBEXT" = "a"; then
 904   AC_MSG_ERROR(
 905 [could not find a way to build shared libraries.
 906 It is currently not possible to build Wine without shared library
 907 (.so) support to allow transparent switch between .so and .dll files.
 908 If you are using Linux, you will need a newer binutils.]
 909 )
 910 fi
 911
 912 dnl Check for cross compiler to build test programs
 913 AC_SUBST([CROSSTEST_DISABLE],[\#])
 914 if test "$cross_compiling" = "no" -a "x$enable_tests" != xno -a "$LIBEXT" != "dll"
 915 then
 916     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 917     if test "$CROSSCC" != "false"
 918     then
 919         ac_save_CC="$CC"
 920         CC="$CROSSCC"
 921         AC_MSG_CHECKING([whether $CROSSCC works])
 922         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 923                           [AC_MSG_RESULT([yes])
 924                            set x $CROSSCC
 925                            shift
 926                            target=""
 927                            while test $# -ge 1
 928                            do
 929                                case "$1" in
 930                                  *-gcc) target=`expr "$1" : '\(.*\)-gcc'` ;;
 931                                esac
 932                                shift
 933                            done
 934                            if test -n "$target"
 935                            then
 936                                CROSSTEST_DISABLE=""
 937                                AC_SUBST(CROSSTARGET,"$target")
 938                            fi],
 939                           [AC_MSG_RESULT([no])])
 940         CC="$ac_save_CC"
 941     fi
 942 fi
 943
 944 dnl **** Check for pthread ****
 945
 946 if test "$ac_cv_header_pthread_h" = "yes"
 947 then
 948     AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])
 949 fi
 950 WINE_ERROR_WITH(pthread,[test "x$LIBPTHREAD" = "x"],[pthread ${notice_platform}development files not found.
 951 Wine cannot support threads without libpthread.])
 952
 953 dnl **** Check for X11 ****
 954
 955 AC_PATH_XTRA
 956
 957 if test "$have_x" = "yes"
 958 then
 959     XLIB="-lX11"
 960     ac_save_CPPFLAGS="$CPPFLAGS"
 961     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 962
 963     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 964     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 965
 966     dnl *** All of the following tests require X11/Xlib.h
 967     AC_CHECK_HEADERS([X11/Xlib.h \
 968                       X11/XKBlib.h \
 969                       X11/Xutil.h \
 970                       X11/Xcursor/Xcursor.h \
 971                       X11/extensions/shape.h \
 972                       X11/extensions/XInput.h \
 973                       X11/extensions/XInput2.h \
 974                       X11/extensions/Xcomposite.h \
 975                       X11/extensions/Xinerama.h \
 976                       X11/extensions/Xrandr.h \
 977                       X11/extensions/Xrender.h \
 978                       X11/extensions/xf86vmode.h \
 979                       X11/extensions/xf86vmproto.h],,,
 980 [#ifdef HAVE_X11_XLIB_H
 981 # include <X11/Xlib.h>
 982 #endif
 983 #ifdef HAVE_X11_XUTIL_H
 984 # include <X11/Xutil.h>
 985 #endif])
 986
 987         dnl *** Check for X keyboard extension
 988         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 989         then
 990               AC_CHECK_LIB(X11, XkbQueryExtension,
 991               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 992               $X_LIBS $XLIB $X_EXTRA_LIBS)
 993         fi
 994
 995         dnl *** Check for X cursor
 996         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 997         then
 998             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 999         fi
1000         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
1001                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
1002
1003         dnl *** Check for X input extension
1004         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
1005         then
1006             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1007         fi
1008         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
1009                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
1010
1011         dnl *** Check for X input 2 extension
1012         if test "x$ac_cv_lib_soname_Xi" != x
1013         then
1014             WINE_NOTICE_WITH(xinput2,[test "$ac_cv_header_X11_extensions_XInput2_h" != "yes"],
1015                              [XInput2 headers not found, the XInput 2 extension won't be supported.])
1016         fi
1017
1018         dnl *** Check for X shape extension
1019         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
1020         then
1021               AC_CHECK_LIB(Xext,XShapeQueryExtension,
1022               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
1023               $X_LIBS $XLIB $X_EXTRA_LIBS)
1024         fi
1025         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
1026                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
1027
1028         dnl *** Check for XFree86 VMODE extension
1029         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
1030         then
1031             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1032         fi
1033         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
1034                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
1035
1036         dnl *** Check for Transform functions in Xrender
1037         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
1038         then
1039             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
1040               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
1041                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
1042                  [Define if Xrender has the XRenderSetPictureTransform function])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1043                AC_CHECK_LIB(Xrender,XRenderCreateLinearGradient,
1044                 [AC_DEFINE(HAVE_XRENDERCREATELINEARGRADIENT, 1,
1045                  [Define if Xrender has the XRenderCreateLinearGradient function])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])],,
1046               [$X_LIBS $XLIB $X_EXTRA_LIBS])
1047
1048         fi
1049         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
1050                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
1051
1052         dnl *** Check for X RandR extension
1053         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
1054         then
1055                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1056 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func; if (func) return 0;]])],
1057                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,
1058                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/Xrandr.h>]],
1059                         [[static typeof(XRRGetScreenResources) *f; if (f) return 0;]])],
1060                       [AC_DEFINE(HAVE_XRRGETSCREENRESOURCES, 1,
1061                         [Define if Xrandr has the XRRGetScreenResources function])])],,
1062                     [$X_LIBS $XLIB $X_EXTRA_LIBS])])
1063         fi
1064         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
1065                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
1066
1067         dnl *** Check for Xinerama extension
1068         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
1069         then
1070                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1071 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func; if (func) return 0;]])],
1072                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1073         fi
1074         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
1075                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
1076
1077         dnl *** Check for X Composite extension
1078         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
1079         then
1080             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1081         fi
1082         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
1083                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
1084
1085         dnl *** Check for XICCallback struct
1086         AC_CHECK_MEMBERS([XICCallback.callback, XEvent.xcookie],,,
1087 [#ifdef HAVE_X11_XLIB_H
1088 #include <X11/Xlib.h>
1089 #endif])
1090
1091     dnl *** End of X11/Xlib.h check
1092
1093     dnl Check for the presence of OpenGL
1094     opengl_msg=""
1095     if test "x$with_opengl" != "xno"
1096     then
1097         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glu.h GL/osmesa.h,,,
1098 [#ifdef HAVE_GL_GLX_H
1099 # include <GL/glx.h>
1100 #endif])
1101         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
1102         then
1103             dnl Check for some problems due to old Mesa versions
1104             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
1105               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;  return (test == GL_UNSIGNED_SHORT_5_6_5);]])],
1106                 [wine_cv_opengl_header_version_OK="yes"],
1107                 [wine_cv_opengl_header_version_OK="no"]))
1108
1109             if test "$wine_cv_opengl_header_version_OK" = "yes"
1110             then
1111                 dnl Check for the presence of the library
1112                 WINE_CHECK_SONAME(GL,glXCreateContext,
1113                              [OPENGL_LIBS="-lGL"
1114                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1115                              [WINE_CHECK_SONAME(GL,glXCreateContext,
1116                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
1117                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1118                                     [if test -f /usr/X11R6/lib/libGL.a
1119                                     then
1120                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1121 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1122                                     else
1123                                         opengl_msg="No OpenGL library found on this system."
1124                                     fi],
1125                                     $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1126                              $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1127                  if test "$ac_cv_header_GL_glu_h" = "yes"
1128                  then
1129                     WINE_CHECK_SONAME(GLU,gluLookAt,,,[$OPENGL_LIBS $X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1130                  fi
1131                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
1132                                  [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1133
1134                  if test "$ac_cv_header_GL_osmesa_h" = "yes"
1135                  then
1136                     WINE_CHECK_SONAME(OSMesa,glAccum,,,[$X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1137                  fi
1138                  WINE_NOTICE_WITH(osmesa,[test "x$ac_cv_lib_soname_OSMesa" = "x"],
1139                                  [libOSMesa ${notice_platform}development files not found (or too old), OpenGL rendering in bitmaps won't be supported.])
1140              else
1141                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
1142              fi
1143          else
1144              opengl_msg="OpenGL development headers not found."
1145          fi
1146          test -n "$opengl_msg" && enable_opengl32=${enable_opengl32:-no}
1147          test "x$ac_cv_lib_soname_GLU" = "x" && enable_glu32=${enable_glu32:-no}
1148     else
1149          enable_opengl32=${enable_opengl32:-no}
1150          enable_glu32=${enable_glu32:-no}
1151     fi
1152     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1153 OpenGL and Direct3D won't be supported.])
1154
1155     CPPFLAGS="$ac_save_CPPFLAGS"
1156 else
1157     XLIB=""
1158     X_CFLAGS=""
1159     X_LIBS=""
1160     enable_winex11_drv=${enable_winex11_drv:-no}
1161     enable_opengl32=${enable_opengl32:-no}
1162     enable_glu32=${enable_glu32:-no}
1163 fi
1164 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1165 without X support, which probably isn't what you want. You will need
1166 to install ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1167
1168 dnl **** Check for OpenCL ****
1169 if test "$ac_cv_header_CL_cl_h" = "yes"
1170 then
1171     AC_CHECK_LIB(OpenCL,clGetPlatformInfo,[AC_SUBST(LIBOPENCL,["-lOpenCL"])])
1172 fi
1173 WINE_NOTICE_WITH(opencl,[test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes],
1174                  [OpenCL ${notice_platform}development files not found, OpenCL won't be supported.])
1175 test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes && enable_opencl=${enable_opencl:-no}
1176
1177 dnl **** Check for libxml2 ****
1178
1179 AC_SUBST(XML2LIBS,"")
1180 AC_SUBST(XML2INCL,"")
1181 AC_SUBST(XSLTINCL,"")
1182 if test "x$with_xml" != "xno"
1183 then
1184     ac_save_CPPFLAGS="$CPPFLAGS"
1185     if test "$PKG_CONFIG" != "false"
1186     then
1187         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
1188         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
1189     else
1190         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
1191         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
1192     fi
1193     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
1194     AC_CHECK_HEADERS([libxml/parser.h libxml/xmlsave.h libxml/SAX2.h])
1195     if test "$ac_cv_header_libxml_parser_h" = "yes" -a "$ac_cv_header_libxml_xmlsave_h" = "yes" -a "$ac_cv_header_libxml_SAX2_h" = "yes"
1196     then
1197         AC_CHECK_LIB(xml2, xmlParseMemory,
1198             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
1199              XML2LIBS="$ac_xml_libs"
1200              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
1201         AC_CHECK_LIB(xml2, xmlReadMemory,
1202             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
1203         AC_CHECK_LIB(xml2, xmlNewDocPI,
1204             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
1205         AC_CHECK_LIB(xml2, xmlSchemaSetParserStructuredErrors,
1206             [AC_DEFINE(HAVE_XMLSCHEMASSETPARSERSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetParserStructuredErrors function])],,$ac_xml_libs)
1207         AC_CHECK_LIB(xml2, xmlSchemaSetValidStructuredErrors,
1208             [AC_DEFINE(HAVE_XMLSCHEMASSETVALIDSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetValidStructuredErrors function])],,$ac_xml_libs)
1209         AC_CHECK_LIB(xml2, xmlFirstElementChild,
1210             [AC_DEFINE(HAVE_XMLFIRSTELEMENTCHILD,1,[Define if libxml2 has the xmlFirstElementChild function])],,$ac_xml_libs)
1211         AC_CHECK_TYPE([xmlDocProperties],
1212             [AC_DEFINE(HAVE_XMLDOC_PROPERTIES,1,[Define if libxml2 has the xmlDocProperties enum])],,[[#include <libxml/tree.h>]])
1213     fi
1214     CPPFLAGS="$ac_save_CPPFLAGS"
1215 fi
1216 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1217                  [libxml2 ${notice_platform}development files not found (or too old), XML won't be supported.])
1218
1219 if test "x$with_xslt" != "xno"
1220 then
1221     if test "$PKG_CONFIG" != "false"
1222     then
1223         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
1224         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
1225     else
1226         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
1227         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
1228     fi
1229     ac_save_CPPFLAGS="$CPPFLAGS"
1230     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
1231     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1232     [#ifdef HAVE_LIBXSLT_PATTERN_H
1233 # include <libxslt/pattern.h>
1234 #endif])
1235     CPPFLAGS="$ac_save_CPPFLAGS"
1236     if test "$ac_cv_header_libxslt_transform_h" = "yes"
1237     then
1238         WINE_CHECK_SONAME(xslt,xsltCompilePattern,
1239                          [XSLTINCL="$ac_xslt_cflags"],,[$ac_xslt_libs])
1240     fi
1241 fi
1242 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1243                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1244
1245 dnl **** Check for libdbus ****
1246 if test "x$with_dbus" != "xno"
1247 then
1248     ac_save_CPPFLAGS="$CPPFLAGS"
1249     if test "$PKG_CONFIG" != "false"
1250     then
1251         ac_dbus_libs="`$PKG_CONFIG --libs dbus-1 2>/dev/null`"
1252         ac_dbus_cflags="`$PKG_CONFIG --cflags dbus-1 2>/dev/null`"
1253         CPPFLAGS="$CPPFLAGS $ac_dbus_cflags"
1254     fi
1255     AC_CHECK_HEADER([dbus/dbus.h],
1256         [WINE_CHECK_SONAME(dbus-1, dbus_connection_close,
1257             [AC_SUBST(DBUSINCL,"$ac_dbus_cflags")],,[$ac_dbus_libs])])
1258     CPPFLAGS="$ac_save_CPPFLAGS"
1259 fi
1260 WINE_NOTICE_WITH(dbus,[test "x$ac_cv_lib_soname_dbus_1" = "x" -a \
1261                             "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1262                  [libdbus ${notice_platform}development files not found, no dynamic device support.])
1263
1264 dnl **** Check for libhal ****
1265 if test "x$with_hal" != "xno" -a "x$ac_cv_lib_soname_dbus_1" != x
1266 then
1267     ac_save_CPPFLAGS="$CPPFLAGS"
1268     if test "$PKG_CONFIG" != "false"
1269     then
1270         ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
1271         ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
1272         CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
1273     fi
1274     AC_CHECK_HEADER([hal/libhal.h],
1275         [WINE_CHECK_SONAME(hal, libhal_ctx_new,
1276             [AC_SUBST(HALINCL,"$ac_hal_cflags")],,[$ac_hal_libs])])
1277     CPPFLAGS="$ac_save_CPPFLAGS"
1278     WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x" -a \
1279                                "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1280                      [libhal ${notice_platform}development files not found, no legacy dynamic device support.])
1281 fi
1282
1283 dnl **** Check for libgnutls ****
1284 if test "x$with_gnutls" != "xno"
1285 then
1286     ac_save_CPPFLAGS="$CPPFLAGS"
1287     if test "$PKG_CONFIG" != "false"
1288     then
1289         ac_gnutls_libs="`$PKG_CONFIG --libs gnutls 2>/dev/null`"
1290         ac_gnutls_cflags="`$PKG_CONFIG --cflags gnutls 2>/dev/null`"
1291         CPPFLAGS="$CPPFLAGS $ac_gnutls_cflags"
1292     fi
1293     AC_CHECK_HEADER(gnutls/gnutls.h,
1294         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[static typeof(gnutls_mac_get_key_size) *func; if (func) return 0;]])],
1295             [WINE_CHECK_SONAME(gnutls,gnutls_global_init,
1296                 [AC_SUBST(GNUTLSINCL,"$ac_gnutls_cflags")],,[$ac_gnutls_libs])])])
1297     CPPFLAGS="$ac_save_CPPFLAGS"
1298 fi
1299 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1300                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1301
1302 dnl **** Check which curses lib to use ***
1303 CURSESLIBS=""
1304 if test "$ac_cv_header_ncurses_h" = "yes"
1305 then
1306     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1307 elif test "$ac_cv_header_curses_h" = "yes"
1308 then
1309     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1310 fi
1311 ac_save_LIBS="$LIBS"
1312 LIBS="$LIBS $CURSESLIBS"
1313 AC_CHECK_FUNCS(mousemask)
1314 LIBS="$ac_save_LIBS"
1315 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1316                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1317
1318 dnl **** Check for SANE ****
1319 if test "x$with_sane" != "xno"
1320 then
1321     ac_save_CPPFLAGS="$CPPFLAGS"
1322     AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
1323     if test "$sane_devel" != "no"
1324     then
1325         ac_sane_incl="`$sane_devel --cflags`"
1326         ac_sane_libs="`$sane_devel --ldflags`"
1327         CPPFLAGS="$CPPFLAGS $ac_sane_incl"
1328     fi
1329     AC_CHECK_HEADER(sane/sane.h,
1330         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
1331     CPPFLAGS="$ac_save_CPPFLAGS"
1332 fi
1333 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1334                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1335
1336 dnl **** Check for libv4l1 ****
1337 if test "x$with_v4l" != "xno"
1338 then
1339     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1340 fi
1341 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1342                  [libv4l ${notice_platform}development files not found.])
1343
1344 dnl **** Check for libgphoto2 ****
1345 if test "x$with_gphoto" != "xno"
1346 then
1347     ac_save_CPPFLAGS="$CPPFLAGS"
1348     AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
1349     AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
1350     if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
1351     then
1352         ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
1353         ac_gphoto2_libs=""
1354         for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
1355         do
1356             case "$i" in
1357             -L/usr/lib|-L/usr/lib64) ;;
1358             -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
1359             esac
1360         done
1361         CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
1362     fi
1363     ac_gphoto2_libs=${ac_gphoto2_libs:-"-lgphoto2"}
1364     AC_CHECK_HEADER(gphoto2-camera.h,
1365                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
1366                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
1367                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
1368                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
1369                                   [$ac_gphoto2_libs])])
1370     CPPFLAGS="$ac_save_CPPFLAGS"
1371 fi
1372 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1373                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1374
1375
1376 dnl **** Check for resolver library ***
1377 if test "$ac_cv_header_resolv_h" = "yes"
1378 then
1379     ac_save_LIBS="$LIBS"
1380     for lib in '' -lresolv
1381     do
1382       LIBS="$lib $ac_save_LIBS"
1383       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1384 #include <netinet/in.h>
1385 #endif
1386 #include <resolv.h>]],[[res_query("foo",ns_c_in,0,0,0);]])],
1387         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1388          AC_SUBST(RESOLVLIBS,"$lib")])
1389       if test "${RESOLVLIBS+set}" = set; then
1390         break
1391       fi
1392     done
1393     LIBS="$ac_save_LIBS"
1394 fi
1395
1396 dnl **** Check for LittleCMS ***
1397 AC_SUBST(LCMSLIBS,"")
1398 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
1399 then
1400     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
1401         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
1402          LCMSLIBS="-llcms"])
1403 fi
1404 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
1405                  [liblcms ${notice_platform}development files not found, Color Management won't be supported.])
1406
1407 dnl **** Check for FreeType 2 ****
1408 if test "x$with_freetype" != "xno"
1409 then
1410     if test "$PKG_CONFIG" != "false"
1411     then
1412         ac_freetype_incl="`$PKG_CONFIG --cflags freetype2 2>/dev/null`"
1413         ac_freetype_libs="`$PKG_CONFIG --libs freetype2 2>/dev/null`"
1414     else
1415         AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],no)
1416         if test "$ft_devel" != "no"
1417         then
1418             ac_freetype_incl=`$ft_devel --cflags`
1419             ac_freetype_libs=`$ft_devel --libs`
1420         fi
1421     fi
1422     ac_freetype_libs=${ac_freetype_libs:-"-lfreetype"}
1423     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
1424     if test "$ft_lib" = "yes"
1425     then
1426         ac_save_CPPFLAGS="$CPPFLAGS"
1427         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1428         AC_CHECK_HEADERS(ft2build.h \
1429                          freetype/freetype.h \
1430                          freetype/ftglyph.h \
1431                          freetype/fttypes.h \
1432                          freetype/tttables.h \
1433                          freetype/ftsnames.h \
1434                          freetype/ttnameid.h \
1435                          freetype/ftoutln.h \
1436                          freetype/ftwinfnt.h \
1437                          freetype/ftmodapi.h \
1438                          freetype/ftlcdfil.h,,,
1439                          [#ifdef HAVE_FT2BUILD_H
1440                           # include <ft2build.h>
1441                           #endif])
1442         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1443                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1444           [Define if you have the <freetype/fttrigon.h> header file.])
1445                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1446         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1447         dnl Check that we have at least freetype/freetype.h
1448         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1449         then
1450             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1451             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1452             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1453         fi
1454     fi
1455 fi
1456 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType ${notice_platform}development files not found. Fonts will not be built.])
1457 test "x$FREETYPELIBS" = "x" && enable_fonts=${enable_fonts:-no}
1458
1459 dnl **** Check for parport (currently Linux only) ****
1460 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1461  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1462 # include <sys/ioctl.h>
1463 #endif
1464 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1465     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1466 if test "$ac_cv_c_ppdev" = "yes"
1467 then
1468     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1469 fi
1470
1471 dnl **** Check for pthread functions ****
1472 WINE_CHECK_LIB_FUNCS(\
1473         pthread_attr_get_np \
1474         pthread_getattr_np \
1475         pthread_getthreadid_np \
1476         pthread_get_stackaddr_np \
1477         pthread_get_stacksize_np,
1478         [$LIBPTHREAD])
1479
1480 dnl **** Check for zlib ****
1481 if test "$ac_cv_header_zlib_h" = "yes"
1482 then
1483     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1484                             AC_SUBST(ZLIB,"-lz")])
1485 fi
1486 WINE_NOTICE_WITH(zlib,[test "x$ZLIB" = "x"],[libz ${notice_platform}development files not found, data compression won't be supported.])
1487
1488 dnl **** Check for gettextpo ****
1489 if test "x$enable_tools" != xno
1490 then
1491     if test "$ac_cv_header_gettext_po_h" = "yes"
1492     then
1493         AC_CHECK_LIB(gettextpo,po_message_msgctxt,
1494                      [AC_DEFINE(HAVE_LIBGETTEXTPO,1,[Define to 1 if you have the `gettextpo' library (-lgettextpo).])
1495                       AC_SUBST(LIBGETTEXTPO,"-lgettextpo")])
1496     fi
1497     test "x$with_gettextpo" != xyes || WINE_NOTICE_WITH(gettextpo,[test "x$LIBGETTEXTPO" = "x"],
1498           [GetText ${notice_platform}development files not found (or too old), po files can't be rebuilt.])
1499 fi
1500
1501 dnl **** Check for gstreamer ****
1502 if test "x$with_gstreamer" != "xno"
1503 then
1504     ac_save_CPPFLAGS="$CPPFLAGS"
1505     if test "$PKG_CONFIG" != "false"; then
1506         ac_gst_incl=""
1507         for i in `$PKG_CONFIG --cflags gstreamer-app-0.10 2>/dev/null`
1508         do
1509             case "$i" in
1510                 -I*) ac_gst_incl="$ac_gst_incl $i";;
1511             esac
1512         done
1513         ac_gst_libs="`$PKG_CONFIG --libs gstreamer-app-0.10 2>/dev/null`"
1514         CPPFLAGS="$CPPFLAGS $ac_gst_incl"
1515         AC_CHECK_HEADER([gst/gstpad.h],
1516           [AC_CHECK_HEADER([gst/app/gstappsink.h],
1517              [AC_MSG_CHECKING([whether gint64 defined by gst/app/gstappsink.h is indeed 64-bit])
1518               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gst/app/gstappsink.h>]],
1519                                                  [[static int a[sizeof(gint64) > 4 ? 1 : -1]; if (a[0]) return 0;]])],
1520                 [AC_MSG_RESULT([yes])
1521                  AC_CHECK_LIB(gstreamer-0.10,gst_pad_get_caps_reffed,
1522                    [AC_CHECK_LIB(gstapp-0.10,gst_app_buffer_new,
1523                       [AC_SUBST(GSTREAMER_LIBS,"$ac_gst_libs")
1524                        AC_SUBST(GSTREAMER_INCL,"$ac_gst_incl")],,[$ac_gst_libs])])],
1525                 [AC_MSG_RESULT([no])])])])
1526     fi
1527     CPPFLAGS="$ac_save_CPPFLAGS"
1528 fi
1529 WINE_NOTICE_WITH(gstreamer,[test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" != xyes -a "x$ac_cv_header_QuickTime_ImageCompression_h" != xyes],
1530                  [gstreamer-0.10 base plugins ${notice_platform}development files not found, gstreamer support disabled])
1531 test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" = xyes || enable_winegstreamer=${enable_winegstreamer:-no}
1532
1533 dnl **** Check for ALSA 1.x ****
1534 AC_SUBST(ALSALIBS,"")
1535 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1536 then
1537     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access_mask,
1538         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1539 #include <alsa/asoundlib.h>
1540 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1541 #include <sys/asoundlib.h>
1542 #endif]], [[snd_pcm_hw_params_get_access_mask(NULL, NULL)]])],
1543                         [ALSALIBS="-lasound"])])
1544 fi
1545
1546 dnl **** Check for OSSv4 ****
1547 if test "x$with_oss" != xno
1548 then
1549     ac_save_CPPFLAGS="$CPPFLAGS"
1550     if test -f /etc/oss.conf
1551     then
1552         . /etc/oss.conf
1553     fi
1554     ac_oss_incl="-I${OSSLIBDIR:-/usr/lib/oss}/include"
1555     CPPFLAGS="$CPPFLAGS $ac_oss_incl"
1556     AC_CHECK_HEADER([sys/soundcard.h],
1557         [AC_CHECK_MEMBERS([oss_sysinfo.numaudioengines],
1558                           [AC_SUBST(OSS4INCL,"$ac_oss_incl")],,
1559                           [#include <sys/soundcard.h>])])
1560     CPPFLAGS="$ac_save_CPPFLAGS"
1561     if test "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes
1562     then
1563         WINE_NOTICE([OSS sound system found but too old (OSSv4 needed), OSS won't be supported.])
1564     fi
1565 fi
1566
1567 dnl **** Check for capi4linux ****
1568
1569 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1570 then
1571     WINE_CHECK_SONAME(capi20,capi20_register)
1572 fi
1573 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1574                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1575
1576 dnl **** Check for cups ****
1577 AC_SUBST(CUPSINCL,"")
1578 if test "x$with_cups" != "xno"
1579 then
1580     ac_save_CPPFLAGS="$CPPFLAGS"
1581     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1582     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1583     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1584     AC_CHECK_HEADERS(cups/cups.h,
1585             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1586                        [CUPSINCL="$ac_cups_cflags"],,
1587                        [$ac_cups_libs])])
1588     CPPFLAGS="$ac_save_CPPFLAGS"
1589 fi
1590 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1591                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1592
1593 dnl **** Check for fontconfig ****
1594 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1595 then
1596     WINE_CHECK_SONAME(fontconfig,FcInit)
1597 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1598 then
1599     dnl fontconfig is in the X directory on Mac OS X
1600     ac_save_CPPFLAGS="$CPPFLAGS"
1601     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1602     $as_unset ac_cv_header_fontconfig_fontconfig_h
1603     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1604     CPPFLAGS="$ac_save_CPPFLAGS"
1605     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1606     then
1607         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1608         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1609     fi
1610 fi
1611 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1612                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1613
1614 dnl **** Check for SSL ****
1615 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1616 then
1617     WINE_CHECK_SONAME(ssl,SSL_library_init)
1618     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1619 fi
1620 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1621                  [OpenSSL ${notice_platform}development files not found, SSL won't be supported.])
1622
1623 dnl **** Check for gsm codec ****
1624 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1625 then
1626     WINE_CHECK_SONAME(gsm,gsm_create)
1627 fi
1628 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1629                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1630
1631 dnl **** Check for libjpeg ****
1632 if test "$ac_cv_header_jpeglib_h" = "yes"
1633 then
1634     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1635 fi
1636 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1637                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1638
1639 dnl **** Check for libpng ****
1640 if test "$ac_cv_header_png_h" = "yes"
1641 then
1642     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm -lz,[[libpng[[0-9]]*]])
1643     AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1644         [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])]
1645         ,,-lm -lz)
1646 elif test -n "$X_CFLAGS" -a "x$with_png" != "xno"
1647 then
1648     dnl libpng is in the X directory on Mac OS X
1649     ac_save_CPPFLAGS="$CPPFLAGS"
1650     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1651     $as_unset ac_cv_header_png_h
1652     AC_CHECK_HEADERS([png.h])
1653     CPPFLAGS="$ac_save_CPPFLAGS"
1654     if test "$ac_cv_header_png_h" = "yes"
1655     then
1656         AC_SUBST(PNGINCL,"$X_CFLAGS")
1657         WINE_CHECK_SONAME(png,png_create_read_struct,,,[$X_LIBS -lm -lz],[[libpng[[0-9]]*]])
1658         AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1659                 [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1)],,[$X_LIBS -lm -lz])
1660     fi
1661 fi
1662 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1663                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1664
1665 dnl **** Check for libtiff ****
1666 if test "$ac_cv_header_tiffio_h" = "yes"
1667 then
1668     WINE_CHECK_SONAME(tiff,TIFFClientOpen)
1669 fi
1670 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1671                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1672
1673 dnl **** Check for mpg123 ****
1674 if test "$ac_cv_header_mpg123_h" = "yes"
1675 then
1676     AC_CHECK_LIB(mpg123,mpg123_feed,[AC_SUBST(LIBMPG123,"-lmpg123")])
1677 fi
1678 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1679                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1680 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_header_AudioToolbox_AudioConverter_h" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1681
1682 dnl **** Check for OpenAL 1.1 ****
1683 if test "$ac_cv_header_AL_al_h" = "yes"
1684 then
1685     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1686                       ac_cv_lib_openal=yes
1687                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1688 fi
1689 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1690                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1691 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1692
1693 dnl **** Check for libkstat ****
1694 if test "$ac_cv_header_kstat_h" = "yes"
1695 then
1696     AC_CHECK_LIB(kstat,kstat_open,
1697                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1698                   AC_SUBST(LIBKSTAT,"-lkstat")])
1699 fi
1700
1701 dnl **** Check for libodbc ****
1702 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1703
1704 dnl **** Disable unsupported winmm drivers ****
1705 test -n "$ALSALIBS" || enable_winealsa_drv=${enable_winealsa_drv:-no}
1706 test -n "$COREAUDIO" || enable_winecoreaudio_drv=${enable_winecoreaudio_drv:-no}
1707 test "x$ac_cv_member_oss_sysinfo_numaudioengines" = xyes || enable_wineoss_drv=${enable_wineoss_drv:-no}
1708 test "$ac_cv_header_linux_joystick_h" = "yes" || enable_winejoystick_drv=${enable_winejoystick_drv:-no}
1709
1710 dnl **** Check for any sound system ****
1711 if test "x$ALSALIBS$COREAUDIO" = "x" -a \
1712         "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes -a \
1713         "x$with_alsa$with_coreaudio$with_oss" != xnonono
1714 then
1715     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1716 fi
1717
1718 dnl **** Check for gcc specific options ****
1719
1720 AC_SUBST(EXTRACFLAGS,"")
1721 if test "x${GCC}" = "xyes"
1722 then
1723   EXTRACFLAGS="-Wall -pipe"
1724
1725   dnl Check for strength-reduce bug
1726   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1727                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1728 [[static int Array[[3]];
1729   unsigned int B = 3;
1730   int i;
1731   for(i=0; i<B; i++) Array[[i]] = i - 3;
1732   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1733   L[[i]] = 4;
1734   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1735     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1736   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1737   then
1738     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1739   fi
1740
1741   dnl Check for some compiler flags
1742   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1743   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1744   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1745   WINE_TRY_CFLAGS([-Wempty-body])
1746   WINE_TRY_CFLAGS([-Wignored-qualifiers])
1747   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1748   WINE_TRY_CFLAGS([-Wtype-limits])
1749   WINE_TRY_CFLAGS([-Wunused-but-set-parameter])
1750   WINE_TRY_CFLAGS([-Wwrite-strings])
1751
1752   dnl On Darwin, prefer stabs; everywhere else, default to dwarf-2 debug info
1753   for ac_flag in $CFLAGS; do
1754     case $ac_flag in
1755       -g) case $host_os in
1756             darwin*) WINE_TRY_CFLAGS([-gstabs+]) ;;
1757             *) WINE_TRY_CFLAGS([-gdwarf-2])
1758                WINE_TRY_CFLAGS([-gstrict-dwarf]) ;;
1759           esac ;;
1760     esac
1761   done
1762
1763   dnl gcc-4.6+ omits frame pointers by default, breaking some copy protections
1764   case $host_cpu in
1765     *i[[3456789]]86*) WINE_TRY_CFLAGS([-fno-omit-frame-pointer]) ;;
1766   esac
1767
1768   dnl mingw uses Windows 64-bit types, not Unix ones
1769   case $host in
1770     x86_64-*mingw32*|x86_64-*cygwin*) WINE_TRY_CFLAGS([-Wno-format]) ;;
1771   esac
1772
1773   dnl Check for noisy string.h
1774   saved_CFLAGS="$CFLAGS"
1775   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1776   AC_CACHE_CHECK([for broken string.h that generates warnings with -Wpointer-arith], ac_cv_c_string_h_warnings,
1777       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1778   CFLAGS="$saved_CFLAGS"
1779   if test "$ac_cv_c_string_h_warnings" = "no"
1780   then
1781     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1782   fi
1783
1784   dnl Check for noisy string.h on logical ops
1785   saved_CFLAGS="$CFLAGS"
1786   CFLAGS="$CFLAGS -Wlogical-op -Werror"
1787   AC_CACHE_CHECK([for broken string.h that generates warnings with -Wlogical-op], ac_cv_c_logicalop_noisy,
1788       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[char*f(const char *h,char n) {return strchr(h,n);}]])],[ac_cv_c_logicalop_noisy=no],[ac_cv_c_logicalop_noisy=yes]))
1789   CFLAGS="$saved_CFLAGS"
1790   if test "$ac_cv_c_logicalop_noisy" = "no"
1791   then
1792     EXTRACFLAGS="$EXTRACFLAGS -Wlogical-op"
1793   fi
1794
1795   dnl Enable -Werror for maintainer mode
1796   if test "x$enable_maintainer_mode" = "xyes"
1797   then
1798       WINE_TRY_CFLAGS([-Werror])
1799   fi
1800
1801   dnl Check for ms_hook_prologue support
1802   saved_CFLAGS="$CFLAGS"
1803   CFLAGS="$CFLAGS -Werror"
1804   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1805                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1806                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1807   CFLAGS="$saved_CFLAGS"
1808   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1809   then
1810       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1811                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1812   else
1813       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1814   fi
1815 fi
1816
1817 dnl **** Disable Fortify, it has too many false positives
1818
1819 AC_CACHE_CHECK([for the need to disable Fortify], ac_cv_c_fortify_enabled,
1820     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]],
1821 [[#if defined(__USE_FORTIFY_LEVEL) && __USE_FORTIFY_LEVEL > 0
1822 #error Fortify enabled
1823 #endif]])],
1824         [ac_cv_c_fortify_enabled=no],[ac_cv_c_fortify_enabled=yes]))
1825 if test "$ac_cv_c_fortify_enabled" = yes
1826 then
1827     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=0"
1828 fi
1829
1830 dnl **** Check for underscore on external symbols ****
1831
1832 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1833     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1834                       [extern int ac_test;],
1835                       [if (ac_test) return 1],
1836                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1837
1838 case $host_cpu in
1839   *i[[3456789]]86*)
1840     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1841         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1842 [#ifndef _MSC_VER
1843 #define __stdcall __attribute__((__stdcall__))
1844 #endif
1845 int __stdcall ac_test(int i) { return i; }],
1846                           [if (ac_test(1)) return 1],
1847                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1848   *) ac_cv_c_stdcall_suffix="no" ;;
1849 esac
1850
1851 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1852 if test "$ac_cv_c_extern_prefix" = "yes"
1853 then
1854     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1855     asm_name_prefix="_"
1856 else
1857     AC_DEFINE([__ASM_NAME(name)], [name])
1858     asm_name_prefix=""
1859 fi
1860
1861 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1862 if test "$ac_cv_c_stdcall_suffix" = "yes"
1863 then
1864     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1865 else
1866     AC_DEFINE([__ASM_STDCALL(args)],[""])
1867 fi
1868
1869 dnl **** Check how to define a function in assembly code ****
1870
1871 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1872   WINE_TRY_ASM_LINK(
1873       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1874       ac_cv_asm_func_def=".def",
1875     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1876       ac_cv_asm_func_def=".type @function",
1877     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1878       ac_cv_asm_func_def=".type 2",
1879       ac_cv_asm_func_def="unknown")])]))
1880
1881 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1882 case "$ac_cv_asm_func_def" in
1883   ".def")
1884      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1885      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1886   ".type @function")
1887      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1888      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1889   ".type 2")
1890      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1891      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1892   *)
1893      AC_DEFINE([__ASM_FUNC(name)], [""])
1894      asm_func_header="" ;;
1895 esac
1896
1897 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1898     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1899                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1900
1901 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1902     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1903                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1904
1905 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1906     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1907                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1908
1909 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1910 asm_func_trailer=""
1911 if test "$ac_cv_c_dot_previous" = "yes"
1912 then
1913    asm_func_trailer="\\n\\t.previous"
1914 fi
1915 if test "$ac_cv_c_cfi_support" = "yes"
1916 then
1917    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1918    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1919    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1920    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1921 else
1922    AC_DEFINE([__ASM_CFI(str)],[""])
1923 fi
1924
1925 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1926
1927 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1928 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1929 then
1930     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1931 else
1932     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1933 fi
1934 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1935           [Define to a macro to generate an assembly function with C calling convention])
1936 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1937           [Define to a macro to generate an assembly function with stdcall calling convention])
1938
1939 dnl **** Platform-specific checks ****
1940
1941 AC_SUBST(LDPATH,"")
1942 case $build_os in
1943   cygwin*|mingw32*)
1944     AC_SUBST(TOOLSEXT,".exe")
1945     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1946     ;;
1947   darwin*|macosx*)
1948     ;;
1949   *)
1950     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1951     ;;
1952 esac
1953
1954 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1955 case $host_os in
1956   mingw32*)
1957     AC_SUBST(CRTLIBS,"-lmsvcrt")
1958     AC_SUBST(SOCKETLIBS,"-L\$(top_builddir)/dlls/ws2_32 -lws2_32")
1959     ;;
1960 esac
1961
1962 AC_SUBST(MAIN_BINARY,"wine")
1963 test "x$enable_win64" != "xyes" || MAIN_BINARY="wine64"
1964
1965 case $host_os in
1966   linux*)
1967     case $host_cpu in
1968       *i[[3456789]]86*) AC_SUBST(EXTRA_BINARIES,"wine-preloader") ;;
1969       x86_64*) AC_SUBST(EXTRA_BINARIES,"wine64-preloader") ;;
1970     esac
1971     ;;
1972 esac
1973
1974 dnl **** Check for functions ****
1975
1976 ac_save_CFLAGS="$CFLAGS"
1977 CFLAGS="$CFLAGS $BUILTINFLAG"
1978 AC_CHECK_FUNCS(\
1979         _finite \
1980         _isnan \
1981         _pclose \
1982         _popen \
1983         _snprintf \
1984         _spawnvp \
1985         _strdup \
1986         _stricmp \
1987         _strnicmp \
1988         _strtoi64 \
1989         _strtoui64 \
1990         _vsnprintf \
1991         asctime_r \
1992         chsize \
1993         dlopen \
1994         epoll_create \
1995         ffs \
1996         finite \
1997         fnmatch \
1998         fork \
1999         fpclass \
2000         fstatfs \
2001         fstatvfs \
2002         ftruncate \
2003         futimes \
2004         futimesat \
2005         getattrlist \
2006         getdirentries \
2007         getopt_long \
2008         getpagesize \
2009         getpwuid \
2010         gettimeofday \
2011         getuid \
2012         kqueue \
2013         lstat \
2014         memmove \
2015         mmap \
2016         pclose \
2017         pipe2 \
2018         poll \
2019         popen \
2020         port_create \
2021         prctl \
2022         pread \
2023         pwrite \
2024         readdir \
2025         readlink \
2026         sched_yield \
2027         select \
2028         setproctitle \
2029         setrlimit \
2030         settimeofday \
2031         sigaltstack \
2032         sigprocmask \
2033         snprintf \
2034         spawnvp \
2035         statfs \
2036         statvfs \
2037         strcasecmp \
2038         strdup \
2039         strerror \
2040         strncasecmp \
2041         strtold \
2042         strtoll \
2043         strtoull \
2044         symlink \
2045         tcgetattr \
2046         thr_kill2 \
2047         timegm \
2048         usleep \
2049         vsnprintf \
2050         wait4 \
2051         waitpid \
2052 )
2053 CFLAGS="$ac_save_CFLAGS"
2054
2055 dnl Check for -ldl
2056 if test "$ac_cv_func_dlopen" = no
2057 then
2058     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
2059 fi
2060 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
2061
2062 dnl Check for -lpoll for Mac OS X/Darwin
2063 if test "$ac_cv_func_poll" = no
2064 then
2065     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
2066 fi
2067
2068 dnl Check for -lnsl for Solaris
2069 AC_SEARCH_LIBS(gethostbyname, nsl)
2070
2071 dnl Check for -lsocket for Solaris
2072 AC_SEARCH_LIBS(connect, socket)
2073
2074 dnl Check for -lresolv for Solaris
2075 AC_SEARCH_LIBS(inet_aton, resolv)
2076
2077 dnl **** Check for functions which may rely on -lsocket on Solaris.
2078 AC_CHECK_FUNCS(\
2079         getaddrinfo \
2080         getnameinfo \
2081         getnetbyname \
2082         getprotobyname \
2083         getprotobynumber \
2084         getservbyport \
2085         inet_network \
2086         inet_ntop \
2087         inet_pton \
2088         sendmsg \
2089         socketpair \
2090 )
2091
2092 dnl **** Check for OpenLDAP ***
2093 AC_SUBST(LDAPLIBS,"")
2094 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
2095 then
2096     AC_CHECK_TYPE(LDAPSortKey,
2097         [AC_CHECK_LIB(ldap_r, ldap_initialize,
2098             [AC_CHECK_LIB(lber, ber_init,
2099                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
2100                  LDAPLIBS="-lldap_r -llber"],,
2101                  [$LIBPTHREAD])],,
2102                  [$LIBPTHREAD])],,
2103         [#include <ldap.h>])
2104     WINE_CHECK_LIB_FUNCS(\
2105         ldap_count_references \
2106         ldap_first_reference \
2107         ldap_next_reference \
2108         ldap_parse_reference \
2109         ldap_parse_sort_control \
2110         ldap_parse_sortresponse_control \
2111         ldap_parse_vlv_control \
2112         ldap_parse_vlvresponse_control,
2113         [$LDAPLIBS $LIBPTHREAD])
2114 fi
2115 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
2116                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
2117
2118 AC_CACHE_CHECK([whether mkdir takes only one argument],
2119         wine_cv_one_arg_mkdir,
2120         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
2121                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
2122 if test "$wine_cv_one_arg_mkdir" = "yes"
2123 then
2124   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
2125 fi
2126
2127 AC_CACHE_CHECK([for sched_setaffinity],wine_cv_have_sched_setaffinity,
2128                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2129 [[#define _GNU_SOURCE
2130 #include <sched.h>]], [[sched_setaffinity(0, 0, 0);]])],[wine_cv_have_sched_setaffinity=yes],[wine_cv_have_sched_setaffinity=no]))
2131 if test "$wine_cv_have_sched_setaffinity" = "yes"
2132 then
2133   AC_DEFINE(HAVE_SCHED_SETAFFINITY, 1, [Define to 1 if you have the `sched_setaffinity' function.])
2134 fi
2135
2136 dnl **** Check for types ****
2137
2138 AC_C_INLINE
2139 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
2140 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
2141 #include <signal.h>])
2142 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
2143
2144 AC_CHECK_TYPES([struct xinpgen],,,
2145 [#include <sys/types.h>
2146 #ifdef HAVE_SYS_SOCKET_H
2147 #include <sys/socket.h>
2148 #endif
2149 #ifdef HAVE_SYS_SOCKETVAR_H
2150 #include <sys/socketvar.h>
2151 #endif
2152 #ifdef HAVE_NET_ROUTE_H
2153 #include <net/route.h>
2154 #endif
2155 #ifdef HAVE_NETINET_IN_H
2156 #include <netinet/in.h>
2157 #endif
2158 #ifdef HAVE_NETINET_IN_SYSTM_H
2159 #include <netinet/in_systm.h>
2160 #endif
2161 #ifdef HAVE_NETINET_IP_H
2162 #include <netinet/ip.h>
2163 #endif
2164 #ifdef HAVE_NETINET_IN_PCB_H
2165 #include <netinet/in_pcb.h>
2166 #endif])
2167
2168 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
2169 [#ifdef HAVE_LINUX_INPUT_H
2170 #include <linux/input.h>
2171 #endif])
2172
2173 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
2174                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
2175 if test "$wine_cv_have_sigaddset" = "yes"
2176 then
2177   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
2178 fi
2179
2180
2181 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
2182         wine_cv_linux_gethostbyname_r_6,
2183         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
2184     char *name=0;
2185     struct hostent he;
2186     struct hostent *result;
2187     char *buf=0;
2188     int bufsize=0;
2189     int errnr;
2190     char *addr=0;
2191     int addrlen=0;
2192     int addrtype=0;
2193     gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
2194     gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
2195     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
2196         ])
2197    )
2198    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
2199    then
2200       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
2201                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
2202    fi
2203
2204 if test "$ac_cv_header_linux_joystick_h" = "yes"
2205 then
2206    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
2207         wine_cv_linux_joystick_22_api,
2208         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2209         #include <sys/ioctl.h>
2210         #include <sys/types.h>
2211         #include <linux/joystick.h>
2212
2213         struct js_event blub;
2214         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
2215         #error "no 2.2 header"
2216         #endif
2217         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
2218    )
2219    if test "$wine_cv_linux_joystick_22_api" = "yes"
2220    then
2221       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
2222                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
2223    fi
2224 fi
2225
2226 dnl **** FIXME: what about mixed cases, where we need two of them? ***
2227
2228 dnl Check for statfs members
2229 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
2230 [#include <sys/types.h>
2231 #ifdef HAVE_SYS_PARAM_H
2232 # include <sys/param.h>
2233 #endif
2234 #ifdef HAVE_SYS_MOUNT_H
2235 # include <sys/mount.h>
2236 #endif
2237 #ifdef HAVE_SYS_VFS_H
2238 # include <sys/vfs.h>
2239 #endif
2240 #ifdef HAVE_SYS_STATFS_H
2241 # include <sys/statfs.h>
2242 #endif])
2243
2244 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2245 [#ifdef HAVE_SYS_STATVFS_H
2246 #include <sys/statvfs.h>
2247 #endif])
2248
2249 dnl Check for dirent.d_reclen
2250 AC_CHECK_MEMBERS([struct dirent.d_reclen],,,
2251 [#ifdef HAVE_DIRENT_H
2252 #include <dirent.h>
2253 #endif])
2254
2255 dnl Check for socket structure members
2256 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2257 [#include <sys/types.h>
2258 #ifdef HAVE_SYS_SOCKET_H
2259 # include <sys/socket.h>
2260 #endif
2261 #ifdef HAVE_SYS_UN_H
2262 # include <sys/un.h>
2263 #endif])
2264
2265 dnl Check for scsireq_t and sg_io_hdr_t members
2266 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2267 [#include <sys/types.h>
2268 #ifdef HAVE_SCSI_SG_H
2269 #include <scsi/sg.h>
2270 #endif])
2271
2272 dnl Check for siginfo_t members
2273 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2274
2275 dnl Check for struct mtget members
2276 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2277 [#include <sys/types.h>
2278 #ifdef HAVE_SYS_MTIO_H
2279 #include <sys/mtio.h>
2280 #endif])
2281
2282 dnl Check for struct option
2283 AC_CHECK_MEMBERS([struct option.name],,,
2284 [#ifdef HAVE_GETOPT_H
2285 #include <getopt.h>
2286 #endif])
2287
2288 dnl Check for stat.st_blocks and ns-resolved times
2289 AC_CHECK_MEMBERS([struct stat.st_blocks,struct stat.st_mtim,struct stat.st_ctim,struct stat.st_atim])
2290
2291 dnl Check for sin6_scope_id
2292 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2293 [#ifdef HAVE_SYS_TYPES_H
2294 #include <sys/types.h>
2295 #endif
2296 #ifdef HAVE_NETINET_IN_H
2297 #include <netinet/in.h>
2298 #endif])
2299
2300 dnl Check for ns_msg ptr member
2301 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2302 [#ifdef HAVE_SYS_TYPES_H
2303 #include <sys/types.h>
2304 #endif
2305 #ifdef HAVE_NETINET_IN_H
2306 # include <netinet/in.h>
2307 #endif
2308 #ifdef HAVE_ARPA_NAMESER_H
2309 # include <arpa/nameser.h>
2310 #endif])
2311
2312 dnl Check for struct icmpstat
2313 AC_CHECK_MEMBERS([struct icmpstat.icps_inhist],,,
2314 [#ifdef HAVE_SYS_TYPES_H
2315 #include <sys/types.h>
2316 #endif
2317 #ifdef HAVE_NETINET_IP_H
2318 #include <netinet/ip.h>
2319 #endif
2320 #ifdef HAVE_NETINET_IP_ICMP_H
2321 #include <netinet/ip_icmp.h>
2322 #endif
2323 #ifdef HAVE_NETINET_ICMP_VAR_H
2324 #include <netinet/icmp_var.h>
2325 #endif])
2326
2327 dnl Check for struct icmpstat.icps_outhist
2328 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2329 [#ifdef HAVE_SYS_TYPES_H
2330 #include <sys/types.h>
2331 #endif
2332 #ifdef HAVE_ALIAS_H
2333 #include <alias.h>
2334 #endif
2335 #ifdef HAVE_SYS_SOCKET_H
2336 #include <sys/socket.h>
2337 #endif
2338 #ifdef HAVE_SYS_SOCKETVAR_H
2339 #include <sys/socketvar.h>
2340 #endif
2341 #ifdef HAVE_SYS_TIMEOUT_H
2342 #include <sys/timeout.h>
2343 #endif
2344 #ifdef HAVE_NETINET_IN_H
2345 #include <netinet/in.h>
2346 #endif
2347 #ifdef HAVE_NETINET_IN_SYSTM_H
2348 #include <netinet/in_systm.h>
2349 #endif
2350 #ifdef HAVE_NETINET_IP_H
2351 #include <netinet/ip.h>
2352 #endif
2353 #ifdef HAVE_NETINET_IP_VAR_H
2354 #include <netinet/ip_var.h>
2355 #endif
2356 #ifdef HAVE_NETINET_IP_ICMP_H
2357 #include <netinet/ip_icmp.h>
2358 #endif
2359 #ifdef HAVE_NETINET_ICMP_VAR_H
2360 #include <netinet/icmp_var.h>
2361 #endif])
2362
2363 dnl Check for struct ipstat
2364 AC_CHECK_MEMBERS([struct ipstat.ips_total],,,
2365 [#ifdef HAVE_SYS_TYPES_H
2366 #include <sys/types.h>
2367 #endif
2368 #ifdef HAVE_SYS_SOCKETVAR_H
2369 #include <sys/socketvar.h>
2370 #endif
2371 #ifdef HAVE_NETINET_IN_H
2372 #include <netinet/in.h>
2373 #endif
2374 #ifdef HAVE_NETINET_IP_VAR_H
2375 #include <netinet/ip_var.h>
2376 #endif])
2377
2378 dnl Check for struct ip_stats
2379 AC_CHECK_MEMBERS([struct ip_stats.ips_total],,,
2380 [#ifdef HAVE_NETINET_IP_VAR_H
2381 #include <netinet/ip_var.h>
2382 #endif])
2383
2384 dnl Check for struct tcpstat
2385 AC_CHECK_MEMBERS([struct tcpstat.tcps_connattempt],,,
2386 [#ifdef HAVE_SYS_TYPES_H
2387 #include <sys/types.h>
2388 #endif
2389 #ifdef HAVE_SYS_SOCKETVAR_H
2390 #include <sys/socketvar.h>
2391 #endif
2392 #ifdef HAVE_NETINET_IN_H
2393 #include <netinet/in.h>
2394 #endif
2395 #ifdef HAVE_NETINET_TCP_H
2396 #include <netinet/tcp.h>
2397 #endif
2398 #ifdef HAVE_NETINET_TCP_VAR_H
2399 #include <netinet/tcp_var.h>
2400 #endif])
2401
2402 dnl Check for struct tcp_stats
2403 AC_CHECK_MEMBERS([struct tcp_stats.tcps_connattempt],,,
2404 [#ifdef HAVE_NETINET_TCP_VAR_H
2405 #include <netinet/tcp_var.h>
2406 #endif])
2407
2408 dnl Check for struct udpstat
2409 AC_CHECK_MEMBERS([struct udpstat.udps_ipackets],,,
2410 [#ifdef HAVE_SYS_TYPES_H
2411 #include <sys/types.h>
2412 #endif
2413 #ifdef HAVE_NETINET_IN_H
2414 #include <netinet/in.h>
2415 #endif
2416 #ifdef HAVE_NETINET_IP_VAR_H
2417 #include <netinet/ip_var.h>
2418 #endif
2419 #ifdef HAVE_NETINET_UDP_H
2420 #include <netinet/udp.h>
2421 #endif
2422 #ifdef HAVE_NETINET_UDP_VAR_H
2423 #include <netinet/udp_var.h>
2424 #endif])
2425
2426 dnl Check for struct ifreq.ifr_hwaddr
2427 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2428 [#ifdef HAVE_SYS_TYPES_H
2429 #include <sys/types.h>
2430 #endif
2431 #ifdef HAVE_NET_IF_H
2432 # include <net/if.h>
2433 #endif])
2434
2435 dnl Check for the external timezone variables timezone and daylight
2436 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2437                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2438 if test "$ac_cv_have_timezone" = "yes"
2439 then
2440     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2441 fi
2442 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2443                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2444 if test "$ac_cv_have_daylight" = "yes"
2445 then
2446     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2447 fi
2448
2449 dnl Check for isinf
2450 ac_save_LIBS="$LIBS"
2451 LIBS="$LIBS -lm"
2452 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2453                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2454 if test "$ac_cv_have_isinf" = "yes"
2455 then
2456     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2457 fi
2458
2459 dnl Check for isnan
2460 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2461                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2462 if test "$ac_cv_have_isnan" = "yes"
2463 then
2464     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2465 fi
2466 LIBS="$ac_save_LIBS"
2467
2468 dnl *** check for the need to define platform-specific symbols
2469
2470 case $host_cpu in
2471   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2472   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2473   *sparc64*)        WINE_CHECK_DEFINE([__sparc64__]) ;;
2474   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2475   *powerpc64*)      WINE_CHECK_DEFINE([__powerpc64__]) ;;
2476   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2477   *arm*)            WINE_CHECK_DEFINE([__arm__]) ;;
2478 esac
2479
2480 case $host_vendor in
2481   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2482 esac
2483
2484 dnl **** Generate output files ****
2485
2486 AH_TOP([#ifndef WINE_CROSSTEST
2487 #define __WINE_CONFIG_H])
2488 AH_BOTTOM([#endif /* WINE_CROSSTEST */])
2489
2490 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2491
2492 WINE_CONFIG_SYMLINK(dlls/shell32/AUTHORS,AUTHORS)
2493 WINE_CONFIG_SYMLINK(dlls/wineps.drv/generic.ppd)
2494 WINE_CONFIG_SYMLINK(fonts/marlett.ttf,,enable_fonts)
2495 WINE_CONFIG_SYMLINK(fonts/symbol.ttf,,enable_fonts)
2496 WINE_CONFIG_SYMLINK(fonts/tahoma.ttf,,enable_fonts)
2497 WINE_CONFIG_SYMLINK(fonts/tahomabd.ttf,,enable_fonts)
2498 WINE_CONFIG_SYMLINK(po/LINGUAS)
2499 WINE_CONFIG_SYMLINK(tools/l_intl.nls,,enable_tools)
2500 WINE_CONFIG_SYMLINK(wine,tools/winewrapper)
2501 WINE_CONFIG_SYMLINK(wine64,tools/winewrapper,enable_win64)
2502
2503 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/dibdrv)
2504 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2505 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2506 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2507 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2508 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2509 WINE_CONFIG_EXTRA_DIR(include/wine)
2510
2511 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2512 WINE_CONFIG_MAKERULES([Maketest.rules],[MAKE_TEST_RULES],[Make.rules])
2513 WINE_CONFIG_MAKERULES([dlls/Makedll.rules],[MAKE_DLL_RULES],[Make.rules])
2514 WINE_CONFIG_MAKERULES([dlls/Makeimplib.rules],[MAKE_IMPLIB_RULES],[Make.rules])
2515 WINE_CONFIG_MAKERULES([programs/Makeprog.rules],[MAKE_PROG_RULES],[Make.rules])
2516
2517 WINE_CONFIG_DLL(acledit)
2518 WINE_CONFIG_DLL(aclui,,[implib])
2519 WINE_CONFIG_DLL(activeds,,[implib])
2520 WINE_CONFIG_DLL(actxprxy)
2521 WINE_CONFIG_LIB(adsiid)
2522 WINE_CONFIG_DLL(advapi32,,[implib])
2523 WINE_CONFIG_TEST(dlls/advapi32/tests)
2524 WINE_CONFIG_DLL(advpack,,[implib])
2525 WINE_CONFIG_TEST(dlls/advpack/tests)
2526 WINE_CONFIG_DLL(amstream)
2527 WINE_CONFIG_TEST(dlls/amstream/tests)
2528 WINE_CONFIG_DLL(apphelp)
2529 WINE_CONFIG_TEST(dlls/apphelp/tests)
2530 WINE_CONFIG_DLL(appwiz.cpl,,[po])
2531 WINE_CONFIG_DLL(atl,,[implib])
2532 WINE_CONFIG_TEST(dlls/atl/tests)
2533 WINE_CONFIG_DLL(atl80)
2534 WINE_CONFIG_DLL(authz)
2535 WINE_CONFIG_DLL(avicap32,,[implib])
2536 WINE_CONFIG_DLL(avifil32,,[implib,po])
2537 WINE_CONFIG_TEST(dlls/avifil32/tests)
2538 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2539 WINE_CONFIG_DLL(avrt,,[implib])
2540 WINE_CONFIG_DLL(bcrypt)
2541 WINE_CONFIG_DLL(browseui,,[po])
2542 WINE_CONFIG_TEST(dlls/browseui/tests)
2543 WINE_CONFIG_DLL(cabinet,,[implib])
2544 WINE_CONFIG_TEST(dlls/cabinet/tests)
2545 WINE_CONFIG_DLL(capi2032,,[implib])
2546 WINE_CONFIG_DLL(cards,,[implib])
2547 WINE_CONFIG_DLL(cfgmgr32,,[implib])
2548 WINE_CONFIG_DLL(clusapi,,[implib])
2549 WINE_CONFIG_DLL(comcat)
2550 WINE_CONFIG_TEST(dlls/comcat/tests)
2551 WINE_CONFIG_DLL(comctl32,,[implib,po])
2552 WINE_CONFIG_TEST(dlls/comctl32/tests)
2553 WINE_CONFIG_DLL(comdlg32,,[implib,po])
2554 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2555 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2556 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2557 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2558 WINE_CONFIG_DLL(compstui,,[implib])
2559 WINE_CONFIG_DLL(credui,,[implib,po])
2560 WINE_CONFIG_TEST(dlls/credui/tests)
2561 WINE_CONFIG_DLL(crtdll,,[implib])
2562 WINE_CONFIG_DLL(crypt32,,[implib,po])
2563 WINE_CONFIG_TEST(dlls/crypt32/tests)
2564 WINE_CONFIG_DLL(cryptdlg,,[po])
2565 WINE_CONFIG_DLL(cryptdll,,[implib])
2566 WINE_CONFIG_DLL(cryptnet,,[implib])
2567 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2568 WINE_CONFIG_DLL(cryptui,,[implib,po])
2569 WINE_CONFIG_TEST(dlls/cryptui/tests)
2570 WINE_CONFIG_DLL(ctapi32)
2571 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2572 WINE_CONFIG_DLL(ctl3d32,,[implib])
2573 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2574 WINE_CONFIG_DLL(d3d10,,[implib])
2575 WINE_CONFIG_TEST(dlls/d3d10/tests)
2576 WINE_CONFIG_DLL(d3d10core,,[implib])
2577 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2578 WINE_CONFIG_DLL(d3d8,,[implib])
2579 WINE_CONFIG_TEST(dlls/d3d8/tests)
2580 WINE_CONFIG_DLL(d3d9,,[implib])
2581 WINE_CONFIG_TEST(dlls/d3d9/tests)
2582 WINE_CONFIG_DLL(d3dcompiler_33)
2583 WINE_CONFIG_DLL(d3dcompiler_34)
2584 WINE_CONFIG_DLL(d3dcompiler_35)
2585 WINE_CONFIG_DLL(d3dcompiler_36)
2586 WINE_CONFIG_DLL(d3dcompiler_37)
2587 WINE_CONFIG_DLL(d3dcompiler_38)
2588 WINE_CONFIG_DLL(d3dcompiler_39)
2589 WINE_CONFIG_DLL(d3dcompiler_40)
2590 WINE_CONFIG_DLL(d3dcompiler_41)
2591 WINE_CONFIG_DLL(d3dcompiler_42)
2592 WINE_CONFIG_DLL(d3dcompiler_43,,[implib],[d3dcompiler])
2593 WINE_CONFIG_TEST(dlls/d3dcompiler_43/tests)
2594 WINE_CONFIG_DLL(d3dim,,[implib])
2595 WINE_CONFIG_DLL(d3drm,,[implib])
2596 WINE_CONFIG_TEST(dlls/d3drm/tests)
2597 WINE_CONFIG_DLL(d3dx10_33)
2598 WINE_CONFIG_DLL(d3dx10_34)
2599 WINE_CONFIG_DLL(d3dx10_35)
2600 WINE_CONFIG_DLL(d3dx10_36)
2601 WINE_CONFIG_DLL(d3dx10_37)
2602 WINE_CONFIG_DLL(d3dx10_38)
2603 WINE_CONFIG_DLL(d3dx10_39)
2604 WINE_CONFIG_DLL(d3dx10_40)
2605 WINE_CONFIG_DLL(d3dx10_41)
2606 WINE_CONFIG_DLL(d3dx10_42)
2607 WINE_CONFIG_DLL(d3dx10_43)
2608 WINE_CONFIG_DLL(d3dx9_24)
2609 WINE_CONFIG_DLL(d3dx9_25)
2610 WINE_CONFIG_DLL(d3dx9_26)
2611 WINE_CONFIG_DLL(d3dx9_27)
2612 WINE_CONFIG_DLL(d3dx9_28)
2613 WINE_CONFIG_DLL(d3dx9_29)
2614 WINE_CONFIG_DLL(d3dx9_30)
2615 WINE_CONFIG_DLL(d3dx9_31)
2616 WINE_CONFIG_DLL(d3dx9_32)
2617 WINE_CONFIG_DLL(d3dx9_33)
2618 WINE_CONFIG_DLL(d3dx9_34)
2619 WINE_CONFIG_DLL(d3dx9_35)
2620 WINE_CONFIG_DLL(d3dx9_36,,[implib],[d3dx9])
2621 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2622 WINE_CONFIG_DLL(d3dx9_37)
2623 WINE_CONFIG_DLL(d3dx9_38)
2624 WINE_CONFIG_DLL(d3dx9_39)
2625 WINE_CONFIG_DLL(d3dx9_40)
2626 WINE_CONFIG_DLL(d3dx9_41)
2627 WINE_CONFIG_DLL(d3dx9_42)
2628 WINE_CONFIG_DLL(d3dx9_43)
2629 WINE_CONFIG_DLL(d3dxof,,[implib])
2630 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2631 WINE_CONFIG_DLL(dbgeng,,[implib])
2632 WINE_CONFIG_DLL(dbghelp,,[implib])
2633 WINE_CONFIG_DLL(dciman32,,[implib])
2634 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2635 WINE_CONFIG_DLL(ddraw,,[implib])
2636 WINE_CONFIG_TEST(dlls/ddraw/tests)
2637 WINE_CONFIG_DLL(ddrawex)
2638 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2639 WINE_CONFIG_DLL(devenum,,[po])
2640 WINE_CONFIG_TEST(dlls/devenum/tests)
2641 WINE_CONFIG_DLL(dhcpcsvc)
2642 WINE_CONFIG_DLL(dinput,,[implib,po,staticimplib])
2643 WINE_CONFIG_TEST(dlls/dinput/tests)
2644 WINE_CONFIG_DLL(dinput8,,[implib])
2645 WINE_CONFIG_TEST(dlls/dinput8/tests)
2646 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2647 WINE_CONFIG_DLL(dispex)
2648 WINE_CONFIG_TEST(dlls/dispex/tests)
2649 WINE_CONFIG_DLL(display.drv16,enable_win16)
2650 WINE_CONFIG_DLL(dmband)
2651 WINE_CONFIG_TEST(dlls/dmband/tests)
2652 WINE_CONFIG_DLL(dmcompos)
2653 WINE_CONFIG_DLL(dmime)
2654 WINE_CONFIG_TEST(dlls/dmime/tests)
2655 WINE_CONFIG_DLL(dmloader)
2656 WINE_CONFIG_TEST(dlls/dmloader/tests)
2657 WINE_CONFIG_DLL(dmscript)
2658 WINE_CONFIG_DLL(dmstyle)
2659 WINE_CONFIG_DLL(dmsynth)
2660 WINE_CONFIG_TEST(dlls/dmsynth/tests)
2661 WINE_CONFIG_DLL(dmusic)
2662 WINE_CONFIG_TEST(dlls/dmusic/tests)
2663 WINE_CONFIG_DLL(dmusic32,,[implib])
2664 WINE_CONFIG_DLL(dnsapi,,[implib])
2665 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2666 WINE_CONFIG_DLL(dplay,,[implib])
2667 WINE_CONFIG_DLL(dplayx,,[implib])
2668 WINE_CONFIG_TEST(dlls/dplayx/tests)
2669 WINE_CONFIG_DLL(dpnaddr)
2670 WINE_CONFIG_DLL(dpnet,,[implib])
2671 WINE_CONFIG_TEST(dlls/dpnet/tests)
2672 WINE_CONFIG_DLL(dpnhpast)
2673 WINE_CONFIG_DLL(dpnlobby)
2674 WINE_CONFIG_DLL(dpwsockx)
2675 WINE_CONFIG_DLL(drmclien)
2676 WINE_CONFIG_DLL(dsound,,[implib])
2677 WINE_CONFIG_TEST(dlls/dsound/tests)
2678 WINE_CONFIG_DLL(dssenh)
2679 WINE_CONFIG_TEST(dlls/dssenh/tests)
2680 WINE_CONFIG_DLL(dswave)
2681 WINE_CONFIG_DLL(dwmapi,,[implib])
2682 WINE_CONFIG_DLL(dwrite,,[implib])
2683 WINE_CONFIG_TEST(dlls/dwrite/tests)
2684 WINE_CONFIG_DLL(dxdiagn,,[po])
2685 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2686 WINE_CONFIG_LIB(dxerr8)
2687 WINE_CONFIG_LIB(dxerr9)
2688 WINE_CONFIG_DLL(dxgi,,[implib])
2689 WINE_CONFIG_TEST(dlls/dxgi/tests)
2690 WINE_CONFIG_LIB(dxguid)
2691 WINE_CONFIG_DLL(explorerframe)
2692 WINE_CONFIG_TEST(dlls/explorerframe/tests)
2693 WINE_CONFIG_DLL(faultrep,,[implib])
2694 WINE_CONFIG_TEST(dlls/faultrep/tests)
2695 WINE_CONFIG_DLL(fltlib)
2696 WINE_CONFIG_DLL(fusion)
2697 WINE_CONFIG_TEST(dlls/fusion/tests)
2698 WINE_CONFIG_DLL(fwpuclnt)
2699 WINE_CONFIG_DLL(gameux)
2700 WINE_CONFIG_TEST(dlls/gameux/tests)
2701 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2702 WINE_CONFIG_DLL(gdi32,,[implib,po])
2703 WINE_CONFIG_TEST(dlls/gdi32/tests)
2704 WINE_CONFIG_DLL(gdiplus,,[implib])
2705 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2706 WINE_CONFIG_DLL(glu32,,[implib])
2707 WINE_CONFIG_DLL(gphoto2.ds,,[po])
2708 WINE_CONFIG_DLL(gpkcsp)
2709 WINE_CONFIG_DLL(hal)
2710 WINE_CONFIG_DLL(hhctrl.ocx,,[po])
2711 WINE_CONFIG_DLL(hid,,[implib])
2712 WINE_CONFIG_DLL(hlink,,[implib])
2713 WINE_CONFIG_TEST(dlls/hlink/tests)
2714 WINE_CONFIG_DLL(hnetcfg)
2715 WINE_CONFIG_DLL(httpapi)
2716 WINE_CONFIG_DLL(iccvid,,[po])
2717 WINE_CONFIG_DLL(icmp)
2718 WINE_CONFIG_DLL(ieframe,,[implib,po])
2719 WINE_CONFIG_TEST(dlls/ieframe/tests)
2720 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2721 WINE_CONFIG_DLL(imaadp32.acm)
2722 WINE_CONFIG_DLL(imagehlp,,[implib])
2723 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2724 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2725 WINE_CONFIG_DLL(imm32,,[implib])
2726 WINE_CONFIG_TEST(dlls/imm32/tests)
2727 WINE_CONFIG_DLL(inetcomm,,[implib])
2728 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2729 WINE_CONFIG_DLL(inetcpl.cpl,,[po])
2730 WINE_CONFIG_DLL(inetmib1)
2731 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2732 WINE_CONFIG_DLL(infosoft)
2733 WINE_CONFIG_TEST(dlls/infosoft/tests)
2734 WINE_CONFIG_DLL(initpki)
2735 WINE_CONFIG_DLL(inkobj)
2736 WINE_CONFIG_DLL(inseng)
2737 WINE_CONFIG_DLL(iphlpapi,,[implib])
2738 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2739 WINE_CONFIG_DLL(itircl)
2740 WINE_CONFIG_DLL(itss)
2741 WINE_CONFIG_TEST(dlls/itss/tests)
2742 WINE_CONFIG_DLL(joy.cpl,,[po])
2743 WINE_CONFIG_DLL(jscript,,[po])
2744 WINE_CONFIG_TEST(dlls/jscript/tests)
2745 WINE_CONFIG_DLL(kernel32,,[implib,mc])
2746 WINE_CONFIG_TEST(dlls/kernel32/tests)
2747 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2748 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[implib],[kernel])
2749 WINE_CONFIG_DLL(ktmw32)
2750 WINE_CONFIG_DLL(loadperf,,[implib])
2751 WINE_CONFIG_DLL(localspl,,[po])
2752 WINE_CONFIG_TEST(dlls/localspl/tests)
2753 WINE_CONFIG_DLL(localui,,[po])
2754 WINE_CONFIG_TEST(dlls/localui/tests)
2755 WINE_CONFIG_DLL(lz32,,[implib])
2756 WINE_CONFIG_TEST(dlls/lz32/tests)
2757 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2758 WINE_CONFIG_DLL(mapi32,,[implib,po])
2759 WINE_CONFIG_TEST(dlls/mapi32/tests)
2760 WINE_CONFIG_DLL(mapistub)
2761 WINE_CONFIG_DLL(mciavi32)
2762 WINE_CONFIG_DLL(mcicda)
2763 WINE_CONFIG_DLL(mciqtz32)
2764 WINE_CONFIG_DLL(mciseq)
2765 WINE_CONFIG_DLL(mciwave)
2766 WINE_CONFIG_DLL(mgmtapi)
2767 WINE_CONFIG_DLL(midimap)
2768 WINE_CONFIG_DLL(mlang,,[implib])
2769 WINE_CONFIG_TEST(dlls/mlang/tests)
2770 WINE_CONFIG_DLL(mmcndmgr)
2771 WINE_CONFIG_TEST(dlls/mmcndmgr/tests)
2772 WINE_CONFIG_DLL(mmdevapi)
2773 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2774 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2775 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2776 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2777 WINE_CONFIG_DLL(mountmgr.sys)
2778 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2779 WINE_CONFIG_DLL(mpr,,[implib,po])
2780 WINE_CONFIG_TEST(dlls/mpr/tests)
2781 WINE_CONFIG_DLL(mprapi,,[implib])
2782 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2783 WINE_CONFIG_DLL(msacm32.drv)
2784 WINE_CONFIG_DLL(msacm32,,[implib,po])
2785 WINE_CONFIG_TEST(dlls/msacm32/tests)
2786 WINE_CONFIG_DLL(msadp32.acm)
2787 WINE_CONFIG_DLL(mscat32)
2788 WINE_CONFIG_DLL(mscms,,[implib])
2789 WINE_CONFIG_TEST(dlls/mscms/tests)
2790 WINE_CONFIG_DLL(mscoree)
2791 WINE_CONFIG_TEST(dlls/mscoree/tests)
2792 WINE_CONFIG_DLL(msctf)
2793 WINE_CONFIG_TEST(dlls/msctf/tests)
2794 WINE_CONFIG_DLL(msdaps)
2795 WINE_CONFIG_DLL(msdmo,,[implib])
2796 WINE_CONFIG_DLL(msftedit)
2797 WINE_CONFIG_DLL(msg711.acm)
2798 WINE_CONFIG_DLL(msgsm32.acm)
2799 WINE_CONFIG_DLL(mshtml.tlb)
2800 WINE_CONFIG_DLL(mshtml,,[implib,po])
2801 WINE_CONFIG_TEST(dlls/mshtml/tests)
2802 WINE_CONFIG_DLL(msi,,[implib,po])
2803 WINE_CONFIG_TEST(dlls/msi/tests)
2804 WINE_CONFIG_DLL(msident)
2805 WINE_CONFIG_DLL(msimg32,,[implib])
2806 WINE_CONFIG_DLL(msimsg)
2807 WINE_CONFIG_DLL(msimtf)
2808 WINE_CONFIG_DLL(msisip)
2809 WINE_CONFIG_DLL(msisys.ocx)
2810 WINE_CONFIG_DLL(msls31)
2811 WINE_CONFIG_DLL(msnet32)
2812 WINE_CONFIG_DLL(mspatcha)
2813 WINE_CONFIG_DLL(msrle32,,[po])
2814 WINE_CONFIG_DLL(mssign32)
2815 WINE_CONFIG_DLL(mssip32)
2816 WINE_CONFIG_DLL(mstask)
2817 WINE_CONFIG_TEST(dlls/mstask/tests)
2818 WINE_CONFIG_DLL(msvcirt)
2819 WINE_CONFIG_DLL(msvcm80)
2820 WINE_CONFIG_DLL(msvcm90)
2821 WINE_CONFIG_DLL(msvcp100)
2822 WINE_CONFIG_DLL(msvcp60)
2823 WINE_CONFIG_DLL(msvcp70)
2824 WINE_CONFIG_DLL(msvcp71)
2825 WINE_CONFIG_DLL(msvcp80)
2826 WINE_CONFIG_DLL(msvcp90)
2827 WINE_CONFIG_TEST(dlls/msvcp90/tests)
2828 WINE_CONFIG_DLL(msvcr100)
2829 WINE_CONFIG_TEST(dlls/msvcr100/tests)
2830 WINE_CONFIG_DLL(msvcr70,,[implib])
2831 WINE_CONFIG_DLL(msvcr71,,[implib])
2832 WINE_CONFIG_DLL(msvcr80)
2833 WINE_CONFIG_DLL(msvcr90)
2834 WINE_CONFIG_TEST(dlls/msvcr90/tests)
2835 WINE_CONFIG_DLL(msvcrt,,[implib])
2836 WINE_CONFIG_TEST(dlls/msvcrt/tests)
2837 WINE_CONFIG_DLL(msvcrt20,,[implib])
2838 WINE_CONFIG_DLL(msvcrt40,,[implib])
2839 WINE_CONFIG_DLL(msvcrtd,,[implib])
2840 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
2841 WINE_CONFIG_DLL(msvfw32,,[implib,po])
2842 WINE_CONFIG_TEST(dlls/msvfw32/tests)
2843 WINE_CONFIG_DLL(msvidc32,,[po])
2844 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
2845 WINE_CONFIG_DLL(mswsock,,[implib])
2846 WINE_CONFIG_DLL(msxml)
2847 WINE_CONFIG_DLL(msxml2)
2848 WINE_CONFIG_DLL(msxml3)
2849 WINE_CONFIG_TEST(dlls/msxml3/tests)
2850 WINE_CONFIG_DLL(msxml4)
2851 WINE_CONFIG_DLL(msxml6)
2852 WINE_CONFIG_DLL(nddeapi,,[implib])
2853 WINE_CONFIG_DLL(netapi32,,[implib])
2854 WINE_CONFIG_TEST(dlls/netapi32/tests)
2855 WINE_CONFIG_DLL(newdev,,[implib])
2856 WINE_CONFIG_DLL(normaliz,,[implib])
2857 WINE_CONFIG_DLL(npmshtml)
2858 WINE_CONFIG_DLL(ntdll,,[implib])
2859 WINE_CONFIG_TEST(dlls/ntdll/tests)
2860 WINE_CONFIG_DLL(ntdsapi,,[implib])
2861 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
2862 WINE_CONFIG_DLL(ntoskrnl.exe,,[implib])
2863 WINE_CONFIG_DLL(ntprint)
2864 WINE_CONFIG_TEST(dlls/ntprint/tests)
2865 WINE_CONFIG_DLL(objsel)
2866 WINE_CONFIG_DLL(odbc32,,[implib])
2867 WINE_CONFIG_DLL(odbccp32,,[implib])
2868 WINE_CONFIG_TEST(dlls/odbccp32/tests)
2869 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
2870 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
2871 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
2872 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
2873 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
2874 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
2875 WINE_CONFIG_DLL(ole32,,[implib])
2876 WINE_CONFIG_TEST(dlls/ole32/tests)
2877 WINE_CONFIG_DLL(oleacc,,[implib,po])
2878 WINE_CONFIG_TEST(dlls/oleacc/tests)
2879 WINE_CONFIG_DLL(oleaut32,,[implib,po])
2880 WINE_CONFIG_TEST(dlls/oleaut32/tests)
2881 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
2882 WINE_CONFIG_DLL(olecli32,,[implib])
2883 WINE_CONFIG_DLL(oledb32)
2884 WINE_CONFIG_TEST(dlls/oledb32/tests)
2885 WINE_CONFIG_DLL(oledlg,,[implib,po])
2886 WINE_CONFIG_DLL(olepro32,,[implib])
2887 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
2888 WINE_CONFIG_DLL(olesvr32,,[implib])
2889 WINE_CONFIG_DLL(olethk32)
2890 WINE_CONFIG_DLL(openal32)
2891 WINE_CONFIG_DLL(opencl)
2892 WINE_CONFIG_DLL(opengl32,,[implib])
2893 WINE_CONFIG_TEST(dlls/opengl32/tests)
2894 WINE_CONFIG_DLL(pdh,,[implib])
2895 WINE_CONFIG_TEST(dlls/pdh/tests)
2896 WINE_CONFIG_DLL(photometadatahandler)
2897 WINE_CONFIG_DLL(pidgen)
2898 WINE_CONFIG_DLL(powrprof,,[implib])
2899 WINE_CONFIG_DLL(printui)
2900 WINE_CONFIG_DLL(propsys,,[implib])
2901 WINE_CONFIG_TEST(dlls/propsys/tests)
2902 WINE_CONFIG_DLL(psapi,,[implib])
2903 WINE_CONFIG_TEST(dlls/psapi/tests)
2904 WINE_CONFIG_DLL(pstorec)
2905 WINE_CONFIG_DLL(qcap)
2906 WINE_CONFIG_DLL(qedit)
2907 WINE_CONFIG_TEST(dlls/qedit/tests)
2908 WINE_CONFIG_DLL(qmgr)
2909 WINE_CONFIG_TEST(dlls/qmgr/tests)
2910 WINE_CONFIG_DLL(qmgrprxy)
2911 WINE_CONFIG_DLL(quartz,,[implib])
2912 WINE_CONFIG_TEST(dlls/quartz/tests)
2913 WINE_CONFIG_DLL(query)
2914 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
2915 WINE_CONFIG_DLL(rasapi32,,[implib])
2916 WINE_CONFIG_TEST(dlls/rasapi32/tests)
2917 WINE_CONFIG_DLL(rasdlg,,[implib])
2918 WINE_CONFIG_DLL(regapi)
2919 WINE_CONFIG_DLL(resutils,,[implib])
2920 WINE_CONFIG_DLL(riched20,,[implib])
2921 WINE_CONFIG_TEST(dlls/riched20/tests)
2922 WINE_CONFIG_DLL(riched32)
2923 WINE_CONFIG_TEST(dlls/riched32/tests)
2924 WINE_CONFIG_DLL(rpcrt4,,[implib])
2925 WINE_CONFIG_TEST(dlls/rpcrt4/tests)
2926 WINE_CONFIG_DLL(rsabase)
2927 WINE_CONFIG_DLL(rsaenh,,[implib])
2928 WINE_CONFIG_TEST(dlls/rsaenh/tests)
2929 WINE_CONFIG_DLL(rstrtmgr)
2930 WINE_CONFIG_DLL(rtutils,,[implib])
2931 WINE_CONFIG_DLL(samlib)
2932 WINE_CONFIG_DLL(sane.ds,,[po])
2933 WINE_CONFIG_DLL(scarddlg)
2934 WINE_CONFIG_DLL(sccbase)
2935 WINE_CONFIG_DLL(schannel)
2936 WINE_CONFIG_TEST(dlls/schannel/tests)
2937 WINE_CONFIG_DLL(scrrun)
2938 WINE_CONFIG_TEST(dlls/scrrun/tests)
2939 WINE_CONFIG_DLL(secur32,,[implib])
2940 WINE_CONFIG_TEST(dlls/secur32/tests)
2941 WINE_CONFIG_DLL(security)
2942 WINE_CONFIG_DLL(sensapi,,[implib])
2943 WINE_CONFIG_DLL(serialui,,[implib,po])
2944 WINE_CONFIG_TEST(dlls/serialui/tests)
2945 WINE_CONFIG_DLL(setupapi,,[implib,po])
2946 WINE_CONFIG_TEST(dlls/setupapi/tests)
2947 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
2948 WINE_CONFIG_DLL(sfc,,[implib])
2949 WINE_CONFIG_DLL(sfc_os,,[implib])
2950 WINE_CONFIG_DLL(shdoclc,,[po])
2951 WINE_CONFIG_DLL(shdocvw,,[implib])
2952 WINE_CONFIG_TEST(dlls/shdocvw/tests)
2953 WINE_CONFIG_DLL(shell.dll16,enable_win16)
2954 WINE_CONFIG_DLL(shell32,,[implib,po])
2955 WINE_CONFIG_TEST(dlls/shell32/tests)
2956 WINE_CONFIG_DLL(shfolder,,[implib])
2957 WINE_CONFIG_DLL(shlwapi,,[implib,po])
2958 WINE_CONFIG_TEST(dlls/shlwapi/tests)
2959 WINE_CONFIG_DLL(slbcsp)
2960 WINE_CONFIG_DLL(slc,,[implib])
2961 WINE_CONFIG_DLL(snmpapi,,[implib])
2962 WINE_CONFIG_TEST(dlls/snmpapi/tests)
2963 WINE_CONFIG_DLL(softpub)
2964 WINE_CONFIG_DLL(sound.drv16,enable_win16)
2965 WINE_CONFIG_DLL(spoolss,,[implib])
2966 WINE_CONFIG_TEST(dlls/spoolss/tests)
2967 WINE_CONFIG_DLL(stdole2.tlb)
2968 WINE_CONFIG_DLL(stdole32.tlb)
2969 WINE_CONFIG_DLL(sti,,[implib])
2970 WINE_CONFIG_TEST(dlls/sti/tests)
2971 WINE_CONFIG_DLL(storage.dll16,enable_win16)
2972 WINE_CONFIG_DLL(stress.dll16,enable_win16)
2973 WINE_CONFIG_LIB(strmbase)
2974 WINE_CONFIG_LIB(strmiids)
2975 WINE_CONFIG_DLL(svrapi)
2976 WINE_CONFIG_DLL(sxs,,[implib])
2977 WINE_CONFIG_TEST(dlls/sxs/tests)
2978 WINE_CONFIG_DLL(system.drv16,enable_win16)
2979 WINE_CONFIG_DLL(t2embed)
2980 WINE_CONFIG_DLL(tapi32,,[implib])
2981 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
2982 WINE_CONFIG_DLL(traffic)
2983 WINE_CONFIG_DLL(twain.dll16,enable_win16)
2984 WINE_CONFIG_DLL(twain_32)
2985 WINE_CONFIG_TEST(dlls/twain_32/tests)
2986 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
2987 WINE_CONFIG_DLL(unicows,,[implib])
2988 WINE_CONFIG_DLL(updspapi)
2989 WINE_CONFIG_DLL(url,,[implib])
2990 WINE_CONFIG_DLL(urlmon,,[implib])
2991 WINE_CONFIG_TEST(dlls/urlmon/tests)
2992 WINE_CONFIG_DLL(usbd.sys,,[implib])
2993 WINE_CONFIG_DLL(user.exe16,enable_win16)
2994 WINE_CONFIG_DLL(user32,,[implib,po])
2995 WINE_CONFIG_TEST(dlls/user32/tests)
2996 WINE_CONFIG_DLL(userenv,,[implib])
2997 WINE_CONFIG_TEST(dlls/userenv/tests)
2998 WINE_CONFIG_DLL(usp10,,[implib])
2999 WINE_CONFIG_TEST(dlls/usp10/tests)
3000 WINE_CONFIG_LIB(uuid)
3001 WINE_CONFIG_DLL(uxtheme,,[implib])
3002 WINE_CONFIG_TEST(dlls/uxtheme/tests)
3003 WINE_CONFIG_DLL(vbscript)
3004 WINE_CONFIG_TEST(dlls/vbscript/tests)
3005 WINE_CONFIG_DLL(vcomp)
3006 WINE_CONFIG_DLL(vcomp100)
3007 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
3008 WINE_CONFIG_DLL(vdmdbg,,[implib])
3009 WINE_CONFIG_DLL(ver.dll16,enable_win16)
3010 WINE_CONFIG_DLL(version,,[implib])
3011 WINE_CONFIG_TEST(dlls/version/tests)
3012 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
3013 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
3014 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
3015 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
3016 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
3017 WINE_CONFIG_DLL(w32skrnl,enable_win16)
3018 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
3019 WINE_CONFIG_DLL(wbemprox)
3020 WINE_CONFIG_TEST(dlls/wbemprox/tests)
3021 WINE_CONFIG_DLL(wer,,[implib])
3022 WINE_CONFIG_TEST(dlls/wer/tests)
3023 WINE_CONFIG_DLL(wevtapi)
3024 WINE_CONFIG_DLL(wiaservc)
3025 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
3026 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
3027 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
3028 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
3029 WINE_CONFIG_DLL(windowscodecs,,[implib])
3030 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
3031 WINE_CONFIG_DLL(winealsa.drv)
3032 WINE_CONFIG_DLL(winecoreaudio.drv)
3033 WINE_CONFIG_LIB(winecrt0)
3034 WINE_CONFIG_DLL(wined3d,,[implib])
3035 WINE_CONFIG_DLL(winegstreamer)
3036 WINE_CONFIG_DLL(winejoystick.drv)
3037 WINE_CONFIG_DLL(winemapi)
3038 WINE_CONFIG_DLL(winemp3.acm)
3039 WINE_CONFIG_DLL(wineoss.drv)
3040 WINE_CONFIG_DLL(wineps.drv,,[install-lib,po])
3041 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
3042 WINE_CONFIG_DLL(wineqtdecoder)
3043 WINE_CONFIG_DLL(winequartz.drv)
3044 WINE_CONFIG_DLL(winex11.drv)
3045 WINE_CONFIG_DLL(wing.dll16,enable_win16)
3046 WINE_CONFIG_DLL(wing32)
3047 WINE_CONFIG_DLL(winhttp,,[implib])
3048 WINE_CONFIG_TEST(dlls/winhttp/tests)
3049 WINE_CONFIG_DLL(wininet,,[implib,po])
3050 WINE_CONFIG_TEST(dlls/wininet/tests)
3051 WINE_CONFIG_DLL(winmm,,[implib,po])
3052 WINE_CONFIG_TEST(dlls/winmm/tests)
3053 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
3054 WINE_CONFIG_DLL(winnls32,,[implib])
3055 WINE_CONFIG_DLL(winscard,,[implib])
3056 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
3057 WINE_CONFIG_DLL(winspool.drv,,[implib,po],[winspool])
3058 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
3059 WINE_CONFIG_DLL(winsta)
3060 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
3061 WINE_CONFIG_DLL(wintab32,,[implib])
3062 WINE_CONFIG_TEST(dlls/wintab32/tests)
3063 WINE_CONFIG_DLL(wintrust,,[implib])
3064 WINE_CONFIG_TEST(dlls/wintrust/tests)
3065 WINE_CONFIG_DLL(wlanapi)
3066 WINE_CONFIG_DLL(wldap32,,[implib,po])
3067 WINE_CONFIG_TEST(dlls/wldap32/tests)
3068 WINE_CONFIG_DLL(wmi)
3069 WINE_CONFIG_DLL(wmiutils)
3070 WINE_CONFIG_DLL(wmvcore)
3071 WINE_CONFIG_DLL(wnaspi32,,[implib])
3072 WINE_CONFIG_DLL(wow32,enable_win16,[implib])
3073 WINE_CONFIG_DLL(ws2_32,,[implib])
3074 WINE_CONFIG_TEST(dlls/ws2_32/tests)
3075 WINE_CONFIG_DLL(wshom.ocx)
3076 WINE_CONFIG_TEST(dlls/wshom.ocx/tests)
3077 WINE_CONFIG_DLL(wsnmp32)
3078 WINE_CONFIG_DLL(wsock32,,[implib])
3079 WINE_CONFIG_DLL(wtsapi32,,[implib])
3080 WINE_CONFIG_DLL(wuapi)
3081 WINE_CONFIG_DLL(wuaueng)
3082 WINE_CONFIG_DLL(xapofx1_1)
3083 WINE_CONFIG_DLL(xinput1_1)
3084 WINE_CONFIG_DLL(xinput1_2)
3085 WINE_CONFIG_DLL(xinput1_3,,[implib],[xinput])
3086 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
3087 WINE_CONFIG_DLL(xinput9_1_0)
3088 WINE_CONFIG_DLL(xmllite)
3089 WINE_CONFIG_TEST(dlls/xmllite/tests)
3090 WINE_CONFIG_DLL(xolehlp)
3091 WINE_CONFIG_DLL(xpsprint)
3092 WINE_CONFIG_MAKEFILE([documentation])
3093 WINE_CONFIG_MAKEFILE([fonts],,[install-lib])
3094 WINE_CONFIG_MAKEFILE([include],,[install-dev])
3095 WINE_CONFIG_MAKEFILE([libs/port])
3096 WINE_CONFIG_MAKEFILE([libs/wine],,[install-dev,install-lib])
3097 WINE_CONFIG_MAKEFILE([libs/wpp])
3098 WINE_CONFIG_MAKEFILE([loader],,[install-lib,manpage])
3099 WINE_CONFIG_PROGRAM(aspnet_regiis,,[install])
3100 WINE_CONFIG_PROGRAM(attrib,,[install,po])
3101 WINE_CONFIG_PROGRAM(cabarc,,[install])
3102 WINE_CONFIG_PROGRAM(cacls,,[install])
3103 WINE_CONFIG_PROGRAM(clock,,[install,po])
3104 WINE_CONFIG_PROGRAM(cmd,,[install,po])
3105 WINE_CONFIG_TEST(programs/cmd/tests)
3106 WINE_CONFIG_PROGRAM(control,,[install])
3107 WINE_CONFIG_PROGRAM(cscript,,[install])
3108 WINE_CONFIG_PROGRAM(dxdiag,,[install,po])
3109 WINE_CONFIG_PROGRAM(eject,,[install])
3110 WINE_CONFIG_PROGRAM(expand,,[install])
3111 WINE_CONFIG_PROGRAM(explorer,,[install,po])
3112 WINE_CONFIG_PROGRAM(extrac32,,[install])
3113 WINE_CONFIG_PROGRAM(hh,,[install])
3114 WINE_CONFIG_PROGRAM(hostname,,[install,po])
3115 WINE_CONFIG_PROGRAM(icinfo,,[install])
3116 WINE_CONFIG_PROGRAM(iexplore,,[install])
3117 WINE_CONFIG_PROGRAM(ipconfig,,[install,po])
3118 WINE_CONFIG_PROGRAM(lodctr,,[install])
3119 WINE_CONFIG_PROGRAM(mofcomp,,[install])
3120 WINE_CONFIG_PROGRAM(mshta,,[install])
3121 WINE_CONFIG_PROGRAM(msiexec,,[install,installbin,manpage])
3122 WINE_CONFIG_PROGRAM(net,,[install,po])
3123 WINE_CONFIG_PROGRAM(netsh,,[install])
3124 WINE_CONFIG_PROGRAM(ngen,,[install])
3125 WINE_CONFIG_PROGRAM(notepad,,[install,installbin,manpage,po])
3126 WINE_CONFIG_PROGRAM(oleview,,[install,po])
3127 WINE_CONFIG_PROGRAM(ping,,[install])
3128 WINE_CONFIG_PROGRAM(plugplay,,[install])
3129 WINE_CONFIG_PROGRAM(presentationfontcache,,[install])
3130 WINE_CONFIG_PROGRAM(progman,,[install,po])
3131 WINE_CONFIG_PROGRAM(reg,,[install,po])
3132 WINE_CONFIG_PROGRAM(regasm,,[install])
3133 WINE_CONFIG_PROGRAM(regedit,,[install,installbin,manpage,po])
3134 WINE_CONFIG_TEST(programs/regedit/tests)
3135 WINE_CONFIG_PROGRAM(regsvcs,,[install])
3136 WINE_CONFIG_PROGRAM(regsvr32,,[install,installbin,manpage])
3137 WINE_CONFIG_PROGRAM(rpcss,,[install])
3138 WINE_CONFIG_PROGRAM(rundll.exe16,enable_win16,[install])
3139 WINE_CONFIG_PROGRAM(rundll32,,[install])
3140 WINE_CONFIG_PROGRAM(sc,,[install])
3141 WINE_CONFIG_PROGRAM(secedit,,[install])
3142 WINE_CONFIG_PROGRAM(servicemodelreg,,[install])
3143 WINE_CONFIG_PROGRAM(services,,[install])
3144 WINE_CONFIG_TEST(programs/services/tests)
3145 WINE_CONFIG_PROGRAM(spoolsv,,[install])
3146 WINE_CONFIG_PROGRAM(start,,[install,po])
3147 WINE_CONFIG_PROGRAM(svchost,,[install])
3148 WINE_CONFIG_PROGRAM(taskkill,,[install,po])
3149 WINE_CONFIG_PROGRAM(taskmgr,,[install,po])
3150 WINE_CONFIG_PROGRAM(termsv,,[install])
3151 WINE_CONFIG_PROGRAM(uninstaller,,[install,po])
3152 WINE_CONFIG_PROGRAM(unlodctr,,[install])
3153 WINE_CONFIG_PROGRAM(view,,[install,po])
3154 WINE_CONFIG_PROGRAM(wineboot,,[install,installbin,manpage,po])
3155 WINE_CONFIG_PROGRAM(winebrowser,,[install])
3156 WINE_CONFIG_PROGRAM(winecfg,,[install,installbin,manpage,po])
3157 WINE_CONFIG_PROGRAM(wineconsole,,[install,installbin,manpage,po])
3158 WINE_CONFIG_PROGRAM(winedbg,,[install,installbin,manpage,po])
3159 WINE_CONFIG_PROGRAM(winedevice,,[install])
3160 WINE_CONFIG_PROGRAM(winefile,,[install,installbin,manpage,po])
3161 WINE_CONFIG_PROGRAM(winemenubuilder,,[install])
3162 WINE_CONFIG_PROGRAM(winemine,,[install,installbin,manpage,po])
3163 WINE_CONFIG_PROGRAM(winemsibuilder,,[install])
3164 WINE_CONFIG_PROGRAM(winepath,,[install,installbin,manpage])
3165 WINE_CONFIG_PROGRAM(winetest)
3166 WINE_CONFIG_PROGRAM(winevdm,enable_win16,[install])
3167 WINE_CONFIG_PROGRAM(winhelp.exe16,enable_win16,[install])
3168 WINE_CONFIG_PROGRAM(winhlp32,,[install,po])
3169 WINE_CONFIG_PROGRAM(winoldap.mod16,enable_win16,[install])
3170 WINE_CONFIG_PROGRAM(winver,,[install])
3171 WINE_CONFIG_PROGRAM(wmic,,[install,po])
3172 WINE_CONFIG_PROGRAM(wordpad,,[install,po])
3173 WINE_CONFIG_PROGRAM(write,,[install,po])
3174 WINE_CONFIG_PROGRAM(wscript,,[install])
3175 WINE_CONFIG_TEST(programs/wscript/tests)
3176 WINE_CONFIG_PROGRAM(wusa,,[install])
3177 WINE_CONFIG_PROGRAM(xcopy,,[install,po])
3178 WINE_CONFIG_MAKEFILE([server],,[install-lib,manpage])
3179 WINE_CONFIG_TOOL(tools,[install-dev,install-lib,manpage])
3180 WINE_CONFIG_TOOL(tools/widl,[install-dev,manpage])
3181 WINE_CONFIG_TOOL(tools/winebuild,[install-dev,manpage])
3182 WINE_CONFIG_TOOL(tools/winedump,[install-dev,manpage])
3183 WINE_CONFIG_TOOL(tools/winegcc,[install-dev,manpage])
3184 WINE_CONFIG_TOOL(tools/wmc,[install-dev,manpage])
3185 WINE_CONFIG_TOOL(tools/wrc,[install-dev,manpage])
3186
3187 AC_SUBST([LINGUAS],["\
3188 ar \
3189 bg \
3190 ca \
3191 cs \
3192 da \
3193 de \
3194 el \
3195 en \
3196 en_US \
3197 eo \
3198 es \
3199 fa \
3200 fi \
3201 fr \
3202 he \
3203 hi \
3204 hu \
3205 it \
3206 ja \
3207 ko \
3208 lt \
3209 ml \
3210 nb_NO \
3211 nl \
3212 or \
3213 pa \
3214 pl \
3215 pt_BR \
3216 pt_PT \
3217 rm \
3218 ro \
3219 ru \
3220 sk \
3221 sl \
3222 sr_RS@cyrillic \
3223 sr_RS@latin \
3224 sv \
3225 te \
3226 th \
3227 tr \
3228 uk \
3229 wa \
3230 zh_CN \
3231 zh_TW"])
3232
3233 dnl End of auto-generated output commands
3234
3235 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
3236 [wine_fn_output_makefile ()
3237 {
3238     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
3239 $ALL_MAKEFILE_DEPENDS
3240 _WINE_EOF
3241     AS_ERROR([could not create Makefile])
3242 }])
3243
3244 AC_CONFIG_FILES([Make.tmp:Make.vars.in:Makefile.in])
3245
3246 dnl Some final makefile rules
3247
3248 if test "x$enable_maintainer_mode" = xyes
3249 then
3250     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3251 [\$(srcdir)/configure: configure.ac aclocal.m4
3252         cd \$(srcdir) && autoconf --warnings=all
3253 \$(srcdir)/include/config.h.in: include/stamp-h.in
3254 \$(srcdir)/include/stamp-h.in: configure.ac aclocal.m4
3255         cd \$(srcdir) && autoheader --warnings=all
3256         @echo timestamp > \$[@]])
3257 fi
3258
3259 if test "x$with_gettextpo" = xyes
3260 then
3261     test "$srcdir" = . || AC_MSG_ERROR([Rebuilding po files is not supported for out of tree builds.])
3262     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3263 [ALL_POT_FILES =$ALL_POT_FILES
3264 \$(LINGUAS:%=po/%.po): \$(srcdir)/po/wine.pot
3265         msgmerge --previous -q \$[@] \$(srcdir)/po/wine.pot | msgattrib --no-obsolete -o \$[@].new && mv \$[@].new \$[@]
3266 \$(srcdir)/po/wine.pot: \$(ALL_POT_FILES)
3267         msgcat -o \$[@] \$(ALL_POT_FILES)])
3268 fi
3269
3270 if test "$MSGFMT" != false
3271 then
3272     AC_SUBST([PORCFLAGS],["--po-dir=\$(top_builddir)/po"])
3273     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],[__builddeps__: \$(ALL_MO_FILES)])
3274 else
3275     LINGUAS=
3276 fi
3277
3278 if test "x$enable_tools" != xno
3279 then
3280     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3281 [\$(MAKEDEP): tools/Makefile
3282 clean:: __clean__
3283         \$(RM) tools/makedep\$(EXEEXT)])
3284 fi
3285
3286 if test -n "$with_wine64"
3287 then
3288 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3289 [all: fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader
3290 fonts server tools:
3291         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
3292 $with_wine64/loader/wine:
3293         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine \$[@]
3294 $with_wine64/loader/wine-preloader:
3295         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine-preloader \$[@]
3296 clean::
3297         \$(RM) fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader])
3298 fi
3299
3300 AC_OUTPUT
3301
3302 if test "$no_create" = "yes"
3303 then
3304   exit 0
3305 fi
3306
3307 WINE_PRINT_MESSAGES
3308
3309 echo "
3310 $as_me: Finished.  Do '${ac_make}' to compile Wine.
3311 " >&AS_MESSAGE_FD
3312
3313 dnl Local Variables:
3314 dnl comment-start: "dnl "
3315 dnl comment-end: ""
3316 dnl comment-start-skip: "\\bdnl\\b\\s *"
3317 dnl compile-command: "autoreconf --warnings=all"
3318 dnl End: