git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  47
  48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  49   [if test -z "$with_wine_tools"; then
  50      if test "$cross_compiling" = "yes"; then
  51        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  52      else
  53        wine_cv_toolsdir="\$(TOPOBJDIR)"
  54      fi
  55    elif test -d "$with_wine_tools/tools/winebuild"; then
  56      case $with_wine_tools in
  57        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  58        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  59      esac
  60    else
  61      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  62    fi])
  63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  64
  65 AC_PATH_XTRA
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  71 if test "$XLEX" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  74 fi
  75
  76 dnl Check for bison
  77 AC_CHECK_PROGS(BISON,bison,none)
  78 if test "$BISON" = "none"
  79 then
  80   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  81 fi
  82
  83 AC_CHECK_TOOLS(AS,[gas as],as)
  84 AC_CHECK_TOOL(LD,ld,ld)
  85 AC_CHECK_TOOL(AR,ar,ar)
  86 AC_PROG_RANLIB
  87 AC_CHECK_TOOL(STRIP,strip,strip)
  88 AC_CHECK_TOOL(WINDRES,windres,false)
  89 AC_PROG_LN_S
  90 WINE_PROG_LN
  91 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  92 AC_PROG_INSTALL
  93 dnl Prepend src dir to install path dir if it's a relative path
  94 case "$INSTALL" in
  95   [[\\/$]]* | ?:[[\\/]]* ) ;;
  96   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  97 esac
  98
  99 dnl Check for lint
 100 AC_CHECK_PROGS(LINT, lclint lint)
 101 if test "$LINT" = "lint"
 102 then
 103   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 104   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 105 fi
 106 AC_SUBST(LINT)
 107 AC_SUBST(LINTFLAGS)
 108
 109 dnl Check for db2html
 110 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 111 AC_SUBST(DB2HTML)
 112
 113 dnl Check for db2pdf
 114 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 115 AC_SUBST(DB2PDF)
 116
 117 dnl Check for db2ps
 118 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 119 AC_SUBST(DB2PS)
 120
 121 dnl Check for db2txt
 122 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 123 AC_SUBST(DB2TXT)
 124
 125 dnl **** Check for some libraries ****
 126
 127 dnl Check for -lm
 128 AC_CHECK_LIB(m,sqrt)
 129 dnl Check for -li386 for NetBSD and OpenBSD
 130 AC_CHECK_LIB(i386,i386_set_ldt)
 131 dnl Check for -lossaudio for NetBSD
 132 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 133 dnl Check for -lw for Solaris
 134 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 135 dnl Check for -lnsl for Solaris
 136 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 137 dnl Check for -lsocket for Solaris
 138 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 139 dnl Check for -lresolv for Solaris
 140 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 141 dnl Check for -lxpg4 for FreeBSD
 142 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 143 dnl Check for -lpoll for Mac OS X/Darwin
 144 AC_CHECK_LIB(poll,poll)
 145 dnl Check for -lpthread
 146 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 147
 148 JPEGLIB=""
 149 AC_SUBST(JPEGLIB)
 150 AC_CHECK_HEADERS(jpeglib.h,
 151     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 152         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 153         JPEGLIB="-ljpeg"
 154     )
 155 )
 156
 157 AC_SUBST(GIFLIB,"")
 158 AC_CHECK_HEADERS(gif_lib.h,
 159     AC_CHECK_LIB(ungif,DGifOpen,
 160         [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
 161          GIFLIB="-lungif"],
 162         [AC_CHECK_LIB(gif,DGifOpen,
 163                       [AC_DEFINE(HAVE_LIBGIF,1)
 164                        GIFLIB="-lgif"])]))
 165
 166 AC_SUBST(XLIB)
 167 AC_SUBST(XFILES)
 168 XFILES=""
 169 AC_SUBST(OPENGLFILES)
 170 OPENGLFILES=""
 171 AC_SUBST(GLU32FILES)
 172 GLU32FILES=""
 173 AC_SUBST(OPENGL_LIBS)
 174 OPENGL_LIBS=""
 175 if test "$have_x" = "yes"
 176 then
 177     XLIB="-lXext -lX11"
 178     ac_save_CPPFLAGS="$CPPFLAGS"
 179     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 180
 181     dnl *** All of the following tests require X11/Xlib.h
 182     AC_CHECK_HEADERS(X11/Xlib.h,
 183       [
 184         AC_CHECK_HEADERS([X11/XKBlib.h \
 185                           X11/Xutil.h \
 186                           X11/extensions/shape.h \
 187                           X11/extensions/XInput.h \
 188                           X11/extensions/XShm.h \
 189                           X11/extensions/Xrandr.h \
 190                           X11/extensions/Xrender.h \
 191                           X11/extensions/Xvlib.h \
 192                           X11/extensions/xf86dga.h \
 193                           X11/extensions/xf86vmode.h],,,
 194                          [#include <X11/Xlib.h>
 195                           #ifdef HAVE_X11_XUTIL_H
 196                           # include <X11/Xutil.h>
 197                           #endif])
 198
 199         dnl *** Check for X keyboard extension
 200         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 201         then
 202               AC_CHECK_LIB(X11, XkbQueryExtension,
 203               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 204               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 205         fi
 206
 207         dnl *** Check for X Shm extension
 208         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 209         then
 210               AC_CHECK_LIB(Xext, XShmQueryExtension,
 211               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 212               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 213         fi
 214
 215         dnl *** Check for X shape extension
 216         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 217         then
 218               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 219               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 220               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 221         fi
 222
 223         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 224         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 225         then
 226               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 227                 [ dnl *** If found...
 228                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 229                             [Define if you have the Xxf86dga library version 2])
 230                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 231                ],
 232                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 233                   dnl *** instead (DGA 2.0 not found)...
 234                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 235                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 236                                 [Define if you have the Xxf86dga library version 1])
 237                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 238                     ],,
 239                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 240                   )
 241                 ],
 242                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 243         fi
 244
 245         dnl *** Check for XFree86 VMODE extension
 246         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 247         then
 248                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 249                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 250                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 251                   ],,
 252                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 253         fi
 254
 255         dnl *** Check for X RandR extension
 256         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 257         then
 258                 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
 259                   [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
 260                      X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
 261                   ],,
 262                   $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
 263         fi
 264
 265         dnl *** Check for XVideo extension supporting XvImages
 266         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 267         then
 268                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 269                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 270                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 271                   ],,
 272                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 273         fi
 274       ]
 275     ) dnl *** End of X11/Xlib.h check
 276
 277     dnl Check for the presence of OpenGL
 278     if test "x$with_opengl" != "xno"
 279     then
 280         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 281         then
 282             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 283 This prevents linking to OpenGL. Delete the file and restart configure.])
 284         fi
 285
 286         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 287         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 288         then
 289             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 290             dnl Check for some problems due to old Mesa versions
 291             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 292               AC_TRY_COMPILE(
 293                 [#include <GL/gl.h>],
 294                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 295                 [wine_cv_opengl_version_OK="yes"],
 296                 [wine_cv_opengl_version_OK="no"]
 297               )
 298             )
 299
 300             if test "$wine_cv_opengl_version_OK" = "yes"
 301             then
 302                 dnl Check for the presence of the library
 303                 AC_CHECK_LIB(GL,glXCreateContext,
 304                              OPENGL_LIBS="-lGL"
 305                              ,,
 306                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 307
 308                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 309                 then
 310                         OPENGLFILES='$(OPENGLFILES)'
 311                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 312
 313                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 314                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 315                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 316                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 317
 318                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 319                         then
 320                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 321                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 322                                                   #ifdef HAVE_GL_GLEXT_H
 323                                                   # include <GL/glext.h>
 324                                                   #endif
 325                                                   ],
 326                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 327                                                  [wine_cv_extension_prototypes="yes"],
 328                                                  [wine_cv_extension_prototypes="no"]
 329                                   )]
 330                                 )
 331                                 if test "$wine_cv_extension_prototypes" = "yes"
 332                                 then
 333                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 334                                               [Define if the OpenGL headers define extension typedefs])
 335                                 fi
 336                         fi
 337
 338                 fi
 339                 dnl Check for GLU32 library.
 340                 AC_CHECK_LIB(GLU,gluLookAt,
 341                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 342                              GLU32FILES='$(GLU32FILES)']
 343                              ,,
 344                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 345                 )
 346              fi
 347
 348              dnl Check for glut32 library.
 349              AC_CHECK_LIB(glut,glutMainLoop,
 350                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 351                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 352                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 353          fi
 354     fi
 355
 356     dnl **** Check for NAS ****
 357     AC_SUBST(NASLIBS,"")
 358     AC_CHECK_HEADERS(audio/audiolib.h,
 359          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 360           AC_CHECK_LIB(audio,AuCreateFlow,
 361                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 362                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 363                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 364
 365     CPPFLAGS="$ac_save_CPPFLAGS"
 366     XFILES='$(XFILES)'
 367 else
 368     XLIB=""
 369     X_CFLAGS=""
 370     X_LIBS=""
 371 fi
 372
 373 dnl **** Check which curses lib to use ***
 374 CURSESLIBS=""
 375 if test "x$with_curses" != "xno"
 376 then
 377     AC_CHECK_HEADERS(ncurses.h,
 378         [AC_CHECK_LIB(ncurses,waddch,
 379             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 380              CURSESLIBS="-lncurses"],
 381              [AC_CHECK_HEADERS(curses.h,
 382                  [AC_CHECK_LIB(curses,waddch,
 383                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 384                       CURSESLIBS="-lcurses"])])])])
 385     saved_libs="$LIBS"
 386     LIBS="$CURSESLIBS $LIBS"
 387     AC_CHECK_FUNCS(getbkgd resizeterm)
 388     LIBS="$saved_libs"
 389 fi
 390 AC_SUBST(CURSESLIBS)
 391
 392 dnl **** Check for SANE ****
 393 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 394 if test "$sane_devel" = "no"
 395 then
 396     SANELIBS=""
 397     SANEINCL=""
 398 else
 399     SANELIBS="`$sane_devel --libs`"
 400     SANEINCL="`$sane_devel --cflags`"
 401     ac_save_CPPFLAGS="$CPPFLAGS"
 402     ac_save_LIBS="$LIBS"
 403     CPPFLAGS="$CPPFLAGS $SANEINCL"
 404     LIBS="$LIBS $SANELIBS"
 405     AC_CHECK_HEADER(sane/sane.h,
 406                     [AC_CHECK_LIB(sane,sane_open,
 407                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 408                                   [SANELIBS=""
 409                                   SANEINCL=""])],
 410                     [SANELIBS=""
 411                     SANEINCL=""])
 412     LIBS="$ac_save_LIBS"
 413     CPPFLAGS="$ac_save_CPPFLAGS"
 414 fi
 415 AC_SUBST(SANELIBS)
 416 AC_SUBST(SANEINCL)
 417
 418 dnl **** Check for the ICU library ****
 419 AC_CHECK_HEADERS(unicode/ubidi.h)
 420 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 421 then
 422     saved_libs="$LIBS"
 423     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 424     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
 425     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
 426     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 427     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 428                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 429                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")])
 430     LIBS="$saved_libs"
 431 fi
 432
 433 dnl **** Check for FreeType 2 ****
 434 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 435 if test "$ft_lib" = "no"
 436 then
 437     FREETYPEINCL=""
 438     wine_cv_msg_freetype=no
 439 else
 440     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 441     if test "$ft_devel" = "no"
 442     then
 443         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 444         if test "$ft_devel2" = "freetype2-config"
 445         then
 446                 ft_devel=$ft_devel2
 447         fi
 448     fi
 449     if test "$ft_devel" = "no"
 450     then
 451         FREETYPEINCL=""
 452         wine_cv_msg_freetype=yes
 453     else
 454         FREETYPEINCL=`$ft_devel --cflags`
 455         ac_save_CPPFLAGS="$CPPFLAGS"
 456         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 457         AC_CHECK_HEADERS(ft2build.h \
 458                          freetype/freetype.h \
 459                          freetype/ftglyph.h \
 460                          freetype/tttables.h \
 461                          freetype/ftnames.h \
 462                          freetype/ftsnames.h \
 463                          freetype/ttnameid.h \
 464                          freetype/ftoutln.h \
 465                          freetype/internal/sfnt.h,,,
 466                          [#if HAVE_FT2BUILD_H
 467                           #include <ft2build.h>
 468                           #endif])
 469         AC_TRY_CPP([#include <ft2build.h>
 470                     #include <freetype/fttrigon.h>],
 471                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 472           [Define if you have the <freetype/fttrigon.h> header file.])
 473                     wine_cv_fttrigon=yes],
 474                     wine_cv_fttrigon=no)
 475         CPPFLAGS="$ac_save_CPPFLAGS"
 476         dnl Check that we have at least freetype/freetype.h
 477         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 478         then
 479             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 480             wine_cv_msg_freetype=no
 481         else
 482             FREETYPEINCL=""
 483             wine_cv_msg_freetype=yes
 484         fi
 485     fi
 486 fi
 487 AC_SUBST(FREETYPEINCL)
 488
 489 dnl **** Check for parport (currently Linux only) ****
 490 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 491  AC_TRY_COMPILE(
 492    [#include <linux/ppdev.h>],
 493    [ioctl (1,PPCLAIM,0)],
 494    [ac_cv_c_ppdev="yes"],
 495    [ac_cv_c_ppdev="no"])
 496  )
 497 if test "$ac_cv_c_ppdev" = "yes"
 498 then
 499     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 500 fi
 501
 502 dnl **** Check for va_copy ****
 503 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 504  AC_TRY_LINK(
 505    [#include <stdarg.h>],
 506    [va_list ap1, ap2;
 507     va_copy(ap1,ap2);
 508    ],
 509    [ac_cv_c_va_copy="yes"],
 510    [ac_cv_c_va_copy="no"])
 511  )
 512 if test "$ac_cv_c_va_copy" = "yes"
 513 then
 514     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 515 fi
 516 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 517  AC_TRY_LINK(
 518    [#include <stdarg.h>],
 519    [va_list ap1, ap2;
 520     __va_copy(ap1,ap2);
 521    ],
 522    [ac_cv_c___va_copy="yes"],
 523    [ac_cv_c___va_copy="no"])
 524  )
 525 if test "$ac_cv_c___va_copy" = "yes"
 526 then
 527     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 528 fi
 529
 530 dnl **** Check for sigsetjmp ****
 531 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 532  AC_TRY_LINK(
 533    [#include <setjmp.h>],
 534    [sigjmp_buf buf;
 535     sigsetjmp( buf, 1 );
 536     siglongjmp( buf, 1 );],
 537    [ac_cv_c_sigsetjmp="yes"],
 538    [ac_cv_c_sigsetjmp="no"])
 539  )
 540 if test "$ac_cv_c_sigsetjmp" = "yes"
 541 then
 542     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 543 fi
 544
 545 dnl **** Check for pthread_rwlock_t ****
 546 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 547 #include <pthread.h>])
 548
 549 dnl **** Check for pthread_getattr_np ****
 550 ac_save_LIBS="$LIBS"
 551 LIBS="$LIBS $LIBPTHREAD"
 552 AC_CHECK_FUNCS(pthread_getattr_np)
 553 LIBS="$ac_save_LIBS"
 554
 555 dnl **** Check for Open Sound System ****
 556 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 557
 558 AC_CACHE_CHECK([for Open Sound System],
 559         ac_cv_c_opensoundsystem,
 560         AC_TRY_COMPILE([
 561         #if defined(HAVE_SYS_SOUNDCARD_H)
 562                 #include <sys/soundcard.h>
 563         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 564                 #include <machine/soundcard.h>
 565         #elif defined(HAVE_SOUNDCARD_H)
 566                 #include <soundcard.h>
 567         #endif
 568         ],[
 569
 570 /* check for one of the Open Sound System specific SNDCTL_ defines */
 571 #if !defined(SNDCTL_DSP_STEREO)
 572 #error No open sound system
 573 #endif
 574 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 575
 576 if test "$ac_cv_c_opensoundsystem" = "yes"
 577 then
 578     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 579 fi
 580
 581 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 582         ac_cv_c_opensoundsystem_midi,
 583         AC_TRY_COMPILE([
 584         #if defined(HAVE_SYS_SOUNDCARD_H)
 585                 #include <sys/soundcard.h>
 586         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 587                 #include <machine/soundcard.h>
 588         #elif defined(HAVE_SOUNDCARD_H)
 589                 #include <soundcard.h>
 590         #endif
 591         ],[
 592
 593 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 594 #if !defined(SNDCTL_SEQ_SYNC)
 595 #error No open sound system MIDI interface
 596 #endif
 597 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 598
 599 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 600 then
 601     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 602 fi
 603
 604 dnl **** Check for aRts Sound Server ****
 605 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 606 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 607 then
 608     ARTSC_CFLAGS=""
 609     for i in `$ARTSCCONFIG --cflags`
 610     do
 611       case "$i" in
 612         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 613       esac
 614     done
 615     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 616     save_CFLAGS="$CFLAGS"
 617     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 618     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 619         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 620          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 621          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 622     CFLAGS="$save_CFLAGS"
 623 fi
 624
 625 dnl **** Check for ALSA ****
 626 AC_SUBST(ALSALIBS,"")
 627 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 628 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 629 then
 630     AC_CHECK_LIB(asound,snd_pcm_open,
 631         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 632         ALSALIBS="-lasound")
 633 fi
 634
 635 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 636
 637 AC_SUBST(AUDIOIOLIBS,"")
 638 AC_CHECK_HEADERS(libaudioio.h,
 639     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 640                   [AUDIOIOLIBS="-laudioio"
 641                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 642
 643 dnl **** Check for capi4linux ****
 644
 645 AC_CHECK_HEADERS(capi20.h,[
 646         AC_CHECK_HEADERS(linux/capi.h,[
 647                 AC_CHECK_LIB(capi20,capi20_register,[
 648                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 649                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 650                 ])
 651         ])
 652 ])
 653
 654 dnl **** Check for broken glibc mmap64 ****
 655
 656 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 657         AC_TRY_RUN([
 658                 #define _FILE_OFFSET_BITS 64
 659                 #include <stdio.h>
 660                 #include <unistd.h>
 661                 #include <fcntl.h>
 662                 #include <sys/mman.h>
 663                 #include <errno.h>
 664
 665                 int main(int argc,char **argv) {
 666                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 667                         if (fd == -1) exit(1);
 668
 669                         unlink("conftest.map");
 670
 671                         write(fd,"test",4);
 672
 673                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 674                             (errno == EINVAL)
 675                         ) {
 676                                 exit(1);
 677                         }
 678                         close(fd);
 679                         fprintf(stderr,"success!\n");
 680                         exit(0);
 681                 }
 682
 683         ],
 684     ac_cv_mmap64_works="yes",
 685     ac_cv_mmap64_works="no",
 686     ac_cv_mmap64_works="no") )
 687
 688 if test "$ac_cv_mmap64_works" = "yes"
 689 then
 690     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 691 fi
 692
 693 dnl **** Check for gcc specific options ****
 694
 695 AC_SUBST(EXTRACFLAGS,"")
 696 if test "x${GCC}" = "xyes"
 697 then
 698   EXTRACFLAGS="-Wall -pipe"
 699
 700   dnl Check for strength-reduce bug
 701   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 702                   AC_TRY_RUN([
 703 int     L[[4]] = {0,1,2,3};
 704 int main(void) {
 705   static int Array[[3]];
 706   unsigned int B = 3;
 707   int i;
 708   for(i=0; i<B; i++) Array[[i]] = i - 3;
 709   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 710   L[[i]] = 4;
 711
 712   exit( Array[[1]] != -2 || L[[2]] != 3);
 713 }],
 714     ac_cv_c_gcc_strength_bug="no",
 715     ac_cv_c_gcc_strength_bug="yes",
 716     ac_cv_c_gcc_strength_bug="yes") )
 717   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 718   then
 719     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 720   fi
 721
 722   dnl Check for -fshort-wchar
 723   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 724       [WINE_TRY_CFLAGS([-fshort-wchar],
 725                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 726   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 727   then
 728       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 729   fi
 730
 731   dnl Check for -mpreferred-stack-boundary
 732   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 733       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 734                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 735   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 736   then
 737     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 738   fi
 739
 740   dnl Check for -fno-strict-aliasing
 741   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 742       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 743                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 744   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 745   then
 746     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 747   fi
 748
 749   dnl Check for -gstabs+ option
 750   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 751       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 752   if test "$ac_cv_c_gcc_gstabs" = "yes"
 753   then
 754     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 755   fi
 756
 757   dnl Check for noisy string.h
 758   saved_CFLAGS="$CFLAGS"
 759   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 760   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 761       AC_TRY_COMPILE([#include <string.h>],[],
 762                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 763   CFLAGS="$saved_CFLAGS"
 764   if test "$ac_cv_c_string_h_warnings" = "no"
 765   then
 766     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 767   fi
 768 fi
 769
 770 dnl **** Check how to define a function in assembly code ****
 771
 772 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 773   WINE_TRY_ASM_LINK(
 774       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 775       ac_cv_asm_func_def=".def",
 776     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 777       ac_cv_asm_func_def=".type @function",
 778     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 779       ac_cv_asm_func_def=".type 2",
 780       ac_cv_asm_func_def="unknown")])]))
 781
 782 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 783 case "$ac_cv_asm_func_def" in
 784   ".def")
 785      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 786   ".type @function")
 787      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 788   ".type 2")
 789      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 790   *)
 791      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 792 esac
 793
 794 dnl **** Check for underscore on external symbols ****
 795
 796 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 797     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 798                       [extern int ac_test;],
 799                       [if (ac_test) return 1],
 800                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 801
 802 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 803 if test "$ac_cv_c_extern_prefix" = "yes"
 804 then
 805   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 806 else
 807   AC_DEFINE([__ASM_NAME(name)], [name])
 808 fi
 809
 810 dnl **** Check how to do strings in assembler ****
 811
 812 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 813     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 814       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 815         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 816           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 817
 818 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 819                    [Define to the assembler keyword used to specify an ASCII string])
 820
 821 dnl **** Check for .short in assembler ****
 822
 823 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 824     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 825       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 826         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 827
 828 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 829                    [Define to the assembler keyword used to specify a word value])
 830
 831 dnl **** Check for working dll ****
 832
 833 AC_SUBST(DLLEXT,"")
 834 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 835 AC_SUBST(DLLIBS,"")
 836 AC_SUBST(LDSHARED,"")
 837 AC_SUBST(LDDLLFLAGS,"")
 838 AC_SUBST(LIBEXT,"so")
 839 AC_SUBST(IMPLIBEXT,"def")
 840
 841 case $host_os in
 842   cygwin*|mingw32*)
 843     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 844     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 845     if test "$DLLWRAP" = "false"; then
 846       LIBEXT="a"
 847     else
 848       dnl FIXME - check whether dllwrap works correctly...
 849       LIBEXT="dll"
 850     fi
 851     IMPLIBEXT="a"
 852     ;;
 853   *)
 854     AC_CHECK_HEADERS(dlfcn.h,
 855         [AC_CHECK_FUNCS(dlopen,,
 856             [AC_CHECK_LIB(dl,dlopen,
 857                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 858                           DLLIBS="-ldl"],
 859                          [LIBEXT="a"])])],
 860         [LIBEXT="a"])
 861
 862     if test "$LIBEXT" = "so"
 863     then
 864       DLLFLAGS="$DLLFLAGS -fPIC"
 865       DLLEXT=".so"
 866       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 867           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 868                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 869       if test "$ac_cv_c_dll_gnuelf" = "yes"
 870       then
 871         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 872         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 873         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 874           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 875                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 876         if test "$ac_cv_c_dll_zdefs" = "yes"
 877         then
 878           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 879         fi
 880
 881         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 882           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 883                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 884         if test "$ac_cv_c_dll_init_fini" = "yes"
 885         then
 886           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 887         fi
 888
 889         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 890           [echo '{ global: *; };' >conftest.map
 891            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 892                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 893            rm -f conftest.map])
 894         if test "$ac_cv_c_ld_version_scripts" = "yes"
 895         then
 896           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 897         fi
 898
 899         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 900           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 901                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 902         if test "$ac_cv_c_export_dynamic" = "yes"
 903         then
 904           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 905         fi
 906
 907         case $host_cpu in
 908           *i[[3456789]]86*)
 909             AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
 910               [saved_CFLAGS="$CFLAGS"
 911                CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
 912                AC_TRY_RUN([#include <unistd.h>
 913                            int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
 914                           ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
 915                CFLAGS="$saved_CFLAGS"])
 916             if test "$ac_cv_ld_reloc_exec" = "yes"
 917             then
 918               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
 919             fi
 920             ;;
 921         esac
 922
 923       else
 924         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 925             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 926                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 927         if test "$ac_cv_c_dll_unixware" = "yes"
 928         then
 929           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 930           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 931
 932         else
 933           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 934             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 935           if test "$ac_cv_c_dll_macho" = "yes"
 936           then
 937             LIBEXT="dylib"
 938             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 939             LDSHARED="\$(CC) -dynamiclib"
 940             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 941           fi
 942         fi
 943       fi
 944     fi
 945
 946     dnl Check for cross compiler to build test programs
 947     AC_SUBST(CROSSTEST,"")
 948     if test "$cross_compiling" = "no"
 949     then
 950       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 951       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 952       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 953       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 954     fi
 955     ;;
 956 esac
 957
 958 if test "$LIBEXT" = "a"; then
 959   AC_MSG_ERROR(
 960 [could not find a way to build shared libraries.
 961 It is currently not possible to build Wine without shared library
 962 (.so) support to allow transparent switch between .so and .dll files.
 963 If you are using Linux, you will need a newer binutils.]
 964 )
 965 fi
 966
 967 case $build_os in
 968   cygwin*|mingw32*)
 969     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 970   darwin*|macosx*)
 971     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 972   *)
 973     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 974 esac
 975
 976 dnl Mingw needs explicit msvcrt for linking libwine
 977 case $host_os in
 978   mingw32*)
 979     AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
 980 esac
 981
 982 case $host_os in
 983   linux*)
 984     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
 985     AC_SUBST(MAIN_BINARY,"wine-glibc")
 986     ;;
 987   *)
 988     AC_SUBST(WINE_BINARIES,"wine-kthread")
 989     AC_SUBST(MAIN_BINARY,"wine-kthread")
 990     ;;
 991 esac
 992
 993 dnl **** Get the soname for libraries that we load dynamically ****
 994
 995 if test "$LIBEXT" = "so"
 996 then
 997   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
 998   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 999   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1000   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1001   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1002   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1003   WINE_GET_SONAME(cups,cupsGetDefault)
1004   WINE_GET_SONAME(jack,jack_client_new)
1005   WINE_GET_SONAME(fontconfig,FcInit)
1006   WINE_GET_SONAME(ssl,SSL_library_init)
1007   WINE_GET_SONAME(crypto,BIO_new_socket)
1008   WINE_GET_SONAME(ncurses,waddch)
1009   WINE_GET_SONAME(curses,waddch)
1010 fi
1011
1012
1013 dnl **** Check for functions ****
1014
1015 AC_FUNC_ALLOCA()
1016 AC_CHECK_FUNCS(\
1017         _lwp_create \
1018         _lwp_self \
1019         _pclose \
1020         _popen \
1021         _snprintf \
1022         _spawnvp \
1023         _stricmp \
1024         _strnicmp \
1025         _vsnprintf \
1026         chsize \
1027         clone \
1028         finite \
1029         fpclass \
1030         ftruncate \
1031         ftruncate64 \
1032         getnetbyaddr \
1033         getnetbyname \
1034         getopt_long \
1035         getpagesize \
1036         getprotobyname \
1037         getprotobynumber \
1038         getpwuid \
1039         getservbyport \
1040         gettid \
1041         gettimeofday \
1042         inet_network \
1043         lseek64 \
1044         lstat \
1045         memmove \
1046         mmap \
1047         pclose \
1048         popen \
1049         pread \
1050         pwrite \
1051         readlink \
1052         rfork \
1053         select \
1054         sendmsg \
1055         settimeofday \
1056         sigaltstack \
1057         snprintf \
1058         spawnvp \
1059         statfs \
1060         statvfs \
1061         strcasecmp \
1062         strerror \
1063         strncasecmp \
1064         tcgetattr \
1065         timegm \
1066         usleep \
1067         vfscanf \
1068         vsnprintf \
1069         wait4 \
1070         waitpid \
1071 )
1072
1073 dnl **** Check for header files ****
1074
1075 AC_CHECK_HEADERS(\
1076         arpa/inet.h \
1077         arpa/nameser.h \
1078         cups/cups.h \
1079         direct.h \
1080         elf.h \
1081         float.h \
1082         fontconfig/fontconfig.h \
1083         getopt.h \
1084         ieeefp.h \
1085         io.h \
1086         jack/jack.h \
1087         libio.h \
1088         libutil.h \
1089         link.h \
1090         linux/cdrom.h \
1091         linux/hdreg.h \
1092         linux/input.h \
1093         linux/ioctl.h \
1094         linux/joystick.h \
1095         linux/major.h \
1096         linux/param.h \
1097         linux/serial.h \
1098         linux/ucdrom.h \
1099         machine/cpu.h \
1100         netdb.h \
1101         netinet/in.h \
1102         netinet/in_systm.h \
1103         netinet/tcp.h \
1104         netinet/tcp_fsm.h \
1105         openssl/ssl.h \
1106         process.h \
1107         pthread.h \
1108         pty.h \
1109         pwd.h \
1110         regex.h \
1111         sched.h \
1112         scsi/sg.h \
1113         scsi/scsi.h \
1114         scsi/scsi_ioctl.h \
1115         socket.h \
1116         stdint.h \
1117         strings.h \
1118         sys/cdio.h \
1119         sys/elf32.h \
1120         sys/errno.h \
1121         sys/exec_elf.h \
1122         sys/file.h \
1123         sys/filio.h \
1124         sys/inttypes.h \
1125         sys/ioctl.h \
1126         sys/ipc.h \
1127         sys/link.h \
1128         sys/lwp.h \
1129         sys/mman.h \
1130         sys/modem.h \
1131         sys/msg.h \
1132         sys/param.h \
1133         sys/poll.h \
1134         sys/ptrace.h \
1135         sys/reg.h \
1136         sys/scsiio.h \
1137         sys/shm.h \
1138         sys/signal.h \
1139         sys/socket.h \
1140         sys/sockio.h \
1141         sys/statfs.h \
1142         sys/statvfs.h \
1143         sys/strtio.h \
1144         sys/syscall.h \
1145         sys/sysctl.h \
1146         sys/time.h \
1147         sys/times.h \
1148         sys/uio.h \
1149         sys/un.h \
1150         sys/v86.h \
1151         sys/v86intr.h \
1152         sys/vfs.h \
1153         sys/vm86.h \
1154         sys/wait.h \
1155         syscall.h \
1156         termios.h \
1157         unistd.h \
1158         utime.h \
1159         valgrind/memcheck.h
1160 )
1161 AC_HEADER_STAT()
1162
1163 dnl **** Checks for headers that depend on other ones ****
1164
1165 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1166     [#include <sys/types.h>
1167      #if HAVE_SYS_PARAM_H
1168      # include <sys/param.h>
1169      #endif])
1170
1171 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1172     [#include <sys/types.h>
1173      #if HAVE_SYS_SOCKET_H
1174      # include <sys/socket.h>
1175      #endif])
1176
1177 AC_CHECK_HEADERS([resolv.h],,,
1178     [#include <sys/types.h>
1179      #if HAVE_SYS_SOCKET_H
1180      # include <sys/socket.h>
1181      #endif
1182      #if HAVE_NETINET_IN_H
1183      # include <netinet/in.h>
1184      #endif
1185      #if HAVE_ARPA_NAMESER_H
1186      # include <arpa/nameser.h>
1187      #endif])
1188
1189 AC_CHECK_HEADERS(netinet/ip.h,,,
1190     [#include <sys/types.h>
1191      #if HAVE_SYS_SOCKET_H
1192      # include <sys/socket.h>
1193      #endif
1194      #if HAVE_NETINET_IN_SYSTM_H
1195      # include <netinet/in_systm.h>
1196      #endif])
1197
1198 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1199
1200 dnl **** Check for IPX headers (currently Linux only) ****
1201
1202 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1203  AC_TRY_COMPILE(
1204    [#include <sys/types.h>
1205     #ifdef HAVE_SYS_SOCKET_H
1206     # include <sys/socket.h>
1207     #endif
1208     #include <netipx/ipx.h>],
1209    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1210    [ac_cv_c_ipx_gnu="yes"],
1211    [ac_cv_c_ipx_gnu="no"])
1212  )
1213 if test "$ac_cv_c_ipx_gnu" = "yes"
1214 then
1215     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1216 fi
1217
1218 if test "$ac_cv_c_ipx_gnu" = "no"
1219 then
1220  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1221   AC_TRY_COMPILE(
1222     [#include <sys/types.h>
1223      #ifdef HAVE_SYS_SOCKET_H
1224      # include <sys/socket.h>
1225      #endif
1226      #include <asm/types.h>
1227      #include <linux/ipx.h>],
1228     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1229     [ac_cv_c_ipx_linux="yes"],
1230     [ac_cv_c_ipx_linux="no"])
1231   )
1232   if test "$ac_cv_c_ipx_linux" = "yes"
1233   then
1234       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1235   fi
1236 fi
1237
1238 dnl **** Check for types ****
1239
1240 AC_C_CONST
1241 AC_C_INLINE
1242 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1243
1244 AC_CACHE_CHECK([whether linux/input.h is for real],
1245         wine_cv_linux_input_h,
1246         AC_TRY_COMPILE([
1247             #include <linux/input.h>
1248         ] , [
1249             int foo = EVIOCGBIT(EV_ABS,42);
1250             int bar = BTN_PINKIE;
1251             int fortytwo = 42;
1252         ],
1253         wine_cv_linux_input_h=yes,
1254         wine_cv_linux_input_h=no,
1255         no
1256         )
1257     )
1258     if test "$wine_cv_linux_input_h" = "yes"
1259     then
1260         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1261                   [Define if we have linux/input.h AND it contains the INPUT event API])
1262     fi
1263
1264
1265 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1266         wine_cv_linux_gethostbyname_r_6,
1267         AC_TRY_LINK([
1268 #include <netdb.h>
1269         ], [
1270     char *name=NULL;
1271     struct hostent he;
1272     struct hostent *result;
1273     char *buf=NULL;
1274     int bufsize=0;
1275     int res,errnr;
1276     char *addr=NULL;
1277     int addrlen=0;
1278     int addrtype=0;
1279     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1280     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1281     ],
1282         wine_cv_linux_gethostbyname_r_6=yes,
1283         wine_cv_linux_gethostbyname_r_6=no
1284         )
1285    )
1286    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1287    then
1288       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1289                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1290    fi
1291
1292 if test "$ac_cv_header_linux_joystick_h" = "yes"
1293 then
1294    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1295         wine_cv_linux_joystick_22_api,
1296         AC_TRY_COMPILE([
1297         #include <sys/ioctl.h>
1298         #include <linux/joystick.h>
1299
1300         struct js_event blub;
1301         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1302         #error "no 2.2 header"
1303         #endif
1304         ],/*empty*/,
1305         wine_cv_linux_joystick_22_api=yes,
1306         wine_cv_linux_joystick_22_api=no,
1307         wine_cv_linux_joystick_22_api=no
1308         )
1309    )
1310    if test "$wine_cv_linux_joystick_22_api" = "yes"
1311    then
1312       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1313                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1314    fi
1315 fi
1316
1317 dnl **** statfs checks ****
1318
1319 if test "$ac_cv_header_sys_vfs_h" = "yes"
1320 then
1321     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1322                     wine_cv_sys_vfs_has_statfs,
1323         AC_TRY_COMPILE([
1324         #include <sys/types.h>
1325         #ifdef HAVE_SYS_PARAM_H
1326         # include <sys/param.h>
1327         #endif
1328         #include <sys/vfs.h>
1329         ],[
1330                 struct statfs stfs;
1331
1332                 memset(&stfs,0,sizeof(stfs));
1333         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1334         )
1335     )
1336     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1337     then
1338       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1339                 [Define if the struct statfs is defined by <sys/vfs.h>])
1340     fi
1341 fi
1342
1343 if test "$ac_cv_header_sys_statfs_h" = "yes"
1344 then
1345     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1346                     wine_cv_sys_statfs_has_statfs,
1347         AC_TRY_COMPILE([
1348         #include <sys/types.h>
1349         #ifdef HAVE_SYS_PARAM_H
1350         # include <sys/param.h>
1351         #endif
1352         #include <sys/statfs.h>
1353         ],[
1354                 struct statfs stfs;
1355         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1356         )
1357     )
1358     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1359     then
1360       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1361                 [Define if the struct statfs is defined by <sys/statfs.h>])
1362     fi
1363 fi
1364
1365 if test "$ac_cv_header_sys_mount_h" = "yes"
1366 then
1367     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1368                     wine_cv_sys_mount_has_statfs,
1369         AC_TRY_COMPILE([
1370         #include <sys/types.h>
1371         #ifdef HAVE_SYS_PARAM_H
1372         # include <sys/param.h>
1373         #endif
1374         #include <sys/mount.h>
1375         ],[
1376                 struct statfs stfs;
1377         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1378         )
1379     )
1380     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1381     then
1382       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1383                 [Define if the struct statfs is defined by <sys/mount.h>])
1384     fi
1385 fi
1386
1387 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1388
1389 dnl Check for statfs members
1390 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1391 [#include <sys/types.h>
1392 #ifdef HAVE_SYS_PARAM_H
1393 # include <sys/param.h>
1394 #endif
1395 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1396 # include <sys/mount.h>
1397 #else
1398 # ifdef STATFS_DEFINED_BY_SYS_VFS
1399 #  include <sys/vfs.h>
1400 # else
1401 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1402 #   include <sys/statfs.h>
1403 #  endif
1404 # endif
1405 #endif])
1406
1407 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1408 [#ifdef HAVE_SYS_STATVFS_H
1409 #include <sys/statvfs.h>
1410 #endif])
1411
1412 dnl Check for socket structure members
1413 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1414 [#include <sys/types.h>
1415 #ifdef HAVE_SYS_SOCKET_H
1416 # include <sys/socket.h>
1417 #endif
1418 #ifdef HAVE_SYS_UN_H
1419 # include <sys/un.h>
1420 #endif])
1421
1422 dnl Check for siginfo_t members
1423 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1424
1425 dnl Check for struct option
1426 AC_CHECK_MEMBERS([struct option.name],,,
1427 [#ifdef HAVE_GETOPT_H
1428 #include <getopt.h>
1429 #endif])
1430
1431 dnl Check for stat.st_blocks
1432 AC_CHECK_MEMBERS([struct stat.st_blocks])
1433
1434 dnl *** check for the need to define platform-specific symbols
1435
1436 case $host_cpu in
1437   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1438   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1439   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1440   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1441 esac
1442
1443 case $host_vendor in
1444   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1445 esac
1446
1447 dnl **** Generate output files ****
1448
1449 AH_TOP([#define __WINE_CONFIG_H])
1450
1451 WINE_CONFIG_EXTRA_DIR(controls)
1452 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1453 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1454 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1455 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1456 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1457 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1458 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1459 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1460 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1461 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1462 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1463 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1464 WINE_CONFIG_EXTRA_DIR(files)
1465 WINE_CONFIG_EXTRA_DIR(include/wine)
1466 WINE_CONFIG_EXTRA_DIR(misc)
1467 WINE_CONFIG_EXTRA_DIR(objects)
1468 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1469 WINE_CONFIG_EXTRA_DIR(windows)
1470
1471 MAKE_RULES=Make.rules
1472 AC_SUBST_FILE(MAKE_RULES)
1473
1474 MAKE_DLL_RULES=dlls/Makedll.rules
1475 AC_SUBST_FILE(MAKE_DLL_RULES)
1476
1477 MAKE_TEST_RULES=dlls/Maketest.rules
1478 AC_SUBST_FILE(MAKE_TEST_RULES)
1479
1480 MAKE_LIB_RULES=libs/Makelib.rules
1481 AC_SUBST_FILE(MAKE_LIB_RULES)
1482
1483 MAKE_PROG_RULES=programs/Makeprog.rules
1484 AC_SUBST_FILE(MAKE_PROG_RULES)
1485
1486 AC_CONFIG_FILES([
1487 Make.rules
1488 dlls/Makedll.rules
1489 dlls/Maketest.rules
1490 libs/Makelib.rules
1491 programs/Makeprog.rules
1492 Makefile
1493 dlls/Makefile
1494 dlls/advapi32/Makefile
1495 dlls/advapi32/tests/Makefile
1496 dlls/amstream/Makefile
1497 dlls/avicap32/Makefile
1498 dlls/avifil32/Makefile
1499 dlls/cabinet/Makefile
1500 dlls/capi2032/Makefile
1501 dlls/cards/Makefile
1502 dlls/cfgmgr32/Makefile
1503 dlls/comcat/Makefile
1504 dlls/comctl32/Makefile
1505 dlls/comctl32/tests/Makefile
1506 dlls/commdlg/Makefile
1507 dlls/crtdll/Makefile
1508 dlls/crypt32/Makefile
1509 dlls/ctl3d/Makefile
1510 dlls/d3d8/Makefile
1511 dlls/d3d9/Makefile
1512 dlls/d3dim/Makefile
1513 dlls/d3dx8/Makefile
1514 dlls/dciman32/Makefile
1515 dlls/ddraw/Makefile
1516 dlls/ddraw/tests/Makefile
1517 dlls/devenum/Makefile
1518 dlls/dinput/Makefile
1519 dlls/dinput8/Makefile
1520 dlls/dmband/Makefile
1521 dlls/dmcompos/Makefile
1522 dlls/dmime/Makefile
1523 dlls/dmloader/Makefile
1524 dlls/dmscript/Makefile
1525 dlls/dmstyle/Makefile
1526 dlls/dmsynth/Makefile
1527 dlls/dmusic/Makefile
1528 dlls/dmusic32/Makefile
1529 dlls/dplay/Makefile
1530 dlls/dplayx/Makefile
1531 dlls/dpnhpast/Makefile
1532 dlls/dsound/Makefile
1533 dlls/dsound/tests/Makefile
1534 dlls/dswave/Makefile
1535 dlls/dxerr8/Makefile
1536 dlls/dxerr9/Makefile
1537 dlls/dxguid/Makefile
1538 dlls/gdi/Makefile
1539 dlls/gdi/tests/Makefile
1540 dlls/glu32/Makefile
1541 dlls/glut32/Makefile
1542 dlls/iccvid/Makefile
1543 dlls/icmp/Makefile
1544 dlls/ifsmgr.vxd/Makefile
1545 dlls/imagehlp/Makefile
1546 dlls/imm32/Makefile
1547 dlls/iphlpapi/Makefile
1548 dlls/iphlpapi/tests/Makefile
1549 dlls/kernel/Makefile
1550 dlls/kernel/tests/Makefile
1551 dlls/lzexpand/Makefile
1552 dlls/mapi32/Makefile
1553 dlls/mmdevldr.vxd/Makefile
1554 dlls/monodebg.vxd/Makefile
1555 dlls/mpr/Makefile
1556 dlls/msacm/Makefile
1557 dlls/msacm/imaadp32/Makefile
1558 dlls/msacm/msadp32/Makefile
1559 dlls/msacm/msg711/Makefile
1560 dlls/msacm/winemp3/Makefile
1561 dlls/msdmo/Makefile
1562 dlls/mshtml/Makefile
1563 dlls/msi/Makefile
1564 dlls/msimg32/Makefile
1565 dlls/msisys/Makefile
1566 dlls/msnet32/Makefile
1567 dlls/msrle32/Makefile
1568 dlls/msvcrt/Makefile
1569 dlls/msvcrt/tests/Makefile
1570 dlls/msvcrt20/Makefile
1571 dlls/msvcrt40/Makefile
1572 dlls/msvcrtd/Makefile
1573 dlls/msvidc32/Makefile
1574 dlls/msvideo/Makefile
1575 dlls/mswsock/Makefile
1576 dlls/netapi32/Makefile
1577 dlls/netapi32/tests/Makefile
1578 dlls/newdev/Makefile
1579 dlls/ntdll/Makefile
1580 dlls/ntdll/tests/Makefile
1581 dlls/odbc32/Makefile
1582 dlls/ole32/Makefile
1583 dlls/oleacc/Makefile
1584 dlls/oleaut32/Makefile
1585 dlls/oleaut32/tests/Makefile
1586 dlls/olecli/Makefile
1587 dlls/oledlg/Makefile
1588 dlls/olepro32/Makefile
1589 dlls/olesvr/Makefile
1590 dlls/opengl32/Makefile
1591 dlls/psapi/Makefile
1592 dlls/qcap/Makefile
1593 dlls/quartz/Makefile
1594 dlls/rasapi32/Makefile
1595 dlls/richedit/Makefile
1596 dlls/rpcrt4/Makefile
1597 dlls/rpcrt4/tests/Makefile
1598 dlls/rsabase/Makefile
1599 dlls/secur32/Makefile
1600 dlls/serialui/Makefile
1601 dlls/setupapi/Makefile
1602 dlls/shdocvw/Makefile
1603 dlls/shell32/Makefile
1604 dlls/shell32/tests/Makefile
1605 dlls/shfolder/Makefile
1606 dlls/shlwapi/Makefile
1607 dlls/shlwapi/tests/Makefile
1608 dlls/snmpapi/Makefile
1609 dlls/sti/Makefile
1610 dlls/tapi32/Makefile
1611 dlls/ttydrv/Makefile
1612 dlls/twain/Makefile
1613 dlls/unicows/Makefile
1614 dlls/url/Makefile
1615 dlls/urlmon/Makefile
1616 dlls/urlmon/tests/Makefile
1617 dlls/user/Makefile
1618 dlls/user/tests/Makefile
1619 dlls/uuid/Makefile
1620 dlls/uxtheme/Makefile
1621 dlls/vdhcp.vxd/Makefile
1622 dlls/version/Makefile
1623 dlls/vmm.vxd/Makefile
1624 dlls/vnbt.vxd/Makefile
1625 dlls/vnetbios.vxd/Makefile
1626 dlls/vtdapi.vxd/Makefile
1627 dlls/vwin32.vxd/Makefile
1628 dlls/win32s/Makefile
1629 dlls/winaspi/Makefile
1630 dlls/wined3d/Makefile
1631 dlls/winedos/Makefile
1632 dlls/wineps/Makefile
1633 dlls/wininet/Makefile
1634 dlls/wininet/tests/Makefile
1635 dlls/winmm/Makefile
1636 dlls/winmm/joystick/Makefile
1637 dlls/winmm/mcianim/Makefile
1638 dlls/winmm/mciavi/Makefile
1639 dlls/winmm/mcicda/Makefile
1640 dlls/winmm/mciseq/Makefile
1641 dlls/winmm/mciwave/Makefile
1642 dlls/winmm/midimap/Makefile
1643 dlls/winmm/tests/Makefile
1644 dlls/winmm/wavemap/Makefile
1645 dlls/winmm/winealsa/Makefile
1646 dlls/winmm/winearts/Makefile
1647 dlls/winmm/wineaudioio/Makefile
1648 dlls/winmm/winejack/Makefile
1649 dlls/winmm/winenas/Makefile
1650 dlls/winmm/wineoss/Makefile
1651 dlls/winnls/Makefile
1652 dlls/winsock/Makefile
1653 dlls/winsock/tests/Makefile
1654 dlls/winspool/Makefile
1655 dlls/winspool/tests/Makefile
1656 dlls/wintab32/Makefile
1657 dlls/wintrust/Makefile
1658 dlls/wow32/Makefile
1659 dlls/wsock32/Makefile
1660 dlls/x11drv/Makefile
1661 documentation/Makefile
1662 include/Makefile
1663 libs/Makefile
1664 libs/port/Makefile
1665 libs/unicode/Makefile
1666 libs/wine/Makefile
1667 libs/wpp/Makefile
1668 loader/Makefile
1669 programs/Makefile
1670 programs/avitools/Makefile
1671 programs/clock/Makefile
1672 programs/cmdlgtst/Makefile
1673 programs/control/Makefile
1674 programs/expand/Makefile
1675 programs/notepad/Makefile
1676 programs/progman/Makefile
1677 programs/regedit/Makefile
1678 programs/regsvr32/Makefile
1679 programs/rpcss/Makefile
1680 programs/rundll32/Makefile
1681 programs/start/Makefile
1682 programs/uninstaller/Makefile
1683 programs/view/Makefile
1684 programs/wcmd/Makefile
1685 programs/wineboot/Makefile
1686 programs/winebrowser/Makefile
1687 programs/winecfg/Makefile
1688 programs/wineconsole/Makefile
1689 programs/winedbg/Makefile
1690 programs/winefile/Makefile
1691 programs/winemenubuilder/Makefile
1692 programs/winemine/Makefile
1693 programs/winepath/Makefile
1694 programs/winetest/Makefile
1695 programs/winevdm/Makefile
1696 programs/winhelp/Makefile
1697 programs/winver/Makefile
1698 server/Makefile
1699 tools/Makefile
1700 tools/widl/Makefile
1701 tools/winapi/Makefile
1702 tools/winebuild/Makefile
1703 tools/winedump/Makefile
1704 tools/winegcc/Makefile
1705 tools/wmc/Makefile
1706 tools/wrc/Makefile])
1707
1708 AC_OUTPUT
1709
1710 if test "$have_x" = "no"
1711 then
1712   echo
1713   echo "*** Warning: X development files not found. Wine will be built without"
1714   echo "*** X support, which currently does not work, and would probably not be"
1715   echo "*** what you want anyway. You will need to install devel packages of"
1716   echo "*** Xlib/Xfree86 at the very least."
1717 fi
1718
1719 if test "$wine_cv_opengl_version_OK" = "no"
1720 then
1721   echo
1722   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1723   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1724 fi
1725
1726 if test "$wine_cv_msg_freetype" = "yes"
1727 then
1728   echo
1729   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1730   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1731   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1732   echo "*** enable Wine to use TrueType fonts."
1733 fi
1734
1735 echo
1736 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1737 echo
1738
1739 dnl Local Variables:
1740 dnl comment-start: "dnl "
1741 dnl comment-end: ""
1742 dnl comment-start-skip: "\\bdnl\\b\\s *"
1743 dnl compile-command: "autoconf"
1744 dnl End: