git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CPP
  45
  46 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  47   [if test -z "$with_wine_tools"; then
  48      if test "$cross_compiling" = "yes"; then
  49        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  50      else
  51        wine_cv_toolsdir="\$(TOPOBJDIR)"
  52      fi
  53    elif test -d "$with_wine_tools/tools/winebuild"; then
  54      case $with_wine_tools in
  55        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  56        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  57      esac
  58    else
  59      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  60    fi])
  61 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  62
  63 AC_PATH_XTRA
  64 AC_PROG_YACC
  65 AC_PROG_LEX
  66
  67 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
  68 dnl **** without one present.
  69 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
  70 if test "$XYACC" = "none"
  71 then
  72   AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
  73 fi
  74 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  75 if test "$XLEX" = "none"
  76 then
  77   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  78 fi
  79
  80 AC_CHECK_TOOLS(AS,[gas as],as)
  81 AC_CHECK_TOOL(LD,ld,ld)
  82 AC_CHECK_TOOL(AR,ar,ar)
  83 AC_PROG_RANLIB
  84 AC_CHECK_TOOL(STRIP,strip,strip)
  85 AC_CHECK_TOOL(WINDRES,windres,false)
  86 AC_PROG_LN_S
  87 WINE_PROG_LN
  88 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  89 AC_PROG_INSTALL
  90 dnl Prepend src dir to install path dir if it's a relative path
  91 case "$INSTALL" in
  92   [[\\/$]]* | ?:[[\\/]]* ) ;;
  93   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  94 esac
  95
  96 dnl Check for lint
  97 AC_CHECK_PROGS(LINT, lclint lint)
  98 if test "$LINT" = "lint"
  99 then
 100   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 101   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 102 fi
 103 AC_SUBST(LINT)
 104 AC_SUBST(LINTFLAGS)
 105
 106 dnl Check for db2html
 107 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 108 AC_SUBST(DB2HTML)
 109
 110 dnl Check for db2pdf
 111 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 112 AC_SUBST(DB2PDF)
 113
 114 dnl Check for db2ps
 115 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 116 AC_SUBST(DB2PS)
 117
 118 dnl Check for db2txt
 119 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 120 AC_SUBST(DB2TXT)
 121
 122 dnl **** Check for some libraries ****
 123
 124 dnl Check for -lm
 125 AC_CHECK_LIB(m,sqrt)
 126 dnl Check for -li386 for NetBSD and OpenBSD
 127 AC_CHECK_LIB(i386,i386_set_ldt)
 128 dnl Check for -lossaudio for NetBSD
 129 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 130 dnl Check for -lw for Solaris
 131 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 132 dnl Check for -lnsl for Solaris
 133 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 134 dnl Check for -lsocket for Solaris
 135 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 136 dnl Check for -lresolv for Solaris
 137 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 138 dnl Check for -lxpg4 for FreeBSD
 139 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 140 dnl Check for -lpoll for Mac OS X/Darwin
 141 AC_CHECK_LIB(poll,poll)
 142 dnl Check for -lpthread
 143 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 144
 145 JPEGLIB=""
 146 AC_SUBST(JPEGLIB)
 147 AC_CHECK_HEADERS(jpeglib.h,
 148     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 149         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 150         JPEGLIB="-ljpeg"
 151     )
 152 )
 153
 154 AC_SUBST(GIFLIB,"")
 155 AC_CHECK_HEADERS(gif_lib.h,
 156     AC_CHECK_LIB(ungif,DGifOpen,
 157         [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
 158          GIFLIB="-lungif"],
 159         [AC_CHECK_LIB(gif,DGifOpen,
 160                       [AC_DEFINE(HAVE_LIBGIF,1)
 161                        GIFLIB="-lgif"])]))
 162
 163 AC_SUBST(XLIB)
 164 AC_SUBST(XFILES)
 165 XFILES=""
 166 AC_SUBST(OPENGLFILES)
 167 OPENGLFILES=""
 168 AC_SUBST(GLU32FILES)
 169 GLU32FILES=""
 170 AC_SUBST(OPENGL_LIBS)
 171 OPENGL_LIBS=""
 172 if test "$have_x" = "yes"
 173 then
 174     XLIB="-lXext -lX11"
 175     ac_save_CPPFLAGS="$CPPFLAGS"
 176     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 177
 178     dnl *** All of the following tests require X11/Xlib.h
 179     AC_CHECK_HEADERS(X11/Xlib.h,
 180       [
 181         AC_CHECK_HEADERS([X11/XKBlib.h \
 182                           X11/Xutil.h \
 183                           X11/extensions/shape.h \
 184                           X11/extensions/XInput.h \
 185                           X11/extensions/XShm.h \
 186                           X11/extensions/Xrandr.h \
 187                           X11/extensions/Xrender.h \
 188                           X11/extensions/Xvlib.h \
 189                           X11/extensions/xf86dga.h \
 190                           X11/extensions/xf86vmode.h],,,
 191                          [#include <X11/Xlib.h>
 192                           #ifdef HAVE_X11_XUTIL_H
 193                           # include <X11/Xutil.h>
 194                           #endif])
 195
 196         dnl *** Check for X keyboard extension
 197         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 198         then
 199               AC_CHECK_LIB(X11, XkbQueryExtension,
 200               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 201               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 202         fi
 203
 204         dnl *** Check for X Shm extension
 205         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 206         then
 207               AC_CHECK_LIB(Xext, XShmQueryExtension,
 208               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 209               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 210         fi
 211
 212         dnl *** Check for X shape extension
 213         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 214         then
 215               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 216               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 217               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 218         fi
 219
 220         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 221         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 222         then
 223               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 224                 [ dnl *** If found...
 225                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 226                             [Define if you have the Xxf86dga library version 2])
 227                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 228                ],
 229                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 230                   dnl *** instead (DGA 2.0 not found)...
 231                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 232                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 233                                 [Define if you have the Xxf86dga library version 1])
 234                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 235                     ],,
 236                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 237                   )
 238                 ],
 239                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 240         fi
 241
 242         dnl *** Check for XFree86 VMODE extension
 243         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 244         then
 245                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 246                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 247                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 248                   ],,
 249                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 250         fi
 251
 252         dnl *** Check for X RandR extension
 253         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 254         then
 255                 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
 256                   [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
 257                      X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
 258                   ],,
 259                   $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
 260         fi
 261
 262         dnl *** Check for XVideo extension supporting XvImages
 263         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 264         then
 265                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 266                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 267                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 268                   ],,
 269                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 270         fi
 271       ]
 272     ) dnl *** End of X11/Xlib.h check
 273
 274     dnl Check for the presence of OpenGL
 275     if test "x$with_opengl" != "xno"
 276     then
 277         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 278         then
 279             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 280 This prevents linking to OpenGL. Delete the file and restart configure.])
 281         fi
 282
 283         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 284         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 285         then
 286             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 287             dnl Check for some problems due to old Mesa versions
 288             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 289               AC_TRY_COMPILE(
 290                 [#include <GL/gl.h>],
 291                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 292                 [wine_cv_opengl_version_OK="yes"],
 293                 [wine_cv_opengl_version_OK="no"]
 294               )
 295             )
 296
 297             if test "$wine_cv_opengl_version_OK" = "yes"
 298             then
 299                 dnl Check for the presence of the library
 300                 AC_CHECK_LIB(GL,glXCreateContext,
 301                              OPENGL_LIBS="-lGL"
 302                              ,,
 303                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 304
 305                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 306                 then
 307                         OPENGLFILES='$(OPENGLFILES)'
 308                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 309
 310                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 311                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 312                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 313                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 314
 315                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 316                         then
 317                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 318                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 319                                                   #ifdef HAVE_GL_GLEXT_H
 320                                                   # include <GL/glext.h>
 321                                                   #endif
 322                                                   ],
 323                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 324                                                  [wine_cv_extension_prototypes="yes"],
 325                                                  [wine_cv_extension_prototypes="no"]
 326                                   )]
 327                                 )
 328                                 if test "$wine_cv_extension_prototypes" = "yes"
 329                                 then
 330                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 331                                               [Define if the OpenGL headers define extension typedefs])
 332                                 fi
 333                         fi
 334
 335                 fi
 336                 dnl Check for GLU32 library.
 337                 AC_CHECK_LIB(GLU,gluLookAt,
 338                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 339                              GLU32FILES='$(GLU32FILES)']
 340                              ,,
 341                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 342                 )
 343              fi
 344
 345              dnl Check for glut32 library.
 346              AC_CHECK_LIB(glut,glutMainLoop,
 347                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 348                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 349                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 350          fi
 351     fi
 352
 353     dnl **** Check for NAS ****
 354     AC_SUBST(NASLIBS,"")
 355     AC_CHECK_HEADERS(audio/audiolib.h,
 356          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 357           AC_CHECK_LIB(audio,AuCreateFlow,
 358                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 359                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 360                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 361
 362     CPPFLAGS="$ac_save_CPPFLAGS"
 363     XFILES='$(XFILES)'
 364 else
 365     XLIB=""
 366     X_CFLAGS=""
 367     X_LIBS=""
 368 fi
 369
 370 dnl **** Check which curses lib to use ***
 371 CURSESLIBS=""
 372 if test "x$with_curses" != "xno"
 373 then
 374     AC_CHECK_HEADERS(ncurses.h,
 375         [AC_CHECK_LIB(ncurses,waddch,
 376             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 377              CURSESLIBS="-lncurses"],
 378              [AC_CHECK_HEADERS(curses.h,
 379                  [AC_CHECK_LIB(curses,waddch,
 380                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 381                       CURSESLIBS="-lcurses"])])])])
 382     saved_libs="$LIBS"
 383     LIBS="$CURSESLIBS $LIBS"
 384     AC_CHECK_FUNCS(getbkgd resizeterm)
 385     LIBS="$saved_libs"
 386 fi
 387 AC_SUBST(CURSESLIBS)
 388
 389 dnl **** Check for SANE ****
 390 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 391 if test "$sane_devel" = "no"
 392 then
 393     SANELIBS=""
 394     SANEINCL=""
 395 else
 396     SANELIBS="`$sane_devel --libs`"
 397     SANEINCL="`$sane_devel --cflags`"
 398     ac_save_CPPFLAGS="$CPPFLAGS"
 399     ac_save_LIBS="$LIBS"
 400     CPPFLAGS="$CPPFLAGS $SANEINCL"
 401     LIBS="$LIBS $SANELIBS"
 402     AC_CHECK_HEADER(sane/sane.h,
 403                     [AC_CHECK_LIB(sane,sane_open,
 404                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 405                                   [SANELIBS=""
 406                                   SANEINCL=""])],
 407                     [SANELIBS=""
 408                     SANEINCL=""])
 409     LIBS="$ac_save_LIBS"
 410     CPPFLAGS="$ac_save_CPPFLAGS"
 411 fi
 412 AC_SUBST(SANELIBS)
 413 AC_SUBST(SANEINCL)
 414
 415 dnl **** Check for the ICU library ****
 416 AC_CHECK_HEADERS(unicode/ubidi.h)
 417 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 418 then
 419     AC_CACHE_CHECK([whether we can statically link the ICU libraries], ac_cv_lib_icu,
 420         [saved_libs="$LIBS"
 421          ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 422          ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
 423          ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
 424          LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 425          AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 426                      [ac_cv_lib_icu="yes"],[ac_cv_lib_icu="no"])
 427         LIBS="$saved_libs"])
 428     if test "$ac_cv_lib_icu" = "yes"
 429     then
 430         AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 431         AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 432     fi
 433 fi
 434
 435 dnl **** Check for FreeType 2 ****
 436 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 437 if test "$ft_lib" = "no"
 438 then
 439     FREETYPEINCL=""
 440     wine_cv_msg_freetype=no
 441 else
 442     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 443     if test "$ft_devel" = "no"
 444     then
 445         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 446         if test "$ft_devel2" = "freetype2-config"
 447         then
 448                 ft_devel=$ft_devel2
 449         fi
 450     fi
 451     if test "$ft_devel" = "no"
 452     then
 453         FREETYPEINCL=""
 454         wine_cv_msg_freetype=yes
 455     else
 456         FREETYPEINCL=`$ft_devel --cflags`
 457         ac_save_CPPFLAGS="$CPPFLAGS"
 458         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 459         AC_CHECK_HEADERS(ft2build.h \
 460                          freetype/freetype.h \
 461                          freetype/ftglyph.h \
 462                          freetype/tttables.h \
 463                          freetype/ftnames.h \
 464                          freetype/ftsnames.h \
 465                          freetype/ttnameid.h \
 466                          freetype/ftoutln.h \
 467                          freetype/internal/sfnt.h,,,
 468                          [#if HAVE_FT2BUILD_H
 469                           #include <ft2build.h>
 470                           #endif])
 471         AC_TRY_CPP([#include <ft2build.h>
 472                     #include <freetype/fttrigon.h>],
 473                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 474           [Define if you have the <freetype/fttrigon.h> header file.])
 475                     wine_cv_fttrigon=yes],
 476                     wine_cv_fttrigon=no)
 477         CPPFLAGS="$ac_save_CPPFLAGS"
 478         dnl Check that we have at least freetype/freetype.h
 479         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 480         then
 481             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 482             wine_cv_msg_freetype=no
 483         else
 484             FREETYPEINCL=""
 485             wine_cv_msg_freetype=yes
 486         fi
 487     fi
 488 fi
 489 AC_SUBST(FREETYPEINCL)
 490
 491 dnl **** Check for parport (currently Linux only) ****
 492 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 493  AC_TRY_COMPILE(
 494    [#include <linux/ppdev.h>],
 495    [ioctl (1,PPCLAIM,0)],
 496    [ac_cv_c_ppdev="yes"],
 497    [ac_cv_c_ppdev="no"])
 498  )
 499 if test "$ac_cv_c_ppdev" = "yes"
 500 then
 501     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 502 fi
 503
 504 dnl **** Check for va_copy ****
 505 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 506  AC_TRY_LINK(
 507    [#include <stdarg.h>],
 508    [va_list ap1, ap2;
 509     va_copy(ap1,ap2);
 510    ],
 511    [ac_cv_c_va_copy="yes"],
 512    [ac_cv_c_va_copy="no"])
 513  )
 514 if test "$ac_cv_c_va_copy" = "yes"
 515 then
 516     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 517 fi
 518 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 519  AC_TRY_LINK(
 520    [#include <stdarg.h>],
 521    [va_list ap1, ap2;
 522     __va_copy(ap1,ap2);
 523    ],
 524    [ac_cv_c___va_copy="yes"],
 525    [ac_cv_c___va_copy="no"])
 526  )
 527 if test "$ac_cv_c___va_copy" = "yes"
 528 then
 529     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 530 fi
 531
 532 dnl **** Check for sigsetjmp ****
 533 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 534  AC_TRY_LINK(
 535    [#include <setjmp.h>],
 536    [sigjmp_buf buf;
 537     sigsetjmp( buf, 1 );
 538     siglongjmp( buf, 1 );],
 539    [ac_cv_c_sigsetjmp="yes"],
 540    [ac_cv_c_sigsetjmp="no"])
 541  )
 542 if test "$ac_cv_c_sigsetjmp" = "yes"
 543 then
 544     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 545 fi
 546
 547 dnl **** Check for pthread_rwlock_t ****
 548 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 549 #include <pthread.h>])
 550
 551 dnl **** Check for pthread_getattr_np ****
 552 ac_save_LIBS="$LIBS"
 553 LIBS="$LIBS $LIBPTHREAD"
 554 AC_CHECK_FUNCS(pthread_getattr_np)
 555 LIBS="$ac_save_LIBS"
 556
 557 dnl **** Check for Open Sound System ****
 558 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 559
 560 AC_CACHE_CHECK([for Open Sound System],
 561         ac_cv_c_opensoundsystem,
 562         AC_TRY_COMPILE([
 563         #if defined(HAVE_SYS_SOUNDCARD_H)
 564                 #include <sys/soundcard.h>
 565         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 566                 #include <machine/soundcard.h>
 567         #elif defined(HAVE_SOUNDCARD_H)
 568                 #include <soundcard.h>
 569         #endif
 570         ],[
 571
 572 /* check for one of the Open Sound System specific SNDCTL_ defines */
 573 #if !defined(SNDCTL_DSP_STEREO)
 574 #error No open sound system
 575 #endif
 576 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 577
 578 if test "$ac_cv_c_opensoundsystem" = "yes"
 579 then
 580     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 581 fi
 582
 583 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 584         ac_cv_c_opensoundsystem_midi,
 585         AC_TRY_COMPILE([
 586         #if defined(HAVE_SYS_SOUNDCARD_H)
 587                 #include <sys/soundcard.h>
 588         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 589                 #include <machine/soundcard.h>
 590         #elif defined(HAVE_SOUNDCARD_H)
 591                 #include <soundcard.h>
 592         #endif
 593         ],[
 594
 595 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 596 #if !defined(SNDCTL_SEQ_SYNC)
 597 #error No open sound system MIDI interface
 598 #endif
 599 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 600
 601 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 602 then
 603     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 604 fi
 605
 606 dnl **** Check for aRts Sound Server ****
 607 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 608 AC_CACHE_CHECK([for aRts Sound server],
 609         ac_cv_c_artsserver,
 610         if test x$ARTSCCONFIG = x -o x$ARTSCCONFIG = x'"$ARTSCCONFIG"';
 611         then
 612             ac_cv_c_artsserver=no
 613         else
 614             ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
 615             ARTSC_LIBS=`$ARTSCCONFIG --libs`
 616             ac_cv_c_artsserver=no
 617             save_CFLAGS="$CFLAGS"
 618             CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 619             AC_TRY_COMPILE([
 620              #include <artsc.h>
 621             ],[
 622              arts_stream_t stream;
 623             ],[
 624             ac_cv_c_artsserver=yes
 625             ])
 626             CFLAGS="$save_CFLAGS"
 627         fi)
 628
 629 if test "$ac_cv_c_artsserver" = "yes"
 630 then
 631     AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 632     AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 633
 634     AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])
 635 fi
 636
 637 dnl **** Check for ALSA ****
 638 AC_SUBST(ALSALIBS,"")
 639 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 640 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 641 then
 642     AC_CHECK_LIB(asound,snd_pcm_open,
 643         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 644         ALSALIBS="-lasound")
 645 fi
 646
 647 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 648
 649 AC_SUBST(AUDIOIOLIBS,"")
 650 AC_CHECK_HEADERS(libaudioio.h,
 651     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 652                   [AUDIOIOLIBS="-laudioio"
 653                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 654
 655 dnl **** Check for capi4linux ****
 656
 657 AC_CHECK_HEADERS(capi20.h,[
 658         AC_CHECK_HEADERS(linux/capi.h,[
 659                 AC_CHECK_LIB(capi20,capi20_register,[
 660                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 661                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 662                 ])
 663         ])
 664 ])
 665
 666 dnl **** Check for broken glibc mmap64 ****
 667
 668 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 669         AC_TRY_RUN([
 670                 #define _FILE_OFFSET_BITS 64
 671                 #include <stdio.h>
 672                 #include <unistd.h>
 673                 #include <fcntl.h>
 674                 #include <sys/mman.h>
 675                 #include <errno.h>
 676
 677                 int main(int argc,char **argv) {
 678                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 679                         if (fd == -1) exit(1);
 680
 681                         unlink("conftest.map");
 682
 683                         write(fd,"test",4);
 684
 685                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 686                             (errno == EINVAL)
 687                         ) {
 688                                 exit(1);
 689                         }
 690                         close(fd);
 691                         fprintf(stderr,"success!\n");
 692                         exit(0);
 693                 }
 694
 695         ],
 696     ac_cv_mmap64_works="yes",
 697     ac_cv_mmap64_works="no",
 698     ac_cv_mmap64_works="no") )
 699
 700 if test "$ac_cv_mmap64_works" = "yes"
 701 then
 702     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 703 fi
 704
 705 dnl **** Check for gcc specific options ****
 706
 707 AC_SUBST(EXTRACFLAGS,"")
 708 if test "x${GCC}" = "xyes"
 709 then
 710   EXTRACFLAGS="-Wall -pipe"
 711
 712   dnl Check for strength-reduce bug
 713   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 714                   AC_TRY_RUN([
 715 int     L[[4]] = {0,1,2,3};
 716 int main(void) {
 717   static int Array[[3]];
 718   unsigned int B = 3;
 719   int i;
 720   for(i=0; i<B; i++) Array[[i]] = i - 3;
 721   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 722   L[[i]] = 4;
 723
 724   exit( Array[[1]] != -2 || L[[2]] != 3);
 725 }],
 726     ac_cv_c_gcc_strength_bug="no",
 727     ac_cv_c_gcc_strength_bug="yes",
 728     ac_cv_c_gcc_strength_bug="yes") )
 729   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 730   then
 731     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 732   fi
 733
 734   dnl Check for -mpreferred-stack-boundary
 735   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 736       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 737                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 738   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 739   then
 740     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 741   fi
 742
 743   dnl Check for -fno-strict-aliasing
 744   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 745       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 746                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 747   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 748   then
 749     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 750   fi
 751
 752   dnl Check for -gstabs+ option
 753   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 754       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 755   if test "$ac_cv_c_gcc_gstabs" = "yes"
 756   then
 757     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 758   fi
 759
 760   dnl Check for noisy string.h
 761   saved_CFLAGS="$CFLAGS"
 762   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 763   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 764       AC_TRY_COMPILE([#include <string.h>],[],
 765                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 766   CFLAGS="$saved_CFLAGS"
 767   if test "$ac_cv_c_string_h_warnings" = "no"
 768   then
 769     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 770   fi
 771 fi
 772
 773 dnl **** Check how to define a function in assembly code ****
 774
 775 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 776   WINE_TRY_ASM_LINK(
 777       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 778       ac_cv_asm_func_def=".def",
 779     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 780       ac_cv_asm_func_def=".type @function",
 781     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 782       ac_cv_asm_func_def=".type 2",
 783       ac_cv_asm_func_def="unknown")])]))
 784
 785 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 786 case "$ac_cv_asm_func_def" in
 787   ".def")
 788      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 789   ".type @function")
 790      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 791   ".type 2")
 792      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 793   *)
 794      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 795 esac
 796
 797 dnl **** Check for underscore on external symbols ****
 798
 799 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 800     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 801                       [extern int ac_test;],
 802                       [if (ac_test) return 1],
 803                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 804
 805 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 806 if test "$ac_cv_c_extern_prefix" = "yes"
 807 then
 808   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 809 else
 810   AC_DEFINE([__ASM_NAME(name)], [name])
 811 fi
 812
 813 dnl **** Check how to do strings in assembler ****
 814
 815 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 816     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 817       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 818         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 819           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 820
 821 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 822                    [Define to the assembler keyword used to specify an ASCII string])
 823
 824 dnl **** Check for .short in assembler ****
 825
 826 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 827     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 828       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 829         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 830
 831 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 832                    [Define to the assembler keyword used to specify a word value])
 833
 834 dnl **** Check for working dll ****
 835
 836 AC_SUBST(DLLEXT,"")
 837 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 838 AC_SUBST(DLLIBS,"")
 839 AC_SUBST(LDSHARED,"")
 840 AC_SUBST(LDDLL,"")
 841 AC_SUBST(LIBEXT,"so")
 842 AC_SUBST(IMPLIBEXT,"def")
 843
 844 case $host_os in
 845   cygwin*|mingw32*)
 846     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 847     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 848     if test "$DLLWRAP" = "false"; then
 849       LIBEXT="a"
 850     else
 851       dnl FIXME - check whether dllwrap works correctly...
 852       LIBEXT="dll"
 853     fi
 854     IMPLIBEXT="a"
 855     ;;
 856   *)
 857     AC_CHECK_HEADERS(dlfcn.h,
 858         [AC_CHECK_FUNCS(dlopen,,
 859             [AC_CHECK_LIB(dl,dlopen,
 860                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 861                           DLLIBS="-ldl"],
 862                          [LIBEXT="a"])])],
 863         [LIBEXT="a"])
 864
 865     if test "$LIBEXT" = "so"
 866     then
 867       DLLFLAGS="$DLLFLAGS -fPIC"
 868       DLLEXT=".so"
 869       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 870           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 871                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 872       if test "$ac_cv_c_dll_gnuelf" = "yes"
 873       then
 874         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 875         LDDLL="\$(CC) -shared -Wl,-Bsymbolic"
 876         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 877           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 878                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 879         if test "$ac_cv_c_dll_zdefs" = "yes"
 880         then
 881           LDDLL="$LDDLL,-z,defs"
 882         fi
 883
 884         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 885           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 886                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 887         if test "$ac_cv_c_dll_init_fini" = "yes"
 888         then
 889           AC_DEFINE(HAVE_LINKER_INIT_FINI,1,[Define if the linker supports renaming the init and fini functions])
 890           LDDLL="$LDDLL,-init,__wine_spec_init,-fini,__wine_spec_fini"
 891         fi
 892
 893         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 894           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 895                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 896         if test "$ac_cv_c_export_dynamic" = "yes"
 897         then
 898           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 899         fi
 900
 901         case $host_cpu in
 902           *i[[3456789]]86*)
 903             AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
 904               [saved_CFLAGS="$CFLAGS"
 905                CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
 906                AC_TRY_RUN([#include <unistd.h>
 907                            int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
 908                           ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
 909                CFLAGS="$saved_CFLAGS"])
 910             if test "$ac_cv_ld_reloc_exec" = "yes"
 911             then
 912               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
 913             fi
 914             ;;
 915         esac
 916
 917       else
 918         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 919             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 920                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 921         if test "$ac_cv_c_dll_unixware" = "yes"
 922         then
 923           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 924           LDDLL="\$(CC) -Wl,-G,-B,symbolic"
 925
 926         else
 927           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 928             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 929           if test "$ac_cv_c_dll_macho" = "yes"
 930           then
 931             LIBEXT="dylib"
 932             LDDLL="\$(CC) -bundle -flat_namespace -undefined suppress"
 933             LDSHARED="\$(CC) -dynamiclib"
 934             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 935           fi
 936         fi
 937       fi
 938     fi
 939
 940     dnl Check for cross compiler to build test programs
 941     AC_SUBST(CROSSTEST,"")
 942     if test "$cross_compiling" = "no"
 943     then
 944       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 945       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 946       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 947       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 948     fi
 949     ;;
 950 esac
 951
 952 if test "$LIBEXT" = "a"; then
 953   AC_MSG_ERROR(
 954 [could not find a way to build shared libraries.
 955 It is currently not possible to build Wine without shared library
 956 (.so) support to allow transparent switch between .so and .dll files.
 957 If you are using Linux, you will need a newer binutils.]
 958 )
 959 fi
 960
 961 case $build_os in
 962   cygwin*|mingw32*)
 963     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 964   darwin*|macosx*)
 965     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 966   *)
 967     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 968 esac
 969
 970 dnl Mingw needs explicit msvcrt for linking libwine
 971 case $host_os in
 972   mingw32*)
 973     AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
 974 esac
 975
 976 case $host_os in
 977   linux*)
 978     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
 979     AC_SUBST(MAIN_BINARY,"wine-glibc")
 980     ;;
 981   *)
 982     AC_SUBST(WINE_BINARIES,"wine-kthread")
 983     AC_SUBST(MAIN_BINARY,"wine-kthread")
 984     ;;
 985 esac
 986
 987 dnl **** Get the soname for libraries that we load dynamically ****
 988
 989 if test "$LIBEXT" = "so"
 990 then
 991   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
 992   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 993   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 994   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 995   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
 996   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
 997   WINE_GET_SONAME(cups,cupsGetDefault)
 998   WINE_GET_SONAME(jack,jack_client_new)
 999   WINE_GET_SONAME(fontconfig,FcInit)
1000   WINE_GET_SONAME(ssl,SSL_library_init)
1001   WINE_GET_SONAME(crypto,BIO_new_socket)
1002   WINE_GET_SONAME(ncurses,waddch)
1003   WINE_GET_SONAME(curses,waddch)
1004 fi
1005
1006
1007 dnl **** Check for functions ****
1008
1009 AC_FUNC_ALLOCA()
1010 AC_CHECK_FUNCS(\
1011         _lwp_create \
1012         _lwp_self \
1013         _pclose \
1014         _popen \
1015         _snprintf \
1016         _spawnvp \
1017         _stricmp \
1018         _strnicmp \
1019         _vsnprintf \
1020         chsize \
1021         clone \
1022         finite \
1023         fpclass \
1024         ftruncate \
1025         ftruncate64 \
1026         getnetbyaddr \
1027         getnetbyname \
1028         getopt_long \
1029         getpagesize \
1030         getprotobyname \
1031         getprotobynumber \
1032         getpwuid \
1033         getservbyport \
1034         gettid \
1035         gettimeofday \
1036         inet_network \
1037         lseek64 \
1038         lstat \
1039         memmove \
1040         mmap \
1041         pclose \
1042         popen \
1043         pread \
1044         pwrite \
1045         readlink \
1046         rfork \
1047         select \
1048         sendmsg \
1049         settimeofday \
1050         sigaltstack \
1051         snprintf \
1052         spawnvp \
1053         statfs \
1054         strcasecmp \
1055         strerror \
1056         strncasecmp \
1057         tcgetattr \
1058         timegm \
1059         usleep \
1060         vfscanf \
1061         vsnprintf \
1062         wait4 \
1063         waitpid \
1064 )
1065
1066 dnl **** Check for header files ****
1067
1068 AC_CHECK_HEADERS(\
1069         arpa/inet.h \
1070         arpa/nameser.h \
1071         cups/cups.h \
1072         direct.h \
1073         elf.h \
1074         float.h \
1075         fontconfig/fontconfig.h \
1076         getopt.h \
1077         ieeefp.h \
1078         io.h \
1079         jack/jack.h \
1080         libio.h \
1081         libutil.h \
1082         link.h \
1083         linux/cdrom.h \
1084         linux/hdreg.h \
1085         linux/input.h \
1086         linux/joystick.h \
1087         linux/major.h \
1088         linux/param.h \
1089         linux/serial.h \
1090         linux/ucdrom.h \
1091         machine/cpu.h \
1092         netdb.h \
1093         netinet/in.h \
1094         netinet/in_systm.h \
1095         netinet/tcp.h \
1096         netinet/tcp_fsm.h \
1097         openssl/ssl.h \
1098         process.h \
1099         pthread.h \
1100         pty.h \
1101         pwd.h \
1102         regex.h \
1103         sched.h \
1104         scsi/sg.h \
1105         scsi/scsi.h \
1106         scsi/scsi_ioctl.h \
1107         socket.h \
1108         stdint.h \
1109         strings.h \
1110         sys/cdio.h \
1111         sys/errno.h \
1112         sys/file.h \
1113         sys/filio.h \
1114         sys/inttypes.h \
1115         sys/ioctl.h \
1116         sys/ipc.h \
1117         sys/link.h \
1118         sys/lwp.h \
1119         sys/mman.h \
1120         sys/modem.h \
1121         sys/msg.h \
1122         sys/param.h \
1123         sys/poll.h \
1124         sys/ptrace.h \
1125         sys/reg.h \
1126         sys/scsiio.h \
1127         sys/shm.h \
1128         sys/signal.h \
1129         sys/socket.h \
1130         sys/sockio.h \
1131         sys/statfs.h \
1132         sys/strtio.h \
1133         sys/syscall.h \
1134         sys/sysctl.h \
1135         sys/time.h \
1136         sys/times.h \
1137         sys/uio.h \
1138         sys/un.h \
1139         sys/v86.h \
1140         sys/v86intr.h \
1141         sys/vfs.h \
1142         sys/vm86.h \
1143         sys/wait.h \
1144         syscall.h \
1145         termios.h \
1146         unistd.h \
1147         utime.h \
1148         valgrind/memcheck.h
1149 )
1150 AC_HEADER_STAT()
1151
1152 dnl **** Checks for headers that depend on other ones ****
1153
1154 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1155     [#include <sys/types.h>
1156      #if HAVE_SYS_PARAM_H
1157      # include <sys/param.h>
1158      #endif])
1159
1160 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1161     [#include <sys/types.h>
1162      #if HAVE_SYS_SOCKET_H
1163      # include <sys/socket.h>
1164      #endif])
1165
1166 AC_CHECK_HEADERS([resolv.h],,,
1167     [#include <sys/types.h>
1168      #if HAVE_SYS_SOCKET_H
1169      # include <sys/socket.h>
1170      #endif
1171      #if HAVE_NETINET_IN_H
1172      # include <netinet/in.h>
1173      #endif
1174      #if HAVE_ARPA_NAMESER_H
1175      # include <arpa/nameser.h>
1176      #endif])
1177
1178 AC_CHECK_HEADERS(netinet/ip.h,,,
1179     [#include <sys/types.h>
1180      #if HAVE_SYS_SOCKET_H
1181      # include <sys/socket.h>
1182      #endif
1183      #if HAVE_NETINET_IN_SYSTM_H
1184      # include <netinet/in_systm.h>
1185      #endif])
1186
1187 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1188
1189 dnl **** Check for IPX headers (currently Linux only) ****
1190
1191 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1192  AC_TRY_COMPILE(
1193    [#include <sys/types.h>
1194     #ifdef HAVE_SYS_SOCKET_H
1195     # include <sys/socket.h>
1196     #endif
1197     #include <netipx/ipx.h>],
1198    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1199    [ac_cv_c_ipx_gnu="yes"],
1200    [ac_cv_c_ipx_gnu="no"])
1201  )
1202 if test "$ac_cv_c_ipx_gnu" = "yes"
1203 then
1204     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1205 fi
1206
1207 if test "$ac_cv_c_ipx_gnu" = "no"
1208 then
1209  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1210   AC_TRY_COMPILE(
1211     [#include <sys/types.h>
1212      #ifdef HAVE_SYS_SOCKET_H
1213      # include <sys/socket.h>
1214      #endif
1215      #include <asm/types.h>
1216      #include <linux/ipx.h>],
1217     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1218     [ac_cv_c_ipx_linux="yes"],
1219     [ac_cv_c_ipx_linux="no"])
1220   )
1221   if test "$ac_cv_c_ipx_linux" = "yes"
1222   then
1223       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1224   fi
1225 fi
1226
1227 dnl **** Check for types ****
1228
1229 AC_C_CONST
1230 AC_C_INLINE
1231 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1232 AC_CHECK_SIZEOF(long long,0)
1233
1234 AC_CACHE_CHECK([whether linux/input.h is for real],
1235         wine_cv_linux_input_h,
1236         AC_TRY_COMPILE([
1237             #include <linux/input.h>
1238         ] , [
1239             int foo = EVIOCGBIT(EV_ABS,42);
1240             int bar = BTN_PINKIE;
1241             int fortytwo = 42;
1242         ],
1243         wine_cv_linux_input_h=yes,
1244         wine_cv_linux_input_h=no,
1245         no
1246         )
1247     )
1248     if test "$wine_cv_linux_input_h" = "yes"
1249     then
1250         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1251                   [Define if we have linux/input.h AND it contains the INPUT event API])
1252     fi
1253
1254
1255 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1256         wine_cv_linux_gethostbyname_r_6,
1257         AC_TRY_LINK([
1258 #include <netdb.h>
1259         ], [
1260     char *name=NULL;
1261     struct hostent he;
1262     struct hostent *result;
1263     char *buf=NULL;
1264     int bufsize=0;
1265     int res,errnr;
1266     char *addr=NULL;
1267     int addrlen=0;
1268     int addrtype=0;
1269     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1270     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1271     ],
1272         wine_cv_linux_gethostbyname_r_6=yes,
1273         wine_cv_linux_gethostbyname_r_6=no
1274         )
1275    )
1276    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1277    then
1278       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1279                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1280    fi
1281
1282 if test "$ac_cv_header_linux_joystick_h" = "yes"
1283 then
1284    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1285         wine_cv_linux_joystick_22_api,
1286         AC_TRY_COMPILE([
1287         #include <sys/ioctl.h>
1288         #include <linux/joystick.h>
1289
1290         struct js_event blub;
1291         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1292         #error "no 2.2 header"
1293         #endif
1294         ],/*empty*/,
1295         wine_cv_linux_joystick_22_api=yes,
1296         wine_cv_linux_joystick_22_api=no,
1297         wine_cv_linux_joystick_22_api=no
1298         )
1299    )
1300    if test "$wine_cv_linux_joystick_22_api" = "yes"
1301    then
1302       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1303                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1304    fi
1305 fi
1306
1307 dnl **** statfs checks ****
1308
1309 if test "$ac_cv_header_sys_vfs_h" = "yes"
1310 then
1311     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1312                     wine_cv_sys_vfs_has_statfs,
1313         AC_TRY_COMPILE([
1314         #include <sys/types.h>
1315         #ifdef HAVE_SYS_PARAM_H
1316         # include <sys/param.h>
1317         #endif
1318         #include <sys/vfs.h>
1319         ],[
1320                 struct statfs stfs;
1321
1322                 memset(&stfs,0,sizeof(stfs));
1323         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1324         )
1325     )
1326     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1327     then
1328       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1329                 [Define if the struct statfs is defined by <sys/vfs.h>])
1330     fi
1331 fi
1332
1333 if test "$ac_cv_header_sys_statfs_h" = "yes"
1334 then
1335     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1336                     wine_cv_sys_statfs_has_statfs,
1337         AC_TRY_COMPILE([
1338         #include <sys/types.h>
1339         #ifdef HAVE_SYS_PARAM_H
1340         # include <sys/param.h>
1341         #endif
1342         #include <sys/statfs.h>
1343         ],[
1344                 struct statfs stfs;
1345         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1346         )
1347     )
1348     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1349     then
1350       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1351                 [Define if the struct statfs is defined by <sys/statfs.h>])
1352     fi
1353 fi
1354
1355 if test "$ac_cv_header_sys_mount_h" = "yes"
1356 then
1357     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1358                     wine_cv_sys_mount_has_statfs,
1359         AC_TRY_COMPILE([
1360         #include <sys/types.h>
1361         #ifdef HAVE_SYS_PARAM_H
1362         # include <sys/param.h>
1363         #endif
1364         #include <sys/mount.h>
1365         ],[
1366                 struct statfs stfs;
1367         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1368         )
1369     )
1370     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1371     then
1372       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1373                 [Define if the struct statfs is defined by <sys/mount.h>])
1374     fi
1375 fi
1376
1377 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1378
1379 dnl Check for statfs members
1380 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1381 [#include <sys/types.h>
1382 #ifdef HAVE_SYS_PARAM_H
1383 # include <sys/param.h>
1384 #endif
1385 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1386 # include <sys/mount.h>
1387 #else
1388 # ifdef STATFS_DEFINED_BY_SYS_VFS
1389 #  include <sys/vfs.h>
1390 # else
1391 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1392 #   include <sys/statfs.h>
1393 #  endif
1394 # endif
1395 #endif])
1396
1397 dnl Check for socket structure members
1398 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1399 [#include <sys/types.h>
1400 #ifdef HAVE_SYS_SOCKET_H
1401 # include <sys/socket.h>
1402 #endif
1403 #ifdef HAVE_SYS_UN_H
1404 # include <sys/un.h>
1405 #endif])
1406
1407 dnl Check for siginfo_t members
1408 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1409
1410 dnl Check for struct option
1411 AC_CHECK_MEMBERS([struct option.name],,,
1412 [#ifdef HAVE_GETOPT_H
1413 #include <getopt.h>
1414 #endif])
1415
1416 dnl Check for stat.st_blocks
1417 AC_CHECK_MEMBERS([struct stat.st_blocks])
1418
1419 dnl *** check for the need to define platform-specific symbols
1420
1421 case $host_cpu in
1422   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1423   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1424   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1425   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1426 esac
1427
1428 case $host_vendor in
1429   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1430 esac
1431
1432 dnl **** Generate output files ****
1433
1434 AH_TOP([#define __WINE_CONFIG_H])
1435
1436 WINE_CONFIG_EXTRA_DIR(controls)
1437 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1438 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1439 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1440 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1441 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1442 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1443 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1444 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1445 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1446 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1447 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1448 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1449 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1450 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1451 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1452 WINE_CONFIG_EXTRA_DIR(files)
1453 WINE_CONFIG_EXTRA_DIR(graphics)
1454 WINE_CONFIG_EXTRA_DIR(include/wine)
1455 WINE_CONFIG_EXTRA_DIR(misc)
1456 WINE_CONFIG_EXTRA_DIR(objects)
1457 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1458 WINE_CONFIG_EXTRA_DIR(windows)
1459
1460 MAKE_RULES=Make.rules
1461 AC_SUBST_FILE(MAKE_RULES)
1462
1463 MAKE_DLL_RULES=dlls/Makedll.rules
1464 AC_SUBST_FILE(MAKE_DLL_RULES)
1465
1466 MAKE_TEST_RULES=dlls/Maketest.rules
1467 AC_SUBST_FILE(MAKE_TEST_RULES)
1468
1469 MAKE_LIB_RULES=libs/Makelib.rules
1470 AC_SUBST_FILE(MAKE_LIB_RULES)
1471
1472 MAKE_PROG_RULES=programs/Makeprog.rules
1473 AC_SUBST_FILE(MAKE_PROG_RULES)
1474
1475 AC_CONFIG_FILES([
1476 Make.rules
1477 dlls/Makedll.rules
1478 dlls/Maketest.rules
1479 libs/Makelib.rules
1480 programs/Makeprog.rules
1481 Makefile
1482 dlls/Makefile
1483 dlls/advapi32/Makefile
1484 dlls/advapi32/tests/Makefile
1485 dlls/avicap32/Makefile
1486 dlls/avifil32/Makefile
1487 dlls/cabinet/Makefile
1488 dlls/capi2032/Makefile
1489 dlls/cfgmgr32/Makefile
1490 dlls/comcat/Makefile
1491 dlls/comctl32/Makefile
1492 dlls/comctl32/tests/Makefile
1493 dlls/commdlg/Makefile
1494 dlls/crtdll/Makefile
1495 dlls/crypt32/Makefile
1496 dlls/ctl3d/Makefile
1497 dlls/wined3d/Makefile
1498 dlls/d3d8/Makefile
1499 dlls/d3d9/Makefile
1500 dlls/d3dim/Makefile
1501 dlls/d3dx8/Makefile
1502 dlls/dciman32/Makefile
1503 dlls/ddraw/Makefile
1504 dlls/ddraw/tests/Makefile
1505 dlls/devenum/Makefile
1506 dlls/dinput/Makefile
1507 dlls/dinput8/Makefile
1508 dlls/dmband/Makefile
1509 dlls/dmcompos/Makefile
1510 dlls/dmime/Makefile
1511 dlls/dmloader/Makefile
1512 dlls/dmscript/Makefile
1513 dlls/dmstyle/Makefile
1514 dlls/dmsynth/Makefile
1515 dlls/dmusic/Makefile
1516 dlls/dmusic32/Makefile
1517 dlls/dplay/Makefile
1518 dlls/dplayx/Makefile
1519 dlls/dpnhpast/Makefile
1520 dlls/dsound/Makefile
1521 dlls/dsound/tests/Makefile
1522 dlls/gdi/Makefile
1523 dlls/gdi/tests/Makefile
1524 dlls/glu32/Makefile
1525 dlls/glut32/Makefile
1526 dlls/icmp/Makefile
1527 dlls/imagehlp/Makefile
1528 dlls/imm32/Makefile
1529 dlls/iphlpapi/Makefile
1530 dlls/iphlpapi/tests/Makefile
1531 dlls/kernel/Makefile
1532 dlls/kernel/tests/Makefile
1533 dlls/lzexpand/Makefile
1534 dlls/mapi32/Makefile
1535 dlls/mpr/Makefile
1536 dlls/msacm/Makefile
1537 dlls/msacm/imaadp32/Makefile
1538 dlls/msacm/msadp32/Makefile
1539 dlls/msacm/msg711/Makefile
1540 dlls/msacm/winemp3/Makefile
1541 dlls/msdmo/Makefile
1542 dlls/mshtml/Makefile
1543 dlls/msi/Makefile
1544 dlls/msimg32/Makefile
1545 dlls/msisys/Makefile
1546 dlls/msnet32/Makefile
1547 dlls/msvcrt/Makefile
1548 dlls/msvcrt/tests/Makefile
1549 dlls/msvcrt20/Makefile
1550 dlls/msvcrt40/Makefile
1551 dlls/msvcrtd/Makefile
1552 dlls/msvideo/Makefile
1553 dlls/msvideo/msrle32/Makefile
1554 dlls/mswsock/Makefile
1555 dlls/netapi32/Makefile
1556 dlls/netapi32/tests/Makefile
1557 dlls/newdev/Makefile
1558 dlls/ntdll/Makefile
1559 dlls/ntdll/tests/Makefile
1560 dlls/odbc32/Makefile
1561 dlls/ole32/Makefile
1562 dlls/oleacc/Makefile
1563 dlls/oleaut32/Makefile
1564 dlls/oleaut32/tests/Makefile
1565 dlls/olecli/Makefile
1566 dlls/oledlg/Makefile
1567 dlls/olepro32/Makefile
1568 dlls/olesvr/Makefile
1569 dlls/opengl32/Makefile
1570 dlls/psapi/Makefile
1571 dlls/qcap/Makefile
1572 dlls/quartz/Makefile
1573 dlls/rasapi32/Makefile
1574 dlls/richedit/Makefile
1575 dlls/rpcrt4/Makefile
1576 dlls/rpcrt4/tests/Makefile
1577 dlls/serialui/Makefile
1578 dlls/setupapi/Makefile
1579 dlls/shdocvw/Makefile
1580 dlls/shell32/Makefile
1581 dlls/shell32/tests/Makefile
1582 dlls/shfolder/Makefile
1583 dlls/shlwapi/Makefile
1584 dlls/shlwapi/tests/Makefile
1585 dlls/snmpapi/Makefile
1586 dlls/sti/Makefile
1587 dlls/tapi32/Makefile
1588 dlls/ttydrv/Makefile
1589 dlls/twain/Makefile
1590 dlls/unicows/Makefile
1591 dlls/url/Makefile
1592 dlls/urlmon/Makefile
1593 dlls/urlmon/tests/Makefile
1594 dlls/user/Makefile
1595 dlls/user/tests/Makefile
1596 dlls/uxtheme/Makefile
1597 dlls/version/Makefile
1598 dlls/win32s/Makefile
1599 dlls/winaspi/Makefile
1600 dlls/winedos/Makefile
1601 dlls/wineps/Makefile
1602 dlls/wininet/Makefile
1603 dlls/wininet/tests/Makefile
1604 dlls/winmm/Makefile
1605 dlls/winmm/joystick/Makefile
1606 dlls/winmm/mcianim/Makefile
1607 dlls/winmm/mciavi/Makefile
1608 dlls/winmm/mcicda/Makefile
1609 dlls/winmm/mciseq/Makefile
1610 dlls/winmm/mciwave/Makefile
1611 dlls/winmm/midimap/Makefile
1612 dlls/winmm/tests/Makefile
1613 dlls/winmm/wavemap/Makefile
1614 dlls/winmm/winealsa/Makefile
1615 dlls/winmm/winearts/Makefile
1616 dlls/winmm/wineaudioio/Makefile
1617 dlls/winmm/winenas/Makefile
1618 dlls/winmm/winejack/Makefile
1619 dlls/winmm/wineoss/Makefile
1620 dlls/winnls/Makefile
1621 dlls/winsock/Makefile
1622 dlls/winsock/tests/Makefile
1623 dlls/winspool/Makefile
1624 dlls/winspool/tests/Makefile
1625 dlls/wintab32/Makefile
1626 dlls/wintrust/Makefile
1627 dlls/wow32/Makefile
1628 dlls/wsock32/Makefile
1629 dlls/x11drv/Makefile
1630 documentation/Makefile
1631 include/Makefile
1632 libs/Makefile
1633 libs/port/Makefile
1634 libs/unicode/Makefile
1635 libs/uuid/Makefile
1636 libs/wine/Makefile
1637 libs/wpp/Makefile
1638 loader/Makefile
1639 programs/Makefile
1640 programs/avitools/Makefile
1641 programs/clock/Makefile
1642 programs/cmdlgtst/Makefile
1643 programs/control/Makefile
1644 programs/expand/Makefile
1645 programs/notepad/Makefile
1646 programs/progman/Makefile
1647 programs/regedit/Makefile
1648 programs/regsvr32/Makefile
1649 programs/rpcss/Makefile
1650 programs/rundll32/Makefile
1651 programs/start/Makefile
1652 programs/uninstaller/Makefile
1653 programs/view/Makefile
1654 programs/wcmd/Makefile
1655 programs/wineboot/Makefile
1656 programs/winebrowser/Makefile
1657 programs/winecfg/Makefile
1658 programs/wineconsole/Makefile
1659 programs/winedbg/Makefile
1660 programs/winefile/Makefile
1661 programs/winemenubuilder/Makefile
1662 programs/winemine/Makefile
1663 programs/winepath/Makefile
1664 programs/winetest/Makefile
1665 programs/winevdm/Makefile
1666 programs/winhelp/Makefile
1667 programs/winver/Makefile
1668 server/Makefile
1669 tools/Makefile
1670 tools/widl/Makefile
1671 tools/winapi/Makefile
1672 tools/winebuild/Makefile
1673 tools/winedump/Makefile
1674 tools/winegcc/Makefile
1675 tools/wmc/Makefile
1676 tools/wrc/Makefile])
1677
1678 AC_OUTPUT
1679
1680 if test "$have_x" = "no"
1681 then
1682   echo
1683   echo "*** Warning: X development files not found. Wine will be built without"
1684   echo "*** X support, which currently does not work, and would probably not be"
1685   echo "*** what you want anyway. You will need to install devel packages of"
1686   echo "*** Xlib/Xfree86 at the very least."
1687 fi
1688
1689 if test "$wine_cv_opengl_version_OK" = "no"
1690 then
1691   echo
1692   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1693   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1694 fi
1695
1696 if test "$wine_cv_msg_freetype" = "yes"
1697 then
1698   echo
1699   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1700   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1701   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1702   echo "*** enable Wine to use TrueType fonts."
1703 fi
1704
1705 echo
1706 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1707 echo
1708
1709 dnl Local Variables:
1710 dnl comment-start: "dnl "
1711 dnl comment-end: ""
1712 dnl comment-start-skip: "\\bdnl\\b\\s *"
1713 dnl compile-command: "autoconf"
1714 dnl End: